diff --git a/src/HOL/Real.thy b/src/HOL/Real.thy
--- a/src/HOL/Real.thy
+++ b/src/HOL/Real.thy
@@ -1,1772 +1,1772 @@
 (*  Title:      HOL/Real.thy
     Author:     Jacques D. Fleuriot, University of Edinburgh, 1998
     Author:     Larry Paulson, University of Cambridge
     Author:     Jeremy Avigad, Carnegie Mellon University
     Author:     Florian Zuleger, Johannes Hoelzl, and Simon Funke, TU Muenchen
     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     Construction of Cauchy Reals by Brian Huffman, 2010
 *)
 
 section \<open>Development of the Reals using Cauchy Sequences\<close>
 
 theory Real
 imports Rat
 begin
 
 text \<open>
   This theory contains a formalization of the real numbers as equivalence
-  classes of Cauchy sequences of rationals. See
-  \<^file>\<open>~~/src/HOL/ex/Dedekind_Real.thy\<close> for an alternative construction using
+  classes of Cauchy sequences of rationals. See the AFP entry
+  @{text Dedekind_Real} for an alternative construction using
   Dedekind cuts.
 \<close>
 
 
 subsection \<open>Preliminary lemmas\<close>
 
 text\<open>Useful in convergence arguments\<close>
 lemma inverse_of_nat_le:
   fixes n::nat shows "\<lbrakk>n \<le> m; n\<noteq>0\<rbrakk> \<Longrightarrow> 1 / of_nat m \<le> (1::'a::linordered_field) / of_nat n"
   by (simp add: frac_le)
 
 lemma add_diff_add: "(a + c) - (b + d) = (a - b) + (c - d)"
   for a b c d :: "'a::ab_group_add"
   by simp
 
 lemma minus_diff_minus: "- a - - b = - (a - b)"
   for a b :: "'a::ab_group_add"
   by simp
 
 lemma mult_diff_mult: "(x * y - a * b) = x * (y - b) + (x - a) * b"
   for x y a b :: "'a::ring"
   by (simp add: algebra_simps)
 
 lemma inverse_diff_inverse:
   fixes a b :: "'a::division_ring"
   assumes "a \<noteq> 0" and "b \<noteq> 0"
   shows "inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   using assms by (simp add: algebra_simps)
 
 lemma obtain_pos_sum:
   fixes r :: rat assumes r: "0 < r"
   obtains s t where "0 < s" and "0 < t" and "r = s + t"
 proof
   from r show "0 < r/2" by simp
   from r show "0 < r/2" by simp
   show "r = r/2 + r/2" by simp
 qed
 
 
 subsection \<open>Sequences that converge to zero\<close>
 
 definition vanishes :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
   where "vanishes X \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r)"
 
 lemma vanishesI: "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r) \<Longrightarrow> vanishes X"
   unfolding vanishes_def by simp
 
 lemma vanishesD: "vanishes X \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r"
   unfolding vanishes_def by simp
 
 lemma vanishes_const [simp]: "vanishes (\<lambda>n. c) \<longleftrightarrow> c = 0"
 proof (cases "c = 0")
   case True
   then show ?thesis
     by (simp add: vanishesI)    
 next
   case False
   then show ?thesis
     unfolding vanishes_def
     using zero_less_abs_iff by blast
 qed
 
 lemma vanishes_minus: "vanishes X \<Longrightarrow> vanishes (\<lambda>n. - X n)"
   unfolding vanishes_def by simp
 
 lemma vanishes_add:
   assumes X: "vanishes X"
     and Y: "vanishes Y"
   shows "vanishes (\<lambda>n. X n + Y n)"
 proof (rule vanishesI)
   fix r :: rat
   assume "0 < r"
   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
     by (rule obtain_pos_sum)
   obtain i where i: "\<forall>n\<ge>i. \<bar>X n\<bar> < s"
     using vanishesD [OF X s] ..
   obtain j where j: "\<forall>n\<ge>j. \<bar>Y n\<bar> < t"
     using vanishesD [OF Y t] ..
   have "\<forall>n\<ge>max i j. \<bar>X n + Y n\<bar> < r"
   proof clarsimp
     fix n
     assume n: "i \<le> n" "j \<le> n"
     have "\<bar>X n + Y n\<bar> \<le> \<bar>X n\<bar> + \<bar>Y n\<bar>"
       by (rule abs_triangle_ineq)
     also have "\<dots> < s + t"
       by (simp add: add_strict_mono i j n)
     finally show "\<bar>X n + Y n\<bar> < r"
       by (simp only: r)
   qed
   then show "\<exists>k. \<forall>n\<ge>k. \<bar>X n + Y n\<bar> < r" ..
 qed
 
 lemma vanishes_diff:
   assumes "vanishes X" "vanishes Y"
   shows "vanishes (\<lambda>n. X n - Y n)"
   unfolding diff_conv_add_uminus by (intro vanishes_add vanishes_minus assms)
 
 lemma vanishes_mult_bounded:
   assumes X: "\<exists>a>0. \<forall>n. \<bar>X n\<bar> < a"
   assumes Y: "vanishes (\<lambda>n. Y n)"
   shows "vanishes (\<lambda>n. X n * Y n)"
 proof (rule vanishesI)
   fix r :: rat
   assume r: "0 < r"
   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
     using X by blast
   obtain b where b: "0 < b" "r = a * b"
   proof
     show "0 < r / a" using r a by simp
     show "r = a * (r / a)" using a by simp
   qed
   obtain k where k: "\<forall>n\<ge>k. \<bar>Y n\<bar> < b"
     using vanishesD [OF Y b(1)] ..
   have "\<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r"
     by (simp add: b(2) abs_mult mult_strict_mono' a k)
   then show "\<exists>k. \<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r" ..
 qed
 
 
 subsection \<open>Cauchy sequences\<close>
 
 definition cauchy :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
   where "cauchy X \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r)"
 
 lemma cauchyI: "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r) \<Longrightarrow> cauchy X"
   unfolding cauchy_def by simp
 
 lemma cauchyD: "cauchy X \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r"
   unfolding cauchy_def by simp
 
 lemma cauchy_const [simp]: "cauchy (\<lambda>n. x)"
   unfolding cauchy_def by simp
 
 lemma cauchy_add [simp]:
   assumes X: "cauchy X" and Y: "cauchy Y"
   shows "cauchy (\<lambda>n. X n + Y n)"
 proof (rule cauchyI)
   fix r :: rat
   assume "0 < r"
   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
     by (rule obtain_pos_sum)
   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
     using cauchyD [OF X s] ..
   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
     using cauchyD [OF Y t] ..
   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r"
   proof clarsimp
     fix m n
     assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
     have "\<bar>(X m + Y m) - (X n + Y n)\<bar> \<le> \<bar>X m - X n\<bar> + \<bar>Y m - Y n\<bar>"
       unfolding add_diff_add by (rule abs_triangle_ineq)
     also have "\<dots> < s + t"
       by (rule add_strict_mono) (simp_all add: i j *)
     finally show "\<bar>(X m + Y m) - (X n + Y n)\<bar> < r" by (simp only: r)
   qed
   then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r" ..
 qed
 
 lemma cauchy_minus [simp]:
   assumes X: "cauchy X"
   shows "cauchy (\<lambda>n. - X n)"
   using assms unfolding cauchy_def
   unfolding minus_diff_minus abs_minus_cancel .
 
 lemma cauchy_diff [simp]:
   assumes "cauchy X" "cauchy Y"
   shows "cauchy (\<lambda>n. X n - Y n)"
   using assms unfolding diff_conv_add_uminus by (simp del: add_uminus_conv_diff)
 
 lemma cauchy_imp_bounded:
   assumes "cauchy X"
   shows "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
 proof -
   obtain k where k: "\<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < 1"
     using cauchyD [OF assms zero_less_one] ..
   show "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   proof (intro exI conjI allI)
     have "0 \<le> \<bar>X 0\<bar>" by simp
     also have "\<bar>X 0\<bar> \<le> Max (abs ` X ` {..k})" by simp
     finally have "0 \<le> Max (abs ` X ` {..k})" .
     then show "0 < Max (abs ` X ` {..k}) + 1" by simp
   next
     fix n :: nat
     show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1"
     proof (rule linorder_le_cases)
       assume "n \<le> k"
       then have "\<bar>X n\<bar> \<le> Max (abs ` X ` {..k})" by simp
       then show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" by simp
     next
       assume "k \<le> n"
       have "\<bar>X n\<bar> = \<bar>X k + (X n - X k)\<bar>" by simp
       also have "\<bar>X k + (X n - X k)\<bar> \<le> \<bar>X k\<bar> + \<bar>X n - X k\<bar>"
         by (rule abs_triangle_ineq)
       also have "\<dots> < Max (abs ` X ` {..k}) + 1"
         by (rule add_le_less_mono) (simp_all add: k \<open>k \<le> n\<close>)
       finally show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" .
     qed
   qed
 qed
 
 lemma cauchy_mult [simp]:
   assumes X: "cauchy X" and Y: "cauchy Y"
   shows "cauchy (\<lambda>n. X n * Y n)"
 proof (rule cauchyI)
   fix r :: rat assume "0 < r"
   then obtain u v where u: "0 < u" and v: "0 < v" and "r = u + v"
     by (rule obtain_pos_sum)
   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
     using cauchy_imp_bounded [OF X] by blast
   obtain b where b: "0 < b" "\<forall>n. \<bar>Y n\<bar> < b"
     using cauchy_imp_bounded [OF Y] by blast
   obtain s t where s: "0 < s" and t: "0 < t" and r: "r = a * t + s * b"
   proof
     show "0 < v/b" using v b(1) by simp
     show "0 < u/a" using u a(1) by simp
     show "r = a * (u/a) + (v/b) * b"
       using a(1) b(1) \<open>r = u + v\<close> by simp
   qed
   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
     using cauchyD [OF X s] ..
   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
     using cauchyD [OF Y t] ..
   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>X m * Y m - X n * Y n\<bar> < r"
   proof clarsimp
     fix m n
     assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
     have "\<bar>X m * Y m - X n * Y n\<bar> = \<bar>X m * (Y m - Y n) + (X m - X n) * Y n\<bar>"
       unfolding mult_diff_mult ..
     also have "\<dots> \<le> \<bar>X m * (Y m - Y n)\<bar> + \<bar>(X m - X n) * Y n\<bar>"
       by (rule abs_triangle_ineq)
     also have "\<dots> = \<bar>X m\<bar> * \<bar>Y m - Y n\<bar> + \<bar>X m - X n\<bar> * \<bar>Y n\<bar>"
       unfolding abs_mult ..
     also have "\<dots> < a * t + s * b"
       by (simp_all add: add_strict_mono mult_strict_mono' a b i j *)
     finally show "\<bar>X m * Y m - X n * Y n\<bar> < r"
       by (simp only: r)
   qed
   then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m * Y m - X n * Y n\<bar> < r" ..
 qed
 
 lemma cauchy_not_vanishes_cases:
   assumes X: "cauchy X"
   assumes nz: "\<not> vanishes X"
   shows "\<exists>b>0. \<exists>k. (\<forall>n\<ge>k. b < - X n) \<or> (\<forall>n\<ge>k. b < X n)"
 proof -
   obtain r where "0 < r" and r: "\<forall>k. \<exists>n\<ge>k. r \<le> \<bar>X n\<bar>"
     using nz unfolding vanishes_def by (auto simp add: not_less)
   obtain s t where s: "0 < s" and t: "0 < t" and "r = s + t"
     using \<open>0 < r\<close> by (rule obtain_pos_sum)
   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
     using cauchyD [OF X s] ..
   obtain k where "i \<le> k" and "r \<le> \<bar>X k\<bar>"
     using r by blast
   have k: "\<forall>n\<ge>k. \<bar>X n - X k\<bar> < s"
     using i \<open>i \<le> k\<close> by auto
   have "X k \<le> - r \<or> r \<le> X k"
     using \<open>r \<le> \<bar>X k\<bar>\<close> by auto
   then have "(\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
     unfolding \<open>r = s + t\<close> using k by auto
   then have "\<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)" ..
   then show "\<exists>t>0. \<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
     using t by auto
 qed
 
 lemma cauchy_not_vanishes:
   assumes X: "cauchy X"
     and nz: "\<not> vanishes X"
   shows "\<exists>b>0. \<exists>k. \<forall>n\<ge>k. b < \<bar>X n\<bar>"
   using cauchy_not_vanishes_cases [OF assms]
   by (elim ex_forward conj_forward asm_rl) auto
 
 lemma cauchy_inverse [simp]:
   assumes X: "cauchy X"
     and nz: "\<not> vanishes X"
   shows "cauchy (\<lambda>n. inverse (X n))"
 proof (rule cauchyI)
   fix r :: rat
   assume "0 < r"
   obtain b i where b: "0 < b" and i: "\<forall>n\<ge>i. b < \<bar>X n\<bar>"
     using cauchy_not_vanishes [OF X nz] by blast
   from b i have nz: "\<forall>n\<ge>i. X n \<noteq> 0" by auto
   obtain s where s: "0 < s" and r: "r = inverse b * s * inverse b"
   proof
     show "0 < b * r * b" by (simp add: \<open>0 < r\<close> b)
     show "r = inverse b * (b * r * b) * inverse b"
       using b by simp
   qed
   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>X m - X n\<bar> < s"
     using cauchyD [OF X s] ..
   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>inverse (X m) - inverse (X n)\<bar> < r"
   proof clarsimp
     fix m n
     assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
     have "\<bar>inverse (X m) - inverse (X n)\<bar> = inverse \<bar>X m\<bar> * \<bar>X m - X n\<bar> * inverse \<bar>X n\<bar>"
       by (simp add: inverse_diff_inverse nz * abs_mult)
     also have "\<dots> < inverse b * s * inverse b"
       by (simp add: mult_strict_mono less_imp_inverse_less i j b * s)
     finally show "\<bar>inverse (X m) - inverse (X n)\<bar> < r" by (simp only: r)
   qed
   then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>inverse (X m) - inverse (X n)\<bar> < r" ..
 qed
 
 lemma vanishes_diff_inverse:
   assumes X: "cauchy X" "\<not> vanishes X"
     and Y: "cauchy Y" "\<not> vanishes Y"
     and XY: "vanishes (\<lambda>n. X n - Y n)"
   shows "vanishes (\<lambda>n. inverse (X n) - inverse (Y n))"
 proof (rule vanishesI)
   fix r :: rat
   assume r: "0 < r"
   obtain a i where a: "0 < a" and i: "\<forall>n\<ge>i. a < \<bar>X n\<bar>"
     using cauchy_not_vanishes [OF X] by blast
   obtain b j where b: "0 < b" and j: "\<forall>n\<ge>j. b < \<bar>Y n\<bar>"
     using cauchy_not_vanishes [OF Y] by blast
   obtain s where s: "0 < s" and "inverse a * s * inverse b = r"
   proof
     show "0 < a * r * b"
       using a r b by simp
     show "inverse a * (a * r * b) * inverse b = r"
       using a r b by simp
   qed
   obtain k where k: "\<forall>n\<ge>k. \<bar>X n - Y n\<bar> < s"
     using vanishesD [OF XY s] ..
   have "\<forall>n\<ge>max (max i j) k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r"
   proof clarsimp
     fix n
     assume n: "i \<le> n" "j \<le> n" "k \<le> n"
     with i j a b have "X n \<noteq> 0" and "Y n \<noteq> 0"
       by auto
     then have "\<bar>inverse (X n) - inverse (Y n)\<bar> = inverse \<bar>X n\<bar> * \<bar>X n - Y n\<bar> * inverse \<bar>Y n\<bar>"
       by (simp add: inverse_diff_inverse abs_mult)
     also have "\<dots> < inverse a * s * inverse b"
       by (intro mult_strict_mono' less_imp_inverse_less) (simp_all add: a b i j k n)
     also note \<open>inverse a * s * inverse b = r\<close>
     finally show "\<bar>inverse (X n) - inverse (Y n)\<bar> < r" .
   qed
   then show "\<exists>k. \<forall>n\<ge>k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r" ..
 qed
 
 
 subsection \<open>Equivalence relation on Cauchy sequences\<close>
 
 definition realrel :: "(nat \<Rightarrow> rat) \<Rightarrow> (nat \<Rightarrow> rat) \<Rightarrow> bool"
   where "realrel = (\<lambda>X Y. cauchy X \<and> cauchy Y \<and> vanishes (\<lambda>n. X n - Y n))"
 
 lemma realrelI [intro?]: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> vanishes (\<lambda>n. X n - Y n) \<Longrightarrow> realrel X Y"
   by (simp add: realrel_def)
 
 lemma realrel_refl: "cauchy X \<Longrightarrow> realrel X X"
   by (simp add: realrel_def)
 
 lemma symp_realrel: "symp realrel"
   by (simp add: abs_minus_commute realrel_def symp_def vanishes_def)
 
 lemma transp_realrel: "transp realrel"
   unfolding realrel_def
   by (rule transpI) (force simp add: dest: vanishes_add)
 
 lemma part_equivp_realrel: "part_equivp realrel"
   by (blast intro: part_equivpI symp_realrel transp_realrel realrel_refl cauchy_const)
 
 
 subsection \<open>The field of real numbers\<close>
 
 quotient_type real = "nat \<Rightarrow> rat" / partial: realrel
   morphisms rep_real Real
   by (rule part_equivp_realrel)
 
 lemma cr_real_eq: "pcr_real = (\<lambda>x y. cauchy x \<and> Real x = y)"
   unfolding real.pcr_cr_eq cr_real_def realrel_def by auto
 
 lemma Real_induct [induct type: real]: (* TODO: generate automatically *)
   assumes "\<And>X. cauchy X \<Longrightarrow> P (Real X)"
   shows "P x"
 proof (induct x)
   case (1 X)
   then have "cauchy X" by (simp add: realrel_def)
   then show "P (Real X)" by (rule assms)
 qed
 
 lemma eq_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X = Real Y \<longleftrightarrow> vanishes (\<lambda>n. X n - Y n)"
   using real.rel_eq_transfer
   unfolding real.pcr_cr_eq cr_real_def rel_fun_def realrel_def by simp
 
 lemma Domainp_pcr_real [transfer_domain_rule]: "Domainp pcr_real = cauchy"
   by (simp add: real.domain_eq realrel_def)
 
 instantiation real :: field
 begin
 
 lift_definition zero_real :: "real" is "\<lambda>n. 0"
   by (simp add: realrel_refl)
 
 lift_definition one_real :: "real" is "\<lambda>n. 1"
   by (simp add: realrel_refl)
 
 lift_definition plus_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n + Y n"
   unfolding realrel_def add_diff_add
   by (simp only: cauchy_add vanishes_add simp_thms)
 
 lift_definition uminus_real :: "real \<Rightarrow> real" is "\<lambda>X n. - X n"
   unfolding realrel_def minus_diff_minus
   by (simp only: cauchy_minus vanishes_minus simp_thms)
 
 lift_definition times_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n * Y n"
 proof -
   fix f1 f2 f3 f4
   have "\<lbrakk>cauchy f1; cauchy f4; vanishes (\<lambda>n. f1 n - f2 n); vanishes (\<lambda>n. f3 n - f4 n)\<rbrakk>
        \<Longrightarrow> vanishes (\<lambda>n. f1 n * (f3 n - f4 n) + f4 n * (f1 n - f2 n))"
     by (simp add: vanishes_add vanishes_mult_bounded cauchy_imp_bounded)
   then show "\<lbrakk>realrel f1 f2; realrel f3 f4\<rbrakk> \<Longrightarrow> realrel (\<lambda>n. f1 n * f3 n) (\<lambda>n. f2 n * f4 n)"
     by (simp add: mult.commute realrel_def mult_diff_mult)
 qed
 
 lift_definition inverse_real :: "real \<Rightarrow> real"
   is "\<lambda>X. if vanishes X then (\<lambda>n. 0) else (\<lambda>n. inverse (X n))"
 proof -
   fix X Y
   assume "realrel X Y"
   then have X: "cauchy X" and Y: "cauchy Y" and XY: "vanishes (\<lambda>n. X n - Y n)"
     by (simp_all add: realrel_def)
   have "vanishes X \<longleftrightarrow> vanishes Y"
   proof
     assume "vanishes X"
     from vanishes_diff [OF this XY] show "vanishes Y"
       by simp
   next
     assume "vanishes Y"
     from vanishes_add [OF this XY] show "vanishes X"
       by simp
   qed
   then show "?thesis X Y"
     by (simp add: vanishes_diff_inverse X Y XY realrel_def)
 qed
 
 definition "x - y = x + - y" for x y :: real
 
 definition "x div y = x * inverse y" for x y :: real
 
 lemma add_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X + Real Y = Real (\<lambda>n. X n + Y n)"
   using plus_real.transfer by (simp add: cr_real_eq rel_fun_def)
 
 lemma minus_Real: "cauchy X \<Longrightarrow> - Real X = Real (\<lambda>n. - X n)"
   using uminus_real.transfer by (simp add: cr_real_eq rel_fun_def)
 
 lemma diff_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X - Real Y = Real (\<lambda>n. X n - Y n)"
   by (simp add: minus_Real add_Real minus_real_def)
 
 lemma mult_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X * Real Y = Real (\<lambda>n. X n * Y n)"
   using times_real.transfer by (simp add: cr_real_eq rel_fun_def)
 
 lemma inverse_Real:
   "cauchy X \<Longrightarrow> inverse (Real X) = (if vanishes X then 0 else Real (\<lambda>n. inverse (X n)))"
   using inverse_real.transfer zero_real.transfer
   unfolding cr_real_eq rel_fun_def by (simp split: if_split_asm, metis)
 
 instance
 proof
   fix a b c :: real
   show "a + b = b + a"
     by transfer (simp add: ac_simps realrel_def)
   show "(a + b) + c = a + (b + c)"
     by transfer (simp add: ac_simps realrel_def)
   show "0 + a = a"
     by transfer (simp add: realrel_def)
   show "- a + a = 0"
     by transfer (simp add: realrel_def)
   show "a - b = a + - b"
     by (rule minus_real_def)
   show "(a * b) * c = a * (b * c)"
     by transfer (simp add: ac_simps realrel_def)
   show "a * b = b * a"
     by transfer (simp add: ac_simps realrel_def)
   show "1 * a = a"
     by transfer (simp add: ac_simps realrel_def)
   show "(a + b) * c = a * c + b * c"
     by transfer (simp add: distrib_right realrel_def)
   show "(0::real) \<noteq> (1::real)"
     by transfer (simp add: realrel_def)
   have "vanishes (\<lambda>n. inverse (X n) * X n - 1)" if X: "cauchy X" "\<not> vanishes X" for X
   proof (rule vanishesI)
     fix r::rat
     assume "0 < r"
     obtain b k where "b>0" "\<forall>n\<ge>k. b < \<bar>X n\<bar>"
       using X cauchy_not_vanishes by blast
     then show "\<exists>k. \<forall>n\<ge>k. \<bar>inverse (X n) * X n - 1\<bar> < r" 
       using \<open>0 < r\<close> by force
   qed
   then show "a \<noteq> 0 \<Longrightarrow> inverse a * a = 1"
     by transfer (simp add: realrel_def)
   show "a div b = a * inverse b"
     by (rule divide_real_def)
   show "inverse (0::real) = 0"
     by transfer (simp add: realrel_def)
 qed
 
 end
 
 
 subsection \<open>Positive reals\<close>
 
 lift_definition positive :: "real \<Rightarrow> bool"
   is "\<lambda>X. \<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n"
 proof -
   have 1: "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < Y n"
     if *: "realrel X Y" and **: "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n" for X Y
   proof -
     from * have XY: "vanishes (\<lambda>n. X n - Y n)"
       by (simp_all add: realrel_def)
     from ** obtain r i where "0 < r" and i: "\<forall>n\<ge>i. r < X n"
       by blast
     obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
       using \<open>0 < r\<close> by (rule obtain_pos_sum)
     obtain j where j: "\<forall>n\<ge>j. \<bar>X n - Y n\<bar> < s"
       using vanishesD [OF XY s] ..
     have "\<forall>n\<ge>max i j. t < Y n"
     proof clarsimp
       fix n
       assume n: "i \<le> n" "j \<le> n"
       have "\<bar>X n - Y n\<bar> < s" and "r < X n"
         using i j n by simp_all
       then show "t < Y n" by (simp add: r)
     qed
     then show ?thesis using t by blast
   qed
   fix X Y assume "realrel X Y"
   then have "realrel X Y" and "realrel Y X"
     using symp_realrel by (auto simp: symp_def)
   then show "?thesis X Y"
     by (safe elim!: 1)
 qed
 
 lemma positive_Real: "cauchy X \<Longrightarrow> positive (Real X) \<longleftrightarrow> (\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n)"
   using positive.transfer by (simp add: cr_real_eq rel_fun_def)
 
 lemma positive_zero: "\<not> positive 0"
   by transfer auto
 
 lemma positive_add: 
   assumes "positive x" "positive y" shows "positive (x + y)"
 proof -
   have *: "\<lbrakk>\<forall>n\<ge>i. a < x n; \<forall>n\<ge>j. b < y n; 0 < a; 0 < b; n \<ge> max i j\<rbrakk>
        \<Longrightarrow> a+b < x n + y n" for x y and a b::rat and i j n::nat
     by (simp add: add_strict_mono)
   show ?thesis
     using assms
     by transfer (blast intro: * pos_add_strict)
 qed
 
 lemma positive_mult: 
   assumes "positive x" "positive y" shows "positive (x * y)"
 proof -
   have *: "\<lbrakk>\<forall>n\<ge>i. a < x n; \<forall>n\<ge>j. b < y n; 0 < a; 0 < b; n \<ge> max i j\<rbrakk>
        \<Longrightarrow> a*b < x n * y n" for x y and a b::rat and i j n::nat
     by (simp add: mult_strict_mono')
   show ?thesis
     using assms
     by transfer (blast intro: *  mult_pos_pos)
 qed
 
 lemma positive_minus: "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   apply transfer
   apply (simp add: realrel_def)
   apply (blast dest: cauchy_not_vanishes_cases)
   done
 
 instantiation real :: linordered_field
 begin
 
 definition "x < y \<longleftrightarrow> positive (y - x)"
 
 definition "x \<le> y \<longleftrightarrow> x < y \<or> x = y" for x y :: real
 
 definition "\<bar>a\<bar> = (if a < 0 then - a else a)" for a :: real
 
 definition "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)" for a :: real
 
 instance
 proof
   fix a b c :: real
   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
     by (rule abs_real_def)
   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
        "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"  "a \<le> a" 
        "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
        "a \<le> b \<Longrightarrow> c + a \<le> c + b"
     unfolding less_eq_real_def less_real_def
     by (force simp add: positive_zero dest: positive_add)+
   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
     by (rule sgn_real_def)
   show "a \<le> b \<or> b \<le> a"
     by (auto dest!: positive_minus simp: less_eq_real_def less_real_def)
   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
     unfolding less_real_def
     by (force simp add: algebra_simps dest: positive_mult)
 qed
 
 end
 
 instantiation real :: distrib_lattice
 begin
 
 definition "(inf :: real \<Rightarrow> real \<Rightarrow> real) = min"
 
 definition "(sup :: real \<Rightarrow> real \<Rightarrow> real) = max"
 
 instance
   by standard (auto simp add: inf_real_def sup_real_def max_min_distrib2)
 
 end
 
 lemma of_nat_Real: "of_nat x = Real (\<lambda>n. of_nat x)"
   by (induct x) (simp_all add: zero_real_def one_real_def add_Real)
 
 lemma of_int_Real: "of_int x = Real (\<lambda>n. of_int x)"
   by (cases x rule: int_diff_cases) (simp add: of_nat_Real diff_Real)
 
 lemma of_rat_Real: "of_rat x = Real (\<lambda>n. x)"
 proof (induct x)
   case (Fract a b)
   then show ?case 
   apply (simp add: Fract_of_int_quotient of_rat_divide)
   apply (simp add: of_int_Real divide_inverse inverse_Real mult_Real)
   done
 qed
 
 instance real :: archimedean_field
 proof
   show "\<exists>z. x \<le> of_int z" for x :: real
   proof (induct x)
     case (1 X)
     then obtain b where "0 < b" and b: "\<And>n. \<bar>X n\<bar> < b"
       by (blast dest: cauchy_imp_bounded)
     then have "Real X < of_int (\<lceil>b\<rceil> + 1)"
       using 1
       apply (simp add: of_int_Real less_real_def diff_Real positive_Real)
       apply (rule_tac x=1 in exI)
       apply (simp add: algebra_simps)
       by (metis abs_ge_self le_less_trans le_of_int_ceiling less_le)
     then show ?case
       using less_eq_real_def by blast 
   qed
 qed
 
 instantiation real :: floor_ceiling
 begin
 
 definition [code del]: "\<lfloor>x::real\<rfloor> = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
 
 instance
 proof
   show "of_int \<lfloor>x\<rfloor> \<le> x \<and> x < of_int (\<lfloor>x\<rfloor> + 1)" for x :: real
     unfolding floor_real_def using floor_exists1 by (rule theI')
 qed
 
 end
 
 
 subsection \<open>Completeness\<close>
 
 lemma not_positive_Real: 
   assumes "cauchy X" shows "\<not> positive (Real X) \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> r)" (is "?lhs = ?rhs")
   unfolding positive_Real [OF assms]
 proof (intro iffI allI notI impI)
   show "\<exists>k. \<forall>n\<ge>k. X n \<le> r" if r: "\<not> (\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n)" and "0 < r" for r
   proof -
     obtain s t where "s > 0" "t > 0" "r = s+t"
       using \<open>r > 0\<close> obtain_pos_sum by blast
     obtain k where k: "\<And>m n. \<lbrakk>m\<ge>k; n\<ge>k\<rbrakk> \<Longrightarrow> \<bar>X m - X n\<bar> < t"
       using cauchyD [OF assms \<open>t > 0\<close>] by blast
     obtain n where "n \<ge> k" "X n \<le> s"
       by (meson r \<open>0 < s\<close> not_less)
     then have "X l \<le> r" if "l \<ge> n" for l
       using k [OF \<open>n \<ge> k\<close>, of l] that \<open>r = s+t\<close> by linarith
     then show ?thesis
       by blast
     qed
 qed (meson le_cases not_le)
 
 lemma le_Real:
   assumes "cauchy X" "cauchy Y"
   shows "Real X \<le> Real Y = (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r)"
   unfolding not_less [symmetric, where 'a=real] less_real_def
   apply (simp add: diff_Real not_positive_Real assms)
   apply (simp add: diff_le_eq ac_simps)
   done
 
 lemma le_RealI:
   assumes Y: "cauchy Y"
   shows "\<forall>n. x \<le> of_rat (Y n) \<Longrightarrow> x \<le> Real Y"
 proof (induct x)
   fix X
   assume X: "cauchy X" and "\<forall>n. Real X \<le> of_rat (Y n)"
   then have le: "\<And>m r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. X n \<le> Y m + r"
     by (simp add: of_rat_Real le_Real)
   then have "\<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r" if "0 < r" for r :: rat
   proof -
     from that obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
       by (rule obtain_pos_sum)
     obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>Y m - Y n\<bar> < s"
       using cauchyD [OF Y s] ..
     obtain j where j: "\<forall>n\<ge>j. X n \<le> Y i + t"
       using le [OF t] ..
     have "\<forall>n\<ge>max i j. X n \<le> Y n + r"
     proof clarsimp
       fix n
       assume n: "i \<le> n" "j \<le> n"
       have "X n \<le> Y i + t"
         using n j by simp
       moreover have "\<bar>Y i - Y n\<bar> < s"
         using n i by simp
       ultimately show "X n \<le> Y n + r"
         unfolding r by simp
     qed
     then show ?thesis ..
   qed
   then show "Real X \<le> Real Y"
     by (simp add: of_rat_Real le_Real X Y)
 qed
 
 lemma Real_leI:
   assumes X: "cauchy X"
   assumes le: "\<forall>n. of_rat (X n) \<le> y"
   shows "Real X \<le> y"
 proof -
   have "- y \<le> - Real X"
     by (simp add: minus_Real X le_RealI of_rat_minus le)
   then show ?thesis by simp
 qed
 
 lemma less_RealD:
   assumes "cauchy Y"
   shows "x < Real Y \<Longrightarrow> \<exists>n. x < of_rat (Y n)"
   apply (erule contrapos_pp)
   apply (simp add: not_less)
   apply (erule Real_leI [OF assms])
   done
 
 lemma of_nat_less_two_power [simp]: "of_nat n < (2::'a::linordered_idom) ^ n"
   apply (induct n)
    apply simp
   apply (metis add_le_less_mono mult_2 of_nat_Suc one_le_numeral one_le_power power_Suc)
   done
 
 lemma complete_real:
   fixes S :: "real set"
   assumes "\<exists>x. x \<in> S" and "\<exists>z. \<forall>x\<in>S. x \<le> z"
   shows "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
 proof -
   obtain x where x: "x \<in> S" using assms(1) ..
   obtain z where z: "\<forall>x\<in>S. x \<le> z" using assms(2) ..
 
   define P where "P x \<longleftrightarrow> (\<forall>y\<in>S. y \<le> of_rat x)" for x
   obtain a where a: "\<not> P a"
   proof
     have "of_int \<lfloor>x - 1\<rfloor> \<le> x - 1" by (rule of_int_floor_le)
     also have "x - 1 < x" by simp
     finally have "of_int \<lfloor>x - 1\<rfloor> < x" .
     then have "\<not> x \<le> of_int \<lfloor>x - 1\<rfloor>" by (simp only: not_le)
     then show "\<not> P (of_int \<lfloor>x - 1\<rfloor>)"
       unfolding P_def of_rat_of_int_eq using x by blast
   qed
   obtain b where b: "P b"
   proof
     show "P (of_int \<lceil>z\<rceil>)"
     unfolding P_def of_rat_of_int_eq
     proof
       fix y assume "y \<in> S"
       then have "y \<le> z" using z by simp
       also have "z \<le> of_int \<lceil>z\<rceil>" by (rule le_of_int_ceiling)
       finally show "y \<le> of_int \<lceil>z\<rceil>" .
     qed
   qed
 
   define avg where "avg x y = x/2 + y/2" for x y :: rat
   define bisect where "bisect = (\<lambda>(x, y). if P (avg x y) then (x, avg x y) else (avg x y, y))"
   define A where "A n = fst ((bisect ^^ n) (a, b))" for n
   define B where "B n = snd ((bisect ^^ n) (a, b))" for n
   define C where "C n = avg (A n) (B n)" for n
   have A_0 [simp]: "A 0 = a" unfolding A_def by simp
   have B_0 [simp]: "B 0 = b" unfolding B_def by simp
   have A_Suc [simp]: "\<And>n. A (Suc n) = (if P (C n) then A n else C n)"
     unfolding A_def B_def C_def bisect_def split_def by simp
   have B_Suc [simp]: "\<And>n. B (Suc n) = (if P (C n) then C n else B n)"
     unfolding A_def B_def C_def bisect_def split_def by simp
 
   have width: "B n - A n = (b - a) / 2^n" for n
   proof (induct n)
     case (Suc n)
     then show ?case
       by (simp add: C_def eq_divide_eq avg_def algebra_simps)
   qed simp
   have twos: "\<exists>n. y / 2 ^ n < r" if "0 < r" for y r :: rat
   proof -
     obtain n where "y / r < rat_of_nat n"
       using \<open>0 < r\<close> reals_Archimedean2 by blast
     then have "\<exists>n. y < r * 2 ^ n"
       by (metis divide_less_eq less_trans mult.commute of_nat_less_two_power that)
     then show ?thesis
       by (simp add: field_split_simps)
   qed
   have PA: "\<not> P (A n)" for n
     by (induct n) (simp_all add: a)
   have PB: "P (B n)" for n
     by (induct n) (simp_all add: b)
   have ab: "a < b"
     using a b unfolding P_def
     by (meson leI less_le_trans of_rat_less)
   have AB: "A n < B n" for n
     by (induct n) (simp_all add: ab C_def avg_def)
   have  "A i \<le> A j \<and>  B j \<le> B i" if "i < j" for i j
     using that
   proof (induction rule: less_Suc_induct)
     case (1 i)
     then show ?case
       apply (clarsimp simp add: C_def avg_def add_divide_distrib [symmetric])
       apply (rule AB [THEN less_imp_le])
       done  
   qed simp
   then have A_mono: "A i \<le> A j" and B_mono: "B j \<le> B i" if "i \<le> j" for i j
     by (metis eq_refl le_neq_implies_less that)+
   have cauchy_lemma: "cauchy X" if *: "\<And>n i. i\<ge>n \<Longrightarrow> A n \<le> X i \<and> X i \<le> B n" for X
   proof (rule cauchyI)
     fix r::rat
     assume "0 < r"
     then obtain k where k: "(b - a) / 2 ^ k < r"
       using twos by blast
     have "\<bar>X m - X n\<bar> < r" if "m\<ge>k" "n\<ge>k" for m n
     proof -
       have "\<bar>X m - X n\<bar> \<le> B k - A k"
         by (simp add: * abs_rat_def diff_mono that)
       also have "... < r"
         by (simp add: k width)
       finally show ?thesis .
     qed
     then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r"
       by blast 
   qed
   have "cauchy A"
     by (rule cauchy_lemma) (meson AB A_mono B_mono dual_order.strict_implies_order less_le_trans)
   have "cauchy B"
     by (rule cauchy_lemma) (meson AB A_mono B_mono dual_order.strict_implies_order le_less_trans)
   have "\<forall>x\<in>S. x \<le> Real B"
   proof
     fix x
     assume "x \<in> S"
     then show "x \<le> Real B"
       using PB [unfolded P_def] \<open>cauchy B\<close>
       by (simp add: le_RealI)
   qed
   moreover have "\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> Real A \<le> z"
     by (meson PA Real_leI P_def \<open>cauchy A\<close> le_cases order.trans)
   moreover have "vanishes (\<lambda>n. (b - a) / 2 ^ n)"
   proof (rule vanishesI)
     fix r :: rat
     assume "0 < r"
     then obtain k where k: "\<bar>b - a\<bar> / 2 ^ k < r"
       using twos by blast
     have "\<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r"
     proof clarify
       fix n
       assume n: "k \<le> n"
       have "\<bar>(b - a) / 2 ^ n\<bar> = \<bar>b - a\<bar> / 2 ^ n"
         by simp
       also have "\<dots> \<le> \<bar>b - a\<bar> / 2 ^ k"
         using n by (simp add: divide_left_mono)
       also note k
       finally show "\<bar>(b - a) / 2 ^ n\<bar> < r" .
     qed
     then show "\<exists>k. \<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r" ..
   qed
   then have "Real B = Real A"
     by (simp add: eq_Real \<open>cauchy A\<close> \<open>cauchy B\<close> width)
   ultimately show "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
     by force
 qed
 
 instantiation real :: linear_continuum
 begin
 
 subsection \<open>Supremum of a set of reals\<close>
 
 definition "Sup X = (LEAST z::real. \<forall>x\<in>X. x \<le> z)"
 definition "Inf X = - Sup (uminus ` X)" for X :: "real set"
 
 instance
 proof
   show Sup_upper: "x \<le> Sup X"
     if "x \<in> X" "bdd_above X"
     for x :: real and X :: "real set"
   proof -
     from that obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
       using complete_real[of X] unfolding bdd_above_def by blast
     then show ?thesis
       unfolding Sup_real_def by (rule LeastI2_order) (auto simp: that)
   qed
   show Sup_least: "Sup X \<le> z"
     if "X \<noteq> {}" and z: "\<And>x. x \<in> X \<Longrightarrow> x \<le> z"
     for z :: real and X :: "real set"
   proof -
     from that obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
       using complete_real [of X] by blast
     then have "Sup X = s"
       unfolding Sup_real_def by (best intro: Least_equality)
     also from s z have "\<dots> \<le> z"
       by blast
     finally show ?thesis .
   qed
   show "Inf X \<le> x" if "x \<in> X" "bdd_below X"
     for x :: real and X :: "real set"
     using Sup_upper [of "-x" "uminus ` X"] by (auto simp: Inf_real_def that)
   show "z \<le> Inf X" if "X \<noteq> {}" "\<And>x. x \<in> X \<Longrightarrow> z \<le> x"
     for z :: real and X :: "real set"
     using Sup_least [of "uminus ` X" "- z"] by (force simp: Inf_real_def that)
   show "\<exists>a b::real. a \<noteq> b"
     using zero_neq_one by blast
 qed
 
 end
 
 
 subsection \<open>Hiding implementation details\<close>
 
 hide_const (open) vanishes cauchy positive Real
 
 declare Real_induct [induct del]
 declare Abs_real_induct [induct del]
 declare Abs_real_cases [cases del]
 
 lifting_update real.lifting
 lifting_forget real.lifting
 
 
 subsection \<open>Embedding numbers into the Reals\<close>
 
 abbreviation real_of_nat :: "nat \<Rightarrow> real"
   where "real_of_nat \<equiv> of_nat"
 
 abbreviation real :: "nat \<Rightarrow> real"
   where "real \<equiv> of_nat"
 
 abbreviation real_of_int :: "int \<Rightarrow> real"
   where "real_of_int \<equiv> of_int"
 
 abbreviation real_of_rat :: "rat \<Rightarrow> real"
   where "real_of_rat \<equiv> of_rat"
 
 declare [[coercion_enabled]]
 
 declare [[coercion "of_nat :: nat \<Rightarrow> int"]]
 declare [[coercion "of_nat :: nat \<Rightarrow> real"]]
 declare [[coercion "of_int :: int \<Rightarrow> real"]]
 
 (* We do not add rat to the coerced types, this has often unpleasant side effects when writing
 inverse (Suc n) which sometimes gets two coercions: of_rat (inverse (of_nat (Suc n))) *)
 
 declare [[coercion_map map]]
 declare [[coercion_map "\<lambda>f g h x. g (h (f x))"]]
 declare [[coercion_map "\<lambda>f g (x,y). (f x, g y)"]]
 
 declare of_int_eq_0_iff [algebra, presburger]
 declare of_int_eq_1_iff [algebra, presburger]
 declare of_int_eq_iff [algebra, presburger]
 declare of_int_less_0_iff [algebra, presburger]
 declare of_int_less_1_iff [algebra, presburger]
 declare of_int_less_iff [algebra, presburger]
 declare of_int_le_0_iff [algebra, presburger]
 declare of_int_le_1_iff [algebra, presburger]
 declare of_int_le_iff [algebra, presburger]
 declare of_int_0_less_iff [algebra, presburger]
 declare of_int_0_le_iff [algebra, presburger]
 declare of_int_1_less_iff [algebra, presburger]
 declare of_int_1_le_iff [algebra, presburger]
 
 lemma int_less_real_le: "n < m \<longleftrightarrow> real_of_int n + 1 \<le> real_of_int m"
 proof -
   have "(0::real) \<le> 1"
     by (metis less_eq_real_def zero_less_one)
   then show ?thesis
     by (metis floor_of_int less_floor_iff)
 qed
 
 lemma int_le_real_less: "n \<le> m \<longleftrightarrow> real_of_int n < real_of_int m + 1"
   by (meson int_less_real_le not_le)
 
 lemma real_of_int_div_aux:
   "(real_of_int x) / (real_of_int d) =
     real_of_int (x div d) + (real_of_int (x mod d)) / (real_of_int d)"
 proof -
   have "x = (x div d) * d + x mod d"
     by auto
   then have "real_of_int x = real_of_int (x div d) * real_of_int d + real_of_int(x mod d)"
     by (metis of_int_add of_int_mult)
   then have "real_of_int x / real_of_int d = \<dots> / real_of_int d"
     by simp
   then show ?thesis
     by (auto simp add: add_divide_distrib algebra_simps)
 qed
 
 lemma real_of_int_div:
   "d dvd n \<Longrightarrow> real_of_int (n div d) = real_of_int n / real_of_int d" for d n :: int
   by (simp add: real_of_int_div_aux)
 
 lemma real_of_int_div2: "0 \<le> real_of_int n / real_of_int x - real_of_int (n div x)"
 proof (cases "x = 0")
   case False
   then show ?thesis
     by (metis diff_ge_0_iff_ge floor_divide_of_int_eq of_int_floor_le)
 qed simp
 
 lemma real_of_int_div3: "real_of_int n / real_of_int x - real_of_int (n div x) \<le> 1"
   apply (simp add: algebra_simps)
   by (metis add.commute floor_correct floor_divide_of_int_eq less_eq_real_def of_int_1 of_int_add)
 
 lemma real_of_int_div4: "real_of_int (n div x) \<le> real_of_int n / real_of_int x"
   using real_of_int_div2 [of n x] by simp
 
 
 subsection \<open>Embedding the Naturals into the Reals\<close>
 
 lemma real_of_card: "real (card A) = sum (\<lambda>x. 1) A"
   by simp
 
 lemma nat_less_real_le: "n < m \<longleftrightarrow> real n + 1 \<le> real m"
   by (metis discrete of_nat_1 of_nat_add of_nat_le_iff)
 
 lemma nat_le_real_less: "n \<le> m \<longleftrightarrow> real n < real m + 1"
   for m n :: nat
   by (meson nat_less_real_le not_le)
 
 lemma real_of_nat_div_aux: "real x / real d = real (x div d) + real (x mod d) / real d"
 proof -
   have "x = (x div d) * d + x mod d"
     by auto
   then have "real x = real (x div d) * real d + real(x mod d)"
     by (metis of_nat_add of_nat_mult)
   then have "real x / real d = \<dots> / real d"
     by simp
   then show ?thesis
     by (auto simp add: add_divide_distrib algebra_simps)
 qed
 
 lemma real_of_nat_div: "d dvd n \<Longrightarrow> real(n div d) = real n / real d"
   by (subst real_of_nat_div_aux) (auto simp add: dvd_eq_mod_eq_0 [symmetric])
 
 lemma real_of_nat_div2: "0 \<le> real n / real x - real (n div x)" for n x :: nat
   apply (simp add: algebra_simps)
   by (metis floor_divide_of_nat_eq of_int_floor_le of_int_of_nat_eq)
 
 lemma real_of_nat_div3: "real n / real x - real (n div x) \<le> 1" for n x :: nat
 proof (cases "x = 0")
   case False
   then show ?thesis
     by (metis of_int_of_nat_eq real_of_int_div3 zdiv_int)
 qed auto
 
 lemma real_of_nat_div4: "real (n div x) \<le> real n / real x" for n x :: nat
   using real_of_nat_div2 [of n x] by simp
 
 
 subsection \<open>The Archimedean Property of the Reals\<close>
 
 lemma real_arch_inverse: "0 < e \<longleftrightarrow> (\<exists>n::nat. n \<noteq> 0 \<and> 0 < inverse (real n) \<and> inverse (real n) < e)"
   using reals_Archimedean[of e] less_trans[of 0 "1 / real n" e for n::nat]
   by (auto simp add: field_simps cong: conj_cong simp del: of_nat_Suc)
 
 lemma reals_Archimedean3: "0 < x \<Longrightarrow> \<forall>y. \<exists>n. y < real n * x"
   by (auto intro: ex_less_of_nat_mult)
 
 lemma real_archimedian_rdiv_eq_0:
   assumes x0: "x \<ge> 0"
     and c: "c \<ge> 0"
     and xc: "\<And>m::nat. m > 0 \<Longrightarrow> real m * x \<le> c"
   shows "x = 0"
   by (metis reals_Archimedean3 dual_order.order_iff_strict le0 le_less_trans not_le x0 xc)
 
 
 subsection \<open>Rationals\<close>
 
 lemma Rats_abs_iff[simp]:
   "\<bar>(x::real)\<bar> \<in> \<rat> \<longleftrightarrow> x \<in> \<rat>"
 by(simp add: abs_real_def split: if_splits)
 
 lemma Rats_eq_int_div_int: "\<rat> = {real_of_int i / real_of_int j | i j. j \<noteq> 0}"  (is "_ = ?S")
 proof
   show "\<rat> \<subseteq> ?S"
   proof
     fix x :: real
     assume "x \<in> \<rat>"
     then obtain r where "x = of_rat r"
       unfolding Rats_def ..
     have "of_rat r \<in> ?S"
       by (cases r) (auto simp add: of_rat_rat)
     then show "x \<in> ?S"
       using \<open>x = of_rat r\<close> by simp
   qed
 next
   show "?S \<subseteq> \<rat>"
   proof (auto simp: Rats_def)
     fix i j :: int
     assume "j \<noteq> 0"
     then have "real_of_int i / real_of_int j = of_rat (Fract i j)"
       by (simp add: of_rat_rat)
     then show "real_of_int i / real_of_int j \<in> range of_rat"
       by blast
   qed
 qed
 
 lemma Rats_eq_int_div_nat: "\<rat> = { real_of_int i / real n | i n. n \<noteq> 0}"
 proof (auto simp: Rats_eq_int_div_int)
   fix i j :: int
   assume "j \<noteq> 0"
   show "\<exists>(i'::int) (n::nat). real_of_int i / real_of_int j = real_of_int i' / real n \<and> 0 < n"
   proof (cases "j > 0")
     case True
     then have "real_of_int i / real_of_int j = real_of_int i / real (nat j) \<and> 0 < nat j"
       by simp
     then show ?thesis by blast
   next
     case False
     with \<open>j \<noteq> 0\<close>
     have "real_of_int i / real_of_int j = real_of_int (- i) / real (nat (- j)) \<and> 0 < nat (- j)"
       by simp
     then show ?thesis by blast
   qed
 next
   fix i :: int and n :: nat
   assume "0 < n"
   then have "real_of_int i / real n = real_of_int i / real_of_int(int n) \<and> int n \<noteq> 0"
     by simp
   then show "\<exists>i' j. real_of_int i / real n = real_of_int i' / real_of_int j \<and> j \<noteq> 0"
     by blast
 qed
 
 lemma Rats_abs_nat_div_natE:
   assumes "x \<in> \<rat>"
   obtains m n :: nat where "n \<noteq> 0" and "\<bar>x\<bar> = real m / real n" and "coprime m n"
 proof -
   from \<open>x \<in> \<rat>\<close> obtain i :: int and n :: nat where "n \<noteq> 0" and "x = real_of_int i / real n"
     by (auto simp add: Rats_eq_int_div_nat)
   then have "\<bar>x\<bar> = real (nat \<bar>i\<bar>) / real n" by simp
   then obtain m :: nat where x_rat: "\<bar>x\<bar> = real m / real n" by blast
   let ?gcd = "gcd m n"
   from \<open>n \<noteq> 0\<close> have gcd: "?gcd \<noteq> 0" by simp
   let ?k = "m div ?gcd"
   let ?l = "n div ?gcd"
   let ?gcd' = "gcd ?k ?l"
   have "?gcd dvd m" ..
   then have gcd_k: "?gcd * ?k = m"
     by (rule dvd_mult_div_cancel)
   have "?gcd dvd n" ..
   then have gcd_l: "?gcd * ?l = n"
     by (rule dvd_mult_div_cancel)
   from \<open>n \<noteq> 0\<close> and gcd_l have "?gcd * ?l \<noteq> 0" by simp
   then have "?l \<noteq> 0" by (blast dest!: mult_not_zero)
   moreover
   have "\<bar>x\<bar> = real ?k / real ?l"
   proof -
     from gcd have "real ?k / real ?l = real (?gcd * ?k) / real (?gcd * ?l)"
       by (simp add: real_of_nat_div)
     also from gcd_k and gcd_l have "\<dots> = real m / real n" by simp
     also from x_rat have "\<dots> = \<bar>x\<bar>" ..
     finally show ?thesis ..
   qed
   moreover
   have "?gcd' = 1"
   proof -
     have "?gcd * ?gcd' = gcd (?gcd * ?k) (?gcd * ?l)"
       by (rule gcd_mult_distrib_nat)
     with gcd_k gcd_l have "?gcd * ?gcd' = ?gcd" by simp
     with gcd show ?thesis by auto
   qed
   then have "coprime ?k ?l"
     by (simp only: coprime_iff_gcd_eq_1)
   ultimately show ?thesis ..
 qed
 
 
 subsection \<open>Density of the Rational Reals in the Reals\<close>
 
 text \<open>
   This density proof is due to Stefan Richter and was ported by TN.  The
   original source is \<^emph>\<open>Real Analysis\<close> by H.L. Royden.
   It employs the Archimedean property of the reals.\<close>
 
 lemma Rats_dense_in_real:
   fixes x :: real
   assumes "x < y"
   shows "\<exists>r\<in>\<rat>. x < r \<and> r < y"
 proof -
   from \<open>x < y\<close> have "0 < y - x" by simp
   with reals_Archimedean obtain q :: nat where q: "inverse (real q) < y - x" and "0 < q"
     by blast
   define p where "p = \<lceil>y * real q\<rceil> - 1"
   define r where "r = of_int p / real q"
   from q have "x < y - inverse (real q)"
     by simp
   also from \<open>0 < q\<close> have "y - inverse (real q) \<le> r"
     by (simp add: r_def p_def le_divide_eq left_diff_distrib)
   finally have "x < r" .
   moreover from \<open>0 < q\<close> have "r < y"
     by (simp add: r_def p_def divide_less_eq diff_less_eq less_ceiling_iff [symmetric])
   moreover have "r \<in> \<rat>"
     by (simp add: r_def)
   ultimately show ?thesis by blast
 qed
 
 lemma of_rat_dense:
   fixes x y :: real
   assumes "x < y"
   shows "\<exists>q :: rat. x < of_rat q \<and> of_rat q < y"
   using Rats_dense_in_real [OF \<open>x < y\<close>]
   by (auto elim: Rats_cases)
 
 
 subsection \<open>Numerals and Arithmetic\<close>
 
 declaration \<open>
   K (Lin_Arith.add_inj_const (\<^const_name>\<open>of_nat\<close>, \<^typ>\<open>nat \<Rightarrow> real\<close>)
   #> Lin_Arith.add_inj_const (\<^const_name>\<open>of_int\<close>, \<^typ>\<open>int \<Rightarrow> real\<close>))
 \<close>
 
 
 subsection \<open>Simprules combining \<open>x + y\<close> and \<open>0\<close>\<close> (* FIXME ARE THEY NEEDED? *)
 
 lemma real_add_minus_iff [simp]: "x + - a = 0 \<longleftrightarrow> x = a"
   for x a :: real
   by arith
 
 lemma real_add_less_0_iff: "x + y < 0 \<longleftrightarrow> y < - x"
   for x y :: real
   by auto
 
 lemma real_0_less_add_iff: "0 < x + y \<longleftrightarrow> - x < y"
   for x y :: real
   by auto
 
 lemma real_add_le_0_iff: "x + y \<le> 0 \<longleftrightarrow> y \<le> - x"
   for x y :: real
   by auto
 
 lemma real_0_le_add_iff: "0 \<le> x + y \<longleftrightarrow> - x \<le> y"
   for x y :: real
   by auto
 
 
 subsection \<open>Lemmas about powers\<close>
 
 lemma two_realpow_ge_one: "(1::real) \<le> 2 ^ n"
   by simp
 
 (* FIXME: declare this [simp] for all types, or not at all *)
 declare sum_squares_eq_zero_iff [simp] sum_power2_eq_zero_iff [simp]
 
 lemma real_minus_mult_self_le [simp]: "- (u * u) \<le> x * x"
   for u x :: real
   by (rule order_trans [where y = 0]) auto
 
 lemma realpow_square_minus_le [simp]: "- u\<^sup>2 \<le> x\<^sup>2"
   for u x :: real
   by (auto simp add: power2_eq_square)
 
 
 subsection \<open>Density of the Reals\<close>
 
 lemma field_lbound_gt_zero: "0 < d1 \<Longrightarrow> 0 < d2 \<Longrightarrow> \<exists>e. 0 < e \<and> e < d1 \<and> e < d2"
   for d1 d2 :: "'a::linordered_field"
   by (rule exI [where x = "min d1 d2 / 2"]) (simp add: min_def)
 
 lemma field_less_half_sum: "x < y \<Longrightarrow> x < (x + y) / 2"
   for x y :: "'a::linordered_field"
   by auto
 
 lemma field_sum_of_halves: "x / 2 + x / 2 = x"
   for x :: "'a::linordered_field"
   by simp
 
 
 subsection \<open>Archimedean properties and useful consequences\<close>
 
 text\<open>Bernoulli's inequality\<close>
 proposition Bernoulli_inequality:
   fixes x :: real
   assumes "-1 \<le> x"
     shows "1 + n * x \<le> (1 + x) ^ n"
 proof (induct n)
   case 0
   then show ?case by simp
 next
   case (Suc n)
   have "1 + Suc n * x \<le> 1 + (Suc n)*x + n * x^2"
     by (simp add: algebra_simps)
   also have "... = (1 + x) * (1 + n*x)"
     by (auto simp: power2_eq_square algebra_simps)
   also have "... \<le> (1 + x) ^ Suc n"
     using Suc.hyps assms mult_left_mono by fastforce
   finally show ?case .
 qed
 
 corollary Bernoulli_inequality_even:
   fixes x :: real
   assumes "even n"
     shows "1 + n * x \<le> (1 + x) ^ n"
 proof (cases "-1 \<le> x \<or> n=0")
   case True
   then show ?thesis
     by (auto simp: Bernoulli_inequality)
 next
   case False
   then have "real n \<ge> 1"
     by simp
   with False have "n * x \<le> -1"
     by (metis linear minus_zero mult.commute mult.left_neutral mult_left_mono_neg neg_le_iff_le order_trans zero_le_one)
   then have "1 + n * x \<le> 0"
     by auto
   also have "... \<le> (1 + x) ^ n"
     using assms
     using zero_le_even_power by blast
   finally show ?thesis .
 qed
 
 corollary real_arch_pow:
   fixes x :: real
   assumes x: "1 < x"
   shows "\<exists>n. y < x^n"
 proof -
   from x have x0: "x - 1 > 0"
     by arith
   from reals_Archimedean3[OF x0, rule_format, of y]
   obtain n :: nat where n: "y < real n * (x - 1)" by metis
   from x0 have x00: "x- 1 \<ge> -1" by arith
   from Bernoulli_inequality[OF x00, of n] n
   have "y < x^n" by auto
   then show ?thesis by metis
 qed
 
 corollary real_arch_pow_inv:
   fixes x y :: real
   assumes y: "y > 0"
     and x1: "x < 1"
   shows "\<exists>n. x^n < y"
 proof (cases "x > 0")
   case True
   with x1 have ix: "1 < 1/x" by (simp add: field_simps)
   from real_arch_pow[OF ix, of "1/y"]
   obtain n where n: "1/y < (1/x)^n" by blast
   then show ?thesis using y \<open>x > 0\<close>
     by (auto simp add: field_simps)
 next
   case False
   with y x1 show ?thesis
     by (metis less_le_trans not_less power_one_right)
 qed
 
 lemma forall_pos_mono:
   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
     (\<And>n::nat. n \<noteq> 0 \<Longrightarrow> P (inverse (real n))) \<Longrightarrow> (\<And>e. 0 < e \<Longrightarrow> P e)"
   by (metis real_arch_inverse)
 
 lemma forall_pos_mono_1:
   "(\<And>d e::real. d < e \<Longrightarrow> P d \<Longrightarrow> P e) \<Longrightarrow>
     (\<And>n. P (inverse (real (Suc n)))) \<Longrightarrow> 0 < e \<Longrightarrow> P e"
   apply (rule forall_pos_mono)
   apply auto
   apply (metis Suc_pred of_nat_Suc)
   done
 
 
 subsection \<open>Floor and Ceiling Functions from the Reals to the Integers\<close>
 
 (* FIXME: theorems for negative numerals. Many duplicates, e.g. from Archimedean_Field.thy. *)
 
 lemma real_of_nat_less_numeral_iff [simp]: "real n < numeral w \<longleftrightarrow> n < numeral w"
   for n :: nat
   by (metis of_nat_less_iff of_nat_numeral)
 
 lemma numeral_less_real_of_nat_iff [simp]: "numeral w < real n \<longleftrightarrow> numeral w < n"
   for n :: nat
   by (metis of_nat_less_iff of_nat_numeral)
 
 lemma numeral_le_real_of_nat_iff [simp]: "numeral n \<le> real m \<longleftrightarrow> numeral n \<le> m"
   for m :: nat
   by (metis not_le real_of_nat_less_numeral_iff)
 
 lemma of_int_floor_cancel [simp]: "of_int \<lfloor>x\<rfloor> = x \<longleftrightarrow> (\<exists>n::int. x = of_int n)"
   by (metis floor_of_int)
 
 lemma floor_eq: "real_of_int n < x \<Longrightarrow> x < real_of_int n + 1 \<Longrightarrow> \<lfloor>x\<rfloor> = n"
   by linarith
 
 lemma floor_eq2: "real_of_int n \<le> x \<Longrightarrow> x < real_of_int n + 1 \<Longrightarrow> \<lfloor>x\<rfloor> = n"
   by (fact floor_unique)
 
 lemma floor_eq3: "real n < x \<Longrightarrow> x < real (Suc n) \<Longrightarrow> nat \<lfloor>x\<rfloor> = n"
   by linarith
 
 lemma floor_eq4: "real n \<le> x \<Longrightarrow> x < real (Suc n) \<Longrightarrow> nat \<lfloor>x\<rfloor> = n"
   by linarith
 
 lemma real_of_int_floor_ge_diff_one [simp]: "r - 1 \<le> real_of_int \<lfloor>r\<rfloor>"
   by linarith
 
 lemma real_of_int_floor_gt_diff_one [simp]: "r - 1 < real_of_int \<lfloor>r\<rfloor>"
   by linarith
 
 lemma real_of_int_floor_add_one_ge [simp]: "r \<le> real_of_int \<lfloor>r\<rfloor> + 1"
   by linarith
 
 lemma real_of_int_floor_add_one_gt [simp]: "r < real_of_int \<lfloor>r\<rfloor> + 1"
   by linarith
 
 lemma floor_divide_real_eq_div:
   assumes "0 \<le> b"
   shows "\<lfloor>a / real_of_int b\<rfloor> = \<lfloor>a\<rfloor> div b"
 proof (cases "b = 0")
   case True
   then show ?thesis by simp
 next
   case False
   with assms have b: "b > 0" by simp
   have "j = i div b"
     if "real_of_int i \<le> a" "a < 1 + real_of_int i"
       "real_of_int j * real_of_int b \<le> a" "a < real_of_int b + real_of_int j * real_of_int b"
     for i j :: int
   proof -
     from that have "i < b + j * b"
       by (metis le_less_trans of_int_add of_int_less_iff of_int_mult)
     moreover have "j * b < 1 + i"
     proof -
       have "real_of_int (j * b) < real_of_int i + 1"
         using \<open>a < 1 + real_of_int i\<close> \<open>real_of_int j * real_of_int b \<le> a\<close> by force
       then show "j * b < 1 + i" by linarith
     qed
     ultimately have "(j - i div b) * b \<le> i mod b" "i mod b < ((j - i div b) + 1) * b"
       by (auto simp: field_simps)
     then have "(j - i div b) * b < 1 * b" "0 * b < ((j - i div b) + 1) * b"
       using pos_mod_bound [OF b, of i] pos_mod_sign [OF b, of i]
       by linarith+
     then show ?thesis using b unfolding mult_less_cancel_right by auto
   qed
   with b show ?thesis by (auto split: floor_split simp: field_simps)
 qed
 
 lemma floor_one_divide_eq_div_numeral [simp]:
   "\<lfloor>1 / numeral b::real\<rfloor> = 1 div numeral b"
 by (metis floor_divide_of_int_eq of_int_1 of_int_numeral)
 
 lemma floor_minus_one_divide_eq_div_numeral [simp]:
   "\<lfloor>- (1 / numeral b)::real\<rfloor> = - 1 div numeral b"
 by (metis (mono_tags, opaque_lifting) div_minus_right minus_divide_right
     floor_divide_of_int_eq of_int_neg_numeral of_int_1)
 
 lemma floor_divide_eq_div_numeral [simp]:
   "\<lfloor>numeral a / numeral b::real\<rfloor> = numeral a div numeral b"
 by (metis floor_divide_of_int_eq of_int_numeral)
 
 lemma floor_minus_divide_eq_div_numeral [simp]:
   "\<lfloor>- (numeral a / numeral b)::real\<rfloor> = - numeral a div numeral b"
 by (metis divide_minus_left floor_divide_of_int_eq of_int_neg_numeral of_int_numeral)
 
 lemma of_int_ceiling_cancel [simp]: "of_int \<lceil>x\<rceil> = x \<longleftrightarrow> (\<exists>n::int. x = of_int n)"
   using ceiling_of_int by metis
 
 lemma ceiling_eq: "of_int n < x \<Longrightarrow> x \<le> of_int n + 1 \<Longrightarrow> \<lceil>x\<rceil> = n + 1"
   by (simp add: ceiling_unique)
 
 lemma of_int_ceiling_diff_one_le [simp]: "of_int \<lceil>r\<rceil> - 1 \<le> r"
   by linarith
 
 lemma of_int_ceiling_le_add_one [simp]: "of_int \<lceil>r\<rceil> \<le> r + 1"
   by linarith
 
 lemma ceiling_le: "x \<le> of_int a \<Longrightarrow> \<lceil>x\<rceil> \<le> a"
   by (simp add: ceiling_le_iff)
 
 lemma ceiling_divide_eq_div: "\<lceil>of_int a / of_int b\<rceil> = - (- a div b)"
   by (metis ceiling_def floor_divide_of_int_eq minus_divide_left of_int_minus)
 
 lemma ceiling_divide_eq_div_numeral [simp]:
   "\<lceil>numeral a / numeral b :: real\<rceil> = - (- numeral a div numeral b)"
   using ceiling_divide_eq_div[of "numeral a" "numeral b"] by simp
 
 lemma ceiling_minus_divide_eq_div_numeral [simp]:
   "\<lceil>- (numeral a / numeral b :: real)\<rceil> = - (numeral a div numeral b)"
   using ceiling_divide_eq_div[of "- numeral a" "numeral b"] by simp
 
 text \<open>
   The following lemmas are remnants of the erstwhile functions natfloor
   and natceiling.
 \<close>
 
 lemma nat_floor_neg: "x \<le> 0 \<Longrightarrow> nat \<lfloor>x\<rfloor> = 0"
   for x :: real
   by linarith
 
 lemma le_nat_floor: "real x \<le> a \<Longrightarrow> x \<le> nat \<lfloor>a\<rfloor>"
   by linarith
 
 lemma le_mult_nat_floor: "nat \<lfloor>a\<rfloor> * nat \<lfloor>b\<rfloor> \<le> nat \<lfloor>a * b\<rfloor>"
   by (cases "0 \<le> a \<and> 0 \<le> b")
      (auto simp add: nat_mult_distrib[symmetric] nat_mono le_mult_floor)
 
 lemma nat_ceiling_le_eq [simp]: "nat \<lceil>x\<rceil> \<le> a \<longleftrightarrow> x \<le> real a"
   by linarith
 
 lemma real_nat_ceiling_ge: "x \<le> real (nat \<lceil>x\<rceil>)"
   by linarith
 
 lemma Rats_no_top_le: "\<exists>q \<in> \<rat>. x \<le> q"
   for x :: real
   by (auto intro!: bexI[of _ "of_nat (nat \<lceil>x\<rceil>)"]) linarith
 
 lemma Rats_no_bot_less: "\<exists>q \<in> \<rat>. q < x" for x :: real
   by (auto intro!: bexI[of _ "of_int (\<lfloor>x\<rfloor> - 1)"]) linarith
 
 
 subsection \<open>Exponentiation with floor\<close>
 
 lemma floor_power:
   assumes "x = of_int \<lfloor>x\<rfloor>"
   shows "\<lfloor>x ^ n\<rfloor> = \<lfloor>x\<rfloor> ^ n"
 proof -
   have "x ^ n = of_int (\<lfloor>x\<rfloor> ^ n)"
     using assms by (induct n arbitrary: x) simp_all
   then show ?thesis by (metis floor_of_int)
 qed
 
 lemma floor_numeral_power [simp]: "\<lfloor>numeral x ^ n\<rfloor> = numeral x ^ n"
   by (metis floor_of_int of_int_numeral of_int_power)
 
 lemma ceiling_numeral_power [simp]: "\<lceil>numeral x ^ n\<rceil> = numeral x ^ n"
   by (metis ceiling_of_int of_int_numeral of_int_power)
 
 
 subsection \<open>Implementation of rational real numbers\<close>
 
 text \<open>Formal constructor\<close>
 
 definition Ratreal :: "rat \<Rightarrow> real"
   where [code_abbrev, simp]: "Ratreal = real_of_rat"
 
 code_datatype Ratreal
 
 
 text \<open>Quasi-Numerals\<close>
 
 lemma [code_abbrev]:
   "real_of_rat (numeral k) = numeral k"
   "real_of_rat (- numeral k) = - numeral k"
   "real_of_rat (rat_of_int a) = real_of_int a"
   by simp_all
 
 lemma [code_post]:
   "real_of_rat 0 = 0"
   "real_of_rat 1 = 1"
   "real_of_rat (- 1) = - 1"
   "real_of_rat (1 / numeral k) = 1 / numeral k"
   "real_of_rat (numeral k / numeral l) = numeral k / numeral l"
   "real_of_rat (- (1 / numeral k)) = - (1 / numeral k)"
   "real_of_rat (- (numeral k / numeral l)) = - (numeral k / numeral l)"
   by (simp_all add: of_rat_divide of_rat_minus)
 
 text \<open>Operations\<close>
 
 lemma zero_real_code [code]: "0 = Ratreal 0"
   by simp
 
 lemma one_real_code [code]: "1 = Ratreal 1"
   by simp
 
 instantiation real :: equal
 begin
 
 definition "HOL.equal x y \<longleftrightarrow> x - y = 0" for x :: real
 
 instance by standard (simp add: equal_real_def)
 
 lemma real_equal_code [code]: "HOL.equal (Ratreal x) (Ratreal y) \<longleftrightarrow> HOL.equal x y"
   by (simp add: equal_real_def equal)
 
 lemma [code nbe]: "HOL.equal x x \<longleftrightarrow> True"
   for x :: real
   by (rule equal_refl)
 
 end
 
 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
   by (simp add: of_rat_less_eq)
 
 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
   by (simp add: of_rat_less)
 
 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
   by (simp add: of_rat_add)
 
 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
   by (simp add: of_rat_mult)
 
 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
   by (simp add: of_rat_minus)
 
 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
   by (simp add: of_rat_diff)
 
 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
   by (simp add: of_rat_inverse)
 
 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
   by (simp add: of_rat_divide)
 
 lemma real_floor_code [code]: "\<lfloor>Ratreal x\<rfloor> = \<lfloor>x\<rfloor>"
   by (metis Ratreal_def floor_le_iff floor_unique le_floor_iff
       of_int_floor_le of_rat_of_int_eq real_less_eq_code)
 
 
 text \<open>Quickcheck\<close>
 
 context
   includes term_syntax
 begin
 
 definition
   valterm_ratreal :: "rat \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> real \<times> (unit \<Rightarrow> Code_Evaluation.term)"
   where [code_unfold]: "valterm_ratreal k = Code_Evaluation.valtermify Ratreal {\<cdot>} k"
 
 end
 
 instantiation real :: random
 begin
 
 context
   includes state_combinator_syntax
 begin
 
 definition
   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>r. Pair (valterm_ratreal r))"
 
 instance ..
 
 end
 
 end
 
 instantiation real :: exhaustive
 begin
 
 definition
   "exhaustive_real f d = Quickcheck_Exhaustive.exhaustive (\<lambda>r. f (Ratreal r)) d"
 
 instance ..
 
 end
 
 instantiation real :: full_exhaustive
 begin
 
 definition
   "full_exhaustive_real f d = Quickcheck_Exhaustive.full_exhaustive (\<lambda>r. f (valterm_ratreal r)) d"
 
 instance ..
 
 end
 
 instantiation real :: narrowing
 begin
 
 definition
   "narrowing_real = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.cons Ratreal) narrowing"
 
 instance ..
 
 end
 
 
 subsection \<open>Setup for Nitpick\<close>
 
 declaration \<open>
   Nitpick_HOL.register_frac_type \<^type_name>\<open>real\<close>
     [(\<^const_name>\<open>zero_real_inst.zero_real\<close>, \<^const_name>\<open>Nitpick.zero_frac\<close>),
      (\<^const_name>\<open>one_real_inst.one_real\<close>, \<^const_name>\<open>Nitpick.one_frac\<close>),
      (\<^const_name>\<open>plus_real_inst.plus_real\<close>, \<^const_name>\<open>Nitpick.plus_frac\<close>),
      (\<^const_name>\<open>times_real_inst.times_real\<close>, \<^const_name>\<open>Nitpick.times_frac\<close>),
      (\<^const_name>\<open>uminus_real_inst.uminus_real\<close>, \<^const_name>\<open>Nitpick.uminus_frac\<close>),
      (\<^const_name>\<open>inverse_real_inst.inverse_real\<close>, \<^const_name>\<open>Nitpick.inverse_frac\<close>),
      (\<^const_name>\<open>ord_real_inst.less_real\<close>, \<^const_name>\<open>Nitpick.less_frac\<close>),
      (\<^const_name>\<open>ord_real_inst.less_eq_real\<close>, \<^const_name>\<open>Nitpick.less_eq_frac\<close>)]
 \<close>
 
 lemmas [nitpick_unfold] = inverse_real_inst.inverse_real one_real_inst.one_real
   ord_real_inst.less_real ord_real_inst.less_eq_real plus_real_inst.plus_real
   times_real_inst.times_real uminus_real_inst.uminus_real
   zero_real_inst.zero_real
 
 
 subsection \<open>Setup for SMT\<close>
 
 ML_file \<open>Tools/SMT/smt_real.ML\<close>
 ML_file \<open>Tools/SMT/z3_real.ML\<close>
 
 lemma [z3_rule]:
   "0 + x = x"
   "x + 0 = x"
   "0 * x = 0"
   "1 * x = x"
   "-x = -1 * x"
   "x + y = y + x"
   for x y :: real
   by auto
 
 lemma [smt_arith_multiplication]:
   fixes A B :: real and p n :: real
   assumes "A \<le> B" "0 < n" "p > 0"
   shows "(A / n) * p \<le> (B / n) * p"
   using assms by (auto simp: field_simps)
 
 lemma [smt_arith_multiplication]:
   fixes A B :: real and p n :: real
   assumes "A < B" "0 < n" "p > 0"
   shows "(A / n) * p < (B / n) * p"
   using assms by (auto simp: field_simps)
 
 lemma [smt_arith_multiplication]:
   fixes A B :: real and p n :: int
   assumes "A \<le> B" "0 < n" "p > 0"
   shows "(A / n) * p \<le> (B / n) * p"
   using assms by (auto simp: field_simps)
 
 lemma [smt_arith_multiplication]:
   fixes A B :: real and p n :: int
   assumes "A < B" "0 < n" "p > 0"
   shows "(A / n) * p < (B / n) * p"
   using assms by (auto simp: field_simps)
 
 lemmas [smt_arith_multiplication] =
   verit_le_mono_div[THEN mult_left_mono, unfolded int_distrib, of _ _ \<open>nat (floor (_ :: real))\<close>  \<open>nat (floor (_ :: real))\<close>]
   div_le_mono[THEN mult_left_mono, unfolded int_distrib, of _ _ \<open>nat (floor (_ :: real))\<close>  \<open>nat (floor (_ :: real))\<close>]
   verit_le_mono_div_int[THEN mult_left_mono, unfolded int_distrib, of _ _ \<open>floor (_ :: real)\<close>  \<open>floor (_ :: real)\<close>]
   zdiv_mono1[THEN mult_left_mono, unfolded int_distrib, of _ _ \<open>floor (_ :: real)\<close>  \<open>floor (_ :: real)\<close>]
   arg_cong[of _ _ \<open>\<lambda>a :: real. a / real (n::nat) * real (p::nat)\<close> for n p :: nat, THEN sym]
   arg_cong[of _ _ \<open>\<lambda>a :: real. a / real_of_int n * real_of_int p\<close> for n p :: int, THEN sym]
   arg_cong[of _ _ \<open>\<lambda>a :: real. a / n * p\<close> for n p :: real, THEN sym]
 
 lemmas [smt_arith_simplify] =
    floor_one floor_numeral div_by_1 times_divide_eq_right
    nonzero_mult_div_cancel_left division_ring_divide_zero div_0
   divide_minus_left zero_less_divide_iff
 
 
 subsection \<open>Setup for Argo\<close>
 
 ML_file \<open>Tools/Argo/argo_real.ML\<close>
 
 end
diff --git a/src/HOL/ex/Dedekind_Real.thy b/src/HOL/ex/Dedekind_Real.thy
deleted file mode 100644
--- a/src/HOL/ex/Dedekind_Real.thy
+++ /dev/null
@@ -1,1663 +0,0 @@
-section \<open>The Reals as Dedekind Sections of Positive Rationals\<close>
-
-text \<open>Fundamentals of Abstract Analysis [Gleason- p. 121] provides some of the definitions.\<close>
-
-(*  Title:      HOL/ex/Dedekind_Real.thy
-    Author:     Jacques D. Fleuriot, University of Cambridge
-    Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4; 2019
-*)
-
-theory Dedekind_Real
-imports Complex_Main 
-begin
-
-text\<open>Could be moved to \<open>Groups\<close>\<close>
-lemma add_eq_exists: "\<exists>x. a+x = (b::'a::ab_group_add)"
-  by (rule_tac x="b-a" in exI, simp)
-
-subsection \<open>Dedekind cuts or sections\<close>
-
-definition
-  cut :: "rat set \<Rightarrow> bool" where
-  "cut A \<equiv> {} \<subset> A \<and> A \<subset> {0<..} \<and>
-            (\<forall>y \<in> A. ((\<forall>z. 0<z \<and> z < y \<longrightarrow> z \<in> A) \<and> (\<exists>u \<in> A. y < u)))"
-
-lemma cut_of_rat: 
-  assumes q: "0 < q" shows "cut {r::rat. 0 < r \<and> r < q}" (is "cut ?A")
-proof -
-  from q have pos: "?A \<subset> {0<..}" by force
-  have nonempty: "{} \<subset> ?A"
-  proof
-    show "{} \<subseteq> ?A" by simp
-    show "{} \<noteq> ?A"
-      using field_lbound_gt_zero q by auto
-  qed
-  show ?thesis
-    by (simp add: cut_def pos nonempty,
-        blast dest: dense intro: order_less_trans)
-qed
-
-
-typedef preal = "Collect cut"
-  by (blast intro: cut_of_rat [OF zero_less_one])
-
-lemma Abs_preal_induct [induct type: preal]:
-  "(\<And>x. cut x \<Longrightarrow> P (Abs_preal x)) \<Longrightarrow> P x"
-  using Abs_preal_induct [of P x] by simp
-
-lemma cut_Rep_preal [simp]: "cut (Rep_preal x)"
-  using Rep_preal [of x] by simp
-
-definition
-  psup :: "preal set \<Rightarrow> preal" where
-  "psup P = Abs_preal (\<Union>X \<in> P. Rep_preal X)"
-
-definition
-  add_set :: "[rat set,rat set] \<Rightarrow> rat set" where
-  "add_set A B = {w. \<exists>x \<in> A. \<exists>y \<in> B. w = x + y}"
-
-definition
-  diff_set :: "[rat set,rat set] \<Rightarrow> rat set" where
-  "diff_set A B = {w. \<exists>x. 0 < w \<and> 0 < x \<and> x \<notin> B \<and> x + w \<in> A}"
-
-definition
-  mult_set :: "[rat set,rat set] \<Rightarrow> rat set" where
-  "mult_set A B = {w. \<exists>x \<in> A. \<exists>y \<in> B. w = x * y}"
-
-definition
-  inverse_set :: "rat set \<Rightarrow> rat set" where
-  "inverse_set A \<equiv> {x. \<exists>y. 0 < x \<and> x < y \<and> inverse y \<notin> A}"
-
-instantiation preal :: "{ord, plus, minus, times, inverse, one}"
-begin
-
-definition
-  preal_less_def:
-    "r < s \<equiv> Rep_preal r < Rep_preal s"
-
-definition
-  preal_le_def:
-    "r \<le> s \<equiv> Rep_preal r \<subseteq> Rep_preal s"
-
-definition
-  preal_add_def:
-    "r + s \<equiv> Abs_preal (add_set (Rep_preal r) (Rep_preal s))"
-
-definition
-  preal_diff_def:
-    "r - s \<equiv> Abs_preal (diff_set (Rep_preal r) (Rep_preal s))"
-
-definition
-  preal_mult_def:
-    "r * s \<equiv> Abs_preal (mult_set (Rep_preal r) (Rep_preal s))"
-
-definition
-  preal_inverse_def:
-    "inverse r \<equiv> Abs_preal (inverse_set (Rep_preal r))"
-
-definition "r div s = r * inverse (s::preal)"
-
-definition
-  preal_one_def:
-    "1 \<equiv> Abs_preal {x. 0 < x \<and> x < 1}"
-
-instance ..
-
-end
-
-
-text\<open>Reduces equality on abstractions to equality on representatives\<close>
-declare Abs_preal_inject [simp]
-declare Abs_preal_inverse [simp]
-
-lemma rat_mem_preal: "0 < q \<Longrightarrow> cut {r::rat. 0 < r \<and> r < q}"
-by (simp add: cut_of_rat)
-
-lemma preal_nonempty: "cut A \<Longrightarrow> \<exists>x\<in>A. 0 < x"
-  unfolding cut_def [abs_def] by blast
-
-lemma preal_Ex_mem: "cut A \<Longrightarrow> \<exists>x. x \<in> A"
-  using preal_nonempty by blast
-
-lemma preal_exists_bound: "cut A \<Longrightarrow> \<exists>x. 0 < x \<and> x \<notin> A"
-  using Dedekind_Real.cut_def by fastforce
-
-lemma preal_exists_greater: "\<lbrakk>cut A; y \<in> A\<rbrakk> \<Longrightarrow> \<exists>u \<in> A. y < u"
-  unfolding cut_def [abs_def] by blast
-
-lemma preal_downwards_closed: "\<lbrakk>cut A; y \<in> A; 0 < z; z < y\<rbrakk> \<Longrightarrow> z \<in> A"
-  unfolding cut_def [abs_def] by blast
-
-text\<open>Relaxing the final premise\<close>
-lemma preal_downwards_closed': "\<lbrakk>cut A; y \<in> A; 0 < z; z \<le> y\<rbrakk> \<Longrightarrow> z \<in> A"
-  using less_eq_rat_def preal_downwards_closed by blast
-
-text\<open>A positive fraction not in a positive real is an upper bound.
- Gleason p. 122 - Remark (1)\<close>
-
-lemma not_in_preal_ub:
-  assumes A: "cut A"
-    and notx: "x \<notin> A"
-    and y: "y \<in> A"
-    and pos: "0 < x"
-  shows "y < x"
-proof (cases rule: linorder_cases)
-  assume "x<y"
-  with notx show ?thesis
-    by (simp add:  preal_downwards_closed [OF A y] pos)
-next
-  assume "x=y"
-  with notx and y show ?thesis by simp
-next
-  assume "y<x"
-  thus ?thesis .
-qed
-
-text \<open>preal lemmas instantiated to \<^term>\<open>Rep_preal X\<close>\<close>
-
-lemma mem_Rep_preal_Ex: "\<exists>x. x \<in> Rep_preal X"
-thm preal_Ex_mem
-by (rule preal_Ex_mem [OF cut_Rep_preal])
-
-lemma Rep_preal_exists_bound: "\<exists>x>0. x \<notin> Rep_preal X"
-by (rule preal_exists_bound [OF cut_Rep_preal])
-
-lemmas not_in_Rep_preal_ub = not_in_preal_ub [OF cut_Rep_preal]
-
-
-subsection\<open>Properties of Ordering\<close>
-
-instance preal :: order
-proof
-  fix w :: preal
-  show "w \<le> w" by (simp add: preal_le_def)
-next
-  fix i j k :: preal
-  assume "i \<le> j" and "j \<le> k"
-  then show "i \<le> k" by (simp add: preal_le_def)
-next
-  fix z w :: preal
-  assume "z \<le> w" and "w \<le> z"
-  then show "z = w" by (simp add: preal_le_def Rep_preal_inject)
-next
-  fix z w :: preal
-  show "z < w \<longleftrightarrow> z \<le> w \<and> \<not> w \<le> z"
-  by (auto simp: preal_le_def preal_less_def Rep_preal_inject)
-qed  
-
-lemma preal_imp_pos: "\<lbrakk>cut A; r \<in> A\<rbrakk> \<Longrightarrow> 0 < r"
-  by (auto simp: cut_def)
-
-instance preal :: linorder
-proof
-  fix x y :: preal
-  show "x \<le> y \<or> y \<le> x"
-    unfolding preal_le_def
-    by (meson cut_Rep_preal not_in_preal_ub preal_downwards_closed preal_imp_pos subsetI)
-qed
-
-instantiation preal :: distrib_lattice
-begin
-
-definition
-  "(inf :: preal \<Rightarrow> preal \<Rightarrow> preal) = min"
-
-definition
-  "(sup :: preal \<Rightarrow> preal \<Rightarrow> preal) = max"
-
-instance
-  by intro_classes
-    (auto simp: inf_preal_def sup_preal_def max_min_distrib2)
-
-end
-
-subsection\<open>Properties of Addition\<close>
-
-lemma preal_add_commute: "(x::preal) + y = y + x"
-  unfolding preal_add_def add_set_def
-  by (metis (no_types, opaque_lifting) add.commute)
-
-text\<open>Lemmas for proving that addition of two positive reals gives
- a positive real\<close>
-
-lemma mem_add_set:
-  assumes "cut A" "cut B"
-  shows "cut (add_set A B)"
-proof -
-  have "{} \<subset> add_set A B"
-    using assms by (force simp: add_set_def dest: preal_nonempty)
-  moreover
-  obtain q where "q > 0" "q \<notin> add_set A B"
-  proof -
-    obtain a b where "a > 0" "a \<notin> A" "b > 0" "b \<notin> B" "\<And>x. x \<in> A \<Longrightarrow> x < a" "\<And>y. y \<in> B \<Longrightarrow> y < b"
-      by (meson assms preal_exists_bound not_in_preal_ub)
-    with assms have "a+b \<notin> add_set A B"
-      by (fastforce simp add: add_set_def)
-    then show thesis
-      using \<open>0 < a\<close> \<open>0 < b\<close> add_pos_pos that by blast
-  qed
-  then have "add_set A B \<subset> {0<..}"
-    unfolding add_set_def
-    using preal_imp_pos [OF \<open>cut A\<close>] preal_imp_pos [OF \<open>cut B\<close>]  by fastforce
-  moreover have "z \<in> add_set A B" 
-    if u: "u \<in> add_set A B" and "0 < z" "z < u" for u z
-    using u unfolding add_set_def
-  proof (clarify)
-    fix x::rat and y::rat
-    assume ueq: "u = x + y" and x: "x \<in> A" and y:"y \<in> B"
-    have xpos [simp]: "x > 0" and ypos [simp]: "y > 0"
-      using assms preal_imp_pos x y by blast+
-    have xypos [simp]: "x+y > 0" by (simp add: pos_add_strict)
-    let ?f = "z/(x+y)"
-    have fless: "?f < 1"
-      using divide_less_eq_1_pos \<open>z < u\<close> ueq xypos by blast
-    show "\<exists>x' \<in> A. \<exists>y'\<in>B. z = x' + y'"
-    proof (intro bexI)
-      show "z = x*?f + y*?f"
-        by (simp add: distrib_right [symmetric] divide_inverse ac_simps order_less_imp_not_eq2)
-    next
-      show "y * ?f \<in> B"
-      proof (rule preal_downwards_closed [OF \<open>cut B\<close> y])
-        show "0 < y * ?f"
-          by (simp add: \<open>0 < z\<close>)
-      next
-        show "y * ?f < y"
-          by (insert mult_strict_left_mono [OF fless ypos], simp)
-      qed
-    next
-      show "x * ?f \<in> A"
-      proof (rule preal_downwards_closed [OF \<open>cut A\<close> x])
-        show "0 < x * ?f"
-          by (simp add: \<open>0 < z\<close>)
-      next
-        show "x * ?f < x"
-          by (insert mult_strict_left_mono [OF fless xpos], simp)
-      qed
-    qed
-  qed
-  moreover
-  have "\<And>y. y \<in> add_set A B \<Longrightarrow> \<exists>u \<in> add_set A B. y < u"
-    unfolding add_set_def using preal_exists_greater assms by fastforce
-  ultimately show ?thesis
-    by (simp add: Dedekind_Real.cut_def)
-qed
-
-lemma preal_add_assoc: "((x::preal) + y) + z = x + (y + z)"
-  apply (simp add: preal_add_def mem_add_set)
-  apply (force simp: add_set_def ac_simps)
-  done
-
-instance preal :: ab_semigroup_add
-proof
-  fix a b c :: preal
-  show "(a + b) + c = a + (b + c)" by (rule preal_add_assoc)
-  show "a + b = b + a" by (rule preal_add_commute)
-qed
-
-
-subsection\<open>Properties of Multiplication\<close>
-
-text\<open>Proofs essentially same as for addition\<close>
-
-lemma preal_mult_commute: "(x::preal) * y = y * x"
-  unfolding preal_mult_def mult_set_def
-  by (metis (no_types, opaque_lifting) mult.commute)
-
-text\<open>Multiplication of two positive reals gives a positive real.\<close>
-
-lemma mem_mult_set:
-  assumes "cut A" "cut B"
-  shows "cut (mult_set A B)"
-proof -
-  have "{} \<subset> mult_set A B"
-    using assms
-      by (force simp: mult_set_def dest: preal_nonempty)
-    moreover
-    obtain q where "q > 0" "q \<notin> mult_set A B"
-    proof -
-      obtain x y where x [simp]: "0 < x" "x \<notin> A" and y [simp]: "0 < y" "y \<notin> B"
-        using preal_exists_bound assms by blast
-      show thesis
-      proof 
-        show "0 < x*y" by simp
-        show "x * y \<notin> mult_set A B"
-        proof -
-          {
-            fix u::rat and v::rat
-            assume u: "u \<in> A" and v: "v \<in> B" and xy: "x*y = u*v"
-            moreover have "u<x" and "v<y" using assms x y u v by (blast dest: not_in_preal_ub)+
-            moreover have "0\<le>v"
-              using less_imp_le preal_imp_pos assms x y u v by blast
-            moreover have "u*v < x*y"
-                using assms x \<open>u < x\<close> \<open>v < y\<close> \<open>0 \<le> v\<close> by (blast intro: mult_strict_mono)
-            ultimately have False by force
-          }
-          thus ?thesis by (auto simp: mult_set_def)
-        qed
-      qed
-    qed
-  then have "mult_set A B \<subset> {0<..}"
-    unfolding mult_set_def
-    using preal_imp_pos [OF \<open>cut A\<close>] preal_imp_pos [OF \<open>cut B\<close>]  by fastforce
-  moreover have "z \<in> mult_set A B"
-    if u: "u \<in> mult_set A B" and "0 < z" "z < u" for u z
-    using u unfolding mult_set_def
-  proof (clarify)
-    fix x::rat and y::rat
-    assume ueq: "u = x * y" and x: "x \<in> A" and y: "y \<in> B"  
-    have [simp]: "y > 0"
-      using \<open>cut B\<close> preal_imp_pos y by blast
-    show "\<exists>x' \<in> A. \<exists>y' \<in> B. z = x' * y'"
-    proof
-      have "z = (z/y)*y"
-          by (simp add: divide_inverse mult.commute [of y] mult.assoc order_less_imp_not_eq2)
-      then show "\<exists>y'\<in>B. z = (z/y) * y'"
-        using y by blast
-    next
-      show "z/y \<in> A"
-      proof (rule preal_downwards_closed [OF \<open>cut A\<close> x])
-        show "0 < z/y"
-          by (simp add: \<open>0 < z\<close>)
-        show "z/y < x"
-          using \<open>0 < y\<close> pos_divide_less_eq \<open>z < u\<close> ueq by blast  
-      qed
-    qed
-  qed
-  moreover have "\<And>y. y \<in> mult_set A B \<Longrightarrow> \<exists>u \<in> mult_set A B. y < u"
-    apply (simp add: mult_set_def)
-    by (metis preal_exists_greater mult_strict_right_mono preal_imp_pos assms)
-  ultimately show ?thesis
-    by (simp add: Dedekind_Real.cut_def)
-qed
-
-lemma preal_mult_assoc: "((x::preal) * y) * z = x * (y * z)"
-  apply (simp add: preal_mult_def mem_mult_set Rep_preal)
-  apply (simp add: mult_set_def)
-  apply (metis (no_types, opaque_lifting) ab_semigroup_mult_class.mult_ac(1))
-  done
-
-instance preal :: ab_semigroup_mult
-proof
-  fix a b c :: preal
-  show "(a * b) * c = a * (b * c)" by (rule preal_mult_assoc)
-  show "a * b = b * a" by (rule preal_mult_commute)
-qed
-
-
-text\<open>Positive real 1 is the multiplicative identity element\<close>
-
-lemma preal_mult_1: "(1::preal) * z = z"
-proof (induct z)
-  fix A :: "rat set"
-  assume A: "cut A"
-  have "{w. \<exists>u. 0 < u \<and> u < 1 \<and> (\<exists>v \<in> A. w = u * v)} = A" (is "?lhs = A")
-  proof
-    show "?lhs \<subseteq> A"
-    proof clarify
-      fix x::rat and u::rat and v::rat
-      assume upos: "0<u" and "u<1" and v: "v \<in> A"
-      have vpos: "0<v" by (rule preal_imp_pos [OF A v])
-      hence "u*v < 1*v" by (simp only: mult_strict_right_mono upos \<open>u < 1\<close> v)
-      thus "u * v \<in> A"
-        by (force intro: preal_downwards_closed [OF A v] mult_pos_pos  upos vpos)
-    qed
-  next
-    show "A \<subseteq> ?lhs"
-    proof clarify
-      fix x::rat
-      assume x: "x \<in> A"
-      have xpos: "0<x" by (rule preal_imp_pos [OF A x])
-      from preal_exists_greater [OF A x]
-      obtain v where v: "v \<in> A" and xlessv: "x < v" ..
-      have vpos: "0<v" by (rule preal_imp_pos [OF A v])
-      show "\<exists>u. 0 < u \<and> u < 1 \<and> (\<exists>v\<in>A. x = u * v)"
-      proof (intro exI conjI)
-        show "0 < x/v"
-          by (simp add: zero_less_divide_iff xpos vpos)
-        show "x / v < 1"
-          by (simp add: pos_divide_less_eq vpos xlessv)
-        have "x = (x/v)*v"
-            by (simp add: divide_inverse mult.assoc vpos order_less_imp_not_eq2)
-        then show "\<exists>v'\<in>A. x = (x / v) * v'"
-          using v by blast
-      qed
-    qed
-  qed
-  thus "1 * Abs_preal A = Abs_preal A"
-    by (simp add: preal_one_def preal_mult_def mult_set_def rat_mem_preal A)
-qed
-
-instance preal :: comm_monoid_mult
-  by intro_classes (rule preal_mult_1)
-
-
-subsection\<open>Distribution of Multiplication across Addition\<close>
-
-lemma mem_Rep_preal_add_iff:
-  "(z \<in> Rep_preal(r+s)) = (\<exists>x \<in> Rep_preal r. \<exists>y \<in> Rep_preal s. z = x + y)"
-  apply (simp add: preal_add_def mem_add_set Rep_preal)
-  apply (simp add: add_set_def) 
-  done
-
-lemma mem_Rep_preal_mult_iff:
-  "(z \<in> Rep_preal(r*s)) = (\<exists>x \<in> Rep_preal r. \<exists>y \<in> Rep_preal s. z = x * y)"
-  apply (simp add: preal_mult_def mem_mult_set Rep_preal)
-  apply (simp add: mult_set_def) 
-  done
-
-lemma distrib_subset1:
-  "Rep_preal (w * (x + y)) \<subseteq> Rep_preal (w * x + w * y)"
-  by (force simp: Bex_def mem_Rep_preal_add_iff mem_Rep_preal_mult_iff distrib_left)
-
-lemma preal_add_mult_distrib_mean:
-  assumes a: "a \<in> Rep_preal w"
-    and b: "b \<in> Rep_preal w"
-    and d: "d \<in> Rep_preal x"
-    and e: "e \<in> Rep_preal y"
-  shows "\<exists>c \<in> Rep_preal w. a * d + b * e = c * (d + e)"
-proof
-  let ?c = "(a*d + b*e)/(d+e)"
-  have [simp]: "0<a" "0<b" "0<d" "0<e" "0<d+e"
-    by (blast intro: preal_imp_pos [OF cut_Rep_preal] a b d e pos_add_strict)+
-  have cpos: "0 < ?c"
-    by (simp add: zero_less_divide_iff zero_less_mult_iff pos_add_strict)
-  show "a * d + b * e = ?c * (d + e)"
-    by (simp add: divide_inverse mult.assoc order_less_imp_not_eq2)
-  show "?c \<in> Rep_preal w"
-  proof (cases rule: linorder_le_cases)
-    assume "a \<le> b"
-    hence "?c \<le> b"
-      by (simp add: pos_divide_le_eq distrib_left mult_right_mono
-                    order_less_imp_le)
-    thus ?thesis by (rule preal_downwards_closed' [OF cut_Rep_preal b cpos])
-  next
-    assume "b \<le> a"
-    hence "?c \<le> a"
-      by (simp add: pos_divide_le_eq distrib_left mult_right_mono
-                    order_less_imp_le)
-    thus ?thesis by (rule preal_downwards_closed' [OF cut_Rep_preal a cpos])
-  qed
-qed
-
-lemma distrib_subset2:
-  "Rep_preal (w * x + w * y) \<subseteq> Rep_preal (w * (x + y))"
-  apply (clarsimp simp: mem_Rep_preal_add_iff mem_Rep_preal_mult_iff)
-  using mem_Rep_preal_add_iff preal_add_mult_distrib_mean by blast
-
-lemma preal_add_mult_distrib2: "(w * ((x::preal) + y)) = (w * x) + (w * y)"
-  by (metis Rep_preal_inverse distrib_subset1 distrib_subset2 subset_antisym)
-
-lemma preal_add_mult_distrib: "(((x::preal) + y) * w) = (x * w) + (y * w)"
-  by (simp add: preal_mult_commute preal_add_mult_distrib2)
-
-instance preal :: comm_semiring
-  by intro_classes (rule preal_add_mult_distrib)
-
-
-subsection\<open>Existence of Inverse, a Positive Real\<close>
-
-lemma mem_inverse_set:
-  assumes "cut A" shows "cut (inverse_set A)"
-proof -
-  have "\<exists>x y. 0 < x \<and> x < y \<and> inverse y \<notin> A"
-  proof -
-    from preal_exists_bound [OF \<open>cut A\<close>]
-    obtain x where [simp]: "0<x" "x \<notin> A" by blast
-    show ?thesis
-    proof (intro exI conjI)
-      show "0 < inverse (x+1)"
-        by (simp add: order_less_trans [OF _ less_add_one]) 
-      show "inverse(x+1) < inverse x"
-        by (simp add: less_imp_inverse_less less_add_one)
-      show "inverse (inverse x) \<notin> A"
-        by (simp add: order_less_imp_not_eq2)
-    qed
-  qed
-  then have "{} \<subset> inverse_set A"
-    using inverse_set_def by fastforce
-  moreover obtain q where "q > 0" "q \<notin> inverse_set A"
-  proof -
-    from preal_nonempty [OF \<open>cut A\<close>]
-    obtain x where x: "x \<in> A" and  xpos [simp]: "0<x" ..
-    show ?thesis
-    proof 
-      show "0 < inverse x" by simp
-      show "inverse x \<notin> inverse_set A"
-      proof -
-        { fix y::rat 
-          assume ygt: "inverse x < y"
-          have [simp]: "0 < y" by (simp add: order_less_trans [OF _ ygt])
-          have iyless: "inverse y < x" 
-            by (simp add: inverse_less_imp_less [of x] ygt)
-          have "inverse y \<in> A"
-            by (simp add: preal_downwards_closed [OF \<open>cut A\<close> x] iyless)}
-        thus ?thesis by (auto simp: inverse_set_def)
-      qed
-    qed
-  qed
-  moreover have "inverse_set A \<subset> {0<..}"
-    using calculation inverse_set_def by blast
-  moreover have "z \<in> inverse_set A"
-    if u: "u \<in> inverse_set A" and "0 < z" "z < u" for u z
-    using u that less_trans unfolding inverse_set_def by auto
-  moreover have "\<And>y. y \<in> inverse_set A \<Longrightarrow> \<exists>u \<in> inverse_set A. y < u"
-    by (simp add: inverse_set_def) (meson dense less_trans)
-  ultimately show ?thesis
-    by (simp add: Dedekind_Real.cut_def)
-qed
-
-
-subsection\<open>Gleason's Lemma 9-3.4, page 122\<close>
-
-lemma Gleason9_34_exists:
-  assumes A: "cut A"
-    and "\<forall>x\<in>A. x + u \<in> A"
-    and "0 \<le> z"
-  shows "\<exists>b\<in>A. b + (of_int z) * u \<in> A"
-proof (cases z rule: int_cases)
-  case (nonneg n)
-  show ?thesis
-  proof (simp add: nonneg, induct n)
-    case 0
-    from preal_nonempty [OF A]
-    show ?case  by force 
-  next
-    case (Suc k)
-    then obtain b where b: "b \<in> A" "b + of_nat k * u \<in> A" ..
-    hence "b + of_int (int k)*u + u \<in> A" by (simp add: assms)
-    thus ?case by (force simp: algebra_simps b)
-  qed
-next
-  case (neg n)
-  with assms show ?thesis by simp
-qed
-
-lemma Gleason9_34_contra:
-  assumes A: "cut A"
-    shows "\<lbrakk>\<forall>x\<in>A. x + u \<in> A; 0 < u; 0 < y; y \<notin> A\<rbrakk> \<Longrightarrow> False"
-proof (induct u, induct y)
-  fix a::int and b::int
-  fix c::int and d::int
-  assume bpos [simp]: "0 < b"
-    and dpos [simp]: "0 < d"
-    and closed: "\<forall>x\<in>A. x + (Fract c d) \<in> A"
-    and upos: "0 < Fract c d"
-    and ypos: "0 < Fract a b"
-    and notin: "Fract a b \<notin> A"
-  have cpos [simp]: "0 < c" 
-    by (simp add: zero_less_Fract_iff [OF dpos, symmetric] upos) 
-  have apos [simp]: "0 < a" 
-    by (simp add: zero_less_Fract_iff [OF bpos, symmetric] ypos) 
-  let ?k = "a*d"
-  have frle: "Fract a b \<le> Fract ?k 1 * (Fract c d)" 
-  proof -
-    have "?thesis = ((a * d * b * d) \<le> c * b * (a * d * b * d))"
-      by (simp add: order_less_imp_not_eq2 ac_simps) 
-    moreover
-    have "(1 * (a * d * b * d)) \<le> c * b * (a * d * b * d)"
-      by (rule mult_mono, 
-          simp_all add: int_one_le_iff_zero_less zero_less_mult_iff 
-                        order_less_imp_le)
-    ultimately
-    show ?thesis by simp
-  qed
-  have k: "0 \<le> ?k" by (simp add: order_less_imp_le zero_less_mult_iff)  
-  from Gleason9_34_exists [OF A closed k]
-  obtain z where z: "z \<in> A" 
-             and mem: "z + of_int ?k * Fract c d \<in> A" ..
-  have less: "z + of_int ?k * Fract c d < Fract a b"
-    by (rule not_in_preal_ub [OF A notin mem ypos])
-  have "0<z" by (rule preal_imp_pos [OF A z])
-  with frle and less show False by (simp add: Fract_of_int_eq) 
-qed
-
-
-lemma Gleason9_34:
-  assumes "cut A" "0 < u"
-  shows "\<exists>r \<in> A. r + u \<notin> A"
-  using assms Gleason9_34_contra preal_exists_bound by blast
-
-
-
-subsection\<open>Gleason's Lemma 9-3.6\<close>
-
-lemma lemma_gleason9_36:
-  assumes A: "cut A"
-    and x: "1 < x"
-  shows "\<exists>r \<in> A. r*x \<notin> A"
-proof -
-  from preal_nonempty [OF A]
-  obtain y where y: "y \<in> A" and  ypos: "0<y" ..
-  show ?thesis 
-  proof (rule classical)
-    assume "~(\<exists>r\<in>A. r * x \<notin> A)"
-    with y have ymem: "y * x \<in> A" by blast 
-    from ypos mult_strict_left_mono [OF x]
-    have yless: "y < y*x" by simp 
-    let ?d = "y*x - y"
-    from yless have dpos: "0 < ?d" and eq: "y + ?d = y*x" by auto
-    from Gleason9_34 [OF A dpos]
-    obtain r where r: "r\<in>A" and notin: "r + ?d \<notin> A" ..
-    have rpos: "0<r" by (rule preal_imp_pos [OF A r])
-    with dpos have rdpos: "0 < r + ?d" by arith
-    have "~ (r + ?d \<le> y + ?d)"
-    proof
-      assume le: "r + ?d \<le> y + ?d" 
-      from ymem have yd: "y + ?d \<in> A" by (simp add: eq)
-      have "r + ?d \<in> A" by (rule preal_downwards_closed' [OF A yd rdpos le])
-      with notin show False by simp
-    qed
-    hence "y < r" by simp
-    with ypos have  dless: "?d < (r * ?d)/y"
-      using dpos less_divide_eq_1 by fastforce
-    have "r + ?d < r*x"
-    proof -
-      have "r + ?d < r + (r * ?d)/y" by (simp add: dless)
-      also from ypos have "\<dots> = (r/y) * (y + ?d)"
-        by (simp only: algebra_simps divide_inverse, simp)
-      also have "\<dots> = r*x" using ypos
-        by simp
-      finally show "r + ?d < r*x" .
-    qed
-    with r notin rdpos
-    show "\<exists>r\<in>A. r * x \<notin> A" by (blast dest:  preal_downwards_closed [OF A])
-  qed  
-qed
-
-subsection\<open>Existence of Inverse: Part 2\<close>
-
-lemma mem_Rep_preal_inverse_iff:
-  "(z \<in> Rep_preal(inverse r)) \<longleftrightarrow> (0 < z \<and> (\<exists>y. z < y \<and> inverse y \<notin> Rep_preal r))"
-  apply (simp add: preal_inverse_def mem_inverse_set Rep_preal)
-  apply (simp add: inverse_set_def) 
-  done
-
-lemma Rep_preal_one:
-     "Rep_preal 1 = {x. 0 < x \<and> x < 1}"
-by (simp add: preal_one_def rat_mem_preal)
-
-lemma subset_inverse_mult_lemma:
-  assumes xpos: "0 < x" and xless: "x < 1"
-  shows "\<exists>v u y. 0 < v \<and> v < y \<and> inverse y \<notin> Rep_preal R \<and> 
-    u \<in> Rep_preal R \<and> x = v * u"
-proof -
-  from xpos and xless have "1 < inverse x" by (simp add: one_less_inverse_iff)
-  from lemma_gleason9_36 [OF cut_Rep_preal this]
-  obtain t where t: "t \<in> Rep_preal R" 
-             and notin: "t * (inverse x) \<notin> Rep_preal R" ..
-  have rpos: "0<t" by (rule preal_imp_pos [OF cut_Rep_preal t])
-  from preal_exists_greater [OF cut_Rep_preal t]
-  obtain u where u: "u \<in> Rep_preal R" and rless: "t < u" ..
-  have upos: "0<u" by (rule preal_imp_pos [OF cut_Rep_preal u])
-  show ?thesis
-  proof (intro exI conjI)
-    show "0 < x/u" using xpos upos
-      by (simp add: zero_less_divide_iff)  
-    show "x/u < x/t" using xpos upos rpos
-      by (simp add: divide_inverse mult_less_cancel_left rless) 
-    show "inverse (x / t) \<notin> Rep_preal R" using notin
-      by (simp add: divide_inverse mult.commute) 
-    show "u \<in> Rep_preal R" by (rule u) 
-    show "x = x / u * u" using upos 
-      by (simp add: divide_inverse mult.commute) 
-  qed
-qed
-
-lemma subset_inverse_mult: 
-     "Rep_preal 1 \<subseteq> Rep_preal(inverse r * r)"
-  by (force simp: Rep_preal_one mem_Rep_preal_inverse_iff mem_Rep_preal_mult_iff dest: subset_inverse_mult_lemma)
-
-lemma inverse_mult_subset: "Rep_preal(inverse r * r) \<subseteq> Rep_preal 1"
-  proof -
-  have "0 < u * v" if "v \<in> Rep_preal r" "0 < u" "u < t" for u v t :: rat
-    using that by (simp add: zero_less_mult_iff preal_imp_pos [OF cut_Rep_preal]) 
-  moreover have "t * q < 1"
-    if "q \<in> Rep_preal r" "0 < t" "t < y" "inverse y \<notin> Rep_preal r"
-    for t q y :: rat
-  proof -
-    have "q < inverse y"
-      using not_in_Rep_preal_ub that by auto 
-    hence "t * q < t/y" 
-      using that by (simp add: divide_inverse mult_less_cancel_left)
-    also have "\<dots> \<le> 1" 
-      using that by (simp add: pos_divide_le_eq)
-    finally show ?thesis .
-  qed
-  ultimately show ?thesis
-    by (auto simp: Rep_preal_one mem_Rep_preal_inverse_iff mem_Rep_preal_mult_iff)
-qed 
-
-lemma preal_mult_inverse: "inverse r * r = (1::preal)"
-  by (meson Rep_preal_inject inverse_mult_subset subset_antisym subset_inverse_mult)
-
-lemma preal_mult_inverse_right: "r * inverse r = (1::preal)"
-  using preal_mult_commute preal_mult_inverse by auto
-
-
-text\<open>Theorems needing \<open>Gleason9_34\<close>\<close>
-
-lemma Rep_preal_self_subset: "Rep_preal (r) \<subseteq> Rep_preal(r + s)"
-proof 
-  fix x
-  assume x: "x \<in> Rep_preal r"
-  obtain y where y: "y \<in> Rep_preal s" and "y > 0"
-    using Rep_preal preal_nonempty by blast
-  have ry: "x+y \<in> Rep_preal(r + s)" using x y
-    by (auto simp: mem_Rep_preal_add_iff)
-  then show "x \<in> Rep_preal(r + s)"
-    by (meson \<open>0 < y\<close> add_less_same_cancel1 not_in_Rep_preal_ub order.asym preal_imp_pos [OF cut_Rep_preal x])
-qed
-
-lemma Rep_preal_sum_not_subset: "~ Rep_preal (r + s) \<subseteq> Rep_preal(r)"
-proof -
-  obtain y where y: "y \<in> Rep_preal s" and "y > 0"
-    using Rep_preal preal_nonempty by blast
-  obtain x where "x \<in> Rep_preal r" and notin: "x + y \<notin> Rep_preal r"
-    using Dedekind_Real.Rep_preal Gleason9_34 \<open>0 < y\<close> by blast 
-  then have "x + y \<in> Rep_preal (r + s)" using y
-    by (auto simp: mem_Rep_preal_add_iff)
-  thus ?thesis using notin by blast
-qed
-
-text\<open>at last, Gleason prop. 9-3.5(iii) page 123\<close>
-proposition preal_self_less_add_left: "(r::preal) < r + s"
-  by (meson Rep_preal_sum_not_subset not_less preal_le_def)
-
-
-subsection\<open>Subtraction for Positive Reals\<close>
-
-text\<open>gleason prop. 9-3.5(iv), page 123: proving \<^prop>\<open>a < b \<Longrightarrow> \<exists>d. a + d = b\<close>. 
-We define the claimed \<^term>\<open>D\<close> and show that it is a positive real\<close>
-
-lemma mem_diff_set:
-  assumes "r < s"
-  shows "cut (diff_set (Rep_preal s) (Rep_preal r))"
-proof -
-  obtain p where "Rep_preal r \<subseteq> Rep_preal s" "p \<in> Rep_preal s" "p \<notin> Rep_preal r"
-    using assms unfolding preal_less_def by auto
-  then have "{} \<subset> diff_set (Rep_preal s) (Rep_preal r)"
-    apply (simp add: diff_set_def psubset_eq)
-    by (metis cut_Rep_preal add_eq_exists less_add_same_cancel1 preal_exists_greater preal_imp_pos)
-  moreover
-  obtain q where "q > 0" "q \<notin> Rep_preal s"
-    using Rep_preal_exists_bound by blast
-  then have qnot: "q \<notin> diff_set (Rep_preal s) (Rep_preal r)"
-    by (auto simp: diff_set_def dest: cut_Rep_preal [THEN preal_downwards_closed])
-  moreover have "diff_set (Rep_preal s) (Rep_preal r) \<subset> {0<..}" (is "?lhs < ?rhs")
-    using \<open>0 < q\<close> diff_set_def qnot by blast
-  moreover have "z \<in> diff_set (Rep_preal s) (Rep_preal r)"
-    if u: "u \<in> diff_set (Rep_preal s) (Rep_preal r)" and "0 < z" "z < u" for u z
-    using u that less_trans Rep_preal unfolding diff_set_def Dedekind_Real.cut_def by auto
-  moreover have "\<exists>u \<in> diff_set (Rep_preal s) (Rep_preal r). y < u"
-    if y: "y \<in> diff_set (Rep_preal s) (Rep_preal r)" for y
-  proof -
-    obtain a b where "0 < a" "0 < b" "a \<notin> Rep_preal r" "a + y + b \<in> Rep_preal s"
-      using y
-      by (simp add: diff_set_def) (metis cut_Rep_preal add_eq_exists less_add_same_cancel1 preal_exists_greater) 
-    then have "a + (y + b) \<in> Rep_preal s"
-      by (simp add: add.assoc)
-    then have "y + b \<in> diff_set (Rep_preal s) (Rep_preal r)"
-      using \<open>0 < a\<close> \<open>0 < b\<close> \<open>a \<notin> Rep_preal r\<close> y
-      by (auto simp: diff_set_def)
-    then show ?thesis
-      using \<open>0 < b\<close> less_add_same_cancel1 by blast
-  qed
-  ultimately show ?thesis
-    by (simp add: Dedekind_Real.cut_def)
-qed
-
-lemma mem_Rep_preal_diff_iff:
-  "r < s \<Longrightarrow>
-       (z \<in> Rep_preal (s - r)) \<longleftrightarrow> 
-       (\<exists>x. 0 < x \<and> 0 < z \<and> x \<notin> Rep_preal r \<and> x + z \<in> Rep_preal s)"
-  apply (simp add: preal_diff_def mem_diff_set Rep_preal)
-  apply (force simp: diff_set_def) 
-  done
-
-proposition less_add_left:
-  fixes r::preal 
-  assumes "r < s"
-  shows "r + (s-r) = s"
-proof -
-  have "a + b \<in> Rep_preal s"
-    if "a \<in> Rep_preal r" "c + b \<in> Rep_preal s" "c \<notin> Rep_preal r"
-    and "0 < b" "0 < c" for a b c
-    by (meson cut_Rep_preal add_less_imp_less_right add_pos_pos not_in_Rep_preal_ub preal_downwards_closed preal_imp_pos that)
-  then have "r + (s-r) \<le> s"
-    using assms mem_Rep_preal_add_iff mem_Rep_preal_diff_iff preal_le_def by auto
-  have "x \<in> Rep_preal (r + (s - r))" if "x \<in> Rep_preal s" for x
-  proof (cases "x \<in> Rep_preal r")
-    case True
-    then show ?thesis
-      using Rep_preal_self_subset by blast
-  next
-    case False
-    have "\<exists>u v z. 0 < v \<and> 0 < z \<and> u \<in> Rep_preal r \<and> z \<notin> Rep_preal r \<and> z + v \<in> Rep_preal s \<and> x = u + v"
-      if x: "x \<in> Rep_preal s"
-    proof -
-      have xpos: "x > 0"
-        using Rep_preal preal_imp_pos that by blast 
-      obtain e where epos: "0 < e" and xe: "x + e \<in> Rep_preal s"
-        by (metis cut_Rep_preal x add_eq_exists less_add_same_cancel1 preal_exists_greater)
-      from  Gleason9_34 [OF cut_Rep_preal epos]
-      obtain u where r: "u \<in> Rep_preal r" and notin: "u + e \<notin> Rep_preal r" ..
-      with x False xpos have rless: "u < x" by (blast intro: not_in_Rep_preal_ub)
-      from add_eq_exists [of u x]
-      obtain y where eq: "x = u+y" by auto
-      show ?thesis 
-      proof (intro exI conjI)
-        show "u + e \<notin> Rep_preal r" by (rule notin)
-        show "u + e + y \<in> Rep_preal s" using xe eq by (simp add: ac_simps)
-        show "0 < u + e" 
-          using epos preal_imp_pos [OF cut_Rep_preal r] by simp
-      qed (use r rless eq in auto)
-    qed
-    then show ?thesis
-      using assms mem_Rep_preal_add_iff mem_Rep_preal_diff_iff that by blast
-  qed
-  then have "s \<le> r + (s-r)"
-    by (auto simp: preal_le_def)
-  then show ?thesis
-    by (simp add: \<open>r + (s - r) \<le> s\<close> antisym)
-qed
-
-lemma preal_add_less2_mono1: "r < (s::preal) \<Longrightarrow> r + t < s + t"
-  by (metis add.assoc add.commute less_add_left preal_self_less_add_left)
-
-lemma preal_add_less2_mono2: "r < (s::preal) \<Longrightarrow> t + r < t + s"
-  by (auto intro: preal_add_less2_mono1 simp add: preal_add_commute [of t])
-
-lemma preal_add_right_less_cancel: "r + t < s + t \<Longrightarrow> r < (s::preal)"
-  by (metis linorder_cases order.asym preal_add_less2_mono1)
-
-lemma preal_add_left_less_cancel: "t + r < t + s \<Longrightarrow> r < (s::preal)"
-  by (auto elim: preal_add_right_less_cancel simp add: preal_add_commute [of t])
-
-lemma preal_add_less_cancel_left [simp]: "(t + (r::preal) < t + s) \<longleftrightarrow> (r < s)"
-  by (blast intro: preal_add_less2_mono2 preal_add_left_less_cancel)
-
-lemma preal_add_less_cancel_right [simp]: "((r::preal) + t < s + t) = (r < s)"
-  using preal_add_less_cancel_left [symmetric, of r s t] by (simp add: ac_simps)
-
-lemma preal_add_le_cancel_left [simp]: "(t + (r::preal) \<le> t + s) = (r \<le> s)"
-  by (simp add: linorder_not_less [symmetric]) 
-
-lemma preal_add_le_cancel_right [simp]: "((r::preal) + t \<le> s + t) = (r \<le> s)"
-  using preal_add_le_cancel_left [symmetric, of r s t] by (simp add: ac_simps)
-
-lemma preal_add_right_cancel: "(r::preal) + t = s + t \<Longrightarrow> r = s"
-  by (metis less_irrefl linorder_cases preal_add_less_cancel_right)
-
-lemma preal_add_left_cancel: "c + a = c + b \<Longrightarrow> a = (b::preal)"
-  by (auto intro: preal_add_right_cancel simp add: preal_add_commute)
-
-instance preal :: linordered_ab_semigroup_add
-proof
-  fix a b c :: preal
-  show "a \<le> b \<Longrightarrow> c + a \<le> c + b" by (simp only: preal_add_le_cancel_left)
-qed
-
-
-subsection\<open>Completeness of type \<^typ>\<open>preal\<close>\<close>
-
-text\<open>Prove that supremum is a cut\<close>
-
-text\<open>Part 1 of Dedekind sections definition\<close>
-
-lemma preal_sup:
-  assumes le: "\<And>X. X \<in> P \<Longrightarrow> X \<le> Y" and "P \<noteq> {}" 
-  shows "cut (\<Union>X \<in> P. Rep_preal(X))"
-proof -
-  have "{} \<subset> (\<Union>X \<in> P. Rep_preal(X))"
-    using \<open>P \<noteq> {}\<close> mem_Rep_preal_Ex by fastforce
-  moreover
-  obtain q where "q > 0" and "q \<notin> (\<Union>X \<in> P. Rep_preal(X))"
-    using Rep_preal_exists_bound [of Y] le by (auto simp: preal_le_def)
-  then have "(\<Union>X \<in> P. Rep_preal(X)) \<subset> {0<..}"
-    using cut_Rep_preal preal_imp_pos by force
-  moreover
-  have "\<And>u z. \<lbrakk>u \<in> (\<Union>X \<in> P. Rep_preal(X)); 0 < z; z < u\<rbrakk> \<Longrightarrow> z \<in> (\<Union>X \<in> P. Rep_preal(X))"
-    by (auto elim: cut_Rep_preal [THEN preal_downwards_closed])
-  moreover
-  have "\<And>y. y \<in> (\<Union>X \<in> P. Rep_preal(X)) \<Longrightarrow> \<exists>u \<in> (\<Union>X \<in> P. Rep_preal(X)). y < u"
-    by (blast dest: cut_Rep_preal [THEN preal_exists_greater])
-  ultimately show ?thesis
-    by (simp add: Dedekind_Real.cut_def)
-qed
-
-lemma preal_psup_le:
-     "\<lbrakk>\<And>X. X \<in> P \<Longrightarrow> X \<le> Y;  x \<in> P\<rbrakk> \<Longrightarrow> x \<le> psup P"
-  using preal_sup [of P Y] unfolding preal_le_def psup_def by fastforce 
-
-lemma psup_le_ub: "\<lbrakk>\<And>X. X \<in> P \<Longrightarrow> X \<le> Y; P \<noteq> {}\<rbrakk> \<Longrightarrow> psup P \<le> Y"
-  using preal_sup [of P Y] by (simp add: SUP_least preal_le_def psup_def) 
-
-text\<open>Supremum property\<close>
-proposition preal_complete:
-  assumes le: "\<And>X. X \<in> P \<Longrightarrow> X \<le> Y" and "P \<noteq> {}" 
-  shows "(\<exists>X \<in> P. Z < X) \<longleftrightarrow> (Z < psup P)" (is "?lhs = ?rhs")
-proof
-  assume ?lhs
-  then show ?rhs
-    using preal_sup [OF assms] preal_less_def psup_def by auto
-next
-  assume ?rhs
-  then show ?lhs
-    by (meson \<open>P \<noteq> {}\<close> not_less psup_le_ub) 
-qed
-
-subsection \<open>Defining the Reals from the Positive Reals\<close>
-
-text \<open>Here we do quotients the old-fashioned way\<close>
-
-definition
-  realrel   ::  "((preal * preal) * (preal * preal)) set" where
-  "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) \<and> x1+y2 = x2+y1}"
-
-definition "Real = UNIV//realrel"
-
-typedef real = Real
-  morphisms Rep_Real Abs_Real
-  unfolding Real_def by (auto simp: quotient_def)
-
-text \<open>This doesn't involve the overloaded "real" function: users don't see it\<close>
-definition
-  real_of_preal :: "preal \<Rightarrow> real" where
-  "real_of_preal m = Abs_Real (realrel `` {(m + 1, 1)})"
-
-instantiation real :: "{zero, one, plus, minus, uminus, times, inverse, ord, abs, sgn}"
-begin
-
-definition
-  real_zero_def: "0 = Abs_Real(realrel``{(1, 1)})"
-
-definition
-  real_one_def: "1 = Abs_Real(realrel``{(1 + 1, 1)})"
-
-definition
-  real_add_def: "z + w =
-       the_elem (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
-                 { Abs_Real(realrel``{(x+u, y+v)}) })"
-
-definition
-  real_minus_def: "- r =  the_elem (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
-
-definition
-  real_diff_def: "r - (s::real) = r + - s"
-
-definition
-  real_mult_def:
-    "z * w =
-       the_elem (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
-                 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
-
-definition
-  real_inverse_def: "inverse (r::real) = (THE s. (r = 0 \<and> s = 0) \<or> s * r = 1)"
-
-definition
-  real_divide_def: "r div (s::real) = r * inverse s"
-
-definition
-  real_le_def: "z \<le> (w::real) \<longleftrightarrow>
-    (\<exists>x y u v. x+v \<le> u+y \<and> (x,y) \<in> Rep_Real z \<and> (u,v) \<in> Rep_Real w)"
-
-definition
-  real_less_def: "x < (y::real) \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
-
-definition
-  real_abs_def: "\<bar>r::real\<bar> = (if r < 0 then - r else r)"
-
-definition
-  real_sgn_def: "sgn (x::real) = (if x=0 then 0 else if 0<x then 1 else - 1)"
-
-instance ..
-
-end
-
-subsection \<open>Equivalence relation over positive reals\<close>
-
-lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
-  by (simp add: realrel_def)
-
-lemma preal_trans_lemma:
-  assumes "x + y1 = x1 + y" and "x + y2 = x2 + y"
-  shows "x1 + y2 = x2 + (y1::preal)"
-  by (metis add.left_commute assms preal_add_left_cancel)
-
-lemma equiv_realrel: "equiv UNIV realrel"
-  by (auto simp: equiv_def refl_on_def sym_def trans_def realrel_def intro: dest: preal_trans_lemma)
-
-text\<open>Reduces equality of equivalence classes to the \<^term>\<open>realrel\<close> relation:
-  \<^term>\<open>(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)\<close>\<close>
-lemmas equiv_realrel_iff [simp] = 
-       eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
-
-lemma realrel_in_real [simp]: "realrel``{(x,y)} \<in> Real"
-  by (simp add: Real_def realrel_def quotient_def, blast)
-
-declare Abs_Real_inject [simp] Abs_Real_inverse [simp]
-
-
-text\<open>Case analysis on the representation of a real number as an equivalence
-      class of pairs of positive reals.\<close>
-lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
-     "(\<And>x y. z = Abs_Real(realrel``{(x,y)}) \<Longrightarrow> P) \<Longrightarrow> P"
-  by (metis Rep_Real_inverse prod.exhaust  Rep_Real [of z, unfolded Real_def, THEN quotientE])
-
-subsection \<open>Addition and Subtraction\<close>
-
-lemma real_add:
-     "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
-      Abs_Real (realrel``{(x+u, y+v)})"
-proof -
-  have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
-        respects2 realrel"
-  by (clarsimp simp: congruent2_def) (metis add.left_commute preal_add_assoc)
-  thus ?thesis
-    by (simp add: real_add_def UN_UN_split_split_eq UN_equiv_class2 [OF equiv_realrel equiv_realrel])
-qed
-
-lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
-proof -
-  have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
-    by (auto simp: congruent_def add.commute) 
-  thus ?thesis
-    by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
-qed
-
-instance real :: ab_group_add
-proof
-  fix x y z :: real
-  show "(x + y) + z = x + (y + z)"
-    by (cases x, cases y, cases z, simp add: real_add add.assoc)
-  show "x + y = y + x"
-    by (cases x, cases y, simp add: real_add add.commute)
-  show "0 + x = x"
-    by (cases x, simp add: real_add real_zero_def ac_simps)
-  show "- x + x = 0"
-    by (cases x, simp add: real_minus real_add real_zero_def add.commute)
-  show "x - y = x + - y"
-    by (simp add: real_diff_def)
-qed
-
-
-subsection \<open>Multiplication\<close>
-
-lemma real_mult_congruent2_lemma:
-     "!!(x1::preal). \<lbrakk>x1 + y2 = x2 + y1\<rbrakk> \<Longrightarrow>
-          x * x1 + y * y1 + (x * y2 + y * x2) =
-          x * x2 + y * y2 + (x * y1 + y * x1)"
-  by (metis (no_types, opaque_lifting) add.left_commute preal_add_commute preal_add_mult_distrib2)
-
-lemma real_mult_congruent2:
-  "(\<lambda>p1 p2.
-        (\<lambda>(x1,y1). (\<lambda>(x2,y2). 
-          { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
-     respects2 realrel"
-  apply (rule congruent2_commuteI [OF equiv_realrel])
-  by (auto simp: mult.commute add.commute combine_common_factor preal_add_assoc preal_add_commute)
-
-lemma real_mult:
-  "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
-   Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
-  by (simp add: real_mult_def UN_UN_split_split_eq
-      UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
-
-lemma real_mult_commute: "(z::real) * w = w * z"
-by (cases z, cases w, simp add: real_mult ac_simps)
-
-lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
-  by (cases z1, cases z2, cases z3) (simp add: real_mult algebra_simps)
-
-lemma real_mult_1: "(1::real) * z = z"
-  by (cases z) (simp add: real_mult real_one_def algebra_simps)
-
-lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
-  by (cases z1, cases z2, cases w) (simp add: real_add real_mult algebra_simps)
-
-text\<open>one and zero are distinct\<close>
-lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
-proof -
-  have "(1::preal) < 1 + 1"
-    by (simp add: preal_self_less_add_left)
-  then show ?thesis
-    by (simp add: real_zero_def real_one_def neq_iff)
-qed
-
-instance real :: comm_ring_1
-proof
-  fix x y z :: real
-  show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
-  show "x * y = y * x" by (rule real_mult_commute)
-  show "1 * x = x" by (rule real_mult_1)
-  show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
-  show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
-qed
-
-subsection \<open>Inverse and Division\<close>
-
-lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
-  by (simp add: real_zero_def add.commute)
-
-lemma real_mult_inverse_left_ex:
-  assumes "x \<noteq> 0" obtains y::real where "y*x = 1"
-proof (cases x)
-  case (Abs_Real u v)
-  show ?thesis
-  proof (cases u v rule: linorder_cases)
-    case less
-    then have "v * inverse (v - u) = 1 + u * inverse (v - u)"
-      using less_add_left [of u v]
-      by (metis preal_add_commute preal_add_mult_distrib preal_mult_inverse_right)
-    then have "Abs_Real (realrel``{(1, inverse (v-u) + 1)}) * x - 1 = 0"
-      by (simp add: Abs_Real real_mult preal_mult_inverse_right real_one_def) (simp add: algebra_simps)
-    with that show thesis by auto
-  next
-    case equal
-    then show ?thesis
-      using Abs_Real assms real_zero_iff by blast
-  next
-    case greater
-    then have "u * inverse (u - v) = 1 + v * inverse (u - v)"
-      using less_add_left [of v u] by (metis add.commute distrib_right preal_mult_inverse_right)
-    then have "Abs_Real (realrel``{(inverse (u-v) + 1, 1)}) * x - 1 = 0"
-      by (simp add: Abs_Real real_mult preal_mult_inverse_right real_one_def) (simp add: algebra_simps)
-    with that show thesis by auto
-  qed
-qed
-
-
-lemma real_mult_inverse_left:
-  fixes x :: real
-  assumes "x \<noteq> 0" shows "inverse x * x = 1"
-proof -
-  obtain y where "y*x = 1"
-    using assms real_mult_inverse_left_ex by blast
-  then have "(THE s. s * x = 1) * x = 1"
-  proof (rule theI)
-    show "y' = y" if "y' * x = 1" for y'
-      by (metis \<open>y * x = 1\<close> mult.left_commute mult.right_neutral that) 
-  qed
-  then show ?thesis
-    using assms real_inverse_def by auto
-qed
-
-
-subsection\<open>The Real Numbers form a Field\<close>
-
-instance real :: field
-proof
-  fix x y z :: real
-  show "x \<noteq> 0 \<Longrightarrow> inverse x * x = 1" by (rule real_mult_inverse_left)
-  show "x / y = x * inverse y" by (simp add: real_divide_def)
-  show "inverse 0 = (0::real)" by (simp add: real_inverse_def)
-qed
-
-
-subsection\<open>The \<open>\<le>\<close> Ordering\<close>
-
-lemma real_le_refl: "w \<le> (w::real)"
-  by (cases w, force simp: real_le_def)
-
-text\<open>The arithmetic decision procedure is not set up for type preal.
-  This lemma is currently unused, but it could simplify the proofs of the
-  following two lemmas.\<close>
-lemma preal_eq_le_imp_le:
-  assumes eq: "a+b = c+d" and le: "c \<le> a"
-  shows "b \<le> (d::preal)"
-proof -
-  from le have "c+d \<le> a+d" by simp
-  hence "a+b \<le> a+d" by (simp add: eq)
-  thus "b \<le> d" by simp
-qed
-
-lemma real_le_lemma:
-  assumes l: "u1 + v2 \<le> u2 + v1"
-    and "x1 + v1 = u1 + y1"
-    and "x2 + v2 = u2 + y2"
-  shows "x1 + y2 \<le> x2 + (y1::preal)"
-proof -
-  have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: assms)
-  hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: ac_simps)
-  also have "\<dots> \<le> (x2+y1) + (u2+v1)" by (simp add: assms)
-  finally show ?thesis by simp
-qed
-
-lemma real_le: 
-  "Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})  \<longleftrightarrow>  x1 + y2 \<le> x2 + y1"
-  unfolding real_le_def by (auto intro: real_le_lemma)
-
-lemma real_le_antisym: "\<lbrakk>z \<le> w; w \<le> z\<rbrakk> \<Longrightarrow> z = (w::real)"
-  by (cases z, cases w, simp add: real_le)
-
-lemma real_trans_lemma:
-  assumes "x + v \<le> u + y"
-    and "u + v' \<le> u' + v"
-    and "x2 + v2 = u2 + y2"
-  shows "x + v' \<le> u' + (y::preal)"
-proof -
-  have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: ac_simps)
-  also have "\<dots> \<le> (u+y) + (u+v')" by (simp add: assms)
-  also have "\<dots> \<le> (u+y) + (u'+v)" by (simp add: assms)
-  also have "\<dots> = (u'+y) + (u+v)"  by (simp add: ac_simps)
-  finally show ?thesis by simp
-qed
-
-lemma real_le_trans: "\<lbrakk>i \<le> j; j \<le> k\<rbrakk> \<Longrightarrow> i \<le> (k::real)"
-  by (cases i, cases j, cases k) (auto simp: real_le intro: real_trans_lemma)
-
-instance real :: order
-proof
-  show "u < v \<longleftrightarrow> u \<le> v \<and> \<not> v \<le> u" for u v::real
-    by (auto simp: real_less_def intro: real_le_antisym)
-qed (auto intro: real_le_refl real_le_trans real_le_antisym)
-
-instance real :: linorder
-proof
-  show "x \<le> y \<or> y \<le> x" for x y :: real
-    by (meson eq_refl le_cases real_le_def)
-qed
-
-instantiation real :: distrib_lattice
-begin
-
-definition
-  "(inf :: real \<Rightarrow> real \<Rightarrow> real) = min"
-
-definition
-  "(sup :: real \<Rightarrow> real \<Rightarrow> real) = max"
-
-instance
-  by standard (auto simp: inf_real_def sup_real_def max_min_distrib2)
-
-end
-
-subsection\<open>The Reals Form an Ordered Field\<close>
-
-lemma real_le_eq_diff: "(x \<le> y) \<longleftrightarrow> (x-y \<le> (0::real))"
-  by (cases x, cases y) (simp add: real_le real_zero_def real_diff_def real_add real_minus preal_add_commute)
-
-lemma real_add_left_mono: 
-  assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
-proof -
-  have "z + x - (z + y) = (z + -z) + (x - y)" 
-    by (simp add: algebra_simps) 
-  with le show ?thesis 
-    by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"])
-qed
-
-lemma real_sum_gt_zero_less: "(0 < s + (-w::real)) \<Longrightarrow> (w < s)"
-  by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of s])
-
-lemma real_less_sum_gt_zero: "(w < s) \<Longrightarrow> (0 < s + (-w::real))"
-  by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of s])
-
-lemma real_mult_order: 
-  fixes x y::real
-  assumes "0 < x" "0 < y"
-  shows "0 < x * y"
-  proof (cases x, cases y)
-  show "0 < x * y"
-    if x: "x = Abs_Real (Dedekind_Real.realrel `` {(x1, x2)})"
-      and y: "y = Abs_Real (Dedekind_Real.realrel `` {(y1, y2)})"
-    for x1 x2 y1 y2
-  proof -
-    have "x2 < x1" "y2 < y1"
-      using assms not_le real_zero_def real_le x y
-      by (metis preal_add_le_cancel_left real_zero_iff)+
-    then obtain xd yd where "x1 = x2 + xd" "y1 = y2 + yd"
-      using less_add_left by metis
-    then have "\<not> (x * y \<le> 0)"
-      apply (simp add: x y real_mult real_zero_def real_le)
-      apply (simp add: not_le algebra_simps preal_self_less_add_left)
-      done
-    then show ?thesis
-      by auto
-  qed
-qed
-
-lemma real_mult_less_mono2: "\<lbrakk>(0::real) < z; x < y\<rbrakk> \<Longrightarrow> z * x < z * y"
-  by (metis add_uminus_conv_diff real_less_sum_gt_zero real_mult_order real_sum_gt_zero_less right_diff_distrib')
-
-
-instance real :: linordered_field
-proof
-  fix x y z :: real
-  show "x \<le> y \<Longrightarrow> z + x \<le> z + y" by (rule real_add_left_mono)
-  show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
-  show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
-    by (simp only: real_sgn_def)
-  show "z * x < z * y" if "x < y" "0 < z"
-    by (simp add: real_mult_less_mono2 that)
-qed
-
-
-subsection \<open>Completeness of the reals\<close>
-
-text\<open>The function \<^term>\<open>real_of_preal\<close> requires many proofs, but it seems
-to be essential for proving completeness of the reals from that of the
-positive reals.\<close>
-
-lemma real_of_preal_add:
-  "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
-  by (simp add: real_of_preal_def real_add algebra_simps)
-
-lemma real_of_preal_mult:
-  "real_of_preal ((x::preal) * y) = real_of_preal x * real_of_preal y"
-  by (simp add: real_of_preal_def real_mult algebra_simps)
-
-text\<open>Gleason prop 9-4.4 p 127\<close>
-lemma real_of_preal_trichotomy:
-  "\<exists>m. (x::real) = real_of_preal m \<or> x = 0 \<or> x = -(real_of_preal m)"
-proof (cases x)
-  case (Abs_Real u v)
-  show ?thesis
-  proof (cases u v rule: linorder_cases)
-    case less
-    then show ?thesis
-      using less_add_left
-      apply (simp add: Abs_Real real_of_preal_def real_minus real_zero_def)
-      by (metis preal_add_assoc preal_add_commute)      
-  next
-    case equal
-    then show ?thesis
-      using Abs_Real real_zero_iff by blast
-  next
-    case greater
-    then show ?thesis
-      using less_add_left
-      apply (simp add: Abs_Real real_of_preal_def real_minus real_zero_def)
-      by (metis preal_add_assoc preal_add_commute)      
-  qed
-qed
-
-lemma real_of_preal_less_iff [simp]:
-  "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
-  by (metis not_less preal_add_less_cancel_right real_le real_of_preal_def)
-
-lemma real_of_preal_le_iff [simp]:
-  "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
-  by (simp add: linorder_not_less [symmetric])
-
-lemma real_of_preal_zero_less [simp]: "0 < real_of_preal m"
-  by (metis less_add_same_cancel2 preal_self_less_add_left real_of_preal_add real_of_preal_less_iff)
-
-
-subsection\<open>Theorems About the Ordering\<close>
-
-lemma real_gt_zero_preal_Ex: "(0 < x) \<longleftrightarrow> (\<exists>y. x = real_of_preal y)"
-  using order.asym real_of_preal_trichotomy by fastforce
-
-subsection \<open>Completeness of Positive Reals\<close>
-
-text \<open>
-  Supremum property for the set of positive reals
-
-  Let \<open>P\<close> be a non-empty set of positive reals, with an upper
-  bound \<open>y\<close>.  Then \<open>P\<close> has a least upper bound
-  (written \<open>S\<close>).
-
-  FIXME: Can the premise be weakened to \<open>\<forall>x \<in> P. x\<le> y\<close>?
-\<close>
-
-lemma posreal_complete:
-  assumes positive_P: "\<forall>x \<in> P. (0::real) < x"
-    and not_empty_P: "\<exists>x. x \<in> P"
-    and upper_bound_Ex: "\<exists>y. \<forall>x \<in> P. x<y"
-  shows "\<exists>s. \<forall>y. (\<exists>x \<in> P. y < x) = (y < s)"
-proof (rule exI, rule allI)
-  fix y
-  let ?pP = "{w. real_of_preal w \<in> P}"
-
-  show "(\<exists>x\<in>P. y < x) = (y < real_of_preal (psup ?pP))"
-  proof (cases "0 < y")
-    assume neg_y: "\<not> 0 < y"
-    show ?thesis
-    proof
-      assume "\<exists>x\<in>P. y < x"
-      thus "y < real_of_preal (psup ?pP)"
-        by (metis dual_order.strict_trans neg_y not_less_iff_gr_or_eq real_of_preal_zero_less) 
-    next
-      assume "y < real_of_preal (psup ?pP)"
-      obtain "x" where x_in_P: "x \<in> P" using not_empty_P ..
-      thus "\<exists>x \<in> P. y < x" using x_in_P
-        using neg_y not_less_iff_gr_or_eq positive_P by fastforce 
-    qed
-  next
-    assume pos_y: "0 < y"
-    then obtain py where y_is_py: "y = real_of_preal py"
-      by (auto simp: real_gt_zero_preal_Ex)
-
-    obtain a where "a \<in> P" using not_empty_P ..
-    with positive_P have a_pos: "0 < a" ..
-    then obtain pa where "a = real_of_preal pa"
-      by (auto simp: real_gt_zero_preal_Ex)
-    hence "pa \<in> ?pP" using \<open>a \<in> P\<close> by auto
-    hence pP_not_empty: "?pP \<noteq> {}" by auto
-
-    obtain sup where sup: "\<forall>x \<in> P. x < sup"
-      using upper_bound_Ex ..
-    from this and \<open>a \<in> P\<close> have "a < sup" ..
-    hence "0 < sup" using a_pos by arith
-    then obtain possup where "sup = real_of_preal possup"
-      by (auto simp: real_gt_zero_preal_Ex)
-    hence "\<forall>X \<in> ?pP. X \<le> possup"
-      using sup by auto
-    with pP_not_empty have psup: "\<And>Z. (\<exists>X \<in> ?pP. Z < X) = (Z < psup ?pP)"
-      by (meson preal_complete)
-    show ?thesis
-    proof
-      assume "\<exists>x \<in> P. y < x"
-      then obtain x where x_in_P: "x \<in> P" and y_less_x: "y < x" ..
-      hence "0 < x" using pos_y by arith
-      then obtain px where x_is_px: "x = real_of_preal px"
-        by (auto simp: real_gt_zero_preal_Ex)
-
-      have py_less_X: "\<exists>X \<in> ?pP. py < X"
-      proof
-        show "py < px" using y_is_py and x_is_px and y_less_x
-          by simp
-        show "px \<in> ?pP" using x_in_P and x_is_px by simp
-      qed
-
-      have "(\<exists>X \<in> ?pP. py < X) \<Longrightarrow> (py < psup ?pP)"
-        using psup by simp
-      hence "py < psup ?pP" using py_less_X by simp
-      thus "y < real_of_preal (psup {w. real_of_preal w \<in> P})"
-        using y_is_py and pos_y by simp
-    next
-      assume y_less_psup: "y < real_of_preal (psup ?pP)"
-
-      hence "py < psup ?pP" using y_is_py
-        by simp
-      then obtain "X" where py_less_X: "py < X" and X_in_pP: "X \<in> ?pP"
-        using psup by auto
-      then obtain x where x_is_X: "x = real_of_preal X"
-        by (simp add: real_gt_zero_preal_Ex)
-      hence "y < x" using py_less_X and y_is_py
-        by simp
-      moreover have "x \<in> P" 
-        using x_is_X and X_in_pP by simp
-      ultimately show "\<exists> x \<in> P. y < x" ..
-    qed
-  qed
-qed
-
-
-subsection \<open>Completeness\<close>
-
-lemma reals_complete:
-  fixes S :: "real set"
-  assumes notempty_S: "\<exists>X. X \<in> S"
-    and exists_Ub: "bdd_above S"
-  shows "\<exists>x. (\<forall>s\<in>S. s \<le> x) \<and> (\<forall>y. (\<forall>s\<in>S. s \<le> y) \<longrightarrow> x \<le> y)"
-proof -
-  obtain X where X_in_S: "X \<in> S" using notempty_S ..
-  obtain Y where Y_isUb: "\<forall>s\<in>S. s \<le> Y"
-    using exists_Ub by (auto simp: bdd_above_def)
-  let ?SHIFT = "{z. \<exists>x \<in>S. z = x + (-X) + 1} \<inter> {x. 0 < x}"
-
-  {
-    fix x
-    assume S_le_x: "\<forall>s\<in>S. s \<le> x"
-    {
-      fix s
-      assume "s \<in> {z. \<exists>x\<in>S. z = x + - X + 1}"
-      hence "\<exists> x \<in> S. s = x + -X + 1" ..
-      then obtain x1 where x1: "x1 \<in> S" "s = x1 + (-X) + 1" ..
-      then have "x1 \<le> x" using S_le_x by simp
-      with x1 have "s \<le> x + - X + 1" by arith
-    }
-    then have "\<forall>s\<in>?SHIFT. s \<le> x + (-X) + 1"
-      by auto
-  } note S_Ub_is_SHIFT_Ub = this
-
-  have *: "\<forall>s\<in>?SHIFT. s \<le> Y + (-X) + 1" using Y_isUb by (rule S_Ub_is_SHIFT_Ub)
-  have "\<forall>s\<in>?SHIFT. s < Y + (-X) + 2"
-  proof
-    fix s assume "s\<in>?SHIFT"
-    with * have "s \<le> Y + (-X) + 1" by simp
-    also have "\<dots> < Y + (-X) + 2" by simp
-    finally show "s < Y + (-X) + 2" .
-  qed
-  moreover have "\<forall>y \<in> ?SHIFT. 0 < y" by auto
-  moreover have shifted_not_empty: "\<exists>u. u \<in> ?SHIFT"
-    using X_in_S and Y_isUb by auto
-  ultimately obtain t where t_is_Lub: "\<forall>y. (\<exists>x\<in>?SHIFT. y < x) = (y < t)"
-    using posreal_complete [of ?SHIFT] unfolding bdd_above_def by blast
-
-  show ?thesis
-  proof
-    show "(\<forall>s\<in>S. s \<le> (t + X + (-1))) \<and> (\<forall>y. (\<forall>s\<in>S. s \<le> y) \<longrightarrow> (t + X + (-1)) \<le> y)"
-    proof safe
-      fix x
-      assume "\<forall>s\<in>S. s \<le> x"
-      hence "\<forall>s\<in>?SHIFT. s \<le> x + (-X) + 1"
-        using S_Ub_is_SHIFT_Ub by simp
-      then have "\<not> x + (-X) + 1 < t"
-        by (subst t_is_Lub[rule_format, symmetric]) (simp add: not_less)
-      thus "t + X + -1 \<le> x" by arith
-    next
-      fix y
-      assume y_in_S: "y \<in> S"
-      obtain "u" where u_in_shift: "u \<in> ?SHIFT" using shifted_not_empty ..
-      hence "\<exists> x \<in> S. u = x + - X + 1" by simp
-      then obtain "x" where x_and_u: "u = x + - X + 1" ..
-      have u_le_t: "u \<le> t"
-      proof (rule dense_le)
-        fix x assume "x < u" then have "x < t"
-          using u_in_shift t_is_Lub by auto
-        then show "x \<le> t"  by simp
-      qed
-
-      show "y \<le> t + X + -1"
-      proof cases
-        assume "y \<le> x"
-        moreover have "x = u + X + - 1" using x_and_u by arith
-        moreover have "u + X + - 1  \<le> t + X + -1" using u_le_t by arith
-        ultimately show "y  \<le> t + X + -1" by arith
-      next
-        assume "~(y \<le> x)"
-        hence x_less_y: "x < y" by arith
-
-        have "x + (-X) + 1 \<in> ?SHIFT" using x_and_u and u_in_shift by simp
-        hence "0 < x + (-X) + 1" by simp
-        hence "0 < y + (-X) + 1" using x_less_y by arith
-        hence *: "y + (-X) + 1 \<in> ?SHIFT" using y_in_S by simp
-        have "y + (-X) + 1 \<le> t"
-        proof (rule dense_le)
-          fix x assume "x < y + (-X) + 1" then have "x < t"
-            using * t_is_Lub by auto
-          then show "x \<le> t"  by simp
-        qed
-        thus ?thesis by simp
-      qed
-    qed
-  qed
-qed
-
-subsection \<open>The Archimedean Property of the Reals\<close>
-
-theorem reals_Archimedean:
-  fixes x :: real
-  assumes x_pos: "0 < x"
-  shows "\<exists>n. inverse (of_nat (Suc n)) < x"
-proof (rule ccontr)
-  assume contr: "\<not> ?thesis"
-  have "\<forall>n. x * of_nat (Suc n) \<le> 1"
-  proof
-    fix n
-    from contr have "x \<le> inverse (of_nat (Suc n))"
-      by (simp add: linorder_not_less)
-    hence "x \<le> (1 / (of_nat (Suc n)))"
-      by (simp add: inverse_eq_divide)
-    moreover have "(0::real) \<le> of_nat (Suc n)"
-      by (rule of_nat_0_le_iff)
-    ultimately have "x * of_nat (Suc n) \<le> (1 / of_nat (Suc n)) * of_nat (Suc n)"
-      by (rule mult_right_mono)
-    thus "x * of_nat (Suc n) \<le> 1" by (simp del: of_nat_Suc)
-  qed
-  hence 2: "bdd_above {z. \<exists>n. z = x * (of_nat (Suc n))}"
-    by (auto intro!: bdd_aboveI[of _ 1])
-  have 1: "\<exists>X. X \<in> {z. \<exists>n. z = x* (of_nat (Suc n))}" by auto
-  obtain t where
-    upper: "\<And>z. z \<in> {z. \<exists>n. z = x * of_nat (Suc n)} \<Longrightarrow> z \<le> t" and
-    least: "\<And>y. (\<And>a. a \<in> {z. \<exists>n. z = x * of_nat (Suc n)} \<Longrightarrow> a \<le> y) \<Longrightarrow> t \<le> y"
-    using reals_complete[OF 1 2] by auto
-
-  have "t \<le> t + - x"
-  proof (rule least)
-    fix a assume a: "a \<in> {z. \<exists>n. z = x * (of_nat (Suc n))}"
-    have "\<forall>n::nat. x * of_nat n \<le> t + - x"
-    proof
-      fix n
-      have "x * of_nat (Suc n) \<le> t"
-        by (simp add: upper)
-      hence  "x * (of_nat n) + x \<le> t"
-        by (simp add: distrib_left)
-      thus  "x * (of_nat n) \<le> t + - x" by arith
-    qed    hence "\<forall>m. x * of_nat (Suc m) \<le> t + - x" by (simp del: of_nat_Suc)
-    with a show "a \<le> t + - x"
-      by auto
-  qed
-  thus False using x_pos by arith
-qed
-
-text \<open>
-  There must be other proofs, e.g. \<open>Suc\<close> of the largest
-  integer in the cut representing \<open>x\<close>.
-\<close>
-
-lemma reals_Archimedean2: "\<exists>n. (x::real) < of_nat (n::nat)"
-proof cases
-  assume "x \<le> 0"
-  hence "x < of_nat (1::nat)" by simp
-  thus ?thesis ..
-next
-  assume "\<not> x \<le> 0"
-  hence x_greater_zero: "0 < x" by simp
-  hence "0 < inverse x" by simp
-  then obtain n where "inverse (of_nat (Suc n)) < inverse x"
-    using reals_Archimedean by blast
-  hence "inverse (of_nat (Suc n)) * x < inverse x * x"
-    using x_greater_zero by (rule mult_strict_right_mono)
-  hence "inverse (of_nat (Suc n)) * x < 1"
-    using x_greater_zero by simp
-  hence "of_nat (Suc n) * (inverse (of_nat (Suc n)) * x) < of_nat (Suc n) * 1"
-    by (rule mult_strict_left_mono) (simp del: of_nat_Suc)
-  hence "x < of_nat (Suc n)"
-    by (simp add: algebra_simps del: of_nat_Suc)
-  thus "\<exists>(n::nat). x < of_nat n" ..
-qed
-
-instance real :: archimedean_field
-proof
-  fix r :: real
-  obtain n :: nat where "r < of_nat n"
-    using reals_Archimedean2 ..
-  then have "r \<le> of_int (int n)"
-    by simp
-  then show "\<exists>z. r \<le> of_int z" ..
-qed
-
-end