diff --git a/thys/Deep_Learning/Lebesgue_Functional.thy b/thys/Deep_Learning/Lebesgue_Functional.thy
--- a/thys/Deep_Learning/Lebesgue_Functional.thy
+++ b/thys/Deep_Learning/Lebesgue_Functional.thy
@@ -1,95 +1,95 @@
 (* Author: Alexander Bentkamp, Universität des Saarlandes
 *)
 section \<open>Alternative Lebesgue Measure Definition\<close>
 
 theory Lebesgue_Functional
 imports "HOL-Analysis.Lebesgue_Measure"
 begin
 
 text \<open>Lebesgue\_Measure.lborel is defined on the typeclass euclidean\_space, which does not allow the
 space dimension to be dependent on a variable. As the Lebesgue measure of higher dimensions is the
 product measure of the one dimensional Lebesgue measure, we can easily define a more flexible version
 of the Lebesgue measure as follows. This version of the Lebesgue measure measures sets of functions
 from nat to real whose values are undefined for arguments higher than n. These "Extensional Function Spaces"
  are defined in HOL/FuncSet. \<close>
 
 definition lborel_f :: "nat \<Rightarrow> (nat \<Rightarrow> real) measure" where
   "lborel_f n = (\<Pi>\<^sub>M b\<in>{..<n}. lborel)"
 
 lemma product_sigma_finite_interval: "product_sigma_finite (\<lambda>b. interval_measure (\<lambda>x. x))"
   unfolding product_sigma_finite_def using  sigma_finite_interval_measure by auto
 
 lemma l_borel_f_1: "distr (lborel_f 1) lborel (\<lambda>x. x 0) = lborel"
   unfolding lborel_f_def
   using product_sigma_finite.distr_singleton[OF product_sigma_finite_interval, of 0]
     lborel_eq_real lessThan_Suc by auto
 
 lemma space_lborel_f: "space (lborel_f n) = Pi\<^sub>E {..<n} (\<lambda>_. UNIV)" unfolding lborel_f_def
   unfolding space_PiM space_lborel space_borel by metis
 
 lemma space_lborel_f_subset: "space (lborel_f n) \<subseteq> space (lborel_f (Suc n))"
 unfolding space_lborel_f by (rule subsetI, rule PiE_I, blast,
   metis PiE_E  Suc_n_not_le_n le_cases lessThan_subset_iff subsetCE)
 
 lemma space_lborel_add_dim:
 assumes "f \<in> space (lborel_f n)"
 shows "f(n:=x) \<in> space (lborel_f (Suc n))"
 unfolding space_lborel_f
 using assms lessThan_Suc space_lborel_f by auto
 
 lemma integral_lborel_f:
 assumes "f \<in> borel_measurable (lborel_f (Suc n))"
 shows "integral\<^sup>N (lborel_f (Suc n)) f = \<integral>\<^sup>+ y. \<integral>\<^sup>+ x. f (x(n := y)) \<partial>lborel_f n \<partial>lborel"
   unfolding lborel_f_def
   using product_sigma_finite.product_nn_integral_insert_rev[OF product_sigma_finite_interval, of "{..<n}", OF finite_lessThan _]
   assms[unfolded lborel_f_def] lborel_eq_real by (simp add: lessThan_Suc)
 
 lemma emeasure_lborel_f_Suc:
 assumes "A \<in> sets (lborel_f (Suc n))"
 assumes "\<And>y. {x\<in>space (lborel_f n). x(n := y) \<in> A} \<in> sets (lborel_f n)"
 shows "emeasure (lborel_f (Suc n)) A = \<integral>\<^sup>+ y. emeasure (lborel_f n) {x\<in>space (lborel_f n). x(n := y) \<in> A} \<partial>lborel"
 proof -
   {
     fix x y assume "x\<in>space (lborel_f n)"
-    then have "(indicator A) (x(n := y)) = (indicator {x\<in>space (lborel_f n). x(n := y) \<in> A}) x" using indicator_def
-      by (metis (no_types, lifting) mem_Collect_eq)
+    then have "(indicator A) (x(n := y)) = (indicator {x\<in>space (lborel_f n). x(n := y) \<in> A}) x"
+      by (simp add: indicator_def)
   }
   then show ?thesis
     unfolding nn_integral_indicator[OF assms(1), symmetric] nn_integral_indicator[OF assms(2), symmetric]
      integral_lborel_f[OF borel_measurable_indicator, OF assms(1)]
     using nn_integral_cong by (metis (no_types, lifting))
 qed
 
 lemma lborel_f_measurable_add_dim: "(\<lambda>f. f(n := x)) \<in> measurable (lborel_f n) (lborel_f (Suc n))"
 proof -
   have "x \<in> space lborel" by simp
   have 0:"(\<lambda>(f, y). f(n := y)) \<circ> (\<lambda>xa. (xa, x)) = (\<lambda>f. f(n := x))" unfolding comp_def  using case_prod_conv by fast
   show ?thesis unfolding lborel_f_def
     using measurable_comp[OF measurable_Pair2'[of x lborel "Pi\<^sub>M {..<n} (\<lambda>b. lborel)", OF \<open>x \<in> space lborel\<close>]
     measurable_add_dim[of n "{..<n}" "\<lambda>b. lborel"], unfolded 0] lessThan_Suc by auto
 qed
 
 lemma sets_lborel_f_sub_dim:
 assumes "A \<in> sets (lborel_f (Suc n))"
 shows "{x. x(n := y) \<in> A} \<inter> space (lborel_f n) \<in> sets (lborel_f n)"
 proof -
   have "(\<lambda>f. f(n := y)) -` A \<inter> space (lborel_f n) \<in> sets (lborel_f n)"
     using measurable_sets[OF lborel_f_measurable_add_dim assms] by auto
   moreover have "(\<lambda>f. f(n := y)) -` A = {x. x(n := y) \<in> A}" by auto
   finally show ?thesis by metis
 qed
 
 lemma lborel_f_measurable_restrict:
 assumes "m \<le> n"
 shows "(\<lambda>f. restrict f {..<m}) \<in> measurable (lborel_f n) (lborel_f m)"
 using measurable_restrict_subset lborel_f_def assms by auto
 
 lemma lborel_measurable_sub_dim: "(\<lambda>f. restrict f {..<n}) \<in> measurable (lborel_f (Suc n)) (lborel_f n)"
 using lborel_f_measurable_restrict[of "n" "Suc n"] by linarith
 
 lemma measurable_lborel_component [measurable]:
 assumes "k<n"
 shows "(\<lambda>x. x k) \<in> borel_measurable (lborel_f n)"
   unfolding lborel_f_def using assms measurable_PiM_component_rev by simp_all
 
 end
diff --git a/thys/Ergodic_Theory/Recurrence.thy b/thys/Ergodic_Theory/Recurrence.thy
--- a/thys/Ergodic_Theory/Recurrence.thy
+++ b/thys/Ergodic_Theory/Recurrence.thy
@@ -1,2293 +1,2293 @@
 (*  Author:  Sébastien Gouëzel   sebastien.gouezel@univ-rennes1.fr
     License: BSD
 *)
 
 section \<open>Conservativity, recurrence\<close>
 
 theory Recurrence
   imports Measure_Preserving_Transformations
 begin
 
 text \<open>A dynamical system is conservative if almost every point comes back close to its starting point.
 This is always the case if the measure is finite, not when it is infinite (think of the translation
 on $\mathbb{Z}$). In conservative systems, an important construction is the induced map: the first return
 map to a set of finite measure. It is measure-preserving and conservative if the original system is.
 This makes it possible to reduce statements about general conservative systems in infinite measure
 to statements about systems in finite measure, and as such is extremely useful.\<close>
 
 subsection \<open>Definition of conservativity\<close>
 
 locale conservative = qmpt +
   assumes conservative: "\<And>A. A \<in> sets M \<Longrightarrow> emeasure M A > 0 \<Longrightarrow> \<exists>n>0. emeasure M ((T^^n)-`A \<inter> A) >0"
 
 lemma conservativeI:
   assumes "qmpt M T"
     "\<And>A. A \<in> sets M \<Longrightarrow> emeasure M A > 0 \<Longrightarrow> \<exists>n>0. emeasure M ((T^^n)-`A \<inter> A) >0"
   shows "conservative M T"
 unfolding conservative_def conservative_axioms_def using assms by auto
 
 text \<open>To prove conservativity, it is in fact sufficient to show that the preimages of a set
 of positive measure intersect it, without any measure control. Indeed, in a non-conservative
 system, one can construct a set which does not satisfy this property.\<close>
 
 lemma conservativeI2:
   assumes "qmpt M T"
     "\<And>A. A \<in> sets M \<Longrightarrow> emeasure M A > 0 \<Longrightarrow> \<exists>n>0. (T^^n)-`A \<inter> A \<noteq> {}"
   shows "conservative M T"
 unfolding conservative_def conservative_axioms_def
 proof (auto simp add: assms)
   interpret qmpt M T using assms by auto
   fix A
   assume A_meas [measurable]: "A \<in> sets M" and "emeasure M A > 0"
   show "\<exists>n>0. 0 < emeasure M ((T ^^ n) -` A \<inter> A)"
   proof (rule ccontr)
     assume "\<not> (\<exists>n>0. 0 < emeasure M ((T ^^ n) -` A \<inter> A))"
     then have meas_0: "emeasure M ((T ^^ n) -` A \<inter> A) = 0" if "n>0" for n
       by (metis zero_less_iff_neq_zero that)
     define C where "C = (\<Union>n. (T^^(Suc n))-`A \<inter> A)"
     have C_meas [measurable]: "C \<in> sets M" unfolding C_def by measurable
     have "emeasure M C = 0" unfolding C_def
       by (intro emeasure_UN_eq_0[of M, of "\<lambda>n. (T^^(Suc n))-`A \<inter> A", OF meas_0], auto)
 
     define A2 where "A2 = A-C"
     then have A2_meas [measurable]: "A2 \<in> sets M" by simp
     have "\<not>(\<exists>n>0. (T^^n)-`A2 \<inter> A2 \<noteq> {})"
     proof (rule ccontr, simp)
       assume "\<exists>n>0. (T^^n)-`A2 \<inter> A2 \<noteq> {}"
       then obtain n where n: "n > 0" "(T^^n)-`A2 \<inter> A2 \<noteq> {}" by auto
       define m where "m = n-1"
       have "(T^^(m+1))-`A2 \<inter> A2 \<noteq> {}" unfolding m_def using n by auto
       then show False using C_def A2_def by auto
     qed
     then have "emeasure M A2 = 0" using assms(2)[OF A2_meas] by (meson zero_less_iff_neq_zero)
     then have "emeasure M (C \<union> A2) = 0" using \<open>emeasure M C = 0\<close> by (simp add: emeasure_Un_null_set null_setsI)
     moreover have "A \<subseteq> C \<union> A2" unfolding A2_def by auto
     ultimately have "emeasure M A = 0" by (meson A2_meas C_meas emeasure_eq_0 sets.Un)
     then show False using \<open>emeasure M A > 0\<close> by auto
   qed
 qed
 
 text \<open>There is also a dual formulation, saying that conservativity follows from the fact
 that a set disjoint from all its preimages has to be null.\<close>
 
 lemma conservativeI3:
   assumes "qmpt M T"
           "\<And>A. A \<in> sets M \<Longrightarrow> (\<forall>n>0. (T^^n)-`A \<inter> A = {}) \<Longrightarrow> A \<in> null_sets M"
   shows "conservative M T"
 proof (rule conservativeI2[OF assms(1)])
   fix A assume "A \<in> sets M" "0 < emeasure M A"
   then have "\<not>(A \<in> null_sets M)" unfolding null_sets_def by auto
   then show "\<exists>n>0. (T ^^ n) -` A \<inter> A \<noteq> {}"
     using assms(2)[OF \<open>A \<in> sets M\<close>] by auto
 qed
 
 text \<open>The inverse of a conservative map is still conservative\<close>
 
 lemma (in conservative) conservative_Tinv:
   assumes "invertible_qmpt"
   shows "conservative M Tinv"
 proof (rule conservativeI2)
   show "qmpt M Tinv" using Tinv_qmpt[OF assms].
   have "bij T" using assms unfolding invertible_qmpt_def by auto
   fix A assume [measurable]: "A \<in> sets M" and "emeasure M A > 0"
   then obtain n where *: "n>0" "emeasure M ((T^^n)-`A \<inter> A) > 0"
     using conservative[OF \<open>A \<in> sets M\<close> \<open>emeasure M A > 0\<close>] by blast
   have "bij (T^^n)" using bij_fn[OF \<open>bij T\<close>] by auto
   then have "bij(inv (T^^n))" using bij_imp_bij_inv by auto
   then have "bij (Tinv^^n)" unfolding Tinv_def using inv_fn[OF \<open>bij T\<close>, of n] by auto
 
   have "(T^^n)-`A \<inter> A \<noteq> {}" using * by auto
   then have "(Tinv^^n)-`((T^^n)-`A \<inter> A) \<noteq> {}"
     using surj_vimage_empty[OF bij_is_surj[OF \<open>bij (Tinv^^n)\<close>]] by meson
   then have **: "(Tinv^^n)-`((T^^n)-`A) \<inter> (Tinv^^n)-` A \<noteq> {}"
     by auto
 
   have "(Tinv^^n)-`((T^^n)-`A) = ((T^^n) o (Tinv^^n))-`A"
     by auto
   moreover have "(T^^n) o (Tinv^^n) = (\<lambda>x. x)"
     unfolding Tinv_def using \<open>bij T\<close> fn_o_inv_fn_is_id by blast
   ultimately have "(Tinv^^n)-`((T^^n)-`A) = A" by auto
   then have "(Tinv^^n)-` A \<inter> A \<noteq> {}" using ** by auto
   then show "\<exists>n>0. (Tinv ^^ n) -` A \<inter> A \<noteq> {}" using \<open>n>0\<close> by auto
 qed
 
 text \<open>We introduce the locale of a conservative measure preserving map.\<close>
 
 locale conservative_mpt = mpt + conservative
 
 lemma conservative_mptI:
   assumes "mpt M T"
     "\<And>A. A \<in> sets M \<Longrightarrow> emeasure M A > 0 \<Longrightarrow> \<exists>n>0. (T^^n)-`A \<inter> A \<noteq> {}"
   shows "conservative_mpt M T"
 unfolding conservative_mpt_def
 apply (auto simp add: assms(1), rule conservativeI2)
 using assms(1) by (auto simp add: mpt_def assms(2))
 
 text \<open>The fact that finite measure preserving transformations are conservative, albeit easy,
 is extremely important. This result is known as Poincaré recurrence theorem.\<close>
 
 sublocale fmpt \<subseteq> conservative_mpt
 proof (rule conservative_mptI)
   show "mpt M T" by (simp add: mpt_axioms)
   fix A assume A_meas [measurable]: "A \<in> sets M" and "emeasure M A > 0"
   show "\<exists>n>0. (T^^n)-`A \<inter> A \<noteq> {}"
   proof (rule ccontr)
     assume "\<not>(\<exists>n>0. (T^^n)-`A \<inter> A \<noteq> {})"
     then have disj: "(T^^(Suc n))--`A \<inter> A = {}" for n unfolding vimage_restr_def using zero_less_one by blast
 
     define B where "B = (\<lambda> n. (T^^n)--`A)"
     then have B_meas [measurable]: "B n \<in> sets M" for n by simp
     have same: "measure M (B n) = measure M A" for n
       by (simp add: B_def A_meas T_vrestr_same_measure(2))
 
     have "B n \<inter> B m = {}" if "n > m" for m n
     proof -
       have "B n \<inter> B m = (T^^m)--` (B (n-m) \<inter> A)"
         using B_def \<open>m < n\<close> A_meas vrestr_intersec T_vrestr_composed(1) by auto
       moreover have "B (n-m) \<inter> A = {}" unfolding B_def
         by (metis disj \<open>m < n\<close> Suc_diff_Suc)
       ultimately show ?thesis by simp
     qed
     then have "disjoint_family B" by (metis disjoint_family_on_def inf_sup_aci(1) less_linear)
 
     have "measure M A < e" if "e>0" for e::real
     proof -
       obtain N::nat where "N>0" "(measure M (space M))/e<N" using \<open>0 < e\<close>
         by (metis divide_less_0_iff reals_Archimedean2 less_eq_real_def measure_nonneg not_gr0 not_le of_nat_0)
       then have "(measure M (space M))/N < e" using \<open>0 < e\<close> \<open>N>0\<close>
         by (metis bounded_measure div_0 le_less_trans measure_empty mult.commute pos_divide_less_eq)
       have *: "disjoint_family_on B {..<N}"
         by (meson UNIV_I \<open>disjoint_family B\<close> disjoint_family_on_mono subsetI)
       then have "(\<Sum>i\<in>{..<N}. measure M (B i)) \<le> measure M (space M)"
         by (metis bounded_measure \<open>\<And>n. B n \<in> sets M\<close>
             image_subset_iff finite_lessThan finite_measure_finite_Union)
       also have "(\<Sum>i\<in>{..<N}. measure M (B i)) = (\<Sum>i\<in>{..<N}. measure M A)" using same by simp
       also have "... = N * (measure M A)" by simp
       finally have "N * (measure M A) \<le> measure M (space M)" by simp
       then have "measure M A \<le> (measure M (space M))/N" using \<open>N>0\<close> by (simp add: mult.commute mult_imp_le_div_pos)
       then show "measure M A < e" using \<open>(measure M (space M))/N<e\<close> by simp
     qed
     then have "measure M A \<le> 0" using not_less by blast
     then have "measure M A = 0" by (simp add: measure_le_0_iff)
     then have "emeasure M A = 0" using emeasure_eq_measure by simp
     then show False using \<open>emeasure M A > 0\<close> by simp
   qed
 qed
 
 text \<open>The following fact that powers of conservative maps are also conservative is true,
 but nontrivial. It is proved as follows: consider a set $A$ with positive measure,
 take a time $n_1$ such that $A_1 = T^{-n_1} A \cap A$ has positive measure, then a time
 $n_2$ such that $A_2 = T^{-n_2} A_1 \cap A$ has positive measure, and so on. It follows
 that $T^{-(n_i+n_{i+1}+\dots+n_j)}A \cap A$ has positive measure for all $i<j$. Then, one
 can find $i<j$ such that $n_i+\dots+n_j$ is a multiple of $N$.\<close>
 
 proposition (in conservative) conservative_power:
   "conservative M (T^^n)"
 proof (unfold_locales)
   show "T ^^ n \<in> quasi_measure_preserving M M"
     by (auto simp add: Tn_quasi_measure_preserving)
 
   fix A assume [measurable]: "A \<in> sets M" "0 < emeasure M A"
   define good_time where "good_time = (\<lambda>K. Inf{(i::nat). i > 0 \<and> emeasure M ((T^^i)-`K \<inter> A) > 0})"
   define next_good_set where "next_good_set = (\<lambda>K. (T^^(good_time K))-`K \<inter> A)"
 
   have good_rec: "((good_time K > 0) \<and> (next_good_set K \<subseteq> A) \<and>
           (next_good_set K \<in> sets M) \<and> (emeasure M (next_good_set K) > 0))"
         if [measurable]: "K \<in> sets M" and "K \<subseteq> A" "emeasure M K > 0" for K
   proof -
     have a: "next_good_set K \<in> sets M" "next_good_set K \<subseteq> A"
       using next_good_set_def by simp_all
     obtain k where "k > 0" and posK: "emeasure M ((T^^k)-`K \<inter> K) > 0"
       using conservative[OF \<open>K \<in> sets M\<close>, OF \<open>emeasure M K > 0\<close>] by auto
     have *:"(T^^k)-`K \<inter> K \<subseteq> (T^^k)-`K \<inter> A" using \<open>K \<subseteq> A\<close> by auto
     have posKA: "emeasure M ((T^^k)-`K \<inter> A) > 0" using emeasure_mono[OF *, of M] posK by simp
     let ?S = "{(i::nat). i>0 \<and> emeasure M ((T^^i)-`K \<inter> A) > 0}"
     have "k \<in> ?S" using \<open>k>0\<close> posKA by simp
     then have "?S \<noteq> {}" by auto
     then have "Inf ?S \<in> ?S" using Inf_nat_def1[of ?S] by simp
     then have "good_time K \<in> ?S" using good_time_def by simp
     then show "(good_time K > 0) \<and> (next_good_set K \<subseteq> A) \<and>
           (next_good_set K \<in> sets M) \<and> (emeasure M (next_good_set K) > 0)"
       using a next_good_set_def by auto
   qed
 
   define B where "B = (\<lambda>i. (next_good_set^^i) A)"
   define t where "t = (\<lambda>i. good_time (B i))"
   have good_B: "(B i \<subseteq> A) \<and> (B i \<in> sets M) \<and> (emeasure M (B i) > 0)" for i
   proof (induction i)
     case 0
     have "B 0 = A" using B_def by simp
     then show ?case using \<open>B 0 = A\<close> \<open>A \<in> sets M\<close> \<open>emeasure M A > 0\<close> by simp
   next
     case (Suc i)
     moreover have "B (i+1) = next_good_set (B i)" using B_def by simp
     ultimately show ?case using good_rec[of "B i"] by auto
   qed
   have t_pos: "\<And>i. t i > 0" using t_def by (simp add: good_B good_rec)
 
   define s where "s = (\<lambda>i k. (\<Sum>n \<in> {i..<i+k}. t n))"
   have "B (i+k) \<subseteq> (T^^(s i k))-`A \<inter> A" for i k
   proof (induction k)
     case 0
     show ?case using s_def good_B[of i] by simp
   next
     case (Suc k)
     have "B(i+k+1) = (T^^(t (i+k)))-`(B (i+k)) \<inter> A" using t_def B_def next_good_set_def by simp
     moreover have "B(i+k) \<subseteq> (T^^(s i k))-`A" using Suc.IH by simp
     ultimately have "B(i+k+1) \<subseteq> (T^^(t (i+k)))-` (T^^(s i k))-`A \<inter> A" by auto
     then have "B(i+k+1) \<subseteq> (T^^(t(i+k) + s i k))-`A \<inter> A" by (simp add: add.commute funpow_add vimage_comp)
     moreover have "t(i+k) + s i k = s i (k+1)" using s_def by simp
     ultimately show ?case by simp
   qed
   moreover have "(T^^j)-`A \<inter> A \<in> sets M" for j by simp
   ultimately have *: "emeasure M ((T^^(s i k))-`A \<inter> A) > 0" for i k
     by (metis inf.orderE inf.strict_boundedE good_B emeasure_mono)
 
   show "\<exists>k>0. 0 < emeasure M (((T ^^ n) ^^ k) -` A \<inter> A)"
   proof (cases)
     assume "n = 0"
     then have "((T ^^ n) ^^ 1) -` A = A" by simp
     then show ?thesis using \<open>emeasure M A > 0\<close> by auto
   next
     assume "\<not>(n = 0)"
     then have "n > 0" by simp
     define u where "u = (\<lambda>i. s 0 i mod n)"
     have "range u \<subseteq> {..<n}" by (simp add: \<open>0 < n\<close> image_subset_iff u_def)
     then have "finite (range u)" using finite_nat_iff_bounded by auto
     then have "\<exists>i j. (i<j) \<and> (u i = u j)" by (metis finite_imageD infinite_UNIV_nat injI less_linear)
     then obtain i k where "k>0" "u i = u (i+k)" using less_imp_add_positive by blast
     moreover have "s 0 (i+k) = s 0 i + s i k" unfolding s_def by (simp add: sum.atLeastLessThan_concat)
     ultimately have "(s i k) mod n = 0" using u_def nat_mod_cong by metis
     then obtain r where "s i k = n * r" by auto
     moreover have "s i k > 0" unfolding s_def
       using \<open>k > 0\<close> t_pos sum_strict_mono[of "{i..<i+k}", of "\<lambda>x. 0", of "\<lambda>x. t x"] by simp
     ultimately have "r > 0" by simp
     moreover have "emeasure M ((T^^(n * r))-`A \<inter> A) > 0" using * \<open>s i k = n * r\<close> by metis
     ultimately show ?thesis by (metis funpow_mult)
   qed
 qed
 
 proposition (in conservative_mpt) conservative_mpt_power:
   "conservative_mpt M (T^^n)"
 using conservative_power mpt_power unfolding conservative_mpt_def by auto
 
 text \<open>The standard way to use conservativity is as follows: if a set is almost disjoint from
 all its preimages, then it is null:\<close>
 
 lemma (in conservative) ae_disjoint_then_null:
   assumes "A \<in> sets M"
           "\<And>n. n > 0 \<Longrightarrow> A \<inter> (T^^n)-`A \<in> null_sets M"
   shows "A \<in> null_sets M"
 by (metis Int_commute assms(1) assms(2) conservative zero_less_iff_neq_zero null_setsD1 null_setsI)
 
 lemma (in conservative) disjoint_then_null:
   assumes "A \<in> sets M"
           "\<And>n. n > 0 \<Longrightarrow> A \<inter> (T^^n)-`A = {}"
   shows "A \<in> null_sets M"
 by (rule ae_disjoint_then_null, auto simp add: assms)
 
 text \<open>Conservativity is preserved by replacing the measure by an equivalent one.\<close>
 
 lemma (in conservative) conservative_density:
   assumes [measurable]: "h \<in> borel_measurable M"
       and "AE x in M. h x \<noteq> 0" "AE x in M. h x \<noteq> \<infinity>"
   shows "conservative (density M h) T"
 proof -
   interpret A: qmpt "density M h" T
     by (rule qmpt_density[OF assms])
   show ?thesis
     apply (rule conservativeI3) apply (simp add: A.qmpt_axioms)
     unfolding sets_density null_sets_density[OF assms(1) assms(2)]
     by (metis conservative emeasure_empty not_gr_zero null_setsI)
 qed
 
 context qmpt begin
 
 text \<open>We introduce the recurrent subset of $A$, i.e., the set of points of $A$ that return to
 $A$, and the infinitely recurrent subset, i.e., the set of points of $A$ that return
 infinitely often to $A$. In conservative systems, both coincide with $A$ almost everywhere.\<close>
 
 definition recurrent_subset::"'a set \<Rightarrow> 'a set"
   where "recurrent_subset A = (\<Union>n \<in> {1..}. A \<inter> (T^^n)-`A)"
 
 definition recurrent_subset_infty::"'a set \<Rightarrow> 'a set"
   where "recurrent_subset_infty A = A - (\<Union>n. (T^^n)-` (A - recurrent_subset A))"
 
 lemma recurrent_subset_infty_inf_returns:
   "x \<in> recurrent_subset_infty A \<longleftrightarrow> (x \<in> A \<and> infinite {n. (T^^n) x \<in> A})"
 proof
   assume *: "x \<in> recurrent_subset_infty A"
   have "infinite {n. (T^^n) x \<in> A}"
   proof (rule ccontr)
     assume "\<not>(infinite {n. (T^^n) x \<in> A})"
     then have F: "finite {n. (T^^n) x \<in> A}" by auto
     have "0 \<in> {n. (T^^n) x \<in> A}" using * recurrent_subset_infty_def by auto
     then have NE: "{n. (T^^n) x \<in> A} \<noteq> {}" by blast
     define N where "N = Max {n. (T^^n) x \<in> A}"
     have "N \<in> {n. (T^^n) x \<in> A}" unfolding N_def using F NE using Max_in by auto
     then have "(T^^N) x \<in> A" by auto
     moreover have "x \<notin> (T^^N)-` (A - recurrent_subset A)" using * unfolding recurrent_subset_infty_def by auto
     ultimately have "(T^^N) x \<in> recurrent_subset A" by auto
     then have "(T ^^ N) x \<in> A \<and> (\<exists>n. n \<in> {1..} \<and> (T ^^ n) ((T ^^ N) x) \<in> A)"
       unfolding recurrent_subset_def by blast
     then obtain n where "n>0" "(T^^n) ((T^^N) x) \<in> A"
       by (metis atLeast_iff gr0I not_one_le_zero)
     then have "n+N \<in> {n. (T^^n) x \<in> A}" by (simp add: funpow_add)
     then show False unfolding N_def using \<open>n>0\<close> F NE
       by (metis Max_ge Nat.add_0_right add.commute nat_add_left_cancel_less not_le)
   qed
   then show "x \<in> A \<and> infinite {n. (T^^n) x \<in> A}" using * recurrent_subset_infty_def by auto
 next
   assume *: "(x \<in> A \<and> infinite {n. (T ^^ n) x \<in> A})"
   {
     fix n
     obtain N where "N>n" "(T^^N) x \<in> A" using *
       using infinite_nat_iff_unbounded by force
     define k where "k = N-n"
     then have "k>0" "N = n+k" using \<open>N>n\<close> by auto
     then have "(T^^k) ((T^^n) x) \<in> A"
       by (metis \<open>(T ^^ N) x \<in> A\<close> \<open>N = n + k\<close> add.commute comp_def funpow_add)
     then have "(T^^ n) x \<notin> A - recurrent_subset A"
       unfolding recurrent_subset_def using \<open>k>0\<close> by auto
   }
   then show "x \<in> recurrent_subset_infty A" unfolding recurrent_subset_infty_def using * by auto
 qed
 
 lemma recurrent_subset_infty_series_infinite:
   assumes "x \<in> recurrent_subset_infty A"
   shows "(\<Sum>n. indicator A ((T^^n) x)) = (\<infinity>::ennreal)"
 proof (rule ennreal_ge_nat_imp_PInf)
   have *: "\<not> finite {n. (T^^n) x \<in> A}" using recurrent_subset_infty_inf_returns assms by auto
   fix N::nat
   obtain F where F: "finite F" "F \<subseteq> {n. (T^^n) x \<in> A}" "card F = N"
     using infinite_arbitrarily_large[OF *] by blast
   have "N = (\<Sum>n \<in> F. 1::ennreal)"
     using F(3) by auto
   also have "... = (\<Sum>n \<in> F. (indicator A ((T^^n) x))::ennreal)"
     apply (rule sum.cong) using F(2) indicator_def by auto
   also have "... \<le> (\<Sum>n. indicator A ((T^^n) x))"
     by (rule sum_le_suminf, auto simp add: F)
   finally show "N \<le> (\<Sum>n. (indicator A ((T^^n) x))::ennreal)" by auto
 qed
 
 lemma recurrent_subset_infty_def':
   "recurrent_subset_infty A = (\<Inter>m. (\<Union>n\<in>{m..}. A \<inter> (T^^n)-`A))"
 proof (auto)
   fix x assume x: "x \<in> recurrent_subset_infty A"
   then show "x \<in> A" unfolding recurrent_subset_infty_def by auto
   fix N::nat
   show "\<exists>n\<in>{N..}. (T^^n) x \<in> A" using recurrent_subset_infty_inf_returns x
     using infinite_nat_iff_unbounded_le by auto
 next
   fix x assume "x \<in> A" "\<forall>N. \<exists>n\<in>{N..}. (T^^n) x \<in> A"
   then show "x \<in> recurrent_subset_infty A"
     unfolding recurrent_subset_infty_inf_returns using infinite_nat_iff_unbounded_le by auto
 qed
 
 lemma recurrent_subset_incl:
   "recurrent_subset A \<subseteq> A"
   "recurrent_subset_infty A \<subseteq> A"
   "recurrent_subset_infty A \<subseteq> recurrent_subset A"
 unfolding recurrent_subset_def recurrent_subset_infty_def' by (simp, simp, fast)
 
 lemma recurrent_subset_meas [measurable]:
   assumes [measurable]: "A \<in> sets M"
   shows "recurrent_subset A \<in> sets M"
         "recurrent_subset_infty A \<in> sets M"
 unfolding recurrent_subset_def recurrent_subset_infty_def' by measurable
 
 lemma recurrent_subset_rel_incl:
   assumes "A \<subseteq> B"
   shows "recurrent_subset A \<subseteq> recurrent_subset B"
         "recurrent_subset_infty A \<subseteq> recurrent_subset_infty B"
 proof -
   show "recurrent_subset A \<subseteq> recurrent_subset B"
     unfolding recurrent_subset_def using assms by auto
   show "recurrent_subset_infty A \<subseteq> recurrent_subset_infty B"
     apply (auto, subst recurrent_subset_infty_inf_returns)
     using assms recurrent_subset_incl(2) infinite_nat_iff_unbounded_le recurrent_subset_infty_inf_returns by fastforce
 qed
 
 text \<open>If a point belongs to the infinitely recurrent subset of $A$, then when they return to $A$
 its iterates also belong to the infinitely recurrent subset.\<close>
 
 lemma recurrent_subset_infty_returns:
   assumes "x \<in> recurrent_subset_infty A" "(T^^n) x \<in> A"
   shows "(T^^n) x \<in> recurrent_subset_infty A"
 proof (subst recurrent_subset_infty_inf_returns, rule ccontr)
   assume "\<not> ((T ^^ n) x \<in> A \<and> infinite {k. (T ^^ k) ((T ^^ n) x) \<in> A})"
   then have 1: "finite {k. (T^^k) ((T^^n) x) \<in> A}" using assms(2) by auto
   have "0 \<in> {k. (T^^k) ((T^^n) x) \<in> A}" using assms(2) by auto
   then have 2: "{k. (T^^k) ((T^^n) x) \<in> A} \<noteq> {}" by blast
   define M where "M = Max {k. (T^^k) ((T^^n) x) \<in> A}"
   have M_prop: "\<And>k. k > M \<Longrightarrow> (T^^k) ((T^^n) x) \<notin> A"
     unfolding M_def using 1 2 by auto
   {
     fix N assume *: "(T^^N) x \<in> A"
     have "N \<le> n+M"
     proof (cases)
       assume "N \<le> n"
       then show ?thesis by auto
     next
       assume "\<not>(N \<le> n)"
       then have "N > n" by simp
       define k where "k = N-n"
       have "N = n + k" unfolding k_def using \<open>N > n\<close> by auto
       then have "(T^^k) ((T^^n)x) \<in> A" using * by (simp add: add.commute funpow_add)
       then have "k \<le> M" using M_prop using not_le by blast
       then show ?thesis unfolding k_def by auto
     qed
   }
   then have "finite {N. (T^^N) x \<in> A}"
     by (metis (no_types, lifting) infinite_nat_iff_unbounded mem_Collect_eq not_less)
   moreover have "infinite {N. (T^^N) x \<in> A}"
     using recurrent_subset_infty_inf_returns assms(1) by auto
   ultimately show False by auto
 qed
 
 lemma recurrent_subset_of_recurrent_subset:
   "recurrent_subset_infty(recurrent_subset_infty A) = recurrent_subset_infty A"
 proof
   show "recurrent_subset_infty (recurrent_subset_infty A) \<subseteq> recurrent_subset_infty A"
     using recurrent_subset_incl(2)[of A] recurrent_subset_rel_incl(2) by auto
   show "recurrent_subset_infty A \<subseteq> recurrent_subset_infty (recurrent_subset_infty A)"
     using recurrent_subset_infty_returns recurrent_subset_infty_inf_returns
     by (metis (no_types, lifting) Collect_cong subsetI)
 qed
 
 text \<open>The Poincare recurrence theorem states that almost every point of $A$ returns
 (infinitely often) to $A$, i.e., the recurrent and infinitely recurrent subsets of $A$
 coincide almost everywhere with $A$. This is essentially trivial in conservative systems,
 as it is a reformulation of the definition of conservativity. (What is not trivial, and has been
 proved above, is that it is true in finite measure preserving systems, i.e., finite measure
 preserving systems are automatically conservative.)\<close>
 
 theorem (in conservative) Poincare_recurrence_thm:
   assumes [measurable]: "A \<in> sets M"
   shows "A - recurrent_subset A \<in> null_sets M"
         "A - recurrent_subset_infty A \<in> null_sets M"
         "A \<Delta> recurrent_subset A \<in> null_sets M"
         "A \<Delta> recurrent_subset_infty A \<in> null_sets M"
         "emeasure M (recurrent_subset A) = emeasure M A"
         "emeasure M (recurrent_subset_infty A) = emeasure M A"
         "AE x \<in> A in M. x \<in> recurrent_subset_infty A"
 proof -
   define B where "B = {x \<in> A. \<forall> n\<in>{1..}. (T^^n) x \<in> (space M - A)}"
 
   have rs: "recurrent_subset A = A - B"
     by (auto simp add: B_def recurrent_subset_def)
        (meson Tn_meas assms measurable_space sets.sets_into_space subsetCE)
   then have *: "A - recurrent_subset A = B" using B_def by blast
   have "B \<in> null_sets M"
     by (rule disjoint_then_null, auto simp add: B_def)
   then show "A - recurrent_subset A \<in> null_sets M" using * by simp
 
   then have *: "(\<Union>n. (T^^n)--`(A-recurrent_subset A)) \<in> null_sets M"
     using T_quasi_preserves_null2(2) by blast
   have "recurrent_subset_infty A = recurrent_subset_infty A \<inter> space M" using sets.sets_into_space by auto
   also have "... = A \<inter> space M - (\<Union>n. (T^^n)-`(A-recurrent_subset A) \<inter> space M)" unfolding recurrent_subset_infty_def by blast
   also have "... = A - (\<Union>n. (T^^n)--`(A-recurrent_subset A))" unfolding vimage_restr_def using sets.sets_into_space by auto
   finally have **: "recurrent_subset_infty A = A - (\<Union>n. (T ^^ n) --` (A - recurrent_subset A))" .
   then have "A - recurrent_subset_infty A \<subseteq> (\<Union>n. (T^^n)--`(A-recurrent_subset A))" by auto
   with * ** show "A - recurrent_subset_infty A \<in> null_sets M"
     by (simp add: Diff_Diff_Int null_set_Int1)
 
   have "A \<Delta> recurrent_subset A = A - recurrent_subset A" using recurrent_subset_incl(1)[of A] by blast
   then show "A \<Delta> recurrent_subset A \<in> null_sets M" using \<open>A - recurrent_subset A \<in> null_sets M\<close> by auto
   then show "emeasure M (recurrent_subset A) = emeasure M A"
     by (rule Delta_null_same_emeasure[symmetric], auto)
 
   have "A \<Delta> recurrent_subset_infty A = A - recurrent_subset_infty A" using recurrent_subset_incl(2)[of A] by blast
   then show "A \<Delta> recurrent_subset_infty A \<in> null_sets M" using \<open>A - recurrent_subset_infty A \<in> null_sets M\<close> by auto
   then show "emeasure M (recurrent_subset_infty A) = emeasure M A"
     by (rule Delta_null_same_emeasure[symmetric], auto)
 
   show "AE x\<in>A in M. x \<in> recurrent_subset_infty A"
     unfolding eventually_ae_filter
     by (metis (no_types, lifting) DiffI \<open>A - recurrent_subset_infty A \<in> null_sets M\<close> mem_Collect_eq subsetI)
 qed
 
 text \<open>A convenient way to use conservativity is given in the following theorem: if $T$ is
 conservative, then the series $\sum_n f(T^n x)$ is infinite for almost every $x$ with $f x > 0$.
 When $f$ is an indicator function, this is the fact that, starting from $B$, one returns
 infinitely many times to $B$ almost surely. The general case follows by approximating $f$ from
 below by constants time indicators.\<close>
 
 theorem (in conservative) recurrence_series_infinite:
   fixes f::"'a \<Rightarrow> ennreal"
   assumes [measurable]: "f \<in> borel_measurable M"
   shows "AE x in M. f x > 0 \<longrightarrow> (\<Sum>n. f ((T^^n) x)) = \<infinity>"
 proof -
   have *: "AE x in M. f x > epsilon \<longrightarrow> (\<Sum>n. f ((T^^n) x)) = \<top>" if "epsilon > 0" for epsilon
   proof -
     define B where "B = {x \<in> space M. f x > epsilon}"
     have [measurable]: "B \<in> sets M" unfolding B_def by auto
     have "(\<Sum>n. f ((T^^n) x)) = \<infinity>" if "x \<in> recurrent_subset_infty B" for x
     proof -
       have "\<infinity> = epsilon * \<infinity>" using \<open>epsilon > 0\<close> ennreal_mult_top by auto
       also have "... = epsilon * (\<Sum>n. indicator B ((T^^n) x))"
         using recurrent_subset_infty_series_infinite[OF that] by simp
       also have "... = (\<Sum>n. epsilon * indicator B ((T^^n) x))"
         by auto
       also have "... \<le> (\<Sum>n. f ((T^^n) x))"
         apply (rule suminf_le) unfolding indicator_def B_def by auto
       finally show ?thesis
         by (simp add: dual_order.antisym)
     qed
     moreover have "AE x in M. f x > epsilon \<longrightarrow> x \<in> recurrent_subset_infty B"
       using Poincare_recurrence_thm(7)[OF \<open>B \<in> sets M\<close>] unfolding B_def by auto
     ultimately show ?thesis by auto
   qed
   have "\<exists>u::(nat \<Rightarrow> ennreal). (\<forall>n. u n > 0) \<and> u \<longlonglongrightarrow> 0"
     by (meson approx_from_above_dense_linorder ex_gt_or_lt gr_implies_not_zero)
   then obtain u::"nat \<Rightarrow> ennreal" where u: "\<And>n. u n > 0" "u \<longlonglongrightarrow> 0"
     by auto
   have "AE x in M. (\<forall>n::nat. (f x > u n \<longrightarrow> (\<Sum>n. f ((T^^n) x)) = \<top>))"
     unfolding AE_all_countable using u by (auto intro!: *)
   moreover have "f x > 0 \<longrightarrow> (\<Sum>n. f ((T^^n) x)) = \<infinity>" if "(\<forall>n::nat. (f x > u n \<longrightarrow> (\<Sum>n. f ((T^^n) x)) = \<top>))" for x
   proof (auto)
     assume "f x > 0"
     obtain n where "u n < f x"
       using order_tendstoD(2)[OF u(2) \<open>f x > 0\<close>] eventually_False_sequentially eventually_mono by blast
     then show "(\<Sum>n. f ((T^^n) x)) = \<top>" using that by auto
   qed
   ultimately show ?thesis by auto
 qed
 
 
 subsection \<open>The first return time\<close>
 
 text \<open>The first return time to a set $A$ under the dynamics $T$ is the smallest integer $n$ such
 that $T^n(x) \in A$. The first return time is only well defined
 on the recurrent subset of $A$, elsewhere we set it to $0$ for definiteness.
 We can partition $A$ according to the value of the return time on it, thus defining
 the return partition of $A$.\<close>
 
 definition return_time_function::"'a set \<Rightarrow> ('a \<Rightarrow> nat)"
   where "return_time_function A x = (
     if (x \<in> recurrent_subset A) then (Inf {n::nat\<in>{1..}. (T^^n) x \<in> A})
     else 0)"
 
 definition return_partition::"'a set \<Rightarrow> nat \<Rightarrow> 'a set"
   where "return_partition A k = A \<inter> (T^^k)--`A - (\<Union>i\<in>{0<..<k}. (T^^i)--`A)"
 
 text \<open>Basic properties of the return partition.\<close>
 
 lemma return_partition_basics:
   assumes A_meas [measurable]: "A \<in> sets M"
   shows [measurable]: "return_partition A n \<in> sets M"
     and "disjoint_family (\<lambda>n. return_partition A (n+1))"
         "(\<Union>n. return_partition A (n+1)) = recurrent_subset A"
 proof -
   show "return_partition A n \<in> sets M" for n unfolding return_partition_def by auto
 
   define B where "B = (\<lambda>n. A \<inter> (T^^(n+1))--`A)"
   have "return_partition A (n+1) = B n -(\<Union>i\<in>{0..<n}. B i)" for n
     unfolding return_partition_def B_def by (auto) (auto simp add: less_Suc_eq_0_disj)
   then have *: "\<And>n. return_partition A (n+1) = disjointed B n" using disjointed_def[of B] by simp
   then show "disjoint_family (\<lambda>n. return_partition A (n+1))" using disjoint_family_disjointed by simp
 
   have "A \<inter> (T^^n)-`A = A \<inter> (T^^n)--`A" for n
     using sets.sets_into_space[OF A_meas] by auto
   then have "recurrent_subset A = (\<Union>n\<in> {1..}. A \<inter> (T^^n)--`A)" unfolding recurrent_subset_def by simp
   also have "... = (\<Union>n. B n)" by (simp add: B_def atLeast_Suc_greaterThan greaterThan_0)
   also have "... = (\<Union>n. return_partition A (n+1))" using * UN_disjointed_eq[of B] by simp
   finally show "(\<Union>n. return_partition A (n+1)) = recurrent_subset A" by simp
 qed
 
 text \<open>Basic properties of the return time, relationship with the return partition.\<close>
 
 lemma return_time0:
   "(return_time_function A)-`{0} = UNIV - recurrent_subset A"
 proof (auto)
   fix x
   assume *: "x \<in> recurrent_subset A" "return_time_function A x = 0"
   define K where "K = {n::nat\<in>{1..}. (T^^n) x \<in> A}"
   have **: "return_time_function A x = Inf K"
     using K_def return_time_function_def * by simp
   have "K \<noteq> {}" using K_def recurrent_subset_def * by auto
   moreover have "0 \<notin> K" using K_def by auto
   ultimately have "Inf K >0"
     by (metis (no_types, lifting) K_def One_nat_def atLeast_iff cInf_lessD mem_Collect_eq neq0_conv not_le zero_less_Suc)
   then have "return_time_function A x > 0" using ** by simp
   then show "False" using * by simp
 qed (auto simp add: return_time_function_def)
 
 lemma return_time_n:
   assumes [measurable]: "A \<in> sets M"
   shows "(return_time_function A)-`{Suc n} = return_partition A (Suc n)"
 proof (auto)
   fix x assume *: "return_time_function A x = Suc n"
   then have rx: "x \<in> recurrent_subset A" using return_time_function_def by (auto, meson Zero_not_Suc)
   define K where "K = {i\<in>{1..}. (T^^i) x \<in> A}"
   have "return_time_function A x = Inf K" using return_time_function_def rx K_def by auto
   then have "Inf K = Suc n" using * by simp
   moreover have "K \<noteq> {}" using rx recurrent_subset_def K_def by auto
   ultimately have "Suc n \<in> K" using Inf_nat_def1[of K] by simp
   then have "(T^^(Suc n))x \<in> A" using K_def by auto
   then have a: "x \<in> A \<inter> (T^^(Suc n))--`A"
     using rx recurrent_subset_incl[of A] sets.sets_into_space[OF assms] by auto
   have "\<And>i. i\<in>{1..<Suc n} \<Longrightarrow> i \<notin> K" using cInf_lower \<open>Inf K = Suc n\<close> by force
   then have "\<And>i. i\<in>{1..<Suc n} \<Longrightarrow> x \<notin> (T^^i)--`A" using K_def by auto
   then have "x \<notin> (\<Union>i\<in>{1..<Suc n}. (T^^i)--`A)" by auto
   then show "x \<in> return_partition A (Suc n)" using a return_partition_def by simp
 next
   fix x assume *: "x \<in> return_partition A (Suc n)"
   then have a: "x \<in> space M" unfolding return_partition_def using vimage_restr_def by blast
   define K where "K = {i::nat\<in>{1..}. (T^^i) x \<in> A}"
   have "Inf K = Suc n"
     apply (rule cInf_eq_minimum) using * by (auto simp add: a assms K_def return_partition_def)
 
   have "x \<in> recurrent_subset A" using * return_partition_basics(3)[OF assms] by auto
   then show "return_time_function A x = Suc n"
     using return_time_function_def K_def \<open>Inf K = Suc n\<close> by auto
 qed
 
 text \<open>The return time is measurable.\<close>
 
 lemma return_time_function_meas [measurable]:
   assumes [measurable]: "A \<in> sets M"
   shows "return_time_function A \<in> measurable M (count_space UNIV)"
         "return_time_function A \<in> borel_measurable M"
 proof -
   have "(return_time_function A)-`{n} \<inter> space M \<in> sets M" for n
   proof (cases "n = 0")
     case True
     then show ?thesis using return_time0 recurrent_subset_meas[OF assms] by auto
   next
     case False
     show ?thesis
       using return_time_n return_partition_basics(1)[OF assms] not0_implies_Suc[OF False] by auto
   qed
   then show "return_time_function A \<in> measurable M (count_space UNIV)"
     by (simp add: measurable_count_space_eq2_countable assms)
   then show "return_time_function A \<in> borel_measurable M"
     using measurable_cong_sets sets_borel_eq_count_space by blast
 qed
 
 text \<open>A close cousin of the return time and the return partition is the first entrance set:
 we partition the space according to the first positive time where a point enters $A$.\<close>
 
 definition first_entrance_set::"'a set \<Rightarrow> nat \<Rightarrow> 'a set"
   where "first_entrance_set A n = (T^^n) --` A - (\<Union> i<n. (T^^i)--`A)"
 
 lemma first_entrance_meas [measurable]:
   assumes [measurable]: "A \<in> sets M"
     shows "first_entrance_set A n \<in> sets M"
 unfolding first_entrance_set_def by measurable
 
 lemma first_entrance_disjoint:
   "disjoint_family (first_entrance_set A)"
 proof -
   have "first_entrance_set A = disjointed (\<lambda>i. (T^^i)--`A)"
     by (auto simp add: disjointed_def first_entrance_set_def)
   then show ?thesis by (simp add: disjoint_family_disjointed)
 qed
 
 text \<open>There is an important dynamical phenomenon: if a point has first entrance time equal to
 $n$, then their preimages either have first entrance time equal to $n+1$ (these are the preimages
 not in $A$) or they belong to $A$ and have first return time equal to $n+1$. When $T$ preserves the
 measure, this gives an inductive control on the measure of the first entrance set, that will be
 used again and again in the proof of Kac's Formula. We formulate these (simple but extremely useful)
 facts now.\<close>
 
 lemma first_entrance_rec:
   assumes [measurable]: "A \<in> sets M"
   shows "first_entrance_set A (Suc n) = T--`(first_entrance_set A n) - A"
 proof -
   have A0: "A = (T^^0)--`A" by auto
   have "first_entrance_set A n = (T^^n) --` A - (\<Union> i<n. (T^^i)--`A)"
     using first_entrance_set_def by simp
   then have "T--`(first_entrance_set A n) = (T^^(n+1))--`A - (\<Union> i<n. (T^^(i+1))--`A)"
     using T_vrestr_composed(2) \<open>A \<in> sets M\<close> by simp
   then have *: "T--`(first_entrance_set A n) - A = (T^^(n+1))--`A - (A \<union> (\<Union> i<n. (T^^(i+1))--`A))"
     by blast
   have "(\<Union> i<n. (T^^(i+1))--`A) = (\<Union> j\<in>{1..<n+1}. (T^^j)--`A)"
     by (rule UN_le_add_shift_strict)
   then have "A \<union> (\<Union> i<n. (T^^(i+1))--`A) = (\<Union> j\<in>{0..<n+1}. (T^^j)--`A)"
     by (metis A0 Un_commute atLeast0LessThan UN_le_eq_Un0_strict)
   then show ?thesis using * first_entrance_set_def by auto
 qed
 
 lemma return_time_rec:
   assumes "A \<in> sets M"
   shows "(return_time_function A)-`{Suc n} = T--`(first_entrance_set A n) \<inter> A"
 proof -
   have "return_partition A (Suc n) = T--`(first_entrance_set A n) \<inter> A"
     unfolding return_partition_def first_entrance_set_def
     by (auto simp add: T_vrestr_composed[OF assms]) (auto simp add: less_Suc_eq_0_disj)
   then show ?thesis using return_time_n[OF assms] by simp
 qed
 
 
 subsection \<open>Local time controls\<close>
 
 text \<open>The local time is the time that an orbit spends in a given set. Local time controls
 are basic to all the forthcoming developments.\<close>
 
 definition local_time::"'a set \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> nat"
 where "local_time A n x = card {i\<in>{..<n}. (T^^i) x \<in> A}"
 
 lemma local_time_birkhoff:
   "local_time A n x = birkhoff_sum (indicator A) n x"
 proof (induction n)
   case 0
   then show ?case unfolding local_time_def birkhoff_sum_def by simp
 next
   case (Suc n)
   have "local_time A (n+1) x = local_time A n x + indicator A ((T^^n) x)"
   proof (cases)
     assume *: "(T^^n) x \<in> A"
     then have "{i\<in>{..<Suc n}. (T^^i) x \<in> A} = {i\<in>{..<n}. (T^^i) x \<in> A} \<union> {n}"
       by auto
     then have "card {i\<in>{..<Suc n}. (T^^i) x \<in> A} = card {i\<in>{..<n}. (T^^i) x \<in> A} + card {n}"
       using card_Un_disjoint by auto
     then have "local_time A (n+1) x = local_time A n x + 1" using local_time_def by simp
     moreover have "indicator A ((T^^n)x) = (1::nat)" using * indicator_def by auto
     ultimately show ?thesis by simp
   next
     assume *: "\<not>((T^^n) x \<in> A)"
     then have "{i\<in>{..<Suc n}. (T^^i) x \<in> A} = {i\<in>{..<n}. (T^^i) x \<in> A}" using less_Suc_eq by force
     then have "card {i\<in>{..<Suc n}. (T^^i) x \<in> A} = card {i\<in>{..<n}. (T^^i) x \<in> A}"
       by auto
     then have "local_time A (n+1) x = local_time A n x" using local_time_def by simp
     moreover have "indicator A ((T^^n)x) = (0::nat)" using * indicator_def by auto
     ultimately show ?thesis by simp
   qed
   then have "local_time A (n+1) x = birkhoff_sum (indicator A) n x + indicator A ((T^^n) x)"
     using Suc.IH by auto
   moreover have "birkhoff_sum (indicator A) (n+1) x = birkhoff_sum (indicator A) n x + indicator A ((T^^n) x)"
     by (metis birkhoff_sum_cocycle[where ?n = "n" and ?m = "1"] birkhoff_sum_1(2))
   ultimately have "local_time A (n+1) x = birkhoff_sum (indicator A) (n+1) x" by metis
   then show ?case by (metis Suc_eq_plus1)
 qed
 
 lemma local_time_meas [measurable]:
   assumes [measurable]: "A \<in> sets M"
   shows "local_time A n \<in> borel_measurable M"
 unfolding local_time_birkhoff by auto
 
 lemma local_time_cocycle:
   "local_time A n x + local_time A m ((T^^n)x) = local_time A (n+m) x"
 by (metis local_time_birkhoff birkhoff_sum_cocycle)
 
 lemma local_time_incseq:
   "incseq (\<lambda>n. local_time A n x)"
 using local_time_cocycle incseq_def by (metis le_iff_add)
 
 lemma local_time_Suc:
   "local_time A (n+1) x = local_time A n x + indicator A ((T^^n)x)"
 by (metis local_time_birkhoff birkhoff_sum_cocycle birkhoff_sum_1(2))
 
 text \<open>The local time is bounded by $n$: at most, one returns to $A$ all the time!\<close>
 
 lemma local_time_bound:
   "local_time A n x \<le> n"
 proof -
   have "card {i\<in>{..<n}. (T^^i) x \<in> A} \<le> card {..<n}" by (rule card_mono, auto)
   then show ?thesis unfolding local_time_def by auto
 qed
 
 text \<open>The fact that local times are unbounded will be the main technical tool in the proof
 of recurrence results or Kac formula below. In this direction, we prove more and more general
 results in the lemmas below.
 
 We show that, in $T^{-n}(A)$, the number of visits to $A$ tends to infinity in
 measure, when $A$ has finite measure. In other words, the points in $T^{-n}(A)$ with
 local time $<k$ have a measure tending to $0$ with $k$. The argument, by induction on $k$, goes
 as follows.
 
 Consider the last return to $A$ before time $n$, say at time $n-i$. It lands in the set $S_i$ with
 retun time $i$. We get $T^{-n} A \subseteq \bigcup_{n<N} T^{-(n-i)}S_i \cup R$, where the union
 is disjoint and $R$ is a set of measure $\mu(T^{-n}A) - \sum_{n<N} \mu(T^{-(n-i)}S_i)
 = \mu(A) -\sum_{n<N} \mu(S_i)$, which tends to $0$ with $N$ and that we may therefore discard.
 A point with local time $<k$ at time $n$ in $T^{-n}A$ is then a point with local time $<k-1$
 at time $n-i$ in $T^{-(n-i)}S_i \subseteq T^{-(n-i)}A$. Hence, we may conclude by the induction
 assumption that this has small measure.\<close>
 
 lemma (in conservative_mpt) local_time_unbounded1:
   assumes A_meas [measurable]: "A \<in> sets M"
     and fin: "emeasure M A < \<infinity>"
   shows "(\<lambda>n. emeasure M {x \<in> (T^^n)--`A. local_time A n x < k}) \<longlonglongrightarrow> 0"
 proof (induction k)
   case 0
   have "{x \<in> (T^^n)--`A. local_time A n x < 0} = {}" for n by simp
   then show ?case by simp
 next
   case (Suc k)
   define K where "K = (\<lambda>p n. {x \<in> (T^^n)--`A. local_time A n x < p})"
   have K_meas [measurable]: "K p n \<in> sets M" for n p
     unfolding K_def by measurable
 
   show ?case
   proof (rule tendsto_zero_ennreal)
     fix e :: real assume "0 < e"
     define e2 where "e2 = e/3"
     have "e2 > 0" using e2_def \<open>e>0\<close> by simp
     have "(\<Sum>n. emeasure M (return_partition A (n+1))) = emeasure M ((\<Union>n. return_partition A (n + 1)))"
       apply (rule suminf_emeasure) using return_partition_basics[OF A_meas] by auto
     also have "... = emeasure M (recurrent_subset A)"
       using return_partition_basics(3)[OF A_meas] by simp
     also have "... = emeasure M A"
       by (metis A_meas double_diff emeasure_Diff_null_set order_refl Poincare_recurrence_thm(1)[OF A_meas] recurrent_subset_incl(1))
     finally have "(\<Sum>n. emeasure M (return_partition A (n+1))) = emeasure M A" by simp
     moreover have "summable (\<lambda>n. emeasure M (return_partition A (n+1)))"
       by simp
     ultimately have "(\<lambda>N. (\<Sum>n<N. emeasure M (return_partition A (n+1)))) \<longlonglongrightarrow> emeasure M A"
       unfolding sums_def[symmetric] sums_iff by simp
     then have "(\<lambda>N. (\<Sum>n<N. emeasure M (return_partition A (n+1))) + e2) \<longlonglongrightarrow> emeasure M A + e2"
       by (intro tendsto_add) auto
     moreover have "emeasure M A < emeasure M A + e2"
       using \<open>emeasure M A < \<infinity>\<close> \<open>0 < e2\<close> by auto
     ultimately have "eventually (\<lambda>N. (\<Sum>n<N. emeasure M (return_partition A (n+1))) + e2 > emeasure M A) sequentially"
       by (simp add: order_tendsto_iff)
     then obtain N where "N>0" and largeM: "(\<Sum>n<N. emeasure M (return_partition A (n+1))) + e2 > emeasure M A"
       by (metis (no_types, lifting) add.commute add_Suc_right eventually_at_top_linorder le_add2 zero_less_Suc)
 
     have upper: "emeasure M (K (Suc k) n) \<le> e2 + (\<Sum>i<N. emeasure M (K k (n-i-1)))" if "n>N" for n
     proof -
       define B where "B = (\<lambda>i. (T^^(n-i-1))--`(return_partition A (i+1)))"
       have B_meas [measurable]: "B i \<in> sets M" for i unfolding B_def by measurable
       have disj_B: "disjoint_family_on B {..<N}"
       proof -
         have "B i \<inter> B j = {}" if "i\<in>{..<N}" "j\<in>{..<N}" "i < j" for i j
         proof -
           have "n > i" "n>j" using \<open>n>N\<close> that by auto
           let ?k = "j-i"
           have "x \<notin> B i" if "x \<in> B j" for x
           proof -
             have "(T^^(n-j-1)) x \<in> return_partition A (j+1)" using B_def that by auto
             moreover have "?k>0" using \<open>i < j\<close> by simp
             moreover have "?k < j+1" by simp
             ultimately have "(T^^(n-j-1)) x \<notin> (T^^?k)--`A" using return_partition_def by auto
             then have "x \<notin> (T^^(n-j-1))--` (T^^?k)--`A" by auto
             then have "x \<notin> (T^^(n-j-1 + ?k))--`A" using T_vrestr_composed[OF A_meas] by simp
             then have "x \<notin> (T^^(n-i-1))--`A" using \<open>i<j\<close> \<open>n>j\<close> by auto
             then have "x \<notin> (T^^(n-i-1))--` (return_partition A (i+1))" using return_partition_def by auto
             then show "x \<notin> B i" using B_def by auto
           qed
           then show "B i \<inter> B j = {}" by auto
         qed
         then have "\<And>i j. i\<in>{..<N} \<Longrightarrow> j\<in>{..<N} \<Longrightarrow> i \<noteq> j \<Longrightarrow> B i \<inter> B j = {}"
           by (metis Int_commute linorder_neqE_nat)
         then show ?thesis unfolding disjoint_family_on_def by auto
       qed
 
       have incl_B: "B i \<subseteq> (T^^n)--`A" if "i \<in> {..<N}" for i
       proof -
         have "n > i" using \<open>n>N\<close> that by auto
         have "B i \<subseteq> (T^^(n-i-1))--` (T^^(i+1))--` A"
           using B_def return_partition_def by auto
         then show "B i \<subseteq> (T^^n)--`A"
           using T_vrestr_composed(1)[OF A_meas, of "n-i-1", of "i+1"] \<open>n>i\<close> by auto
       qed
 
       define R where "R = (T^^n)--`A - (\<Union>i \<in> {..<N}. B i)"
       have [measurable]: "R \<in> sets M" unfolding R_def by measurable
       have dec_n: "(T^^n)--`A = R \<union> (\<Union>i \<in> {..<N}. B i)" using R_def incl_B by blast
       have small_R: "emeasure M R < e2"
       proof -
         have "R \<inter> (\<Union>i \<in> {..<N}. B i) = {}" using R_def by blast
         then have "emeasure M ((T^^n)--`A) = emeasure M R + emeasure M (\<Union>i \<in> {..<N}. B i)"
           using plus_emeasure[of R, of M, of "\<Union>i \<in> {..<N}. B i"] dec_n by auto
         moreover have "emeasure M (\<Union>i \<in> {..<N}. B i) = (\<Sum>i \<in> {..<N}. emeasure M (B i))"
           by (intro disj_B sum_emeasure[symmetric], auto)
         ultimately have "emeasure M ((T^^n)--`A) = emeasure M R + (\<Sum>i \<in> {..<N}. emeasure M (B i))"
           by simp
         moreover have "emeasure M ((T^^n)--`A) = emeasure M A"
           using T_vrestr_same_emeasure(2)[OF A_meas] by simp
         moreover have "\<And>i. emeasure M (B i) = emeasure M (return_partition A (i+1))"
           using T_vrestr_same_emeasure(2) B_def return_partition_basics(1)[OF A_meas] by simp
         ultimately have a: "emeasure M A = emeasure M R + (\<Sum>i \<in> {..<N}. emeasure M (return_partition A (i+1)))"
           by simp
         moreover have b: "(\<Sum>i \<in> {..<N}. emeasure M (return_partition A (i+1))) \<noteq> \<infinity>" using fin
           by (simp add: a less_top)
         ultimately show ?thesis
           using largeM fin b by simp
       qed
 
       have "K (Suc k) n \<subseteq> R \<union> (\<Union>i<N. K k (n-i-1))"
       proof
         fix x assume a: "x \<in> K (Suc k) n"
         show "x \<in> R \<union> (\<Union>i<N. K k (n-i-1))"
         proof (cases)
           assume "\<not>(x \<in> R)"
           have "x \<in> (T^^n)--`A" using a K_def by simp
           then have "x\<in> (\<Union>i \<in> {..<N}. B i)" using dec_n \<open>\<not>(x \<in> R)\<close> by simp
           then obtain i where "i\<in>{..<N}" "x \<in> B i" by auto
           then have "n>i" using \<open>n>N\<close> by auto
           then have "(T^^(n-i-1)) x \<in> return_partition A (i+1)" using B_def \<open>x \<in> B i\<close> by auto
           then have i: "(T^^(n-i-1)) x \<in> A" using return_partition_def by auto
           then have "indicator A ((T^^(n-i-1)) x) = (1::nat)" by auto
           then have "local_time A (n-i) x = local_time A (n-i-1) x + 1"
             by (metis Suc_diff_Suc Suc_eq_plus1 diff_diff_add local_time_Suc[of A, of "n-i-1"] \<open>n>i\<close>)
           then have "local_time A (n-i) x > local_time A (n-i-1) x" by simp
           moreover have "local_time A n x \<ge> local_time A (n-i) x" using local_time_incseq
             by (metis \<open>i < n\<close> le_add_diff_inverse2 less_or_eq_imp_le local_time_cocycle le_iff_add)
           ultimately have "local_time A n x > local_time A (n-i-1) x" by simp
           moreover have "local_time A n x < Suc k" using a K_def by simp
           ultimately have *: "local_time A (n-i-1) x < k" by simp
 
           have "x \<in> space M" using \<open>x \<in> (T^^n)--`A\<close> by auto
           then have "x \<in> (T^^(n-i-1))--`A" using i A_meas vimage_restr_def by (metis IntI sets.Int_space_eq2 vimageI)
           then have "x \<in> K k (n-i-1)" using * K_def by blast
           then show ?thesis using \<open>i\<in>{..<N}\<close> by auto
         qed (simp)
       qed
       then have "emeasure M (K (Suc k) n) \<le> emeasure M (R \<union> (\<Union>i<N. K k (n-i-1)))"
         by (intro emeasure_mono, auto)
       also have "... \<le> emeasure M R + emeasure M (\<Union>i<N. K k (n-i-1))"
         by (rule emeasure_subadditive, auto)
       also have "... \<le> emeasure M R + (\<Sum>i<N. emeasure M (K k (n-i-1)))"
         by (metis add_left_mono image_subset_iff emeasure_subadditive_finite[where ?A = "\<lambda>i. K k (n-i-1)" and ?I = "{..<N}", OF finite_lessThan[of N]] K_meas)
       also have "... \<le> e2 + (\<Sum>i<N. emeasure M (K k (n-i-1)))"
         using small_R by (auto intro!: add_right_mono)
       finally show "emeasure M (K (Suc k) n) \<le> e2 + (\<Sum>i<N. emeasure M (K k (n-i-1)))" .
     qed
 
     have "(\<lambda>n. (\<Sum>i\<in>{..<N}. emeasure M (K k (n-i-1)))) \<longlonglongrightarrow> (\<Sum>i\<in>{..<N}. 0)"
       apply (intro tendsto_intros seq_offset_neg) using Suc.IH K_def by simp
     then have "eventually (\<lambda>n. (\<Sum>i\<in>{..<N}. emeasure M (K k (n-i-1))) < e2) sequentially"
       using \<open>e2 > 0\<close> by (simp add: order_tendsto_iff)
     then obtain N2 where N2bound: "\<And>n. n > N2 \<Longrightarrow> (\<Sum>i\<in>{..<N}. emeasure M (K k (n-i-1))) < e2"
       by (meson eventually_at_top_dense)
     define N3 where "N3 = max N N2"
     have "emeasure M (K (Suc k) n) < e" if "n > N3" for n
     proof -
       have "n>N2" "n > N" using N3_def that by auto
       then have "emeasure M (K (Suc k) n) \<le> ennreal e2 + (\<Sum>i\<in>{..<N}. emeasure M (K k (n-i-1)))"
         using upper by simp
       also have "... \<le> ennreal e2 + ennreal e2"
         using N2bound[OF \<open>n > N2\<close>] less_imp_le by auto
       also have "... < e" using e2_def \<open>e > 0\<close>
         by (auto simp add: ennreal_plus[symmetric] simp del: ennreal_plus intro!: ennreal_lessI)
       ultimately show "emeasure M (K (Suc k) n) < e" using le_less_trans by blast
     qed
     then show "\<forall>\<^sub>F x in sequentially. emeasure M {xa \<in> (T ^^ x) --` A. local_time A x xa < Suc k} < ennreal e"
       unfolding K_def by (auto simp: eventually_at_top_dense intro!: exI[of _ N3])
   qed
 qed
 
 text \<open>We deduce that local times to a set $B$ also tend to infinity on $T^{-n}A$ if $B$ is related
 to $A$, i.e., if points in $A$ have some iterate in $B$.
 This is clearly a necessary condition for the lemmas to hold: otherwise, points of $A$
 that never visit $B$ have a local time equal to $B$ equal to $0$, and so do all their preimages.
 
 The lemmas are readily reduced to the previous one on the local time to $A$, since if one visits
 $A$ then one visits $B$ in finite time by assumption (uniformly bounded in the first lemma,
 uniformly bounded on a set of large measure in the second lemma).\<close>
 
 lemma (in conservative_mpt) local_time_unbounded2:
   assumes A_meas [measurable]: "A \<in> sets M"
       and fin: "emeasure M A < \<infinity>"
       and incl: "A \<subseteq> (T^^i)--`B"
   shows "(\<lambda>n. emeasure M {x \<in> (T^^n)--`A. local_time B n x < k}) \<longlonglongrightarrow> 0"
 proof -
   have "emeasure M {x \<in> (T^^n)--`A. local_time B n x < k} \<le> emeasure M {x \<in> (T^^n)--`A. local_time A n x < k + i}"
     if "n > i" for n
   proof -
     have "local_time A n x \<le> local_time B n x + i" for x
     proof -
       have "local_time B n x \<ge> local_time A (n-i) x"
       proof -
         define KA where "KA = {t \<in> {0..<n-i}. (T^^t) x \<in> A}"
         define KB where "KB = {t \<in> {0..<n}. (T^^t) x \<in> B}"
         then have "KB \<subseteq> {0..<n}" by auto
         then have "finite KB" using finite_lessThan[of n] finite_subset by auto
         let ?g = "\<lambda>t. t + i"
         have "\<And>t. t \<in> KA \<Longrightarrow> ?g t \<in> KB"
         proof -
           fix t assume "t \<in> KA"
           then have "(T^^t) x \<in> A" using KA_def by simp
           then have "(T^^i) ((T^^t) x) \<in> B" using incl by auto
           then have "(T^^(t+i)) x \<in> B" by (simp add: funpow_add add.commute)
           moreover have "t+i < n" using \<open>t \<in> KA\<close> KA_def \<open>n > i\<close> by auto
           ultimately show "?g t \<in> KB" unfolding KB_def by simp
         qed
         then have "?g`KA \<subseteq> KB" by auto
         moreover have "inj_on ?g KA" by simp
         ultimately have "card KB \<ge> card KA"
           using card_inj_on_le[where ?f = "?g" and ?A = KA and ?B = KB] \<open>finite KB\<close> by simp
         then show ?thesis using KA_def KB_def local_time_def by simp
       qed
       moreover have "i \<ge> local_time A i ((T^^(n-i))x)" using local_time_bound by auto
       ultimately show "local_time B n x + i \<ge> local_time A n x"
         using local_time_cocycle[where ?n = "n-i" and ?m = i and ?x = x and ?A = A] \<open>n>i\<close> by auto
     qed
     then have "local_time B n x < k \<Longrightarrow> local_time A n x < k + i" for x
       by (meson add_le_cancel_right le_trans not_less)
     then show ?thesis
       by (intro emeasure_mono, auto)
   qed
   then have "eventually (\<lambda>n. emeasure M {x \<in> (T^^n)--`A. local_time B n x < k}
                 \<le> emeasure M {x \<in> (T^^n)--`A. local_time A n x < k + i}) sequentially"
     using eventually_at_top_dense by blast
   from tendsto_sandwich[OF _ this tendsto_const local_time_unbounded1[OF A_meas fin, of "k+i"]]
   show ?thesis by auto
 qed
 
 lemma (in conservative_mpt) local_time_unbounded3:
   assumes A_meas[measurable]: "A \<in> sets M"
       and B_meas[measurable]: "B \<in> sets M"
       and fin: "emeasure M A < \<infinity>"
       and incl: "A - (\<Union>i. (T^^i)--`B) \<in> null_sets M"
   shows "(\<lambda>n. emeasure M {x \<in> (T^^n)--`A. local_time B n x < k}) \<longlonglongrightarrow> 0"
 proof -
   define R where "R = A - (\<Union>i. (T^^i)--`B)"
   have R_meas[measurable]: "R \<in> sets M"
     by (simp add: A_meas B_meas T_vrestr_meas(2)[OF B_meas] R_def countable_Un_Int(1) sets.Diff)
   have "emeasure M R = 0" using incl R_def by auto
   define A2 where "A2 = A - R"
   have A2_meas [measurable]: "A2 \<in> sets M" unfolding A2_def by auto
   have meq: "emeasure M A2 = emeasure M A" using \<open>emeasure M R = 0\<close>
     unfolding A2_def by (subst emeasure_Diff) (auto simp: R_def)
   then have A2_fin: "emeasure M A2 < \<infinity>" using fin by auto
   define K where "K = (\<lambda>N. A2 \<inter> (\<Union>i<N. (T^^i)--`B))"
   have K_meas [measurable]: "K N \<in> sets M" for N unfolding K_def by auto
   have K_incl: "\<And>N. K N \<subseteq> A" using K_def A2_def by blast
   have "(\<Union>N. K N) = A2" using A2_def R_def K_def by blast
   moreover have "incseq K" unfolding K_def incseq_def by fastforce
   ultimately have "(\<lambda>N. emeasure M (K N)) \<longlonglongrightarrow> emeasure M A2" by (auto intro: Lim_emeasure_incseq)
   then have conv: "(\<lambda>N. emeasure M (K N)) \<longlonglongrightarrow> emeasure M A" using meq by simp
 
   define Bad where "Bad = (\<lambda>U n. {x \<in> (T^^n)--`U. local_time B n x < k})"
   define Bad0 where "Bad0 = (\<lambda>n. {x \<in> space M. local_time B n x < k})"
   have Bad0_meas [measurable]: "Bad0 n \<in> sets M" for n unfolding Bad0_def by auto
   have Bad_inter: "\<And>U n. Bad U n = (T^^n)--`U \<inter> Bad0 n" unfolding Bad_def Bad0_def by auto
   have Bad_meas [measurable]: "\<And>U n. U \<in> sets M \<Longrightarrow> Bad U n \<in> sets M" unfolding Bad_def by auto
 
   show ?thesis
   proof (rule tendsto_zero_ennreal)
     fix e::real
     assume "e > 0"
     define e2 where "e2 = e/3"
     then have "e2 > 0" using \<open>e>0\<close> by simp
     then have "ennreal e2 > 0" by simp
     have "(\<lambda>N. emeasure M (K N) + e2) \<longlonglongrightarrow> emeasure M A + e2"
       using conv by (intro tendsto_add) auto
     moreover have "emeasure M A < emeasure M A + e2" using fin \<open>e2 > 0\<close> by simp
     ultimately have "eventually (\<lambda>N. emeasure M (K N) + e2 > emeasure M A) sequentially"
       by (simp add: order_tendsto_iff)
     then obtain N where "N>0" and largeK: "emeasure M (K N) + e2 > emeasure M A"
       by (metis (no_types, lifting) add.commute add_Suc_right eventually_at_top_linorder le_add2 zero_less_Suc)
     define S where "S = A - (K N)"
     have S_meas [measurable]: "S \<in> sets M" using A_meas K_meas S_def by simp
     have "emeasure M A = emeasure M (K N) + emeasure M S"
       by (metis Diff_disjoint Diff_partition plus_emeasure[OF K_meas[of N], OF S_meas] S_def K_incl[of N])
     then have S_small: "emeasure M S < e2" using largeK fin by simp
     have A_incl: "A \<subseteq> S \<union> (\<Union>i<N. A2 \<inter> (T^^i)--`B)" using S_def K_def by auto
 
     define L where "L = (\<lambda>i. A2 \<inter> (T^^i)--`B)"
     have L_meas [measurable]: "L i \<in> sets M" for i unfolding L_def by auto
     have "\<And>i. L i \<subseteq> A2" using L_def by simp
     then have L_fin: "emeasure M (L i) < \<infinity>" for i
       using emeasure_mono[of "L i" A2 M] A2_meas A2_fin by simp
     have "\<And>i. L i \<subseteq> (T^^i)--`B" using L_def by auto
     then have a: "\<And>i. (\<lambda>n. emeasure M (Bad (L i) n)) \<longlonglongrightarrow> 0" unfolding Bad_def
       using local_time_unbounded2[OF L_meas, OF L_fin] by blast
     have "(\<lambda>n. (\<Sum>i<N. emeasure M (Bad (L i) n))) \<longlonglongrightarrow> 0" using tendsto_sum[OF a] by auto
     then have "eventually (\<lambda>n. (\<Sum>i<N. emeasure M (Bad (L i) n)) < e2) sequentially"
       using \<open>ennreal e2 > 0\<close> order_tendsto_iff by metis
     then obtain N2 where *: "\<And>n. n > N2 \<Longrightarrow> (\<Sum>i<N. emeasure M (Bad (L i) n)) < e2"
       by (auto simp add: eventually_at_top_dense)
 
     have "emeasure M (Bad A n) < e" if "n > N2" for n
     proof -
       have "emeasure M (Bad S n) \<le> emeasure M ((T^^n)--`S)"
         apply (rule emeasure_mono) unfolding Bad_def by auto
       also have "... = emeasure M S" using T_vrestr_same_emeasure(2) by simp
       also have "... \<le> e2" using S_small by simp
       finally have SBad_small: "emeasure M (Bad S n) \<le> e2" by simp
 
       have "(T^^n)--`A \<subseteq> (T^^n)--`S \<union> (\<Union>i<N. (T^^n)--`(L i))"
         using A_incl unfolding L_def by fastforce
       then have I: "Bad A n \<subseteq> Bad S n \<union> (\<Union>i<N. Bad (L i) n)" using Bad_inter by force
       have "emeasure M (Bad A n) \<le> emeasure M (Bad S n \<union> (\<Union>i<N. Bad (L i) n))"
         by (rule emeasure_mono[OF I], measurable)
       also have "... \<le> emeasure M (Bad S n) + emeasure M (\<Union>i<N. Bad (L i) n)"
         by (intro emeasure_subadditive countable_Un_Int(1), auto)
       also have "... \<le> emeasure M (Bad S n) + (\<Sum>i<N. emeasure M (Bad (L i) n))"
         by (simp add: add_left_mono image_subset_iff Bad_meas[OF L_meas]
             emeasure_subadditive_finite[OF finite_lessThan[of N], where ?A = "\<lambda>i. Bad (L i) n"])
       also have "... \<le> ennreal e2 + ennreal e2"
         using SBad_small less_imp_le[OF *[OF \<open>n > N2\<close>]] by (rule add_mono)
       also have "... < e" using e2_def \<open>e>0\<close> by (simp del: ennreal_plus add: ennreal_plus[symmetric] ennreal_lessI)
       finally show "emeasure M (Bad A n) < e" by simp
     qed
     then show "\<forall>\<^sub>F x in sequentially. emeasure M {xa \<in> (T ^^ x) --` A. local_time B x xa < k} < e"
       unfolding eventually_at_top_dense Bad_def by auto
   qed
 qed
 
 
 
 subsection \<open>The induced map\<close>
 
 text \<open>The map induced by $T$ on a set $A$ is obtained by iterating $T$ until one lands again
 in $A$. (Outside of $A$, we take the identity for definiteness.) It has very nice properties:
 if $T$ is conservative, then the induced map $T_A$ also is. If $T$ is measure preserving, then
 so is $T_A$. (In particular, even if $T$ preserves an infinite measure, $T_A$ is a probability
 preserving map if $A$ has measure $1$ -- this makes it possible to prove some statements in
 infinite measure by using results in finite measure systems). If $T$ is invertible, then so is
 $T_A$. We prove all these properties in this paragraph.\<close>
 
 definition induced_map::"'a set \<Rightarrow> ('a \<Rightarrow> 'a)"
   where "induced_map A = (\<lambda> x. (T^^(return_time_function A x)) x)"
 
 text \<open>The set $A$ is stabilized by the induced map.\<close>
 
 lemma induced_map_stabilizes_A:
   "x \<in> A \<longleftrightarrow> induced_map A x \<in> A"
 proof (rule equiv_neg)
   fix x assume "x \<in> A"
   show "induced_map A x \<in> A"
   proof (cases)
     assume "x \<notin> recurrent_subset A"
     then have "induced_map A x = x" using induced_map_def return_time_function_def by simp
     then show ?thesis using \<open>x \<in> A\<close> by simp
   next
     assume H: "\<not>(x \<notin> recurrent_subset A)"
     define K where "K = {n\<in>{1..}. (T^^n) x \<in> A}"
     have "K \<noteq> {}" using H recurrent_subset_def K_def by blast
     moreover have "return_time_function A x = Inf K" using return_time_function_def K_def H by simp
     ultimately have "return_time_function A x \<in> K" using Inf_nat_def1 by simp
     then show ?thesis unfolding induced_map_def K_def by blast
   qed
 next
   fix x assume "x \<notin> A"
   then have "x \<notin> recurrent_subset A" using recurrent_subset_def by simp
   then have "induced_map A x = x" using induced_map_def return_time_function_def by simp
   then show "induced_map A x \<notin> A" using \<open>x \<notin> A\<close> by simp
 qed
 
 lemma induced_map_iterates_stabilize_A:
   assumes "x \<in> A"
   shows "((induced_map A)^^n) x \<in> A"
 proof (induction n)
   case 0
   show ?case using \<open>x \<in> A\<close> by auto
 next
   case (Suc n)
   have "((induced_map A)^^(Suc n)) x = (induced_map A) (((induced_map A)^^n) x)" by auto
   then show ?case using Suc.IH induced_map_stabilizes_A by auto
 qed
 
 lemma induced_map_meas [measurable]:
   assumes [measurable]: "A \<in> sets M"
     shows "induced_map A \<in> measurable M M"
 unfolding induced_map_def by auto
 
 text \<open>The iterates of the induced map are given by a power of the original map, where the power
 is the Birkhoff sum (for the induced map) of the first return time. This is obvious, but useful.\<close>
 
 lemma induced_map_iterates:
   "((induced_map A)^^n) x = (T^^(\<Sum>i < n. return_time_function A ((induced_map A ^^i) x))) x"
 proof (induction n)
   case 0
   show ?case by auto
 next
   case (Suc n)
   have "((induced_map A)^^(n+1)) x = induced_map A (((induced_map A)^^n) x)" by (simp add: funpow_add)
   also have "... = (T^^(return_time_function A (((induced_map A)^^n) x))) (((induced_map A)^^n) x)"
     using induced_map_def by auto
   also have "... = (T^^(return_time_function A (((induced_map A)^^n) x))) ((T^^(\<Sum>i < n. return_time_function A ((induced_map A ^^i) x))) x)"
     using Suc.IH by auto
   also have "... = (T^^(return_time_function A (((induced_map A)^^n) x) + (\<Sum>i < n. return_time_function A ((induced_map A ^^i) x)))) x"
     by (simp add: funpow_add)
   also have "... = (T^^(\<Sum>i < Suc n. return_time_function A ((induced_map A ^^i) x))) x" by (simp add: add.commute)
   finally show ?case by simp
 qed
 
 lemma induced_map_stabilizes_recurrent_infty:
   assumes "x \<in> recurrent_subset_infty A"
   shows "((induced_map A)^^n) x \<in> recurrent_subset_infty A"
 proof -
   have "x \<in> A" using assms(1) recurrent_subset_incl(2) by auto
 
   define R where "R = (\<Sum>i < n. return_time_function A ((induced_map A ^^i) x))"
   have *: "((induced_map A)^^n) x = (T^^R) x" unfolding R_def by (rule induced_map_iterates)
   moreover have "((induced_map A)^^n) x \<in> A"
     by (rule induced_map_iterates_stabilize_A, simp add: \<open>x \<in> A\<close>)
   ultimately have "(T^^R) x \<in> A" by simp
   then show ?thesis using recurrent_subset_infty_returns[OF assms] * by auto
 qed
 
 text \<open>If $x \in A$, then its successive returns to $A$ are exactly given by the iterations
 of the induced map.\<close>
 
 lemma induced_map_returns:
   assumes "x \<in> A"
   shows "((T^^n) x \<in> A) \<longleftrightarrow> (\<exists>N\<le>n. n = (\<Sum>i<N. return_time_function A ((induced_map A ^^ i) x)))"
 proof
   assume "(T^^n) x \<in> A"
   have "\<And>y. y \<in> A \<Longrightarrow> (T^^n)y \<in> A \<Longrightarrow> \<exists>N\<le>n. n = (\<Sum>i<N. return_time_function A (((induced_map A)^^i) y))" for n
   proof (induction n rule: nat_less_induct)
     case (1 n)
     show "\<exists>N\<le>n. n = (\<Sum>i<N. return_time_function A (((induced_map A)^^i) y))"
     proof (cases)
       assume "n = 0"
       then show ?thesis by auto
     next
       assume "\<not>(n = 0)"
       then have "n > 0" by simp
       then have y_rec: "y \<in> recurrent_subset A" using \<open>y \<in> A\<close> \<open>(T^^n) y \<in> A\<close> recurrent_subset_def by auto
       then have *: "return_time_function A y > 0" by (metis DiffE insert_iff neq0_conv vimage_eq return_time0)
       define m where "m = return_time_function A y"
       have "m > 0" using * m_def by simp
       define K where "K = {t \<in> {1..}. (T ^^ t) y \<in> A}"
       have "n \<in> K" unfolding K_def using \<open>n > 0\<close> \<open>(T^^n)y \<in> A\<close> by simp
       then have "n \<ge> Inf K" by (simp add: cInf_lower)
       moreover have "m = Inf K" unfolding m_def K_def return_time_function_def using y_rec by simp
       ultimately have "n \<ge> m" by simp
       define z where "z = induced_map A y"
       have "z \<in> A" using \<open>y \<in> A\<close> induced_map_stabilizes_A z_def by simp
       have "z = (T^^m) y" using induced_map_def y_rec z_def m_def by auto
       then have "(T^^(n-m)) z = (T^^n) y" using \<open>n \<ge> m\<close> funpow_add[of "n-m" m T, symmetric]
         by (metis comp_apply le_add_diff_inverse2)
       then have "(T^^(n-m)) z \<in> A" using \<open>(T^^n) y \<in> A\<close> by simp
       moreover have "n-m < n" using \<open>m > 0\<close> \<open>n > 0\<close> by simp
       ultimately obtain N0 where "N0 \<le> n-m" "n-m = (\<Sum>i<N0. return_time_function A (((induced_map A)^^i) z))"
         using \<open>z \<in> A\<close> "1.IH" by blast
       then have "n-m = (\<Sum>i<N0. return_time_function A (((induced_map A)^^i) (induced_map A y)))"
         using z_def by auto
       moreover have "\<And>i. ((induced_map A)^^i) (induced_map A y) = ((induced_map A)^^(i+1)) y"
         by (metis Suc_eq_plus1 comp_apply funpow_Suc_right)
       ultimately have "n-m = (\<Sum>i<N0. return_time_function A (((induced_map A)^^(i+1)) y))"
         by simp
       then have "n-m = (\<Sum>i \<in> {1..<N0+1}. return_time_function A (((induced_map A)^^i) y))"
         using sum.shift_bounds_nat_ivl[of "\<lambda>i. return_time_function A (((induced_map A)^^i) y)", of 0, of 1, of N0, symmetric]
               atLeast0LessThan by auto
       moreover have "m = (\<Sum>i\<in>{0..<1}. return_time_function A (((induced_map A)^^i) y))" using m_def by simp
       ultimately have "n = (\<Sum>i\<in>{0..<1}. return_time_function A (((induced_map A)^^i) y))
         + (\<Sum>i \<in> {1..<N0+1}. return_time_function A (((induced_map A)^^i) y))" using \<open>n \<ge> m\<close> by simp
       then have "n = (\<Sum>i\<in>{0..<N0+1}. return_time_function A (((induced_map A)^^i) y))"
         using le_add2 sum.atLeastLessThan_concat by blast
       moreover have "N0 + 1 \<le> n" using \<open>N0 \<le> n-m\<close> \<open>n - m < n\<close> by linarith
       ultimately show ?thesis by (metis atLeast0LessThan)
     qed
   qed
   then show "\<exists>N\<le>n. n = (\<Sum>i<N. return_time_function A ((induced_map A ^^ i) x))"
     using \<open>x \<in> A\<close> \<open>(T^^n) x \<in> A\<close> by simp
 next
   assume "\<exists>N\<le>n. n = (\<Sum>i<N. return_time_function A ((induced_map A ^^ i) x))"
   then obtain N where "n = (\<Sum>i<N. return_time_function A ((induced_map A ^^ i) x))" by blast
   then have "(T^^n) x = ((induced_map A)^^N) x" using induced_map_iterates[of N, of A, of x] by simp
   then show "(T^^n) x \<in> A" using \<open>x \<in> A\<close> induced_map_iterates_stabilize_A by auto
 qed
 
 text \<open>If a map is conservative, then the induced map is still conservative.
 Note that this statement is not true if one replaces the word "conservative" with "qmpt":
 inducion only works well in conservative settings.
 
 For instance, the right translation
 on $\mathbb{Z}$ is qmpt, but the induced map on $\mathbb{N}$ (again the right translation) is not,
 since the measure of $\{0\}$ is nonzero, while its preimage, the empty set, has zero measure.
 
 To prove conservativity, given a subset $B$ of $A$, there exists some time $n$ such that
 $T^{-n} B \cap B$ has positive measure. But this time $n$ corresponds to some returns to $A$ for
 the induced map, so $T^{-n} B \cap B$ is included in $\bigcup_m T_A^{-m} B \cap B$, hence
 one of these sets must have positive measure.
 
 The fact that the map is qmpt is then deduced from the conservativity.
 \<close>
 
 proposition (in conservative) induced_map_conservative:
   assumes A_meas: "A \<in> sets M"
   shows "conservative (restrict_space M A) (induced_map A)"
 proof
   have "sigma_finite_measure M" by unfold_locales
   then have "sigma_finite_measure (restrict_space M A)"
     using sigma_finite_measure_restrict_space assms by auto
   then show "\<exists>Aa. countable Aa \<and> Aa \<subseteq> sets (restrict_space M A) \<and> \<Union>Aa = space (restrict_space M A)
     \<and> (\<forall>a\<in>Aa. emeasure (restrict_space M A) a \<noteq> \<infinity>)" using sigma_finite_measure_def by auto
 
   have imp: "\<And>B. (B \<in> sets M \<and> B \<subseteq> A \<and> emeasure M B > 0) \<Longrightarrow> (\<exists>N>0. emeasure M (((induced_map A)^^N)-`B \<inter> B) > 0)"
   proof -
     fix B
     assume assm: "B \<in> sets M \<and> B \<subseteq> A \<and> emeasure M B > 0"
     then have "B \<subseteq> A" by simp
     have inc: "(\<Union>n\<in>{1..}. (T^^n)-`B \<inter> B) \<subseteq> (\<Union>N\<in>{1..}. ((induced_map A)^^N)-` B \<inter> B)"
     proof
       fix x assume "x \<in> (\<Union>n\<in>{1..}. (T^^n)-`B \<inter> B)"
       then obtain n where "n\<in>{1..}" and *: "x \<in> (T^^n)-`B \<inter> B" by auto
       then have "n > 0" by auto
       have "x \<in> A" "(T^^n) x \<in> A" using * \<open>B \<subseteq> A\<close> by auto
       then obtain N where **: "n = (\<Sum>i<N. return_time_function A ((induced_map A ^^ i) x))"
         using induced_map_returns by auto
       then have "((induced_map A)^^N) x = (T^^n) x" using induced_map_iterates[of N, of A, of x] by simp
       then have "((induced_map A)^^N) x \<in> B" using * by simp
       then have "x \<in> ((induced_map A)^^N)-` B \<inter> B" using * by simp
       moreover have "N > 0" using ** \<open>n > 0\<close>
         by (metis leD lessThan_iff less_nat_zero_code neq0_conv sum.neutral_const sum_mono)
       ultimately show "x \<in> (\<Union>N\<in>{1..}. ((induced_map A)^^N)-` B \<inter> B)" by auto
     qed
     have B_meas [measurable]: "B \<in> sets M" and B_pos: "emeasure M B > 0" using assm by auto
     obtain n where "n > 0" and pos: "emeasure M ((T^^n)-`B \<inter> B) > 0"
       using conservative[OF B_meas, OF B_pos] by auto
     then have "n \<in> {1..}" by auto
 
     have itB_meas: "\<And>i. ((induced_map A)^^i)-` B \<inter> B \<in> sets M"
       using B_meas measurable_compose_n[OF induced_map_meas[OF A_meas]] by (metis Int_assoc measurable_sets sets.Int sets.Int_space_eq1)
     then have "(\<Union>i\<in>{1..}. ((induced_map A)^^i)-` B \<inter> B) \<in> sets M" by measurable
     moreover have "(T^^n)-`B \<inter> B \<subseteq> (\<Union>i\<in>{1..}. ((induced_map A)^^i)-` B \<inter> B)" using inc \<open>n \<in> {1..}\<close> by force
     ultimately have "emeasure M (\<Union>i\<in>{1..}. ((induced_map A)^^i)-` B \<inter> B) > 0"
       by (metis (no_types, lifting) emeasure_eq_0 zero_less_iff_neq_zero pos)
     then have "emeasure M (\<Union>i\<in>{1..}. ((induced_map A)^^i)-` B \<inter> B) \<noteq> 0" by simp
     have "\<exists>i\<in>{1..}. emeasure M (((induced_map A)^^i)-` B \<inter> B) \<noteq> 0"
     proof (rule ccontr)
       assume "\<not>(\<exists>i\<in>{1..}. emeasure M (((induced_map A)^^i)-` B \<inter> B) \<noteq> 0)"
       then have a: "\<And>i. i \<in> {1..} \<Longrightarrow> ((induced_map A)^^i)-` B \<inter> B \<in> null_sets M"
         using itB_meas by auto
       have "(\<Union>i\<in>{1..}. ((induced_map A)^^i)-` B \<inter> B) \<in> null_sets M"
         by (rule null_sets_UN', simp_all add: a)
       then show "False" using \<open>emeasure M (\<Union>i\<in>{1..}. ((induced_map A)^^i)-` B \<inter> B) > 0\<close> by auto
     qed
     then show "\<exists>N>0. emeasure M (((induced_map A)^^N)-` B \<inter> B) > 0"
       by (simp add: Bex_def less_eq_Suc_le zero_less_iff_neq_zero)
   qed
 
   define K where "K = {B. B \<in> sets M \<and> B \<subseteq> A}"
   have K_stable: "(induced_map A)-`B \<in> K" if "B \<in> K" for B
   proof -
     have B_meas: "B \<in> sets M" and "B \<subseteq> A" using that unfolding K_def by auto
     then have a: "(induced_map A)-`B \<subseteq> A" using induced_map_stabilizes_A by auto
     then have "(induced_map A)-`B = (induced_map A)-`B \<inter> space M" using assms sets.sets_into_space by auto
     then have "(induced_map A)-`B \<in> sets M" using induced_map_meas[OF assms] B_meas by (metis vrestr_meas vrestr_of_set)
     then show "(induced_map A)-`B \<in> K" unfolding K_def using a by auto
   qed
 
   define K0 where "K0 = K \<inter> (null_sets M)"
   have K0_stable: "(induced_map A)-`B \<in> K0" if "B \<in> K0" for B
   proof -
     have "B \<in> K" using that unfolding K0_def by simp
     then have a: "(induced_map A)-`B \<subseteq> A" and b: "(induced_map A)-`B \<in> sets M"
       using K_stable unfolding K_def by auto
     have B_meas [measurable]: "B \<in> sets M" using \<open>B \<in> K\<close> unfolding K_def by simp
     have B0: "B \<in> null_sets M" using \<open>B \<in> K0\<close> unfolding K0_def by simp
 
     have "(induced_map A)-`B \<subseteq> (\<Union>n. (T^^n)-`B)" unfolding induced_map_def by auto
     then have "(induced_map A)-`B \<subseteq> (\<Union>n. (T^^n)-`B \<inter> space M)"
       using b sets.sets_into_space by simp blast
     then have inc: "(induced_map A)-`B \<subseteq> (\<Union>n. (T^^n)--`B)" unfolding vimage_restr_def
       using sets.sets_into_space [OF B_meas] by simp
 
     have "(T^^n)--`B \<in> null_sets M" for n using B0 T_quasi_preserves_null(2)[OF B_meas] by simp
     then have "(\<Union>n. (T^^n)--`B) \<in> null_sets M" using null_sets_UN by auto
     then have "(induced_map A)-`B \<in> null_sets M" using null_sets_subset[OF _ b inc] by auto
     then show "(induced_map A)-`B \<in> K0" unfolding K0_def K_def by (simp add: a b)
   qed
 
   have *: "D \<in> null_sets M \<longleftrightarrow> D \<in> null_sets (restrict_space M A)" if "D\<in>K" for D
     using that unfolding K_def apply auto
     apply (metis assms emeasure_restrict_space null_setsD1 null_setsI sets.Int_space_eq2 sets_restrict_space_iff)
     by (metis assms emeasure_restrict_space null_setsD1 null_setsI sets.Int_space_eq2)
 
   show "induced_map A \<in> quasi_measure_preserving (restrict_space M A) (restrict_space M A)"
     unfolding quasi_measure_preserving_def
   proof (auto)
     have "induced_map A \<in> A \<rightarrow> A" using induced_map_stabilizes_A by auto
     then show a: "induced_map A \<in> measurable (restrict_space M A) (restrict_space M A)"
       using measurable_restrict_space3[where ?A = A and ?B = A and ?M = M and ?N = M] induced_map_meas[OF A_meas] by auto
 
     fix B assume H: "B \<in> sets (restrict_space M A)"
                     "induced_map A -`B \<inter> space (restrict_space M A) \<in> null_sets (restrict_space M A)"
     then have "B \<in> K" unfolding K_def by (metis assms mem_Collect_eq sets.Int_space_eq2 sets_restrict_space_iff)
     then have B_meas [measurable]: "B \<in> sets M" and B_incl: "B \<subseteq> A" unfolding K_def by auto
     have "induced_map A -`B \<in> K" using K_stable \<open>B \<in> K\<close> by auto
     then have B2_meas: "induced_map A -`B \<in> sets M" and B2_incl: "induced_map A -`B \<subseteq> A"
       unfolding K_def by auto
     have "induced_map A -` B = induced_map A -`B \<inter> space (restrict_space M A)"
       using B2_incl by (simp add: Int_absorb2 assms space_restrict_space)
     then have "induced_map A -` B \<in> null_sets (restrict_space M A)" using H(2) by simp
     then have "induced_map A -` B \<in> K0" unfolding K0_def using \<open>induced_map A -`B \<in> K\<close> * by auto
     {
       fix n
       have *: "((induced_map A)^^(n+1))-`B \<in> K0"
       proof (induction n)
         case (Suc n)
         have "((induced_map A)^^(Suc n+1))-`B = (induced_map A)-`(((induced_map A)^^(n+1))-` B)"
           by (metis Suc_eq_plus1 funpow_Suc_right vimage_comp)
         then show ?case by (metis Suc.IH K0_stable)
       qed (auto simp add: \<open>induced_map A -` B \<in> K0\<close>)
       have **: "((induced_map A)^^(n+1))-` B \<in> sets M" using * K0_def K_def by auto
       have "((induced_map A)^^(n+1))-` B \<inter> B \<in> null_sets M"
         apply (rule null_sets_subset[of "((induced_map A)^^(n+1))-`B"])
         using * unfolding K0_def apply simp
         using ** by auto
     }
     then have "((induced_map A)^^n)-` B \<inter> B \<in> null_sets M" if "n>0" for n
       using that by (metis Suc_eq_plus1 neq0_conv not0_implies_Suc)
     then have "B \<in> null_sets M" using imp B_incl B_meas zero_less_iff_neq_zero inf.strict_order_iff
       by (metis null_setsD1 null_setsI)
     then show "B \<in> null_sets (restrict_space M A)" using * \<open>B \<in> K\<close> by auto
   next
     fix B assume H: "B \<in> sets (restrict_space M A)"
                     "B \<in> null_sets (restrict_space M A)"
     then have "B \<in> K" unfolding K_def by (metis assms mem_Collect_eq sets.Int_space_eq2 sets_restrict_space_iff)
     then have B_meas [measurable]: "B \<in> sets M" and B_incl: "B \<subseteq> A" unfolding K_def by auto
     have "B \<in> null_sets M" using * H(2) \<open>B \<in> K\<close> by simp
     then have "B \<in> K0" unfolding K0_def using \<open>B \<in> K\<close> by simp
     then have inK: "(induced_map A)-`B \<in> K0" using K0_stable by auto
     then have inA: "(induced_map A)-`B \<subseteq> A" unfolding K0_def K_def by auto
     then have "(induced_map A)-`B = (induced_map A)-`B \<inter> space (restrict_space M A)"
       by (simp add: Int_absorb2 assms space_restrict_space2)
     then show "induced_map A -` B \<inter> space (restrict_space M A) \<in> null_sets (restrict_space M A)"
       using * inK unfolding K0_def by auto
   qed
 
   fix B
   assume B_measA: "B \<in> sets (restrict_space M A)" and B_posA: "0 < emeasure (restrict_space M A) B"
   then have B_meas: "B \<in> sets M" by (metis assms sets.Int_space_eq2 sets_restrict_space_iff)
   have B_incl: "B \<subseteq> A" by (metis B_measA assms sets.Int_space_eq2 sets_restrict_space_iff)
   then have B_pos: "0 < emeasure M B" using B_posA by (simp add: assms emeasure_restrict_space)
   obtain N where "N>0" "emeasure M (((induced_map A)^^N)-`B \<inter> B) > 0" using imp B_meas B_incl B_pos by auto
   then have "emeasure (restrict_space M A) ((induced_map A ^^ N) -` B \<inter> B) > 0"
     using assms emeasure_restrict_space by (metis B_incl Int_lower2 sets.Int_space_eq2 subset_trans)
   then show "\<exists>n>0. 0 < emeasure (restrict_space M A) ((induced_map A ^^ n) -` B \<inter> B)"
     using \<open>N > 0\<close> by auto
 qed
 
 text \<open>Now, we want to prove that, if a map is conservative and measure preserving, then
 the induced map is also measure preserving. We first prove it for subsets $W$ of $A$ of finite
 measure, the general case will readily follow.
 
 The argument uses the fact that the preimage of the set of points with first entrance time $n$
 is the union of the set of points with first entrance time $n+1$, and the points of $A$ with
 first return $n+1$. Following the preimage of $W$ under this process, we will get the intersection
 of $T_A^{-1} W$ with the different elements of the return partition, and the points in $T^{-n}W$
 whose first $n-1$ iterates do not meet $A$ (and the measures of these sets add up to $\mu(W)$).
 To conclude, it suffices to show that the measure of points in $T^{-n}W$
 whose first $n-1$ iterates do not meet $A$ tends to $0$. This follows from our local times
 estimates above.\<close>
 
 lemma (in conservative_mpt) induced_map_measure_preserving_aux:
   assumes A_meas [measurable]: "A \<in> sets M"
       and W_meas [measurable]: "W \<in> sets M"
       and incl: "W \<subseteq> A"
       and fin: "emeasure M W < \<infinity>"
   shows "emeasure M ((induced_map A)--`W) = emeasure M W"
 proof -
   have "W \<subseteq> space M" using W_meas
     using sets.sets_into_space by blast
   define BW where "BW = (\<lambda>n. (first_entrance_set A n) \<inter> (T^^n)--`W)"
   define DW where "DW = (\<lambda>n. (return_time_function A)-` {n} \<inter> (induced_map A)--`W)"
 
   have "\<And>n. DW n = (return_time_function A)-` {n} \<inter> space M \<inter> (induced_map A)--`W"
     using DW_def by auto
   then have DW_meas [measurable]: "\<And>n. DW n \<in> sets M" by auto
   have disj_DW: "disjoint_family (\<lambda>n. DW n)" using DW_def disjoint_family_on_def by blast
   then have disj_DW2: "disjoint_family (\<lambda>n. DW (n+1))" by (simp add: disjoint_family_on_def)
 
   have "(\<Union>n. DW n) = DW 0 \<union> (\<Union>n. DW (n+1))" by (auto) (metis not0_implies_Suc)
   moreover have "(DW 0) \<inter> (\<Union>n. DW (n+1)) = {}"
     by (auto) (metis IntI Suc_neq_Zero UNIV_I empty_iff disj_DW disjoint_family_on_def)
   ultimately have *: "emeasure M (\<Union>n. DW n) = emeasure M (DW 0) + emeasure M (\<Union>n. DW (n+1))"
     by (simp add: countable_Un_Int(1) plus_emeasure)
 
   have "DW 0 = (return_time_function A)-` {0} \<inter> W"
     unfolding DW_def induced_map_def return_time_function_def
     apply (auto simp add: return_time0[of A]) using sets.sets_into_space[OF W_meas] by auto
   also have "... = W - recurrent_subset A" using return_time0 by blast
   also have "... \<subseteq> A - recurrent_subset A" using incl by blast
   finally have "DW 0 \<in> null_sets M" by (metis A_meas DW_meas null_sets_subset Poincare_recurrence_thm(1))
   then have "emeasure M (DW 0) = 0" by auto
   have "(induced_map A)--`W = (\<Union>n. DW n)" using DW_def by blast
   then have "emeasure M ((induced_map A)--`W) = emeasure M (\<Union>n. DW n)" by simp
   also have "... = emeasure M (\<Union>n. DW (n+1))" using * \<open>emeasure M (DW 0) = 0\<close> by simp
   also have "... = (\<Sum>n. emeasure M (DW (n+1)))"
     apply (rule suminf_emeasure[symmetric]) using disj_DW2 by auto
   finally have m: "emeasure M ((induced_map A)--`W) = (\<Sum>n. emeasure M (DW (n+1)))" by simp
   moreover have "summable (\<lambda>n. emeasure M (DW (n+1)))" by simp
   ultimately have lim: "(\<lambda>N. (\<Sum> n\<in>{..<N}. emeasure M (DW (n+1)))) \<longlonglongrightarrow> emeasure M ((induced_map A)--`W)"
     by (simp add: summable_LIMSEQ)
 
   have BW_meas [measurable]: "\<And>n. BW n \<in> sets M" unfolding BW_def by simp
   have *: "\<And>n. T--`(BW n) - A = BW (n+1)"
   proof -
     fix n
     have "T--`(BW n) = T--`(first_entrance_set A n) \<inter> (T^^(n+1))--`W"
       unfolding BW_def by (simp add: assms(2) T_vrestr_composed(2))
     then have "T--`(BW n) - A = (T--`(first_entrance_set A n) - A) \<inter> (T^^(n+1))--`W"
       by blast
     then have "T--`(BW n) - A = first_entrance_set A (n+1) \<inter> (T^^(n+1))--`W"
       using first_entrance_rec[OF A_meas] by simp
     then show "T--`(BW n) - A = BW (n+1)" using BW_def by simp
   qed
 
   have **: "DW (n+1) = T--`(BW n) \<inter> A" for n
   proof -
     have "T--`(BW n) = T--`(first_entrance_set A n) \<inter> (T^^(n+1))--`W"
       unfolding BW_def by (simp add: assms(2) T_vrestr_composed(2))
     then have "T--`(BW n) \<inter> A = (T--`(first_entrance_set A n) \<inter> A) \<inter> (T^^(n+1))--`W"
       by blast
     then have *: "T--`(BW n) \<inter> A = (return_time_function A)-`{n+1} \<inter> (T^^(n+1))--`W"
       using return_time_rec[OF A_meas] by simp
 
     have "DW (n+1) = (return_time_function A)-`{n+1} \<inter> (induced_map A)-`W"
       using DW_def \<open>W \<subseteq> space M\<close> return_time_rec by auto
     also have "... = (return_time_function A)-`{n+1} \<inter> (T^^(n+1))-`W"
       by (auto simp add: induced_map_def)
     also have "... = (return_time_function A)-`{n+1} \<inter> (T^^(n+1))--`W"
       using \<open>W \<subseteq> space M\<close> return_time_rec by auto
     finally show "DW (n+1) = T--`(BW n) \<inter> A" using * by simp
   qed
 
   have "emeasure M W = (\<Sum> n\<in>{..<N}. emeasure M (DW (n+1))) + emeasure M (BW N)" for N
   proof (induction N)
     case 0
     have "BW 0 = W" unfolding BW_def first_entrance_set_def using incl by auto
     then show ?case by simp
   next
     case (Suc N)
     have "T--`(BW N) = BW (N+1) \<union> DW (N+1)" using * ** by blast
     moreover have "BW (N+1) \<inter> DW (N+1) = {}" using * ** by blast
     ultimately have "emeasure M (T--`(BW N)) = emeasure M (BW (N+1)) + emeasure M (DW (N+1))"
       using DW_meas BW_meas plus_emeasure[of "BW (N+1)"] by simp
     then have "emeasure M (BW N) = emeasure M (BW (N+1)) + emeasure M (DW (N+1))"
       using T_vrestr_same_emeasure(1) BW_meas by auto
     then have "(\<Sum> n\<in>{..<N}. emeasure M (DW (n+1))) + emeasure M (BW N)
                 = (\<Sum> n\<in>{..<N+1}. emeasure M (DW (n+1))) + emeasure M (BW (N+1))"
       by (simp add: add.commute add.left_commute)
     then show ?case using Suc.IH by simp
   qed
   moreover
   have "(\<lambda>N. emeasure M (BW N)) \<longlonglongrightarrow> 0"
   proof (rule tendsto_sandwich[of "\<lambda>_. 0"_ _ "\<lambda>N. emeasure M {x \<in> (T^^N)--`W. local_time A N x < 1}"])
     have "emeasure M (BW N) \<le> emeasure M {x \<in> (T^^N)--`W. local_time A N x < 1}" for N
       apply (rule emeasure_mono) unfolding BW_def local_time_def first_entrance_set_def by auto
     then show "\<forall>\<^sub>F n in sequentially. emeasure M (BW n) \<le> emeasure M {x \<in> (T ^^ n) --` W. local_time A n x < 1}"
       by auto
     have i: "W \<subseteq> (T^^0)--`A" using incl by auto
     show "(\<lambda>N. emeasure M {x \<in> (T ^^ N) --` W. local_time A N x < 1}) \<longlonglongrightarrow> 0"
       apply (rule local_time_unbounded2[OF _ _ i]) using fin by auto
   qed (auto)
   then have "(\<lambda>N. (\<Sum> n\<in>{..<N}. emeasure M (DW (n+1))) + emeasure M (BW N)) \<longlonglongrightarrow> emeasure M (induced_map A --` W) + 0"
     using lim by (intro tendsto_add) auto
   ultimately show ?thesis
     by (auto intro: LIMSEQ_unique LIMSEQ_const_iff)
 qed
 
 lemma (in conservative_mpt) induced_map_measure_preserving:
   assumes A_meas [measurable]: "A \<in> sets M"
       and W_meas [measurable]: "W \<in> sets M"
   shows "emeasure M ((induced_map A)--`W) = emeasure M W"
 proof -
   define WA where "WA = W \<inter> A"
   have WA_meas [measurable]: "WA \<in> sets M" "WA \<subseteq> A" using WA_def by auto
   have WAi_meas [measurable]: "(induced_map A)--`WA \<in> sets M" by simp
   have a: "emeasure M WA = emeasure M ((induced_map A)--`WA)"
   proof (cases)
     assume "emeasure M WA < \<infinity>"
     then show ?thesis using induced_map_measure_preserving_aux[OF A_meas, OF \<open>WA \<in> sets M\<close>, OF \<open>WA \<subseteq> A\<close>] by simp
   next
     assume "\<not>(emeasure M WA < \<infinity>)"
     then have "emeasure M WA = \<infinity>" by (simp add: less_top[symmetric])
     {
       fix C::real
       obtain Z where "Z \<in> sets M" "Z \<subseteq> WA" "emeasure M Z < \<infinity>" "emeasure M Z > C"
         by (blast intro: \<open>emeasure M WA = \<infinity>\<close> WA_meas approx_PInf_emeasure_with_finite)
       have "Z \<subseteq> A" using \<open>Z \<subseteq> WA\<close> WA_def by simp
       have "C < emeasure M Z" using \<open>emeasure M Z > C\<close> by simp
       also have "... = emeasure M ((induced_map A)--`Z)"
         using induced_map_measure_preserving_aux[OF A_meas, OF \<open>Z \<in> sets M\<close>, OF \<open>Z \<subseteq> A\<close>] \<open>emeasure M Z < \<infinity>\<close> by simp
       also have "... \<le> emeasure M ((induced_map A)--`WA)"
         apply(rule emeasure_mono) using \<open>Z \<subseteq> WA\<close> vrestr_inclusion by auto
       finally have "emeasure M ((induced_map A)--`WA) > C" by simp
     }
     then have "emeasure M ((induced_map A)--`WA) = \<infinity>"
       by (cases "emeasure M ((induced_map A)--`WA)") auto
     then show ?thesis using \<open>emeasure M WA = \<infinity>\<close> by simp
   qed
   define WB where "WB = W - WA"
   have WB_meas [measurable]: "WB \<in> sets M" unfolding WB_def by simp
   have WBi_meas [measurable]: "(induced_map A)--`WB \<in> sets M" by simp
   have "WB \<inter> A = {}" unfolding WB_def WA_def by auto
   moreover have id: "\<And>x. x \<notin> A \<Longrightarrow> (induced_map A x) = x" unfolding induced_map_def return_time_function_def
     apply (auto) using recurrent_subset_incl by auto
   ultimately have "(induced_map A)--`WB = WB"
     using induced_map_stabilizes_A sets.sets_into_space[OF WB_meas] apply auto
     by (metis disjoint_iff_not_equal) fastforce+
   then have b: "emeasure M ((induced_map A)--`WB) = emeasure M WB" by simp
 
   have "W = WA \<union> WB" "WA \<inter> WB = {}" using WA_def WB_def by auto
   have *: "emeasure M W = emeasure M WA + emeasure M WB"
     by (subst \<open>W = WA \<union> WB\<close>, rule plus_emeasure[symmetric], auto simp add: \<open>WA \<inter> WB = {}\<close>)
 
   have W_AUB: "(induced_map A)--`W = (induced_map A)--`WA \<union> (induced_map A)--`WB"
     using \<open>W = WA \<union> WB\<close> by auto
   have W_AIB: "(induced_map A)--`WA \<inter> (induced_map A)--`WB = {}"
     by (metis \<open>WA \<inter> WB = {}\<close> vrestr_empty vrestr_intersec)
   have "emeasure M ((induced_map A)--`W) = emeasure M ((induced_map A)--`WA) + emeasure M ((induced_map A)--`WB)"
     unfolding W_AUB by (rule plus_emeasure[symmetric]) (auto simp add: W_AIB)
 
   then show ?thesis using a b * by simp
 qed
 
 text \<open>We can now express the fact that induced maps preserve the measure.\<close>
 
 theorem (in conservative_mpt) induced_map_conservative_mpt:
   assumes "A \<in> sets M"
   shows "conservative_mpt (restrict_space M A) (induced_map A)"
 unfolding conservative_mpt_def
 proof
   show *: "conservative (restrict_space M A) (induced_map A)" using induced_map_conservative[OF assms] by auto
   show "mpt (restrict_space M A) (induced_map A)" unfolding mpt_def mpt_axioms_def
   proof
     show "qmpt (restrict_space M A) (induced_map A)" using * conservative_def by auto
     then have meas: "(induced_map A) \<in> measurable (restrict_space M A) (restrict_space M A)"
       unfolding qmpt_def qmpt_axioms_def quasi_measure_preserving_def by auto
     moreover have "\<And>B. B \<in> sets (restrict_space M A) \<Longrightarrow>
         emeasure (restrict_space M A) ((induced_map A) -`B \<inter> space (restrict_space M A)) = emeasure (restrict_space M A) B"
     proof -
       have s: "space (restrict_space M A) = A" using assms space_restrict_space2 by auto
       have i: "\<And>D. D \<in> sets M \<and> D \<subseteq> A \<Longrightarrow> emeasure (restrict_space M A) D = emeasure M D"
         using assms by (simp add: emeasure_restrict_space)
       have j: "\<And>D. D \<in> sets (restrict_space M A) \<longleftrightarrow> (D \<in> sets M \<and> D \<subseteq> A)" using assms
         by (metis sets.Int_space_eq2 sets_restrict_space_iff)
       fix B
       assume a: "B \<in> sets (restrict_space M A)"
       then have B_meas: "B \<in> sets M" using j by auto
       then have first: "emeasure (restrict_space M A) B = emeasure M B" using i j a by auto
       have incl: "(induced_map A) -`B \<subseteq> A" using j a induced_map_stabilizes_A assms by auto
       then have eq: "(induced_map A) -`B \<inter> space (restrict_space M A) = (induced_map A) --`B"
         unfolding vimage_restr_def s using assms sets.sets_into_space
         by (metis a inf.orderE j meas measurable_sets s)
       then have "emeasure M B = emeasure M ((induced_map A) -`B \<inter> space (restrict_space M A))"
         using induced_map_measure_preserving a j assms by auto
       also have "... = emeasure (restrict_space M A) ((induced_map A) -`B \<inter> space (restrict_space M A))"
         using incl eq B_meas induced_map_meas[OF assms] assms i j
         by (metis emeasure_restrict_space inf.orderE s space_restrict_space)
       finally show "emeasure (restrict_space M A) ((induced_map A) -`B \<inter> space (restrict_space M A))
                     = emeasure (restrict_space M A) B"
         using first by auto
     qed
     ultimately show "induced_map A \<in> measure_preserving (restrict_space M A) (restrict_space M A)"
       unfolding measure_preserving_def by auto
   qed
 qed
 
 theorem (in fmpt) induced_map_fmpt:
   assumes "A \<in> sets M"
   shows "fmpt (restrict_space M A) (induced_map A)"
 unfolding fmpt_def
 proof -
   have "conservative_mpt (restrict_space M A) (induced_map A)" using induced_map_conservative_mpt[OF assms] by simp
   then have "mpt (restrict_space M A) (induced_map A)" using conservative_mpt_def by auto
   moreover have "finite_measure (restrict_space M A)" by (simp add: assms finite_measureI finite_measure_restrict_space)
   ultimately show "mpt (restrict_space M A) (induced_map A) \<and> finite_measure (restrict_space M A)" by simp
 qed
 
 text \<open>It will be useful to reformulate the fact that the recurrent subset has full measure
 in terms of the induced measure, to simplify the use of the induced map later on.\<close>
 
 lemma (in conservative) induced_map_recurrent_typical:
   assumes A_meas [measurable]: "A \<in> sets M"
   shows "AE z in (restrict_space M A). z \<in> recurrent_subset A"
         "AE z in (restrict_space M A). z \<in> recurrent_subset_infty A"
 proof -
   have "recurrent_subset A \<in> sets M" using recurrent_subset_meas[OF A_meas] by auto
   then have rsA: "recurrent_subset A \<in> sets (restrict_space M A)" 
     using recurrent_subset_incl(1)[of A]
     by (metis (no_types, lifting) A_meas sets_restrict_space_iff space_restrict_space space_restrict_space2)
 
   have "emeasure (restrict_space M A) (space (restrict_space M A) - recurrent_subset A) = emeasure (restrict_space M A) (A - recurrent_subset A)"
     by (metis (no_types, lifting) A_meas space_restrict_space2)
   also have "... = emeasure M (A - recurrent_subset A)"
     by (simp add: emeasure_restrict_space)
   also have "... = 0" using Poincare_recurrence_thm[OF A_meas] by auto
   finally have "space (restrict_space M A) - recurrent_subset A \<in> null_sets (restrict_space M A)"
     using rsA by blast
   then show "AE z in (restrict_space M A). z \<in> recurrent_subset A"
       by (metis (no_types, lifting) DiffI eventually_ae_filter mem_Collect_eq subsetI)
 
   have "recurrent_subset_infty A \<in> sets M" using recurrent_subset_meas[OF A_meas] by auto
   then have rsiA: "recurrent_subset_infty A \<in> sets (restrict_space M A)" 
     using recurrent_subset_incl(2)[of A]
     by (metis (no_types, lifting) A_meas sets_restrict_space_iff space_restrict_space space_restrict_space2)
 
   have "emeasure (restrict_space M A) (space (restrict_space M A) - recurrent_subset_infty A) = emeasure (restrict_space M A) (A - recurrent_subset_infty A)"
     by (metis (no_types, lifting) A_meas space_restrict_space2)
   also have "... = emeasure M (A - recurrent_subset_infty A)"
     apply (rule emeasure_restrict_space) using A_meas by auto
   also have "... = 0" using Poincare_recurrence_thm[OF A_meas] by auto
   finally have "space (restrict_space M A) - recurrent_subset_infty A \<in> null_sets (restrict_space M A)"
     using rsiA by blast
   then show "AE z in (restrict_space M A). z \<in> recurrent_subset_infty A"
     by (metis (no_types, lifting) DiffI eventually_ae_filter mem_Collect_eq subsetI)
 qed
 
 
 subsection \<open>Kac's theorem, and variants\<close>
 
 text \<open>Kac's theorem states that, for conservative maps, the integral of the return time
 to a subset $A$ is equal to the measure of the space if the dynamics is ergodic, or of the
 space seen by $A$ in the general case.
 
 This result generalizes to any induced function, not just the return time, that we define now.\<close>
 
 definition induced_function::"'a set \<Rightarrow> ('a \<Rightarrow> 'b::comm_monoid_add) \<Rightarrow> ('a \<Rightarrow> 'b)"
   where "induced_function A f = (\<lambda>x. (\<Sum>i\<in>{..< return_time_function A x}. f((T^^i) x)))"
 
 text \<open>By definition, the induced function is supported on the recurrent subset of $A$.\<close>
 
 lemma induced_function_support:
   fixes f::"'a \<Rightarrow> ennreal"
   shows "induced_function A f y = induced_function A f y * indicator ((return_time_function A)-`{1..}) y"
 by (auto simp add: induced_function_def indicator_def not_less_eq_eq)
 
 text \<open>Basic measurability statements.\<close>
 
 lemma induced_function_meas_ennreal [measurable]:
   fixes f::"'a \<Rightarrow> ennreal"
   assumes [measurable]: "f \<in> borel_measurable M" "A \<in> sets M"
   shows "induced_function A f \<in> borel_measurable M"
 unfolding induced_function_def by simp
 
 lemma induced_function_meas_real [measurable]:
   fixes f::"'a \<Rightarrow> real"
   assumes [measurable]: "f \<in> borel_measurable M" "A \<in> sets M"
   shows "induced_function A f \<in> borel_measurable M"
 unfolding induced_function_def by simp
 
 
 text \<open>The Birkhoff sums of the induced function for the induced map form a subsequence of the original
 Birkhoff sums for the original map, corresponding to the return times to $A$.\<close>
 
 lemma (in conservative) induced_function_birkhoff_sum:
   fixes f::"'a \<Rightarrow> real"
   assumes "A \<in> sets M"
   shows "birkhoff_sum f (qmpt.birkhoff_sum (induced_map A) (return_time_function A) n x) x
           = qmpt.birkhoff_sum (induced_map A) (induced_function A f) n x"
 proof -
   interpret A: conservative "restrict_space M A" "induced_map A" by (rule induced_map_conservative[OF assms])
   define TA where "TA = induced_map A"
   define phiA where "phiA = return_time_function A"
   define R where "R = (\<lambda>n. A.birkhoff_sum phiA n x)"
   show ?thesis
   proof (induction n)
     case 0
     show ?case using birkhoff_sum_1(1) A.birkhoff_sum_1(1) by auto
   next
     case (Suc n)
     have "(T^^(R n)) x = (TA^^n) x" unfolding TA_def R_def A.birkhoff_sum_def phiA_def by (rule induced_map_iterates[symmetric])
     have "R(n+1) = R n + phiA ((TA^^n) x)"
       unfolding R_def using A.birkhoff_sum_cocycle[where ?n = n and ?m = 1 and ?f = phiA] A.birkhoff_sum_1(2) TA_def by auto
     then have "birkhoff_sum f (R (n+1)) x = birkhoff_sum f (R n) x + birkhoff_sum f (phiA ((TA^^n) x)) ((T^^(R n)) x)"
       using birkhoff_sum_cocycle[where ?n = "R n" and ?f = f] by auto
     also have "... = birkhoff_sum f (R n) x + birkhoff_sum f (phiA ((TA^^n) x)) ((TA^^n) x)"
       using \<open>(T^^(R n)) x = (TA^^n) x\<close> by simp
     also have "... = birkhoff_sum f (R n) x + (induced_function A f) ((TA^^n) x)"
       unfolding induced_function_def birkhoff_sum_def phiA_def by simp
     also have "... = A.birkhoff_sum (induced_function A f) n x + (induced_function A f) ((TA^^n) x)" using Suc.IH R_def phiA_def by auto
     also have "... = A.birkhoff_sum (induced_function A f) (n+1) x"
       using A.birkhoff_sum_cocycle[where ?n = n and ?m = 1 and ?f = "induced_function A f" and ?x = x, symmetric]
       A.birkhoff_sum_1(2)[where ?f = "induced_function A f" and ?x = "(TA^^n) x"]
       unfolding TA_def by auto
     finally show ?case unfolding R_def phiA_def by simp
   qed
 qed
 
 text \<open>The next lemma is very simple (just a change of variables to reorder
 the indices in the double sum). However, the proof I give is very tedious:
 infinite sums on proper subsets are not handled well, hence I use integrals
 on products of discrete spaces instead, and go back and forth between the two
 notions -- maybe there are better suited tools in the library, but I could
 not locate them...
 
 This is the main combinatorial tool used in the proof of Kac's Formula.\<close>
 
 lemma kac_series_aux:
   fixes d:: "nat \<Rightarrow> nat \<Rightarrow> ennreal"
   shows "(\<Sum>n. (\<Sum>i\<le>n. d i n)) = (\<Sum>n. d 0 n) + (\<Sum>n. (\<Sum>i. d (i+1) (n+1+i)))"
     (is "_ = ?R")
 proof -
   define g where "g = (\<lambda>(i,n). (i+(1::nat), n+1+i))"
   define U where "U = {(i,n). (i>(0::nat)) \<and> (n\<ge>i)}"
   have bij: "bij_betw g UNIV U"
     by (rule bij_betw_byWitness[where ?f' = "\<lambda>(i, n). (i-1, n-i)"], auto simp add: g_def U_def)
 
   define e where "e = (\<lambda> (i,j). d i j)"
   have pos: "\<And>x. e x \<ge> 0" using e_def by auto
   have "(\<Sum>n. (\<Sum>i. d (i+1) (n+1+i))) = (\<Sum>n. (\<Sum>i. e(i+1, n+1+i)))" using e_def by simp
   also have "... = \<integral>\<^sup>+n. \<integral>\<^sup>+i. e (i+1, n+1+i) \<partial>count_space UNIV \<partial>count_space UNIV"
     using pos nn_integral_count_space_nat suminf_0_le by auto
   also have "... = (\<integral>\<^sup>+x. e (g x) \<partial>count_space UNIV)"
     unfolding g_def using nn_integral_snd_count_space[of "\<lambda>(i,n). e(i+1, n+1+i)"]
     by (auto simp add: prod.case_distrib)
   also have "... = (\<integral>\<^sup>+y \<in> U. e y \<partial>count_space UNIV)"
     using nn_integral_count_compose_bij[OF bij] by simp
   finally have *: "(\<Sum>n. (\<Sum>i. d (i+1) (n+1+i))) = (\<integral>\<^sup>+y \<in> U. e y \<partial>count_space UNIV)"
     by simp
 
   define V where "V = {((i::nat),(n::nat)). i = 0}"
   have i: "e (i, n) * indicator {0} i = e (i, n) * indicator V (i, n)" for i n
     by (auto simp add: indicator_def V_def)
   have "d 0 n = (\<integral>\<^sup>+i \<in> {0}. e (i, n) \<partial>count_space UNIV)" for n
   proof -
     have "(\<integral>\<^sup>+i \<in> {0}. e (i, n) \<partial>count_space UNIV) = (\<integral>\<^sup>+i. e (i, n) \<partial>count_space {0})"
       using nn_integral_count_space_indicator[of _ "\<lambda>i. e(i, n)"] by simp
     also have "... = e (0, n)"
       using nn_integral_count_space_finite[where ?f = "\<lambda>i. e (i, n)"] by simp
     finally show ?thesis using e_def by simp
   qed
   then have "(\<Sum>n. d 0 n) = (\<Sum>n. (\<integral>\<^sup>+i. e (i, n) * indicator {0} i \<partial>count_space UNIV))"
     by simp
   also have "... = (\<integral>\<^sup>+n. (\<integral>\<^sup>+i. e (i, n) * indicator {0} i \<partial>count_space UNIV) \<partial>count_space UNIV)"
     by (simp add: nn_integral_count_space_nat)
   also have "... = (\<integral>\<^sup>+(i,n). e (i, n) * indicator {0} i \<partial>count_space UNIV)"
     using nn_integral_snd_count_space[of "\<lambda> (i,n). e(i,n) * indicator {0} i"] by auto
   also have "... = (\<integral>\<^sup>+(i,n). e (i, n) * indicator V (i,n) \<partial>count_space UNIV)"
     by (metis i)
   finally have "(\<Sum>n. d 0 n) = (\<integral>\<^sup>+y \<in> V. e y \<partial>count_space UNIV)"
     by (simp add: split_def)
 
   then have "?R = (\<integral>\<^sup>+y \<in> V. e y \<partial>count_space UNIV) + (\<integral>\<^sup>+y \<in> U. e y \<partial>count_space UNIV)"
     using * by simp
   also have "... = (\<integral>\<^sup>+y \<in> V \<union> U. e y \<partial>count_space UNIV)"
     by (rule nn_integral_disjoint_pair_countspace[symmetric], auto simp add: U_def V_def)
   also have "... = (\<integral>\<^sup>+(i, n). e (i, n) * indicator {..n} i \<partial>count_space UNIV)"
-    by (rule nn_integral_cong, auto simp add: indicator_def V_def U_def pos, meson)
+    by (rule nn_integral_cong, auto simp add: indicator_def of_bool_def V_def U_def pos, meson)
   also have "... = (\<integral>\<^sup>+n. (\<integral>\<^sup>+i. e (i, n) * indicator {..n} i \<partial>count_space UNIV)\<partial>count_space UNIV)"
     using nn_integral_snd_count_space[of "\<lambda>(i,n). e(i,n) * indicator {..n} i"] by auto
   also have "... = (\<Sum>n. (\<Sum>i. e (i, n) * indicator {..n} i))"
     using pos nn_integral_count_space_nat suminf_0_le by auto
   moreover have "(\<Sum>i. e (i, n) * indicator {..n} i) = (\<Sum>i\<le>n. e (i, n))" for n
   proof -
     have "finite {..n}" by simp
     moreover have "\<And>i. i \<notin> {..n} \<Longrightarrow> e (i,n) * indicator {..n} i = 0" using indicator_def by simp
     then have "(\<Sum>i. e (i,n) * indicator {..n} i) = (\<Sum>i \<in> {..n} . e (i, n) * indicator {..n} i)"
       by (meson calculation suminf_finite)
     moreover have "\<And>i. i \<in> {..n} \<Longrightarrow> e (i, n) * indicator {..n} i = e (i, n)" using indicator_def by auto
     ultimately show "(\<Sum>i. e (i, n) * indicator {..n} i) = (\<Sum>i\<le>n. e (i, n))" by simp
   qed
   ultimately show ?thesis using e_def by simp
 qed
 
 end
 
 context conservative_mpt begin
 
 text \<open>We prove Kac's Formula (in the general form for induced functions) first for
 functions taking values in ennreal (to avoid all summabilities issues). The result for
 real functions will follow by domination. First, we assume additionally that $f$ is bounded
 and has a support of finite measure, the general case will follow readily by truncation.
 
 The proof is again an instance of the fact that the preimage of the set of points
 with first entrance time $n$ is the union of the set of points with first entrance time $n+1$,
 and the points of $A$ with first return $n+1$. Keeping track of the integral of $f$ on the
 different parts that appear in this argument, we will see that the integral of the induced
 function on the set of points with return time at most $n$ is equal to the integral of the function,
 up to an error controlled by the measure of points in $T^{-n}(supp(f))$ with local time $0$.
 Local time controls ensure that this contribution vanishes asymptotically.
 \<close>
 
 lemma induced_function_nn_integral_aux:
   fixes f::"'a \<Rightarrow> ennreal"
   assumes A_meas [measurable]: "A \<in> sets M"
       and f_meas [measurable]: "f \<in> borel_measurable M"
       and f_bound: "\<And>x. f x \<le> ennreal C" "0 \<le> C"
       and f_supp: "emeasure M {x \<in> space M. f x > 0} < \<infinity>"
   shows "(\<integral>\<^sup>+y. induced_function A f y \<partial>M) = (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
 proof -
   define B where "B = (\<lambda>n. first_entrance_set A n)"
   have B_meas [measurable]: "\<And>n. B n \<in> sets M" by (simp add: B_def)
   then have B2 [measurable]: "(\<Union>n. B (n+1)) \<in> sets M" by measurable
 
   have *: "B = disjointed (\<lambda>i. (T^^i)--`A)"
     by (auto simp add: B_def disjointed_def first_entrance_set_def)
   then have "disjoint_family B" by (simp add: disjoint_family_disjointed)
 
   have "(\<Union>n. (T^^n)--`A) = (\<Union>n. disjointed (\<lambda>i. (T^^i)--`A) n)" by (simp add: UN_disjointed_eq)
   then have "(\<Union>n. (T^^n)--`A) = (\<Union>n. B n)" using * by simp
   then have "(\<Union>n. (T^^n)--`A) = B 0 \<union> (\<Union>n. B (n+1))" by (auto) (metis not0_implies_Suc)
   then have "(\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M) = (\<integral>\<^sup>+ x \<in> (B 0 \<union> (\<Union>n. B (n+1))). f x \<partial>M)" by simp
   also have "... = (\<integral>\<^sup>+ x \<in> B 0. f x \<partial>M) + (\<integral>\<^sup>+ x \<in> (\<Union>n. B (n+1)). f x \<partial>M)"
   proof (rule nn_integral_disjoint_pair)
     show "B 0 \<inter> (\<Union>n. B (n+1)) = {}"
       by (auto) (metis IntI Suc_neq_Zero UNIV_I empty_iff \<open>disjoint_family B\<close> disjoint_family_on_def)
   qed auto
   finally have "(\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M) = (\<integral>\<^sup>+ x \<in> B 0. f x \<partial>M) + (\<integral>\<^sup>+ x \<in> (\<Union>n. B (n+1)). f x \<partial>M)"
     by simp
   moreover have "(\<integral>\<^sup>+ x \<in> (\<Union>n. B (n+1)). f x \<partial>M) = (\<Sum>n. (\<integral>\<^sup>+ x \<in> B (n+1). f x \<partial>M))"
     apply (rule nn_integral_disjoint_family) using \<open>disjoint_family B\<close> by (auto simp add: disjoint_family_on_def)
   ultimately have Bdec: "(\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M) = (\<integral>\<^sup>+ x \<in> B 0. f x \<partial>M) + (\<Sum>n. \<integral>\<^sup>+ x \<in> B (n+1). f x \<partial>M)" by simp
 
   define D where "D = (\<lambda>n. (return_time_function A)-` {n+1})"
   then have "disjoint_family D" by (auto simp add: disjoint_family_on_def)
   have *: "\<And>n. D n = T--`(B n) \<inter> A"
     using D_def B_def return_time_rec[OF assms(1)] by simp
   then have [measurable]: "\<And>n. D n \<in> sets M" by simp
   have **: "\<And>n. B (n+1) = T--`(B n) - A" using first_entrance_rec[OF assms(1)] B_def by simp
 
   have pos0: "\<And>i x. f((T^^i)x) \<ge> 0" using assms(3) by simp
   have pos:"\<And> i C x. f((T^^i)x) * indicator (C) x \<ge> 0" using assms(3) by simp
   have mes0 [measurable]: "\<And> i. (\<lambda>x. f((T^^i)x)) \<in> borel_measurable M" by simp
   then have [measurable]: "\<And> i C. C \<in> sets M \<Longrightarrow> (\<lambda>x. f((T^^i)x) * indicator C x) \<in> borel_measurable M" by simp
 
   have "\<And>y. induced_function A f y = induced_function A f y * indicator ((return_time_function A)-`{1..}) y"
     by (rule induced_function_support)
   moreover have "(return_time_function A)-`{(1::nat)..} = (\<Union>n. D n)"
     by (auto simp add: D_def Suc_le_D)
   ultimately have "\<And>y. induced_function A f y = induced_function A f y * indicator (\<Union>n. D n) y" by simp
   then have "(\<integral>\<^sup>+y. induced_function A f y \<partial>M) = (\<integral>\<^sup>+y \<in> (\<Union>n. D n). induced_function A f y \<partial>M)" by simp
   also have "... = (\<Sum>n. (\<integral>\<^sup>+y \<in> D n. induced_function A f y \<partial>M))"
     apply (rule nn_integral_disjoint_family)
     unfolding induced_function_def by (auto simp add: pos0 sum_nonneg \<open>disjoint_family D\<close>)
   finally have a: "(\<integral>\<^sup>+y. induced_function A f y \<partial>M) = (\<Sum>n. (\<integral>\<^sup>+y \<in> D n. induced_function A f y \<partial>M))"
     by simp
 
   define d where "d = (\<lambda>i n. (\<integral>\<^sup>+y \<in> D n. f((T^^i)y) \<partial>M))"
 
   have "(\<integral>\<^sup>+y \<in> D n. induced_function A f y \<partial>M) = (\<Sum>i\<in>{..n}. d i n)" for n
   proof -
     have "induced_function A f y * indicator (D n) y = (\<Sum>i\<in>{..<n+1}. f((T^^i)y) * indicator (D n) y)" for y
       by (auto simp add: induced_function_def D_def indicator_def)
     then have "(\<integral>\<^sup>+y \<in> D n. induced_function A f y \<partial>M) = (\<Sum>i\<in>{..<n+1}. (\<integral>\<^sup>+y \<in> D n. f((T^^i)y) \<partial>M))"
       using pos nn_integral_sum[of "{..<n+1}", of "\<lambda>i y. f((T^^i)y) * indicator (D n) y"] by simp
     also have "... = (\<Sum>i\<in>{..n}. (\<integral>\<^sup>+y \<in> D n. f((T^^i)y) \<partial>M))"
       using lessThan_Suc_atMost by auto
     finally show ?thesis using d_def by simp
   qed
   then have induced_dec: "(\<integral>\<^sup>+y. induced_function A f y \<partial>M) = (\<Sum>n. (\<Sum>i\<in>{..n}. d i n))"
     using a by simp
 
   have "(\<Union>n\<in>{1..}. (return_time_function A)-` {n}) = UNIV - (return_time_function A)-` {0}" by auto
   then have "(\<Union>n\<in>{1..}. (return_time_function A)-` {n}) = recurrent_subset A"
     using return_time0 by auto
   moreover have "(\<Union>n. (return_time_function A)-` {n+1}) = (\<Union>n\<in>{1..}. (return_time_function A)-` {n})"
     by (auto simp add: Suc_le_D)
   ultimately have "(\<Union>n. D n) = recurrent_subset A" using D_def by simp
   moreover have "(\<integral>\<^sup>+x \<in> A. f x \<partial>M) = (\<integral>\<^sup>+x \<in> recurrent_subset A. f x \<partial>M)"
     by (rule nn_integral_null_delta, auto simp add: Diff_mono Un_absorb2 recurrent_subset_incl(1)[of A] Poincare_recurrence_thm(1)[OF assms(1)])
   moreover have "B 0 = A" using B_def first_entrance_set_def by simp
   ultimately have "(\<integral>\<^sup>+x \<in> B 0. f x \<partial>M) = (\<integral>\<^sup>+x \<in> (\<Union>n. D n). f x \<partial>M)" by simp
   also have "... = (\<Sum>n. (\<integral>\<^sup>+x \<in> D n. f x \<partial>M))"
     by (rule nn_integral_disjoint_family, auto simp add: \<open>disjoint_family D\<close>)
   finally have B0dec: "(\<integral>\<^sup>+x \<in> B 0. f x \<partial>M) = (\<Sum>n. d 0 n)" using d_def by simp
 
   have *: "(\<integral>\<^sup>+x \<in> B n. f x \<partial>M) = (\<Sum>i<k. (\<integral>\<^sup>+x \<in> D(n+i). f((T^^(i+1))x) \<partial>M)) + (\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M)" for n k
   proof (induction k)
     case 0
     show ?case by simp
   next
     case (Suc k)
     have "T--`(B(n+k)) = B(n+k+1) \<union> D(n+k)" using * ** by blast
 
     have "(\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M) = (\<integral>\<^sup>+x. (\<lambda>x. f((T^^k)x) * indicator (B (n+k)) x)(T x) \<partial>M)"
       by (rule measure_preserving_preserves_nn_integral[OF Tm], auto simp add: pos)
     also have "... = (\<integral>\<^sup>+x. f((T^^(k+1))x) * indicator (T--`(B (n+k))) x \<partial>M)"
     proof (rule nn_integral_cong_AE)
       have "(T^^k)(T x) = (T^^(k+1))x" for x
         using comp_eq_dest_lhs by (metis Suc_eq_plus1 funpow.simps(2) funpow_swap1)
       moreover have "AE x in M. f((T^^k)(T x)) * indicator (B (n+k)) (T x) = f((T^^k)(T x)) * indicator (T--`(B (n+k))) x"
         by (simp add: indicator_def \<open>\<And>n. B n \<in> sets M\<close>)
       ultimately show "AE x in M. f((T^^k)(T x)) * indicator (B (n+k)) (T x) = f((T^^(k+1))x) * indicator (T--`(B (n+k))) x"
         by simp
     qed
     also have "... = (\<integral>\<^sup>+x \<in> B(n+k+1) \<union> D(n+k). f((T^^(k+1))x) \<partial>M)"
       using \<open>T--`(B(n+k)) = B(n+k+1) \<union> D(n+k)\<close> by simp
     also have "... = (\<integral>\<^sup>+x \<in> B(n+k+1). f((T^^(k+1))x) \<partial>M) + (\<integral>\<^sup>+x \<in> D(n+k). f((T^^(k+1))x) \<partial>M)"
     proof (rule nn_integral_disjoint_pair[OF mes0[of "k+1"]])
       show "B(n+k+1) \<inter> D(n+k) = {}" using * ** by blast
     qed (auto)
     finally have "(\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M) = (\<integral>\<^sup>+x \<in> B(n+k+1). f((T^^(k+1))x) \<partial>M) + (\<integral>\<^sup>+x \<in> D(n+k). f((T^^(k+1))x) \<partial>M)"
       by simp
     then show ?case by (simp add: Suc.IH add.commute add.left_commute)
   qed
 
   have a: "(\<lambda>k. (\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M)) \<longlonglongrightarrow> 0" for n
   proof -
     define W where "W = {x \<in> space M. f x > 0} \<inter> (T^^n)--`A"
     have "emeasure M W \<le> emeasure M {x \<in> space M. f x > 0}"
       by (intro emeasure_mono, auto simp add: W_def)
     then have W_fin: "emeasure M W < \<infinity>" using f_supp by auto
     have W_meas [measurable]: "W \<in> sets M" unfolding W_def by simp
     have W_incl: "W \<subseteq> (T^^n)--`A" unfolding W_def by simp
 
     define V where "V = (\<lambda>k. {x \<in> (T^^k)--`W. local_time A k x = 0})"
     have V_meas [measurable]: "V k \<in> sets M" for k unfolding V_def by simp
     have a: "(\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M) \<le> C * emeasure M (V k)" for k
     proof -
       have "f((T^^k)x) * indicator (B(n+k)) x = f((T^^k)x) * indicator (B(n+k) \<inter> (T^^k)--`W) x" for x
       proof (cases)
         assume "f((T^^k)x) * indicator (B(n+k)) x = 0"
         then show ?thesis by (simp add: indicator_def)
       next
         assume "\<not>(f((T^^k)x) * indicator (B(n+k)) x = 0)"
         then have H: "f((T^^k)x) * indicator (B(n+k)) x \<noteq> 0" by simp
         then have inB: "x \<in> B(n+k)" using H using indicator_simps(2) by fastforce
         then have s: "x \<in> space M" using B_meas[of "n+k"] sets.sets_into_space by blast
         then have a: "(T^^k)x \<in> space M" by (metis measurable_space Tn_meas[of k])
 
         have "f((T^^k)x) > 0" using H by (simp add: le_neq_trans)
         then have *: "(T^^k)x \<in> {y \<in> space M. f y > 0}" using a by simp
 
         have "(T^^(n+k))x \<in> A" using inB B_def first_entrance_set_def by auto
         then have "(T^^n)((T^^k)x) \<in> A" by (simp add: funpow_add)
         then have "(T^^k)x \<in> (T^^n)--`A" using a by auto
         then have "(T^^k)x \<in> W" using * W_def by simp
         then have "x \<in> (T^^k)--`W" using s a by simp
         then have "x \<in> (B(n+k) \<inter> (T^^k)--`W)" using inB by simp
         then show ?thesis by auto
       qed
       then have *: "(\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M) = (\<integral>\<^sup>+x \<in> B(n+k) \<inter> (T^^k)--`W. f((T^^k)x) \<partial>M)"
         by simp
       have "B(n+k) \<subseteq> {x \<in> space M. local_time A k x = 0}"
         unfolding local_time_def B_def first_entrance_set_def by auto
       then have "B(n+k) \<inter> (T^^k)--`W \<subseteq> V k" unfolding V_def by blast
       then have "f((T^^k)x) * indicator (B(n+k) \<inter> (T^^k)--`W) x \<le> ennreal C * indicator (V k) x" for x
         using f_bound by (auto split: split_indicator)
       then have "(\<integral>\<^sup>+x \<in> B(n+k) \<inter> (T^^k)--`W. f((T^^k)x) \<partial>M) \<le> (\<integral>\<^sup>+x. ennreal C * indicator (V k) x \<partial>M)"
         by (simp add: nn_integral_mono)
       also have "... = ennreal C * emeasure M (V k)" by (simp add: \<open>0 \<le> C\<close> nn_integral_cmult)
       finally show "(\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M) \<le> C * emeasure M (V k)" using * by simp
     qed
 
     have "(\<lambda>k. emeasure M (V k)) \<longlonglongrightarrow> 0" unfolding V_def
       using local_time_unbounded2[OF W_meas, OF W_fin, OF W_incl, of 1] by auto
     from ennreal_tendsto_cmult[OF _ this, of C]
     have t0: "(\<lambda>k. C * emeasure M (V k)) \<longlonglongrightarrow> 0"
       by simp
     from a show "(\<lambda>k. (\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M)) \<longlonglongrightarrow> 0"
       by (intro tendsto_sandwich[OF _ _ tendsto_const t0]) auto
   qed
   have b: "(\<lambda>k. (\<Sum>i<k.(\<integral>\<^sup>+x \<in> D(n+i). f((T^^(i+1))x) \<partial>M))) \<longlonglongrightarrow> (\<Sum>i. d (i+1) (n+i))" for n
   proof -
     define e where "e = (\<lambda>i. d (i+1) (n+i))"
     then have "(\<lambda>k. (\<Sum>i<k. e i)) \<longlonglongrightarrow> (\<Sum>i. e i)"
       by (intro summable_LIMSEQ) simp
     then show "(\<lambda>k. (\<Sum>i<k.(\<integral>\<^sup>+x \<in> D(n+i). f((T^^(i+1))x) \<partial>M))) \<longlonglongrightarrow> (\<Sum>i. d (i+1) (n+i))"
       using e_def d_def by simp
   qed
 
   have "(\<lambda>k. (\<Sum>i<k. (\<integral>\<^sup>+x \<in> D(n+i). f((T^^(i+1))x) \<partial>M)) + (\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M))
                 \<longlonglongrightarrow> (\<Sum>i. d (i+1) (n+i))" for n
     using tendsto_add[OF b a] by simp
   moreover have "(\<lambda>k. (\<Sum>i<k. (\<integral>\<^sup>+x \<in> D(n+i). f((T^^(i+1))x) \<partial>M)) + (\<integral>\<^sup>+x \<in> B(n+k). f((T^^k)x) \<partial>M))
                 \<longlonglongrightarrow> (\<integral>\<^sup>+x \<in> B n. f x \<partial>M)" for n using * by simp
   ultimately have "(\<integral>\<^sup>+x \<in> B n. f x \<partial>M) = (\<Sum>i. d (i+1) (n+i))" for n using LIMSEQ_unique by blast
   then have "(\<Sum>n. (\<integral>\<^sup>+x \<in> B (n+1). f x \<partial>M)) = (\<Sum>n. (\<Sum>i. d (i+1) (n+1+i)))" by simp
   then have "(\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M) = (\<Sum>n. d 0 n) + (\<Sum>n. (\<Sum>i. d (i+1) (n+1+i)))"
     using Bdec B0dec by simp
   then show ?thesis using induced_dec kac_series_aux by simp
 qed
 
 text \<open>We remove the boundedness assumption on $f$ and the finiteness assumption on its support
 by truncation (both in space and on the values of $f$).\<close>
 
 theorem induced_function_nn_integral:
   fixes f::"'a \<Rightarrow> ennreal"
   assumes A_meas [measurable]: "A \<in> sets M"
       and f_meas [measurable]: "f \<in> borel_measurable M"
   shows "(\<integral>\<^sup>+y. induced_function A f y \<partial>M) = (\<integral>\<^sup>+x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
 proof -
   obtain Y::"nat \<Rightarrow> 'a set" where Y_meas: "\<And> n. Y n \<in> sets M" and Y_fin: "\<And>n. emeasure M (Y n) \<noteq> \<infinity>"
         and Y_full: "(\<Union>n. Y n) = space M" and Y_inc: "incseq Y"
     by (meson range_subsetD sigma_finite_incseq)
   define F where "F = (\<lambda>(n::nat) x. min (f x) n * indicator (Y n) x)"
   have mes [measurable]: "\<And>n. (F n) \<in> borel_measurable M" unfolding F_def using assms(2) Y_meas by measurable
   then have mes_rel [measurable]: "(\<lambda>x. F n x * indicator (\<Union>n. (T^^n)--`A) x) \<in> borel_measurable M" for n
     by measurable
   have bound: "\<And>n x. F n x \<le> ennreal n" by (simp add: F_def indicator_def ennreal_of_nat_eq_real_of_nat)
   have "\<And>n. {x \<in> space M. F n x > 0} \<subseteq> Y n" unfolding F_def using not_le by fastforce
   then have le: "emeasure M {x \<in> space M. F n x > 0} \<le> emeasure M (Y n)" for n by (metis emeasure_mono Y_meas)
   have fin: "emeasure M {x \<in> space M. F n x > 0} < \<infinity>" for n
     using Y_fin[of n] le[of n] by (simp add: less_top)
   have *: "(\<integral>\<^sup>+y. induced_function A (F n) y \<partial>M) = (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). (F n) x \<partial>M)" for n
     by (rule induced_function_nn_integral_aux[OF A_meas mes bound _ fin]) simp
 
   have inc_Fx: "\<And>x. incseq (\<lambda>n. F n x)" unfolding F_def incseq_def
   proof (auto simp add: incseq_def)
     fix x::"'a" and m n::"nat"
     assume "m \<le> n"
     then have "min (f x) m \<le> min (f x) n" using linear by fastforce
     moreover have "(indicator (Y m) x::ennreal) \<le> (indicator (Y n) x::ennreal)" using Y_inc
       apply (auto simp add: incseq_def) using \<open>m \<le> n\<close> by blast
     ultimately show "min (f x) m * (indicator (Y m) x::ennreal) \<le> min (f x) n * (indicator (Y n) x::ennreal)"
       by (auto split: split_indicator)
   qed
   then have "incseq (\<lambda>n. F n x * indicator (\<Union>n. (T^^n)--`A) x)" for x
     by (auto simp add: indicator_def incseq_def)
   then have inc_rel: "incseq (\<lambda>n x. F n x * indicator (\<Union>n. (T^^n)--`A) x)" by (auto simp add: incseq_def le_fun_def)
   then have a: "(SUP n. (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). F n x \<partial>M))
               = (\<integral>\<^sup>+ x. (SUP n. F n x * indicator (\<Union>n. (T^^n)--`A) x) \<partial>M)"
     using nn_integral_monotone_convergence_SUP[OF inc_rel, OF mes_rel] by simp
 
   have SUP_Fx: "(SUP n. F n x) = f x" if "x \<in> space M" for x
   proof -
     obtain N where "x \<in> Y N" using Y_full \<open>x \<in> space M\<close> by auto
     have "(SUP n. F n x) = (SUP n. inf (f x) (of_nat n))"
     proof (rule SUP_eq)
       show "\<exists>j\<in>UNIV. F i x \<le> inf (f x) (of_nat j)" for i
         by (auto simp: F_def intro!: exI[of _ i] split: split_indicator)
       show "\<exists>i\<in>UNIV. inf (f x) (of_nat j) \<le> F i x" for j
         using \<open>x \<in> Y N\<close> \<open>incseq Y\<close>[THEN monoD, of N "max N j"]
         by (intro bexI[of _ "max N j"])
            (auto simp: F_def subset_eq not_le inf_min intro: min.coboundedI2 less_imp_le split: split_indicator split_max)
     qed
     then show ?thesis
       by (simp add: inf_SUP[symmetric] ennreal_SUP_of_nat_eq_top)
   qed
   then have "(SUP n. F n x * indicator (\<Union>n. (T^^n)--`A) x) = f x * indicator (\<Union>n. (T^^n)--`A) x"
     if "x \<in> space M" for x
     by (auto simp add: indicator_def SUP_Fx that)
   then have **: "(SUP n. (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). F n x \<partial>M)) = (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     by (simp add: a cong: nn_integral_cong)
 
   have "incseq (\<lambda>n. induced_function A (F n) x)" for x
     unfolding induced_function_def
     using incseq_sumI2[of "{..<return_time_function A x}", of "\<lambda>i n. F n ((T^^i)x)"] inc_Fx by simp
   then have "incseq (\<lambda>n. induced_function A (F n))" by (auto simp add: incseq_def le_fun_def)
   then have b: "(SUP n. (\<integral>\<^sup>+ x. induced_function A (F n) x \<partial>M)) = (\<integral>\<^sup>+ x. (SUP n. induced_function A (F n) x) \<partial>M)"
     by (rule nn_integral_monotone_convergence_SUP[symmetric]) (measurable)
 
   have "(SUP n. induced_function A (F n) x) = induced_function A f x" if [simp]: "x \<in> space M" for x
   proof -
     have "(SUP n. (\<Sum> i \<in>{..<return_time_function A x}. F n ((T^^i)x)))
               = (\<Sum> i \<in> {..<return_time_function A x}. f ((T^^i)x))"
       using ennreal_SUP_sum[OF inc_Fx, where ?I = "{..<return_time_function A x}"] SUP_Fx by simp
     then show "(SUP n. induced_function A (F n) x) = induced_function A f x"
       by (auto simp add: induced_function_def)
   qed
   then have "(SUP n. (\<integral>\<^sup>+ x. induced_function A (F n) x \<partial>M)) = (\<integral>\<^sup>+ x. induced_function A f x \<partial>M)"
     by (simp add: b cong: nn_integral_cong)
   then show ?thesis using * ** by simp
 qed
 
 text \<open>Taking the constant function equal to $1$ in the previous statement, we obtain the usual
 Kac Formula.\<close>
 
 theorem kac_formula_nonergodic:
   assumes A_meas [measurable]: "A \<in> sets M"
   shows "(\<integral>\<^sup>+y. return_time_function A y \<partial>M) = emeasure M (\<Union>n. (T^^n)--`A)"
 proof -
   define f where "f = (\<lambda>(x::'a). 1::ennreal)"
   have "\<And>x. induced_function A f x = return_time_function A x"
     unfolding induced_function_def f_def by (simp add:)
   then have "(\<integral>\<^sup>+y. return_time_function A y \<partial>M) = (\<integral>\<^sup>+y. induced_function A f y \<partial>M)" by auto
   also have "... = (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     by (rule induced_function_nn_integral) (auto simp add: f_def)
   also have "... = emeasure M (\<Union>n. (T^^n)--`A)" using f_def by auto
   finally show ?thesis by simp
 qed
 
 lemma (in fmpt) return_time_integrable:
   assumes A_meas [measurable]: "A \<in> sets M"
   shows "integrable M (return_time_function A)"
   by (rule integrableI_nonneg)
      (auto simp add: kac_formula_nonergodic[OF assms] ennreal_of_nat_eq_real_of_nat[symmetric] less_top[symmetric])
 
 text \<open>Now, we want to prove the same result but for real-valued integrable function. We first
 prove the statement for nonnegative functions by reducing to the nonnegative extended reals,
 and then for general functions by difference.\<close>
 
 lemma induced_function_integral_aux:
   fixes f::"'a \<Rightarrow> real"
   assumes A_meas [measurable]: "A \<in> sets M"
       and f_int [measurable]: "integrable M f"
       and f_pos: "\<And>x. f x \<ge> 0"
   shows "integrable M (induced_function A f)"
         "(\<integral>y. induced_function A f y \<partial>M) = (\<integral>x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
 proof -
   show "integrable M (induced_function A f)"
   proof (rule integrableI_nonneg)
     show "AE x in M. induced_function A f x \<ge> 0" unfolding induced_function_def by (simp add: f_pos sum_nonneg)
     have "(\<integral>\<^sup>+x. ennreal (induced_function A f x) \<partial>M) = (\<integral>\<^sup>+ x. induced_function A (\<lambda>x. ennreal(f x)) x \<partial>M)"
       unfolding induced_function_def by (auto simp: f_pos)
     also have "... = (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
       by (rule induced_function_nn_integral, auto simp add: assms)
     also have "... \<le> (\<integral>\<^sup>+ x. f x \<partial>M)"
       using nn_set_integral_set_mono[where ?A = "(\<Union>n. (T^^n)--`A)" and ?B = UNIV and ?f = "\<lambda>x. ennreal(f x)"]
       by auto
     also have "... < \<infinity>" using assms by (auto simp: less_top)
     finally show "(\<integral>\<^sup>+ x. induced_function A f x \<partial>M) < \<infinity>" by simp
   qed (simp)
 
   have "(\<integral>\<^sup>+ x. (f x * indicator (\<Union>n. (T^^n)--`A) x) \<partial>M) = (\<integral>\<^sup>+ x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     by (auto split: split_indicator intro!: nn_integral_cong)
   also have "... = (\<integral>\<^sup>+ x. induced_function A (\<lambda>x. ennreal(f x)) x \<partial>M)"
     by (rule induced_function_nn_integral[symmetric], auto simp add: assms)
   also have "... = (\<integral>\<^sup>+x. ennreal (induced_function A f x) \<partial>M)" unfolding induced_function_def by (auto simp: f_pos)
   finally have *: "(\<integral>\<^sup>+ x. (f x * indicator (\<Union>n. (T^^n)--`A) x) \<partial>M) = (\<integral>\<^sup>+x. ennreal (induced_function A f x) \<partial>M)"
     by simp
 
   have "(\<integral> x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M) = (\<integral> x. f x * indicator (\<Union>n. (T^^n)--`A) x \<partial>M)"
     by (simp add: mult.commute set_lebesgue_integral_def)
   also have "... = enn2real (\<integral>\<^sup>+ x. (f x * indicator (\<Union>n. (T^^n)--`A) x) \<partial>M)"
     by (rule integral_eq_nn_integral, auto simp add: f_pos)
   also have "... = enn2real (\<integral>\<^sup>+x. ennreal (induced_function A f x) \<partial>M)" using * by simp
   also have "... = (\<integral> x. induced_function A f x \<partial>M)"
     apply (rule integral_eq_nn_integral[symmetric])
     unfolding induced_function_def by (auto simp add: f_pos sum_nonneg)
   finally show "(\<integral> x. induced_function A f x \<partial>M) = (\<integral> x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     by simp
 qed
 
 text \<open>Here is the general version of Kac's Formula (for a general induced function, starting
 from a real-valued integrable function).\<close>
 
 theorem induced_function_integral_nonergodic:
   fixes f::"'a \<Rightarrow> real"
   assumes [measurable]: "A \<in> sets M" "integrable M f"
   shows "integrable M (induced_function A f)"
         "(\<integral>y. induced_function A f y \<partial>M) = (\<integral>x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
 proof -
   have U_meas [measurable]: "(\<Union>n. (T^^n)--`A) \<in> sets M" by measurable
   define g where "g = (\<lambda>x. max (f x) 0)"
   have g_int [measurable]: "integrable M g" unfolding g_def using assms by auto
   then have g_int2: "integrable M (induced_function A g)"
     using induced_function_integral_aux(1) g_def by auto
   define h where "h = (\<lambda>x. max (-f x) 0)"
   have h_int [measurable]: "integrable M h" unfolding h_def using assms by auto
   then have h_int2: "integrable M (induced_function A h)"
     using induced_function_integral_aux(1) h_def by auto
   have D1: "f = (\<lambda>x. g x - h x)" unfolding g_def h_def by auto
   have D2: "induced_function A f = (\<lambda>x. induced_function A g x - induced_function A h x)"
     unfolding induced_function_def using D1 by (simp add: sum_subtractf)
   then show "integrable M (induced_function A f)" using g_int2 h_int2 by auto
 
   have "(\<integral>x. induced_function A f x \<partial>M) = (\<integral>x. induced_function A g x - induced_function A h x \<partial>M)"
     using D2 by simp
   also have "... = (\<integral>x. induced_function A g x \<partial>M) - (\<integral>x. induced_function A h x \<partial>M)"
     using g_int2 h_int2 by auto
   also have "... = (\<integral>x \<in> (\<Union>n. (T^^n)--`A). g x \<partial>M) - (\<integral>x \<in> (\<Union>n. (T^^n)--`A). h x \<partial>M)"
     using induced_function_integral_aux(2) g_def h_def g_int h_int by auto
   also have "... = (\<integral>x \<in> (\<Union>n. (T^^n)--`A). (g x - h x) \<partial>M)"
     apply (rule set_integral_diff(2)[symmetric])
     unfolding set_integrable_def
     using g_int h_int integrable_mult_indicator[OF U_meas] by blast+
   also have "... = (\<integral>x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     using D1 by simp
   finally show "(\<integral>x. induced_function A f x \<partial>M) = (\<integral>x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)" by simp
 qed
 
 text \<open>We can reformulate the previous statement in terms of induced measure.\<close>
 
 lemma induced_function_integral_restr_nonergodic:
   fixes f::"'a \<Rightarrow> real"
   assumes [measurable]: "A \<in> sets M" "integrable M f"
   shows "integrable (restrict_space M A) (induced_function A f)"
         "(\<integral>y. induced_function A f y \<partial>(restrict_space M A)) = (\<integral> x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
 proof -
   have [measurable]: "integrable M (induced_function A f)" by (rule induced_function_integral_nonergodic(1)[OF assms])
   then show "integrable (restrict_space M A) (induced_function A f)"
     by (metis assms(1) integrable_mult_indicator integrable_restrict_space sets.Int_space_eq2)
   have "(\<integral>y. induced_function A f y \<partial>(restrict_space M A)) = (\<integral>y \<in> A. induced_function A f y \<partial>M)"
     by (simp add: integral_restrict_space set_lebesgue_integral_def)
   also have "... = (\<integral>y. induced_function A f y \<partial>M)"
     unfolding real_scaleR_def set_lebesgue_integral_def
   proof (rule Bochner_Integration.integral_cong [OF refl])
     have "induced_function A f y = 0" if "y \<notin> A" for y unfolding induced_function_def
       using that return_time0[of A] recurrent_subset_incl(1)[of A] return_time_function_def by auto
     then show "\<And>x. indicator A x * induced_function A f x = induced_function A f x" 
       unfolding indicator_def by auto
   qed
   also have "... = (\<integral> x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     by (rule induced_function_integral_nonergodic(2)[OF assms])
   finally show "(\<integral>y. induced_function A f y \<partial>(restrict_space M A)) = (\<integral> x \<in> (\<Union>n. (T^^n)--`A). f x \<partial>M)"
     by simp
 qed
 
 end
 
 end (*of Recurrence.thy*)
diff --git a/thys/Ergodic_Theory/SG_Library_Complement.thy b/thys/Ergodic_Theory/SG_Library_Complement.thy
--- a/thys/Ergodic_Theory/SG_Library_Complement.thy
+++ b/thys/Ergodic_Theory/SG_Library_Complement.thy
@@ -1,1319 +1,1322 @@
 (*  Author:  Sébastien Gouëzel   sebastien.gouezel@univ-rennes1.fr
     License: BSD
 *)
 
 section \<open>SG Libary complements\<close>
 
 theory SG_Library_Complement
   imports "HOL-Probability.Probability"
 begin
 
 text \<open>In this file are included many statements that were useful to me, but belong rather
 naturally to existing theories. In a perfect world, some of these statements would get included
 into these files.
 
 I tried to indicate to which of these classical theories the statements could be added.
 \<close>
 
 subsection \<open>Basic logic\<close>
 
 text \<open>This one is certainly available, but I could not locate it...\<close>
 lemma equiv_neg:
   "\<lbrakk> P \<Longrightarrow> Q; \<not>P \<Longrightarrow> \<not>Q \<rbrakk> \<Longrightarrow> (P\<longleftrightarrow>Q)"
 by blast
 
 
 subsection \<open>Basic set theory\<close>
 
 lemma compl_compl_eq_id [simp]:
   "UNIV - (UNIV - s) = s"
 by auto
 
 abbreviation sym_diff :: "'a set \<Rightarrow> 'a set \<Rightarrow> 'a set" (infixl "\<Delta>" 70) where
   "sym_diff A B \<equiv> ((A - B) \<union> (B-A))"
 
 text \<open>Not sure the next lemmas are useful, as they are proved solely by auto, so they
 could be reproved automatically whenever necessary.\<close>
 
 lemma sym_diff_inc:
   "A \<Delta> C \<subseteq> A \<Delta> B \<union> B \<Delta> C"
 by auto
 
 lemma sym_diff_vimage [simp]:
   "f-`(A \<Delta> B) = (f-`A) \<Delta> (f-`B)"
 by auto
 
 
 subsection \<open>Set-Interval.thy\<close>
 
 text \<open>The next two lemmas belong naturally to \verb+Set_Interval.thy+, next to
 \verb+UN_le_add_shift+. They are not trivially equivalent to the corresponding lemmas
 with large inequalities, due to the difference when $n = 0$.\<close>
 
 lemma UN_le_eq_Un0_strict:
   "(\<Union>i<n+1::nat. M i) = (\<Union>i\<in>{1..<n+1}. M i) \<union> M 0" (is "?A = ?B")
 proof
   show "?A \<subseteq> ?B"
   proof
     fix x assume "x \<in> ?A"
     then obtain i where i: "i<n+1" "x \<in> M i" by auto
     show "x \<in> ?B"
     proof(cases i)
       case 0 with i show ?thesis by simp
     next
       case (Suc j) with i show ?thesis by auto
     qed
   qed
 qed (auto)
 
 text \<open>I use repeatedly this one, but I could not find it directly\<close>
 
 lemma union_insert_0:
   "(\<Union>n::nat. A n) = A 0 \<union> (\<Union>n\<in>{1..}. A n)"
 by (metis UN_insert Un_insert_left sup_bot.left_neutral One_nat_def atLeast_0 atLeast_Suc_greaterThan ivl_disj_un_singleton(1))
 
 text \<open>Next one could be close to \verb+sum.nat_group+\<close>
 
 lemma sum_arith_progression:
   "(\<Sum>r<(N::nat). (\<Sum>i<a. f (i*N+r))) = (\<Sum>j<a*N. f j)"
 proof -
   have *: "(\<Sum>r<N. f (i*N+r)) = (\<Sum> j \<in> {i*N..<i*N + N}. f j)" for i
     by (rule sum.reindex_bij_betw, rule bij_betw_byWitness[where ?f' = "\<lambda>r. r-i*N"], auto)
 
   have "(\<Sum>r<N. (\<Sum>i<a. f (i*N+r))) = (\<Sum>i<a. (\<Sum>r<N. f (i*N+r)))"
     using sum.swap by auto
   also have "... = (\<Sum>i<a. (\<Sum> j \<in> {i*N..<i*N + N}. f j))"
     using * by auto
   also have "... = (\<Sum>j<a*N. f j)"
     by (rule sum.nat_group)
   finally show ?thesis by simp
 qed
 
 
 subsection \<open>Miscellanous basic results\<close>
 
 lemma ind_from_1 [case_names 1 Suc, consumes 1]:
   assumes "n > 0"
   assumes "P 1"
       and "\<And>n. n > 0 \<Longrightarrow> P n \<Longrightarrow> P (Suc n)"
   shows "P n"
 proof -
   have "(n = 0) \<or> P n"
   proof (induction n)
     case 0 then show ?case by auto
   next
     case (Suc k)
     consider "Suc k = 1" | "Suc k > 1" by linarith
     then show ?case
       apply (cases) using assms Suc.IH by auto
   qed
   then show ?thesis using \<open>n > 0\<close> by auto
 qed
 
 text \<open>This lemma is certainly available somewhere, but I couldn't
 locate it\<close>
 
 lemma tends_to_real_e:
   fixes u::"nat \<Rightarrow> real"
   assumes "u \<longlonglongrightarrow> l" "e>0"
   shows "\<exists>N. \<forall>n>N. abs(u n -l) < e"
   by (metis assms dist_real_def le_less lim_sequentially)
 
 lemma nat_mod_cong:
   assumes "a = b+(c::nat)"
           "a mod n = b mod n"
   shows "c mod n = 0"
 proof -
   let ?k = "a mod n"
   obtain a1 where "a = a1*n + ?k" by (metis div_mult_mod_eq)
   moreover obtain b1 where "b = b1*n + ?k" using assms(2) by (metis div_mult_mod_eq)
   ultimately have "a1 * n + ?k = b1 * n + ?k + c" using assms(1) by arith
   then have "c = (a1 - b1) * n" by (simp add: diff_mult_distrib)
   then show ?thesis by simp
 qed
 
 lemma funpow_add': "(f ^^ (m + n)) x = (f ^^ m) ((f ^^ n) x)"
 by (simp add: funpow_add)
 
 text \<open>The next two lemmas are not directly equivalent, since $f$ might
 not be injective.\<close>
 
 lemma abs_Max_sum:
   fixes A::"real set"
   assumes "finite A" "A \<noteq> {}"
   shows "abs(Max A) \<le> (\<Sum>a\<in>A. abs(a))"
   by (simp add: assms member_le_sum)
 
 lemma abs_Max_sum2:
   fixes f::"_ \<Rightarrow> real"
   assumes "finite A" "A \<noteq> {}"
   shows "abs(Max (f`A)) \<le> (\<Sum>a\<in>A. abs(f a))"
 using assms by (induct rule: finite_ne_induct, auto)
 
 subsection \<open>Conditionally-Complete-Lattices.thy\<close>
 
 lemma mono_cInf:
   fixes f :: "'a::conditionally_complete_lattice \<Rightarrow> 'b::conditionally_complete_lattice"
   assumes "mono f" "A \<noteq> {}" "bdd_below A"
   shows "f(Inf A) \<le> Inf (f`A)"
 using assms by (simp add: cINF_greatest cInf_lower monoD)
 
 lemma mono_bij_cInf:
   fixes f :: "'a::conditionally_complete_linorder \<Rightarrow> 'b::conditionally_complete_linorder"
   assumes "mono f" "bij f" "A \<noteq> {}" "bdd_below A"
   shows "f (Inf A) = Inf (f`A)"
 proof -
   have "(inv f) (Inf (f`A)) \<le> Inf ((inv f)`(f`A))"
     apply (rule cInf_greatest, auto simp add: assms(3))
     using mono_inv[OF assms(1) assms(2)] assms by (simp add: mono_def bdd_below_image_mono cInf_lower)
   then have "Inf (f`A) \<le> f (Inf ((inv f)`(f`A)))"
     by (metis (no_types, lifting) assms(1) assms(2) mono_def bij_inv_eq_iff)
   also have "... = f(Inf A)"
     using assms by (simp add: bij_is_inj)
   finally show ?thesis using mono_cInf[OF assms(1) assms(3) assms(4)] by auto
 qed
 
 subsection \<open>Topological-spaces.thy\<close>
 
 lemma open_less_abs [simp]:
   "open {x. (C::real) < abs x}"
 proof -
   have *: "{x. C < abs x} = abs-`{C<..}" by auto
   show ?thesis unfolding * by (auto intro!: continuous_intros)
 qed
 
 lemma closed_le_abs [simp]:
   "closed {x. (C::real) \<le> abs x}"
 proof -
   have *: "{x. C \<le> \<bar>x\<bar>} = abs-`{C..}" by auto
   show ?thesis unfolding * by (auto intro!: continuous_intros)
 qed
 
 text \<open>The next statements come from the same statements for true subsequences\<close>
 
 lemma eventually_weak_subseq:
   fixes u::"nat \<Rightarrow> nat"
   assumes "(\<lambda>n. real(u n)) \<longlonglongrightarrow> \<infinity>" "eventually P sequentially"
   shows "eventually (\<lambda>n. P (u n)) sequentially"
 proof -
   obtain N where *: "\<forall>n\<ge>N. P n" using assms(2) unfolding eventually_sequentially by auto
   obtain M where "\<forall>m\<ge>M. ereal(u m) \<ge> N" using assms(1) by (meson Lim_PInfty)
   then have "\<And>m. m \<ge> M \<Longrightarrow> u m \<ge> N" by auto
   then have "\<And>m. m \<ge> M \<Longrightarrow> P(u m)" using \<open>\<forall>n\<ge>N. P n\<close> by simp
   then show ?thesis unfolding eventually_sequentially by auto
 qed
 
 lemma filterlim_weak_subseq:
   fixes u::"nat \<Rightarrow> nat"
   assumes "(\<lambda>n. real(u n)) \<longlonglongrightarrow> \<infinity>"
   shows "LIM n sequentially. u n:> at_top"
 unfolding filterlim_iff by (metis assms eventually_weak_subseq)
 
 lemma limit_along_weak_subseq:
   fixes u::"nat \<Rightarrow> nat" and v::"nat \<Rightarrow> _"
   assumes "(\<lambda>n. real(u n)) \<longlonglongrightarrow> \<infinity>" "v \<longlonglongrightarrow> l"
   shows "(\<lambda> n. v(u n)) \<longlonglongrightarrow> l"
 using filterlim_compose[of v, OF _ filterlim_weak_subseq] assms by auto
 
 lemma frontier_indist_le:
   assumes "x \<in> frontier {y. infdist y S \<le> r}"
   shows "infdist x S = r"
 proof -
   have "infdist x S = r" if H: "\<forall>e>0. (\<exists>y. infdist y S \<le> r \<and> dist x y < e) \<and> (\<exists>z. \<not> infdist z S \<le> r \<and> dist x z < e)"
   proof -
     have "infdist x S < r + e" if "e > 0" for e
     proof -
       obtain y where "infdist y S \<le> r" "dist x y < e"
         using H \<open>e > 0\<close> by blast
       then show ?thesis
         by (metis add.commute add_mono_thms_linordered_field(3) infdist_triangle le_less_trans)
     qed
     then have A: "infdist x S \<le> r"
       by (meson field_le_epsilon order.order_iff_strict)
     have "r < infdist x S + e" if "e > 0" for e
     proof -
       obtain y where "\<not>(infdist y S \<le> r)" "dist x y < e"
         using H \<open>e > 0\<close> by blast
       then have "r < infdist y S" by auto
       also have "... \<le> infdist x S + dist y x"
         by (rule infdist_triangle)
       finally show ?thesis using \<open>dist x y < e\<close>
         by (simp add: dist_commute)
       qed
     then have B: "r \<le> infdist x S"
       by (meson field_le_epsilon order.order_iff_strict)
     show ?thesis using A B by auto
   qed
   then show ?thesis
     using assms unfolding frontier_straddle by auto
 qed
 
 
 subsection \<open>Limits\<close>
 
 text \<open>The next lemmas are not very natural, but I needed them several times\<close>
 
 lemma tendsto_shift_1_over_n [tendsto_intros]:
   fixes f::"nat \<Rightarrow> real"
   assumes "(\<lambda>n. f n / n) \<longlonglongrightarrow> l"
   shows "(\<lambda>n. f (n+k) / n) \<longlonglongrightarrow> l"
 proof -
   have "(1+k*(1/n))* (f(n+k)/(n+k)) = f(n+k)/n" if "n>0" for n using that by (auto simp add: divide_simps)
   with eventually_mono[OF eventually_gt_at_top[of "0::nat"] this]
   have "eventually (\<lambda>n.(1+k*(1/n))* (f(n+k)/(n+k)) = f(n+k)/n) sequentially"
     by auto
   moreover have "(\<lambda>n. (1+k*(1/n))* (f(n+k)/(n+k))) \<longlonglongrightarrow> (1+real k*0) * l"
     by (intro tendsto_intros LIMSEQ_ignore_initial_segment assms)
   ultimately show ?thesis using Lim_transform_eventually by auto
 qed
 
 lemma tendsto_shift_1_over_n' [tendsto_intros]:
   fixes f::"nat \<Rightarrow> real"
   assumes "(\<lambda>n. f n / n) \<longlonglongrightarrow> l"
   shows "(\<lambda>n. f (n-k) / n) \<longlonglongrightarrow> l"
 proof -
   have "(1-k*(1/(n+k)))* (f n/ n) = f n/(n+k)" if "n>0" for n using that by (auto simp add: divide_simps)
   with eventually_mono[OF eventually_gt_at_top[of "0::nat"] this]
   have "eventually (\<lambda>n. (1-k*(1/(n+k)))* (f n/ n) = f n/(n+k)) sequentially"
     by auto
   moreover have "(\<lambda>n. (1-k*(1/(n+k)))* (f n/ n)) \<longlonglongrightarrow> (1-real k*0) * l"
     by (intro tendsto_intros assms LIMSEQ_ignore_initial_segment)
   ultimately have "(\<lambda>n. f n / (n+k)) \<longlonglongrightarrow> l" using Lim_transform_eventually by auto
   then have a: "(\<lambda>n. f(n-k)/(n-k+k)) \<longlonglongrightarrow> l" using seq_offset_neg by auto
 
   have "f(n-k)/(n-k+k) = f(n-k)/n" if "n>k" for n
     using that by auto
   with eventually_mono[OF eventually_gt_at_top[of k] this]
   have "eventually (\<lambda>n. f(n-k)/(n-k+k) = f(n-k)/n) sequentially"
     by auto
   with Lim_transform_eventually[OF a this]
   show ?thesis by auto
 qed
 
 declare LIMSEQ_realpow_zero [tendsto_intros]
 
 subsection \<open>Topology-Euclidean-Space\<close>
 
 text \<open>A (more usable) variation around \verb+continuous_on_closure_sequentially+. The assumption
 that the spaces are metric spaces is definitely too strong, but sufficient for most applications.\<close>
 
 lemma continuous_on_closure_sequentially':
   fixes f::"'a::metric_space \<Rightarrow> 'b::metric_space"
   assumes "continuous_on (closure C) f"
           "\<And>(n::nat). u n \<in> C"
           "u \<longlonglongrightarrow> l"
   shows "(\<lambda>n. f (u n)) \<longlonglongrightarrow> f l"
 proof -
   have "l \<in> closure C" unfolding closure_sequential using assms by auto
   then show ?thesis
     using \<open>continuous_on (closure C) f\<close> unfolding comp_def continuous_on_closure_sequentially
     using assms by auto
 qed
 
 
 subsection \<open>Convexity\<close>
 
 lemma convex_on_mean_ineq:
   fixes f::"real \<Rightarrow> real"
   assumes "convex_on A f" "x \<in> A" "y \<in> A"
   shows "f ((x+y)/2) \<le> (f x + f y) / 2"
 using convex_onD[OF assms(1), of "1/2" x y] using assms by (auto simp add: divide_simps)
 
 lemma convex_on_closure:
   assumes "convex (C::'a::real_normed_vector set)"
           "convex_on C f"
           "continuous_on (closure C) f"
   shows "convex_on (closure C) f"
 proof (rule convex_onI)
   fix x y::'a and t::real
   assume "x \<in> closure C" "y \<in> closure C" "0 < t" "t < 1"
   obtain u v::"nat \<Rightarrow> 'a" where *: "\<And>n. u n \<in> C" "u \<longlonglongrightarrow> x"
                                    "\<And>n. v n \<in> C" "v \<longlonglongrightarrow> y"
     using \<open>x \<in> closure C\<close> \<open>y \<in> closure C\<close> unfolding closure_sequential by blast
   define w where "w = (\<lambda>n. (1-t) *\<^sub>R (u n) + t *\<^sub>R (v n))"
   have "w n \<in> C" for n
     using \<open>0 < t\<close> \<open>t< 1\<close> convexD[OF \<open>convex C\<close> *(1)[of n] *(3)[of n]] unfolding w_def by auto
   have "w \<longlonglongrightarrow> ((1-t) *\<^sub>R x + t *\<^sub>R y)"
     unfolding w_def using *(2) *(4) by (intro tendsto_intros)
 
   have *: "f(w n) \<le> (1-t) * f(u n) + t * f (v n)" for n
     using *(1) *(3) \<open>convex_on C f\<close> \<open>0<t\<close> \<open>t<1\<close> less_imp_le unfolding w_def
     convex_on_alt by (simp add: add.commute)
   have i: "(\<lambda>n. f (w n)) \<longlonglongrightarrow> f ((1-t) *\<^sub>R x + t *\<^sub>R y)"
     by (rule continuous_on_closure_sequentially'[OF assms(3) \<open>\<And>n. w n \<in> C\<close> \<open>w \<longlonglongrightarrow> ((1-t) *\<^sub>R x + t *\<^sub>R y)\<close>])
   have ii: "(\<lambda>n. (1-t) * f(u n) + t * f (v n)) \<longlonglongrightarrow> (1-t) * f x + t * f y"
     apply (intro tendsto_intros)
     apply (rule continuous_on_closure_sequentially'[OF assms(3) \<open>\<And>n. u n \<in> C\<close> \<open>u \<longlonglongrightarrow> x\<close>])
     apply (rule continuous_on_closure_sequentially'[OF assms(3) \<open>\<And>n. v n \<in> C\<close> \<open>v \<longlonglongrightarrow> y\<close>])
     done
   show "f ((1 - t) *\<^sub>R x + t *\<^sub>R y) \<le> (1 - t) * f x + t * f y"
     apply (rule LIMSEQ_le[OF i ii]) using * by auto
 qed
 
 lemma convex_on_norm [simp]:
   "convex_on UNIV (\<lambda>(x::'a::real_normed_vector). norm x)"
 using convex_on_dist[of UNIV "0::'a"] by auto
 
 lemma continuous_abs_powr [continuous_intros]:
   assumes "p > 0"
   shows "continuous_on UNIV (\<lambda>(x::real). \<bar>x\<bar> powr p)"
 apply (rule continuous_on_powr') using assms by (auto intro: continuous_intros)
 
 lemma continuous_mult_sgn [continuous_intros]:
   fixes f::"real \<Rightarrow> real"
   assumes "continuous_on UNIV f" "f 0 = 0"
   shows "continuous_on UNIV (\<lambda>x. sgn x * f x)"
 proof -
   have *: "continuous_on {0..} (\<lambda>x. sgn x * f x)"
     apply (subst continuous_on_cong[of "{0..}" "{0..}" _ f], auto simp add: sgn_real_def assms(2))
     by (rule continuous_on_subset[OF assms(1)], auto)
   have **: "continuous_on {..0} (\<lambda>x. sgn x * f x)"
     apply (subst continuous_on_cong[of "{..0}" "{..0}" _ "\<lambda>x. -f x"], auto simp add: sgn_real_def assms(2))
     by (rule continuous_on_subset[of UNIV], auto simp add: assms intro!: continuous_intros)
   show ?thesis
     using continuous_on_closed_Un[OF _ _ * **] apply (auto intro: continuous_intros)
     using continuous_on_subset by fastforce
 qed
 
 lemma DERIV_abs_powr [derivative_intros]:
   assumes "p > (1::real)"
   shows "DERIV (\<lambda>x. \<bar>x\<bar> powr p) x :> p * sgn x * \<bar>x\<bar> powr (p - 1)"
 proof -
   consider "x = 0" | "x>0" | "x < 0" by linarith
   then show ?thesis
   proof (cases)
     case 1
     have "continuous_on UNIV (\<lambda>x. sgn x * \<bar>x\<bar> powr (p - 1))"
       by (auto simp add: assms intro!:continuous_intros)
     then have "(\<lambda>h. sgn h * \<bar>h\<bar> powr (p-1)) \<midarrow>0\<rightarrow> (\<lambda>h. sgn h * \<bar>h\<bar> powr (p-1)) 0"
       using continuous_on_def by blast
     moreover have "\<bar>h\<bar> powr p / h = sgn h * \<bar>h\<bar> powr (p-1)" for h
     proof -
       have "\<bar>h\<bar> powr p / h = sgn h * \<bar>h\<bar> powr p / \<bar>h\<bar>"
         by (auto simp add: algebra_simps divide_simps sgn_real_def)
       also have "... = sgn h * \<bar>h\<bar> powr (p-1)"
         using assms apply (cases "h = 0") apply (auto)
         by (metis abs_ge_zero powr_diff [symmetric] powr_one_gt_zero_iff times_divide_eq_right)
       finally show ?thesis by simp
     qed
     ultimately have "(\<lambda>h. \<bar>h\<bar> powr p / h) \<midarrow>0\<rightarrow> 0" by auto
     then show ?thesis unfolding DERIV_def by (auto simp add: \<open>x = 0\<close>)
   next
     case 2
     have *: "\<forall>\<^sub>F y in nhds x. \<bar>y\<bar> powr p = y powr p"
       unfolding eventually_nhds apply (rule exI[of _ "{0<..}"]) using \<open>x > 0\<close> by auto
     show ?thesis
       apply (subst DERIV_cong_ev[of _ x _ "(\<lambda>x. x powr p)" _ "p * x powr (p-1)"])
       using \<open>x > 0\<close> by (auto simp add: * has_real_derivative_powr)
   next
     case 3
     have *: "\<forall>\<^sub>F y in nhds x. \<bar>y\<bar> powr p = (-y) powr p"
       unfolding eventually_nhds apply (rule exI[of _ "{..<0}"]) using \<open>x < 0\<close> by auto
     show ?thesis
       apply (subst DERIV_cong_ev[of _ x _ "(\<lambda>x. (-x) powr p)" _ "p * (- x) powr (p - real 1) * - 1"])
       using \<open>x < 0\<close> apply (simp, simp add: *, simp)
       apply (rule DERIV_fun_powr[of "\<lambda>y. -y" "-1" "x" p]) using \<open>x < 0\<close> by (auto simp add: derivative_intros)
   qed
 qed
 
 lemma convex_abs_powr:
   assumes "p \<ge> 1"
   shows "convex_on UNIV (\<lambda>x::real. \<bar>x\<bar> powr p)"
 proof (cases "p = 1")
   case True
   have "convex_on UNIV (\<lambda>x::real. norm x)"
     by (rule convex_on_norm)
   moreover have "\<bar>x\<bar> powr p = norm x" for x using True by auto
   ultimately show ?thesis by simp
 next
   case False
   then have "p > 1" using assms by auto
   define g where "g = (\<lambda>x::real. p * sgn x * \<bar>x\<bar> powr (p - 1))"
   have *: "DERIV (\<lambda>x. \<bar>x\<bar> powr p) x :> g x" for x
     unfolding g_def using \<open>p>1\<close> by (intro derivative_intros)
   have **: "g x \<le> g y" if "x \<le> y" for x y
   proof -
     consider "x \<ge> 0 \<and> y \<ge> 0" | "x \<le> 0 \<and> y \<le> 0" | "x < 0 \<and> y > 0" using \<open>x \<le> y\<close> by linarith
     then show ?thesis
     proof (cases)
       case 1
       then show ?thesis unfolding g_def sgn_real_def using \<open>p>1\<close> \<open>x \<le> y\<close> by (auto simp add: powr_mono2)
     next
       case 2
       then show ?thesis unfolding g_def sgn_real_def using \<open>p>1\<close> \<open>x \<le> y\<close> by (auto simp add: powr_mono2)
     next
       case 3
       then have "g x \<le> 0" "0 \<le> g y" unfolding g_def using \<open>p > 1\<close> by auto
       then show ?thesis by simp
     qed
   qed
   show ?thesis
     apply (rule convex_on_realI[of _ _ g]) using * ** by auto
 qed
 
 lemma convex_powr:
   assumes "p \<ge> 1"
   shows "convex_on {0..} (\<lambda>x::real. x powr p)"
 proof -
   have "convex_on {0..} (\<lambda>x::real. \<bar>x\<bar> powr p)"
     using convex_abs_powr[OF \<open>p \<ge> 1\<close>] convex_on_subset by auto
   moreover have "\<bar>x\<bar> powr p = x powr p" if "x \<in> {0..}" for x using that by auto
   ultimately show ?thesis by (simp add: convex_on_def)
 qed
 
 lemma convex_powr':
   assumes "p > 0" "p \<le> 1"
   shows "convex_on {0..} (\<lambda>x::real. - (x powr p))"
 proof -
   have "convex_on {0<..} (\<lambda>x::real. - (x powr p))"
     apply (rule convex_on_realI[of _ _ "\<lambda>x. -p * x powr (p-1)"])
     apply (auto intro!:derivative_intros simp add: has_real_derivative_powr)
     using \<open>p > 0\<close> \<open>p \<le> 1\<close> by (auto simp add: algebra_simps divide_simps powr_mono2')
   moreover have "continuous_on {0..} (\<lambda>x::real. - (x powr p))"
     by (rule continuous_on_minus, rule continuous_on_powr', auto simp add: \<open>p > 0\<close> intro!: continuous_intros)
   moreover have "{(0::real)..} = closure {0<..}" "convex {(0::real)<..}" by auto
   ultimately show ?thesis using convex_on_closure by metis
 qed
 
 lemma convex_fx_plus_fy_ineq:
   fixes f::"real \<Rightarrow> real"
   assumes "convex_on {0..} f"
           "x \<ge> 0" "y \<ge> 0" "f 0 = 0"
   shows "f x + f y \<le> f (x+y)"
 proof -
   have *: "f a + f b \<le> f (a+b)" if "a \<ge> 0" "b \<ge> a" for a b
   proof (cases "a = 0")
     case False
     then have "a > 0" "b > 0" using \<open>b \<ge> a\<close> \<open>a \<ge> 0\<close> by auto
     have "(f 0 - f a) / (0 - a) \<le> (f 0 - f (a+b))/ (0 - (a+b))"
       apply (rule convex_on_diff[OF \<open>convex_on {0..} f\<close>]) using \<open>a > 0\<close> \<open>b > 0\<close> by auto
     also have "... \<le> (f b - f (a+b)) / (b - (a+b))"
       apply (rule convex_on_diff[OF \<open>convex_on {0..} f\<close>]) using \<open>a > 0\<close> \<open>b > 0\<close> by auto
     finally show ?thesis
       using \<open>a > 0\<close> \<open>b > 0\<close> \<open>f 0 = 0\<close> by (auto simp add: divide_simps algebra_simps)
   qed (simp add: \<open>f 0 = 0\<close>)
   then show ?thesis
     using \<open>x \<ge> 0\<close> \<open>y \<ge> 0\<close> by (metis add.commute le_less not_le)
 qed
 
 lemma x_plus_y_p_le_xp_plus_yp:
   fixes p x y::real
   assumes "p > 0" "p \<le> 1" "x \<ge> 0" "y \<ge> 0"
   shows "(x + y) powr p \<le> x powr p + y powr p"
 using convex_fx_plus_fy_ineq[OF convex_powr'[OF \<open>p > 0\<close> \<open>p \<le> 1\<close>] \<open>x \<ge> 0\<close> \<open>y \<ge> 0\<close>] by auto
 
 
 subsection \<open>Nonnegative-extended-real.thy\<close>
 
 lemma x_plus_top_ennreal [simp]:
   "x + \<top> = (\<top>::ennreal)"
 by simp
 
 lemma ennreal_ge_nat_imp_PInf:
   fixes x::ennreal
   assumes "\<And>N. x \<ge> of_nat N"
   shows "x = \<infinity>"
 using assms apply (cases x, auto) by (meson not_less reals_Archimedean2)
 
 lemma ennreal_archimedean:
   assumes "x \<noteq> (\<infinity>::ennreal)"
   shows "\<exists>n::nat. x \<le> n"
   using assms ennreal_ge_nat_imp_PInf linear by blast
 
 lemma e2ennreal_mult:
   fixes a b::ereal
   assumes "a \<ge> 0"
   shows "e2ennreal(a * b) = e2ennreal a * e2ennreal b"
 by (metis assms e2ennreal_neg eq_onp_same_args ereal_mult_le_0_iff linear times_ennreal.abs_eq)
 
 lemma e2ennreal_mult':
   fixes a b::ereal
   assumes "b \<ge> 0"
   shows "e2ennreal(a * b) = e2ennreal a * e2ennreal b"
 using e2ennreal_mult[OF assms, of a] by (simp add: mult.commute)
 
 lemma SUP_real_ennreal:
   assumes "A \<noteq> {}" "bdd_above (f`A)"
   shows "(SUP a\<in>A. ennreal (f a)) = ennreal(SUP a\<in>A. f a)"
 apply (rule antisym, simp add: SUP_least assms(2) cSUP_upper ennreal_leI)
 by (metis assms(1) ennreal_SUP ennreal_less_top le_less)
 
 lemma e2ennreal_Liminf:
   "F \<noteq> bot \<Longrightarrow> e2ennreal (Liminf F f) = Liminf F (\<lambda>n. e2ennreal (f n))"
   by (rule Liminf_compose_continuous_mono[symmetric])
      (auto simp: mono_def e2ennreal_mono continuous_on_e2ennreal)
 
 lemma e2ennreal_eq_infty[simp]: "0 \<le> x \<Longrightarrow> e2ennreal x = top \<longleftrightarrow> x = \<infinity>"
   by (cases x) (auto)
 
 lemma ennreal_Inf_cmult:
   assumes "c>(0::real)"
   shows "Inf {ennreal c * x |x. P x} = ennreal c * Inf {x. P x}"
 proof -
   have "(\<lambda>x::ennreal. c * x) (Inf {x::ennreal. P x}) = Inf ((\<lambda>x::ennreal. c * x)`{x::ennreal. P x})"
     apply (rule mono_bij_Inf)
     apply (simp add: monoI mult_left_mono)
     apply (rule bij_betw_byWitness[of _ "\<lambda>x. (x::ennreal) / c"], auto simp add: assms)
     apply (metis assms ennreal_lessI ennreal_neq_top mult.commute mult_divide_eq_ennreal not_less_zero)
     apply (metis assms divide_ennreal_def ennreal_less_zero_iff ennreal_neq_top less_irrefl mult.assoc mult.left_commute mult_divide_eq_ennreal)
     done
   then show ?thesis by (simp only: setcompr_eq_image[symmetric])
 qed
 
 lemma continuous_on_const_minus_ennreal:
   fixes f :: "'a :: topological_space \<Rightarrow> ennreal"
   shows "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. a - f x)"
   including ennreal.lifting
 proof (transfer fixing: A; clarsimp)
   fix f :: "'a \<Rightarrow> ereal" and a :: "ereal" assume "0 \<le> a" "\<forall>x. 0 \<le> f x" and f: "continuous_on A f"
   then show "continuous_on A (\<lambda>x. max 0 (a - f x))"
   proof cases
     assume "\<exists>r. a = ereal r"
     with f show ?thesis
       by (auto simp: continuous_on_def minus_ereal_def ereal_Lim_uminus[symmetric]
               intro!: tendsto_add_ereal_general tendsto_max)
   next
     assume "\<nexists>r. a = ereal r"
     with \<open>0 \<le> a\<close> have "a = \<infinity>"
       by (cases a) auto
     then show ?thesis
       by (simp add: continuous_on_const)
   qed
 qed
 
 lemma const_minus_Liminf_ennreal:
   fixes a :: ennreal
   shows "F \<noteq> bot \<Longrightarrow> a - Liminf F f = Limsup F (\<lambda>x. a - f x)"
 by (intro Limsup_compose_continuous_antimono[symmetric])
    (auto simp: antimono_def ennreal_mono_minus continuous_on_id continuous_on_const_minus_ennreal)
 
 lemma tendsto_cmult_ennreal [tendsto_intros]:
   fixes c l::ennreal
   assumes "\<not>(c = \<infinity> \<and> l = 0)"
           "(f \<longlongrightarrow> l) F"
   shows "((\<lambda>x. c * f x) \<longlongrightarrow> c * l) F"
 by (cases "c = 0", insert assms, auto intro!: tendsto_intros)
 
 
 subsection \<open>Indicator-Function.thy\<close>
 
 text \<open>There is something weird with \verb+sum_mult_indicator+: it is defined both
 in Indicator.thy and BochnerIntegration.thy, with a different meaning. I am surprised
 there is no name collision... Here, I am using the version from BochnerIntegration.\<close>
 
 lemma sum_indicator_eq_card2:
   assumes "finite I"
   shows "(\<Sum>i\<in>I. (indicator (P i) x)::nat) = card {i\<in>I. x \<in> P i}"
 using sum_mult_indicator [OF assms, of "\<lambda>y. 1::nat" P "\<lambda>y. x"]
 unfolding card_eq_sum by auto
 
+subclass (in zero_less_one) zero_neq_one
+  by standard (use zero_less_one in blast)
+
 lemma disjoint_family_indicator_le_1:
   assumes "disjoint_family_on A I"
   shows "(\<Sum> i\<in> I. indicator (A i) x) \<le> (1::'a:: {comm_monoid_add,zero_less_one})"
 proof (cases "finite I")
   case True
   then have *: "(\<Sum> i\<in> I. indicator (A i) x) = ((indicator (\<Union>i\<in>I. A i) x)::'a)"
     by (simp add: indicator_UN_disjoint[OF True assms(1), of x])
   show ?thesis
     unfolding * unfolding indicator_def by (simp add: order_less_imp_le)
 next
   case False
   then show ?thesis by (simp add: order_less_imp_le)
 qed
 
 subsection \<open>sigma-algebra.thy\<close>
 
 lemma algebra_intersection:
   assumes "algebra \<Omega> A"
           "algebra \<Omega> B"
   shows "algebra \<Omega> (A \<inter> B)"
 apply (subst algebra_iff_Un) using assms by (auto simp add: algebra_iff_Un)
 
 lemma sigma_algebra_intersection:
   assumes "sigma_algebra \<Omega> A"
           "sigma_algebra \<Omega> B"
   shows "sigma_algebra \<Omega> (A \<inter> B)"
 apply (subst sigma_algebra_iff) using assms by (auto simp add: sigma_algebra_iff algebra_intersection)
 
 lemma subalgebra_M_M [simp]:
   "subalgebra M M"
 by (simp add: subalgebra_def)
 
 text \<open>The next one is \verb+disjoint_family_Suc+ with inclusions reversed.\<close>
 
 lemma disjoint_family_Suc2:
   assumes Suc: "\<And>n. A (Suc n) \<subseteq> A n"
   shows "disjoint_family (\<lambda>i. A i - A (Suc i))"
 proof -
   have "A (m+n) \<subseteq> A n" for m n
   proof (induct m)
     case 0 show ?case by simp
   next
     case (Suc m) then show ?case
       by (metis Suc_eq_plus1 assms add.commute add.left_commute subset_trans)
   qed
   then have "A m \<subseteq> A n" if "m > n" for m n
     by (metis that add.commute le_add_diff_inverse nat_less_le)
   then show ?thesis
     by (auto simp add: disjoint_family_on_def)
        (metis insert_absorb insert_subset le_SucE le_antisym not_le_imp_less)
 qed
 
 
 subsection \<open>Measure-Space.thy\<close>
 
 lemma AE_equal_sum:
   assumes "\<And>i. AE x in M. f i x = g i x"
   shows "AE x in M. (\<Sum>i\<in>I. f i x) = (\<Sum>i\<in>I. g i x)"
 proof (cases)
   assume "finite I"
   have "\<exists>A. A \<in> null_sets M \<and> (\<forall>x\<in> (space M - A). f i x = g i x)" for i
     using assms(1)[of i] by (metis (mono_tags, lifting) AE_E3)
   then obtain A where A: "\<And>i. A i \<in> null_sets M \<and> (\<forall>x\<in> (space M -A i). f i x = g i x)"
     by metis
   define B where "B = (\<Union>i\<in>I. A i)"
   have "B \<in> null_sets M" using \<open>finite I\<close> A B_def by blast
   then have "AE x in M. x \<in> space M - B" by (simp add: AE_not_in)
   moreover
   {
     fix x assume "x \<in> space M - B"
     then have "\<And>i. i \<in> I \<Longrightarrow> f i x = g i x" unfolding B_def using A by auto
     then have "(\<Sum>i\<in>I. f i x) = (\<Sum>i\<in>I. g i x)" by auto
   }
   ultimately show ?thesis by auto
 qed (simp)
 
 lemma emeasure_pos_unionE:
   assumes "\<And> (N::nat). A N \<in> sets M"
           "emeasure M (\<Union>N. A N) > 0"
   shows "\<exists>N. emeasure M (A N) > 0"
 proof (rule ccontr)
   assume "\<not>(\<exists>N. emeasure M (A N) > 0)"
   then have "\<And>N. A N \<in> null_sets M"
     using assms(1) by auto
   then have "(\<Union>N. A N) \<in> null_sets M" by auto
   then show False using assms(2) by auto
 qed
 
 lemma (in prob_space) emeasure_intersection:
   fixes e::"nat \<Rightarrow> real"
   assumes [measurable]: "\<And>n. U n \<in> sets M"
       and [simp]: "\<And>n. 0 \<le> e n" "summable e"
       and ge: "\<And>n. emeasure M (U n) \<ge> 1 - (e n)"
   shows "emeasure M (\<Inter>n. U n) \<ge> 1 - (\<Sum>n. e n)"
 proof -
   define V where "V = (\<lambda>n. space M - (U n))"
   have [measurable]: "V n \<in> sets M" for n
     unfolding V_def by auto
   have *: "emeasure M (V n) \<le> e n" for n
     unfolding V_def using ge[of n] by (simp add: emeasure_eq_measure prob_compl ennreal_leI)
   have "emeasure M (\<Union>n. V n) \<le> (\<Sum>n. emeasure M (V n))"
     by (rule emeasure_subadditive_countably, auto)
   also have "... \<le> (\<Sum>n. ennreal (e n))"
     using * by (intro suminf_le) auto
   also have "... = ennreal (\<Sum>n. e n)"
     by (intro suminf_ennreal_eq) auto
   finally have "emeasure M (\<Union>n. V n) \<le> suminf e" by simp
   then have "1 - suminf e \<le> emeasure M (space M - (\<Union>n. V n))"
     by (simp add: emeasure_eq_measure prob_compl suminf_nonneg)
   also have "... \<le> emeasure M (\<Inter>n. U n)"
     by (rule emeasure_mono) (auto simp: V_def)
   finally show ?thesis by simp
 qed
 
 lemma null_sym_diff_transitive:
   assumes "A \<Delta> B \<in> null_sets M" "B \<Delta> C \<in> null_sets M"
       and [measurable]: "A \<in> sets M" "C \<in> sets M"
   shows "A \<Delta> C \<in> null_sets M"
 proof -
   have "A \<Delta> B \<union> B \<Delta> C \<in> null_sets M" using assms(1) assms(2) by auto
   moreover have "A \<Delta> C \<subseteq> A \<Delta> B \<union> B \<Delta> C" by auto
   ultimately show ?thesis by (meson null_sets_subset assms(3) assms(4) sets.Diff sets.Un)
 qed
 
 lemma Delta_null_of_null_is_null:
   assumes "B \<in> sets M" "A \<Delta> B \<in> null_sets M" "A \<in> null_sets M"
   shows "B \<in> null_sets M"
 proof -
   have "B \<subseteq> A \<union> (A \<Delta> B)" by auto
   then show ?thesis using assms by (meson null_sets.Un null_sets_subset)
 qed
 
 lemma Delta_null_same_emeasure:
   assumes "A \<Delta> B \<in> null_sets M" and [measurable]: "A \<in> sets M" "B \<in> sets M"
   shows "emeasure M A = emeasure M B"
 proof -
   have "A = (A \<inter> B) \<union> (A-B)" by blast
   moreover have "A-B \<in> null_sets M" using assms null_sets_subset by blast
   ultimately have a: "emeasure M A = emeasure M (A \<inter> B)" using emeasure_Un_null_set by (metis assms(2) assms(3) sets.Int)
 
   have "B = (A \<inter> B) \<union> (B-A)" by blast
   moreover have "B-A \<in> null_sets M" using assms null_sets_subset by blast
   ultimately have "emeasure M B = emeasure M (A \<inter> B)" using emeasure_Un_null_set by (metis assms(2) assms(3) sets.Int)
   then show ?thesis using a by auto
 qed
 
 lemma AE_upper_bound_inf_ereal:
   fixes F G::"'a \<Rightarrow> ereal"
   assumes "\<And>e. (e::real) > 0 \<Longrightarrow> AE x in M. F x \<le> G x + e"
   shows "AE x in M. F x \<le> G x"
 proof -
   have "AE x in M. \<forall>n::nat. F x \<le> G x + ereal (1 / Suc n)"
     using assms by (auto simp: AE_all_countable)
   then show ?thesis
   proof (eventually_elim)
     fix x assume x: "\<forall>n::nat. F x \<le> G x + ereal (1 / Suc n)"
     show "F x \<le> G x"
     proof (intro ereal_le_epsilon2[of _ "G x"] allI impI)
       fix e :: real assume "0 < e"
       then obtain n where n: "1 / Suc n < e"
         by (blast elim: nat_approx_posE)
       have "F x \<le> G x + 1 / Suc n"
         using x by simp
       also have "\<dots> \<le> G x + e"
         using n by (intro add_mono ennreal_leI) auto
       finally show "F x \<le> G x + ereal e" .
     qed
   qed
 qed
 
 
 text \<open>Egorov theorem asserts that, if a sequence of functions converges almost everywhere to a
 limit, then the convergence is uniform on a subset of close to full measure. The first step in the
 proof is the following lemma, often useful by itself, asserting the same result for predicates:
 if a property $P_n x$ is eventually true for almost every $x$, then there exists $N$
 such that $P_n x$ is true for all $n\geq N$ and all $x$ in a set of close to full measure.
 \<close>
 lemma (in finite_measure) Egorov_lemma:
   assumes [measurable]: "\<And>n. (P n) \<in> measurable M (count_space UNIV)"
       and "AE x in M. eventually (\<lambda>n. P n x) sequentially"
           "epsilon > 0"
   shows "\<exists>U N. U \<in> sets M \<and> (\<forall>n \<ge> N. \<forall>x \<in> U. P n x) \<and> emeasure M (space M - U) < epsilon"
 proof -
   define K where "K = (\<lambda>n. {x \<in> space M. \<exists>k\<ge>n. \<not>(P k x)})"
   have [measurable]: "K n \<in> sets M" for n
     unfolding K_def by auto
   have "x \<notin> (\<Inter>n. K n)" if "eventually (\<lambda>n. P n x) sequentially" for x
     unfolding K_def using that unfolding K_def eventually_sequentially by auto
   then have "AE x in M. x \<notin> (\<Inter>n. K n)" using assms by auto
   then have Z: "0 = emeasure M (\<Inter>n. K n)"
     using AE_iff_measurable[of "(\<Inter>n. K n)" M "\<lambda>x. x \<notin> (\<Inter>n. K n)"] unfolding K_def by auto
   have *: "(\<lambda>n. emeasure M (K n)) \<longlonglongrightarrow> 0"
     unfolding Z apply (rule Lim_emeasure_decseq) using order_trans by (auto simp add: K_def decseq_def)
   have "eventually (\<lambda>n. emeasure M (K n) < epsilon) sequentially"
     by (rule order_tendstoD(2)[OF * \<open>epsilon > 0\<close>])
   then obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> emeasure M (K n) < epsilon"
     unfolding eventually_sequentially by auto
   define U where "U = space M - K N"
   have A [measurable]: "U \<in> sets M" unfolding U_def by auto
   have "space M - U = K N"
     unfolding U_def K_def by auto
   then have B: "emeasure M (space M - U) < epsilon"
     using N by auto
   have "\<forall>n \<ge> N. \<forall>x \<in> U. P n x"
     unfolding U_def K_def by auto
   then show ?thesis using A B by blast
 qed
 
 text \<open>The next lemma asserts that, in an uncountable family of disjoint sets, then there is one
 set with zero measure (and in fact uncountably many). It is often applied to the boundaries of
 $r$-neighborhoods of a given set, to show that one could choose $r$ for which this boundary has
 zero measure (this shows up often in relation with weak convergence).\<close>
 
 lemma (in finite_measure) uncountable_disjoint_family_then_exists_zero_measure:
   assumes [measurable]: "\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets M"
       and "uncountable I"
           "disjoint_family_on A I"
   shows "\<exists>i\<in>I. measure M (A i) = 0"
 proof -
   define f where "f = (\<lambda>(r::real). {i \<in> I. measure M (A i) > r})"
   have *: "finite (f r)" if "r > 0" for r
   proof -
     obtain N::nat where N: "measure M (space M)/r \<le> N"
       using real_arch_simple by blast
     have "finite (f r) \<and> card (f r) \<le> N"
     proof (rule finite_if_finite_subsets_card_bdd)
       fix G assume G: "G \<subseteq> f r" "finite G"
       then have "G \<subseteq> I" unfolding f_def by auto
       have "card G * r = (\<Sum>i \<in> G. r)" by auto
       also have "... \<le> (\<Sum>i \<in> G. measure M (A i))"
         apply (rule sum_mono) using G unfolding f_def by auto
       also have "... = measure M (\<Union>i\<in>G. A i)"
         apply (rule finite_measure_finite_Union[symmetric])
         using \<open>finite G\<close> \<open>G \<subseteq> I\<close> \<open>disjoint_family_on A I\<close> disjoint_family_on_mono by auto
       also have "... \<le> measure M (space M)"
         by (simp add: bounded_measure)
       finally have "card G \<le> measure M (space M)/r"
         using \<open>r > 0\<close> by (simp add: divide_simps)
       then show "card G \<le> N" using N by auto
     qed
     then show ?thesis by simp
   qed
   have "countable (\<Union>n. f (((1::real)/2)^n))"
     by (rule countable_UN, auto intro!: countable_finite *)
   then have "I - (\<Union>n. f (((1::real)/2)^n)) \<noteq> {}"
     using assms(2) by (metis countable_empty uncountable_minus_countable)
   then obtain i where "i \<in> I" "i \<notin> (\<Union>n. f ((1/2)^n))" by auto
   then have "measure M (A i) \<le> (1 / 2) ^ n" for n
     unfolding f_def using linorder_not_le by auto
   moreover have "(\<lambda>n. ((1::real) / 2) ^ n) \<longlonglongrightarrow> 0"
     by (intro tendsto_intros, auto)
   ultimately have "measure M (A i) \<le> 0"
     using LIMSEQ_le_const by force
   then have "measure M (A i) = 0"
     by (simp add: measure_le_0_iff)
   then show ?thesis using \<open>i \<in> I\<close> by auto
 qed
 
 text \<open>The next statements are useful measurability statements.\<close>
 
 lemma measurable_Inf [measurable]:
   assumes [measurable]: "\<And>(n::nat). P n \<in> measurable M (count_space UNIV)"
   shows "(\<lambda>x. Inf {n. P n x}) \<in> measurable M (count_space UNIV)" (is "?f \<in> _")
 proof -
   define A where "A = (\<lambda>n. (P n)-`{True} \<inter> space M - (\<Union>m<n. (P m)-`{True} \<inter> space M))"
   have A_meas [measurable]: "A n \<in> sets M" for n unfolding A_def by measurable
   define B where "B = (\<lambda>n. if n = 0 then (space M - (\<Union>n. A n)) else A (n-1))"
   show ?thesis
   proof (rule measurable_piecewise_restrict2[of B])
     show "B n \<in> sets M" for n unfolding B_def by simp
     show "space M = (\<Union>n. B n)"
       unfolding B_def using sets.sets_into_space [OF A_meas] by auto
     have *: "?f x = n" if "x \<in> A n" for x n
       apply (rule cInf_eq_minimum) using that unfolding A_def by auto
     moreover have **: "?f x = (Inf ({}::nat set))" if "x \<in> space M - (\<Union>n. A n)" for x
     proof -
       have "\<not>(P n x)" for n
         apply (induction n rule: nat_less_induct) using that unfolding A_def by auto
       then show ?thesis by simp
     qed
     ultimately have "\<exists>c. \<forall>x \<in> B n. ?f x = c" for n
       apply (cases "n = 0") unfolding B_def by auto
     then show "\<exists>h \<in> measurable M (count_space UNIV). \<forall>x \<in> B n. ?f x = h x" for n
       by fastforce
   qed
 qed
 
 lemma measurable_T_iter [measurable]:
   fixes f::"'a \<Rightarrow> nat"
   assumes [measurable]: "T \<in> measurable M M"
           "f \<in> measurable M (count_space UNIV)"
   shows "(\<lambda>x. (T^^(f x)) x) \<in> measurable M M"
 proof -
   have [measurable]: "(T^^n) \<in> measurable M M" for n::nat
     by (induction n, auto)
   show ?thesis
     by (rule measurable_compose_countable, auto)
 qed
 
 lemma measurable_infdist [measurable]:
   "(\<lambda>x. infdist x S) \<in> borel_measurable borel"
 by (rule borel_measurable_continuous_onI, intro continuous_intros)
 
 text \<open>The next lemma shows that, in a sigma finite measure space, sets with large measure
 can be approximated by sets with large but finite measure.\<close>
 
 lemma (in sigma_finite_measure) approx_with_finite_emeasure:
   assumes W_meas: "W \<in> sets M"
       and W_inf: "emeasure M W > C"
   obtains Z where "Z \<in> sets M" "Z \<subseteq> W" "emeasure M Z < \<infinity>" "emeasure M Z > C"
 proof (cases "emeasure M W = \<infinity>")
   case True
   obtain r where r: "C = ennreal r" using W_inf by (cases C, auto)
   obtain Z where "Z \<in> sets M" "Z \<subseteq> W" "emeasure M Z < \<infinity>" "emeasure M Z > C"
     unfolding r using approx_PInf_emeasure_with_finite[OF W_meas True, of r] by auto
   then show ?thesis using that by blast
 next
   case False
   then have "W \<in> sets M" "W \<subseteq> W" "emeasure M W < \<infinity>" "emeasure M W > C"
     using assms apply auto using top.not_eq_extremum by blast
   then show ?thesis using that by blast
 qed
 
 subsection \<open>Nonnegative-Lebesgue-Integration.thy\<close>
 
 text \<open>The next lemma is a variant of \verb+nn_integral_density+,
 with the density on the right instead of the left, as seems more common.\<close>
 
 lemma nn_integral_densityR:
   assumes [measurable]: "f \<in> borel_measurable F" "g \<in> borel_measurable F"
   shows "(\<integral>\<^sup>+ x. f x * g x \<partial>F) = (\<integral>\<^sup>+ x. f x \<partial>(density F g))"
 proof -
   have "(\<integral>\<^sup>+ x. f x * g x \<partial>F) = (\<integral>\<^sup>+ x. g x * f x \<partial>F)" by (simp add: mult.commute)
   also have "... = (\<integral>\<^sup>+ x. f x \<partial>(density F g))"
     by (rule nn_integral_density[symmetric], simp_all add: assms)
   finally show ?thesis by simp
 qed
 
 lemma not_AE_zero_int_ennreal_E:
   fixes f::"'a \<Rightarrow> ennreal"
   assumes "(\<integral>\<^sup>+x. f x \<partial>M) > 0"
       and [measurable]: "f \<in> borel_measurable M"
   shows "\<exists>A\<in>sets M. \<exists>e::real>0. emeasure M A > 0 \<and> (\<forall>x \<in> A. f x \<ge> e)"
 proof (rule not_AE_zero_ennreal_E, auto simp add: assms)
   assume *: "AE x in M. f x = 0"
   have "(\<integral>\<^sup>+x. f x \<partial>M) = (\<integral>\<^sup>+x. 0 \<partial>M)" by (rule nn_integral_cong_AE, simp add: *)
   then have "(\<integral>\<^sup>+x. f x \<partial>M) = 0" by simp
   then show False using assms by simp
 qed
 
 lemma (in finite_measure) nn_integral_bounded_eq_bound_then_AE:
   assumes "AE x in M. f x \<le> ennreal c" "(\<integral>\<^sup>+x. f x \<partial>M) = c * emeasure M (space M)"
       and [measurable]: "f \<in> borel_measurable M"
   shows "AE x in M. f x = c"
 proof (cases)
   assume "emeasure M (space M) = 0"
   then show ?thesis by (rule emeasure_0_AE)
 next
   assume "emeasure M (space M) \<noteq> 0"
   have fin: "AE x in M. f x \<noteq> top" using assms by (auto simp: top_unique)
   define g where "g = (\<lambda>x. c - f x)"
   have [measurable]: "g \<in> borel_measurable M" unfolding g_def by auto
   have "(\<integral>\<^sup>+x. g x \<partial>M) = (\<integral>\<^sup>+x. c \<partial>M) - (\<integral>\<^sup>+x. f x \<partial>M)"
     unfolding g_def by (rule nn_integral_diff, auto simp add: assms ennreal_mult_eq_top_iff)
   also have "\<dots> = 0" using assms(2) by (auto simp: ennreal_mult_eq_top_iff)
   finally have "AE x in M. g x = 0"
     by (subst nn_integral_0_iff_AE[symmetric]) auto
   then have "AE x in M. c \<le> f x" unfolding g_def using fin by (auto simp: ennreal_minus_eq_0)
   then show ?thesis using assms(1) by auto
 qed
 
 
 lemma null_sets_density:
   assumes [measurable]: "h \<in> borel_measurable M"
       and "AE x in M. h x \<noteq> 0"
   shows "null_sets (density M h) = null_sets M"
 proof -
   have *: "A \<in> sets M \<and> (AE x\<in>A in M. h x = 0) \<longleftrightarrow> A \<in> null_sets M" for A
   proof (auto)
     assume "A \<in> sets M" "AE x\<in>A in M. h x = 0"
     then show "A \<in> null_sets M"
       unfolding AE_iff_null_sets[OF \<open>A \<in> sets M\<close>] using assms(2) by auto
   next
     assume "A \<in> null_sets M"
     then show "AE x\<in>A in M. h x = 0"
       by (metis (mono_tags, lifting) AE_not_in eventually_mono)
   qed
   show ?thesis
     apply (rule set_eqI)
     unfolding null_sets_density_iff[OF \<open>h \<in> borel_measurable M\<close>] using * by auto
 qed
 
 
 text \<open>The next proposition asserts that, if a function $h$ is integrable, then its integral on
 any set with small enough measure is small. The good conceptual proof is by considering the
 distribution of the function $h$ on $\mathbb{R}$ and looking at its tails. However, there is a
 less conceptual but more direct proof, based on dominated convergence and a proof by contradiction.
 This is the proof we give below.\<close>
 
 proposition integrable_small_integral_on_small_sets:
   fixes h::"'a \<Rightarrow> real"
   assumes [measurable]: "integrable M h"
       and "delta > 0"
   shows "\<exists>epsilon>(0::real). \<forall>U \<in> sets M. emeasure M U < epsilon \<longrightarrow> abs (\<integral>x\<in>U. h x \<partial>M) < delta"
 proof (rule ccontr)
   assume H: "\<not> (\<exists>epsilon>0. \<forall>U\<in>sets M. emeasure M U < ennreal epsilon \<longrightarrow> abs(set_lebesgue_integral M U h) < delta)"
   have "\<exists>f. \<forall>epsilon\<in>{0<..}. f epsilon \<in>sets M \<and> emeasure M (f epsilon) < ennreal epsilon
                             \<and> \<not>(abs(set_lebesgue_integral M (f epsilon) h) < delta)"
     apply (rule bchoice) using H by auto
   then obtain f::"real \<Rightarrow> 'a set" where f:
               "\<And>epsilon. epsilon > 0 \<Longrightarrow> f epsilon \<in>sets M"
               "\<And>epsilon. epsilon > 0 \<Longrightarrow> emeasure M (f epsilon) < ennreal epsilon"
               "\<And>epsilon. epsilon > 0 \<Longrightarrow> \<not>(abs(set_lebesgue_integral M (f epsilon) h) < delta)"
     by blast
   define A where "A = (\<lambda>n::nat. f ((1/2)^n))"
   have [measurable]: "A n \<in> sets M" for n
     unfolding A_def using f(1) by auto
   have *: "emeasure M (A n) < ennreal ((1/2)^n)" for n
     unfolding A_def using f(2) by auto
   have Large: "\<not>(abs(set_lebesgue_integral M (A n) h) < delta)" for n
     unfolding A_def using f(3) by auto
 
   have S: "summable (\<lambda>n. Sigma_Algebra.measure M (A n))"
     apply (rule summable_comparison_test'[of "\<lambda>n. (1/2)^n" 0])
     apply (rule summable_geometric, auto)
     apply (subst ennreal_le_iff[symmetric], simp)
     using less_imp_le[OF *] by (metis * emeasure_eq_ennreal_measure top.extremum_strict)
   have "AE x in M. eventually (\<lambda>n. x \<in> space M - A n) sequentially"
     apply (rule borel_cantelli_AE1, auto simp add: S)
     by (metis * top.extremum_strict top.not_eq_extremum)
   moreover have "(\<lambda>n. indicator (A n) x * h x) \<longlonglongrightarrow> 0"
     if "eventually (\<lambda>n. x \<in> space M - A n) sequentially" for x
   proof -
     have "eventually (\<lambda>n. indicator (A n) x * h x = 0) sequentially"
       apply (rule eventually_mono[OF that]) unfolding indicator_def by auto
     then show ?thesis
       unfolding eventually_sequentially using lim_explicit by force
   qed
   ultimately have A: "AE x in M. ((\<lambda>n. indicator (A n) x * h x) \<longlonglongrightarrow> 0)"
     by auto
   have I: "integrable M (\<lambda>x. abs(h x))"
     using \<open>integrable M h\<close> by auto
   have L: "(\<lambda>n. abs (\<integral>x. indicator (A n) x * h x \<partial>M)) \<longlonglongrightarrow> abs (\<integral>x. 0 \<partial>M)"
     apply (intro tendsto_intros)
     apply (rule integral_dominated_convergence[OF _ _ I A])
     unfolding indicator_def by auto
   have "eventually (\<lambda>n. abs (\<integral>x. indicator (A n) x * h x \<partial>M) < delta) sequentially"
     apply (rule order_tendstoD[OF L]) using \<open>delta > 0\<close> by auto
   then show False
     using Large by (auto simp: set_lebesgue_integral_def)
 qed
 
 text \<open>We also give the version for nonnegative ennreal valued functions. It follows from the
 previous one.\<close>
 
 proposition small_nn_integral_on_small_sets:
   fixes h::"'a \<Rightarrow> ennreal"
   assumes [measurable]: "h \<in> borel_measurable M"
       and "delta > (0::real)" "(\<integral>\<^sup>+x. h x \<partial>M) \<noteq> \<infinity>"
   shows "\<exists>epsilon>(0::real). \<forall>U \<in> sets M. emeasure M U < epsilon \<longrightarrow> (\<integral>\<^sup>+x\<in>U. h x \<partial>M) < delta"
 proof -
   define f where "f = (\<lambda>x. enn2real(h x))"
   have "AE x in M. h x \<noteq> \<infinity>"
     using assms by (metis nn_integral_PInf_AE)
   then have *: "AE x in M. ennreal (f x) = h x"
     unfolding f_def using ennreal_enn2real_if by auto
   have **: "(\<integral>\<^sup>+x. ennreal (f x) \<partial>M) \<noteq> \<infinity>"
     using nn_integral_cong_AE[OF *] assms by auto
   have [measurable]: "f \<in> borel_measurable M" unfolding f_def by auto
   have "integrable M f"
     apply (rule integrableI_nonneg) using assms * f_def ** apply auto
     using top.not_eq_extremum by blast
   obtain epsilon::real where H: "epsilon > 0" "\<And>U. U \<in> sets M \<Longrightarrow> emeasure M U < epsilon \<Longrightarrow> abs(\<integral>x\<in>U. f x \<partial>M) < delta"
     using integrable_small_integral_on_small_sets[OF \<open>integrable M f\<close> \<open>delta > 0\<close>] by blast
   have "(\<integral>\<^sup>+x\<in>U. h x \<partial>M) < delta" if [measurable]: "U \<in> sets M" "emeasure M U < epsilon" for U
   proof -
     have "(\<integral>\<^sup>+x. indicator U x * h x \<partial>M) = (\<integral>\<^sup>+x. ennreal(indicator U x * f x) \<partial>M)"
       apply (rule nn_integral_cong_AE) using * unfolding indicator_def by auto
     also have "... = ennreal (\<integral>x. indicator U x * f x \<partial>M)"
       apply (rule nn_integral_eq_integral)
       apply (rule Bochner_Integration.integrable_bound[OF \<open>integrable M f\<close>])
       unfolding indicator_def f_def by auto
     also have "... < ennreal delta"
       apply (rule ennreal_lessI) using H(2)[OF that] by (auto simp: set_lebesgue_integral_def)
     finally show ?thesis by (auto simp add: mult.commute)
   qed
   then show ?thesis using \<open>epsilon > 0\<close> by auto
 qed
 
 subsection \<open>Probability-measure.thy\<close>
 
 text \<open>The next lemmas ensure that, if sets have a probability close to $1$, then their
 intersection also does.\<close>
 
 lemma (in prob_space) sum_measure_le_measure_inter:
   assumes "A \<in> sets M" "B \<in> sets M"
   shows "prob A + prob B \<le> 1 + prob (A \<inter> B)"
 proof -
   have "prob A + prob B = prob (A \<union> B) + prob (A \<inter> B)"
     by (simp add: assms fmeasurable_eq_sets measure_Un3)
   also have "... \<le> 1 + prob (A \<inter> B)"
     by auto
   finally show ?thesis by simp
 qed
 
 lemma (in prob_space) sum_measure_le_measure_inter3:
   assumes [measurable]: "A \<in> sets M" "B \<in> sets M" "C \<in> sets M"
   shows "prob A + prob B + prob C \<le> 2 + prob (A \<inter> B \<inter> C)"
 using sum_measure_le_measure_inter[of B C] sum_measure_le_measure_inter[of A "B \<inter> C"]
 by (auto simp add: inf_assoc)
 
 lemma (in prob_space) sum_measure_le_measure_Inter:
   assumes [measurable]: "finite I" "I \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> A i \<in> sets M"
   shows "(\<Sum>i\<in>I. prob (A i)) \<le> real(card I) - 1 + prob (\<Inter>i\<in>I. A i)"
 using assms proof (induct I rule: finite_ne_induct)
   fix x F assume H: "finite F" "F \<noteq> {}" "x \<notin> F"
             "((\<And>i. i \<in> F \<Longrightarrow> A i \<in> events) \<Longrightarrow> (\<Sum>i\<in>F. prob (A i)) \<le> real (card F) - 1 + prob (\<Inter>(A ` F)))"
         and [measurable]: "(\<And>i. i \<in> insert x F \<Longrightarrow> A i \<in> events)"
   have "(\<Inter>x\<in>F. A x) \<in> events" using \<open>finite F\<close> \<open>F \<noteq> {}\<close> by auto
   have "(\<Sum>i\<in>insert x F. prob (A i)) = (\<Sum>i\<in>F. prob (A i)) + prob (A x)"
     using H(1) H(3) by auto
   also have "... \<le> real (card F)-1 + prob (\<Inter>(A ` F)) + prob (A x)"
     using H(4) by auto
   also have "... \<le> real (card F) + prob ((\<Inter>(A ` F)) \<inter> A x)"
     using sum_measure_le_measure_inter[OF \<open>(\<Inter>x\<in>F. A x) \<in> events\<close>, of "A x"] by auto
   also have "... = real (card (insert x F)) - 1 + prob (\<Inter>(A ` (insert x F)))"
     using H(1) H(2) unfolding card_insert_disjoint[OF \<open>finite F\<close> \<open>x \<notin> F\<close>] by (simp add: inf_commute)
   finally show "(\<Sum>i\<in>insert x F. prob (A i)) \<le> real (card (insert x F)) - 1 + prob (\<Inter>(A ` (insert x F)))"
     by simp
 qed (auto)
 
 text \<open>A random variable gives a small mass to small neighborhoods of
 infinity.\<close>
 lemma (in prob_space) random_variable_small_tails:
   assumes "alpha > 0" and [measurable]: "f \<in> borel_measurable M"
   shows "\<exists>(C::real). prob {x \<in> space M. abs(f x) \<ge> C} < alpha \<and> C \<ge> K"
 proof -
   have *: "(\<Inter>(n::nat). {x\<in>space M. abs(f x) \<ge> n}) = {}"
     apply auto
     by (metis real_arch_simple add.right_neutral add_mono_thms_linordered_field(4) not_less zero_less_one)
   have **: "(\<lambda>n. prob {x \<in> space M. abs(f x) \<ge> n}) \<longlonglongrightarrow> prob (\<Inter>(n::nat). {x \<in> space M. abs(f x) \<ge> n})"
     by (rule finite_Lim_measure_decseq, auto simp add: decseq_def)
   have "eventually (\<lambda>n. prob {x \<in> space M. abs(f x) \<ge> n} < alpha) sequentially"
     apply (rule order_tendstoD[OF _ \<open>alpha > 0\<close>]) using ** unfolding * by auto
   then obtain N::nat where N: "\<And>n::nat. n \<ge> N \<Longrightarrow> prob {x \<in> space M. abs(f x) \<ge> n} < alpha"
     unfolding eventually_sequentially by blast
   have "\<exists>n::nat. n \<ge> N \<and> n \<ge> K"
     by (meson le_cases of_nat_le_iff order.trans real_arch_simple)
   then obtain n::nat where n: "n \<ge> N" "n \<ge> K" by blast
   show ?thesis
     apply (rule exI[of _ "of_nat n"]) using N n by auto
 qed
 
 subsection \<open>Distribution-functions.thy\<close>
 
 text \<open>There is a locale called \verb+finite_borel_measure+ in \verb+distribution-functions.thy+.
 However, it only deals with real measures, and real weak convergence. I will not need the
 weak convergence in more general settings, but still it seems more natural to me to do the
 proofs in the natural settings. Let me introduce the locale \verb+finite_borel_measure'+ for
 this, although it would be better to rename the locale in the library file.\<close>
 
 locale finite_borel_measure' = finite_measure M for M :: "('a::metric_space) measure" +
   assumes M_is_borel [simp, measurable_cong]: "sets M = sets borel"
 begin
 
 lemma space_eq_univ [simp]: "space M = UNIV"
   using M_is_borel[THEN sets_eq_imp_space_eq] by simp
 
 lemma measurable_finite_borel [simp]:
   "f \<in> borel_measurable borel \<Longrightarrow> f \<in> borel_measurable M"
   by (rule borel_measurable_subalgebra[where N = borel]) auto
 
 text \<open>Any closed set can be slightly enlarged to obtain a set whose boundary has $0$ measure.\<close>
 
 lemma approx_closed_set_with_set_zero_measure_boundary:
   assumes "closed S" "epsilon > 0" "S \<noteq> {}"
   shows "\<exists>r. r < epsilon \<and> r > 0 \<and> measure M {x. infdist x S = r} = 0 \<and> measure M {x. infdist x S \<le> r} < measure M S + epsilon"
 proof -
   have [measurable]: "S \<in> sets M"
     using \<open>closed S\<close> by auto
   define T where "T = (\<lambda>r. {x. infdist x S \<le> r})"
   have [measurable]: "T r \<in> sets borel" for r
     unfolding T_def by measurable
   have *: "(\<Inter>n. T ((1/2)^n)) = S"
   unfolding T_def proof (auto)
     fix x assume *: "\<forall>n. infdist x S \<le> (1 / 2) ^n"
     have "infdist x S \<le> 0"
       apply (rule LIMSEQ_le_const[of "\<lambda>n. (1/2)^n"], intro tendsto_intros) using * by auto
     then show "x \<in> S"
       using assms infdist_pos_not_in_closed by fastforce
   qed
   have A: "((1::real)/2)^n \<le> (1/2)^m" if "m \<le> n" for m n::nat
     using that by (simp add: power_decreasing)
   have "(\<lambda>n. measure M (T ((1/2)^n))) \<longlonglongrightarrow> measure M S"
     unfolding *[symmetric] apply (rule finite_Lim_measure_decseq, auto simp add: T_def decseq_def)
     using A order.trans by blast
   then have B: "eventually (\<lambda>n. measure M (T ((1/2)^n)) < measure M S + epsilon) sequentially"
     apply (rule order_tendstoD) using \<open>epsilon > 0\<close> by simp
   have C: "eventually (\<lambda>n. (1/2)^n < epsilon) sequentially"
     by (rule order_tendstoD[OF _ \<open>epsilon > 0\<close>], intro tendsto_intros, auto)
   obtain n where n: "(1/2)^n < epsilon" "measure M (T ((1/2)^n)) < measure M S + epsilon"
     using eventually_conj[OF B C] unfolding eventually_sequentially by auto
   have "\<exists>r\<in>{0<..<(1/2)^n}. measure M {x. infdist x S = r} = 0"
     apply (rule uncountable_disjoint_family_then_exists_zero_measure, auto simp add: disjoint_family_on_def)
     using uncountable_open_interval by fastforce
   then obtain r where r: "r\<in>{0<..<(1/2)^n}" "measure M {x. infdist x S = r} = 0"
     by blast
   then have r2: "r > 0" "r < epsilon" using n by auto
   have "measure M {x. infdist x S \<le> r} \<le> measure M {x. infdist x S \<le> (1/2)^n}"
     apply (rule finite_measure_mono) using r by auto
   then have "measure M {x. infdist x S \<le> r} < measure M S + epsilon"
     using n(2) unfolding T_def by auto
   then show ?thesis
     using r(2) r2 by auto
 qed
 end (* of locale finite_borel_measure'*)
 
 sublocale finite_borel_measure \<subseteq> finite_borel_measure'
   by (standard, simp add: M_is_borel)
 
 
 subsection \<open>Weak-convergence.thy\<close>
 
 text \<open>Since weak convergence is not implemented as a topology, the fact that the convergence of
 a sequence implies the convergence of a subsequence is not automatic. We prove it in the lemma
 below..\<close>
 
 lemma weak_conv_m_subseq:
   assumes "weak_conv_m M_seq M" "strict_mono r"
   shows "weak_conv_m (\<lambda>n. M_seq (r n)) M"
 using assms LIMSEQ_subseq_LIMSEQ unfolding weak_conv_m_def weak_conv_def comp_def by auto
 
 context
   fixes \<mu> :: "nat \<Rightarrow> real measure"
     and M :: "real measure"
   assumes \<mu>: "\<And>n. real_distribution (\<mu> n)"
   assumes M: "real_distribution M"
   assumes \<mu>_to_M: "weak_conv_m \<mu> M"
 begin
 
 text \<open>The measure of a closed set behaves upper semicontinuously with respect to weak convergence:
 if $\mu_n \to \mu$, then $\limsup \mu_n(F) \leq \mu(F)$ (and the inequality can be strict, think of
 the situation where $\mu$ is a Dirac mass at $0$ and $F = \{0\}$, but $\mu_n$ has a density so that
 $\mu_n(\{0\}) = 0$).\<close>
 
 lemma closed_set_weak_conv_usc:
   assumes "closed S" "measure M S < l"
   shows "eventually (\<lambda>n. measure (\<mu> n) S < l) sequentially"
 proof (cases "S = {}")
   case True
   then show ?thesis
     using \<open>measure M S < l\<close> by auto
 next
   case False
   interpret real_distribution M using M by simp
   define epsilon where "epsilon = l - measure M S"
   have "epsilon > 0" unfolding epsilon_def using assms(2) by auto
   obtain r where r: "r > 0" "r < epsilon" "measure M {x. infdist x S = r} = 0" "measure M {x. infdist x S \<le> r} < measure M S + epsilon"
     using approx_closed_set_with_set_zero_measure_boundary[OF \<open>closed S\<close> \<open>epsilon > 0\<close> \<open>S \<noteq> {}\<close>] by blast
   define T where "T = {x. infdist x S \<le> r}"
   have [measurable]: "T \<in> sets borel"
     unfolding T_def by auto
   have "S \<subseteq> T"
     unfolding T_def using \<open>closed S\<close> \<open>r > 0\<close> by auto
   have "measure M T < l"
     using r(4) unfolding T_def epsilon_def by auto
   have "measure M (frontier T) \<le> measure M {x. infdist x S = r}"
     apply (rule finite_measure_mono) unfolding T_def using frontier_indist_le by auto
   then have "measure M (frontier T) = 0"
     using \<open>measure M {x. infdist x S = r} = 0\<close> by (auto simp add: measure_le_0_iff)
   then have "(\<lambda>n. measure (\<mu> n) T) \<longlonglongrightarrow> measure M T"
     using \<mu>_to_M by (simp add: \<mu> emeasure_eq_measure real_distribution_axioms weak_conv_imp_continuity_set_conv)
   then have *: "eventually (\<lambda>n. measure (\<mu> n) T < l) sequentially"
     apply (rule order_tendstoD) using \<open>measure M T < l\<close> by simp
   have **: "measure (\<mu> n) S \<le> measure (\<mu> n) T" for n
     apply (rule finite_measure.finite_measure_mono)
     using \<mu> apply (simp add: finite_borel_measure.axioms(1) real_distribution.finite_borel_measure_M)
     using \<open>S \<subseteq> T\<close> apply simp
     by (simp add: \<mu> real_distribution.events_eq_borel)
   show ?thesis
     apply (rule eventually_mono[OF *]) using ** le_less_trans by auto
 qed
 
 text \<open>In the same way, the measure of an open set behaves lower semicontinuously with respect to
 weak convergence: if $\mu_n \to \mu$, then $\liminf \mu_n(U) \geq \mu(U)$ (and the inequality can be
 strict). This follows from the same statement for closed sets by passing to the complement.\<close>
 
 lemma open_set_weak_conv_lsc:
   assumes "open S" "measure M S > l"
   shows "eventually (\<lambda>n. measure (\<mu> n) S > l) sequentially"
 proof -
   interpret real_distribution M
     using M by auto
   have [measurable]: "S \<in> events" using assms(1) by auto
   have "eventually (\<lambda>n. measure (\<mu> n) (UNIV - S) < 1 - l) sequentially"
     apply (rule closed_set_weak_conv_usc)
     using assms prob_compl[of S] by auto
   moreover have "measure (\<mu> n) (UNIV - S) = 1 - measure (\<mu> n) S" for n
   proof -
     interpret mu: real_distribution "\<mu> n"
       using \<mu> by auto
     have "S \<in> mu.events" using assms(1) by auto
     then show ?thesis using mu.prob_compl[of S] by auto
   qed
   ultimately show ?thesis by auto
 qed
 
 end (*of context weak_conv_m*)
 
 end (*of SG_Library_Complement.thy*)
diff --git a/thys/Green/Green.thy b/thys/Green/Green.thy
--- a/thys/Green/Green.thy
+++ b/thys/Green/Green.thy
@@ -1,3117 +1,3117 @@
 theory Green
   imports Paths Derivs Integrals General_Utils
 begin
 
 lemma frontier_Un_subset_Un_frontier:
      "frontier (s \<union> t) \<subseteq> (frontier s) \<union> (frontier t)"
   by (simp add: frontier_def Un_Diff) (auto simp add: closure_def interior_def islimpt_def)
 
 definition has_partial_derivative:: "(('a::euclidean_space) \<Rightarrow> 'b::euclidean_space) \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a) \<Rightarrow> bool" where
   "has_partial_derivative F base_vec F' a
         \<equiv> ((\<lambda>x::'a::euclidean_space. F( (a - ((a \<bullet> base_vec) *\<^sub>R base_vec)) + (x \<bullet> base_vec) *\<^sub>R base_vec ))
                 has_derivative F') (at a)"
 
 definition has_partial_vector_derivative:: "(('a::euclidean_space) \<Rightarrow> 'b::euclidean_space) \<Rightarrow> 'a \<Rightarrow> ( 'b) \<Rightarrow> ('a) \<Rightarrow> bool" where
   "has_partial_vector_derivative F base_vec F' a
         \<equiv> ((\<lambda>x. F( (a - ((a \<bullet> base_vec) *\<^sub>R base_vec)) + x *\<^sub>R base_vec ))
                 has_vector_derivative F') (at (a \<bullet> base_vec))"
 
 definition partially_vector_differentiable where
   "partially_vector_differentiable F base_vec p \<equiv> (\<exists>F'. has_partial_vector_derivative F base_vec F' p)"
 
 definition partial_vector_derivative:: "(('a::euclidean_space) \<Rightarrow> 'b::euclidean_space) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b" where
   "partial_vector_derivative F base_vec a
         \<equiv> (vector_derivative (\<lambda>x. F( (a - ((a \<bullet> base_vec) *\<^sub>R base_vec)) + x *\<^sub>R base_vec)) (at (a \<bullet> base_vec)))"
 
 lemma partial_vector_derivative_works:
   assumes "partially_vector_differentiable F base_vec a"
   shows "has_partial_vector_derivative F base_vec (partial_vector_derivative F base_vec a) a"
 proof -
   obtain F' where F'_prop: "((\<lambda>x. F( (a - ((a \<bullet> base_vec) *\<^sub>R base_vec)) + x *\<^sub>R base_vec ))
                             has_vector_derivative F') (at (a \<bullet> base_vec))"
     using assms partially_vector_differentiable_def has_partial_vector_derivative_def
     by blast
   show ?thesis
     using Derivative.differentiableI_vector[OF F'_prop]
     by(simp add: vector_derivative_works partial_vector_derivative_def[symmetric]
         has_partial_vector_derivative_def[symmetric])
 qed
 
 lemma fundamental_theorem_of_calculus_partial_vector:
   fixes a b:: "real" and
     F:: "('a::euclidean_space \<Rightarrow> 'b::euclidean_space)" and
     i:: "'a" and
     j:: "'b" and
     F_j_i:: "('a::euclidean_space \<Rightarrow> real)"
   assumes a_leq_b: "a \<le> b" and
     Base_vecs: "i \<in> Basis" "j \<in> Basis" and
     no_i_component: "c \<bullet> i = 0 " and
     has_partial_deriv: "\<forall>p \<in> D. has_partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i (F_j_i p) p" and
     domain_subset_of_D: "{x *\<^sub>R i + c |x. a \<le> x \<and> x \<le> b} \<subseteq> D"
   shows "((\<lambda>x. F_j_i( x *\<^sub>R i + c)) has_integral
           F(b *\<^sub>R i + c) \<bullet> j - F(a *\<^sub>R i + c) \<bullet> j) (cbox a b)"
 proof -
   let ?domain = "{v. \<exists>x. a \<le> x \<and> x \<le> b \<and> v = x *\<^sub>R i + c}"
   have "\<forall>x\<in> ?domain.  has_partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i (F_j_i x) x"
     using has_partial_deriv domain_subset_of_D
     by auto
   then have "\<forall>x\<in> (cbox a b).  ((\<lambda>x. F(x *\<^sub>R i + c) \<bullet> j) has_vector_derivative (F_j_i( x *\<^sub>R i + c))) (at x)"
   proof(clarsimp simp add: has_partial_vector_derivative_def)
     fix x::real
     assume range_of_x: "a \<le> x" "x \<le> b"
     assume ass2: "\<forall>x. (\<exists>z\<ge>a. z \<le> b \<and> x = z *\<^sub>R i + c) \<longrightarrow>
                      ((\<lambda>z. F(x - (x \<bullet> i) *\<^sub>R i + z *\<^sub>R i) \<bullet> j) has_vector_derivative F_j_i x) (at (x \<bullet> i))"
     have "((\<lambda>z. F((x *\<^sub>R i + c) - ((x *\<^sub>R i + c) \<bullet> i) *\<^sub>R i + z *\<^sub>R i) \<bullet> j) has_vector_derivative F_j_i (x *\<^sub>R i + c)) (at ((x *\<^sub>R i + c) \<bullet> i)) "
       using range_of_x ass2 by auto
     then have 0: "((\<lambda>x. F( c + x *\<^sub>R i) \<bullet> j) has_vector_derivative F_j_i (x *\<^sub>R i + c)) (at x)"
       by (simp add: assms(2) inner_left_distrib no_i_component)
     have 1: "(\<lambda>x. F(x *\<^sub>R i + c) \<bullet> j) = (\<lambda>x. F(c + x *\<^sub>R i) \<bullet> j)"
       by (simp add: add.commute)
     then show "((\<lambda>x. F(x *\<^sub>R i + c) \<bullet> j) has_vector_derivative F_j_i (x *\<^sub>R i + c)) (at x)" 
       using 0 and 1 by auto
   qed
   then have "\<forall>x\<in> (cbox a b).  ((\<lambda>x. F(x *\<^sub>R i + c) \<bullet> j) has_vector_derivative (F_j_i( x *\<^sub>R i + c))) (at_within x (cbox a b))"
     using has_vector_derivative_at_within
     by blast
   then show "( (\<lambda>x. F_j_i( x *\<^sub>R i + c)) has_integral
              F(b *\<^sub>R i + c) \<bullet> j - F(a *\<^sub>R i + c) \<bullet> j) (cbox a b)"
     using fundamental_theorem_of_calculus[of "a" "b" "(\<lambda>x::real.  F(x *\<^sub>R i + c) \<bullet> j)" "(\<lambda>x::real. F_j_i( x *\<^sub>R i + c))"] and
       a_leq_b
     by auto
 qed
 
 lemma fundamental_theorem_of_calculus_partial_vector_gen:
   fixes k1 k2:: "real" and
     F:: "('a::euclidean_space \<Rightarrow> 'b::euclidean_space)" and
     i:: "'a" and
     F_i:: "('a::euclidean_space \<Rightarrow> 'b)"
   assumes a_leq_b: "k1 \<le> k2" and
     unit_len: "i \<bullet> i = 1" and
     no_i_component: "c \<bullet> i = 0 " and
     has_partial_deriv: "\<forall>p \<in> D. has_partial_vector_derivative F i (F_i p) p" and
     domain_subset_of_D: "{v. \<exists>x. k1 \<le> x \<and> x \<le> k2 \<and> v = x *\<^sub>R i + c} \<subseteq> D"
   shows "( (\<lambda>x. F_i( x *\<^sub>R i + c)) has_integral
                                         F(k2 *\<^sub>R i + c) - F(k1 *\<^sub>R i + c)) (cbox k1 k2)"
 proof -
   let ?domain = "{v. \<exists>x. k1 \<le> x \<and> x \<le> k2 \<and> v = x *\<^sub>R i + c}"
   have "\<forall>x\<in> ?domain.  has_partial_vector_derivative F i (F_i x) x"
     using has_partial_deriv domain_subset_of_D
     by auto
   then have "\<forall>x\<in> (cbox k1 k2).  ((\<lambda>x. F(x *\<^sub>R i + c)) has_vector_derivative (F_i( x *\<^sub>R i + c))) (at x)"
   proof (clarsimp simp add: has_partial_vector_derivative_def)
     fix x::real
     assume range_of_x: "k1 \<le> x" "x \<le> k2"
     assume ass2: "\<forall>x. (\<exists>z\<ge>k1. z \<le> k2 \<and> x = z *\<^sub>R i + c) \<longrightarrow>
                      ((\<lambda>z. F(x - (x \<bullet> i) *\<^sub>R i + z *\<^sub>R i)) has_vector_derivative F_i x) (at (x \<bullet> i))"
     have "((\<lambda>z. F((x *\<^sub>R i + c) - ((x *\<^sub>R i + c) \<bullet> i) *\<^sub>R i + z *\<^sub>R i)) has_vector_derivative F_i (x *\<^sub>R i + c)) (at ((x *\<^sub>R i + c) \<bullet> i)) "
       using range_of_x ass2 by auto
     then have 0: "((\<lambda>x. F( c + x *\<^sub>R i)) has_vector_derivative F_i (x *\<^sub>R i + c)) (at x)"
       by (simp add: inner_commute inner_right_distrib no_i_component unit_len)
     have 1: "(\<lambda>x. F(x *\<^sub>R i + c)) = (\<lambda>x. F(c + x *\<^sub>R i))"
       by (simp add: add.commute)
     then show "((\<lambda>x. F(x *\<^sub>R i + c)) has_vector_derivative F_i (x *\<^sub>R i + c)) (at x)" using 0 and 1 by auto
   qed
   then have "\<forall>x\<in> (cbox k1 k2).  ((\<lambda>x. F(x *\<^sub>R i + c) ) has_vector_derivative (F_i( x *\<^sub>R i + c))) (at_within x (cbox k1 k2))"
     using has_vector_derivative_at_within
     by blast
   then show "( (\<lambda>x. F_i( x *\<^sub>R i + c)) has_integral
                                         F(k2 *\<^sub>R i + c) - F(k1 *\<^sub>R i + c)) (cbox k1 k2)"
     using fundamental_theorem_of_calculus[of "k1" "k2" "(\<lambda>x::real.  F(x *\<^sub>R i + c))" "(\<lambda>x::real. F_i( x *\<^sub>R i + c))"] and
       a_leq_b
     by auto
 qed
 
 lemma add_scale_img:
   assumes "a < b" shows "(\<lambda>x::real. a + (b - a) * x) ` {0 .. 1} = {a .. b}"
   using assms 
   apply (auto simp: algebra_simps affine_ineq image_iff)
   using less_eq_real_def apply force
   apply (rule_tac x="(x-a)/(b-a)" in bexI)
    apply (auto simp: field_simps)
   done
 
 lemma add_scale_img':
   assumes "a \<le> b"
   shows "(\<lambda>x::real. a + (b - a) * x) ` {0 .. 1} = {a .. b}"
 proof (cases "a = b")
   case True
   then show ?thesis by force
 next
   case False
   then show ?thesis
     using add_scale_img assms by auto
 qed
 
-definition analytically_valid:: "'a::euclidean_space set \<Rightarrow> ('a \<Rightarrow> 'b::{euclidean_space,times,one}) \<Rightarrow> 'a \<Rightarrow> bool" where
+definition analytically_valid:: "'a::euclidean_space set \<Rightarrow> ('a \<Rightarrow> 'b::{euclidean_space,times,zero_neq_one}) \<Rightarrow> 'a \<Rightarrow> bool" where
   "analytically_valid s F i \<equiv>
        (\<forall>a \<in> s. partially_vector_differentiable F i a) \<and>
        continuous_on s F \<and> \<comment> \<open>TODO: should we replace this with saying that \<open>F\<close> is partially diffrerentiable on \<open>Dy\<close>,\<close>
                            \<comment> \<open>i.e. there is a partial derivative on every dimension\<close>
        integrable lborel (\<lambda>p. (partial_vector_derivative F i) p * indicator s p) \<and>
        (\<lambda>x. integral UNIV (\<lambda>y. (partial_vector_derivative F i (y *\<^sub>R i + x *\<^sub>R (\<Sum> b \<in>(Basis - {i}). b)))
             * (indicator s (y *\<^sub>R i + x *\<^sub>R (\<Sum>b \<in> Basis - {i}. b)) ))) \<in> borel_measurable lborel"
   (*(\<lambda>x. integral UNIV (\<lambda>y. ((partial_vector_derivative F i) (y, x)) * (indicator s (y, x)))) \<in> borel_measurable lborel)"*)
 
 
 lemma analytically_valid_imp_part_deriv_integrable_on:
   assumes "analytically_valid (s::(real*real) set) (f::(real*real)\<Rightarrow> real) i"
   shows "(partial_vector_derivative f i) integrable_on s"
 proof -
   have "integrable lborel (\<lambda>p. partial_vector_derivative f i p * indicator s p)"
     using assms
     by(simp add:  analytically_valid_def indic_ident)
   then have "integrable lborel (\<lambda>p::(real*real). if p \<in> s then partial_vector_derivative f i p else 0)"
     using indic_ident[of "partial_vector_derivative f i"]
     by (simp add: indic_ident)
   then have "(\<lambda>x. if x \<in> s then partial_vector_derivative f i x else 0) integrable_on UNIV"
     using Equivalence_Lebesgue_Henstock_Integration.integrable_on_lborel
     by auto
   then show "(partial_vector_derivative f i) integrable_on s"
     using integrable_restrict_UNIV
     by auto
 qed
 
 (*******************************************************************************)
 
 definition typeII_twoCube :: "((real * real) \<Rightarrow> (real * real)) \<Rightarrow> bool" where
   "typeII_twoCube twoC
          \<equiv> \<exists>a b g1 g2. a < b \<and> (\<forall>x \<in> {a..b}. g2 x \<le> g1 x) \<and>
                        twoC = (\<lambda>(y, x). ((1 - y) * (g2 ((1-x)*a + x*b)) + y * (g1 ((1-x)*a + x*b)),
                                         (1-x)*a + x*b)) \<and>
                        g1 piecewise_C1_differentiable_on {a .. b} \<and>
                        g2 piecewise_C1_differentiable_on {a .. b}"
 
 abbreviation unit_cube where "unit_cube \<equiv> cbox (0,0) (1::real,1::real)" 
 
 definition cubeImage:: "two_cube \<Rightarrow> ((real*real) set)" where
   "cubeImage twoC \<equiv> (twoC ` unit_cube)"
 
 lemma typeII_twoCubeImg:
   assumes "typeII_twoCube twoC"
   shows "\<exists>a b g1 g2. a < b \<and> (\<forall>x \<in> {a .. b}. g2 x \<le> g1 x) \<and>
                       cubeImage twoC = {(y,x). x \<in> {a..b} \<and> y \<in> {g2 x .. g1 x}}
                       \<and> twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))
                       \<and> g1 piecewise_C1_differentiable_on {a .. b} \<and> g2 piecewise_C1_differentiable_on {a .. b} "
   using assms
 proof (simp add: typeII_twoCube_def cubeImage_def image_def)
   assume " \<exists>a b. a < b \<and> (\<exists>g1 g2. (\<forall>x\<in>{a..b}. g2 x \<le> g1 x) \<and>
                             twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b)) \<and>
                             g1 piecewise_C1_differentiable_on {a..b} \<and> g2 piecewise_C1_differentiable_on {a..b})"
   then obtain a b g1 g2 where
     twoCisTypeII: "a < b"
     "(\<forall>x\<in>{a..b}. g2 x \<le> g1 x)"
     "twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     by auto
   have ab1: "a - x * a + x * b \<le> b" if a1: "0 \<le> x" "x \<le> 1" for x
     using that apply (simp add: algebra_simps)
     by (metis affine_ineq less_eq_real_def mult.commute twoCisTypeII(1))
   have ex: "\<exists>z\<in>Green.unit_cube.
                (d, c) =
                (case z of
                 (y, x) \<Rightarrow>
                   (g2 (a - x * a + x * b) - y * g2 (a - x * a + x * b) + y * g1 (a - x * a + x * b),
                    a - x * a + x * b))" 
     if c_bounds: "a \<le> c" "c \<le> b" and d_bounds: "g2 c \<le> d" "d \<le> g1 c" for c d
   proof -
     have b_minus_a_nzero: "b - a \<noteq> 0" using twoCisTypeII(1) by auto
     have x_witness: "\<exists>k1. c = (1 - k1)*a + k1 * b \<and> 0 \<le> k1 \<and> k1 \<le> 1"
       apply (rule_tac x="(c - a)/(b - a)" in exI)
       using c_bounds \<open>a < b\<close> apply (simp add: divide_simps algebra_simps)
       using sum_sqs_eq by blast
     have y_witness: "\<exists>k2. d = (1 - k2)*(g2 c) + k2 * (g1 c) \<and> 0 \<le> k2 \<and> k2 \<le> 1"
     proof (cases "g1 c - g2 c = 0")
       case True
       with d_bounds show ?thesis by (fastforce simp add: algebra_simps)
     next
       case False
       let ?k2 = "(d - g2 c)/(g1 c - g2 c)"
       have k2_in_bounds: "0 \<le> ?k2 \<and> ?k2 \<le> 1" 
         using twoCisTypeII(2) c_bounds d_bounds False by simp
       have "d = (1 - ?k2) * g2 c + ?k2 * g1 c" 
         using False sum_sqs_eq by (fastforce simp add: divide_simps algebra_simps)
       with k2_in_bounds show ?thesis 
         by fastforce
     qed
     show "\<exists>x\<in>unit_cube. (d, c) = (case x of (y, x) \<Rightarrow> (g2 (a - x * a + x * b) - y * g2 (a - x * a + x * b) + y * g1 (a - x * a + x * b), a - x * a + x * b))"
       using x_witness y_witness by (force simp add: left_diff_distrib)
   qed
   have "{y. \<exists>x\<in>unit_cube. y = twoC x} = {(y, x). a \<le> x \<and> x \<le> b \<and> g2 x \<le> y \<and> y \<le> g1 x}"
     apply (auto simp add: twoCisTypeII ab1 left_diff_distrib ex)
     using order.order_iff_strict twoCisTypeII(1) apply fastforce
      apply (smt affine_ineq atLeastAtMost_iff mult_left_mono twoCisTypeII)+
     done
   then show "\<exists>a b. a < b \<and> (\<exists>g1 g2. (\<forall>x\<in>{a..b}. g2 x \<le> g1 x) \<and>
                             {y. \<exists>x\<in>unit_cube. y = twoC x} = {(y, x). a \<le> x \<and> x \<le> b \<and> g2 x \<le> y \<and> y \<le> g1 x} \<and>
                             twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b)) \<and>
                             g1 piecewise_C1_differentiable_on {a..b} \<and> g2 piecewise_C1_differentiable_on {a..b})"
     using twoCisTypeII by blast
 qed
 
 definition horizontal_boundary :: "two_cube \<Rightarrow> one_chain" where
   "horizontal_boundary twoC \<equiv> {(1, (\<lambda>x. twoC(x,0))), (-1, (\<lambda>x. twoC(x,1)))}"
 
 definition vertical_boundary :: "two_cube \<Rightarrow> one_chain" where
   "vertical_boundary twoC \<equiv> {(-1, (\<lambda>y. twoC(0,y))), (1, (\<lambda>y. twoC(1,y)))}"
 
 definition boundary :: "two_cube \<Rightarrow> one_chain" where
   "boundary twoC \<equiv> horizontal_boundary twoC \<union> vertical_boundary twoC"
 
 definition valid_two_cube where
   "valid_two_cube twoC \<equiv> card (boundary twoC) = 4"
 
 definition two_chain_integral:: "two_chain \<Rightarrow> ((real*real)\<Rightarrow>(real)) \<Rightarrow> real" where
   "two_chain_integral twoChain F \<equiv> \<Sum>C\<in>twoChain. (integral (cubeImage C) F)"
 
 definition valid_two_chain where
   "valid_two_chain twoChain \<equiv> (\<forall>twoCube \<in> twoChain. valid_two_cube twoCube) \<and> pairwise (\<lambda>c1 c2. ((boundary c1) \<inter> (boundary c2)) = {}) twoChain \<and> inj_on cubeImage twoChain"
 
 definition two_chain_boundary:: "two_chain \<Rightarrow> one_chain" where
   "two_chain_boundary twoChain == \<Union>(boundary ` twoChain)"
 
 definition gen_division where
   "gen_division s S \<equiv> (finite S \<and> (\<Union>S = s) \<and> pairwise (\<lambda>X Y. negligible (X \<inter> Y)) S)"
 
 
 definition two_chain_horizontal_boundary:: "two_chain \<Rightarrow> one_chain" where
   "two_chain_horizontal_boundary twoChain  \<equiv> \<Union>(horizontal_boundary ` twoChain)"
 
 definition two_chain_vertical_boundary:: "two_chain \<Rightarrow> one_chain" where
   "two_chain_vertical_boundary twoChain  \<equiv> \<Union>(vertical_boundary ` twoChain)"
 
 definition only_horizontal_division where
   "only_horizontal_division one_chain two_chain 
       \<equiv> \<exists>\<H> \<V>. finite \<H> \<and> finite \<V> \<and>
                (\<forall>(k,\<gamma>) \<in> \<H>.
                  (\<exists>(k', \<gamma>') \<in> two_chain_horizontal_boundary two_chain.
                      (\<exists>a \<in> {0..1}. \<exists>b \<in> {0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>))) \<and>
                (common_sudiv_exists (two_chain_vertical_boundary two_chain) \<V>
                 \<or> common_reparam_exists \<V> (two_chain_vertical_boundary two_chain)) \<and>
                boundary_chain \<V> \<and>
                one_chain = \<H> \<union> \<V> \<and> (\<forall>(k,\<gamma>)\<in>\<V>. valid_path \<gamma>)"
 
 lemma sum_zero_set:
   assumes "\<forall>x \<in> s. f x = 0" "finite s" "finite t"
   shows "sum f (s \<union> t) = sum f t"
   using assms
   by (simp add: IntE sum.union_inter_neutral sup_commute)
 
 abbreviation "valid_typeII_division s twoChain \<equiv> ((\<forall>twoCube \<in> twoChain. typeII_twoCube twoCube) \<and>
                                                 (gen_division s (cubeImage ` twoChain)) \<and>
                                                 (valid_two_chain twoChain))"
 
 lemma two_chain_vertical_boundary_is_boundary_chain:
   shows "boundary_chain (two_chain_vertical_boundary twoChain)"
   by(simp add: boundary_chain_def two_chain_vertical_boundary_def vertical_boundary_def)
 
 lemma two_chain_horizontal_boundary_is_boundary_chain:
   shows "boundary_chain (two_chain_horizontal_boundary twoChain)"
   by(simp add: boundary_chain_def two_chain_horizontal_boundary_def horizontal_boundary_def)
 
 definition typeI_twoCube :: "two_cube \<Rightarrow> bool" where
   "typeI_twoCube (twoC::two_cube)
         \<equiv> \<exists>a b g1 g2. a < b \<and> (\<forall>x \<in> {a..b}. g2 x \<le> g1 x) \<and>
                        twoC = (\<lambda>(x,y). ((1-x)*a + x*b,
                                         (1 - y) * (g2 ((1-x)*a + x*b)) + y * (g1 ((1-x)*a + x*b)))) \<and>
                        g1 piecewise_C1_differentiable_on {a..b} \<and>
                        g2 piecewise_C1_differentiable_on {a..b}"
 
 lemma typeI_twoCubeImg:
   assumes "typeI_twoCube twoC"
   shows "\<exists>a b g1 g2. a < b \<and> (\<forall>x \<in> {a .. b}. g2 x \<le> g1 x) \<and>
                       cubeImage twoC = {(x,y). x \<in> {a..b} \<and> y \<in> {g2 x .. g1 x}} \<and>
                       twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b))) \<and>
                       g1 piecewise_C1_differentiable_on {a .. b} \<and> g2 piecewise_C1_differentiable_on {a .. b} "
 proof -
   have "\<exists>a b. a < b \<and>
           (\<exists>g1 g2. (\<forall>x\<in>{a..b}. g2 x \<le> g1 x) \<and>
                    twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))\<and>
                    g1 piecewise_C1_differentiable_on {a .. b} \<and> g2 piecewise_C1_differentiable_on {a .. b})"
     using assms by (simp add: typeI_twoCube_def)
   then obtain a b g1 g2 where
     twoCisTypeI: "a < b"
         "(\<forall>x\<in>{a..b}. g2 x \<le> g1 x)"
         "twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))"
         "g1 piecewise_C1_differentiable_on {a .. b}"
         "g2 piecewise_C1_differentiable_on {a .. b}"
     by auto
   have ex: "\<exists>z\<in>Green.unit_cube.
                (c, d) =
                (case z of
                 (x, y) \<Rightarrow>
                   (a - x * a + x * b,
                    g2 (a - x * a + x * b) - y * g2 (a - x * a + x * b) + y * g1 (a - x * a + x * b)))"
     if c_bounds: "a \<le> c" "c \<le> b" and  d_bounds: "g2 c \<le> d" "d \<le> g1 c" for c d
   proof -
     have x_witness: "\<exists>k1. c = (1 - k1)*a + k1 * b \<and> 0 \<le> k1 \<and> k1 \<le> 1"
     proof -
       let ?k1 = "(c - a)/(b - a)"
       have k1_in_bounds: "0 \<le> (c - a)/(b - a) \<and> (c - a)/(b - a) \<le> 1" 
         using twoCisTypeI(1) c_bounds by simp
       have "c = (1 - ?k1)*a + ?k1 * b" 
         using twoCisTypeI(1) sum_sqs_eq
         by (auto simp add: divide_simps algebra_simps)
       then show ?thesis
         using twoCisTypeI k1_in_bounds by fastforce
     qed
     have y_witness: "\<exists>k2. d = (1 - k2)*(g2 c) + k2 * (g1 c) \<and> 0 \<le> k2 \<and> k2 \<le> 1"
     proof (cases "g1 c - g2 c = 0")
       case True
       with d_bounds show ?thesis
         by force
     next
       case False
       let ?k2 = "(d - g2 c)/(g1 c - g2 c)"
       have k2_in_bounds: "0 \<le> ?k2 \<and> ?k2 \<le> 1" using twoCisTypeI(2) c_bounds d_bounds False by simp
       have "d = (1 - ?k2) * g2 c + ?k2 * g1 c"
         using False apply (simp add: divide_simps algebra_simps)
         using sum_sqs_eq by fastforce        
       then show ?thesis using k2_in_bounds by fastforce
     qed
     show "\<exists>x\<in>unit_cube. (c, d) =
             (case x of (x, y) \<Rightarrow> (a - x * a + x * b, g2 (a - x * a + x * b) - y * g2 (a - x * a + x * b) + y * g1 (a - x * a + x * b)))"
       using x_witness y_witness by (force simp add: left_diff_distrib)
   qed
   have "{y. \<exists>x\<in>unit_cube. y = twoC x} = {(x, y). a \<le> x \<and> x \<le> b \<and> g2 x \<le> y \<and> y \<le> g1 x}"
     apply (auto simp add: twoCisTypeI left_diff_distrib ex)
     using less_eq_real_def twoCisTypeI(1) apply auto[1]
        apply (smt affine_ineq twoCisTypeI)
       apply (smt affine_ineq atLeastAtMost_iff mult_left_mono twoCisTypeI)+
     done
   then show ?thesis
     unfolding cubeImage_def image_def using twoCisTypeI by auto
 qed
 
 lemma typeI_cube_explicit_spec:
   assumes "typeI_twoCube twoC"
   shows "\<exists>a b g1 g2. a < b \<and> (\<forall>x \<in> {a .. b}. g2 x \<le> g1 x) \<and>
                       cubeImage twoC = {(x,y). x \<in> {a..b} \<and> y \<in> {g2 x .. g1 x}}
                       \<and> twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))
                       \<and> g1 piecewise_C1_differentiable_on {a .. b} \<and> g2 piecewise_C1_differentiable_on {a .. b}
                       \<and> (\<lambda>x. twoC(x, 0)) = (\<lambda>x. (a + (b - a) * x, g2 (a + (b - a) * x)))
                       \<and> (\<lambda>y. twoC(1, y)) = (\<lambda>x. (b, g2 b + x *\<^sub>R (g1 b - g2 b)))
                       \<and> (\<lambda>x. twoC(x, 1)) = (\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x)))
                       \<and> (\<lambda>y. twoC(0, y)) = (\<lambda>x. (a, g2 a + x *\<^sub>R (g1 a - g2 a)))"
 proof -
   let ?bottom_edge = "(\<lambda>x. twoC(x, 0))"
   let ?right_edge = "(\<lambda>y. twoC(1, y))"
   let ?top_edge = "(\<lambda>x. twoC(x, 1))"
   let ?left_edge = "(\<lambda>y. twoC(0, y))"
   obtain a b g1 g2 where
     twoCisTypeI: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(x,y). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     using assms and typeI_twoCubeImg[of"twoC"] by auto
   have bottom_edge_explicit: "?bottom_edge = (\<lambda>x. (a + (b - a) * x, g2 (a + (b - a) * x)))"
     by (simp add: twoCisTypeI(4) algebra_simps)
   have right_edge_explicit: "?right_edge = (\<lambda>x. (b, g2 b + x *\<^sub>R (g1 b - g2 b)))"
     by (simp add: twoCisTypeI(4) algebra_simps)
   have top_edge_explicit: "?top_edge = (\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x)))"
     by (simp add: twoCisTypeI(4) algebra_simps)
   have left_edge_explicit: "?left_edge = (\<lambda>x. (a, g2 a + x *\<^sub>R (g1 a - g2 a)))"
     by (simp add: twoCisTypeI(4) algebra_simps)
   show ?thesis
     using bottom_edge_explicit right_edge_explicit top_edge_explicit left_edge_explicit twoCisTypeI
     by auto
 qed
 
 lemma typeI_twoCube_smooth_edges:
   assumes "typeI_twoCube twoC"
     "(k,\<gamma>) \<in> boundary twoC"
   shows "\<gamma> piecewise_C1_differentiable_on {0..1}"
 proof -
   let ?bottom_edge = "(\<lambda>x. twoC(x, 0))"
   let ?right_edge = "(\<lambda>y. twoC(1, y))"
   let ?top_edge = "(\<lambda>x. twoC(x, 1))"
   let ?left_edge = "(\<lambda>y. twoC(0, y))"
   obtain a b g1 g2 where
     twoCisTypeI: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(x,y). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     "(\<lambda>x. twoC(x, 0)) = (\<lambda>x. (a + (b - a) * x, g2 (a + (b - a) * x)))"
     "(\<lambda>y. twoC(1, y)) = (\<lambda>x. (b, g2 b + x *\<^sub>R (g1 b - g2 b)))"
     "(\<lambda>x. twoC(x, 1)) = (\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x)))"
     "(\<lambda>y. twoC(0, y)) = (\<lambda>x. (a, g2 a + x *\<^sub>R (g1 a - g2 a)))"
     using assms and typeI_cube_explicit_spec[of"twoC"]
     by auto
   have bottom_edge_smooth: "(\<lambda>x. twoC (x, 0)) piecewise_C1_differentiable_on {0..1}"
   proof -
     have "\<forall>x. (\<lambda>x. (a + (b - a) * x))-` {x} = {(x - a)/(b -a)}"
       using twoCisTypeI(1)
       by(auto simp add: Set.vimage_def)
     then have finite_vimg: "\<And>x. finite({0..1} \<inter> (\<lambda>x. (a + (b - a) * x))-` {x})" by auto
     have scale_shif_smth: "(\<lambda>x. (a + (b - a) * x)) C1_differentiable_on {0..1}" using scale_shift_smooth by auto
     then have scale_shif_pw_smth: "(\<lambda>x. (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}" using C1_differentiable_imp_piecewise by blast
     have g2_smooth: "g2 piecewise_C1_differentiable_on (\<lambda>x. a + (b - a) * x) ` {0..1}" using add_scale_img[OF twoCisTypeI(1)] twoCisTypeI(6) by auto
     have "(\<lambda>x. g2 (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using piecewise_C1_differentiable_compose[OF scale_shif_pw_smth g2_smooth finite_vimg]
       by (auto simp add: o_def)
     then have "(\<lambda>x::real. (a + (b - a) * x, g2 (a + (b - a) * x))) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[where f = "(\<lambda>x::real. (a + (b - a) * x, g2 (a + (b - a) * x)))"]
       apply (simp only: real_pair_basis)
       by fastforce
     then show ?thesis using twoCisTypeI(7) by auto
   qed
   have top_edge_smooth: "?top_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "\<forall>x. (\<lambda>x. (a + (b - a) * x))-` {x} = {(x - a)/(b -a)}"
       using twoCisTypeI(1)
       by(auto simp add: Set.vimage_def)
     then have finite_vimg: "\<And>x. finite({0..1} \<inter> (\<lambda>x. (a + (b - a) * x))-` {x})" by auto
     have scale_shif_smth: "(\<lambda>x. (a + (b - a) * x)) C1_differentiable_on {0..1}" using scale_shift_smooth by auto
     then have scale_shif_pw_smth: "(\<lambda>x. (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}" using C1_differentiable_imp_piecewise by blast
     have g1_smooth: "g1 piecewise_C1_differentiable_on (\<lambda>x. a + (b - a) * x) ` {0..1}" using add_scale_img[OF twoCisTypeI(1)] twoCisTypeI(5) by auto
     have "(\<lambda>x. g1 (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using piecewise_C1_differentiable_compose[OF scale_shif_pw_smth g1_smooth finite_vimg]
       by (auto simp add: o_def)
     then have "(\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x))) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[where f = "(\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x)))"]
       apply (simp only: real_pair_basis)
       by fastforce
     then show ?thesis using twoCisTypeI(9) by auto
   qed
   have right_edge_smooth: "?right_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "(\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b))) C1_differentiable_on {0..1}"
       using scale_shift_smooth C1_differentiable_imp_piecewise by auto
     then have "(\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b))) piecewise_C1_differentiable_on {0..1}"
       using C1_differentiable_imp_piecewise by fastforce
     then have "(\<lambda>x. (b, g2 b + x *\<^sub>R (g1 b - g2 b))) piecewise_C1_differentiable_on {0..1}"
       using pair_prod_smooth_pw_smooth by auto
     then show ?thesis
       using twoCisTypeI(8) by auto
   qed
   have left_edge_smooth: "?left_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "(\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a))) C1_differentiable_on {0..1}"
       using scale_shift_smooth by auto
     then have "(\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a))) piecewise_C1_differentiable_on {0..1}"
       using C1_differentiable_imp_piecewise by fastforce
     then have "(\<lambda>x. (a, g2 a + x *\<^sub>R (g1 a - g2 a))) piecewise_C1_differentiable_on {0..1}"
       using pair_prod_smooth_pw_smooth by auto
     then show ?thesis
       using twoCisTypeI(10) by auto
   qed
   have "\<gamma> = ?bottom_edge \<or> \<gamma> = ?right_edge \<or> \<gamma> = ?top_edge \<or> \<gamma> = ?left_edge"
     using assms by (auto simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   then show ?thesis
     using left_edge_smooth right_edge_smooth top_edge_smooth bottom_edge_smooth by auto
 qed
 
 lemma two_chain_integral_eq_integral_divisable:
   assumes f_integrable: "\<forall>twoCube \<in> twoChain. F integrable_on cubeImage twoCube" and
     gen_division: "gen_division s (cubeImage ` twoChain)" and
     valid_two_chain: "valid_two_chain twoChain"
   shows "integral s F = two_chain_integral twoChain F"
 proof -
   show "integral s F = two_chain_integral twoChain F"
   proof (simp add: two_chain_integral_def)
     have partial_deriv_integrable:
       "\<forall>twoCube \<in> twoChain. ((F) has_integral (integral (cubeImage twoCube) (F))) (cubeImage twoCube)"
       using f_integrable by auto
     then have partial_deriv_integrable:
       "\<And>twoCubeImg. twoCubeImg \<in> cubeImage ` twoChain \<Longrightarrow> (F has_integral (integral (twoCubeImg) F)) (twoCubeImg)"
       using Henstock_Kurzweil_Integration.integrable_neg by force
     have finite_images: "finite (cubeImage ` twoChain)"
       using gen_division gen_division_def by auto
     have negligible_images: "pairwise (\<lambda>S S'. negligible (S \<inter> S')) (cubeImage ` twoChain)"
       using gen_division  by (auto simp add: gen_division_def pairwise_def)
     have inj: "inj_on cubeImage twoChain"
       using valid_two_chain by (simp add: inj_on_def valid_two_chain_def)
     have "integral s F = (\<Sum>twoCubeImg\<in>cubeImage ` twoChain. integral twoCubeImg F)"
       using has_integral_Union[OF finite_images partial_deriv_integrable negligible_images] gen_division
       by (auto simp add: gen_division_def)
     also have "\<dots> = (\<Sum>C\<in>twoChain. integral (cubeImage C) F)"
       using sum.reindex inj by auto
     finally show "integral s F = (\<Sum>C\<in>twoChain. integral (cubeImage C) F)" .
   qed
 qed
 
 definition only_vertical_division where
   "only_vertical_division one_chain two_chain \<equiv>
        \<exists>\<V> \<H>. finite \<H> \<and> finite \<V> \<and>
                (\<forall>(k,\<gamma>) \<in> \<V>.
                  (\<exists>(k',\<gamma>') \<in> two_chain_vertical_boundary two_chain.
                      (\<exists>a \<in> {0..1}. \<exists>b \<in> {0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>))) \<and>
                (common_sudiv_exists (two_chain_horizontal_boundary two_chain) \<H>
                 \<or> common_reparam_exists \<H> (two_chain_horizontal_boundary two_chain)) \<and>
                boundary_chain \<H> \<and> one_chain = \<V> \<union> \<H> \<and>
                (\<forall>(k,\<gamma>)\<in>\<H>. valid_path \<gamma>)"
 
 abbreviation "valid_typeI_division s twoChain 
    \<equiv> (\<forall>twoCube \<in> twoChain. typeI_twoCube twoCube) \<and>
       gen_division s (cubeImage ` twoChain) \<and> valid_two_chain twoChain"
 
 
 lemma field_cont_on_typeI_region_cont_on_edges:
   assumes typeI_twoC: "typeI_twoCube twoC" 
     and field_cont: "continuous_on (cubeImage twoC) F" 
     and member_of_boundary: "(k,\<gamma>) \<in> boundary twoC"
   shows "continuous_on (\<gamma> ` {0 .. 1}) F"
 proof -
   obtain a b g1 g2 where
     twoCisTypeI: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(x,y). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     "(\<lambda>x. twoC(x, 0)) = (\<lambda>x. (a + (b - a) * x, g2 (a + (b - a) * x)))"
     "(\<lambda>y. twoC(1, y)) = (\<lambda>x. (b, g2 b + x *\<^sub>R (g1 b - g2 b)))"
     "(\<lambda>x. twoC(x, 1)) = (\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x)))"
     "(\<lambda>y. twoC(0, y)) = (\<lambda>x. (a, g2 a + x *\<^sub>R (g1 a - g2 a)))"
     using typeI_twoC and typeI_cube_explicit_spec[of"twoC"]
     by auto
   let ?bottom_edge = "(\<lambda>x. twoC(x, 0))"
   let ?right_edge = "(\<lambda>y. twoC(1, y))"
   let ?top_edge = "(\<lambda>x. twoC(x, 1))"
   let ?left_edge = "(\<lambda>y. twoC(0, y))"
   let ?Dg1 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (x, g1(x))}"
   have line_is_pair_img: "?Dg1 = (\<lambda>x. (x, g1(x))) ` (cbox a b)"
     using image_def by auto
   have field_cont_on_top_edge_image: "continuous_on ?Dg1  F"
     by (rule continuous_on_subset [OF field_cont]) (auto simp: twoCisTypeI(2) twoCisTypeI(3))
   have top_edge_is_compos_of_scal_and_g1:
     "(\<lambda>x. twoC(x, 1)) = (\<lambda>x. (x, g1(x))) \<circ> (\<lambda>x. a + (b - a) * x)"
     using twoCisTypeI  by auto
   have Dg1_is_bot_edge_pathimg: "path_image (\<lambda>x. twoC(x, 1)) = ?Dg1"
     using line_is_pair_img and top_edge_is_compos_of_scal_and_g1 image_comp path_image_def add_scale_img and twoCisTypeI(1)
     by (metis (no_types, lifting) cbox_interval)
   then have cont_on_top: "continuous_on (path_image ?top_edge) F"
     using field_cont_on_top_edge_image by auto
   let ?Dg2 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (x, g2(x))}"
   have line_is_pair_img: "?Dg2 = (\<lambda>x. (x, g2(x))) ` (cbox a b)"
     using image_def by auto
   have field_cont_on_bot_edge_image: "continuous_on ?Dg2 F"
     apply (rule continuous_on_subset [OF field_cont])
     using twoCisTypeI(2) twoCisTypeI(3) by auto
   have bot_edge_is_compos_of_scal_and_g2: "(\<lambda>x. twoC(x, 0)) = (\<lambda>x. (x, g2(x))) \<circ> (\<lambda>x. a + (b - a) * x)"
     using twoCisTypeI by auto
   have Dg2_is_bot_edge_pathimg:
     "path_image (\<lambda>x. twoC(x, 0)) = ?Dg2"
     using line_is_pair_img and bot_edge_is_compos_of_scal_and_g2 image_comp path_image_def add_scale_img and twoCisTypeI(1)
     by (metis (no_types, lifting) cbox_interval)
   then have cont_on_bot: "continuous_on (path_image ?bottom_edge) F"
     using field_cont_on_bot_edge_image by auto
   let ?D_left_edge = "{p. \<exists>y. y \<in> cbox (g2 a) (g1 a) \<and> p = (a, y)}"
   have field_cont_on_left_edge_image: "continuous_on ?D_left_edge  F"
     apply (rule continuous_on_subset [OF field_cont])
     using twoCisTypeI(1) twoCisTypeI(3) by auto
   have "g2 a \<le> g1 a" using twoCisTypeI(1) twoCisTypeI(2) by auto
   then have "(\<lambda>x. g2 a + (g1 a - g2 a) * x) ` {(0::real)..1} = {g2 a .. g1 a}"
     using add_scale_img'[of "g2 a" "g1 a"] by blast
   then have left_eq: "?D_left_edge = ?left_edge ` {0..1}"
     unfolding twoCisTypeI(10)
     by(auto simp add: subset_iff image_def set_eq_iff Semiring_Normalization.comm_semiring_1_class.semiring_normalization_rules(7))
   then have cont_on_left: "continuous_on (path_image ?left_edge) F"
     using field_cont_on_left_edge_image path_image_def
     by (metis left_eq field_cont_on_left_edge_image path_image_def)
   let ?D_right_edge =  "{p. \<exists>y. y \<in> cbox (g2 b) (g1 b) \<and> p = (b, y)}"
   have field_cont_on_left_edge_image: "continuous_on ?D_right_edge F"
     apply (rule continuous_on_subset [OF field_cont])
     using twoCisTypeI(1) twoCisTypeI(3) by auto
   have "g2 b \<le> g1 b" using twoCisTypeI(1)  twoCisTypeI(2) by auto
   then have "(\<lambda>x. g2 b + (g1 b - g2 b) * x) ` {(0::real)..1} = {g2 b .. g1 b}"
     using add_scale_img'[of "g2 b" "g1 b"] by blast
   then have right_eq: "?D_right_edge = ?right_edge ` {0..1}"
     unfolding twoCisTypeI(8) 
     by(auto simp add: subset_iff image_def set_eq_iff Semiring_Normalization.comm_semiring_1_class.semiring_normalization_rules(7))
   then have cont_on_right:
     "continuous_on (path_image ?right_edge) F"
     using field_cont_on_left_edge_image path_image_def
     by (metis right_eq field_cont_on_left_edge_image path_image_def)
   have all_edge_cases:
     "(\<gamma> = ?bottom_edge \<or> \<gamma> = ?right_edge \<or> \<gamma> = ?top_edge \<or> \<gamma> = ?left_edge)"
     using assms by (auto simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   show ?thesis
     apply (simp add: path_image_def[symmetric])
     using cont_on_top cont_on_bot cont_on_right cont_on_left all_edge_cases
     by blast
 qed
 
 lemma typeII_cube_explicit_spec:
   assumes "typeII_twoCube twoC"
   shows "\<exists>a b g1 g2. a < b \<and> (\<forall>x \<in> {a .. b}. g2 x \<le> g1 x) \<and>
                      cubeImage twoC = {(y, x). x \<in> {a..b} \<and> y \<in> {g2 x .. g1 x}}
                   \<and> twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))
                   \<and> g1 piecewise_C1_differentiable_on {a .. b} \<and> g2 piecewise_C1_differentiable_on {a .. b}
                   \<and> (\<lambda>x. twoC(0, x)) = (\<lambda>x. (g2 (a + (b - a) * x), a + (b - a) * x))
                   \<and> (\<lambda>y. twoC(y, 1)) = (\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b))
                   \<and> (\<lambda>x. twoC(1, x)) = (\<lambda>x. (g1 (a + (b - a) * x), a + (b - a) * x))
                   \<and> (\<lambda>y. twoC(y, 0)) = (\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a), a))"
 proof -
   let ?bottom_edge = "(\<lambda>x. twoC(0, x))"
   let ?right_edge = "(\<lambda>y. twoC(y, 1))"
   let ?top_edge = "(\<lambda>x. twoC(1, x))"
   let ?left_edge = "(\<lambda>y. twoC(y, 0))"
   obtain a b g1 g2 where
     twoCisTypeII: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(y, x). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     using assms and typeII_twoCubeImg[of"twoC"] by auto
   have bottom_edge_explicit: "?bottom_edge = (\<lambda>x. (g2 (a + (b - a) * x), a + (b - a) * x))"
     by (simp add: twoCisTypeII(4) algebra_simps)
   have right_edge_explicit: "?right_edge = (\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b))"
     by (simp add: twoCisTypeII(4) algebra_simps)
   have top_edge_explicit: "?top_edge = (\<lambda>x. (g1 (a + (b - a) * x), a + (b - a) * x))"
     by (simp add: twoCisTypeII(4) algebra_simps)
   have left_edge_explicit: "?left_edge = (\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a), a))"
     by (simp add: twoCisTypeII(4) algebra_simps)
   show ?thesis
     using bottom_edge_explicit right_edge_explicit top_edge_explicit left_edge_explicit twoCisTypeII
     by auto
 qed
 
 lemma typeII_twoCube_smooth_edges:
   assumes "typeII_twoCube twoC" "(k,\<gamma>) \<in> boundary twoC"
   shows "\<gamma> piecewise_C1_differentiable_on {0..1}"
 proof -
   let ?bottom_edge = "(\<lambda>x. twoC(0, x))"
   let ?right_edge = "(\<lambda>y. twoC(y, 1))"
   let ?top_edge = "(\<lambda>x. twoC(1, x))"
   let ?left_edge = "(\<lambda>y. twoC(y, 0))"
   obtain a b g1 g2 where
     twoCisTypeII: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(y, x). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     "(\<lambda>x. twoC(0, x)) = (\<lambda>x. (g2 (a + (b - a) * x), a + (b - a) * x))"
     "(\<lambda>y. twoC(y, 1)) = (\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b))"
     "(\<lambda>x. twoC(1, x)) = (\<lambda>x. (g1 (a + (b - a) * x), a + (b - a) * x))"
     "(\<lambda>y. twoC(y, 0)) = (\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a), a))"
     using assms and typeII_cube_explicit_spec[of"twoC"]
     by auto
   have bottom_edge_smooth: "?bottom_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "\<forall>x. (\<lambda>x. (a + (b - a) * x)) -` {x} = {(x - a)/(b -a)}"
       using twoCisTypeII(1)  by auto
     then have finite_vimg: "\<And>x. finite({0..1} \<inter> (\<lambda>x. (a + (b - a) * x))-` {x})" by auto
     have scale_shif_pw_smth: "(\<lambda>x. (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}" 
       using scale_shift_smooth C1_differentiable_imp_piecewise by blast
     have g2_smooth: "g2 piecewise_C1_differentiable_on (\<lambda>x. a + (b - a) * x) ` {0..1}" using add_scale_img[OF twoCisTypeII(1)] twoCisTypeII(6) by auto
     have "(\<lambda>x. g2 (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using piecewise_C1_differentiable_compose[OF scale_shif_pw_smth g2_smooth finite_vimg]
       by (auto simp add: o_def)
     then have "(\<lambda>x::real. (g2 (a + (b - a) * x), a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[where f = "(\<lambda>x::real. (g2 (a + (b - a) * x), a + (b - a) * x))"]
       by (fastforce simp add: real_pair_basis)
     then show ?thesis using twoCisTypeII(7) by auto
   qed
   have top_edge_smooth: "?top_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "\<forall>x. (\<lambda>x. (a + (b - a) * x))-` {x} = {(x - a)/(b -a)}"
       using twoCisTypeII(1) by auto
     then have finite_vimg: "\<And>x. finite({0..1} \<inter> (\<lambda>x. (a + (b - a) * x))-` {x})" by auto
     have scale_shif_pw_smth: "(\<lambda>x. (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}" 
       using scale_shift_smooth C1_differentiable_imp_piecewise by blast
     have g1_smooth: "g1 piecewise_C1_differentiable_on (\<lambda>x. a + (b - a) * x) ` {0..1}" using add_scale_img[OF twoCisTypeII(1)] twoCisTypeII(5) by auto
     have "(\<lambda>x. g1 (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using piecewise_C1_differentiable_compose[OF scale_shif_pw_smth g1_smooth finite_vimg]
       by (auto simp add: o_def)
     then have "(\<lambda>x::real. (g1 (a + (b - a) * x), a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[where f = "(\<lambda>x::real. (g1 (a + (b - a) * x), a + (b - a) * x))"]
       by (fastforce simp add: real_pair_basis)
     then show ?thesis using twoCisTypeII(9) by auto
   qed
   have right_edge_smooth: "?right_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "(\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b))) piecewise_C1_differentiable_on {0..1}"
       by (simp add: C1_differentiable_imp_piecewise)
     then have "(\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b)) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[of "(1,0)" "(\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b))"]
       by (auto simp add: real_pair_basis)
     then show ?thesis
       using twoCisTypeII(8) by auto
   qed
   have left_edge_smooth: "?left_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have 0: "(\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a))) C1_differentiable_on {0..1}"
       using C1_differentiable_imp_piecewise by fastforce
     have "(\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a), a)) piecewise_C1_differentiable_on {0..1}"
       using C1_differentiable_imp_piecewise[OF C1_differentiable_on_pair[OF 0 C1_differentiable_on_const[of "a" "{0..1}"]]]
       by force
     then show ?thesis
       using twoCisTypeII(10) by auto
   qed
   have "\<gamma> = ?bottom_edge \<or> \<gamma> = ?right_edge \<or> \<gamma> = ?top_edge \<or> \<gamma> = ?left_edge"
     using assms by (auto simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   then show ?thesis
     using left_edge_smooth right_edge_smooth top_edge_smooth bottom_edge_smooth by auto
 qed
 
 lemma field_cont_on_typeII_region_cont_on_edges:
   assumes typeII_twoC:
     "typeII_twoCube twoC" and
     field_cont:
     "continuous_on (cubeImage twoC) F" and
     member_of_boundary:
     "(k,\<gamma>) \<in> boundary twoC"
   shows "continuous_on (\<gamma> ` {0 .. 1}) F"
 proof -
   obtain a b g1 g2 where
     twoCisTypeII: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(y, x). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     "(\<lambda>x. twoC(0, x)) = (\<lambda>x. (g2 (a + (b - a) * x), a + (b - a) * x))"
     "(\<lambda>y. twoC(y, 1)) = (\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b))"
     "(\<lambda>x. twoC(1, x)) = (\<lambda>x. (g1 (a + (b - a) * x), a + (b - a) * x))"
     "(\<lambda>y. twoC(y, 0)) = (\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a), a))"
     using typeII_twoC and typeII_cube_explicit_spec[of"twoC"]
     by auto
   let ?bottom_edge = "(\<lambda>x. twoC(0, x))"
   let ?right_edge = "(\<lambda>y. twoC(y, 1))"
   let ?top_edge = "(\<lambda>x. twoC(1, x))"
   let ?left_edge = "(\<lambda>y. twoC(y, 0))"
   let ?Dg1 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (g1(x), x)}"
   have line_is_pair_img: "?Dg1 = (\<lambda>x. (g1(x), x)) ` (cbox a b)"
     using image_def by auto
   have field_cont_on_top_edge_image: "continuous_on ?Dg1 F"
     by (rule continuous_on_subset [OF field_cont]) (auto simp: twoCisTypeII(2) twoCisTypeII(3))
   have top_edge_is_compos_of_scal_and_g1:
     "(\<lambda>x. twoC(1, x)) = (\<lambda>x. (g1(x), x)) \<circ> (\<lambda>x. a + (b - a) * x)"
     using twoCisTypeII by auto
   have Dg1_is_bot_edge_pathimg:
     "path_image (\<lambda>x. twoC(1, x)) = ?Dg1"
     using line_is_pair_img and top_edge_is_compos_of_scal_and_g1 image_comp path_image_def add_scale_img and twoCisTypeII(1)
     by (metis (no_types, lifting) cbox_interval)
   then have cont_on_top: "continuous_on (path_image ?top_edge) F"
     using field_cont_on_top_edge_image by auto
   let ?Dg2 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (g2(x), x)}"
   have line_is_pair_img: "?Dg2 = (\<lambda>x. (g2(x), x)) ` (cbox a b)"
     using image_def by auto
   have field_cont_on_bot_edge_image: "continuous_on ?Dg2 F"
     by (rule continuous_on_subset [OF field_cont]) (auto simp add: twoCisTypeII(2) twoCisTypeII(3))
   have bot_edge_is_compos_of_scal_and_g2:
     "(\<lambda>x. twoC(0, x)) = (\<lambda>x. (g2(x), x)) \<circ> (\<lambda>x. a + (b - a) * x)"
     using twoCisTypeII by auto
   have Dg2_is_bot_edge_pathimg: "path_image (\<lambda>x. twoC(0, x)) = ?Dg2"
     unfolding path_image_def
     using line_is_pair_img and bot_edge_is_compos_of_scal_and_g2 image_comp  add_scale_img [OF \<open>a < b\<close>]
     by (metis (no_types, lifting) box_real(2))
   then have cont_on_bot: "continuous_on (path_image ?bottom_edge) F"
     using field_cont_on_bot_edge_image
     by auto
   let ?D_left_edge =  "{p. \<exists>y. y \<in> cbox (g2 a) (g1 a) \<and> p = (y, a)}"
   have field_cont_on_left_edge_image: "continuous_on ?D_left_edge F"
     apply (rule continuous_on_subset [OF field_cont])
     using twoCisTypeII(1) twoCisTypeII(3) by auto
   have "g2 a \<le> g1 a" using twoCisTypeII(1) twoCisTypeII(2) by auto
   then have "(\<lambda>x. g2 a + x * (g1 a - g2 a)) ` {(0::real)..1} = {g2 a .. g1 a}"
     using add_scale_img'[of "g2 a" "g1 a"] by (auto simp add: ac_simps)
   with \<open>g2 a \<le> g1 a\<close> have left_eq: "?D_left_edge = ?left_edge ` {0..1}"
     by (simp only: twoCisTypeII(10)) auto
   then have cont_on_left: "continuous_on (path_image ?left_edge) F"
     using field_cont_on_left_edge_image path_image_def
     by (metis left_eq field_cont_on_left_edge_image path_image_def)
   let ?D_right_edge = "{p. \<exists>y. y \<in> cbox (g2 b) (g1 b) \<and> p = (y, b)}"
   have field_cont_on_left_edge_image: "continuous_on ?D_right_edge F"
     apply (rule continuous_on_subset [OF field_cont])
     using twoCisTypeII(1) twoCisTypeII(3) by auto
   have "g2 b \<le> g1 b" using twoCisTypeII(1) twoCisTypeII(2) by auto
   then have "(\<lambda>x. g2 b + x * (g1 b - g2 b)) ` {(0::real)..1} = {g2 b .. g1 b}"
     using add_scale_img'[of "g2 b" "g1 b"] by (auto simp add: ac_simps)
   with \<open>g2 b \<le> g1 b\<close> have right_eq: "?D_right_edge = ?right_edge ` {0..1}"
     by (simp only: twoCisTypeII(8)) auto
   then have cont_on_right:
     "continuous_on (path_image ?right_edge) F"
     using field_cont_on_left_edge_image path_image_def
     by (metis right_eq field_cont_on_left_edge_image path_image_def)
   have all_edge_cases:
     "(\<gamma> = ?bottom_edge \<or> \<gamma> = ?right_edge \<or> \<gamma> = ?top_edge \<or> \<gamma> = ?left_edge)"
     using assms unfolding boundary_def horizontal_boundary_def vertical_boundary_def by blast
   show ?thesis
     apply (simp add: path_image_def[symmetric])
     using cont_on_top cont_on_bot cont_on_right cont_on_left all_edge_cases
     by blast
 qed
 
 lemma two_cube_boundary_is_boundary: "boundary_chain (boundary C)"
   by (auto simp add: boundary_chain_def boundary_def horizontal_boundary_def vertical_boundary_def)
 
 lemma common_boundary_subdiv_exists_refl:
   assumes "\<forall>(k,\<gamma>)\<in>boundary twoC. valid_path \<gamma>"
   shows "common_boundary_sudivision_exists (boundary twoC) (boundary twoC)"
   using assms chain_subdiv_chain_refl common_boundary_sudivision_exists_def two_cube_boundary_is_boundary by blast
 
 lemma common_boundary_subdiv_exists_refl':
   assumes "\<forall>(k,\<gamma>)\<in>C. valid_path \<gamma>"
     "boundary_chain (C::(int \<times> (real \<Rightarrow> real \<times> real)) set)"
   shows "common_boundary_sudivision_exists (C) (C)"
   using assms chain_subdiv_chain_refl common_boundary_sudivision_exists_def by blast
 
 lemma gen_common_boundary_subdiv_exists_refl_twochain_boundary:
   assumes "\<forall>(k,\<gamma>)\<in>C. valid_path \<gamma>"
     "boundary_chain (C::(int \<times> (real \<Rightarrow> real \<times> real)) set)"
   shows "common_sudiv_exists (C) (C)"
   using assms chain_subdiv_chain_refl common_boundary_sudivision_exists_def common_subdiv_imp_gen_common_subdiv by blast
 
 lemma two_chain_boundary_is_boundary_chain:
   shows "boundary_chain (two_chain_boundary twoChain)"
   by (simp add: boundary_chain_def two_chain_boundary_def boundary_def horizontal_boundary_def vertical_boundary_def)
 
 lemma typeI_edges_are_valid_paths:
   assumes "typeI_twoCube twoC" "(k,\<gamma>) \<in> boundary twoC"
   shows "valid_path \<gamma>"
   using typeI_twoCube_smooth_edges[OF assms] C1_differentiable_imp_piecewise
   by (auto simp: valid_path_def)
 
 lemma typeII_edges_are_valid_paths:
   assumes "typeII_twoCube twoC" "(k,\<gamma>) \<in> boundary twoC"
   shows "valid_path \<gamma>"
   using typeII_twoCube_smooth_edges[OF assms] C1_differentiable_imp_piecewise
   by (auto simp: valid_path_def)
 
 lemma finite_two_chain_vertical_boundary:
   assumes "finite two_chain"
   shows "finite (two_chain_vertical_boundary two_chain)"
   using assms  by (simp add: two_chain_vertical_boundary_def vertical_boundary_def)
 
 lemma finite_two_chain_horizontal_boundary:
   assumes "finite two_chain"
   shows "finite (two_chain_horizontal_boundary two_chain)"
   using assms  by (simp add: two_chain_horizontal_boundary_def horizontal_boundary_def)
 
 locale R2 =
   fixes i j
   assumes i_is_x_axis: "i = (1::real,0::real)" and
     j_is_y_axis: "j = (0::real, 1::real)"
 begin
 
 lemma analytically_valid_y:
   assumes "analytically_valid s F i"
   shows "(\<lambda>x. integral UNIV (\<lambda>y. (partial_vector_derivative F i) (y, x) * (indicator s (y, x)))) \<in> borel_measurable lborel"
 proof -
   have "{(1::real, 0::real), (0, 1)} - {(1, 0)} = {(0::real,1::real)}"
     by force
   with assms show ?thesis
     using assms  by(simp add: real_pair_basis analytically_valid_def i_is_x_axis j_is_y_axis)
 qed
 
 lemma analytically_valid_x:
   assumes "analytically_valid s F j"
   shows "(\<lambda>x. integral UNIV (\<lambda>y. ((partial_vector_derivative F j) (x, y)) * (indicator s (x, y)))) \<in> borel_measurable lborel"
 proof -
   have "{(1::real, 0::real), (0, 1)} - {(0, 1)} = {(1::real, 0::real)}"
     by force
   with assms show ?thesis
     by(simp add: real_pair_basis analytically_valid_def i_is_x_axis j_is_y_axis)
 qed
 
 lemma Greens_thm_type_I:
   fixes F:: "((real*real) \<Rightarrow> (real * real))" and
     gamma1 gamma2 gamma3 gamma4 :: "(real \<Rightarrow> (real * real))" and
     a:: "real" and b:: "real" and
     g1:: "(real \<Rightarrow> real)" and g2:: "(real \<Rightarrow> real)"
   assumes Dy_def: "Dy_pair = {(x::real,y) . x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}" and
     gamma1_def: "gamma1 = (\<lambda>x. (a + (b - a) * x, g2(a + (b - a) * x)))" and
     gamma1_smooth: "gamma1 piecewise_C1_differentiable_on {0..1}" and (*TODO: This should be piecewise smooth*)
     gamma2_def: "gamma2 = (\<lambda>x. (b, g2(b) + x  *\<^sub>R (g1(b) - g2(b))))" and
     gamma3_def: "gamma3 = (\<lambda>x. (a + (b - a) * x, g1(a + (b - a) * x)))" and
     gamma3_smooth: "gamma3 piecewise_C1_differentiable_on {0..1}" and
     gamma4_def: "gamma4 = (\<lambda>x. (a,  g2(a) + x *\<^sub>R (g1(a) - g2(a))))" and
     F_i_analytically_valid: "analytically_valid Dy_pair (\<lambda>p. F(p) \<bullet> i) j" and
     g2_leq_g1: "\<forall>x \<in> cbox a b. (g2 x) \<le> (g1 x)" and (*This is needed otherwise what would Dy be?*)
     a_lt_b: "a < b"
   shows "(line_integral F {i} gamma1) +
          (line_integral F {i} gamma2) -
          (line_integral F {i} gamma3) -
          (line_integral F {i} gamma4)
                  = (integral Dy_pair (\<lambda>a. - (partial_vector_derivative (\<lambda>p. F(p) \<bullet> i) j a)))"
     "line_integral_exists F {i} gamma4"
     "line_integral_exists F {i} gamma3"
     "line_integral_exists F {i} gamma2"
     "line_integral_exists F {i} gamma1"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>a. (F a) \<bullet> i)  j"
   have F_first_is_continuous: "continuous_on Dy_pair (\<lambda>a. F(a) \<bullet> i)"
     using F_i_analytically_valid
     by (auto simp add: analytically_valid_def)
   let ?f = "(\<lambda>x. if x \<in> (Dy_pair) then (partial_vector_derivative (\<lambda>a. (F a) \<bullet> i)  j) x else 0)"
   have f_lesbegue_integrable: "integrable lborel ?f"
     using F_i_analytically_valid
     by (auto simp add: analytically_valid_def indic_ident)
   have partially_vec_diff: "\<forall>a \<in> Dy_pair. partially_vector_differentiable (\<lambda>a. (F a) \<bullet> i) j a"
     using F_i_analytically_valid
     by (auto simp add: analytically_valid_def indicator_def)
   have x_axis_integral_measurable: "(\<lambda>x. integral UNIV (\<lambda>y. ?f(x, y))) \<in> borel_measurable lborel"
   proof -
     have "(\<lambda>p. (?F_b' p) * indicator (Dy_pair) p) = (\<lambda>x. if x \<in> (Dy_pair) then (?F_b') x else 0)"
       using indic_ident[of "?F_b'"] by auto
     then have "\<And>x y. ?F_b' (x,y) * indicator (Dy_pair) (x,y) = (\<lambda>x. if x \<in> (Dy_pair) then (?F_b') x else 0) (x,y)"
       by auto
     then show ?thesis
       using analytically_valid_x[OF F_i_analytically_valid]
       by (auto simp add: indicator_def)
   qed
   have F_partially_differentiable: "\<forall>a\<in>Dy_pair. has_partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j (?F_b' a) a"
     using partial_vector_derivative_works partially_vec_diff
     by fastforce
   have g1_g2_continuous: "continuous_on (cbox a b) g1"
     "continuous_on (cbox a b) g2"
   proof -
     have shift_scale_cont: "continuous_on {a..b} (\<lambda>x. (x - a)*(1/(b-a)))"
       by (intro continuous_intros)
     have shift_scale_inv: "(\<lambda>x. a + (b - a) * x) \<circ> (\<lambda>x. (x - a)*(1/(b-a))) = id"
       using a_lt_b by (auto simp add: o_def)
     have img_shift_scale: "(\<lambda>x. (x - a)*(1/(b-a)))`{a..b} = {0..1}"
       using a_lt_b apply (auto simp: divide_simps image_iff)
       apply (rule_tac x="x * (b - a) + a" in bexI)
       using le_diff_eq by fastforce+
     have gamma1_y_component: "(\<lambda>x. g2(a + (b - a) * x)) = g2 \<circ> (\<lambda>x.(a + (b - a) * x))"
       by auto
     have "continuous_on {0..1} (\<lambda>x. g2(a + (b - a) * x))"
       using continuous_on_inner[OF piecewise_C1_differentiable_on_imp_continuous_on[OF gamma1_smooth], of "(\<lambda>x. j)", OF continuous_on_const]
       by (simp add: gamma1_def j_is_y_axis)
     then have "continuous_on {a..b} ((\<lambda>x. g2(a + (b - a) * x)) \<circ> (\<lambda>x. (x - a)*(1/(b-a))))"
       using img_shift_scale continuous_on_compose shift_scale_cont
       by force
     then have "continuous_on {a..b} (g2 \<circ> (\<lambda>x.(a + (b - a) * x)) \<circ> (\<lambda>x. (x - a)*(1/(b-a))))"
       using gamma1_y_component by auto
     then show "continuous_on (cbox a b) g2"
       using a_lt_b by (simp add: shift_scale_inv)
     have gamma3_y_component: "(\<lambda>x. g1(a + (b - a) * x)) = g1 \<circ> (\<lambda>x.(a + (b - a) * x))"
       by auto
     have "continuous_on {0..1} (\<lambda>x. g1(a + (b - a) * x))"
       using continuous_on_inner[OF piecewise_C1_differentiable_on_imp_continuous_on[OF gamma3_smooth], of "(\<lambda>x. j)", OF continuous_on_const]
       by (simp add: gamma3_def j_is_y_axis)
     then have "continuous_on {a..b} ((\<lambda>x. g1(a + (b - a) * x)) \<circ> (\<lambda>x. (x - a)*(1/(b-a))))"
       using img_shift_scale continuous_on_compose shift_scale_cont
       by force
     then have "continuous_on {a..b} (g1 \<circ> (\<lambda>x.(a + (b - a) * x)) \<circ> (\<lambda>x. (x - a)*(1/(b-a))))"
       using gamma3_y_component by auto
     then show "continuous_on (cbox a b) g1"
       using a_lt_b by (simp add: shift_scale_inv)
   qed
   have g2_scale_j_contin: "continuous_on (cbox a b) (\<lambda>x. (0, g2 x))"
     by (intro continuous_intros g1_g2_continuous)
   let ?Dg2 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (x, g2(x))}"
   have line_is_pair_img: "?Dg2 = (\<lambda>x. (x, g2(x))) ` (cbox a b)"
     using image_def by auto
   have g2_path_continuous: "continuous_on (cbox a b) (\<lambda>x. (x, g2(x)))"
     by (intro continuous_intros g1_g2_continuous)
   have field_cont_on_gamma1_image: "continuous_on ?Dg2  (\<lambda>a. F(a) \<bullet> i)"
     apply (rule continuous_on_subset [OF F_first_is_continuous])
     by (auto simp add: Dy_def g2_leq_g1)
   have gamma1_is_compos_of_scal_and_g2:
     "gamma1 = (\<lambda>x. (x, g2(x))) \<circ> (\<lambda>x. a + (b - a) * x)"
     using gamma1_def by auto
   have add_scale_img:
     "(\<lambda>x. a + (b - a) * x) ` {0 .. 1} = {a .. b}" using add_scale_img and a_lt_b by auto
   then have Dg2_is_gamma1_pathimg: "path_image gamma1 = ?Dg2"
     by (metis (no_types, lifting) box_real(2) gamma1_is_compos_of_scal_and_g2 image_comp line_is_pair_img path_image_def)
   have Base_vecs: "i \<in> Basis" "j \<in> Basis" "i \<noteq> j"
     using real_pair_basis and i_is_x_axis and j_is_y_axis by auto
   have gamma1_as_euclid_space_fun: "gamma1 = (\<lambda>x. (a + (b - a) * x) *\<^sub>R i + (0, g2 (a + (b - a) * x)))"
     using i_is_x_axis gamma1_def by auto
   have 0: "line_integral F {i} gamma1 = integral (cbox a b) (\<lambda>x. F(x, g2(x)) \<bullet> i )"
           "line_integral_exists F {i} gamma1"
     using line_integral_on_pair_path_strong [OF norm_Basis[OF Base_vecs(1)] _ gamma1_as_euclid_space_fun, of "F"] 
       gamma1_def gamma1_smooth g2_scale_j_contin a_lt_b add_scale_img
       Dg2_is_gamma1_pathimg and field_cont_on_gamma1_image
     by (auto simp: pathstart_def pathfinish_def i_is_x_axis)
   then show "(line_integral_exists F {i} gamma1)" by metis
   have gamma2_x_const: "\<forall>x. gamma2 x \<bullet> i = b"
     by (simp add: i_is_x_axis gamma2_def)
   have 1: "(line_integral F {i} gamma2) = 0" "(line_integral_exists F {i} gamma2)"
       using line_integral_on_pair_straight_path[OF gamma2_x_const] straight_path_diffrentiable_x gamma2_def
       by (auto simp add: mult.commute)
   then show "(line_integral_exists F {i} gamma2)" by metis
   have "continuous_on (cbox a b) (\<lambda>x. F(x, g2(x))  \<bullet> i)"
     using line_is_pair_img and g2_path_continuous and field_cont_on_gamma1_image
       Topological_Spaces.continuous_on_compose i_is_x_axis j_is_y_axis
     by auto
   then have 6: "(\<lambda>x. F(x, g2(x))  \<bullet> i) integrable_on (cbox a b)"
     using integrable_continuous [of "a" "b" "(\<lambda>x. F(x, g2(x))  \<bullet> i)"] by auto
   have g1_scale_j_contin: "continuous_on (cbox a b) (\<lambda>x. (0, g1 x))"
     by (intro continuous_intros g1_g2_continuous)
   let ?Dg1 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (x, g1(x))}"
   have line_is_pair_img: "?Dg1 = (\<lambda>x. (x, g1(x)) ) ` (cbox a b)"
     using image_def  by auto
   have g1_path_continuous: "continuous_on (cbox a b) (\<lambda>x. (x, g1(x)))"
     by (intro continuous_intros g1_g2_continuous)
   have field_cont_on_gamma3_image: "continuous_on ?Dg1  (\<lambda>a. F(a)  \<bullet> i)"
     apply (rule continuous_on_subset [OF F_first_is_continuous])
     by (auto simp add: Dy_def g2_leq_g1)
   have gamma3_is_compos_of_scal_and_g1:
     "gamma3 = (\<lambda>x. (x, g1(x))) \<circ> (\<lambda>x. a + (b - a) * x)"
     using gamma3_def by auto
   then have Dg1_is_gamma3_pathimg: "path_image gamma3 = ?Dg1"
     by (metis (no_types, lifting) box_real(2) image_comp line_is_pair_img local.add_scale_img path_image_def)
   have Base_vecs: "i \<in> Basis" "j \<in> Basis" "i \<noteq> j"
     using real_pair_basis and i_is_x_axis and j_is_y_axis by auto
   have gamma3_as_euclid_space_fun: "gamma3 = (\<lambda>x. (a + (b - a) * x) *\<^sub>R i + (0, g1 (a + (b - a) * x)))"
     using i_is_x_axis gamma3_def by auto
   have 2: "line_integral F {i} gamma3 = integral (cbox a b) (\<lambda>x. F(x, g1(x)) \<bullet> i )"
          "line_integral_exists F {i} gamma3"
     using line_integral_on_pair_path_strong [OF norm_Basis[OF Base_vecs(1)] _ gamma3_as_euclid_space_fun, of "F"]
       gamma3_def and gamma3_smooth and g1_scale_j_contin and a_lt_b and add_scale_img
       Dg1_is_gamma3_pathimg and field_cont_on_gamma3_image
     by (auto simp: pathstart_def pathfinish_def i_is_x_axis)
   then show "(line_integral_exists F {i} gamma3)" by metis
   have gamma4_x_const: "\<forall>x. gamma4 x \<bullet> i = a"
     using gamma4_def
     by (auto simp add: real_inner_class.inner_add_left inner_not_same_Basis  i_is_x_axis)
   have 3: "(line_integral F {i} gamma4) = 0" "(line_integral_exists F {i} gamma4)"
     using line_integral_on_pair_straight_path[OF gamma4_x_const] straight_path_diffrentiable_x gamma4_def
     by (auto simp add: mult.commute)
   then show "(line_integral_exists F {i} gamma4)" 
     by metis
   have "continuous_on (cbox a b) (\<lambda>x. F(x, g1(x)) \<bullet> i)"
     using line_is_pair_img and g1_path_continuous and field_cont_on_gamma3_image
       continuous_on_compose i_is_x_axis j_is_y_axis
     by auto
   then have 7: "(\<lambda>x. F(x, g1(x))  \<bullet> i) integrable_on (cbox a b)"
     using integrable_continuous [of "a" "b" "(\<lambda>x. F(x, g1(x))  \<bullet> i)"]
     by auto
   have partial_deriv_one_d_integrable:
     "((\<lambda>y. ?F_b'(xc, y)) has_integral 
         F(xc,g1(xc)) \<bullet> i - F(xc, g2(xc)) \<bullet> i) (cbox (g2 xc) (g1 xc))" 
      if "xc \<in> cbox a b" for xc
   proof -
     have "{(xc', y).  y \<in> cbox (g2 xc) (g1 xc) \<and> xc' = xc} \<subseteq> Dy_pair"
       using that by (auto simp add: Dy_def)
     then show "((\<lambda>y. ?F_b' (xc, y)) has_integral F(xc, g1 xc) \<bullet> i - F(xc, g2 xc) \<bullet> i) (cbox (g2 xc) (g1 xc))"
       using that and Base_vecs and F_partially_differentiable
         and Dy_def [symmetric] and g2_leq_g1
         and fundamental_theorem_of_calculus_partial_vector
         [of "g2 xc" "g1 xc" "j" "i" "xc *\<^sub>R i" "Dy_pair" "F" "?F_b'" ]
       by (auto simp add:  Groups.ab_semigroup_add_class.add.commute i_is_x_axis j_is_y_axis)
   qed
   have partial_deriv_integrable: "(?F_b') integrable_on Dy_pair"
     by (simp add: F_i_analytically_valid analytically_valid_imp_part_deriv_integrable_on)
   have 4: "integral Dy_pair ?F_b'
            = integral (cbox a b) (\<lambda>x. integral (cbox (g2 x) (g1 x)) (\<lambda>y. ?F_b' (x, y)))"
   proof -
     have x_axis_gauge_integrable:
       "\<And>x. (\<lambda>y. ?f(x,y)) integrable_on UNIV"
     proof -
       fix x::real
       have "\<forall>x. x \<notin> cbox a b \<longrightarrow>  (\<lambda>y. ?f (x, y)) = (\<lambda>y. 0)"
         by (auto simp add: Dy_def)
       then have f_integrable_x_not_in_range:
         "\<forall>x. x \<notin> cbox a b \<longrightarrow>  (\<lambda>y. ?f (x, y)) integrable_on UNIV"
         by (simp add: integrable_0)
       let ?F_b'_oneD = "(\<lambda>x. (\<lambda>y. if y \<in> (cbox (g2 x) ( g1 x)) then ?F_b' (x,y) else 0))"
       have f_value_x_in_range: "\<forall>x \<in> cbox a b. ?F_b'_oneD x = (\<lambda>y. ?f(x,y))"
         by (auto simp add: Dy_def)
       have "\<forall>x \<in> cbox a b. ?F_b'_oneD x integrable_on UNIV"
         using has_integral_integrable integrable_restrict_UNIV partial_deriv_one_d_integrable by blast
       then have f_integrable_x_in_range:
         "\<forall>x. x \<in> cbox a b \<longrightarrow>  (\<lambda>y. ?f (x, y)) integrable_on UNIV"
         using f_value_x_in_range by auto
       show "(\<lambda>y. ?f (x, y)) integrable_on UNIV"
         using f_integrable_x_not_in_range and f_integrable_x_in_range by auto
     qed
     have arg: "(\<lambda>a. if a \<in> Dy_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> i) j a else 0) =
                (\<lambda>x. if x \<in> Dy_pair then if x \<in> Dy_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> i) j x else 0 else 0)"
       by auto
     have arg2: "Dy_pair = {(x, y). (\<forall>i\<in>Basis. a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i) \<and> (\<forall>i\<in>Basis. g2 x \<bullet> i \<le> y \<bullet> i \<and> y \<bullet> i \<le> g1 x \<bullet> i)}"
       using Dy_def  by auto
     have arg3: "\<And> x. x \<in> Dy_pair \<Longrightarrow> (\<lambda>x. if x \<in> Dy_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> i) j x else 0) x
                            = (\<lambda>x. partial_vector_derivative (\<lambda>a. F a \<bullet> i) j x) x"
       by auto
     have arg4: "\<And>x. x \<in> (cbox a b) \<Longrightarrow>
                             (\<lambda>x. integral (cbox (g2 x) (g1 x)) (\<lambda>y. if (x, y) \<in> Dy_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> i) j (x, y) else 0)) x =
                                       (\<lambda>x. integral (cbox (g2 x) (g1 x)) (\<lambda>y. partial_vector_derivative (\<lambda>a. F a \<bullet> i) j (x, y))) x"
       apply (simp add: Dy_def)
       by (smt Henstock_Kurzweil_Integration.integral_cong atLeastAtMost_iff)
     show ?thesis
       using gauge_integral_Fubini_curve_bounded_region_x
         [OF f_lesbegue_integrable x_axis_gauge_integrable x_axis_integral_measurable arg arg2]
         Henstock_Kurzweil_Integration.integral_cong[OF arg3, of "Dy_pair" "(\<lambda>x. x)"]
         Henstock_Kurzweil_Integration.integral_cong[OF arg4, of "cbox a b" "(\<lambda>x. x)"]
       by auto
   qed
   have 5: "(integral Dy_pair (\<lambda>a. (?F_b' a))
         = integral (cbox a b) (\<lambda>x. F(x, g1(x))  \<bullet> i - F(x, g2(x))  \<bullet> i))"
     using 4 Henstock_Kurzweil_Integration.integral_cong partial_deriv_one_d_integrable integrable_def
     by (smt integral_unique)
   show "(line_integral F {i} gamma1) + (line_integral F {i} gamma2) -
           (line_integral F {i} gamma3) - (line_integral F {i} gamma4)
         = (integral Dy_pair (\<lambda>a. - (?F_b' a)))"
     using "0"(1) "1"(1) "2"(1) "3"(1) 5 "6" "7" 
     by (simp add: Henstock_Kurzweil_Integration.integral_diff)    
 qed
 
 theorem Greens_thm_type_II:
   fixes F:: "((real*real) \<Rightarrow> (real * real))" and
     gamma4 gamma3 gamma2 gamma1 :: "(real \<Rightarrow> (real * real))" and
     a:: "real" and b:: "real" and
     g1:: "(real \<Rightarrow> real)" and g2:: "(real \<Rightarrow> real)"
   assumes Dx_def: "Dx_pair = {(x::real,y) . y \<in> cbox a b \<and> x \<in> cbox (g2 y) (g1 y)}" and
     gamma4_def: "gamma4 = (\<lambda>x. (g2(a + (b - a) * x), a + (b - a) * x))" and
     gamma4_smooth: "gamma4 piecewise_C1_differentiable_on {0..1}" and (*TODO: This should be piecewise smooth*)
     gamma3_def: "gamma3 = (\<lambda>x. (g2(b) + x  *\<^sub>R (g1(b) - g2(b)), b))" and
     gamma2_def: "gamma2 = (\<lambda>x. (g1(a + (b - a) * x), a + (b - a) * x))" and
     gamma2_smooth: "gamma2 piecewise_C1_differentiable_on {0..1}" and
     gamma1_def: "gamma1 = (\<lambda>x. (g2(a) + x *\<^sub>R (g1(a) - g2(a)), a))" and
     F_j_analytically_valid: "analytically_valid Dx_pair (\<lambda>p. F(p) \<bullet> j) i" and
     g2_leq_g1: "\<forall>x \<in> cbox a b. (g2 x) \<le> (g1 x)" and (*This is needed otherwise what would Dy be?*)
     a_lt_b: "a < b"
   shows "-(line_integral F {j} gamma4) -
          (line_integral F {j} gamma3) +
          (line_integral F {j} gamma2) +
          (line_integral F {j} gamma1)
                  = (integral Dx_pair (\<lambda>a. (partial_vector_derivative (\<lambda>a. (F a) \<bullet> j)  i a)))"
     "line_integral_exists F {j} gamma4"
     "line_integral_exists F {j} gamma3"
     "line_integral_exists F {j} gamma2"
     "line_integral_exists F {j} gamma1"
 proof -
   let ?F_a' = "partial_vector_derivative (\<lambda>a. (F a) \<bullet> j)  i"
   have F_first_is_continuous: "continuous_on Dx_pair (\<lambda>a. F(a) \<bullet> j)"
     using F_j_analytically_valid
     by (auto simp add: analytically_valid_def)
   let ?f = "(\<lambda>x. if x \<in> (Dx_pair) then (partial_vector_derivative (\<lambda>a. (F a) \<bullet> j)  i) x else 0)"
   have f_lesbegue_integrable: "integrable lborel ?f"
     using F_j_analytically_valid
     by (auto simp add: analytically_valid_def indic_ident)
   have partially_vec_diff: "\<forall>a \<in> Dx_pair. partially_vector_differentiable (\<lambda>a. (F a) \<bullet> j) i a"
     using F_j_analytically_valid
     by (auto simp add: analytically_valid_def indicator_def)
   have "\<And>x y. ?F_a' (x,y) * indicator (Dx_pair) (x,y) = (\<lambda>x. if x \<in> (Dx_pair) then ?F_a' x else 0) (x,y)"
     using indic_ident[of "?F_a'"] by auto
   then have y_axis_integral_measurable: "(\<lambda>x. integral UNIV (\<lambda>y. ?f(y, x))) \<in> borel_measurable lborel"
     using analytically_valid_y[OF F_j_analytically_valid]
     by (auto simp add: indicator_def)
   have F_partially_differentiable: "\<forall>a\<in>Dx_pair. has_partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i (?F_a' a) a"
     using partial_vector_derivative_works partially_vec_diff by fastforce
   have g1_g2_continuous: "continuous_on (cbox a b) g1" "continuous_on (cbox a b) g2"
   proof -
     have shift_scale_cont: "continuous_on {a..b} (\<lambda>x. (x - a)*(1/(b-a)))"
       by (intro continuous_intros)
     have shift_scale_inv: "(\<lambda>x. a + (b - a) * x) \<circ> (\<lambda>x. (x - a)*(1/(b-a))) = id"
       using a_lt_b by (auto simp add: o_def)
     have img_shift_scale:
       "(\<lambda>x. (x - a)*(1/(b-a)))`{a..b} = {0..1}"
       apply (auto simp: divide_simps image_iff)
        apply (rule_tac x="x * (b - a) + a" in bexI)
       using a_lt_b by (auto simp: algebra_simps mult_le_cancel_left affine_ineq)
     have "continuous_on {0..1} (\<lambda>x. g2(a + (b - a) * x))"
       using continuous_on_inner[OF piecewise_C1_differentiable_on_imp_continuous_on[OF gamma4_smooth], of "(\<lambda>x. i)", OF continuous_on_const]
       by (simp add: gamma4_def i_is_x_axis)
     then have "continuous_on {a..b} ((\<lambda>x. g2(a + (b - a) * x)) \<circ> (\<lambda>x. (x - a)*(1/(b-a))))"
       using img_shift_scale continuous_on_compose shift_scale_cont by force
     then show "continuous_on (cbox a b) g2"
       using a_lt_b by (simp add: shift_scale_inv)
     have "continuous_on {0..1} (\<lambda>x. g1(a + (b - a) * x))"
       using continuous_on_inner[OF piecewise_C1_differentiable_on_imp_continuous_on[OF gamma2_smooth], of "(\<lambda>x. i)", OF continuous_on_const]
       by (simp add: gamma2_def i_is_x_axis)
     then have "continuous_on {a..b} ((\<lambda>x. g1(a + (b - a) * x)) \<circ> (\<lambda>x. (x - a)*(1/(b-a))))"
       using img_shift_scale continuous_on_compose shift_scale_cont by force
     then show "continuous_on (cbox a b) g1"
       using a_lt_b by (simp add: shift_scale_inv)
   qed
   have g2_scale_i_contin: "continuous_on (cbox a b) (\<lambda>x. (g2 x, 0))"
     by (intro continuous_intros g1_g2_continuous)
   let ?Dg2 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (g2(x), x)}"
   have line_is_pair_img: "?Dg2 = (\<lambda>x. (g2(x), x) ) ` (cbox a b)"
     using image_def  by auto
   have g2_path_continuous: "continuous_on (cbox a b) (\<lambda>x. (g2(x), x))"
     by (intro continuous_intros g1_g2_continuous)
   have field_cont_on_gamma4_image: "continuous_on ?Dg2 (\<lambda>a. F(a) \<bullet> j)"
     by (rule continuous_on_subset [OF F_first_is_continuous]) (auto simp: Dx_def g2_leq_g1)
   have gamma4_is_compos_of_scal_and_g2: "gamma4 = (\<lambda>x. (g2(x), x)) \<circ> (\<lambda>x. a + (b - a) * x)"
     using gamma4_def  by auto
   have add_scale_img:
     "(\<lambda>x. a + (b - a) * x) ` {0 .. 1} = {a .. b}" using add_scale_img and a_lt_b by auto
   then have Dg2_is_gamma4_pathimg: "path_image gamma4 = ?Dg2"
     using line_is_pair_img and gamma4_is_compos_of_scal_and_g2 image_comp path_image_def
     by (metis (no_types, lifting) cbox_interval)
   have Base_vecs: "i \<in> Basis" "j \<in> Basis" "i \<noteq> j"
     using real_pair_basis and i_is_x_axis and j_is_y_axis by auto
   have gamma4_as_euclid_space_fun: "gamma4 = (\<lambda>x. (a + (b - a) * x) *\<^sub>R j + (g2 (a + (b - a) * x), 0))"
     using j_is_y_axis gamma4_def
     by auto
   have 0: "(line_integral F {j} gamma4) = integral (cbox a b) (\<lambda>x. F(g2(x), x) \<bullet> j)"
           "line_integral_exists F {j} gamma4"
     using line_integral_on_pair_path_strong [OF norm_Basis[OF Base_vecs(2)] _ gamma4_as_euclid_space_fun]
       gamma4_def gamma4_smooth g2_scale_i_contin a_lt_b add_scale_img
       Dg2_is_gamma4_pathimg and field_cont_on_gamma4_image
     by (auto simp: pathstart_def pathfinish_def j_is_y_axis)
   then show "line_integral_exists F {j} gamma4" by metis
   have gamma3_y_const: "\<forall>x. gamma3 x \<bullet> j = b"
     by (simp add: gamma3_def j_is_y_axis)
   have 1: "(line_integral F {j} gamma3) = 0" "(line_integral_exists F {j} gamma3)"
     using line_integral_on_pair_straight_path[OF gamma3_y_const] straight_path_diffrentiable_y gamma3_def
     by (auto simp add: mult.commute)
   then show "line_integral_exists F {j} gamma3" by auto
   have "continuous_on (cbox a b) (\<lambda>x. F(g2(x), x) \<bullet> j)"
     by (smt Collect_mono_iff continuous_on_compose2 continuous_on_eq field_cont_on_gamma4_image g2_path_continuous line_is_pair_img)
   then have 6: "(\<lambda>x. F(g2(x), x)  \<bullet> j) integrable_on (cbox a b)"
     using integrable_continuous by blast
   have g1_scale_i_contin: "continuous_on (cbox a b) (\<lambda>x. (g1 x, 0))"
     by (intro continuous_intros g1_g2_continuous)
   let ?Dg1 =  "{p. \<exists>x. x \<in> cbox a b \<and> p = (g1(x), x)}"
   have line_is_pair_img: "?Dg1 = (\<lambda>x. (g1(x), x) ) ` (cbox a b)"
     using image_def by auto
   have g1_path_continuous: "continuous_on (cbox a b) (\<lambda>x. (g1(x), x))"
     by (intro continuous_intros g1_g2_continuous)
   have field_cont_on_gamma2_image: "continuous_on ?Dg1  (\<lambda>a. F(a) \<bullet> j)"
     by (rule continuous_on_subset [OF F_first_is_continuous]) (auto simp: Dx_def g2_leq_g1)
   have "gamma2 = (\<lambda>x. (g1(x), x)) \<circ> (\<lambda>x. a + (b - a) * x)"
     using gamma2_def by auto
   then have Dg1_is_gamma2_pathimg: "path_image gamma2 = ?Dg1"
     using line_is_pair_img image_comp path_image_def add_scale_img
     by (metis (no_types, lifting) cbox_interval)
   have Base_vecs: "i \<in> Basis" "j \<in> Basis" "i \<noteq> j"
     using real_pair_basis and i_is_x_axis and j_is_y_axis by auto
   have gamma2_as_euclid_space_fun: "gamma2 = (\<lambda>x. (a + (b - a) * x) *\<^sub>R j + (g1 (a + (b - a) * x), 0))"
     using j_is_y_axis gamma2_def by auto
   have 2: "(line_integral F {j} gamma2) = integral (cbox a b) (\<lambda>x. F(g1(x), x) \<bullet> j)"
     "(line_integral_exists F {j} gamma2)"
     using line_integral_on_pair_path_strong [OF norm_Basis[OF Base_vecs(2)] _ gamma2_as_euclid_space_fun]
       gamma2_def and gamma2_smooth and g1_scale_i_contin and a_lt_b and add_scale_img
       Dg1_is_gamma2_pathimg and field_cont_on_gamma2_image
     by (auto simp: pathstart_def pathfinish_def j_is_y_axis)
   then show "line_integral_exists F {j} gamma2" by metis
   have gamma1_y_const: "\<forall>x. gamma1 x \<bullet> j = a"
     using gamma1_def
     by (auto simp add: real_inner_class.inner_add_left
         euclidean_space_class.inner_not_same_Basis j_is_y_axis)
   have 3: "(line_integral F {j} gamma1) = 0" "(line_integral_exists F {j} gamma1)"
     using line_integral_on_pair_straight_path[OF gamma1_y_const] straight_path_diffrentiable_y gamma1_def
     by (auto simp add: mult.commute)
   then show "line_integral_exists F {j} gamma1" by auto
   have "continuous_on (cbox a b) (\<lambda>x. F(g1(x), x) \<bullet> j)"
     by (smt Collect_mono_iff continuous_on_compose2 continuous_on_eq field_cont_on_gamma2_image g1_path_continuous line_is_pair_img)
   then have 7: "(\<lambda>x. F(g1(x), x) \<bullet> j) integrable_on (cbox a b)"
     using integrable_continuous [of "a" "b" "(\<lambda>x. F(g1(x), x) \<bullet> j)"]
     by auto
   have partial_deriv_one_d_integrable:
     "((\<lambda>y. ?F_a'(y, xc)) has_integral F(g1(xc), xc) \<bullet> j - F(g2(xc), xc) \<bullet> j) (cbox (g2 xc) (g1 xc))"
     if "xc \<in> cbox a b" for xc::real
   proof -
     have "{(y, xc').  y \<in> cbox (g2 xc) (g1 xc) \<and> xc' = xc} \<subseteq> Dx_pair"
       using that by (auto simp add: Dx_def)
     then show ?thesis
       using that and Base_vecs and F_partially_differentiable
         and Dx_def [symmetric] and g2_leq_g1
         and fundamental_theorem_of_calculus_partial_vector
         [of "g2 xc" "g1 xc" "i" "j" "xc *\<^sub>R j" "Dx_pair" "F" "?F_a'" ]
       by (auto simp add:  Groups.ab_semigroup_add_class.add.commute i_is_x_axis j_is_y_axis)
   qed
   have "?f integrable_on UNIV"
     by (simp add: f_lesbegue_integrable integrable_on_lborel)
   then have partial_deriv_integrable: "?F_a' integrable_on Dx_pair"
     using integrable_restrict_UNIV by auto
   have 4: "integral Dx_pair ?F_a' = integral (cbox a b) (\<lambda>x. integral (cbox (g2 x) (g1 x)) (\<lambda>y. ?F_a' (y, x)))"
   proof -
     have y_axis_gauge_integrable: "(\<lambda>y. ?f(y, x)) integrable_on UNIV" for x
     proof -
       let ?F_a'_oneD = "(\<lambda>x. (\<lambda>y. if y \<in> (cbox (g2 x) ( g1 x)) then ?F_a' (y, x) else 0))"
       have "\<forall>x. x \<notin> cbox a b \<longrightarrow>  (\<lambda>y. ?f (y, x)) = (\<lambda>y. 0)"
         by (auto simp add: Dx_def)
       then have f_integrable_x_not_in_range:
         "\<forall>x. x \<notin> cbox a b \<longrightarrow>  (\<lambda>y. ?f (y, x)) integrable_on UNIV"
         by (simp add: integrable_0)
       have "\<forall>x \<in> cbox a b. ?F_a'_oneD x = (\<lambda>y. ?f(y, x))"
         using g2_leq_g1 by (auto simp add: Dx_def)
       moreover have "\<forall>x \<in> cbox a b. ?F_a'_oneD x integrable_on UNIV"
         using has_integral_integrable integrable_restrict_UNIV partial_deriv_one_d_integrable by blast
       ultimately have "\<forall>x. x \<in> cbox a b \<longrightarrow>  (\<lambda>y. ?f (y, x)) integrable_on UNIV"
         by auto
       then show "(\<lambda>y. ?f (y, x)) integrable_on UNIV"
         using f_integrable_x_not_in_range by auto
     qed
     have arg: "(\<lambda>a. if a \<in> Dx_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> j) i a else 0) =
                (\<lambda>x. if x \<in> Dx_pair then if x \<in> Dx_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> j) i x else 0 else 0)"
       by auto
     have arg2: "Dx_pair = {(y, x). (\<forall>i\<in>Basis. a \<bullet> i \<le> x \<bullet> i \<and> x \<bullet> i \<le> b \<bullet> i) \<and> (\<forall>i\<in>Basis. g2 x \<bullet> i \<le> y \<bullet> i \<and> y \<bullet> i \<le> g1 x \<bullet> i)}"
       using Dx_def by auto
     have arg3: "\<And> x. x \<in> Dx_pair \<Longrightarrow> (\<lambda>x. if x \<in> Dx_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> j) i x else 0) x
                            = (\<lambda>x. partial_vector_derivative (\<lambda>a. F a \<bullet> j) i x) x"
       by auto
     have arg4: "\<And>x. x \<in> (cbox a b) \<Longrightarrow>
                       (\<lambda>x. integral (cbox (g2 x) (g1 x)) (\<lambda>y. if (y, x) \<in> Dx_pair then partial_vector_derivative (\<lambda>a. F a \<bullet> j) i (y, x) else 0)) x =
                       (\<lambda>x. integral (cbox (g2 x) (g1 x)) (\<lambda>y. partial_vector_derivative (\<lambda>a. F a \<bullet> j) i (y, x))) x"
       apply (clarsimp simp: Dx_def)
       by (smt Henstock_Kurzweil_Integration.integral_cong atLeastAtMost_iff)
     show ?thesis
       using gauge_integral_Fubini_curve_bounded_region_y
         [OF f_lesbegue_integrable y_axis_gauge_integrable y_axis_integral_measurable arg arg2]
         Henstock_Kurzweil_Integration.integral_cong[OF arg3, of "Dx_pair" "(\<lambda>x. x)"]
         Henstock_Kurzweil_Integration.integral_cong[OF arg4, of "cbox a b" "(\<lambda>x. x)"]
       by auto
   qed
   have "((integral Dx_pair (\<lambda>a. (?F_a' a)))
         = integral (cbox a b) (\<lambda>x. F(g1(x), x) \<bullet> j - F(g2(x), x) \<bullet> j))"
     using 4 Henstock_Kurzweil_Integration.integral_cong partial_deriv_one_d_integrable integrable_def
     by (smt integral_unique)
   then have "integral Dx_pair (\<lambda>a. - (?F_a' a))
               = - integral (cbox a b) (\<lambda>x. F(g1(x), x) \<bullet> j - F(g2(x), x) \<bullet> j)"
     using partial_deriv_integrable and integral_neg by auto
   then have 5: "integral Dx_pair (\<lambda>a. - (?F_a' a))
                 = integral (cbox a b) (\<lambda>x. ( F(g2(x), x) \<bullet> j - F(g1(x), x) \<bullet> j))"
     using 6 7  
       and integral_neg [of _ "(\<lambda>x. F(g1 x, x) \<bullet> j - F(g2 x, x) \<bullet> j)"] by auto
   have "(line_integral F {j} gamma4) + (line_integral F {j} gamma3) -
         (line_integral F {j} gamma2) - (line_integral F {j} gamma1)
         = (integral Dx_pair (\<lambda>a. -(?F_a' a)))"
     using 0 1 2 3 5 6 7
       Henstock_Kurzweil_Integration.integral_diff[of "(\<lambda>x. F(g2(x), x)  \<bullet> j)"
         "cbox a b" "(\<lambda>x. F(g1(x), x) \<bullet> j)"] by (auto)
   then show "-(line_integral F {j} gamma4) -
          (line_integral F {j} gamma3) +
          (line_integral F {j} gamma2) +
          (line_integral F {j} gamma1)
                  = (integral Dx_pair (\<lambda>a. (?F_a' a)))"
     by (simp add: \<open>integral Dx_pair (\<lambda>a. - ?F_a' a) = - integral (cbox a b) (\<lambda>x. F(g1 x, x) \<bullet> j - F(g2 x, x) \<bullet> j)\<close> \<open>integral Dx_pair ?F_a' = integral (cbox a b) (\<lambda>x. F(g1 x, x) \<bullet> j - F(g2 x, x) \<bullet> j)\<close>)
 qed
 
 end
 
 locale green_typeII_cube =  R2 + 
   fixes twoC F
   assumes 
     two_cube: "typeII_twoCube twoC" and
     valid_two_cube: "valid_two_cube twoC" and
     f_analytically_valid: "analytically_valid (cubeImage twoC) (\<lambda>x. (F x) \<bullet> j) i"
 begin
 
 lemma GreenThm_typeII_twoCube:
   shows "integral (cubeImage twoC) (\<lambda>a. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i  a) = one_chain_line_integral F {j} (boundary twoC)"
     "\<forall>(k,\<gamma>) \<in> boundary twoC. line_integral_exists F {j} \<gamma>"
 proof -
   let ?bottom_edge = "(\<lambda>x. twoC(x, 0))"
   let ?right_edge = "(\<lambda>y. twoC(1, y))"
   let ?top_edge = "(\<lambda>x. twoC(x, 1))"
   let ?left_edge = "(\<lambda>y. twoC(0, y))"
   have line_integral_around_boundary: 
       "one_chain_line_integral F {j} (boundary twoC) =  
          line_integral F {j} ?bottom_edge + line_integral F {j} ?right_edge
          - line_integral F {j} ?top_edge - line_integral F {j} ?left_edge"
   proof (simp add: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def)
     have finite1: "finite {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (- 1, \<lambda>x. twoC (x, 1))}" by auto
     then have sum_step1: "(\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (1, \<lambda>x. twoC (x, 0)), (- 1, \<lambda>x. twoC (x, 1))}. k * line_integral F {j} g) =
                        line_integral F {j} (\<lambda>x. twoC (x, 0)) + (\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (- 1, \<lambda>x. twoC (x, 1))}. k * line_integral F {j} g)"
       using sum.insert_remove [OF finite1]
       using valid_two_cube
       apply (simp only: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def valid_two_cube_def)
       by (auto simp: card_insert_if split: if_split_asm)
     have three_distinct_edges: "card {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (- 1, \<lambda>x. twoC (x, 1))} = 3"
       using valid_two_cube
       apply (simp add: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def valid_two_cube_def)
       by (auto simp: card_insert_if split: if_split_asm)
     have finite2: "finite {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))}" by auto
     then have sum_step2: "(\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (-1, \<lambda>x. twoC (x, 1))}. k * line_integral F {j} g) =
                        (- line_integral F {j} (\<lambda>x. twoC (x, 1))) + (\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))}. k * line_integral F {j} g)"
       using sum.insert_remove [OF finite2] three_distinct_edges
       by (auto simp: card_insert_if split: if_split_asm)
     have two_distinct_edges: "card {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))} = 2"
       using three_distinct_edges
       by (simp add: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def)
     have finite3: "finite {(- 1::int, \<lambda>y. twoC (0, y))}" by auto
     then have sum_step3: "(\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))}. k * line_integral F {j} g) =
                        ( line_integral F {j} (\<lambda>y. twoC (1, y))) + (\<Sum>(k, g)\<in>{(- (1::real), \<lambda>y. twoC (0, y))}. k * line_integral F {j} g)"
       using sum.insert_remove [OF finite2] three_distinct_edges
       by (auto simp: card_insert_if split: if_split_asm)
     show "(\<Sum>x\<in>{(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (1, \<lambda>x. twoC (x, 0)), (- 1, \<lambda>x. twoC (x, 1))}. case x of (k, g) \<Rightarrow> k * line_integral F {j} g) =
                   line_integral F {j} (\<lambda>x. twoC (x, 0)) + line_integral F {j} (\<lambda>y. twoC (1, y)) - line_integral F {j} (\<lambda>x. twoC (x, 1)) - line_integral F {j} (\<lambda>y. twoC (0, y))"
       using sum_step1 sum_step2 sum_step3  by auto
   qed
   obtain a b g1 g2 where
     twoCisTypeII: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(y, x). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(y, x). ((1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b), (1 - x) * a + x * b))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     using two_cube and typeII_twoCubeImg[of"twoC"]
     by auto
   have left_edge_explicit: "?left_edge = (\<lambda>x. (g2 (a + (b - a) * x), a + (b - a) * x))"
     by (simp add: twoCisTypeII(4) algebra_simps)
   have left_edge_smooth: "?left_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "\<forall>x. (\<lambda>x. (a + (b - a) * x))-` {x} = {(x - a)/(b -a)}"
       using twoCisTypeII(1) by(auto simp add: Set.vimage_def)
     then have finite_vimg: "\<And>x. finite({0..1} \<inter> (\<lambda>x. (a + (b - a) * x))-` {x})" by auto
     have scale_shif_smth: "(\<lambda>x. (a + (b - a) * x)) C1_differentiable_on {0..1}" using scale_shift_smooth by auto
     then have scale_shif_pw_smth: "(\<lambda>x. (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}" using C1_differentiable_imp_piecewise by blast
     have g2_smooth: "g2 piecewise_C1_differentiable_on (\<lambda>x. a + (b - a) * x) ` {0..1}" using add_scale_img[OF twoCisTypeII(1)] twoCisTypeII(6) by auto
     have "(\<lambda>x. g2 (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using piecewise_C1_differentiable_compose[OF scale_shif_pw_smth g2_smooth finite_vimg]
       by (auto simp add: o_def)
     then have "(\<lambda>x::real. (g2 (a + (b - a) * x), a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[where f = "(\<lambda>x::real. (g2 (a + (b - a) * x), a + (b - a) * x))"]
       by (fastforce simp add: real_pair_basis)
     then show ?thesis using left_edge_explicit by auto
   qed
   have top_edge_explicit: "?top_edge = (\<lambda>x. (g2 b + x *\<^sub>R (g1 b - g2 b), b))"
    and right_edge_explicit: "?right_edge = (\<lambda>x. (g1 (a + (b - a) * x), a + (b - a) * x))"
     by (simp_all add: twoCisTypeII(4) algebra_simps)
   have right_edge_smooth: "?right_edge piecewise_C1_differentiable_on {0..1}"
   proof -
     have "\<forall>x. (\<lambda>x. (a + (b - a) * x))-` {x} = {(x - a)/(b -a)}"
       using twoCisTypeII(1) by(auto simp add: Set.vimage_def)
     then have finite_vimg: "\<And>x. finite({0..1} \<inter> (\<lambda>x. (a + (b - a) * x))-` {x})" by auto
     then have scale_shif_pw_smth: "(\<lambda>x. (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}" 
       using C1_differentiable_imp_piecewise [OF scale_shift_smooth] by auto
     have g1_smooth: "g1 piecewise_C1_differentiable_on (\<lambda>x. a + (b - a) * x) ` {0..1}" using add_scale_img[OF twoCisTypeII(1)] twoCisTypeII(5) by auto
     have "(\<lambda>x. g1 (a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using piecewise_C1_differentiable_compose[OF scale_shif_pw_smth g1_smooth finite_vimg]
       by (auto simp add: o_def)
     then have "(\<lambda>x::real. (g1 (a + (b - a) * x), a + (b - a) * x)) piecewise_C1_differentiable_on {0..1}"
       using all_components_smooth_one_pw_smooth_is_pw_smooth[where f = "(\<lambda>x::real. (g1 (a + (b - a) * x), a + (b - a) * x))"]
       by (fastforce simp add: real_pair_basis)
     then show ?thesis using right_edge_explicit by auto
   qed
   have bottom_edge_explicit: "?bottom_edge = (\<lambda>x. (g2 a + x *\<^sub>R (g1 a - g2 a), a))"
     by (simp add: twoCisTypeII(4) algebra_simps)
   show "integral (cubeImage twoC) (\<lambda>a. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i  a) = one_chain_line_integral F {j} (boundary twoC)"
     using Greens_thm_type_II[OF twoCisTypeII(3) left_edge_explicit left_edge_smooth
         top_edge_explicit right_edge_explicit right_edge_smooth
         bottom_edge_explicit f_analytically_valid
         twoCisTypeII(2) twoCisTypeII(1)]
       line_integral_around_boundary
     by auto
   have "line_integral_exists F {j} \<gamma>" if "(k,\<gamma>) \<in> boundary twoC" for k \<gamma>
   proof -
     have "line_integral_exists F {j} (\<lambda>y. twoC (0, y))"
          "line_integral_exists F {j} (\<lambda>x. twoC (x, 1))"
          "line_integral_exists F {j} (\<lambda>y. twoC (1, y))"
          "line_integral_exists F {j} (\<lambda>x. twoC (x, 0))"
       using Greens_thm_type_II[OF twoCisTypeII(3) left_edge_explicit left_edge_smooth
           top_edge_explicit right_edge_explicit right_edge_smooth
           bottom_edge_explicit f_analytically_valid
           twoCisTypeII(2) twoCisTypeII(1)] line_integral_around_boundary
       by auto
     then show "line_integral_exists F {j} \<gamma>"
       using that by (auto simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   qed
   then show "\<forall>(k,\<gamma>) \<in> boundary twoC. line_integral_exists F {j} \<gamma>" by auto
 qed
 
 lemma line_integral_exists_on_typeII_Cube_boundaries':
   assumes "(k,\<gamma>) \<in> boundary twoC"
   shows "line_integral_exists F {j} \<gamma>"
   using assms GreenThm_typeII_twoCube(2) by blast
 
 end
 
 locale green_typeII_chain =  R2 + 
   fixes F two_chain s
   assumes valid_typeII_div: "valid_typeII_division s two_chain" and
           F_anal_valid: "\<forall>twoC \<in> two_chain. analytically_valid (cubeImage twoC) (\<lambda>x. (F x) \<bullet> j) i"
 begin
 
 lemma two_chain_valid_valid_cubes: "\<forall>two_cube \<in> two_chain. valid_two_cube two_cube" using valid_typeII_div
   by (auto simp add: valid_two_chain_def)
 
 lemma typeII_chain_line_integral_exists_boundary':
   shows "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. line_integral_exists F {j} \<gamma>"
 proof -
   have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {j} \<gamma>"
     using green_typeII_cube.line_integral_exists_on_typeII_Cube_boundaries'[of i j] F_anal_valid valid_typeII_div 
     apply(auto simp add:  two_chain_boundary_def)
     using R2_axioms green_typeII_cube_axioms_def green_typeII_cube_def two_chain_valid_valid_cubes by blast
   then show integ_exis_vert:
     "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. line_integral_exists F {j} \<gamma>"
     by (simp add: two_chain_boundary_def two_chain_vertical_boundary_def boundary_def)
 qed
 
 lemma typeII_chain_line_integral_exists_boundary'':
      "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. line_integral_exists F {j} \<gamma>"
 proof -
   have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {j} \<gamma>"
     using green_typeII_cube.line_integral_exists_on_typeII_Cube_boundaries'[of i j] valid_typeII_div
     apply (simp add: two_chain_boundary_def boundary_def)
     using F_anal_valid R2_axioms green_typeII_cube_axioms_def green_typeII_cube_def two_chain_valid_valid_cubes by fastforce
   then show integ_exis_vert:
     "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. line_integral_exists F {j} \<gamma>"
     by (simp add: two_chain_boundary_def two_chain_horizontal_boundary_def boundary_def)
 qed
 
 lemma typeII_cube_line_integral_exists_boundary:
      "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {j} \<gamma>"
   using valid_typeII_div typeII_chain_line_integral_exists_boundary' typeII_chain_line_integral_exists_boundary''
   apply (auto simp add: two_chain_boundary_def two_chain_horizontal_boundary_def two_chain_vertical_boundary_def)
   using boundary_def by auto
 
 lemma type_II_chain_horiz_bound_valid:
      "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. valid_path \<gamma>"
   using valid_typeII_div typeII_edges_are_valid_paths
   by (force simp add: two_chain_boundary_def two_chain_horizontal_boundary_def boundary_def)
 
 lemma type_II_chain_vert_bound_valid: (*This and the previous one need to be used in all proofs*)
      "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. valid_path \<gamma>"
   using typeII_edges_are_valid_paths valid_typeII_div
   by (force simp add: two_chain_boundary_def two_chain_vertical_boundary_def boundary_def)
 
 lemma members_of_only_horiz_div_line_integrable':
   assumes "only_horizontal_division one_chain two_chain"
     "(k::int, \<gamma>)\<in>one_chain"
     "(k::int, \<gamma>)\<in>one_chain"
     "finite two_chain"
     "\<forall>two_cube \<in> two_chain. valid_two_cube two_cube"
   shows "line_integral_exists F {j} \<gamma>"
 proof -
   have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {j} \<gamma>"
     using typeII_cube_line_integral_exists_boundary by blast
   have integ_exis_vert:
     "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. line_integral_exists F {j} \<gamma>"
     using typeII_chain_line_integral_exists_boundary' assms by auto
   have integ_exis_horiz:
     "(\<And>k \<gamma>. (\<exists>(k', \<gamma>') \<in> two_chain_horizontal_boundary two_chain. \<exists>a\<in>{0..1}. \<exists>b\<in>{0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>) \<Longrightarrow>
                             line_integral_exists F {j} \<gamma>)"
     using integ_exis type_II_chain_horiz_bound_valid
     using line_integral_exists_subpath[of "F" "{j}"]
     by (fastforce simp add: two_chain_boundary_def two_chain_horizontal_boundary_def
         two_chain_vertical_boundary_def boundary_def)
   obtain \<H> \<V> where hv_props: "finite \<H>"
         "(\<forall>(k,\<gamma>) \<in> \<H>. (\<exists>(k', \<gamma>') \<in> two_chain_horizontal_boundary two_chain.
             (\<exists>a \<in> {0 .. 1}. \<exists>b \<in> {0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>)))"
         "one_chain = \<H> \<union> \<V>"
         "((common_sudiv_exists (two_chain_vertical_boundary two_chain) \<V>)
           \<or> common_reparam_exists \<V> (two_chain_vertical_boundary two_chain))"
     "finite \<V>"
     "boundary_chain \<V>"
     "\<forall>(k,\<gamma>)\<in>\<V>. valid_path \<gamma>"
     using assms(1) unfolding only_horizontal_division_def  by blast
   have finite_j: "finite {j}" by auto
   show "line_integral_exists F {j} \<gamma>"
   proof(cases "common_sudiv_exists (two_chain_vertical_boundary two_chain) \<V>")
     case True
     show ?thesis
       using gen_common_subdivision_imp_eq_line_integral(2)[OF True two_chain_vertical_boundary_is_boundary_chain hv_props(6) integ_exis_vert finite_two_chain_vertical_boundary[OF assms(4)] hv_props(5) finite_j]
         integ_exis_horiz[of "\<gamma>"] assms(3) case_prod_conv hv_props(2) hv_props(3)
       by fastforce
   next
     case False
     have i: "{j} \<subseteq> Basis" using j_is_y_axis real_pair_basis by auto
     have ii: " \<forall>(k2, \<gamma>2)\<in>two_chain_vertical_boundary two_chain. \<forall>b\<in>{j}. continuous_on (path_image \<gamma>2) (\<lambda>x. F x \<bullet> b)"
       using F_anal_valid field_cont_on_typeII_region_cont_on_edges valid_typeII_div
       by (fastforce simp add: analytically_valid_def two_chain_vertical_boundary_def boundary_def path_image_def)
     show "line_integral_exists F {j} \<gamma>"
       using common_reparam_exists_imp_eq_line_integral(2)[OF finite_j hv_props(5) 
            finite_two_chain_vertical_boundary[OF assms(4)] hv_props(6) two_chain_vertical_boundary_is_boundary_chain ii _ hv_props(7) type_II_chain_vert_bound_valid]
         integ_exis_horiz[of "\<gamma>"] assms(3) hv_props False 
       by fastforce
   qed
 qed
 
 lemma GreenThm_typeII_twoChain:
   shows "two_chain_integral two_chain (partial_vector_derivative (\<lambda>a. (F a) \<bullet> j)  i) = one_chain_line_integral F {j} (two_chain_boundary two_chain)"
 proof (simp add: two_chain_boundary_def one_chain_line_integral_def two_chain_integral_def)
   let ?F_a' = "partial_vector_derivative (\<lambda>a. (F a) \<bullet> j)  i"
   have "(\<Sum>(k,g)\<in> boundary twoCube. k * line_integral F {j} g) = integral (cubeImage twoCube) (\<lambda>a. ?F_a' a)"
     if "twoCube \<in> two_chain" for twoCube
     using green_typeII_cube.GreenThm_typeII_twoCube(1) valid_typeII_div F_anal_valid one_chain_line_integral_def valid_two_chain_def
     by (simp add: R2_axioms green_typeII_cube_axioms_def green_typeII_cube_def that)
   then have double_sum_eq_sum:
     "(\<Sum>twoCube\<in>(two_chain).(\<Sum>(k,g)\<in> boundary twoCube. k * line_integral F {j} g))
                      =  (\<Sum>twoCube\<in>(two_chain). integral (cubeImage twoCube) (\<lambda>a. ?F_a' a))"
     using Finite_Cartesian_Product.sum_cong_aux by auto
   have pairwise_disjoint_boundaries: "\<forall>x\<in> (boundary ` two_chain). (\<forall>y\<in> (boundary ` two_chain). (x \<noteq> y \<longrightarrow> (x \<inter> y = {})))"
     using valid_typeII_div by (fastforce simp add:  image_def valid_two_chain_def pairwise_def)
   have finite_boundaries: "\<forall>B \<in> (boundary` two_chain). finite B"
     using valid_typeII_div image_iff by (fastforce simp add: valid_two_cube_def valid_two_chain_def)
   have boundary_inj: "inj_on boundary two_chain"
     using valid_typeII_div by (force simp add: valid_two_cube_def valid_two_chain_def pairwise_def inj_on_def)
   have "(\<Sum>x\<in>(\<Union>x\<in>two_chain. boundary x). case x of (k, g) \<Rightarrow> k * line_integral F {j} g) =
                       (\<Sum>twoCube\<in>(two_chain).(\<Sum>(k,g)\<in> boundary twoCube. k * line_integral F {j} g))"
     using sum.reindex[OF boundary_inj,  of "\<lambda>x. (\<Sum>(k,g)\<in> x. k * line_integral F {j} g)"]
     using sum.Union_disjoint[OF finite_boundaries
         pairwise_disjoint_boundaries,
         of "\<lambda>x. case x of (k, g) \<Rightarrow> (k::int) * line_integral F {j} g"]
     by auto
   then show "(\<Sum>C\<in>two_chain. integral (cubeImage C) (\<lambda>a. ?F_a' a)) = (\<Sum>x\<in>(\<Union>x\<in>two_chain. boundary x). case x of (k, g) \<Rightarrow> k * line_integral F {j} g)"
     using double_sum_eq_sum  by auto
 qed
 
 lemma GreenThm_typeII_divisible:
   assumes 
     gen_division: "gen_division s (cubeImage ` two_chain)"    (*This should follow from the assumption that images are not negligible*)
   shows "integral s (partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i) = one_chain_line_integral F {j} (two_chain_boundary two_chain)"
 proof -
   let ?F_a' = "(partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i)"
   have "integral s (\<lambda>x. ?F_a' x) = two_chain_integral two_chain (\<lambda>a. ?F_a' a)"
   proof (simp add: two_chain_integral_def)
     have partial_deriv_integrable:
       "(?F_a' has_integral (integral (cubeImage twoCube) ?F_a')) (cubeImage twoCube)"
       if "twoCube \<in> two_chain" for twoCube
       by (simp add: analytically_valid_imp_part_deriv_integrable_on F_anal_valid integrable_integral that)
     then have partial_deriv_integrable:
       "\<And>twoCubeImg. twoCubeImg \<in> cubeImage ` two_chain \<Longrightarrow> ((\<lambda>x. ?F_a' x) has_integral (integral (twoCubeImg) (\<lambda>x. ?F_a' x))) (twoCubeImg)"
       using integrable_neg by force
     have finite_images: "finite (cubeImage ` two_chain)"
       using gen_division gen_division_def by auto
     have negligible_images: "pairwise (\<lambda>S S'. negligible (S \<inter> S')) (cubeImage ` two_chain)"
       using gen_division by (auto simp add: gen_division_def pairwise_def)
     have "inj_on cubeImage two_chain" using valid_typeII_div valid_two_chain_def by auto
     then have "(\<Sum>twoCubeImg\<in>cubeImage ` two_chain. integral twoCubeImg (\<lambda>x. ?F_a' x))
              = (\<Sum>C\<in>two_chain. integral (cubeImage C) (\<lambda>a. ?F_a' a))"
       using sum.reindex by auto
     then show "integral s (\<lambda>x. ?F_a' x) = (\<Sum>C\<in>two_chain. integral (cubeImage C) (\<lambda>a. ?F_a' a))"
       using has_integral_Union[OF finite_images partial_deriv_integrable negligible_images] gen_division
       by (auto simp add: gen_division_def)
   qed
   then show ?thesis
     using GreenThm_typeII_twoChain F_anal_valid
     by auto
 qed
 
 lemma GreenThm_typeII_divisible_region_boundary_gen:
   assumes only_horizontal_division: "only_horizontal_division \<gamma> two_chain"
   shows "integral s (partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i) = one_chain_line_integral F {j} \<gamma>"
 proof -
   let ?F_a' = "(partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i)"
     (*Proving that line_integral on the x axis is 0 for the vertical 1-cubes*)
   have horiz_line_integral_zero:
     "one_chain_line_integral F {j} (two_chain_horizontal_boundary two_chain) = 0"
   proof (simp add: one_chain_line_integral_def)
     have "line_integral F {j} (snd oneCube) = 0"
       if "oneCube \<in> two_chain_horizontal_boundary(two_chain)" for oneCube
     proof -
       from that obtain x y1 y2 k 
         where horiz_edge_def: "oneCube = (k, (\<lambda>t::real. ((1 - t) * (y2) + t * y1, x::real)))"
         using valid_typeII_div
         by (auto simp add: typeII_twoCube_def two_chain_horizontal_boundary_def horizontal_boundary_def)
       let ?horiz_edge = "(snd oneCube)"
       have horiz_edge_y_const: "\<forall>t. (?horiz_edge t) \<bullet> j = x"
         by (auto simp add: horiz_edge_def real_inner_class.inner_add_left
             euclidean_space_class.inner_not_same_Basis j_is_y_axis)
       have horiz_edge_is_straight_path: "?horiz_edge = (\<lambda>t. (y2 + t * (y1 - y2), x))"
         by (auto simp: horiz_edge_def algebra_simps)
       have "\<forall>x. ?horiz_edge differentiable at x"
         using horiz_edge_is_straight_path straight_path_diffrentiable_y
         by (metis mult_commute_abs)
       then show "line_integral F {j} (snd oneCube) = 0"
         using line_integral_on_pair_straight_path(1) j_is_y_axis real_pair_basis horiz_edge_y_const
         by blast
     qed
     then show "(\<Sum>x\<in>two_chain_horizontal_boundary two_chain. case x of (k, g) \<Rightarrow> k * line_integral F {j} g) = 0"
       by (force intro: sum.neutral)
   qed
     (*then, the x axis line_integral on the boundaries of the twoCube is equal to the line_integral on the horizontal boundaries of the twoCube \<longrightarrow> 1*)
   have boundary_is_finite: "finite (two_chain_boundary two_chain)"
     unfolding two_chain_boundary_def
   proof (rule finite_UN_I)
     show "finite two_chain"
       using valid_typeII_div finite_image_iff gen_division_def valid_two_chain_def by auto
     show "\<And>a. a \<in> two_chain \<Longrightarrow> finite (boundary a)"
       by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   qed
   have boundary_is_vert_hor:
      "two_chain_boundary two_chain =
       (two_chain_vertical_boundary two_chain) \<union>
       (two_chain_horizontal_boundary two_chain)"
     by(auto simp add: two_chain_boundary_def two_chain_vertical_boundary_def two_chain_horizontal_boundary_def
         boundary_def)
   then have hor_vert_finite:
     "finite (two_chain_vertical_boundary two_chain)"
     "finite (two_chain_horizontal_boundary two_chain)"
     using boundary_is_finite by auto
   have horiz_verti_disjoint:
     "(two_chain_vertical_boundary two_chain) \<inter>
      (two_chain_horizontal_boundary two_chain) = {}"
   proof (simp add: two_chain_vertical_boundary_def two_chain_horizontal_boundary_def horizontal_boundary_def
         vertical_boundary_def)
     show "(\<Union>x\<in>two_chain. {(- 1, \<lambda>y. x (0, y)), (1::int, \<lambda>y. x (1::real, y))}) \<inter> (\<Union>x\<in>two_chain. {(1, \<lambda>z. x (z, 0)), (- 1, \<lambda>z. x (z, 1))}) = {}"
     proof -
       have "{(- 1, \<lambda>y. twoCube (0, y)), (1::int, \<lambda>y. twoCube (1, y))} \<inter>
             {(1, \<lambda>z. twoCube2 (z, 0)), (- 1, \<lambda>z. twoCube2 (z, 1))} = {}"
         if "twoCube\<in>two_chain" "twoCube2\<in>two_chain" for twoCube twoCube2
       proof (cases "twoCube = twoCube2")
         case True
         have card_4: "card {(- 1, \<lambda>y. twoCube2 (0::real, y)), (1::int, \<lambda>y. twoCube2 (1, y)), (1, \<lambda>x. twoCube2 (x, 0)), (- 1, \<lambda>x. twoCube2 (x, 1))} = 4"
           using valid_typeII_div valid_two_chain_def that(2)
           by (auto simp add: boundary_def vertical_boundary_def horizontal_boundary_def valid_two_cube_def)
         show ?thesis
           using card_4 by (auto simp: True card_insert_if split: if_split_asm)
       next
         case False
         show ?thesis
           using valid_typeII_div valid_two_chain_def
           by (simp add: boundary_def vertical_boundary_def horizontal_boundary_def pairwise_def \<open>twoCube \<noteq> twoCube2\<close> that)
       qed
       then have "\<Union> ((\<lambda>twoCube. {(- 1, \<lambda>y. twoCube (0::real, y)), (1::real, \<lambda>y. twoCube (1::real, y))}) ` two_chain)
                                           \<inter> \<Union> ((\<lambda>twoCube. {(1::int, \<lambda>z. twoCube (z, 0::real)), (- 1, \<lambda>z. twoCube (z, 1::real))}) ` two_chain)
                                               = {}"
         by (fastforce simp add: Union_disjoint)
       then show ?thesis by force
     qed
   qed
   have "one_chain_line_integral F {j} (two_chain_boundary two_chain)
        = one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain) +
          one_chain_line_integral F {j} (two_chain_horizontal_boundary two_chain)"
     using boundary_is_vert_hor horiz_verti_disjoint
     by (simp add: hor_vert_finite sum.union_disjoint one_chain_line_integral_def)
   then have y_axis_line_integral_is_only_vertical:
     "one_chain_line_integral F {j} (two_chain_boundary two_chain)
                          = one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
     using horiz_line_integral_zero
     by auto
       (*Since \<gamma> \<subseteq> the boundary of the 2-chain and the horizontal boundaries are \<subseteq> \<gamma>, then there is some \<H> \<subseteq> \<partial>\<^sub>H(2-\<C>) such that \<gamma> = \<H> \<union> \<partial>\<^sub>v(2-\<C>)*)
   obtain \<H> \<V> where hv_props: "finite \<H>"
     "(\<forall>(k,\<gamma>) \<in> \<H>. (\<exists>(k', \<gamma>') \<in> two_chain_horizontal_boundary two_chain.
                       (\<exists>a \<in> {0 .. 1}.
                             \<exists>b \<in> {0..1}.
                                 a \<le> b \<and> subpath a b \<gamma>' = \<gamma>)))"
     "\<gamma> = \<H> \<union> \<V>"
     "(common_sudiv_exists (two_chain_vertical_boundary two_chain) \<V>
       \<or> common_reparam_exists \<V> (two_chain_vertical_boundary two_chain))"
     "finite \<V>"
     "boundary_chain \<V>"
     "\<forall>(k,\<gamma>)\<in>\<V>. valid_path \<gamma>"
     using only_horizontal_division
     by(fastforce simp add:  only_horizontal_division_def)
   have "finite {j}" by auto
   then have eq_integrals: " one_chain_line_integral F {j} \<V> = one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
   proof(cases "common_sudiv_exists (two_chain_vertical_boundary two_chain) \<V>")
     case True then show ?thesis
       using gen_common_subdivision_imp_eq_line_integral(1)[OF True two_chain_vertical_boundary_is_boundary_chain hv_props(6) _ hor_vert_finite(1) hv_props(5)]
         typeII_chain_line_integral_exists_boundary'
       by force
   next
     case False
     have integ_exis_vert:
       "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. line_integral_exists F {j} \<gamma>"
       using typeII_chain_line_integral_exists_boundary' assms
       by (fastforce simp add: valid_two_chain_def)
     have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {j} \<gamma>"
       using typeII_cube_line_integral_exists_boundary by blast
     have valid_paths: "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. valid_path \<gamma>"
       using typeII_edges_are_valid_paths valid_typeII_div
       by (fastforce simp add: two_chain_boundary_def two_chain_horizontal_boundary_def boundary_def)
     have integ_exis_horiz:
       "(\<And>k \<gamma>. (\<exists>(k', \<gamma>')\<in>two_chain_horizontal_boundary two_chain. \<exists>a\<in>{0..1}. \<exists>b\<in>{0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>) \<Longrightarrow>
                 line_integral_exists F {j} \<gamma>)"
       using integ_exis valid_paths line_integral_exists_subpath[of "F" "{j}"]
       by (fastforce simp add: two_chain_boundary_def two_chain_horizontal_boundary_def
           two_chain_vertical_boundary_def boundary_def)
     have finite_j: "finite {j}" by auto
     have i: "{j} \<subseteq> Basis" using j_is_y_axis real_pair_basis by auto
     have ii: " \<forall>(k2, \<gamma>2)\<in>two_chain_vertical_boundary two_chain. \<forall>b\<in>{j}. continuous_on (path_image \<gamma>2) (\<lambda>x. F x \<bullet> b)"
       using valid_typeII_div field_cont_on_typeII_region_cont_on_edges F_anal_valid
       by (fastforce simp add: analytically_valid_def two_chain_vertical_boundary_def boundary_def path_image_def)
     show "one_chain_line_integral F {j} \<V> = one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
       using hv_props(4) False common_reparam_exists_imp_eq_line_integral(1)[OF finite_j hv_props(5) hor_vert_finite(1) hv_props(6) two_chain_vertical_boundary_is_boundary_chain ii 
           _ hv_props(7) type_II_chain_vert_bound_valid] 
       by fastforce
   qed
     (*Since \<H> \<subseteq> \<partial>\<^sub>H(2-\<C>), then the line_integral on the x axis along \<H> is 0, and from 1 Q.E.D. *)
   have line_integral_on_path:
     "one_chain_line_integral F {j} \<gamma> =
      one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
   proof (simp only: one_chain_line_integral_def)
     have "line_integral F {j} (snd oneCube) = 0" if oneCube: "oneCube \<in> \<H>" for oneCube
     proof -
       obtain k \<gamma> where k_gamma: "(k,\<gamma>) = oneCube"
         using prod.collapse by blast
       then obtain k' \<gamma>' a b where kp_gammap:
         "(k'::int, \<gamma>') \<in> two_chain_horizontal_boundary two_chain"
         "a \<in> {0 .. 1}"
         "b \<in> {0..1}"
         "subpath a b \<gamma>' = \<gamma>"
         using hv_props oneCube
         by (smt case_prodE split_conv)
       obtain x y1 y2 where horiz_edge_def: "(k',\<gamma>') = (k', (\<lambda>t::real. ((1 - t) * (y2) + t * y1, x::real)))"
         using valid_typeII_div kp_gammap
         by (auto simp add: typeII_twoCube_def two_chain_horizontal_boundary_def horizontal_boundary_def)
       have horiz_edge_y_const: "\<forall>t. \<gamma> (t) \<bullet> j = x"
         using horiz_edge_def kp_gammap(4)
         by (auto simp add: real_inner_class.inner_add_left
             euclidean_space_class.inner_not_same_Basis j_is_y_axis subpath_def)
       have horiz_edge_is_straight_path:
         "\<gamma> = (\<lambda>t::real. ((1*y2 - a*y2) +  a*y1 + ((b-a)*y1 - (b - a)*y2)*t, x::real))"
       proof -
         fix t::real
         have "(1 - (b - a)*t + a) * (y2) + ((b-a)*t + a) * y1 = (1 - (b - a)*t + a) * (y2) + ((b-a)*t + a) * y1"
           by auto
         then have "\<gamma> = (\<lambda>t::real. ((1 - (b - a)*t - a) * (y2) + ((b-a)*t + a) * y1, x::real))"
           using horiz_edge_def Product_Type.snd_conv Product_Type.fst_conv kp_gammap(4)
           by (simp add: subpath_def diff_diff_eq[symmetric])
         also have "\<dots> = (\<lambda>t::real. ((1*y2 - (b - a)*y2*t - a*y2) + ((b-a)*y1*t + a*y1), x::real))"
           by(auto simp add: ring_class.ring_distribs(2) Groups.diff_diff_eq left_diff_distrib)
         also have "... = (\<lambda>t::real. ((1*y2 - a*y2) +  a*y1 + ((b-a)*y1 - (b - a)*y2)*t, x::real))"
           by (force simp add: left_diff_distrib)
         finally show "\<gamma> = (\<lambda>t::real. ((1*y2 - a*y2) +  a*y1 + ((b-a)*y1 - (b - a)*y2)*t, x::real))" .
       qed
       show "line_integral F {j} (snd oneCube) = 0"
       proof -
         have "\<forall>x. \<gamma> differentiable at x"
           by (simp add: horiz_edge_is_straight_path straight_path_diffrentiable_y)
         then have "line_integral F {j} \<gamma> = 0"
           by (simp add: horiz_edge_y_const line_integral_on_pair_straight_path(1))
         then show ?thesis
           using Product_Type.snd_conv k_gamma by auto
       qed
     qed
     then have "\<forall>x\<in>\<H>. (case x of (k, g) \<Rightarrow> (k::int) * line_integral F {j} g) = 0"
       by auto
     then show "(\<Sum>x\<in>\<gamma>. case x of (k, g) \<Rightarrow> real_of_int k * line_integral F {j} g) =
                (\<Sum>x\<in>two_chain_vertical_boundary two_chain. case x of (k, g) \<Rightarrow> real_of_int k * line_integral F {j} g)"
       using hv_props(1) hv_props(3) hv_props(5) sum_zero_set hor_vert_finite(1) eq_integrals
       by (clarsimp simp add: one_chain_line_integral_def sum_zero_set)
   qed
   then have "one_chain_line_integral F {j} \<gamma> =
                            one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
     using line_integral_on_path by auto
   then have "one_chain_line_integral F {j} \<gamma> =
                            one_chain_line_integral F {j} (two_chain_boundary two_chain)"
     using y_axis_line_integral_is_only_vertical by auto
   then show ?thesis
     using valid_typeII_div GreenThm_typeII_divisible by auto
 qed
 
 lemma GreenThm_typeII_divisible_region_boundary:
   assumes
     two_cubes_trace_vertical_boundaries: 
     "two_chain_vertical_boundary two_chain \<subseteq> \<gamma>" and
     boundary_of_region_is_subset_of_partition_boundary:
     "\<gamma> \<subseteq> two_chain_boundary two_chain"
   shows "integral s (partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i) = one_chain_line_integral F {j} \<gamma>"
 proof -
   let ?F_a' = "(partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i)"
     (*Proving that line_integral on the x axis is 0 for the vertical 1-cubes*)
   have horiz_line_integral_zero:
     "one_chain_line_integral F {j} (two_chain_horizontal_boundary two_chain) = 0"
   proof (simp add: one_chain_line_integral_def)
     have "line_integral F {j} (snd oneCube) = 0"
       if one: "oneCube \<in> two_chain_horizontal_boundary(two_chain)" for oneCube
     proof -
       obtain x y1 y2 k where horiz_edge_def: "oneCube = (k, (\<lambda>t::real. ((1 - t) * (y2) + t * y1, x::real)))"
         using valid_typeII_div one
         by (auto simp add: typeII_twoCube_def two_chain_horizontal_boundary_def horizontal_boundary_def)
       let ?horiz_edge = "(snd oneCube)"
       have horiz_edge_y_const: "\<forall>t. (?horiz_edge t) \<bullet> j = x"
         using horiz_edge_def
         by (auto simp add: real_inner_class.inner_add_left
             euclidean_space_class.inner_not_same_Basis j_is_y_axis)
       have horiz_edge_is_straight_path:
         "?horiz_edge = (\<lambda>t. (y2 + t * (y1 - y2), x))"
         by (simp add: add_diff_eq diff_add_eq mult.commute right_diff_distrib horiz_edge_def)
       show "line_integral F {j} (snd oneCube) = 0"
         by (metis horiz_edge_is_straight_path horiz_edge_y_const line_integral_on_pair_straight_path(1) mult.commute straight_path_diffrentiable_y)
     qed
     then show "(\<Sum>x\<in>two_chain_horizontal_boundary two_chain. case x of (k, g) \<Rightarrow> k * line_integral F {j} g) = 0"
       by (simp add: prod.case_eq_if)
   qed
     (*then, the x axis line_integral on the boundaries of the twoCube is equal to the line_integral on the horizontal boundaries of the twoCube \<longrightarrow> 1*)
   have boundary_is_finite: "finite (two_chain_boundary two_chain)"
     unfolding two_chain_boundary_def
   proof (rule finite_UN_I)
     show "finite two_chain"
       using valid_typeII_div finite_image_iff gen_division_def valid_two_chain_def by auto
     show "\<And>a. a \<in> two_chain \<Longrightarrow> finite (boundary a)"
       by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   qed
   have boundary_is_vert_hor:
     "two_chain_boundary two_chain = (two_chain_vertical_boundary two_chain) \<union> (two_chain_horizontal_boundary two_chain)"
     by(auto simp add: two_chain_boundary_def two_chain_vertical_boundary_def two_chain_horizontal_boundary_def boundary_def)
   then have hor_vert_finite:
     "finite (two_chain_vertical_boundary two_chain)"
     "finite (two_chain_horizontal_boundary two_chain)"
     using boundary_is_finite by auto
   have horiz_verti_disjoint:
     "(two_chain_vertical_boundary two_chain) \<inter> (two_chain_horizontal_boundary two_chain) = {}"
   proof (simp add: two_chain_vertical_boundary_def two_chain_horizontal_boundary_def horizontal_boundary_def
         vertical_boundary_def)
     show "(\<Union>x\<in>two_chain. {(- 1, \<lambda>y. x (0, y)), (1::int, \<lambda>y. x (1::real, y))}) \<inter> (\<Union>x\<in>two_chain. {(1, \<lambda>z. x (z, 0)), (- 1, \<lambda>z. x (z, 1))}) = {}"
     proof -
       have "{(- 1, \<lambda>y. twoCube (0, y)), (1::int, \<lambda>y. twoCube (1, y))} \<inter>
             {(1, \<lambda>y. twoCube2 (y, 0)), (- 1, \<lambda>y. twoCube2 (y, 1))} = {}"
         if  "twoCube\<in>two_chain" "twoCube2\<in>two_chain" for twoCube twoCube2
       proof (cases "twoCube = twoCube2")
         case True
         have "card {(- 1, \<lambda>y. twoCube2 (0::real, y)), (1::int, \<lambda>y. twoCube2 (1, y)), (1, \<lambda>x. twoCube2 (x, 0)), (- 1, \<lambda>x. twoCube2 (x, 1))} = 4"
           using valid_typeII_div valid_two_chain_def that(2)
           by (auto simp add: boundary_def vertical_boundary_def horizontal_boundary_def valid_two_cube_def)
         then show ?thesis
           by (auto simp: True card_insert_if split: if_split_asm)
       next
         case False show ?thesis
           using valid_typeII_div valid_two_chain_def
           by (simp add: boundary_def vertical_boundary_def horizontal_boundary_def pairwise_def \<open>twoCube \<noteq> twoCube2\<close> that(1) that(2))
       qed
       then have "\<Union> ((\<lambda>twoCube. {(- 1, \<lambda>y. twoCube (0::real, y)), (1::real, \<lambda>y. twoCube (1::real, y))}) ` two_chain)
                                           \<inter> \<Union> ((\<lambda>twoCube. {(1::int, \<lambda>z. twoCube (z, 0::real)), (- 1, \<lambda>z. twoCube (z, 1::real))}) ` two_chain)
                                               = {}"
         by (force simp add: Complete_Lattices.Union_disjoint)
       then show ?thesis by force
     qed
   qed
   have "one_chain_line_integral F {j} (two_chain_boundary two_chain)
         = one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain) +
           one_chain_line_integral F {j} (two_chain_horizontal_boundary two_chain)"
     using boundary_is_vert_hor horiz_verti_disjoint
     by (auto simp add: one_chain_line_integral_def hor_vert_finite sum.union_disjoint)
   then have y_axis_line_integral_is_only_vertical:
     "one_chain_line_integral F {j} (two_chain_boundary two_chain)
      = one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
     using horiz_line_integral_zero by auto
       (*Since \<gamma> \<subseteq> the boundary of the 2-chain and the horizontal boundaries are \<subseteq> \<gamma>, then there is some \<H> \<subseteq> \<partial>\<^sub>H(2-\<C>) such that \<gamma> = \<H> \<union> \<partial>\<^sub>v(2-\<C>)*)
   have "\<exists>\<H>. \<H> \<subseteq> (two_chain_horizontal_boundary two_chain) \<and>
              \<gamma> = \<H> \<union> (two_chain_vertical_boundary two_chain)"
   proof
     let ?\<H> = "\<gamma> - (two_chain_vertical_boundary two_chain)"
     show "?\<H> \<subseteq> two_chain_horizontal_boundary two_chain \<and> \<gamma> = ?\<H> \<union> two_chain_vertical_boundary two_chain"
       using two_cubes_trace_vertical_boundaries
         boundary_of_region_is_subset_of_partition_boundary boundary_is_vert_hor
       by blast
   qed
   then obtain \<H> where
     h_props: "\<H> \<subseteq> (two_chain_horizontal_boundary two_chain)"
     "\<gamma> = \<H> \<union> (two_chain_vertical_boundary two_chain)"
     by auto
   have h_vert_disj: "\<H> \<inter> (two_chain_vertical_boundary two_chain) = {}"
     using horiz_verti_disjoint h_props(1) by auto
   have h_finite: "finite \<H>"
     using hor_vert_finite h_props(1) Finite_Set.rev_finite_subset by force
   have line_integral_on_path:
     "one_chain_line_integral F {j} \<gamma> =
      one_chain_line_integral F {j} \<H> + one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
     by (auto simp add: one_chain_line_integral_def  h_props sum.union_disjoint[OF h_finite hor_vert_finite(1) h_vert_disj])
       (*Since \<H> \<subseteq> \<partial>\<^sub>H(2-\<C>), then the line_integral on the x axis along \<H> is 0, and from 1 Q.E.D. *)
   have "one_chain_line_integral F {j} \<H> = 0"
   proof (simp add: one_chain_line_integral_def)
     have "line_integral F {j} (snd oneCube) = 0"
       if oneCube: "oneCube \<in> two_chain_horizontal_boundary(two_chain)" for oneCube
     proof -
       obtain x y1 y2 k where horiz_edge_def: "oneCube = (k, (\<lambda>t::real. ((1 - t) * (y2) + t * y1, x::real)))"
         using valid_typeII_div oneCube
         by (auto simp add: typeII_twoCube_def two_chain_horizontal_boundary_def horizontal_boundary_def)
       let ?horiz_edge = "(snd oneCube)"
       have horiz_edge_y_const: "\<forall>t. (?horiz_edge t) \<bullet> j = x"
         by (simp add: j_is_y_axis horiz_edge_def)
       have horiz_edge_is_straight_path:
         "?horiz_edge = (\<lambda>t. (y2 + t * (y1 - y2), x))"
         by (simp add: add_diff_eq diff_add_eq mult.commute right_diff_distrib horiz_edge_def)
       show "line_integral F {j} (snd oneCube) = 0"
         by (simp add: horiz_edge_is_straight_path j_is_y_axis line_integral_on_pair_straight_path(1) mult.commute straight_path_diffrentiable_y)
     qed
     then have "\<forall>oneCube \<in> \<H>. line_integral F {j} (snd oneCube) = 0"
       using h_props by auto
     then have "\<forall>x\<in>\<H>. (case x of (k, g) \<Rightarrow> (k::int) * line_integral F {j} g) = 0"
       by auto
     then show "(\<Sum>x\<in>\<H>. case x of (k, g) \<Rightarrow> k * line_integral F {j} g) = 0"
       by simp
   qed
   then have "one_chain_line_integral F {j} \<gamma> =
                            one_chain_line_integral F {j} (two_chain_vertical_boundary two_chain)"
     using line_integral_on_path by auto
   then have "one_chain_line_integral F {j} \<gamma> =
              one_chain_line_integral F {j} (two_chain_boundary two_chain)"
     using y_axis_line_integral_is_only_vertical by auto
   then show ?thesis
     using valid_typeII_div GreenThm_typeII_divisible by auto
 qed
 
 end
 
 locale green_typeI_cube =  R2 +
   fixes twoC F
   assumes 
     two_cube: "typeI_twoCube twoC" and
     valid_two_cube: "valid_two_cube twoC" and
     f_analytically_valid: "analytically_valid (cubeImage twoC) (\<lambda>x. (F x) \<bullet> i) j"
 begin
 
 lemma GreenThm_typeI_twoCube:
   shows "integral (cubeImage twoC) (\<lambda>a. - partial_vector_derivative (\<lambda>p. F p \<bullet> i) j  a) = one_chain_line_integral F {i} (boundary twoC)"
     "\<forall>(k,\<gamma>) \<in> boundary twoC. line_integral_exists F {i} \<gamma>"
 proof -
   let ?bottom_edge = "(\<lambda>x. twoC(x, 0))"
   let ?right_edge = "(\<lambda>y. twoC(1, y))"
   let ?top_edge = "(\<lambda>x. twoC(x, 1))"
   let ?left_edge = "(\<lambda>y. twoC(0, y))"
   have line_integral_around_boundary:
     "one_chain_line_integral F {i} (boundary twoC) = 
      line_integral F {i} ?bottom_edge + line_integral F {i} ?right_edge
      -  line_integral F {i} ?top_edge - line_integral F {i} ?left_edge"
   proof (simp add: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def)
     have finite1: "finite {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (- 1, \<lambda>x. twoC (x, 1))}" by auto
     have sum_step1: "(\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (1, \<lambda>x. twoC (x, 0)), (- 1, \<lambda>x. twoC (x, 1))}. k * line_integral F {i} g) =
                        line_integral F {i} (\<lambda>x. twoC (x, 0)) + (\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (- 1, \<lambda>x. twoC (x, 1))}. k * line_integral F {i} g)"
       using sum.insert_remove [OF finite1] valid_two_cube
       by (auto simp: horizontal_boundary_def vertical_boundary_def boundary_def valid_two_cube_def card_insert_if split: if_split_asm)
     have three_distinct_edges: "card {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (- 1, \<lambda>x. twoC (x, 1))} = 3"
       using valid_two_cube
       apply (simp add: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def valid_two_cube_def)
       by (auto simp: card_insert_if split: if_split_asm)
     have finite2: "finite {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))}" by auto
     have sum_step2: "(\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (-1, \<lambda>x. twoC (x, 1))}. k * line_integral F {i} g) =
                           (- line_integral F {i} (\<lambda>x. twoC (x, 1))) + (\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))}. k * line_integral F {i} g)"
       using sum.insert_remove [OF finite2] three_distinct_edges
       by (auto simp: card_insert_if split: if_split_asm)
     have two_distinct_edges: "card {(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))} = 2"
       using three_distinct_edges
       by (simp add: one_chain_line_integral_def horizontal_boundary_def vertical_boundary_def boundary_def)
     have finite3: "finite {(- 1::int, \<lambda>y. twoC (0, y))}" by auto
     have sum_step3: "(\<Sum>(k, g)\<in>{(- (1::int), \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y))}. k * line_integral F {i} g) =
                           (line_integral F {i} (\<lambda>y. twoC (1, y))) + (\<Sum>(k, g)\<in>{(- (1::real), \<lambda>y. twoC (0, y))}. k * line_integral F {i} g)"
       using sum.insert_remove [OF finite2] three_distinct_edges 
       by (auto simp: card_insert_if split: if_split_asm)
     show "(\<Sum>x\<in>{(- 1::int, \<lambda>y. twoC (0, y)), (1, \<lambda>y. twoC (1, y)), (1, \<lambda>x. twoC (x, 0)), (- 1, \<lambda>x. twoC (x, 1))}. case x of (k, g) \<Rightarrow> k * line_integral F {i} g) =
                                line_integral F {i} (\<lambda>x. twoC (x, 0)) + line_integral F {i} (\<lambda>y. twoC (1, y)) - line_integral F {i} (\<lambda>x. twoC (x, 1)) - line_integral F {i} (\<lambda>y. twoC (0, y))"
       using sum_step1 sum_step2 sum_step3 by auto
   qed
   obtain a b g1 g2 where
     twoCisTypeI: "a < b"
     "(\<forall>x \<in> cbox a b. g2 x \<le> g1 x)"
     "cubeImage twoC = {(x,y). x \<in> cbox a b \<and> y \<in> cbox (g2 x) (g1 x)}"
     "twoC = (\<lambda>(x, y). ((1 - x) * a + x * b, (1 - y) * g2 ((1 - x) * a + x * b) + y * g1 ((1 - x) * a + x * b)))"
     "g1 piecewise_C1_differentiable_on {a .. b}"
     "g2 piecewise_C1_differentiable_on {a .. b}"
     "(\<lambda>x. twoC(x, 0)) = (\<lambda>x. (a + (b - a) * x, g2 (a + (b - a) * x)))"
     "(\<lambda>y. twoC(1, y)) = (\<lambda>x. (b, g2 b + x *\<^sub>R (g1 b - g2 b)))"
     "(\<lambda>x. twoC(x, 1)) = (\<lambda>x. (a + (b - a) * x, g1 (a + (b - a) * x)))"
     "(\<lambda>y. twoC(0, y)) = (\<lambda>x. (a, g2 a + x *\<^sub>R (g1 a - g2 a)))"
     using two_cube and typeI_cube_explicit_spec[of"twoC"]  by auto
   have bottom_edge_smooth: "(\<lambda>x. twoC (x, 0)) piecewise_C1_differentiable_on {0..1}"
     using typeI_twoCube_smooth_edges two_cube boundary_def vertical_boundary_def horizontal_boundary_def
     by auto
   have top_edge_smooth: "?top_edge piecewise_C1_differentiable_on {0..1}"
     using typeI_twoCube_smooth_edges two_cube boundary_def vertical_boundary_def horizontal_boundary_def
     by auto
   show "integral (cubeImage twoC) (\<lambda>a. - partial_vector_derivative (\<lambda>p. F p \<bullet> i) j  a) = one_chain_line_integral F {i} (boundary twoC)"
     using Greens_thm_type_I[OF twoCisTypeI(3) twoCisTypeI(7) bottom_edge_smooth
         twoCisTypeI(8) twoCisTypeI(9) top_edge_smooth
         twoCisTypeI(10) f_analytically_valid twoCisTypeI(2) twoCisTypeI(1)]
         line_integral_around_boundary
     by auto
   have "line_integral_exists F {i} (\<lambda>y. twoC (0, y))"
        "line_integral_exists F {i} (\<lambda>x. twoC (x, 1))"
        "line_integral_exists F {i} (\<lambda>y. twoC (1, y))"
        "line_integral_exists F {i} (\<lambda>x. twoC (x, 0))"
     using Greens_thm_type_I[OF twoCisTypeI(3) twoCisTypeI(7) bottom_edge_smooth
         twoCisTypeI(8) twoCisTypeI(9) top_edge_smooth
         twoCisTypeI(10) f_analytically_valid twoCisTypeI(2) twoCisTypeI(1)]
       line_integral_around_boundary
     by auto
   then have "line_integral_exists F {i} \<gamma>" if "(k,\<gamma>) \<in> boundary twoC" for k \<gamma>
     using that  by (auto simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   then show "\<forall>(k,\<gamma>) \<in> boundary twoC. line_integral_exists F {i} \<gamma>" by auto
 qed
 
 lemma line_integral_exists_on_typeI_Cube_boundaries':
   assumes "(k,\<gamma>) \<in> boundary twoC"
   shows "line_integral_exists F {i} \<gamma>"
   using assms two_cube valid_two_cube f_analytically_valid GreenThm_typeI_twoCube(2) by blast
 
 end
 
 locale green_typeI_chain = R2 + 
   fixes F two_chain s
   assumes valid_typeI_div: "valid_typeI_division s two_chain" and
           F_anal_valid: "\<forall>twoC \<in> two_chain. analytically_valid (cubeImage twoC) (\<lambda>x. (F x) \<bullet> i) j"
 begin
 
 lemma two_chain_valid_valid_cubes: "\<forall>two_cube \<in> two_chain. valid_two_cube two_cube" using valid_typeI_div
       by (auto simp add: valid_two_chain_def)
 
 lemma typeI_cube_line_integral_exists_boundary':
   assumes "\<forall>two_cube \<in> two_chain. typeI_twoCube two_cube"
   assumes "\<forall>twoC \<in> two_chain. analytically_valid (cubeImage twoC) (\<lambda>x. (F x) \<bullet> i) j"
   assumes "\<forall>two_cube \<in> two_chain. valid_two_cube two_cube"
   shows "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. line_integral_exists F {i} \<gamma>"
 proof -
   have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {i} \<gamma>"
     using green_typeI_cube.line_integral_exists_on_typeI_Cube_boundaries'[of i j] assms
     using R2_axioms green_typeI_cube_axioms_def green_typeI_cube_def two_chain_boundary_def by fastforce
   then show integ_exis_vert:
     "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. line_integral_exists F {i} \<gamma>"
     by (simp add: two_chain_boundary_def two_chain_vertical_boundary_def boundary_def)
 qed
 
 lemma typeI_cube_line_integral_exists_boundary'':
   "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. line_integral_exists F {i} \<gamma>"
 proof -
   have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {i} \<gamma>"
     using green_typeI_cube.line_integral_exists_on_typeI_Cube_boundaries'[of i j] valid_typeI_div
     apply (simp add: two_chain_boundary_def boundary_def)
     using F_anal_valid R2_axioms green_typeI_cube_axioms_def green_typeI_cube_def two_chain_valid_valid_cubes by fastforce
   then show integ_exis_horiz:
     "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. line_integral_exists F {i} \<gamma>"
     by (simp add: two_chain_boundary_def two_chain_horizontal_boundary_def boundary_def)
 qed
 
 lemma typeI_cube_line_integral_exists_boundary:
   "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {i} \<gamma>"
   using  typeI_cube_line_integral_exists_boundary' typeI_cube_line_integral_exists_boundary''
   apply (auto simp add: two_chain_boundary_def two_chain_horizontal_boundary_def two_chain_vertical_boundary_def)
   by (meson R2_axioms green_typeI_chain.F_anal_valid green_typeI_chain_axioms green_typeI_cube.line_integral_exists_on_typeI_Cube_boundaries' green_typeI_cube_axioms_def green_typeI_cube_def two_chain_valid_valid_cubes valid_typeI_div)
 
 lemma type_I_chain_horiz_bound_valid:
   "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. valid_path \<gamma>"
   using typeI_edges_are_valid_paths valid_typeI_div
   by (force simp add: two_chain_boundary_def two_chain_horizontal_boundary_def boundary_def)
 
 lemma type_I_chain_vert_bound_valid: (*This and the previous one need to be used in all proofs*)
   assumes "\<forall>two_cube \<in> two_chain. typeI_twoCube two_cube"
   shows "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. valid_path \<gamma>"
   using typeI_edges_are_valid_paths assms(1)
   by (force simp add: two_chain_boundary_def two_chain_vertical_boundary_def boundary_def)
 
 lemma members_of_only_vertical_div_line_integrable':
   assumes "only_vertical_division one_chain two_chain"
     "(k::int, \<gamma>)\<in>one_chain"
     "(k::int, \<gamma>)\<in>one_chain"
     "finite two_chain"
   shows "line_integral_exists F {i} \<gamma>"
 proof -
   have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {i} \<gamma>"
     using typeI_cube_line_integral_exists_boundary by blast
   have integ_exis_horiz:
     "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. line_integral_exists F {i} \<gamma>"
     using typeI_cube_line_integral_exists_boundary'' assms by auto
   have valid_paths: "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. valid_path \<gamma>"
     using type_I_chain_vert_bound_valid valid_typeI_div by linarith
   have integ_exis_vert:
     "(\<And>k \<gamma>. (\<exists>(k', \<gamma>')\<in>two_chain_vertical_boundary two_chain. \<exists>a\<in>{0..1}. \<exists>b\<in>{0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>) \<Longrightarrow>
                             line_integral_exists F {i} \<gamma>)"
     using integ_exis valid_paths line_integral_exists_subpath[of "F" "{i}"]
     by (fastforce simp add: two_chain_boundary_def two_chain_horizontal_boundary_def
         two_chain_vertical_boundary_def boundary_def)
   obtain \<H> \<V> where hv_props: "finite \<V>"
         "(\<forall>(k,\<gamma>) \<in> \<V>. (\<exists>(k', \<gamma>') \<in> two_chain_vertical_boundary two_chain.
                         (\<exists>a \<in> {0 .. 1}. \<exists>b \<in> {0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>)))"
         "one_chain = \<H> \<union> \<V>"
         "(common_sudiv_exists (two_chain_horizontal_boundary two_chain) \<H>)
          \<or> common_reparam_exists \<H> (two_chain_horizontal_boundary two_chain)"
         "finite \<H>"
         "boundary_chain \<H>"
         "\<forall>(k,\<gamma>)\<in>\<H>. valid_path \<gamma>"
     using assms(1) unfolding only_vertical_division_def by blast
   have finite_i: "finite {i}" by auto
   show "line_integral_exists F {i} \<gamma>"
   proof(cases "common_sudiv_exists (two_chain_horizontal_boundary two_chain) \<H>")
     case True
     show ?thesis
       using gen_common_subdivision_imp_eq_line_integral(2)[OF True two_chain_horizontal_boundary_is_boundary_chain hv_props(6) integ_exis_horiz finite_two_chain_horizontal_boundary[OF assms(4)] hv_props(5) finite_i]
         integ_exis_vert[of "\<gamma>"] assms(3) case_prod_conv hv_props(2) hv_props(3)
       by fastforce
   next
     case False
     have i: "{i} \<subseteq> Basis" using i_is_x_axis real_pair_basis by auto
     have ii: " \<forall>(k2, \<gamma>2)\<in>two_chain_horizontal_boundary two_chain. \<forall>b\<in>{i}. continuous_on (path_image \<gamma>2) (\<lambda>x. F x \<bullet> b)"
       using assms field_cont_on_typeI_region_cont_on_edges F_anal_valid valid_typeI_div
       by (fastforce simp add: analytically_valid_def two_chain_horizontal_boundary_def boundary_def path_image_def)
     show "line_integral_exists F {i} \<gamma>"
       using common_reparam_exists_imp_eq_line_integral(2)[OF finite_i hv_props(5) finite_two_chain_horizontal_boundary[OF assms(4)] hv_props(6) two_chain_horizontal_boundary_is_boundary_chain ii 
             _ hv_props(7) type_I_chain_horiz_bound_valid]
         integ_exis_vert[of "\<gamma>"] False
         assms(3) hv_props(2-4) by fastforce
   qed
 qed
 
 lemma GreenThm_typeI_two_chain:
    "two_chain_integral two_chain (\<lambda>a. - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j a) = one_chain_line_integral F {i} (two_chain_boundary two_chain)"
 proof (simp add: two_chain_boundary_def one_chain_line_integral_def two_chain_integral_def)
   let ?F_b' = "partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j"
   have all_two_cubes_have_four_distict_edges: "\<forall>twoCube \<in> two_chain. card (boundary twoCube) = 4"
     using valid_typeI_div valid_two_chain_def valid_two_cube_def by auto
   have no_shared_edges_have_similar_orientations:
     "\<forall>twoCube1 \<in> two_chain. \<forall>twoCube2 \<in> two_chain.  twoCube1 \<noteq> twoCube2 \<longrightarrow>
                           boundary twoCube1 \<inter> boundary twoCube2 = {}"
     using valid_typeI_div valid_two_chain_def
     by (auto simp add: pairwise_def)
   have "(\<Sum>(k,g)\<in> boundary twoCube. k * line_integral F {i} g) = integral (cubeImage twoCube) (\<lambda>a. - ?F_b' a)"
         if "twoCube \<in> two_chain" for twoCube
   proof -
     have analytically_val: " analytically_valid (cubeImage twoCube) (\<lambda>x. F x \<bullet> i) j"
       using that F_anal_valid by auto
     show "(\<Sum>(k, g)\<in>boundary twoCube. k * line_integral F {i} g) = integral (cubeImage twoCube) (\<lambda>a. - ?F_b' a)"
       using green_typeI_cube.GreenThm_typeI_twoCube
       apply (simp add: one_chain_line_integral_def)
       by (simp add: R2_axioms analytically_val green_typeI_cube_axioms_def green_typeI_cube_def that two_chain_valid_valid_cubes valid_typeI_div)
   qed
   then have double_sum_eq_sum:
     "(\<Sum>twoCube\<in>(two_chain).(\<Sum>(k,g)\<in> boundary twoCube. k * line_integral F {i} g))
                      =  (\<Sum>twoCube\<in>(two_chain). integral (cubeImage twoCube) (\<lambda>a. - ?F_b' a))"
     using Finite_Cartesian_Product.sum_cong_aux by auto
   have pairwise_disjoint_boundaries: "\<forall>x\<in> (boundary ` two_chain). (\<forall>y\<in> (boundary ` two_chain). (x \<noteq> y \<longrightarrow> (x \<inter> y = {})))"
     using no_shared_edges_have_similar_orientations
     by (force simp add: image_def disjoint_iff_not_equal)
   have finite_boundaries: "\<forall>B \<in> (boundary` two_chain). finite B"
     using all_two_cubes_have_four_distict_edges
     using image_iff by fastforce
   have boundary_inj: "inj_on boundary two_chain"
     using  all_two_cubes_have_four_distict_edges and no_shared_edges_have_similar_orientations
     by (force simp add: inj_on_def)
   have "(\<Sum>x\<in>(\<Union>(boundary` two_chain)). case x of (k, g) \<Rightarrow> k * line_integral F {i} g) 
         = (sum \<circ> sum) (\<lambda>x. case x of (k, g) \<Rightarrow> (k::int) * line_integral F {i} g) (boundary ` two_chain)"
     using sum.Union_disjoint[OF finite_boundaries pairwise_disjoint_boundaries]
     by simp
   also have "... = (\<Sum>twoCube\<in>(two_chain).(\<Sum>(k,g)\<in> boundary twoCube. k * line_integral F {i} g))"
     using sum.reindex[OF boundary_inj, of "\<lambda>x. (\<Sum>(k,g)\<in> x. k * line_integral F {i} g)"]
     by auto
   finally show "(\<Sum>C\<in>two_chain. - integral (cubeImage C) (partial_vector_derivative (\<lambda>x. F x \<bullet> i) j)) = (\<Sum>x\<in>(\<Union>x\<in>two_chain. boundary x). case x of (k, g) \<Rightarrow> real_of_int k * line_integral F {i} g)"
     using double_sum_eq_sum by auto
 qed
 
 lemma GreenThm_typeI_divisible:
   assumes gen_division: "gen_division s (cubeImage ` two_chain)"
   shows "integral s (\<lambda>x. - partial_vector_derivative (\<lambda>a. F(a) \<bullet> i) j x) = one_chain_line_integral F {i} (two_chain_boundary two_chain)"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>a. F(a) \<bullet> i) j"
   have "integral s (\<lambda>x. - ?F_b' x) = two_chain_integral two_chain (\<lambda>a. - ?F_b' a)"
   proof (simp add: two_chain_integral_def)
     have "(\<Sum>f\<in>two_chain. integral (cubeImage f) (partial_vector_derivative (\<lambda>p. F p \<bullet> i) j)) = integral s (partial_vector_derivative (\<lambda>p. F p \<bullet> i) j)"
       by (metis analytically_valid_imp_part_deriv_integrable_on F_anal_valid gen_division two_chain_integral_def two_chain_integral_eq_integral_divisable valid_typeI_div)
     then show "- integral s (partial_vector_derivative (\<lambda>a. F a \<bullet> i) j) = (\<Sum>C\<in>two_chain. - integral (cubeImage C) (partial_vector_derivative (\<lambda>a. F a \<bullet> i) j))"
       by (simp add: sum_negf)
   qed
   then show ?thesis
     using GreenThm_typeI_two_chain assms by auto
 qed
 
 lemma GreenThm_typeI_divisible_region_boundary:
   assumes 
     gen_division: "gen_division s (cubeImage ` two_chain)" and
     two_cubes_trace_horizontal_boundaries:
     "two_chain_horizontal_boundary two_chain \<subseteq> \<gamma>" and
     boundary_of_region_is_subset_of_partition_boundary:
     "\<gamma> \<subseteq> two_chain_boundary two_chain"
   shows "integral s (\<lambda>x. - partial_vector_derivative (\<lambda>a. F(a) \<bullet> i) j x) = one_chain_line_integral F {i} \<gamma>"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>a. F(a) \<bullet> i)"
   have all_two_cubes_have_four_distict_edges: "\<forall>twoCube \<in> two_chain. card (boundary twoCube) = 4"
     using valid_typeI_div valid_two_chain_def valid_two_cube_def by auto
   have no_shared_edges_have_similar_orientations:
     "\<forall>twoCube1 \<in> two_chain. \<forall>twoCube2 \<in> two_chain.
         twoCube1 \<noteq> twoCube2 \<longrightarrow> boundary twoCube1 \<inter> boundary twoCube2 = {}"
     using valid_typeI_div valid_two_chain_def by (auto simp add: pairwise_def)
       (*Proving that line_integral on the x axis is 0 for the vertical 1-cubes*)
   have vert_line_integral_zero:
     "one_chain_line_integral F {i} (two_chain_vertical_boundary two_chain) = 0"
   proof (simp add: one_chain_line_integral_def)
     have "line_integral F {i} (snd oneCube) = 0"
       if oneCube: "oneCube \<in> two_chain_vertical_boundary(two_chain)" for oneCube
     proof -
       obtain x y1 y2 k where vert_edge_def: "oneCube = (k, (\<lambda>t::real. (x::real, (1 - t) * (y2) + t * y1)))"
         using valid_typeI_div oneCube
         by (auto simp add: typeI_twoCube_def two_chain_vertical_boundary_def vertical_boundary_def)
       let ?vert_edge = "(snd oneCube)"
       have vert_edge_x_const: "\<forall>t. (?vert_edge t) \<bullet> i = x"
         by (simp add: i_is_x_axis vert_edge_def)
       have vert_edge_is_straight_path: "?vert_edge = (\<lambda>t. (x, y2 + t * (y1 - y2)))"
         using vert_edge_def Product_Type.snd_conv
         by (auto simp add: mult.commute right_diff_distrib')
       show ?thesis
         by (simp add: i_is_x_axis line_integral_on_pair_straight_path(1) mult.commute straight_path_diffrentiable_x vert_edge_is_straight_path)
     qed
     then show "(\<Sum>x\<in>two_chain_vertical_boundary two_chain. case x of (k, g) \<Rightarrow> k * line_integral F {i} g) = 0"
       using comm_monoid_add_class.sum.neutral by (simp add: prod.case_eq_if)
   qed
     (*then, the x axis line_integral on the boundaries of the twoCube is equal to the line_integral on the horizontal boundaries of the twoCube \<longrightarrow> 1*)
   have boundary_is_finite: "finite (two_chain_boundary two_chain)"
     unfolding two_chain_boundary_def
     by (metis all_two_cubes_have_four_distict_edges card.infinite finite_UN_I finite_imageD 
               gen_division gen_division_def zero_neq_numeral valid_typeI_div valid_two_chain_def)
   have boundary_is_vert_hor: "(two_chain_boundary two_chain) =
                               (two_chain_vertical_boundary two_chain) \<union>
                               (two_chain_horizontal_boundary two_chain)"
   by(auto simp add: two_chain_boundary_def two_chain_vertical_boundary_def two_chain_horizontal_boundary_def
         boundary_def)
   then have hor_vert_finite:
     "finite (two_chain_vertical_boundary two_chain)"
     "finite (two_chain_horizontal_boundary two_chain)"
     using boundary_is_finite by auto
   have horiz_verti_disjoint:
     "(two_chain_vertical_boundary two_chain) \<inter> (two_chain_horizontal_boundary two_chain) = {}"
   proof (simp add: two_chain_vertical_boundary_def two_chain_horizontal_boundary_def horizontal_boundary_def
         vertical_boundary_def)
     show "(\<Union>x\<in>two_chain. {(- 1, \<lambda>y. x (0, y)), (1::int, \<lambda>y. x (1::real, y))}) \<inter> (\<Union>x\<in>two_chain. {(1, \<lambda>z. x (z, 0)), (- 1, \<lambda>z. x (z, 1))}) = {}"
     proof -
       have "{(- 1, \<lambda>y. twoCube (0, y)), (1::int, \<lambda>y. twoCube (1, y))} \<inter>
             {(1, \<lambda>z. twoCube2 (z, 0)), (- 1, \<lambda>z. twoCube2 (z, 1))} = {}"
         if "twoCube\<in>two_chain" "twoCube2\<in>two_chain" for twoCube twoCube2
       proof (cases "twoCube = twoCube2")
         case True
         have "card {(- 1::int, \<lambda>y. twoCube2 (0::real, y)), (1::int, \<lambda>y. twoCube2 (1, y)), (1, \<lambda>x. twoCube2 (x, 0)), (- 1, \<lambda>x. twoCube2 (x, 1))} = 4"
           using all_two_cubes_have_four_distict_edges that(2)
           by (auto simp add: boundary_def vertical_boundary_def horizontal_boundary_def)
         then show ?thesis
           by (auto simp: True card_insert_if split: if_split_asm)
       next
         case False
         then show ?thesis
           using no_shared_edges_have_similar_orientations
           by (simp add: that boundary_def vertical_boundary_def horizontal_boundary_def)
       qed
       then have "\<Union> ((\<lambda>twoCube. {(-1::int, \<lambda>y. twoCube (0,y)), (1, \<lambda>y. twoCube (1, y))}) ` two_chain)
                \<inter> \<Union> ((\<lambda>twoCube. {(1, \<lambda>y. twoCube (y, 0)), (-1, \<lambda>z. twoCube (z, 1))}) ` two_chain) = {}"
         using Complete_Lattices.Union_disjoint by force
       then show ?thesis by force
     qed
   qed
   have "one_chain_line_integral F {i} (two_chain_boundary two_chain)
         = one_chain_line_integral F {i} (two_chain_vertical_boundary two_chain) +
           one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
     using boundary_is_vert_hor horiz_verti_disjoint
     by (auto simp add: one_chain_line_integral_def hor_vert_finite sum.union_disjoint)
   then have x_axis_line_integral_is_only_horizontal:
     "one_chain_line_integral F {i} (two_chain_boundary two_chain)
      = one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
     using vert_line_integral_zero by auto
       (*Since \<gamma> \<subseteq> the boundary of the 2-chain and the horizontal boundaries are \<subseteq> \<gamma>, then there is some \<V> \<subseteq> \<partial>\<^sub>V(2-\<C>) such that \<gamma> = \<V> \<union> \<partial>\<^sub>H(2-\<C>)*)
   have "\<exists>\<V>. \<V> \<subseteq> (two_chain_vertical_boundary two_chain) \<and> \<gamma> = \<V> \<union> (two_chain_horizontal_boundary two_chain)"
   proof
     let ?\<V> = "\<gamma> - (two_chain_horizontal_boundary two_chain)"
     show "?\<V> \<subseteq> two_chain_vertical_boundary two_chain \<and> \<gamma> = ?\<V> \<union> two_chain_horizontal_boundary two_chain"
       using two_cubes_trace_horizontal_boundaries
         boundary_of_region_is_subset_of_partition_boundary boundary_is_vert_hor
       by blast
   qed
   then obtain \<V> where
     v_props: "\<V> \<subseteq> (two_chain_vertical_boundary two_chain)" "\<gamma> = \<V> \<union> (two_chain_horizontal_boundary two_chain)"
     by auto
   have v_horiz_disj: "\<V> \<inter> (two_chain_horizontal_boundary two_chain) = {}"
     using horiz_verti_disjoint v_props(1) by auto
   have v_finite: "finite \<V>"
     using hor_vert_finite v_props(1) Finite_Set.rev_finite_subset by force
   have line_integral_on_path: "one_chain_line_integral F {i} \<gamma> =
                                one_chain_line_integral F {i} \<V> + one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
     by(auto simp add: one_chain_line_integral_def v_props sum.union_disjoint[OF v_finite hor_vert_finite(2) v_horiz_disj])
       (*Since \<V> \<subseteq> \<partial>\<^sub>V(2-\<C>), then the line_integral on the x axis along \<H> is 0, and from 1 Q.E.D. *)
   have "one_chain_line_integral F {i} \<V> = 0"
   proof (simp add: one_chain_line_integral_def)
     have "line_integral F {i} (snd oneCube) = 0"
       if oneCube: "oneCube \<in> two_chain_vertical_boundary(two_chain)" for oneCube
     proof -
       obtain x y1 y2 k where vert_edge_def: "oneCube = (k, (\<lambda>t::real. (x::real, (1 - t) * (y2) + t * y1)))"
         using valid_typeI_div oneCube
         by (auto simp add: typeI_twoCube_def two_chain_vertical_boundary_def vertical_boundary_def)
       let ?vert_edge = "(snd oneCube)"
       have vert_edge_x_const: "\<forall>t. (?vert_edge t) \<bullet> i = x"
         by (simp add: i_is_x_axis vert_edge_def)
       have vert_edge_is_straight_path:
         "?vert_edge = (\<lambda>t. (x, y2 + t * (y1 - y2)))"
         by (auto simp: vert_edge_def algebra_simps)
       have "\<forall>x. ?vert_edge differentiable at x"
         by (metis mult.commute vert_edge_is_straight_path straight_path_diffrentiable_x)
       then show "line_integral F {i} (snd oneCube) = 0"
         using line_integral_on_pair_straight_path(1) vert_edge_x_const by blast
     qed
     then have "\<forall>oneCube \<in> \<V>. line_integral F {i} (snd oneCube) = 0"
       using v_props by auto
     then show "(\<Sum>x\<in>\<V>. case x of (k, g) \<Rightarrow> k * line_integral F {i} g) = 0"
       using comm_monoid_add_class.sum.neutral by (simp add: prod.case_eq_if) 
   qed
   then have "one_chain_line_integral F {i} \<gamma> =
              one_chain_line_integral F {i} (two_chain_boundary two_chain)"
     using x_axis_line_integral_is_only_horizontal by (simp add: line_integral_on_path)
   then show ?thesis
     using assms and GreenThm_typeI_divisible by auto
 qed
 
 lemma GreenThm_typeI_divisible_region_boundary_gen:
   assumes valid_typeI_div: "valid_typeI_division s two_chain" and
     f_analytically_valid: "\<forall>twoC \<in> two_chain. analytically_valid (cubeImage twoC) (\<lambda>a. F(a) \<bullet> i) j" and
     only_vertical_division:
     "only_vertical_division \<gamma> two_chain"
   shows "integral s (\<lambda>x. - partial_vector_derivative (\<lambda>a. F(a) \<bullet> i) j x) = one_chain_line_integral F {i} \<gamma>"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>a. F(a) \<bullet> i)"
   have all_two_cubes_have_four_distict_edges: "\<forall>twoCube \<in> two_chain. card (boundary twoCube) = 4"
     using valid_typeI_div valid_two_chain_def valid_two_cube_def
     by auto
   have no_shared_edges_have_similar_orientations:
     "\<forall>twoCube1 \<in> two_chain. \<forall>twoCube2 \<in> two_chain.
          twoCube1 \<noteq> twoCube2 \<longrightarrow> boundary twoCube1 \<inter> boundary twoCube2 = {}"
     using valid_typeI_div valid_two_chain_def by (auto simp add: pairwise_def)
       (*Proving that line_integral on the x axis is 0 for the vertical 1-cubes*)
   have vert_line_integral_zero:
     "one_chain_line_integral F {i} (two_chain_vertical_boundary two_chain) = 0"
   proof (simp add: one_chain_line_integral_def)
     have "line_integral F {i} (snd oneCube) = 0"
       if oneCube: "oneCube \<in> two_chain_vertical_boundary(two_chain)" for oneCube
     proof -
       obtain x y1 y2 k where vert_edge_def: "oneCube = (k, (\<lambda>t::real. (x::real, (1 - t) * (y2) + t * y1)))"
         using valid_typeI_div oneCube
         by (auto simp add: typeI_twoCube_def two_chain_vertical_boundary_def vertical_boundary_def)
       let ?vert_edge = "(snd oneCube)"
       have vert_edge_x_const: "\<forall>t. (?vert_edge t) \<bullet> i = x"
         by (simp add: i_is_x_axis vert_edge_def)
       have vert_edge_is_straight_path: "?vert_edge = (\<lambda>t. (x, y2 + t * (y1 - y2)))"
         by (auto simp: vert_edge_def algebra_simps)
       show ?thesis
         by (simp add: i_is_x_axis line_integral_on_pair_straight_path(1) mult.commute straight_path_diffrentiable_x vert_edge_is_straight_path)
     qed
     then show "(\<Sum>x\<in>two_chain_vertical_boundary two_chain. case x of (k, g) \<Rightarrow> k * line_integral F {i} g) = 0"
       using comm_monoid_add_class.sum.neutral by (simp add: prod.case_eq_if)
   qed
     (*then, the x axis line_integral on the boundaries of the twoCube is equal to the line_integral on the horizontal boundaries of the twoCube \<longrightarrow> 1*)
   have boundary_is_finite: "finite (two_chain_boundary two_chain)"
     unfolding two_chain_boundary_def
   proof (rule finite_UN_I)
     show "finite two_chain"
       using assms(1) finite_imageD gen_division_def valid_two_chain_def by auto
     show "\<And>a. a \<in> two_chain \<Longrightarrow> finite (boundary a)"
       by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
   qed
   have boundary_is_vert_hor: "two_chain_boundary two_chain =
                               (two_chain_vertical_boundary two_chain) \<union> (two_chain_horizontal_boundary two_chain)"
     by (auto simp add: two_chain_boundary_def two_chain_vertical_boundary_def two_chain_horizontal_boundary_def boundary_def)
   then have hor_vert_finite:
     "finite (two_chain_vertical_boundary two_chain)"
     "finite (two_chain_horizontal_boundary two_chain)"
     using boundary_is_finite by auto
   have horiz_verti_disjoint:
     "(two_chain_vertical_boundary two_chain) \<inter> (two_chain_horizontal_boundary two_chain) = {}"
   proof (simp add: two_chain_vertical_boundary_def two_chain_horizontal_boundary_def horizontal_boundary_def
         vertical_boundary_def)
     show "(\<Union>x\<in>two_chain. {(- 1, \<lambda>y. x (0, y)), (1::int, \<lambda>y. x (1::real, y))}) 
         \<inter> (\<Union>x\<in>two_chain. {(1, \<lambda>y. x (y, 0)), (- 1, \<lambda>y. x (y, 1))}) = {}"
     proof -
       have "{(- 1, \<lambda>y. twoCube (0, y)), (1::int, \<lambda>y. twoCube (1, y))} \<inter>
             {(1, \<lambda>y. twoCube2 (y, 0)), (- 1, \<lambda>y. twoCube2 (y, 1))} = {}"
         if "twoCube \<in> two_chain" "twoCube2 \<in> two_chain" for twoCube twoCube2
       proof (cases "twoCube = twoCube2")
         case True
         have "card {(- 1::int, \<lambda>y. twoCube2 (0, y)), (1::int, \<lambda>y. twoCube2 (1, y)), (1, \<lambda>x. twoCube2 (x, 0)), (- 1, \<lambda>x. twoCube2 (x, 1))} = 4"
           using all_two_cubes_have_four_distict_edges that(2)
           by (auto simp add: boundary_def vertical_boundary_def horizontal_boundary_def)
         then show ?thesis
           by (auto simp: card_insert_if True split: if_split_asm)
       next
         case False
         then show ?thesis
           using no_shared_edges_have_similar_orientations
           by (simp add: that boundary_def vertical_boundary_def horizontal_boundary_def)
       qed
       then have "\<Union> ((\<lambda>twoCube. {(- 1, \<lambda>y. twoCube (0, y)), (1, \<lambda>y. twoCube (1, y))}) ` two_chain)
                \<inter> \<Union> ((\<lambda>twoCube. {(1::int, \<lambda>y. twoCube (y, 0)), (- 1, \<lambda>y. twoCube (y, 1))}) ` two_chain)
                  = {}"
         using Complete_Lattices.Union_disjoint by force
       then show ?thesis by force
     qed
   qed
   have "one_chain_line_integral F {i} (two_chain_boundary two_chain)
          = one_chain_line_integral F {i} (two_chain_vertical_boundary two_chain) +
            one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
     using boundary_is_vert_hor horiz_verti_disjoint
     by (auto simp add: one_chain_line_integral_def hor_vert_finite sum.union_disjoint)
   then have x_axis_line_integral_is_only_horizontal:
     "one_chain_line_integral F {i} (two_chain_boundary two_chain)
      = one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
     using vert_line_integral_zero by auto
       (*Since \<gamma> \<subseteq> the boundary of the 2-chain and the horizontal boundaries are \<subseteq> \<gamma>, then there is some \<V> \<subseteq> \<partial>\<^sub>V(2-\<C>) such that \<gamma> = \<V> \<union> \<partial>\<^sub>H(2-\<C>)*)
   obtain \<H> \<V> where hv_props: "finite \<V>"
     "(\<forall>(k,\<gamma>) \<in> \<V>. (\<exists>(k', \<gamma>') \<in> two_chain_vertical_boundary two_chain.
         (\<exists>a \<in> {0 .. 1}. \<exists>b \<in> {0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>)))" "\<gamma> = \<H> \<union> \<V>"
     "(common_sudiv_exists (two_chain_horizontal_boundary two_chain) \<H>)
      \<or> common_reparam_exists \<H> (two_chain_horizontal_boundary two_chain)"
     "finite \<H>"
     "boundary_chain \<H>"
     "\<forall>(k,\<gamma>)\<in>\<H>. valid_path \<gamma>"
     using only_vertical_division by (auto simp add:  only_vertical_division_def)
   have "finite {i}" by auto
   then have eq_integrals: " one_chain_line_integral F {i} \<H> = one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
   proof(cases "common_sudiv_exists (two_chain_horizontal_boundary two_chain) \<H>")
     case True
     then show ?thesis
       using gen_common_subdivision_imp_eq_line_integral(1)[OF True two_chain_horizontal_boundary_is_boundary_chain hv_props(6) _ hor_vert_finite(2) hv_props(5)]
         typeI_cube_line_integral_exists_boundary''
       by force
   next
     case False
     have integ_exis_horiz:
       "\<forall>(k,\<gamma>) \<in> two_chain_horizontal_boundary two_chain. line_integral_exists F {i} \<gamma>"
       using typeI_cube_line_integral_exists_boundary'' assms
       by (fastforce simp add: valid_two_chain_def)
     have integ_exis: "\<forall>(k,\<gamma>) \<in> two_chain_boundary two_chain. line_integral_exists F {i} \<gamma>"
       using typeI_cube_line_integral_exists_boundary by blast
     have valid_paths: "\<forall>(k,\<gamma>) \<in> two_chain_vertical_boundary two_chain. valid_path \<gamma>"
       using typeI_edges_are_valid_paths assms
       by (fastforce simp add: two_chain_boundary_def two_chain_vertical_boundary_def boundary_def)
     have integ_exis_vert:
       "(\<And>k \<gamma>. (\<exists>(k', \<gamma>') \<in> two_chain_vertical_boundary two_chain. \<exists>a\<in>{0..1}. \<exists>b\<in>{0..1}. a \<le> b \<and> subpath a b \<gamma>' = \<gamma>) \<Longrightarrow>
                                     line_integral_exists F {i} \<gamma>)"
       using integ_exis valid_paths line_integral_exists_subpath[of "F" "{i}"]
       by (fastforce simp add: two_chain_boundary_def two_chain_vertical_boundary_def
           two_chain_horizontal_boundary_def boundary_def)
     have finite_i: "finite {i}" by auto
     have i: "{i} \<subseteq> Basis" using i_is_x_axis real_pair_basis by auto
     have ii: " \<forall>(k2, \<gamma>2)\<in>two_chain_horizontal_boundary two_chain. \<forall>b\<in>{i}. continuous_on (path_image \<gamma>2) (\<lambda>x. F x \<bullet> b)"
       using assms(1) field_cont_on_typeI_region_cont_on_edges assms(2)
       by (fastforce simp add: analytically_valid_def two_chain_horizontal_boundary_def boundary_def path_image_def)
     have *: "common_reparam_exists \<H> (two_chain_horizontal_boundary two_chain)"
       using hv_props(4) False by auto
     show "one_chain_line_integral F {i} \<H> = one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
       using common_reparam_exists_imp_eq_line_integral(1)[OF finite_i hv_props(5) hor_vert_finite(2) hv_props(6) two_chain_horizontal_boundary_is_boundary_chain ii * hv_props(7) type_I_chain_horiz_bound_valid]
       by fastforce
   qed
     (*Since \<V> \<subseteq> \<partial>\<^sub>H(2-\<C>), then the line_integral on the x axis along \<V> is 0, and from 1 Q.E.D. *)
   have line_integral_on_path:
     "one_chain_line_integral F {i} \<gamma> =
      one_chain_line_integral F {i} (two_chain_horizontal_boundary two_chain)"
   proof (auto simp add: one_chain_line_integral_def)
     have "line_integral F {i} (snd oneCube) = 0" if oneCube: "oneCube \<in> \<V>" for oneCube
     proof -
       obtain k \<gamma> where k_gamma: "(k,\<gamma>) = oneCube"
         by (metis coeff_cube_to_path.cases)
       then obtain k' \<gamma>' a b where kp_gammap:
         "(k'::int, \<gamma>') \<in> two_chain_vertical_boundary two_chain"
         "a \<in> {0 .. 1}"
         "b \<in> {0..1}"
         "subpath a b \<gamma>' = \<gamma>"
         using hv_props oneCube
         by (smt case_prodE split_conv)
       obtain x y1 y2 where vert_edge_def: "(k',\<gamma>') = (k', (\<lambda>t::real. (x::real, (1 - t) * (y2) + t * y1)))"
         using valid_typeI_div kp_gammap
         by (auto simp add: typeI_twoCube_def two_chain_vertical_boundary_def vertical_boundary_def)
       have vert_edge_x_const: "\<forall>t. \<gamma> (t) \<bullet> i = x"
         by (metis (no_types, lifting) Pair_inject fstI i_is_x_axis inner_Pair_0(2) kp_gammap(4) real_inner_1_right subpath_def vert_edge_def)
       have "\<gamma> = (\<lambda>t::real. (x::real, (1 - (b - a)*t - a) * (y2) + ((b-a)*t + a) * y1))"
         using vert_edge_def Product_Type.snd_conv Product_Type.fst_conv kp_gammap(4)
         by (simp add: subpath_def diff_diff_eq[symmetric])
       also have "... = (\<lambda>t::real. (x::real, (1*y2 - a*y2) +  a*y1 + ((b-a)*y1 - (b - a)*y2)*t))"
         by (simp add: algebra_simps)
       finally have vert_edge_is_straight_path:
         "\<gamma> = (\<lambda>t::real. (x::real, (1*y2 - a*y2) +  a*y1 + ((b-a)*y1 - (b - a)*y2)*t))" .
       show "line_integral F {i} (snd oneCube) = 0"
       proof -
         have "\<forall>x. \<gamma> differentiable at x"
           by (simp add: straight_path_diffrentiable_x vert_edge_is_straight_path)
         then have "line_integral F {i} \<gamma> = 0"
           using line_integral_on_pair_straight_path(1) vert_edge_x_const by blast
         then show ?thesis
           using Product_Type.snd_conv k_gamma by auto
       qed
     qed
     then have "\<forall>x\<in>\<V>. (case x of (k, g) \<Rightarrow> (k::int) * line_integral F {i} g) = 0"
       by auto
     then show "(\<Sum>x\<in>\<gamma>. case x of (k, g) \<Rightarrow> real_of_int k * line_integral F {i} g) =
                (\<Sum>x\<in>two_chain_horizontal_boundary two_chain. case x of (k, g) \<Rightarrow> of_int k * line_integral F {i} g)"
       using hv_props(1) hv_props(3) hv_props(5) sum_zero_set hor_vert_finite(2) eq_integrals
       apply(auto simp add: one_chain_line_integral_def)
       by (smt Un_commute sum_zero_set)
   qed
   then have "one_chain_line_integral F {i} \<gamma> =
              one_chain_line_integral F {i} (two_chain_boundary two_chain)"
     using x_axis_line_integral_is_only_horizontal line_integral_on_path by auto
   then show ?thesis
     using assms GreenThm_typeI_divisible by auto
 qed
 
 end
 
 locale green_typeI_typeII_chain = R2: R2 i j + T1: green_typeI_chain i j F two_chain_typeI + T2: green_typeII_chain i j F two_chain_typeII for i j F two_chain_typeI two_chain_typeII
 begin
 
 lemma GreenThm_typeI_typeII_divisible_region_boundary:
   assumes 
     gen_divisions: "gen_division s (cubeImage ` two_chain_typeI)"
     "gen_division s (cubeImage ` two_chain_typeII)" and
     typeI_two_cubes_trace_horizontal_boundaries:
     "two_chain_horizontal_boundary two_chain_typeI \<subseteq> \<gamma>" and
     typeII_two_cubes_trace_vertical_boundaries:
     "two_chain_vertical_boundary two_chain_typeII \<subseteq> \<gamma>" and
     boundary_of_region_is_subset_of_partition_boundaries:
     "\<gamma> \<subseteq> two_chain_boundary two_chain_typeI"
     "\<gamma> \<subseteq> two_chain_boundary two_chain_typeII"
   shows "integral s (\<lambda>x. partial_vector_derivative (\<lambda>a. F a \<bullet> j) i x - partial_vector_derivative (\<lambda>a. F a \<bullet> i) j x)
          = one_chain_line_integral F {i, j} \<gamma>"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>a. F a \<bullet> i) j"
   let ?F_a' = "partial_vector_derivative (\<lambda>a. F a \<bullet> j) i"
   have typeI_regions_integral: "integral s (\<lambda>x. - partial_vector_derivative (\<lambda>a. F a \<bullet> i) j x) = one_chain_line_integral F {i} \<gamma>"
     using T1.GreenThm_typeI_divisible_region_boundary
         gen_divisions(1) typeI_two_cubes_trace_horizontal_boundaries
         boundary_of_region_is_subset_of_partition_boundaries(1)
     by blast
   have typeII_regions_integral: "integral s (partial_vector_derivative (\<lambda>x. F x \<bullet> j) i) = one_chain_line_integral F {j} \<gamma>"
     using T2.GreenThm_typeII_divisible_region_boundary gen_divisions(2)
          typeII_two_cubes_trace_vertical_boundaries
         boundary_of_region_is_subset_of_partition_boundaries(2)
     by auto
   have integral_dis: "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = integral s (\<lambda>x. ?F_a' x) + integral s (\<lambda>x. - ?F_b' x)"
   proof -
     have "\<forall>twoCube \<in> two_chain_typeII. (?F_a' has_integral integral (cubeImage twoCube) ?F_a') (cubeImage twoCube)"
       by (simp add: analytically_valid_imp_part_deriv_integrable_on T2.F_anal_valid has_integral_iff)
     then have "\<And>u. u \<in> (cubeImage ` two_chain_typeII) \<Longrightarrow> (?F_a' has_integral integral u ?F_a') u"
       by auto
     then have "(?F_a' has_integral (\<Sum>img\<in>cubeImage ` two_chain_typeII. integral img ?F_a')) s"
       using gen_divisions(2) unfolding gen_division_def
       by (metis has_integral_Union)
     then have F_a'_integrable: "(?F_a' integrable_on s)" by auto
     have "\<forall>twoCube \<in> two_chain_typeI. (?F_b' has_integral integral (cubeImage twoCube) ?F_b') (cubeImage twoCube)"
       using analytically_valid_imp_part_deriv_integrable_on T1.F_anal_valid by blast
     then have "\<And>u. u \<in> (cubeImage ` two_chain_typeI) \<Longrightarrow> (?F_b' has_integral integral u ?F_b') u"
       by auto
     then have "(?F_b' has_integral (\<Sum>img\<in>cubeImage ` two_chain_typeI. integral img ?F_b')) s"
       using gen_divisions(1) unfolding gen_division_def
       by (metis has_integral_Union)
     then show ?thesis
       by (simp add: F_a'_integrable Henstock_Kurzweil_Integration.integral_diff has_integral_iff)
   qed
   have line_integral_dist: "one_chain_line_integral F {i, j} \<gamma> = one_chain_line_integral F {i} \<gamma> + one_chain_line_integral F {j} \<gamma>"
   proof (simp add: one_chain_line_integral_def)
     have "k * line_integral F {i, j} g = k * line_integral F {i} g +  k * line_integral F {j} g"
       if kg: "(k,g) \<in> \<gamma>" for k g
     proof -
       obtain twoCube_typeI where twoCube_typeI_props:
         "twoCube_typeI \<in> two_chain_typeI"
         "(k, g) \<in> boundary twoCube_typeI"
         "typeI_twoCube twoCube_typeI"
         "continuous_on (cubeImage twoCube_typeI) (\<lambda>x. F(x) \<bullet> i)"
         using boundary_of_region_is_subset_of_partition_boundaries(1) two_chain_boundary_def T1.valid_typeI_div
           T1.F_anal_valid kg
         by (auto simp add: analytically_valid_def)
       obtain twoCube_typeII where twoCube_typeII_props:
         "twoCube_typeII \<in> two_chain_typeII"
         "(k, g) \<in> boundary twoCube_typeII"
         "typeII_twoCube twoCube_typeII"
         "continuous_on (cubeImage twoCube_typeII) (\<lambda>x. F(x) \<bullet> j)"
         using boundary_of_region_is_subset_of_partition_boundaries(2) two_chain_boundary_def T2.valid_typeII_div
           kg T2.F_anal_valid
         by (auto simp add: analytically_valid_def)
       have "line_integral F {i, j} g = line_integral F {i} g + line_integral F {j} g"
       proof -
         have int_exists_i: "line_integral_exists F {i} g"
           using T1.typeI_cube_line_integral_exists_boundary assms kg
           by (auto simp add: valid_two_chain_def)
         have int_exists_j: "line_integral_exists F {j} g"
           using T2.typeII_cube_line_integral_exists_boundary assms kg
           by (auto simp add: valid_two_chain_def)
         have finite: "finite {i, j}" by auto
         show ?thesis
           using line_integral_sum_gen[OF finite int_exists_i int_exists_j] R2.i_is_x_axis R2.j_is_y_axis
           by auto
       qed
       then show "k * line_integral F {i, j} g = k * line_integral F {i} g + k * line_integral F {j} g"
         by (simp add: distrib_left)
     qed
     then have line_integral_distrib: 
           "(\<Sum>(k,g)\<in>\<gamma>. k * line_integral F {i, j} g) =
            (\<Sum>(k,g)\<in>\<gamma>. k * line_integral F {i} g +  k * line_integral F {j} g)"
       by (force intro: sum.cong split_cong)
     have "(\<lambda>x. (case x of (k, g) \<Rightarrow> (k::int) * line_integral F {i} g) + (case x of (k, g) \<Rightarrow> (k::int) * line_integral F {j} g)) =
                                      (\<lambda>x. (case x of (k, g) \<Rightarrow> (k * line_integral F {i} g) +  (k::int) * line_integral F {j} g))"
       using comm_monoid_add_class.sum.distrib by auto
     then show "(\<Sum>(k, g)\<in>\<gamma>. k * line_integral F {i, j} g) =
           (\<Sum>(k, g)\<in>\<gamma>. (k::int) * line_integral F {i} g) + (\<Sum>(k, g)\<in>\<gamma>. (k::int) * line_integral F {j} g)"
       using comm_monoid_add_class.sum.distrib[of "(\<lambda>(k, g).  k * line_integral F {i} g)" "(\<lambda>(k, g).  k * line_integral F {j} g)" \<gamma>]
         line_integral_distrib
       by presburger
   qed
   show ?thesis
     using integral_dis line_integral_dist typeI_regions_integral typeII_regions_integral
     by auto
 qed
 
 lemma GreenThm_typeI_typeII_divisible_region':
   assumes 
     only_vertical_division:
     "only_vertical_division one_chain_typeI two_chain_typeI"
     "boundary_chain one_chain_typeI" and
     only_horizontal_division:
     "only_horizontal_division one_chain_typeII two_chain_typeII"
     "boundary_chain one_chain_typeII" and
     typeI_and_typII_one_chains_have_gen_common_subdiv:
     "common_sudiv_exists one_chain_typeI one_chain_typeII"
   shows "integral s (\<lambda>x. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i x - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j x) = one_chain_line_integral F {i, j} one_chain_typeI"
     "integral s (\<lambda>x. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i x - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j x) = one_chain_line_integral F {i, j} one_chain_typeII"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j"
   let ?F_a' = "partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i"
   have one_chain_i_integrals:
     "one_chain_line_integral F {i} one_chain_typeI = one_chain_line_integral F {i} one_chain_typeII \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeI. line_integral_exists F {i} \<gamma>) \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeII. line_integral_exists F {i} \<gamma>)"
   proof (intro conjI)
     have "finite two_chain_typeI"
       using T1.valid_typeI_div finite_image_iff
       by (auto simp add: gen_division_def valid_two_chain_def)
     then show ii: "\<forall>(k, \<gamma>)\<in>one_chain_typeI. line_integral_exists F {i} \<gamma>"
       using T1.members_of_only_vertical_div_line_integrable' assms 
       by fastforce
     have "finite (two_chain_horizontal_boundary two_chain_typeI)"
       by (meson T1.valid_typeI_div finite_imageD finite_two_chain_horizontal_boundary gen_division_def valid_two_chain_def)
     then have "finite one_chain_typeI"
       using only_vertical_division(1) only_vertical_division_def by auto
     moreover have "finite one_chain_typeII"
       using only_horizontal_division(1) only_horizontal_division_def by auto
     ultimately show "one_chain_line_integral F {i} one_chain_typeI = one_chain_line_integral F {i} one_chain_typeII"
                and "\<forall>(k, \<gamma>)\<in>one_chain_typeII. line_integral_exists F {i} \<gamma>"
       using gen_common_subdivision_imp_eq_line_integral[OF typeI_and_typII_one_chains_have_gen_common_subdiv
           only_vertical_division(2) only_horizontal_division(2)] ii 
       by auto
   qed
   have one_chain_j_integrals:
     "one_chain_line_integral F {j} one_chain_typeII = one_chain_line_integral F {j} one_chain_typeI \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeII. line_integral_exists F {j} \<gamma>) \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeI. line_integral_exists F {j} \<gamma>)"
   proof (intro conjI)
     have "finite two_chain_typeII"
       using T2.valid_typeII_div finite_image_iff
       by (auto simp add: gen_division_def valid_two_chain_def)
     then show ii: "\<forall>(k,\<gamma>)\<in>one_chain_typeII. line_integral_exists F {j} \<gamma>"
       using T2.members_of_only_horiz_div_line_integrable' assms T2.two_chain_valid_valid_cubes by blast
     have typeII_and_typI_one_chains_have_common_subdiv: "common_sudiv_exists one_chain_typeII one_chain_typeI"
       by (simp add: common_sudiv_exists_comm typeI_and_typII_one_chains_have_gen_common_subdiv)
     have iv: "finite one_chain_typeI"
       using only_vertical_division(1) only_vertical_division_def by auto
     moreover have iv': "finite one_chain_typeII"
       using only_horizontal_division(1) only_horizontal_division_def by auto
     ultimately show "one_chain_line_integral F {j} one_chain_typeII =
                      one_chain_line_integral F {j} one_chain_typeI"
                     "\<forall>(k, \<gamma>)\<in>one_chain_typeI. line_integral_exists F {j} \<gamma>"
       using gen_common_subdivision_imp_eq_line_integral[OF typeII_and_typI_one_chains_have_common_subdiv
           only_horizontal_division(2) only_vertical_division(2) ii] ii 
       by auto
   qed
   have typeI_regions_integral:
     "integral s (\<lambda>x. - ?F_b' x) = one_chain_line_integral F {i} one_chain_typeI"
     using T1.GreenThm_typeI_divisible_region_boundary_gen T1.valid_typeI_div
           T1.F_anal_valid  only_vertical_division(1)
     by auto
   have typeII_regions_integral:
     "integral s ?F_a' = one_chain_line_integral F {j} one_chain_typeII"
     using T2.GreenThm_typeII_divisible_region_boundary_gen T2.valid_typeII_div
         T2.F_anal_valid  only_horizontal_division(1)
     by auto
   have line_integral_dist:
     "one_chain_line_integral F {i, j} one_chain_typeI = one_chain_line_integral F {i} one_chain_typeI + one_chain_line_integral F {j} one_chain_typeI \<and>
      one_chain_line_integral F {i, j} one_chain_typeII = one_chain_line_integral F {i} one_chain_typeII + one_chain_line_integral F {j} one_chain_typeII"
   proof (simp add: one_chain_line_integral_def)
     have line_integral_distrib:
       "(\<Sum>(k,g)\<in>one_chain_typeI. k * line_integral F {i, j} g) =
        (\<Sum>(k,g)\<in>one_chain_typeI. k * line_integral F {i} g +  k * line_integral F {j} g) \<and>
        (\<Sum>(k,g)\<in>one_chain_typeII. k * line_integral F {i, j} g) =
        (\<Sum>(k,g)\<in>one_chain_typeII. k * line_integral F {i} g +  k * line_integral F {j} g)"
     proof -
       have 0: "k * line_integral F {i, j} g = k * line_integral F {i} g +  k * line_integral F {j} g"
         if  "(k,g) \<in> one_chain_typeII" for k g
       proof -
         have "line_integral_exists F {i} g" "line_integral_exists F {j} g" "finite {i, j}"
           using one_chain_i_integrals one_chain_j_integrals that by fastforce+
         moreover have "{i} \<inter> {j} = {}"
           by (simp add: R2.i_is_x_axis R2.j_is_y_axis)
         ultimately have "line_integral F {i, j} g = line_integral F {i} g + line_integral F {j} g"
           by (metis insert_is_Un line_integral_sum_gen(1))
         then show "k * line_integral F {i, j} g = k * line_integral F {i} g + k * line_integral F {j} g"
           by (simp add: distrib_left)
       qed
       have "k * line_integral F {i, j} g = k * line_integral F {i} g +  k * line_integral F {j} g"
         if "(k,g) \<in> one_chain_typeI" for k g
       proof -
         have "line_integral F {i, j} g = line_integral F {i} g + line_integral F {j} g"
           by (smt that disjoint_insert(2) finite.emptyI finite.insertI R2.i_is_x_axis inf_bot_right insert_absorb insert_commute insert_is_Un R2.j_is_y_axis line_integral_sum_gen(1) one_chain_i_integrals one_chain_j_integrals prod.case_eq_if singleton_inject snd_conv)
         then show "k * line_integral F {i, j} g = k * line_integral F {i} g + k * line_integral F {j} g"
           by (simp add: distrib_left)
       qed
       then show ?thesis
         using 0 by (smt sum.cong split_cong)
     qed
     show "(\<Sum>(k::int, g)\<in>one_chain_typeI. k * line_integral F {i, j} g) =
           (\<Sum>(k, g)\<in>one_chain_typeI. k * line_integral F {i} g) + (\<Sum>(k::int, g)\<in>one_chain_typeI. k * line_integral F {j} g) \<and>
           (\<Sum>(k::int, g)\<in>one_chain_typeII. k * line_integral F {i, j} g) =
           (\<Sum>(k, g)\<in>one_chain_typeII. k * line_integral F {i} g) + (\<Sum>(k::int, g)\<in>one_chain_typeII. k * line_integral F {j} g)"
     proof -
       have 0: "(\<lambda>x. (case x of (k::int, g) \<Rightarrow> k * line_integral F {i} g) + (case x of (k::int, g) \<Rightarrow> k * line_integral F {j} g)) =
                                   (\<lambda>x. (case x of (k::int, g) \<Rightarrow> (k * line_integral F {i} g) +  k * line_integral F {j} g))"
         using comm_monoid_add_class.sum.distrib by auto
       then have 1: "(\<Sum>x\<in>one_chain_typeI. (case x of (k::int, g) \<Rightarrow> k * line_integral F {i} g) + (case x of (k::int, g) \<Rightarrow> k * line_integral F {j} g)) =
                     (\<Sum>x\<in>one_chain_typeI. (case x of (k::int, g) \<Rightarrow>( k * line_integral F {i} g + k * line_integral F {j} g)))"
         by presburger
       have "(\<Sum>x\<in>one_chain_typeII. (case x of (k, g) \<Rightarrow> k * line_integral F {i} g) + (case x of (k, g) \<Rightarrow> k * line_integral F {j} g)) =
             (\<Sum>x\<in>one_chain_typeII. (case x of (k, g) \<Rightarrow>( k * line_integral F {i} g + k * line_integral F {j} g)))"
         using 0 by presburger
       then show ?thesis
         using sum.distrib[of "(\<lambda>(k, g).  k * line_integral F {i} g)" "(\<lambda>(k, g).  k * line_integral F {j} g)" "one_chain_typeI"]
           sum.distrib[of "(\<lambda>(k, g).  k * line_integral F {i} g)" "(\<lambda>(k, g).  k * line_integral F {j} g)" "one_chain_typeII"]
           line_integral_distrib 1
         by auto
     qed
   qed
   have integral_dis: "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = integral s (\<lambda>x. ?F_a' x) + integral s (\<lambda>x. - ?F_b' x)"
   proof -
     have "(?F_a' has_integral integral (cubeImage twoCube) ?F_a') (cubeImage twoCube)"
       if "twoCube \<in> two_chain_typeII" for twoCube
       by (simp add: analytically_valid_imp_part_deriv_integrable_on T2.F_anal_valid has_integral_integrable_integral that)
     then have "\<And>u. u \<in> (cubeImage ` two_chain_typeII) \<Longrightarrow> (?F_a' has_integral integral u ?F_a') u"
       by auto
     then have "(?F_a' has_integral (\<Sum>img\<in>cubeImage ` two_chain_typeII. integral img ?F_a')) s"
       using T2.valid_typeII_div unfolding gen_division_def
       by (metis has_integral_Union)
     then have F_a'_integrable:
       "(?F_a' integrable_on s)" by auto
     have "\<forall>twoCube \<in> two_chain_typeI. (?F_b' has_integral integral (cubeImage twoCube) ?F_b') (cubeImage twoCube)"
       using analytically_valid_imp_part_deriv_integrable_on T1.F_anal_valid by blast
     then have "\<And>u. u \<in> (cubeImage ` two_chain_typeI) \<Longrightarrow> (?F_b' has_integral integral u ?F_b') u"
       by auto
     then have "(?F_b' has_integral (\<Sum>img\<in>cubeImage ` two_chain_typeI. integral img ?F_b')) s"
       using T1.valid_typeI_div unfolding gen_division_def
       by (metis has_integral_Union)
     then show ?thesis
       by (simp add: F_a'_integrable Henstock_Kurzweil_Integration.integral_diff has_integral_iff)
   qed
   show "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = one_chain_line_integral F {i, j} one_chain_typeI"
     using one_chain_j_integrals integral_dis line_integral_dist typeI_regions_integral typeII_regions_integral
     by auto
   show "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = one_chain_line_integral F {i, j} one_chain_typeII"
     using one_chain_i_integrals integral_dis line_integral_dist typeI_regions_integral typeII_regions_integral
     by auto
 qed
 
 lemma GreenThm_typeI_typeII_divisible_region:
   assumes only_vertical_division:
     "only_vertical_division one_chain_typeI two_chain_typeI"
     "boundary_chain one_chain_typeI" and
     only_horizontal_division:
     "only_horizontal_division one_chain_typeII two_chain_typeII"
     "boundary_chain one_chain_typeII" and
     typeI_and_typII_one_chains_have_common_subdiv:
     "common_boundary_sudivision_exists one_chain_typeI one_chain_typeII"
   shows "integral s (\<lambda>x. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i x - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j x) = one_chain_line_integral F {i, j} one_chain_typeI"
     "integral s (\<lambda>x. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i x - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j x) = one_chain_line_integral F {i, j} one_chain_typeII"
   using GreenThm_typeI_typeII_divisible_region' only_vertical_division only_horizontal_division common_subdiv_imp_gen_common_subdiv[OF typeI_and_typII_one_chains_have_common_subdiv]
   by auto
 
 lemma GreenThm_typeI_typeII_divisible_region_finite_holes:
   assumes valid_cube_boundary: "\<forall>(k,\<gamma>)\<in>boundary C. valid_path \<gamma>" and
     only_vertical_division:
     "only_vertical_division (boundary C) two_chain_typeI" and
     only_horizontal_division:
     "only_horizontal_division (boundary C) two_chain_typeII" and
     s_is_oneCube: "s = cubeImage C"
   shows "integral (cubeImage C) (\<lambda>x. partial_vector_derivative (\<lambda>x. F x \<bullet> j) i x - partial_vector_derivative (\<lambda>x. F x \<bullet> i) j x) =
                      one_chain_line_integral F {i, j} (boundary C)"
   using GreenThm_typeI_typeII_divisible_region[OF only_vertical_division
       two_cube_boundary_is_boundary only_horizontal_division two_cube_boundary_is_boundary
       common_boundary_subdiv_exists_refl[OF assms(1)]] s_is_oneCube
   by auto
 
 lemma GreenThm_typeI_typeII_divisible_region_equivallent_boundary:
   assumes 
     gen_divisions: "gen_division s (cubeImage ` two_chain_typeI)"
     "gen_division s (cubeImage ` two_chain_typeII)" and
     typeI_two_cubes_trace_horizontal_boundaries:
     "two_chain_horizontal_boundary two_chain_typeI \<subseteq> one_chain_typeI" and
     typeII_two_cubes_trace_vertical_boundaries:
     "two_chain_vertical_boundary two_chain_typeII \<subseteq> one_chain_typeII" and
     boundary_of_region_is_subset_of_partition_boundaries:
     "one_chain_typeI \<subseteq> two_chain_boundary two_chain_typeI"
     "one_chain_typeII \<subseteq> two_chain_boundary two_chain_typeII" and
     typeI_and_typII_one_chains_have_common_subdiv:
     "common_boundary_sudivision_exists one_chain_typeI one_chain_typeII"
   shows "integral s (\<lambda>x. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i x - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j x) = one_chain_line_integral F {i, j} one_chain_typeI"
     "integral s (\<lambda>x. partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i x - partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j x) = one_chain_line_integral F {i, j} one_chain_typeII"
 proof -
   let ?F_b' = "partial_vector_derivative (\<lambda>x. (F x) \<bullet> i) j"
   let ?F_a' = "partial_vector_derivative (\<lambda>x. (F x) \<bullet> j) i"
   have one_chain_i_integrals:
     "one_chain_line_integral F {i} one_chain_typeI = one_chain_line_integral F {i} one_chain_typeII \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeI. line_integral_exists F {i} \<gamma>) \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeII. line_integral_exists F {i} \<gamma>)"
   proof (intro conjI)
     have i: "boundary_chain one_chain_typeI"
       using two_chain_boundary_is_boundary_chain boundary_chain_def
         boundary_of_region_is_subset_of_partition_boundaries(1)
       by blast
     have i': "boundary_chain one_chain_typeII"
       using two_chain_boundary_is_boundary_chain boundary_chain_def
         boundary_of_region_is_subset_of_partition_boundaries(2)
       by blast
     have "\<And>k \<gamma>. (k,\<gamma>)\<in>one_chain_typeI \<Longrightarrow> line_integral_exists F {i} \<gamma>"
       using T1.typeI_cube_line_integral_exists_boundary assms
       by (fastforce simp add: valid_two_chain_def)
     then show ii: "\<forall>(k,\<gamma>)\<in>one_chain_typeI. line_integral_exists F {i} \<gamma>" by auto
     have "finite (two_chain_boundary two_chain_typeI)"
       unfolding two_chain_boundary_def
     proof (rule finite_UN_I)
       show "finite two_chain_typeI"
         using T1.valid_typeI_div finite_imageD gen_division_def valid_two_chain_def by auto
       show "\<And>a. a \<in> two_chain_typeI \<Longrightarrow> finite (boundary a)"
         by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
     qed
     then have "finite one_chain_typeI"
       using boundary_of_region_is_subset_of_partition_boundaries(1) finite_subset by fastforce
     moreover have "finite (two_chain_boundary two_chain_typeII)"
       unfolding two_chain_boundary_def
     proof (rule finite_UN_I)
       show "finite two_chain_typeII"
         using T2.valid_typeII_div finite_imageD gen_division_def valid_two_chain_def by auto
       show "\<And>a. a \<in> two_chain_typeII \<Longrightarrow> finite (boundary a)"
         by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
     qed
     then have "finite one_chain_typeII"
       using boundary_of_region_is_subset_of_partition_boundaries(2) finite_subset by fastforce
     ultimately show "one_chain_line_integral F {i} one_chain_typeI = one_chain_line_integral F {i} one_chain_typeII"
       "\<forall>(k, \<gamma>)\<in>one_chain_typeII. line_integral_exists F {i} \<gamma>"
       using ii common_subdivision_imp_eq_line_integral[OF typeI_and_typII_one_chains_have_common_subdiv
           i i' ii]
       by auto
   qed
   have one_chain_j_integrals:
     "one_chain_line_integral F {j} one_chain_typeI = one_chain_line_integral F {j} one_chain_typeII \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeI. line_integral_exists F {j} \<gamma>) \<and>
               (\<forall>(k,\<gamma>)\<in>one_chain_typeII. line_integral_exists F {j} \<gamma>)"
   proof (intro conjI)
     have i: "boundary_chain one_chain_typeI" and i': "boundary_chain one_chain_typeII"
       using two_chain_boundary_is_boundary_chain boundary_of_region_is_subset_of_partition_boundaries
       unfolding boundary_chain_def by blast+
     have "line_integral_exists F {j} \<gamma>" if "(k,\<gamma>)\<in>one_chain_typeII" for k \<gamma>
     proof -
       have F_is_continuous: "\<forall>twoC \<in> two_chain_typeII. continuous_on (cubeImage twoC) (\<lambda>a. F(a) \<bullet> j)"
         using T2.F_anal_valid by(simp add: analytically_valid_def)
       show "line_integral_exists F {j} \<gamma>"
         using that T2.valid_typeII_div
           boundary_of_region_is_subset_of_partition_boundaries(2)
         using green_typeII_cube.line_integral_exists_on_typeII_Cube_boundaries' assms valid_two_chain_def
         apply (simp add: two_chain_boundary_def)
         by (metis T2.typeII_cube_line_integral_exists_boundary case_prodD subset_iff that two_chain_boundary_def)
     qed
     then show ii: " \<forall>(k,\<gamma>)\<in>one_chain_typeII. line_integral_exists F {j} \<gamma>" by auto
     have "finite (two_chain_boundary two_chain_typeI)"
       unfolding two_chain_boundary_def
     proof (rule finite_UN_I)
       show "finite two_chain_typeI"
         using T1.valid_typeI_div finite_imageD gen_division_def valid_two_chain_def by auto
       show "\<And>a. a \<in> two_chain_typeI \<Longrightarrow> finite (boundary a)"
         by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
     qed
     then have iv: "finite one_chain_typeI"
       using boundary_of_region_is_subset_of_partition_boundaries(1) finite_subset
       by fastforce
     have "finite (two_chain_boundary two_chain_typeII)"
       unfolding two_chain_boundary_def
     proof (rule finite_UN_I)
       show "finite two_chain_typeII"
         using T2.valid_typeII_div finite_imageD gen_division_def valid_two_chain_def by auto
       show "\<And>a. a \<in> two_chain_typeII \<Longrightarrow> finite (boundary a)"
         by (simp add: boundary_def horizontal_boundary_def vertical_boundary_def)
     qed
     then have iv': "finite one_chain_typeII"
       using boundary_of_region_is_subset_of_partition_boundaries(2) finite_subset
       by fastforce
     have typeII_and_typI_one_chains_have_common_subdiv:
       "common_boundary_sudivision_exists one_chain_typeII one_chain_typeI"
       using typeI_and_typII_one_chains_have_common_subdiv
         common_boundary_sudivision_commutative
       by auto
     show "one_chain_line_integral F {j} one_chain_typeI = one_chain_line_integral F {j} one_chain_typeII" 
           "\<forall>(k, \<gamma>)\<in>one_chain_typeI. line_integral_exists F {j} \<gamma>"
       using common_subdivision_imp_eq_line_integral[OF typeII_and_typI_one_chains_have_common_subdiv
           i' i ii iv' iv] ii
       by auto
   qed
   have typeI_regions_integral:
     "integral s (\<lambda>x. - ?F_b' x) = one_chain_line_integral F {i} one_chain_typeI"
     using T1.GreenThm_typeI_divisible_region_boundary gen_divisions(1)
          typeI_two_cubes_trace_horizontal_boundaries
         boundary_of_region_is_subset_of_partition_boundaries(1)
     by auto
   have typeII_regions_integral:
     "integral s ?F_a' = one_chain_line_integral F {j} one_chain_typeII"
     using T2.GreenThm_typeII_divisible_region_boundary gen_divisions(2) 
         typeII_two_cubes_trace_vertical_boundaries
         boundary_of_region_is_subset_of_partition_boundaries(2)
     by auto
   have line_integral_dist:
     "one_chain_line_integral F {i, j} one_chain_typeI = one_chain_line_integral F {i} one_chain_typeI + one_chain_line_integral F {j} one_chain_typeI \<and>
      one_chain_line_integral F {i, j} one_chain_typeII = one_chain_line_integral F {i} one_chain_typeII + one_chain_line_integral F {j} one_chain_typeII"
   proof (simp add: one_chain_line_integral_def)
     have line_integral_distrib:
       "(\<Sum>(k,g)\<in>one_chain_typeI. k * line_integral F {i, j} g) =
        (\<Sum>(k,g)\<in>one_chain_typeI. k * line_integral F {i} g +  k * line_integral F {j} g) \<and>
        (\<Sum>(k,g)\<in>one_chain_typeII. k * line_integral F {i, j} g) =
        (\<Sum>(k,g)\<in>one_chain_typeII. k * line_integral F {i} g +  k * line_integral F {j} g)"
     proof -
       have 0: "k * line_integral F {i, j} g = k * line_integral F {i} g +  k * line_integral F {j} g"
         if "(k,g) \<in> one_chain_typeII" for k g
       proof -
         have "line_integral F {i, j} g = line_integral F {i} g + line_integral F {j} g"
         proof -
           have finite: "finite {i, j}" by auto
           have line_integral_all: "\<forall>i\<in>{i, j}. line_integral_exists F {i} g"
             using one_chain_i_integrals one_chain_j_integrals that by auto
           show ?thesis
             using line_integral_sum_gen[OF finite] R2.i_is_x_axis R2.j_is_y_axis line_integral_all by auto
         qed
         then show "k * line_integral F {i, j} g = k * line_integral F {i} g + k * line_integral F {j} g"
           by (simp add: distrib_left)
       qed
       have "k * line_integral F {i, j} g = k * line_integral F {i} g +  k * line_integral F {j} g"
         if "(k,g) \<in> one_chain_typeI" for k g
       proof -
         have finite: "finite {i, j}" by auto
         have line_integral_all: "\<forall>i\<in>{i, j}. line_integral_exists F {i} g"
           using one_chain_i_integrals one_chain_j_integrals that by auto
         have "line_integral F {i, j} g = line_integral F {i} g + line_integral F {j} g"
           using line_integral_sum_gen[OF finite] R2.i_is_x_axis R2.j_is_y_axis line_integral_all by auto
         then show "k * line_integral F {i, j} g = k * line_integral F {i} g + k * line_integral F {j} g"
           by (simp add: distrib_left)
       qed
       then show ?thesis
         using 0  by (smt sum.cong split_cong)
     qed
     show "(\<Sum>(k::int, g)\<in>one_chain_typeI. k * line_integral F {i, j} g) =
           (\<Sum>(k, g)\<in>one_chain_typeI. k * line_integral F {i} g) + (\<Sum>(k::int, g)\<in>one_chain_typeI. k * line_integral F {j} g) \<and>
           (\<Sum>(k::int, g)\<in>one_chain_typeII. k * line_integral F {i, j} g) =
           (\<Sum>(k, g)\<in>one_chain_typeII. k * line_integral F {i} g) + (\<Sum>(k::int, g)\<in>one_chain_typeII. k * line_integral F {j} g)"
     proof -
       have 0: "(\<lambda>x. (case x of (k::int, g) \<Rightarrow> k * line_integral F {i} g) + (case x of (k::int, g) \<Rightarrow> k * line_integral F {j} g)) =
                                   (\<lambda>x. (case x of (k::int, g) \<Rightarrow> (k * line_integral F {i} g) +  k * line_integral F {j} g))"
         using comm_monoid_add_class.sum.distrib by auto
       then have 1: "(\<Sum>x\<in>one_chain_typeI. (case x of (k::int, g) \<Rightarrow> k * line_integral F {i} g) + (case x of (k::int, g) \<Rightarrow> k * line_integral F {j} g)) =
                     (\<Sum>x\<in>one_chain_typeI. (case x of (k::int, g) \<Rightarrow>( k * line_integral F {i} g + k * line_integral F {j} g)))"
         by presburger
       have "(\<Sum>x\<in>one_chain_typeII. (case x of (k, g) \<Rightarrow> k * line_integral F {i} g) + (case x of (k, g) \<Rightarrow> k * line_integral F {j} g)) =
             (\<Sum>x\<in>one_chain_typeII. (case x of (k, g) \<Rightarrow>( k * line_integral F {i} g + k * line_integral F {j} g)))"
         using 0 by presburger
       then show ?thesis
         using sum.distrib[of "(\<lambda>(k, g).  k * line_integral F {i} g)" "(\<lambda>(k, g).  k * line_integral F {j} g)" "one_chain_typeI"]
           sum.distrib[of "(\<lambda>(k, g).  k * line_integral F {i} g)" "(\<lambda>(k, g).  k * line_integral F {j} g)" "one_chain_typeII"]
           line_integral_distrib
           1
         by auto
     qed
   qed
   have integral_dis: "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = integral s (\<lambda>x. ?F_a' x) + integral s (\<lambda>x. - ?F_b' x)"
   proof -
     have "(?F_a' has_integral (\<Sum>img\<in>cubeImage ` two_chain_typeII. integral img ?F_a')) s"
     proof -
       have "(?F_a' has_integral integral (cubeImage twoCube) ?F_a') (cubeImage twoCube)"
         if "twoCube \<in> two_chain_typeII" for twoCube
         by (simp add: analytically_valid_imp_part_deriv_integrable_on T2.F_anal_valid has_integral_integrable_integral that) 
       then have  "\<And>u. u \<in> (cubeImage ` two_chain_typeII) \<Longrightarrow> (?F_a' has_integral integral u ?F_a') u"
         by auto
       then show ?thesis
       using gen_divisions(2) unfolding gen_division_def
       by (metis has_integral_Union)
     qed
     then have F_a'_integrable:
       "(?F_a' integrable_on s)" by auto
     have "(?F_b' has_integral (\<Sum>img\<in>cubeImage ` two_chain_typeI. integral img ?F_b')) s"
     proof -
       have "\<forall>twoCube \<in> two_chain_typeI. (?F_b' has_integral integral (cubeImage twoCube) ?F_b') (cubeImage twoCube)"
         by (simp add: analytically_valid_imp_part_deriv_integrable_on T1.F_anal_valid has_integral_integrable_integral) 
       then have "\<And>u. u \<in> (cubeImage ` two_chain_typeI) \<Longrightarrow> (?F_b' has_integral integral u ?F_b') u"
         by auto
       then show ?thesis
       using gen_divisions(1) unfolding gen_division_def
       by (metis has_integral_Union)
     qed
     then show ?thesis
       using F_a'_integrable Henstock_Kurzweil_Integration.integral_diff by auto
   qed
   show "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = one_chain_line_integral F {i, j} one_chain_typeI"
     using one_chain_j_integrals integral_dis line_integral_dist typeI_regions_integral typeII_regions_integral
     by auto
   show "integral s (\<lambda>x. ?F_a' x - ?F_b' x) = one_chain_line_integral F {i, j} one_chain_typeII"
     using one_chain_i_integrals integral_dis line_integral_dist typeI_regions_integral typeII_regions_integral
     by auto
 qed
 
 end
 end
diff --git a/thys/MFMC_Countable/MFMC_Bounded.thy b/thys/MFMC_Countable/MFMC_Bounded.thy
--- a/thys/MFMC_Countable/MFMC_Bounded.thy
+++ b/thys/MFMC_Countable/MFMC_Bounded.thy
@@ -1,653 +1,653 @@
 (* Author: Andreas Lochbihler, Digital Asset *)
 
 section \<open>The max-flow min-cut theorem in bounded networks\<close>
 
 subsection \<open>Linkages in unhindered bipartite webs\<close>
 
 theory MFMC_Bounded imports
   Matrix_For_Marginals
   MFMC_Reduction
 begin
 
 context countable_bipartite_web begin
 
 lemma countable_A [simp]: "countable (A \<Gamma>)"
   using A_vertex countable_V by(blast intro: countable_subset)
 
 lemma unhindered_criterion [rule_format]:
   assumes "\<not> hindered \<Gamma>"
   shows "\<forall>X \<subseteq> A \<Gamma>. finite X \<longrightarrow> (\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x) \<le> (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y)"
   using assms
 proof(rule contrapos_np)
   assume "\<not> ?thesis"
   then obtain X where "X \<in> {X. X \<subseteq> A \<Gamma> \<and> finite X \<and> (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) < (\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x)}" (is "_ \<in> Collect ?P") 
     by(auto simp add: not_le)
   from wf_eq_minimal[THEN iffD1, OF wf_finite_psubset, rule_format, OF this, simplified]
   obtain X where X_A: "X \<subseteq> A \<Gamma>" and fin_X [simp]: "finite X"
     and less: "(\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) < (\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x)"
     and minimal: "\<And>X'. X' \<subset> X \<Longrightarrow> (\<Sum>\<^sup>+ x\<in>X'. weight \<Gamma> x) \<le> (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X'. weight \<Gamma> y)"
     by(clarsimp simp add: not_less)(meson finite_subset order_trans psubset_imp_subset)
   have nonempty: "X \<noteq> {}" using less by auto
   then obtain xx where xx: "xx \<in> X" by auto
   define f where
     "f x = (if x = xx then (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) - (\<Sum>\<^sup>+ x\<in>X - {xx}. weight \<Gamma> x) else if x \<in> X then weight \<Gamma> x else 0)" for x
   define g where
     "g y = (if y \<in> \<^bold>E `` X then weight \<Gamma> y else 0)" for y
   define E' where "E' \<equiv> \<^bold>E \<inter> X \<times> UNIV"
   have Xxx: "X - {xx} \<subset> X" using xx by blast
   have E [simp]: "E' `` X' = \<^bold>E `` X'" if "X' \<subseteq> X" for X' using that by(auto simp add: E'_def)
   have in_E': "(x, y) \<in> E' \<longleftrightarrow> x \<in> X \<and> (x, y) \<in> \<^bold>E" for x y by(auto simp add: E'_def)
 
   have "(\<Sum>\<^sup>+ x\<in>X. f x) = (\<Sum>\<^sup>+ x\<in>X - {xx}. f x) + (\<Sum>\<^sup>+ x\<in>{xx}. f x)" using xx
     by(auto simp add: nn_integral_count_space_indicator nn_integral_add[symmetric] simp del: nn_integral_indicator_singleton intro!: nn_integral_cong split: split_indicator)
   also have "\<dots> = (\<Sum>\<^sup>+ x\<in>X - {xx}. weight \<Gamma> x) + ((\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) - (\<Sum>\<^sup>+ x\<in>X - {xx}. weight \<Gamma> x))"
     by(rule arg_cong2[where f="(+)"])(auto simp add: f_def xx nn_integral_count_space_indicator intro!: nn_integral_cong)
   also have "\<dots> = (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. g y)" using minimal[OF Xxx] xx 
     by(subst add_diff_eq_iff_ennreal[THEN iffD2])(fastforce simp add: g_def[abs_def] nn_integral_count_space_indicator intro!: nn_integral_cong intro: nn_integral_mono elim: order_trans split: split_indicator)+
   finally have sum_eq: "(\<Sum>\<^sup>+ x\<in>X. f x) = (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. g y)" .
 
   have "(\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) = (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. g y)"
     by(auto simp add: nn_integral_count_space_indicator g_def intro!: nn_integral_cong)
   then have fin: "\<dots> \<noteq> \<top>" using less by auto
 
   have fin2: "(\<Sum>\<^sup>+ x\<in>X'. weight \<Gamma> x) \<noteq> \<top>" if "X' \<subset> X" for X'
   proof -
     have "(\<Sum>\<^sup>+ x\<in>\<^bold>E `` X'. weight \<Gamma> x) \<le> (\<Sum>\<^sup>+ x\<in>\<^bold>E `` X. weight \<Gamma> x)" using that 
       by(auto 4 3 simp add: nn_integral_count_space_indicator intro!: nn_integral_mono split: split_indicator split_indicator_asm)
     then show ?thesis using minimal[OF that] less by(auto simp add: top_unique)
   qed
 
   have "f xx = (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) - (\<Sum>\<^sup>+ x\<in>X - {xx}. weight \<Gamma> x)" by (simp add: f_def)
   also have "\<dots> < (\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x) - (\<Sum>\<^sup>+ x\<in>X - {xx}. weight \<Gamma> x)" using less fin2[OF Xxx] minimal[OF Xxx]
     by(subst minus_less_iff_ennreal)(fastforce simp add: less_top[symmetric] nn_integral_count_space_indicator diff_add_self_ennreal intro: nn_integral_mono elim: order_trans split: split_indicator)+
   also have "\<dots> = (\<Sum>\<^sup>+ x\<in>{xx}. weight \<Gamma> x)" using fin2[OF Xxx] xx 
     apply(simp add: nn_integral_count_space_indicator del: nn_integral_indicator_singleton)
     apply(subst nn_integral_diff[symmetric])
     apply(auto simp add: AE_count_space split: split_indicator simp del: nn_integral_indicator_singleton intro!: nn_integral_cong)
     done
   also have "\<dots> = weight \<Gamma> xx" by(simp add: nn_integral_count_space_indicator)
   finally have fxx: "f xx < weight \<Gamma> xx" .
 
   have le: "(\<Sum>\<^sup>+ x\<in>X'. f x) \<le> (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X'. g y)" if "X' \<subseteq> X" for X'
   proof(cases "X' = X")
     case True
     then show ?thesis using sum_eq by simp
   next
     case False
     hence X': "X' \<subset> X" using that by blast
     have "(\<Sum>\<^sup>+ x\<in>X'. f x) = (\<Sum>\<^sup>+ x\<in>X' - {xx}. f x) + (\<Sum>\<^sup>+ x\<in>{xx}. f x * indicator X' xx)"
       by(auto simp add: nn_integral_count_space_indicator nn_integral_add[symmetric] simp del: nn_integral_indicator_singleton intro!: nn_integral_cong split: split_indicator)
     also have "\<dots> \<le> (\<Sum>\<^sup>+ x\<in>X' - {xx}. f x) + (\<Sum>\<^sup>+ x\<in>{xx}. weight \<Gamma> x * indicator X' xx)" using fxx
       by(intro add_mono)(auto split: split_indicator simp add: nn_integral_count_space_indicator)
     also have "\<dots> = (\<Sum>\<^sup>+ x\<in>X'. weight \<Gamma> x)" using xx that
       by(auto simp add: nn_integral_count_space_indicator nn_integral_add[symmetric] f_def simp del: nn_integral_indicator_singleton intro!: nn_integral_cong split: split_indicator)
     also have "\<dots> \<le> (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X'. weight \<Gamma> y)" by(rule minimal[OF X'])
     also have "\<dots> = (\<Sum>\<^sup>+ y\<in>\<^bold>E `` X'. g y)" using that 
       by(auto 4 3 intro!: nn_integral_cong simp add: g_def Image_iff)
     finally show ?thesis .
   qed
   
   have "countable X" using X_A A_vertex countable_V by(blast intro: countable_subset)
   moreover have "\<^bold>E `` X \<subseteq> \<^bold>V" by(auto simp add: vertex_def)
   with countable_V have "countable (\<^bold>E `` X)" by(blast intro: countable_subset)
   moreover have "E' \<subseteq> X \<times> \<^bold>E `` X" by(auto simp add: E'_def)
   ultimately obtain h' where h'_dom: "\<And>x y. 0 < h' x y \<Longrightarrow> (x, y) \<in> E'"
     and h'_fin: "\<And>x y. h' x y \<noteq> \<top>"
     and h'_f: "\<And>x. x \<in> X \<Longrightarrow> (\<Sum>\<^sup>+ y\<in>E' `` X. h' x y) = f x"
     and h'_g: "\<And>y. y \<in> E' `` X \<Longrightarrow> (\<Sum>\<^sup>+ x\<in>X. h' x y) = g y"
     using bounded_matrix_for_marginals_ennreal[where f=f and g=g and A=X and B="E' `` X" and R=E' and thesis=thesis] sum_eq fin le
     by(auto)
 
   have h'_outside: "(x, y) \<notin> E' \<Longrightarrow> h' x y = 0" for x y using h'_dom[of x y] not_gr_zero by(fastforce)
 
   define h where "h = (\<lambda>(x, y). if x \<in> X \<and> edge \<Gamma> x y then h' x y else 0)"
   have h_OUT: "d_OUT h x = (if x \<in> X then f x else 0)" for x
     by(auto 4 3 simp add: h_def d_OUT_def h'_f[symmetric] E'_def nn_integral_count_space_indicator intro!: nn_integral_cong intro: h'_outside split: split_indicator)
   have h_IN: "d_IN h y = (if y \<in> \<^bold>E `` X then weight \<Gamma> y else 0)" for y using h'_g[of y, symmetric]
     by(auto 4 3 simp add: h_def d_IN_def g_def nn_integral_count_space_indicator nn_integral_0_iff_AE  in_E' intro!: nn_integral_cong intro: h'_outside split: split_indicator split_indicator_asm)
 
   have h: "current \<Gamma> h"
   proof
     show "d_OUT h x \<le> weight \<Gamma> x" for x using fxx by(auto simp add: h_OUT f_def)
     show "d_IN h y \<le> weight \<Gamma> y" for y by(simp add: h_IN)
     show "h e = 0" if "e \<notin> \<^bold>E" for e using that by(cases e)(auto simp add: h_def)
   qed
 
   have "separating \<Gamma> (TER h)"
   proof
     fix x y p
     assume x: "x \<in> A \<Gamma>" and y: "y \<in> B \<Gamma>" and p: "path \<Gamma> x p y"
     then obtain [simp]: "p = [y]" and xy: "(x, y) \<in> \<^bold>E" using disjoint 
       by -(erule rtrancl_path.cases; auto dest: bipartite_E)+
     show "(\<exists>z\<in>set p. z \<in> TER h) \<or> x \<in> TER h"
     proof(rule disjCI)
       assume "x \<notin> TER h"
       hence "x \<in> X" using x by(auto simp add: SAT.simps SINK.simps h_OUT split: if_split_asm)
       hence "y \<in> TER h" using xy currentD_OUT[OF h y] by(auto simp add: SAT.simps h_IN SINK.simps)
       thus "\<exists>z\<in>set p. z \<in> TER h" by simp
     qed
   qed
   then have w: "wave \<Gamma> h" using h ..
 
   have "xx \<in> A \<Gamma>" using xx X_A by blast
   moreover have "xx \<notin> \<E> (TER h)"
   proof
     assume "xx \<in> \<E> (TER h)"
     then obtain p y where y: "y \<in> B \<Gamma>" and p: "path \<Gamma> xx p y"
       and bypass: "\<And>z. \<lbrakk> xx \<noteq> y; z \<in> set p \<rbrakk> \<Longrightarrow> z = xx \<or> z \<notin> TER h"
       by(rule \<E>_E) auto
     from p obtain [simp]: "p = [y]" and xy: "edge \<Gamma> xx y" and neq: "xx \<noteq> y" using disjoint X_A xx y
       by -(erule rtrancl_path.cases; auto dest: bipartite_E)+
     from neq bypass[of y] have "y \<notin> TER h" by simp
     moreover from xy xx currentD_OUT[OF h y] have "y \<in> TER h" 
       by(auto simp add: SAT.simps h_IN SINK.simps)
     ultimately show False by contradiction
   qed
   moreover have "d_OUT h xx < weight \<Gamma> xx" using fxx xx by(simp add: h_OUT)
   ultimately have "hindrance \<Gamma> h" ..
   then show "hindered \<Gamma>" using h w ..
 qed
 
 end
 
 lemma nn_integral_count_space_top_approx:
   fixes f :: "nat => ennreal" and b :: ennreal
   assumes "nn_integral (count_space UNIV) f = top"
   and "b < top"
   obtains n where "b < sum f {..<n}"
   using assms unfolding nn_integral_count_space_nat suminf_eq_SUP SUP_eq_top_iff by(auto)
 
 lemma One_le_of_nat_ennreal: "(1 :: ennreal) \<le> of_nat x \<longleftrightarrow> 1 \<le> x"
   by (metis of_nat_le_iff of_nat_1)
 
 locale bounded_countable_bipartite_web = countable_bipartite_web \<Gamma>
   for \<Gamma> :: "('v, 'more) web_scheme" (structure)
   +
   assumes bounded_B: "x \<in> A \<Gamma> \<Longrightarrow> (\<Sum>\<^sup>+ y \<in> \<^bold>E `` {x}. weight \<Gamma> y) < \<top>"
 begin
 
 theorem unhindered_linkable_bounded:
   assumes "\<not> hindered \<Gamma>"
   shows "linkable \<Gamma>"
 proof(cases "A \<Gamma> = {}")
   case True
   hence "linkage \<Gamma> (\<lambda>_. 0)" by(auto simp add: linkage.simps)
   moreover have "web_flow \<Gamma> (\<lambda>_. 0)" by(auto simp add: web_flow.simps)
   ultimately show ?thesis by blast 
 next
   case nonempty: False
   define A_n :: "nat \<Rightarrow> 'v set" where "A_n n = from_nat_into (A \<Gamma>) ` {..n}" for n
   have fin_A_n [simp]: "finite (A_n n)" for n by(simp add: A_n_def)
   have A_n_A: "A_n n \<subseteq> A \<Gamma>" for n by(auto simp add: A_n_def from_nat_into[OF nonempty])
 
   have countable2: "countable (\<^bold>E `` A_n n)" for n using countable_V
     by(rule countable_subset[rotated])(auto simp add: vertex_def)
 
   have "\<exists>Y2. \<forall>n. \<forall>X \<subseteq> A_n n. Y2 n X \<subseteq> \<^bold>E `` X \<and> (\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x) \<le> (\<Sum>\<^sup>+ y\<in>Y2 n X. weight \<Gamma> y) \<and> (\<Sum>\<^sup>+ y\<in>Y2 n X. weight \<Gamma> y) \<noteq> \<top>"
   proof(rule choice strip ex_simps(6)[THEN iffD2])+
     fix n X
     assume X: "X \<subseteq> A_n n"
     then have [simp]: "finite X" by(rule finite_subset) simp
     have X_count: "countable (\<^bold>E `` X)" using countable2
       by(rule countable_subset[rotated])(rule Image_mono[OF order_refl X])
 
     show "\<exists>Y. Y \<subseteq> \<^bold>E `` X \<and> (\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x) \<le> (\<Sum>\<^sup>+ y\<in>Y. weight \<Gamma> y) \<and> (\<Sum>\<^sup>+ y\<in>Y. weight \<Gamma> y) \<noteq> \<top>" (is "Ex ?P")
     proof(cases "(\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) = \<top>")
       case True
       define Y' where "Y' = to_nat_on (\<^bold>E `` X) ` (\<^bold>E `` X)"
       have inf: "infinite (\<^bold>E `` X)" using True
         by(intro notI)(auto simp add: nn_integral_count_space_finite)
       then have Y': "Y' = UNIV" using X_count by(auto simp add: Y'_def intro!: image_to_nat_on)
       have "(\<Sum>\<^sup>+ y\<in>\<^bold>E `` X. weight \<Gamma> y) = (\<Sum>\<^sup>+ y\<in>from_nat_into (\<^bold>E `` X) ` Y'. weight \<Gamma> y * indicator (\<^bold>E `` X) y)"
         using X_count
         by(auto simp add: nn_integral_count_space_indicator Y'_def image_image intro!: nn_integral_cong from_nat_into_to_nat_on[symmetric] rev_image_eqI split: split_indicator)
       also have "\<dots> = (\<Sum>\<^sup>+ y. weight \<Gamma> (from_nat_into (\<^bold>E `` X) y) * indicator (\<^bold>E `` X) (from_nat_into (\<^bold>E `` X) y))"
         using X_count inf by(subst nn_integral_count_space_reindex)(auto simp add: inj_on_def Y')
       finally have "\<dots> = \<top>" using True by simp
       from nn_integral_count_space_top_approx[OF this, of "sum (weight \<Gamma>) X"]
       obtain yy where yy: "sum (weight \<Gamma>) X < (\<Sum> y<yy. weight \<Gamma> (from_nat_into (\<^bold>E `` X) y) * indicator (\<^bold>E `` X) (from_nat_into (\<^bold>E `` X) y))"
         by(auto simp add: less_top[symmetric])
       define Y where "Y = from_nat_into (\<^bold>E `` X) ` {..<yy} \<inter> \<^bold>E `` X"
       have [simp]: "finite Y" by(simp add: Y_def)
       have "(\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x) = sum (weight \<Gamma>) X" by(simp add: nn_integral_count_space_finite)
       also have "\<dots> \<le> (\<Sum> y<yy. weight \<Gamma> (from_nat_into (\<^bold>E `` X) y) * indicator (\<^bold>E `` X) (from_nat_into (\<^bold>E `` X) y))"
         using yy by simp
       also have "\<dots> = (\<Sum> y \<in> from_nat_into (\<^bold>E `` X) ` {..<yy}. weight \<Gamma> y * indicator (\<^bold>E `` X) y)"
         using X_count inf by(subst sum.reindex)(auto simp add: inj_on_def)
       also have "\<dots> = (\<Sum> y \<in> Y. weight \<Gamma> y)" by(auto intro!: sum.cong simp add: Y_def)
       also have "\<dots> = (\<Sum>\<^sup>+ y\<in>Y. weight \<Gamma> y)" by(simp add: nn_integral_count_space_finite)
       also have "Y \<subseteq> \<^bold>E `` X" by(simp add: Y_def)
       moreover have "(\<Sum>\<^sup>+ y\<in>Y. weight \<Gamma> y) \<noteq> \<top>" by(simp add: nn_integral_count_space_finite)
       ultimately show ?thesis by blast
     next
       case False
       with unhindered_criterion[OF assms, of X] X A_n_A[of n] have "?P (\<^bold>E `` X)" by auto
       then show ?thesis ..
     qed
   qed
   then obtain Y2
     where Y2_A: "Y2 n X \<subseteq> \<^bold>E `` X"
     and le: "(\<Sum>\<^sup>+ x\<in>X. weight \<Gamma> x) \<le> (\<Sum>\<^sup>+ y\<in>Y2 n X. weight \<Gamma> y)"
     and finY2: "(\<Sum>\<^sup>+ y\<in>Y2 n X. weight \<Gamma> y) \<noteq> \<top>" if "X \<subseteq> A_n n" for n X by iprover
   define Y where "Y n = (\<Union> X \<in> Pow (A_n n). Y2 n X)" for n
   define s where "s n = (\<Sum>\<^sup>+ y\<in>Y n. weight \<Gamma> y)" for n
   have Y_vertex: "Y n \<subseteq> \<^bold>V" for n by(auto 4 3 simp add: Y_def vertex_def dest!: Y2_A[of _ n])
   have Y_B: "Y n \<subseteq> B \<Gamma>" for n unfolding Y_def by(auto dest!: Y2_A[of _ n] dest: bipartite_E)
 
   have s_top [simp]: "s n \<noteq> \<top>" for n
   proof -
     have "\<lbrakk>x \<in> Y2 n X; X \<subseteq> A_n n\<rbrakk> \<Longrightarrow> Suc 0 \<le> card {X. X \<subseteq> A_n n \<and> x \<in> Y2 n X}" for x X
       by(subst card_le_Suc_iff)(auto intro!: exI[where x=X] exI[where x="{X. X \<subseteq> A_n n \<and> x \<in> Y2 n X} - {X}"])
     then have "(\<Sum>\<^sup>+ y\<in>Y n. weight \<Gamma> y) \<le> (\<Sum>\<^sup>+ y\<in>Y n. \<Sum> X\<in>Pow (A_n n). weight \<Gamma> y * indicator (Y2 n X) y)"
       by(intro nn_integral_mono)(auto simp add: Y_def One_le_of_nat_ennreal intro!: mult_right_mono[of "1 :: ennreal", simplified])
     also have "\<dots> = (\<Sum> X\<in>Pow (A_n n). \<Sum>\<^sup>+ y\<in>Y n. weight \<Gamma> y * indicator (Y2 n X) y)"
       by(subst nn_integral_sum) auto
     also have "\<dots> = (\<Sum> X\<in>Pow (A_n n). \<Sum>\<^sup>+ y\<in>Y2 n X. weight \<Gamma> y)"
       by(auto intro!: sum.cong nn_integral_cong simp add: nn_integral_count_space_indicator Y_def split: split_indicator)
     also have "\<dots> < \<top>" by(simp add: less_top[symmetric] finY2)
     finally show ?thesis by(simp add: less_top s_def)
   qed
 
   define f :: "nat \<Rightarrow> 'v option \<Rightarrow> real"
     where "f n xo = (case xo of Some x \<Rightarrow> if x \<in> A_n n then enn2real (weight \<Gamma> x) else 0 
                     | None \<Rightarrow> enn2real (s n - sum (weight \<Gamma>) (A_n n)))" for n xo
   define g :: "nat \<Rightarrow> 'v \<Rightarrow> real"
     where "g n y = enn2real (weight \<Gamma> y * indicator (Y n) y)" for n y
   define R :: "nat \<Rightarrow> ('v option \<times> 'v) set"
     where "R n = map_prod Some id ` (\<^bold>E \<inter> A_n n \<times> Y n) \<union> {None} \<times> Y n" for n
   define A_n' where "A_n' n = Some ` A_n n \<union> {None}" for n
 
   have f_simps:
     "f n (Some x) = (if x \<in> A_n n then enn2real (weight \<Gamma> x) else 0)"
     "f n None = enn2real (s n - sum (weight \<Gamma>) (A_n n))"
     for n x by(simp_all add: f_def)
   
   have g_s: "(\<Sum>\<^sup>+ y\<in>Y n. g n y) = s n" for n
     by(auto simp add: s_def g_def ennreal_enn2real_if intro!: nn_integral_cong)
 
   have "(\<Sum>\<^sup>+ x\<in>A_n' n. f n x) = (\<Sum>\<^sup>+ x\<in>Some`A_n n. weight \<Gamma> (the x)) + (\<Sum>\<^sup>+ x\<in>{None}. f n x)" for n
     by(auto simp add: nn_integral_count_space_indicator nn_integral_add[symmetric] f_simps A_n'_def ennreal_enn2real_if simp del: nn_integral_indicator_singleton intro!: nn_integral_cong split: split_indicator)
   also have "\<dots> n = sum (weight \<Gamma>) (A_n n) + (s n - sum (weight \<Gamma>) (A_n n))" for n
     by(subst nn_integral_count_space_reindex)(auto simp add: nn_integral_count_space_finite f_simps ennreal_enn2real_if)
   also have "\<dots> n = s n" for n using le[OF order_refl, of n]
     by(simp add: s_def nn_integral_count_space_finite)(auto elim!: order_trans simp add: nn_integral_count_space_indicator Y_def intro!: nn_integral_mono split: split_indicator)
   finally have sum_eq: "(\<Sum>\<^sup>+ x\<in>A_n' n. f n x) = (\<Sum>\<^sup>+ y\<in>Y n. g n y)" for n using g_s by simp
 
   have "\<exists>h'. \<forall>n. (\<forall>x y. (x, y) \<notin> R n \<longrightarrow> h' n x y = 0) \<and> (\<forall>x y. h' n x y \<noteq> \<top>) \<and> (\<forall>x\<in>A_n' n. (\<Sum>\<^sup>+ y\<in>Y n. h' n x y) = f n x) \<and> (\<forall>y\<in>Y n. (\<Sum>\<^sup>+ x\<in>A_n' n. h' n x y) = g n y)" 
     (is "Ex (\<lambda>h'. \<forall>n. ?Q n (h' n))")
   proof(rule choice allI)+
     fix n
     note sum_eq
     moreover have "(\<Sum>\<^sup>+ y\<in>Y n. g n y) \<noteq> \<top>" using g_s by simp
     moreover have le_fg: "(\<Sum>\<^sup>+ x\<in>X. f n x) \<le> (\<Sum>\<^sup>+ y\<in>R n `` X. g n y)" if "X \<subseteq> A_n' n" for X
     proof(cases "None \<in> X")
       case True
       have "(\<Sum>\<^sup>+ x\<in>X. f n x) \<le> (\<Sum>\<^sup>+ x\<in>A_n' n. f n x)" using that
         by(auto simp add: nn_integral_count_space_indicator intro!: nn_integral_mono split: split_indicator)
       also have "\<dots> = (\<Sum>\<^sup>+ y\<in>Y n. g n y)" by(simp add: sum_eq)
       also have "R n `` X = Y n" using True by(auto simp add: R_def)
       ultimately show ?thesis by simp
     next
       case False
       then have *: "Some ` (the ` X) = X"
         by(auto simp add: image_image)(metis (no_types, lifting) image_iff notin_range_Some option.sel option.collapse)+
       from False that have X: "the ` X \<subseteq> A_n n" by(auto simp add: A_n'_def)
       from * have "(\<Sum>\<^sup>+ x\<in>X. f n x) = (\<Sum>\<^sup>+ x\<in>Some ` (the ` X). f n x)" by simp
       also have "\<dots> = (\<Sum>\<^sup>+ x\<in>the ` X. f n (Some x))" by(rule nn_integral_count_space_reindex) simp
       also have "\<dots> = (\<Sum>\<^sup>+ x\<in>the ` X. weight \<Gamma> x)" using that False
         by(auto 4  3intro!: nn_integral_cong simp add: f_simps A_n'_def ennreal_enn2real_if)
       also have "\<dots> \<le> (\<Sum>\<^sup>+ y\<in>Y2 n (the ` X). weight \<Gamma> y)" using False that 
         by(intro le)(auto simp add: A_n'_def)
       also have "\<dots> \<le> (\<Sum>\<^sup>+ y\<in>R n `` X. weight \<Gamma> y)" using False Y2_A[of "the ` X" n] X
         by(auto simp add: A_n'_def nn_integral_count_space_indicator R_def Image_iff Y_def intro: rev_image_eqI intro!: nn_integral_mono split: split_indicator)
           (drule (1) subsetD; clarify; drule (1) bspec; auto 4 3 intro: rev_image_eqI)
       also have "\<dots> = (\<Sum>\<^sup>+ y\<in>R n `` X. g n y)"
         by(auto intro!: nn_integral_cong simp add: R_def g_def ennreal_enn2real_if)
       finally show ?thesis .
     qed
     moreover have "countable (A_n' n)" by(simp add: A_n'_def countable_finite)
     moreover have "countable (Y2 n X)" if "X \<subseteq> A_n n" for X using Y2_A[OF that]
       by(rule countable_subset)(rule countable_subset[OF _ countable_V]; auto simp add: vertex_def)
     then have "countable (Y n)" unfolding Y_def
       by(intro countable_UN)(simp_all add: countable_finite)
     moreover have "R n \<subseteq> A_n' n \<times> Y n" by(auto simp add: R_def A_n'_def)
     ultimately obtain h' where "\<And>x y. 0 < h' x y \<Longrightarrow> (x, y) \<in> R n" "\<And>x y. h' x y \<noteq> \<top>" 
       "\<And>x. x \<in> A_n' n \<Longrightarrow> (\<Sum>\<^sup>+ y\<in>Y n. h' x y) = (f n x)" "\<And>y. y \<in> Y n \<Longrightarrow> (\<Sum>\<^sup>+ x\<in>A_n' n. h' x y) = g n y"
       by(rule bounded_matrix_for_marginals_ennreal) blast+
     hence "?Q n h'" by(auto)(use not_gr_zero in blast)
     thus "Ex (?Q n)" by blast
   qed
   then obtain h' where dom_h': "\<And>x y. (x, y) \<notin> R n \<Longrightarrow> h' n x y = 0"
     and fin_h' [simp]: "\<And>x y. h' n x y \<noteq> \<top>"
     and h'_f: "\<And>x. x \<in> A_n' n \<Longrightarrow> (\<Sum>\<^sup>+ y\<in>Y n. h' n x y) = f n x"
     and h'_g: "\<And>y. y \<in> Y n \<Longrightarrow> (\<Sum>\<^sup>+ x\<in>A_n' n. h' n x y) = g n y"
     for n by blast
   
   define h :: "nat \<Rightarrow> 'v \<times> 'v \<Rightarrow> real"
     where "h n = (\<lambda>(x, y). if x \<in> A_n n \<and> y \<in> Y n then enn2real (h' n (Some x) y) else 0)" for n
   have h_nonneg: "0 \<le> h n xy" for n xy by(simp add: h_def split_def)
   have h_notB: "h n (x, y) = 0" if "y \<notin> B \<Gamma>" for n x y using Y_B[of n] that by(auto simp add: h_def)
   have h_le_weight2: "h n (x, y) \<le> weight \<Gamma> y" for n x y
   proof(cases "x \<in> A_n n \<and> y \<in> Y n")
     case True
     have "h' n (Some x) y \<le> (\<Sum>\<^sup>+ x\<in>A_n' n. h' n x y)"
       by(rule nn_integral_ge_point)(auto simp add: A_n'_def True)
     also have "\<dots> \<le> weight \<Gamma> y" using h'_g[of y n] True by(simp add: g_def ennreal_enn2real_if)
     finally show ?thesis using True by(simp add: h_def ennreal_enn2real_if)
   qed(auto simp add: h_def)
   have h_OUT: "d_OUT (h n) x = (if x \<in> A_n n then weight \<Gamma> x else 0)" for n x
     using h'_f[of "Some x" n, symmetric]
     by(auto simp add: h_def d_OUT_def A_n'_def f_simps ennreal_enn2real_if nn_integral_count_space_indicator intro!: nn_integral_cong)
   have h_IN: "d_IN (h n) y = (if y \<in> Y n then enn2real (weight \<Gamma> y - h' n None y) else 0)" for n y
   proof(cases "y \<in> Y n")
     case True
     have "d_IN (h n) y = (\<Sum>\<^sup>+ x\<in>Some ` A_n n. h' n x y)"
       by(subst nn_integral_count_space_reindex)
         (auto simp add: d_IN_def h_def nn_integral_count_space_indicator ennreal_enn2real_if R_def intro!: nn_integral_cong dom_h' split: split_indicator)
     also have "\<dots> = (\<Sum>\<^sup>+ x\<in>A_n' n. h' n x y) - (\<Sum>\<^sup>+ x\<in>{None}. h' n x y)"
       apply(simp add: nn_integral_count_space_indicator del: nn_integral_indicator_singleton)
       apply(subst nn_integral_diff[symmetric])
       apply(auto simp add: AE_count_space A_n'_def nn_integral_count_space_indicator split: split_indicator intro!: nn_integral_cong)
       done
     also have "\<dots> = g n y - h' n None y" using h'_g[OF True] by(simp add: nn_integral_count_space_indicator)
     finally show ?thesis using True by(simp add: g_def ennreal_enn2real_if)
   qed(auto simp add: d_IN_def ennreal_enn2real_if nn_integral_0_iff_AE AE_count_space h_def g_def)
 
   let ?Q = "\<^bold>V \<times> \<^bold>V"
 
   have "bounded (range (\<lambda>n. h n xy))" if "xy \<in> ?Q" for xy unfolding bounded_def dist_real_def
   proof(rule exI strip|erule imageE|hypsubst)+
     fix n
     obtain x y where [simp]: "xy = (x, y)" by(cases xy)
     have "h n (x, y) \<le> d_OUT (h n) x" unfolding d_OUT_def by(rule nn_integral_ge_point) simp
     also have "\<dots> \<le> weight \<Gamma> x" by(simp add: h_OUT)
     finally show "\<bar>0 - h n xy\<bar> \<le> enn2real (weight \<Gamma> (fst xy))"
       by(simp add: h_nonneg)(metis enn2real_ennreal ennreal_cases ennreal_le_iff weight_finite)
   qed
   moreover have "countable ?Q" using countable_V by(simp)
   ultimately obtain k where k: "strict_mono k" 
     and conv: "\<And>xy. xy \<in> ?Q \<Longrightarrow> convergent (\<lambda>n. h (k n) xy)"
     by(rule convergent_bounded_family) blast+
 
   have h_outside: "h n xy = 0" if "xy \<notin> ?Q" for xy n using that A_n_A[of n] A_vertex Y_vertex 
     by(auto simp add: h_def split: prod.split)
   have h_outside_AB: "h n (x, y) = 0" if "x \<notin> A \<Gamma> \<or> y \<notin> B \<Gamma>" for n x y 
     using that A_n_A[of n] Y_B[of n] by(auto simp add: h_def)
   have h_outside_E: "h n (x, y) = 0" if "(x, y) \<notin> \<^bold>E" for n x y using that unfolding h_def
     by(clarsimp)(subst dom_h', auto simp add: R_def)
 
   define H where "H xy = lim (\<lambda>n. h (k n) xy)" for xy
   have H: "(\<lambda>n. h (k n) xy) \<longlonglongrightarrow> H xy" for xy
     using conv[of xy] unfolding H_def by(cases "xy \<in> ?Q")(auto simp add: convergent_LIMSEQ_iff h_outside)
   have H_outside: "H (x, y) = 0" if "x \<notin> A \<Gamma> \<or> y \<notin> B \<Gamma>" for x y
     using that by(simp add: H_def convergent_LIMSEQ_iff h_outside_AB)
   have H': "(\<lambda>n. ennreal (h (k n) xy)) \<longlonglongrightarrow> H xy" for xy
     using H by(rule tendsto_ennrealI)
   have H_def': "H xy = lim (\<lambda>n. ennreal (h (k n) xy))" for xy by (metis H' limI)
 
   have H_OUT: "d_OUT H x = weight \<Gamma> x" if x: "x \<in> A \<Gamma>" for x
   proof -
     let ?w = "\<lambda>y. if (x, y) \<in> \<^bold>E then weight \<Gamma> y else 0"
     have sum_w: "(\<Sum>\<^sup>+ y. if edge \<Gamma> x y then weight \<Gamma> y else 0) = (\<Sum>\<^sup>+ y \<in> \<^bold>E `` {x}. weight \<Gamma> y)"
-      by(simp add: nn_integral_count_space_indicator indicator_def if_distrib cong: if_cong)
+      by(simp add: nn_integral_count_space_indicator indicator_def of_bool_def if_distrib cong: if_cong)
     have "(\<lambda>n. d_OUT (h (k n)) x) \<longlonglongrightarrow> d_OUT H x" unfolding d_OUT_def
       by(rule nn_integral_dominated_convergence[where w="?w"])(use bounded_B x in \<open>simp_all add: AE_count_space H h_outside_E h_le_weight2 sum_w\<close>)
     moreover define n_x where "n_x = to_nat_on (A \<Gamma>) x"
     have x': "x \<in> A_n (k n)" if "n \<ge> n_x" for n
       using that seq_suble[OF k, of n] x unfolding A_n_def
       by(intro rev_image_eqI[where x=n_x])(simp_all add: A_n_def n_x_def)
     have "(\<lambda>n. d_OUT (h (k n)) x) \<longlonglongrightarrow> weight \<Gamma> x"
       by(intro tendsto_eventually eventually_sequentiallyI[where c="n_x"])(simp add: h_OUT x')
     ultimately show ?thesis by(rule LIMSEQ_unique)
   qed
   then have "linkage \<Gamma> H" ..
   moreover
   have "web_flow \<Gamma> H" unfolding web_flow_iff
   proof
     show "d_OUT H x \<le> weight \<Gamma> x" for x
       by(cases "x \<in> A \<Gamma>")(simp_all add: H_OUT[unfolded d_OUT_def] H_outside d_OUT_def)
 
     show "d_IN H y \<le> weight \<Gamma> y" for y
     proof -
       have "d_IN H y = (\<Sum>\<^sup>+ x. liminf (\<lambda>n. ennreal (h (k n) (x, y))))" unfolding d_IN_def H_def'
         by(rule nn_integral_cong convergent_liminf_cl[symmetric] convergentI H')+
       also have "\<dots> \<le> liminf (\<lambda>n. d_IN (h (k n)) y)"
         unfolding d_IN_def by(rule nn_integral_liminf) simp
       also have "\<dots> \<le> liminf (\<lambda>n. weight \<Gamma> y)" unfolding h_IN
         by(rule Liminf_mono)(auto simp add: ennreal_enn2real_if)
       also have "\<dots> = weight \<Gamma> y" by(simp add: Liminf_const)
       finally show "?thesis" .
     qed
 
     show "ennreal (H e) = 0" if "e \<notin> \<^bold>E" for e
     proof(rule LIMSEQ_unique[OF H'])   
       obtain x y where [simp]: "e = (x, y)" by(cases e)
       have "ennreal (h (k n) (x, y)) = 0" for n
         using dom_h'[of "Some x" y "k n"] that by(auto simp add: h_def R_def enn2real_eq_0_iff elim: meta_mp)
       then show "(\<lambda>n. ennreal (h (k n) e)) \<longlonglongrightarrow> 0" using that 
         by(intro tendsto_eventually eventually_sequentiallyI) simp
     qed
   qed
   ultimately show ?thesis by blast
 qed
 
 end
 
 subsection \<open>Glueing the reductions together\<close>
 
 locale bounded_countable_web = countable_web \<Gamma>
   for \<Gamma> :: "('v, 'more) web_scheme" (structure)
   +
   assumes bounded_out: "x \<in> \<^bold>V - B \<Gamma> \<Longrightarrow> (\<Sum>\<^sup>+ y \<in> \<^bold>E `` {x}. weight \<Gamma> y) < \<top>"
 begin
 
 lemma bounded_countable_bipartite_web_of: "bounded_countable_bipartite_web (bipartite_web_of \<Gamma>)"
   (is "bounded_countable_bipartite_web ?\<Gamma>")
 proof -
   interpret bi: countable_bipartite_web ?\<Gamma> by(rule countable_bipartite_web_of)
   show ?thesis
   proof
     fix x
     assume "x \<in> A ?\<Gamma>"
     then obtain x' where x: "x = Inl x'" and x': "vertex \<Gamma> x'" "x' \<notin> B \<Gamma>" by auto
     have "\<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {x} \<subseteq> Inr ` ({x'} \<union> (\<^bold>E `` {x'}))" using x 
       by(auto simp add: bipartite_web_of_def vertex_def split: sum.split_asm)
     hence "(\<Sum>\<^sup>+ y \<in> \<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {x}. weight ?\<Gamma> y) \<le> (\<Sum>\<^sup>+ y \<in> \<dots>. weight ?\<Gamma> y)"
       by(auto simp add: nn_integral_count_space_indicator intro!: nn_integral_mono split: split_indicator)
     also have "\<dots> = (\<Sum>\<^sup>+ y\<in>{x'} \<union> (\<^bold>E `` {x'}). weight (bipartite_web_of \<Gamma>) (Inr y))"
       by(rule nn_integral_count_space_reindex)(auto)
     also have "\<dots> \<le> weight \<Gamma> x' + (\<Sum>\<^sup>+ y \<in> \<^bold>E `` {x'}. weight \<Gamma> y)"
       apply(subst (1 2) nn_integral_count_space_indicator, simp, simp)
       apply(cases "\<not> edge \<Gamma> x' x'")
       apply(subst nn_integral_disjoint_pair)
       apply(auto intro!: nn_integral_mono add_increasing split: split_indicator)
       done
     also have "\<dots> < \<top>" using bounded_out[of x'] x' using weight_finite[of x'] by(simp del: weight_finite add: less_top)
     finally show "(\<Sum>\<^sup>+ y \<in> \<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {x}. weight ?\<Gamma> y) < \<top>"  .
   qed
 qed
 
 theorem loose_linkable_bounded:
   assumes "loose \<Gamma>"
   shows "linkable \<Gamma>"
 proof -
   interpret bi: bounded_countable_bipartite_web "bipartite_web_of \<Gamma>" by(rule bounded_countable_bipartite_web_of)
   have "\<not> hindered (bipartite_web_of \<Gamma>)" using assms by(rule unhindered_bipartite_web_of)
   then have "linkable (bipartite_web_of \<Gamma>)"
     by(rule bi.unhindered_linkable_bounded)
   then show ?thesis by(rule linkable_bipartite_web_ofD) simp
 qed
 
 lemma bounded_countable_web_quotient_web: "bounded_countable_web (quotient_web \<Gamma> f)" (is "bounded_countable_web ?\<Gamma>")
 proof -
   interpret r: countable_web ?\<Gamma> by(rule countable_web_quotient_web)
   show ?thesis
   proof
     fix x
     assume "x \<in> \<^bold>V\<^bsub>quotient_web \<Gamma> f\<^esub> - B (quotient_web \<Gamma> f)"
     then have x: "x \<in> \<^bold>V - B \<Gamma>" by(auto dest: vertex_quotient_webD)
     have "(\<Sum>\<^sup>+ y \<in> \<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {x}. weight ?\<Gamma> y) \<le> (\<Sum>\<^sup>+ y \<in> \<^bold>E `` {x}. weight \<Gamma> y)"
       by(auto simp add: nn_integral_count_space_indicator intro!: nn_integral_mono split: split_indicator)
     also have "\<dots> < \<top>" using x by(rule bounded_out)
     finally show "(\<Sum>\<^sup>+ y \<in> \<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {x}. weight ?\<Gamma> y) < \<top>"  .
   qed
 qed
 
 lemma ex_orthogonal_current:
   "\<exists>f S. web_flow \<Gamma> f \<and> separating \<Gamma> S \<and> orthogonal_current \<Gamma> f S"
 proof -
   from ex_maximal_wave[OF countable]
   obtain f where f: "current \<Gamma> f"
     and w: "wave \<Gamma> f"
     and maximal: "\<And>w. \<lbrakk> current \<Gamma> w; wave \<Gamma> w; f \<le> w \<rbrakk> \<Longrightarrow> f = w" by blast
   from ex_trimming[OF f w countable weight_finite] obtain h where h: "trimming \<Gamma> f h" ..
 
   let ?\<Gamma> = "quotient_web \<Gamma> f"
   interpret \<Gamma>: bounded_countable_web "?\<Gamma>" by(rule bounded_countable_web_quotient_web)
   have "loose ?\<Gamma>" using f w maximal by(rule loose_quotient_web[OF  weight_finite])
   then have "linkable ?\<Gamma>" by(rule \<Gamma>.loose_linkable_bounded)
   then obtain g where wg: "web_flow ?\<Gamma> g" and link: "linkage ?\<Gamma> g" by blast
 
   let ?k = "plus_current h g"
   have "web_flow \<Gamma> ?k" "orthogonal_current \<Gamma> ?k (\<E> (TER f))"
     by(rule linkage_quotient_webD[OF f w wg link h])+
   moreover have "separating \<Gamma> (\<E> (TER f))"
     using waveD_separating[OF w] by(rule separating_essential)
   ultimately show ?thesis by blast
 qed
 
 end
 
 locale bounded_countable_network = countable_network \<Delta>
   for \<Delta> :: "('v, 'more) network_scheme" (structure) +
   assumes out: "\<lbrakk> x \<in> \<^bold>V; x \<noteq> source \<Delta> \<rbrakk> \<Longrightarrow> d_OUT (capacity \<Delta>) x < \<top>"
 
 context antiparallel_edges begin
 
 lemma \<Delta>''_bounded_countable_network: "bounded_countable_network \<Delta>''"
   if "\<And>x. \<lbrakk> x \<in> \<^bold>V; x \<noteq> source \<Delta> \<rbrakk> \<Longrightarrow> d_OUT (capacity \<Delta>) x < \<top>"
 proof -
   interpret ae: countable_network \<Delta>'' by(rule \<Delta>''_countable_network)
   show ?thesis
   proof
     fix x
     assume x: "x \<in> \<^bold>V\<^bsub>\<Delta>''\<^esub>" and not_source: "x \<noteq> source \<Delta>''"
     from x consider (Vertex) x' where "x = Vertex x'" "x' \<in> \<^bold>V" | (Edge) y z where "x = Edge y z" "edge \<Delta> y z"
       unfolding "\<^bold>V_\<Delta>''" by auto
     then show "d_OUT (capacity \<Delta>'') x < \<top>"
     proof cases
       case Vertex
       then show ?thesis using x not_source that[of x'] by auto
     next
       case Edge
       then show ?thesis using capacity_finite[of "(y, z)"] by(simp del: capacity_finite add: less_top)
     qed
   qed
 qed
 
 end
 
 context bounded_countable_network begin
 
 lemma bounded_countable_web_web_of_network: 
   assumes source_in: "\<And>x. \<not> edge \<Delta> x (source \<Delta>)"
   and sink_out: "\<And>y. \<not> edge \<Delta> (sink \<Delta>) y"
   and undead: "\<And>x y. edge \<Delta> x y \<Longrightarrow> (\<exists>z. edge \<Delta> y z) \<or> (\<exists>z. edge \<Delta> z x)"
   and source_sink: "\<not> edge \<Delta> (source \<Delta>) (sink \<Delta>)"
   and no_loop: "\<And>x. \<not> edge \<Delta> x x"
   shows "bounded_countable_web (web_of_network \<Delta>)" (is "bounded_countable_web ?\<Gamma>")
 proof -
   interpret web: countable_web ?\<Gamma> by(rule countable_web_web_of_network) fact+
   show ?thesis
   proof
     fix e
     assume "e \<in> \<^bold>V\<^bsub>?\<Gamma>\<^esub> - B ?\<Gamma>"
     then obtain x y where e: "e = (x, y)" and xy: "edge \<Delta> x y" by(cases e) simp
     from xy have y: "y \<noteq> source \<Delta>" using source_in[of x] by auto
     have "\<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {e} \<subseteq> \<^bold>E \<inter> {y} \<times> UNIV" using e by auto
     hence "(\<Sum>\<^sup>+ e' \<in> \<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {e}. weight ?\<Gamma> e') \<le> (\<Sum>\<^sup>+ e \<in> \<^bold>E \<inter> {y} \<times> UNIV. capacity \<Delta> e)" using e
       by(auto simp add: nn_integral_count_space_indicator intro!: nn_integral_mono split: split_indicator)
     also have "\<dots> \<le> (\<Sum>\<^sup>+ e \<in> Pair y ` UNIV. capacity \<Delta> e)"
       by(auto simp add: nn_integral_count_space_indicator intro!: nn_integral_mono split: split_indicator)
     also have "\<dots> = d_OUT (capacity \<Delta>) y" unfolding d_OUT_def
       by(rule nn_integral_count_space_reindex) simp
     also have "\<dots> < \<top>" using out[of y] xy y by(auto simp add: vertex_def)
     finally show "(\<Sum>\<^sup>+ e' \<in> \<^bold>E\<^bsub>?\<Gamma>\<^esub> `` {e}. weight ?\<Gamma> e') < \<top>" .
   qed
 qed
 
 context begin
 
 qualified lemma max_flow_min_cut'_bounded:
   assumes source_in: "\<And>x. \<not> edge \<Delta> x (source \<Delta>)"
   and sink_out: "\<And>y. \<not> edge \<Delta> (sink \<Delta>) y"
   and undead: "\<And>x y. edge \<Delta> x y \<Longrightarrow> (\<exists>z. edge \<Delta> y z) \<or> (\<exists>z. edge \<Delta> z x)"
   and source_sink: "\<not> edge \<Delta> (source \<Delta>) (sink \<Delta>)"
   and no_loop: "\<And>x. \<not> edge \<Delta> x x"
   and capacity_pos: "\<And>e. e \<in> \<^bold>E \<Longrightarrow> capacity \<Delta> e > 0"
   shows "\<exists>f S. flow \<Delta> f \<and> cut \<Delta> S \<and> orthogonal \<Delta> f S"
   by(rule max_flow_min_cut')(rule bounded_countable_web.ex_orthogonal_current[OF bounded_countable_web_web_of_network], fact+)
 
 qualified lemma max_flow_min_cut''_bounded:
   assumes sink_out: "\<And>y. \<not> edge \<Delta> (sink \<Delta>) y"
   and source_in: "\<And>x. \<not> edge \<Delta> x (source \<Delta>)"
   and no_loop: "\<And>x. \<not> edge \<Delta> x x"
   and capacity_pos: "\<And>e. e \<in> \<^bold>E \<Longrightarrow> capacity \<Delta> e > 0"
   shows "\<exists>f S. flow \<Delta> f \<and> cut \<Delta> S \<and> orthogonal \<Delta> f S"
 proof -
   interpret antiparallel_edges \<Delta> ..
   interpret \<Delta>'': bounded_countable_network \<Delta>'' by(rule \<Delta>''_bounded_countable_network)(rule out)
   have "\<exists>f S. flow \<Delta>'' f \<and> cut \<Delta>'' S \<and> orthogonal \<Delta>'' f S"
     by(rule \<Delta>''.max_flow_min_cut'_bounded)(auto simp add: sink_out source_in no_loop capacity_pos elim: edg.cases)
   then obtain f S where f: "flow \<Delta>'' f" and cut: "cut \<Delta>'' S" and ortho: "orthogonal \<Delta>'' f S" by blast
   have "flow \<Delta> (collect f)" using f by(rule flow_collect)
   moreover have "cut \<Delta> (cut' S)" using cut by(rule cut_cut')
   moreover have "orthogonal \<Delta> (collect f) (cut' S)" using ortho f by(rule orthogonal_cut')
   ultimately show ?thesis by blast
 qed
 
 qualified lemma max_flow_min_cut'''_bounded:
   assumes sink_out: "\<And>y. \<not> edge \<Delta> (sink \<Delta>) y"
   and source_in: "\<And>x. \<not> edge \<Delta> x (source \<Delta>)"
   and capacity_pos: "\<And>e. e \<in> \<^bold>E \<Longrightarrow> capacity \<Delta> e > 0"
   shows "\<exists>f S. flow \<Delta> f \<and> cut \<Delta> S \<and> orthogonal \<Delta> f S"
 proof -
   interpret antiparallel_edges \<Delta> ..
   interpret \<Delta>'': bounded_countable_network \<Delta>'' by(rule \<Delta>''_bounded_countable_network)(rule out)
   have "\<exists>f S. flow \<Delta>'' f \<and> cut \<Delta>'' S \<and> orthogonal \<Delta>'' f S"
     by(rule \<Delta>''.max_flow_min_cut''_bounded)(auto simp add: sink_out source_in capacity_pos elim: edg.cases)
   then obtain f S where f: "flow \<Delta>'' f" and cut: "cut \<Delta>'' S" and ortho: "orthogonal \<Delta>'' f S" by blast
   have "flow \<Delta> (collect f)" using f by(rule flow_collect)
   moreover have "cut \<Delta> (cut' S)" using cut by(rule cut_cut')
   moreover have "orthogonal \<Delta> (collect f) (cut' S)" using ortho f by(rule orthogonal_cut')
   ultimately show ?thesis by blast
 qed
 
 lemma \<Delta>'''_bounded_countable_network: "bounded_countable_network \<Delta>'''"
 proof -
   interpret \<Delta>''': countable_network \<Delta>''' by(rule \<Delta>'''_countable_network)
   show ?thesis 
   proof
     fix x
     assume x: "x \<in> \<^bold>V\<^bsub>\<Delta>'''\<^esub>" and not_source: "x \<noteq> source \<Delta>'''"
     from x have x': "x \<in> \<^bold>V" by(auto simp add: vertex_def)
     have "d_OUT (capacity \<Delta>''') x \<le> d_OUT (capacity \<Delta>) x" by(rule d_OUT_mono) simp
     also have "\<dots> < \<top>" using x' not_source by(simp add: out)
     finally show "d_OUT (capacity \<Delta>''') x < \<top>"  .
   qed
 qed
 
 theorem max_flow_min_cut_bounded:
   "\<exists>f S. flow \<Delta> f \<and> cut \<Delta> S \<and> orthogonal \<Delta> f S"
 proof -
   interpret \<Delta>': bounded_countable_network \<Delta>''' by(rule \<Delta>'''_bounded_countable_network)
   have "\<exists>f S. flow \<Delta>''' f \<and> cut \<Delta>''' S \<and> orthogonal \<Delta>''' f S" by(rule \<Delta>'.max_flow_min_cut'''_bounded) auto
   then obtain f S where f: "flow \<Delta>''' f" and cut: "cut \<Delta>''' S" and ortho: "orthogonal \<Delta>''' f S" by blast
   from flow_\<Delta>'''[OF this] show ?thesis by blast
 qed
 
 end
 
 end
 
 end
diff --git a/thys/Prime_Number_Theorem/Prime_Number_Theorem_Library.thy b/thys/Prime_Number_Theorem/Prime_Number_Theorem_Library.thy
--- a/thys/Prime_Number_Theorem/Prime_Number_Theorem_Library.thy
+++ b/thys/Prime_Number_Theorem/Prime_Number_Theorem_Library.thy
@@ -1,2041 +1,2041 @@
 section \<open>Auxiliary material\<close>
 theory Prime_Number_Theorem_Library
 imports
   Zeta_Function.Zeta_Function
   "HOL-Real_Asymp.Real_Asymp"
 begin
 
 (* TODO: Move *)
 lemma asymp_equivD_strong:
   assumes "f \<sim>[F] g" "eventually (\<lambda>x. f x \<noteq> 0 \<or> g x \<noteq> 0) F"
   shows   "((\<lambda>x. f x / g x) \<longlongrightarrow> 1) F"
 proof -
   from assms(1) have "((\<lambda>x. if f x = 0 \<and> g x = 0 then 1 else f x / g x) \<longlongrightarrow> 1) F"
     by (rule asymp_equivD)
   also have "?this \<longleftrightarrow> ?thesis"
     by (intro filterlim_cong eventually_mono[OF assms(2)]) auto
   finally show ?thesis .
 qed
 
 lemma frontier_real_Ici [simp]:
   fixes a :: real
   shows "frontier {a..} = {a}"
   unfolding frontier_def by (auto simp: interior_real_atLeast)
 
 lemma sum_upto_ln_conv_sum_upto_mangoldt:
   "sum_upto (\<lambda>n. ln (real n)) x = sum_upto (\<lambda>n. mangoldt n * nat \<lfloor>x / real n\<rfloor>) x"
 proof -
   have "sum_upto (\<lambda>n. ln (real n)) x =
           sum_upto (\<lambda>n. \<Sum>d | d dvd n. mangoldt d) x"
     by (intro sum_upto_cong) (simp_all add: mangoldt_sum)
   also have "\<dots> = sum_upto (\<lambda>k. sum_upto (\<lambda>d. mangoldt k) (x / real k)) x"
     by (rule sum_upto_sum_divisors)
   also have "\<dots> = sum_upto (\<lambda>n. mangoldt n * nat \<lfloor>x / real n\<rfloor>) x"
     unfolding sum_upto_altdef by (simp add: mult_ac)
   finally show ?thesis .
 qed
 
 lemma ln_fact_conv_sum_upto_mangoldt:
   "ln (fact n) = sum_upto (\<lambda>k. mangoldt k * (n div k)) n"
 proof -
   have [simp]: "{0<..Suc n} = insert (Suc n) {0<..n}" for n by auto
   have "ln (fact n) = sum_upto (\<lambda>n. ln (real n)) n"
     by (induction n) (auto simp: sum_upto_altdef nat_add_distrib ln_mult)
   also have "\<dots> = sum_upto (\<lambda>k. mangoldt k * (n div k)) n"
     unfolding sum_upto_ln_conv_sum_upto_mangoldt
     by (intro sum_upto_cong) (auto simp: floor_divide_of_nat_eq)
   finally show ?thesis .
 qed
 
 lemma powr_sum: "x \<noteq> 0 \<Longrightarrow> finite A \<Longrightarrow> x powr sum f A = (\<Prod>y\<in>A. x powr f y)"
   by (simp add: powr_def exp_sum sum_distrib_right)
 
 lemma fds_abs_converges_comparison_test:
   fixes s :: "'a :: dirichlet_series"
   assumes "eventually (\<lambda>n. norm (fds_nth f n) \<le> fds_nth g n) at_top" and "fds_converges g (s \<bullet> 1)"
   shows   "fds_abs_converges f s"
   unfolding fds_abs_converges_def
 proof (rule summable_comparison_test_ev)
   from assms(2) show "summable (\<lambda>n. fds_nth g n / n powr (s \<bullet> 1))"
     by (auto simp: fds_converges_def)
   from assms(1) eventually_gt_at_top[of 0]
     show "eventually (\<lambda>n. norm (norm (fds_nth f n / nat_power n s)) \<le>
                             fds_nth g n / real n powr (s \<bullet> 1)) at_top"
     by eventually_elim (auto simp: norm_divide norm_nat_power intro!: divide_right_mono)
 qed
 
 lemma fds_converges_scaleR [intro]:
   assumes "fds_converges f s"
   shows   "fds_converges (c *\<^sub>R f) s"
 proof -
   from assms have "summable (\<lambda>n. c *\<^sub>R (fds_nth f n / nat_power n s))"
     by (intro summable_scaleR_right) (auto simp: fds_converges_def)
   also have "(\<lambda>n. c *\<^sub>R (fds_nth f n / nat_power n s)) = (\<lambda>n. (c *\<^sub>R fds_nth f n / nat_power n s))"
     by (simp add: scaleR_conv_of_real)
   finally show ?thesis by (simp add: fds_converges_def)
 qed
 
 lemma fds_abs_converges_scaleR [intro]:
   assumes "fds_abs_converges f s"
   shows   "fds_abs_converges (c *\<^sub>R f) s"
 proof -
   from assms have "summable (\<lambda>n. abs c * norm (fds_nth f n / nat_power n s))"
     by (intro summable_mult) (auto simp: fds_abs_converges_def)
   also have "(\<lambda>n. abs c * norm (fds_nth f n / nat_power n s)) =
                (\<lambda>n. norm ((c *\<^sub>R fds_nth f n) / nat_power n s))" by (simp add: norm_divide)
   finally show ?thesis by (simp add: fds_abs_converges_def)
 qed
 
 lemma conv_abscissa_scaleR: "conv_abscissa (scaleR c f) \<le> conv_abscissa f"
   by (rule conv_abscissa_mono) auto
 
 lemma abs_conv_abscissa_scaleR: "abs_conv_abscissa (scaleR c f) \<le> abs_conv_abscissa f"
   by (rule abs_conv_abscissa_mono) auto
 
 lemma fds_converges_mult_const_left [intro]:
   "fds_converges f s \<Longrightarrow> fds_converges (fds_const c * f) s"
   by (auto simp: fds_converges_def dest: summable_mult[of _ c])
 
 lemma fds_abs_converges_mult_const_left [intro]:
   "fds_abs_converges f s \<Longrightarrow> fds_abs_converges (fds_const c * f) s"
   by (auto simp: fds_abs_converges_def norm_mult norm_divide dest: summable_mult[of _ "norm c"])
 
 lemma conv_abscissa_mult_const_left:
   "conv_abscissa (fds_const c * f) \<le> conv_abscissa f"
   by (intro conv_abscissa_mono) auto
 
 lemma abs_conv_abscissa_mult_const_left:
   "abs_conv_abscissa (fds_const c * f) \<le> abs_conv_abscissa f"
   by (intro abs_conv_abscissa_mono) auto
 
 lemma fds_converges_mult_const_right [intro]:
   "fds_converges f s \<Longrightarrow> fds_converges (f * fds_const c) s"
   by (auto simp: fds_converges_def dest: summable_mult2[of _ c])
 
 lemma fds_abs_converges_mult_const_right [intro]:
   "fds_abs_converges f s \<Longrightarrow> fds_abs_converges (f * fds_const c) s"
   by (auto simp: fds_abs_converges_def norm_mult norm_divide dest: summable_mult2[of _ "norm c"])
 
 lemma conv_abscissa_mult_const_right:
   "conv_abscissa (f * fds_const c) \<le> conv_abscissa f"
   by (intro conv_abscissa_mono) auto
 
 lemma abs_conv_abscissa_mult_const_right:
   "abs_conv_abscissa (f * fds_const c) \<le> abs_conv_abscissa f"
   by (intro abs_conv_abscissa_mono) auto
 
 
 lemma bounded_coeffs_imp_fds_abs_converges:
   fixes s :: "'a :: dirichlet_series" and f :: "'a fds"
   assumes "Bseq (fds_nth f)" "s \<bullet> 1 > 1"
   shows   "fds_abs_converges f s"
 proof -
   from assms obtain C where C: "\<And>n. norm (fds_nth f n) \<le> C"
     by (auto simp: Bseq_def)
   show ?thesis
   proof (rule fds_abs_converges_comparison_test)
     from \<open>s \<bullet> 1 > 1\<close> show "fds_converges (C *\<^sub>R fds_zeta) (s \<bullet> 1)"
       by (intro fds_abs_converges_imp_converges) auto
     from C show "eventually (\<lambda>n. norm (fds_nth f n) \<le> fds_nth (C *\<^sub>R fds_zeta) n) at_top"
       by (intro always_eventually) (auto simp: fds_nth_zeta)
   qed
 qed
 
 lemma bounded_coeffs_imp_fds_abs_converges':
   fixes s :: "'a :: dirichlet_series" and f :: "'a fds"
   assumes "Bseq (\<lambda>n. fds_nth f n * nat_power n s0)" "s \<bullet> 1 > 1 - s0 \<bullet> 1"
   shows   "fds_abs_converges f s"
 proof -
   have "fds_nth (fds_shift s0 f) = (\<lambda>n. fds_nth f n * nat_power n s0)"
     by (auto simp: fun_eq_iff)
   with assms have "Bseq (fds_nth (fds_shift s0 f))" by simp
   with assms(2) have "fds_abs_converges (fds_shift s0 f) (s + s0)"
     by (intro bounded_coeffs_imp_fds_abs_converges) (auto simp: algebra_simps)
   thus ?thesis by simp
 qed
 
 lemma bounded_coeffs_imp_abs_conv_abscissa_le:
   fixes s :: "'a :: dirichlet_series" and f :: "'a fds" and c :: ereal
   assumes "Bseq (\<lambda>n. fds_nth f n * nat_power n s)" "1 - s \<bullet> 1 \<le> c"
   shows   "abs_conv_abscissa f \<le> c"
 proof (rule abs_conv_abscissa_leI_weak)
   fix x assume "c < ereal x"
   have "ereal (1 - s \<bullet> 1) \<le> c" by fact
   also have "\<dots> < ereal x" by fact
   finally have "1 - s \<bullet> 1 < ereal x" by simp
   thus "fds_abs_converges f (of_real x)"
     by (intro bounded_coeffs_imp_fds_abs_converges'[OF assms(1)]) auto
 qed
 
 lemma bounded_coeffs_imp_abs_conv_abscissa_le_1:
   fixes s :: "'a :: dirichlet_series" and f :: "'a fds"
   assumes "Bseq (\<lambda>n. fds_nth f n)"
   shows   "abs_conv_abscissa f \<le> 1"
 proof -
   have [simp]: "fds_nth f n * nat_power n 0 = fds_nth f n" for n
     by (cases "n = 0") auto
   show ?thesis
     by (rule bounded_coeffs_imp_abs_conv_abscissa_le[where s = 0]) (insert assms, auto simp:)
 qed
 
 (* TODO: replace library version *)
 (* EXAMPLE: This might make a good example to illustrate real_asymp *)
 lemma
   fixes a b c :: real
   assumes ab: "a + b > 0" and c: "c < -1"
   shows set_integrable_powr_at_top: "(\<lambda>x. (b + x) powr c) absolutely_integrable_on {a<..}"
   and   set_lebesgue_integral_powr_at_top:
           "(\<integral>x\<in>{a<..}. ((b + x) powr c) \<partial>lborel) = -((b + a) powr (c + 1) / (c + 1))"
   and   powr_has_integral_at_top:
           "((\<lambda>x. (b + x) powr c) has_integral -((b + a) powr (c + 1) / (c + 1))) {a<..}"
 proof -
   let ?f = "\<lambda>x. (b + x) powr c" and ?F = "\<lambda>x. (b + x) powr (c + 1) / (c + 1)"
   have limits: "((?F \<circ> real_of_ereal) \<longlongrightarrow> ?F a) (at_right (ereal a))"
                "((?F \<circ> real_of_ereal) \<longlongrightarrow> 0) (at_left \<infinity>)"
     using c ab unfolding ereal_tendsto_simps1 by (real_asymp simp: field_simps)+
   have 1: "set_integrable lborel (einterval a \<infinity>) ?f" using ab c limits
     by (intro interval_integral_FTC_nonneg) (auto intro!: derivative_eq_intros)
   thus 2: "?f absolutely_integrable_on {a<..}"
     by (auto simp: set_integrable_def integrable_completion)
   have "LBINT x=ereal a..\<infinity>. (b + x) powr c = 0 - ?F a" using ab c limits
     by (intro interval_integral_FTC_nonneg) (auto intro!: derivative_eq_intros)
   thus 3: "(\<integral>x\<in>{a<..}. ((b + x) powr c) \<partial>lborel) = -((b + a) powr (c + 1) / (c + 1))"
     by (simp add: interval_integral_to_infinity_eq)
   show "(?f has_integral -((b + a) powr (c + 1) / (c + 1))) {a<..}"
     using set_borel_integral_eq_integral[OF 1] 3 by (simp add: has_integral_iff)
 qed
 
 lemma fds_converges_altdef2:
   "fds_converges f s \<longleftrightarrow> convergent (\<lambda>N. eval_fds (fds_truncate N f) s)"
   unfolding fds_converges_def summable_iff_convergent' eval_fds_truncate
   by (auto simp: not_le intro!: convergent_cong always_eventually sum.mono_neutral_right)
 
 lemma tendsto_eval_fds_truncate:
   assumes "fds_converges f s"
   shows   "(\<lambda>N. eval_fds (fds_truncate N f) s) \<longlonglongrightarrow> eval_fds f s"
 proof -
   have "(\<lambda>N. eval_fds (fds_truncate N f) s) \<longlonglongrightarrow> eval_fds f s \<longleftrightarrow>
           (\<lambda>N. \<Sum>i\<le>N. fds_nth f i / nat_power i s) \<longlonglongrightarrow> eval_fds f s"
     unfolding eval_fds_truncate
     by (intro filterlim_cong always_eventually allI sum.mono_neutral_left) (auto simp: not_le)
   also have \<dots> using assms
     by (simp add: fds_converges_iff sums_def' atLeast0AtMost)
   finally show ?thesis .
 qed
 
 lemma linepath_translate_left: "linepath (c + a) (c + a) = (\<lambda>x. c + a) \<circ> linepath a b"
   by (auto simp: fun_eq_iff linepath_def algebra_simps)
 
 lemma linepath_translate_right: "linepath (a + c) (b + c) = (\<lambda>x. x + c) \<circ> linepath a b"
   by (auto simp: fun_eq_iff linepath_def algebra_simps)
 
 lemma integrable_on_affinity:
   assumes "m \<noteq> 0" "f integrable_on (cbox a b)"
   shows   "(\<lambda>x. f (m *\<^sub>R x + c)) integrable_on ((\<lambda>x. (1 / m) *\<^sub>R x - ((1 / m) *\<^sub>R c)) ` cbox a b)"
 proof -
   from assms obtain I where "(f has_integral I) (cbox a b)"
     by (auto simp: integrable_on_def)
   from has_integral_affinity[OF this assms(1), of c] show ?thesis
     by (auto simp: integrable_on_def)
 qed
 
 lemma has_integral_cmul_iff:
   assumes "c \<noteq> 0"
   shows   "((\<lambda>x. c *\<^sub>R f x) has_integral (c *\<^sub>R I)) A \<longleftrightarrow> (f has_integral I) A"
   using assms has_integral_cmul[of f I A c]
         has_integral_cmul[of "\<lambda>x. c *\<^sub>R f x" "c *\<^sub>R I" A "inverse c"] by (auto simp: field_simps)
 
 lemma has_integral_affinity':
   fixes a :: "'a::euclidean_space"
   assumes "(f has_integral i) (cbox a b)" and "m > 0"
   shows "((\<lambda>x. f(m *\<^sub>R x + c)) has_integral (i /\<^sub>R m ^ DIM('a)))
            (cbox ((a - c) /\<^sub>R m) ((b - c) /\<^sub>R m))"
 proof (cases "cbox a b = {}")
   case True
   hence "(cbox ((a - c) /\<^sub>R m) ((b - c) /\<^sub>R m)) = {}"
     using \<open>m > 0\<close> unfolding box_eq_empty by (auto simp: algebra_simps)
   with True and assms show ?thesis by simp
 next
   case False
   have "((\<lambda>x. f (m *\<^sub>R x + c)) has_integral (1 / \<bar>m\<bar> ^ DIM('a)) *\<^sub>R i)
           ((\<lambda>x. (1 / m) *\<^sub>R x + - ((1 / m) *\<^sub>R c)) ` cbox a b)"
     using assms by (intro has_integral_affinity) auto
   also have "((\<lambda>x. (1 / m) *\<^sub>R x + - ((1 / m) *\<^sub>R c)) ` cbox a b) =
                ((\<lambda>x.  - ((1 / m) *\<^sub>R c) + x) ` (\<lambda>x. (1 / m) *\<^sub>R x) ` cbox a b)"
     by (simp add: image_image algebra_simps)
   also have "(\<lambda>x. (1 / m) *\<^sub>R x) ` cbox a b = cbox ((1 / m) *\<^sub>R a) ((1 / m) *\<^sub>R b)" using \<open>m > 0\<close> False
     by (subst image_smult_cbox) simp_all
   also have "(\<lambda>x. - ((1 / m) *\<^sub>R c) + x) ` \<dots> = cbox ((a - c) /\<^sub>R m) ((b - c) /\<^sub>R m)"
     by (subst cbox_translation [symmetric]) (simp add: field_simps vector_add_divide_simps)
   finally show ?thesis using \<open>m > 0\<close> by (simp add: field_simps)
 qed
 
 lemma has_integral_affinity_iff:
   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: real_normed_vector"
   assumes "m > 0"
   shows   "((\<lambda>x. f (m *\<^sub>R x + c)) has_integral (I /\<^sub>R m ^ DIM('a)))
                (cbox ((a - c) /\<^sub>R m) ((b - c) /\<^sub>R m)) \<longleftrightarrow>
            (f has_integral I) (cbox a b)" (is "?lhs = ?rhs")
 proof
   assume ?lhs
   from has_integral_affinity'[OF this, of "1 / m" "-c /\<^sub>R m"] and \<open>m > 0\<close>
     show ?rhs by (simp add: vector_add_divide_simps) (simp add: field_simps)
 next
   assume ?rhs
   from has_integral_affinity'[OF this, of m c] and \<open>m > 0\<close>
   show ?lhs by simp
 qed
 
 lemma has_contour_integral_linepath_Reals_iff:
   fixes a b :: complex and f :: "complex \<Rightarrow> complex"
   assumes "a \<in> Reals" "b \<in> Reals" "Re a < Re b"
   shows   "(f has_contour_integral I) (linepath a b) \<longleftrightarrow>
              ((\<lambda>x. f (of_real x)) has_integral I) {Re a..Re b}"
 proof -
   from assms have [simp]: "of_real (Re a) = a" "of_real (Re b) = b"
     by (simp_all add: complex_eq_iff)
   from assms have "a \<noteq> b" by auto
   have "((\<lambda>x. f (of_real x)) has_integral I) (cbox (Re a) (Re b)) \<longleftrightarrow>
           ((\<lambda>x. f (a + b * of_real x - a * of_real x)) has_integral I /\<^sub>R (Re b - Re a)) {0..1}"
     by (subst has_integral_affinity_iff [of "Re b - Re a" _ "Re a", symmetric])
        (insert assms, simp_all add: field_simps scaleR_conv_of_real)
   also have "(\<lambda>x. f (a + b * of_real x - a * of_real x)) =
                (\<lambda>x. (f (a + b * of_real x - a * of_real x) * (b - a)) /\<^sub>R (Re b - Re a))"
     using \<open>a \<noteq> b\<close> by (auto simp: field_simps fun_eq_iff scaleR_conv_of_real)
   also have "(\<dots> has_integral I /\<^sub>R (Re b - Re a)) {0..1} \<longleftrightarrow>
                ((\<lambda>x. f (linepath a b x) * (b - a)) has_integral I) {0..1}" using assms
     by (subst has_integral_cmul_iff) (auto simp: linepath_def scaleR_conv_of_real algebra_simps)
   also have "\<dots> \<longleftrightarrow> (f has_contour_integral I) (linepath a b)" unfolding has_contour_integral_def
     by (intro has_integral_cong) (simp add: vector_derivative_linepath_within)
   finally show ?thesis by simp
 qed
 
 lemma contour_integrable_linepath_Reals_iff:
   fixes a b :: complex and f :: "complex \<Rightarrow> complex"
   assumes "a \<in> Reals" "b \<in> Reals" "Re a < Re b"
   shows   "(f contour_integrable_on linepath a b) \<longleftrightarrow>
              (\<lambda>x. f (of_real x)) integrable_on {Re a..Re b}"
   using has_contour_integral_linepath_Reals_iff[OF assms, of f]
   by (auto simp: contour_integrable_on_def integrable_on_def)
 
 lemma contour_integral_linepath_Reals_eq:
   fixes a b :: complex and f :: "complex \<Rightarrow> complex"
   assumes "a \<in> Reals" "b \<in> Reals" "Re a < Re b"
   shows   "contour_integral (linepath a b) f = integral {Re a..Re b} (\<lambda>x. f (of_real x))"
 proof (cases "f contour_integrable_on linepath a b")
   case True
   thus ?thesis using has_contour_integral_linepath_Reals_iff[OF assms, of f]
     using has_contour_integral_integral has_contour_integral_unique by blast
 next
   case False
   thus ?thesis using contour_integrable_linepath_Reals_iff[OF assms, of f]
     by (simp add: not_integrable_contour_integral not_integrable_integral)
 qed
 
 lemma has_contour_integral_linepath_same_Im_iff:
   fixes a b :: complex and f :: "complex \<Rightarrow> complex"
   assumes "Im a = Im b" "Re a < Re b"
   shows   "(f has_contour_integral I) (linepath a b) \<longleftrightarrow>
              ((\<lambda>x. f (of_real x + Im a * \<i>)) has_integral I) {Re a..Re b}"
 proof -
   have deriv: "vector_derivative ((\<lambda>x. x - Im a * \<i>) \<circ> linepath a b) (at y) = b - a" for y
     using linepath_translate_right[of a "-Im a * \<i>" b, symmetric] by simp
   have "(f has_contour_integral I) (linepath a b) \<longleftrightarrow>
           ((\<lambda>x. f (x + Im a * \<i>)) has_contour_integral I) (linepath (a - Im a * \<i>) (b - Im a * \<i>))"
     using linepath_translate_right[of a "-Im a * \<i>" b] deriv by (simp add: has_contour_integral)
   also have "\<dots> \<longleftrightarrow> ((\<lambda>x. f (x + Im a * \<i>)) has_integral I) {Re a..Re b}" using assms
     by (subst has_contour_integral_linepath_Reals_iff) (auto simp: complex_is_Real_iff)
   finally show ?thesis .
 qed
 
 lemma contour_integrable_linepath_same_Im_iff:
   fixes a b :: complex and f :: "complex \<Rightarrow> complex"
   assumes "Im a = Im b" "Re a < Re b"
   shows   "(f contour_integrable_on linepath a b) \<longleftrightarrow>
              (\<lambda>x. f (of_real x + Im a * \<i>)) integrable_on {Re a..Re b}"
   using has_contour_integral_linepath_same_Im_iff[OF assms, of f]
   by (auto simp: contour_integrable_on_def integrable_on_def)
 
 lemma contour_integral_linepath_same_Im:
   fixes a b :: complex and f :: "complex \<Rightarrow> complex"
   assumes "Im a = Im b" "Re a < Re b"
   shows   "contour_integral (linepath a b) f = integral {Re a..Re b} (\<lambda>x. f (x + Im a * \<i>))"
 proof (cases "f contour_integrable_on linepath a b")
   case True
   thus ?thesis using has_contour_integral_linepath_same_Im_iff[OF assms, of f]
     using has_contour_integral_integral has_contour_integral_unique by blast
 next
   case False
   thus ?thesis using contour_integrable_linepath_same_Im_iff[OF assms, of f]
     by (simp add: not_integrable_contour_integral not_integrable_integral)
 qed
 
 
 lemmas [simp del] = div_mult_self3 div_mult_self4 div_mult_self2 div_mult_self1
 
 lemma continuous_on_compact_bound:
   assumes "compact A" "continuous_on A f"
   obtains B where "B \<ge> 0" "\<And>x. x \<in> A \<Longrightarrow> norm (f x) \<le> B"
 proof -
   from assms(2,1) have "compact (f ` A)" by (rule compact_continuous_image)
   then obtain B where "\<forall>x\<in>A. norm (f x) \<le> B"
     by (auto dest!: compact_imp_bounded simp: bounded_iff)
   hence "max B 0 \<ge> 0" and "\<forall>x\<in>A. norm (f x) \<le> max B 0" by auto
   thus ?thesis using that by blast
 qed
 
 interpretation cis: periodic_fun_simple cis "2 * pi"
   by standard (simp_all add: complex_eq_iff)
 
 lemma open_contains_cbox:
   fixes x :: "'a :: euclidean_space"
   assumes "open A" "x \<in> A"
   obtains a b where "cbox a b \<subseteq> A" "x \<in> box a b" "\<forall>i\<in>Basis. a \<bullet> i < b \<bullet> i"
 proof -
   from assms obtain R where R: "R > 0" "ball x R \<subseteq> A"
     by (auto simp: open_contains_ball)
   define r :: real where "r = R / (2 * sqrt DIM('a))"
   from \<open>R > 0\<close> have [simp]: "r > 0" by (auto simp: r_def)
   define d :: 'a where "d = r *\<^sub>R Topology_Euclidean_Space.One"
   have "cbox (x - d) (x + d) \<subseteq> A"
   proof safe
     fix y assume y: "y \<in> cbox (x - d) (x + d)"
     have "dist x y = sqrt (\<Sum>i\<in>Basis. (dist (x \<bullet> i) (y \<bullet> i))\<^sup>2)"
       by (subst euclidean_dist_l2) (auto simp: L2_set_def)
     also from y have "sqrt (\<Sum>i\<in>Basis. (dist (x \<bullet> i) (y \<bullet> i))\<^sup>2) \<le> sqrt (\<Sum>i\<in>(Basis::'a set). r\<^sup>2)"
       by (intro real_sqrt_le_mono sum_mono power_mono)
          (auto simp: dist_norm d_def cbox_def algebra_simps)
     also have "\<dots> = sqrt (DIM('a) * r\<^sup>2)" by simp
     also have "DIM('a) * r\<^sup>2 = (R / 2) ^ 2"
       by (simp add: r_def power_divide)
     also have "sqrt \<dots> = R / 2"
       using \<open>R > 0\<close> by simp
     also from \<open>R > 0\<close> have "\<dots> < R" by simp
     finally have "y \<in> ball x R" by simp
     with R show "y \<in> A" by blast
   qed
   thus ?thesis
     using that[of "x - d" "x + d"] by (auto simp: algebra_simps d_def box_def)
 qed
 
 lemma open_contains_box:
   fixes x :: "'a :: euclidean_space"
   assumes "open A" "x \<in> A"
   obtains a b where "box a b \<subseteq> A" "x \<in> box a b" "\<forall>i\<in>Basis. a \<bullet> i < b \<bullet> i"
 proof -
   from open_contains_cbox[OF assms] guess a b .
   with that[of a b] box_subset_cbox[of a b] show ?thesis by auto
 qed
 
 lemma analytic_onE_box:
   assumes "f analytic_on A" "s \<in> A"
   obtains a b where "Re a < Re b" "Im a < Im b" "s \<in> box a b" "f analytic_on box a b"
 proof -
   from assms obtain r where r: "r > 0" "f holomorphic_on ball s r"
     by (auto simp: analytic_on_def)
   with open_contains_box[of "ball s r" s] obtain a b
     where "box a b \<subseteq> ball s r" "s \<in> box a b" "\<forall>i\<in>Basis. a \<bullet> i < b \<bullet> i" by auto
   moreover from r have "f analytic_on ball s r" by (simp add: analytic_on_open)
   ultimately show ?thesis using that[of a b] analytic_on_subset[of _ "ball s r" "box a b"]
     by (auto simp: Basis_complex_def)
 qed
 
 lemma inner_image_box:
   assumes "(i :: 'a :: euclidean_space) \<in> Basis"
   assumes "\<forall>i\<in>Basis. a \<bullet> i < b \<bullet> i"
   shows   "(\<lambda>x. x \<bullet> i) ` box a b = {a \<bullet> i<..<b \<bullet> i}"
 proof safe
   fix x assume x: "x \<in> {a \<bullet> i<..<b \<bullet> i}"
   let ?y = "(\<Sum>j\<in>Basis. (if i = j then x else (a + b) \<bullet> j / 2) *\<^sub>R j)"
   from x assms have "?y \<bullet> i \<in> (\<lambda>x. x \<bullet> i) ` box a b"
     by (intro imageI) (auto simp: box_def algebra_simps)
   also have "?y \<bullet> i = (\<Sum>j\<in>Basis. (if i = j then x else (a + b) \<bullet> j / 2) * (j \<bullet> i))"
     by (simp add: inner_sum_left)
   also have "\<dots> = (\<Sum>j\<in>Basis. if i = j then x else 0)"
     by (intro sum.cong) (auto simp: inner_not_same_Basis assms)
   also have "\<dots> = x" using assms by simp
   finally show "x \<in> (\<lambda>x. x \<bullet> i) ` box a b"  .
 qed (insert assms, auto simp: box_def)
 
 lemma Re_image_box:
   assumes "Re a < Re b" "Im a < Im b"
   shows   "Re ` box a b = {Re a<..<Re b}"
   using inner_image_box[of "1::complex" a b] assms by (auto simp: Basis_complex_def)
 
 lemma Im_image_box:
   assumes "Re a < Re b" "Im a < Im b"
   shows   "Im ` box a b = {Im a<..<Im b}"
   using inner_image_box[of "\<i>::complex" a b] assms by (auto simp: Basis_complex_def)
 
 lemma inner_image_cbox:
   assumes "(i :: 'a :: euclidean_space) \<in> Basis"
   assumes "\<forall>i\<in>Basis. a \<bullet> i \<le> b \<bullet> i"
   shows   "(\<lambda>x. x \<bullet> i) ` cbox a b = {a \<bullet> i..b \<bullet> i}"
 proof safe
   fix x assume x: "x \<in> {a \<bullet> i..b \<bullet> i}"
   let ?y = "(\<Sum>j\<in>Basis. (if i = j then x else a \<bullet> j) *\<^sub>R j)"
   from x assms have "?y \<bullet> i \<in> (\<lambda>x. x \<bullet> i) ` cbox a b"
     by (intro imageI) (auto simp: cbox_def)
   also have "?y \<bullet> i = (\<Sum>j\<in>Basis. (if i = j then x else a \<bullet> j) * (j \<bullet> i))"
     by (simp add: inner_sum_left)
   also have "\<dots> = (\<Sum>j\<in>Basis. if i = j then x else 0)"
     by (intro sum.cong) (auto simp: inner_not_same_Basis assms)
   also have "\<dots> = x" using assms by simp
   finally show "x \<in> (\<lambda>x. x \<bullet> i) ` cbox a b"  .
 qed (insert assms, auto simp: cbox_def)
 
 lemma Re_image_cbox:
   assumes "Re a \<le> Re b" "Im a \<le> Im b"
   shows   "Re ` cbox a b = {Re a..Re b}"
   using inner_image_cbox[of "1::complex" a b] assms by (auto simp: Basis_complex_def)
 
 lemma Im_image_cbox:
   assumes "Re a \<le> Re b" "Im a \<le> Im b"
   shows   "Im ` cbox a b = {Im a..Im b}"
   using inner_image_cbox[of "\<i>::complex" a b] assms by (auto simp: Basis_complex_def)
 
 lemma analytic_onE_cball:
   assumes "f analytic_on A" "s \<in> A" "ub > (0::real)"
   obtains R where "R > 0" "R < ub" "f analytic_on cball s R"
 proof -
   from assms obtain r where "r > 0" "f holomorphic_on ball s r"
     by (auto simp: analytic_on_def)
   hence "f analytic_on ball s r" by (simp add: analytic_on_open)
   hence "f analytic_on cball s (min (ub / 2) (r / 2))"
     by (rule analytic_on_subset, subst cball_subset_ball_iff) (use \<open>r > 0\<close> in auto)
   moreover have "min (ub / 2) (r / 2) > 0" and "min (ub / 2) (r / 2) < ub"
     using \<open>r > 0\<close> and \<open>ub > 0\<close> by (auto simp: min_def)
   ultimately show ?thesis using that[of "min (ub / 2) (r / 2)"]
     by blast
 qed
 
 
 corollary analytic_pre_zeta' [analytic_intros]:
   assumes "f analytic_on A" "a > 0"
   shows   "(\<lambda>x. pre_zeta a (f x)) analytic_on A"
   using analytic_on_compose_gen[OF assms(1) analytic_pre_zeta[of a UNIV]] assms(2)
   by (auto simp: o_def)
 
 corollary analytic_hurwitz_zeta' [analytic_intros]:
   assumes "f analytic_on A" "(\<And>x. x \<in> A \<Longrightarrow> f x \<noteq> 1)" "a > 0"
   shows   "(\<lambda>x. hurwitz_zeta a (f x)) analytic_on A"
   using analytic_on_compose_gen[OF assms(1) analytic_hurwitz_zeta[of a "-{1}"]] assms(2,3)
   by (auto simp: o_def)
 
 corollary analytic_zeta' [analytic_intros]:
   assumes "f analytic_on A" "(\<And>x. x \<in> A \<Longrightarrow> f x \<noteq> 1)"
   shows   "(\<lambda>x. zeta (f x)) analytic_on A"
   using analytic_on_compose_gen[OF assms(1) analytic_zeta[of "-{1}"]] assms(2)
   by (auto simp: o_def)
 
 
 lemma logderiv_zeta_analytic: "(\<lambda>s. deriv zeta s / zeta s) analytic_on {s. Re s \<ge> 1} - {1}"
   using zeta_Re_ge_1_nonzero by (auto intro!: analytic_intros)
 
 lemma cis_pi_half [simp]: "cis (pi / 2) = \<i>"
   by (simp add: complex_eq_iff)
 
 lemma mult_real_sqrt: "x \<ge> 0 \<Longrightarrow> x * sqrt y = sqrt (x ^ 2 * y)"
   by (simp add: real_sqrt_mult)
 
 lemma arcsin_pos: "x \<in> {0<..1} \<Longrightarrow> arcsin x > 0"
   using arcsin_less_arcsin[of 0 x] by simp
 
 lemmas analytic_imp_holomorphic' = holomorphic_on_subset[OF analytic_imp_holomorphic]
 
 lemma residue_simple':
   assumes "open s" "0 \<in> s" "f holomorphic_on s"
   shows   "residue (\<lambda>w. f w / w) 0 = f 0"
   using residue_simple[of s 0 f] assms by simp
 
 
 lemma fds_converges_cong:
   assumes "eventually (\<lambda>n. fds_nth f n = fds_nth g n) at_top" "s = s'"
   shows   "fds_converges f s \<longleftrightarrow> fds_converges g s'"
   unfolding fds_converges_def
   by (intro summable_cong eventually_mono[OF assms(1)]) (simp_all add: assms)
 
 lemma fds_abs_converges_cong:
   assumes "eventually (\<lambda>n. fds_nth f n = fds_nth g n) at_top" "s = s'"
   shows   "fds_abs_converges f s \<longleftrightarrow> fds_abs_converges g s'"
   unfolding fds_abs_converges_def
   by (intro summable_cong eventually_mono[OF assms(1)]) (simp_all add: assms)
 
 lemma conv_abscissa_cong:
   assumes "eventually (\<lambda>n. fds_nth f n = fds_nth g n) at_top"
   shows   "conv_abscissa f = conv_abscissa g"
 proof -
   have "fds_converges f = fds_converges g"
     by (intro ext fds_converges_cong assms refl)
   thus ?thesis by (simp add: conv_abscissa_def)
 qed
 
 lemma abs_conv_abscissa_cong:
   assumes "eventually (\<lambda>n. fds_nth f n = fds_nth g n) at_top"
   shows   "abs_conv_abscissa f = abs_conv_abscissa g"
 proof -
   have "fds_abs_converges f = fds_abs_converges g"
     by (intro ext fds_abs_converges_cong assms refl)
   thus ?thesis by (simp add: abs_conv_abscissa_def)
 qed
 
 
 definition fds_remainder where
   "fds_remainder m = fds_subseries (\<lambda>n. n > m)"
 
 lemma fds_nth_remainder: "fds_nth (fds_remainder m f) = (\<lambda>n. if n > m then fds_nth f n else 0)"
   by (simp add: fds_remainder_def fds_subseries_def fds_nth_fds')
 
 lemma fds_converges_remainder_iff [simp]:
   "fds_converges (fds_remainder m f) s \<longleftrightarrow> fds_converges f s"
   by (intro fds_converges_cong eventually_mono[OF eventually_gt_at_top[of m]])
      (auto simp: fds_nth_remainder)
 
 lemma fds_abs_converges_remainder_iff [simp]:
   "fds_abs_converges (fds_remainder m f) s \<longleftrightarrow> fds_abs_converges f s"
   by (intro fds_abs_converges_cong eventually_mono[OF eventually_gt_at_top[of m]])
      (auto simp: fds_nth_remainder)
 
 lemma fds_converges_remainder [intro]:
         "fds_converges f s \<Longrightarrow> fds_converges (fds_remainder m f) s"
   and fds_abs_converges_remainder [intro]:
         "fds_abs_converges f s \<Longrightarrow> fds_abs_converges (fds_remainder m f) s"
   by simp_all
 
 lemma conv_abscissa_remainder [simp]:
   "conv_abscissa (fds_remainder m f) = conv_abscissa f"
   by (intro conv_abscissa_cong eventually_mono[OF eventually_gt_at_top[of m]])
      (auto simp: fds_nth_remainder)
 
 lemma abs_conv_abscissa_remainder [simp]:
   "abs_conv_abscissa (fds_remainder m f) = abs_conv_abscissa f"
   by (intro abs_conv_abscissa_cong eventually_mono[OF eventually_gt_at_top[of m]])
      (auto simp: fds_nth_remainder)
 
 lemma eval_fds_remainder:
    "eval_fds (fds_remainder m f) s = (\<Sum>n. fds_nth f (n + Suc m) / nat_power (n + Suc m) s)"
     (is "_ = suminf (\<lambda>n. ?f (n + Suc m))")
 proof (cases "fds_converges f s")
   case False
   hence "\<not>fds_converges (fds_remainder m f) s" by simp
   hence "(\<lambda>x. (\<lambda>n. fds_nth (fds_remainder m f) n / nat_power n s) sums x) = (\<lambda>_. False)"
     by (auto simp: fds_converges_def summable_def)
   hence "eval_fds (fds_remainder m f) s = (THE _. False)"
     by (simp add: eval_fds_def suminf_def)
   moreover from False have "\<not>summable (\<lambda>n. ?f (n + Suc m))" unfolding fds_converges_def
     by (subst summable_iff_shift) auto
   hence "(\<lambda>x. (\<lambda>n. ?f (n + Suc m)) sums x) = (\<lambda>_. False)"
     by (auto simp: summable_def)
   hence "suminf (\<lambda>n. ?f (n + Suc m)) = (THE _. False)"
     by (simp add: suminf_def)
   ultimately show ?thesis by simp
 next
   case True
   hence *: "fds_converges (fds_remainder m f) s" by simp
   have "eval_fds (fds_remainder m f) s = (\<Sum>n. fds_nth (fds_remainder m f) n / nat_power n s)"
     unfolding eval_fds_def ..
   also have "\<dots> = (\<Sum>n. fds_nth (fds_remainder m f) (n + Suc m) / nat_power (n + Suc m) s)"
     using * unfolding fds_converges_def
     by (subst suminf_minus_initial_segment) (auto simp: fds_nth_remainder)
   also have "(\<lambda>n. fds_nth (fds_remainder m f) (n + Suc m)) = (\<lambda>n. fds_nth f (n + Suc m))"
     by (intro ext) (auto simp: fds_nth_remainder)
   finally show ?thesis .
 qed
 
 lemma fds_truncate_plus_remainder: "fds_truncate m f + fds_remainder m f = f"
   by (intro fds_eqI) (auto simp: fds_truncate_def fds_remainder_def fds_subseries_def)
 
 
 lemma holomorphic_fds_eval' [holomorphic_intros]:
   assumes "g holomorphic_on A" "\<And>x. x \<in> A \<Longrightarrow> Re (g x) > conv_abscissa f"
   shows   "(\<lambda>x. eval_fds f (g x)) holomorphic_on A"
   using holomorphic_on_compose_gen[OF assms(1) holomorphic_fds_eval[OF order.refl, of f]] assms(2)
   by (auto simp: o_def)
 
 lemma analytic_fds_eval' [analytic_intros]:
   assumes "g analytic_on A" "\<And>x. x \<in> A \<Longrightarrow> Re (g x) > conv_abscissa f"
   shows   "(\<lambda>x. eval_fds f (g x)) analytic_on A"
   using analytic_on_compose_gen[OF assms(1) analytic_fds_eval[OF order.refl, of f]] assms(2)
   by (auto simp: o_def)
 
 lemma homotopic_loopsI:
   fixes h :: "real \<times> real \<Rightarrow> _"
   assumes "continuous_on ({0..1} \<times> {0..1}) h"
           "h ` ({0..1} \<times> {0..1}) \<subseteq> s"
           "\<And>x. x \<in> {0..1} \<Longrightarrow> h (0, x) = p x"
           "\<And>x. x \<in> {0..1} \<Longrightarrow> h (1, x) = q x"
           "\<And>x. x \<in> {0..1} \<Longrightarrow> pathfinish (h \<circ> Pair x) = pathstart (h \<circ> Pair x)"
   shows   "homotopic_loops s p q"
   using assms unfolding homotopic_loops by (intro exI[of _ h]) auto
 
 lemma continuous_on_linepath [continuous_intros]:
   assumes "continuous_on A a" "continuous_on A b" "continuous_on A f"
   shows   "continuous_on A (\<lambda>x. linepath (a x) (b x) (f x))"
   using assms by (auto simp: linepath_def intro!: continuous_intros assms)
 
 lemma continuous_on_part_circlepath [continuous_intros]:
   assumes "continuous_on A c" "continuous_on A r" "continuous_on A a" "continuous_on A b"
           "continuous_on A f"
   shows   "continuous_on A (\<lambda>x. part_circlepath (c x) (r x) (a x) (b x) (f x))"
   using assms by (auto simp: part_circlepath_def intro!: continuous_intros assms)
 
 lemma homotopic_loops_part_circlepath:
   assumes "sphere c r \<subseteq> A" and "r \<ge> 0" and
           "b1 = a1 + 2 * of_int k * pi" and "b2 = a2 + 2 * of_int k * pi"
   shows   "homotopic_loops A (part_circlepath c r a1 b1) (part_circlepath c r a2 b2)"
 proof -
   define h where "h = (\<lambda>(x,y). part_circlepath c r (linepath a1 a2 x) (linepath b1 b2 x) y)"
   show ?thesis
   proof (rule homotopic_loopsI)
     show "continuous_on ({0..1} \<times> {0..1}) h"
       by (auto simp: h_def case_prod_unfold intro!: continuous_intros)
   next
     from assms have "h ` ({0..1} \<times> {0..1}) \<subseteq> sphere c r"
       by (auto simp: h_def part_circlepath_def dist_norm norm_mult)
     also have "\<dots> \<subseteq> A" by fact
     finally show "h ` ({0..1} \<times> {0..1}) \<subseteq> A" .
   next
     fix x :: real assume x: "x \<in> {0..1}"
     show "h (0, x) = part_circlepath c r a1 b1 x" and "h (1, x) = part_circlepath c r a2 b2 x"
       by (simp_all add: h_def linepath_def)
     have "cis (pi * (real_of_int k * 2)) = 1"
       using cis.plus_of_int[of 0 k] by (simp add: algebra_simps)
     thus "pathfinish (h \<circ> Pair x) = pathstart (h \<circ> Pair x)"
       by (simp add: h_def o_def exp_eq_polar linepath_def algebra_simps
                     cis_mult [symmetric] cis_divide [symmetric] assms)
   qed
 qed
 
 lemma homotopic_pathsI:
   fixes h :: "real \<times> real \<Rightarrow> _"
   assumes "continuous_on ({0..1} \<times> {0..1}) h"
   assumes "h ` ({0..1} \<times> {0..1}) \<subseteq> s"
   assumes "\<And>x. x \<in> {0..1} \<Longrightarrow> h (0, x) = p x"
   assumes "\<And>x. x \<in> {0..1} \<Longrightarrow> h (1, x) = q x"
   assumes "\<And>x. x \<in> {0..1} \<Longrightarrow> pathstart (h \<circ> Pair x) = pathstart p"
   assumes "\<And>x. x \<in> {0..1} \<Longrightarrow> pathfinish (h \<circ> Pair x) = pathfinish p"
   shows   "homotopic_paths s p q"
   using assms unfolding homotopic_paths by (intro exI[of _ h]) auto
 
 lemma part_circlepath_conv_subpath:
   "part_circlepath c r a b = subpath (a / (2*pi)) (b / (2*pi)) (circlepath c r)"
   by (simp add: part_circlepath_def circlepath_def subpath_def linepath_def algebra_simps exp_eq_polar)
 
 lemma homotopic_paths_part_circlepath:
   assumes "a \<le> b" "b \<le> c"
   assumes "path_image (part_circlepath C r a c) \<subseteq> A" "r \<ge> 0"
   shows   "homotopic_paths A (part_circlepath C r a c)
              (part_circlepath C r a b +++ part_circlepath C r b c)"
   (is "homotopic_paths _ ?g (?h1 +++ ?h2)")
 proof (cases "a = c")
   case False
   with assms have "a < c" by simp
   define slope where "slope = (b - a) / (c - a)"
   from assms and \<open>a < c\<close> have slope: "slope \<in> {0..1}"
     by (auto simp: field_simps slope_def)
   define f :: "real \<Rightarrow> real" where
     "f = linepath 0 slope +++ linepath slope 1"
 
   show ?thesis
   proof (rule homotopic_paths_reparametrize)
     fix t :: real assume t: "t \<in> {0..1}"
     show "(?h1 +++ ?h2) t = ?g (f t)"
     proof (cases "t \<le> 1 / 2")
       case True
       hence "?g (f t) = C + r * cis ((1 - f t) * a + f t * c)"
         by (simp add: joinpaths_def part_circlepath_def exp_eq_polar linepath_def)
       also from True \<open>a < c\<close> have "(1 - f t) * a + f t * c = (1 - 2 * t) * a + 2 * t * b"
         unfolding f_def slope_def linepath_def joinpaths_def
         by (simp add: divide_simps del: div_mult_self3 div_mult_self4 div_mult_self2 div_mult_self1)
            (simp add: algebra_simps)?
       also from True have "C + r * cis \<dots> = (?h1 +++ ?h2) t"
         by (simp add: joinpaths_def part_circlepath_def exp_eq_polar linepath_def)
       finally show ?thesis ..
     next
       case False
       hence "?g (f t) = C + r * cis ((1 - f t) * a + f t * c)"
         by (simp add: joinpaths_def part_circlepath_def exp_eq_polar linepath_def)
       also from False \<open>a < c\<close> have "(1 - f t) * a + f t * c = (2 - 2 * t) * b + (2 * t - 1) * c"
         unfolding f_def slope_def linepath_def joinpaths_def
         by (simp add: divide_simps del: div_mult_self3 div_mult_self4 div_mult_self2 div_mult_self1)
            (simp add: algebra_simps)?
       also from False have "C + r * cis \<dots> = (?h1 +++ ?h2) t"
         by (simp add: joinpaths_def part_circlepath_def exp_eq_polar linepath_def)
       finally show ?thesis ..
     qed
   next
     from slope have "path_image f \<subseteq> {0..1}"
       by (auto simp: f_def path_image_join closed_segment_eq_real_ivl)
     thus "f ` {0..1} \<subseteq> {0..1}" by (simp add: path_image_def)
   next
     have "path f" unfolding f_def by auto
     thus "continuous_on {0..1} f" by (simp add: path_def)
   qed (insert assms, auto simp: f_def joinpaths_def linepath_def)
 next
   case [simp]: True
   with assms have [simp]: "b = c" by auto
   have "part_circlepath C r c c +++ part_circlepath C r c c = part_circlepath C r c c"
     by (simp add: fun_eq_iff joinpaths_def part_circlepath_def)
   thus ?thesis using assms by simp
 qed
 
 lemma has_contour_integral_mirror_iff:
   assumes "valid_path g"
   shows   "(f has_contour_integral I) (-g) \<longleftrightarrow> ((\<lambda>x. -f (- x)) has_contour_integral I) g"
 proof -
   from assms have "g piecewise_differentiable_on {0..1}"
     by (auto simp: valid_path_def piecewise_C1_imp_differentiable)
   then obtain S where S: "finite S" "\<And>x. x \<in> {0..1} - S \<Longrightarrow> g differentiable at x within {0..1}"
      unfolding piecewise_differentiable_on_def by blast
   have S': "g differentiable at x" if "x \<in> {0..1} - ({0, 1} \<union> S)" for x
   proof -
     from that have "x \<in> interior {0..1}" by auto
     with S(2)[of x] that show ?thesis by (auto simp: at_within_interior[of _ "{0..1}"])
   qed
 
   have "(f has_contour_integral I) (-g) \<longleftrightarrow>
           ((\<lambda>x. f (- g x) * vector_derivative (-g) (at x)) has_integral I) {0..1}"
     by (simp add: has_contour_integral)
   also have "\<dots> \<longleftrightarrow> ((\<lambda>x. -f (- g x) * vector_derivative g (at x)) has_integral I) {0..1}"
     by (intro has_integral_spike_finite_eq[of "S \<union> {0, 1}"])
        (insert \<open>finite S\<close> S', auto simp: o_def fun_Compl_def)
   also have "\<dots> \<longleftrightarrow> ((\<lambda>x. -f (-x)) has_contour_integral I) g"
     by (simp add: has_contour_integral)
   finally show ?thesis .
 qed
 
 lemma contour_integral_on_mirror_iff:
   assumes "valid_path g"
   shows   "f contour_integrable_on (-g) \<longleftrightarrow> (\<lambda>x. -f (- x)) contour_integrable_on g"
   by (auto simp: contour_integrable_on_def has_contour_integral_mirror_iff assms)
 
 lemma contour_integral_mirror:
   assumes "valid_path g"
   shows   "contour_integral (-g) f = contour_integral g (\<lambda>x. -f (- x))"
 proof (cases "f contour_integrable_on (-g)")
   case True
   then obtain I where I: "(f has_contour_integral I) (-g)"
     by (auto simp: contour_integrable_on_def)
   also note has_contour_integral_mirror_iff[OF assms]
   finally have "((\<lambda>x. - f (- x)) has_contour_integral I) g" .
   with I show ?thesis using contour_integral_unique by blast
 next
   case False
   hence "\<not>(\<lambda>x. -f (-x)) contour_integrable_on g"
     by (auto simp: contour_integral_on_mirror_iff assms)
   from False and this show ?thesis
     by (simp add: not_integrable_contour_integral)
 qed
 
 lemma contour_integrable_neg_iff:
   "(\<lambda>x. -f x) contour_integrable_on g \<longleftrightarrow> f contour_integrable_on g"
   using contour_integrable_neg[of f g] contour_integrable_neg[of "\<lambda>x. -f x" g] by auto
 
 lemma contour_integral_neg:
   shows "contour_integral g (\<lambda>x. -f x) = -contour_integral g f"
 proof (cases "f contour_integrable_on g")
   case True
   thus ?thesis by (simp add: contour_integral_neg)
 next
   case False
   hence "\<not>(\<lambda>x. -f x) contour_integrable_on g" by (simp add: contour_integrable_neg_iff)
   with False show ?thesis
     by (simp add: not_integrable_contour_integral)
 qed
 
 
 lemma minus_cis: "-cis x = cis (x + pi)"
   by (simp add: complex_eq_iff)
 
 lemma path_image_part_circlepath_subset:
   assumes "a \<le> a'" "a' \<le> b'" "b' \<le> b"
   shows   "path_image (part_circlepath c r a' b') \<subseteq> path_image (part_circlepath c r a b)"
   using assms by (subst (1 2) path_image_part_circlepath) auto
 
 lemma part_circlepath_mirror:
   assumes "a' = a + pi + 2 * pi * of_int k" "b' = b + pi + 2 * pi * of_int k" "c' = -c"
   shows   "-part_circlepath c r a b = part_circlepath c' r a' b'"
 proof
   fix x :: real
   have "part_circlepath c' r a' b' x = c' + r * cis (linepath a b x + pi + k * (2 * pi))"
     by (simp add: part_circlepath_def exp_eq_polar assms linepath_translate_right mult_ac)
   also have "cis (linepath a b x + pi + k * (2 * pi)) = cis (linepath a b x + pi)"
     by (rule cis.plus_of_int)
   also have "\<dots> = -cis (linepath a b x)"
     by (simp add: minus_cis)
   also have "c' + r * \<dots> = -part_circlepath c r a b x"
     by (simp add: part_circlepath_def assms exp_eq_polar)
   finally show "(- part_circlepath c r a b) x = part_circlepath c' r a' b' x"
     by simp
 qed
 
 lemma path_mirror [intro]: "path (g :: _ \<Rightarrow> 'b::topological_group_add) \<Longrightarrow> path (-g)"
   by (auto simp: path_def intro!: continuous_intros)
 
 lemma path_mirror_iff [simp]: "path (-g :: _ \<Rightarrow> 'b::topological_group_add) \<longleftrightarrow> path g"
   using path_mirror[of g] path_mirror[of "-g"] by (auto simp: fun_Compl_def)
 
 lemma valid_path_mirror [intro]: "valid_path g \<Longrightarrow> valid_path (-g)"
   by (auto simp: valid_path_def fun_Compl_def piecewise_C1_differentiable_neg)
 
 lemma valid_path_mirror_iff [simp]: "valid_path (-g) \<longleftrightarrow> valid_path g"
   using valid_path_mirror[of g] valid_path_mirror[of "-g"] by (auto simp: fun_Compl_def)
 
 lemma pathstart_mirror [simp]: "pathstart (-g) = -pathstart g"
   and pathfinish_mirror [simp]: "pathfinish (-g) = -pathfinish g"
   by (simp_all add: pathstart_def pathfinish_def)
 
 lemma path_image_mirror: "path_image (-g) = uminus ` path_image g"
   by (auto simp: path_image_def)
 
 lemma contour_integral_bound_part_circlepath:
   assumes "f contour_integrable_on part_circlepath c r a b"
   assumes "B \<ge> 0" "r \<ge> 0" "\<And>x. x \<in> path_image (part_circlepath c r a b) \<Longrightarrow> norm (f x) \<le> B"
   shows   "norm (contour_integral (part_circlepath c r a b) f) \<le> B * r * \<bar>b - a\<bar>"
 proof -
   let ?I = "integral {0..1} (\<lambda>x. f (part_circlepath c r a b x) * \<i> * of_real (r * (b - a)) *
               exp (\<i> * linepath a b x))"
   have "norm ?I \<le> integral {0..1} (\<lambda>x::real. B * 1 * (r * \<bar>b - a\<bar>) * 1)"
   proof (rule integral_norm_bound_integral, goal_cases)
     case 1
     with assms(1) show ?case
       by (simp add: contour_integrable_on vector_derivative_part_circlepath mult_ac)
   next
     case (3 x)
     with assms(2-) show ?case unfolding norm_mult norm_of_real abs_mult
       by (intro mult_mono) (auto simp: path_image_def)
   qed auto
   also have "?I = contour_integral (part_circlepath c r a b) f"
     by (simp add: contour_integral_integral vector_derivative_part_circlepath mult_ac)
   finally show ?thesis by simp
 qed
 
 lemma contour_integral_spike_finite_simple_path:
   assumes "finite A" "simple_path g" "g = g'" "\<And>x. x \<in> path_image g - A \<Longrightarrow> f x = f' x"
   shows   "contour_integral g f = contour_integral g' f'"
   unfolding contour_integral_integral
 proof (rule integral_spike)
   have "finite (g -` A \<inter> {0<..<1})" using \<open>simple_path g\<close> \<open>finite A\<close>
     by (intro finite_vimage_IntI simple_path_inj_on) auto
   hence "finite ({0, 1} \<union> g -` A \<inter> {0<..<1})" by auto
   thus "negligible ({0, 1} \<union> g -` A \<inter> {0<..<1})" by (rule negligible_finite)
 next
   fix x assume "x \<in> {0..1} - ({0, 1} \<union> g -` A \<inter> {0<..<1})"
   hence "g x \<in> path_image g - A" by (auto simp: path_image_def)
   from assms(4)[OF this] and assms(3)
     show "f' (g' x) * vector_derivative g' (at x) = f (g x) * vector_derivative g (at x)" by simp
   qed
 
 proposition contour_integral_bound_part_circlepath_strong:
   assumes fi: "f contour_integrable_on part_circlepath z r s t"
       and "finite k" and le: "0 \<le> B" "0 < r" "s \<le> t"
       and B: "\<And>x. x \<in> path_image(part_circlepath z r s t) - k \<Longrightarrow> norm(f x) \<le> B"
     shows "cmod (contour_integral (part_circlepath z r s t) f) \<le> B * r * (t - s)"
 proof -
   from fi have "(f has_contour_integral contour_integral (part_circlepath z r s t) f)
                   (part_circlepath z r s t)"
     by (rule has_contour_integral_integral)
   from has_contour_integral_bound_part_circlepath_strong[OF this assms(2-)] show ?thesis by auto
 qed
 
 lemma cos_le_zero:
   assumes "x \<in> {pi/2..3*pi/2}"
   shows   "cos x \<le> 0"
 proof -
   have "cos x = -cos (x - pi)" by (simp add: cos_diff)
   moreover from assms have "cos (x - pi) \<ge> 0"
     by (intro cos_ge_zero) auto
   ultimately show ?thesis by simp
 qed
 
 lemma cos_le_zero': "x \<in> {-3*pi/2..-pi/2} \<Longrightarrow> cos x \<le> 0"
   using cos_le_zero[of "-x"] by simp
 
 lemma cis_minus_pi_half [simp]: "cis (- (pi / 2)) = -\<i>"
   by (simp add: complex_eq_iff)
 
 lemma winding_number_join_pos_combined':
      "\<lbrakk>valid_path \<gamma>1 \<and> z \<notin> path_image \<gamma>1 \<and> 0 < Re (winding_number \<gamma>1 z);
        valid_path \<gamma>2 \<and> z \<notin> path_image \<gamma>2 \<and> 0 < Re (winding_number \<gamma>2 z);
        pathfinish \<gamma>1 = pathstart \<gamma>2\<rbrakk>
       \<Longrightarrow> valid_path(\<gamma>1 +++ \<gamma>2) \<and> z \<notin> path_image(\<gamma>1 +++ \<gamma>2) \<and> 0 < Re(winding_number(\<gamma>1 +++ \<gamma>2) z)"
   by (simp add: valid_path_join path_image_join winding_number_join valid_path_imp_path)
 
 lemma Union_atLeastAtMost_real_of_nat:
   assumes "a < b"
   shows   "(\<Union>n\<in>{a..<b}. {real n..real (n + 1)}) = {real a..real b}"
 proof (intro equalityI subsetI)
   fix x assume x: "x \<in> {real a..real b}"
   thus "x \<in> (\<Union>n\<in>{a..<b}. {real n..real (n + 1)})"
   proof (cases "x = real b")
     case True
     with assms show ?thesis by (auto intro!: bexI[of _ "b - 1"])
   next
     case False
     with x have x: "x \<ge> real a" "x < real b" by simp_all
     hence "x \<ge> real (nat \<lfloor>x\<rfloor>)" "x \<le> real (Suc (nat \<lfloor>x\<rfloor>))" by linarith+
     moreover from x have "nat \<lfloor>x\<rfloor> \<ge> a" "nat \<lfloor>x\<rfloor> < b" by linarith+
     ultimately have "\<exists>n\<in>{a..<b}. x \<in> {real n..real (n + 1)}"
       by (intro bexI[of _ "nat \<lfloor>x\<rfloor>"]) simp_all
     thus ?thesis by blast
   qed
 qed auto
 
 lemma nat_sum_has_integral_floor:
   fixes f :: "nat \<Rightarrow> 'a :: banach"
   assumes mn: "m < n"
   shows "((\<lambda>x. f (nat \<lfloor>x\<rfloor>)) has_integral sum f {m..<n}) {real m..real n}"
 proof -
   define D where "D = (\<lambda>i. {real i..real (Suc i)}) ` {m..<n}"
   have D: "D division_of {m..n}"
     using Union_atLeastAtMost_real_of_nat[OF mn] by (simp add: division_of_def D_def)
   have "((\<lambda>x. f (nat \<lfloor>x\<rfloor>)) has_integral (\<Sum>X\<in>D. f (nat \<lfloor>Inf X\<rfloor>))) {real m..real n}"
   proof (rule has_integral_combine_division)
     fix X assume X: "X \<in> D"
     have "nat \<lfloor>x\<rfloor> = nat \<lfloor>Inf X\<rfloor>" if "x \<in> X - {Sup X}" for x
       using that X by (auto simp: D_def nat_eq_iff floor_eq_iff)
     hence "((\<lambda>x. f (nat \<lfloor>x\<rfloor>)) has_integral f (nat \<lfloor>Inf X\<rfloor>)) X \<longleftrightarrow>
            ((\<lambda>x. f (nat \<lfloor>Inf X\<rfloor>)) has_integral f (nat \<lfloor>Inf X\<rfloor>)) X" using X
       by (intro has_integral_spike_eq[of "{Sup X}"]) auto
     also from X have "\<dots>" using has_integral_const_real[of "f (nat \<lfloor>Inf X\<rfloor>)" "Inf X" "Sup X"]
       by (auto simp: D_def)
     finally show "((\<lambda>x. f (nat \<lfloor>x\<rfloor>)) has_integral f (nat \<lfloor>Inf X\<rfloor>)) X" .
   qed fact+
   also have "(\<Sum>X\<in>D. f (nat \<lfloor>Inf X\<rfloor>)) = (\<Sum>k\<in>{m..<n}. f k)"
     unfolding D_def by (subst sum.reindex) (auto simp: inj_on_def nat_add_distrib)
   finally show ?thesis .
 qed
 
 lemma nat_sum_has_integral_ceiling:
   fixes f :: "nat \<Rightarrow> 'a :: banach"
   assumes mn: "m < n"
   shows "((\<lambda>x. f (nat \<lceil>x\<rceil>)) has_integral sum f {m<..n}) {real m..real n}"
 proof -
   define D where "D = (\<lambda>i. {real i..real (Suc i)}) ` {m..<n}"
   have D: "D division_of {m..n}"
     using Union_atLeastAtMost_real_of_nat[OF mn] by (simp add: division_of_def D_def)
   have "((\<lambda>x. f (nat \<lceil>x\<rceil>)) has_integral (\<Sum>X\<in>D. f (nat \<lfloor>Sup X\<rfloor>))) {real m..real n}"
   proof (rule has_integral_combine_division)
     fix X assume X: "X \<in> D"
     have "nat \<lceil>x\<rceil> = nat \<lfloor>Sup X\<rfloor>" if "x \<in> X - {Inf X}" for x
       using that X by (auto simp: D_def nat_eq_iff ceiling_eq_iff)
     hence "((\<lambda>x. f (nat \<lceil>x\<rceil>)) has_integral f (nat \<lfloor>Sup X\<rfloor>)) X \<longleftrightarrow>
            ((\<lambda>x. f (nat \<lfloor>Sup X\<rfloor>)) has_integral f (nat \<lfloor>Sup X\<rfloor>)) X" using X
       by (intro has_integral_spike_eq[of "{Inf X}"]) auto
     also from X have "\<dots>" using has_integral_const_real[of "f (nat \<lfloor>Sup X\<rfloor>)" "Inf X" "Sup X"]
       by (auto simp: D_def)
     finally show "((\<lambda>x. f (nat \<lceil>x\<rceil>)) has_integral f (nat \<lfloor>Sup X\<rfloor>)) X" .
   qed fact+
   also have "(\<Sum>X\<in>D. f (nat \<lfloor>Sup X\<rfloor>)) = (\<Sum>k\<in>{m..<n}. f (Suc k))"
     unfolding D_def by (subst sum.reindex) (auto simp: inj_on_def nat_add_distrib)
   also have "\<dots> = (\<Sum>k\<in>{m<..n}. f k)"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>x. x - 1" Suc]) auto
   finally show ?thesis .
 qed
 
 lemma zeta_partial_sum_le:
   fixes x :: real and m :: nat
   assumes x: "x \<in> {0<..1}"
   shows "(\<Sum>k=1..m. real k powr (x - 1)) \<le> real m powr x / x"
 proof -
   consider "m = 0" | "m = 1" | "m > 1" by force
   thus ?thesis
   proof cases
     assume m: "m > 1"
     hence "{1..m} = insert 1 {1<..m}" by auto
     also have "(\<Sum>k\<in>\<dots>. real k powr (x - 1)) = 1 + (\<Sum>k\<in>{1<..m}. real k powr (x - 1))"
       by simp
     also have "(\<Sum>k\<in>{1<..m}. real k powr (x - 1)) \<le> real m powr x / x - 1 / x"
     proof (rule has_integral_le)
       show "((\<lambda>t. (nat \<lceil>t\<rceil>) powr (x - 1)) has_integral (\<Sum>n\<in>{1<..m}. n powr (x - 1))) {real 1..m}"
         using m by (intro nat_sum_has_integral_ceiling) auto
     next
       have "((\<lambda>t. t powr (x - 1)) has_integral (real m powr x / x - real 1 powr x / x))
               {real 1..real m}"
         by (intro fundamental_theorem_of_calculus)
            (insert x m, auto simp flip: has_field_derivative_iff_has_vector_derivative
                              intro!: derivative_eq_intros)
       thus "((\<lambda>t. t powr (x - 1)) has_integral (real m powr x / x - 1 / x)) {real 1..real m}"
         by simp
     qed (insert x, auto intro!: powr_mono2')
     also have "1 + (real m powr x / x - 1 / x) \<le> real m powr x / x"
       using x by (simp add: field_simps)
     finally show ?thesis by simp
   qed (use assms in auto)
 qed
 
 lemma zeta_partial_sum_le':
   fixes x :: real and m :: nat
   assumes x: "x > 0" and m: "m > 0"
   shows   "(\<Sum>n=1..m. real n powr (x - 1)) \<le> m powr x * (1 / x + 1 / m)"
 proof (cases "x > 1")
   case False
   with assms have "(\<Sum>n=1..m. real n powr (x - 1)) \<le> m powr x / x"
     by (intro zeta_partial_sum_le) auto
   also have "\<dots> \<le> m powr x * (1 / x + 1 / m)"
     using assms by (simp add: field_simps)
   finally show ?thesis .
 next
   case True
   have "(\<Sum>n\<in>{1..m}. n powr (x - 1)) = (\<Sum>n\<in>insert m {0..<m}. n powr (x - 1))"
     by (intro sum.mono_neutral_left) auto
   also have "\<dots> = m powr (x - 1) + (\<Sum>n\<in>{0..<m}. n powr (x - 1))" by simp
   also have "(\<Sum>n\<in>{0..<m}. n powr (x - 1)) \<le> real m powr x / x"
   proof (rule has_integral_le)
     show "((\<lambda>t. (nat \<lfloor>t\<rfloor>) powr (x - 1)) has_integral (\<Sum>n\<in>{0..<m}. n powr (x - 1))) {real 0..m}"
       using m by (intro nat_sum_has_integral_floor) auto
   next
     show "((\<lambda>t. t powr (x - 1)) has_integral (real m powr x / x)) {real 0..real m}"
       using has_integral_powr_from_0[of "x - 1"] x by auto
   next
     fix t assume "t \<in> {real 0..real m}"
     with \<open>x > 1\<close> show "real (nat \<lfloor>t\<rfloor>) powr (x - 1) \<le> t powr (x - 1)"
       by (cases "t = 0") (auto intro: powr_mono2)
   qed
   also have "m powr (x - 1) + m powr x / x = m powr x * (1 / x + 1 / m)"
     using m x by (simp add: powr_diff field_simps)
   finally show ?thesis by simp
 qed
 
 lemma natfun_bigo_1E:
   assumes "(f :: nat \<Rightarrow> _) \<in> O(\<lambda>_. 1)"
   obtains C where "C \<ge> lb" "\<And>n. norm (f n) \<le> C"
 proof -
   from assms obtain C N where "\<forall>n\<ge>N. norm (f n) \<le> C"
     by (auto elim!: landau_o.bigE simp: eventually_at_top_linorder)
   hence *: "norm (f n) \<le> Max ({C, lb} \<union> (norm ` f ` {..<N}))" for n
     by (cases "n \<ge> N") (subst Max_ge_iff; force simp: image_iff)+
   moreover have "Max ({C, lb} \<union> (norm ` f ` {..<N})) \<ge> lb"
     by (intro Max.coboundedI) auto
   ultimately show ?thesis using that by blast
 qed
 
 lemma natfun_bigo_iff_Bseq: "f \<in> O(\<lambda>_. 1) \<longleftrightarrow> Bseq f"
 proof
   assume "Bseq f"
   then obtain C where "C > 0" "\<And>n. norm (f n) \<le> C" by (auto simp: Bseq_def)
   thus "f \<in> O(\<lambda>_. 1)" by (intro bigoI[of _ C]) auto
 next
   assume "f \<in> O(\<lambda>_. 1)"
   from natfun_bigo_1E[OF this, where lb = 1] obtain C where "C \<ge> 1" "\<And>n. norm (f n) \<le> C"
     by auto
   thus "Bseq f" by (auto simp: Bseq_def intro!: exI[of _ C])
 qed
 
 lemma enn_decreasing_sum_le_set_nn_integral:
   fixes f :: "real \<Rightarrow> ennreal"
   assumes decreasing: "\<And>x y. 0 \<le> x \<Longrightarrow> x \<le> y \<Longrightarrow> f y \<le> f x"
   shows "(\<Sum>n. f (real (Suc n))) \<le> set_nn_integral lborel {0..} f"
 proof -
   have "(\<Sum>n. (f (Suc n))) =
           (\<Sum>n. \<integral>\<^sup>+x\<in>{real n<..real (Suc n)}. (f (Suc n)) \<partial>lborel)"
     by (subst nn_integral_cmult_indicator) auto
   also have "nat \<lceil>x\<rceil> = Suc n" if "x \<in> {real n<..real (Suc n)}" for x n
     using that by (auto simp: nat_eq_iff ceiling_eq_iff)
   hence "(\<Sum>n. \<integral>\<^sup>+x\<in>{real n<..real (Suc n)}. (f (Suc n)) \<partial>lborel) =
           (\<Sum>n. \<integral>\<^sup>+x\<in>{real n<..real (Suc n)}. (f (real (nat \<lceil>x\<rceil>))) \<partial>lborel)"
     by (intro suminf_cong nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = (\<integral>\<^sup>+x\<in>(\<Union>i. {real i<..real (Suc i)}). (f (nat \<lceil>x::real\<rceil>)) \<partial>lborel)"
     by (subst nn_integral_disjoint_family)
        (auto simp: disjoint_family_on_def)
   also have "\<dots> \<le> (\<integral>\<^sup>+x\<in>{0..}. (f x) \<partial>lborel)"
     by (intro nn_integral_mono) (auto simp: indicator_def intro!: decreasing)
   finally show ?thesis .
 qed
 
 (* TODO replace version in library *)
 lemma nn_integral_has_integral_lebesgue:
   fixes f :: "'a::euclidean_space \<Rightarrow> real"
   assumes nonneg: "\<And>x. x \<in> \<Omega> \<Longrightarrow> 0 \<le> f x" and I: "(f has_integral I) \<Omega>"
   shows "integral\<^sup>N lborel (\<lambda>x. indicator \<Omega> x * f x) = I"
 proof -
   from I have "(\<lambda>x. indicator \<Omega> x *\<^sub>R f x) \<in> lebesgue \<rightarrow>\<^sub>M borel"
     by (rule has_integral_implies_lebesgue_measurable)
   then obtain f' :: "'a \<Rightarrow> real"
     where [measurable]: "f' \<in> borel \<rightarrow>\<^sub>M borel" and eq: "AE x in lborel. indicator \<Omega> x * f x = f' x"
     by (auto dest: completion_ex_borel_measurable_real)
 
   from I have "((\<lambda>x. abs (indicator \<Omega> x * f x)) has_integral I) UNIV"
-    using nonneg by (simp add: indicator_def if_distrib[of "\<lambda>x. x * f y" for y] cong: if_cong)
+    using nonneg by (simp add: indicator_def of_bool_def if_distrib[of "\<lambda>x. x * f y" for y] cong: if_cong)
   also have "((\<lambda>x. abs (indicator \<Omega> x * f x)) has_integral I) UNIV \<longleftrightarrow> ((\<lambda>x. abs (f' x)) has_integral I) UNIV"
     using eq by (intro has_integral_AE) auto
   finally have "integral\<^sup>N lborel (\<lambda>x. abs (f' x)) = I"
     by (rule nn_integral_has_integral_lborel[rotated 2]) auto
   also have "integral\<^sup>N lborel (\<lambda>x. abs (f' x)) = integral\<^sup>N lborel (\<lambda>x. abs (indicator \<Omega> x * f x))"
     using eq by (intro nn_integral_cong_AE) auto
   also have "(\<lambda>x. abs (indicator \<Omega> x * f x)) = (\<lambda>x. indicator \<Omega> x * f x)"
     using nonneg by (auto simp: indicator_def fun_eq_iff)
   finally show ?thesis .
 qed
 
 lemma decreasing_sum_le_integral:
   fixes f :: "real \<Rightarrow> real"
   assumes nonneg: "\<And>x. x \<ge> 0 \<Longrightarrow> f x \<ge> 0"
   assumes decreasing: "\<And>x y. 0 \<le> x \<Longrightarrow> x \<le> y \<Longrightarrow> f y \<le> f x"
   assumes integral: "(f has_integral I) {0..}"
   shows   "summable (\<lambda>i. f (real (Suc i)))" and "suminf (\<lambda>i. f (real (Suc i))) \<le> I"
 proof -
   have [simp]: "I \<ge> 0"
     by (intro has_integral_nonneg[OF integral] nonneg) auto
   have "(\<Sum>n. ennreal (f (Suc n))) =
           (\<Sum>n. \<integral>\<^sup>+x\<in>{real n<..real (Suc n)}. ennreal (f (Suc n)) \<partial>lborel)"
     by (subst nn_integral_cmult_indicator) auto
   also have "nat \<lceil>x\<rceil> = Suc n" if "x \<in> {real n<..real (Suc n)}" for x n
     using that by (auto simp: nat_eq_iff ceiling_eq_iff)
   hence "(\<Sum>n. \<integral>\<^sup>+x\<in>{real n<..real (Suc n)}. ennreal (f (Suc n)) \<partial>lborel) =
           (\<Sum>n. \<integral>\<^sup>+x\<in>{real n<..real (Suc n)}. ennreal (f (real (nat \<lceil>x\<rceil>))) \<partial>lborel)"
     by (intro suminf_cong nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = (\<integral>\<^sup>+x\<in>(\<Union>i. {real i<..real (Suc i)}). ennreal (f (nat \<lceil>x::real\<rceil>)) \<partial>lborel)"
     by (subst nn_integral_disjoint_family)
        (auto simp: disjoint_family_on_def intro!: measurable_completion)
   also have "\<dots> \<le> (\<integral>\<^sup>+x\<in>{0..}. ennreal (f x) \<partial>lborel)"
     by (intro nn_integral_mono) (auto simp: indicator_def nonneg intro!: decreasing)
   also have "\<dots> = (\<integral>\<^sup>+ x. ennreal (indicat_real {0..} x * f x) \<partial>lborel)"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = ennreal I"
     using nn_integral_has_integral_lebesgue[OF nonneg integral] by (auto simp: nonneg)
   finally have *: "(\<Sum>n. ennreal (f (Suc n))) \<le> ennreal I" .
   from * show summable: "summable (\<lambda>i. f (real (Suc i)))"
     by (intro summable_suminf_not_top) (auto simp: top_unique intro: nonneg)
   note *
   also from summable have "(\<Sum>n. ennreal (f (Suc n))) = ennreal (\<Sum>n. f (Suc n))"
     by (subst suminf_ennreal2) (auto simp: o_def nonneg)
   finally show "(\<Sum>n. f (real (Suc n))) \<le> I" by (subst (asm) ennreal_le_iff) auto
 qed
 
 lemma decreasing_sum_le_integral':
   fixes f :: "real \<Rightarrow> real"
   assumes "\<And>x. x \<ge> 0 \<Longrightarrow> f x \<ge> 0"
   assumes "\<And>x y. 0 \<le> x \<Longrightarrow> x \<le> y \<Longrightarrow> f y \<le> f x"
   assumes "(f has_integral I) {0..}"
   shows   "summable (\<lambda>i. f (real i))" and "suminf (\<lambda>i. f (real i)) \<le> f 0 + I"
 proof -
   have "summable ((\<lambda>i. f (real (Suc i))))"
     using decreasing_sum_le_integral[OF assms] by (simp add: o_def)
   thus *: "summable (\<lambda>i. f (real i))" by (subst (asm) summable_Suc_iff)
   have "(\<Sum>n. f (real (Suc n))) \<le> I" by (intro decreasing_sum_le_integral assms)
   thus "suminf (\<lambda>i. f (real i)) \<le> f 0 + I"
     using * by (subst (asm) suminf_split_head) auto
 qed
 
 lemma norm_suminf_le:
   assumes "\<And>n. norm (f n :: 'a :: banach) \<le> g n" "summable g"
   shows   "norm (suminf f) \<le> suminf g"
 proof -
   have *: "summable (\<lambda>n. norm (f n))" using assms
     by (intro summable_norm summable_comparison_test[OF _ assms(2)] exI[of _ 0]) auto
   hence "norm (suminf f) \<le> (\<Sum>n. norm (f n))" by (intro summable_norm) auto
   also have "\<dots> \<le> suminf g" by (intro suminf_le * assms allI)
   finally show ?thesis .
 qed
 
 lemma of_nat_powr_neq_1_complex [simp]:
   assumes "n > 1" "Re s \<noteq> 0"
   shows   "of_nat n powr s \<noteq> (1::complex)"
 proof -
   have "norm (of_nat n powr s) = real n powr Re s"
     by (simp add: norm_powr_real_powr)
   also have "\<dots> \<noteq> 1"
     using assms by (auto simp: powr_def)
   finally show ?thesis by auto
 qed
 
 lemma abs_summable_on_uminus_iff:
   "(\<lambda>x. -f x) abs_summable_on A \<longleftrightarrow> f abs_summable_on A"
   using abs_summable_on_uminus[of f A] abs_summable_on_uminus[of "\<lambda>x. -f x" A] by auto
 
 lemma abs_summable_on_cmult_right_iff:
   fixes f :: "'a \<Rightarrow> 'b :: {banach, real_normed_field, second_countable_topology}"
   assumes "c \<noteq> 0"
   shows   "(\<lambda>x. c * f x) abs_summable_on A \<longleftrightarrow> f abs_summable_on A"
   using assms abs_summable_on_cmult_right[of c f A]
         abs_summable_on_cmult_right[of "inverse c" "\<lambda>x. c * f x" A] by (auto simp: field_simps)
 
 lemma abs_summable_on_cmult_left_iff:
   fixes f :: "'a \<Rightarrow> 'b :: {banach, real_normed_field, second_countable_topology}"
   assumes "c \<noteq> 0"
   shows   "(\<lambda>x. f x * c) abs_summable_on A \<longleftrightarrow> f abs_summable_on A"
   using assms abs_summable_on_cmult_left[of c f A]
         abs_summable_on_cmult_left[of "inverse c" "\<lambda>x. f x * c" A] by (auto simp: field_simps)
 
 lemma fds_logderiv_completely_multiplicative:
   fixes f :: "'a :: {real_normed_field} fds"
   assumes "completely_multiplicative_function (fds_nth f)" "fds_nth f 1 \<noteq> 0"
   shows   "fds_deriv f / f = - fds (\<lambda>n. fds_nth f n * mangoldt n)"
 proof -
   have "fds_deriv f / f = - fds (\<lambda>n. fds_nth f n * mangoldt n) * f / f"
     using completely_multiplicative_fds_deriv[of "fds_nth f"] assms by simp
   also have "\<dots> = - fds (\<lambda>n. fds_nth f n * mangoldt n)"
     using assms by (simp add: divide_fds_def fds_right_inverse)
   finally show ?thesis .
 qed
 
 lemma fds_nth_logderiv_completely_multiplicative:
   fixes f :: "'a :: {real_normed_field} fds"
   assumes "completely_multiplicative_function (fds_nth f)" "fds_nth f 1 \<noteq> 0"
   shows   "fds_nth (fds_deriv f / f) n = -fds_nth f n * mangoldt n"
   using assms by (subst fds_logderiv_completely_multiplicative) (simp_all add: fds_nth_fds')
 
 lemma eval_fds_logderiv_completely_multiplicative:
   fixes s :: "'a :: dirichlet_series" and l :: 'a and f :: "'a fds"
   defines "h \<equiv> fds_deriv f / f"
   assumes "completely_multiplicative_function (fds_nth f)" and [simp]: "fds_nth f 1 \<noteq> 0"
   assumes "s \<bullet> 1 > abs_conv_abscissa f"
   shows  "(\<lambda>p. of_real (ln (real p)) * (1 / (1 - fds_nth f p / nat_power p s) - 1))
             abs_summable_on {p. prime p}" (is ?th1)
     and  "eval_fds h s = -(\<Sum>\<^sub>ap | prime p. of_real (ln (real p)) *
                             (1 / (1 - fds_nth f p / nat_power p s) - 1))" (is ?th2)
 proof -
   let ?P = "{p::nat. prime p}"
   interpret f: completely_multiplicative_function "fds_nth f" by fact
   have "fds_abs_converges h s"
     using abs_conv_abscissa_completely_multiplicative_log_deriv[OF assms(2)] assms
     by (intro fds_abs_converges) auto
   hence *: "(\<lambda>n. fds_nth h n / nat_power n s) abs_summable_on UNIV"
     by (auto simp: h_def fds_abs_converges_altdef')
 
   note *
   also have "(\<lambda>n. fds_nth h n / nat_power n s) abs_summable_on UNIV \<longleftrightarrow>
           (\<lambda>x. -fds_nth f x * mangoldt x / nat_power x s) abs_summable_on Collect primepow"
     unfolding h_def using fds_nth_logderiv_completely_multiplicative[OF assms(2)]
     by (intro abs_summable_on_cong_neutral) (auto simp: fds_nth_fds mangoldt_def)
   finally have sum1: "(\<lambda>x. -fds_nth f x * mangoldt x / nat_power x s)
                       abs_summable_on Collect primepow"
     by (rule abs_summable_on_subset) auto
   also have "?this \<longleftrightarrow> (\<lambda>(p,k). -fds_nth f (p ^ Suc k) * mangoldt (p ^ Suc k) /
                                 nat_power (p ^ Suc k) s) abs_summable_on (?P \<times> UNIV)"
     using bij_betw_primepows unfolding case_prod_unfold
     by (intro abs_summable_on_reindex_bij_betw [symmetric])
   also have "\<dots> \<longleftrightarrow> (\<lambda>(p,k). -((fds_nth f p / nat_power p s) ^ Suc k * of_real (ln (real p))))
                 abs_summable_on (?P \<times> UNIV)"
     unfolding case_prod_unfold
     by (intro abs_summable_on_cong, subst mangoldt_primepow)
        (auto simp: f.mult f.power nat_power_mult_distrib nat_power_power_left power_divide
              dest: prime_gt_1_nat)
   finally have sum2: \<dots> .
 
   have sum4: "summable (\<lambda>n. (norm (fds_nth f p / nat_power p s)) ^ Suc n)" if p: "prime p" for p
   proof -
     have "summable (\<lambda>n. \<bar>ln (real p)\<bar> * (norm (fds_nth f p / nat_power p s)) ^ Suc n)"
       using p abs_summable_on_Sigma_project2[OF sum2, of p] unfolding abs_summable_on_nat_iff'
       by (simp add: norm_power norm_mult norm_divide mult_ac del: power_Suc)
     thus ?thesis by (rule summable_mult_D) (insert p, auto dest: prime_gt_1_nat)
   qed
   have sums: "(\<lambda>n. (fds_nth f p / nat_power p s) ^ Suc n) sums
                 (1 / (1 - fds_nth f p / nat_power p s) - 1)" if p: "prime p" for p :: nat
   proof -
     from sum4[OF p] have "norm (fds_nth f p / nat_power p s) < 1"
       unfolding summable_Suc_iff by (simp add: summable_geometric_iff)
     from geometric_sums[OF this] show ?thesis by (subst sums_Suc_iff) auto
   qed
 
   have eq: "(\<Sum>\<^sub>ak. - ((fds_nth f p / nat_power p s) ^ Suc k * of_real (ln (real p)))) =
                -(of_real (ln (real p)) * (1 / (1 - fds_nth f p / nat_power p s) - 1))"
     if p: "prime p" for p
   proof -
     have "(\<Sum>\<^sub>ak. - ((fds_nth f p / nat_power p s) ^ Suc k * of_real (ln (real p)))) =
              (\<Sum>\<^sub>ak. (fds_nth f p / nat_power p s) ^ Suc k) * of_real (-ln (real p))"
       using sum4[of p] p
       by (subst infsetsum_cmult_left [symmetric])
          (auto simp: abs_summable_on_nat_iff' norm_power simp del: power_Suc)
     also have "(\<Sum>\<^sub>ak. (fds_nth f p / nat_power p s) ^ Suc k) =
                  (1 / (1 - fds_nth f p / nat_power p s) - 1)" using sum4[OF p] sums[OF p]
       by (subst infsetsum_nat')
          (auto simp: sums_iff abs_summable_on_nat_iff' norm_power simp del: power_Suc)
     finally show ?thesis by (simp add: mult_ac)
   qed
 
   have sum3: "(\<lambda>x. \<Sum>\<^sub>ay. - ((fds_nth f x / nat_power x s) ^ Suc y * of_real (ln (real x))))
                  abs_summable_on {p. prime p}"
     using sum2 by (rule abs_summable_on_Sigma_project1') auto
   also have "?this \<longleftrightarrow> (\<lambda>p. -(of_real (ln (real p)) *
                 (1 / (1 - fds_nth f p / nat_power p s) - 1))) abs_summable_on {p. prime p}"
     by (intro abs_summable_on_cong eq) auto
   also have "\<dots> \<longleftrightarrow> ?th1" by (subst abs_summable_on_uminus_iff) auto
   finally show ?th1 .
 
   have "eval_fds h s = (\<Sum>\<^sub>an. fds_nth h n / nat_power n s)"
     using * unfolding eval_fds_def by (subst infsetsum_nat') auto
   also have "\<dots> = (\<Sum>\<^sub>an \<in> {n. primepow n}. -fds_nth f n * mangoldt n / nat_power n s)"
     unfolding h_def using fds_nth_logderiv_completely_multiplicative[OF assms(2)]
     by (intro infsetsum_cong_neutral) (auto simp: fds_nth_fds mangoldt_def)
   also have "\<dots> = (\<Sum>\<^sub>a(p,k)\<in>(?P \<times> UNIV). -fds_nth f (p ^ Suc k) * mangoldt (p ^ Suc k) /
                                             nat_power (p ^ Suc k) s)"
      using bij_betw_primepows unfolding case_prod_unfold
      by (intro infsetsum_reindex_bij_betw [symmetric])
   also have "\<dots> = (\<Sum>\<^sub>a(p,k)\<in>(?P \<times> UNIV).
                      -((fds_nth f p / nat_power p s) ^ Suc k) * of_real (ln (real p)))"
     by (intro infsetsum_cong)
        (auto simp: f.mult f.power mangoldt_def aprimedivisor_prime_power ln_realpow prime_gt_0_nat
           nat_power_power_left divide_simps simp del: power_Suc)
   also have "\<dots> = (\<Sum>\<^sub>ap | prime p. \<Sum>\<^sub>ak.
                     - ((fds_nth f p / nat_power p s) ^ Suc k) * of_real (ln (real p)))"
     using sum2 by (subst infsetsum_Times) (auto simp: case_prod_unfold)
   also have "\<dots> = (\<Sum>\<^sub>ap | prime p. -(of_real (ln (real p)) *
                     (1 / (1 - fds_nth f p / nat_power p s) - 1)))"
     using eq by (intro infsetsum_cong) auto
   finally show ?th2 by (subst (asm) infsetsum_uminus)
 qed
 
 lemma eval_fds_logderiv_zeta:
   assumes "Re s > 1"
   shows  "(\<lambda>p. of_real (ln (real p)) / (p powr s - 1))
             abs_summable_on {p. prime p}" (is ?th1)
     and  "deriv zeta s / zeta s =
             -(\<Sum>\<^sub>ap | prime p. of_real (ln (real p)) / (p powr s - 1))" (is ?th2)
 proof -
   have *: "completely_multiplicative_function (fds_nth fds_zeta :: _ \<Rightarrow> complex)"
     by standard auto
   note abscissa = le_less_trans[OF abs_conv_abscissa_completely_multiplicative_log_deriv[OF *]]
   have "(\<lambda>p. ln (real p) * (1 / (1 - fds_nth fds_zeta p / p powr s) - 1))
            abs_summable_on {p. prime p}"
     using eval_fds_logderiv_completely_multiplicative[OF *, of s] assms by auto
   also have "?this \<longleftrightarrow> (\<lambda>p. ln (real p) / (p powr s - 1)) abs_summable_on {p. prime p}" using assms
     by (intro abs_summable_on_cong) (auto simp: fds_nth_zeta divide_simps dest: prime_gt_1_nat)
   finally show ?th1 .
 
   from assms have ev: "eventually (\<lambda>z. z \<in> {z. Re z > 1}) (nhds s)"
     by (intro eventually_nhds_in_open open_halfspace_Re_gt) auto
   have "deriv zeta s = deriv (eval_fds fds_zeta) s"
     by (intro deriv_cong_ev[OF eventually_mono[OF ev]]) (auto simp: eval_fds_zeta)
   also have "deriv (eval_fds fds_zeta) s / zeta s = eval_fds (fds_deriv fds_zeta / fds_zeta) s"
     using assms zeta_Re_gt_1_nonzero[of s]
     by (subst eval_fds_log_deriv) (auto simp: eval_fds_zeta eval_fds_deriv intro!: abscissa)
   also have "eval_fds (fds_deriv fds_zeta / fds_zeta) s =
                -(\<Sum>\<^sub>ap | prime p. ln (real p) * (1 / (1 - fds_nth fds_zeta p / p powr s) - 1))"
     (is "_ = -?S") using eval_fds_logderiv_completely_multiplicative[OF *, of s] assms by auto
   also have "?S = (\<Sum>\<^sub>ap | prime p. ln (real p) / (p powr s - 1))" using assms
     by (intro infsetsum_cong) (auto simp: fds_nth_zeta divide_simps dest: prime_gt_1_nat)
   finally show ?th2 .
 qed
 
 lemma sums_logderiv_zeta:
   assumes "Re s > 1"
   shows   "(\<lambda>p. if prime p then of_real (ln (real p)) / (of_nat p powr s - 1) else 0) sums
              -(deriv zeta s / zeta s)" (is "?f sums _")
 proof -
   note * = eval_fds_logderiv_zeta[OF assms]
   from sums_infsetsum_nat[OF *(1)] and *(2) show ?thesis by simp
 qed
 
 lemma abs_conv_abscissa_diff_le:
   "abs_conv_abscissa (f - g :: 'a :: dirichlet_series fds) \<le>
      max (abs_conv_abscissa f) (abs_conv_abscissa g)"
   using abs_conv_abscissa_add_le[of f "-g"] by auto
 
 lemma abs_conv_abscissa_diff_leI:
   "abs_conv_abscissa (f :: 'a :: dirichlet_series fds) \<le> d \<Longrightarrow> abs_conv_abscissa g \<le> d \<Longrightarrow>
      abs_conv_abscissa (f - g) \<le> d"
   using abs_conv_abscissa_diff_le[of f g] by (auto simp: le_max_iff_disj)
 
 lemma range_add_nat: "range (\<lambda>n. n + c) = {(c::nat)..}"
 proof safe
   fix x assume "x \<ge> c"
   hence "x = x - c + c" by simp
   thus "x \<in> range (\<lambda>n. n + c)" by blast
 qed auto
 
 lemma abs_summable_hurwitz_zeta:
   assumes "Re s > 1" "a + real b > 0"
   shows   "(\<lambda>n. 1 / (of_nat n + a) powr s) abs_summable_on {b..}"
 proof -
   from assms have "summable (\<lambda>n. cmod (1 / (of_nat (n + b) + a) powr s))"
     using summable_hurwitz_zeta_real[of "Re s" "a + b"]
     by (auto simp: norm_divide powr_minus field_simps norm_powr_real_powr)
   hence "(\<lambda>n. 1 / (of_nat (n + b) + a) powr s) abs_summable_on UNIV"
     by (auto simp: abs_summable_on_nat_iff' add_ac)
   also have "?this \<longleftrightarrow> (\<lambda>n. 1 / (of_nat n + a) powr s) abs_summable_on range (\<lambda>n. n + b)"
     by (rule abs_summable_on_reindex_iff) auto
   also have "range (\<lambda>n. n + b) = {b..}" by (rule range_add_nat)
   finally show ?thesis .
 qed
 
 lemma hurwitz_zeta_nat_conv_infsetsum:
   assumes "a > 0" and "Re s > 1"
   shows   "hurwitz_zeta (real a) s = (\<Sum>\<^sub>an. of_nat (n + a) powr -s)"
           "hurwitz_zeta (real a) s = (\<Sum>\<^sub>an\<in>{a..}. of_nat n powr -s)"
 proof -
   have "hurwitz_zeta (real a) s = (\<Sum>n. of_nat (n + a) powr -s)"
     using assms by (subst hurwitz_zeta_conv_suminf) auto
   also have "\<dots> = (\<Sum>\<^sub>an. of_nat (n + a) powr -s)"
     using abs_summable_hurwitz_zeta[of s a 0] assms
     by (intro infsetsum_nat' [symmetric]) (auto simp: powr_minus field_simps)
   finally show "hurwitz_zeta (real a) s = (\<Sum>\<^sub>an. of_nat (n + a) powr -s)" .
   also have "\<dots> = (\<Sum>\<^sub>an\<in>range (\<lambda>n. n + a). of_nat n powr -s)"
     by (rule infsetsum_reindex [symmetric]) auto
   also have "range (\<lambda>n. n + a) = {a..}" by (rule range_add_nat)
   finally show "hurwitz_zeta (real a) s = (\<Sum>\<^sub>an\<in>{a..}. of_nat n powr -s)" .
 qed
 
 lemma continuous_on_pre_zeta [continuous_intros]:
   assumes "continuous_on A f" "a > 0"
   shows   "continuous_on A (\<lambda>x. pre_zeta a (f x))"
 proof -
   from assms have "continuous_on UNIV (pre_zeta a)"
     by (intro holomorphic_on_imp_continuous_on[OF holomorphic_pre_zeta]) auto
   from continuous_on_compose2[OF this assms(1)] show ?thesis by simp
 qed
 
 lemma continuous_pre_zeta [continuous_intros]:
   assumes "continuous (at x within A) f" "a > 0"
   shows   "continuous (at x within A) (\<lambda>x. pre_zeta a (f x))"
 proof -
   have "continuous (at z) (pre_zeta a)" for z
     by (rule continuous_on_interior[of UNIV]) (insert assms, auto intro!: continuous_intros)
   from continuous_within_compose3[OF this assms(1)] show ?thesis .
 qed
 
 
 lemma pre_zeta_bound:
   assumes "0 < Re s" and a: "a > 0"
   shows   "norm (pre_zeta a s) \<le> (1 + norm s / Re s) / 2 * a powr -Re s"
 proof -
   let ?f = "\<lambda>x. - (s * (x + a) powr (-1-s))"
   let ?g' = "\<lambda>x. norm s * (x + a) powr (-1-Re s)"
   let ?g = "\<lambda>x. -norm s / Re s * (x + a) powr (-Re s)"
   define R where "R = EM_remainder 1 ?f 0"
   have [simp]: "-Re s - 1 = -1 - Re s" by (simp add: algebra_simps)
 
   have "\<bar>frac x - 1 / 2\<bar> \<le> 1 / 2" for x :: real unfolding frac_def
     by linarith
   hence "\<bar>pbernpoly (Suc 0) x\<bar> \<le> 1 / 2" for x
     by (simp add: pbernpoly_def bernpoly_def)
   moreover have "((\<lambda>b. cmod s * (b + a) powr - Re s / Re s) \<longlongrightarrow> 0) at_top"
     using \<open>Re s > 0\<close> \<open>a > 0\<close> by real_asymp
   ultimately have *: "\<forall>x. x \<ge> real 0 \<longrightarrow> norm (EM_remainder 1 ?f (int x)) \<le>
                            (1 / 2) / fact 1 * (-?g (real x))"
     using \<open>a > 0\<close> \<open>Re s > 0\<close>
     by (intro norm_EM_remainder_le_strong_nat'[where g' = ?g' and Y = "{}"])
        (auto intro!: continuous_intros derivative_eq_intros
              simp: field_simps norm_mult norm_powr_real_powr add_eq_0_iff)
   have R: "norm R \<le> norm s / (2 * Re s) * a powr -Re s"
     unfolding R_def using spec[OF *, of 0] by simp
 
   from assms have "pre_zeta a s = a powr -s / 2 + R"
     by (simp add: pre_zeta_def pre_zeta_aux_def R_def)
   also have "norm \<dots> \<le> a powr -Re s / 2 + norm s / (2 * Re s) * a powr -Re s" using a
     by (intro order.trans[OF norm_triangle_ineq] add_mono R) (auto simp: norm_powr_real_powr)
   also have "\<dots> = (1 + norm s / Re s) / 2 * a powr -Re s"
     by (simp add: field_simps)
   finally show ?thesis .
 qed
 
 lemma pre_zeta_bound':
   assumes "0 < Re s" and a: "a > 0"
   shows   "norm (pre_zeta a s) \<le> norm s / (Re s * a powr Re s)"
 proof -
   from assms have "norm (pre_zeta a s) \<le> (1 + norm s / Re s) / 2 * a powr -Re s"
     by (intro pre_zeta_bound) auto
   also have "\<dots> = (Re s + norm s) / 2 / (Re s * a powr Re s)"
     using assms by (auto simp: field_simps powr_minus)
   also have "Re s + norm s \<le> norm s + norm s" by (intro add_right_mono complex_Re_le_cmod)
   also have "(norm s + norm s) / 2 = norm s" by simp
   finally show "norm (pre_zeta a s) \<le> norm s / (Re s * a powr Re s)"
     using assms by (simp add: divide_right_mono)
 qed
 
 lemma summable_comparison_test_bigo:
   fixes f :: "nat \<Rightarrow> real"
   assumes "summable (\<lambda>n. norm (g n))" "f \<in> O(g)"
   shows   "summable f"
 proof -
   from \<open>f \<in> O(g)\<close> obtain C where C: "eventually (\<lambda>x. norm (f x) \<le> C * norm (g x)) at_top"
     by (auto elim: landau_o.bigE)
   thus ?thesis
     by (rule summable_comparison_test_ev) (insert assms, auto intro: summable_mult)
 qed
 
 lemma deriv_zeta_eq:
   assumes s: "s \<noteq> 1"
   shows   "deriv zeta s = deriv (pre_zeta 1) s - 1 / (s - 1)\<^sup>2"
 proof -
   from s have ev: "eventually (\<lambda>z. z \<noteq> 1) (nhds s)" by (intro t1_space_nhds)
   have [derivative_intros]: "(pre_zeta 1 has_field_derivative deriv (pre_zeta 1) s) (at s)"
     by (intro holomorphic_derivI[of _ UNIV] holomorphic_intros) auto
   have "((\<lambda>s. pre_zeta 1 s + 1 / (s - 1)) has_field_derivative
           (deriv (pre_zeta 1) s - 1 / (s - 1)\<^sup>2)) (at s)"
     using s by (auto intro!: derivative_eq_intros simp: power2_eq_square)
   also have "?this \<longleftrightarrow> (zeta has_field_derivative (deriv (pre_zeta 1) s - 1 / (s - 1)\<^sup>2)) (at s)"
     by (intro has_field_derivative_cong_ev eventually_mono[OF ev])
        (auto simp: zeta_def hurwitz_zeta_def)
   finally show ?thesis by (rule DERIV_imp_deriv)
 qed
 
 lemma zeta_remove_zero:
   assumes "Re s \<ge> 1"
   shows   "(s - 1) * pre_zeta 1 s + 1 \<noteq> 0"
 proof (cases "s = 1")
   case False
   hence "(s - 1) * pre_zeta 1 s + 1 = (s - 1) * zeta s"
     by (simp add: zeta_def hurwitz_zeta_def divide_simps)
   also from False assms have "\<dots> \<noteq> 0" using zeta_Re_ge_1_nonzero[of s] by auto
   finally show ?thesis .
 qed auto
 
 lemma eval_fds_deriv_zeta:
   assumes "Re s > 1"
   shows   "eval_fds (fds_deriv fds_zeta) s = deriv zeta s"
 proof -
   have ev: "eventually (\<lambda>z. z \<in> {z. Re z > 1}) (nhds s)"
     using assms by (intro eventually_nhds_in_open open_halfspace_Re_gt) auto
   from assms have "eval_fds (fds_deriv fds_zeta) s = deriv (eval_fds fds_zeta) s"
     by (subst eval_fds_deriv) auto
   also have "\<dots> = deriv zeta s"
     by (intro deriv_cong_ev eventually_mono[OF ev]) (auto simp: eval_fds_zeta)
   finally show ?thesis .
 qed
 
 lemma length_sorted_list_of_set [simp]:
   "finite A \<Longrightarrow> length (sorted_list_of_set A) = card A"
   by (metis length_remdups_card_conv length_sort set_sorted_list_of_set
             sorted_list_of_set_sort_remdups)
 
 lemma le_nat_iff': "x \<le> nat y \<longleftrightarrow> x = 0 \<and> y \<le> 0 \<or> int x \<le> y"
   by auto
 
 lemma sum_upto_plus1:
   assumes "x \<ge> 0"
   shows   "sum_upto f (x + 1) = sum_upto f x + f (Suc (nat \<lfloor>x\<rfloor>))"
 proof -
   have "sum_upto f (x + 1) = sum f {0<..Suc (nat \<lfloor>x\<rfloor>)}"
     using assms by (simp add: sum_upto_altdef nat_add_distrib)
   also have "{0<..Suc (nat \<lfloor>x\<rfloor>)} = insert (Suc (nat \<lfloor>x\<rfloor>)) {0<..nat \<lfloor>x\<rfloor>}"
     by auto
   also have "sum f \<dots> = sum_upto f x + f (Suc (nat \<lfloor>x\<rfloor>))"
     by (subst sum.insert) (auto simp: sum_upto_altdef add_ac)
   finally show ?thesis .
 qed
 
 lemma sum_upto_minus1:
   assumes "x \<ge> 1"
   shows   "sum_upto f (x - 1) = (sum_upto f x - f (nat \<lfloor>x\<rfloor>) :: 'a :: ab_group_add)"
   using sum_upto_plus1[of "x - 1" f] assms by (simp add: algebra_simps nat_diff_distrib)
 
 lemma integral_smallo:
   fixes f g g' :: "real \<Rightarrow> real"
   assumes "f \<in> o(g')" and "filterlim g at_top at_top"
   assumes "\<And>a' x. a \<le> a' \<Longrightarrow> a' \<le> x \<Longrightarrow> f integrable_on {a'..x}"
   assumes deriv: "\<And>x. x \<ge> a \<Longrightarrow> (g has_field_derivative g' x) (at x)"
   assumes cont: "continuous_on {a..} g'"
   assumes nonneg: "\<And>x. x \<ge> a \<Longrightarrow> g' x \<ge> 0"
   shows   "(\<lambda>x. integral {a..x} f) \<in> o(g)"
 proof (rule landau_o.smallI)
   fix c :: real assume c: "c > 0"
   note [continuous_intros] = continuous_on_subset[OF cont]
   define c' where "c' = c / 2"
   from c have c': "c' > 0" by (simp add: c'_def)
   from landau_o.smallD[OF assms(1) this]
     obtain b where b: "\<And>x. x \<ge> b \<Longrightarrow> norm (f x) \<le> c' * norm (g' x)"
     unfolding eventually_at_top_linorder by blast
   define b' where "b' = max a b"
   define D where "D = norm (integral {a..b'} f)"
 
   have "filterlim (\<lambda>x. c' * g x) at_top at_top"
     using c' by (intro filterlim_tendsto_pos_mult_at_top[OF tendsto_const] assms)
   hence "eventually (\<lambda>x. c' * g x \<ge> D - c' * g b') at_top"
     by (auto simp: filterlim_at_top)
   thus "eventually (\<lambda>x. norm (integral {a..x} f) \<le> c * norm (g x)) at_top"
     using eventually_ge_at_top[of b']
   proof eventually_elim
     case (elim x)
     have b': "a \<le> b'" "b \<le> b'" by (auto simp: b'_def)
     from elim b' have integrable: "(\<lambda>x. \<bar>g' x\<bar>) integrable_on {b'..x}"
       by (intro integrable_continuous_real continuous_intros) auto
     have "integral {a..x} f = integral {a..b'} f + integral {b'..x} f"
       using elim b' by (intro Henstock_Kurzweil_Integration.integral_combine [symmetric] assms) auto
     also have "norm \<dots> \<le> D + norm (integral {b'..x} f)"
       unfolding D_def by (rule norm_triangle_ineq)
     also have "norm (integral {b'..x} f) \<le> integral {b'..x} (\<lambda>x. c' * norm (g' x))"
       using b' elim assms c' integrable by (intro integral_norm_bound_integral b assms) auto
     also have "\<dots> = c' * integral {b'..x} (\<lambda>x. \<bar>g' x\<bar>)" by simp
     also have "integral {b'..x} (\<lambda>x. \<bar>g' x\<bar>) = integral {b'..x} g'"
       using assms b' by (intro integral_cong) auto
     also have "(g' has_integral (g x - g b')) {b'..x}" using b' elim
       by (intro fundamental_theorem_of_calculus)
          (auto simp flip: has_field_derivative_iff_has_vector_derivative
                intro!: has_field_derivative_at_within[OF deriv])
     hence "integral {b'..x} g' = g x - g b'"
       by (simp add: has_integral_iff)
     also have "D + c' * (g x - g b') \<le> c * g x"
       using elim by (simp add: field_simps c'_def)
     also have "\<dots> \<le> c * norm (g x)"
       using c by (intro mult_left_mono) auto
     finally show ?case by simp
   qed
 qed
 
 lemma integral_bigo:
   fixes f g g' :: "real \<Rightarrow> real"
   assumes "f \<in> O(g')" and "filterlim g at_top at_top"
   assumes "\<And>a' x. a \<le> a' \<Longrightarrow> a' \<le> x \<Longrightarrow> f integrable_on {a'..x}"
   assumes deriv: "\<And>x. x \<ge> a \<Longrightarrow> (g has_field_derivative g' x) (at x within {a..})"
   assumes cont: "continuous_on {a..} g'"
   assumes nonneg: "\<And>x. x \<ge> a \<Longrightarrow> g' x \<ge> 0"
   shows   "(\<lambda>x. integral {a..x} f) \<in> O(g)"
 proof -
   note [continuous_intros] = continuous_on_subset[OF cont]
   from landau_o.bigE[OF assms(1)]
     obtain c b where c: "c > 0" and b: "\<And>x. x \<ge> b \<Longrightarrow> norm (f x) \<le> c * norm (g' x)"
       unfolding eventually_at_top_linorder by metis
   define c' where "c' = c / 2"
   define b' where "b' = max a b"
   define D where "D = norm (integral {a..b'} f)"
 
   have "filterlim (\<lambda>x. c * g x) at_top at_top"
     using c by (intro filterlim_tendsto_pos_mult_at_top[OF tendsto_const] assms)
   hence "eventually (\<lambda>x. c * g x \<ge> D - c * g b') at_top"
     by (auto simp: filterlim_at_top)
   hence "eventually (\<lambda>x. norm (integral {a..x} f) \<le> 2 * c * norm (g x)) at_top"
     using eventually_ge_at_top[of b']
   proof eventually_elim
     case (elim x)
     have b': "a \<le> b'" "b \<le> b'" by (auto simp: b'_def)
     from elim b' have integrable: "(\<lambda>x. \<bar>g' x\<bar>) integrable_on {b'..x}"
       by (intro integrable_continuous_real continuous_intros) auto
     have "integral {a..x} f = integral {a..b'} f + integral {b'..x} f"
       using elim b' by (intro Henstock_Kurzweil_Integration.integral_combine [symmetric] assms) auto
     also have "norm \<dots> \<le> D + norm (integral {b'..x} f)"
       unfolding D_def by (rule norm_triangle_ineq)
     also have "norm (integral {b'..x} f) \<le> integral {b'..x} (\<lambda>x. c * norm (g' x))"
       using b' elim assms c integrable by (intro integral_norm_bound_integral b assms) auto
     also have "\<dots> = c * integral {b'..x} (\<lambda>x. \<bar>g' x\<bar>)" by simp
     also have "integral {b'..x} (\<lambda>x. \<bar>g' x\<bar>) = integral {b'..x} g'"
       using assms b' by (intro integral_cong) auto
     also have "(g' has_integral (g x - g b')) {b'..x}" using b' elim
       by (intro fundamental_theorem_of_calculus)
          (auto simp flip: has_field_derivative_iff_has_vector_derivative
                intro!: DERIV_subset[OF deriv])
     hence "integral {b'..x} g' = g x - g b'"
       by (simp add: has_integral_iff)
     also have "D + c * (g x - g b') \<le> 2 * c * g x"
       using elim by (simp add: field_simps c'_def)
     also have "\<dots> \<le> 2 * c * norm (g x)"
       using c by (intro mult_left_mono) auto
     finally show ?case by simp
   qed
   thus ?thesis by (rule bigoI)
 qed
 
 lemma primepows_le_subset:
   assumes x: "x > 0" and l: "l > 0"
   shows   "{(p, i). prime p \<and> l \<le> i \<and> real (p ^ i) \<le> x} \<subseteq> {..nat \<lfloor>root l x\<rfloor>} \<times> {..nat \<lfloor>log 2 x\<rfloor>}"
 proof safe
   fix p i :: nat assume pi: "prime p" "i \<ge> l" "real (p ^ i) \<le> x"
   have "real p ^ l \<le> real p ^ i" using pi x l
     by (intro power_increasing) (auto dest: prime_gt_0_nat)
   also have "\<dots> \<le> x" using pi by simp
   finally have "root l (real p ^ l) \<le> root l x"
     using x pi l by (subst real_root_le_iff) auto
   also have "root l (real p ^ l) = real p"
     using pi l by (subst real_root_pos2) auto
   finally show "p \<le> nat \<lfloor>root l x\<rfloor>" using pi l x by (simp add: le_nat_iff' le_floor_iff)
 
   from pi have "2 ^ i \<le> real p ^ i" using l
     by (intro power_mono) (auto dest: prime_gt_1_nat)
   also have "\<dots> \<le> x" using pi by simp
   finally show "i \<le> nat \<lfloor>log 2 x\<rfloor>" using pi x
     by (auto simp: le_nat_iff' le_floor_iff le_log_iff powr_realpow)
 qed
 
 lemma mangoldt_non_primepow: "\<not>primepow n \<Longrightarrow> mangoldt n = 0"
   by (auto simp: mangoldt_def)
 
 lemma le_imp_bigo_real:
   assumes "c \<ge> 0" "eventually (\<lambda>x. f x \<le> c * (g x :: real)) F" "eventually (\<lambda>x. 0 \<le> f x) F"
   shows   "f \<in> O[F](g)"
 proof -
   have "eventually (\<lambda>x. norm (f x) \<le> c * norm (g x)) F"
     using assms(2,3)
   proof eventually_elim
     case (elim x)
     have "norm (f x) \<le> c * g x" using elim by simp
     also have "\<dots> \<le> c * norm (g x)" by (intro mult_left_mono assms) auto
     finally show ?case .
   qed
   thus ?thesis by (intro bigoI[of _ c]) auto
 qed
 
 (* TODO: unneeded. But why does real_asymp not work? *)
 lemma ln_minus_ln_floor_bigo: "(\<lambda>x. ln x - ln (real (nat \<lfloor>x\<rfloor>))) \<in> O(\<lambda>_. 1)"
 proof (intro le_imp_bigo_real[of 1] eventually_mono[OF eventually_ge_at_top[of 1]])
   fix x :: real assume x: "x \<ge> 1"
   from x have *: "x - real (nat \<lfloor>x\<rfloor>) \<le> 1" by linarith
   from x have "ln x - ln (real (nat \<lfloor>x\<rfloor>)) \<le> (x - real (nat \<lfloor>x\<rfloor>)) / real (nat \<lfloor>x\<rfloor>)"
     by (intro ln_diff_le) auto
   also have "\<dots> \<le> 1 / 1" using x * by (intro frac_le) auto
   finally show "ln x - ln (real (nat \<lfloor>x\<rfloor>)) \<le> 1 * 1" by simp
 qed auto
 
 lemma cos_geD:
   assumes "cos x \<ge> cos a" "0 \<le> a" "a \<le> pi" "-pi \<le> x" "x \<le> pi"
   shows   "x \<in> {-a..a}"
 proof (cases "x \<ge> 0")
   case True
   with assms show ?thesis
     by (subst (asm) cos_mono_le_eq) auto
 next
   case False
   with assms show ?thesis using cos_mono_le_eq[of a "-x"]
     by auto
 qed
 
 (* TODO: Could be generalised *)
 lemma path_image_part_circlepath_same_Re:
   assumes "0 \<le> b" "b \<le> pi" "a = -b" "r \<ge> 0"
   shows   "path_image (part_circlepath c r a b) = sphere c r \<inter> {s. Re s \<ge> Re c + r * cos a}"
 proof safe
   fix z assume "z \<in> path_image (part_circlepath c r a b)"
   with assms obtain t where t: "t \<in> {a..b}" "z = c + of_real r * cis t"
     by (auto simp: path_image_part_circlepath exp_eq_polar)
   from t and assms show "z \<in> sphere c r"
     by (auto simp: dist_norm norm_mult)
   from t and assms show "Re z \<ge> Re c + r * cos a"
     using cos_monotone_0_pi_le[of t b] cos_monotone_minus_pi_0'[of a t]
     by (cases "t \<ge> 0") (auto intro!: mult_left_mono)
 next
   fix z assume z: "z \<in> sphere c r" "Re z \<ge> Re c + r * cos a"
   show "z \<in> path_image (part_circlepath c r a b)"
   proof (cases "r = 0")
     case False
     with assms have r: "r > 0" by simp
     with z have z_eq: "z = c + r * cis (Arg (z - c))"
       using Arg_eq[of "z - c"] by (auto simp: dist_norm exp_eq_polar norm_minus_commute)
   moreover from z(2) r assms have "cos b \<le> cos (Arg (z - c))"
     by (subst (asm) z_eq) auto
   with assms have "Arg (z - c) \<in> {-b..b}"
     using Arg_le_pi[of "z - c"] mpi_less_Arg[of "z - c"] by (intro cos_geD) auto
   ultimately show "z \<in> path_image (part_circlepath c r a b)"
     using assms by (subst path_image_part_circlepath) (auto simp: exp_eq_polar)
   qed (insert assms z, auto simp: path_image_part_circlepath)
 qed
 
 lemma part_circlepath_rotate_left:
   "part_circlepath c r (x + a) (x + b) = (\<lambda>z. c + cis x * (z - c)) \<circ> part_circlepath c r a b"
   by (simp add: part_circlepath_def exp_eq_polar fun_eq_iff
                 linepath_translate_left linepath_translate_right cis_mult add_ac)
 
 lemma part_circlepath_rotate_right:
   "part_circlepath c r (a + x) (b + x) = (\<lambda>z. c + cis x * (z - c)) \<circ> part_circlepath c r a b"
   by (simp add: part_circlepath_def exp_eq_polar fun_eq_iff
                 linepath_translate_left linepath_translate_right cis_mult add_ac)
 
 lemma path_image_semicircle_Re_ge:
   assumes "r \<ge> 0"
   shows   "path_image (part_circlepath c r (-pi/2) (pi/2)) =
              sphere c r \<inter> {s. Re s \<ge> Re c}"
   by (subst path_image_part_circlepath_same_Re) (simp_all add: assms)
 
 lemma sphere_rotate: "(\<lambda>z. c + cis x * (z - c)) ` sphere c r = sphere c r"
 proof safe
   fix z assume z: "z \<in> sphere c r"
   hence "z = c + cis x * (c + cis (-x) * (z - c) - c)"
         "c + cis (-x) * (z - c) \<in> sphere c r"
     by (auto simp: dist_norm norm_mult norm_minus_commute
                    cis_conv_exp exp_minus field_simps norm_divide)
   with z show "z \<in> (\<lambda>z. c + cis x * (z - c)) ` sphere c r" by blast
 qed (auto simp: dist_norm norm_minus_commute norm_mult)
 
 
 lemma path_image_semicircle_Re_le:
   assumes "r \<ge> 0"
   shows   "path_image (part_circlepath c r (pi/2) (3/2*pi)) =
              sphere c r \<inter> {s. Re s \<le> Re c}"
 proof -
   let ?f = "(\<lambda>z. c + cis pi * (z - c))"
   have *: "part_circlepath c r (pi/2) (3/2*pi) = part_circlepath c r (pi + (-pi/2)) (pi + pi/2)"
     by simp
   have "path_image (part_circlepath c r (pi/2) (3/2*pi)) =
           ?f ` sphere c r \<inter> ?f ` {s. Re c \<le> Re s}"
     unfolding * part_circlepath_rotate_left path_image_compose path_image_semicircle_Re_ge[OF assms]
     by auto
   also have "?f ` sphere c r = sphere c r"
     by (rule sphere_rotate)
   also have "?f ` {s. Re c \<le> Re s} = {s. Re c \<ge> Re s}"
     by (auto simp: image_iff intro!: exI[of _ "2 * c - x" for x])
   finally show ?thesis .
 qed
 
 lemma path_image_semicircle_Im_ge:
   assumes "r \<ge> 0"
   shows   "path_image (part_circlepath c r 0 pi) =
              sphere c r \<inter> {s. Im s \<ge> Im c}"
 proof -
   let ?f = "(\<lambda>z. c + cis (pi/2) * (z - c))"
   have *: "part_circlepath c r 0 pi = part_circlepath c r (pi / 2 + (-pi/2)) (pi / 2 + pi/2)"
     by simp
   have "path_image (part_circlepath c r 0 pi) =
           ?f ` sphere c r \<inter> ?f ` {s. Re c \<le> Re s}"
     unfolding * part_circlepath_rotate_left path_image_compose path_image_semicircle_Re_ge[OF assms]
     by auto
   also have "?f ` sphere c r = sphere c r"
     by (rule sphere_rotate)
   also have "?f ` {s. Re c \<le> Re s} = {s. Im c \<le> Im s}"
     by (auto simp: image_iff intro!: exI[of _ "c - \<i> * (x - c)" for x])
   finally show ?thesis .
 qed
 
 lemma path_image_semicircle_Im_le:
   assumes "r \<ge> 0"
   shows   "path_image (part_circlepath c r pi (2 * pi)) =
              sphere c r \<inter> {s. Im s \<le> Im c}"
 proof -
   let ?f = "(\<lambda>z. c + cis (3*pi/2) * (z - c))"
   have *: "part_circlepath c r pi (2*pi) = part_circlepath c r (3*pi/2 + (-pi/2)) (3*pi/2 + pi/2)"
     by simp
   have "path_image (part_circlepath c r pi (2 * pi)) =
           ?f ` sphere c r \<inter> ?f ` {s. Re c \<le> Re s}"
     unfolding * part_circlepath_rotate_left path_image_compose path_image_semicircle_Re_ge[OF assms]
     by auto
   also have "?f ` sphere c r = sphere c r"
     by (rule sphere_rotate)
   also have "cis (3 * pi / 2) = -\<i>"
     using cis_mult[of pi "pi / 2"] by simp
   hence "?f ` {s. Re c \<le> Re s} = {s. Im c \<ge> Im s}"
     by (auto simp: image_iff intro!: exI[of _ "c + \<i> * (x - c)" for x])
   finally show ?thesis .
 qed
 
 lemma powr_numeral [simp]: "x \<ge> 0 \<Longrightarrow> (x::real) powr numeral y = x ^ numeral y"
   using powr_numeral[of x y] by (cases "x = 0") auto
 
 lemma eval_fds_logderiv_zeta_real:
   assumes "x > (1 :: real)"
   shows  "(\<lambda>p. ln (real p) / (p powr x - 1)) abs_summable_on {p. prime p}" (is ?th1)
     and  "deriv zeta (of_real x) / zeta (of_real x) =
             -of_real (\<Sum>\<^sub>ap | prime p. ln (real p) / (p powr x - 1))" (is ?th2)
 proof -
   have "(\<lambda>p. Re (of_real (ln (real p)) / (of_nat p powr of_real x - 1)))
           abs_summable_on {p. prime p}" using assms
     by (intro abs_summable_Re eval_fds_logderiv_zeta) auto
   also have "?this \<longleftrightarrow> ?th1"
     by (intro abs_summable_on_cong) (auto simp: powr_Reals_eq)
   finally show ?th1 .
   show ?th2 using assms
     by (subst eval_fds_logderiv_zeta) (auto simp: infsetsum_of_real [symmetric] powr_Reals_eq)
 qed
 
 lemma
   fixes a b c d :: real
   assumes ab: "d * a + b \<ge> 1" and c: "c < -1" and d: "d > 0"
   defines "C \<equiv> - ((ln (d * a + b) - 1 / (c + 1)) * (d * a + b) powr (c + 1) / (d * (c + 1)))"
   shows set_integrable_ln_powr_at_top:
           "(\<lambda>x. (ln (d * x + b) * ((d * x + b) powr c))) absolutely_integrable_on {a<..}" (is ?th1)
   and   set_lebesgue_integral_ln_powr_at_top:
           "(\<integral>x\<in>{a<..}. (ln (d * x + b) * ((d * x + b) powr c)) \<partial>lborel) = C" (is ?th2)
   and   ln_powr_has_integral_at_top:
           "((\<lambda>x. ln (d * x + b) * (d * x + b) powr c) has_integral C) {a<..}" (is ?th3)
 proof -
   define f where "f = (\<lambda>x. ln (d * x + b) * (d * x + b) powr c)"
   define F where "F = (\<lambda>x. (ln (d * x + b) - 1 / (c + 1)) * (d * x + b) powr (c + 1) / (d * (c + 1)))"
 
   have *: "(F has_field_derivative f x) (at x)" "isCont f x" "f x \<ge> 0" if "x > a" for x
   proof -
     have "1 \<le> d * a + b" by fact
     also have "\<dots> < d * x + b" using that assms
       by (intro add_strict_right_mono mult_strict_left_mono)
     finally have gt_1: "d * x + b > 1" .
     show "(F has_field_derivative f x) (at x)" "isCont f x" using ab c d gt_1
     by (auto simp: F_def f_def divide_simps intro!: derivative_eq_intros continuous_intros)
        (auto simp: algebra_simps powr_add)?
     show "f x \<ge> 0" using gt_1 by (auto simp: f_def)
   qed
 
   have limits: "((F \<circ> real_of_ereal) \<longlongrightarrow> F a) (at_right (ereal a))"
                "((F \<circ> real_of_ereal) \<longlongrightarrow> 0) (at_left \<infinity>)"
     using c ab d unfolding ereal_tendsto_simps1 F_def  by (real_asymp; simp add: field_simps)+
   have 1: "set_integrable lborel (einterval a \<infinity>) f" using ab c limits
     by (intro interval_integral_FTC_nonneg) (auto intro!: * AE_I2)
   thus 2: "f absolutely_integrable_on {a<..}"
     by (auto simp: set_integrable_def integrable_completion)
   have "(LBINT x=ereal a..\<infinity>. f x) = 0 - F a" using ab c limits
     by (intro interval_integral_FTC_nonneg) (auto intro!: *)
   thus 3: ?th2
     by (simp add: interval_integral_to_infinity_eq F_def f_def C_def)
   show ?th3
     using set_borel_integral_eq_integral[OF 1] 3 by (simp add: has_integral_iff f_def C_def)
 qed
 
 lemma ln_fact_conv_sum_upto: "ln (fact n) = sum_upto ln n"
   by (induction n) (auto simp: sum_upto_plus1 add.commute[of 1] ln_mult)
 
 lemma sum_upto_ln_conv_ln_fact: "sum_upto ln x = ln (fact (nat \<lfloor>x\<rfloor>))"
   by (simp add: ln_fact_conv_sum_upto sum_upto_altdef)
 
 lemma real_of_nat_div: "real (a div b) = real_of_int \<lfloor>real a / real b\<rfloor>"
   by (subst floor_divide_of_nat_eq) auto
 
 lemma integral_subset_negligible:
   fixes f :: "'a :: euclidean_space \<Rightarrow> 'b :: banach"
   assumes "S \<subseteq> T" "negligible (T - S)"
   shows   "integral S f = integral T f"
 proof -
   have "integral T f = integral T (\<lambda>x. if x \<in> S then f x else 0)"
     by (rule integral_spike[of "T - S"]) (use assms in auto)
   also have "\<dots> = integral (S \<inter> T) f"
     by (subst integral_restrict_Int) auto
   also have "S \<inter> T = S" using assms by auto
   finally show ?thesis ..
 qed
 
 lemma integrable_on_cong [cong]:
   assumes "\<And>x. x \<in> A \<Longrightarrow> f x = g x" "A = B"
   shows   "f integrable_on A \<longleftrightarrow> g integrable_on B"
   using has_integral_cong[of A f g, OF assms(1)] assms(2)
   by (auto simp: integrable_on_def)
 
 lemma measurable_sum_upto [measurable]:
   fixes f :: "'a \<Rightarrow> nat \<Rightarrow> real"
   assumes [measurable]: "\<And>y. (\<lambda>t. f t y) \<in> M \<rightarrow>\<^sub>M borel"
   assumes [measurable]: "x \<in> M \<rightarrow>\<^sub>M borel"
   shows "(\<lambda>t. sum_upto (f t) (x t)) \<in> M \<rightarrow>\<^sub>M borel"
 proof -
   have meas: "(\<lambda>t. set_lebesgue_integral lborel {y. y \<ge> 0 \<and> y - real (nat \<lfloor>x t\<rfloor>) \<le> 0} (\<lambda>y. f t (nat \<lceil>y\<rceil>)))
           \<in> M \<rightarrow>\<^sub>M borel" (is "?f \<in> _") unfolding set_lebesgue_integral_def
     by measurable
   also have "?f = (\<lambda>t. sum_upto (f t) (x t))"
   proof
     fix t :: 'a
     show "?f t = sum_upto (f t) (x t)"
     proof (cases "x t < 1")
       case True
       hence "{y. y \<ge> 0 \<and> y - real (nat \<lfloor>x t\<rfloor>) \<le> 0} = {0}" by auto
       thus ?thesis using True
         by (simp add: set_integral_at_point sum_upto_altdef)
     next
       case False
       define n where "n = nat \<lfloor>x t\<rfloor>"
       from False have "n > 0" by (auto simp: n_def)
 
       have *: "((\<lambda>x. f t (nat \<lceil>x\<rceil>)) has_integral sum (f t) {0<..n}) {real 0..real n}"
         using \<open>n > 0\<close> by (intro nat_sum_has_integral_ceiling) auto
 
       have **: "(\<lambda>x. f t (nat \<lceil>x\<rceil>)) absolutely_integrable_on {real 0..real n}"
       proof (rule absolutely_integrable_absolutely_integrable_ubound)
         show "(\<lambda>_. MAX n\<in>{0..n}. \<bar>f t n\<bar>) absolutely_integrable_on {real 0..real n}"
           using \<open>n > 0\<close> by (subst absolutely_integrable_on_iff_nonneg)
                            (auto simp: Max_ge_iff intro!: exI[of _ "f t 0"])
         show "(\<lambda>x. f t (nat \<lceil>x\<rceil>)) integrable_on {real 0..real n}"
           using * by (simp add: has_integral_iff)
       next
         fix y :: real assume y: "y \<in> {real 0..real n}"
         have "f t (nat \<lceil>y\<rceil>) \<le> \<bar>f t (nat \<lceil>y\<rceil>)\<bar>"
           by simp
         also have "\<dots> \<le> (MAX n\<in>{0..n}. \<bar>f t n\<bar>)"
           using y by (intro Max.coboundedI) auto
         finally show "f t (nat \<lceil>y\<rceil>) \<le> (MAX n\<in>{0..n}. \<bar>f t n\<bar>)" .
       qed
       have "sum (f t) {0<..n} = (\<integral>x\<in>{real 0..real n}. f t (nat \<lceil>x\<rceil>) \<partial>lebesgue)"
         using has_integral_set_lebesgue[OF **] * by (simp add: has_integral_iff)
       also have "\<dots> = (\<integral>x\<in>{real 0..real n}. f t (nat \<lceil>x\<rceil>) \<partial>lborel)"
         unfolding set_lebesgue_integral_def by (subst integral_completion) auto
       also have "{real 0..real n} = {y. 0 \<le> y \<and> y - real (nat \<lfloor>x t\<rfloor>) \<le> 0}"
         by (auto simp: n_def)
       also have "sum (f t) {0<..n} = sum_upto (f t) (x t)"
         by (simp add: sum_upto_altdef n_def)
       finally show ?thesis ..
     qed
   qed
   finally show ?thesis .
 qed
 
 end
diff --git a/thys/Treaps/Random_List_Permutation.thy b/thys/Treaps/Random_List_Permutation.thy
--- a/thys/Treaps/Random_List_Permutation.thy
+++ b/thys/Treaps/Random_List_Permutation.thy
@@ -1,473 +1,474 @@
 (*
   File:      Random_List.thy
   Authors:   Manuel Eberl
 
   Some facts about randomly permuted lists and how to obtain them by drawing i.i.d.
   priorities for every element.
 *)
 section \<open>Randomly-permuted lists\<close>
 theory Random_List_Permutation
 imports
   Probability_Misc
   Comparison_Sort_Lower_Bound.Linorder_Relations
 begin
 
 subsection \<open>General facts about linear orderings\<close>
 
 text \<open>
   We define the set of all linear orderings on a given set and show some properties about it.
 \<close>
 definition linorders_on :: "'a set \<Rightarrow> ('a \<times> 'a) set set" where
   "linorders_on A = {R. linorder_on A R}"
   
 lemma linorders_on_empty [simp]: "linorders_on {} = {{}}"
   by (auto simp: linorders_on_def linorder_on_def refl_on_def)
     
 lemma linorders_finite_nonempty:
   assumes "finite A"
   shows   "linorders_on A \<noteq> {}"
 proof -
   from finite_distinct_list[OF assms] obtain xs where "set xs = A" "distinct xs" by blast
   hence "linorder_on A (linorder_of_list xs)" by auto
   thus ?thesis by (auto simp: linorders_on_def)
 qed
 
 text \<open>
   There is an obvious bijection between permutations of a set (i.\,e.\ lists with all elements
   from that set without repetition) and linear orderings on it.
 \<close>
 lemma bij_betw_linorders_on:
   assumes "finite A"
   shows   "bij_betw linorder_of_list (permutations_of_set A) (linorders_on A)"
   using bij_betw_linorder_of_list[of A] assms unfolding linorders_on_def by simp
 
 lemma sorted_wrt_list_of_set_linorder_of_list [simp]:
   assumes "distinct xs"
   shows   "sorted_wrt_list_of_set (linorder_of_list xs) (set xs) = xs"
   by (rule sorted_wrt_list_of_set_eqI[of "set xs"]) (insert assms, auto)
     
 lemma linorder_of_list_sorted_wrt_list_of_set [simp]:
   assumes "linorder_on A R" "finite A"
   shows   "linorder_of_list (sorted_wrt_list_of_set R A) = R"
 proof -
   from assms(1) have subset: "R \<subseteq> A \<times> A" by (auto simp: linorder_on_def refl_on_def)
   from assms and subset show ?thesis
     by (auto simp: linorder_of_list_def linorder_sorted_wrt_list_of_set sorted_wrt_linorder_index_le_iff)
 qed
 
 lemma bij_betw_linorders_on':
   assumes "finite A"
   shows   "bij_betw (\<lambda>R. sorted_wrt_list_of_set R A) (linorders_on A) (permutations_of_set A)"
   by (rule bij_betw_byWitness[where f' = linorder_of_list])
      (insert assms, auto simp: linorders_on_def permutations_of_set_def
         linorder_sorted_wrt_list_of_set)
 
 lemma finite_linorders_on [intro]:
   assumes "finite A"
   shows   "finite (linorders_on A)"
 proof -
   have "finite (permutations_of_set A)" by simp
   also have "?this \<longleftrightarrow> finite (linorders_on A)"
     using assms by (rule bij_betw_finite [OF bij_betw_linorders_on])
   finally show ?thesis .
 qed
 
 
 text \<open>
   Next, we look at the ordering defined by a list that is permuted with some permutation
   function. For this, we first define the composition of a relation with a function.
 \<close>
 definition map_relation :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('b \<times> 'b) set \<Rightarrow> ('a \<times> 'a) set" where
   "map_relation A f R = {(x,y)\<in>A\<times>A. (f x, f y) \<in> R}"
 
 lemma index_distinct_eqI:
   assumes "distinct xs" "i < length xs" "xs ! i = x"
   shows   "index xs x = i"
   using assms by (induction xs arbitrary: i) (auto simp: nth_Cons split: nat.splits)
   
 lemma index_permute_list:
   assumes "\<pi> permutes {..<length xs}" "distinct xs" "x \<in> set xs"
   shows   "index (permute_list \<pi> xs) x = inv \<pi> (index xs x)"
 proof -
   have *: "inv \<pi> permutes {..<length xs}" by (rule permutes_inv) fact
   from assms show ?thesis
     using assms permutes_in_image[OF *]
     by (intro index_distinct_eqI) (simp_all add: permute_list_nth permutes_inverses)
 qed
 
 lemma linorder_of_list_permute:
   assumes "\<pi> permutes {..<length xs}" "distinct xs"
   shows   "linorder_of_list (permute_list \<pi> xs) =
              map_relation (set xs) ((!) xs \<circ> inv \<pi> \<circ> index xs) (linorder_of_list xs)"
 proof -
   note * = permutes_inv[OF assms(1)]
   have less: "inv \<pi> i < length xs" if "i < length xs" for i
     using permutes_in_image[OF *] and that by simp
   from assms and * show ?thesis
     by (auto simp: linorder_of_list_def map_relation_def index_nth_id index_permute_list less)
 qed
 
 
 lemma inj_on_conv_Ex1: "inj_on f A \<longleftrightarrow> (\<forall>y\<in>f`A. \<exists>!x\<in>A. y = f x)"
   by (auto simp: inj_on_def)
 
 lemma bij_betw_conv_Ex1: "bij_betw f A B \<longleftrightarrow> (\<forall>y\<in>B. \<exists>!x\<in>A. f x = y) \<and> B = f ` A"
   unfolding bij_betw_def inj_on_conv_Ex1 by (auto simp: eq_commute)
 
 lemma permutesI:
   assumes "bij_betw f A A" "\<forall>x. x \<notin> A \<longrightarrow> f x = x"
   shows   "f permutes A"
   unfolding permutes_def
 proof (intro conjI allI impI)
   fix y
   from assms have [simp]: "f x \<in> A \<longleftrightarrow> x \<in> A" for x
     by (auto simp: bij_betw_def)
   show "\<exists>!x. f x = y"
   proof (cases "y \<in> A")
     case True
     also from assms have "A = f ` A" by (auto simp: bij_betw_def)
     finally obtain x where "x \<in> A" "y = f x" by auto
     with assms and \<open>y \<in> A\<close> show ?thesis
       by (intro ex1I[of _ x]) (auto simp: bij_betw_def dest: inj_onD)
   qed (insert assms, auto)
 qed (insert assms, auto)
 
 text \<open>
   We now show the important lemma that any two linear orderings on a finite set can be
   mapped onto each other by a permutation.
 \<close>
 lemma linorder_permutation_exists:
   assumes "finite A" "linorder_on A R" "linorder_on A R'"
   obtains \<pi> where "\<pi> permutes A" "R' = map_relation A \<pi> R"
 proof -
   define xs where "xs = sorted_wrt_list_of_set R A"
   define ys where "ys = sorted_wrt_list_of_set R' A"
   have xs_ys: "distinct xs" "distinct ys" "set xs = A" "set ys = A"
     using assms by (simp_all add: linorder_sorted_wrt_list_of_set xs_def ys_def)
       
   from xs_ys have "mset ys = mset xs" by (simp add: set_eq_iff_mset_eq_distinct [symmetric])
   from mset_eq_permutation[OF this] guess \<pi> . note \<pi> = this
   define \<pi>' where "\<pi>' = (\<lambda>x. if x \<notin> A then x else xs ! inv \<pi> (index xs x))"
   have \<pi>': "\<pi>' permutes A"
   proof (rule permutesI)
     have "bij_betw ((!) xs \<circ> inv \<pi>) {..<length xs} A"
       by (rule bij_betw_trans permutes_imp_bij permutes_inv \<pi> bij_betw_nth)+ (simp_all add: xs_ys)
     hence "bij_betw ((!) xs \<circ> inv \<pi> \<circ> index xs) A A"
       by (rule bij_betw_trans [rotated] bij_betw_index)+
          (insert bij_betw_index[of xs A "length xs"], simp_all add: xs_ys atLeast0LessThan)
     also have "bij_betw ((!) xs \<circ> inv \<pi> \<circ> index xs) A A \<longleftrightarrow> bij_betw \<pi>' A A"
       by (rule bij_betw_cong) (auto simp: \<pi>'_def)
     finally show \<dots> .
   qed (simp_all add: \<pi>'_def)
   
   from assms have "R' = linorder_of_list ys" by (simp add: ys_def)
   also from \<pi> have "ys = permute_list \<pi> xs" by simp
   also have "linorder_of_list (permute_list \<pi> xs) = 
                map_relation A ((!) xs \<circ> inv \<pi> \<circ> index xs) (linorder_of_list xs)"
     using \<pi> by (subst linorder_of_list_permute) (simp_all add: xs_ys)
   also from assms have "linorder_of_list xs = R" by (simp add: xs_def)
   finally have "R' = map_relation A ((!) xs \<circ> inv \<pi> \<circ> index xs) R" .
   also have "\<dots> = map_relation A \<pi>' R" by (auto simp: map_relation_def \<pi>'_def)
   finally show ?thesis using \<pi>' and that[of \<pi>'] by simp
 qed
 
 text \<open>
   We now define the linear ordering defined by some priority function, i.\,e.\ a function
   that injectively associates priorities to every element such that elements with lower priority
   are smaller in the resulting ordering.
 \<close>
 definition linorder_from_keys :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b :: linorder) \<Rightarrow> ('a \<times> 'a) set" where
   "linorder_from_keys A f = {(x,y)\<in>A\<times>A. f x \<le> f y}"
 
 lemma linorder_from_keys_permute:
   assumes "g permutes A"
   shows   "linorder_from_keys A (f \<circ> g) = map_relation A g (linorder_from_keys A f)"
   using permutes_in_image[OF assms] by (auto simp: map_relation_def linorder_from_keys_def)
   
 lemma linorder_on_linorder_from_keys [intro]:
   assumes "inj_on f A"
   shows   "linorder_on A (linorder_from_keys A f)"
   using assms by (auto simp: linorder_on_def refl_on_def antisym_def linorder_from_keys_def
                     trans_def total_on_def dest: inj_onD)
 
 lemma linorder_from_keys_empty [simp]: "linorder_from_keys {} = (\<lambda>_. {})"
   by (simp add: linorder_from_keys_def fun_eq_iff)
     
 
 text \<open>
   We now show another important fact, namely that when we draw $n$ values i.\,i.\,d.\ uniformly
   from a non-trivial real interval, we almost surely get distinct values.
 \<close>
 lemma emeasure_PiM_diagonal:
   fixes a b :: real
   assumes "x \<in> A" "y \<in> A" "x \<noteq> y"
   assumes "a < b" "finite A"
   defines "M \<equiv> uniform_measure lborel {a..b}"
   shows   "emeasure (PiM A (\<lambda>_. M)) {h\<in>A \<rightarrow>\<^sub>E UNIV. h x = h y} = 0"
 proof -
   from assms have M: "prob_space M" unfolding M_def
     by (intro prob_space_uniform_measure) auto
   then interpret product_prob_space "\<lambda>_. M" A
     unfolding product_prob_space_def product_prob_space_axioms_def product_sigma_finite_def
     by (auto simp: prob_space_imp_sigma_finite)
   from M interpret pair_sigma_finite M M by unfold_locales
   have [measurable]: "{h\<in>extensional {x, y}. h x = h y} \<in> sets (Pi\<^sub>M {x, y} (\<lambda>i. lborel))"
   proof -
     have "{h\<in>extensional {x,y}. h x = h y} = {h \<in> space (Pi\<^sub>M {x, y} (\<lambda>i. lborel)). h x = h y}"
       by (auto simp: extensional_def space_PiM)
     also have "... \<in> sets (Pi\<^sub>M {x, y} (\<lambda>i. lborel))"
       by measurable
     finally show ?thesis .
   qed
   have [simp]: "sets (PiM A (\<lambda>_. M)) = sets (PiM A (\<lambda>_. lborel))" for A :: "'a set"
     by (intro sets_PiM_cong refl) (simp_all add: M_def)
   have sets_M_M: "sets (M \<Otimes>\<^sub>M M) = sets (borel \<Otimes>\<^sub>M borel)"
     by (intro sets_pair_measure_cong) (auto simp: M_def)
   have [measurable]: "(\<lambda>(b, a). if b = a then 1 else 0) \<in> borel_measurable (M \<Otimes>\<^sub>M M)"
     unfolding measurable_split_conv
     by (subst measurable_cong_sets[OF sets_M_M refl])
        (auto intro!: measurable_If measurable_const measurable_equality_set)
       
   have "{h\<in>A \<rightarrow>\<^sub>E UNIV. h x = h y} = 
           (\<lambda>h. restrict h {x, y}) -` {h\<in>extensional {x, y}. h x = h y} \<inter> space (PiM A (\<lambda>_. M :: real measure))"
     by (auto simp: space_PiM PiE_def extensional_def M_def)
   also have "emeasure (PiM A (\<lambda>_. M)) \<dots> = 
                emeasure (distr (PiM A (\<lambda>_. M)) (PiM {x,y} (\<lambda>_. lborel :: real measure)) 
                  (\<lambda>h. restrict h {x,y})) {h\<in>extensional {x, y}. h x = h y}"
   proof (rule emeasure_distr [symmetric])
     have "(\<lambda>h. restrict h {x, y}) \<in> Pi\<^sub>M A (\<lambda>_. lborel) \<rightarrow>\<^sub>M Pi\<^sub>M {x, y} (\<lambda>_. lborel)"
       using assms by (intro measurable_restrict_subset) auto
     also have "\<dots> = Pi\<^sub>M A (\<lambda>_. M) \<rightarrow>\<^sub>M Pi\<^sub>M {x, y} (\<lambda>_. lborel)"
       by (intro sets_PiM_cong measurable_cong_sets refl) (simp_all add: M_def)
     finally show "(\<lambda>h. restrict h {x, y}) \<in> \<dots>" .
   next
     show "{h\<in>extensional {x, y}. h x = h y} \<in> sets (Pi\<^sub>M {x, y} (\<lambda>_. lborel))" by simp
   qed
   also have "distr (PiM A (\<lambda>_. M)) (PiM {x,y} (\<lambda>_. lborel :: real measure)) (\<lambda>h. restrict h {x,y}) =
                distr (PiM A (\<lambda>_. M)) (PiM {x,y} (\<lambda>_. M)) (\<lambda>h. restrict h {x,y})"
     by (intro distr_cong refl sets_PiM_cong) (simp_all add: M_def)
   also from assms have "\<dots> = Pi\<^sub>M {x, y} (\<lambda>i. M)" by (intro distr_restrict [symmetric]) auto
   also have "emeasure \<dots> {h\<in>extensional {x, y}. h x = h y} =
     nn_integral \<dots> (\<lambda>h. indicator {h\<in>extensional {x, y}. h x = h y} h)"
     by (intro nn_integral_indicator [symmetric]) simp_all
   also have "\<dots> = nn_integral (Pi\<^sub>M {x, y} (\<lambda>i. M)) (\<lambda>h. if h x = h y then 1 else 0)"
     by (intro nn_integral_cong) (auto simp add: indicator_def space_PiM PiE_def)
   also from \<open>x \<noteq> y\<close> have "\<dots> = (\<integral>\<^sup>+ z. (if fst z = snd z then 1 else 0) \<partial>(M \<Otimes>\<^sub>M M))"
     by (intro product_nn_integral_pair) auto
   also have "\<dots> = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+y. (if x = y then 1 else 0) \<partial>M) \<partial>M)"
     by (subst M.nn_integral_fst [symmetric]) simp_all
-  also have "\<dots> = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+y. indicator {x} y \<partial>M) \<partial>M)" by (simp add: indicator_def eq_commute)
+  also have "\<dots> = (\<integral>\<^sup>+ x. (\<integral>\<^sup>+y. indicator {x} y \<partial>M) \<partial>M)"
+    by (simp add: indicator_def of_bool_def eq_commute)
   also have "\<dots> = (\<integral>\<^sup>+ x. emeasure M {x} \<partial>M)" by (subst nn_integral_indicator) (simp_all add: M_def)
   also have "\<dots> = (\<integral>\<^sup>+ x. 0 \<partial>M)" unfolding M_def
     by (intro nn_integral_cong_AE refl AE_uniform_measureI) auto
   also have "\<dots> = 0" by simp
   finally show ?thesis .
 qed      
 
 lemma measurable_linorder_from_keys_restrict:
   assumes fin: "finite A"
   shows "linorder_from_keys A \<in> Pi\<^sub>M A (\<lambda>_. borel :: real measure) \<rightarrow>\<^sub>M count_space (Pow (A \<times> A))"
   (is "_ : ?M \<rightarrow>\<^sub>M _")
   apply (subst measurable_count_space_eq2)
   apply (auto simp add: fin linorder_from_keys_def)
 proof -
   note fin[simp]
   fix R assume "R \<subseteq> A \<times> A"
   then have "linorder_from_keys A -` {R} \<inter> space ?M =
     {f \<in> space ?M. \<forall>x\<in>A. \<forall>y\<in>A. (x, y) \<in> R \<longleftrightarrow> f x \<le> f y}"
     by (auto simp add: linorder_from_keys_def set_eq_iff)
   also have "\<dots> \<in> sets ?M"
     by measurable
   finally show "linorder_from_keys A -` {R} \<inter> space ?M \<in> sets ?M" .
 qed
 
 lemma measurable_count_space_extend:
   assumes "f \<in> measurable M (count_space A)" "A \<subseteq> B"
   shows   "f \<in> measurable M (count_space B)"
 proof -
   note assms(1)
   also have "count_space A = restrict_space (count_space B) A"
     using assms(2) by (subst restrict_count_space) (simp_all add: Int_absorb2)
   finally show ?thesis by (simp add: measurable_restrict_space2_iff)
 qed
   
 lemma measurable_linorder_from_keys_restrict':
   assumes fin: "finite A" "A \<subseteq> B"
   shows "linorder_from_keys A \<in> Pi\<^sub>M A (\<lambda>_. borel :: real measure) \<rightarrow>\<^sub>M count_space (Pow (B \<times> B))"
   apply (rule measurable_count_space_extend)
    apply (rule measurable_linorder_from_keys_restrict[OF assms(1)])
   using assms by auto
   
 
 context
   fixes a b :: real and A :: "'a set" and M and B
   assumes fin: "finite A" and ab: "a < b" and B: "A \<subseteq> B"
   defines "M \<equiv> distr (PiM A (\<lambda>_. uniform_measure lborel {a..b})) 
                   (count_space (Pow (B \<times> B))) (linorder_from_keys A)"
 begin
 
 lemma measurable_linorder_from_keys [measurable]: 
   "linorder_from_keys A \<in> Pi\<^sub>M A (\<lambda>_. borel :: real measure) \<rightarrow>\<^sub>M count_space (Pow (B \<times> B))"
   by (rule measurable_linorder_from_keys_restrict') (auto simp: fin B)
 
 text \<open>
   The ordering defined by randomly-chosen priorities is almost surely linear:
 \<close>
 theorem almost_everywhere_linorder: "AE R in M. linorder_on A R"
 proof -
   define N where "N = PiM A (\<lambda>_. uniform_measure lborel {a..b})"
   have [simp]: "sets (Pi\<^sub>M A (\<lambda>_. uniform_measure lborel {a..b})) = sets (PiM A (\<lambda>_. lborel))"
     by (intro sets_PiM_cong) simp_all
   let ?M_A = "(Pi\<^sub>M A (\<lambda>_. lborel :: real measure))"
   have meas: "{h \<in> A \<rightarrow>\<^sub>E UNIV. h i = h j} \<in> sets ?M_A"
     if [simp]: "i \<in> A" "j \<in> A" for i j
   proof -
     have "{h \<in> A \<rightarrow>\<^sub>E UNIV. h i = h j} = {h \<in> space ?M_A. h i = h j}"
       by (auto simp: space_PiM)
     also have "... \<in> sets ?M_A"
       by measurable
     finally show ?thesis .
   qed
   define X :: "('a \<Rightarrow> real) set" where "X = (\<Union>x\<in>A. \<Union>y\<in>A-{x}. {h\<in>A \<rightarrow>\<^sub>E UNIV. h x = h y})"
   have "AE f in N. inj_on f A"
   proof (rule AE_I)
     show "{f \<in> space N. \<not> inj_on f A} \<subseteq> X"
       by (auto simp: inj_on_def X_def space_PiM N_def)
   next
     show "X \<in> sets N" unfolding X_def N_def
       using meas by (auto intro!: countable_finite fin sets.countable_UN')
   next
     have "emeasure N X \<le> (\<Sum>i\<in>A. emeasure N (\<Union>y\<in>A - {i}. {h \<in> A \<rightarrow>\<^sub>E UNIV. h i = h y}))"
       unfolding X_def N_def using fin meas
       by (intro emeasure_subadditive_finite) 
          (auto simp: disjoint_family_on_def intro!: sets.countable_UN' countable_finite)
     also have "\<dots> \<le> (\<Sum>i\<in>A. \<Sum>j\<in>A-{i}. emeasure N {h \<in> A \<rightarrow>\<^sub>E UNIV. h i = h j})"
       unfolding N_def using fin meas
       by (intro emeasure_subadditive_finite sum_mono) 
          (auto simp: disjoint_family_on_def intro!: sets.countable_UN' countable_finite)
     also have "\<dots> = (\<Sum>i\<in>A. \<Sum>j\<in>A-{i}. 0)" unfolding N_def using fin ab
       by (intro sum.cong refl emeasure_PiM_diagonal) auto
     also have "\<dots> = 0" by simp
     finally show "emeasure N X = 0" by simp
   qed
   hence "AE f in N. linorder_on A (linorder_from_keys A f)"
     by eventually_elim auto
   thus ?thesis unfolding M_def N_def
     by (subst AE_distr_iff) auto
 qed
 
 text \<open>
   Furthermore, this is equivalent to choosing one of the $|A|!$ linear orderings uniformly
   at random.
 \<close>
 theorem random_linorder_by_prios:
   "M = uniform_measure (count_space (Pow (B \<times> B))) (linorders_on A)"
 proof -
   from linorders_finite_nonempty[OF fin] obtain R where R: "linorder_on A R"
     by (auto simp: linorders_on_def)
   
   have *: "emeasure M {R} \<le> emeasure M {R'}" if "linorder_on A R" "linorder_on A R'" for R R'
   proof -
     define N where "N = PiM A (\<lambda>_. uniform_measure lborel {a..b})"
     from linorder_permutation_exists[OF fin that]
     obtain \<pi> where \<pi>: "\<pi> permutes A" "R' = map_relation A \<pi> R"
       by blast
     have "(\<lambda>f. f \<circ> \<pi>) \<in> Pi\<^sub>M A (\<lambda>_. lborel :: real measure) \<rightarrow>\<^sub>M Pi\<^sub>M A (\<lambda>_. lborel :: real measure)"
       by (auto intro!: measurable_PiM_single' measurable_PiM_component_rev
           simp: comp_def permutes_in_image[OF \<pi>(1)] space_PiM PiE_def extensional_def)
     also have "\<dots> = N \<rightarrow>\<^sub>M Pi\<^sub>M A (\<lambda>_. lborel)"
       unfolding N_def by (intro measurable_cong_sets refl sets_PiM_cong) simp_all
     finally have [measurable]: "(\<lambda>f. f \<circ> \<pi>) \<in> \<dots>" .    
         
     have [simp]: "measurable N X = measurable (PiM A (\<lambda>_. lborel)) X" for X :: "('a \<times> 'a) set measure"
       unfolding N_def by (intro measurable_cong_sets refl sets_PiM_cong) simp_all
     have [simp]: "measurable M X = measurable (count_space (Pow (B \<times> B))) X" for X :: "('a \<times> 'a) set measure"
       unfolding M_def by simp
       
     have M_eq: "M = distr N (count_space (Pow (B \<times> B))) (linorder_from_keys A)"
       by (simp only: M_def N_def)
     also have "N = distr N (PiM A (\<lambda>_. lborel)) (\<lambda>f. f \<circ> \<pi>)"
       unfolding N_def by (rule PiM_uniform_measure_permute [symmetric]) fact+
     also have "distr \<dots> (count_space (Pow (B \<times> B))) (linorder_from_keys A) = 
                  distr N (count_space (Pow (B \<times> B))) (linorder_from_keys A \<circ> (\<lambda>f. f \<circ> \<pi>)) "
       by (intro distr_distr) simp_all
     also have "\<dots> = distr N (count_space (Pow (B \<times> B))) (map_relation A \<pi> \<circ> linorder_from_keys A)"
       by (intro distr_cong refl) (auto simp: linorder_from_keys_permute[OF \<pi>(1)])
     also have "\<dots> = distr M (count_space (Pow (B \<times> B))) (map_relation A \<pi>)"
       unfolding M_eq using B
       by (intro distr_distr [symmetric]) (auto simp: map_relation_def)
     finally have M_eq': "distr M (count_space (Pow (B \<times> B))) (map_relation A \<pi>) = M" ..
 
     from that have subset': "R \<subseteq> B \<times> B" "R' \<subseteq> B \<times> B"
       using B by (auto simp: linorder_on_def refl_on_def)
     hence "emeasure M {R} \<le> emeasure M (map_relation A \<pi> -` {R'} \<inter> space M)"
       using subset' by (intro emeasure_mono) (auto simp: M_def \<pi> )
     also have "\<dots> = emeasure (distr M (count_space (Pow (B \<times> B))) (map_relation A \<pi>)) {R'} "
       by (rule emeasure_distr [symmetric]) (insert subset' B, auto simp: map_relation_def)
     also note M_eq'
     finally show ?thesis .
   qed
   have same_prob: "emeasure M {R'} = emeasure M {R}" if "linorder_on A R'" for R'
     using *[of R R'] and *[of R' R] and R and that by simp
   
   from ab have "prob_space M"
     unfolding M_def
     by (intro prob_space.prob_space_distr prob_space_PiM prob_space_uniform_measure) simp_all
   hence "1 = emeasure M (Pow (B \<times> B))" 
     using prob_space.emeasure_space_1[OF \<open>prob_space M\<close>] by (simp add: M_def)
   also have "(Pow (B \<times> B)) = linorders_on A \<union> ((Pow (B \<times> B))-linorders_on A)"
     using B by (auto simp: linorders_on_def linorder_on_def refl_on_def)
   also have "emeasure M \<dots> = emeasure M (linorders_on A) + emeasure M (Pow (B \<times> B)-linorders_on A)"
     using B by (subst plus_emeasure) (auto simp: M_def linorders_on_def linorder_on_def refl_on_def)
   also have "emeasure M (Pow (B \<times> B)-linorders_on A) = 0" using almost_everywhere_linorder 
     by (subst (asm) AE_iff_measurable) (auto simp: linorders_on_def M_def)
   also from fin have "emeasure M (linorders_on A) = (\<Sum>R'\<in>linorders_on A. emeasure M {R'})"
     using B by (intro emeasure_eq_sum_singleton) 
                (auto simp: M_def  linorders_on_def linorder_on_def refl_on_def)
   also have "\<dots> = (\<Sum>R'\<in>linorders_on A. emeasure M {R})"
     by (rule sum.cong) (simp_all add: linorders_on_def same_prob)
   also from fin have "\<dots> = fact (card A) * emeasure M {R}"
     by (simp add: linorders_on_def card_finite_linorders)
   finally have [simp]: "emeasure M {R} = inverse (fact (card A))"
     by (simp add: inverse_ennreal_unique)
   
   show ?thesis
   proof (rule measure_eqI_countable_AE')
     show "sets M = Pow (Pow (B \<times> B))"
       by (simp add: M_def)
   next
     from \<open>finite A\<close> show "countable (linorders_on A)"
       by (blast intro: countable_finite)
   next
     show "AE R in uniform_measure (count_space (Pow (B \<times> B))) 
             (linorders_on A). R \<in> linorders_on A"
       by (rule AE_uniform_measureI) 
          (insert B, auto simp: linorders_on_def linorder_on_def refl_on_def)
   next
     fix R' assume R': "R' \<in> linorders_on A"
     have subset: "linorders_on A \<subseteq> Pow (B \<times> B)"
       using B by (auto simp: linorders_on_def linorder_on_def refl_on_def)
     have "emeasure (uniform_measure (count_space (Pow (B \<times> B))) 
            (linorders_on A)) {R'} = emeasure (count_space (Pow (B \<times> B))) (linorders_on A \<inter> {R'}) /
                                       emeasure (count_space (Pow (B \<times> B))) (linorders_on A)"
       using R' B by (subst emeasure_uniform_measure) (auto simp: linorders_on_def linorder_on_def refl_on_def)
     also have "\<dots> = 1 / emeasure (count_space (Pow (B \<times> B))) (linorders_on A)"
       using R' B by (subst emeasure_count_space) (auto simp: linorders_on_def linorder_on_def refl_on_def)
     also have "\<dots> = 1 / fact (card A)"
       using fin finite_linorders_on[of A]
       by (subst emeasure_count_space [OF subset])
          (auto simp: divide_ennreal [symmetric] linorders_on_def card_finite_linorders)
     also have "\<dots> = emeasure M {R}"
       by (simp add: field_simps divide_ennreal_def)
     also have "\<dots> = emeasure M {R'}"
       using R' by (intro same_prob [symmetric]) (auto simp: linorders_on_def)
     finally show "emeasure M {R'} = emeasure (uniform_measure (count_space (Pow (B \<times> B))) 
                     (linorders_on A)) {R'}" ..
   next
     show "linorders_on A \<subseteq> Pow (B \<times> B)"
       using B by (auto simp: linorders_on_def linorder_on_def refl_on_def)
   qed (auto simp: M_def linorders_on_def almost_everywhere_linorder)
 qed
 
 end
 end
diff --git a/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy b/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy
--- a/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy
+++ b/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy
@@ -1,2089 +1,2089 @@
 (*
   File:   Zeta_3_Irrational.thy
   Author: Manuel Eberl, TU München
 *)
 section \<open>The Irrationality of $\zeta(3)$\<close>
 theory Zeta_3_Irrational
 imports
   "E_Transcendental.E_Transcendental"
   "Prime_Number_Theorem.Prime_Number_Theorem"
   "Prime_Distribution_Elementary.PNT_Consequences"
 begin
 
 text \<open>
   Ap\'{e}ry's original proof of the irrationality of $\zeta(3)$ contained several
   tricky identities of sums involving binomial coefficients that are difficult to
   prove. I instead follow Beukers's proof, which consists of several fairly
   straightforward manipulations of integrals with absolutely no caveats.
 
   Both Ap\'{e}ry and Beukers make use of an asymptotic upper bound on
   $\text{lcm}\{1\ldots n\}$ -- namely $\text{lcm}\{1\ldots n\} \in o(c^n)$ for
   any $c > e$, which is a consequence of the Prime Number Theorem (which, fortunately,
   is available in the \emph{Archive of Formal Proofs}~\cite{afp_primes1,afp_primes2}).
 
   I follow the concise presentation of Beukers's proof in Filaseta's lecture
   notes~\cite{filaseta}, which turned out to be very amenable to formalisation.
 
   There is another earlier formalisation of the irrationality of $\zeta(3)$ by
   Mahboubi\ \emph{et al.}~\cite{mahboubi}, who followed Ap\'{e}ry's original proof,
   but were ultimately forced to find a more elementary way to prove the asymptotics
   of $\text{lcm}\{1\ldots n\}$ than the Prime Number Theorem.
 
   First, we will require some auxiliary material before we get started with the actual
   proof.
 \<close>
 
 (* TODO: A lot of this (if not all of it) should really be in the library *)
 subsection \<open>Auxiliary facts about polynomials\<close>
 
 lemma degree_higher_pderiv: "degree ((pderiv ^^ n) p) = degree p - n"
   for p :: "'a::{comm_semiring_1,semiring_no_zero_divisors,semiring_char_0} poly"
   by (induction n arbitrary: p) (auto simp: degree_pderiv)
 
 lemma pcompose_power_left: "pcompose (p ^ n) q = pcompose p q ^ n"
   by (induction n) (auto simp: pcompose_mult pcompose_1)
 
 lemma pderiv_sum: "pderiv (\<Sum>x\<in>A. f x) = (\<Sum>x\<in>A. pderiv (f x))"
   by (induction A rule: infinite_finite_induct) (auto simp: pderiv_add)
 
 lemma higher_pderiv_minus: "(pderiv ^^ n) (-p :: 'a :: idom poly) = -(pderiv ^^ n) p"
   by (induction n) (auto simp: pderiv_minus)
 
 lemma pderiv_power: "pderiv (p ^ n) = smult (of_nat n) (p ^ (n - 1)) * pderiv p"
   by (cases n) (simp_all add: pderiv_power_Suc del: power_Suc)
 
 lemma pderiv_monom: "pderiv (monom c n) = monom (of_nat n * c) (n - 1)"
   by (simp add: monom_altdef pderiv_smult pderiv_power pderiv_pCons mult_ac)
 
 lemma higher_pderiv_monom:
   "k \<le> n \<Longrightarrow> (pderiv ^^ k) (monom c n) = monom (of_nat (pochhammer (n - k + 1) k) * c) (n - k)"
   by (induction k) (auto simp: pderiv_monom pochhammer_rec Suc_diff_le Suc_diff_Suc mult_ac)
 
 lemma higher_pderiv_mult:
   "(pderiv ^^ n) (p * q) =
      (\<Sum>k\<le>n. Polynomial.smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (n - k)) q))"
 proof (induction n)
   case (Suc n)
   have eq: "(Suc n choose k) = (n choose k) + (n choose (k-1))" if "k > 0" for k
     using that by (cases k) auto
   have "(pderiv ^^ Suc n) (p * q) =
           (\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) +
           (\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ Suc k) p * (pderiv ^^ (n - k)) q))"
     by (simp add: Suc pderiv_sum pderiv_smult pderiv_mult sum.distrib smult_add_right algebra_simps Suc_diff_le)
   also have "(\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) =
              (\<Sum>k\<in>insert 0 {1..n}. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>k=1..n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) + p * (pderiv ^^ Suc n) q"
     by (subst sum.insert) (auto simp: add_ac)
   also have "(\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ Suc k) p * (pderiv ^^ (n - k)) q)) =
              (\<Sum>k=1..n+1. smult (of_nat (n choose (k-1))) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>k. k - 1" Suc]) auto
   also have "\<dots> = (\<Sum>k\<in>insert (n+1) {1..n}. smult (of_nat (n choose (k-1))) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>k=1..n. smult (of_nat (n choose (k-1))) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) + (pderiv ^^ Suc n) p * q"
     by (subst sum.insert) (auto simp: add_ac)
   also have "(\<Sum>k=1..n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) +
                  p * (pderiv ^^ Suc n) q + \<dots> =
              (\<Sum>k=1..n. smult (of_nat (Suc n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) +
                  p * (pderiv ^^ Suc n) q + (pderiv ^^ Suc n) p * q"
     by (simp add: sum.distrib algebra_simps smult_add_right eq smult_add_left)
   also have "\<dots> = (\<Sum>k\<in>{1..n}\<union>{0,Suc n}. smult (of_nat (Suc n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (subst sum.union_disjoint) (auto simp: algebra_simps)
   also have "{1..n}\<union>{0,Suc n} = {..Suc n}" by auto
   finally show ?case .
 qed auto
 
 subsection \<open>Auxiliary facts about integrals\<close>
 
 theorem (in pair_sigma_finite) Fubini_set_integrable:
   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
   assumes f[measurable]: "set_borel_measurable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
     and integ1: "set_integrable M1 A (\<lambda>x. \<integral>y\<in>B. norm (f (x, y)) \<partial>M2)"
     and integ2: "AE x\<in>A in M1. set_integrable M2 B (\<lambda>y. f (x, y))"
   shows "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
   unfolding set_integrable_def
 proof (rule Fubini_integrable)
   note integ1
   also have "set_integrable M1 A (\<lambda>x. \<integral>y\<in>B. norm (f (x, y)) \<partial>M2) \<longleftrightarrow>
         integrable M1 (\<lambda>x. LINT y|M2. norm (indicat_real (A \<times> B) (x, y) *\<^sub>R f (x, y)))"
     unfolding set_integrable_def
     by (intro integrable_cong) (auto simp: indicator_def set_lebesgue_integral_def)
   finally show \<dots> .
 next
   from integ2 show "AE x in M1. integrable M2 (\<lambda>y. indicat_real (A \<times> B) (x, y) *\<^sub>R f (x, y))"
   proof eventually_elim
     case (elim x)
     show "integrable M2 (\<lambda>y. indicat_real (A \<times> B) (x, y) *\<^sub>R f (x, y))"
     proof (cases "x \<in> A")
       case True
       with elim have "set_integrable M2 B (\<lambda>y. f (x, y))" by simp
       also have "?this \<longleftrightarrow> ?thesis"
         unfolding set_integrable_def using True
         by (intro integrable_cong) (auto simp: indicator_def)
       finally show ?thesis .
     qed auto
   qed
 qed (insert assms, auto simp: set_borel_measurable_def)
 
 lemma (in pair_sigma_finite) set_integral_fst':
   fixes f :: "_ \<Rightarrow> 'c :: {second_countable_topology, banach}"
   assumes "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
   shows   "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
              (\<integral>x\<in>A. (\<integral>y\<in>B. f (x, y) \<partial>M2) \<partial>M1)"
 proof -
   have "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
           (\<integral>z. indicator (A \<times> B) z *\<^sub>R f z \<partial>(M1 \<Otimes>\<^sub>M M2))"
     by (simp add: set_lebesgue_integral_def)
   also have "\<dots> = (\<integral>x. \<integral>y. indicator (A \<times> B) (x,y) *\<^sub>R f (x,y) \<partial>M2 \<partial>M1)"
     using assms by (subst integral_fst' [symmetric]) (auto simp: set_integrable_def)
   also have "\<dots> = (\<integral>x\<in>A. (\<integral>y\<in>B. f (x,y) \<partial>M2) \<partial>M1)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong refl) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 lemma (in pair_sigma_finite) set_integral_snd:
   fixes f :: "_ \<Rightarrow> 'c :: {second_countable_topology, banach}"
   assumes "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
   shows   "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
              (\<integral>y\<in>B. (\<integral>x\<in>A. f (x, y) \<partial>M1) \<partial>M2)"
 proof -
   have "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
           (\<integral>z. indicator (A \<times> B) z *\<^sub>R f z \<partial>(M1 \<Otimes>\<^sub>M M2))"
     by (simp add: set_lebesgue_integral_def)
   also have "\<dots> = (\<integral>y. \<integral>x. indicator (A \<times> B) (x,y) *\<^sub>R f (x,y) \<partial>M1 \<partial>M2)"
     using assms by (subst integral_snd) (auto simp: set_integrable_def case_prod_unfold)
   also have "\<dots> = (\<integral>y\<in>B. (\<integral>x\<in>A. f (x,y) \<partial>M1) \<partial>M2)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong refl) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 proposition (in pair_sigma_finite) Fubini_set_integral:
   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
   assumes f: "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) (case_prod f)"
   shows "(\<integral>y\<in>B. (\<integral>x\<in>A. f x y \<partial>M1) \<partial>M2) = (\<integral>x\<in>A. (\<integral>y\<in>B. f x y \<partial>M2) \<partial>M1)"
 proof -
   have "(\<integral>y\<in>B. (\<integral>x\<in>A. f x y \<partial>M1) \<partial>M2) = (\<integral>y. (\<integral>x. indicator (A \<times> B) (x, y) *\<^sub>R f x y \<partial>M1) \<partial>M2)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong) (auto simp: indicator_def)
   also have "\<dots> = (\<integral>x. (\<integral>y. indicator (A \<times> B) (x, y) *\<^sub>R f x y \<partial>M2) \<partial>M1)"
     using assms by (intro Fubini_integral) (auto simp: set_integrable_def case_prod_unfold)
   also have "\<dots> = (\<integral>x\<in>A. (\<integral>y\<in>B. f x y \<partial>M2) \<partial>M1)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 lemma (in pair_sigma_finite) nn_integral_swap:
   assumes [measurable]: "f \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)"
   shows "(\<integral>\<^sup>+x. f x \<partial>(M1 \<Otimes>\<^sub>M M2)) = (\<integral>\<^sup>+(y,x). f (x,y) \<partial>(M2 \<Otimes>\<^sub>M M1))"
   by (subst distr_pair_swap, subst nn_integral_distr) (auto simp: case_prod_unfold)
 
 lemma set_integrable_bound:
   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
     and g :: "'a \<Rightarrow> 'c::{banach, second_countable_topology}"
   shows "set_integrable M A f \<Longrightarrow> set_borel_measurable M A g \<Longrightarrow>
            (AE x in M. x \<in> A \<longrightarrow> norm (g x) \<le> norm (f x)) \<Longrightarrow> set_integrable M A g"
   unfolding set_integrable_def
   apply (erule Bochner_Integration.integrable_bound)
    apply (simp add: set_borel_measurable_def)
   apply (erule eventually_mono)
   apply (auto simp: indicator_def)
   done
 
 lemma set_integrableI_nonneg:
   fixes f :: "'a \<Rightarrow> real"
   assumes "set_borel_measurable M A f"
   assumes "AE x in M. x \<in> A \<longrightarrow> 0 \<le> f x" "(\<integral>\<^sup>+x\<in>A. f x \<partial>M) < \<infinity>"
   shows "set_integrable M A f"
   unfolding set_integrable_def
 proof (rule integrableI_nonneg)
   from assms show "(\<lambda>x. indicator A x *\<^sub>R f x) \<in> borel_measurable M"
     by (simp add: set_borel_measurable_def)
   from assms(2) show "AE x in M. 0 \<le> indicat_real A x *\<^sub>R f x"
     by eventually_elim (auto simp: indicator_def)
   have "(\<integral>\<^sup>+x. ennreal (indicator A x *\<^sub>R f x) \<partial>M) = (\<integral>\<^sup>+x\<in>A. f x \<partial>M)"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> < \<infinity>" by fact
   finally show "(\<integral>\<^sup>+x. ennreal (indicator A x *\<^sub>R f x) \<partial>M) < \<infinity>" .
 qed
 
 lemma set_integral_eq_nn_integral:
   assumes "set_borel_measurable M A f"
   assumes "set_nn_integral M A f = ennreal x" "x \<ge> 0"
   assumes "AE x in M. x \<in> A \<longrightarrow> f x \<ge> 0"
   shows   "set_integrable M A f"
     and   "set_lebesgue_integral M A f = x"
 proof -
   have eq: "(\<lambda>x. (if x \<in> A then 1 else 0) * f x) = (\<lambda>x. if x \<in> A then f x else 0)"
            "(\<lambda>x. if x \<in> A then ennreal (f x) else 0) =
               (\<lambda>x. ennreal (f x) * (if x \<in> A then 1 else 0))"
            "(\<lambda>x. ennreal (f x * (if x \<in> A then 1 else 0))) =
               (\<lambda>x. ennreal (f x) * (if x \<in> A then 1 else 0))"
     by auto
   from assms show *: "set_integrable M A f"
     by (intro set_integrableI_nonneg) auto
 
   have "set_lebesgue_integral M A f = enn2real (set_nn_integral M A f)"
     unfolding set_lebesgue_integral_def using assms(1,4) * eq
     by (subst integral_eq_nn_integral)
-       (auto intro!: nn_integral_cong simp: indicator_def set_integrable_def mult_ac)
+       (auto intro!: nn_integral_cong simp: indicator_def of_bool_def set_integrable_def mult_ac)
   also have "\<dots> = x" using assms by simp
   finally show "set_lebesgue_integral M A f = x" .
 qed
 
 lemma set_integral_0 [simp, intro]: "set_integrable M A (\<lambda>y. 0)"
   by (simp add: set_integrable_def)
 
 lemma set_integrable_sum:
   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
   assumes "finite B"
   assumes "\<And>x. x \<in> B \<Longrightarrow> set_integrable M A (f x)"
   shows "set_integrable M A (\<lambda>y. \<Sum>x\<in>B. f x y)"
   using assms by (induction rule: finite_induct) (auto intro!: set_integral_add)
 
 lemma set_integral_sum:
   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
   assumes "finite B"
   assumes "\<And>x. x \<in> B \<Longrightarrow> set_integrable M A (f x)"
   shows "set_lebesgue_integral M A (\<lambda>y. \<Sum>x\<in>B. f x y) = (\<Sum>x\<in>B. set_lebesgue_integral M A (f x))"
   using assms
   apply (induction rule: finite_induct)
   apply simp
   apply simp
   apply (subst set_integral_add)
     apply (auto intro!: set_integrable_sum)
   done
 
 lemma set_nn_integral_cong:
   assumes "M = M'" "A = B" "\<And>x. x \<in> space M \<inter> A \<Longrightarrow> f x = g x"
   shows   "set_nn_integral M A f = set_nn_integral M' B g"
   using assms unfolding assms(1,2) by (intro nn_integral_cong) (auto simp: indicator_def)
 
 lemma set_nn_integral_mono:
   assumes "\<And>x. x \<in> space M \<inter> A \<Longrightarrow> f x \<le> g x"
   shows   "set_nn_integral M A f \<le> set_nn_integral M A g"
   using assms by (intro nn_integral_mono) (auto simp: indicator_def)
 
 lemma
   fixes f :: "real \<Rightarrow> real"
   assumes "a \<le> b"
   assumes deriv: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes cont: "continuous_on {a..b} f"
   shows has_bochner_integral_FTC_Icc_real:
       "has_bochner_integral lborel (\<lambda>x. f x * indicator {a .. b} x) (F b - F a)" (is ?has)
     and integral_FTC_Icc_real: "(\<integral>x. f x * indicator {a .. b} x \<partial>lborel) = F b - F a" (is ?eq)
 proof -
   have 1: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_vector_derivative f x) (at x within {a .. b})"
     unfolding has_field_derivative_iff_has_vector_derivative[symmetric]
     using deriv by auto
   show ?has ?eq
     using has_bochner_integral_FTC_Icc[OF \<open>a \<le> b\<close> 1 cont] integral_FTC_Icc[OF \<open>a \<le> b\<close> 1 cont]
     by (auto simp: mult.commute)
 qed
 
 lemma integral_by_parts_integrable:
   fixes f g F G::"real \<Rightarrow> real"
   assumes "a \<le> b"
   assumes cont_f[intro]: "continuous_on {a..b} f"
   assumes cont_g[intro]: "continuous_on {a..b} g"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (G has_field_derivative g x) (at x within {a..b})"
   shows  "integrable lborel (\<lambda>x.((F x) * (g x) + (f x) * (G x)) * indicator {a .. b} x)"
 proof -
   have "integrable lborel (\<lambda>x. indicator {a..b} x *\<^sub>R ((F x) * (g x) + (f x) * (G x)))"
     by (intro borel_integrable_compact continuous_intros assms)
        (auto intro!: DERIV_continuous_on assms)
   thus ?thesis by (simp add: mult_ac)
 qed
 
 lemma integral_by_parts:
   fixes f g F G::"real \<Rightarrow> real"
   assumes [arith]: "a \<le> b"
   assumes cont_f[intro]: "continuous_on {a..b} f"
   assumes cont_g[intro]: "continuous_on {a..b} g"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (G has_field_derivative g x) (at x within {a..b})"
   shows "(\<integral>x. (F x * g x) * indicator {a .. b} x \<partial>lborel)
             =  F b * G b - F a * G a - \<integral>x. (f x * G x) * indicator {a .. b} x \<partial>lborel"
 proof-
   have 0: "(\<integral>x. (F x * g x + f x * G x) * indicator {a .. b} x \<partial>lborel) = F b * G b - F a * G a"
     by (rule integral_FTC_Icc_real, auto intro!: derivative_eq_intros continuous_intros)
        (auto intro!: assms DERIV_continuous_on)
   have [continuous_intros]: "continuous_on {a..b} F"
     by (rule DERIV_continuous_on assms)+
   have [continuous_intros]: "continuous_on {a..b} G"
     by (rule DERIV_continuous_on assms)+
 
   have "(\<integral>x. indicator {a..b} x *\<^sub>R (F x * g x + f x * G x) \<partial>lborel) =
     (\<integral>x. indicator {a..b} x *\<^sub>R(F x * g x) \<partial>lborel) + \<integral>x. indicator {a..b} x *\<^sub>R (f x * G x) \<partial>lborel"
     apply (subst Bochner_Integration.integral_add[symmetric])
       apply (rule borel_integrable_compact; force intro!: continuous_intros assms)
      apply (rule borel_integrable_compact; force intro!: continuous_intros assms)
     apply (simp add: algebra_simps)
     done
 
   thus ?thesis using 0 by (simp add: algebra_simps)
 qed
 
 lemma interval_lebesgue_integral_by_parts:
   assumes "a \<le> b"
   assumes cont_f[intro]: "continuous_on {a..b} f"
   assumes cont_g[intro]: "continuous_on {a..b} g"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (G has_field_derivative g x) (at x within {a..b})"
   shows "(LBINT x=a..b. F x * g x) = F b * G b - F a * G a - (LBINT x=a..b. f x * G x)"
   using integral_by_parts[of a b f g F G] assms
   by (simp add: interval_integral_Icc set_lebesgue_integral_def mult_ac)
 
 lemma interval_lebesgue_integral_by_parts_01:
   assumes cont_f[intro]: "continuous_on {0..1} f"
   assumes cont_g[intro]: "continuous_on {0..1} g"
   assumes [intro]: "\<And>x. x \<in> {0..1} \<Longrightarrow> (F has_field_derivative f x) (at x within {0..1})"
   assumes [intro]: "\<And>x. x \<in> {0..1} \<Longrightarrow> (G has_field_derivative g x) (at x within {0..1})"
   shows "(LBINT x=0..1. F x * g x) = F 1 * G 1 - F 0 * G 0 - (LBINT x=0..1. f x * G x)"
   using interval_lebesgue_integral_by_parts[of 0 1 f g F G] assms
   by (simp add: zero_ereal_def one_ereal_def)
 
 lemma continuous_on_imp_set_integrable_cbox:
   fixes h :: "'a :: euclidean_space \<Rightarrow> real"
   assumes "continuous_on (cbox a b) h"
   shows   "set_integrable lborel (cbox a b) h"
 proof -
   from assms have "h absolutely_integrable_on cbox a b"
     by (rule absolutely_integrable_continuous)
   moreover have "(\<lambda>x. indicat_real (cbox a b) x *\<^sub>R h x) \<in> borel_measurable borel"
     by (rule borel_measurable_continuous_on_indicator) (use assms in auto)
   ultimately show ?thesis
     unfolding set_integrable_def using assms by (subst (asm) integrable_completion) auto
 qed
 
 
 subsection \<open>Shifted Legendre polynomials\<close>
 
 text \<open>
   The first ingredient we need to show Apéry's theorem is the \<^emph>\<open>shifted
   Legendre polynomials\<close>
     \[P_n(X) = \frac{1}{n!} \frac{\partial^n}{\partial X^n} (X^n(1-X)^n)\]
   and the auxiliary polynomials
     \[Q_{n,k}(X) = \frac{\partial^k}{\partial X^k} (X^n(1-X)^n)\ .\]
   Note that $P_n$ is in fact an \emph{integer} polynomial.
 
   Only some very basic properties of these will be proven, since that is all we will need.
 \<close>
 
 context
   fixes n :: nat
 begin
 
 definition gen_shleg_poly :: "nat \<Rightarrow> int poly" where
   "gen_shleg_poly k = (pderiv ^^ k) ([:0, 1, -1:] ^ n)"
 
 definition shleg_poly where "shleg_poly = gen_shleg_poly n div [:fact n:]"
 
 text \<open>
   We can easily prove the following more explicit formula for $Q_{n,k}$:
   \[Q_{n,k}(X) = \sum_{i=0}^k (-1)^{k-1} {k \choose i}
       n^{\underline{i}}\, n^{\underline{k-i}}\, X^{n-i}\, (1-X)^{n-k+i}\]
 \<close>
 lemma gen_shleg_poly_altdef:
   assumes "k \<le> n"
   shows "gen_shleg_poly k =
             (\<Sum>i\<le>k. smult ((-1)^(k-i) * of_nat (k choose i) *
                     pochhammer (n-i+1) i * pochhammer (n-k+i+1) (k-i))
                     ([:0, 1:] ^ (n - i) * [:1, -1:] ^ (n-k+i)))"
 proof -
   have *: "(pderiv ^^ i) (x \<circ>\<^sub>p [:1, -1:]) =
           smult ((-1) ^ i) ((pderiv ^^ i) x \<circ>\<^sub>p [:1, -1:])" for i and x :: "int poly"
     by (induction i arbitrary: x)
        (auto simp: pderiv_smult pderiv_pcompose funpow_Suc_right pderiv_pCons
                    higher_pderiv_minus simp del: funpow.simps(2))
 
   have "gen_shleg_poly k = (pderiv ^^ k) ([:0, 1, -1:] ^ n)"
     by (simp add: gen_shleg_poly_def)
   also have "[:0, 1, -1::int:] = [:0, 1:] * [:1, -1:]"
     by simp
   also have "\<dots> ^ n = [:0, 1:] ^ n * [:1, -1:] ^ n"
     by (simp flip: power_mult_distrib)
   also have "(pderiv ^^ k) \<dots> =
                (\<Sum>i\<le>k. smult (of_nat (k choose i)) ((pderiv ^^ i)
                  ([:0, 1:] ^ n) * (pderiv ^^ (k - i)) ([:1, -1:] ^ n)))"
     by (simp add: higher_pderiv_mult)
   also have "\<dots> = (\<Sum>i\<le>k. smult (of_nat (k choose i))
                     ((pderiv ^^ i) (monom 1 n) * (pderiv ^^ (k - i)) (monom 1 n \<circ>\<^sub>p [:1, -1:])))"
     by (simp add: monom_altdef pcompose_pCons pcompose_power_left)
   also have "\<dots> = (\<Sum>i\<le>k. smult ((-1) ^ (k - i) * of_nat (k choose i))
                    ((pderiv ^^ i) (monom 1 n) * ((pderiv ^^ (k - i)) (monom 1 n) \<circ>\<^sub>p [:1, -1:])))"
     by (simp add: * mult_ac)
   also have "\<dots> = (\<Sum>i\<le>k. smult ((-1) ^ (k - i) * of_nat (k choose i))
                    (monom (pochhammer (n - i + 1) i) (n - i) *
                     monom (pochhammer (n - k + i + 1) (k - i)) (n - k + i) \<circ>\<^sub>p [:1, -1:]))"
     using assms by (simp add: higher_pderiv_monom)
   also have "\<dots> = (\<Sum>i\<le>k. smult ((-1) ^ (k - i) * of_nat (k choose i) * pochhammer (n - i + 1) i * pochhammer (n - k + i + 1) (k - i))
                    ([:0, 1:] ^ (n - i) * [:1, -1:] ^ (n - k + i)))"
     by (simp add: monom_altdef algebra_simps pcompose_smult pcompose_power_left pcompose_pCons)
   finally show ?thesis .
 qed
 
 lemma degree_gen_shleg_poly [simp]: "degree (gen_shleg_poly k) = 2 * n - k"
   by (simp add: gen_shleg_poly_def degree_higher_pderiv degree_power_eq)
 
 lemma gen_shleg_poly_n: "gen_shleg_poly n = smult (fact n) shleg_poly"
 proof -
   obtain r where r: "gen_shleg_poly n = [:fact n:] * r"
     unfolding gen_shleg_poly_def using fact_dvd_higher_pderiv[of n "[:0,1,-1:]^n"] by blast
   have "smult (fact n) shleg_poly = smult (fact n) (gen_shleg_poly n div [:fact n:])"
     by (simp add: shleg_poly_def)
   also note r
   also have "[:fact n:] * r div [:fact n:] = r"
     by (rule nonzero_mult_div_cancel_left) auto
   finally show ?thesis
     by (simp add: r)
 qed
 
 lemma degree_shleg_poly [simp]: "degree shleg_poly = n"
   using degree_gen_shleg_poly[of n] by (simp add: gen_shleg_poly_n)
 
 lemma pderiv_gen_shleg_poly [simp]: "pderiv (gen_shleg_poly k) = gen_shleg_poly (Suc k)"
   by (simp add: gen_shleg_poly_def)
 
 
 text \<open>
   The following functions are the interpretation of the shifted Legendre polynomials
   and the auxiliary polynomials as a function from reals to reals.
 \<close>
 definition Gen_Shleg :: "nat \<Rightarrow> real \<Rightarrow> real"
   where "Gen_Shleg k x = poly (of_int_poly (gen_shleg_poly k)) x"
 
 definition Shleg :: "real \<Rightarrow> real" where "Shleg = poly (of_int_poly shleg_poly)"
 
 lemma Gen_Shleg_altdef:
   assumes "k \<le> n"
   shows   "Gen_Shleg k x = (\<Sum>i\<le>k. (-1)^(k-i) * of_nat (k choose i) *
                             of_int (pochhammer (n-i+1) i * pochhammer (n-k+i+1) (k-i)) *
                             x ^ (n - i) * (1 - x) ^ (n-k+i))"
   using assms by (simp add: Gen_Shleg_def gen_shleg_poly_altdef poly_sum mult_ac)
 
 lemma Gen_Shleg_0 [simp]: "k < n \<Longrightarrow> Gen_Shleg k 0 = 0"
   by (simp add: Gen_Shleg_altdef zero_power)
 
 lemma Gen_Shleg_1 [simp]: "k < n \<Longrightarrow> Gen_Shleg k 1 = 0"
   by (simp add: Gen_Shleg_altdef zero_power)
 
 lemma Gen_Shleg_n_0 [simp]: "Gen_Shleg n 0 = fact n"
 proof -
   have "Gen_Shleg n 0 = (\<Sum>i\<le>n. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ (n - i))"
     by (simp add: Gen_Shleg_altdef)
   also have "\<dots> = (\<Sum>i\<in>{n}. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ (n - i))"
     by (intro sum.mono_neutral_right) auto
   also have "\<dots> = fact n"
     by (simp add: pochhammer_fact flip: pochhammer_of_nat)
   finally show ?thesis .
 qed
 
 lemma Gen_Shleg_n_1 [simp]: "Gen_Shleg n 1 = (-1) ^ n * fact n"
 proof -
   have "Gen_Shleg n 1 = (\<Sum>i\<le>n. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ i)"
     by (simp add: Gen_Shleg_altdef)
   also have "\<dots> = (\<Sum>i\<in>{0}. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ i)"
     by (intro sum.mono_neutral_right) auto
   also have "\<dots> = (-1) ^ n * fact n"
     by (simp add: pochhammer_fact flip: pochhammer_of_nat)
   finally show ?thesis .
 qed
 
 lemma Shleg_altdef: "Shleg x = Gen_Shleg n x / fact n"
   by (simp add: Shleg_def Gen_Shleg_def gen_shleg_poly_n)
 
 lemma Shleg_0 [simp]: "Shleg 0 = 1" and Shleg_1 [simp]: "Shleg 1 = (-1) ^ n"
   by (simp_all add: Shleg_altdef)
 
 lemma Gen_Shleg_0_left: "Gen_Shleg 0 x = x ^ n * (1 - x) ^ n"
   by (simp add: Gen_Shleg_def gen_shleg_poly_def power_mult_distrib)
 
 lemma has_field_derivative_Gen_Shleg:
   "(Gen_Shleg k has_field_derivative Gen_Shleg (Suc k) x) (at x)"
 proof -
   note [derivative_intros] = poly_DERIV
   show ?thesis unfolding Gen_Shleg_def
     by (rule derivative_eq_intros) auto
 qed
 
 lemma continuous_on_Gen_Shleg: "continuous_on A (Gen_Shleg k)"
   by (auto simp: Gen_Shleg_def intro!: continuous_intros)
 
 lemma continuous_on_Gen_Shleg' [continuous_intros]:
   "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. Gen_Shleg k (f x))"
   by (rule continuous_on_compose2[OF continuous_on_Gen_Shleg[of UNIV]]) auto
 
 lemma continuous_on_Shleg: "continuous_on A Shleg"
   by (auto simp: Shleg_def intro!: continuous_intros)
 
 lemma continuous_on_Shleg' [continuous_intros]:
   "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. Shleg (f x))"
   by (rule continuous_on_compose2[OF continuous_on_Shleg[of UNIV]]) auto
 
 lemma measurable_Gen_Shleg [measurable]: "Gen_Shleg n \<in> borel_measurable borel"
   by (intro borel_measurable_continuous_onI continuous_on_Gen_Shleg)
 
 lemma measurable_Shleg [measurable]: "Shleg \<in> borel_measurable borel"
   by (intro borel_measurable_continuous_onI continuous_on_Shleg)
 
 end
 
 
 subsection \<open>Auxiliary facts about the \<open>\<zeta>\<close> function\<close>
 
 lemma Re_zeta_ge_1:
   assumes "x > 1"
   shows   "Re (zeta (of_real x)) \<ge> 1"
 proof -
   have *: "(\<lambda>n. real (Suc n) powr -x) sums Re (zeta (complex_of_real x))"
     using sums_Re[OF sums_zeta[of "of_real x"]] assms by (simp add: powr_Reals_eq)
   show "Re (zeta (of_real x)) \<ge> 1"
   proof (rule sums_le[OF _ _ *])
     show "(\<lambda>n. if n = 0 then 1 else 0) sums 1"
       by (rule sums_single)
   qed auto
 qed
 
 lemma sums_zeta_of_nat_offset:
   fixes r :: nat
   assumes n: "n > 1"
   shows "(\<lambda>k. 1 / (r + k + 1) ^ n) sums (zeta (of_nat n) - (\<Sum>k=1..r. 1 / k ^ n))"
 proof -
   have "(\<lambda>k. 1 / (k + 1) ^ n) sums zeta (of_nat n)"
     using sums_zeta[of "of_nat n"] n
     by (simp add: powr_minus field_simps flip: of_nat_Suc)
   from sums_split_initial_segment[OF this, of r]
   have "(\<lambda>k. 1 / (r + k + 1) ^ n) sums (zeta (of_nat n) - (\<Sum>k<r. 1 / Suc k ^ n))"
     by (simp add: algebra_simps)
   also have "(\<Sum>k<r. 1 / Suc k ^ n) = (\<Sum>k=1..r. 1 / k ^ n)"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>k. k - 1" Suc]) auto
   finally show ?thesis .
 qed
 
 lemma sums_Re_zeta_of_nat_offset:
   fixes r :: nat
   assumes n: "n > 1"
   shows "(\<lambda>k. 1 / (r + k + 1) ^ n) sums (Re (zeta (of_nat n)) - (\<Sum>k=1..r. 1 / k ^ n))"
 proof -
   have "(\<lambda>k. Re (1 / (r + k + 1) ^ n)) sums (Re (zeta (of_nat n) - (\<Sum>k=1..r. 1 / k ^ n)))"
     by (intro sums_Re sums_zeta_of_nat_offset assms)
   thus ?thesis by simp
 qed
 
 
 subsection \<open>Divisor of a sum of rationals\<close>
 
 text \<open>
   A finite sum of rationals of the form $\frac{a_1}{b_1} + \ldots + \frac{a_n}{b_n}$
   can be brought into the form $\frac{c}{d}$, where $d$ is the LCM of the $b_i$ (or
   some integer multiple thereof).
 \<close>
 lemma sum_rationals_common_divisor:
   fixes f g :: "'a \<Rightarrow> int"
   assumes "finite A"
   assumes "\<And>x. x \<in> A \<Longrightarrow> g x \<noteq> 0"
   shows   "\<exists>c. (\<Sum>x\<in>A. f x / g x) = real_of_int c / (LCM x\<in>A. g x)"
   using assms
 proof (induction rule: finite_induct)
   case empty
   thus ?case by auto
 next
   case (insert x A)
   define d where "d = (LCM x\<in>A. g x)"
   from insert have [simp]: "d \<noteq> 0"
     by (auto simp: d_def Lcm_0_iff)
   from insert have [simp]: "g x \<noteq> 0" by auto
   from insert obtain c where c: "(\<Sum>x\<in>A. f x / g x) = real_of_int c / real_of_int d"
     by (auto simp: d_def)
   define e1 where "e1 = lcm d (g x) div d"
   define e2 where "e2 = lcm d (g x) div g x"
   have "(\<Sum>y\<in>insert x A. f y / g y) = c / d + f x / g x"
     using insert c by simp
   also have "c / d = (c * e1) / lcm d (g x)"
     by (simp add: e1_def real_of_int_div)
   also have "f x / g x = (f x * e2) / lcm d (g x)"
     by (simp add: e2_def real_of_int_div)
   also have "(c * e1) / lcm d (g x) + \<dots> = (c * e1 + f x * e2) / (LCM x\<in>insert x A. g x)"
     using insert by (simp add: add_divide_distrib lcm.commute d_def)
   finally show ?case ..
 qed
 
 lemma sum_rationals_common_divisor':
   fixes f g :: "'a \<Rightarrow> int"
   assumes "finite A"
   assumes "\<And>x. x \<in> A \<Longrightarrow> g x \<noteq> 0" and "(\<And>x. x \<in> A \<Longrightarrow> g x dvd d)" and "d \<noteq> 0"
   shows   "\<exists>c. (\<Sum>x\<in>A. f x / g x) = real_of_int c / real_of_int d"
 proof -
   define d' where "d' = (LCM x\<in>A. g x)"
   have "d' dvd d"
     unfolding d'_def using assms(3) by (auto simp: Lcm_dvd_iff)
   then obtain e where e: "d = d' * e" by blast
   have "\<exists>c. (\<Sum>x\<in>A. f x / g x) = real_of_int c / (LCM x\<in>A. g x)"
     by (rule sum_rationals_common_divisor) fact+
   then obtain c where c: "(\<Sum>x\<in>A. f x / g x) = real_of_int c / real_of_int d'"
     unfolding d'_def ..
   also have "\<dots> = real_of_int (c * e) / real_of_int d"
     using \<open>d \<noteq> 0\<close> by (simp add: e)
   finally show ?thesis ..
 qed
 
 
 subsection \<open>The first double integral\<close>
 
 text \<open>
   We shall now investigate the double integral
   \[I_1 := \int_0^1 \int_0^1 -\frac{\ln(xy)}{1-xy}\,x^r y^s\, \text{d}x\,\text{d}y\ .\]
   Since everything is non-negative for now, we can work over the extended non-negative
   real numbers and the issues of integrability or summability do not arise at all.
 \<close>
 
 definition beukers_nn_integral1 :: "nat \<Rightarrow> nat \<Rightarrow> ennreal" where
   "beukers_nn_integral1 r s =
      (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y) / (1 - x*y) * x^r * y^s) \<partial>lborel)"
 
 definition beukers_integral1 :: "nat \<Rightarrow> nat \<Rightarrow> real" where
   "beukers_integral1 r s = (\<integral>(x,y)\<in>{0<..<1}\<times>{0<..<1}. (-ln (x*y) / (1 - x*y) * x^r * y^s) \<partial>lborel)"
 
 lemma
   fixes x y z :: real
   assumes xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0..1}"
   shows beukers_denom_ineq: "(1 - x * y) * z < 1" and beukers_denom_neq: "(1 - x * y) * z \<noteq> 1"
 proof -
   from xyz have *: "x * y < 1 * 1"
     by (intro mult_strict_mono) auto
   from * have "(1 - x * y) * z \<le> (1 - x * y) * 1"
     using xyz by (intro mult_left_mono) auto
   also have "\<dots> < 1 * 1"
     using xyz by (intro mult_strict_right_mono) auto
   finally show "(1 - x * y) * z < 1" "(1 - x * y) * z \<noteq> 1" by simp_all
 qed
 
 text \<open>
   We first evaluate the improper integral
     \[\int_0^1 -\ln x \cdot x^e\,\text{d}x = \frac{1}{(e+1)^2}\ .\]
   for any $e>-1$.
 \<close>
 lemma integral_0_1_ln_times_powr:
   assumes "e > -1"
   shows   "(LBINT x=0..1. -ln x * x powr e) = 1 / (e + 1)\<^sup>2"
     and   "interval_lebesgue_integrable lborel 0 1 (\<lambda>x. -ln x * x powr e)"
 proof -
   define f where "f = (\<lambda>x. -ln x * x powr e)"
   define F where "F = (\<lambda>x. x powr (e + 1) * (1 - (e + 1) * ln x) / (e + 1) ^ 2)"
 
   have 0: "isCont f x" if "x \<in> {0<..<1}" for x
     using that by (auto intro!: continuous_intros simp: f_def)
   have 1: "(F has_real_derivative f x) (at x)" if "x \<in> {0<..<1}" for x
   proof -
     show "(F has_real_derivative f x) (at x)"
       unfolding F_def f_def using that assms
       apply (insert that assms)
       apply (rule derivative_eq_intros refl | simp)+
       apply (simp add: divide_simps)
       apply (simp add: power2_eq_square algebra_simps powr_add power_numeral_reduce)
       done
   qed
   have 2: "AE x in lborel. ereal 0 < ereal x \<longrightarrow> ereal x < ereal 1 \<longrightarrow> 0 \<le> f x"
     by (intro AE_I2) (auto simp: f_def mult_nonpos_nonneg)
   have 3: "((F \<circ> real_of_ereal) \<longlongrightarrow> 0) (at_right (ereal 0))"
     unfolding ereal_tendsto_simps F_def using assms by real_asymp
   have 4: "((F \<circ> real_of_ereal) \<longlongrightarrow> F 1) (at_left (ereal 1))"
     unfolding ereal_tendsto_simps F_def
     using assms by real_asymp (simp add: field_simps)
 
   have "(LBINT x=ereal 0..ereal 1. f x) = F 1 - 0"
     by (rule interval_integral_FTC_nonneg[where F = F])
        (use 0 1 2 3 4 in auto)
   thus "(LBINT x=0..1. -ln x * x powr e) = 1 / (e + 1)\<^sup>2"
     by (simp add: F_def zero_ereal_def one_ereal_def f_def)
   have "set_integrable lborel (einterval (ereal 0) (ereal 1)) f"
     by (rule interval_integral_FTC_nonneg)
        (use 0 1 2 3 4 in auto)
   thus "interval_lebesgue_integrable lborel 0 1 f"
     by (simp add: interval_lebesgue_integrable_def einterval_def)
 qed
 
 lemma interval_lebesgue_integral_lborel_01_cong:
   assumes "\<And>x. x \<in> {0<..<1} \<Longrightarrow> f x = g x"
   shows   "interval_lebesgue_integral lborel 0 1 f =
            interval_lebesgue_integral lborel 0 1 g"
   using assms
   by (subst (1 2) interval_integral_Ioo)
      (auto intro!: set_lebesgue_integral_cong assms)
 
 lemma nn_integral_0_1_ln_times_powr:
   assumes "e > -1"
   shows    "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y powr e) \<partial>lborel) = ennreal (1 / (e + 1)\<^sup>2)"
 proof -
   have *: "(LBINT x=0..1. - ln x * x powr e = 1 / (e + 1)\<^sup>2)"
           "interval_lebesgue_integrable lborel 0 1 (\<lambda>x. - ln x * x powr e)"
     using integral_0_1_ln_times_powr[OF assms] by simp_all
   have eq: "(\<lambda>y. (if 0 < y \<and> y < 1 then 1 else 0) * ln y * y powr e) =
             (\<lambda>y. if 0 < y \<and> y < 1 then ln y * y powr e else 0)"
     by auto
 
   have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y powr e) \<partial>lborel) =
            (\<integral>\<^sup>+y. ennreal (-ln y * y powr e * indicator {0<..<1} y) \<partial>lborel)"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = ennreal (1 / (e + 1)\<^sup>2)"
     using * eq
     by (subst nn_integral_eq_integral)
        (auto intro!: AE_I2 simp: indicator_def interval_lebesgue_integrable_def
                set_integrable_def one_ereal_def zero_ereal_def interval_integral_Ioo
                 mult_ac mult_nonpos_nonneg set_lebesgue_integral_def)
   finally show ?thesis .
 qed
 
 lemma nn_integral_0_1_ln_times_power:
   "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y ^ n) \<partial>lborel) = ennreal (1 / (n + 1)\<^sup>2)"
 proof -
   have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y ^ n) \<partial>lborel) =
           (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y powr real n) \<partial>lborel)"
     by (intro set_nn_integral_cong) (auto simp: powr_realpow)
   also have "\<dots> = ennreal (1 / (n + 1)^2)"
     by (subst nn_integral_0_1_ln_times_powr) auto
   finally show ?thesis by simp
 qed
 
 text \<open>
   Next, we also evaluate the more trivial integral
     \[\int_0^1 x^n\ \text{d}x\ .\]
 \<close>
 lemma nn_integral_0_1_power:
   "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y ^ n) \<partial>lborel) = ennreal (1 / (n + 1))"
 proof -
   have *: "((\<lambda>a. a ^ (n + 1) / real (n + 1)) has_real_derivative x ^ n) (at x)" for x
     by (rule derivative_eq_intros refl | simp)+
   have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y ^ n) \<partial>lborel) = (\<integral>\<^sup>+y\<in>{0..1}. ennreal (y ^ n) \<partial>lborel)"
     by (intro nn_integral_cong_AE AE_I[of _ _ "{0,1}"])
        (auto simp: indicator_def emeasure_lborel_countable)
   also have "\<dots> = ennreal (1 ^ (n + 1) / (n + 1) - 0 ^ (n + 1) / (n + 1))"
     using * by (intro nn_integral_FTC_Icc) auto
   also have "\<dots> = ennreal (1 / (n + 1))"
     by simp
   finally show ?thesis by simp
 qed
 
 text \<open>
   $I_1$ can alternatively be written as the triple integral
     \[\int_0^1\int_0^1\int_0^1
         \frac{x^r y^s}{1-(1-xy)w}\ \text{d}x\,\text{d}y\,\text{d}w\ .\]
 \<close>
 lemma beukers_nn_integral1_altdef:
   "beukers_nn_integral1 r s =
      (\<integral>\<^sup>+(w,x,y)\<in>{0<..<1}\<times>{0<..<1}\<times>{0<..<1}.
        ennreal (1 / (1-(1-x*y)*w) * x^r * y^s) \<partial>lborel)"
 proof -
   have "(\<integral>\<^sup>+(w,x,y)\<in>{0<..<1}\<times>{0<..<1}\<times>{0<..<1}.
            ennreal (1 / (1-(1-x*y)*w) * x^r * y^s) \<partial>lborel) =
         (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. (\<integral>\<^sup>+w\<in>{0<..<1}.
            ennreal (1 / (1-(1-x*y)*w) * x^r * y^s) \<partial>lborel) \<partial>lborel)"
     by (subst lborel_prod [symmetric], subst lborel_pair.nn_integral_snd [symmetric])
        (auto simp: case_prod_unfold indicator_def simp flip: lborel_prod intro!: nn_integral_cong)
   also have "\<dots> = (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y)/(1-x*y) * x^r * y^s) \<partial>lborel)"
   proof (intro nn_integral_cong, clarify)
     fix x y :: real
     have "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)*x^r*y^s) \<partial>lborel) =
              ennreal (-ln (x*y)*x^r*y^s/(1-x*y))"
       if xy: "(x, y) \<in> {0<..<1} \<times> {0<..<1}"
     proof -
       from xy have "x * y < 1"
         using mult_strict_mono[of x 1 y 1] by simp
       have deriv: "((\<lambda>w. -ln (1-(1-x*y)*w) / (1-x*y)) has_real_derivative
               1/(1-(1-x*y)*w)) (at w)" if w: "w \<in> {0..1}" for w
         by (insert xy w \<open>x*y<1\<close> beukers_denom_ineq[of x y w])
            (rule derivative_eq_intros refl | simp add: divide_simps)+
       have "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)*x^r*y^s) \<partial>lborel) =
               ennreal (x^r*y^s) * (\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel)"
         using xy by (subst nn_integral_cmult [symmetric])
                     (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
       also have "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel) =
                  (\<integral>\<^sup>+w\<in>{0..1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel)"
         by (intro nn_integral_cong_AE AE_I[of _ _ "{0,1}"])
            (auto simp: emeasure_lborel_countable indicator_def)
       also have "(\<integral>\<^sup>+w\<in>{0..1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel) =
                    ennreal (-ln (1-(1-x*y)*1)/(1-x*y) - (-ln (1-(1-x*y)*0)/(1-x*y)))"
         using xy deriv less_imp_le[OF beukers_denom_ineq[of x y]]
         by (intro nn_integral_FTC_Icc) auto
       finally show ?thesis using xy
         by (simp flip: ennreal_mult' ennreal_mult'' add: mult_ac)
     qed
     thus "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)*x^r*y^s) \<partial>lborel) * indicator ({0<..<1}\<times>{0<..<1}) (x, y) =
            ennreal (-ln (x*y)/(1-x*y)*x^r*y^s) * indicator ({0<..<1}\<times>{0<..<1}) (x, y)"
       by (auto simp: indicator_def)
   qed
   also have "\<dots> = beukers_nn_integral1 r s"
     by (simp add: beukers_nn_integral1_def)
   finally show ?thesis ..
 qed
 
 context
   fixes r s :: nat and I1 I2' :: real and I2 :: ennreal and D :: "(real \<times> real \<times> real) set"
   assumes rs: "s \<le> r"
   defines "D \<equiv> {0<..<1}\<times>{0<..<1}\<times>{0<..<1}"
 begin
 
 text \<open>
   By unfolding the geometric series, pulling the summation out and evaluating the integrals,
   we find that
     \[I_1 = \sum_{k=0}^\infty \frac{1}{(k+r+1)^2(k+s+1)} + \frac{1}{(k+r+1)(k+s+1)^2}\ .\]
 \<close>
 lemma beukers_nn_integral1_series:
   "beukers_nn_integral1 r s = (\<Sum>k. ennreal (1/((k+r+1)^2*(k+s+1)) + 1/((k+r+1)*(k+s+1)^2)))"
 proof -
   have "beukers_nn_integral1 r s =
           (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. (\<Sum>k. ennreal (-ln (x*y) * x^(k+r) * y^(k+s))) \<partial>lborel)"
     unfolding beukers_nn_integral1_def
   proof (intro set_nn_integral_cong refl, clarify)
     fix x y :: real assume xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
     from xy have "x * y < 1" using mult_strict_mono[of x 1 y 1] by simp
     have "(\<Sum>k. ennreal (-ln (x*y) * x^(k+r) * y^(k+s))) =
              ennreal (-ln (x*y) * x^r * y^s) * (\<Sum>k. ennreal ((x*y)^k))"
       using xy by (subst ennreal_suminf_cmult [symmetric], subst ennreal_mult'' [symmetric])
                   (auto simp: power_add mult_ac power_mult_distrib)
     also have "(\<Sum>k. ennreal ((x*y)^k)) = ennreal (1 / (1 - x*y))"
       using geometric_sums[of "x*y"] \<open>x * y < 1\<close> xy by (intro suminf_ennreal_eq) auto
     also have "ennreal (-ln (x*y) * x^r * y^s) * \<dots> =
                  ennreal (-ln (x*y) / (1 - x*y) * x^r * y^s)"
       using \<open>x * y < 1\<close> by (subst ennreal_mult'' [symmetric]) auto
     finally show "ennreal (-ln (x*y) / (1 - x*y) * x^r * y^s) =
                     (\<Sum>k. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)))" ..
   qed
   also have "\<dots> = (\<Sum>k. (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. (ennreal (-ln (x*y) * x^(k+r) * y^(k+s))) \<partial>lborel))"
     unfolding case_prod_unfold by (subst nn_integral_suminf [symmetric]) (auto simp flip: borel_prod)
   also have "\<dots> = (\<Sum>k. ennreal (1 / ((k+r+1)^2*(k+s+1)) + 1 / ((k+r+1)*(k+s+1)^2)))"
   proof (rule suminf_cong)
     fix k :: nat
     define F where "F = (\<lambda>x y::real. x + y)"
     have "(\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) =
             (\<integral>\<^sup>+x\<in>{0<..<1}. (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) \<partial>lborel)"
       unfolding case_prod_unfold lborel_prod [symmetric]
       by (subst lborel.nn_integral_fst [symmetric]) (auto intro!: nn_integral_cong simp: indicator_def)
     also have "\<dots> = (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r) / (k+s+1) + x^(k+r)/(k+s+1)^2) \<partial>lborel)"
     proof (intro set_nn_integral_cong refl, clarify)
       fix x :: real assume x: "x \<in> {0<..<1}"
       have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) =
               (\<integral>\<^sup>+y\<in>{0<..<1}. (ennreal (-ln x * x^(k+r) * y^(k+s)) + ennreal (-ln y * x^(k+r) * y^(k+s))) \<partial>lborel)"
         by (intro set_nn_integral_cong)
            (use x in \<open>auto simp: ln_mult ring_distribs mult_nonpos_nonneg simp flip: ennreal_plus\<close>)
       also have "\<dots> = (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln x * x^(k+r) * y^(k+s)) \<partial>lborel) +
                       (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * x^(k+r) * y^(k+s)) \<partial>lborel)"
         by (subst nn_integral_add [symmetric]) (auto intro!: nn_integral_cong simp: indicator_def)
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln x * x^(k+r) * y^(k+s)) \<partial>lborel) =
                  ennreal (-ln x * x^(k+r)) * (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y^(k+s)) \<partial>lborel)"
         by (subst nn_integral_cmult [symmetric])
            (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult'')
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y^(k+s)) \<partial>lborel) = ennreal (1/(k+s+1))"
         by (subst nn_integral_0_1_power) simp
       also have "ennreal (-ln x * x^(k+r)) * \<dots> = ennreal (-ln x * x^(k+r) / (k+s+1))"
         by (subst ennreal_mult'' [symmetric]) auto
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * x^(k+r) * y^(k+s)) \<partial>lborel) =
                    ennreal (x^(k+r)) * (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y^(k+s)) \<partial>lborel)"
         by (subst nn_integral_cmult [symmetric])
            (use x in \<open>auto intro!: nn_integral_cong simp: indicator_def mult_ac simp flip: ennreal_mult'\<close>)
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y^(k+s)) \<partial>lborel) = ennreal (1 / (k + s + 1)\<^sup>2)"
         by (subst nn_integral_0_1_ln_times_power) simp
       also have "ennreal (x ^ (k + r)) * \<dots> = ennreal (x ^ (k + r) / (k + s + 1) ^ 2)"
         by (subst ennreal_mult'' [symmetric]) auto
       also have "ennreal (- ln x * x ^ (k + r) / (k + s + 1)) + \<dots> =
                    ennreal (-ln x * x^(k+r) / (k+s+1) + x^(k+r)/(k+s+1)^2)"
         using x by (subst ennreal_plus) (auto simp: mult_nonpos_nonneg divide_nonpos_nonneg)
       finally show "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) =
                       ennreal (-ln x * x^(k+r) / (k+s+1) + x^(k+r)/(k+s+1)^2)" .
     qed
     also have "\<dots> = (\<integral>\<^sup>+x\<in>{0<..<1}. (ennreal (-ln x * x^(k+r) / (k+s+1)) +
                        ennreal (x^(k+r)/(k+s+1)^2)) \<partial>lborel)"
       by (intro set_nn_integral_cong refl, subst ennreal_plus)
          (auto simp: mult_nonpos_nonneg divide_nonpos_nonneg)
     also have "\<dots> = (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r) / (k+s+1)) \<partial>lborel) +
                     (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (x^(k+r)/(k+s+1)^2) \<partial>lborel)"
       by (subst nn_integral_add [symmetric]) (auto intro!: nn_integral_cong simp: indicator_def)
     also have "(\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r) / (k+s+1)) \<partial>lborel) =
                   ennreal (1 / (k+s+1)) * (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r)) \<partial>lborel)"
       by (subst nn_integral_cmult [symmetric])
          (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
     also have "\<dots> = ennreal (1 / ((k+s+1) * (k+r+1)^2))"
       by (subst nn_integral_0_1_ln_times_power, subst ennreal_mult [symmetric]) (auto simp: algebra_simps)
     also have "(\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (x^(k+r)/(k+s+1)^2) \<partial>lborel) =
                   ennreal (1/(k+s+1)^2) * (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (x^(k+r)) \<partial>lborel)"
       by (subst nn_integral_cmult [symmetric])
          (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
     also have "\<dots> = ennreal (1/((k+r+1)*(k+s+1)^2))"
       by (subst nn_integral_0_1_power, subst ennreal_mult [symmetric]) (auto simp: algebra_simps)
     also have "ennreal (1 / ((k+s+1) * (k+r+1)^2)) + \<dots> =
                  ennreal (1/((k+r+1)^2*(k+s+1)) + 1/((k+r+1)*(k+s+1)^2))"
       by (subst ennreal_plus [symmetric]) (auto simp: algebra_simps)
     finally show "(\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) = \<dots>" .
   qed
   finally show ?thesis .
 qed
 
 text \<open>
   Remembering that $\zeta(3) = \sum k^{-3}$, it is easy to see that if $r = s$, this sum is simply
     \[2\left(\zeta(3) - \sum_{k=1}^r \frac{1}{k^3}\right)\ .\]
 \<close>
 lemma beukers_nn_integral1_same:
   assumes "r = s"
   shows   "beukers_nn_integral1 r s = ennreal (2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)))"
     and   "2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)) \<ge> 0"
 proof -
   from assms have [simp]: "s = r" by simp
   have *: "Suc 2 = 3" by simp
   have "beukers_nn_integral1 r s = (\<Sum>k. ennreal (2 / (r + k + 1) ^ 3))"
     unfolding beukers_nn_integral1_series
     by (simp only: assms power_Suc [symmetric] mult.commute[of "x ^ 2" for x] *
                    times_divide_eq_right mult_1_right add_ac flip: mult_2)
   also have **: "(\<lambda>k. 2 / (r + k + 1) ^ 3) sums
               (2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)))"
     using sums_mult[OF sums_Re_zeta_of_nat_offset[of 3], of 2] by simp
   hence "(\<Sum>k. ennreal (2 / (r + k + 1) ^ 3)) = ennreal \<dots>"
     by (intro suminf_ennreal_eq) auto
   finally show "beukers_nn_integral1 r s = ennreal (2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)))" .
   show "2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)) \<ge> 0"
     by (rule sums_le[OF _ sums_zero **]) auto
 qed
 
 lemma beukers_integral1_same:
   assumes "r = s"
   shows   "beukers_integral1 r s = 2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3))"
 proof -
   have "ln (a * b) * a ^ r * b ^ s / (1 - a * b) \<le> 0" if "a \<in> {0<..<1}" "b \<in> {0<..<1}" for a b :: real
     using that mult_strict_mono[of a 1 b 1] by (intro mult_nonpos_nonneg divide_nonpos_nonneg) auto
   thus ?thesis
     using beukers_nn_integral1_same[OF assms]
     unfolding beukers_nn_integral1_def beukers_integral1_def
     by (intro set_integral_eq_nn_integral AE_I2)
        (auto simp flip: lborel_prod simp: case_prod_unfold set_borel_measurable_def
              intro: divide_nonpos_nonneg mult_nonpos_nonneg)
 qed
 
 text \<open>
   In contrast, for \<open>r > s\<close>, we find that
     \[I_1 = \frac{1}{r-s} \sum_{k=s+1}^r \frac{1}{k^2}\ .\]
 \<close>
 lemma beukers_nn_integral1_different:
   assumes "r > s"
   shows   "beukers_nn_integral1 r s = ennreal ((\<Sum>k\<in>{s<..r}. 1 / k ^ 2) / (r - s))"
 proof -
   have "(\<lambda>k. 1 / (r - s) * (1 / (s + k + 1) ^ 2 - 1 / (r + k + 1) ^ 2))
           sums (1 / (r - s) * ((Re (zeta (of_nat 2)) - (\<Sum>k=1..s. 1/k^2)) -
                                (Re (zeta (of_nat 2)) - (\<Sum>k=1..r. 1/k^2))))"
     (is "_ sums ?S") by (intro sums_mult sums_diff sums_Re_zeta_of_nat_offset) auto
   also have "?S = ((\<Sum>k=1..r. 1/k^2) - (\<Sum>k=1..s. 1/k^2)) / (r - s)"
     by (simp add: algebra_simps diff_divide_distrib)
   also have "(\<Sum>k=1..r. 1/k^2) - (\<Sum>k=1..s. 1/k^2) = (\<Sum>k\<in>{1..r}-{1..s}. 1/k^2)"
     using assms by (subst Groups_Big.sum_diff) auto
   also have "{1..r} - {1..s} = {s<..r}" by auto
 
   also have "(\<lambda>k. 1 / (r - s) * (1 / (s + k + 1) ^ 2 - 1 / (r + k + 1) ^ 2)) =
                (\<lambda>k. 1 / ((k+r+1) * (k+s+1)^2) + 1 / ((k+r+1)^2 * (k+s+1)))"
   proof (intro ext, goal_cases)
     case (1 k)
     define x where "x = real (k + r + 1)"
     define y where "y = real (k + s + 1)"
     have [simp]: "x \<noteq> 0" "y \<noteq> 0" by (auto simp: x_def y_def)
     have "(x\<^sup>2 * y + x * y\<^sup>2) * (real r - real s) = x * y * (x\<^sup>2 - y\<^sup>2)"
       by (simp add: algebra_simps power2_eq_square x_def y_def)
     hence "1 / (x*y^2) + 1 / (x^2*y) = 1 / (r - s) * (1 / y^2 - 1 / x^2)"
       using assms by (simp add: divide_simps of_nat_diff)
     thus ?case by (simp add: x_def y_def algebra_simps)
   qed
   finally show ?thesis
     unfolding beukers_nn_integral1_series by (intro suminf_ennreal_eq) (auto simp: add_ac)
 qed
 
 lemma beukers_integral1_different:
   assumes "r > s"
   shows   "beukers_integral1 r s = (\<Sum>k\<in>{s<..r}. 1 / k ^ 2) / (r - s)"
 proof -
   have "ln (a * b) * a ^ r * b ^ s / (1 - a * b) \<le> 0" if "a \<in> {0<..<1}" "b \<in> {0<..<1}" for a b :: real
     using that mult_strict_mono[of a 1 b 1] by (intro mult_nonpos_nonneg divide_nonpos_nonneg) auto
     thus ?thesis
     using beukers_nn_integral1_different[OF assms]
     unfolding beukers_nn_integral1_def beukers_integral1_def
     by (intro set_integral_eq_nn_integral AE_I2)
        (auto simp flip: lborel_prod simp: case_prod_unfold set_borel_measurable_def
              intro: divide_nonpos_nonneg mult_nonpos_nonneg intro!: sum_nonneg divide_nonneg_nonneg)
 qed
 
 end
 
 text \<open>
   It is also easy to see that if we exchange \<open>r\<close> and \<open>s\<close>, nothing changes.
 \<close>
 lemma beukers_nn_integral1_swap:
   "beukers_nn_integral1 r s = beukers_nn_integral1 s r"
   unfolding beukers_nn_integral1_def lborel_prod [symmetric]
   by (subst lborel_pair.nn_integral_swap, simp)
      (intro nn_integral_cong, auto simp: indicator_def algebra_simps split: if_splits)
 
 lemma beukers_nn_integral1_finite: "beukers_nn_integral1 r s < \<infinity>"
   using beukers_nn_integral1_different[of r s] beukers_nn_integral1_different[of s r]
   by (cases r s rule: linorder_cases)
      (simp_all add: beukers_nn_integral1_same beukers_nn_integral1_swap)
 
 lemma beukers_integral1_integrable:
   "set_integrable lborel ({0<..<1}\<times>{0<..<1})
      (\<lambda>(x,y). (-ln (x*y) / (1 - x*y) * x^r * y^s :: real))"
 proof (intro set_integrableI_nonneg AE_I2; clarify?)
   fix x y :: real assume xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
   have "0 \<ge> ln (x * y) / (1 - x * y) * x ^ r * y ^ s"
     using mult_strict_mono[of x 1 y 1]
     by (intro mult_nonpos_nonneg divide_nonpos_nonneg) (use xy in auto)
   thus "0 \<le> - ln (x * y) / (1 - x * y) * x ^ r * y ^ s" by simp
 next
   show "\<integral>\<^sup>+x\<in>{0<..<1}\<times>{0<..<1}. ennreal (case x of (x, y) \<Rightarrow>
            - ln (x * y) / (1 - x * y) * x ^ r * y ^ s) \<partial>lborel < \<infinity>"
     using beukers_nn_integral1_finite by (simp add: beukers_nn_integral1_def case_prod_unfold)
 qed (simp_all flip: lborel_prod add: set_borel_measurable_def)
 
 lemma beukers_integral1_integrable':
   "set_integrable lborel ({0<..<1}\<times>{0<..<1}\<times>{0<..<1})
      (\<lambda>(z,x,y). (x^r * y^s / (1 - (1 - x*y) * z) :: real))"
 proof (intro set_integrableI_nonneg AE_I2; clarify?)
   fix x y z :: real assume xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0<..<1}"
   show "0 \<le> x^r * y^s / (1 - (1 - x*y) * z)"
     using mult_strict_mono[of x 1 y 1] xyz beukers_denom_ineq[of x y z]
     by (intro mult_nonneg_nonneg divide_nonneg_nonneg) auto
 next
   show "\<integral>\<^sup>+x\<in>{0<..<1}\<times>{0<..<1}\<times>{0<..<1}. ennreal (case x of (z,x,y) \<Rightarrow>
            x ^ r * y ^ s / (1-(1-x*y)*z)) \<partial>lborel < \<infinity>"
     using beukers_nn_integral1_finite
     by (simp add: beukers_nn_integral1_altdef case_prod_unfold)
 qed (simp_all flip: lborel_prod add: set_borel_measurable_def)
 
 lemma beukers_integral1_conv_nn_integral:
   "beukers_integral1 r s = enn2real (beukers_nn_integral1 r s)"
 proof -
   have "ln (a * b) * a ^ r * b ^ s / (1 - a * b) \<le> 0" if "a \<in> {0<..<1}" "b \<in> {0<..<1}"
     for a b :: real
     using mult_strict_mono[of a 1 b 1] that by (intro divide_nonpos_nonneg mult_nonpos_nonneg) auto
   thus ?thesis unfolding beukers_integral1_def using beukers_nn_integral1_finite[of r s]
     by (intro set_integral_eq_nn_integral)
        (auto simp: case_prod_unfold beukers_nn_integral1_def
                    set_borel_measurable_def simp flip: borel_prod
              intro!: AE_I2 intro: divide_nonpos_nonneg mult_nonpos_nonneg)
 qed
 
 lemma beukers_integral1_swap: "beukers_integral1 r s = beukers_integral1 s r"
   by (simp add: beukers_integral1_conv_nn_integral beukers_nn_integral1_swap)
 
 
 subsection \<open>The second double integral\<close>
 
 context
   fixes n :: nat
   fixes D :: "(real \<times> real) set" and D' :: "(real \<times> real \<times> real) set"
   fixes P :: "real \<Rightarrow> real" and Q :: "nat \<Rightarrow> real \<Rightarrow> real"
   defines "D \<equiv> {0<..<1} \<times> {0<..<1}" and "D' \<equiv> {0<..<1} \<times> {0<..<1} \<times> {0<..<1}"
   defines "Q \<equiv> Gen_Shleg n" and "P \<equiv> Shleg n"
 begin
 
 text \<open>
   The next integral to consider is the following variant of $I_1$:
   \[I_2 :=
       \int_0^1 \int_0^1 -\frac{\ln(xy)}{1-xy} P_n(x) P_n(y)\,\text{d}x\,\text{d}y\ .\]
 \<close>
 
 definition beukers_integral2 :: real where
   "beukers_integral2 = (\<integral>(x,y)\<in>D. (-ln (x*y) / (1-x*y) * P x * P y) \<partial>lborel)"
 
 text \<open>
   $I_2$ is simply a sum of integrals of type $I_1$, so using our results for
   $I_1$, we can write $I_2$ in the form $A \zeta(3) + \frac{B}{\text{lcm}\{1\ldots n\}^3}$
   where $A$ and $B$ are integers and $A > 0$:
 \<close>
 lemma beukers_integral2_conv_int_combination:
   obtains A B :: int where "A > 0" and
     "beukers_integral2 = of_int A * Re (zeta 3) + of_int B / of_nat (Lcm {1..n} ^ 3)"
 proof -
   let ?I1 = "(\<lambda>i. (i, i)) ` {..n}"
   let ?I2 = "Set.filter (\<lambda>(i,j). i \<noteq> j) ({..n}\<times>{..n})"
   let ?I3 = "Set.filter (\<lambda>(i,j). i < j) ({..n}\<times>{..n})"
   let ?I4 = "Set.filter (\<lambda>(i,j). i > j) ({..n}\<times>{..n})"
   define p where "p = shleg_poly n"
   define I where "I = (SIGMA i:{..n}. {1..i})"
   define J where "J = (SIGMA (i,j):?I4. {j<..i})"
   define h where "h = beukers_integral1"
   define A :: int where "A = (\<Sum>i\<le>n. 2 * poly.coeff p i ^ 2)"
   define B1 where "B1 = (\<Sum>(i,k)\<in>I. real_of_int (-2 * coeff p i ^ 2) / real_of_int (k ^ 3))"
   define B2 where "B2 = (\<Sum>((i,j),k)\<in>J. real_of_int (2 * coeff p i * coeff p j) / real_of_int (k^2*(i-j)))"
   define d where "d = Lcm {1..n} ^ 3"
 
   have [simp]: "h i j = h j i" for i j
     by (simp add: h_def beukers_integral1_swap)
 
   have "beukers_integral2 =
         (\<integral>(x,y)\<in>D. (\<Sum>(i,j)\<in>{..n}\<times>{..n}. coeff p i * coeff p j *
            -ln (x*y) / (1-x*y) * x ^ i * y ^ j) \<partial>lborel)"
     unfolding beukers_integral2_def
     by (subst sum.cartesian_product [symmetric])
        (simp add: poly_altdef P_def Shleg_def mult_ac case_prod_unfold p_def
                   sum_distrib_left sum_distrib_right sum_negf sum_divide_distrib)
   also have "\<dots> = (\<Sum>(i,j)\<in>{..n}\<times>{..n}. coeff p i * coeff p j * h i j)"
     unfolding case_prod_unfold
   proof (subst set_integral_sum)
     fix ij :: "nat \<times> nat"
     have "set_integrable lborel D
           (\<lambda>(x,y). real_of_int (coeff p (fst ij) * coeff p (snd ij)) *
                  (-ln (x*y) / (1-x*y) * x ^ fst ij * y ^ snd ij))"
       unfolding case_prod_unfold using beukers_integral1_integrable[of "fst ij" "snd ij"]
       by (intro set_integrable_mult_right) (auto simp: D_def case_prod_unfold)
     thus "set_integrable lborel D
           (\<lambda>pa. real_of_int (coeff p (fst ij) * coeff p (snd ij)) *
                  -ln (fst pa * snd pa) / (1 - fst pa * snd pa) * fst pa ^ fst ij * snd pa ^ snd ij)"
       by (simp add: mult_ac case_prod_unfold)
   qed (auto simp: beukers_integral1_def h_def case_prod_unfold mult.assoc D_def
             simp flip: set_integral_mult_right)
   also have "\<dots> = (\<Sum>(i,j)\<in>?I1\<union>?I2. coeff p i * coeff p j * h i j)"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>(i,j)\<in>?I1. coeff p i * coeff p j * h i j) +
                   (\<Sum>(i,j)\<in>?I2. coeff p i * coeff p j * h i j)"
     by (intro sum.union_disjoint) auto
   also have "(\<Sum>(i,j)\<in>?I1. coeff p i * coeff p j * h i j) =
                (\<Sum>i\<le>n. coeff p i ^ 2 * h i i)"
     by (subst sum.reindex) (auto intro: inj_onI simp: case_prod_unfold power2_eq_square)
   also have "\<dots> = (\<Sum>i\<le>n. coeff p i ^ 2 * 2 * (Re (zeta 3) - (\<Sum>k=1..i. 1 / k ^ 3)))"
     unfolding h_def D_def
     by (intro sum.cong refl, subst beukers_integral1_same) auto
   also have "\<dots> = of_int A * Re (zeta 3) -
                     (\<Sum>i\<le>n. 2 * coeff p i ^ 2 * (\<Sum>k=1..i. 1 / k ^ 3))"
     by (simp add: sum_subtractf sum_distrib_left sum_distrib_right algebra_simps A_def)
   also have "\<dots> = of_int A * Re (zeta 3) + B1"
     unfolding I_def B1_def by (subst sum.Sigma [symmetric]) (auto simp: sum_distrib_left sum_negf)
   also have "(\<Sum>(i,j)\<in>?I2. coeff p i * coeff p j * h i j) =
                (\<Sum>(i,j)\<in>?I3\<union>?I4. coeff p i * coeff p j * h i j)"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>(i,j)\<in>?I3. coeff p i * coeff p j * h i j) +
                   (\<Sum>(i,j)\<in>?I4. coeff p i * coeff p j * h i j)"
     by (intro sum.union_disjoint) auto
   also have "(\<Sum>(i,j)\<in>?I3. coeff p i * coeff p j * h i j) =
                (\<Sum>(i,j)\<in>?I4. coeff p i * coeff p j * h i j)"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>(i,j). (j,i)" "\<lambda>(i,j). (j,i)"]) auto
   also have "\<dots> + \<dots> = 2 * \<dots>" by simp
   also have "\<dots> = (\<Sum>(i,j)\<in>?I4. \<Sum>k\<in>{j<..i}. 2 * coeff p i * coeff p j / k ^ 2 / (i - j))"
     unfolding sum_distrib_left
     by (intro sum.cong refl)
        (auto simp: h_def beukers_integral1_different sum_divide_distrib sum_distrib_left mult_ac)
   also have "\<dots> = B2"
     unfolding J_def B2_def by (subst sum.Sigma [symmetric]) (auto simp: case_prod_unfold)
 
   also have "\<exists>B1'. B1 = real_of_int B1' / real_of_int d"
     unfolding B1_def case_prod_unfold
     by (rule sum_rationals_common_divisor') (auto simp: d_def I_def)
   then obtain B1' where "B1 = real_of_int B1' / real_of_int d" ..
 
   also have "\<exists>B2'. B2 = real_of_int B2' / real_of_int d"
     unfolding B2_def case_prod_unfold J_def
   proof (rule sum_rationals_common_divisor'; clarsimp?)
     fix i j k :: nat assume ijk: "i \<le> n" "j < k" "k \<le> i"
     have "int (k ^ 2 * (i - j)) dvd int (Lcm {1..n} ^ 2 * Lcm {1..n})"
       unfolding int_dvd_int_iff using ijk
       by (intro mult_dvd_mono dvd_power_same dvd_Lcm) auto
     also have "\<dots> = d"
       by (simp add: d_def power_numeral_reduce)
     finally show "int k ^ 2 * int (i - j) dvd int d" by simp
   qed(auto simp: d_def J_def intro!: Nat.gr0I)
   then obtain B2' where "B2 = real_of_int B2' / real_of_int d" ..
 
   finally have "beukers_integral2 =
                   of_int A * Re (zeta 3) + of_int (B1' + B2') / of_nat (Lcm {1..n} ^ 3)"
     by (simp add: add_divide_distrib d_def)
 
   moreover have "coeff p 0 = P 0"
     unfolding P_def p_def Shleg_def by (simp add: poly_0_coeff_0)
   hence "coeff p 0 = 1"
     by (simp add: P_def)
   hence "A > 0"
     unfolding A_def by (intro sum_pos2[of _ 0]) auto
 
   ultimately show ?thesis
     by (intro that[of A "B1' + B2'"]) auto
 qed
 
 lemma beukers_integral2_integrable:
   "set_integrable lborel D (\<lambda>(x,y). -ln (x*y) / (1 - x*y) * P x * P y)"
 proof -
   have "bounded (P ` {0..1})"
     unfolding P_def Shleg_def
     by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   have [measurable]: "P \<in> borel_measurable borel" by (simp add: P_def)
   from C[of 0] have "C \<ge> 0" by simp
   show ?thesis
   proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
     show "set_integrable lborel D (\<lambda>(x,y). C ^ 2 * (-ln (x*y) / (1 - x*y)))"
       using beukers_integral1_integrable[of 0 0] unfolding case_prod_unfold
       by (intro set_integrable_mult_right) (auto simp: D_def)
   next
     fix x y :: real
     assume xy: "(x, y) \<in> D"
     from xy have "x * y < 1"
       using mult_strict_mono[of x 1 y 1] by (simp add: D_def)
     have "norm (-ln (x*y) / (1 - x*y) * P x * P y) = (-ln (x*y)) / (1 - x*y) * norm (P x) * norm (P y)"
       using xy \<open>x * y < 1\<close> by (simp add: abs_mult abs_divide D_def)
     also have "\<dots> \<le> (-ln (x*y)) / (1-x*y) * C * C"
       using xy C[of x] C[of y] \<open>x * y < 1\<close> \<open>C \<ge> 0\<close>
       by (intro mult_mono divide_left_mono)
          (auto simp: D_def divide_nonpos_nonneg mult_nonpos_nonneg)
     also have "\<dots> = norm ((-ln (x*y)) / (1-x*y) * C * C)"
       using xy \<open>x * y < 1\<close> \<open>C \<ge> 0\<close> by (simp add: abs_divide abs_mult D_def)
     finally show "norm (-ln (x*y) / (1 - x*y) * P x * P y)
            \<le> norm (case (x, y) of (x, y) \<Rightarrow> C\<^sup>2 * (- ln (x * y) / (1 - x * y)))"
       by (auto simp: algebra_simps power2_eq_square abs_mult abs_divide)
   qed (auto simp: D_def set_borel_measurable_def case_prod_unfold simp flip: lborel_prod)
 qed
 
 
 subsection \<open>The triple integral\<close>
 
 text \<open>
   Lastly, we turn to the triple integral
   \[I_3 := \int_0^1 \int_0^1 \int_0^1
       \frac{(x(1-x)y(1-y)w(1-w))^n}{(1-(1-xy)w)^{n+1}}\ \text{d}x\,\text{d}y\,\text{d}w\ .\]
 \<close>
 
 definition beukers_nn_integral3 :: ennreal where
   "beukers_nn_integral3 =
      (\<integral>\<^sup>+(w,x,y)\<in>D'. ((x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1)) \<partial>lborel)"
 
 definition beukers_integral3 :: real where
   "beukers_integral3 =
      (\<integral>(w,x,y)\<in>D'. ((x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1)) \<partial>lborel)"
 
 text \<open>
   We first prove the following bound
   (which is a consequence of the arithmetic--geometric mean inequality)
   that will help us to bound the triple integral.
 \<close>
 lemma beukers_integral3_integrand_bound:
   fixes x y z :: real
   assumes xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0<..<1}"
   shows   "(x*(1-x)*y*(1-y)*z*(1-z)) / (1-(1-x*y)*z) \<le> 1 / 27" (is "?lhs \<le> _")
 proof -
   have ineq1: "x * (1 - x) \<le> 1 / 4" if x: "x \<in> {0..1}" for x :: real
   proof -
     have "x * (1 - x) - 1 / 4 = -((x - 1 / 2) ^ 2)"
       by (simp add: algebra_simps power2_eq_square)
     also have "\<dots> \<le> 0"
       by simp
     finally show ?thesis by simp
   qed
 
   have ineq2: "x * (1 - x) ^ 2 \<le> 4 / 27" if x: "x \<in> {0..1}" for x :: real
   proof -
     have "x * (1 - x) ^ 2 - 4 / 27 = (x - 4 / 3) * (x - 1 / 3) ^ 2"
       by (simp add: algebra_simps power2_eq_square)
     also have "\<dots> \<le> 0"
       by (rule mult_nonpos_nonneg) (use x in auto)
     finally show ?thesis by simp
   qed
 
   have "1 - (1-x*y)*z = (1 - z) + x * y * z"
     by (simp add: algebra_simps)
   also have "\<dots> \<ge> 2 * sqrt (1 - z) * sqrt x * sqrt y * sqrt z"
     using arith_geo_mean_sqrt[of "1 - z" "x * y * z"] xyz
     by (auto simp: real_sqrt_mult)
 
   finally have *: "?lhs \<le> (x*(1-x)*y*(1-y)*z*(1-z)) / (2 * sqrt (1 - z) * sqrt x * sqrt y * sqrt z)"
     using xyz beukers_denom_ineq[of x y z]
     by (intro divide_left_mono mult_nonneg_nonneg mult_pos_pos) auto
 
   have "(x*(1-x)*y*(1-y)*z*(1-z)) = (sqrt x * sqrt x * (1-x) * sqrt y * sqrt y *
                (1-y) * sqrt z * sqrt z * sqrt (1-z) * sqrt (1-z))"
     using xyz by simp
   also have "\<dots> / (2 * sqrt (1 - z) * sqrt x * sqrt y * sqrt z) =
                sqrt (x * (1 - x) ^ 2) * sqrt (y * (1 - y) ^ 2) * sqrt (z * (1 - z)) / 2"
     using xyz by (simp add: divide_simps real_sqrt_mult del: real_sqrt_mult_self)
   also have "\<dots> \<le> sqrt (4 / 27) * sqrt (4 / 27) * sqrt (1 / 4) / 2"
     using xyz by (intro divide_right_mono mult_mono real_sqrt_le_mono ineq1 ineq2) auto
   also have "\<dots> = 1 / 27"
     by (simp add: real_sqrt_divide)
   finally show ?thesis using * by argo
 qed
 
 text \<open>
   Connecting the above bound with our results of $I_1$, it is easy to see that
   $I_3 \leq 2 \cdot 27^{-n} \cdot \zeta(3)$:
 \<close>
 lemma beukers_nn_integral3_le:
   "beukers_nn_integral3 \<le> ennreal (2 * (1 / 27) ^ n * Re (zeta 3))"
 proof -
   have D' [measurable]: "D' \<in> sets (borel \<Otimes>\<^sub>M borel \<Otimes>\<^sub>M borel)"
     unfolding D'_def by (simp flip: borel_prod)
   have "beukers_nn_integral3 =
           (\<integral>\<^sup>+(w,x,y)\<in>D'. ((x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1)) \<partial>lborel)"
     by (simp add: beukers_nn_integral3_def)
   also have "\<dots> \<le> (\<integral>\<^sup>+(w,x,y)\<in>D'. ((1 / 27) ^ n / (1-(1-x*y)*w)) \<partial>lborel)"
   proof (intro set_nn_integral_mono ennreal_leI, clarify, goal_cases)
     case (1 w x y)
     have "(x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1) =
             ((x*(1-x)*y*(1-y)*w*(1-w)) / (1-(1-x*y)*w)) ^ n / (1-(1-x*y)*w)"
       by (simp add: divide_simps)
     also have "\<dots> \<le> (1 / 27) ^ n / (1 - (1 - x * y) * w)"
       using beukers_denom_ineq[of x y w] 1
       by (intro divide_right_mono power_mono beukers_integral3_integrand_bound)
          (auto simp: D'_def)
     finally show ?case .
   qed
   also have "\<dots> = ennreal ((1 / 27) ^ n) * (\<integral>\<^sup>+(w,x,y)\<in>D'. (1 / (1-(1-x*y)*w)) \<partial>lborel)"
     unfolding lborel_prod [symmetric] case_prod_unfold
     by (subst nn_integral_cmult [symmetric])
        (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
   also have "(\<integral>\<^sup>+(w,x,y)\<in>D'. (1 / (1-(1-x*y)*w)) \<partial>lborel) =
                (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (- (ln (x * y) / (1 - x * y))) \<partial>lborel)"
     using beukers_nn_integral1_altdef[of 0 0]
     by (simp add: beukers_nn_integral1_def D'_def case_prod_unfold)
   also have "\<dots> = ennreal (2 * Re (zeta 3))"
     using beukers_nn_integral1_same[of 0 0] by (simp add: D_def beukers_nn_integral1_def)
   also have "ennreal ((1 / 27) ^ n) * \<dots> = ennreal (2 * (1 / 27) ^ n * Re (zeta 3))"
     by (subst ennreal_mult' [symmetric]) (simp_all add: mult_ac)
   finally show ?thesis .
 qed
 
 lemma beukers_nn_integral3_finite: "beukers_nn_integral3 < \<infinity>"
   by (rule le_less_trans, rule beukers_nn_integral3_le) simp_all
 
 lemma beukers_integral3_integrable:
   "set_integrable lborel D' (\<lambda>(w,x,y). (x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1))"
   unfolding case_prod_unfold using less_imp_le[OF beukers_denom_ineq] beukers_nn_integral3_finite
   by (intro set_integrableI_nonneg AE_I2 impI)
      (auto simp: D'_def set_borel_measurable_def beukers_nn_integral3_def case_prod_unfold
            simp flip: lborel_prod intro!: divide_nonneg_nonneg mult_nonneg_nonneg)
 
 lemma beukers_integral3_conv_nn_integral:
   "beukers_integral3 = enn2real beukers_nn_integral3"
   unfolding beukers_integral3_def using beukers_nn_integral3_finite less_imp_le[OF beukers_denom_ineq]
   by (intro set_integral_eq_nn_integral AE_I2 impI)
      (auto simp: D'_def set_borel_measurable_def beukers_nn_integral3_def case_prod_unfold
            simp flip: lborel_prod)
 
 lemma beukers_integral3_le: "beukers_integral3 \<le> 2 * (1 / 27) ^ n * Re (zeta 3)"
 proof -
   have "beukers_integral3 = enn2real beukers_nn_integral3"
     by (rule beukers_integral3_conv_nn_integral)
   also have "\<dots> \<le> enn2real (ennreal (2 * (1 / 27) ^ n * Re (zeta 3)))"
     by (intro enn2real_mono beukers_nn_integral3_le) auto
   also have "\<dots> = 2 * (1 / 27) ^ n * Re (zeta 3)"
     using Re_zeta_ge_1[of 3] by (intro enn2real_ennreal mult_nonneg_nonneg) auto
   finally show ?thesis .
 qed
 
 text \<open>
   It is also easy to see that $I_3 > 0$.
 \<close>
 lemma beukers_nn_integral3_pos: "beukers_nn_integral3 > 0"
 proof -
   have D' [measurable]: "D' \<in> sets (borel \<Otimes>\<^sub>M borel \<Otimes>\<^sub>M borel)"
     unfolding D'_def by (simp flip: borel_prod)
 
   have *: "\<not>(AE (w,x,y) in lborel. ennreal ((x*(1-x)*y*(1-y)*w*(1-w))^n /
              (1-(1-x*y)*w)^(n+1)) * indicator D' (w,x,y) \<le> 0)"
             (is "\<not>(AE z in lborel. ?P z)")
   proof -
     {
       fix w x y :: real assume xyw: "(w,x,y) \<in> D'"
       hence "(x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1) > 0"
         using beukers_denom_ineq[of x y w]
         by (intro divide_pos_pos mult_pos_pos zero_less_power) (auto simp: D'_def)
       with xyw have "\<not>?P (w,x,y)"
         by (auto simp: indicator_def D'_def)
     }
     hence *: "\<not>?P z" if "z \<in> D'" for z using that by blast
     hence "{z\<in>space lborel. \<not>?P z} = D'" by auto
     moreover have "emeasure lborel D' = 1"
     proof -
       have "D' = box (0,0,0) (1,1,1)"
         by (auto simp: D'_def box_def Basis_prod_def)
       also have "emeasure lborel \<dots> = 1"
         by (subst emeasure_lborel_box) (auto simp: Basis_prod_def)
       finally show ?thesis by simp
     qed
     ultimately show ?thesis
       by (subst AE_iff_measurable[of D']) (simp_all flip: borel_prod)
   qed
 
   hence "nn_integral lborel (\<lambda>_::real\<times>real\<times>real. 0) < beukers_nn_integral3"
     unfolding beukers_nn_integral3_def
     by (intro nn_integral_less) (simp_all add: case_prod_unfold flip: lborel_prod)
   thus ?thesis by simp
 qed
 
 lemma beukers_integral3_pos: "beukers_integral3 > 0"
 proof -
   have "0 < enn2real beukers_nn_integral3"
     using beukers_nn_integral3_pos beukers_nn_integral3_finite
     by (subst enn2real_positive_iff) auto
   also have "\<dots> = beukers_integral3"
     by (rule beukers_integral3_conv_nn_integral [symmetric])
   finally show ?thesis .
 qed
 
 
 subsection \<open>Connecting the double and triple integral\<close>
 
 text \<open>
   In this section, we will prove the most technically involved part,
   namely that $I_2 = I_3$. I will not go into detail about how this works --
   the reader is advised to simply look at Filaseta's presentation of the proof.
 
   The basic idea is to integrate by parts \<open>n\<close> times with respect to \<open>y\<close> to eliminate
   the factor $P(y)$, then change variables $z = \frac{1-w}{1-(1-xy)w}$, and then
   apply the same integration by parts \<open>n\<close> times to \<open>x\<close> to eliminate $P(x)$.
 \<close>
 
 text \<open>
   The first expand \[-\frac{\ln (xy)}{1-xy} = \int_0^1 \frac{1}{1-(1-xy)z}\,\text{d}z\ .\]
 \<close>
 lemma beukers_aux_ln_conv_integral:
   fixes x y :: real
   assumes xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
   shows "-ln (x*y) / (1-x*y) = (LBINT z=0..1. 1 / (1-(1-x*y)*z))"
 proof -
   have "x * y < 1"
     using mult_strict_mono[of x 1 y 1] xy by simp
   have less: "(1 - x * y) * u < 1" if u: "u \<in> {0..1}" for u
   proof -
     from u \<open>x * y < 1\<close> have "(1 - x * y) * u \<le> (1 - x * y) * 1"
       by (intro mult_left_mono) auto
     also have "\<dots> < 1 * 1"
       using xy by (intro mult_strict_right_mono) auto
     finally show "(1 - x * y) * u < 1" by simp
   qed
   have neq: "(1 - x * y) * u \<noteq> 1" if "u \<in> {0..1}" for u
     using less[of u] that by simp
 
   let ?F = "\<lambda>z. ln (1-(1-x*y)*z)/(x*y-1)"
   have "(LBINT z=ereal 0..ereal 1. 1 / (1-(1-x*y)*z)) = ?F 1 - ?F 0"
   proof (rule interval_integral_FTC_finite, goal_cases cont deriv)
     case cont
     show ?case
       using neq by (intro continuous_intros) auto
   next
     case (deriv z)
     show ?case
       unfolding has_field_derivative_iff_has_vector_derivative [symmetric]
       by (insert less[of z] xy \<open>x * y < 1\<close> deriv)
          (rule derivative_eq_intros refl | simp)+
   qed
   also have "\<dots> = -ln (x*y) / (1-x*y)"
     using \<open>x * y < 1\<close> by (simp add: field_simps)
   finally show ?thesis
     by (simp add: zero_ereal_def one_ereal_def)
 qed
 
 text \<open>
   The first part we shall show is the integration by parts.
 \<close>
 lemma beukers_aux_by_parts_aux:
   assumes xz: "x \<in> {0<..<1}" "z \<in> {0<..<1}" and "k \<le> n"
   shows "(LBINT y=0..1. Q n y * (1/(1-(1-x*y)*z))) =
          (LBINT y=0..1. Q (n-k) y * (fact k * (x*z)^k / (1-(1-x*y)*z) ^ (k+1)))"
   using assms(3)
 proof (induction k)
   case (Suc k)
   note [derivative_intros] = DERIV_chain2[OF has_field_derivative_Gen_Shleg]
   define G where "G = (\<lambda>y. -fact k * (x*z)^k / (1-(1-x*y)*z) ^ (k+1))"
   define g where "g = (\<lambda>y. fact (Suc k) * (x*z)^Suc k / (1-(1-x*y)*z) ^ (k+2))"
 
   have less: "(1 - x * y) * z < 1" and neq: "(1 - x * y) * z \<noteq> 1"
     if y: "y \<in> {0..1}" for y
   proof -
     from y xz have "x * y \<le> x * 1"
       by (intro mult_left_mono) auto
     also have "\<dots> < 1"
       using xz by simp
     finally have "(1 - x * y) * z \<le> 1 * z"
       using xz y by (intro mult_right_mono) auto
     also have "\<dots> < 1"
       using xz by simp
     finally show "(1 - x * y) * z < 1" by simp
     thus "(1 - x * y) * z \<noteq> 1" by simp
   qed
 
   have cont: "continuous_on {0..1} g"
     using neq by (auto simp: g_def intro!: continuous_intros)
   have deriv: "(G has_real_derivative g y) (at y within {0..1})" if y: "y \<in> {0..1}" for y
     unfolding G_def
     by (insert neq xz y, (rule derivative_eq_intros refl power_not_zero)+)
        (auto simp: divide_simps g_def)
   have deriv2: "(Q (n - Suc k) has_real_derivative Q (n - k) y) (at y within {0..1})" for y
     using Suc.prems by (auto intro!: derivative_eq_intros simp: Suc_diff_Suc Q_def)
 
   have "(LBINT y=0..1. Q (n-Suc k) y * (fact (Suc k) * (x*z)^Suc k / (1-(1-x*y)*z) ^ (k+2))) =
         (LBINT y=0..1. Q (n-Suc k) y * g y)"
     by (simp add: g_def)
   also have "(LBINT y=0..1. Q (n-Suc k) y * g y) = -(LBINT y=0..1. Q (n-k) y * G y)"
     using Suc.prems deriv deriv2 cont
     by (subst interval_lebesgue_integral_by_parts_01[where f = "Q (n-k)" and G = G])
        (auto intro!: continuous_intros simp: Q_def)
   also have "\<dots> = (LBINT y=0..1. Q (n-k) y * (fact k * (x*z)^k / (1-(1-x*y)*z) ^ (k+1)))"
     by (simp add: G_def flip: interval_lebesgue_integral_uminus)
   finally show ?case using Suc by simp
 qed auto
 
 lemma beukers_aux_by_parts:
   assumes xz: "x \<in> {0<..<1}" "z \<in> {0<..<1}"
   shows "(LBINT y=0..1. P y / (1-(1-x*y)*z)) =
          (LBINT y=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z) ^ (n+1))"
 proof -
   have "(LBINT y=0..1. P y * (1/(1-(1-x*y)*z))) =
            1 / fact n * (LBINT y=0..1. Q n y * (1/(1-(1-x*y)*z)))"
     unfolding interval_lebesgue_integral_mult_right [symmetric]
     by (simp add: P_def Q_def Shleg_altdef)
   also have "\<dots> = (LBINT y=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z) ^ (n+1))"
     by (subst beukers_aux_by_parts_aux[OF assms, of n], simp,
         subst interval_lebesgue_integral_mult_right [symmetric])
        (simp add: Q_def mult_ac Gen_Shleg_0_left power_mult_distrib)
   finally show ?thesis by simp
 qed
 
 text \<open>
   We then get the following by applying the integration by parts to \<open>y\<close>:
 \<close>
 lemma beukers_aux_integral_transform1:
   fixes z :: real
   assumes z: "z \<in> {0<..<1}"
   shows   "(LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)) =
            (LBINT (x,y):D. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
 proof -
   have cbox: "cbox (0, 0) (1, 1) = ({0..1} \<times> {0..1} :: (real \<times> real) set)"
     by (auto simp: cbox_def Basis_prod_def inner_prod_def)
   have box: "box (0, 0) (1, 1) = ({0<..<1} \<times> {0<..<1} :: (real \<times> real) set)"
     by (auto simp: box_def Basis_prod_def inner_prod_def)
   have "set_integrable lborel (cbox (0,0) (1,1))
           (\<lambda>(x, y). P x * P y / (1 - (1 - x * y) * z))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0, 0) (1, 1)"
     have "(1 - fst p * snd p) * z \<le> 1 * z"
       using mult_mono[of "fst p" 1 "snd p" 1] p z cbox by (intro mult_right_mono) auto
     also have "\<dots> < 1" using z by simp
     finally show "1 - (1 - fst p * snd p) * z \<noteq> 0" by simp
   qed
   hence integrable: "set_integrable lborel (box (0,0) (1,1))
           (\<lambda>(x, y). P x * P y / (1 - (1 - x * y) * z))"
     by (rule set_integrable_subset) (auto simp:  box simp flip: borel_prod)
 
   have "set_integrable lborel (cbox (0,0) (1,1))
           (\<lambda>(x, y). P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0, 0) (1, 1)"
     have "(1 - fst p * snd p) * z \<le> 1 * z"
       using mult_mono[of "fst p" 1 "snd p" 1] p z cbox by (intro mult_right_mono) auto
     also have "\<dots> < 1" using z by simp
     finally show "(1 - (1 - fst p * snd p) * z) ^ (n + 1) \<noteq> 0" by simp
   qed
   hence integrable': "set_integrable lborel D
           (\<lambda>(x, y). P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     by (rule set_integrable_subset) (auto simp: box D_def simp flip: borel_prod)
 
   have "(LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)) =
           (LBINT x=0..1. (LBINT y=0..1. P x * P y / (1-(1-x*y)*z)))"
     unfolding D_def lborel_prod [symmetric] using box integrable
     by (subst lborel_pair.set_integral_fst') (simp_all add: interval_integral_Ioo lborel_prod)
   also have "\<dots> = (LBINT x=0..1. P x * (LBINT y=0..1. P y / (1-(1-x*y)*z)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (simp add: mult_ac)
   also have "\<dots> = (LBINT x=0..1. P x * (LBINT y=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     using z by (intro interval_lebesgue_integral_lborel_01_cong, subst beukers_aux_by_parts) auto
   also have "\<dots> = (LBINT x=0..1. (LBINT y=0..1. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (simp add: mult_ac)
   also have "\<dots> = (LBINT (x,y):D. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     unfolding D_def lborel_prod [symmetric] using box integrable'
     by (subst lborel_pair.set_integral_fst')
        (simp_all add: D_def interval_integral_Ioo lborel_prod)
   finally show "(LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)) = \<dots>" .
 qed
 
 text \<open>
   We then change variables for \<open>z\<close>:
 \<close>
 lemma beukers_aux_integral_transform2:
   assumes xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
   shows "(LBINT z=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
          (LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
 proof -
   define g where "g = (\<lambda>z. (1 - z) / (1-(1-x*y)*z))"
   define g' where "g' = (\<lambda>z. -x*y / (1-(1-x*y)*z)^2)"
   have "x * y < 1"
     using mult_strict_mono[of x 1 y 1] xy by simp
   have less: "(1 - (x * y)) * w < 1" and neq: "(1 - (x * y)) * w \<noteq> 1"
     if w: "w \<in> {0..1}" for w
   proof -
     have "(1 - (x * y)) * w \<le> (1 - (x * y)) * 1"
       using w \<open>x * y < 1\<close> by (intro mult_left_mono) auto
     also have "\<dots> < 1"
       using xy by simp
     finally show "(1 - (x * y)) * w < 1" .
     thus "(1 - (x * y)) * w \<noteq> 1" by simp
   qed
 
   have deriv: "(g has_real_derivative g' w) (at w within {0..1})" if "w \<in> {0..1}" for w
     unfolding g_def g'_def
     apply (insert that xy neq)
     apply (rule derivative_eq_intros refl)+
      apply (simp_all add: divide_simps power2_eq_square)
      apply (auto simp: algebra_simps)
     done
   have "continuous_on {0..1} (\<lambda>xa. (1 - xa) ^ n / (1 - (1 - x * y) * xa))"
     using neq by (auto intro!: continuous_intros)
   moreover have "g ` {0..1} \<subseteq> {0..1}"
   proof clarify
     fix w :: real assume w: "w \<in> {0..1}"
     have "(1 - x * y) * w \<le> 1 * w"
       using \<open>x * y < 1\<close> xy w by (intro mult_right_mono) auto
     thus "g w \<in> {0..1}"
       unfolding g_def using less[of w] w by (auto simp: divide_simps)
   qed
   ultimately have cont: "continuous_on (g ` {0..1}) (\<lambda>xa. (1 - xa) ^ n / (1 - (1 - x * y) * xa))"
     by (rule continuous_on_subset)
   have cont': "continuous_on {0..1} g'"
     using neq by (auto simp: g'_def intro!: continuous_intros)
 
   have "(LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w)) =
           (1-y)^n * (LBINT w=0..1. (1 - w)^n / (1-(1-x*y)*w))"
     unfolding interval_lebesgue_integral_mult_right [symmetric]
     by (simp add: algebra_simps power_mult_distrib)
   also have "(LBINT w=0..1. (1 - w)^n / (1-(1-x*y)*w)) =
         -(LBINT w=g 0..g 1. (1 - w)^n / (1-(1-x*y)*w))"
     by (subst interval_integral_endpoints_reverse)(simp add: g_def zero_ereal_def one_ereal_def)
   also have "(LBINT w=g 0..g 1. (1 - w)^n / (1-(1-x*y)*w)) =
              (LBINT w=0..1. g' w * ((1 - g w) ^ n / (1 - (1-x*y) * g w)))"
     using deriv cont cont'
     by (subst interval_integral_substitution_finite [symmetric, where g = g and g' = g'])
        (simp_all add: zero_ereal_def one_ereal_def)
   also have "-\<dots> = (LBINT z=0..1. ((x*y)^n * z^n / (1-(1-x*y)*z)^(n+1)))"
     unfolding interval_lebesgue_integral_uminus [symmetric] using xy
     apply (intro interval_lebesgue_integral_lborel_01_cong)
     apply (simp add: divide_simps g_def g'_def)
     apply (auto simp: algebra_simps power_mult_distrib power2_eq_square)
     done
   also have "(1-y)^n * \<dots> = (LBINT z=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     unfolding interval_lebesgue_integral_mult_right [symmetric]
     by (simp add: algebra_simps power_mult_distrib)
   finally show "\<dots> = (LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w))" ..
 qed
 
 text \<open>
   Lastly, we apply the same integration by parts to \<open>x\<close>:
 \<close>
 lemma beukers_aux_integral_transform3:
   assumes w: "w \<in> {0<..<1}"
   shows   "(LBINT (x,y):D. P x * (1-y)^n / (1-(1-x*y)*w)) =
            (LBINT (x,y):D. (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
 proof -
   have cbox: "cbox (0, 0) (1, 1) = ({0..1} \<times> {0..1} :: (real \<times> real) set)"
     by (auto simp: cbox_def Basis_prod_def inner_prod_def)
   have box: "box (0, 0) (1, 1) = ({0<..<1} \<times> {0<..<1} :: (real \<times> real) set)"
     by (auto simp: box_def Basis_prod_def inner_prod_def)
 
   have "set_integrable lborel
           (cbox (0,0) (1,1)) (\<lambda>(x,y). P x * (1-y)^n/(1-(1-x*y)*w))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0,0) (1,1)"
     have "(1 - fst p * snd p) * w \<le> 1 * w"
       using p cbox w by (intro mult_right_mono) auto
     also have "\<dots> < 1" using w by simp
     finally have "(1 - fst p * snd p) * w < 1" by simp
     thus "1 - (1 - fst p * snd p) * w \<noteq> 0" by simp
   qed
   hence integrable: "set_integrable lborel D (\<lambda>(x,y). P x * (1-y)^n/(1-(1-x*y)*w))"
     by (rule set_integrable_subset) (auto simp: D_def simp flip: borel_prod)
 
   have "set_integrable lborel (cbox (0,0) (1,1))
           (\<lambda>(x,y). (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0,0) (1,1)"
     have "(1 - fst p * snd p) * w \<le> 1 * w"
       using p cbox w by (intro mult_right_mono) auto
     also have "\<dots> < 1" using w by simp
     finally have "(1 - fst p * snd p) * w < 1" by simp
     thus "(1 - (1 - fst p * snd p) * w) ^ (n + 1) \<noteq> 0" by simp
   qed
   hence integrable': "set_integrable lborel D
                         (\<lambda>(x,y). (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
     by (rule set_integrable_subset) (auto simp: D_def simp flip: borel_prod)
 
   have "(LBINT (x,y):D. P x * (1-y)^n / (1-(1-x*y)*w)) =
           (LBINT y=0..1. (LBINT x=0..1. P x * (1-y)^n / (1-(1-x*y)*w)))"
     using integrable unfolding case_prod_unfold D_def lborel_prod [symmetric]
     by (subst lborel_pair.set_integral_snd) (auto simp: interval_integral_Ioo)
   also have "\<dots> = (LBINT y=0..1. (1-y)^n * (LBINT x=0..1. P x / (1-(1-y*x)*w)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (auto simp: mult_ac)
   also have "\<dots> = (LBINT y=0..1. (1-y)^n * (LBINT x=0..1. (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1)))"
     using w by (intro interval_lebesgue_integral_lborel_01_cong, subst beukers_aux_by_parts) (auto simp: mult_ac)
   also have "\<dots> = (LBINT y=0..1. (LBINT x=0..1.
                      (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (auto simp: mult_ac)
   also have "\<dots> = (LBINT (x,y):D. (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
     using integrable' unfolding case_prod_unfold D_def lborel_prod [symmetric]
     by (subst lborel_pair.set_integral_snd) (auto simp: interval_integral_Ioo)
   finally show ?thesis .
 qed
 
 text \<open>
   We need to show the existence of some of these triple integrals.
 \<close>
 lemma beukers_aux_integrable1:
   "set_integrable lborel (({0<..<1} \<times> {0<..<1}) \<times> {0<..<1})
      (\<lambda>((x,y),z). P x * P y / (1-(1-x*y)*z))"
 proof -
   have D [measurable]: "D \<in> sets (borel \<Otimes>\<^sub>M borel)"
     unfolding D_def by (simp flip: borel_prod)
   have "bounded (P ` {0..1})"
     unfolding P_def by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   show ?thesis unfolding D'_def case_prod_unfold
   proof (subst lborel_prod [symmetric],
          intro lborel_pair.Fubini_set_integrable AE_I2 impI; clarsimp?)
     fix x y :: real
     assume xy: "x > 0" "x < 1" "y > 0" "y < 1"
     have "x * y < 1" using xy mult_strict_mono[of x 1 y 1] by simp
     show "set_integrable lborel {0<..<1} (\<lambda>z. P x * P y / (1-(1-x*y)*z))"
       by (rule set_integrable_subset[of _ "{0..1}"], rule borel_integrable_atLeastAtMost')
          (use \<open>x*y<1\<close> beukers_denom_neq[of x y] xy in \<open>auto intro!: continuous_intros simp: P_def\<close>)
   next
     have "set_integrable lborel D
              (\<lambda>(x,y). (\<integral>z\<in>{0<..<1}. norm (P x * P y / (1-(1-x*y)*z)) \<partial>lborel))"
     proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
       show "set_integrable lborel D (\<lambda>(x,y). C\<^sup>2 * (-ln (x*y) / (1 - x*y)))"
         using beukers_integral1_integrable[of 0 0]
         unfolding case_prod_unfold by (intro set_integrable_mult_right) (auto simp: D_def)
     next
       fix x y assume xy: "(x, y) \<in> D"
       have "norm (LBINT z:{0<..<1}. norm (P x * P y / (1-(1-x*y)*z))) =
               norm (LBINT z:{0<..<1}. \<bar>P x\<bar> * \<bar>P y\<bar> * (1 / (1-(1-x*y)*z)))"
       proof (intro arg_cong[where f = norm] set_lebesgue_integral_cong allI impI, goal_cases)
         case (2 z)
         with beukers_denom_ineq[of x y z] xy show ?case
           by (auto simp: abs_mult D_def)
       qed (auto simp: abs_mult D_def)
       also have "\<dots> = norm (\<bar>P x\<bar> * \<bar>P y\<bar> * (LBINT z=0..1. (1 / (1-(1-x*y)*z))))"
         by (subst set_integral_mult_right) (auto simp: interval_integral_Ioo)
       also have "\<dots> = norm (norm (P x) * norm (P y) * (- ln (x * y) / (1 - x * y)))"
         using beukers_aux_ln_conv_integral[of x y] xy by (simp add: D_def)
       also have "\<dots> = norm (P x) * norm (P y) * (- ln (x * y) / (1 - x * y))"
         using xy mult_strict_mono[of x 1 y 1]
         by (auto simp: D_def divide_nonpos_nonneg abs_mult)
       also have "norm (P x) * norm (P y) * (- ln (x * y) / (1 - x * y)) \<le>
                    norm (C * C * (- ln (x * y) / (1 - x * y)))"
         using xy C[of x] C[of y] mult_strict_mono[of x 1 y 1] unfolding norm_mult norm_divide
         by (intro mult_mono C) (auto simp: D_def divide_nonpos_nonneg)
       finally show "norm (LBINT z:{0<..<1}. norm (P x * P y / (1-(1-x*y)*z)))
            \<le> norm (case (x, y) of (x, y) \<Rightarrow> C\<^sup>2 * (- ln (x * y) / (1 - x * y)))"
         by (simp add: power2_eq_square mult_ac)
     next
       show "set_borel_measurable lborel D (\<lambda>(x, y).
               LBINT z:{0<..<1}. norm (P x * P y / (1 - (1 - x * y) * z)))"
         unfolding lborel_prod [symmetric] set_borel_measurable_def
                   case_prod_unfold set_lebesgue_integral_def P_def
         by measurable
     qed
     thus "set_integrable lborel ({0<..<1} \<times> {0<..<1})
             (\<lambda>x. LBINT y:{0<..<1}. \<bar>P (fst x) * P (snd x)\<bar> / \<bar>1 - (1 - fst x * snd x) * y\<bar>)"
       by (simp add: case_prod_unfold D_def)
   qed (auto simp: case_prod_unfold lborel_prod [symmetric] set_borel_measurable_def P_def)
 qed
 
 lemma beukers_aux_integrable2:
   "set_integrable lborel D' (\<lambda>(z,x,y). P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z) ^ (n+1))"
 proof -
   have [measurable]: "P \<in> borel_measurable borel" unfolding P_def
     by (intro borel_measurable_continuous_onI continuous_intros)
   have "bounded (P ` {0..1})"
     unfolding P_def by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   show ?thesis unfolding D'_def
   proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
     show "set_integrable lborel ({0<..<1} \<times> {0<..<1} \<times> {0<..<1})
             (\<lambda>(z,x,y). C * (1 / (1-(1-x*y)*z)))"
       unfolding case_prod_unfold
       using beukers_integral1_integrable'[of 0 0]
       by (intro set_integrable_mult_right) (auto simp: lborel_prod case_prod_unfold)
   next
     fix x y z :: real assume xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0<..<1}"
     have "norm (P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
             norm (P x) * (1-y)^n * ((x*y*z) / (1-(1-x*y)*z))^n / (1-(1-x*y)*z)"
       using xyz beukers_denom_ineq[of x y z] by (simp add: abs_mult power_divide mult_ac)
     also have "(x*y*z) / (1-(1-x*y)*z) = 1/((1-z)/(z*x*y)+1)"
       using xyz by (simp add: field_simps)
     also have "norm (P x) * (1-y)^n * \<dots>^n / (1-(1-x*y)*z) \<le>
                C * 1^n * 1^n / (1-(1-x*y)*z)"
       using xyz C[of x] beukers_denom_ineq[of x y z]
       by (intro mult_mono divide_right_mono power_mono zero_le_power mult_nonneg_nonneg divide_nonneg_nonneg)
          (auto simp: field_simps)
     also have "\<dots> \<le> \<bar>C * 1^n * 1^n / (1-(1-x*y)*z)\<bar>"
       by linarith
     finally show "norm (P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) \<le>
                     norm (case (z,x,y) of (z,x,y) \<Rightarrow> C * (1 / (1-(1-x*y)*z)))"
       by (simp add: case_prod_unfold)
   qed (simp_all add: case_prod_unfold set_borel_measurable_def flip: borel_prod)
 qed
 
 lemma beukers_aux_integrable3:
   "set_integrable lborel D' (\<lambda>(w,x,y). P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
 proof -
   have [measurable]: "P \<in> borel_measurable borel" unfolding P_def
     by (intro borel_measurable_continuous_onI continuous_intros)
   have "bounded (P ` {0..1})"
     unfolding P_def by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   show ?thesis unfolding D'_def
   proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
     show "set_integrable lborel ({0<..<1} \<times> {0<..<1} \<times> {0<..<1})
             (\<lambda>(z,x,y). C * (1 / (1-(1-x*y)*z)))"
       unfolding case_prod_unfold
       using beukers_integral1_integrable'[of 0 0]
       by (intro set_integrable_mult_right) (auto simp: lborel_prod case_prod_unfold)
   next
     fix x y w :: real assume xyw: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "w \<in> {0<..<1}"
     have "norm (P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)) =
             norm (P x) * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)"
       using xyw beukers_denom_ineq[of x y w] by (simp add: abs_mult power_divide mult_ac)
     also have "\<dots> \<le> C * 1^n * 1^n / (1-(1-x*y)*w)"
       using xyw C[of x] beukers_denom_ineq[of x y w]
       by (intro mult_mono divide_right_mono power_mono zero_le_power mult_nonneg_nonneg divide_nonneg_nonneg)
          (auto simp: field_simps)
     also have "\<dots> \<le> \<bar>C * 1^n * 1^n / (1-(1-x*y)*w)\<bar>"
       by linarith
     finally show "norm (P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)) \<le>
                     norm (case (w,x,y) of (z,x,y) \<Rightarrow> C * (1 / (1-(1-x*y)*z)))"
       by (simp add: case_prod_unfold)
   qed (simp_all add: case_prod_unfold set_borel_measurable_def flip: borel_prod)
 qed
 
 text \<open>
   Now we only need to put all of these results together:
 \<close>
 lemma beukers_integral2_conv_3: "beukers_integral2 = beukers_integral3"
 proof -
   have cont_P: "continuous_on {0..1} P"
     by (auto simp: P_def intro: continuous_intros)
   have D [measurable]: "D \<in> sets borel" "D \<in> sets (borel \<Otimes>\<^sub>M borel)"
     unfolding D_def by (simp_all flip: borel_prod)
   have [measurable]: "P \<in> borel_measurable borel" unfolding P_def
     by (intro borel_measurable_continuous_onI continuous_intros)
 
   have "beukers_integral2 = (LBINT (x,y):D. P x * P y * (LBINT z=0..1. 1 / (1-(1-x*y)*z)))"
     unfolding beukers_integral2_def case_prod_unfold
     by (intro set_lebesgue_integral_cong allI impI, measurable)
        (subst beukers_aux_ln_conv_integral, auto simp: D_def)
   also have "\<dots> = (LBINT (x,y):D. (LBINT z=0..1. P x * P y / (1-(1-x*y)*z)))"
       by (subst interval_lebesgue_integral_mult_right [symmetric]) auto
   also have "\<dots> = (LBINT (x,y):D. (LBINT z:{0<..<1}. P x * P y / (1-(1-x*y)*z)))"
     by (simp add: interval_integral_Ioo)
   also have "\<dots> = (LBINT z:{0<..<1}. (LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)))"
   proof (subst lborel_pair.Fubini_set_integral [symmetric])
     have "set_integrable lborel (({0<..<1} \<times> {0<..<1}) \<times> {0<..<1})
             (\<lambda>((x, y), z). P x * P y / (1 - (1 - x * y) * z))"
       using beukers_aux_integrable1 by simp
     also have "?this \<longleftrightarrow> set_integrable (lborel \<Otimes>\<^sub>M lborel) ({0<..<1} \<times> D)
                            (\<lambda>(z,x,y). P x * P y / (1 - (1 - x * y) * z))"
       unfolding set_integrable_def
       by (subst lborel_pair.integrable_product_swap_iff [symmetric], intro integrable_cong)
          (auto simp: indicator_def case_prod_unfold lborel_prod D_def)
     finally show \<dots> .
   qed (auto simp: case_prod_unfold)
   also have "\<dots> = (LBINT z:{0<..<1}. (LBINT (x,y):D. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     by (rule set_lebesgue_integral_cong) (use beukers_aux_integral_transform1 in simp_all)
   also have "\<dots> = (LBINT (x,y):D. (LBINT z:{0<..<1}. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     using beukers_aux_integrable2
     by (subst lborel_pair.Fubini_set_integral [symmetric])
        (auto simp: case_prod_unfold lborel_prod D_def D'_def)
   also have "\<dots> = (LBINT (x,y):D. (LBINT w:{0<..<1}. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)))"
   proof (intro set_lebesgue_integral_cong allI impI; clarify?)
     fix x y :: real
     assume xy: "(x, y) \<in> D"
     have "(LBINT z:{0<..<1}. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
             P x * (LBINT z=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
       by (subst interval_lebesgue_integral_mult_right [symmetric])
          (simp add: mult_ac interval_integral_Ioo)
     also have "\<dots> = P x * (LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
       using xy by (subst beukers_aux_integral_transform2) (auto simp: D_def)
     also have "\<dots> = (LBINT w:{0<..<1}. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
       by (subst interval_lebesgue_integral_mult_right [symmetric])
          (simp add: mult_ac interval_integral_Ioo)
     finally show "(LBINT z:{0<..<1}. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
                     (LBINT w:{0<..<1}. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w))" .
   qed (auto simp: D_def simp flip: borel_prod)
   also have "\<dots> = (LBINT w:{0<..<1}. (LBINT (x,y):D. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)))"
     using beukers_aux_integrable3
     by (subst lborel_pair.Fubini_set_integral [symmetric])
        (auto simp: case_prod_unfold lborel_prod D_def D'_def)
   also have "\<dots> = (LBINT w=0..1. (1-w)^n * (LBINT (x,y):D. P x * (1-y)^n / (1-(1-x*y)*w)))"
     unfolding case_prod_unfold
     by (subst set_integral_mult_right [symmetric]) (simp add: mult_ac interval_integral_Ioo)
   also have "\<dots> = (LBINT w=0..1. (1-w)^n * (LBINT (x,y):D. (x*y*w*(1-x)*(1-y))^n / (1-(1-x*y)*w)^(n+1)))"
     by (intro interval_lebesgue_integral_lborel_01_cong, subst beukers_aux_integral_transform3)
        (auto simp: mult_ac power_mult_distrib)
   also have "\<dots> = (LBINT w=0..1. (LBINT (x,y):D. (x*y*w*(1-x)*(1-y)*(1-w))^n / (1-(1-x*y)*w)^(n+1)))"
     by (subst set_integral_mult_right [symmetric])
        (auto simp: case_prod_unfold mult_ac power_mult_distrib)
   also have "\<dots> = beukers_integral3"
     using beukers_integral3_integrable unfolding D'_def D_def beukers_integral3_def
     by (subst (2) lborel_prod [symmetric], subst lborel_pair.set_integral_fst')
        (auto simp: case_prod_unfold interval_integral_Ioo lborel_prod algebra_simps)
   finally show ?thesis .
 qed
 
 
 subsection \<open>The main result\<close>
 
 text \<open>
   Combining all of the results so far, we can derive the key inequalities
   \[0 < A\zeta(3) + B < 2 \zeta(3) \cdot 27^{-n} \cdot \text{lcm}\{1\ldots n\}^3\]
   for integers $A$, $B$ with $A > 0$.
 \<close>
 lemma zeta_3_linear_combination_bounds:
   obtains A B :: int
   where "A > 0"
         "A * Re (zeta 3) + B \<in> {0 <.. 2 * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n}"
 proof -
   define I where "I = beukers_integral2"
   define d where "d = Lcm {1..n} ^ 3"
   have "d > 0" by (auto simp: d_def intro!: Nat.gr0I)
   from beukers_integral2_conv_int_combination obtain A' B :: int
     where *: "A' > 0" "I = A' * Re (zeta 3) + B / d" unfolding I_def d_def .
   define A where "A = A' * d"
   from * have A: "A > 0" "I = (A * Re (zeta 3) + B) / d"
     using \<open>d > 0\<close> by (simp_all add: A_def field_simps)
 
   have "0 < I"
     using beukers_integral3_pos by (simp add: I_def beukers_integral2_conv_3)
   with \<open>d > 0\<close> have "A * Re (zeta 3) + B > 0"
     by (simp add: field_simps A)
 
   moreover have "I \<le> 2 * (1 / 27) ^ n * Re (zeta 3)"
     using beukers_integral2_conv_3 beukers_integral3_le by (simp add: I_def)
   hence "A * Re (zeta 3) + B \<le> 2 * Re (zeta 3) * d / 27 ^ n"
     using \<open>d > 0\<close> by (simp add: A field_simps)
 
   ultimately show ?thesis
     using A by (intro that[of A B]) (auto simp: d_def)
 qed
 
 text \<open>
   If $\zeta(3) = \frac{a}{b}$ for some integers $a$ and $b$, we can thus derive
   the inequality $2b\zeta(3) \cdot 27^{-n} \cdot \text{lcm}\{1\ldots n\}^3\geq 1$ for any
   natural number $n$.
 \<close>
 lemma beukers_key_inequality:
   fixes a :: int and b :: nat
   assumes "b > 0" and ab: "Re (zeta 3) = a / b"
   shows   "2 * b * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n \<ge> 1"
 proof -
   from zeta_3_linear_combination_bounds obtain A B :: int
     where AB: "A > 0"
               "A * Re (zeta 3) + B \<in> {0 <.. 2 * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n}" .
   from AB have "0 < (A * Re (zeta 3) + B) * b"
     using \<open>b > 0\<close> by (intro mult_pos_pos) auto
   also have "\<dots> = A * (Re (zeta 3) * b) + B * b"
     using \<open>b > 0\<close> by (simp add: algebra_simps)
   also have "Re (zeta 3) * b = a"
     using \<open>b > 0\<close> by (simp add: ab)
   also have "of_int A * of_int a + of_int (B * b) = of_int (A * a + B * b)"
     by simp
   finally have "1 \<le> A * a + B * b"
     by linarith
   hence "1 \<le> real_of_int (A * a + B * b)"
     by linarith
   also have "\<dots> = (A * (a / b) + B) * b"
     using \<open>b > 0\<close> by (simp add: ring_distribs)
   also have "a / b = Re (zeta 3)"
     by (simp add: ab)
   also have "A * Re (zeta 3) + B \<le> 2 * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n"
     using AB by simp
   finally show "2 * b * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n \<ge> 1"
     using \<open>b > 0\<close> by (simp add: mult_ac)
 qed
 
 end
 
 (* TODO: Move *)
 lemma smallo_power: "n > 0 \<Longrightarrow> f \<in> o[F](g) \<Longrightarrow> (\<lambda>x. f x ^ n) \<in> o[F](\<lambda>x. g x ^ n)"
   by (induction n rule: nat_induct_non_zero) (auto intro: landau_o.small.mult)
 
 text \<open>
   This is now a contradiction, since $\text{lcm}\{1\ldots n\} \in o(3^n)$ by the
   Prime Number Theorem -- hence the main result.
 \<close>
 theorem zeta_3_irrational: "zeta 3 \<notin> \<rat>"
 proof
   assume "zeta 3 \<in> \<rat>"
   obtain a :: int and b :: nat where "b > 0" and ab': "zeta 3 = a / b"
   proof -
     from \<open>zeta 3 \<in> \<rat>\<close> obtain r where r: "zeta 3 = of_rat r"
       by (elim Rats_cases)
     also have "r = rat_of_int (fst (quotient_of r)) / rat_of_int (snd (quotient_of r))"
       by (intro quotient_of_div) auto
     also have "of_rat \<dots> = (of_int (fst (quotient_of r)) / of_int (snd (quotient_of r)) :: complex)"
       by (simp add: of_rat_divide)
     also have "of_int (snd (quotient_of r)) = of_nat (nat (snd (quotient_of r)))"
       using quotient_of_denom_pos'[of r] by auto
     finally have "zeta 3 = of_int (fst (quotient_of r)) / of_nat (nat (snd (quotient_of r)))" .
     thus ?thesis
       using quotient_of_denom_pos'[of r]
       by (intro that[of "nat (snd (quotient_of r))" "fst (quotient_of r)"]) auto
   qed
   hence ab: "Re (zeta 3) = a / b" by simp
 
   interpret prime_number_theorem
     by standard (rule prime_number_theorem)
 
   have Lcm_upto_smallo: "(\<lambda>n. real (Lcm {1..n})) \<in> o(\<lambda>n. c ^ n)" if c: "c > exp 1" for c
   proof -
     have "0 < exp (1::real)" by simp
     also note c
     finally have "c > 0" .
     have "(\<lambda>n. real (Lcm {1..n})) = (\<lambda>n. real (Lcm {1..nat \<lfloor>real n\<rfloor>}))"
       by simp
     also have "\<dots> \<in> o(\<lambda>n. c powr real n)"
       using Lcm_upto.smallo'
       by (rule landau_o.small.compose) (simp_all add: c filterlim_real_sequentially)
     also have "(\<lambda>n. c powr real n) = (\<lambda>n. c ^ n)"
       using c \<open>c > 0\<close> by (subst powr_realpow) auto
     finally show ?thesis .
   qed
 
   have "(\<lambda>n. 2 * b * Re (zeta 3) * real (Lcm {1..n}) ^ 3 / 27 ^ n) \<in>
           O(\<lambda>n. real (Lcm {1..n}) ^ 3 / 27 ^ n)"
     using \<open>b > 0\<close> Re_zeta_ge_1[of 3] by simp
   also have "exp 1 < (3 :: real)"
     using e_approx_32 by (simp add: abs_if split: if_splits)
   hence "(\<lambda>n. real (Lcm {1..n}) ^ 3 / 27 ^ n) \<in> o(\<lambda>n. (3 ^ n) ^ 3 / 27 ^ n)"
     unfolding of_nat_power
     by (intro landau_o.small.divide_right smallo_power Lcm_upto_smallo) auto
   also have "(\<lambda>n. (3 ^ n) ^ 3 / 27 ^ n :: real) = (\<lambda>_. 1)"
     by (simp add: power_mult [of 3, symmetric] mult.commute[of _ 3] power_mult[of _ 3])
   finally have *: "(\<lambda>n. 2 * b * Re (zeta 3) * real (Lcm {1..n}) ^ 3 / 27 ^ n) \<in> o(\<lambda>_. 1)" .
   have lim: "(\<lambda>n. 2 * b * Re (zeta 3) * real (Lcm {1..n}) ^ 3 / 27 ^ n) \<longlonglongrightarrow> 0"
     using smalloD_tendsto[OF *] by simp
 
   moreover have "1 \<le> real (2 * b) * Re (zeta 3) * real (Lcm {1..n} ^ 3) / 27 ^ n" for n
     using beukers_key_inequality[of b a] ab \<open>b > 0\<close> by simp
 
   ultimately have "1 \<le> (0 :: real)"
     by (intro tendsto_lowerbound[OF lim] always_eventually allI) auto
   thus False by simp
 qed
 
 end
\ No newline at end of file
diff --git a/thys/Zeta_Function/Zeta_Library.thy b/thys/Zeta_Function/Zeta_Library.thy
--- a/thys/Zeta_Function/Zeta_Library.thy
+++ b/thys/Zeta_Function/Zeta_Library.thy
@@ -1,897 +1,898 @@
 section \<open>Various preliminary material\<close>
 theory Zeta_Library
 imports
   "HOL-Complex_Analysis.Complex_Analysis"
   "HOL-Real_Asymp.Real_Asymp"
   "Dirichlet_Series.Dirichlet_Series_Analysis"
 begin
 
 subsection \<open>Facts about limits\<close>
 
 lemma at_within_altdef:
   "at x within A = (INF S\<in>{S. open S \<and> x \<in> S}. principal (S \<inter> (A - {x})))"
   unfolding at_within_def nhds_def inf_principal [symmetric]
     by (subst INF_inf_distrib [symmetric]) (auto simp: INF_constant)
 
 lemma tendsto_at_left_realI_sequentially:
   fixes f :: "real \<Rightarrow> 'b::first_countable_topology"
   assumes *: "\<And>X. filterlim X (at_left c) sequentially \<Longrightarrow> (\<lambda>n. f (X n)) \<longlonglongrightarrow> y"
   shows "(f \<longlongrightarrow> y) (at_left c)"
 proof -
   obtain A where A: "decseq A" "open (A n)" "y \<in> A n" "nhds y = (INF n. principal (A n))" for n
     by (rule nhds_countable[of y]) (rule that)
 
   have "\<forall>m. \<exists>d<c. \<forall>x\<in>{d<..<c}. f x \<in> A m"
   proof (rule ccontr)
     assume "\<not> (\<forall>m. \<exists>d<c. \<forall>x\<in>{d<..<c}. f x \<in> A m)"
     then obtain m where **: "\<And>d. d < c \<Longrightarrow> \<exists>x\<in>{d<..<c}. f x \<notin> A m"
       by auto
     have "\<exists>X. \<forall>n. (f (X n) \<notin> A m \<and> X n < c) \<and> X (Suc n) > c - max 0 ((c - X n) / 2)"
     proof (intro dependent_nat_choice, goal_cases)
       case 1
       from **[of "c - 1"] show ?case by auto
     next
       case (2 x n)
       with **[of "c - max 0 (c - x) / 2"] show ?case by force
     qed
     then obtain X where X: "\<And>n. f (X n) \<notin> A m" "\<And>n. X n < c" "\<And>n. X (Suc n) > c - max 0 ((c - X n) / 2)"
       by auto
     have X_ge: "X n \<ge> c - (c - X 0) / 2 ^ n" for n
     proof (induction n)
       case (Suc n)
       have "c - (c - X 0) / 2 ^ Suc n = c - (c - (c - (c - X 0) / 2 ^ n)) / 2"
         by simp
       also have "c - (c - (c - (c - X 0) / 2 ^ n)) / 2 \<le> c - (c - X n) / 2"
         by (intro diff_left_mono divide_right_mono Suc diff_right_mono) auto
       also have "\<dots> = c - max 0 ((c - X n) / 2)"
         using X[of n] by (simp add: max_def)
       also have "\<dots> < X (Suc n)"
         using X[of n] by simp
       finally show ?case by linarith
     qed auto
 
     have "X \<longlonglongrightarrow> c"
     proof (rule tendsto_sandwich)
       show "eventually (\<lambda>n. X n \<le> c) sequentially"
         using X by (intro always_eventually) (auto intro!: less_imp_le)
       show "eventually (\<lambda>n. X n \<ge> c - (c - X 0) / 2 ^ n) sequentially"
         using X_ge by (intro always_eventually) auto
     qed real_asymp+
     hence "filterlim X (at_left c) sequentially"
       by (rule tendsto_imp_filterlim_at_left)
          (use X in \<open>auto intro!: always_eventually less_imp_le\<close>)
     from topological_tendstoD[OF *[OF this] A(2, 3), of m] X(1) show False
       by auto
   qed
 
   then obtain d where d: "d m < c" "x \<in> {d m<..<c} \<Longrightarrow> f x \<in> A m" for m x
     by metis
   have ***: "at_left c = (INF S\<in>{S. open S \<and> c \<in> S}. principal (S \<inter> {..<c}))"
     by (simp add: at_within_altdef)
   from d show ?thesis
     unfolding *** A using A(1,2) by (intro filterlim_base[of _ "\<lambda>m. {d m<..}"]) auto
 qed
 
 lemma
   shows at_right_PInf [simp]: "at_right (\<infinity> :: ereal) = bot"
     and at_left_MInf [simp]: "at_left (-\<infinity> :: ereal) = bot"
 proof -
   have "{(\<infinity>::ereal)<..} = {}" "{..<-(\<infinity>::ereal)} = {}"
     by auto
   thus "at_right (\<infinity> :: ereal) = bot" "at_left (-\<infinity> :: ereal) = bot"
     by (simp_all add: at_within_def)
 qed
 
 lemma tendsto_at_left_erealI_sequentially:
   fixes f :: "ereal \<Rightarrow> 'b::first_countable_topology"
   assumes *: "\<And>X. filterlim X (at_left c) sequentially \<Longrightarrow> (\<lambda>n. f (X n)) \<longlonglongrightarrow> y"
   shows "(f \<longlongrightarrow> y) (at_left c)"
 proof (cases c)
   case [simp]: PInf
   have "((\<lambda>x. f (ereal x)) \<longlongrightarrow> y) at_top" using assms
     by (intro tendsto_at_topI_sequentially assms)
        (simp_all flip: ereal_tendsto_simps add: o_def filterlim_at)
   thus ?thesis
     by (simp add: at_left_PInf filterlim_filtermap)
 next
   case [simp]: MInf
   thus ?thesis by auto
 next
   case [simp]: (real c')
   have "((\<lambda>x. f (ereal x)) \<longlongrightarrow> y) (at_left c')"
   proof (intro tendsto_at_left_realI_sequentially assms)
     fix X assume *: "filterlim X (at_left c') sequentially"
     show "filterlim (\<lambda>n. ereal (X n)) (at_left c) sequentially"
       by (rule filterlim_compose[OF _ *])
          (simp add: sequentially_imp_eventually_within tendsto_imp_filterlim_at_left)
   qed
   thus ?thesis
     by (simp add: at_left_ereal filterlim_filtermap)
 qed
 
 lemma tendsto_at_right_realI_sequentially:
   fixes f :: "real \<Rightarrow> 'b::first_countable_topology"
   assumes *: "\<And>X. filterlim X (at_right c) sequentially \<Longrightarrow> (\<lambda>n. f (X n)) \<longlonglongrightarrow> y"
   shows "(f \<longlongrightarrow> y) (at_right c)"
 proof -
   obtain A where A: "decseq A" "open (A n)" "y \<in> A n" "nhds y = (INF n. principal (A n))" for n
     by (rule nhds_countable[of y]) (rule that)
 
   have "\<forall>m. \<exists>d>c. \<forall>x\<in>{c<..<d}. f x \<in> A m"
   proof (rule ccontr)
     assume "\<not> (\<forall>m. \<exists>d>c. \<forall>x\<in>{c<..<d}. f x \<in> A m)"
     then obtain m where **: "\<And>d. d > c \<Longrightarrow> \<exists>x\<in>{c<..<d}. f x \<notin> A m"
       by auto
     have "\<exists>X. \<forall>n. (f (X n) \<notin> A m \<and> X n > c) \<and> X (Suc n) < c + max 0 ((X n - c) / 2)"
     proof (intro dependent_nat_choice, goal_cases)
       case 1
       from **[of "c + 1"] show ?case by auto
     next
       case (2 x n)
       with **[of "c + max 0 (x - c) / 2"] show ?case by force
     qed
     then obtain X where X: "\<And>n. f (X n) \<notin> A m" "\<And>n. X n > c" "\<And>n. X (Suc n) < c + max 0 ((X n - c) / 2)"
       by auto
     have X_le: "X n \<le> c + (X 0 - c) / 2 ^ n" for n
     proof (induction n)
       case (Suc n)
       have "X (Suc n) < c + max 0 ((X n - c) / 2)"
         by (intro X) 
       also have "\<dots> = c + (X n - c) / 2"
         using X[of n] by (simp add: field_simps max_def)
       also have "\<dots> \<le> c + (c + (X 0 - c) / 2 ^ n - c) / 2"
         by (intro add_left_mono divide_right_mono Suc diff_right_mono) auto
       also have "\<dots> = c + (X 0 - c) / 2 ^ Suc n"
         by simp
       finally show ?case by linarith
     qed auto
 
     have "X \<longlonglongrightarrow> c"
     proof (rule tendsto_sandwich)
       show "eventually (\<lambda>n. X n \<ge> c) sequentially"
         using X by (intro always_eventually) (auto intro!: less_imp_le)
       show "eventually (\<lambda>n. X n \<le> c + (X 0 - c) / 2 ^ n) sequentially"
         using X_le by (intro always_eventually) auto
     qed real_asymp+
     hence "filterlim X (at_right c) sequentially"
       by (rule tendsto_imp_filterlim_at_right)
          (use X in \<open>auto intro!: always_eventually less_imp_le\<close>)
     from topological_tendstoD[OF *[OF this] A(2, 3), of m] X(1) show False
       by auto
   qed
 
   then obtain d where d: "d m > c" "x \<in> {c<..<d m} \<Longrightarrow> f x \<in> A m" for m x
     by metis
   have ***: "at_right c = (INF S\<in>{S. open S \<and> c \<in> S}. principal (S \<inter> {c<..}))"
     by (simp add: at_within_altdef)
   from d show ?thesis
     unfolding *** A using A(1,2) by (intro filterlim_base[of _ "\<lambda>m. {..<d m}"]) auto
 qed
 
 lemma tendsto_at_right_erealI_sequentially:
   fixes f :: "ereal \<Rightarrow> 'b::first_countable_topology"
   assumes *: "\<And>X. filterlim X (at_right c) sequentially \<Longrightarrow> (\<lambda>n. f (X n)) \<longlonglongrightarrow> y"
   shows "(f \<longlongrightarrow> y) (at_right c)"
 proof (cases c)
   case [simp]: MInf
   have "((\<lambda>x. f (-ereal x)) \<longlongrightarrow> y) at_top" using assms
    by (intro tendsto_at_topI_sequentially assms)
       (simp_all flip: uminus_ereal.simps ereal_tendsto_simps add: o_def filterlim_at)
   thus ?thesis
     by (simp add: at_right_MInf filterlim_filtermap at_top_mirror)
 next
   case [simp]: PInf
   thus ?thesis by auto
 next
   case [simp]: (real c')
   have "((\<lambda>x. f (ereal x)) \<longlongrightarrow> y) (at_right c')"
   proof (intro tendsto_at_right_realI_sequentially assms)
     fix X assume *: "filterlim X (at_right c') sequentially"
     show "filterlim (\<lambda>n. ereal (X n)) (at_right c) sequentially"
       by (rule filterlim_compose[OF _ *])
          (simp add: sequentially_imp_eventually_within tendsto_imp_filterlim_at_right)
   qed
   thus ?thesis
     by (simp add: at_right_ereal filterlim_filtermap)
 qed
 
 proposition analytic_continuation':
   assumes hol: "f holomorphic_on S" "g holomorphic_on S"
       and "open S" and "connected S"
       and "U \<subseteq> S" and "\<xi> \<in> S"
       and "\<xi> islimpt U"
       and fU0 [simp]: "\<And>z. z \<in> U \<Longrightarrow> f z = g z"
       and "w \<in> S"
     shows "f w = g w"
   using analytic_continuation[OF holomorphic_on_diff[OF hol] assms(3-7) _ assms(9)] assms(8)
   by simp
 
 
 subsection \<open>Various facts about integrals\<close>
 
 lemma continuous_on_imp_set_integrable_cbox:
   fixes h :: "'a :: euclidean_space \<Rightarrow> 'b :: euclidean_space"
   assumes "continuous_on (cbox a b) h"
   shows   "set_integrable lborel (cbox a b) h"
 proof -
   from assms have "h absolutely_integrable_on cbox a b"
     by (rule absolutely_integrable_continuous)
   moreover have "(\<lambda>x. indicat_real (cbox a b) x *\<^sub>R h x) \<in> borel_measurable borel"
     by (rule borel_measurable_continuous_on_indicator) (use assms in auto)
   ultimately show ?thesis
     unfolding set_integrable_def using assms by (subst (asm) integrable_completion) auto
 qed
 
 lemma set_nn_integral_cong:
   assumes "M = M'" "A = B" "\<And>x. x \<in> space M \<inter> A \<Longrightarrow> f x = g x"
   shows   "set_nn_integral M A f = set_nn_integral M' B g"
   using assms unfolding assms(1,2) by (intro nn_integral_cong) (auto simp: indicator_def)
 
 lemma set_integrable_bound:
   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
     and g :: "'a \<Rightarrow> 'c::{banach, second_countable_topology}"
   assumes "set_integrable M A f" "set_borel_measurable M A g"
   assumes "AE x in M. x \<in> A \<longrightarrow> norm (g x) \<le> norm (f x)"
   shows   "set_integrable M A g"
   unfolding set_integrable_def
 proof (rule Bochner_Integration.integrable_bound)
   from assms(1) show "integrable M (\<lambda>x. indicator A x *\<^sub>R f x)"
     by (simp add: set_integrable_def)
   from assms(2) show "(\<lambda>x. indicat_real A x *\<^sub>R g x) \<in> borel_measurable M"
     by (simp add: set_borel_measurable_def)
   from assms(3) show "AE x in M. norm (indicat_real A x *\<^sub>R g x) \<le> norm (indicat_real A x *\<^sub>R f x)"
     by eventually_elim (simp add: indicator_def)
 qed
 
 (* TODO replace version in library. Better name? *)
 lemma nn_integral_has_integral_lebesgue:
   fixes f :: "'a::euclidean_space \<Rightarrow> real"
   assumes nonneg: "\<And>x. x \<in> \<Omega> \<Longrightarrow> 0 \<le> f x" and I: "(f has_integral I) \<Omega>"
   shows "integral\<^sup>N lborel (\<lambda>x. indicator \<Omega> x * f x) = I"
 proof -
   from I have "(\<lambda>x. indicator \<Omega> x *\<^sub>R f x) \<in> lebesgue \<rightarrow>\<^sub>M borel"
     by (rule has_integral_implies_lebesgue_measurable)
   then obtain f' :: "'a \<Rightarrow> real"
     where [measurable]: "f' \<in> borel \<rightarrow>\<^sub>M borel" and eq: "AE x in lborel. indicator \<Omega> x * f x = f' x"
     by (auto dest: completion_ex_borel_measurable_real)
 
   from I have "((\<lambda>x. abs (indicator \<Omega> x * f x)) has_integral I) UNIV"
-    using nonneg by (simp add: indicator_def if_distrib[of "\<lambda>x. x * f y" for y] cong: if_cong)
+    using nonneg by (simp add: indicator_def of_bool_def if_distrib[of "\<lambda>x. x * f y" for y] cong: if_cong)
   also have "((\<lambda>x. abs (indicator \<Omega> x * f x)) has_integral I) UNIV \<longleftrightarrow> ((\<lambda>x. abs (f' x)) has_integral I) UNIV"
     using eq by (intro has_integral_AE) auto
   finally have "integral\<^sup>N lborel (\<lambda>x. abs (f' x)) = I"
     by (rule nn_integral_has_integral_lborel[rotated 2]) auto
   also have "integral\<^sup>N lborel (\<lambda>x. abs (f' x)) = integral\<^sup>N lborel (\<lambda>x. abs (indicator \<Omega> x * f x))"
     using eq by (intro nn_integral_cong_AE) auto
   also have "(\<lambda>x. abs (indicator \<Omega> x * f x)) = (\<lambda>x. indicator \<Omega> x * f x)"
     using nonneg by (auto simp: indicator_def fun_eq_iff)
   finally show ?thesis .
 qed
 
 
 subsection \<open>Uniform convergence of integrals\<close>
 
 lemma has_absolute_integral_change_of_variables_1':
   fixes f :: "real \<Rightarrow> real" and g :: "real \<Rightarrow> real"
   assumes S: "S \<in> sets lebesgue"
     and der_g: "\<And>x. x \<in> S \<Longrightarrow> (g has_field_derivative g' x) (at x within S)"
     and inj: "inj_on g S"
   shows "(\<lambda>x. \<bar>g' x\<bar> *\<^sub>R f(g x)) absolutely_integrable_on S \<and>
            integral S (\<lambda>x. \<bar>g' x\<bar> *\<^sub>R f(g x)) = b
      \<longleftrightarrow> f absolutely_integrable_on (g ` S) \<and> integral (g ` S) f = b"
 proof -
   have "(\<lambda>x. \<bar>g' x\<bar> *\<^sub>R vec (f(g x)) :: real ^ 1) absolutely_integrable_on S \<and>
            integral S (\<lambda>x. \<bar>g' x\<bar> *\<^sub>R vec (f(g x))) = (vec b :: real ^ 1)
          \<longleftrightarrow> (\<lambda>x. vec (f x) :: real ^ 1) absolutely_integrable_on (g ` S) \<and>
            integral (g ` S) (\<lambda>x. vec (f x)) = (vec b :: real ^ 1)"
     using assms unfolding has_field_derivative_iff_has_vector_derivative
     by (intro has_absolute_integral_change_of_variables_1 assms) auto
   thus ?thesis
     by (simp add: absolutely_integrable_on_1_iff integral_on_1_eq)
 qed
 
 lemma set_nn_integral_lborel_eq_integral:
   fixes f::"'a::euclidean_space \<Rightarrow> real"
   assumes "set_borel_measurable borel A f"
   assumes "\<And>x. x \<in> A \<Longrightarrow> 0 \<le> f x" "(\<integral>\<^sup>+x\<in>A. f x \<partial>lborel) < \<infinity>"
   shows "(\<integral>\<^sup>+x\<in>A. f x \<partial>lborel) = integral A f"
 proof -
   have eq: "(\<integral>\<^sup>+x\<in>A. f x \<partial>lborel) = (\<integral>\<^sup>+x. ennreal (indicator A x * f x) \<partial>lborel)"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = integral UNIV (\<lambda>x. indicator A x * f x)"
     using assms eq by (intro nn_integral_lborel_eq_integral)
                       (auto simp: indicator_def set_borel_measurable_def)
   also have "integral UNIV (\<lambda>x. indicator A x * f x) = integral A (\<lambda>x. indicator A x * f x)"
-    by (rule integral_spike_set) (auto simp: indicator_def)
+    by (rule integral_spike_set) (auto intro: empty_imp_negligible)
+ 
   also have "\<dots> = integral A f"
     by (rule integral_cong) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 lemma nn_integral_has_integral_lebesgue':
   fixes f :: "'a::euclidean_space \<Rightarrow> real"
   assumes nonneg: "\<And>x. x \<in> \<Omega> \<Longrightarrow> 0 \<le> f x" and I: "(f has_integral I) \<Omega>"
   shows "integral\<^sup>N lborel (\<lambda>x. ennreal (f x) * indicator \<Omega> x) = ennreal I"
 proof -
   have "integral\<^sup>N lborel (\<lambda>x. ennreal (f x) * indicator \<Omega> x) =
         integral\<^sup>N lborel (\<lambda>x. ennreal (indicator \<Omega> x * f x))"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = ennreal I"
     using assms by (intro nn_integral_has_integral_lebesgue)
   finally show ?thesis .
 qed
 
 lemma uniform_limit_set_lebesgue_integral:
   fixes f :: "'a \<Rightarrow> 'b :: euclidean_space \<Rightarrow> 'c :: {banach, second_countable_topology}"
   assumes "set_integrable lborel X' g"
   assumes [measurable]: "X' \<in> sets borel"
   assumes [measurable]: "\<And>y. y \<in> Y \<Longrightarrow> set_borel_measurable borel X' (f y)"
   assumes "\<And>y. y \<in> Y \<Longrightarrow> (AE t\<in>X' in lborel. norm (f y t) \<le> g t)"
   assumes "eventually (\<lambda>x. X x \<in> sets borel \<and> X x \<subseteq> X') F"
   assumes "filterlim (\<lambda>x. set_lebesgue_integral lborel (X x) g)
              (nhds (set_lebesgue_integral lborel X' g)) F"
   shows "uniform_limit Y
            (\<lambda>x y. set_lebesgue_integral lborel (X x) (f y))
            (\<lambda>y. set_lebesgue_integral lborel X' (f y)) F"
 proof (rule uniform_limitI, goal_cases)
   case (1 \<epsilon>)
   have integrable_g: "set_integrable lborel U g"
     if "U \<in> sets borel" "U \<subseteq> X'" for U
     by (rule set_integrable_subset[OF assms(1)]) (use that in auto)
   have "eventually (\<lambda>x. dist (set_lebesgue_integral lborel (X x) g)
                              (set_lebesgue_integral lborel X' g) < \<epsilon>) F"
     using \<open>\<epsilon> > 0\<close> assms by (auto simp: tendsto_iff)
   from this show ?case using \<open>eventually (\<lambda>_. _ \<and> _) F\<close>
   proof eventually_elim
     case (elim x)
     hence [measurable]:"X x \<in> sets borel" and "X x \<subseteq> X'" by auto
     have integrable: "set_integrable lborel U (f y)"
       if "y \<in> Y" "U \<in> sets borel" "U \<subseteq> X'" for y U
       apply (rule set_integrable_subset)
         apply (rule set_integrable_bound[OF assms(1)])
          apply (use assms(3) that in \<open>simp add: set_borel_measurable_def\<close>)
       using assms(4)[OF \<open>y \<in> Y\<close>] apply eventually_elim apply force
       using that apply simp_all
       done
     show ?case
     proof
       fix y assume "y \<in> Y"
       have "dist (set_lebesgue_integral lborel (X x) (f y))
                  (set_lebesgue_integral lborel X' (f y)) =
             norm (set_lebesgue_integral lborel X' (f y) -
                   set_lebesgue_integral lborel (X x) (f y))"
         by (simp add: dist_norm norm_minus_commute)
       also have "set_lebesgue_integral lborel X' (f y) -
                     set_lebesgue_integral lborel (X x) (f y) =
                  set_lebesgue_integral lborel (X' - X x) (f y)"
         unfolding set_lebesgue_integral_def
         apply (subst Bochner_Integration.integral_diff [symmetric])
         unfolding set_integrable_def [symmetric]
           apply (rule integrable; (fact | simp))
          apply (rule integrable; fact)
         apply (intro Bochner_Integration.integral_cong)
          apply (use \<open>X x \<subseteq> X'\<close> in \<open>auto simp: indicator_def\<close>)
         done
       also have "norm \<dots> \<le> (\<integral>t\<in>X'-X x. norm (f y t) \<partial>lborel)"
         by (intro set_integral_norm_bound integrable) (fact | simp)+
       also have "AE t\<in>X' - X x in lborel. norm (f y t) \<le> g t"
         using assms(4)[OF \<open>y \<in> Y\<close>] by eventually_elim auto
       with \<open>y \<in> Y\<close> have "(\<integral>t\<in>X'-X x. norm (f y t) \<partial>lborel) \<le> (\<integral>t\<in>X'-X x. g t \<partial>lborel)"
         by (intro set_integral_mono_AE set_integrable_norm integrable integrable_g) auto
       also have "\<dots> = (\<integral>t\<in>X'. g t \<partial>lborel) - (\<integral>t\<in>X x. g t \<partial>lborel)"
         unfolding set_lebesgue_integral_def
         apply (subst Bochner_Integration.integral_diff [symmetric])
         unfolding set_integrable_def [symmetric]
           apply (rule integrable_g; (fact | simp))
          apply (rule integrable_g; fact)
         apply (intro Bochner_Integration.integral_cong)
          apply (use \<open>X x \<subseteq> X'\<close> in \<open>auto simp: indicator_def\<close>)
         done
       also have "\<dots> \<le> dist (\<integral>t\<in>X x. g t \<partial>lborel) (\<integral>t\<in>X'. g t \<partial>lborel)"
         by (simp add: dist_norm)
       also have "\<dots> < \<epsilon>" by fact
       finally show "dist (set_lebesgue_integral lborel (X x) (f y))
                          (set_lebesgue_integral lborel X' (f y)) < \<epsilon>" .
     qed
   qed
 qed
 
 lemma integral_dominated_convergence_at_right:
   fixes s :: "real \<Rightarrow> 'a \<Rightarrow> 'b::{banach, second_countable_topology}" and w :: "'a \<Rightarrow> real"
     and f :: "'a \<Rightarrow> 'b" and M and c :: real
   assumes "f \<in> borel_measurable M" "\<And>t. s t \<in> borel_measurable M" "integrable M w"
   assumes lim: "AE x in M. ((\<lambda>i. s i x) \<longlongrightarrow> f x) (at_right c)"
   assumes bound: "\<forall>\<^sub>F i in at_right c. AE x in M. norm (s i x) \<le> w x"
   shows "((\<lambda>t. integral\<^sup>L M (s t)) \<longlongrightarrow> integral\<^sup>L M f) (at_right c)"
 proof (rule tendsto_at_right_realI_sequentially)
   fix X :: "nat \<Rightarrow> real" assume X: "filterlim X (at_right c) sequentially"
   from filterlim_iff[THEN iffD1, OF this, rule_format, OF bound]
   obtain N where w: "\<And>n. N \<le> n \<Longrightarrow> AE x in M. norm (s (X n) x) \<le> w x"
     by (auto simp: eventually_sequentially)
 
   show "(\<lambda>n. integral\<^sup>L M (s (X n))) \<longlonglongrightarrow> integral\<^sup>L M f"
   proof (rule LIMSEQ_offset, rule integral_dominated_convergence)
     show "AE x in M. norm (s (X (n + N)) x) \<le> w x" for n
       by (rule w) auto
     show "AE x in M. (\<lambda>n. s (X (n + N)) x) \<longlonglongrightarrow> f x"
       using lim
     proof eventually_elim
       fix x assume "((\<lambda>i. s i x) \<longlongrightarrow> f x) (at_right c)"
       then show "(\<lambda>n. s (X (n + N)) x) \<longlonglongrightarrow> f x"
         by (intro LIMSEQ_ignore_initial_segment filterlim_compose[OF _ X])
     qed
   qed fact+
 qed
 
 lemma integral_dominated_convergence_at_left:
   fixes s :: "real \<Rightarrow> 'a \<Rightarrow> 'b::{banach, second_countable_topology}" and w :: "'a \<Rightarrow> real"
     and f :: "'a \<Rightarrow> 'b" and M and c :: real
   assumes "f \<in> borel_measurable M" "\<And>t. s t \<in> borel_measurable M" "integrable M w"
   assumes lim: "AE x in M. ((\<lambda>i. s i x) \<longlongrightarrow> f x) (at_left c)"
   assumes bound: "\<forall>\<^sub>F i in at_left c. AE x in M. norm (s i x) \<le> w x"
   shows "((\<lambda>t. integral\<^sup>L M (s t)) \<longlongrightarrow> integral\<^sup>L M f) (at_left c)"
 proof (rule tendsto_at_left_realI_sequentially)
   fix X :: "nat \<Rightarrow> real" assume X: "filterlim X (at_left c) sequentially"
   from filterlim_iff[THEN iffD1, OF this, rule_format, OF bound]
   obtain N where w: "\<And>n. N \<le> n \<Longrightarrow> AE x in M. norm (s (X n) x) \<le> w x"
     by (auto simp: eventually_sequentially)
 
   show "(\<lambda>n. integral\<^sup>L M (s (X n))) \<longlonglongrightarrow> integral\<^sup>L M f"
   proof (rule LIMSEQ_offset, rule integral_dominated_convergence)
     show "AE x in M. norm (s (X (n + N)) x) \<le> w x" for n
       by (rule w) auto
     show "AE x in M. (\<lambda>n. s (X (n + N)) x) \<longlonglongrightarrow> f x"
       using lim
     proof eventually_elim
       fix x assume "((\<lambda>i. s i x) \<longlongrightarrow> f x) (at_left c)"
       then show "(\<lambda>n. s (X (n + N)) x) \<longlonglongrightarrow> f x"
         by (intro LIMSEQ_ignore_initial_segment filterlim_compose[OF _ X])
     qed
   qed fact+
 qed
 
 lemma uniform_limit_interval_integral_right:
   fixes f :: "'a \<Rightarrow> real \<Rightarrow> 'c :: {banach, second_countable_topology}"
   assumes "interval_lebesgue_integrable lborel a b g"
   assumes [measurable]: "\<And>y. y \<in> Y \<Longrightarrow> set_borel_measurable borel (einterval a b) (f y)"
   assumes "\<And>y. y \<in> Y \<Longrightarrow> (AE t\<in>einterval a b in lborel. norm (f y t) \<le> g t)"
   assumes "a < b"
   shows   "uniform_limit Y (\<lambda>b' y. LBINT t=a..b'. f y t) (\<lambda>y. LBINT t=a..b. f y t) (at_left b)"
 proof (cases "Y = {}")
   case False
   have g_nonneg: "AE t\<in>einterval a b in lborel. g t \<ge> 0"
   proof -
     from \<open>Y \<noteq> {}\<close> obtain y where "y \<in> Y" by auto
     from assms(3)[OF this] show ?thesis 
       by eventually_elim (auto elim: order.trans[rotated])
   qed
 
   have ev: "eventually (\<lambda>b'. b' \<in> {a<..<b}) (at_left b)"
     using \<open>a < b\<close> by (intro eventually_at_leftI)
   with \<open>a < b\<close> have "?thesis \<longleftrightarrow> uniform_limit Y (\<lambda>b' y. \<integral>t\<in>einterval a (min b b'). f y t \<partial>lborel)
                                   (\<lambda>y. \<integral>t\<in>einterval a b. f y t \<partial>lborel) (at_left b)"
     by (intro filterlim_cong arg_cong2[where f = uniformly_on])
        (auto simp: interval_lebesgue_integral_def fun_eq_iff min_def
              intro!: eventually_mono[OF ev])
   also have \<dots>
   proof (rule uniform_limit_set_lebesgue_integral[where g = g], goal_cases)
     show "\<forall>\<^sub>F b' in at_left b. einterval a (min b b') \<in> sets borel \<and>
                               einterval a (min b b') \<subseteq> einterval a b"
       using ev by eventually_elim (auto simp: einterval_def)
   next
     show "((\<lambda>b'. set_lebesgue_integral lborel (einterval a (min b b')) g) \<longlongrightarrow>
             set_lebesgue_integral lborel (einterval a b) g) (at_left b)"
       unfolding set_lebesgue_integral_def
     proof (intro tendsto_at_left_erealI_sequentially integral_dominated_convergence)
       have *: "set_borel_measurable borel (einterval a b) g"
         using assms(1) less_imp_le[OF \<open>a < b\<close>]
         by (simp add: interval_lebesgue_integrable_def set_integrable_def set_borel_measurable_def)
       show "(\<lambda>x. indicat_real (einterval a b) x *\<^sub>R g x) \<in> borel_measurable lborel"
         using * by (simp add: set_borel_measurable_def)
       fix X :: "nat \<Rightarrow> ereal" and n :: nat
       have "set_borel_measurable borel (einterval a (min b (X n))) g"
         by (rule set_borel_measurable_subset[OF *]) (auto simp: einterval_def)
       thus "(\<lambda>x. indicat_real (einterval a (min b (X n))) x *\<^sub>R g x) \<in> borel_measurable lborel"
         by (simp add: set_borel_measurable_def)
     next
       fix X :: "nat \<Rightarrow> ereal"
       assume X: "filterlim X (at_left b) sequentially"
       show "AE x in lborel. (\<lambda>n. indicat_real (einterval a (min b (X n))) x *\<^sub>R g x)
                \<longlonglongrightarrow> indicat_real (einterval a b) x *\<^sub>R g x"
       proof (rule AE_I2)
         fix x :: real
         have "(\<lambda>t. indicator (einterval a (min b (X t))) x :: real) \<longlonglongrightarrow>
                 indicator (einterval a b) x"
         proof (cases "x \<in> einterval a b")
           case False
           hence "x \<notin> einterval a (min b (X t))"for t by (auto simp: einterval_def)
           with False show ?thesis by (simp add: indicator_def)
         next
           case True
           with \<open>a < b\<close> have "eventually (\<lambda>t. t \<in> {max a x<..<b}) (at_left b)"
             by (intro eventually_at_leftI[of "ereal x"]) (auto simp: einterval_def min_def)
           from this and X have "eventually (\<lambda>t. X t \<in> {max a x<..<b}) sequentially"
             by (rule eventually_compose_filterlim)
           hence "eventually (\<lambda>t. indicator (einterval a (min b (X t))) x = (1 :: real)) sequentially"
             by eventually_elim (use True in \<open>auto simp: indicator_def einterval_def\<close>)
           from tendsto_eventually[OF this] and True show ?thesis
             by (simp add: indicator_def)
         qed
         thus "(\<lambda>n. indicat_real (einterval a (min b (X n))) x *\<^sub>R g x)
                  \<longlonglongrightarrow> indicat_real (einterval a b) x *\<^sub>R g x" by (intro tendsto_intros)
       qed
     next
       fix X :: "nat \<Rightarrow> ereal" and n :: nat
       show "AE x in lborel. norm (indicator (einterval a (min b (X n))) x *\<^sub>R g x) \<le>
               indicator (einterval a b) x *\<^sub>R g x"
         using g_nonneg by eventually_elim (auto simp: indicator_def einterval_def)
     qed (use assms less_imp_le[OF \<open>a < b\<close>] in 
          \<open>auto simp: interval_lebesgue_integrable_def set_integrable_def\<close>) 
   qed (use assms in \<open>auto simp: interval_lebesgue_integrable_def\<close>)
   finally show ?thesis .
 qed auto
 
 lemma uniform_limit_interval_integral_left:
   fixes f :: "'a \<Rightarrow> real \<Rightarrow> 'c :: {banach, second_countable_topology}"
   assumes "interval_lebesgue_integrable lborel a b g"
   assumes [measurable]: "\<And>y. y \<in> Y \<Longrightarrow> set_borel_measurable borel (einterval a b) (f y)"
   assumes "\<And>y. y \<in> Y \<Longrightarrow> (AE t\<in>einterval a b in lborel. norm (f y t) \<le> g t)"
   assumes "a < b"
   shows   "uniform_limit Y (\<lambda>a' y. LBINT t=a'..b. f y t) (\<lambda>y. LBINT t=a..b. f y t) (at_right a)"
 proof (cases "Y = {}")
   case False
   have g_nonneg: "AE t\<in>einterval a b in lborel. g t \<ge> 0"
   proof -
     from \<open>Y \<noteq> {}\<close> obtain y where "y \<in> Y" by auto
     from assms(3)[OF this] show ?thesis 
       by eventually_elim (auto elim: order.trans[rotated])
   qed
 
   have ev: "eventually (\<lambda>b'. b' \<in> {a<..<b}) (at_right a)"
     using \<open>a < b\<close> by (intro eventually_at_rightI)
   with \<open>a < b\<close> have "?thesis \<longleftrightarrow> uniform_limit Y (\<lambda>a' y. \<integral>t\<in>einterval (max a a') b. f y t \<partial>lborel)
                                   (\<lambda>y. \<integral>t\<in>einterval a b. f y t \<partial>lborel) (at_right a)"
     by (intro filterlim_cong arg_cong2[where f = uniformly_on])
        (auto simp: interval_lebesgue_integral_def fun_eq_iff max_def
              intro!: eventually_mono[OF ev])
   also have \<dots>
   proof (rule uniform_limit_set_lebesgue_integral[where g = g], goal_cases)
     show "\<forall>\<^sub>F a' in at_right a. einterval (max a a') b \<in> sets borel \<and>
                               einterval (max a a') b \<subseteq> einterval a b"
       using ev by eventually_elim (auto simp: einterval_def)
   next
     show "((\<lambda>a'. set_lebesgue_integral lborel (einterval (max a a') b) g) \<longlongrightarrow>
             set_lebesgue_integral lborel (einterval a b) g) (at_right a)"
       unfolding set_lebesgue_integral_def
     proof (intro tendsto_at_right_erealI_sequentially integral_dominated_convergence)
       have *: "set_borel_measurable borel (einterval a b) g"
         using assms(1) less_imp_le[OF \<open>a < b\<close>]
         by (simp add: interval_lebesgue_integrable_def set_integrable_def set_borel_measurable_def)
       show "(\<lambda>x. indicat_real (einterval a b) x *\<^sub>R g x) \<in> borel_measurable lborel"
         using * by (simp add: set_borel_measurable_def)
       fix X :: "nat \<Rightarrow> ereal" and n :: nat
       have "set_borel_measurable borel (einterval (max a (X n)) b) g"
         by (rule set_borel_measurable_subset[OF *]) (auto simp: einterval_def)
       thus "(\<lambda>x. indicat_real (einterval (max a (X n)) b) x *\<^sub>R g x) \<in> borel_measurable lborel"
         by (simp add: set_borel_measurable_def)
     next
       fix X :: "nat \<Rightarrow> ereal"
       assume X: "filterlim X (at_right a) sequentially"
       show "AE x in lborel. (\<lambda>n. indicat_real (einterval (max a (X n)) b) x *\<^sub>R g x)
                \<longlonglongrightarrow> indicat_real (einterval a b) x *\<^sub>R g x"
       proof (rule AE_I2)
         fix x :: real
         have "(\<lambda>t. indicator (einterval (max a (X t)) b) x :: real) \<longlonglongrightarrow>
                 indicator (einterval a b) x"
         proof (cases "x \<in> einterval a b")
           case False
           hence "x \<notin> einterval (max a (X t)) b"for t by (auto simp: einterval_def)
           with False show ?thesis by (simp add: indicator_def)
         next
           case True
           with \<open>a < b\<close> have "eventually (\<lambda>t. t \<in> {a<..<x}) (at_right a)"
             by (intro eventually_at_rightI[of _ "ereal x"]) (auto simp: einterval_def min_def)
           from this and X have "eventually (\<lambda>t. X t \<in> {a<..<x}) sequentially"
             by (rule eventually_compose_filterlim)
           hence "eventually (\<lambda>t. indicator (einterval (max a (X t)) b) x = (1 :: real)) sequentially"
             by eventually_elim (use True in \<open>auto simp: indicator_def einterval_def\<close>)
           from tendsto_eventually[OF this] and True show ?thesis
             by (simp add: indicator_def)
         qed
         thus "(\<lambda>n. indicat_real (einterval (max a (X n)) b) x *\<^sub>R g x)
                  \<longlonglongrightarrow> indicat_real (einterval a b) x *\<^sub>R g x" by (intro tendsto_intros)
       qed
     next
       fix X :: "nat \<Rightarrow> ereal" and n :: nat
       show "AE x in lborel. norm (indicator (einterval (max a (X n)) b) x *\<^sub>R g x) \<le>
               indicator (einterval a b) x *\<^sub>R g x"
         using g_nonneg by eventually_elim (auto simp: indicator_def einterval_def)
     qed (use assms less_imp_le[OF \<open>a < b\<close>] in 
          \<open>auto simp: interval_lebesgue_integrable_def set_integrable_def\<close>) 
   qed (use assms in \<open>auto simp: interval_lebesgue_integrable_def\<close>)
   finally show ?thesis .
 qed auto
 
 lemma uniform_limit_interval_integral_sequentially:
   fixes f :: "'a \<Rightarrow> real \<Rightarrow> 'c :: {banach, second_countable_topology}"
   assumes "interval_lebesgue_integrable lborel a b g"
   assumes [measurable]: "\<And>y. y \<in> Y \<Longrightarrow> set_borel_measurable borel (einterval a b) (f y)"
   assumes "\<And>y. y \<in> Y \<Longrightarrow> (AE t\<in>einterval a b in lborel. norm (f y t) \<le> g t)"
   assumes a': "filterlim a' (at_right a) sequentially"
   assumes b': "filterlim b' (at_left b) sequentially"
   assumes "a < b"
   shows   "uniform_limit Y (\<lambda>n y. LBINT t=a' n..b' n. f y t)
              (\<lambda>y. LBINT t=a..b. f y t) sequentially"
 proof (cases "Y = {}")
   case False
   have g_nonneg: "AE t\<in>einterval a b in lborel. g t \<ge> 0"
   proof -
     from \<open>Y \<noteq> {}\<close> obtain y where "y \<in> Y" by auto
     from assms(3)[OF this] show ?thesis 
       by eventually_elim (auto elim: order.trans[rotated])
   qed
 
   have ev: "eventually (\<lambda>n. a < a' n \<and> a' n < b' n \<and> b' n < b) sequentially"
   proof -
     from ereal_dense2[OF \<open>a < b\<close>] obtain t where t: "a < ereal t" "ereal t < b" by blast
     from t have "eventually (\<lambda>n. a' n \<in> {a<..<t}) sequentially"
       by (intro eventually_compose_filterlim[OF _ a'] eventually_at_rightI[of _ "ereal t"])
     moreover from t have "eventually (\<lambda>n. b' n \<in> {t<..<b}) sequentially"
       by (intro eventually_compose_filterlim[OF _ b'] eventually_at_leftI[of "ereal t"])
     ultimately show "eventually (\<lambda>n. a < a' n \<and> a' n < b' n \<and> b' n < b) sequentially"
       by eventually_elim auto
   qed
 
   have "?thesis \<longleftrightarrow> uniform_limit Y (\<lambda>n y. \<integral>t\<in>einterval (max a (a' n)) (min b (b' n)). f y t \<partial>lborel)
                       (\<lambda>y. \<integral>t\<in>einterval a b. f y t \<partial>lborel) sequentially" using \<open>a < b\<close>
     by (intro filterlim_cong arg_cong2[where f = uniformly_on])
        (auto simp: interval_lebesgue_integral_def fun_eq_iff min_def max_def
              intro!: eventually_mono[OF ev])
   also have \<dots>
   proof (rule uniform_limit_set_lebesgue_integral[where g = g], goal_cases)
     show "\<forall>\<^sub>F n in sequentially. einterval (max a (a' n)) (min b (b' n)) \<in> sets borel \<and>
                                 einterval (max a (a' n)) (min b (b' n)) \<subseteq> einterval a b"
       using ev by eventually_elim (auto simp: einterval_def)
   next
     show "((\<lambda>n. set_lebesgue_integral lborel (einterval (max a (a' n)) (min b (b' n))) g) \<longlongrightarrow>
             set_lebesgue_integral lborel (einterval a b) g) sequentially"
       unfolding set_lebesgue_integral_def
     proof (intro integral_dominated_convergence)
       have *: "set_borel_measurable borel (einterval a b) g"
         using assms(1) less_imp_le[OF \<open>a < b\<close>]
         by (simp add: interval_lebesgue_integrable_def set_integrable_def set_borel_measurable_def)
       show "(\<lambda>x. indicat_real (einterval a b) x *\<^sub>R g x) \<in> borel_measurable lborel"
         using * by (simp add: set_borel_measurable_def)
       fix n :: nat
       have "set_borel_measurable borel (einterval (max a (a' n)) (min b (b' n))) g"
         by (rule set_borel_measurable_subset[OF *]) (auto simp: einterval_def)
       thus "(\<lambda>x. indicat_real (einterval (max a (a' n)) (min b (b' n))) x *\<^sub>R g x) \<in> borel_measurable lborel"
         by (simp add: set_borel_measurable_def)
     next
       show "AE x in lborel. (\<lambda>n. indicat_real (einterval (max a (a' n)) (min b (b' n))) x *\<^sub>R g x)
                \<longlonglongrightarrow> indicat_real (einterval a b) x *\<^sub>R g x"
       proof (rule AE_I2)
         fix x :: real
         have "(\<lambda>t. indicator (einterval (max a (a' t)) (min b (b' t))) x :: real) \<longlonglongrightarrow>
                 indicator (einterval a b) x"
         proof (cases "x \<in> einterval a b")
           case False
           hence "x \<notin> einterval (max a (a' t)) (min b (b' t))"for t
             by (auto simp: einterval_def)
           with False show ?thesis by (simp add: indicator_def)
         next
           case True
           with \<open>a < b\<close> have "eventually (\<lambda>t. t \<in> {a<..<x}) (at_right a)"
             by (intro eventually_at_rightI[of _ "ereal x"]) (auto simp: einterval_def min_def)
 
           have "eventually (\<lambda>n. x \<in> {a' n<..<b' n}) sequentially"
           proof -
             have "eventually (\<lambda>n. a' n \<in> {a<..<x}) sequentially" using True
               by (intro eventually_compose_filterlim[OF _ a'] eventually_at_rightI[of _ "ereal x"])
                  (auto simp: einterval_def)
             moreover have "eventually (\<lambda>n. b' n \<in> {x<..<b}) sequentially" using True
               by (intro eventually_compose_filterlim[OF _ b'] eventually_at_leftI[of "ereal x"])
                  (auto simp: einterval_def)
             ultimately show "eventually (\<lambda>n. x \<in> {a' n<..<b' n}) sequentially"
               by eventually_elim auto
           qed
           hence "eventually (\<lambda>t. indicator (einterval (max a (a' t)) (min b (b' t))) x = (1 :: real)) sequentially"
             by eventually_elim (use True in \<open>auto simp: indicator_def einterval_def\<close>)
           from tendsto_eventually[OF this] and True show ?thesis
             by (simp add: indicator_def)
         qed
         thus "(\<lambda>n. indicat_real (einterval (max a (a' n)) (min b (b' n))) x *\<^sub>R g x)
                  \<longlonglongrightarrow> indicat_real (einterval a b) x *\<^sub>R g x" by (intro tendsto_intros)
       qed
     next
       fix X :: "nat \<Rightarrow> ereal" and n :: nat
       show "AE x in lborel. norm (indicator (einterval (max a (a' n)) (min b (b' n))) x *\<^sub>R g x) \<le>
               indicator (einterval a b) x *\<^sub>R g x"
         using g_nonneg by eventually_elim (auto simp: indicator_def einterval_def)
     qed (use assms less_imp_le[OF \<open>a < b\<close>] in 
          \<open>auto simp: interval_lebesgue_integrable_def set_integrable_def\<close>) 
   qed (use assms in \<open>auto simp: interval_lebesgue_integrable_def\<close>)
   finally show ?thesis .
 qed auto
 
 lemma interval_lebesgue_integrable_combine:
   assumes "interval_lebesgue_integrable lborel A B f"
   assumes "interval_lebesgue_integrable lborel B C f"
   assumes "set_borel_measurable borel (einterval A C) f"
   assumes "A \<le> B" "B \<le> C"
   shows   "interval_lebesgue_integrable lborel A C f"
 proof -
   have meas: "set_borel_measurable borel (einterval A B \<union> einterval B C) f"
     by (rule set_borel_measurable_subset[OF assms(3)]) (use assms in \<open>auto simp: einterval_def\<close>)
   have "set_integrable lborel (einterval A B \<union> einterval B C) f"
     using assms by (intro set_integrable_Un) (auto simp: interval_lebesgue_integrable_def)
   also have "?this \<longleftrightarrow> set_integrable lborel (einterval A C) f"
   proof (cases "B \<in> {\<infinity>, -\<infinity>}")
     case True
     with assms have "einterval A B \<union> einterval B C = einterval A C"
       by (auto simp: einterval_def)
     thus ?thesis by simp
   next
     case False
     then obtain B' where [simp]: "B = ereal B'"
       by (cases B) auto
     have "indicator (einterval A C) x = (indicator (einterval A B \<union> einterval B C) x :: real)"
       if "x \<noteq> B'" for x using assms(4,5) that
       by (cases A; cases C) (auto simp: einterval_def indicator_def)
     hence "{x \<in> space lborel. indicat_real (einterval A B \<union> einterval B C) x *\<^sub>R f x \<noteq>
               indicat_real (einterval A C) x *\<^sub>R f x} \<subseteq> {B'}" by force
     thus ?thesis unfolding set_integrable_def using meas assms
       by (intro integrable_cong_AE AE_I[of _ _ "{B'}"])
          (simp_all add: set_borel_measurable_def)
   qed
   also have "\<dots> \<longleftrightarrow> ?thesis"
     using order.trans[OF assms(4,5)] by (simp add: interval_lebesgue_integrable_def)
   finally show ?thesis .
 qed
 
 lemma interval_lebesgue_integrable_bigo_right:
   fixes A B :: real
   fixes f :: "real \<Rightarrow> real"
   assumes "f \<in> O[at_left B](g)"
   assumes cont: "continuous_on {A..<B} f"
   assumes meas: "set_borel_measurable borel {A<..<B} f"
   assumes "interval_lebesgue_integrable lborel A B g"
   assumes "A < B"
   shows   "interval_lebesgue_integrable lborel A B f"
 proof -
   from assms(1) obtain c where c: "c > 0" "eventually (\<lambda>x. norm (f x) \<le> c * norm (g x)) (at_left B)"
     by (elim landau_o.bigE)
   then obtain B' where B': "B' < B" "\<And>x. x \<in> {B'<..<B} \<Longrightarrow> norm (f x) \<le> c * norm (g x)"
     using \<open>A < B\<close> by (auto simp: Topological_Spaces.eventually_at_left[of A])
 
   show ?thesis
   proof (rule interval_lebesgue_integrable_combine)
     show "interval_lebesgue_integrable lborel A (max A B') f"
       using B' assms
       by (intro interval_integrable_continuous_on continuous_on_subset[OF cont]) auto
     show "set_borel_measurable borel (einterval (ereal A) (ereal B)) f"
       using assms by simp
     have meas': "set_borel_measurable borel {max A B'<..<B} f"
       by (rule set_borel_measurable_subset[OF meas]) auto
     have "set_integrable lborel {max A B'<..<B} f"
     proof (rule set_integrable_bound[OF _ _ AE_I2[OF impI]])
       have "set_integrable lborel {A<..<B} (\<lambda>x. c * g x)"
         using assms by (simp add: interval_lebesgue_integrable_def)
       thus "set_integrable lborel {max A B'<..<B} (\<lambda>x. c * g x)"
         by (rule set_integrable_subset) auto
     next
       fix x assume "x \<in> {max A B'<..<B}"
       hence "norm (f x) \<le> c * norm (g x)"
         by (intro B') auto
       also have "\<dots> \<le> norm (c * g x)"
         unfolding norm_mult by (intro mult_right_mono) auto
       finally show  "norm (f x) \<le> norm (c * g x)" .
     qed (use meas' in \<open>simp_all add: set_borel_measurable_def\<close>)
     thus "interval_lebesgue_integrable lborel (ereal (max A B')) (ereal B) f"
       unfolding interval_lebesgue_integrable_def einterval_eq_Icc using \<open>B' < B\<close> assms by simp
   qed (use B' assms in auto)
 qed
 
 lemma interval_lebesgue_integrable_bigo_left:
   fixes A B :: real
   fixes f :: "real \<Rightarrow> real"
   assumes "f \<in> O[at_right A](g)"
   assumes cont: "continuous_on {A<..B} f"
   assumes meas: "set_borel_measurable borel {A<..<B} f"
   assumes "interval_lebesgue_integrable lborel A B g"
   assumes "A < B"
   shows   "interval_lebesgue_integrable lborel A B f"
 proof -
   from assms(1) obtain c where c: "c > 0" "eventually (\<lambda>x. norm (f x) \<le> c * norm (g x)) (at_right A)"
     by (elim landau_o.bigE)
   then obtain A' where A': "A' > A" "\<And>x. x \<in> {A<..<A'} \<Longrightarrow> norm (f x) \<le> c * norm (g x)"
     using \<open>A < B\<close> by (auto simp: Topological_Spaces.eventually_at_right[of A])
 
   show ?thesis
   proof (rule interval_lebesgue_integrable_combine)
     show "interval_lebesgue_integrable lborel (min B A') B f"
       using A' assms
       by (intro interval_integrable_continuous_on continuous_on_subset[OF cont]) auto
     show "set_borel_measurable borel (einterval (ereal A) (ereal B)) f"
       using assms by simp
     have meas': "set_borel_measurable borel {A<..<min B A'} f"
       by (rule set_borel_measurable_subset[OF meas]) auto
     have "set_integrable lborel {A<..<min B A'} f"
     proof (rule set_integrable_bound[OF _ _ AE_I2[OF impI]])
       have "set_integrable lborel {A<..<B} (\<lambda>x. c * g x)"
         using assms by (simp add: interval_lebesgue_integrable_def)
       thus "set_integrable lborel {A<..<min B A'} (\<lambda>x. c * g x)"
         by (rule set_integrable_subset) auto
     next
       fix x assume "x \<in> {A<..<min B A'}"
       hence "norm (f x) \<le> c * norm (g x)"
         by (intro A') auto
       also have "\<dots> \<le> norm (c * g x)"
         unfolding norm_mult by (intro mult_right_mono) auto
       finally show  "norm (f x) \<le> norm (c * g x)" .
     qed (use meas' in \<open>simp_all add: set_borel_measurable_def\<close>)
     thus "interval_lebesgue_integrable lborel (ereal A) (ereal (min B A')) f"
       unfolding interval_lebesgue_integrable_def einterval_eq_Icc using \<open>A' > A\<close> assms by simp
   qed (use A' assms in auto)
 qed
 
 
 subsection \<open>Other material\<close>
 
 (* TODO: Library *)
 lemma summable_comparison_test_bigo:
   fixes f :: "nat \<Rightarrow> real"
   assumes "summable (\<lambda>n. norm (g n))" "f \<in> O(g)"
   shows   "summable f"
 proof -
   from \<open>f \<in> O(g)\<close> obtain C where C: "eventually (\<lambda>x. norm (f x) \<le> C * norm (g x)) at_top"
     by (auto elim: landau_o.bigE)
   thus ?thesis
     by (rule summable_comparison_test_ev) (insert assms, auto intro: summable_mult)
 qed
 
 lemma fps_expansion_cong:
   assumes "eventually (\<lambda>x. g x = h x) (nhds x)"
   shows   "fps_expansion g x = fps_expansion h x"
 proof -
   have "(deriv ^^ n) g x = (deriv ^^ n) h x" for n
     by (intro higher_deriv_cong_ev assms refl)
   thus ?thesis by (simp add: fps_expansion_def)
 qed
 
 lemma fps_expansion_eq_zero_iff:
   assumes "g holomorphic_on ball z r" "r > 0"
   shows   "fps_expansion g z = 0 \<longleftrightarrow> (\<forall>z\<in>ball z r. g z = 0)"
 proof
   assume *: "\<forall>z\<in>ball z r. g z = 0"
   have "eventually (\<lambda>w. w \<in> ball z r) (nhds z)"
     using assms by (intro eventually_nhds_in_open) auto
   hence "eventually (\<lambda>z. g z = 0) (nhds z)"
     by eventually_elim (use * in auto)
   hence "fps_expansion g z = fps_expansion (\<lambda>_. 0) z"
     by (intro fps_expansion_cong)
   thus "fps_expansion g z = 0"
     by (simp add: fps_expansion_def fps_zero_def)
 next
   assume *: "fps_expansion g z = 0"
   have "g w = 0" if "w \<in> ball z r" for w
     by (rule holomorphic_fun_eq_0_on_ball[OF assms(1) that])
        (use * in \<open>auto simp: fps_expansion_def fps_eq_iff\<close>)
   thus "\<forall>w\<in>ball z r. g w = 0" by blast
 qed
 
 lemma fds_nth_higher_deriv:
   "fds_nth ((fds_deriv ^^ k) F) = (\<lambda>n. (-1) ^ k * of_real (ln n) ^ k * fds_nth F n)"
   by (induction k) (auto simp: fds_nth_deriv fun_eq_iff simp flip: scaleR_conv_of_real)
 
 lemma binomial_n_n_minus_one [simp]: "n > 0 \<Longrightarrow> n choose (n - Suc 0) = n"
   by (cases n) auto
 
 lemma has_field_derivative_complex_powr_right:
   "w \<noteq> 0 \<Longrightarrow> ((\<lambda>z. w powr z) has_field_derivative Ln w * w powr z) (at z within A)"
   by (rule DERIV_subset, rule has_field_derivative_powr_right) auto
 
 lemmas has_field_derivative_complex_powr_right' =
   has_field_derivative_complex_powr_right[THEN DERIV_chain2]
 
 end
\ No newline at end of file