diff --git a/thys/DiscretePricing/Disc_Cond_Expect.thy b/thys/DiscretePricing/Disc_Cond_Expect.thy
--- a/thys/DiscretePricing/Disc_Cond_Expect.thy
+++ b/thys/DiscretePricing/Disc_Cond_Expect.thy
@@ -1,1336 +1,1336 @@
 (*  Title:      Disc_Cond_Expect.thy
     Author:     Mnacho Echenim, Univ. Grenoble Alpes
 *)
 
 section \<open>Discrete Conditional Expectation\<close>
 
 theory Disc_Cond_Expect imports "HOL-Probability.Probability" Generated_Subalgebra
 
 begin
 
 subsection \<open>Preliminary measurability results\<close>
 
 text \<open>These are some useful results, in particular when working with functions that have a countable
 codomain.\<close>
 
 definition disc_fct  where
   "disc_fct f \<equiv> countable (range f)"
 
 definition  point_measurable where
   "point_measurable M S f \<equiv> (f`(space M)\<subseteq> S) \<and> (\<forall>  r \<in> (range f) \<inter> S . f-`{r} \<inter> (space M) \<in> sets M)"
 
 
 lemma singl_meas_if:
   assumes "f \<in> space M \<rightarrow> space N"
   and "\<forall>r\<in> range f\<inter> space N. \<exists>A\<in> sets N. range f\<inter> A = {r}"
 shows "point_measurable (fct_gen_subalgebra M N f) (space N) f" unfolding point_measurable_def
 proof
   show "f`space (fct_gen_subalgebra M N f)\<subseteq> space N" using assms
     by (simp add: Pi_iff fct_gen_subalgebra_space image_subsetI)
   show "(\<forall>r\<in>range f \<inter> space N. f -` {r} \<inter> space (fct_gen_subalgebra M N f) \<in> sets (fct_gen_subalgebra M N f))"
   proof
     fix r
     assume "r\<in> range f \<inter> space N"
     hence "\<exists>A\<in> sets N. range f\<inter> A = {r}" using assms by blast
     from this obtain A where "A\<in> sets N" and "range f \<inter> A = {r}" by auto note Aprops = this
     hence "f-`A = f-`{r}" by auto
     hence "f-`A \<inter> space M = f-`{r} \<inter> space (fct_gen_subalgebra M N f)" by (simp add: fct_gen_subalgebra_space)
     thus "f -` {r} \<inter> space (fct_gen_subalgebra M N f) \<in> sets (fct_gen_subalgebra M N f)"
       using Aprops fct_gen_subalgebra_sets_mem[of A N f M] by simp
   qed
 qed
 
 lemma  meas_single_meas:
   assumes "f\<in> measurable M N"
   and "\<forall>r\<in> range f\<inter> space N. \<exists>A\<in> sets N. range f\<inter> A = {r}"
 shows "point_measurable M (space N) f"
 proof -
   have "subalgebra M (fct_gen_subalgebra M N f) " using assms fct_gen_subalgebra_is_subalgebra by blast
   hence "sets (fct_gen_subalgebra M N f) \<subseteq> sets M" by (simp add: subalgebra_def)
   moreover have "point_measurable (fct_gen_subalgebra M N f) (space N) f" using assms singl_meas_if
     by (metis (no_types, lifting) Pi_iff measurable_space)
   ultimately show ?thesis
   proof -
     obtain bb :: "'a measure \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b" where
       f1: "\<forall>m B f. (\<not> point_measurable m B f \<or> f ` space m \<subseteq> B \<and> (\<forall>b. b \<notin> range f \<inter> B \<or> f -` {b} \<inter> space m \<in> sets m)) \<and> (\<not> f ` space m \<subseteq> B \<or> bb m B f \<in> range f \<inter> B \<and> f -` {bb m B f} \<inter> space m \<notin> sets m \<or> point_measurable m B f)"
       by (metis (no_types) point_measurable_def)
     moreover
     { assume "f -` {bb M (space N) f} \<inter> space (fct_gen_subalgebra M N f) \<in> sets (fct_gen_subalgebra M N f)"
       then have "f -` {bb M (space N) f} \<inter> space M \<in> sets (fct_gen_subalgebra M N f)"
         by (metis \<open>subalgebra M (fct_gen_subalgebra M N f)\<close> subalgebra_def)
       then have "f -` {bb M (space N) f} \<inter> space M \<in> sets M"
         using \<open>sets (fct_gen_subalgebra M N f) \<subseteq> sets M\<close> by blast
       then have "f ` space M \<subseteq> space N \<and> f -` {bb M (space N) f} \<inter> space M \<in> sets M"
         using f1 by (metis \<open>point_measurable (fct_gen_subalgebra M N f) (space N) f\<close> \<open>subalgebra M (fct_gen_subalgebra M N f)\<close> subalgebra_def)
       then have ?thesis
         using f1 by metis }
     ultimately show ?thesis
       by (metis (no_types) \<open>point_measurable (fct_gen_subalgebra M N f) (space N) f\<close> \<open>subalgebra M (fct_gen_subalgebra M N f)\<close> subalgebra_def)
   qed
 qed
 
 
 
 definition countable_preimages where
 "countable_preimages B Y = (\<lambda>n. if ((infinite B) \<or> (finite B \<and> n < card B)) then Y -` {(from_nat_into B) n} else {})"
 
 lemma  count_pre_disj:
   fixes i::nat
   assumes "countable B"
   and "i \<noteq> j"
 shows "(countable_preimages B Y) i \<inter> (countable_preimages B Y) j = {}"
 proof (cases  "(countable_preimages B Y) i = {} \<or> (countable_preimages B Y) j = {}")
   case True
   thus ?thesis by auto
 next
   case False
   hence "Y -` {(from_nat_into B) i} \<noteq> {} \<and> Y -` {(from_nat_into B) j} \<noteq> {}"  unfolding countable_preimages_def by meson
   have "(infinite B) \<or> (finite B \<and> i < card B \<and> j < card B)" using False unfolding countable_preimages_def
     by meson
   have "(from_nat_into B) i \<noteq> (from_nat_into B) j"
     by (metis False assms(1) assms(2) bij_betw_def countable_preimages_def from_nat_into_inj from_nat_into_inj_infinite lessThan_iff to_nat_on_finite)
   thus ?thesis
   proof -
     have f1: "\<forall>A f n. if infinite A \<or> finite A \<and> n < card A then countable_preimages A f n = f -` {from_nat_into A n::'a} else countable_preimages A f n = ({}::'b set)"
       by (meson countable_preimages_def)
     then have f2: "infinite B \<or> finite B \<and> i < card B"
       by (metis (no_types) False)
     have "infinite B \<or> finite B \<and> j < card B"
       using f1 by (meson False)
     then show ?thesis
       using f2 f1 \<open>from_nat_into B i \<noteq> from_nat_into B j\<close> by fastforce
   qed
 qed
 
 lemma count_pre_surj:
   assumes "countable B"
   and "w \<in> Y -`B"
 shows "\<exists>i. w \<in> (countable_preimages B Y) i"
 proof (cases "finite B")
   case True
     have "\<exists> i < card B. (from_nat_into B) i = Y w"
       by (metis True assms(1) assms(2) bij_betw_def from_nat_into_to_nat_on image_eqI lessThan_iff
           to_nat_on_finite vimageE)
     from this obtain i where "i< card B" and "(from_nat_into B) i = Y w" by blast
     hence "w \<in> (countable_preimages B Y) i"
       by (simp add: countable_preimages_def)
     thus "\<exists>i. w \<in> (countable_preimages B Y) i" by auto
   next
   case False
     hence "\<exists> i. (from_nat_into B) i = Y w"
       by (meson assms(1) assms(2) from_nat_into_to_nat_on vimageE)
     from this obtain i where  "(from_nat_into B) i = Y w" by blast
     hence "w \<in> (countable_preimages B Y) i"
       by (simp add: False countable_preimages_def)
     thus "\<exists>i. w \<in> (countable_preimages B Y) i" by auto
 qed
 
 
 lemma count_pre_img:
   assumes "x \<in> (countable_preimages B Y) n"
   shows "Y x = (from_nat_into B) n"
 proof -
   have "x\<in> Y -` {(from_nat_into B) n}" using assms unfolding countable_preimages_def
     by (meson empty_iff)
   thus ?thesis by simp
 qed
 
 
 lemma count_pre_union_img:
   assumes "countable B"
   shows "Y -`B = (\<Union> i. (countable_preimages B Y) i)"
 proof (cases "B = {}")
   case False
   have "Y -`B \<subseteq> (\<Union> i. (countable_preimages B Y) i)"
     by (simp add: assms count_pre_surj subset_eq)
   moreover have "(\<Union> i. (countable_preimages B Y) i) \<subseteq> Y -`B"
   proof -
     have f1: "\<forall>b A f n. (b::'b) \<notin> countable_preimages A f n \<or> (f b::'a) = from_nat_into A n"
       by (meson count_pre_img)
     have "range (from_nat_into B) = B"
       by (meson False assms range_from_nat_into)
     then show ?thesis
       using f1 by blast
   qed
   ultimately show ?thesis by simp
 next
   case True
   hence "\<forall> i. (countable_preimages B Y) i = {}" unfolding countable_preimages_def by simp
   hence "(\<Union> i. (countable_preimages B Y) i) = {}" by auto
   moreover have "Y -`B = {}" using True by simp
   ultimately show ?thesis by simp
 qed
 
 lemma  count_pre_meas:
   assumes "point_measurable M (space N) Y"
   and "B\<subseteq> space N"
   and "countable B"
   shows "\<forall>i. (countable_preimages B Y) i \<inter> space M \<in> sets M"
 proof
   fix i
   have "Y -`B = (\<Union> i. (countable_preimages B Y) i)" using assms
     by (simp add: count_pre_union_img)
   show "countable_preimages B Y i \<inter> space M \<in> sets M"
   proof (cases "countable_preimages B Y i = {}")
     case True
     thus ?thesis by simp
   next
     case False
     from this obtain y where "y \<in> countable_preimages B Y i" by auto
     hence "countable_preimages B Y i = Y -`{Y y}"
       by (metis False count_pre_img countable_preimages_def)
     have "Y y = from_nat_into B i"
       by (meson \<open>y \<in> countable_preimages B Y i\<close> count_pre_img)
     hence "Y y \<in> space N"
       by (metis UNIV_I UN_I \<open>y \<in> countable_preimages B Y i\<close> \<open>Y -`B = (\<Union> i. (countable_preimages B Y) i)\<close> assms(2)  empty_iff from_nat_into subsetCE vimage_empty)
     moreover have "Y y \<in> range Y" by simp
     thus ?thesis
       by (metis IntI \<open>countable_preimages B Y i = Y -` {Y y}\<close> assms(1) calculation point_measurable_def)
   qed
 qed
 
 
 lemma  disct_fct_point_measurable:
 assumes "disc_fct f"
 and "point_measurable M (space N) f"
 shows "f\<in> measurable M N" unfolding measurable_def
 proof
   show "f \<in> space M \<rightarrow> space N \<and> (\<forall>y\<in>sets N. f -` y \<inter> space M \<in> sets M)"
   proof
     show "f \<in> space M \<rightarrow> space N" using assms unfolding point_measurable_def by auto
     show "\<forall>y\<in>sets N. f -` y \<inter> space M \<in> sets M"
     proof
       fix y
       assume "y\<in> sets N"
       let ?imY = "range f \<inter> y"
       have "f-`y = f-`?imY" by auto
       moreover have "countable ?imY" using assms unfolding disc_fct_def by auto
       ultimately have "f -`y = (\<Union> i. (countable_preimages ?imY f) i)" using assms count_pre_union_img by metis
       hence yeq: "f -` y \<inter> space M = (\<Union> i. ((countable_preimages ?imY f) i) \<inter> space M)" by auto
       have "\<forall>i. countable_preimages ?imY f i \<inter> space M \<in> sets M"
         by (metis \<open>countable (range f \<inter> y)\<close> \<open>y \<in> sets N\<close> assms(2) inf_le2 le_inf_iff count_pre_meas  sets.Int_space_eq1)
       hence "(\<Union> i. ((countable_preimages ?imY f) i) \<inter> space M) \<in> sets M" by blast
       thus "f -` y \<inter> space M \<in> sets M" using yeq by simp
     qed
   qed
 qed
 
 
 lemma  set_point_measurable:
   assumes "point_measurable M (space N) Y"
   and "B \<subseteq> space N"
   and "countable B"
 shows "(Y -`B) \<inter> space M \<in> sets M"
 proof -
   have "Y -`B = (\<Union> i. (countable_preimages B Y) i)" using assms
     by (simp add: count_pre_union_img)
   hence "Y -`B \<inter> space M = (\<Union> i. ((countable_preimages B Y) i \<inter> space M))"
     by auto
   have "\<forall>i. (countable_preimages B Y) i \<inter> space M \<in> sets M" using assms by (simp add: count_pre_meas)
   hence "(\<Union> i. ((countable_preimages B Y) i \<inter> space M)) \<in> sets M" by blast
   show ?thesis
     using \<open>(\<Union>i. countable_preimages B Y i \<inter> space M) \<in> sets M\<close> \<open>Y -` B \<inter> space M = (\<Union>i. countable_preimages B Y i \<inter> space M)\<close> by auto
 qed
 
 
 subsection \<open>Definition of explicit conditional expectation\<close>
 
 text \<open>This section is devoted to an explicit computation of a conditional expectation for random variables
 that have a countable codomain. More precisely, the computed random variable is almost everywhere equal to a conditional
 expectation of the random variable under consideration.\<close>
 
 definition  img_dce where
   "img_dce M Y X = (\<lambda> y. if measure M ((Y -` {y}) \<inter> space M) = 0 then 0 else
     ((integral\<^sup>L M (\<lambda>w. ((X w) * (indicator ((Y -`{y})\<inter> space M) w))))/(measure M ((Y -` {y}) \<inter> space M))))"
 
 definition  expl_cond_expect where
   "expl_cond_expect M Y X = (img_dce M Y X) \<circ> Y"
 
 lemma  nn_expl_cond_expect_pos:
   assumes "\<forall>w \<in> space M. 0 \<le> X w"
 shows "\<forall> w\<in> space M. 0 \<le> (expl_cond_expect M Y X) w"
 proof
   fix w
   assume space: "w\<in> space M"
   show "0 \<le> (expl_cond_expect M Y X) w"
   proof (cases "measure M ((Y -` {Y w})\<inter> space M) = 0")
     case True
     thus "0 \<le> (expl_cond_expect M Y X) w" unfolding expl_cond_expect_def img_dce_def by simp
   next
     case False
     hence "Y -`{Y w} \<inter> space M \<in> sets M" using measure_notin_sets by blast
     let ?indA = "((\<lambda> x. indicator ((Y -`{Y w})\<inter> space M) x))"
     have "\<forall>w \<in> space M. 0 \<le> (X w) * (?indA w)" by (simp add: assms)
     hence  "0 \<le> (integral\<^sup>L M (\<lambda>w. ((X w) * (?indA w))))" by simp
     moreover have "(expl_cond_expect M Y X) w = (integral\<^sup>L M (\<lambda>w. ((X w) * (?indA w)))) / (measure M ((Y -` {Y w})\<inter> space M))"
       unfolding expl_cond_expect_def img_dce_def using False by simp
     moreover have "0 < measure M ((Y -` {Y w}) \<inter> space M)" using False by (simp add: zero_less_measure_iff)
     ultimately show "0 \<le> (expl_cond_expect M Y X) w" by simp
   qed
 qed
 
 
 
 lemma  expl_cond_expect_const:
   assumes "Y w = Y y"
   shows "expl_cond_expect M Y X w = expl_cond_expect M Y X y"
     unfolding expl_cond_expect_def img_dce_def
     by (simp add: assms)
 
 
 lemma  expl_cond_exp_cong:
   assumes "\<forall>w\<in>space M. X w = Z w"
 shows "\<forall>w\<in> space M. expl_cond_expect M Y X w = expl_cond_expect M Y Z w" unfolding expl_cond_expect_def img_dce_def
   by (metis (no_types, lifting) Bochner_Integration.integral_cong assms(1) o_apply)
 
 (* example of a proof that IMO takes too long in Isabelle *)
 lemma  expl_cond_exp_add:
   assumes "integrable M X"
   and "integrable M Z"
 shows "\<forall>w\<in> space M. expl_cond_expect M Y (\<lambda>x. X x + Z x) w = expl_cond_expect M Y X w + expl_cond_expect M Y Z w"
 proof
   fix w
   assume "w\<in> space M"
   define prY where "prY = measure M ((Y -` {Y w}) \<inter> space M)"
   show "expl_cond_expect M Y (\<lambda>x. X x + Z x) w = expl_cond_expect M Y X w + expl_cond_expect M Y Z w"
   proof (cases "prY = 0")
     case True
     thus ?thesis unfolding expl_cond_expect_def img_dce_def prY_def by simp
   next
     case False
     hence "(Y -` {Y w}) \<inter> space M \<in> sets M" unfolding prY_def using measure_notin_sets by blast
     let ?indA = "indicator ((Y -` {Y w}) \<inter> space M)::('a\<Rightarrow>real)"
     have "integrable M (\<lambda>x. X x * ?indA x)"
       using \<open>Y -` {Y w} \<inter> space M \<in> sets M\<close> assms(1) integrable_real_mult_indicator by blast
     moreover have "integrable M (\<lambda>x. Z x * ?indA x)"
       using \<open>Y -` {Y w} \<inter> space M \<in> sets M\<close> assms(2) integrable_real_mult_indicator by blast
     ultimately have "integral\<^sup>L M (\<lambda>x. X x * ?indA x + Z x * ?indA x) = integral\<^sup>L M (\<lambda>x. X x * ?indA x) + integral\<^sup>L M (\<lambda>x. Z x * ?indA x)"
       using Bochner_Integration.integral_add by blast
     moreover have "\<forall>x\<in> space M. X x * ?indA x + Z x * ?indA x = (X x + Z x) * ?indA x"
       by (simp add: indicator_def)
     ultimately have fsteq: "integral\<^sup>L M (\<lambda>x. (X x + Z x) * ?indA x) = integral\<^sup>L M (\<lambda>x. X x * ?indA x) + integral\<^sup>L M (\<lambda>x. Z x * ?indA x)"
       by (metis (no_types, lifting) Bochner_Integration.integral_cong)
     have "integral\<^sup>L M (\<lambda>x. (X x + Z x) * ?indA x/prY) = integral\<^sup>L M (\<lambda>x. (X x + Z x) * ?indA x)/prY"
       by simp
     also have "... = integral\<^sup>L M (\<lambda>x. X x * ?indA x)/prY + integral\<^sup>L M (\<lambda>x. Z x * ?indA x)/prY" using fsteq
       by (simp add: add_divide_distrib)
     also have "... = integral\<^sup>L M (\<lambda>x. X x * ?indA x/prY) + integral\<^sup>L M (\<lambda>x. Z x * ?indA x/prY)" by auto
     finally have "integral\<^sup>L M (\<lambda>x. (X x + Z x) * ?indA x/prY) = integral\<^sup>L M (\<lambda>x. X x * ?indA x/prY) + integral\<^sup>L M (\<lambda>x. Z x * ?indA x/prY)" .
     thus ?thesis using False unfolding expl_cond_expect_def img_dce_def
       by (simp add: add_divide_distrib fsteq)
   qed
 qed
 
 
 lemma expl_cond_exp_diff:
   assumes "integrable M X"
   and "integrable M Z"
 shows "\<forall>w\<in> space M. expl_cond_expect M Y (\<lambda>x. X x - Z x) w = expl_cond_expect M Y X w - expl_cond_expect M Y Z w"
 proof
   fix w
   assume "w\<in> space M"
   define prY where "prY = measure M ((Y -` {Y w}) \<inter> space M)"
   show "expl_cond_expect M Y (\<lambda>x. X x - Z x) w = expl_cond_expect M Y X w - expl_cond_expect M Y Z w"
   proof (cases "prY = 0")
     case True
     thus ?thesis unfolding expl_cond_expect_def img_dce_def prY_def by simp
   next
     case False
     hence "(Y -` {Y w}) \<inter> space M \<in> sets M" unfolding prY_def using measure_notin_sets by blast
     let ?indA = "indicator ((Y -` {Y w}) \<inter> space M)::('a\<Rightarrow>real)"
     have "integrable M (\<lambda>x. X x * ?indA x)"
       using \<open>Y -` {Y w} \<inter> space M \<in> sets M\<close> assms(1) integrable_real_mult_indicator by blast
     moreover have "integrable M (\<lambda>x. Z x * ?indA x)"
       using \<open>Y -` {Y w} \<inter> space M \<in> sets M\<close> assms(2) integrable_real_mult_indicator by blast
     ultimately have "integral\<^sup>L M (\<lambda>x. X x * ?indA x - Z x * ?indA x) = integral\<^sup>L M (\<lambda>x. X x * ?indA x) - integral\<^sup>L M (\<lambda>x. Z x * ?indA x)"
       using Bochner_Integration.integral_diff by blast
     moreover have "\<forall>x\<in> space M. X x * ?indA x - Z x * ?indA x = (X x - Z x) * ?indA x"
       by (simp add: indicator_def)
     ultimately have fsteq: "integral\<^sup>L M (\<lambda>x. (X x - Z x) * ?indA x) = integral\<^sup>L M (\<lambda>x. X x * ?indA x) - integral\<^sup>L M (\<lambda>x. Z x * ?indA x)"
       by (metis (no_types, lifting) Bochner_Integration.integral_cong)
     have "integral\<^sup>L M (\<lambda>x. (X x - Z x) * ?indA x/prY) = integral\<^sup>L M (\<lambda>x. (X x - Z x) * ?indA x)/prY"
       by simp
     also have "... = integral\<^sup>L M (\<lambda>x. X x * ?indA x)/prY - integral\<^sup>L M (\<lambda>x. Z x * ?indA x)/prY" using fsteq
       by (simp add: diff_divide_distrib)
     also have "... = integral\<^sup>L M (\<lambda>x. X x * ?indA x/prY) - integral\<^sup>L M (\<lambda>x. Z x * ?indA x/prY)" by auto
     finally have "integral\<^sup>L M (\<lambda>x. (X x - Z x) * ?indA x/prY) = integral\<^sup>L M (\<lambda>x. X x * ?indA x/prY) - integral\<^sup>L M (\<lambda>x. Z x * ?indA x/prY)" .
     thus ?thesis using False unfolding expl_cond_expect_def img_dce_def
       by (simp add: diff_divide_distrib fsteq)
   qed
 qed
 
 lemma  expl_cond_expect_prop_sets:
   assumes "disc_fct Y"
   and "point_measurable M (space N) Y"
   and "D = {w\<in> space M. Y w \<in> space N \<and> (P (expl_cond_expect M Y X w))}"
 shows "D\<in> sets M"
 proof -
   let ?C = "{y \<in> (Y`(space M)) \<inter> (space N). P (img_dce M Y X y)}"
   have "space M \<subseteq> UNIV" by simp
   hence "Y`(space M) \<subseteq> range Y" by auto
   hence "countable (Y`(space M))" using assms countable_subset unfolding disc_fct_def  by auto
   hence "countable ?C" using assms unfolding disc_fct_def by auto
   have eqset: "D = (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
   proof
     show "D\<subseteq> (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
     proof
       fix w
       assume "w\<in> D"
       hence "w\<in> space M \<and> Y w \<in> (space N) \<and> (P (expl_cond_expect M Y X w))"
         by (simp add: assms)
       hence "P (img_dce M Y X (Y w))" by (simp add: expl_cond_expect_def)
       hence "Y w \<in> ?C" using \<open>w \<in> space M \<and> Y w \<in> space N \<and> P (expl_cond_expect M Y X w)\<close> by blast
       thus "w\<in> (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
         using \<open>w \<in> space M \<and> Y w \<in> space N \<and> P (expl_cond_expect M Y X w)\<close> by blast
     qed
     show "(\<Union> b\<in> ?C. Y-`{b})\<inter> space M \<subseteq> D"
     proof
       fix w
       assume "w\<in> (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
       from this obtain b where "b\<in> ?C \<and> w\<in> Y-`{b}" by auto note bprops = this
       hence "Y w = b" by auto
       hence "Y w\<in> space N" using bprops by simp
       show "w \<in> D"
         by (metis (mono_tags, lifting) IntE \<open>Y w = b\<close> \<open>w \<in> (\<Union>b\<in>?C. Y -` {b}) \<inter> space M\<close> assms(3)
             bprops mem_Collect_eq o_apply expl_cond_expect_def)
     qed
   qed
   also have "... = (\<Union> b\<in> ?C. Y-`{b}\<inter> space M)" by blast
   finally have "D = (\<Union> b\<in> ?C. Y-`{b}\<inter> space M)".
   have "\<forall>b\<in> ?C. Y-`{b} \<inter> space M \<in> sets M" using assms unfolding point_measurable_def by auto
   hence "(\<Union> b\<in> ?C. Y-`{b}\<inter> space M) \<in> sets M" using \<open>countable ?C\<close> by blast
   thus ?thesis
     using \<open>D = (\<Union>b\<in>?C. Y -` {b} \<inter> space M)\<close> by blast
 qed
 
 lemma  expl_cond_expect_prop_sets2:
   assumes "disc_fct Y"
   and "point_measurable (fct_gen_subalgebra M N Y) (space N) Y"
   and "D = {w\<in> space M. Y w \<in> space N \<and> (P (expl_cond_expect M Y X w))}"
 shows "D\<in> sets (fct_gen_subalgebra M N Y)"
 proof -
   let ?C = "{y \<in> (Y`(space M)) \<inter> (space N). P (img_dce M Y X y)}"
   have "space M \<subseteq> UNIV" by simp
   hence "Y`(space M) \<subseteq> range Y" by auto
   hence "countable (Y`(space M))" using assms countable_subset unfolding disc_fct_def  by auto
   hence "countable ?C" using assms unfolding disc_fct_def by auto
   have eqset: "D = (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
   proof
     show "D\<subseteq> (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
     proof
       fix w
       assume "w\<in> D"
       hence "w\<in> space M \<and> Y w \<in> (space N) \<and> (P (expl_cond_expect M Y X w))"
         by (simp add: assms)
       hence "P (img_dce M Y X (Y w))" by (simp add: expl_cond_expect_def)
       hence "Y w \<in> ?C" using \<open>w \<in> space M \<and> Y w \<in> space N \<and> P (expl_cond_expect M Y X w)\<close> by blast
       thus "w\<in> (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
         using \<open>w \<in> space M \<and> Y w \<in> space N \<and> P (expl_cond_expect M Y X w)\<close> by blast
     qed
     show "(\<Union> b\<in> ?C. Y-`{b})\<inter> space M \<subseteq> D"
     proof
       fix w
       assume "w\<in> (\<Union> b\<in> ?C. Y-`{b})\<inter> space M"
       from this obtain b where "b\<in> ?C \<and> w\<in> Y-`{b}" by auto note bprops = this
       hence "Y w = b" by auto
       hence "Y w\<in> space N" using bprops by simp
       show "w \<in> D"
         by (metis (mono_tags, lifting) IntE \<open>Y w = b\<close> \<open>w \<in> (\<Union>b\<in>?C. Y -` {b}) \<inter> space M\<close> assms(3)
             bprops mem_Collect_eq o_apply expl_cond_expect_def)
     qed
   qed
   also have "... = (\<Union> b\<in> ?C. Y-`{b}\<inter> space M)" by blast
   finally have "D = (\<Union> b\<in> ?C. Y-`{b}\<inter> space M)".
   have "space M = space (fct_gen_subalgebra M N Y)"
     by (simp add: fct_gen_subalgebra_space)
   hence "\<forall>b\<in> ?C. Y-`{b} \<inter> space M \<in> sets (fct_gen_subalgebra M N Y)" using assms unfolding point_measurable_def by auto
   hence "(\<Union> b\<in> ?C. Y-`{b}\<inter> space M) \<in> sets (fct_gen_subalgebra M N Y)" using \<open>countable ?C\<close> by blast
   thus ?thesis
     using \<open>D = (\<Union>b\<in>?C. Y -` {b} \<inter> space M)\<close> by blast
 qed
 
 
 
 
 
 lemma  expl_cond_expect_disc_fct:
   assumes "disc_fct Y"
   shows "disc_fct (expl_cond_expect M Y X)"
    using assms unfolding disc_fct_def expl_cond_expect_def
     by (metis countable_image image_comp)
 
 
 
 
 
 
 
 lemma  expl_cond_expect_point_meas:
   assumes "disc_fct Y"
   and "point_measurable M (space N) Y"
 shows "point_measurable M UNIV (expl_cond_expect M Y X)"
 proof -
   have "disc_fct (expl_cond_expect M Y X)" using assms by (simp add: expl_cond_expect_disc_fct)
   show ?thesis unfolding point_measurable_def
   proof
     show "(expl_cond_expect M Y X)`space M \<subseteq> UNIV" by simp
     show "\<forall>r\<in>range (expl_cond_expect M Y X) \<inter> UNIV. expl_cond_expect M Y X -` {r} \<inter> space M \<in> sets M"
       proof
       fix r
       assume "r\<in> range (expl_cond_expect M Y X) \<inter> UNIV"
       let ?D = "{w \<in> space M. Y w \<in> space N \<and> (expl_cond_expect M Y X w) = r}"
       have "?D \<in> sets M" using expl_cond_expect_prop_sets[of Y M N ?D "\<lambda>x. x = r" X] using assms by simp
       moreover have "expl_cond_expect M Y X -`{r}\<inter> space M = ?D"
       proof
         show "expl_cond_expect M Y X -`{r}\<inter> space M \<subseteq> ?D"
         proof
           fix w
           assume "w\<in> expl_cond_expect M Y X -`{r}\<inter> space M"
           hence "Y w \<in> space N"
             by (meson IntD2 assms(1) assms(2) disct_fct_point_measurable measurable_space)
           thus "w \<in> ?D"
             using \<open>w \<in> expl_cond_expect M Y X -` {r} \<inter> space M\<close> by blast
         qed
         show "?D \<subseteq> expl_cond_expect M Y X -`{r}\<inter> space M"
         proof
           fix w
           assume "w\<in> ?D"
           thus "w\<in> expl_cond_expect M Y X -`{r}\<inter> space M" by blast
         qed
       qed
       ultimately show "expl_cond_expect M Y X -` {r} \<inter> space M \<in> sets M" by simp
     qed
   qed
 qed
 
 lemma  expl_cond_expect_borel_measurable:
   assumes "disc_fct Y"
   and "point_measurable M (space N) Y"
 shows "(expl_cond_expect M Y X) \<in> borel_measurable M" using expl_cond_expect_point_meas[of Y M] assms
           disct_fct_point_measurable[of "expl_cond_expect M Y X"]
         by (simp add: expl_cond_expect_disc_fct)
 
 
 
 lemma  expl_cond_exp_borel:
   assumes "Y \<in> space M \<rightarrow> space N"
   and "disc_fct Y"
   and "\<forall>r\<in> range Y\<inter> space N. \<exists>A\<in> sets N. range Y\<inter> A = {r}"
   shows "(expl_cond_expect M Y X) \<in> borel_measurable (fct_gen_subalgebra M N Y)"
 proof (intro borel_measurableI)
   fix S::"real set"
   assume "open S"
   show "expl_cond_expect M Y X -` S \<inter> space (fct_gen_subalgebra M N Y) \<in> sets (fct_gen_subalgebra M N Y)"
   proof (rule expl_cond_expect_prop_sets2)
     show "disc_fct Y" using assms by simp
     show "point_measurable (fct_gen_subalgebra M N Y) (space N) Y" using  assms
       by (simp add: singl_meas_if)
     show "expl_cond_expect M Y X -` S \<inter> space (fct_gen_subalgebra M N Y) = {w \<in> space M. Y w \<in> space N \<and> (expl_cond_expect M Y X w) \<in> S}"
     proof
       show " expl_cond_expect M Y X -` S \<inter> space (fct_gen_subalgebra M N Y) \<subseteq> {w \<in> space M. Y w \<in> space N \<and> expl_cond_expect M Y X w \<in> S}"
       proof
         fix x
         assume asm: "x \<in> expl_cond_expect M Y X -` S \<inter> space (fct_gen_subalgebra M N Y)"
         hence "expl_cond_expect M Y X x \<in> S" by auto
         moreover have  "x\<in> space M" using asm by (simp add:fct_gen_subalgebra_space)
         ultimately show "x \<in>{w \<in> space M. Y w \<in> space N \<and> expl_cond_expect M Y X w \<in> S}" using assms by auto
       qed
       show "{w \<in> space M. Y w \<in> space N \<and> expl_cond_expect M Y X w \<in> S} \<subseteq> expl_cond_expect M Y X -` S \<inter> space (fct_gen_subalgebra M N Y)"
       proof
         fix x
         assume asm2: "x \<in> {w \<in> space M. Y w \<in> space N \<and> expl_cond_expect M Y X w \<in> S}"
         hence "x\<in> space (fct_gen_subalgebra M N Y)" by (simp add:fct_gen_subalgebra_space)
         moreover have "x \<in> expl_cond_expect M Y X -`S" using asm2 by simp
         ultimately show "x \<in> expl_cond_expect M Y X -` S \<inter> space (fct_gen_subalgebra M N Y)" by simp
       qed
     qed
   qed
 qed
 
 
 
 
 
 lemma  expl_cond_expect_indic_borel_measurable:
   assumes "disc_fct Y"
   and "point_measurable M (space N) Y"
   and "B\<subseteq> space N"
   and "countable B"
   shows "(\<lambda>w. expl_cond_expect M Y X w * indicator (countable_preimages B Y n \<inter> space M) w)\<in> borel_measurable M"
 proof -
   have "countable_preimages B Y n \<inter> space M \<in> sets M" using  assms by (auto simp add: count_pre_meas)
   have "(expl_cond_expect M Y X)\<in> borel_measurable M" using expl_cond_expect_point_meas[of Y M N X] assms
       disct_fct_point_measurable[of "expl_cond_expect M Y X"]
     by (simp add: expl_cond_expect_disc_fct)
   moreover have "(indicator (countable_preimages B Y n \<inter> space M))\<in> borel_measurable M"
     using \<open>countable_preimages B Y n \<inter> space M \<in> sets M\<close> borel_measurable_indicator by blast
   ultimately show ?thesis
     using borel_measurable_times by blast
 qed
 
 
 lemma (in finite_measure) dce_prod:
   assumes "point_measurable M (space N) Y"
    and "integrable M X"
    and "\<forall> w\<in> space M. 0 \<le> X w"
 shows "\<forall> w. (Y w) \<in> space N \<longrightarrow> (expl_cond_expect M Y X) w * measure M ((Y -` {Y w})\<inter> space M) = integral\<^sup>L M (\<lambda>y. (X y) * (indicator ((Y -`{Y w})\<inter> space M) y))"
 proof (intro allI impI)
   fix w
   assume "Y w\<in> space N"
   let ?indY = "(\<lambda>y. indicator ((Y -`{Y w})\<inter> space M) y)::'a \<Rightarrow> real"
   show "expl_cond_expect M Y X w * measure M ((Y -` {Y w})\<inter> space M) = integral\<^sup>L M (\<lambda>y. (X y) * ?indY y) "
   proof (cases "AE y in M. ?indY y = 0")
     case True
     (* Very long proof, Sledgehammer was lost. Everything had to be detailed *)
     hence "emeasure M ((Y -` {Y w})\<inter> space M) = 0"
     proof -
       have "AE y in M. y \<notin>  Y -` {Y w} \<inter> space M"
         using True eventually_elim2 by auto
       hence "\<exists>N\<in> null_sets M.{x\<in> space M. \<not>(x\<notin> Y -` {Y w} \<inter> space M)} \<subseteq> N"
         using eventually_ae_filter[of "\<lambda>x. x \<notin> Y -` {Y w} \<inter> space M" M] by simp
       hence "\<exists>N\<in> null_sets M. {x\<in> space M. x\<in> Y -` {Y w} \<inter> space M} \<subseteq> N" by simp
       from this obtain N where "N\<in> null_sets M" and "{x\<in> space M. x\<in> Y -` {Y w} \<inter> space M} \<subseteq> N" by auto
           note Nprops = this
       have "{x\<in> space M. x\<in> Y -` {Y w}} \<subseteq> N" using Nprops by auto
       hence "emeasure M {x\<in> space M. x\<in> Y -` {Y w}} \<le> emeasure M N"
         by (simp add: emeasure_mono Nprops(1) null_setsD2)
       thus ?thesis
         by (metis (no_types, lifting) Collect_cong Int_def Nprops(1) le_zero_eq null_setsD1)
     qed
     hence "enn2real (emeasure M ((Y -` {Y w})\<inter> space M)) = 0" by simp
     hence "measure M ((Y -` {Y w})\<inter> space M) = 0" unfolding measure_def by simp
     hence lhs: "expl_cond_expect M Y X w = 0" unfolding expl_cond_expect_def img_dce_def by simp
     have  zer: "AE y in M. (X y) * ?indY y = (\<lambda>y. 0) y" using True by auto
     hence rhs: "integral\<^sup>L M  (\<lambda>y. (X y) * ?indY y) = 0"
     proof -
       have "\<forall> w\<in> space M. 0 \<le> X w * ?indY w" using assms by simp
       have "integrable M (\<lambda>y. (X y) * ?indY y)" using assms
-        by (metis (mono_tags, lifting) IntI UNIV_I \<open>Y w \<in> space N\<close> image_eqI integrable_cong integrable_real_mult_indicator point_measurable_def)
+        by (metis (mono_tags, lifting) IntI UNIV_I \<open>Y w \<in> space N\<close> image_eqI Bochner_Integration.integrable_cong integrable_real_mult_indicator point_measurable_def)
       hence "(\<lambda>y. (X y) * ?indY y) \<in> borel_measurable M" by blast
       thus ?thesis using zer integral_cong_AE[of "(\<lambda>y. (X y) * ?indY y)" M "\<lambda>y. 0"] by simp
     qed
     thus "expl_cond_expect M Y X w*measure M ((Y -` {Y w})\<inter> space M) = integral\<^sup>L M (\<lambda>y. (X y) * ?indY y)" using lhs rhs by simp
   next
     case False
     hence "\<not>(AE y in M. y \<notin> (Y -`{Y w})\<inter> space M)"
       by (simp add: indicator_eq_0_iff)
     hence "emeasure M ((Y -` {Y w})\<inter> space M) \<noteq> 0"
     proof -
       have "(Y -` {Y w})\<inter> space M\<in> sets M"
         by (meson IntI UNIV_I \<open>Y w \<in> space N\<close> assms(1) image_eqI point_measurable_def)
       have "(Y -` {Y w})\<inter> space M \<notin> null_sets M"
         using \<open>\<not> (AE y in M. y \<notin> Y -` {Y w} \<inter> space M)\<close> eventually_ae_filter by blast
       thus ?thesis
         using \<open>Y -` {Y w} \<inter> space M \<in> sets M\<close> by blast
     qed
     hence "measure M ((Y -` {Y w})\<inter> space M) \<noteq> 0"
       by (simp add: emeasure_eq_measure)
     thus "expl_cond_expect M Y X w* measure M ((Y -` {Y w})\<inter> space M) = integral\<^sup>L M (\<lambda>y. (X y) * ?indY y)" unfolding expl_cond_expect_def img_dce_def
       using o_apply by auto
   qed
 qed
 
 
 
 lemma  expl_cond_expect_const_exp:
   shows "integral\<^sup>L M (\<lambda>y. expl_cond_expect M Y X w * (indicator (Y -` {Y w} \<inter> space M)) y) =
     integral\<^sup>L M (\<lambda>y. expl_cond_expect M Y X y * (indicator (Y -` {Y w} \<inter> space M)) y)"
 proof -
   let ?ind = "(indicator (Y -` {Y w} \<inter> space M))"
   have "\<forall> y\<in> space M. expl_cond_expect M Y X w * ?ind y = expl_cond_expect M Y X y * ?ind y"
   proof
     fix y
     assume "y\<in> space M"
     show "expl_cond_expect M Y X w * ?ind y = expl_cond_expect M Y X y * ?ind y"
     proof (cases "y\<in> Y -` {Y w} \<inter> space M")
       case False
       thus ?thesis by simp
     next
       case True
       hence "Y w = Y y" by auto
       hence "expl_cond_expect M Y X w = expl_cond_expect M Y X y"
         using expl_cond_expect_const[of Y w y M X] by simp
       thus ?thesis by simp
     qed
   qed
   thus ?thesis
     by (meson Bochner_Integration.integral_cong)
 qed
 
 lemma  nn_expl_cond_expect_const_exp:
   assumes "\<forall>w\<in> space M. 0 \<le> X w"
   shows "integral\<^sup>N M (\<lambda>y. expl_cond_expect M Y X w * (indicator (Y -` {Y w} \<inter> space M)) y) =
     integral\<^sup>N M (\<lambda>y. expl_cond_expect M Y X y * (indicator (Y -` {Y w} \<inter> space M)) y)"
 proof -
   let ?ind = "(indicator (Y -` {Y w} \<inter> space M))"
   have forall: "\<forall> y\<in> space M. expl_cond_expect M Y X w * ?ind y = expl_cond_expect M Y X y * ?ind y"
   proof
     fix y
     assume "y\<in> space M"
     show "expl_cond_expect M Y X w * ?ind y = expl_cond_expect M Y X y * ?ind y"
     proof (cases "y\<in> Y -` {Y w} \<inter> space M")
       case False
       thus ?thesis by simp
     next
       case True
       hence "Y w = Y y" by auto
       hence "expl_cond_expect M Y X w = expl_cond_expect M Y X y"
         using expl_cond_expect_const[of Y] by blast
       thus ?thesis by simp
     qed
   qed
   show ?thesis
     by (metis (no_types, lifting) forall nn_integral_cong)
 qed
 
 
 lemma (in finite_measure) nn_expl_cond_bounded:
   assumes "\<forall>w\<in> space M. 0 \<le> X w"
   and "integrable M X"
   and "point_measurable M (space N) Y"
   and "w\<in> space M"
   and "Y w\<in> space N"
   shows "integral\<^sup>N M (\<lambda>y. expl_cond_expect M Y X y * (indicator (Y -` {Y w} \<inter> space M)) y) < \<infinity>"
 proof -
   let ?ind = "(indicator (Y -` {Y w} \<inter> space M))::'a\<Rightarrow>real"
   have "0 \<le> expl_cond_expect M Y X w" using assms nn_expl_cond_expect_pos[of M X Y] by simp
   have "integrable M (\<lambda>y. expl_cond_expect M Y X w * ?ind y)"
   proof -
     have eq: "(Y -`{Y w} \<inter> space M) \<inter> space M = (Y -`{Y w} \<inter> space M)" by auto
     have "(Y -` {Y w} \<inter> space M) \<in> sets M" using assms
       by (simp add: point_measurable_def)
     moreover have "emeasure M (Y -`{Y w} \<inter> space M) < \<infinity>" by (simp add: inf.strict_order_iff)
     ultimately have "integrable M (\<lambda>y. ?ind y)"
       using integrable_indicator_iff[of M "(Y -`{Y w} \<inter> space M)"] by simp
     thus ?thesis using integrable_mult_left_iff[of M "expl_cond_expect M Y X w" "?ind"] by blast
   qed
   have "\<forall>y\<in> space M. 0 \<le> expl_cond_expect M Y X w * ?ind y"
     using \<open>0 \<le> expl_cond_expect M Y X w\<close> mult_nonneg_nonneg by blast
   hence "\<forall>y\<in> space M. expl_cond_expect M Y X w * ?ind y = norm (expl_cond_expect M Y X w * ?ind y)" by auto
   hence inf: "integral\<^sup>N M (\<lambda>y. expl_cond_expect M Y X w * ?ind y) < \<infinity>"
     using integrable_iff_bounded[of M "(\<lambda>y. expl_cond_expect M Y X w * ?ind y)"]
       \<open>0 \<le> expl_cond_expect M Y X w\<close>  real_norm_def nn_integral_cong
     by (metis (no_types, lifting) \<open>integrable M (\<lambda>y. expl_cond_expect M Y X w * indicator (Y -` {Y w} \<inter> space M) y)\<close>)
   have "integral\<^sup>N M (\<lambda>y. expl_cond_expect M Y X y * ?ind y) =
     integral\<^sup>N M (\<lambda>y. expl_cond_expect M Y X w * ?ind y)" using assms
     by (simp add: nn_expl_cond_expect_const_exp)
   also have "... < \<infinity>"  using inf by simp
   finally show ?thesis .
 qed
 
 
 lemma (in finite_measure)  count_prod:
   fixes Y::"'a\<Rightarrow>'b"
   assumes "B\<subseteq> space N"
   and "point_measurable M (space N) Y"
   and "integrable M X"
   and "\<forall> w \<in> space M. 0 \<le> X w"
 shows "\<forall>i. integral\<^sup>L M (\<lambda>y. (X y) * (indicator (countable_preimages B Y i \<inter> space M)) y) =
   integral\<^sup>L M (\<lambda>y. (expl_cond_expect M Y X y) * (indicator (countable_preimages B Y i \<inter> space M)) y)"
 proof
   fix i
   show "integral\<^sup>L M (\<lambda>y. X y * indicator (countable_preimages B Y i \<inter> space M) y) =
          integral\<^sup>L M (\<lambda>y. expl_cond_expect M Y X y * indicator (countable_preimages B Y i \<inter> space M) y)"
   proof (cases "countable_preimages B Y i \<inter> space M = {}")
     case True
     thus ?thesis by simp
   next
     case False
     from this obtain w where "w\<in> countable_preimages B Y i" by auto
     hence "Y w = (from_nat_into B) i" by (meson count_pre_img)
     hence "Y w \<in> B"
     proof (cases "infinite B")
       case True
       thus ?thesis
         by (simp add: \<open>Y w = from_nat_into B i\<close> from_nat_into infinite_imp_nonempty)
     next
       case False
       thus ?thesis
         by (metis Finite_Set.card_0_eq \<open>Y w = from_nat_into B i\<close> \<open>w \<in> countable_preimages B Y i\<close> countable_preimages_def equals0D from_nat_into gr_implies_not0)
     qed
     let ?ind = "(indicator (Y -` {Y w} \<inter> space M))::'a\<Rightarrow>real"
     have "integral\<^sup>L M (\<lambda>y. (X y) * (indicator (countable_preimages B Y i \<inter> space M)) y) = integral\<^sup>L M (\<lambda>y. X y * ?ind y)"
       by (metis (no_types, opaque_lifting) \<open>Y w = from_nat_into B i\<close> \<open>\<And>thesis. (\<And>w. w \<in> countable_preimages B Y i \<Longrightarrow> thesis) \<Longrightarrow> thesis\<close> countable_preimages_def empty_iff)
     also have "... =
       expl_cond_expect M Y X w * measure M (Y -` {Y w} \<inter> space M)"  using dce_prod[of N Y X]
        by (metis (no_types, lifting) \<open>Y w \<in> B\<close> assms subsetCE)
     also have "... = expl_cond_expect M Y X w * (integral\<^sup>L M ?ind)"
        by auto
     also have "... = integral\<^sup>L M (\<lambda>y. expl_cond_expect M Y X w * ?ind y)"
        by auto
     also have "... = integral\<^sup>L M (\<lambda>y. expl_cond_expect M Y X y * ?ind y)"
     proof -
       have "\<forall> y\<in> space M. expl_cond_expect M Y X w * ?ind y = expl_cond_expect M Y X y * ?ind y"
       proof
         fix y
         assume "y\<in> space M"
         show "expl_cond_expect M Y X w * ?ind y = expl_cond_expect M Y X y * ?ind y"
         proof (cases "y\<in> Y -` {Y w} \<inter> space M")
           case False
           thus ?thesis by simp
         next
           case True
           hence "Y w = Y y" by auto
           hence "expl_cond_expect M Y X w = expl_cond_expect M Y X y"
             using expl_cond_expect_const[of Y] by blast
           thus ?thesis by simp
         qed
       qed
       thus ?thesis
         by (meson Bochner_Integration.integral_cong)
     qed
     also have "... = integral\<^sup>L M (\<lambda>y. expl_cond_expect M Y X y * indicator (countable_preimages B Y i \<inter> space M) y)"
       by (metis (no_types, opaque_lifting) \<open>Y w = from_nat_into B i\<close> \<open>\<And>thesis. (\<And>w. w \<in> countable_preimages B Y i \<Longrightarrow> thesis) \<Longrightarrow> thesis\<close> countable_preimages_def empty_iff)
     finally show ?thesis .
   qed
 qed
 
 
 
 lemma (in finite_measure) count_pre_integrable:
   assumes "point_measurable M (space N) Y"
   and "disc_fct Y"
   and "B\<subseteq> space N"
   and "countable B"
   and "integrable M X"
   and "\<forall> w \<in> space M. 0 \<le> X w"
 shows "integrable M (\<lambda>w. expl_cond_expect M Y X w * indicator (countable_preimages B Y n \<inter> space M) w)"
 proof-
   have "integral\<^sup>L M (\<lambda>y. (X y) * (indicator (countable_preimages B Y n \<inter> space M)) y) =
   integral\<^sup>L M (\<lambda>y. (expl_cond_expect M Y X y) * (indicator (countable_preimages B Y n \<inter> space M)) y)" using assms count_prod
     by blast
   have "\<forall>w \<in> space M. 0 \<le> (expl_cond_expect M Y X w) * (indicator (countable_preimages B Y n \<inter> space M)) w"
     by (simp add: assms nn_expl_cond_expect_pos)
   have "countable_preimages B Y n \<inter> space M \<in> sets M" using count_pre_meas[of M] assms by auto
   hence "integrable M (\<lambda>w. X w * indicator (countable_preimages B Y n \<inter> space M) w)"
     using assms integrable_real_mult_indicator by blast
   show ?thesis
   proof (rule integrableI_nonneg)
     show "(\<lambda>w. expl_cond_expect M Y X w * indicator (countable_preimages B Y n \<inter> space M) w)\<in> borel_measurable M"
     proof -
       have "(expl_cond_expect M Y X)\<in> borel_measurable M" using expl_cond_expect_point_meas[of Y M N X] assms
           disct_fct_point_measurable[of "expl_cond_expect M Y X"]
         by (simp add: expl_cond_expect_disc_fct)
       moreover have "(indicator (countable_preimages B Y n \<inter> space M))\<in> borel_measurable M"
         using \<open>countable_preimages B Y n \<inter> space M \<in> sets M\<close> borel_measurable_indicator by blast
       ultimately show ?thesis
         using borel_measurable_times by blast
     qed
     show "AE x in M. 0 \<le> expl_cond_expect M Y X x * indicator (countable_preimages B Y n \<inter> space M) x"
       by (simp add: \<open>\<forall>w\<in>space M. 0 \<le> expl_cond_expect M Y X w * indicator (countable_preimages B Y n \<inter> space M) w\<close>)
     show "(\<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indicator (countable_preimages B Y n \<inter> space M) x) \<partial>M) < \<infinity>"
     proof (cases "countable_preimages B Y n \<inter> space M = {}")
       case True
       thus ?thesis by simp
     next
       case False
       from this obtain w where "w\<in> countable_preimages B Y n\<inter> space M" by auto
       hence "countable_preimages B Y n = Y -`{Y w}"
         by (metis IntD1 count_pre_img countable_preimages_def equals0D)
       have "w\<in> space M" using False
         using \<open>w \<in> countable_preimages B Y n \<inter> space M\<close> by blast
       moreover have "Y w \<in> space N"
         by (meson \<open>w \<in> space M\<close> assms(1) assms(2) disct_fct_point_measurable measurable_space)
       ultimately show ?thesis using assms nn_expl_cond_bounded[of X N Y]
         using \<open>countable_preimages B Y n = Y -` {Y w}\<close> by presburger
     qed
   qed
 qed
 
 
 
 
 
 lemma (in finite_measure) nn_cond_expl_is_cond_exp_tmp:
   assumes "\<forall> w\<in> space M. 0 \<le> X w"
   and "integrable M X"
   and "disc_fct  Y"
   and "point_measurable M (space M') Y"
 shows "\<forall> A \<in> sets M'. integrable M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator ((Y -`A)\<inter> (space M)) w)) \<and>
   integral\<^sup>L M (\<lambda>w. (X w) * (indicator ((Y -`A)\<inter> (space M)) w)) =
   integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
 proof
   fix A
   assume "A \<in> sets M'"
   let ?imA = "A \<inter> (range Y)"
   have "countable ?imA" using assms disc_fct_def by blast
   have "Y -`A = Y -`?imA" by auto
   define prY where "prY = countable_preimages ?imA Y"
   have un: "Y -`?imA = (\<Union> i. prY i)" using \<open>countable ?imA\<close>
     by (metis count_pre_union_img prY_def)
    have "(Y -`?imA) \<inter> (space M) = (\<Union> i. prY i) \<inter> (space M)" using \<open>Y -`A = Y -`?imA\<close> un  by simp
    also have "... = (\<Union> i. (prY i) \<inter> (space M))" by blast
    finally have eq2: "(Y -`?imA) \<inter> (space M) = (\<Union> i. (prY i) \<inter> (space M))".
    define indpre::"nat \<Rightarrow> 'a \<Rightarrow> real" where "indpre = (\<lambda> i x. (indicator ((prY i) \<inter> (space M))) x)"
    have "\<forall> i. indpre i \<in> borel_measurable M"
    proof
      fix i
      show "indpre i \<in> borel_measurable M" unfolding indpre_def prY_def
      proof (rule borel_measurable_indicator, cases "countable_preimages (A \<inter> range Y) Y i \<inter> space M = {}")
        case True
        thus "countable_preimages (A \<inter> range Y) Y i \<inter> space M \<in> sets M" by simp
      next
        case False
        from this obtain x where "x\<in> countable_preimages (A \<inter> range Y) Y i \<inter> space M" by blast
            hence "Y x \<in> space M'"
              by (metis Int_iff UN_I \<open>A \<in> sets M'\<close> \<open>prY \<equiv> countable_preimages (A \<inter> range Y) Y\<close> imageE
                  rangeI sets.sets_into_space subset_eq un vimage_eq)
            thus "countable_preimages (A \<inter> range Y) Y i \<inter> space M \<in> sets M"
              by (metis IntE IntI \<open>x \<in> countable_preimages (A \<inter> range Y) Y i \<inter> space M\<close> assms(4)
                  count_pre_img countable_preimages_def empty_iff point_measurable_def rangeI)
      qed
    qed
    have "\<forall>i. integrable M (\<lambda>w. (X w) * indpre i w)"
    proof
      fix i
      show "integrable M (\<lambda>w. (X w) * indpre i w)" unfolding indpre_def prY_def
      proof (rule integrable_real_mult_indicator)
        show "countable_preimages (A \<inter> range Y) Y i \<inter> space M \<in> sets M"
        proof (cases "countable_preimages (A \<inter> range Y) Y i = {}")
          case True
          thus "countable_preimages (A \<inter> range Y) Y i \<inter> space M \<in> sets M"  by (simp add: True)
        next
          case False
          hence "Y -` {(from_nat_into (A \<inter> range Y)) i} \<noteq> {}"  unfolding countable_preimages_def by meson
          have "(infinite (A \<inter> range Y)) \<or> (finite (A \<inter> range Y) \<and> i < card (A \<inter> range Y))" using False unfolding countable_preimages_def
            by meson
          show ?thesis
            by (metis \<open>A \<in> sets M'\<close> \<open>countable (A \<inter> range Y)\<close> assms(4) count_pre_meas le_inf_iff
                range_from_nat_into sets.Int_space_eq1 sets.empty_sets sets.sets_into_space subset_range_from_nat_into)
        qed
        show "integrable M X" using assms by simp
      qed
    qed
    hence prod_bm: "\<forall> i. (\<lambda>w. (X w) * indpre i w) \<in> borel_measurable M"
      by (simp add: assms(2) borel_measurable_integrable borel_measurable_times)
    have posprod: "\<forall> i w. 0 \<le> (X w) * indpre i w"
    proof (intro allI)
      fix i
      fix w
      show "0 \<le> (X w) * indpre i w"
        by (metis IntE assms(1) indicator_pos_le indicator_simps(2) indpre_def mult_eq_0_iff mult_sign_intros(1))
    qed
    let ?indA = "indicator ((Y -`(A \<inter> range Y))\<inter> (space M))::'a\<Rightarrow>real"
 
    have "\<forall> i j. i \<noteq> j \<longrightarrow> ((prY i) \<inter> (space M)) \<inter> ((prY j) \<inter> (space M)) = {}"
      by (simp add: \<open>countable (A \<inter> range Y)\<close> \<open>prY \<equiv> countable_preimages (A \<inter> range Y) Y\<close> count_pre_disj inf_commute inf_sup_aci(3))
    hence sumind: "\<forall>x. (\<lambda>i. indpre i x) sums ?indA x" using \<open>countable ?imA\<close> eq2 unfolding prY_def indpre_def
      by (metis indicator_sums)
    hence sumxlim: "\<forall>x. (\<lambda>i. (X x) * indpre i x::real) sums ((X x) * indicator ((Y -`?imA) \<inter> (space M)) x)" using \<open>countable ?imA\<close> unfolding prY_def
      using sums_mult by blast
    hence sum: "\<forall>x. (\<Sum> i.((X x) * indpre i x)::real) = (X x) * indicator ((Y -`?imA) \<inter> (space M)) x"  by (metis sums_unique)
    hence b: "\<forall> w. 0 \<le> (\<Sum> i.((X w) * indpre i w))" using suminf_nonneg
      by (metis \<open>\<forall>x. (\<lambda>i. X x * indpre i x) sums (X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x)\<close> posprod summable_def)
    have sumcondlim: "\<forall>x. (\<lambda>i. (expl_cond_expect M Y X x) * indpre i x::real) sums ((expl_cond_expect M Y X x) * ?indA x)" using \<open>countable ?imA\<close> unfolding prY_def
      using sums_mult sumind by blast
 
    have "integrable M (\<lambda>w. (X w) * ?indA w)"
    proof (rule integrable_real_mult_indicator)
      show "Y -` (A\<inter> range Y) \<inter> space M \<in> sets M"
        using \<open>A \<in> sets M'\<close> assms(3) assms(4) disct_fct_point_measurable measurable_sets
        by (metis \<open>Y -` A = Y -` (A \<inter> range Y)\<close>)
      show "integrable M X" using assms by simp
    qed
    hence intsum: "integrable M (\<lambda>w. (\<Sum>i. ((X w) * indpre i w)))" using sum
-       integrable_cong[of M M "\<lambda> w.(X w) * (indicator ((Y -`A)\<inter> (space M)) w)" "\<lambda>w. (\<Sum> i.((X w) * indpre i w))"]
+       Bochner_Integration.integrable_cong[of M M "\<lambda> w.(X w) * (indicator ((Y -`A)\<inter> (space M)) w)" "\<lambda>w. (\<Sum> i.((X w) * indpre i w))"]
      using \<open>Y -` A = Y -` (A \<inter> range Y)\<close> by presburger
    have "integral\<^sup>L M (\<lambda>w. (X w) * ?indA w) = integral\<^sup>L M (\<lambda>w. (\<Sum> i.((X w) * indpre i w)))"
      using \<open>Y -` A = Y -` (A \<inter> range Y)\<close> sum by auto
    also have "... =
       \<integral>\<^sup>+ w.   ((\<Sum> i. ((X w) * indpre i w))) \<partial>M" using nn_integral_eq_integral
      by (metis (mono_tags, lifting) AE_I2 intsum b  nn_integral_cong)
    also have "(\<integral>\<^sup>+ w.   ((\<Sum> i. ((X w) * indpre i w))) \<partial>M) =  \<integral>\<^sup>+ w.   ((\<Sum> i. ennreal ((X w) * indpre i w))) \<partial>M" using suminf_ennreal2 summable_def posprod sum sumxlim
    proof -
      { fix aa :: 'a
        have "\<forall>a. ennreal (\<Sum>n. X a * indpre n a) = (\<Sum>n. ennreal (X a * indpre n a))"
          by (metis (full_types) posprod suminf_ennreal2 summable_def sumxlim)
        then have "(\<integral>\<^sup>+ a. ennreal (\<Sum>n. X a * indpre n a) \<partial>M) = (\<integral>\<^sup>+ a. (\<Sum>n. ennreal (X a * indpre n a)) \<partial>M) \<or> ennreal (\<Sum>n. X aa * indpre n aa) = (\<Sum>n. ennreal (X aa * indpre n aa))"
          by metis }
      then show ?thesis
        by presburger
    qed
    also have "... = (\<Sum>i. integral\<^sup>N M ((\<lambda>i w. (X w) * indpre i w) i))"
    proof (intro nn_integral_suminf)
      fix i
      show "(\<lambda>x. ennreal (X x * indpre i x))\<in> borel_measurable M"
        using measurable_compose_rev measurable_ennreal prod_bm by blast
    qed
    also have "... = (\<Sum>i. integral\<^sup>N M ((\<lambda>i w. (expl_cond_expect M Y X w) * indpre i w) i))"
    proof (intro suminf_cong)
      fix n
      have "A \<inter> range Y \<subseteq> space M'"
        using \<open>A \<in> sets M'\<close> sets.Int_space_eq1 by auto
      have "integral\<^sup>N M (\<lambda>w. (X w) * indpre n w) = integral\<^sup>L M (\<lambda>w. (X w) * indpre n w)"
        using nn_integral_eq_integral[of M "\<lambda>w. (X w) * indpre n w"]
        by (simp add: \<open>\<forall>i. integrable M (\<lambda>w. X w * indpre i w)\<close> posprod)
      also have "... = integral\<^sup>L M (\<lambda>w. (expl_cond_expect M Y X) w * indpre n w)"
      proof -
        have "integral\<^sup>L M (\<lambda>w. X w * indicator (countable_preimages (A \<inter> range Y) Y n \<inter> space M) w) =
          integral\<^sup>L M (\<lambda>w. expl_cond_expect M Y X w * indicator (countable_preimages (A \<inter> range Y) Y n \<inter> space M) w)"
          using count_prod[of "A\<inter> range Y" "M'" Y X ] assms \<open>A \<inter> range Y \<subseteq> space M'\<close> by blast
        thus ?thesis
          using \<open>indpre \<equiv> \<lambda>i. indicator (prY i \<inter> space M)\<close> prY_def by presburger
      qed
      also have "... = integral\<^sup>N M (\<lambda>w. (expl_cond_expect M Y X) w * indpre n w)"
      proof -
        have "integrable M (\<lambda>w. (expl_cond_expect M Y X) w * indpre n w)" unfolding indpre_def prY_def
        using count_pre_integrable assms \<open>A \<inter> range Y \<subseteq> space M'\<close> \<open>countable (A \<inter> range Y)\<close> by blast
        moreover have "AE w in M. 0 \<le> (expl_cond_expect M Y X) w * indpre n w"
          by (simp add: \<open>indpre \<equiv> \<lambda>i. indicator (prY i \<inter> space M)\<close> assms(1) nn_expl_cond_expect_pos)
        ultimately show ?thesis by (simp add:nn_integral_eq_integral)
      qed
      finally show "integral\<^sup>N M (\<lambda>w. (X w) * indpre n w) = integral\<^sup>N M (\<lambda>w. (expl_cond_expect M Y X) w * indpre n w)" .
    qed
    also have "... = integral\<^sup>N M (\<lambda>w. \<Sum>i. ((expl_cond_expect M Y X w) * indpre i w))"
    proof -
      have "(\<lambda>x. (\<Sum>i. ennreal (expl_cond_expect M Y X x * indpre i x))) =
       (\<lambda>x. ennreal (\<Sum>i. (expl_cond_expect M Y X x * indpre i x)))"
      proof-
        have posex: "\<forall> i x. 0 \<le> (expl_cond_expect M Y X x) * (indpre i x)"
          by (metis IntE \<open>indpre \<equiv> \<lambda>i. indicator (prY i \<inter> space M)\<close> assms(1) indicator_pos_le indicator_simps(2) mult_eq_0_iff mult_sign_intros(1) nn_expl_cond_expect_pos)
        have "\<forall>x. (\<Sum>i. ennreal (expl_cond_expect M Y X x * indpre i x)) =  (ennreal (\<Sum>i. (expl_cond_expect M Y X x * indpre i x)))"
        proof
          fix x
          show "(\<Sum>i. ennreal (expl_cond_expect M Y X x * indpre i x)) =  (ennreal (\<Sum>i. (expl_cond_expect M Y X x * indpre i x)))"
            using suminf_ennreal2[of "\<lambda>i. (expl_cond_expect M Y X x * indpre i x)"] sumcondlim summable_def posex
          proof -
            have f1: "summable (\<lambda>n. expl_cond_expect M Y X x * indpre n x)"
              using sumcondlim summable_def by blast
            obtain nn :: nat where
              "\<not> 0 \<le> expl_cond_expect M Y X x * indpre nn x \<or> \<not> summable (\<lambda>n. expl_cond_expect M Y X x * indpre n x) \<or> ennreal (\<Sum>n. expl_cond_expect M Y X x * indpre n x) = (\<Sum>n. ennreal (expl_cond_expect M Y X x * indpre n x))"
              by (metis (full_types) \<open>\<lbrakk>\<And>i. 0 \<le> expl_cond_expect M Y X x * indpre i x; summable (\<lambda>i. expl_cond_expect M Y X x * indpre i x)\<rbrakk> \<Longrightarrow> (\<Sum>i. ennreal (expl_cond_expect M Y X x * indpre i x)) = ennreal (\<Sum>i. expl_cond_expect M Y X x * indpre i x)\<close>)
            then show ?thesis
              using f1 posex by presburger
          qed
        qed
        thus ?thesis by simp
      qed
      have "\<forall>i. (\<lambda>w. (expl_cond_expect M Y X w) * indpre i w) \<in> borel_measurable M"
      proof -
        show ?thesis
          using \<open>\<forall>i. (indpre i)\<in> borel_measurable M\<close> assms(3) assms(4) borel_measurable_times expl_cond_expect_borel_measurable by blast
      qed
      hence "\<And>i. (\<lambda>x. ennreal (expl_cond_expect M Y X x * indpre i x))\<in> borel_measurable M"
        using measurable_compose_rev measurable_ennreal by blast
      thus ?thesis using nn_integral_suminf[of "(\<lambda>i w.  (expl_cond_expect M Y X w) * indpre i w)" M, symmetric]
        using \<open>(\<lambda>x. \<Sum>i. ennreal (expl_cond_expect M Y X x * indpre i x)) = (\<lambda>x. ennreal (\<Sum>i. expl_cond_expect M Y X x * indpre i x))\<close> by auto
    qed
    also have "... = integral\<^sup>N M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)"
      using sumcondlim
      by (metis (no_types, lifting) sums_unique)
    also have "... = integral\<^sup>L M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)"
    proof -
      have scdint: "integrable M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)"
      proof -
        have rv: "(\<lambda>w. (expl_cond_expect M Y X w) * indicator ((Y -`?imA) \<inter> (space M)) w) \<in> borel_measurable M"
        proof -
          have "expl_cond_expect M Y X \<in> borel_measurable M" using expl_cond_expect_borel_measurable
            using assms by blast
          moreover have "(Y -`?imA) \<inter> (space M) \<in> sets M"
            by (metis \<open>A \<in> sets M'\<close> \<open>Y -` A = Y -` (A \<inter> range Y)\<close> assms(3) assms(4) disct_fct_point_measurable measurable_sets)
          ultimately show ?thesis
            using borel_measurable_indicator_iff borel_measurable_times  by blast
        qed
        moreover have born:  "integral\<^sup>N M (\<lambda>w. ennreal (norm (expl_cond_expect M Y X w * ?indA w))) < \<infinity>"
        proof -
          have "integral\<^sup>N M (\<lambda>w. ennreal (norm (expl_cond_expect M Y X w * ?indA w))) =
             integral\<^sup>N M (\<lambda>w. ennreal (expl_cond_expect M Y X w * ?indA w))"
          proof -
            have "\<forall>w\<in> space M. norm (expl_cond_expect M Y X w * ?indA w) = expl_cond_expect M Y X w * ?indA w"
              using nn_expl_cond_expect_pos by (simp add: nn_expl_cond_expect_pos assms(1))
            thus ?thesis by (metis (no_types, lifting) nn_integral_cong)
          qed
          thus ?thesis
            by (metis (no_types, lifting)
              \<open>(\<Sum>i. \<integral>\<^sup>+ x. ennreal (X x * indpre i x) \<partial>M) = (\<Sum>i. \<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indpre i x) \<partial>M)\<close>
              \<open>(\<Sum>i. \<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indpre i x) \<partial>M) = (\<integral>\<^sup>+ x. ennreal (\<Sum>i. expl_cond_expect M Y X x * indpre i x) \<partial>M)\<close>
              \<open>(\<integral>\<^sup>+ w. (\<Sum>i. ennreal (X w * indpre i w)) \<partial>M) = (\<Sum>i. \<integral>\<^sup>+ x. ennreal (X x * indpre i x) \<partial>M)\<close>
              \<open>(\<integral>\<^sup>+ x. ennreal (\<Sum>i. X x * indpre i x) \<partial>M) = (\<integral>\<^sup>+ w. (\<Sum>i. ennreal (X w * indpre i w)) \<partial>M)\<close>
              \<open>(\<integral>\<^sup>+ x. ennreal (\<Sum>i. expl_cond_expect M Y X x * indpre i x) \<partial>M) = (\<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x) \<partial>M)\<close>
              \<open>ennreal (integral\<^sup>L M (\<lambda>w. \<Sum>i. X w * indpre i w)) = (\<integral>\<^sup>+ x. ennreal (\<Sum>i. X x * indpre i x) \<partial>M)\<close>
              ennreal_less_top infinity_ennreal_def)
          qed
        show "integrable M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)"
        proof (rule iffD2[OF integrable_iff_bounded])
          show "((\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` (A \<inter> range Y) \<inter> space M) w) \<in> borel_measurable M) \<and>
           ((\<integral>\<^sup>+ x. (ennreal (norm (expl_cond_expect M Y X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x))) \<partial>M) < \<infinity>)"
          proof
            show "(\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` (A \<inter> range Y) \<inter> space M) w)\<in> borel_measurable M"
              using rv by simp
            show "(\<integral>\<^sup>+ x. ennreal (norm (expl_cond_expect M Y X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x)) \<partial>M) < \<infinity>"
              using born by simp
          qed
        qed
      qed
      moreover have "\<forall>w\<in> space M. 0 \<le> (expl_cond_expect M Y X w) * indicator ((Y -`?imA) \<inter> (space M)) w"
        by (simp add: assms(1) nn_expl_cond_expect_pos)
      ultimately show ?thesis using nn_integral_eq_integral
        by (metis (mono_tags, lifting) AE_I2 nn_integral_cong)
    qed
    finally have myeq: "ennreal (integral\<^sup>L M (\<lambda>w. (X w) * ?indA w)) = integral\<^sup>L M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)" .
 
     thus "integrable M (\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` A \<inter> space M) w) \<and> integral\<^sup>L M (\<lambda>w. X w * indicator (Y -` A \<inter> space M) w) =
          integral\<^sup>L M  (\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` A \<inter> space M) w)"
     proof -
       have "0 \<le> integral\<^sup>L M (\<lambda>w. X w * indicator (Y -` A \<inter> space M) w)"
         using \<open>Y -` A = Y -` (A \<inter> range Y)\<close> b sum by fastforce
       moreover have "0 \<le> integral\<^sup>L M (\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` A \<inter> space M) w)"
         by (simp add:  assms(1) nn_expl_cond_expect_pos)
       ultimately have expeq: "integral\<^sup>L M (\<lambda>w. X w * indicator (Y -` A \<inter> space M) w) =
          integral\<^sup>L M  (\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` A \<inter> space M) w)"
         by (metis (mono_tags, lifting) Bochner_Integration.integral_cong \<open>Y -` A = Y -` (A \<inter> range Y)\<close> ennreal_inj myeq)
       have "integrable M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)"
        proof -
          have rv: "(\<lambda>w. (expl_cond_expect M Y X w) * indicator ((Y -`?imA) \<inter> (space M)) w) \<in> borel_measurable M"
          proof -
            have "expl_cond_expect M Y X \<in> borel_measurable M" using expl_cond_expect_borel_measurable
              using assms by blast
            moreover have "(Y -`?imA) \<inter> (space M) \<in> sets M"
              by (metis \<open>A \<in> sets M'\<close> \<open>Y -` A = Y -` (A \<inter> range Y)\<close> assms(3) assms(4) disct_fct_point_measurable measurable_sets)
            ultimately show ?thesis
              using borel_measurable_indicator_iff borel_measurable_times  by blast
          qed
          moreover have born:  "integral\<^sup>N M (\<lambda>w. ennreal (norm (expl_cond_expect M Y X w * ?indA w))) < \<infinity>"
          proof -
            have "integral\<^sup>N M (\<lambda>w. ennreal (norm (expl_cond_expect M Y X w * ?indA w))) =
               integral\<^sup>N M (\<lambda>w. ennreal (expl_cond_expect M Y X w * ?indA w))"
            proof -
              have "\<forall>w\<in> space M. norm (expl_cond_expect M Y X w * ?indA w) = expl_cond_expect M Y X w * ?indA w"
                using nn_expl_cond_expect_pos by (simp add: nn_expl_cond_expect_pos assms(1))
              thus ?thesis by (metis (no_types, lifting) nn_integral_cong)
            qed
            thus ?thesis
              by (metis (no_types, lifting)
                \<open>(\<Sum>i. \<integral>\<^sup>+ x. ennreal (X x * indpre i x) \<partial>M) = (\<Sum>i. \<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indpre i x) \<partial>M)\<close>
                \<open>(\<Sum>i. \<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indpre i x) \<partial>M) = (\<integral>\<^sup>+ x. ennreal (\<Sum>i. expl_cond_expect M Y X x * indpre i x) \<partial>M)\<close>
                \<open>(\<integral>\<^sup>+ w. (\<Sum>i. ennreal (X w * indpre i w)) \<partial>M) = (\<Sum>i. \<integral>\<^sup>+ x. ennreal (X x * indpre i x) \<partial>M)\<close>
                \<open>(\<integral>\<^sup>+ x. ennreal (\<Sum>i. X x * indpre i x) \<partial>M) = (\<integral>\<^sup>+ w. (\<Sum>i. ennreal (X w * indpre i w)) \<partial>M)\<close>
                \<open>(\<integral>\<^sup>+ x. ennreal (\<Sum>i. expl_cond_expect M Y X x * indpre i x) \<partial>M) = (\<integral>\<^sup>+ x. ennreal (expl_cond_expect M Y X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x) \<partial>M)\<close>
                \<open>ennreal (integral\<^sup>L M (\<lambda>w. \<Sum>i. X w * indpre i w)) = (\<integral>\<^sup>+ x. ennreal (\<Sum>i. X x * indpre i x) \<partial>M)\<close>
                ennreal_less_top infinity_ennreal_def)
            qed
          show "integrable M (\<lambda>w. (expl_cond_expect M Y X w) * ?indA w)"
          proof (rule iffD2[OF integrable_iff_bounded])
            show "((\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` (A \<inter> range Y) \<inter> space M) w) \<in> borel_measurable M) \<and>
             ((\<integral>\<^sup>+ x. (ennreal (norm (expl_cond_expect M Y X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x))) \<partial>M) < \<infinity>)"
            proof
              show "(\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` (A \<inter> range Y) \<inter> space M) w)\<in> borel_measurable M"
                using rv by simp
              show "(\<integral>\<^sup>+ x. ennreal (norm (expl_cond_expect M Y X x * indicator (Y -` (A \<inter> range Y) \<inter> space M) x)) \<partial>M) < \<infinity>"
                using born by simp
            qed
          qed
        qed
        hence "integrable M (\<lambda>w. expl_cond_expect M Y X w * indicator (Y -` A \<inter> space M) w)"
          using \<open>Y -` A = Y -` (A \<inter> range Y)\<close> by presburger
       thus ?thesis  using expeq by simp
     qed
   qed
 
 
 
 lemma (in finite_measure) nn_expl_cond_exp_integrable:
   assumes "\<forall> w\<in> space M. 0 \<le> X w"
   and "integrable M X"
   and "disc_fct  Y"
   and "point_measurable M (space N) Y"
 shows "integrable M (expl_cond_expect M Y X)"
 proof -
   have "Y-`space N \<inter> space M = space M"
     by (meson assms(3) assms(4) disct_fct_point_measurable inf_absorb2 measurable_space subsetI vimageI)
   let ?indA = "indicator ((Y -`space N)\<inter> (space M))::'a\<Rightarrow>real"
   have "\<forall>w\<in> space M. (?indA w)= (1::real)" by (simp add: \<open>Y -` space N \<inter> space M = space M\<close>)
   hence "\<forall>w\<in> space M. ((expl_cond_expect M Y X) w) * (?indA w) = (expl_cond_expect M Y X) w" by simp
   moreover have "integrable M (\<lambda>w. ((expl_cond_expect M Y X) w) * (?indA w))" using assms
       nn_cond_expl_is_cond_exp_tmp[of X Y N] by blast
-  ultimately show ?thesis by (metis (no_types, lifting) integrable_cong)
+  ultimately show ?thesis by (metis (no_types, lifting) Bochner_Integration.integrable_cong)
 qed
 
 lemma (in finite_measure) nn_cond_expl_is_cond_exp:
   assumes "\<forall> w\<in> space M. 0 \<le> X w"
   and "integrable M X"
   and "disc_fct  Y"
   and "point_measurable M (space N) Y"
 shows "\<forall> A \<in> sets N. integral\<^sup>L M (\<lambda>w. (X w) * (indicator ((Y -`A)\<inter> (space M)) w)) =
   integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
   by (metis (mono_tags, lifting) assms nn_cond_expl_is_cond_exp_tmp)
 
 lemma (in finite_measure) expl_cond_exp_integrable:
   assumes "integrable M X"
     and "disc_fct Y"
     and "point_measurable M (space N) Y"
   shows "integrable M (expl_cond_expect M Y X)"
 proof -
   let ?zer = "\<lambda>w. 0"
   let ?Xp = "\<lambda>w. max (?zer w) (X w)"
   let ?Xn = "\<lambda>w. max (?zer 0) (-X w)"
   have "\<forall>w. X w = ?Xp w - ?Xn w" by auto
   have ints: "integrable M ?Xp" "integrable M ?Xn" using integrable_max assms by auto
   hence "integrable M (expl_cond_expect M Y ?Xp)" using assms nn_expl_cond_exp_integrable
     by (metis max.cobounded1)
   moreover have "integrable M (expl_cond_expect M Y ?Xn)" using ints assms nn_expl_cond_exp_integrable
     by (metis max.cobounded1)
   ultimately have integr: "integrable M (\<lambda>w. (expl_cond_expect M Y ?Xp) w - (expl_cond_expect M Y ?Xn) w)" by auto
   have "\<forall>w\<in> space M. (expl_cond_expect M Y ?Xp) w - (expl_cond_expect M Y ?Xn) w = (expl_cond_expect M Y X) w"
   proof
     fix w
     assume "w\<in> space M"
     hence "(expl_cond_expect M Y ?Xp) w - (expl_cond_expect M Y ?Xn) w = (expl_cond_expect M Y (\<lambda>x. ?Xp x - ?Xn x)) w"
       using ints by (simp add: expl_cond_exp_diff)
     also have "... = expl_cond_expect M Y X w" using expl_cond_exp_cong \<open>\<forall>w. X w = ?Xp w - ?Xn w\<close> by auto
     finally show "(expl_cond_expect M Y ?Xp) w - (expl_cond_expect M Y ?Xn) w = expl_cond_expect M Y X w" .
   qed
   thus ?thesis using integr
-    by (metis (mono_tags, lifting) integrable_cong)
+    by (metis (mono_tags, lifting) Bochner_Integration.integrable_cong)
 qed
 
 
 lemma (in finite_measure) is_cond_exp:
   assumes "integrable M X"
   and "disc_fct  Y"
   and "point_measurable M (space N) Y"
 shows "\<forall> A \<in> sets N. integral\<^sup>L M (\<lambda>w. (X w) * (indicator ((Y -`A)\<inter> (space M)) w)) =
   integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
 proof -
   let ?zer = "\<lambda>w. 0"
   let ?Xp = "\<lambda>w. max (?zer w) (X w)"
   let ?Xn = "\<lambda>w. max (?zer 0) (-X w)"
   have "\<forall>w. X w = ?Xp w - ?Xn w" by auto
   have ints: "integrable M ?Xp" "integrable M ?Xn" using integrable_max assms by auto
   hence posint: "integrable M (expl_cond_expect M Y ?Xp)" using assms nn_expl_cond_exp_integrable
     by (metis max.cobounded1)
   have negint: "integrable M (expl_cond_expect M Y ?Xn)" using ints assms nn_expl_cond_exp_integrable
     by (metis max.cobounded1)
   have eqp: "\<forall> A \<in> sets N. integral\<^sup>L M (\<lambda>w. (?Xp w) * (indicator ((Y -`A)\<inter> (space M)) w)) =
     integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y ?Xp) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
     using nn_cond_expl_is_cond_exp[of ?Xp Y N] assms  by auto
   have eqn: "\<forall> A \<in> sets N. integral\<^sup>L M (\<lambda>w. (?Xn w) * (indicator ((Y -`A)\<inter> (space M)) w)) =
     integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y ?Xn) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
     using nn_cond_expl_is_cond_exp[of ?Xn Y N] assms  by auto
 
   show "\<forall> A \<in> sets N. integral\<^sup>L M (\<lambda>w. (X w) * (indicator ((Y -`A)\<inter> (space M)) w)) =
     integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
   proof
     fix A
     assume "A\<in> sets N"
     let ?imA = "A \<inter> (range Y)"
     have "countable ?imA" using assms disc_fct_def by blast
     have "Y -`A = Y -`?imA" by auto
     have yev: "Y -` (A\<inter> range Y) \<inter> space M \<in> sets M"
         using \<open>A \<in> sets N\<close> assms(3) assms(2) disct_fct_point_measurable measurable_sets
         by (metis \<open>Y -` A = Y -` (A \<inter> range Y)\<close>)
     let ?indA = "indicator ((Y -`(A \<inter> range Y))\<inter> (space M))::'a\<Rightarrow>real"
     have intp: "integrable M (\<lambda>w. (?Xp w) * ?indA w)"
     proof (rule integrable_real_mult_indicator)
       show "Y -` (A\<inter> range Y) \<inter> space M \<in> sets M" using yev by simp
       show "integrable M ?Xp" using assms by simp
     qed
     have intn: "integrable M (\<lambda>w. (?Xn w) * ?indA w)"
     proof (rule integrable_real_mult_indicator)
       show "Y -` (A\<inter> range Y) \<inter> space M \<in> sets M" using yev by simp
       show "integrable M ?Xn" using assms by simp
     qed
     have exintp: "integrable M (\<lambda>w. (expl_cond_expect M Y ?Xp w) * ?indA w)"
     proof (rule integrable_real_mult_indicator)
       show "Y -` (A\<inter> range Y) \<inter> space M \<in> sets M" using yev by simp
       show "integrable M (expl_cond_expect M Y ?Xp)" using posint by simp
     qed
     have exintn: "integrable M (\<lambda>w. (expl_cond_expect M Y ?Xn w) * ?indA w)"
     proof (rule integrable_real_mult_indicator)
       show "Y -` (A\<inter> range Y) \<inter> space M \<in> sets M" using yev by simp
       show "integrable M (expl_cond_expect M Y ?Xn)" using negint by simp
     qed
     have "integral\<^sup>L M (\<lambda>w. X w * indicator (Y -` A \<inter> space M) w) =
       integral\<^sup>L M (\<lambda>w. (?Xp w - ?Xn w) * indicator (Y -` A \<inter> space M) w)"
       using \<open>\<forall>w. X w =?Xp w - ?Xn w\<close> by auto
     also have "... =   integral\<^sup>L M (\<lambda>w. (?Xp w * indicator (Y -` A \<inter> space M) w) - ?Xn w * indicator (Y -` A \<inter> space M) w)"
       by (simp add: left_diff_distrib)
     also have "... = integral\<^sup>L M (\<lambda>w. (?Xp w * indicator (Y -` A \<inter> space M) w)) -
       integral\<^sup>L M (\<lambda>w. ?Xn w * indicator (Y -` A \<inter> space M) w)"
       using \<open>Y -` A = Y -` (A \<inter> range Y)\<close> intp intn by auto
     also have "... = integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y ?Xp) w) * (indicator ((Y -`A) \<inter> (space M))) w) -
       integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y ?Xn) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
       using eqp eqn by (simp add: \<open>A \<in> sets N\<close>)
     also have "... = integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y ?Xp) w) * (indicator ((Y -`A) \<inter> (space M))) w -
       ((expl_cond_expect M Y ?Xn) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
       using \<open>Y -` A = Y -` (A \<inter> range Y)\<close> exintn exintp by auto
     also have "... = integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y ?Xp) w - (expl_cond_expect M Y ?Xn) w) * (indicator ((Y -`A) \<inter> (space M))) w)"
       by (simp add: left_diff_distrib)
     also have "... = integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y (\<lambda>x. ?Xp x - ?Xn x) w) * (indicator ((Y -`A) \<inter> (space M))) w))"
       using expl_cond_exp_diff[of M ?Xp ?Xn Y] ints by (metis (mono_tags, lifting) Bochner_Integration.integral_cong)
     also have "... = integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X w) * (indicator ((Y -`A) \<inter> (space M))) w))"
       using \<open>\<forall>w. X w = ?Xp w - ?Xn w\<close> expl_cond_exp_cong[of M X "\<lambda>x. ?Xp x - ?Xn x" Y] by presburger
     finally show "integral\<^sup>L M (\<lambda>w. X w * indicator (Y -` A \<inter> space M) w) = integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X w) * (indicator ((Y -`A) \<inter> (space M))) w))" .
   qed
 qed
 
 
 lemma (in finite_measure) charact_cond_exp:
   assumes "disc_fct Y"
     and "integrable M X"
     and "point_measurable M (space N) Y"
     and "Y \<in> space M \<rightarrow> space N"
     and "\<forall>r\<in> range Y\<inter> space N. \<exists>A\<in> sets N. range Y\<inter> A = {r}"
   shows "AE w in M. real_cond_exp M (fct_gen_subalgebra M N Y) X w = expl_cond_expect M Y X w"
 proof (rule sigma_finite_subalgebra.real_cond_exp_charact)
   have "Y\<in> measurable M N"
     by (simp add: assms(1) assms(3) disct_fct_point_measurable)
   have "point_measurable M (space N) Y" by (simp add: assms(3))
   show "sigma_finite_subalgebra M (fct_gen_subalgebra M N Y)" unfolding sigma_finite_subalgebra_def
   proof
     show "subalgebra M (fct_gen_subalgebra M N Y)" using \<open>Y\<in> measurable M N\<close> by (simp add: fct_gen_subalgebra_is_subalgebra)
     show "sigma_finite_measure (restr_to_subalg M (fct_gen_subalgebra M N Y))" unfolding sigma_finite_measure_def
     proof (intro exI conjI)
       let ?A = "{space M}"
       show "countable ?A" by simp
       show "?A \<subseteq> sets (restr_to_subalg M (fct_gen_subalgebra M N Y))"
         by (metis empty_subsetI insert_subset sets.top space_restr_to_subalg)
       show "\<Union> ?A = space (restr_to_subalg M (fct_gen_subalgebra M N Y))"
         by (simp add: space_restr_to_subalg)
       show "\<forall>a\<in>{space M}. emeasure (restr_to_subalg M (fct_gen_subalgebra M N Y)) a \<noteq> \<infinity>"
         by (metis \<open>subalgebra M (fct_gen_subalgebra M N Y)\<close> emeasure_finite emeasure_restr_to_subalg infinity_ennreal_def sets.top singletonD subalgebra_def)
     qed
   qed
   show "integrable M X" using assms by simp
   show "expl_cond_expect M Y X \<in> borel_measurable (fct_gen_subalgebra M N Y)" using assms by (simp add:expl_cond_exp_borel)
   show "integrable M (expl_cond_expect M Y X)"
     using assms expl_cond_exp_integrable  by blast
   have "\<forall>A\<in> sets M. integral\<^sup>L M (\<lambda>w. (X w) * (indicator A w)) = set_lebesgue_integral M A X"
     by (metis (no_types, lifting) Bochner_Integration.integral_cong mult_commute_abs real_scaleR_def set_lebesgue_integral_def)
    have "\<forall>A\<in> sets M. integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator A w)) = set_lebesgue_integral M A (expl_cond_expect M Y X)"
     by (metis (no_types, lifting) Bochner_Integration.integral_cong mult_commute_abs real_scaleR_def set_lebesgue_integral_def)
   have "\<forall>A\<in> sets (fct_gen_subalgebra M N Y). integral\<^sup>L M (\<lambda>w. (X w) * (indicator A w)) =
   integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator A w))"
   proof
     fix A
     assume "A \<in> sets (fct_gen_subalgebra M N Y)"
     hence "A \<in> {Y -` B \<inter> space M |B. B \<in> sets N}" using assms by (simp add:fct_gen_subalgebra_sigma_sets)
     hence "\<exists>B \<in> sets N. A = Y -`B \<inter> space M" by auto
     from this obtain B where "B\<in> sets N" and "A = Y -`B\<inter> space M" by auto
     thus "integral\<^sup>L M (\<lambda>w. (X w) * (indicator A w)) =
       integral\<^sup>L M (\<lambda>w. ((expl_cond_expect M Y X) w) * (indicator A w))" using is_cond_exp
       using Bochner_Integration.integral_cong \<open>point_measurable M (space N) Y\<close> assms(1) assms(2) by blast
   qed
   thus "\<And>A. A \<in> sets (fct_gen_subalgebra M N Y) \<Longrightarrow> set_lebesgue_integral M A X = set_lebesgue_integral M A (expl_cond_expect M Y X)"
     by (smt Bochner_Integration.integral_cong Groups.mult_ac(2) real_scaleR_def set_lebesgue_integral_def)
 qed
 
 
 lemma (in finite_measure) charact_cond_exp':
   assumes "disc_fct Y"
     and "integrable M X"
     and "Y\<in> measurable M N"
     and "\<forall>r\<in> range Y\<inter> space N. \<exists>A\<in> sets N. range Y\<inter> A = {r}"
   shows "AE w in M. real_cond_exp M (fct_gen_subalgebra M N Y) X w = expl_cond_expect M Y X w"
 proof (rule charact_cond_exp)
   show "disc_fct Y" using assms by simp
   show "integrable M X" using assms by simp
   show "\<forall>r\<in>range Y \<inter> space N. \<exists>A\<in>sets N. range Y \<inter> A = {r}" using assms by simp
   show "Y\<in> space M \<rightarrow> space N"
     by (meson Pi_I assms(3) measurable_space)
   show "point_measurable M (space N) Y" using assms by (simp add: meas_single_meas)
 qed
 
 
 
 end
diff --git a/thys/DiscretePricing/Fair_Price.thy b/thys/DiscretePricing/Fair_Price.thy
--- a/thys/DiscretePricing/Fair_Price.thy
+++ b/thys/DiscretePricing/Fair_Price.thy
@@ -1,3523 +1,3522 @@
 (*  Title:      Fair_Price.thy
     Author:     Mnacho Echenim, Univ. Grenoble Alpes
 *)
 
 section \<open>Fair Prices\<close>
 
 text  \<open>This section contains the formalization of financial notions, such as markets, price processes, portfolios,
 arbitrages, fair prices, etc. It also defines risk-neutral probability spaces, and proves the main result about the fair
 price of a derivative in a risk-neutral probability space, namely that this fair price is equal to the expectation of
 the discounted value of the derivative's payoff.\<close>
 
 theory Fair_Price imports Filtration Martingale Geometric_Random_Walk
 begin
 
 subsection \<open>Preliminary results\<close>
 
 lemma (in prob_space) finite_borel_measurable_integrable:
   assumes "f\<in> borel_measurable M"
   and "finite (f`(space M))"
   shows "integrable M f"
 proof -
   have "simple_function M f" using assms by (simp add: simple_function_borel_measurable)
   moreover have "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>" by simp
   ultimately have "Bochner_Integration.simple_bochner_integrable M f"
     using Bochner_Integration.simple_bochner_integrable.simps by blast
   hence "has_bochner_integral M f (Bochner_Integration.simple_bochner_integral M f)"
     using has_bochner_integral_simple_bochner_integrable by auto
   thus ?thesis using integrable.simps by auto
 qed
 
 
 subsubsection \<open>On the almost everywhere filter\<close>
 
 lemma AE_eq_trans[trans]:
   assumes "AE x in M. A x = B x"
   and "AE x in M. B x = C x"
   shows "AE x in M. A x = C x"
   using assms  by auto
 
 
 abbreviation AEeq where "AEeq M X Y \<equiv> AE w in M. X w = Y w"
 
 
 
 lemma AE_add:
   assumes "AE w in M. f w = g w"
   and "AE w in M. f' w = g' w"
 shows "AE w in M. f w + f' w = g w + g' w" using assms by auto
 
 
 lemma AE_sum:
   assumes "finite I"
   and  "\<forall> i\<in>I. AE w in M. f i w = g i w"
   shows "AE w in M. (\<Sum>i\<in> I. f i w) = (\<Sum>i\<in> I. g i w)" using assms(1) subset_refl[of I]
 proof (induct rule: finite_subset_induct)
   case empty
   then show ?case by simp
 next
   case (insert a F)
   have "AEeq M (f a) (g a)" using assms(2) insert.hyps(2) by auto
   have "AE w in M. (\<Sum>i\<in> insert a F. f i w) = f a w + (\<Sum>i\<in> F. f i w)"
     by (simp add: insert.hyps(1) insert.hyps(3))
   also have "AE w in M. f a w + (\<Sum>i\<in> F. f i w) = g a w + (\<Sum>i\<in> F. f i w)"
     using \<open>AEeq M (f a) (g a)\<close> by auto
   also have "AE w in M. g a w + (\<Sum>i\<in> F. f i w) = g a w + (\<Sum>i\<in> F. g i w)"
     using insert.hyps(4) by auto
   also have "AE w in M. g a w + (\<Sum>i\<in> F. g i w) = (\<Sum>i\<in> insert a F. g i w)"
     by (simp add: insert.hyps(1) insert.hyps(3))
   finally show ?case by auto
 qed
 
 
 lemma AE_eq_cst:
   assumes "AE w in M. (\<lambda>w. c) w = (\<lambda>w. d) w"
   and "emeasure M (space M) \<noteq> 0"
   shows "c = d"
 proof (rule ccontr)
   assume "c \<noteq> d"
   from \<open>AE w in M. (\<lambda>w. c) w = (\<lambda>w. d) w\<close> obtain N where Nprops: "{w\<in> space M. \<not>(\<lambda>w. c) w = (\<lambda>w. d) w} \<subseteq> N" "N\<in> sets M" "emeasure M N = 0"
     by (force elim:AE_E)
   have "\<forall>w\<in> space M. (\<lambda>w. c) w \<noteq> (\<lambda>w. d) w" using \<open>c\<noteq> d\<close> by simp
   hence "{w\<in> space M. (\<lambda>w. c) w \<noteq> (\<lambda>w. d) w} = space M" by auto
   hence "space M\<subseteq> N" using Nprops by auto
   thus False using \<open>emeasure M N = 0\<close> assms
     by (meson Nprops(2) \<open>emeasure M (space M) \<noteq> 0\<close> \<open>emeasure M N = 0\<close> \<open>space M \<subseteq> N\<close> emeasure_eq_0)
 qed
 
 subsubsection \<open>On conditional expectations\<close>
 
 lemma (in prob_space) subalgebra_sigma_finite:
   assumes "subalgebra M N"
   shows "sigma_finite_subalgebra M N" unfolding sigma_finite_subalgebra_def by (simp add: assms prob_space_axioms prob_space_imp_sigma_finite prob_space_restr_to_subalg)
 
 
 
 lemma (in prob_space) trivial_subalg_cond_expect_AE:
   assumes "subalgebra M N"
   and "sets N = {{}, space M}"
   and "integrable M f"
 shows "AE x in M. real_cond_exp M N f x = (\<lambda>x. expectation f) x"
 proof (intro sigma_finite_subalgebra.real_cond_exp_charact)
   show "sigma_finite_subalgebra M N" by (simp add: assms(1) subalgebra_sigma_finite)
   show "integrable M f" using assms by simp
   show "integrable M (\<lambda>x. expectation f)" by auto
   show "(\<lambda>x. expectation f) \<in> borel_measurable N" by simp
   show "\<And>A. A \<in> sets N \<Longrightarrow> set_lebesgue_integral M A f = \<integral>x\<in>A. expectation f\<partial>M"
   proof -
     fix A
     assume "A \<in> sets N"
     show "set_lebesgue_integral M A f = \<integral>x\<in>A. expectation f\<partial>M"
     proof (cases "A = {}")
       case True
       thus ?thesis by (simp add: set_lebesgue_integral_def)
     next
       case False
       hence "A = space M" using assms \<open>A\<in> sets N\<close> by auto
       have "set_lebesgue_integral M A f = expectation f" using \<open>A = space M\<close>
         by (metis (mono_tags, lifting) Bochner_Integration.integral_cong indicator_simps(1)
                   scaleR_one set_lebesgue_integral_def)
       also have "... =\<integral>x\<in>A. expectation f\<partial>M" using \<open>A = space M\<close>
         by (auto simp add:prob_space set_lebesgue_integral_def)
       finally show ?thesis .
     qed
   qed
 qed
 
 lemma (in prob_space) triv_subalg_borel_eq:
   assumes "subalgebra M F"
   and "sets F = {{}, space M}"
   and "AE x in M. f x = (c::'b::{t2_space})"
   and "f\<in> borel_measurable F"
 shows "\<forall>x\<in> space M. f x = c"
 proof
   fix x
   assume "x\<in> space M"
   have "space M = space F" using assms by (simp add:subalgebra_def)
   hence "x\<in> space F" using \<open>x\<in> space M\<close> by simp
   have "space M \<noteq> {}" by (simp add:not_empty)
   hence "\<exists>d. \<forall>y\<in> space F. f y = d" by (metis assms(1) assms(2) assms(4) subalgebra_def triv_measurable_cst)
   from this obtain d where "\<forall>y \<in>space F. f y = d" by auto
   hence "f x = d" using \<open>x\<in> space F\<close> by simp
   also have "... = c"
   proof (rule ccontr)
     assume "d\<noteq> c"
     from \<open>AE x in M. f x= c\<close> obtain N where Nprops: "{x\<in> space M. \<not>f x = c} \<subseteq> N" "N\<in> sets M" "emeasure M N = 0"
       by (force elim:AE_E)
     have "space M \<subseteq> {x\<in> space M. \<not>f x = c}" using \<open>\<forall>y \<in>space F. f y = d\<close> \<open>space M = space F\<close> \<open>d\<noteq> c\<close> by auto
     hence "space M\<subseteq> N" using Nprops by auto
     thus False using \<open>emeasure M N = 0\<close> emeasure_space_1  Nprops(2) emeasure_mono by fastforce
   qed
   finally show "f x = c" .
 qed
 
 
 
 lemma (in prob_space) trivial_subalg_cond_expect_eq:
   assumes "subalgebra M N"
   and "sets N = {{}, space M}"
   and "integrable M f"
 shows "\<forall>x\<in> space M. real_cond_exp M N f x = expectation f"
 proof (rule triv_subalg_borel_eq)
   show "subalgebra M N" "sets N = {{}, space M}" using assms by auto
   show "real_cond_exp M N f \<in> borel_measurable N" by simp
   show "AE x in M. real_cond_exp M N f x = expectation f"
     by (rule trivial_subalg_cond_expect_AE, (auto simp add:assms))
 qed
 
 
 
 lemma (in sigma_finite_subalgebra) real_cond_exp_cong':
   assumes "\<forall>w \<in> space M. f w = g w"
   and "f\<in> borel_measurable M"
 shows "AE w in M. real_cond_exp M F f w = real_cond_exp M F g w"
 proof (rule real_cond_exp_cong)
   show "AE w in M. f w = g w" using assms by simp
   show "f\<in> borel_measurable M" using assms by simp
   show "g\<in> borel_measurable M" using assms by (metis measurable_cong)
 qed
 
 lemma (in sigma_finite_subalgebra) real_cond_exp_bsum :
   fixes f::"'b \<Rightarrow> 'a \<Rightarrow> real"
   assumes [measurable]: "\<And>i. i\<in>I \<Longrightarrow> integrable M (f i)"
   shows "AE x in M. real_cond_exp M F (\<lambda>x. \<Sum>i\<in>I. f i x) x = (\<Sum>i\<in>I. real_cond_exp M F (f i) x)"
 proof (rule real_cond_exp_charact)
   fix A assume [measurable]: "A \<in> sets F"
   then have A_meas [measurable]: "A \<in> sets M" by (meson subsetD subalg subalgebra_def)
 
   have *: "\<And>i. i \<in> I \<Longrightarrow> integrable M (\<lambda>x. indicator A x * f i x)"
     using integrable_mult_indicator[OF \<open>A \<in> sets M\<close> assms(1)]  by auto
   have **: "\<And>i. i \<in> I \<Longrightarrow> integrable M (\<lambda>x. indicator A x * real_cond_exp M F (f i) x)"
     using integrable_mult_indicator[OF \<open>A \<in> sets M\<close> real_cond_exp_int(1)[OF assms(1)]]  by auto
   have inti: "\<And>i. i \<in> I \<Longrightarrow>(\<integral>x. indicator A x * f i x \<partial>M) = (\<integral>x. indicator A x * real_cond_exp M F (f i) x \<partial>M)" using
       real_cond_exp_intg(2)[symmetric,of "indicator A" ]
     using "*" \<open>A \<in> sets F\<close> assms borel_measurable_indicator by blast
   have "(\<integral>x\<in>A. (\<Sum>i\<in>I. f i x)\<partial>M) = (\<integral>x. (\<Sum>i\<in>I. indicator A x * f i x)\<partial>M)"
     by (simp add: sum_distrib_left set_lebesgue_integral_def)
   also have "... = (\<Sum>i\<in>I. (\<integral>x. indicator A x * f i x \<partial>M))" using Bochner_Integration.integral_sum[of I M "\<lambda>i x. indicator A x * f i x"] *
     by simp
   also have "... = (\<Sum>i\<in>I. (\<integral>x. indicator A x * real_cond_exp M F (f i) x \<partial>M))"
     using inti by auto
   also have "... = (\<integral>x. (\<Sum>i\<in>I. indicator A x * real_cond_exp M F (f i) x)\<partial>M)"
     by (rule Bochner_Integration.integral_sum[symmetric], simp add: **)
   also have "... = (\<integral>x\<in>A. (\<Sum>i\<in>I. real_cond_exp M F (f i) x)\<partial>M)"
     by (simp add: sum_distrib_left set_lebesgue_integral_def)
   finally show "(\<integral>x\<in>A. (\<Sum>i\<in>I. f i x)\<partial>M) = (\<integral>x\<in>A. (\<Sum>i\<in>I. real_cond_exp M F (f i) x)\<partial>M)" by auto
 qed (auto simp add: assms real_cond_exp_int(1)[OF assms(1)])
 
 subsection \<open>Financial formalizations\<close>
 
 subsubsection \<open>Markets\<close>
 
 
 
 definition stk_strict_subs::"'c set \<Rightarrow> bool" where
 "stk_strict_subs S \<longleftrightarrow> S \<noteq> UNIV"
 
 typedef ('a,'c) discrete_market = "{(s::('c set), a::'c \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> real)). stk_strict_subs s}" unfolding stk_strict_subs_def by fastforce
 
 definition prices where
   "prices Mkt = (snd (Rep_discrete_market Mkt))"
 
 definition assets where
 
   "assets Mkt = UNIV"
 
 
 definition stocks where
   "stocks Mkt = (fst (Rep_discrete_market Mkt))"
 
 definition discrete_market_of
 where
   "discrete_market_of S A =
     Abs_discrete_market (if (stk_strict_subs S) then S else {}, A)"
 
 lemma prices_of:
   shows "prices (discrete_market_of S A) = A"
 proof -
   have "stk_strict_subs (if (stk_strict_subs S) then S else {})"
   proof (cases "stk_strict_subs S")
     case True thus ?thesis by simp
   next
     case False thus ?thesis unfolding stk_strict_subs_def by simp
   qed
   hence fct: "((if (stk_strict_subs S) then S else {}), A) \<in> {(s, a). stk_strict_subs s}" by simp
   have "discrete_market_of S A = Abs_discrete_market (if (stk_strict_subs S) then S else {}, A)" unfolding discrete_market_of_def by simp
   hence "Rep_discrete_market (discrete_market_of S A) = (if (stk_strict_subs S) then S else {},A)"
     using Abs_discrete_market_inverse[of "(if (stk_strict_subs S) then S else {}, A)"] fct  by simp
   thus ?thesis unfolding prices_def by simp
 qed
 
 lemma stocks_of:
   assumes "UNIV \<noteq> S"
   shows "stocks (discrete_market_of S A) = S"
 proof -
   have "stk_strict_subs S" using assms unfolding stk_strict_subs_def by simp
   hence fct: "((if (stk_strict_subs S) then S else {}), A) \<in> {(s, a). stk_strict_subs s}" by simp
   have "discrete_market_of S A = Abs_discrete_market (if (stk_strict_subs S) then S else {}, A)" unfolding discrete_market_of_def by simp
   hence "Rep_discrete_market (discrete_market_of S A) = (if (stk_strict_subs S) then S else {},A)"
     using Abs_discrete_market_inverse[of "(if (stk_strict_subs S) then S else {}, A)"] fct  by simp
   thus ?thesis unfolding stocks_def using \<open>stk_strict_subs S\<close> by simp
 qed
 
 lemma mkt_stocks_assets:
   shows "stk_strict_subs (stocks Mkt)" unfolding stocks_def prices_def
   by (metis Rep_discrete_market mem_Collect_eq split_beta')
 
 subsubsection \<open>Quantity processes and portfolios\<close>
 text \<open>These are functions that assign quantities to assets; each quantity is a stochastic process. Basic
 operations are defined on these processes.\<close>
 
 paragraph \<open>Basic operations\<close>
 
 definition qty_empty where
   "qty_empty = (\<lambda> (x::'a) (n::nat) w. 0::real)"
 
 definition qty_single where
   "qty_single asset qt_proc = (qty_empty(asset := qt_proc))"
 
 definition qty_sum::"('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> ('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> ('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real)"  where
   "qty_sum pf1 pf2 = (\<lambda>x n w. pf1 x n w + pf2 x n w)"
 
 definition qty_mult_comp::"('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> ('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real)"  where
   "qty_mult_comp pf1 qty = (\<lambda>x n w. (pf1 x n w) * (qty n w))"
 
 definition qty_rem_comp::"('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> 'b \<Rightarrow> ('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real)"  where
   "qty_rem_comp pf1 x = pf1(x:=(\<lambda>n w. 0))"
 
 definition qty_replace_comp where
   "qty_replace_comp pf1 x pf2 = qty_sum (qty_rem_comp pf1 x) (qty_mult_comp pf2 (pf1 x))"
 
 
 paragraph \<open>Support sets\<close>
 
 text \<open>If p x n w is different from 0, this means that this quantity is held on interval ]n-1, n].\<close>
 definition support_set::"('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> 'b set" where
   "support_set p = {x. \<exists> n w. p x n w \<noteq> 0}"
 
 lemma qty_empty_support_set:
   shows "support_set qty_empty = {}" unfolding support_set_def qty_empty_def by simp							
 lemma sum_support_set:
   shows "support_set (qty_sum pf1 pf2) \<subseteq> (support_set pf1) \<union> (support_set pf2)"
 proof (intro subsetI, rule ccontr)
   fix x
   assume "x\<in> support_set (qty_sum pf1 pf2)" and "x \<notin> support_set pf1 \<union> support_set pf2" note xprops = this
   hence "\<exists> n w. (qty_sum pf1 pf2) x n w \<noteq> 0" by (simp add: support_set_def)
   from this obtain n w where "(qty_sum pf1 pf2) x n w \<noteq> 0" by auto note nwprops = this
   have "pf1 x n w = 0" "pf2 x n w = 0" using xprops by (auto simp add:support_set_def)
   hence "(qty_sum pf1 pf2) x n w = 0" unfolding qty_sum_def by simp
   thus False using nwprops by simp
 qed
 
 lemma mult_comp_support_set:
 shows "support_set (qty_mult_comp pf1 qty) \<subseteq> (support_set pf1)"
 proof (intro subsetI, rule ccontr)
   fix x
   assume "x\<in> support_set (qty_mult_comp pf1 qty)" and "x \<notin> support_set pf1" note xprops = this
   hence "\<exists> n w. (qty_mult_comp pf1 qty) x n w \<noteq> 0" by (simp add: support_set_def)
   from this obtain n w where "qty_mult_comp pf1 qty x n w \<noteq> 0" by auto note nwprops = this
   have "pf1 x n w = 0" using xprops by (simp add:support_set_def)
   hence "(qty_mult_comp pf1 qty) x n w = 0" unfolding qty_mult_comp_def by simp
   thus False using nwprops by simp
 qed
 
 lemma remove_comp_support_set:
 shows "support_set (qty_rem_comp pf1 x) \<subseteq> ((support_set pf1) - {x})"
 proof (intro subsetI, rule ccontr)
   fix y
   assume "y\<in> support_set (qty_rem_comp pf1 x)" and "y \<notin> support_set pf1 - {x}" note xprops = this
   hence "y\<notin> support_set pf1 \<or> y = x" by simp
   have "\<exists> n w. (qty_rem_comp pf1 x) y n w \<noteq> 0" using xprops by (simp add: support_set_def)
   from this obtain n w where "(qty_rem_comp pf1 x) y n w \<noteq> 0" by auto note nwprops = this
   show False
   proof (cases "y\<notin> support_set pf1")
     case True
     hence "pf1 y n w = 0" using xprops by (simp add:support_set_def)
     hence "(qty_rem_comp pf1 x) x n w = 0" unfolding qty_rem_comp_def by simp
     thus ?thesis using nwprops by (metis \<open>pf1 y n w = 0\<close> fun_upd_apply qty_rem_comp_def)
   next
     case False
     hence "y = x" using \<open>y\<notin> support_set pf1 \<or> y = x\<close> by simp
     hence "(qty_rem_comp pf1 x) x n w = 0" unfolding qty_rem_comp_def by simp
     thus ?thesis using nwprops by (simp add: \<open>y = x\<close>)
   qed
 qed
 
 lemma replace_comp_support_set:
   shows "support_set (qty_replace_comp pf1 x pf2) \<subseteq> (support_set pf1 - {x}) \<union> support_set pf2"
 proof -
   have "support_set (qty_replace_comp pf1 x pf2) \<subseteq> support_set (qty_rem_comp pf1 x) \<union> support_set (qty_mult_comp pf2 (pf1 x))"
     unfolding qty_replace_comp_def by (simp add:sum_support_set)
   also have "... \<subseteq> (support_set pf1 - {x}) \<union> support_set pf2" using remove_comp_support_set mult_comp_support_set
     by (metis sup.mono)
   finally show ?thesis .
 qed
 
 lemma single_comp_support:
   shows "support_set (qty_single asset qty) \<subseteq> {asset}"
 proof
   fix x
   assume "x\<in> support_set (qty_single asset qty)"
   show "x\<in> {asset}"
   proof (rule ccontr)
     assume "x\<notin> {asset}"
     hence "x\<noteq> asset" by auto
     have "\<exists> n w. qty_single asset qty x n w \<noteq> 0" using \<open>x\<in> support_set (qty_single asset qty)\<close>
       by (simp add:support_set_def)
     from this obtain n w where "qty_single asset qty x n w \<noteq> 0" by auto
     thus False using \<open>x\<noteq>asset\<close> by (simp add: qty_single_def qty_empty_def)
   qed
 qed
 
 lemma single_comp_nz_support:
   assumes "\<exists> n w. qty n w\<noteq> 0"
   shows "support_set (qty_single asset qty) = {asset}"
 proof
   show "support_set (qty_single asset qty) \<subseteq> {asset}" by (simp add: single_comp_support)
   have "asset\<in> support_set (qty_single asset qty)" using assms unfolding support_set_def qty_single_def by simp
   thus "{asset} \<subseteq> support_set (qty_single asset qty)" by auto
 qed
 
 paragraph \<open>Portfolios\<close>
 
 definition portfolio where
   "portfolio p \<longleftrightarrow> finite (support_set p)"
 
 
 
 
 definition stock_portfolio :: "('a, 'b) discrete_market \<Rightarrow> ('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> bool" where
   "stock_portfolio Mkt p \<longleftrightarrow> portfolio p \<and> support_set p \<subseteq> stocks Mkt"
 
 lemma sum_portfolio:
   assumes "portfolio pf1"
   and "portfolio pf2"
 shows "portfolio (qty_sum pf1 pf2)" unfolding portfolio_def
 proof -
   have "support_set (qty_sum pf1 pf2) \<subseteq> (support_set pf1) \<union> (support_set pf2)"  by (simp add: sum_support_set)
   thus "finite (support_set (qty_sum pf1 pf2))" using assms unfolding portfolio_def using infinite_super by auto
 qed
 
 lemma sum_basic_support_set:
   assumes "stock_portfolio Mkt pf1"
   and "stock_portfolio Mkt pf2"
 shows "stock_portfolio Mkt (qty_sum pf1 pf2)" using assms sum_support_set[of pf1 pf2] unfolding stock_portfolio_def
   by (metis Diff_subset_conv gfp.leq_trans subset_Un_eq sum_portfolio)
 
 lemma mult_comp_portfolio:
   assumes "portfolio pf1"
 shows "portfolio (qty_mult_comp pf1 qty)" unfolding portfolio_def
 proof -
   have "support_set (qty_mult_comp pf1 qty) \<subseteq> (support_set pf1)"  by (simp add: mult_comp_support_set)
   thus "finite (support_set (qty_mult_comp pf1 qty))" using assms unfolding portfolio_def using infinite_super by auto
 qed
 
 lemma mult_comp_basic_support_set:
   assumes "stock_portfolio Mkt pf1"
 shows "stock_portfolio Mkt (qty_mult_comp pf1 qty)" using assms mult_comp_support_set[of pf1] unfolding stock_portfolio_def
   using mult_comp_portfolio by blast
 
 
 
 lemma remove_comp_portfolio:
   assumes "portfolio pf1"
 shows "portfolio (qty_rem_comp pf1 x)" unfolding portfolio_def
 proof -
   have "support_set (qty_rem_comp pf1 x) \<subseteq> (support_set pf1)" using remove_comp_support_set[of pf1 x] by blast
   thus "finite (support_set (qty_rem_comp pf1 x))" using assms unfolding portfolio_def using infinite_super by auto
 qed
 
 lemma remove_comp_basic_support_set:
   assumes "stock_portfolio Mkt pf1"
 shows "stock_portfolio Mkt (qty_mult_comp pf1 qty)" using assms mult_comp_support_set[of pf1] unfolding stock_portfolio_def
   using mult_comp_portfolio by blast
 
 lemma replace_comp_portfolio:
   assumes "portfolio pf1"
   and "portfolio pf2"
 shows "portfolio (qty_replace_comp pf1 x pf2)" unfolding portfolio_def
 proof -
   have "support_set (qty_replace_comp pf1 x pf2) \<subseteq> (support_set pf1) \<union> (support_set pf2)" using replace_comp_support_set[of pf1 x pf2] by blast
   thus "finite (support_set (qty_replace_comp pf1 x pf2))" using assms unfolding portfolio_def using infinite_super by auto
 qed
 
 lemma replace_comp_stocks:
   assumes "support_set pf1 \<subseteq> stocks Mkt \<union> {x}"
   and "support_set pf2 \<subseteq> stocks Mkt"
 shows "support_set (qty_replace_comp pf1 x pf2) \<subseteq> stocks Mkt"
 proof -
   have "support_set (qty_rem_comp pf1 x) \<subseteq> stocks Mkt" using assms(1) remove_comp_support_set by fastforce
   moreover have "support_set (qty_mult_comp pf2 (pf1 x)) \<subseteq> stocks Mkt" using assms mult_comp_support_set by fastforce
   ultimately show ?thesis unfolding qty_replace_comp_def using sum_support_set by fastforce
 qed
 
 
 
 lemma single_comp_portfolio:
   shows "portfolio (qty_single asset qty)"
   by (meson finite.emptyI finite.insertI finite_subset portfolio_def single_comp_support)
 
 paragraph \<open>Value processes\<close>
 
 definition val_process where
   "val_process Mkt p = (if (\<not> (portfolio p)) then (\<lambda> n w. 0)
     else (\<lambda> n w . (sum (\<lambda>x. ((prices Mkt) x n w) * (p x (Suc n) w)) (support_set p))))"
 
 
 
 lemma subset_val_process':
   assumes "finite A"
   and "support_set p \<subseteq> A"
 shows "val_process Mkt p n w = (sum (\<lambda>x. ((prices Mkt) x n w) * (p x (Suc n) w)) A)"
 proof -
   have "portfolio p" using assms unfolding portfolio_def using finite_subset by auto
   have "\<exists>C. (support_set p) \<inter> C = {} \<and> (support_set p) \<union> C = A" using assms(2) by auto
   from this obtain C where "(support_set p) \<inter> C = {}" and "(support_set p) \<union> C = A" by auto note Cprops = this
   have "finite C" using assms \<open>(support_set p) \<union> C = A\<close> by auto
   have "\<forall>x\<in> C. p x (Suc n) w = 0" using Cprops(1) support_set_def by fastforce
   hence "(\<Sum>x\<in> C. ((prices Mkt) x n w) * (p x (Suc n) w)) = 0" by simp
   hence "val_process Mkt p n w = (\<Sum>x\<in> (support_set p). ((prices Mkt) x n w) * (p x (Suc n) w))
     + (\<Sum>x\<in> C. ((prices Mkt) x n w) * (p x (Suc n) w))" unfolding val_process_def using \<open>portfolio p\<close> by simp
   also have "... = (\<Sum> x\<in> A. ((prices Mkt) x n w) * (p x (Suc n) w))"
     using \<open>portfolio p\<close> \<open>finite C\<close> Cprops portfolio_def sum_union_disjoint' by (metis (no_types, lifting))
   finally show "val_process Mkt p n w = (\<Sum> x\<in> A. ((prices Mkt) x n w) * (p x (Suc n) w))" .
 qed
 
 
 lemma sum_val_process:
   assumes "portfolio pf1"
   and "portfolio pf2"
 shows "\<forall>n w. val_process Mkt (qty_sum pf1 pf2) n w = (val_process Mkt pf1) n w + (val_process Mkt pf2) n w"
 proof (intro allI)
   fix n w
   have vp1: "val_process Mkt pf1 n w = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x n w) * (pf1 x (Suc n) w))"
   proof -
     have "finite (support_set pf1 \<union> support_set pf2) \<and> support_set pf1 \<subseteq> support_set pf1 \<union> support_set pf2"
       by (meson assms(1) assms(2) finite_Un portfolio_def sup.cobounded1)
     then show ?thesis
       by (simp add: subset_val_process')
   qed
   have vp2: "val_process Mkt pf2 n w = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x n w) * (pf2 x (Suc n) w))"
   proof -
     have "finite (support_set pf1 \<union> support_set pf2) \<and> support_set pf2 \<subseteq> support_set pf2 \<union> support_set pf1"
       by (meson assms(1) assms(2) finite_Un portfolio_def sup.cobounded1)
     then show ?thesis
       by (simp add: subset_val_process')
   qed
   have pf:"portfolio (qty_sum pf1 pf2)" using assms by (simp add:sum_portfolio)
   have fin:"finite (support_set pf1 \<union> support_set pf2)" using assms finite_Un unfolding portfolio_def by auto
   have "(val_process Mkt pf1) n w + (val_process Mkt pf2) n w =
     (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x n w) * (pf1 x (Suc n) w)) +
     (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x n w) * (pf2 x (Suc n) w))"
     using vp1 vp2 by simp
   also have "... = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2).
     (((prices Mkt) x n w) * (pf1 x (Suc n) w)) + ((prices Mkt) x n w) * (pf2 x (Suc n) w))"
     by (simp add: sum.distrib)
   also have "... = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2).
     ((prices Mkt) x n w) * ((pf1 x (Suc n) w) + (pf2 x (Suc n) w)))" by (simp add: distrib_left)
   also have "... = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2).
     ((prices Mkt) x n w) * ((qty_sum pf1 pf2) x (Suc n) w))" by (simp add: qty_sum_def)
   also have "... = (\<Sum> x\<in> (support_set (qty_sum pf1 pf2)).
     ((prices Mkt) x n w) * ((qty_sum pf1 pf2) x (Suc n) w))" using sum_support_set[of pf1 pf2]
     subset_val_process'[of "support_set pf1\<union> support_set pf2" "qty_sum pf1 pf2"] pf fin unfolding val_process_def by simp
   also have "... = val_process Mkt (qty_sum pf1 pf2) n w" by (metis (no_types, lifting) pf sum.cong val_process_def)
   finally have "(val_process Mkt pf1) n w + (val_process Mkt pf2) n w = val_process Mkt (qty_sum pf1 pf2) n w" .
   thus "val_process Mkt (qty_sum pf1 pf2) n w = (val_process Mkt pf1) n w + (val_process Mkt pf2) n w" ..
 qed
 
 
 lemma mult_comp_val_process:
   assumes "portfolio pf1"
 shows "\<forall>n w. val_process Mkt (qty_mult_comp pf1 qty) n w = ((val_process Mkt pf1) n w) * (qty (Suc n) w)"
 proof (intro allI)
   fix n w
   have pf:"portfolio (qty_mult_comp pf1 qty)" using assms by (simp add:mult_comp_portfolio)
   have fin:"finite (support_set pf1)" using assms unfolding portfolio_def by auto
   have "((val_process Mkt pf1) n w) * (qty (Suc n) w) =
     (\<Sum> x\<in> (support_set pf1). ((prices Mkt) x n w) * (pf1 x (Suc n) w))*(qty (Suc n) w)"
     unfolding val_process_def using assms by simp
   also have "... = (\<Sum> x\<in> (support_set pf1).
     (((prices Mkt) x n w) * (pf1 x (Suc n) w) * (qty (Suc n) w)))" using sum_distrib_right by auto
   also have "... = (\<Sum> x\<in> (support_set pf1).
     ((prices Mkt) x n w) * ((qty_mult_comp pf1 qty) x (Suc n) w))" unfolding qty_mult_comp_def
     by (simp add: mult.commute mult.left_commute)
   also have "... = (\<Sum> x\<in> (support_set (qty_mult_comp pf1 qty)).
     ((prices Mkt) x n w) * ((qty_mult_comp pf1 qty) x (Suc n) w))" using mult_comp_support_set[of pf1]
     subset_val_process'[of "support_set pf1" "qty_mult_comp pf1 qty"] pf fin unfolding val_process_def by simp
   also have "... = val_process Mkt (qty_mult_comp pf1 qty) n w" by (metis (no_types, lifting) pf sum.cong val_process_def)
   finally have "(val_process Mkt pf1) n w * (qty (Suc n) w) = val_process Mkt (qty_mult_comp pf1 qty) n w" .
   thus "val_process Mkt (qty_mult_comp pf1 qty) n w = (val_process Mkt pf1) n w * (qty (Suc n) w)" ..
 qed
 
 
 
 
 
 lemma remove_comp_values:
   assumes "x \<noteq> y"
   shows "\<forall>n w. pf1 x n w = (qty_rem_comp pf1 y) x n w"
 proof (intro allI)
   fix n w
   show "pf1 x n w = (qty_rem_comp pf1 y) x n w" by (simp add: assms qty_rem_comp_def)
 qed
 
 
 
 
 lemma remove_comp_val_process:
   assumes "portfolio pf1"
 shows "\<forall>n w. val_process Mkt (qty_rem_comp pf1 y) n w = ((val_process Mkt pf1) n w) - (prices Mkt y n w)* (pf1 y (Suc n) w)"
 proof (intro allI)
   fix n w
   have pf:"portfolio (qty_rem_comp pf1 y)" using assms by (simp add:remove_comp_portfolio)
   have fin:"finite (support_set pf1)" using assms unfolding portfolio_def by auto
   hence fin2: "finite (support_set pf1 - {y})" by simp
   have "((val_process Mkt pf1) n w)  =
     (\<Sum> x\<in> (support_set pf1). ((prices Mkt) x n w) * (pf1 x (Suc n) w))"
     unfolding val_process_def using assms by simp
   also have "... = (\<Sum> x\<in> (support_set pf1 - {y}).
     (((prices Mkt) x n w) * (pf1 x (Suc n) w))) + (prices Mkt y n w)* (pf1 y (Suc n) w)"
   proof (cases "y\<in> support_set pf1")
     case True
     thus ?thesis by (simp add: fin sum_diff1)
   next
     case False
     hence "pf1 y (Suc n) w = 0" unfolding support_set_def by simp
     thus ?thesis by (simp add: fin sum_diff1)
   qed
   also have "... = (\<Sum> x\<in> (support_set pf1 - {y}).
     ((prices Mkt) x n w) * ((qty_rem_comp pf1 y) x (Suc n) w)) + (prices Mkt y n w)* (pf1 y (Suc n) w)"
   proof -
     have "(\<Sum> x\<in> (support_set pf1 - {y}). (((prices Mkt) x n w) * (pf1 x (Suc n) w))) =
       (\<Sum> x\<in> (support_set pf1 - {y}). ((prices Mkt) x n w) * ((qty_rem_comp pf1 y) x (Suc n) w))"
     proof (rule sum.cong,simp)
       fix x
       assume "x\<in> support_set pf1 - {y}"
       show "prices Mkt x n w * pf1 x (Suc n) w = prices Mkt x n w * qty_rem_comp pf1 y x (Suc n) w" using remove_comp_values
         by (metis DiffD2 \<open>x \<in> support_set pf1 - {y}\<close> singletonI)
     qed
     thus ?thesis by simp
   qed
   also have "... = (val_process Mkt (qty_rem_comp pf1 y) n w) + (prices Mkt y n w)* (pf1 y (Suc n) w)"
     using subset_val_process'[of "support_set pf1 - {y}" "qty_rem_comp pf1 y"] fin2
     by (simp add: remove_comp_support_set)
   finally have "(val_process Mkt pf1) n w =
     (val_process Mkt (qty_rem_comp pf1 y) n w) + (prices Mkt y n w)* (pf1 y (Suc n) w)" .
   thus  "val_process Mkt (qty_rem_comp pf1 y) n w = ((val_process Mkt pf1) n w) - (prices Mkt y n w)* (pf1 y (Suc n) w)" by simp
 qed
 
 
 
 
 lemma replace_comp_val_process:
   assumes "\<forall>n w. prices Mkt x n w = val_process Mkt pf2 n w"
   and "portfolio pf1"
   and "portfolio pf2"
   shows "\<forall>n w. val_process Mkt (qty_replace_comp pf1 x pf2) n w = val_process Mkt pf1 n w"
 proof (intro allI)
   fix n w
   have "val_process Mkt (qty_replace_comp pf1 x pf2) n w = val_process Mkt (qty_rem_comp pf1 x) n w +
     val_process Mkt (qty_mult_comp pf2 (pf1 x)) n w" unfolding qty_replace_comp_def using assms
     sum_val_process[of "qty_rem_comp pf1 x" "qty_mult_comp pf2 (pf1 x)"]
     by (simp add: mult_comp_portfolio remove_comp_portfolio)
   also have "... = val_process Mkt pf1 n w - (prices Mkt x n w * pf1 x (Suc n) w) + val_process Mkt pf2 n w * pf1 x (Suc n) w"
     by (simp add: assms(2) assms(3) mult_comp_val_process remove_comp_val_process)
   also have "... = val_process Mkt pf1 n w" using assms by simp
   finally show "val_process Mkt (qty_replace_comp pf1 x pf2) n w = val_process Mkt pf1 n w" .
 qed
 
 lemma qty_single_val_process:
 shows "val_process Mkt (qty_single asset qty) n w =
     prices Mkt asset n w * qty (Suc n) w"
 proof -
   have "val_process Mkt (qty_single asset qty) n w =
     (sum (\<lambda>x. ((prices Mkt) x n w) * ((qty_single asset qty) x (Suc n) w)) {asset})"
   proof (rule subset_val_process')
     show "finite {asset}" by simp
     show "support_set (qty_single asset qty) \<subseteq> {asset}" by (simp add: single_comp_support)
   qed
   also have "... = prices Mkt asset n w * qty (Suc n) w" unfolding qty_single_def by simp
   finally show ?thesis .
 qed
 
 
 
 subsubsection \<open>Trading strategies\<close>
 
 
 
 
 
 locale disc_equity_market = triv_init_disc_filtr_prob_space +
   fixes Mkt::"('a,'b) discrete_market"
 
 
 paragraph \<open>Discrete predictable processes\<close>
 
 
 
 paragraph \<open>Trading strategy\<close>
 
 definition (in disc_filtr_prob_space) trading_strategy
 where
   "trading_strategy p \<longleftrightarrow> portfolio p \<and> (\<forall>asset \<in> support_set p. borel_predict_stoch_proc F (p asset))"
 
 definition (in disc_filtr_prob_space) support_adapt:: "('a, 'b) discrete_market \<Rightarrow> ('b \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> bool" where
   "support_adapt Mkt pf \<longleftrightarrow> (\<forall> asset \<in> support_set pf. borel_adapt_stoch_proc F (prices Mkt asset))"
 
 lemma (in disc_filtr_prob_space) quantity_adapted:
   assumes "\<forall> asset \<in> support_set p. p asset (Suc n) \<in> borel_measurable (F n)"
   "\<forall>asset \<in> support_set p. prices Mkt asset n \<in> borel_measurable (F n)"
 shows "val_process Mkt p n \<in> borel_measurable (F n)"
 proof (cases "portfolio p")
 case False
   have "val_process Mkt p = (\<lambda> n w. 0)" unfolding val_process_def using False by simp
   thus "?thesis" by simp
 next
   case True
   hence "val_process Mkt p n = (\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x (Suc n) w)"
     unfolding val_process_def using True by simp
   moreover have "(\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x (Suc n) w) \<in> borel_measurable (F n)"
   proof (rule borel_measurable_sum)
     fix asset
     assume "asset\<in> support_set p"
     hence "p asset (Suc n) \<in> borel_measurable (F n)" using assms unfolding trading_strategy_def adapt_stoch_proc_def by simp
     moreover have "prices Mkt asset n \<in> borel_measurable (F n)"
       using \<open>asset \<in> support_set p\<close>  assms(2) unfolding support_adapt_def by (simp add: adapt_stoch_proc_def)
     ultimately show "(\<lambda>x. prices Mkt asset n x * p asset (Suc n) x) \<in> borel_measurable (F n)" by simp
   qed
   ultimately show "val_process Mkt p n \<in> borel_measurable (F n)" by simp
 qed
 
 
 
 lemma (in disc_filtr_prob_space) trading_strategy_adapted:
   assumes "trading_strategy p"
   and "support_adapt Mkt p"
   shows "borel_adapt_stoch_proc F (val_process Mkt p)" unfolding support_adapt_def
 proof (cases "portfolio p")
 case False
   have "val_process Mkt p = (\<lambda> n w. 0)" unfolding val_process_def using False by simp
   thus "borel_adapt_stoch_proc F (val_process Mkt p)"
     by (simp add: constant_process_borel_adapted)
 next
 case True
   show ?thesis unfolding adapt_stoch_proc_def
   proof
     fix n
     have "val_process Mkt p n = (\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x (Suc n) w)"
       unfolding val_process_def using True by simp
     moreover have "(\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x (Suc n) w) \<in> borel_measurable (F n)"
     proof (rule borel_measurable_sum)
       fix asset
       assume "asset\<in> support_set p"
       hence "p asset (Suc n) \<in> borel_measurable (F n)" using assms unfolding trading_strategy_def predict_stoch_proc_def by simp
       moreover have "prices Mkt asset n \<in> borel_measurable (F n)"
         using \<open>asset \<in> support_set p\<close>  assms(2) unfolding support_adapt_def  by (simp add:adapt_stoch_proc_def)
       ultimately show "(\<lambda>x. prices Mkt asset n x * p asset (Suc n) x) \<in> borel_measurable (F n)" by simp
     qed
     ultimately show "val_process Mkt p n \<in> borel_measurable (F n)" by simp
   qed
 qed
 
 
 
 
 lemma (in disc_equity_market) ats_val_process_adapted:
   assumes "trading_strategy p"
 and "support_adapt Mkt p"
   shows "borel_adapt_stoch_proc F (val_process Mkt p)" unfolding support_adapt_def
   by (meson assms(1) assms(2)  subsetCE trading_strategy_adapted)
 
 
 
 lemma (in disc_equity_market) trading_strategy_init:
   assumes "trading_strategy p"
 and "support_adapt Mkt p"
   shows "\<exists>c. \<forall>w \<in> space M. val_process Mkt p 0 w = c" using assms adapted_init ats_val_process_adapted by simp
 
 
 definition (in disc_equity_market) initial_value where
   "initial_value pf = constant_image (val_process Mkt pf 0)"
 
 lemma (in disc_equity_market) initial_valueI:
   assumes "trading_strategy pf"
 and "support_adapt Mkt pf"
   shows "\<forall>w\<in> space M. val_process Mkt pf 0 w = initial_value pf" unfolding initial_value_def
 proof (rule constant_imageI)
   show "\<exists>c. \<forall>w\<in>space M. val_process Mkt pf 0 w = c" using trading_strategy_init assms by simp
 qed
 
 
 lemma (in disc_equity_market) inc_predict_support_trading_strat:
   assumes "trading_strategy pf1"
   shows "\<forall> asset \<in> support_set pf1 \<union> B. borel_predict_stoch_proc F (pf1 asset)"
 proof
   fix asset
   assume "asset \<in> support_set pf1 \<union> B"
   show "borel_predict_stoch_proc F (pf1 asset)"
   proof (cases "asset \<in> support_set pf1")
     case True
     thus ?thesis using assms unfolding trading_strategy_def by simp
   next
     case False
     hence "\<forall>n w. pf1 asset n w = 0" unfolding support_set_def by simp
     show ?thesis unfolding predict_stoch_proc_def
     proof
       show "pf1 asset 0 \<in> measurable (F 0) borel" using \<open>\<forall>n w. pf1 asset n w = 0\<close>
         by (simp add: borel_measurable_const measurable_cong)
     next
       show "\<forall>n. pf1 asset (Suc n) \<in> borel_measurable (F n)"
       proof
         fix n
         have "\<forall>w. pf1 asset (Suc n) w = 0" using \<open>\<forall>n w. pf1 asset n w = 0\<close> by simp
         have "0\<in> space borel" by simp
         thus "pf1 asset (Suc n) \<in> measurable (F n) borel" using measurable_const[of 0 borel "F n"]
           by (metis \<open>0 \<in> space borel \<Longrightarrow> (\<lambda>x. 0) \<in> borel_measurable (F n)\<close> \<open>0 \<in> space borel\<close>
               \<open>\<forall>n w. pf1 asset n w = 0\<close> measurable_cong)
       qed
     qed
   qed
 qed
 
 lemma (in disc_equity_market) inc_predict_support_trading_strat':
   assumes "trading_strategy pf1"
   and "asset \<in> support_set pf1\<union> B"
   shows "borel_predict_stoch_proc F (pf1 asset)"
 proof (cases "asset \<in> support_set pf1")
   case True
   thus ?thesis using assms unfolding trading_strategy_def by simp
 next
   case False
   hence "\<forall>n w. pf1 asset n w = 0" unfolding support_set_def by simp
   show ?thesis unfolding predict_stoch_proc_def
   proof
     show "pf1 asset 0 \<in> measurable (F 0) borel" using \<open>\<forall>n w. pf1 asset n w = 0\<close>
       by (simp add: borel_measurable_const measurable_cong)
   next
     show "\<forall>n. pf1 asset (Suc n) \<in> borel_measurable (F n)"
     proof
       fix n
       have "\<forall>w. pf1 asset (Suc n) w = 0" using \<open>\<forall>n w. pf1 asset n w = 0\<close> by simp
       have "0\<in> space borel" by simp
       thus "pf1 asset (Suc n) \<in> measurable (F n) borel" using measurable_const[of 0 borel "F n"]
         by (metis \<open>0 \<in> space borel \<Longrightarrow> (\<lambda>x. 0) \<in> borel_measurable (F n)\<close> \<open>0 \<in> space borel\<close>
             \<open>\<forall>n w. pf1 asset n w = 0\<close> measurable_cong)
     qed
   qed
 qed
 
 
 
 lemma (in disc_equity_market) inc_support_trading_strat:
   assumes "trading_strategy pf1"
   shows "\<forall> asset \<in> support_set pf1 \<union> B. borel_adapt_stoch_proc F (pf1 asset)" using assms
   by (simp add: inc_predict_support_trading_strat predict_imp_adapt)
 
 lemma (in disc_equity_market) qty_empty_trading_strat:
   shows "trading_strategy qty_empty" unfolding trading_strategy_def 
 proof (intro conjI ballI)
   show "portfolio qty_empty"
     by (metis fun_upd_triv qty_single_def single_comp_portfolio) 
   show "\<And>asset. asset \<in> support_set qty_empty \<Longrightarrow> borel_predict_stoch_proc F (qty_empty asset)"
     using qty_empty_support_set by auto
 qed													  
 
 lemma (in disc_equity_market) sum_trading_strat:
   assumes "trading_strategy pf1"
   and "trading_strategy pf2"
 shows "trading_strategy (qty_sum pf1 pf2)"
 proof -
   have "\<forall> asset \<in> support_set pf1 \<union> support_set pf2. borel_predict_stoch_proc F (pf1 asset)"
     using assms by (simp add: inc_predict_support_trading_strat)
   have "\<forall> asset \<in> support_set pf2 \<union> support_set pf1. borel_predict_stoch_proc F (pf2 asset)"
     using assms by (simp add: inc_predict_support_trading_strat)
   have "\<forall> asset \<in> support_set pf1 \<union> support_set pf2. borel_predict_stoch_proc F ((qty_sum pf1 pf2) asset)"
   proof
     fix asset
     assume "asset \<in> support_set pf1 \<union> support_set pf2"
     show "borel_predict_stoch_proc F (qty_sum pf1 pf2 asset)" unfolding predict_stoch_proc_def qty_sum_def
     proof
       show "(\<lambda>w. pf1 asset 0 w + pf2 asset 0 w) \<in> borel_measurable (F 0)"
       proof -
         have "(\<lambda>w. pf1 asset 0 w) \<in> borel_measurable (F 0)"
         using \<open>\<forall>asset\<in>support_set pf1 \<union> support_set pf2. borel_predict_stoch_proc F (pf1 asset)\<close>
         \<open>asset \<in> support_set pf1 \<union> support_set pf2\<close> predict_stoch_proc_def by blast
         moreover have "(\<lambda>w. pf2 asset 0 w) \<in> borel_measurable (F 0)"
           using \<open>\<forall>asset\<in>support_set pf2 \<union> support_set pf1. borel_predict_stoch_proc F (pf2 asset)\<close>
           \<open>asset \<in> support_set pf1 \<union> support_set pf2\<close> predict_stoch_proc_def by blast
         ultimately show ?thesis by simp
       qed
     next
       show "\<forall>n. (\<lambda>w. pf1 asset (Suc n) w + pf2 asset (Suc n) w) \<in> borel_measurable (F n)"
       proof
         fix n
         have "(\<lambda>w. pf1 asset (Suc n) w) \<in> borel_measurable (F n)"
           using \<open>\<forall>asset\<in>support_set pf1 \<union> support_set pf2. borel_predict_stoch_proc F (pf1 asset)\<close>
           \<open>asset \<in> support_set pf1 \<union> support_set pf2\<close> predict_stoch_proc_def by blast
         moreover have "(\<lambda>w. pf2 asset (Suc n) w) \<in> borel_measurable (F n)"
           using \<open>\<forall>asset\<in>support_set pf2 \<union> support_set pf1. borel_predict_stoch_proc F (pf2 asset)\<close>
           \<open>asset \<in> support_set pf1 \<union> support_set pf2\<close> predict_stoch_proc_def by blast
         ultimately show "(\<lambda>w. pf1 asset (Suc n) w + pf2 asset (Suc n) w) \<in> borel_measurable (F n)" by simp
       qed
     qed
   qed
   thus ?thesis unfolding trading_strategy_def using sum_support_set[of pf1 pf2]
     by (meson assms(1) assms(2) subsetCE sum_portfolio trading_strategy_def)
 qed
 
 lemma (in disc_equity_market) mult_comp_trading_strat:
   assumes "trading_strategy pf1"
   and "borel_predict_stoch_proc F qty"
 shows "trading_strategy (qty_mult_comp pf1 qty)"
 proof -
   have "\<forall> asset \<in> support_set pf1. borel_predict_stoch_proc F (pf1 asset)"
     using assms unfolding trading_strategy_def by simp
   have "\<forall> asset \<in> support_set pf1. borel_predict_stoch_proc F (qty_mult_comp pf1 qty asset)"
     unfolding predict_stoch_proc_def qty_mult_comp_def
   proof (intro ballI conjI)
     fix asset
     assume "asset \<in> support_set pf1"
     show "(\<lambda>w. pf1 asset 0 w * qty 0 w) \<in> borel_measurable (F 0)"
     proof -
       have "(\<lambda>w. pf1 asset 0 w) \<in> borel_measurable (F 0)"
         using \<open>\<forall>asset\<in>support_set pf1. borel_predict_stoch_proc F (pf1 asset)\<close>
         \<open>asset \<in> support_set pf1\<close> predict_stoch_proc_def by auto
       moreover have "(\<lambda>w. qty 0 w) \<in> borel_measurable (F 0)" using assms predict_stoch_proc_def by auto
       ultimately show "(\<lambda>w. pf1 asset 0 w * qty 0 w) \<in> borel_measurable (F 0)" by simp
     qed
     show "\<forall>n. (\<lambda>w. pf1 asset (Suc n) w * qty (Suc n) w) \<in> borel_measurable (F n)"
     proof
       fix n
       have "(\<lambda>w. pf1 asset (Suc n) w) \<in> borel_measurable (F n)"
         using \<open>\<forall>asset\<in>support_set pf1. borel_predict_stoch_proc F (pf1 asset)\<close>
         \<open>asset \<in> support_set pf1\<close> predict_stoch_proc_def by blast
       moreover have "(\<lambda>w. qty (Suc n) w) \<in> borel_measurable (F n)" using assms predict_stoch_proc_def by blast
       ultimately show "(\<lambda>w. pf1 asset (Suc n) w * qty (Suc n) w) \<in> borel_measurable (F n)" by simp
     qed
   qed
   thus ?thesis unfolding trading_strategy_def using mult_comp_support_set[of pf1 qty]
     by (meson assms(1) mult_comp_portfolio subsetCE trading_strategy_def)
 qed
 
 lemma (in disc_equity_market) remove_comp_trading_strat:
   assumes "trading_strategy pf1"
 shows "trading_strategy (qty_rem_comp pf1 x)"
 proof -
   have "\<forall> asset \<in> support_set pf1. borel_predict_stoch_proc F (pf1 asset)"
     using assms unfolding trading_strategy_def by simp
   have "\<forall> asset \<in> support_set pf1. borel_predict_stoch_proc F (qty_rem_comp pf1 x asset)"
     unfolding predict_stoch_proc_def qty_rem_comp_def
   proof (intro ballI conjI)
     fix asset
     assume "asset \<in> support_set pf1"
     show "(pf1(x := \<lambda>n w. 0)) asset 0 \<in> borel_measurable (F 0)"
     proof -
       show "(\<lambda>w. (pf1(x := \<lambda>n w. 0)) asset 0 w) \<in> borel_measurable (F 0)"
       proof (cases "asset = x")
         case True
         thus ?thesis by simp
       next
         case False
         thus "(\<lambda>w. (pf1(x := \<lambda>n w. 0)) asset 0 w) \<in> borel_measurable (F 0)"
           using \<open>\<forall>asset\<in>support_set pf1. borel_predict_stoch_proc F (pf1 asset)\<close>
           \<open>asset \<in> support_set pf1\<close> by (simp add: predict_stoch_proc_def)
       qed
     qed
     show "\<forall>n. (\<lambda>w. (pf1(x := \<lambda>n w. 0)) asset (Suc n) w) \<in> borel_measurable (F n)"
     proof
       fix n
       show "(\<lambda>w. (pf1(x := \<lambda>n w. 0)) asset (Suc n) w) \<in> borel_measurable (F n)"
       proof (cases "asset = x")
         case True
         thus ?thesis by simp
       next
         case False
         thus "(\<lambda>w. (pf1(x := \<lambda>n w. 0)) asset (Suc n) w) \<in> borel_measurable (F n)"
           using \<open>\<forall>asset\<in>support_set pf1. borel_predict_stoch_proc F (pf1 asset)\<close>
           \<open>asset \<in> support_set pf1\<close> by (simp add: predict_stoch_proc_def)
       qed
     qed
   qed
   thus ?thesis unfolding trading_strategy_def using remove_comp_support_set[of pf1 x]
     by (metis Diff_empty assms remove_comp_portfolio subsetCE subset_Diff_insert trading_strategy_def)
 qed
 
 
 lemma (in disc_equity_market) replace_comp_trading_strat:
   assumes "trading_strategy pf1"
   and "trading_strategy pf2"
 shows "trading_strategy (qty_replace_comp pf1 x pf2)" unfolding qty_replace_comp_def
 proof (rule sum_trading_strat)
   show "trading_strategy (qty_rem_comp pf1 x)" using assms by (simp add: remove_comp_trading_strat)
   show "trading_strategy (qty_mult_comp pf2 (pf1 x))"
   proof (cases "x\<in> support_set pf1")
     case True
     hence "borel_predict_stoch_proc F (pf1 x)" using assms unfolding trading_strategy_def by simp
     thus ?thesis using assms by (simp add: mult_comp_trading_strat)
   next
     case False
     thus ?thesis
     proof -
       obtain nn :: "'c \<Rightarrow> ('c \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> nat" and aa :: "'c \<Rightarrow> ('c \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> 'a" where
         "\<forall>x0 x1. (\<exists>v2 v3. x1 x0 v2 v3 \<noteq> 0) = (x1 x0 (nn x0 x1) (aa x0 x1) \<noteq> 0)"
         by moura
       then have "\<forall>f c. (c \<notin> {c. \<exists>n a. f c n a \<noteq> 0} \<or> f c (nn c f) (aa c f) \<noteq> 0) \<and> (c \<in> {c. \<exists>n a. f c n a \<noteq> 0} \<or> (\<forall>n a. f c n a = 0))"
         by auto
       then show ?thesis
       proof -
         have "\<And>f c n a. qty_mult_comp f (pf1 x) (c::'c) n a = 0"
           by (metis False \<open>\<forall>f c. (c \<notin> {c. \<exists>n a. f c n a \<noteq> 0} \<or> f c (nn c f) (aa c f) \<noteq> 0) \<and> (c \<in> {c. \<exists>n a. f c n a \<noteq> 0} \<or> (\<forall>n a. f c n a = 0))\<close> mult.commute mult_zero_left qty_mult_comp_def support_set_def)
         then show ?thesis
           by (metis (no_types) \<open>\<forall>f c. (c \<notin> {c. \<exists>n a. f c n a \<noteq> 0} \<or> f c (nn c f) (aa c f) \<noteq> 0) \<and> (c \<in> {c. \<exists>n a. f c n a \<noteq> 0} \<or> (\<forall>n a. f c n a = 0))\<close> assms(2) mult_comp_portfolio support_set_def trading_strategy_def)
       qed
     qed
   qed
 qed
 
 
 
 subsubsection \<open>Self-financing portfolios\<close>
 
 paragraph \<open>Closing value process\<close>
 
 fun up_cl_proc where
   "up_cl_proc Mkt p 0 = val_process Mkt p 0" |
   "up_cl_proc Mkt p (Suc n) = (\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x (Suc n) w * p x (Suc n) w)"
 
 
 definition cls_val_process where
 "cls_val_process Mkt p = (if (\<not> (portfolio p)) then (\<lambda> n w. 0)
     else (\<lambda> n w . up_cl_proc Mkt p n w))"
 
 
 
 lemma (in disc_filtr_prob_space) quantity_updated_borel:
   assumes "\<forall>n. \<forall> asset \<in> support_set p. p asset (Suc n) \<in> borel_measurable (F n)"
 and "\<forall>n. \<forall>asset \<in> support_set p. prices Mkt asset n \<in> borel_measurable (F n)"
 shows "\<forall>n. cls_val_process Mkt p n \<in> borel_measurable (F n)"
 proof (cases "portfolio p")
 case False
   have "cls_val_process Mkt p = (\<lambda> n w. 0)" unfolding cls_val_process_def using False by simp
   thus "?thesis" by simp
 next
   case True
   show "\<forall>n. cls_val_process Mkt p n \<in> borel_measurable (F n)"
   proof
     fix n
     show "cls_val_process Mkt p n \<in> borel_measurable (F n)"
     proof (cases "n = 0")
       case False
       hence "\<exists>m. n = Suc m" using old.nat.exhaust by auto
       from this obtain m where "n = Suc m" by auto
       have "cls_val_process Mkt p (Suc m) = (\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x (Suc m) w * p x (Suc m) w)"
         unfolding cls_val_process_def using True by simp
       moreover have "(\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x (Suc m) w * p x (Suc m) w) \<in> borel_measurable (F (Suc m))"
       proof (rule borel_measurable_sum)
         fix asset
         assume "asset\<in> support_set p"
         hence "p asset (Suc m) \<in> borel_measurable (F m)" using assms unfolding trading_strategy_def adapt_stoch_proc_def by simp
         hence "p asset (Suc m) \<in> borel_measurable (F (Suc m))"
           using Suc_n_not_le_n increasing_measurable_info nat_le_linear by blast
         moreover have "prices Mkt asset (Suc m) \<in> borel_measurable (F (Suc m))"
           using \<open>asset \<in> support_set p\<close>  assms(2) unfolding support_adapt_def adapt_stoch_proc_def by blast
         ultimately show "(\<lambda>x. prices Mkt asset (Suc m) x * p asset (Suc m) x) \<in> borel_measurable (F (Suc m))" by simp
       qed
       ultimately have "cls_val_process Mkt p (Suc m) \<in> borel_measurable (F (Suc m))" by simp
       thus ?thesis using \<open>n = Suc m\<close> by simp
     next
       case True
       thus "cls_val_process Mkt p n \<in> borel_measurable (F n)"
         by (metis (no_types, lifting) assms(1) assms(2)  quantity_adapted up_cl_proc.simps(1)
             cls_val_process_def val_process_def)
     qed
   qed
 qed
 
 
 lemma (in disc_equity_market) cls_val_process_adapted:
   assumes "trading_strategy p"
 and "support_adapt Mkt p"
   shows "borel_adapt_stoch_proc F (cls_val_process Mkt p)"
 proof (cases "portfolio p")
   case False
     have "cls_val_process Mkt p = (\<lambda> n w. 0)" unfolding cls_val_process_def using False by simp
     thus "borel_adapt_stoch_proc F (cls_val_process Mkt p)"
       by (simp add: constant_process_borel_adapted)
 next
   case True
   show ?thesis unfolding adapt_stoch_proc_def
   proof
     fix n
     show "cls_val_process Mkt p n \<in> borel_measurable (F n)"
     proof (cases "n = 0")
     case True
       thus "cls_val_process Mkt p n \<in> borel_measurable (F n)"
         using up_cl_proc.simps(1) assms
         by (metis (no_types, lifting) adapt_stoch_proc_def ats_val_process_adapted cls_val_process_def
             val_process_def)
     next
     case False
       hence "\<exists>m. Suc m = n" using not0_implies_Suc by blast
       from this obtain m where "Suc m = n" by auto
       hence "cls_val_process Mkt p n = up_cl_proc Mkt p n" unfolding cls_val_process_def using True by simp
       also have "... = (\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x n w)"
         using up_cl_proc.simps(2) \<open>Suc m = n\<close> by auto
       finally have "cls_val_process Mkt p n = (\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x n w)" .
     moreover have "(\<lambda>w. \<Sum>x\<in>support_set p. prices Mkt x n w * p x n w) \<in> borel_measurable (F n)"
     proof (rule borel_measurable_sum)
       fix asset
       assume "asset\<in> support_set p"
       hence "p asset n \<in> borel_measurable (F n)" using assms unfolding trading_strategy_def predict_stoch_proc_def
         using Suc_n_not_le_n \<open>Suc m = n\<close> increasing_measurable_info nat_le_linear by blast
       moreover have "prices Mkt asset n \<in> borel_measurable (F n)" using  assms \<open>asset \<in> support_set p\<close> unfolding support_adapt_def adapt_stoch_proc_def
         using stock_portfolio_def by blast
       ultimately show "(\<lambda>x. prices Mkt asset n x * p asset n x) \<in> borel_measurable (F n)" by simp
     qed
     ultimately show "cls_val_process Mkt p n \<in> borel_measurable (F n)" by simp
     qed
   qed
 qed
 
 lemma subset_cls_val_process:
   assumes "finite A"
   and "support_set p \<subseteq> A"
 shows "\<forall>n w. cls_val_process Mkt p (Suc n) w = (sum (\<lambda>x. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w)) A)"
 proof (intro allI)
   fix n::nat
   fix w::'b
   have "portfolio p" using assms unfolding portfolio_def using finite_subset by auto
   have "\<exists>C. (support_set p) \<inter> C = {} \<and> (support_set p) \<union> C = A" using assms(2) by auto
   from this obtain C where "(support_set p) \<inter> C = {}" and "(support_set p) \<union> C = A" by auto note Cprops = this
   have "finite C" using assms \<open>(support_set p) \<union> C = A\<close> by auto
   have "\<forall>x\<in> C. p x (Suc n) w = 0" using Cprops(1) support_set_def by fastforce
   hence "(\<Sum>x\<in> C. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w)) = 0" by simp
   hence "cls_val_process Mkt p (Suc n) w = (\<Sum>x\<in> (support_set p). ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))
     + (\<Sum>x\<in> C. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))" unfolding cls_val_process_def
     using \<open>portfolio p\<close> up_cl_proc.simps(2)[of Mkt p n] by simp
   also have "... = (\<Sum> x\<in> A. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))"
     using \<open>portfolio p\<close> \<open>finite C\<close> Cprops portfolio_def sum_union_disjoint' by (metis (no_types, lifting))
   finally show "cls_val_process Mkt p (Suc n) w = (\<Sum> x\<in> A. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))" .
 qed
 
 lemma subset_cls_val_process':
   assumes "finite A"
   and "support_set p \<subseteq> A"
 shows "cls_val_process Mkt p (Suc n) w = (sum (\<lambda>x. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w)) A)"
 proof -
   have "portfolio p" using assms unfolding portfolio_def using finite_subset by auto
   have "\<exists>C. (support_set p) \<inter> C = {} \<and> (support_set p) \<union> C = A" using assms(2) by auto
   from this obtain C where "(support_set p) \<inter> C = {}" and "(support_set p) \<union> C = A" by auto note Cprops = this
   have "finite C" using assms \<open>(support_set p) \<union> C = A\<close> by auto
   have "\<forall>x\<in> C. p x (Suc n) w = 0" using Cprops(1) support_set_def by fastforce
   hence "(\<Sum>x\<in> C. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w)) = 0" by simp
   hence "cls_val_process Mkt p (Suc n) w = (\<Sum>x\<in> (support_set p). ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))
     + (\<Sum>x\<in> C. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))" unfolding cls_val_process_def
     using \<open>portfolio p\<close> up_cl_proc.simps(2)[of Mkt p n] by simp
   also have "... = (\<Sum> x\<in> A. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))"
     using \<open>portfolio p\<close> \<open>finite C\<close> Cprops portfolio_def sum_union_disjoint' by (metis (no_types, lifting))
   finally show "cls_val_process Mkt p (Suc n) w = (\<Sum> x\<in> A. ((prices Mkt) x (Suc n) w) * (p x (Suc n) w))" .
 qed
 
 
 
 lemma sum_cls_val_process_Suc:
   assumes "portfolio pf1"
   and "portfolio pf2"
 shows "\<forall>n w. cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w =
   (cls_val_process Mkt pf1) (Suc n) w + (cls_val_process Mkt pf2) (Suc n) w"
 proof (intro allI)
   fix n w
   have vp1: "cls_val_process Mkt pf1 (Suc n) w =
     (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w))"
   proof -
     have "finite (support_set pf1 \<union> support_set pf2) \<and> support_set pf1 \<subseteq> support_set pf1 \<union> support_set pf2"
       by (meson assms(1) assms(2) finite_Un portfolio_def sup.cobounded1)
     then show ?thesis
       by (simp add: subset_cls_val_process)
   qed
   have vp2: "cls_val_process Mkt pf2 (Suc n) w = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x (Suc n) w) * (pf2 x (Suc n) w))"
   proof -
     have "finite (support_set pf1 \<union> support_set pf2) \<and> support_set pf2 \<subseteq> support_set pf2 \<union> support_set pf1"
       by (meson assms(1) assms(2) finite_Un portfolio_def sup.cobounded1)
     then show ?thesis by (auto simp add: subset_cls_val_process)
   qed
   have pf:"portfolio (qty_sum pf1 pf2)" using assms by (simp add:sum_portfolio)
   have fin:"finite (support_set pf1 \<union> support_set pf2)" using assms finite_Un unfolding portfolio_def by auto
   have "(cls_val_process Mkt pf1) (Suc n) w + (cls_val_process Mkt pf2) (Suc n) w =
     (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w)) +
     (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2). ((prices Mkt) x (Suc n) w) * (pf2 x (Suc n) w))"
     using vp1 vp2 by simp
   also have "... = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2).
     (((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w)) + ((prices Mkt) x (Suc n) w) * (pf2 x (Suc n) w))"
     by (simp add: sum.distrib)
   also have "... = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2).
     ((prices Mkt) x (Suc n) w) * ((pf1 x (Suc n) w) + (pf2 x (Suc n) w)))" by (simp add: distrib_left)
   also have "... = (\<Sum> x\<in> (support_set pf1)\<union> (support_set pf2).
     ((prices Mkt) x (Suc n) w) * ((qty_sum pf1 pf2) x (Suc n) w))" by (simp add: qty_sum_def)
   also have "... = (\<Sum> x\<in> (support_set (qty_sum pf1 pf2)).
     ((prices Mkt) x (Suc n) w) * ((qty_sum pf1 pf2) x (Suc n) w))" using sum_support_set[of pf1 pf2]
     subset_cls_val_process[of "support_set pf1\<union> support_set pf2" "qty_sum pf1 pf2"] pf fin
     unfolding cls_val_process_def by simp
   also have "... = cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w"
     by (metis (no_types, lifting) pf sum.cong up_cl_proc.simps(2) cls_val_process_def)
   finally have "(cls_val_process Mkt pf1) (Suc n) w + (cls_val_process Mkt pf2) (Suc n) w =
     cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w" .
   thus "cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w =
     (cls_val_process Mkt pf1) (Suc n) w + (cls_val_process Mkt pf2) (Suc n) w" ..
 qed
 
 lemma sum_cls_val_process0:
   assumes "portfolio pf1"
   and "portfolio pf2"
 shows "\<forall>w. cls_val_process Mkt (qty_sum pf1 pf2) 0 w =
   (cls_val_process Mkt pf1) 0 w + (cls_val_process Mkt pf2) 0 w" unfolding cls_val_process_def
   by (simp add: sum_val_process assms(1) assms(2) sum_portfolio)
 
 lemma sum_cls_val_process:
   assumes "portfolio pf1"
   and "portfolio pf2"
 shows "\<forall>n w. cls_val_process Mkt (qty_sum pf1 pf2) n w =
   (cls_val_process Mkt pf1) n w + (cls_val_process Mkt pf2) n w"
   by (metis (no_types, lifting) assms(1) assms(2) sum_cls_val_process0 sum_cls_val_process_Suc up_cl_proc.elims)
 
 lemma mult_comp_cls_val_process0:
   assumes "portfolio pf1"
   shows "\<forall>w. cls_val_process Mkt (qty_mult_comp pf1 qty) 0 w =
   ((cls_val_process Mkt pf1) 0 w) * (qty (Suc 0) w)" unfolding cls_val_process_def
   by (simp add: assms mult_comp_portfolio mult_comp_val_process)
 
 lemma mult_comp_cls_val_process_Suc:
   assumes "portfolio pf1"
   shows "\<forall>n w. cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w =
   ((cls_val_process Mkt pf1) (Suc n) w) * (qty (Suc n) w)"
 proof (intro allI)
   fix n w
   have pf:"portfolio (qty_mult_comp pf1 qty)" using assms by (simp add:mult_comp_portfolio)
   have fin:"finite (support_set pf1)" using assms unfolding portfolio_def by auto
   have "((cls_val_process Mkt pf1) (Suc n) w) * (qty (Suc n) w) =
     (\<Sum> x\<in> (support_set pf1). ((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w))*(qty (Suc n) w)"
     unfolding cls_val_process_def using assms by simp
   also have "... = (\<Sum> x\<in> (support_set pf1).
     (((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w) * (qty (Suc n) w)))" using sum_distrib_right by auto
   also have "... = (\<Sum> x\<in> (support_set pf1).
     ((prices Mkt) x (Suc n) w) * ((qty_mult_comp pf1 qty) x (Suc n) w))" unfolding qty_mult_comp_def
     by (simp add: mult.commute mult.left_commute)
   also have "... = (\<Sum> x\<in> (support_set (qty_mult_comp pf1 qty)).
     ((prices Mkt) x (Suc n) w) * ((qty_mult_comp pf1 qty) x (Suc n) w))" using mult_comp_support_set[of pf1 qty]
     subset_cls_val_process[of "support_set pf1" "qty_mult_comp pf1 qty"] pf fin up_cl_proc.simps(2)
     unfolding cls_val_process_def by simp
   also have "... = cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w"   by (metis (no_types, lifting) pf sum.cong cls_val_process_def up_cl_proc.simps(2))
   finally have "(cls_val_process Mkt pf1) (Suc n) w * (qty (Suc n) w) = cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w" .
   thus "cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w = (cls_val_process Mkt pf1) (Suc n) w * (qty (Suc n) w)" ..
 qed
 
 
 
 
 lemma remove_comp_cls_val_process0:
   assumes "portfolio pf1"
   shows "\<forall>w. cls_val_process Mkt (qty_rem_comp pf1 y) 0 w =
   ((cls_val_process Mkt pf1) 0 w) - (prices Mkt y 0 w)* (pf1 y (Suc 0) w)" unfolding cls_val_process_def
   by (simp add: assms remove_comp_portfolio remove_comp_val_process)
 
 
 lemma remove_comp_cls_val_process_Suc:
   assumes "portfolio pf1"
   shows "\<forall>n w. cls_val_process Mkt (qty_rem_comp pf1 y) (Suc n) w =
   ((cls_val_process Mkt pf1) (Suc n) w) - (prices Mkt y (Suc n) w)* (pf1 y (Suc n) w)"
 proof (intro allI)
   fix n w
   have pf:"portfolio (qty_rem_comp pf1 y)" using assms by (simp add:remove_comp_portfolio)
   have fin:"finite (support_set pf1)" using assms unfolding portfolio_def by auto
   hence fin2: "finite (support_set pf1 - {y})" by simp
   have "((cls_val_process Mkt pf1) (Suc n) w)  =
     (\<Sum> x\<in> (support_set pf1). ((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w))"
     unfolding cls_val_process_def using assms by simp
   also have "... = (\<Sum> x\<in> (support_set pf1 - {y}).
     (((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w))) + (prices Mkt y (Suc n) w)* (pf1 y (Suc n) w)"
   proof (cases "y\<in> support_set pf1")
     case True
     thus ?thesis by (simp add: fin sum_diff1)
   next
     case False
     hence "pf1 y (Suc n) w = 0" unfolding support_set_def by simp
     thus ?thesis by (simp add: fin sum_diff1)
   qed
   also have "... = (\<Sum> x\<in> (support_set pf1 - {y}).
     ((prices Mkt) x (Suc n) w) * ((qty_rem_comp pf1 y) x (Suc n) w)) + (prices Mkt y (Suc n) w)* (pf1 y (Suc n) w)"
   proof -
     have "(\<Sum> x\<in> (support_set pf1 - {y}). (((prices Mkt) x (Suc n) w) * (pf1 x (Suc n) w))) =
       (\<Sum> x\<in> (support_set pf1 - {y}). ((prices Mkt) x (Suc n) w) * ((qty_rem_comp pf1 y) x (Suc n) w))"
     proof (rule sum.cong,simp)
       fix x
       assume "x\<in> support_set pf1 - {y}"
       show "prices Mkt x (Suc n) w * pf1 x (Suc n) w = prices Mkt x (Suc n) w * qty_rem_comp pf1 y x (Suc n) w" using remove_comp_values
         by (metis DiffD2 \<open>x \<in> support_set pf1 - {y}\<close> singletonI)
     qed
     thus ?thesis by simp
   qed
   also have "... = (cls_val_process Mkt (qty_rem_comp pf1 y) (Suc n) w) + (prices Mkt y (Suc n) w)* (pf1 y (Suc n) w)"
     using subset_cls_val_process[of "support_set pf1 - {y}" "qty_rem_comp pf1 y"] fin2
     by (simp add: remove_comp_support_set)
   finally have "(cls_val_process Mkt pf1) (Suc n) w =
     (cls_val_process Mkt (qty_rem_comp pf1 y) (Suc n) w) + (prices Mkt y (Suc n) w)* (pf1 y (Suc n) w)" .
   thus  "cls_val_process Mkt (qty_rem_comp pf1 y) (Suc n) w =
     ((cls_val_process Mkt pf1) (Suc n) w) - (prices Mkt y (Suc n) w)* (pf1 y (Suc n) w)" by simp
 qed
 
 
 
 lemma replace_comp_cls_val_process0:
   assumes "\<forall>w. prices Mkt x 0 w = cls_val_process Mkt pf2 0 w"
   and "portfolio pf1"
   and "portfolio pf2"
 shows "\<forall>w. cls_val_process Mkt (qty_replace_comp pf1 x pf2) 0 w = cls_val_process Mkt pf1 0 w"
 proof
   fix w
   have "cls_val_process Mkt (qty_replace_comp pf1 x pf2) 0 w = cls_val_process Mkt (qty_rem_comp pf1 x) 0 w +
     cls_val_process Mkt (qty_mult_comp pf2 (pf1 x)) 0 w" unfolding qty_replace_comp_def using assms
     sum_cls_val_process0[of "qty_rem_comp pf1 x" "qty_mult_comp pf2 (pf1 x)"]
     by (simp add: mult_comp_portfolio remove_comp_portfolio)
   also have "... = cls_val_process Mkt pf1 0 w - (prices Mkt x 0 w * pf1 x (Suc 0) w) +
     cls_val_process Mkt pf2 0 w * pf1 x (Suc 0) w"
     by (simp add: assms(2) assms(3) mult_comp_cls_val_process0 remove_comp_cls_val_process0)
   also have "... = cls_val_process Mkt pf1 0 w" using assms by simp
   finally show "cls_val_process Mkt (qty_replace_comp pf1 x pf2) 0 w = cls_val_process Mkt pf1 0 w" .
 qed
 
 
 lemma replace_comp_cls_val_process_Suc:
   assumes "\<forall>n w. prices Mkt x (Suc n) w = cls_val_process Mkt pf2 (Suc n) w"
   and "portfolio pf1"
   and "portfolio pf2"
   shows "\<forall>n w. cls_val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w = cls_val_process Mkt pf1 (Suc n) w"
 proof (intro allI)
   fix n w
   have "cls_val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w = cls_val_process Mkt (qty_rem_comp pf1 x) (Suc n) w +
     cls_val_process Mkt (qty_mult_comp pf2 (pf1 x)) (Suc n) w" unfolding qty_replace_comp_def using assms
     sum_cls_val_process_Suc[of "qty_rem_comp pf1 x" "qty_mult_comp pf2 (pf1 x)"]
     by (simp add: mult_comp_portfolio remove_comp_portfolio)
   also have "... = cls_val_process Mkt pf1 (Suc n) w - (prices Mkt x (Suc n) w * pf1 x (Suc n) w) +
     cls_val_process Mkt pf2 (Suc n) w * pf1 x (Suc n) w"
     by (simp add: assms(2) assms(3) mult_comp_cls_val_process_Suc remove_comp_cls_val_process_Suc)
   also have "... = cls_val_process Mkt pf1 (Suc n) w" using assms by simp
   finally show "cls_val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w = cls_val_process Mkt pf1 (Suc n) w" .
 qed
 
 
 lemma replace_comp_cls_val_process:
   assumes "\<forall>n w. prices Mkt x n w = cls_val_process Mkt pf2 n w"
   and "portfolio pf1"
   and "portfolio pf2"
   shows "\<forall>n w. cls_val_process Mkt (qty_replace_comp pf1 x pf2) n w = cls_val_process Mkt pf1 n w"
   by (metis (no_types, lifting) assms replace_comp_cls_val_process0 replace_comp_cls_val_process_Suc up_cl_proc.elims)
 
 
 lemma qty_single_updated:
   shows "cls_val_process Mkt (qty_single asset qty) (Suc n) w =
     prices Mkt asset (Suc n) w * qty (Suc n) w"
 proof -
   have "cls_val_process Mkt (qty_single asset qty) (Suc n) w =
     (sum (\<lambda>x. ((prices Mkt) x (Suc n) w) * ((qty_single asset qty) x (Suc n) w)) {asset})"
   proof (rule subset_cls_val_process')
     show "finite {asset}" by simp
     show "support_set (qty_single asset qty) \<subseteq> {asset}" by (simp add: single_comp_support)
   qed
   also have "... = prices Mkt asset (Suc n) w * qty (Suc n) w" unfolding qty_single_def by simp
   finally show ?thesis .
 qed
 
 
 
 paragraph \<open>Self-financing\<close>
 
 definition self_financing where
   "self_financing Mkt p \<longleftrightarrow> (\<forall>n. val_process Mkt p (Suc n) = cls_val_process Mkt p (Suc n))"
 
 
 lemma self_financingE:
   assumes "self_financing Mkt p"
   shows "\<forall>n. val_process Mkt p n = cls_val_process Mkt p n"
 proof
   fix n
   show "val_process Mkt p n = cls_val_process Mkt p n"
   proof (cases "n = 0")
     case False
     thus ?thesis using assms unfolding self_financing_def
       by (metis up_cl_proc.elims)
   next
     case True
     thus ?thesis by (simp add: cls_val_process_def val_process_def)
   qed
 qed
 
 
 
 
 lemma static_portfolio_self_financing:
   assumes "\<forall> x \<in> support_set p. (\<forall>w i. p x i w = p x (Suc i) w)"
   shows "self_financing Mkt p"
 unfolding self_financing_def
 proof (intro allI impI)
   fix n
   show "val_process Mkt p (Suc n) = cls_val_process Mkt p (Suc n)"
   proof (cases "portfolio p")
     case False
     thus ?thesis unfolding val_process_def cls_val_process_def by simp
   next
     case True
     have "\<forall>w. (\<Sum>x\<in> support_set p. prices Mkt x (Suc n) w * p x (Suc (Suc n)) w) =
          cls_val_process Mkt p (Suc n) w"
     proof
       fix w
       show "(\<Sum>x\<in> support_set p. prices Mkt x (Suc n) w * p x (Suc (Suc n)) w) =
            cls_val_process Mkt p (Suc n) w"
       proof -
         have "(\<Sum>x\<in> support_set p. prices Mkt x (Suc n) w * p x (Suc (Suc n)) w) =
             (\<Sum>x\<in> support_set p. prices Mkt x (Suc n) w * p x (Suc n) w)"
         proof (rule sum.cong, simp)
           fix x
           assume "x\<in> support_set p"
           hence "p x (Suc n) w = p x (Suc (Suc n)) w" using assms by blast
           thus "prices Mkt x (Suc n) w * p x (Suc (Suc n)) w = prices Mkt x (Suc n) w * p x (Suc n) w" by simp
         qed
         also have "... = cls_val_process Mkt p (Suc n) w"
            using up_cl_proc.simps(2)[of Mkt p n] by (metis True cls_val_process_def)
         finally show ?thesis .
       qed
     qed
     moreover have "\<forall>w. val_process Mkt p (Suc n) w = (\<Sum>x\<in> support_set p. prices Mkt x (Suc n) w * p x (Suc (Suc n)) w)"
       unfolding val_process_def using True by simp
     ultimately show ?thesis by auto
   qed
 qed
 
 
 
 lemma sum_self_financing:
   assumes "portfolio pf1"
   and "portfolio pf2"
   and "self_financing Mkt pf1"
   and "self_financing Mkt pf2"
 shows "self_financing Mkt (qty_sum pf1 pf2)"
 proof -
   have "\<forall> n w. val_process Mkt (qty_sum pf1 pf2) (Suc n) w =
     cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w"
   proof (intro allI)
     fix n w
     have "val_process Mkt (qty_sum pf1 pf2) (Suc n) w = val_process Mkt pf1 (Suc n) w + val_process Mkt pf2 (Suc n) w"
       using assms by (simp add:sum_val_process)
     also have "... = cls_val_process Mkt pf1 (Suc n) w + val_process Mkt pf2 (Suc n) w" using assms
       unfolding self_financing_def by simp
     also have "... = cls_val_process Mkt pf1 (Suc n) w + cls_val_process Mkt pf2 (Suc n) w"
       using assms unfolding self_financing_def by simp
     also have "... = cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w" using assms by (simp add: sum_cls_val_process)
     finally show "val_process Mkt (qty_sum pf1 pf2) (Suc n) w =
       cls_val_process Mkt (qty_sum pf1 pf2) (Suc n) w" .
   qed
   thus ?thesis unfolding self_financing_def by auto
 qed
 
 lemma mult_time_constant_self_financing:
   assumes "portfolio pf1"
   and "self_financing Mkt pf1"
   and "\<forall>n w. qty n w = qty (Suc n) w"
 shows "self_financing Mkt (qty_mult_comp pf1 qty)"
 proof -
   have "\<forall> n w. val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w =
     cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w"
   proof (intro allI)
     fix n w
     have "val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w = val_process Mkt pf1 (Suc n) w * qty (Suc n) w"
       using assms by (simp add:mult_comp_val_process)
     also have "... = cls_val_process Mkt pf1 (Suc n) w * qty (Suc n) w" using assms
       unfolding self_financing_def by simp
     also have "... = cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w" using assms
        by (auto simp add: mult_comp_cls_val_process_Suc)
     finally show "val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w =
       cls_val_process Mkt (qty_mult_comp pf1 qty) (Suc n) w" .
   qed
   thus ?thesis unfolding self_financing_def by auto
 qed
 
 
 
 lemma replace_comp_self_financing:
   assumes "\<forall>n w. prices Mkt x n w = cls_val_process Mkt pf2 n w"
   and "portfolio pf1"
   and "portfolio pf2"
   and "self_financing Mkt pf1"
   and "self_financing Mkt pf2"
 shows "self_financing Mkt (qty_replace_comp pf1 x pf2)"
 proof -
   have sfeq: "\<forall>n w. prices Mkt x n w = val_process Mkt pf2 n w" using assms by (simp add: self_financingE)
   have "\<forall> n w. cls_val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w =
     val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w"
   proof (intro allI)
     fix n w
     have "cls_val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w = cls_val_process Mkt pf1 (Suc n) w"
       using assms by (simp add:replace_comp_cls_val_process)
     also have "... = val_process Mkt pf1 (Suc n) w" using assms unfolding self_financing_def by simp
     also have "... = val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w"
       using assms sfeq by (simp add: replace_comp_val_process self_financing_def)
     finally show "cls_val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w =
       val_process Mkt (qty_replace_comp pf1 x pf2) (Suc n) w" .
   qed
   thus ?thesis unfolding self_financing_def by auto
 qed
 
 
 
 
 paragraph \<open>Make a portfolio self-financing\<close>
 
 fun  remaining_qty where
   init: "remaining_qty Mkt v pf asset 0 = (\<lambda>w. 0)" |
   first:  "remaining_qty Mkt v pf asset (Suc 0) = (\<lambda>w. (v - val_process Mkt pf 0 w)/(prices Mkt asset 0 w))" |
   step: "remaining_qty Mkt v pf asset (Suc (Suc n)) = (\<lambda>w. (remaining_qty Mkt v pf asset (Suc n) w) +
     (cls_val_process Mkt pf (Suc n) w - val_process Mkt pf (Suc n) w)/(prices Mkt asset (Suc n) w))"
 
 lemma (in disc_equity_market) remaining_qty_predict':
   assumes "borel_adapt_stoch_proc F (prices Mkt asset)"
   and "trading_strategy pf"
 and "support_adapt Mkt pf"
 shows "remaining_qty Mkt v pf asset (Suc n) \<in> borel_measurable (F n)"
 proof (induct n)
   case 0
   have "(\<lambda>w. (v - val_process Mkt pf 0 w)/(prices Mkt asset 0 w))\<in> borel_measurable (F 0)"
   proof (rule borel_measurable_divide)
     have "val_process Mkt pf 0 \<in> borel_measurable (F 0)" using assms
       ats_val_process_adapted by (simp add:adapt_stoch_proc_def)
     thus "(\<lambda>x. v - val_process Mkt pf 0 x) \<in> borel_measurable (F 0)" by simp
     show "prices Mkt asset 0 \<in> borel_measurable (F 0)" using assms unfolding adapt_stoch_proc_def by simp
   qed
   thus ?case by simp
 next
   case (Suc n)
   have "(\<lambda>w. (cls_val_process Mkt pf (Suc n) w - val_process Mkt pf (Suc n) w)/
     (prices Mkt asset (Suc n) w)) \<in> borel_measurable (F (Suc n))"
   proof (rule borel_measurable_divide)
     show "(\<lambda>w. (cls_val_process Mkt pf (Suc n) w - val_process Mkt pf (Suc n) w)) \<in> borel_measurable (F (Suc n))"
     proof (rule borel_measurable_diff)
       show "(\<lambda>w. (cls_val_process Mkt pf (Suc n) w)) \<in> borel_measurable (F (Suc n))"
         using assms cls_val_process_adapted unfolding adapt_stoch_proc_def by auto
       show "(\<lambda>w. (val_process Mkt pf (Suc n) w)) \<in> borel_measurable (F (Suc n))"
         using assms  ats_val_process_adapted by (simp add:adapt_stoch_proc_def)
     qed
     show "prices Mkt asset (Suc n) \<in> borel_measurable (F (Suc n))" using assms unfolding adapt_stoch_proc_def by simp
   qed
   moreover have "remaining_qty Mkt v pf asset (Suc n) \<in> borel_measurable (F (Suc n))" using Suc
     Suc_n_not_le_n increasing_measurable_info nat_le_linear by blast
   ultimately show ?case using Suc remaining_qty.simps(3)[of Mkt v pf asset n] by simp
 qed
 
 lemma (in disc_equity_market) remaining_qty_predict:
   assumes "borel_adapt_stoch_proc F (prices Mkt asset)"
   and "trading_strategy pf"
 and "support_adapt Mkt pf"
 shows "borel_predict_stoch_proc F (remaining_qty Mkt v pf asset)"  unfolding predict_stoch_proc_def
 proof (intro conjI allI)
   show "remaining_qty Mkt v pf asset 0 \<in> borel_measurable (F 0)" using init by simp
   fix n
   show "remaining_qty Mkt v pf asset (Suc n) \<in> borel_measurable (F n)" using assms by (simp add: remaining_qty_predict')
 qed
 
 
 lemma (in disc_equity_market) remaining_qty_adapt:
   assumes "borel_adapt_stoch_proc F (prices Mkt asset)"
   and "trading_strategy pf"
 and "support_adapt Mkt pf"
 shows "remaining_qty Mkt v pf asset n \<in> borel_measurable (F n)"
   using adapt_stoch_proc_def assms(1) assms(2) predict_imp_adapt remaining_qty_predict
   by (metis assms(3))
 
 
 lemma (in disc_equity_market) remaining_qty_adapted:
   assumes "borel_adapt_stoch_proc F (prices Mkt asset)"
   and "trading_strategy pf"
 and "support_adapt Mkt pf"
 shows "borel_adapt_stoch_proc F (remaining_qty Mkt v pf asset)" using assms unfolding adapt_stoch_proc_def
   using assms remaining_qty_adapt by blast
 
 
 definition self_finance where
   "self_finance Mkt v pf (asset::'a) = qty_sum pf (qty_single asset (remaining_qty Mkt v pf asset))"
 
 
 lemma self_finance_portfolio:
   assumes "portfolio pf"
 shows "portfolio (self_finance Mkt v pf asset)" unfolding self_finance_def
   by (simp add: assms single_comp_portfolio sum_portfolio)
 
 
 lemma self_finance_init:
   assumes "\<forall>w. prices Mkt asset 0 w \<noteq> 0"
   and "portfolio pf"
 shows "val_process Mkt (self_finance Mkt v pf asset) 0 w = v"
 proof -
   define scp where "scp = qty_single asset (remaining_qty Mkt v pf asset)"
   have "val_process Mkt (self_finance Mkt v pf asset) 0 w =
     val_process Mkt pf 0 w +
     val_process Mkt scp 0 w" unfolding scp_def using assms single_comp_portfolio[of asset]
     sum_val_process[of pf "qty_single asset (remaining_qty Mkt v pf asset)" Mkt]
     by (simp add: \<open>\<And>qty. portfolio (qty_single asset qty)\<close> self_finance_def)
   also have "... = val_process Mkt pf 0 w +
     (sum (\<lambda>x. ((prices Mkt) x 0 w) * (scp x (Suc 0) w)) {asset})"
     using subset_val_process'[of "{asset}" scp] unfolding scp_def by (auto simp add:  single_comp_support)
   also have "... = val_process Mkt pf 0 w + prices Mkt asset 0 w * scp asset (Suc 0) w" by auto
   also have "... = val_process Mkt pf 0 w + prices Mkt asset 0 w * (remaining_qty Mkt v pf asset) (Suc 0) w"
     unfolding scp_def qty_single_def by simp
   also have "... = val_process Mkt pf 0 w + prices Mkt asset 0 w * (v - val_process Mkt pf 0 w)/(prices Mkt asset 0 w)"
     by simp
   also have "... = val_process Mkt pf 0 w + (v - val_process Mkt pf 0 w)" using assms by simp
   also have "... = v" by simp
   finally show ?thesis .
 qed
 
 
 lemma self_finance_succ:
   assumes "prices Mkt asset (Suc n) w \<noteq> 0"
   and "portfolio pf"
 shows "val_process Mkt (self_finance Mkt v pf asset) (Suc n) w = prices Mkt asset (Suc n) w * remaining_qty Mkt v pf asset (Suc n) w +
   cls_val_process Mkt pf (Suc n) w"
 proof -
   define scp where "scp = qty_single asset (remaining_qty Mkt v pf asset)"
   have "val_process Mkt (self_finance Mkt v pf asset) (Suc n) w =
     val_process Mkt pf (Suc n) w +
     val_process Mkt scp (Suc n) w" unfolding scp_def using assms single_comp_portfolio[of asset]
     sum_val_process[of pf "qty_single asset (remaining_qty Mkt v pf asset)" Mkt]
     by (simp add: \<open>\<And>qty. portfolio (qty_single asset qty)\<close> self_finance_def)
   also have "... = val_process Mkt pf (Suc n) w +
     (sum (\<lambda>x. ((prices Mkt) x (Suc n) w) * (scp x (Suc (Suc n)) w)) {asset})"
     using subset_val_process'[of "{asset}" scp] unfolding scp_def by (auto simp add:  single_comp_support)
   also have "... = val_process Mkt pf (Suc n) w + prices Mkt asset (Suc n) w * scp asset (Suc (Suc n)) w" by auto
   also have "... = val_process Mkt pf (Suc n) w + prices Mkt asset (Suc n) w * (remaining_qty Mkt v pf asset) (Suc (Suc n)) w"
     unfolding scp_def qty_single_def by simp
   also have "... = val_process Mkt pf (Suc n) w +
     prices Mkt asset (Suc n) w *
     (remaining_qty Mkt v pf asset (Suc n) w + (cls_val_process Mkt pf (Suc n) w - val_process Mkt pf (Suc n) w)/(prices Mkt asset (Suc n) w))"
     by simp
   also have "... = val_process Mkt pf (Suc n) w +
      prices Mkt asset (Suc n) w * remaining_qty Mkt v pf asset (Suc n) w +
     prices Mkt asset (Suc n) w * (cls_val_process Mkt pf (Suc n) w - val_process Mkt pf (Suc n) w)/(prices Mkt asset (Suc n) w)"
      by (simp add: distrib_left)
   also have "... = val_process Mkt pf (Suc n) w +
      prices Mkt asset (Suc n) w * remaining_qty Mkt v pf asset (Suc n) w + (cls_val_process Mkt pf (Suc n) w - val_process Mkt pf (Suc n) w)"
      using assms by simp
   also have "... = prices Mkt asset (Suc n) w * remaining_qty Mkt v pf asset (Suc n) w + cls_val_process Mkt pf (Suc n) w" by simp
   finally show ?thesis .
 qed
 
 
 lemma self_finance_updated:
   assumes "prices Mkt asset (Suc n) w \<noteq> 0"
   and "portfolio pf"
 shows "cls_val_process Mkt (self_finance Mkt v pf asset) (Suc n) w =
   cls_val_process Mkt pf (Suc n) w + prices Mkt asset (Suc n) w * (remaining_qty Mkt v pf asset) (Suc n) w"
 proof -
   define scp where "scp = qty_single asset (remaining_qty Mkt v pf asset)"
   have "cls_val_process Mkt (self_finance Mkt v pf asset) (Suc n) w =
     cls_val_process Mkt pf (Suc n) w +
     cls_val_process Mkt scp (Suc n) w" unfolding scp_def using assms single_comp_portfolio[of asset]
     sum_cls_val_process[of pf "qty_single asset (remaining_qty Mkt v pf asset)" Mkt]
     by (simp add: \<open>\<And>qty. portfolio (qty_single asset qty)\<close> self_finance_def)
   also have "... = cls_val_process Mkt pf (Suc n) w +
     (sum (\<lambda>x. ((prices Mkt) x (Suc n) w) * (scp x (Suc n) w)) {asset})"
     using subset_cls_val_process[of "{asset}" scp] unfolding scp_def by (auto simp add:  single_comp_support)
   also have "... = cls_val_process Mkt pf (Suc n) w + prices Mkt asset (Suc n) w * scp asset (Suc n) w" by auto
   also have "... = cls_val_process Mkt pf (Suc n) w + prices Mkt asset (Suc n) w * (remaining_qty Mkt v pf asset) (Suc n) w"
     unfolding scp_def qty_single_def by simp
   finally show ?thesis .
 qed
 
 lemma self_finance_charact:
   assumes "\<forall> n w. prices Mkt asset (Suc n) w \<noteq> 0"
   and "portfolio pf"
 shows "self_financing Mkt (self_finance Mkt v pf asset)"
 proof-
   have "\<forall>n w. val_process Mkt (self_finance Mkt v pf asset) (Suc n) w =
      cls_val_process Mkt (self_finance Mkt v pf asset) (Suc n) w"
   proof (intro allI)
     fix n w
     show "val_process Mkt (self_finance Mkt v pf asset) (Suc n) w =
       cls_val_process Mkt (self_finance Mkt v pf asset) (Suc n) w" using assms self_finance_succ[of Mkt asset]
       by (simp add: self_finance_updated)
   qed
   thus ?thesis unfolding self_financing_def by auto
 qed
 
 
 subsubsection \<open>Replicating portfolios\<close>
 
 
 definition (in disc_filtr_prob_space) price_structure::"('a \<Rightarrow> real) \<Rightarrow> nat \<Rightarrow> real \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> bool" where
   "price_structure pyf T \<pi> pr \<longleftrightarrow> ((\<forall> w\<in> space M. pr 0 w = \<pi>) \<and> (AE w in M. pr T w = pyf w) \<and> (pr T \<in> borel_measurable (F T)))"
 
 lemma (in disc_filtr_prob_space) price_structure_init:
   assumes "price_structure pyf T \<pi> pr"
   shows "\<forall> w\<in> space M. pr 0 w = \<pi>" using assms unfolding price_structure_def by simp
 
 lemma (in disc_filtr_prob_space) price_structure_borel_measurable:
   assumes "price_structure pyf T \<pi> pr"
   shows "pr T \<in> borel_measurable (F T)" using assms unfolding price_structure_def by simp
 
 lemma (in disc_filtr_prob_space) price_structure_maturity:
   assumes "price_structure pyf T \<pi> pr"
   shows "AE w in M. pr T w = pyf w" using assms unfolding price_structure_def by simp
 
 definition (in disc_equity_market) replicating_portfolio where
   "replicating_portfolio pf der matur  \<longleftrightarrow> (stock_portfolio Mkt pf) \<and> (trading_strategy pf) \<and> (self_financing Mkt pf) \<and>
   (AE w in M. cls_val_process Mkt pf matur w = der w)"
 
 
 definition (in disc_equity_market) is_attainable where
   "is_attainable der matur \<longleftrightarrow> (\<exists> pf. replicating_portfolio pf der matur)"
 
 lemma (in disc_equity_market) replicating_price_process:
   assumes "replicating_portfolio pf der matur"
 and "support_adapt Mkt pf"
   shows "price_structure der matur (initial_value pf) (cls_val_process Mkt pf)"
   unfolding price_structure_def
 proof (intro conjI)
   show "AE w in M. cls_val_process Mkt pf matur w = der w" using assms unfolding replicating_portfolio_def by simp
   show "\<forall>w\<in>space M. cls_val_process Mkt pf 0 w = initial_value pf"
   proof
     fix w
     assume "w\<in> space M"
     thus "cls_val_process Mkt pf 0 w = initial_value pf" unfolding initial_value_def using constant_imageI[of "cls_val_process Mkt pf 0"]
       trading_strategy_init[of pf] assms replicating_portfolio_def [of pf der matur]
       by (simp add: stock_portfolio_def cls_val_process_def)
   qed
   show "cls_val_process Mkt pf matur \<in> borel_measurable (F matur)" using assms unfolding replicating_portfolio_def
     using ats_val_process_adapted[of pf]
     cls_val_process_adapted by (simp add:adapt_stoch_proc_def)
 qed
 
 
 subsubsection \<open>Arbitrages\<close>
 
 
 definition (in disc_filtr_prob_space) arbitrage_process
 where
   "arbitrage_process Mkt p \<longleftrightarrow> (\<exists> m. (self_financing Mkt p) \<and> (trading_strategy p) \<and>
     (\<forall>w \<in> space M. val_process Mkt p 0 w = 0) \<and>
     (AE w in M. 0 \<le> cls_val_process Mkt p m w) \<and>
     0 < \<P>(w in M. cls_val_process Mkt p m w > 0))"
 
 lemma (in disc_filtr_prob_space) arbitrage_processE:
   assumes "arbitrage_process Mkt p"
   shows "(\<exists> m. (self_financing Mkt p) \<and> (trading_strategy p) \<and>
     (\<forall>w \<in> space M. cls_val_process Mkt p 0 w = 0) \<and>
     (AE w in M. 0 \<le> cls_val_process Mkt p m w) \<and>
     0 < \<P>(w in M. cls_val_process Mkt p m w > 0))"
   using assms disc_filtr_prob_space.arbitrage_process_def disc_filtr_prob_space_axioms self_financingE by fastforce
 
 
 
 lemma (in disc_filtr_prob_space) arbitrage_processI:
   assumes "(\<exists> m. (self_financing Mkt p) \<and> (trading_strategy p) \<and>
     (\<forall>w \<in> space M. cls_val_process Mkt p 0 w = 0) \<and>
     (AE w in M. 0 \<le> cls_val_process Mkt p m w) \<and>
     0 < \<P>(w in M. cls_val_process Mkt p m w > 0))"
   shows "arbitrage_process Mkt p" unfolding arbitrage_process_def  using assms
   by (simp add: self_financingE cls_val_process_def)
 
 definition (in disc_filtr_prob_space) viable_market
 where
   "viable_market Mkt  \<longleftrightarrow> (\<forall>p. stock_portfolio Mkt p \<longrightarrow> \<not> arbitrage_process Mkt p)"
 
 lemma (in disc_filtr_prob_space) arbitrage_val_process:
   assumes "arbitrage_process Mkt pf1"
   and "self_financing Mkt pf2"
   and "trading_strategy pf2"
   and "\<forall> n w. cls_val_process Mkt pf1 n w = cls_val_process Mkt pf2 n w"
 shows "arbitrage_process Mkt pf2"
 proof -
   have "(\<exists> m. (self_financing Mkt pf1) \<and> (trading_strategy pf1) \<and>
     (\<forall>w \<in> space M. cls_val_process Mkt pf1 0 w = 0) \<and>
     (AE w in M. 0 \<le> cls_val_process Mkt pf1 m w) \<and>
     0 < \<P>(w in M. cls_val_process Mkt pf1 m w > 0))" using assms arbitrage_processE[of Mkt pf1] by simp
   from this obtain m where "(self_financing Mkt pf1)" and "(trading_strategy pf1)" and
     "(\<forall>w \<in> space M. cls_val_process Mkt pf1 0 w = 0)" and
     "(AE w in M. 0 \<le> cls_val_process Mkt pf1 m w)"
     "0 < \<P>(w in M. cls_val_process Mkt pf1 m w > 0)" by auto
   have ae_eq:"\<forall>w\<in> space M. (cls_val_process Mkt pf1 0 w = 0) = (cls_val_process Mkt pf2 0 w = 0)"
   proof
     fix w
     assume "w\<in> space M"
     show "(cls_val_process Mkt pf1 0 w = 0) = (cls_val_process Mkt pf2 0 w = 0) "
       using  assms  by simp
   qed
   have ae_geq:"almost_everywhere M (\<lambda>w. cls_val_process Mkt pf1 m w \<ge> 0) = almost_everywhere M (\<lambda>w. cls_val_process Mkt pf2 m w \<ge> 0)"
   proof (rule AE_cong)
     fix w
     assume "w\<in> space M"
     show "(cls_val_process Mkt pf1 m w \<ge> 0) = (cls_val_process Mkt pf2 m w \<ge> 0) "
       using  assms by simp
   qed
   have "self_financing Mkt pf2" using assms by simp
   moreover have "trading_strategy pf2" using assms by simp
   moreover have "(\<forall>w \<in> space M. cls_val_process Mkt pf2 0 w = 0)"  using \<open>(\<forall>w \<in> space M. cls_val_process Mkt pf1 0 w = 0)\<close> ae_eq by simp
   moreover have "AE w in M. 0 \<le> cls_val_process Mkt pf2 m w" using \<open>AE w in M. 0 \<le> cls_val_process Mkt pf1 m w\<close> ae_geq by simp
   moreover have "0 < prob {w \<in> space M. 0 < cls_val_process Mkt pf2 m w}"
   proof -
     have "{w \<in> space M. 0 < cls_val_process Mkt pf2 m w} = {w \<in> space M. 0 < cls_val_process Mkt pf1 m w}"
       by (simp add: assms(4))
     thus ?thesis by (simp add: \<open>0 < prob {w \<in> space M. 0 < cls_val_process Mkt pf1 m w}\<close>)
   qed
   ultimately show ?thesis using arbitrage_processI by blast
 qed
 
 
 definition coincides_on where
   "coincides_on Mkt Mkt2 A \<longleftrightarrow> (stocks Mkt = stocks Mkt2 \<and> (\<forall>x. x\<in> A \<longrightarrow> prices Mkt x = prices Mkt2 x))"
 
 lemma coincides_val_process:
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set pf \<subseteq> A"
   shows "\<forall>n w. val_process Mkt pf n w = val_process Mkt2 pf n w"
 proof (intro allI)
   fix n w
   show "val_process Mkt pf n w = val_process Mkt2 pf n w"
   proof (cases "portfolio pf")
     case False
     thus ?thesis unfolding val_process_def by simp
   next
     case True
     hence "val_process Mkt pf n w = (\<Sum>x\<in> support_set pf. prices Mkt x n w * pf x (Suc n) w)" using assms
       unfolding val_process_def  by simp
     also have "... = (\<Sum>x\<in> support_set pf. prices Mkt2 x n w * pf x (Suc n) w)"
     proof (rule sum.cong, simp)
       fix y
       assume "y\<in> support_set pf"
       hence "y\<in> A" using assms unfolding  stock_portfolio_def by auto
       hence "prices Mkt y n w = prices Mkt2 y n w" using assms
         unfolding coincides_on_def by auto
       thus "prices Mkt y n w * pf y (Suc n) w = prices Mkt2 y n w * pf y (Suc n) w" by simp
     qed
     also have "... = val_process Mkt2 pf n w"
       by (metis (mono_tags, lifting) calculation val_process_def)
     finally show "val_process Mkt pf n w = val_process Mkt2 pf n w" .
   qed
 qed
 
 lemma coincides_cls_val_process':
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set pf \<subseteq> A"
   shows "\<forall>n w. cls_val_process Mkt pf (Suc n) w = cls_val_process Mkt2 pf (Suc n) w"
 proof (intro allI)
   fix n w
   show "cls_val_process Mkt pf (Suc n) w = cls_val_process Mkt2 pf (Suc n) w"
   proof (cases "portfolio pf")
     case False
     thus ?thesis unfolding cls_val_process_def by simp
   next
     case True
     hence "cls_val_process Mkt pf (Suc n) w = (\<Sum>x\<in> support_set pf. prices Mkt x (Suc n) w * pf x (Suc n) w)" using assms
       unfolding cls_val_process_def  by simp
     also have "... = (\<Sum>x\<in> support_set pf. prices Mkt2 x (Suc n) w * pf x (Suc n) w)"
     proof (rule sum.cong, simp)
       fix y
       assume "y\<in> support_set pf"
       hence "y\<in> A" using assms unfolding  stock_portfolio_def by auto
       hence "prices Mkt y (Suc n) w = prices Mkt2 y (Suc n) w" using assms
         unfolding coincides_on_def by auto
       thus "prices Mkt y (Suc n) w * pf y (Suc n) w = prices Mkt2 y (Suc n) w * pf y (Suc n) w" by simp
     qed
     also have "... = cls_val_process Mkt2 pf (Suc n) w"
       by (metis (mono_tags, lifting) True  up_cl_proc.simps(2) cls_val_process_def)
     finally show "cls_val_process Mkt pf (Suc n) w = cls_val_process Mkt2 pf (Suc n) w" .
   qed
 qed
 
 lemma coincides_cls_val_process:
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set pf \<subseteq> A"
   shows "\<forall>n w. cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w"
 proof (intro allI)
   fix n w
   show "cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w"
   proof (cases "portfolio pf")
     case False
     thus ?thesis unfolding cls_val_process_def by simp
   next
     case True
     show "cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w"
     proof (induct n)
       case 0
       with assms show ?case
         by (simp add: cls_val_process_def coincides_val_process)
     next
       case Suc
       thus ?case using coincides_cls_val_process' assms by blast
     qed
   qed
 qed
 
 
 lemma (in disc_filtr_prob_space) coincides_on_self_financing:
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set p \<subseteq> A"
   and "self_financing Mkt p"
 shows "self_financing Mkt2 p"
 proof -
   have "\<forall> n w. val_process Mkt2 p (Suc n) w = cls_val_process Mkt2 p (Suc n) w"
   proof (intro allI)
     fix n w
     have "val_process Mkt2 p (Suc n) w = val_process Mkt p (Suc n) w"
       using assms(1) assms(2) coincides_val_process stock_portfolio_def by fastforce
     also have "... = cls_val_process Mkt p (Suc n) w" by (metis \<open>self_financing Mkt p\<close> self_financing_def)
     also have "... = cls_val_process Mkt2 p (Suc n) w"
       using assms(1) assms(2) coincides_cls_val_process stock_portfolio_def by blast
     finally show "val_process Mkt2 p (Suc n) w = cls_val_process Mkt2 p (Suc n) w" .
   qed
   thus "self_financing Mkt2 p" unfolding self_financing_def by auto
 qed
 
 
 lemma (in disc_filtr_prob_space) coincides_on_arbitrage:
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set p \<subseteq> A"
   and "arbitrage_process Mkt p"
 shows "arbitrage_process Mkt2 p"
 proof -
   have "(\<exists> m. (self_financing Mkt p) \<and> (trading_strategy p) \<and>
     (\<forall>w\<in> space M. cls_val_process Mkt p 0 w = 0) \<and>
     (AE w in M. 0 \<le> cls_val_process Mkt p m w) \<and>
     0 < \<P>(w in M. cls_val_process Mkt p m w > 0))" using assms using arbitrage_processE by simp
   from this obtain m where "(self_financing Mkt p)" and "(trading_strategy p)" and
     "(\<forall>w\<in> space M. cls_val_process Mkt p 0 w = 0)" and
     "(AE w in M. 0 \<le> cls_val_process Mkt p m w)"
     "0 < \<P>(w in M. cls_val_process Mkt p m w > 0)" by auto
   have ae_eq:"\<forall>w\<in> space M. (cls_val_process Mkt2 p 0 w = 0) = (cls_val_process Mkt p 0 w = 0)"
   proof
     fix w
     assume "w\<in> space M"
     show "(cls_val_process Mkt2 p 0 w = 0) = (cls_val_process Mkt p 0 w = 0) "
       using  assms coincides_cls_val_process by (metis)
   qed
   have ae_geq:"almost_everywhere M (\<lambda>w. cls_val_process Mkt2 p m w \<ge> 0) = almost_everywhere M (\<lambda>w. cls_val_process Mkt p m w \<ge> 0)"
   proof (rule AE_cong)
     fix w
     assume "w\<in> space M"
     show "(cls_val_process Mkt2 p m w \<ge> 0) = (cls_val_process Mkt p m w \<ge> 0) "
       using  assms coincides_cls_val_process by (metis)
   qed
   have "self_financing Mkt2 p" using assms coincides_on_self_financing
     using \<open>self_financing Mkt p\<close> by blast
   moreover have "trading_strategy p" using \<open>trading_strategy p\<close> .
   moreover have "(\<forall>w\<in> space M. cls_val_process Mkt2 p 0 w = 0)"  using \<open>(\<forall>w\<in> space M. cls_val_process Mkt p 0 w = 0)\<close> ae_eq by simp
   moreover have "AE w in M. 0 \<le> cls_val_process Mkt2 p m w" using \<open>AE w in M. 0 \<le> cls_val_process Mkt p m w\<close> ae_geq by simp
   moreover have "0 < prob {w \<in> space M. 0 < cls_val_process Mkt2 p m w}"
   proof -
     have "{w \<in> space M. 0 < cls_val_process Mkt2 p m w} = {w \<in> space M. 0 < cls_val_process Mkt p m w}"
       by (metis (no_types, lifting) assms(1) assms(2) coincides_cls_val_process)
     thus ?thesis by (simp add: \<open>0 < prob {w \<in> space M. 0 < cls_val_process Mkt p m w}\<close>)
   qed
   ultimately show ?thesis using arbitrage_processI by blast
 qed
 
 
 lemma (in disc_filtr_prob_space) coincides_on_stocks_viable:
   assumes "coincides_on Mkt Mkt2 (stocks Mkt)"
   and "viable_market Mkt"
 shows "viable_market Mkt2" using coincides_on_arbitrage
   by (metis (mono_tags, opaque_lifting) assms(1) assms(2) coincides_on_def stock_portfolio_def viable_market_def)
 
 
 lemma coincides_stocks_val_process:
   assumes "stock_portfolio Mkt pf"
   and "coincides_on Mkt Mkt2 (stocks Mkt)"
 shows "\<forall>n w. val_process Mkt pf n w = val_process Mkt2 pf n w" using assms  unfolding stock_portfolio_def
   by (simp add: coincides_val_process)
 
 lemma coincides_stocks_cls_val_process:
   assumes "stock_portfolio Mkt pf"
   and "coincides_on Mkt Mkt2 (stocks Mkt)"
 shows "\<forall>n w. cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w" using assms  unfolding stock_portfolio_def
     by (simp add: coincides_cls_val_process)
 
 lemma (in disc_filtr_prob_space) coincides_on_adapted_val_process:
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set p \<subseteq> A"
   and "borel_adapt_stoch_proc F (val_process Mkt p)"
 shows "borel_adapt_stoch_proc F (val_process Mkt2 p)" unfolding adapt_stoch_proc_def
 proof
   fix n
   have "val_process Mkt p n \<in> borel_measurable (F n)" using assms unfolding adapt_stoch_proc_def by simp
   moreover have "\<forall>w. val_process Mkt p n w = val_process Mkt2 p n w" using assms coincides_val_process[of Mkt Mkt2 A]
     by auto
   thus "val_process Mkt2 p n \<in> borel_measurable (F n)"
     using calculation by presburger
 qed
 
 lemma (in disc_filtr_prob_space) coincides_on_adapted_cls_val_process:
   assumes "coincides_on Mkt Mkt2 A"
   and "support_set p \<subseteq> A"
   and "borel_adapt_stoch_proc F (cls_val_process Mkt p)"
 shows "borel_adapt_stoch_proc F (cls_val_process Mkt2 p)" unfolding adapt_stoch_proc_def
 proof
   fix n
   have "cls_val_process Mkt p n \<in> borel_measurable (F n)" using assms unfolding adapt_stoch_proc_def by simp
   moreover have "\<forall>w. cls_val_process Mkt p n w = cls_val_process Mkt2 p n w" using assms coincides_cls_val_process[of Mkt Mkt2 A]
     by auto
   thus "cls_val_process Mkt2 p n \<in> borel_measurable (F n)"
     using calculation by presburger
 qed
 
 subsubsection \<open>Fair prices\<close>
 definition (in disc_filtr_prob_space) fair_price where
   "fair_price Mkt \<pi> pyf matur \<longleftrightarrow>
     (\<exists> pr. price_structure pyf matur \<pi> pr \<and>
     (\<forall> x Mkt2 p. (x\<notin> stocks Mkt \<longrightarrow>
       ((coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<longrightarrow>
         \<not> arbitrage_process Mkt2 p))))"
 
 
 
 lemma (in disc_filtr_prob_space) fair_priceI:
   assumes "fair_price Mkt \<pi> pyf matur"
   shows "(\<exists> pr. price_structure pyf matur \<pi> pr \<and>
     (\<forall> x. (x\<notin> stocks Mkt \<longrightarrow>
       (\<forall> Mkt2 p. (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<longrightarrow>
         \<not> arbitrage_process Mkt2 p))))" using assms unfolding fair_price_def by simp
 
 paragraph \<open>Existence when replicating portfolio\<close>
 
 
 lemma (in disc_equity_market) replicating_fair_price:
   assumes "viable_market Mkt"
   and "replicating_portfolio pf der matur"
 and "support_adapt Mkt pf"
 shows "fair_price Mkt (initial_value pf) der matur"
 proof (rule ccontr)
   define \<pi> where  "\<pi> = (initial_value pf)"
   assume "\<not> fair_price Mkt \<pi> der matur"
   hence imps: "\<forall>pr. (price_structure der matur \<pi> pr) \<longrightarrow>  (\<exists> x Mkt2 p. (x\<notin> stocks Mkt \<and>
     (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<and>
      arbitrage_process Mkt2 p))" unfolding fair_price_def by simp
   have "(price_structure der matur \<pi> (cls_val_process Mkt pf))" unfolding \<pi>_def  using replicating_price_process assms by simp
   hence "\<exists> x Mkt2 p. (x\<notin> stocks Mkt \<and>
     (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = (cls_val_process Mkt pf)) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<and>
      arbitrage_process Mkt2 p)" using imps by simp
   from this obtain x Mkt2 p where "x\<notin> stocks Mkt" and "coincides_on Mkt Mkt2 (stocks Mkt)" and "prices Mkt2 x = cls_val_process Mkt pf"
     and "portfolio p" and "support_set p\<subseteq> stocks Mkt \<union> {x}" and "arbitrage_process Mkt2 p" by auto
   have "\<forall>n w. cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w"
     using coincides_stocks_cls_val_process[of Mkt pf Mkt2] assms \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close>  unfolding replicating_portfolio_def
     by simp
   have "\<exists>m. self_financing Mkt2 p \<and>
       trading_strategy p \<and>
       (AE w in M. cls_val_process Mkt2 p 0 w = 0) \<and>
       (AE w in M. 0 \<le> cls_val_process Mkt2 p m w) \<and> 0 < prob {w \<in> space M. 0 < cls_val_process Mkt2 p m w}"
     using \<open>arbitrage_process Mkt2 p\<close> using arbitrage_processE[of Mkt2] by simp
   from this obtain m where "self_financing Mkt2 p"
       "trading_strategy p \<and>
       (AE w in M. cls_val_process Mkt2 p 0 w = 0) \<and>
       (AE w in M. 0 \<le> cls_val_process Mkt2 p m w) \<and> 0 < prob {w \<in> space M. 0 < cls_val_process Mkt2 p m w}" by auto note mprop = this
   define eq_stock where "eq_stock = qty_replace_comp p x pf"
   have "\<forall>n w. cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w" using assms unfolding replicating_portfolio_def
       using coincides_cls_val_process
       using \<open>\<forall>n w. cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w\<close> by blast
     hence prx: "\<forall>n w. prices Mkt2 x n w = cls_val_process Mkt2 pf n w" using \<open>prices Mkt2 x = cls_val_process Mkt pf\<close> by simp
   have "stock_portfolio Mkt2 eq_stock"
     by (metis (no_types, lifting) \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>portfolio p\<close> \<open>support_set p \<subseteq> stocks Mkt \<union> {x}\<close>
         assms(2) coincides_on_def disc_equity_market.replicating_portfolio_def disc_equity_market_axioms eq_stock_def
         replace_comp_portfolio replace_comp_stocks stock_portfolio_def)
   moreover have "arbitrage_process Mkt2 eq_stock"
   proof (rule arbitrage_val_process)
     show "arbitrage_process Mkt2 p" using \<open>arbitrage_process Mkt2 p\<close> .
     show vp: "\<forall>n w. cls_val_process Mkt2 p n w = cls_val_process Mkt2 eq_stock n w" using replace_comp_cls_val_process
         \<open>prices Mkt2 x = cls_val_process Mkt pf\<close> unfolding eq_stock_def
       by (metis (no_types, lifting) \<open>\<forall>n w. cls_val_process Mkt pf n w = cls_val_process Mkt2 pf n w\<close> \<open>portfolio p\<close> assms(2) replicating_portfolio_def
           stock_portfolio_def)
     show "trading_strategy eq_stock"
       by (metis \<open>arbitrage_process Mkt2 p\<close> arbitrage_process_def assms(2) eq_stock_def
           replace_comp_trading_strat replicating_portfolio_def)
     show "self_financing Mkt2 eq_stock" unfolding eq_stock_def
     proof (rule replace_comp_self_financing)
       show "portfolio pf" using assms unfolding replicating_portfolio_def stock_portfolio_def by simp
       show "portfolio p" using \<open>portfolio p\<close> .
       show "\<forall>n w. prices Mkt2 x n w = cls_val_process Mkt2 pf n w" using prx .
       show "self_financing Mkt2 p" using \<open>self_financing Mkt2 p\<close> .
       show "self_financing Mkt2 pf" using coincides_on_self_financing[of Mkt Mkt2 "stocks Mkt" pf]
         \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> assms(2) (*disc_equity_market.replicating_portfolio_def
           disc_equity_market_axioms*) unfolding stock_portfolio_def replicating_portfolio_def by auto
     qed
   qed
   moreover have "viable_market Mkt2" using assms coincides_on_stocks_viable[of Mkt Mkt2]
     by (simp add: \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close>)
   ultimately show False unfolding viable_market_def by simp
 qed
 
 
 paragraph \<open>Uniqueness when replicating portfolio\<close>
 
 
 text \<open>The proof of uniqueness requires the existence of a stock that always takes strictly positive values.\<close>
 
 
 locale disc_market_pos_stock = disc_equity_market +
   fixes pos_stock
   assumes in_stock: "pos_stock \<in> stocks Mkt"
   and positive: "\<forall> n w. prices Mkt pos_stock n w > 0"
 and readable: "\<forall> asset\<in> stocks Mkt. borel_adapt_stoch_proc F (prices Mkt asset)"
 
 
 
 
 lemma (in disc_market_pos_stock) pos_stock_borel_adapted:
   shows "borel_adapt_stoch_proc F (prices Mkt pos_stock)"
   using assets_def readable in_stock  by auto
 
 
 definition static_quantities where
   "static_quantities p \<longleftrightarrow> (\<forall>asset \<in> support_set p. \<exists>c::real. p asset = (\<lambda> n w. c))"
 
 lemma (in disc_filtr_prob_space) static_quantities_trading_strat:
   assumes "static_quantities p"
   and "finite (support_set p)"
   shows "trading_strategy p" unfolding trading_strategy_def
 proof (intro conjI ballI)
   show "portfolio p" using assms unfolding portfolio_def by simp
   fix asset
   assume "asset \<in> support_set p"
   hence "\<exists>c. p asset = (\<lambda> n w. c)" using assms unfolding static_quantities_def by simp
   then obtain c where "p asset = (\<lambda> n w. c)" by auto
   show "borel_predict_stoch_proc F (p asset)" unfolding predict_stoch_proc_def
   proof (intro conjI)
     show "p asset 0 \<in> borel_measurable (F 0)" using \<open>p asset = (\<lambda> n w. c)\<close> by simp
     show "\<forall>n. p asset (Suc n) \<in> borel_measurable (F n)"
     proof
     fix n
       have "p asset (Suc n) = (\<lambda> w. c)" using \<open>p asset = (\<lambda> n w. c)\<close> by simp
       thus "p asset (Suc n) \<in> borel_measurable (F n)" by simp
     qed
   qed
 qed
 
 
 
 lemma two_component_support_set:
   assumes "\<exists> n w. a n w \<noteq> 0"
   and "\<exists> n w. b n w\<noteq> 0"
   and "x \<noteq> y"
 shows "support_set ((\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= a, y:= b)) = {x,y}"
 proof
   let ?arb_pf = "(\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= a, y:= b)"
   have "\<exists> n w. ?arb_pf x n w \<noteq> 0" using assms by simp
   moreover have "\<exists>n w. ?arb_pf y n w \<noteq> 0" using assms by simp
   ultimately show "{x, y} \<subseteq> support_set ?arb_pf" unfolding support_set_def by simp
   show "support_set ?arb_pf \<subseteq> {x, y}"
   proof (rule ccontr)
     assume "\<not> support_set ?arb_pf \<subseteq> {x, y}"
     hence "\<exists>z. z\<in> support_set ?arb_pf \<and> z\<notin> {x, y}" by auto
     from this obtain z where "z\<in> support_set ?arb_pf" and "z\<notin> {x, y}" by auto
     have "\<exists>n w. ?arb_pf z n w \<noteq> 0" using \<open>z\<in> support_set ?arb_pf\<close> unfolding support_set_def by simp
     from this obtain n w where "?arb_pf z n w \<noteq> 0" by auto
     have "?arb_pf z n w = 0" using \<open>z\<notin> {x, y}\<close>  by simp
     thus False using \<open>?arb_pf z n w \<noteq> 0\<close> by simp
   qed
 qed
 
 lemma two_component_val_process:
   assumes "arb_pf = ((\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= a, y:= b))"
   and "portfolio arb_pf"
   and "x \<noteq> y"
   and "\<exists> n w. a n w \<noteq> 0"
   and "\<exists> n w. b n w\<noteq> 0"
   shows "val_process Mkt arb_pf n w =
     prices Mkt y n w * b (Suc n) w + prices Mkt x n w * a (Suc n) w"
 proof -
   have "support_set arb_pf = {x,y}" using assms by (simp add:two_component_support_set)
   have "val_process Mkt arb_pf n w = (\<Sum>x\<in>support_set arb_pf. prices Mkt x n w * arb_pf x (Suc n) w)"
         unfolding val_process_def using \<open>portfolio arb_pf\<close> by simp
   also have "... = (\<Sum>x\<in>{x, y}. prices Mkt x n w * arb_pf x (Suc n) w)" using \<open>support_set arb_pf = {x, y}\<close>
         by simp
   also have "... = (\<Sum>x\<in>{y}. prices Mkt x n w * arb_pf x (Suc n) w) + prices Mkt x n w * arb_pf x (Suc n) w"
         using sum.insert[of "{y}" x  "\<lambda>x. prices Mkt x n w * arb_pf x n w"] assms(3) by auto
   also have "... = prices Mkt y n w * arb_pf y (Suc n) w + prices Mkt x n w * arb_pf x (Suc n) w" by simp
   also have "... = prices Mkt y n w * b (Suc n) w + prices Mkt x n w * a (Suc n) w" using assms by auto
   finally show "val_process Mkt arb_pf n w = prices Mkt y n w * b (Suc n) w + prices Mkt x n w * a (Suc n) w" .
 qed
 
 lemma quantity_update_support_set:
   assumes "\<exists>n w. pr n w \<noteq> 0"
   and "x\<notin> support_set p"
 shows "support_set (p(x:=pr)) = support_set p \<union> {x}"
 proof
   show "support_set (p(x := pr)) \<subseteq> support_set p \<union> {x}"
   proof
     fix y
     assume "y\<in> support_set (p(x := pr))"
     show "y \<in> support_set p \<union> {x}"
     proof (rule ccontr)
       assume "\<not>y \<in> support_set p \<union> {x}"
       hence "y \<noteq> x" by simp
       have "\<exists>n w. (p(x := pr)) y n w \<noteq> 0" using \<open>y\<in> support_set (p(x := pr))\<close> unfolding support_set_def by simp
       then obtain n w where nwprop: "(p(x := pr)) y n w \<noteq> 0" by auto
       have "y\<notin> support_set p" using \<open>\<not>y \<in> support_set p \<union> {x}\<close> by simp
       hence "y = x" using nwprop using support_set_def by force
       thus False using \<open>y\<noteq> x\<close> by simp
     qed
   qed
   show "support_set p \<union> {x} \<subseteq> support_set (p(x := pr))"
   proof
     fix y
     assume "y \<in> support_set p \<union> {x}"
     show "y\<in> support_set (p(x := pr))"
     proof (cases "y\<in> support_set p")
       case True
       thus ?thesis
       proof -
         have f1: "y \<in> {b. \<exists>n a. p b n a \<noteq> 0}"
           by (metis True support_set_def)
         then have "y \<noteq> x"
           using assms(2) support_set_def by force
         then show ?thesis
           using f1 by (simp add: support_set_def)
       qed
     next
       case False
       hence "y = x" using \<open>y \<in> support_set p \<union> {x}\<close> by auto
       thus ?thesis using assms by (simp add: support_set_def)
     qed
   qed
 qed
 
 
 lemma fix_asset_price:
   shows "\<exists>x Mkt2. x \<notin> stocks Mkt \<and>
   coincides_on Mkt Mkt2 (stocks Mkt) \<and>
   prices Mkt2 x = pr"
 proof -
   have "\<exists>x. x\<notin> stocks Mkt" by (metis UNIV_eq_I stk_strict_subs_def mkt_stocks_assets)
   from this obtain x where "x\<notin> stocks Mkt" by auto
   let ?res = "discrete_market_of (stocks Mkt) ((prices Mkt)(x:=pr))"
   have "coincides_on Mkt ?res (stocks Mkt)"
   proof -
     have "stocks Mkt = stocks (discrete_market_of (stocks Mkt) ((prices Mkt)(x := pr)))"
       by (metis (no_types) stk_strict_subs_def mkt_stocks_assets stocks_of)
     then show ?thesis
       by (simp add: \<open>x \<notin> stocks Mkt\<close> coincides_on_def prices_of)
   qed
   have "prices ?res x = pr" by (simp add: prices_of)
  show ?thesis
    using \<open>coincides_on Mkt (discrete_market_of (stocks Mkt) ((prices Mkt)(x := pr))) (stocks Mkt)\<close> \<open>prices (discrete_market_of (stocks Mkt) ((prices Mkt)(x := pr))) x = pr\<close> \<open>x \<notin> stocks Mkt\<close> by blast
 qed
 
 
 
 lemma (in disc_market_pos_stock) arbitrage_portfolio_properties:
   assumes "price_structure der matur \<pi> pr"
   and "replicating_portfolio pf der matur"
   and  "(coincides_on Mkt Mkt2 (stocks Mkt))"
   and "(prices Mkt2 x = pr)"
   and "x\<notin> stocks Mkt"
   and "diff_inv = (\<pi> - initial_value pf) / constant_image (prices Mkt pos_stock 0)"
   and "diff_inv \<noteq> 0"
   and "arb_pf = (\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= (\<lambda> n w. -1), pos_stock := (\<lambda> n w. diff_inv))"
   and "contr_pf = qty_sum arb_pf pf"
 shows "self_financing Mkt2 contr_pf"
   and "trading_strategy contr_pf"
   and "\<forall>w\<in> space M. cls_val_process Mkt2 contr_pf 0 w = 0"
   and "0 < diff_inv \<longrightarrow> (AE w in M. 0 < cls_val_process Mkt2 contr_pf matur w)"
   and "diff_inv < 0 \<longrightarrow> (AE w in M. 0 > cls_val_process Mkt2 contr_pf matur w)"
   and "support_set arb_pf = {x, pos_stock}"
   and "portfolio contr_pf"
 proof -
   have "0 < constant_image (prices Mkt pos_stock 0)" using trading_strategy_init
   proof -
     have "borel_adapt_stoch_proc F (prices Mkt pos_stock)" using pos_stock_borel_adapted by simp
     hence "\<exists>c. \<forall>w\<in>space M. prices Mkt pos_stock 0 w = c" using  adapted_init[of "prices Mkt pos_stock"] by simp
     moreover have "\<forall>w\<in> space M. 0 < prices Mkt pos_stock 0 w" using positive by simp
     ultimately show ?thesis using constant_image_pos by simp
   qed
   show "support_set arb_pf = {x, pos_stock}"
   proof -
     have "arb_pf = (\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= (\<lambda> n w. -1), pos_stock := (\<lambda> n w. diff_inv))"
       using \<open>arb_pf = (\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= (\<lambda> n w. -1), pos_stock := (\<lambda> n w. diff_inv))\<close> .
     moreover have "\<exists>n w. diff_inv \<noteq> 0" using assms by simp
     moreover have "x\<noteq> pos_stock" using \<open>x \<notin> stocks Mkt\<close> in_stock by auto
     ultimately show ?thesis by (simp add:two_component_support_set)
   qed
   hence "portfolio arb_pf" unfolding portfolio_def by simp
   have arb_vp:"\<forall>n w. val_process Mkt2 arb_pf n w = prices Mkt2 pos_stock n w * diff_inv - pr n w"
   proof (intro allI)
     fix n w
     have "val_process Mkt2 arb_pf n w = prices Mkt2 pos_stock n w * (\<lambda> n w. diff_inv) n w + prices Mkt2 x n w * (\<lambda> n w. -1) n w"
     proof (rule two_component_val_process)
       show "x\<noteq> pos_stock" using \<open>x \<notin> stocks Mkt\<close> in_stock by auto
       show "arb_pf = (\<lambda>x n w. 0)(x := \<lambda>a b. - 1, pos_stock := \<lambda>a b. diff_inv)" using assms by simp
       show "portfolio arb_pf" using \<open>portfolio arb_pf\<close> by simp
       show "\<exists>n w. - (1::real) \<noteq> 0" by simp
       show "\<exists>n w. diff_inv \<noteq> 0" using assms by auto
     qed
     also have "... = prices Mkt2 pos_stock n w * diff_inv - pr n w" using \<open>prices Mkt2 x = pr\<close> by simp
     finally show "val_process Mkt2 arb_pf n w = prices Mkt2 pos_stock n w * diff_inv - pr n w" .
   qed
   have "static_quantities arb_pf" unfolding static_quantities_def
   proof
     fix asset
     assume "asset \<in> support_set arb_pf"
     thus "\<exists>c. arb_pf asset = (\<lambda>n w. c)"
     proof (cases "asset = x")
       case True
       thus ?thesis using assms by auto
     next
       case False
       hence "asset = pos_stock" using \<open>support_set arb_pf = {x, pos_stock}\<close>
         using \<open>asset \<in> support_set arb_pf\<close> by blast
       thus ?thesis using assms by auto
     qed
   qed
   hence "trading_strategy arb_pf"
     using \<open>portfolio arb_pf\<close> portfolio_def static_quantities_trading_strat by blast
   have "self_financing Mkt2 arb_pf"
         by (simp add: static_portfolio_self_financing \<open>arb_pf = (\<lambda>x n w. 0) (x := \<lambda>n w. -1, pos_stock := \<lambda>n w. diff_inv)\<close>)
   hence arb_uvp: "\<forall>n w. cls_val_process Mkt2 arb_pf n w = prices Mkt2 pos_stock n w * diff_inv - pr n w" using assms arb_vp
     by (simp add:self_financingE)
   show "portfolio contr_pf" using assms
       by (metis \<open>support_set arb_pf = {x, pos_stock}\<close> replicating_portfolio_def
           finite.emptyI finite.insertI portfolio_def stock_portfolio_def sum_portfolio)
   have "support_set contr_pf \<subseteq> stocks Mkt \<union> {x}"
   proof -
     have "support_set contr_pf \<subseteq> support_set arb_pf \<union> support_set pf" using assms
       by (simp add:sum_support_set)
     moreover have "support_set arb_pf \<subseteq> stocks Mkt \<union> {x}" using \<open>support_set arb_pf = {x, pos_stock}\<close> in_stock by simp
     moreover have "support_set pf \<subseteq> stocks Mkt \<union> {x}" using assms unfolding replicating_portfolio_def
       stock_portfolio_def by auto
     ultimately show ?thesis by auto
   qed
   show "self_financing Mkt2 contr_pf"
     proof -
     have "self_financing Mkt2 (qty_sum arb_pf pf)"
     proof (rule sum_self_financing)
       show "portfolio arb_pf"  using  \<open>support_set arb_pf = {x, pos_stock}\<close> unfolding portfolio_def by auto
       show "portfolio pf" using assms unfolding replicating_portfolio_def stock_portfolio_def by auto
       show "self_financing Mkt2 pf" using coincides_on_self_financing
         \<open>(coincides_on Mkt Mkt2 (stocks Mkt))\<close> \<open>(prices Mkt2 x = pr)\<close> assms(2)
         unfolding replicating_portfolio_def stock_portfolio_def  by blast
       show "self_financing Mkt2 arb_pf"
         by (simp add: static_portfolio_self_financing \<open>arb_pf = (\<lambda>x n w. 0) (x := \<lambda>n w. -1, pos_stock := \<lambda>n w. diff_inv)\<close>)
     qed
     thus ?thesis using assms by simp
   qed
   show "trading_strategy contr_pf"
   proof -
     have "trading_strategy (qty_sum arb_pf pf)"
     proof (rule sum_trading_strat)
       show "trading_strategy pf" using assms unfolding replicating_portfolio_def by simp
       show "trading_strategy arb_pf" using \<open>trading_strategy arb_pf\<close> .
     qed
     thus ?thesis using assms by simp
   qed
   show "\<forall>w\<in> space M. cls_val_process Mkt2 contr_pf 0 w = 0"
   proof
     fix w
     assume "w\<in> space M"
     have "cls_val_process Mkt2 contr_pf 0 w = cls_val_process Mkt2 arb_pf 0 w + cls_val_process Mkt2 pf 0 w"
       using sum_cls_val_process0[of arb_pf pf Mkt2]
       using \<open>portfolio arb_pf\<close> assms replicating_portfolio_def stock_portfolio_def by blast
     also have "... = prices Mkt2 pos_stock 0 w * diff_inv - pr 0 w + cls_val_process Mkt2 pf 0 w" using arb_uvp by simp
     also have "... = constant_image (prices Mkt pos_stock 0) * diff_inv - pr 0 w + cls_val_process Mkt2 pf 0 w"
     proof -
       have f1: "prices Mkt pos_stock = prices Mkt2 pos_stock"
         using \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close>  in_stock unfolding coincides_on_def by blast
       have "prices Mkt pos_stock 0 w = constant_image (prices Mkt pos_stock 0)"
         using \<open>w \<in> space M\<close> adapted_init constant_imageI pos_stock_borel_adapted by blast
       then show ?thesis
         using f1 by simp
     qed
     also have "... = (\<pi> - initial_value pf) - pr 0 w + cls_val_process Mkt2 pf 0 w"
       using \<open>0 < constant_image (prices Mkt pos_stock 0)\<close> assms by simp
     also have "... = (\<pi> - initial_value pf) - \<pi> + cls_val_process Mkt2 pf 0 w" using \<open>price_structure der matur \<pi> pr\<close>
       price_structure_init[of der matur \<pi> pr] by (simp add: \<open>w \<in> space M\<close>)
     also have "... = (\<pi> - initial_value pf) - \<pi> + (initial_value pf)" using initial_valueI assms unfolding replicating_portfolio_def
       using \<open>w \<in> space M\<close> coincides_stocks_cls_val_process self_financingE readable
       by (metis (no_types, opaque_lifting) support_adapt_def stock_portfolio_def subsetCE)
     also have "... = 0" by simp
     finally show "cls_val_process Mkt2 contr_pf 0 w = 0" .
   qed
   show "0 < diff_inv \<longrightarrow> (AE w in M. 0 < cls_val_process Mkt2 contr_pf matur w)"
   proof
     assume "0 < diff_inv"
     show "AE w in M. 0 < cls_val_process Mkt2 contr_pf matur w"
     proof (rule AE_mp)
       have "AE w in M. prices Mkt2 x matur w = der w" using \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         unfolding price_structure_def by auto
       moreover have "AE w in M. cls_val_process Mkt2 pf matur  w = der w" using assms coincides_stocks_cls_val_process[of Mkt pf Mkt2]
         \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> unfolding replicating_portfolio_def by auto
       ultimately show "AE w in M. prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w" by auto
       show "AE w in M. prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w \<longrightarrow> 0 < cls_val_process Mkt2 contr_pf matur w"
       proof (rule AE_I2, rule impI)
         fix w
         assume "w\<in> space M"
         and "prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w"
         have "cls_val_process Mkt2 contr_pf matur w = cls_val_process Mkt2 arb_pf matur w + cls_val_process Mkt2 pf matur w"
           using sum_cls_val_process[of arb_pf pf Mkt2]
           \<open>portfolio arb_pf\<close> assms replicating_portfolio_def stock_portfolio_def by blast
         also have "... = prices Mkt2 pos_stock matur w * diff_inv - pr matur w + cls_val_process Mkt2 pf matur w"
           using arb_uvp by simp
         also have "... = prices Mkt2 pos_stock matur w * diff_inv - prices Mkt2 x matur w + cls_val_process Mkt2 pf matur w"
           using \<open>prices Mkt2 x = pr\<close> by simp
         also have "... = prices Mkt2 pos_stock matur w * diff_inv" using \<open>prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w\<close>
           by simp
         also have "... > 0" using positive \<open>0 < diff_inv\<close>
           by (metis \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> coincides_on_def in_stock mult_pos_pos)
         finally have "cls_val_process Mkt2 contr_pf matur w > 0".
         thus "0 < cls_val_process Mkt2 contr_pf matur w" by simp
       qed
     qed
   qed
   show "diff_inv < 0 \<longrightarrow> (AE w in M. 0 > cls_val_process Mkt2 contr_pf matur w)"
   proof
     assume "diff_inv < 0"
     show "AE w in M. 0 > cls_val_process Mkt2 contr_pf matur w"
     proof (rule AE_mp)
       have "AE w in M. prices Mkt2 x matur w = der w" using \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         unfolding price_structure_def by auto
       moreover have "AE w in M. cls_val_process Mkt2 pf matur  w = der w" using assms coincides_stocks_cls_val_process[of Mkt pf Mkt2]
         \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> unfolding replicating_portfolio_def by auto
       ultimately show "AE w in M. prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w" by auto
       show "AE w in M. prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w \<longrightarrow> 0 > cls_val_process Mkt2 contr_pf matur w"
       proof (rule AE_I2, rule impI)
         fix w
         assume "w\<in> space M"
         and "prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w"
         have "cls_val_process Mkt2 contr_pf matur w = cls_val_process Mkt2 arb_pf matur w + cls_val_process Mkt2 pf matur w"
           using sum_cls_val_process[of arb_pf pf Mkt2]
           \<open>portfolio arb_pf\<close> assms replicating_portfolio_def stock_portfolio_def by blast
         also have "... = prices Mkt2 pos_stock matur w * diff_inv - pr matur w + cls_val_process Mkt2 pf matur w"
           using arb_uvp by simp
         also have "... = prices Mkt2 pos_stock matur w * diff_inv - prices Mkt2 x matur w + cls_val_process Mkt2 pf matur w"
           using \<open>prices Mkt2 x = pr\<close> by simp
         also have "... = prices Mkt2 pos_stock matur w * diff_inv" using \<open>prices Mkt2 x matur w = cls_val_process Mkt2 pf matur w\<close>
           by simp
         also have "... < 0" using positive \<open>diff_inv < 0\<close>
           by (metis \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> coincides_on_def in_stock mult_pos_neg)
         finally have "cls_val_process Mkt2 contr_pf matur w < 0".
         thus "0 > cls_val_process Mkt2 contr_pf matur w" by simp
       qed
     qed
   qed
 qed
 
 lemma (in disc_equity_market) mult_comp_cls_val_process_measurable':
   assumes "cls_val_process Mkt2 pf n \<in>borel_measurable (F n)"
   and "portfolio pf"
   and "qty n \<in> borel_measurable (F n)"
   and "0 \<noteq> n"
 shows "cls_val_process Mkt2 (qty_mult_comp pf qty) n \<in> borel_measurable (F n)"
 proof -
   have "\<exists>m. n = Suc m" using assms by presburger
   from this obtain m where "n = Suc m" by auto
   hence "cls_val_process Mkt2 (qty_mult_comp pf qty) (Suc m) \<in> borel_measurable (F (Suc m))"
     using  mult_comp_cls_val_process_Suc[of pf Mkt2 qty] borel_measurable_times[of "cls_val_process Mkt2 pf (Suc m)" "F (Suc m)" "qty (Suc m)"]
       assms \<open>n= Suc m\<close> by presburger
   thus ?thesis using \<open>n = Suc m\<close> by simp
 qed
 
 
 lemma (in disc_equity_market) mult_comp_cls_val_process_measurable:
   assumes "\<forall>n. cls_val_process Mkt2 pf n \<in>borel_measurable (F n)"
   and "portfolio pf"
   and "\<forall>n. qty (Suc n) \<in> borel_measurable (F n)"
 shows "\<forall>n. cls_val_process Mkt2 (qty_mult_comp pf qty) n \<in> borel_measurable (F n)"
 proof
   fix n
   show "cls_val_process Mkt2 (qty_mult_comp pf qty) n \<in> borel_measurable (F n)"
   proof (cases "n=0")
     case False
     hence "\<exists>m. n = Suc m" by presburger
     from this obtain m where "n = Suc m" by auto
     have "qty n \<in> borel_measurable (F n)"
     using Suc_n_not_le_n \<open>n = Suc m\<close> assms(3) increasing_measurable_info nat_le_linear by blast
     hence "qty (Suc m) \<in> borel_measurable (F (Suc m))" using \<open>n = Suc m\<close> by simp
     hence "cls_val_process Mkt2 (qty_mult_comp pf qty) (Suc m) \<in> borel_measurable (F (Suc m))"
       using  mult_comp_cls_val_process_Suc[of pf Mkt2 qty] borel_measurable_times[of "cls_val_process Mkt2 pf (Suc m)" "F (Suc m)" "qty (Suc m)"]
         assms \<open>n= Suc m\<close> by presburger
     thus ?thesis using \<open>n = Suc m\<close> by simp
   next
     case True
     have "qty (Suc 0) \<in> borel_measurable (F 0)" using assms by simp
     moreover have "cls_val_process Mkt2 pf 0 \<in> borel_measurable (F 0)" using assms  by simp
     ultimately have "(\<lambda>w. cls_val_process Mkt2 pf 0 w * qty (Suc 0) w) \<in> borel_measurable (F 0)" by simp
     thus ?thesis using assms(2) True mult_comp_cls_val_process0
       by (simp add: \<open>(\<lambda>w. cls_val_process Mkt2 pf 0 w * qty (Suc 0) w) \<in> borel_measurable (F 0)\<close> mult_comp_cls_val_process0 measurable_cong)
   qed
 qed
 
 
 
 
 
 lemma (in disc_equity_market) mult_comp_val_process_measurable:
   assumes "val_process Mkt2 pf n \<in>borel_measurable (F n)"
   and "portfolio pf"
   and "qty (Suc n) \<in> borel_measurable (F n)"
 shows "val_process Mkt2 (qty_mult_comp pf qty) n \<in> borel_measurable (F n)"
   using  mult_comp_val_process[of pf Mkt2 qty] borel_measurable_times[of "val_process Mkt2 pf n" "F n" "qty (Suc n)"]
   assms by presburger
 
 lemma (in disc_market_pos_stock) repl_fair_price_unique:
   assumes "replicating_portfolio pf der matur"
   and "fair_price Mkt \<pi> der matur"
 shows "\<pi> = initial_value pf"
 proof -
   have expr: "(\<exists> pr. price_structure der matur \<pi> pr \<and>
     (\<forall> x. (x\<notin> stocks Mkt \<longrightarrow>
       (\<forall> Mkt2 p. (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<longrightarrow>
         \<not> arbitrage_process Mkt2 p))))" using assms fair_priceI by simp
   then obtain pr where "price_structure der matur \<pi> pr" and
     xasset: "(\<forall> x. (x\<notin> stocks Mkt \<longrightarrow>
       (\<forall> Mkt2 p. (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<longrightarrow>
         \<not> arbitrage_process Mkt2 p)))" by auto
   define diff_inv where "diff_inv = (\<pi> - initial_value pf) / constant_image (prices Mkt pos_stock 0)"
   {
     fix x
     assume "x\<notin> stocks Mkt"
     hence mkprop: "(\<forall> Mkt2 p. (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<longrightarrow>
           \<not> arbitrage_process Mkt2 p)" using xasset by simp
     fix Mkt2
     assume "(coincides_on Mkt Mkt2 (stocks Mkt))" and "(prices Mkt2 x = pr)"
     have "0 < constant_image (prices Mkt pos_stock 0)" using trading_strategy_init
       proof -
         have "borel_adapt_stoch_proc F (prices Mkt pos_stock)" using pos_stock_borel_adapted by simp
         hence "\<exists>c. \<forall>w\<in>space M. prices Mkt pos_stock 0 w = c" using  adapted_init[of "prices Mkt pos_stock"] by simp
         moreover have "\<forall>w\<in> space M. 0 < prices Mkt pos_stock 0 w" using positive by simp
         ultimately show ?thesis using constant_image_pos by simp
       qed
 
     define arb_pf where "arb_pf = (\<lambda> (x::'b) (n::nat) (w::'a). 0::real)(x:= (\<lambda> n w. -1), pos_stock := (\<lambda> n w. diff_inv))"
     define contr_pf where "contr_pf = qty_sum arb_pf pf"
     have 1:"0 \<noteq> diff_inv \<longrightarrow> self_financing Mkt2 contr_pf"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 2:"0 \<noteq> diff_inv \<longrightarrow> trading_strategy contr_pf"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 3:"0 \<noteq> diff_inv \<longrightarrow> (\<forall>w\<in> space M. cls_val_process Mkt2 contr_pf 0 w = 0)"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 4: "0 < diff_inv \<longrightarrow> (AE w in M. 0 < cls_val_process Mkt2 contr_pf matur w)"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 5: "diff_inv < 0 \<longrightarrow> (AE w in M. 0 > cls_val_process Mkt2 contr_pf matur w)"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 6: "0 \<noteq> diff_inv \<longrightarrow> support_set arb_pf = {x, pos_stock}"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 7: "0 \<noteq> diff_inv \<longrightarrow>support_set contr_pf \<subseteq> stocks Mkt \<union> {x}"
     proof -
       have "0 \<noteq> diff_inv \<longrightarrow> support_set contr_pf \<subseteq> support_set arb_pf \<union> support_set pf" unfolding contr_pf_def
         by (simp add:sum_support_set)
       moreover have "0 \<noteq> diff_inv \<longrightarrow>support_set arb_pf \<subseteq> stocks Mkt \<union> {x}" using \<open>0 \<noteq> diff_inv \<longrightarrow> support_set arb_pf = {x, pos_stock}\<close> in_stock by simp
       moreover have "0 \<noteq> diff_inv \<longrightarrow>support_set pf \<subseteq> stocks Mkt \<union> {x}" using assms unfolding replicating_portfolio_def
         stock_portfolio_def by auto
       ultimately show ?thesis by auto
     qed
     have 8:"0 \<noteq> diff_inv \<longrightarrow>portfolio contr_pf"
       using arbitrage_portfolio_properties[of der matur \<pi> pr pf Mkt2 x diff_inv arb_pf contr_pf]
       using  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close>
         \<open>x \<notin> stocks Mkt\<close> arb_pf_def assms(1) contr_pf_def diff_inv_def by blast
     have 9: "0 \<noteq> diff_inv \<longrightarrow> cls_val_process Mkt2 contr_pf matur \<in> borel_measurable (F matur)"
     proof
       assume "0 \<noteq> diff_inv"
       have 10:"\<forall> asset \<in> support_set arb_pf \<union> support_set pf. prices Mkt2 asset matur \<in> borel_measurable (F matur)"
       proof
         fix asset
         assume "asset \<in> support_set arb_pf \<union> support_set pf"
         show "prices Mkt2 asset matur \<in> borel_measurable (F matur)"
         proof (cases "asset \<in> support_set pf")
           case True
           thus ?thesis using assms readable
             by (metis (no_types, lifting)  \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> adapt_stoch_proc_def
                 coincides_on_def disc_equity_market.replicating_portfolio_def
                 disc_equity_market_axioms  stock_portfolio_def subsetCE)
         next
           case False
           hence "asset\<in> support_set arb_pf" using \<open>asset \<in> support_set arb_pf \<union> support_set pf\<close> by auto
           show ?thesis
           proof (cases "asset = x")
             case True
             thus ?thesis
               using \<open>price_structure der matur \<pi> pr\<close> \<open>prices Mkt2 x = pr\<close> price_structure_borel_measurable by blast
           next
             case False
             hence "asset = pos_stock" using \<open>asset\<in> support_set arb_pf\<close> \<open>0 \<noteq> diff_inv \<longrightarrow> support_set arb_pf = {x, pos_stock}\<close>
               \<open>0 \<noteq> diff_inv\<close> by auto
             thus ?thesis
               by (metis \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> adapt_stoch_proc_def coincides_on_def in_stock pos_stock_borel_adapted)
           qed
         qed
       qed
       moreover have "\<forall>asset\<in>support_set contr_pf. contr_pf asset matur \<in> borel_measurable (F matur)"
         using \<open>0 \<noteq> diff_inv \<longrightarrow>trading_strategy contr_pf\<close> \<open>0 \<noteq> diff_inv\<close>
         by (metis adapt_stoch_proc_def disc_filtr_prob_space.predict_imp_adapt disc_filtr_prob_space_axioms trading_strategy_def)
       ultimately show "cls_val_process Mkt2 contr_pf matur \<in> borel_measurable (F matur)"
       proof-
         have "\<forall>asset\<in>support_set contr_pf. contr_pf asset (Suc matur) \<in> borel_measurable (F matur)"
            using \<open>0 \<noteq> diff_inv \<longrightarrow>trading_strategy contr_pf\<close> \<open>0 \<noteq> diff_inv\<close>
            by (simp add: predict_stoch_proc_def trading_strategy_def)
          moreover have "\<forall>asset\<in>support_set contr_pf. prices Mkt2 asset matur \<in> borel_measurable (F matur)" using 10 unfolding contr_pf_def
            using sum_support_set[of arb_pf pf] by auto
          ultimately show ?thesis  by (metis (no_types, lifting) "1" \<open>0 \<noteq> diff_inv\<close> quantity_adapted self_financingE)
       qed
     qed
     {
       assume "0 > diff_inv"
       define opp_pf where "opp_pf = qty_mult_comp contr_pf (\<lambda> n w. -1)"
       have "arbitrage_process Mkt2 opp_pf"
       proof (rule arbitrage_processI, rule exI, intro conjI)
         show "self_financing Mkt2 opp_pf" using 1 \<open>0 > diff_inv\<close> mult_time_constant_self_financing[of contr_pf] 8
           unfolding opp_pf_def by auto
         show "trading_strategy opp_pf" unfolding opp_pf_def
         proof (rule mult_comp_trading_strat)
           show "trading_strategy contr_pf" using 2 \<open>0 > diff_inv\<close> by auto
           show "borel_predict_stoch_proc F (\<lambda>n w. - 1)" by (simp add: constant_process_borel_predictable)
         qed
         show "\<forall>w\<in>space M. cls_val_process Mkt2 opp_pf 0 w = 0"
         proof
           fix w
           assume "w\<in> space M"
           show "cls_val_process Mkt2 opp_pf 0 w = 0" using 3 8 \<open>0 > diff_inv\<close>
             using \<open>w \<in> space M\<close> mult_comp_cls_val_process0 opp_pf_def by fastforce
         qed
         have "AE w in M. 0 < cls_val_process Mkt2 opp_pf matur w"
         proof (rule AE_mp)
           show "AE w in M. 0 > cls_val_process Mkt2 contr_pf matur w" using 5 \<open>0 > diff_inv\<close> by auto
           show "AE w in M. cls_val_process Mkt2 contr_pf matur w < 0 \<longrightarrow> 0 < cls_val_process Mkt2 opp_pf matur w"
           proof
             fix w
             assume "w\<in> space M"
             show "cls_val_process Mkt2 contr_pf matur w < 0 \<longrightarrow> 0 < cls_val_process Mkt2 opp_pf matur w"
             proof
               assume "cls_val_process Mkt2 contr_pf matur w < 0"
               show "0 < cls_val_process Mkt2 opp_pf matur w"
               proof (cases "matur = 0")
                 case False
                 hence "\<exists>m. Suc m = matur" by presburger
                 from this obtain m where "Suc m = matur" by auto
                 hence "0 < cls_val_process Mkt2 opp_pf (Suc m) w" using 3 8 \<open>0 > diff_inv\<close> \<open>w \<in> space M\<close> mult_comp_cls_val_process_Suc  opp_pf_def
                   using \<open>cls_val_process Mkt2 contr_pf matur w < 0\<close> by fastforce
                 thus ?thesis using \<open>Suc m = matur\<close> by simp
               next
                 case True
                 thus ?thesis using 3 8 \<open>0 > diff_inv\<close> \<open>w \<in> space M\<close> mult_comp_cls_val_process0 opp_pf_def
                   using \<open>cls_val_process Mkt2 contr_pf matur w < 0\<close> by auto
               qed
             qed
           qed
         qed
         thus "AE w in M. 0 \<le> cls_val_process Mkt2 opp_pf matur w" by auto
         show "0 < prob {w \<in> space M. 0 < cls_val_process Mkt2 opp_pf matur w}"
         proof -
           let ?P = "{w\<in> space M. 0 < cls_val_process Mkt2 opp_pf matur w}"
           have "cls_val_process Mkt2 opp_pf matur \<in> borel_measurable (F matur)" (*unfolding opp_pf_def *)
           proof -
             have "cls_val_process Mkt2 contr_pf matur \<in> borel_measurable (F matur)" using 9 \<open>0 > diff_inv\<close> by simp
             moreover have "portfolio contr_pf" using 8 \<open>0 > diff_inv\<close> by simp
             moreover have "(\<lambda>w. - 1) \<in> borel_measurable (F matur)" by (simp add:constant_process_borel_adapted)
             ultimately show ?thesis
               using mult_comp_cls_val_process_measurable
             proof -
               have "diff_inv \<noteq> 0"
                 using \<open>diff_inv < 0\<close> by blast
               then have "self_financing Mkt2 contr_pf"
                 by (metis "1")
               then show ?thesis
                 by (metis (no_types) \<open>(\<lambda>w. - 1) \<in> borel_measurable (F matur)\<close> \<open>portfolio contr_pf\<close>
                     \<open>self_financing Mkt2 opp_pf\<close> \<open>cls_val_process Mkt2 contr_pf matur \<in> borel_measurable (F matur)\<close>
                     mult_comp_val_process_measurable opp_pf_def self_financingE)
             qed
           qed
           moreover have "space M = space (F matur)"
             using filtration by (simp add: filtration_def subalgebra_def)
           ultimately have "?P \<in> sets (F matur)" using borel_measurable_iff_greater[of "val_process Mkt2 contr_pf matur" "F matur"]
             by auto
           hence "?P \<in> sets M" by (meson filtration filtration_def subalgebra_def subsetCE)
           hence "measure M ?P = 1" using  prob_Collect_eq_1[of "\<lambda>x. 0 < cls_val_process Mkt2 opp_pf matur x"]
              \<open>AE w in M. 0 < cls_val_process Mkt2 opp_pf matur w\<close> \<open>0 > diff_inv\<close> by blast
           thus ?thesis by simp
         qed
       qed
         have "\<exists> p. portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<and> arbitrage_process Mkt2 p"
         proof(intro exI conjI)
           show "arbitrage_process Mkt2 opp_pf" using \<open>arbitrage_process Mkt2 opp_pf\<close> .
           show "portfolio opp_pf" unfolding opp_pf_def using 8 \<open>0 > diff_inv\<close> by (auto simp add: mult_comp_portfolio)
           show "support_set opp_pf \<subseteq> stocks Mkt \<union> {x}" unfolding opp_pf_def using 7 \<open>0 > diff_inv\<close>
             using mult_comp_support_set by fastforce
         qed
       } note negp = this
       {
         assume "0 < diff_inv"
         have "arbitrage_process Mkt2 contr_pf"
         proof (rule arbitrage_processI, rule exI, intro conjI)
           show "self_financing Mkt2 contr_pf" using 1 \<open>0 < diff_inv\<close> by auto
           show "trading_strategy contr_pf" using 2 \<open>0 < diff_inv\<close> by auto
           show "\<forall>w\<in>space M. cls_val_process Mkt2 contr_pf 0 w = 0" using 3 \<open>0 < diff_inv\<close> by auto
           show "AE w in M. 0 \<le> cls_val_process Mkt2 contr_pf matur w" using 4 \<open>0 < diff_inv\<close> by auto
           show "0 < prob {w \<in> space M. 0 < cls_val_process Mkt2 contr_pf matur w}"
             proof -
               let ?P = "{w\<in> space M. 0 < cls_val_process Mkt2 contr_pf matur w}"
               have "cls_val_process Mkt2 contr_pf matur \<in> borel_measurable (F matur)" using 9 \<open>0 < diff_inv\<close> by auto
               moreover have "space M = space (F matur)"
                 using filtration  by (simp add: filtration_def subalgebra_def)
               ultimately have "?P \<in> sets (F matur)" using borel_measurable_iff_greater[of "val_process Mkt2 contr_pf matur" "F matur"]
                 by auto
               hence "?P \<in> sets M" by (meson filtration filtration_def subalgebra_def subsetCE)
               hence "measure M ?P = 1" using  prob_Collect_eq_1[of "\<lambda>x. 0 < cls_val_process Mkt2 contr_pf matur x"]
                  4 \<open>0 < diff_inv\<close> by blast
               thus ?thesis by simp
             qed
           qed
           have "\<exists> p. portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<and> arbitrage_process Mkt2 p"
           proof(intro exI conjI)
             show "arbitrage_process Mkt2 contr_pf" using \<open>arbitrage_process Mkt2 contr_pf\<close> .
             show "portfolio contr_pf" using 8 \<open>0 < diff_inv\<close> by auto
             show "support_set contr_pf \<subseteq> stocks Mkt \<union> {x}" using 7 \<open>0 < diff_inv\<close> by auto
           qed
       } note posp = this
       have "diff_inv \<noteq> 0 \<longrightarrow> \<not>(\<exists> pr. price_structure der matur \<pi> pr \<and>
         (\<forall> x. (x\<notin> stocks Mkt \<longrightarrow>
           (\<forall> Mkt2 p. (coincides_on Mkt Mkt2 (stocks Mkt)) \<and> (prices Mkt2 x = pr) \<and> portfolio p \<and> support_set p \<subseteq> stocks Mkt \<union> {x} \<longrightarrow>
             \<not> arbitrage_process Mkt2 p))))"
         using \<open>coincides_on Mkt Mkt2 (stocks Mkt)\<close> \<open>prices Mkt2 x = pr\<close> \<open>x \<notin> stocks Mkt\<close> xasset posp negp by force
   }
   hence "diff_inv = 0" using fix_asset_price expr by metis
   moreover have "constant_image (prices Mkt pos_stock 0) > 0"
     by (simp add: adapted_init constant_image_pos pos_stock_borel_adapted positive)
   ultimately show ?thesis unfolding diff_inv_def by auto
 qed
 
 
 subsection \<open>Risk-neutral probability space\<close>
 
 subsubsection \<open>risk-free rate and discount factor processes\<close>
 
 fun disc_rfr_proc:: "real \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> real"
 where
   rfr_base: "(disc_rfr_proc r) 0 w = 1"|
   rfr_step: "(disc_rfr_proc r) (Suc n) w = (1+r) * (disc_rfr_proc r) n w"
 
 
 lemma disc_rfr_proc_borel_measurable:
   shows "(disc_rfr_proc r) n \<in> borel_measurable M"
 proof (induct n)
 case (Suc n) thus ?case by (simp add:borel_measurable_times)
 qed auto
 
 lemma disc_rfr_proc_nonrandom:
   fixes r::real
   shows "\<And>n. disc_rfr_proc r n \<in> borel_measurable (F 0)" using disc_rfr_proc_borel_measurable by auto
 
 
 lemma (in disc_equity_market) disc_rfr_constant_time:
 shows "\<exists>c. \<forall>w \<in> space (F 0).  (disc_rfr_proc r n) w = c"
 proof (rule triv_measurable_cst)
   show "space (F 0) = space M" using filtration by (simp add:filtration_def subalgebra_def)
   show "sets (F 0) = {{}, space M}" using info_disc_filtr  by (simp add: bot_nat_def init_triv_filt_def)
   show "(disc_rfr_proc r n) \<in> borel_measurable (F 0)" using disc_rfr_proc_nonrandom by blast
   show "space M \<noteq> {}" by (simp add:not_empty)
 qed
 
 
 
 lemma (in disc_filtr_prob_space) disc_rfr_proc_borel_adapted:
   shows "borel_adapt_stoch_proc F (disc_rfr_proc r)"
 unfolding adapt_stoch_proc_def using disc_rfr_proc_nonrandom
          filtration unfolding filtration_def
   by (meson increasing_measurable_info le0)
 
 
 
 lemma disc_rfr_proc_positive:
   assumes "-1 < r"
   shows "\<And>n w . 0 < disc_rfr_proc r n w"
 proof -
   fix n
   fix w::'a
   show "0 < disc_rfr_proc r n w"
   proof (induct n)
   case 0 thus ?case using assms  "disc_rfr_proc.simps" by simp
   next
   case (Suc n) thus ?case using  assms "disc_rfr_proc.simps" by simp
   qed
 qed
 
 
 
 
 
 lemma (in prob_space) disc_rfr_constant_time_pos:
   assumes "-1 < r"
 shows "\<exists>c > 0. \<forall>w \<in> space M.  (disc_rfr_proc r n) w = c"
 proof -
   let ?F = "sigma (space M) {{}, space M}"
   have  ex: "\<exists>c. \<forall>w \<in> space ?F.  (disc_rfr_proc r n) w = c"
   proof (rule triv_measurable_cst)
     show "space ?F = space M" by simp
     show "sets ?F = {{}, space M}" by (meson sigma_algebra.sets_measure_of_eq sigma_algebra_trivial)
     show "(disc_rfr_proc r n) \<in> borel_measurable ?F" using disc_rfr_proc_borel_measurable by blast
     show "space M \<noteq> {}" by (simp add:not_empty)
   qed
   from this obtain c where "\<forall>w \<in> space ?F.  (disc_rfr_proc r n) w = c" by auto note cprops = this
   have "c>0"
   proof -
     have "\<exists> w. w\<in> space M" using subprob_not_empty by blast
     from this obtain w where "w\<in> space M" by auto
     hence "c = disc_rfr_proc r n w" using cprops  by simp
     also have "... > 0" using disc_rfr_proc_positive[of r n] assms by simp
     finally show ?thesis .
   qed
   moreover have "space M = space ?F" by simp
   ultimately show ?thesis using ex using cprops by blast
 qed
 
 
 lemma  disc_rfr_proc_Suc_div:
   assumes "-1 < r"
   shows "\<And>w. disc_rfr_proc r (Suc n) w/disc_rfr_proc r n w = 1+r"
 proof -
   fix w::'a
   show "disc_rfr_proc r (Suc n) w/disc_rfr_proc r n w = 1+r"
     using disc_rfr_proc_positive assms by (metis rfr_step  less_irrefl nonzero_eq_divide_eq)
 qed
 
 definition discount_factor where
   "discount_factor r n = (\<lambda>w. inverse (disc_rfr_proc r n w))"
 
 lemma discount_factor_times_rfr:
   assumes "-1 < r"
   shows "(1+r) * discount_factor r (Suc n) w = discount_factor r n w" unfolding discount_factor_def using assms by simp
 
 lemma discount_factor_borel_measurable:
   shows "discount_factor r n \<in> borel_measurable M" unfolding discount_factor_def
 proof (rule borel_measurable_inverse)
   show "disc_rfr_proc r n \<in> borel_measurable M" by (simp add:disc_rfr_proc_borel_measurable)
 qed
 
 lemma discount_factor_init:
   shows "discount_factor r 0 = (\<lambda>w. 1)" unfolding discount_factor_def by simp
 
 lemma discount_factor_nonrandom:
   shows "discount_factor r n \<in> borel_measurable M" unfolding discount_factor_def
 proof (rule borel_measurable_inverse)
   show "disc_rfr_proc r n \<in> borel_measurable M" by (simp add:disc_rfr_proc_borel_measurable)
 qed
 
 
 lemma discount_factor_positive:
   assumes "-1 < r"
   shows "\<And>n w . 0 < discount_factor r n w" using assms disc_rfr_proc_positive unfolding discount_factor_def by auto
 
 
 lemma (in prob_space) discount_factor_constant_time_pos:
   assumes "-1 < r"
 shows "\<exists>c > 0. \<forall>w \<in> space M.  (discount_factor r n) w = c"  using  disc_rfr_constant_time_pos unfolding discount_factor_def
   by (metis assms inverse_positive_iff_positive)
 
 
 locale rsk_free_asset =
   fixes Mkt r risk_free_asset
   assumes acceptable_rate: "-1 < r"
   and rf_price: "prices Mkt risk_free_asset = disc_rfr_proc r"
   and rf_stock: "risk_free_asset \<in> stocks Mkt"
 
 locale rfr_disc_equity_market = disc_equity_market   + rsk_free_asset +
   assumes rd: "\<forall> asset\<in> stocks Mkt. borel_adapt_stoch_proc F (prices Mkt asset)"
 
 
 
 sublocale rfr_disc_equity_market \<subseteq> disc_market_pos_stock _ _ _ "risk_free_asset"
 by (unfold_locales, (auto simp add: rf_stock rd disc_rfr_proc_positive rf_price acceptable_rate))
 
 subsubsection \<open>Discounted value of a stochastic process\<close>
 
 definition discounted_value where
   "discounted_value r X = (\<lambda> n w. discount_factor r n w * X n w)"
 
 
 
 lemma (in rfr_disc_equity_market) discounted_rfr:
   shows "discounted_value r (prices Mkt risk_free_asset) n w = 1" unfolding discounted_value_def discount_factor_def
   using rf_price by (metis less_irrefl mult.commute positive right_inverse)
 
 lemma  discounted_init:
   shows "\<forall>w. discounted_value r X 0 w = X 0 w" unfolding discounted_value_def by (simp add: discount_factor_init)
 
 lemma  discounted_mult:
   shows "\<forall>n w. discounted_value r (\<lambda>m x. X m x * Y m x) n w = X n w * (discounted_value r Y) n w"
   by (simp add: discounted_value_def)
 
 lemma  discounted_mult':
   shows "discounted_value r (\<lambda>m x. X m x * Y m x) n w = X n w * (discounted_value r Y) n w"
   by (simp add: discounted_value_def)
 
 lemma discounted_mult_times_rfr:
   assumes "-1 < r"
   shows "discounted_value r (\<lambda>m w. (1+r) * X w) (Suc n) w = discounted_value r (\<lambda>m w. X w) n w"
     unfolding discounted_value_def using assms discount_factor_times_rfr discounted_mult
     by (simp add: discount_factor_times_rfr mult.commute)
 
 lemma discounted_cong:
   assumes "\<forall>n w. X n w = Y n w"
   shows "\<forall> n w. discounted_value r X n w = discounted_value r Y n w"
   by (simp add: assms discounted_value_def)
 
 lemma  discounted_cong':
   assumes "X n w = Y n w"
   shows "discounted_value r X n w = discounted_value r Y n w"
   by (simp add: assms discounted_value_def)
 
 lemma discounted_AE_cong:
   assumes "AE w in N. X n w = Y n w"
   shows "AE w in N. discounted_value r X n w = discounted_value r Y n w"
 proof (rule AE_mp)
   show "AE w in N. X n w = Y n w" using assms by simp
   show "AE w in N. X n w = Y n w \<longrightarrow> discounted_value r X n w = discounted_value r Y n w"
   proof
     fix w
     assume "w\<in> space N"
     thus "X n w = Y n w \<longrightarrow> discounted_value r X n w = discounted_value r Y n w " by (simp add:discounted_value_def)
   qed
 qed
 
 
 
 lemma discounted_sum:
   assumes "finite I"
 shows "\<forall>n w. (\<Sum> i\<in> I. (discounted_value r (\<lambda>m x. f i m x)) n w) = (discounted_value r (\<lambda>m x. (\<Sum>i\<in> I. f i m x)) n w)"
   using assms(1) subset_refl[of I]
 proof (induct rule: finite_subset_induct)
   case empty
   then show ?case
     by (simp add: discounted_value_def)
 next
   case (insert a F)
   show ?case
   proof (intro allI)
     fix n w
     have "(\<Sum>i\<in>insert a F. discounted_value r (f i) n w) = discounted_value r (f a) n w + (\<Sum>i\<in>F. discounted_value r (f i) n w)"
       by (simp add: insert.hyps(1) insert.hyps(3))
     also have "... = discounted_value r (f a) n w + discounted_value r (\<lambda>m x. \<Sum>i\<in>F. f i m x) n w" using insert.hyps(4) by simp
     also have "... = discounted_value r (\<lambda>m x. \<Sum>i\<in>insert a F. f i m x) n w"
       by (simp add: discounted_value_def insert.hyps(1) insert.hyps(3) ring_class.ring_distribs(1))
     finally show "(\<Sum>i\<in>insert a F. discounted_value r (f i) n w) = discounted_value r (\<lambda>m x. \<Sum>i\<in>insert a F. f i m x) n w" .
   qed
 qed
 
 lemma  discounted_adapted:
   assumes "borel_adapt_stoch_proc F X"
   shows "borel_adapt_stoch_proc F (discounted_value r X)" unfolding adapt_stoch_proc_def
 proof
   fix t
   show "discounted_value r X t \<in> borel_measurable (F t)" unfolding discounted_value_def
   proof (rule borel_measurable_times)
     show "X t \<in> borel_measurable (F t)" using assms unfolding adapt_stoch_proc_def by simp
     show "discount_factor r t \<in> borel_measurable (F t)" using discount_factor_borel_measurable by auto
   qed
 qed
 
 lemma discounted_measurable:
   assumes "X\<in> borel_measurable N"
   shows "discounted_value r (\<lambda>m. X) m \<in> borel_measurable N" unfolding discounted_value_def
 proof (rule borel_measurable_times)
   show "X\<in> borel_measurable N" using assms by simp
   show "discount_factor r m \<in> borel_measurable N" using discount_factor_borel_measurable by auto
 qed
 
 
 lemma (in prob_space) discounted_integrable:
   assumes "integrable N (X n)"
   and "-1 < r"
   and "space N = space M"
   shows "integrable N (discounted_value r X n)" unfolding discounted_value_def
 proof -
   have "\<exists>c> 0. \<forall>w \<in> space M.  (discount_factor r n) w = c" using discount_factor_constant_time_pos assms by simp
   from this obtain c where "c > 0" and "\<forall>w \<in> space M.  (discount_factor r n) w = c" by auto note cprops = this
   hence "\<forall>w \<in> space M. discount_factor r n w = c" using cprops  by simp
   hence "\<forall>w \<in> space N. discount_factor r n w = c" using assms by simp
   thus "integrable N (\<lambda>w. discount_factor r n w * X n w)"
     using \<open>\<forall>w \<in> space N. discount_factor r n w = c\<close> assms
-    integrable_cong[of N N "(\<lambda>w. discount_factor r n w * X n w)" "(\<lambda>w. c * X n w)"] by simp
+    Bochner_Integration.integrable_cong[of N N "(\<lambda>w. discount_factor r n w * X n w)" "(\<lambda>w. c * X n w)"] by simp
 qed
 
 
 subsubsection \<open>Results on risk-neutral probability spaces\<close>
 
 definition (in rfr_disc_equity_market) risk_neutral_prob where
   "risk_neutral_prob N \<longleftrightarrow> (prob_space N) \<and> (\<forall> asset \<in> stocks Mkt. martingale N F (discounted_value r (prices Mkt asset)))"
 
 
 lemma integrable_val_process:
   assumes "\<forall> asset \<in> support_set pf. integrable M (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   shows "integrable M (val_process Mkt pf n)"
 proof (cases "portfolio pf")
   case False
   thus ?thesis unfolding val_process_def by simp
 next
   case True
   hence "val_process Mkt pf n = (\<lambda>w. \<Sum>x\<in>support_set pf. prices Mkt x n w * pf x (Suc n) w)"
     unfolding val_process_def by simp
   moreover have "integrable M (\<lambda>w. \<Sum>x\<in>support_set pf. prices Mkt x n w * pf x (Suc n) w)" using assms by simp
   ultimately show ?thesis by simp
 qed
 
 lemma integrable_self_fin_uvp:
   assumes "\<forall> asset \<in> support_set pf. integrable M (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   and "self_financing Mkt pf"
 shows "integrable M (cls_val_process Mkt pf n)"
 proof -
   have "val_process Mkt pf n = cls_val_process Mkt pf n" using assms by (simp add:self_financingE)
   moreover have "integrable M (val_process Mkt pf n)" using assms by (simp add:integrable_val_process)
   ultimately show ?thesis by simp
 qed
 
 
 
 lemma (in rfr_disc_equity_market) stocks_portfolio_risk_neutral:
   assumes "risk_neutral_prob N"
   and "trading_strategy pf"
   and "subalgebra N M"
   and "support_set pf \<subseteq> stocks Mkt"
   and "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
   shows  "\<forall>x \<in> support_set pf. AE w in N.
         (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n))) w =
         discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w"
 proof
   have nsigfin: "\<forall>n. sigma_finite_subalgebra N (F n)" using assms unfolding risk_neutral_prob_def martingale_def subalgebra_def
       using filtration filtration_def risk_neutral_prob_def prob_space.subalgebra_sigma_finite in_stock by metis
   have "disc_filtr_prob_space N F"
   proof -
     have "prob_space N" using assms unfolding risk_neutral_prob_def by simp
     moreover have "disc_filtr N F" using assms subalgebra_filtration
       by (metis (no_types, lifting) filtration disc_filtr_def filtration_def)
     ultimately show ?thesis
       by (simp add: disc_filtr_prob_space_axioms_def disc_filtr_prob_space_def)
   qed
   fix asset
   assume "asset \<in> support_set pf"
   hence "asset \<in> stocks Mkt" using assms by auto
   have "discounted_value r (prices Mkt asset) (Suc n) \<in> borel_measurable M" using assms readable
     by (meson \<open>asset \<in> stocks Mkt\<close> borel_adapt_stoch_proc_borel_measurable discounted_adapted
         rfr_disc_equity_market.risk_neutral_prob_def rfr_disc_equity_market_axioms)
   hence b: "discounted_value r (prices Mkt asset) (Suc n) \<in> borel_measurable N"
       using assms Conditional_Expectation.measurable_from_subalg[of N M _ borel] by auto
   show "AEeq N (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset m y) (Suc n)))
   (discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset (Suc m) y) n)"
   proof -
     have "AE w in N. (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset m y) (Suc n))) w =
       (real_cond_exp N (F n) (\<lambda>z. pf asset (Suc n) z * discounted_value r (\<lambda>m y. prices Mkt asset m y) (Suc n) z)) w"
     proof (rule sigma_finite_subalgebra.real_cond_exp_cong)
       show "sigma_finite_subalgebra N (F n)" using nsigfin ..
       show "AE w in N. discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset m y) (Suc n) w =
          pf asset (Suc n) w * discounted_value r (\<lambda>m y. prices Mkt asset m y) (Suc n) w"
         by (simp add: discounted_value_def)
       show "discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset m y) (Suc n) \<in> borel_measurable N"
       proof -
         have "(\<lambda>y. prices Mkt asset (Suc n) y * pf asset (Suc n) y) \<in> borel_measurable N"
           using assms \<open>asset\<in> support_set pf\<close> by (simp add:borel_measurable_integrable)
         thus ?thesis unfolding discounted_value_def using discount_factor_borel_measurable[of r "Suc n" N] by simp
       qed
       show "(\<lambda>z. pf asset (Suc n) z * discounted_value r (prices Mkt asset) (Suc n) z) \<in> borel_measurable N"
       proof -
         have "pf asset (Suc n) \<in> borel_measurable M" using assms \<open>asset\<in> support_set pf\<close> unfolding trading_strategy_def
           using borel_predict_stoch_proc_borel_measurable[of "pf asset"] by auto
         hence a: "pf asset (Suc n) \<in> borel_measurable N" using assms Conditional_Expectation.measurable_from_subalg[of N M _ borel] by blast
         show ?thesis using a b by simp
       qed
     qed
     also have "AE w in N. (real_cond_exp N (F n) (\<lambda>z. pf asset (Suc n) z * discounted_value r (\<lambda>m y. prices Mkt asset m y) (Suc n) z)) w =
       pf asset (Suc n) w * (real_cond_exp N (F n) (\<lambda>z. discounted_value r (\<lambda>m y. prices Mkt asset m y) (Suc n) z)) w"
     proof (rule sigma_finite_subalgebra.real_cond_exp_mult)
       show "discounted_value r (prices Mkt asset) (Suc n) \<in> borel_measurable N" using b by simp
       show "sigma_finite_subalgebra N (F n)" using nsigfin ..
       show "pf asset (Suc n) \<in> borel_measurable (F n)" using assms \<open>asset\<in> support_set pf\<close> unfolding trading_strategy_def
           predict_stoch_proc_def by auto
       show "integrable N (\<lambda>z. pf asset (Suc n) z * discounted_value r (prices Mkt asset) (Suc n) z)"
       proof -
         have "integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)" using assms \<open>asset \<in> support_set pf\<close> by auto
         hence "integrable N (discounted_value r (\<lambda>m w. prices Mkt asset m w * pf asset m w) (Suc n))" using assms
           unfolding risk_neutral_prob_def using acceptable_rate  by (auto simp add:discounted_integrable subalgebra_def)
-        thus ?thesis using discounted_mult
-            integrable_cong[of N N "discounted_value r (\<lambda>m w. prices Mkt asset m w * pf asset m w) (Suc n)" "(\<lambda>z. pf asset (Suc n) z * discounted_value r (prices Mkt asset) (Suc n) z)"]
-          by (simp add: discounted_value_def)
+        thus ?thesis
+          by (smt (verit, ccfv_SIG) Bochner_Integration.integrable_cong discounted_value_def mult.assoc mult.commute)
       qed
     qed
     also have "AE w in N.  pf asset (Suc n) w * (real_cond_exp N (F n) (\<lambda>z. discounted_value r (\<lambda>m y. prices Mkt asset m y) (Suc n) z)) w =
             pf asset (Suc n) w * discounted_value r (\<lambda>m y. prices Mkt asset m y) n w"
     proof -
       have "AEeq N (real_cond_exp N (F n) (\<lambda>z. discounted_value r (\<lambda>m y. prices Mkt asset m y) (Suc n) z))
         (\<lambda>z. discounted_value r (\<lambda>m y. prices Mkt asset m y) n z)"
       proof -
         have "martingale N F (discounted_value r (prices Mkt asset))"
           using assms \<open>asset \<in> stocks Mkt\<close> unfolding risk_neutral_prob_def by simp
         moreover have "filtrated_prob_space N F" using \<open>disc_filtr_prob_space N F\<close>
           using assms(2) disc_filtr_prob_space.axioms(1) filtrated_prob_space.intro filtrated_prob_space_axioms.intro filtration prob_space_axioms
           by (metis assms(3) subalgebra_filtration)
         ultimately show ?thesis using martingaleAE[of N F "discounted_value r (prices Mkt asset)" n "Suc n"] assms
           by simp
       qed
       thus ?thesis by auto
     qed
     also have "AE w in N.  pf asset (Suc n) w * discounted_value r (\<lambda>m y. prices Mkt asset m y) n w =
       discounted_value r (\<lambda>m y. pf asset (Suc m) y * prices Mkt asset m y) n w" by (simp add: discounted_value_def)
     also have "AE w in N. discounted_value r (\<lambda>m y. pf asset (Suc m) y * prices Mkt asset m y) n w =
       discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset (Suc m) y) n w"
       by (simp add: discounted_value_def)
     finally show "AE w in N.
       (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset m y) (Suc n))) w =
       (\<lambda>x. discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset (Suc m) y) n x) w" .
   qed
 qed
 
 
 
 lemma (in rfr_disc_equity_market) self_fin_trad_strat_mart:
   assumes "risk_neutral_prob N"
   and "filt_equiv F M N"
   and "trading_strategy pf"
   and "self_financing Mkt pf"
 and "stock_portfolio Mkt pf"
   and "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   and "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
 shows "martingale N F (discounted_value r (cls_val_process Mkt pf))" (*unfolding martingale_def*)
 proof (rule disc_martingale_charact)
   show nsigfin: "\<forall>n. sigma_finite_subalgebra N (F n)" using filt_equiv_prob_space_subalgebra assms
           using filtration filtration_def risk_neutral_prob_def subalgebra_sigma_finite by fastforce
   show "filtration N F" using assms by (simp  add:filt_equiv_filtration)
   have "borel_adapt_stoch_proc F (discounted_value r (cls_val_process Mkt pf))" using assms discounted_adapted
     cls_val_process_adapted[of pf] stock_portfolio_def
     by (metis (mono_tags, opaque_lifting) support_adapt_def readable subsetCE)
   thus "\<forall>m. discounted_value r (cls_val_process Mkt pf) m \<in> borel_measurable (F m)" unfolding adapt_stoch_proc_def by simp
   show "\<forall>t. integrable N (discounted_value r (cls_val_process Mkt pf) t)"
   proof
     fix t
     have "integrable N (cls_val_process Mkt pf t)" using assms by (simp add: integrable_self_fin_uvp)
     thus "integrable N (discounted_value r (cls_val_process Mkt pf) t)" using assms discounted_integrable acceptable_rate
       by (metis filt_equiv_space)
   qed
   show "\<forall>n. AE w in N. real_cond_exp N (F n) (discounted_value r (cls_val_process Mkt pf) (Suc n)) w =
                    discounted_value r (cls_val_process Mkt pf) n w"
   proof
     fix n
     show "AE w in N. real_cond_exp N (F n) (discounted_value r (cls_val_process Mkt pf) (Suc n)) w =
                     discounted_value r (cls_val_process Mkt pf) n w"
     proof -
       {
         fix w
         assume "w\<in> space M"
         have "discounted_value r (cls_val_process Mkt pf) (Suc n) w =
                   discount_factor r (Suc n) w * (\<Sum>x\<in>support_set pf. prices Mkt x (Suc n) w * pf x (Suc n) w)"
           unfolding discounted_value_def cls_val_process_def using assms unfolding trading_strategy_def by simp
         also have "... = (\<Sum>x\<in>support_set pf. discount_factor r (Suc n) w * prices Mkt x (Suc n) w * pf x (Suc n) w)"
           by (metis (no_types, lifting) mult.assoc sum.cong sum_distrib_left)
         finally have "discounted_value r (cls_val_process Mkt pf) (Suc n) w =
                   (\<Sum>x\<in>support_set pf. discount_factor r (Suc n) w * prices Mkt x (Suc n) w * pf x (Suc n) w)" .
       }
       hence space: "\<forall>w\<in> space M. discounted_value r (cls_val_process Mkt pf) (Suc n) w =
                 (\<Sum>x\<in>support_set pf. discount_factor r (Suc n) w * prices Mkt x (Suc n) w * pf x (Suc n) w)" by simp
       hence nspace: "\<forall>w\<in> space N. discounted_value r (cls_val_process Mkt pf) (Suc n) w =
                 (\<Sum>x\<in>support_set pf. discount_factor r (Suc n) w * prices Mkt x (Suc n) w * pf x (Suc n) w)" using assms by (simp add:filt_equiv_space)
       have sup_disc: "\<forall>x \<in> support_set pf. AE w in N.
         (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n))) w =
         discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w" using assms
         by (simp add:stocks_portfolio_risk_neutral filt_equiv_imp_subalgebra stock_portfolio_def)
       have "AE w in N. real_cond_exp N (F n) (discounted_value r (cls_val_process Mkt pf) (Suc n)) w =
                 real_cond_exp N (F n) (\<lambda>y. \<Sum>x\<in>support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n) y) w"
       proof (rule sigma_finite_subalgebra.real_cond_exp_cong')
         show "sigma_finite_subalgebra N (F n)" using nsigfin ..
         show "\<forall>w\<in>space N. discounted_value r (cls_val_process Mkt pf) (Suc n) w =
           (\<lambda>y. \<Sum>x\<in>support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n) y) w"  using nspace
           by (metis (no_types, lifting) discounted_value_def mult.assoc sum.cong)
         show "(discounted_value r (cls_val_process Mkt pf) (Suc n)) \<in> borel_measurable N" using assms
           using \<open>\<forall>t. integrable N (discounted_value r (cls_val_process Mkt pf) t)\<close> by blast
       qed
       also have "AE w in N. real_cond_exp N (F n)
         (\<lambda>y. \<Sum>x\<in>support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n) y) w =
         (\<Sum>x\<in> support_set pf. (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n))) w)"
       proof (rule sigma_finite_subalgebra.real_cond_exp_bsum)
         show "sigma_finite_subalgebra N (F n)" using filt_equiv_prob_space_subalgebra assms
           using filtration filtration_def risk_neutral_prob_def subalgebra_sigma_finite by fastforce
         fix asset
         assume "asset \<in> support_set pf"
         show "integrable N (discounted_value r (\<lambda>m y. prices Mkt asset m y * pf asset m y) (Suc n))"
         proof (rule discounted_integrable)
           show "integrable N (\<lambda>y. prices Mkt asset (Suc n) y * pf asset (Suc n) y)" using assms \<open>asset\<in> support_set pf\<close> by simp
           show "space N = space M" using assms by (metis filt_equiv_space)
           show "-1 < r" using acceptable_rate by simp
         qed
       qed
       also have "AE w in N.
         (\<Sum>x\<in> support_set pf. (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n))) w) =
         (\<Sum>x\<in> support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w)"
       proof (rule AE_sum)
         show "finite (support_set pf)" using assms(3) portfolio_def trading_strategy_def by auto
         show  "\<forall>x \<in> support_set pf. AE w in N.
         (real_cond_exp N (F n) (discounted_value r (\<lambda>m y. prices Mkt x m y * pf x m y) (Suc n))) w =
         discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w" using sup_disc by simp
       qed
       also have "AE w in N.
         (\<Sum>x\<in> support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w) =
         discounted_value r (cls_val_process Mkt pf) n w"
       proof
         fix w
         assume "w\<in> space N"
         have "(\<Sum>x\<in> support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w) =
           discounted_value r (\<lambda>m y. (\<Sum>x\<in> support_set pf. prices Mkt x m y * pf x (Suc m) y)) n w" using discounted_sum
           assms(3) portfolio_def trading_strategy_def by (simp add: discounted_value_def sum_distrib_left)
         also have "... = discounted_value r (val_process Mkt pf) n w"  unfolding val_process_def
           by (simp add: portfolio_def)
         also have "... = discounted_value r (cls_val_process Mkt pf) n w" using assms
           by (simp add:self_financingE discounted_cong)
         finally show "(\<Sum>x\<in> support_set pf. discounted_value r (\<lambda>m y. prices Mkt x m y * pf x (Suc m) y) n w) =
           discounted_value r (cls_val_process Mkt pf) n w" .
       qed
       finally show "AE w in N. real_cond_exp N (F n) (discounted_value r (cls_val_process Mkt pf) (Suc n)) w =
         discounted_value r (cls_val_process Mkt pf) n w" .
     qed
   qed
 qed
 
 lemma (in disc_filtr_prob_space) finite_integrable_vp:
   assumes "\<forall>n. \<forall> asset \<in> support_set pf. finite (prices Mkt asset n `(space M))"
   and "\<forall>n. \<forall> asset \<in> support_set pf. finite (pf asset n `(space M))"
 and "prob_space N"
   and "filt_equiv F M N"
 and "trading_strategy pf"
 and "\<forall>n. \<forall> asset \<in> support_set pf. prices Mkt asset n \<in> borel_measurable M"
 shows  "\<forall>n. \<forall>asset\<in>support_set pf. integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
 proof (intro allI ballI)
   fix n
   fix asset
   assume "asset\<in>support_set pf"
   show "integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   proof (rule prob_space.finite_borel_measurable_integrable)
     show "prob_space N" using assms by simp
     have "finite ((\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M)"
     proof -
       have "\<forall>y\<in> prices Mkt asset n `(space M). finite ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)"
         by (metis \<open>asset \<in> support_set pf\<close> assms(2) finite_imageI image_image)
       hence "finite (\<Union> y\<in> prices Mkt asset n `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y))"
         using \<open>asset \<in> support_set pf\<close> assms by blast
       moreover have "(\<Union> y\<in> prices Mkt asset n `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)) =
         (\<Union> y\<in> prices Mkt asset n `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"  by simp
       moreover have "((\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M) \<subseteq>
         (\<Union> y\<in> prices Mkt asset n `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
       proof
         fix x
         assume "x \<in> (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M"
         show "x \<in> (\<Union>y\<in>prices Mkt asset n ` space M. (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
           using \<open>x \<in> (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M\<close> by auto
       qed
       ultimately show ?thesis by (simp add:finite_subset)
     qed
     thus "finite ((\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space N)" using assms by (simp add:filt_equiv_space)
     have "(\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) \<in> borel_measurable M"
     proof -
       have "prices Mkt asset n \<in> borel_measurable M" using assms \<open>asset \<in> support_set pf\<close> by simp
       moreover have "pf asset (Suc n) \<in> borel_measurable M" using assms unfolding trading_strategy_def
         using \<open>asset \<in> support_set pf\<close> borel_predict_stoch_proc_borel_measurable by blast
       ultimately show ?thesis by simp
     qed
     thus "(\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) \<in> borel_measurable N" using assms by (simp add:filt_equiv_measurable)
   qed
 qed
 
 
 lemma (in disc_filtr_prob_space) finite_integrable_uvp:
   assumes "\<forall>n. \<forall> asset \<in> support_set pf. finite (prices Mkt asset n `(space M))"
   and "\<forall>n. \<forall> asset \<in> support_set pf. finite (pf asset n `(space M))"
 and "prob_space N"
   and "filt_equiv F M N"
 and "trading_strategy pf"
 and "\<forall>n. \<forall> asset \<in> support_set pf. prices Mkt asset n \<in> borel_measurable M"
 shows  "\<forall>n. \<forall>asset\<in>support_set pf. integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
 proof (intro allI ballI)
   fix n
   fix asset
   assume "asset\<in>support_set pf"
   show "integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
   proof (rule prob_space.finite_borel_measurable_integrable)
     show "prob_space N" using assms by simp
     have "finite ((\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M)"
     proof -
       have "\<forall>y\<in> prices Mkt asset (Suc n) `(space M). finite ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)"
         by (metis \<open>asset \<in> support_set pf\<close> assms(2) finite_imageI image_image)
       hence "finite (\<Union> y\<in> prices Mkt asset (Suc n) `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y))"
         using \<open>asset \<in> support_set pf\<close> assms by blast
       moreover have "(\<Union> y\<in> prices Mkt asset (Suc n) `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)) =
         (\<Union> y\<in> prices Mkt asset (Suc n) `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"  by simp
       moreover have "((\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M) \<subseteq>
         (\<Union> y\<in> prices Mkt asset (Suc n) `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
       proof
         fix x
         assume "x \<in> (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M"
         show "x \<in> (\<Union>y\<in>prices Mkt asset (Suc n) ` space M. (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
           using \<open>x \<in> (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M\<close> by auto
       qed
       ultimately show ?thesis by (simp add:finite_subset)
     qed
     thus "finite ((\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space N)" using assms by (simp add:filt_equiv_space)
     have "(\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) \<in> borel_measurable M"
     proof -
       have "prices Mkt asset (Suc n) \<in> borel_measurable M" using assms
         using \<open>asset \<in> support_set pf\<close> borel_adapt_stoch_proc_borel_measurable by blast
       moreover have "pf asset (Suc n) \<in> borel_measurable M" using assms unfolding trading_strategy_def
         using \<open>asset \<in> support_set pf\<close> borel_predict_stoch_proc_borel_measurable by blast
       ultimately show ?thesis by simp
     qed
     thus "(\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) \<in> borel_measurable N" using assms by (simp add:filt_equiv_measurable)
   qed
 qed
 
 lemma (in rfr_disc_equity_market) self_fin_trad_strat_mart_finite:
   assumes "risk_neutral_prob N"
   and "filt_equiv F M N"
   and "trading_strategy pf"
   and "self_financing Mkt pf"
   and "support_set pf \<subseteq> stocks Mkt"
   and "\<forall>n. \<forall> asset \<in> support_set pf. finite (prices Mkt asset n `(space M))"
   and "\<forall>n. \<forall> asset \<in> support_set pf. finite (pf asset n `(space M))"
 and "\<forall> asset\<in> stocks Mkt. borel_adapt_stoch_proc F (prices Mkt asset)"
 shows "martingale N F (discounted_value r (cls_val_process Mkt pf))"
 proof (rule self_fin_trad_strat_mart, (simp add:assms)+)
   show "\<forall>n. \<forall>asset\<in>support_set pf. integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   proof (intro allI ballI)
     fix n
     fix asset
     assume "asset\<in>support_set pf"
     show "integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
     proof (rule prob_space.finite_borel_measurable_integrable)
       show "prob_space N" using assms unfolding risk_neutral_prob_def by auto
       have "finite ((\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M)"
       proof -
         have "\<forall>y\<in> prices Mkt asset n `(space M). finite ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)"
           by (metis \<open>asset \<in> support_set pf\<close> assms(7) finite_imageI image_image)
         hence "finite (\<Union> y\<in> prices Mkt asset n `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y))"
           using \<open>asset \<in> support_set pf\<close> assms(6) by blast
         moreover have "(\<Union> y\<in> prices Mkt asset n `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)) =
           (\<Union> y\<in> prices Mkt asset n `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"  by simp
         moreover have "((\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M) \<subseteq>
           (\<Union> y\<in> prices Mkt asset n `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
         proof
           fix x
           assume "x \<in> (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M"
           show "x \<in> (\<Union>y\<in>prices Mkt asset n ` space M. (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
             using \<open>x \<in> (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space M\<close> by auto
         qed
         ultimately show ?thesis by (simp add:finite_subset)
       qed
       thus "finite ((\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) ` space N)" using assms by (simp add:filt_equiv_space)
       have "(\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) \<in> borel_measurable M"
       proof -
         have "prices Mkt asset n \<in> borel_measurable M" using assms readable
           using \<open>asset \<in> support_set pf\<close> borel_adapt_stoch_proc_borel_measurable by blast
         moreover have "pf asset (Suc n) \<in> borel_measurable M" using assms unfolding trading_strategy_def
           using \<open>asset \<in> support_set pf\<close> borel_predict_stoch_proc_borel_measurable by blast
         ultimately show ?thesis by simp
       qed
       thus "(\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w) \<in> borel_measurable N" using assms by (simp add:filt_equiv_measurable)
     qed
   qed
   show "\<forall>n. \<forall>asset\<in>support_set pf. integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
   proof (intro allI ballI)
     fix n
     fix asset
     assume "asset\<in>support_set pf"
     show "integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
     proof (rule prob_space.finite_borel_measurable_integrable)
       show "prob_space N" using assms unfolding risk_neutral_prob_def by auto
       have "finite ((\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M)"
       proof -
         have "\<forall>y\<in> prices Mkt asset (Suc n) `(space M). finite ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)"
           by (metis \<open>asset \<in> support_set pf\<close> assms(7) finite_imageI image_image)
         hence "finite (\<Union> y\<in> prices Mkt asset (Suc n) `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y))"
           using \<open>asset \<in> support_set pf\<close> assms(6) by blast
         moreover have "(\<Union> y\<in> prices Mkt asset (Suc n) `(space M). ((\<lambda> z. (\<lambda>w. z * pf asset (Suc n) w) ` space M) y)) =
           (\<Union> y\<in> prices Mkt asset (Suc n) `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"  by simp
         moreover have "((\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M) \<subseteq>
           (\<Union> y\<in> prices Mkt asset (Suc n) `(space M). (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
         proof
           fix x
           assume "x \<in> (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M"
           show "x \<in> (\<Union>y\<in>prices Mkt asset (Suc n) ` space M. (\<lambda>w. y * pf asset (Suc n) w) ` space M)"
             using \<open>x \<in> (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space M\<close> by auto
         qed
         ultimately show ?thesis by (simp add:finite_subset)
       qed
       thus "finite ((\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) ` space N)" using assms by (simp add:filt_equiv_space)
       have "(\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) \<in> borel_measurable M"
       proof -
         have "prices Mkt asset (Suc n) \<in> borel_measurable M" using assms readable
           using \<open>asset \<in> support_set pf\<close> borel_adapt_stoch_proc_borel_measurable by blast
         moreover have "pf asset (Suc n) \<in> borel_measurable M" using assms unfolding trading_strategy_def
           using \<open>asset \<in> support_set pf\<close> borel_predict_stoch_proc_borel_measurable by blast
         ultimately show ?thesis by simp
       qed
       thus "(\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w) \<in> borel_measurable N" using assms by (simp add:filt_equiv_measurable)
     qed
   qed
   show "stock_portfolio Mkt pf" using assms stock_portfolio_def
     by (simp add: stock_portfolio_def trading_strategy_def)
 qed
 
 
 lemma (in rfr_disc_equity_market) replicating_expectation:
   assumes "risk_neutral_prob N"
   and "filt_equiv F M N"
   and "replicating_portfolio pf pyf matur"
   and "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   and "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
   and "viable_market Mkt"
   and "sets (F 0) = {{}, space M}"
   and "pyf  \<in> borel_measurable (F matur)"
 shows "fair_price Mkt (prob_space.expectation N (discounted_value r (\<lambda>m. pyf) matur)) pyf matur"
 proof -
   have fn: "filtrated_prob_space N F" using assms
     by (simp add: \<open>pyf \<in> borel_measurable (F matur)\<close> filtrated_prob_space_axioms.intro
         filtrated_prob_space_def risk_neutral_prob_def filt_equiv_filtration)
   have "discounted_value r (cls_val_process Mkt pf) matur \<in> borel_measurable N"
     using assms(3) disc_equity_market.replicating_portfolio_def disc_equity_market_axioms discounted_adapted
     filtrated_prob_space.borel_adapt_stoch_proc_borel_measurable fn cls_val_process_adapted
     by (metis (no_types, opaque_lifting) support_adapt_def readable  stock_portfolio_def subsetCE)
   have "discounted_value r (\<lambda>m. pyf) matur \<in> borel_measurable N"
   proof -
     have "(\<lambda>m. pyf) matur \<in> borel_measurable (F matur)" using assms by simp
     hence "(\<lambda>m. pyf) matur \<in> borel_measurable M"  using filtration filtrationE1 measurable_from_subalg by blast
     hence "(\<lambda>m. pyf) matur \<in> borel_measurable N" using assms by (simp add:filt_equiv_measurable)
     thus ?thesis by (simp add:discounted_measurable)
   qed
   have mpyf: "AE w in M. cls_val_process Mkt pf matur w = pyf w" using assms unfolding replicating_portfolio_def by simp
   have "AE w in N. cls_val_process Mkt pf matur w = pyf w"
   proof (rule filt_equiv_borel_AE_eq)
     show "filt_equiv F M N" using assms by simp
     show "pyf \<in> borel_measurable (F matur)" using assms by simp
     show "AE w in M. cls_val_process Mkt pf matur w = pyf w" using mpyf by simp
     show "cls_val_process Mkt pf matur \<in> borel_measurable (F matur)"
       using assms(3) price_structure_def replicating_price_process
       by (meson support_adapt_def disc_equity_market.replicating_portfolio_def disc_equity_market_axioms readable  stock_portfolio_def subsetCE)
   qed
   hence disc:"AE w in N. discounted_value r (cls_val_process Mkt pf) matur w = discounted_value r (\<lambda>m. pyf) matur w"
     by (simp add:discounted_AE_cong)
   have "AEeq N (real_cond_exp N (F 0) (discounted_value r (cls_val_process Mkt pf) matur))
     (real_cond_exp N (F 0) (discounted_value r (\<lambda>m. pyf) matur))"
   proof (rule sigma_finite_subalgebra.real_cond_exp_cong)
     show "sigma_finite_subalgebra N (F 0)"
       using filtrated_prob_space.axioms(1) filtrated_prob_space.filtration fn filtrationE1
         prob_space.subalgebra_sigma_finite by blast
     show "AEeq N (discounted_value r (cls_val_process Mkt pf) matur) (discounted_value r (\<lambda>m. pyf) matur)" using disc by simp
     show "discounted_value r (cls_val_process Mkt pf) matur \<in> borel_measurable N"
       using \<open>discounted_value r (cls_val_process Mkt pf) matur \<in> borel_measurable N\<close> .
     show "discounted_value r (\<lambda>m. pyf) matur \<in> borel_measurable N"
       using \<open>discounted_value r (\<lambda>m. pyf) matur \<in> borel_measurable N\<close> .
   qed
   have "martingale N F (discounted_value r (cls_val_process Mkt pf))" using assms unfolding replicating_portfolio_def
     using self_fin_trad_strat_mart[of N pf] by (simp add: stock_portfolio_def)
   hence "AEeq N (real_cond_exp N (F 0) (discounted_value r (cls_val_process Mkt pf) matur))
     (discounted_value r (cls_val_process Mkt pf) 0)" using martingaleAE[of N F "discounted_value r (cls_val_process Mkt pf)" 0 matur]
     fn by simp
   also have "AE w in N. (discounted_value r (cls_val_process Mkt pf) 0 w) = initial_value pf"
   proof
     fix w
     assume "w\<in> space N"
     have "discounted_value r (cls_val_process Mkt pf) 0 w = cls_val_process Mkt pf 0 w" by (simp add:discounted_init)
     also have "... = val_process Mkt pf 0 w" unfolding cls_val_process_def using assms
       unfolding replicating_portfolio_def stock_portfolio_def by simp
     also have "... = initial_value pf" using assms unfolding replicating_portfolio_def using \<open>w\<in> space N\<close>
       by (metis (no_types, lifting) support_adapt_def filt_equiv_space initial_valueI readable stock_portfolio_def subsetCE)
     finally show "discounted_value r (cls_val_process Mkt pf) 0 w = initial_value pf" .
   qed
   finally have "AE w in N. (real_cond_exp N (F 0) (discounted_value r (cls_val_process Mkt pf) matur)) w =
     initial_value pf" .
   moreover have "\<forall>w\<in> space N. (real_cond_exp N (F 0) (discounted_value r (cls_val_process Mkt pf) matur)) w =
     prob_space.expectation N (discounted_value r (cls_val_process Mkt pf) matur)"
   proof (rule prob_space.trivial_subalg_cond_expect_eq)
     show "prob_space N" using assms unfolding risk_neutral_prob_def by simp
     show "subalgebra N (F 0)"
       using \<open>prob_space N\<close> filtrated_prob_space.filtration fn filtrationE1 by blast
     show "sets (F 0) = {{}, space N}" using assms by (simp add:filt_equiv_space)
     show "integrable N (discounted_value r (cls_val_process Mkt pf) matur)"
     proof (rule discounted_integrable)
       show "space N = space M" using assms by (simp add:filt_equiv_space)
       show "integrable N (cls_val_process Mkt pf matur)" using assms unfolding replicating_portfolio_def
         by (simp add: integrable_self_fin_uvp)
       show "-1 < r" using acceptable_rate by simp
     qed
   qed
   ultimately have "AE w in N. prob_space.expectation N (discounted_value r (cls_val_process Mkt pf) matur) =
      initial_value pf" by simp
   hence "prob_space.expectation N (discounted_value r (cls_val_process Mkt pf) matur) =
     initial_value pf" using assms unfolding risk_neutral_prob_def using  prob_space.emeasure_space_1[of N]
     AE_eq_cst[of _ _ N] by simp
   moreover have "prob_space.expectation N (discounted_value r (cls_val_process Mkt pf) matur) =
     prob_space.expectation N (discounted_value r (\<lambda>m. pyf) matur)"
   proof (rule integral_cong_AE)
     show "AEeq N (discounted_value r (cls_val_process Mkt pf) matur) (discounted_value r (\<lambda>m. pyf) matur)"
       using disc by simp
     show "discounted_value r (\<lambda>m. pyf) matur \<in> borel_measurable N"
       using \<open>discounted_value r (\<lambda>m. pyf) matur \<in> borel_measurable N\<close> .
     show "discounted_value r (cls_val_process Mkt pf) matur \<in> borel_measurable N"
       using \<open>discounted_value r (cls_val_process Mkt pf) matur \<in> borel_measurable N\<close> .
   qed
   ultimately have "prob_space.expectation N (discounted_value r (\<lambda>m. pyf) matur) = initial_value pf" by simp
   thus ?thesis using assms
     by (metis (full_types) support_adapt_def disc_equity_market.replicating_portfolio_def disc_equity_market_axioms
         readable replicating_fair_price stock_portfolio_def subsetCE)
 qed
 
 
 lemma (in rfr_disc_equity_market) replicating_expectation_finite:
   assumes "risk_neutral_prob N"
   and "filt_equiv F M N"
   and "replicating_portfolio pf pyf matur"
   and "\<forall>n. \<forall> asset \<in> support_set pf. finite (prices Mkt asset n `(space M))"
   and "\<forall>n. \<forall> asset \<in> support_set pf. finite (pf asset n `(space M))"
   and "viable_market Mkt"
   and "sets (F 0) = {{}, space M}"
   and "pyf  \<in> borel_measurable (F matur)"
 shows "fair_price Mkt (prob_space.expectation N (discounted_value r (\<lambda>m. pyf) matur)) pyf matur"
 proof -
   have  "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset n w * pf asset (Suc n) w)"
   proof (rule finite_integrable_vp, (auto simp add:assms))
     show "prob_space N" using assms unfolding risk_neutral_prob_def by simp
     show "trading_strategy pf" using assms unfolding replicating_portfolio_def by simp
     show "\<And>n asset. asset \<in> support_set pf \<Longrightarrow> random_variable borel (prices Mkt asset n)"
     proof-
       fix n
       fix asset
       assume "asset \<in> support_set pf"
       show "random_variable borel (prices Mkt asset n)"
         using assms unfolding replicating_portfolio_def stock_portfolio_def  adapt_stoch_proc_def using readable
         by (meson \<open>asset \<in> support_set pf\<close> adapt_stoch_proc_borel_measurable subsetCE)
     qed
   qed
   moreover have "\<forall>n. \<forall> asset \<in> support_set pf. integrable N (\<lambda>w. prices Mkt asset (Suc n) w * pf asset (Suc n) w)"
   proof (rule finite_integrable_uvp, (auto simp add:assms))
     show "prob_space N" using assms unfolding risk_neutral_prob_def by simp
     show "trading_strategy pf" using assms unfolding replicating_portfolio_def by simp
     show "\<And>n asset. asset \<in> support_set pf \<Longrightarrow> random_variable borel (prices Mkt asset n)"
     proof-
       fix n
       fix asset
       assume "asset \<in> support_set pf"
       show "random_variable borel (prices Mkt asset n)"
         using assms unfolding replicating_portfolio_def stock_portfolio_def  adapt_stoch_proc_def using readable
         by (meson \<open>asset \<in> support_set pf\<close> adapt_stoch_proc_borel_measurable subsetCE)
     qed
   qed
   ultimately show ?thesis using assms replicating_expectation by simp
 qed
 
 
 
 end
\ No newline at end of file
diff --git a/thys/Ergodic_Theory/Kingman.thy b/thys/Ergodic_Theory/Kingman.thy
--- a/thys/Ergodic_Theory/Kingman.thy
+++ b/thys/Ergodic_Theory/Kingman.thy
@@ -1,2121 +1,2121 @@
 (*  Author:  Sébastien Gouëzel   sebastien.gouezel@univ-rennes1.fr
     License: BSD
 *)
 
 section \<open>Subcocycles, subadditive ergodic theory\<close>
 
 theory Kingman
   imports Ergodicity Fekete
 begin
 
 text \<open>Subadditive ergodic theory is the branch of ergodic theory devoted
 to the study of subadditive cocycles (named subcocycles in what follows), i.e.,
 functions such that $u(n+m, x) \leq u(n, x) + u(m, T^n x)$ for all $x$ and $m,n$.
 
 For instance, Birkhoff sums are examples of such subadditive cocycles (in fact, they are
 additive), but more interesting examples are genuinely subadditive. The main result
 of the theory is Kingman's theorem, asserting the almost sure convergence of
 $u_n / n$ (this is a generalization of Birkhoff theorem). If the asymptotic average
 $\lim \int u_n / n$ (which exists by subadditivity and Fekete lemma) is not $-\infty$,
 then the convergence takes also place in $L^1$. We prove all this below.
 \<close>
 
 context mpt
 begin
 
 subsection \<open>Definition and basic properties\<close>
 
 definition subcocycle::"(nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> bool"
   where "subcocycle u = ((\<forall>n. integrable M (u n)) \<and> (\<forall>n m x. u (n+m) x \<le> u n x + u m ((T^^n) x)))"
 
 lemma subcocycle_ineq:
   assumes "subcocycle u"
   shows "u (n+m) x \<le> u n x + u m ((T^^n) x)"
 using assms unfolding subcocycle_def by blast
 
 lemma subcocycle_0_nonneg:
   assumes "subcocycle u"
   shows "u 0 x \<ge> 0"
 proof -
   have "u (0+0) x \<le> u 0 x + u 0 ((T^^0) x)"
     using assms unfolding subcocycle_def by blast
   then show ?thesis by auto
 qed
 
 lemma subcocycle_integrable:
   assumes "subcocycle u"
   shows "integrable M (u n)"
         "u n \<in> borel_measurable M"
 using assms unfolding subcocycle_def by auto
 
 lemma subcocycle_birkhoff:
   assumes "integrable M f"
   shows "subcocycle (birkhoff_sum f)"
 unfolding subcocycle_def by (auto simp add: assms birkhoff_sum_integral(1) birkhoff_sum_cocycle)
 
 text \<open>The set of subcocycles is stable under addition, multiplication by positive numbers,
 and $\max$.\<close>
 
 lemma subcocycle_add:
   assumes "subcocycle u" "subcocycle v"
   shows "subcocycle (\<lambda>n x. u n x + v n x)"
 unfolding subcocycle_def
 proof (auto)
   fix n
   show "integrable M (\<lambda>x. u n x + v n x)" using assms unfolding subcocycle_def by simp
 next
   fix n m x
   have "u (n+m) x \<le> u n x + u m ((T ^^ n) x)" using assms(1) subcocycle_def by simp
   moreover have "v (n+m) x \<le> v n x + v m ((T ^^ n) x)" using assms(2) subcocycle_def by simp
   ultimately show "u (n + m) x + v (n + m) x \<le> u n x + v n x + (u m ((T ^^ n) x) + v m ((T ^^ n) x))"
     by simp
 qed
 
 lemma subcocycle_cmult:
   assumes "subcocycle u" "c \<ge> 0"
   shows "subcocycle (\<lambda>n x. c * u n x)"
 using assms unfolding subcocycle_def by (auto, metis distrib_left mult_left_mono)
 
 lemma subcocycle_max:
   assumes "subcocycle u" "subcocycle v"
   shows "subcocycle (\<lambda>n x. max (u n x) (v n x))"
 unfolding subcocycle_def proof (auto)
   fix n
   show "integrable M (\<lambda>x. max (u n x) (v n x))" using assms unfolding subcocycle_def by auto
 next
   fix n m x
   have "u (n+m) x \<le> u n x + u m ((T^^n) x)" using assms(1) unfolding subcocycle_def by auto
   then show "u (n + m) x \<le> max (u n x) (v n x) + max (u m ((T ^^ n) x)) (v m ((T ^^ n) x))"
     by simp
 next
   fix n m x
   have "v (n+m) x \<le> v n x + v m ((T^^n) x)" using assms(2) unfolding subcocycle_def by auto
   then show "v (n + m) x \<le> max (u n x) (v n x) + max (u m ((T ^^ n) x)) (v m ((T ^^ n) x))"
     by simp
 qed
 
 text \<open>Applying inductively the subcocycle equation, it follows that a subcocycle is bounded
 by the Birkhoff sum of the subcocycle at time $1$.\<close>
 
 lemma subcocycle_bounded_by_birkhoff1:
   assumes "subcocycle u" "n > 0"
   shows "u n x \<le> birkhoff_sum (u 1) n x"
 using \<open>n > 0\<close> proof (induction rule: ind_from_1)
   case 1
   show ?case by auto
 next
   case (Suc p)
   have "u (Suc p) x \<le> u p x + u 1 ((T^^p)x)" using assms(1) subcocycle_def by (metis Suc_eq_plus1)
   then show ?case using Suc birkhoff_sum_cocycle[where ?n = p and ?m = 1] \<open> p>0 \<close> by (simp add: birkhoff_sum_def)
 qed
 
 text \<open>It is often important to bound a cocycle $u_n(x)$ by the Birkhoff sums of $u_N/N$. Compared
 to the trivial upper bound for $u_1$, there are additional boundary errors that make the
 estimate more cumbersome (but these terms only come from a $N$-neighborhood of $0$ and $n$, so
 they are negligible if $N$ is fixed and $n$ tends to infinity.\<close>
 
 lemma subcocycle_bounded_by_birkhoffN:
   assumes "subcocycle u" "n > 2*N" "N>0"
   shows "u n x \<le> birkhoff_sum (\<lambda>x. u N x / real N) (n - 2 * N) x
                 + (\<Sum>i<N. \<bar>u 1 ((T ^^ i) x)\<bar>)
                 + 2 * (\<Sum>i<2*N. \<bar>u 1 ((T ^^ (n - (2 * N - i))) x)\<bar>)"
 proof -
   have Iar: "u (a*N+r) x \<le> u r x + (\<Sum>i<a. u N ((T^^(i * N + r))x))" for r a
   proof (induction a)
     case 0
     then show ?case by auto
   next
     case (Suc a)
     have "u ((a+1)*N+r) x = u((a*N+r) + N) x"
       by (simp add: semiring_normalization_rules(2) semiring_normalization_rules(23))
     also have "... \<le> u(a*N+r) x + u N ((T^^(a*N+r))x)"
       using assms(1) unfolding subcocycle_def by auto
     also have "... \<le> u r x + (\<Sum>i<a. u N ((T^^(i * N + r))x)) + u N ((T^^(a*N+r))x)"
       using Suc.IH by auto
     also have "... = u r x + (\<Sum>i<a+1. u N ((T^^(i * N + r))x))"
       by auto
     finally show ?case by auto
   qed
 
   have Ia: "u (a*N) x \<le> (\<Sum>i<a. u N ((T^^(i * N))x))" if "a>0" for a
   using that proof (induction rule: ind_from_1)
     case 1
     show ?case by auto
   next
     case (Suc a)
     have "u ((a+1)*N) x = u((a*N) + N) x"
       by (simp add: semiring_normalization_rules(2) semiring_normalization_rules(23))
     also have "... \<le> u(a*N) x + u N ((T^^(a*N))x)"
       using assms(1) unfolding subcocycle_def by auto
     also have "... \<le> (\<Sum>i<a. u N ((T^^(i * N))x)) + u N ((T^^(a*N))x)"
       using Suc by auto
     also have "... = (\<Sum>i<a+1. u N ((T^^(i * N))x))"
       by auto
     finally show ?case by auto
   qed
 
   define E1 where "E1 = (\<Sum>i<N. abs(u 1 ((T^^i)x)))"
   define E2 where "E2 = (\<Sum>i<2*N. abs(u 1 ((T^^(n-(2*N-i))) x)))"
   have "E2 \<ge> 0" unfolding E2_def by auto
 
   obtain a0 s0 where 0: "s0 < N" "n = a0 * N + s0"
     using \<open>0 < N\<close> mod_div_decomp mod_less_divisor by blast
   then have "a0 \<ge> 1" using \<open>n > 2 * N\<close> \<open>N>0\<close>
     by (metis Nat.add_0_right add.commute add_lessD1 add_mult_distrib comm_monoid_mult_class.mult_1 eq_imp_le
     less_imp_add_positive less_imp_le_nat less_one linorder_neqE_nat mult.left_neutral mult_not_zero not_add_less1 one_add_one)
   define a s where "a = a0-1" and "s = s0+N"
   then have as: "n = a * N + s" unfolding a_def s_def using \<open>a0 \<ge> 1\<close> 0 by (simp add: mult_eq_if)
   have s: "s \<ge> N" "s < 2*N" using 0 unfolding s_def by auto
   have a: "a*N > n - 2*N" "a*N \<le> n - N" using as s \<open>n > 2*N\<close> by auto
   then have "(a*N - (n-2*N)) \<le> N" using \<open>n > 2*N\<close> by auto
   have "a*N \<ge> n - 2*N" using a by simp
 
   {
     fix r::nat assume "r < N"
     have "a*N+r > n - 2*N" using \<open>n>2*N\<close> as s by auto
 
     define tr where "tr = n-(a*N+r)"
     have "tr > 0" unfolding tr_def using as s \<open>r<N\<close> by auto
     then have *: "n = (a*N+r) + tr" unfolding tr_def by auto
 
     have "birkhoff_sum (u 1) tr ((T^^(a*N+r))x) = (\<Sum>i<tr. u 1 ((T^^(a*N+r+i))x))"
       unfolding birkhoff_sum_def by (simp add: add.commute funpow_add)
     also have "... = (\<Sum>i\<in>{a*N+r..<a*N+r+tr}. u 1 ((T^^i) x))"
       by (rule sum.reindex_bij_betw, rule bij_betw_byWitness[where ?f' = "\<lambda>i. i - (a * N + r)"], auto)
     also have "... \<le> (\<Sum>i\<in>{a*N+r..<a*N+r+tr}. abs(u 1 ((T^^i) x)))"
       by (simp add: sum_mono)
     also have "... \<le> (\<Sum>i\<in>{n-2*N..<n}. abs(u 1 ((T^^i) x)))"
       apply (rule sum_mono2) using as s \<open>r<N\<close> tr_def by auto
     also have "... = E2" unfolding E2_def
       apply (rule sum.reindex_bij_betw[symmetric], rule bij_betw_byWitness[where ?f' = "\<lambda>i. i - (n-2*N)"])
       using \<open>n > 2*N\<close> by auto
     finally have A: "birkhoff_sum (u 1) tr ((T^^(a*N+r))x) \<le> E2" by simp
 
     have "u n x \<le> u (a*N+r) x + u tr ((T^^(a*N+r))x)"
       using assms(1) * unfolding subcocycle_def by auto
     also have "... \<le> u (a*N+r) x + birkhoff_sum (u 1) tr ((T^^(a*N+r))x)"
       using subcocycle_bounded_by_birkhoff1[OF assms(1)] \<open>tr > 0\<close> by auto
     finally have B: "u n x \<le> u (a*N+r) x + E2"
       using A by auto
 
     have "u (a*N+r) x \<le> (\<Sum>i<N. abs(u 1 ((T^^i)x))) + (\<Sum>i<a. u N ((T^^(i*N+r))x))"
     proof (cases "r = 0")
       case True
       then have "a>0" using \<open>a*N+r > n - 2*N\<close> not_less by fastforce
       have "u(a*N+r) x \<le> (\<Sum>i<a. u N ((T^^(i*N+r))x))" using Ia[OF \<open>a>0\<close>] True by auto
       moreover have "0 \<le> (\<Sum>i<N. abs(u 1 ((T^^i)x)))" by auto
       ultimately show ?thesis by linarith
     next
       case False
       then have I: "u (a*N+r) x \<le> u r x + (\<Sum>i<a. u N ((T^^(i * N + r))x))" using Iar by auto
       have "u r x \<le> (\<Sum>i<r. u 1 ((T^^i)x))"
         using subcocycle_bounded_by_birkhoff1[OF assms(1)] False unfolding birkhoff_sum_def by auto
       also have "... \<le> (\<Sum>i<r. abs(u 1 ((T^^i)x)))"
         by (simp add: sum_mono)
       also have "... \<le> (\<Sum>i<N. abs(u 1 ((T^^i)x)))"
         apply (rule sum_mono2) using \<open>r<N\<close> by auto
       finally show ?thesis using I by auto
     qed
     then have "u n x \<le> E1 + (\<Sum>i<a. u N ((T^^(i*N+r))x)) + E2"
       unfolding E1_def using B by auto
   } note * = this
 
   have I: "u N ((T^^j) x) \<le> E2" if "j\<in>{n-2*N..<a*N}" for j
   proof -
     have "u N ((T^^j) x) \<le> (\<Sum>i<N. u 1 ((T^^i) ((T^^j)x)))"
       using subcocycle_bounded_by_birkhoff1[OF assms(1) \<open>N>0\<close>] unfolding birkhoff_sum_def by auto
     also have "... = (\<Sum>i<N. u 1 ((T^^(i+j))x))" by (simp add: funpow_add)
     also have "... \<le> (\<Sum>i<N. abs(u 1 ((T^^(i+j))x)))" by (rule sum_mono, auto)
     also have "... = (\<Sum>k\<in>{j..<N+j}. abs(u 1 ((T^^k)x)))"
       by (rule sum.reindex_bij_betw, rule bij_betw_byWitness[where ?f' = "\<lambda>k. k-j"], auto)
     also have "... \<le> (\<Sum>i\<in>{n-2*N..<n}. abs(u 1 ((T^^i) x)))"
       apply (rule sum_mono2) using \<open>j\<in>{n-2*N..<a*N}\<close> \<open>a*N \<le> n - N\<close> by auto
     also have "... = E2" unfolding E2_def
       apply (rule sum.reindex_bij_betw[symmetric], rule bij_betw_byWitness[where ?f' = "\<lambda>i. i - (n-2*N)"])
       using \<open>n > 2*N\<close> by auto
     finally show ?thesis by auto
   qed
   have "(\<Sum>j<a*N. u N ((T^^j) x)) - (\<Sum>j<n-2*N. u N ((T^^j) x)) = (\<Sum>j\<in>{n-2*N..<a*N}. u N ((T^^j) x))"
     using sum.atLeastLessThan_concat[OF _ \<open>a*N \<ge> n - 2*N\<close>, of 0 "\<lambda>j. u N ((T^^j) x)", symmetric] atLeast0LessThan by simp
   also have "... \<le> (\<Sum>j\<in>{n-2*N..<a*N}. E2)" by (rule sum_mono[OF I])
   also have "... = (a*N - (n-2*N)) * E2" by simp
   also have "... \<le> N * E2" using \<open>(a*N - (n-2*N)) \<le> N\<close> \<open>E2 \<ge> 0\<close> by (simp add: mult_right_mono)
   finally have J: "(\<Sum>j<a*N. u N ((T^^j) x)) \<le> (\<Sum>j<n-2*N. u N ((T^^j) x)) + N * E2" by auto
 
   have "N * u n x = (\<Sum>r<N. u n x)" by auto
   also have "... \<le> (\<Sum>r<N. E1 + E2 + (\<Sum>i<a. u N ((T^^(i*N+r))x)))"
     apply (rule sum_mono) using * by fastforce
   also have "... = (\<Sum>r<N. E1 + E2) + (\<Sum>r<N. (\<Sum>i<a. u N ((T^^(i*N+r))x)))"
     by (rule sum.distrib)
   also have "... = N* (E1 + E2) + (\<Sum>j<a*N. u N ((T^^j) x))"
     using sum_arith_progression by auto
   also have "... \<le> N *(E1+E2) + (\<Sum>j<n-2*N. u N ((T^^j) x)) + N*E2"
     using J by auto
   also have "... = N * (E1+E2) + N * (\<Sum>j<n-2*N. u N ((T^^j) x) / N) + N * E2"
     using \<open>N>0\<close> by (simp add: sum_distrib_left)
   also have "... = N*(E1 + E2 + (\<Sum>j<n-2*N. u N ((T^^j) x) / N) + E2)"
     by (simp add: distrib_left)
   finally have "u n x \<le> E1 + 2*E2 + birkhoff_sum (\<lambda>x. u N x / N) (n-2*N) x"
     unfolding birkhoff_sum_def using \<open>N>0\<close> by auto
   then show ?thesis unfolding E1_def E2_def by auto
 qed
 
 text \<open>Many natural cocycles are only defined almost everywhere, and then the
 subadditivity property only makes sense almost everywhere. We will now show
 that such an a.e.-subcocycle coincides almost everywhere with a genuine subcocycle
 in the above sense. Then, all the results for subcocycles will apply to such
 a.e.-subcocycles. (Usually, in ergodic theory, subcocycles only satisfy the subadditivity
 property almost everywhere, but we have requested it everywhere for simplicity in the proofs.)
 
 The subcocycle will be defined in a recursive way. This means that is can not be defined in a
 proof (since complicated function definitions are not available inside proofs). Since it is
 defined in terms of $u$, then $u$ has to be available at the top level, which is most
 conveniently done using a context.
 \<close>
 context
   fixes u::"nat \<Rightarrow> 'a \<Rightarrow> real"
   assumes H: "\<And>m n. AE x in M. u (n+m) x \<le> u n x + u m ((T^^n) x)"
           "\<And>n. integrable M (u n)"
 begin
 
 private fun v :: "nat \<Rightarrow> 'a \<Rightarrow> real" where "v n x = (
   if n = 0 then max (u 0 x) 0
   else if n = 1 then u 1 x
   else min (u n x) (Min ((\<lambda>k. v k x + v (n-k) ((T^^k) x))`{0<..<n})))"
 
 private lemma v0 [simp]:
   \<open>v 0 x = max (u 0 x) 0\<close>
   by simp
 
 private lemma v1 [simp]:
   \<open>v (Suc 0) x = u 1 x\<close>
   by simp
 
 private lemma v2 [simp]:
   \<open>v n x = min (u n x) (Min ((\<lambda>k. v k x + v (n-k) ((T^^k) x))`{0<..<n}))\<close> if \<open>n \<ge> 2\<close>
   using that by (subst v.simps) (simp del: v.simps)
 
 declare v.simps [simp del]
 
 private lemma integrable_v:
   "integrable M (v n)" for n
 proof (induction n rule: nat_less_induct)
   case (1 n)
   consider "n = 0" | "n = 1" | "n>1" by linarith
   then show ?case
   proof (cases)
     assume "n = 0"
     have "v 0 x = max (u 0 x) 0" for x by simp
     then show ?thesis using integrable_max[OF H(2)[of 0]] \<open>n = 0\<close> by auto
   next
     assume "n = 1"
     have "v 1 x = u 1 x" for x by simp
     then show ?thesis using H(2)[of 1] \<open>n = 1\<close> by auto
   next
     assume "n > 1"
     hence "v n x = min (u n x) (MIN k \<in> {0<..<n}. v k x + v (n-k) ((T^^k) x))" for x
       by simp
     moreover have "integrable M (\<lambda>x. min (u n x) (MIN k \<in> {0<..<n}. v k x + v (n-k) ((T^^k) x)))"
       apply (rule integrable_min)
       apply (simp add: H(2))
       apply (rule integrable_MIN, simp)
       using \<open>n >1\<close> apply auto[1]
       apply (rule Bochner_Integration.integrable_add)
       using "1.IH" apply auto[1]
       apply (rule Tn_integral_preserving(1))
       using "1.IH" by (metis \<open>1 < n\<close> diff_less greaterThanLessThan_iff max_0_1(2) max_less_iff_conj)
     ultimately show ?case by auto
   qed
 qed
 
 private lemma u_eq_v_AE:
   "AE x in M. v n x = u n x" for n
 proof (induction n rule: nat_less_induct)
   case (1 n)
   consider "n = 0" | "n = 1" | "n>1" by linarith
   then show ?case
   proof (cases)
     assume "n = 0"
     have "AE x in M. u 0 x \<le> u 0 x + u 0 x" using H(1)[of 0 0] by auto
     then have "AE x in M. u 0 x \<ge> 0" by auto
     moreover have "v 0 x = max (u 0 x) 0" for x by simp
     ultimately show ?thesis using \<open>n = 0\<close> by auto
   next
     assume "n = 1"
     have "v 1 x = u 1 x" for x by simp
     then show ?thesis using \<open>n = 1\<close> by simp
   next
     assume "n > 1"
     {
       fix k assume "k<n"
       then have "AE x in M. v k x = u k x" using "1.IH" by simp
       with T_AE_iterates[OF this] have "AE x in M. \<forall>s. v k ((T^^s) x) = u k ((T^^s) x)" by simp
     } note * = this
     have "AE x in M. \<forall>k \<in> {..<n}. \<forall>s. v k ((T^^s) x) = u k ((T^^s) x)"
       apply (rule AE_finite_allI) using * by simp_all
     moreover have "AE x in M. \<forall>i j. u (i+j) x \<le> u i x + u j ((T^^i) x)"
       apply (subst AE_all_countable, intro allI)+ using H(1) by simp
     moreover
     {
       fix x assume "\<forall>k \<in> {..<n}. \<forall>s. v k ((T^^s) x) = u k ((T^^s) x)"
                    "\<forall>i j. u (i+j) x \<le> u i x + u j ((T^^i) x)"
       then have Hx: "\<And>k s. k < n \<Longrightarrow> v k ((T^^s) x) = u k ((T^^s) x)"
                     "\<And>i j. u (i+j) x \<le> u i x + u j ((T^^i) x)"
         by auto
       {
         fix k assume "k \<in> {0<..<n}"
         then have K: "k<n" "n-k<n" by auto
         have "u n x \<le> u k x + u (n-k) ((T^^k) x)" using Hx(2) K by (metis le_add_diff_inverse less_imp_le_nat)
         also have "... = v k x + v (n-k) ((T^^k)x)" using Hx(1)[OF \<open>k <n\<close>, of 0] Hx(1)[OF \<open>n-k <n\<close>, of k] by auto
         finally have "u n x \<le> v k x + v (n-k) ((T^^k)x)" by simp
       }
       then have *: "\<And>z. z \<in> (\<lambda>k. v k x + v (n-k) ((T^^k) x))`{0<..<n} \<Longrightarrow> u n x \<le> z" by blast
       have "u n x \<le> Min ((\<lambda>k. v k x + v (n-k) ((T^^k) x))`{0<..<n})"
         apply (rule Min.boundedI) using \<open>n>1\<close> * by auto
       moreover have "v n x = min (u n x) (Min ((\<lambda>k. v k x + v (n-k) ((T^^k) x))`{0<..<n}))"
         using \<open>1<n\<close> by auto
       ultimately have "v n x = u n x" by auto
     }
     ultimately show ?thesis by auto
   qed
 qed
 
 private lemma subcocycle_v:
   "v (n+m) x \<le> v n x + v m ((T^^n) x)"
 proof -
   consider "n = 0" | "m = 0" | "n>0 \<and> m >0" by auto
   then show ?thesis
   proof (cases)
     case 1
     then have "v n x \<ge> 0" by simp
     then show ?thesis using \<open>n = 0\<close> by auto
   next
     case 2
     then have "v m x \<ge> 0" by simp
     then show ?thesis using \<open>m = 0\<close> by auto
   next
     case 3
     then have "n+m > 1" by simp
     then have "v (n+m) x = min (u(n+m) x) (Min ((\<lambda>k. v k x + v ((n+m)-k) ((T^^k) x))`{0<..<n+m}))" by simp
     also have "... \<le> Min ((\<lambda>k. v k x + v ((n+m)-k) ((T^^k) x))`{0<..<n+m})" by simp
     also have "... \<le> v n x + v ((n+m)-n) ((T^^n) x)"
       apply (rule Min_le, simp)
       by (metis (lifting) \<open>0 < n \<and> 0 < m\<close> add.commute greaterThanLessThan_iff image_iff less_add_same_cancel2)
     finally show ?thesis by simp
   qed
 qed
 
 lemma subcocycle_AE_in_context:
   "\<exists>w. subcocycle w \<and> (AE x in M. \<forall>n. w n x = u n x)"
 proof -
   have "subcocycle v" using subcocycle_v integrable_v unfolding subcocycle_def by auto
   moreover have "AE x in M. \<forall>n. v n x = u n x"
     by (subst AE_all_countable, intro allI, rule u_eq_v_AE)
   ultimately show ?thesis by blast
 qed
 
 end
 
 lemma subcocycle_AE:
   fixes u::"nat \<Rightarrow> 'a \<Rightarrow> real"
   assumes "\<And>m n. AE x in M. u (n+m) x \<le> u n x + u m ((T^^n) x)"
           "\<And>n. integrable M (u n)"
   shows "\<exists>w. subcocycle w \<and> (AE x in M. \<forall>n. w n x = u n x)"
 using subcocycle_AE_in_context assms by blast
 
 
 subsection \<open>The asymptotic average\<close>
 
 text \<open>In this subsection, we define the asymptotic average of a subcocycle $u$, i.e., the
 limit of $\int u_n(x)/n$ (the convergence follows from subadditivity of $\int u_n$) and study its
 basic properties, especially in terms of operations on subcocycles. In general, it can be
 $-\infty$, so we define it in the extended reals.\<close>
 
 definition subcocycle_avg_ereal::"(nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> ereal" where
   "subcocycle_avg_ereal u = Inf {ereal((\<integral>x. u n x \<partial>M) / n) |n. n > 0}"
 
 lemma subcocycle_avg_finite:
   "subcocycle_avg_ereal u < \<infinity>"
 unfolding subcocycle_avg_ereal_def using Inf_less_iff less_ereal.simps(4) by blast
 
 lemma subcocycle_avg_subadditive:
   assumes "subcocycle u"
   shows "subadditive (\<lambda>n. (\<integral>x. u n x \<partial>M))"
 unfolding subadditive_def proof (intro allI)
   have int_u [measurable]: "\<And>n. integrable M (u n)" using assms unfolding subcocycle_def by auto
   fix m n
   have "(\<integral>x. u (n+m) x \<partial>M) \<le> (\<integral>x. u n x + u m ((T^^n) x) \<partial>M)"
     apply (rule integral_mono)
     using int_u apply (auto simp add: Tn_integral_preserving(1))
     using assms unfolding subcocycle_def by auto
   also have "... \<le> (\<integral>x. u n x \<partial>M) + (\<integral>x. u m ((T^^n) x) \<partial>M)"
     using int_u by (auto simp add: Tn_integral_preserving(1))
   also have "... = (\<integral>x. u n x \<partial>M) + (\<integral>x. u m x \<partial>M)"
     using int_u by (auto simp add: Tn_integral_preserving(2))
   finally show "(\<integral>x. u (n+m) x \<partial>M) \<le> (\<integral>x. u n x \<partial>M) + (\<integral>x. u m x \<partial>M)" by simp
 qed
 
 lemma subcocycle_int_tendsto_avg_ereal:
   assumes "subcocycle u"
   shows "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal u"
 unfolding subcocycle_avg_ereal_def
 using subadditive_converges_ereal[OF subcocycle_avg_subadditive[OF assms]] by auto
 
 text \<open>The average behaves well under addition, scalar multiplication and max, trivially.\<close>
 
 lemma subcocycle_avg_ereal_add:
   assumes "subcocycle u" "subcocycle v"
   shows "subcocycle_avg_ereal (\<lambda>n x. u n x + v n x) = subcocycle_avg_ereal u + subcocycle_avg_ereal v"
 proof -
   have int [simp]: "\<And>n. integrable M (u n)" "\<And>n. integrable M (v n)" using assms unfolding subcocycle_def by auto
   {
     fix n
     have "(\<integral>x. u n x / n \<partial>M) + (\<integral>x. v n x / n \<partial>M) = (\<integral>x. u n x / n + v n x / n \<partial>M)"
       by (rule Bochner_Integration.integral_add[symmetric], auto)
     also have "... = (\<integral>x. (u n x + v n x) / n \<partial>M)"
       by (rule Bochner_Integration.integral_cong, auto simp add: add_divide_distrib)
     finally have "ereal (\<integral>x. u n x / n \<partial>M) + (\<integral>x. v n x / n \<partial>M) = (\<integral>x. (u n x + v n x) / n \<partial>M)"
       by auto
   }
   moreover have "(\<lambda>n. ereal (\<integral>x. u n x / n \<partial>M) + (\<integral>x. v n x / n \<partial>M))
                   \<longlonglongrightarrow> subcocycle_avg_ereal u + subcocycle_avg_ereal v"
     apply (intro tendsto_intros subcocycle_int_tendsto_avg_ereal[OF assms(1)] subcocycle_int_tendsto_avg_ereal[OF assms(2)])
     using subcocycle_avg_finite by auto
   ultimately have "(\<lambda>n. (\<integral>x. (u n x + v n x) / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal u + subcocycle_avg_ereal v"
     by auto
   moreover have "(\<lambda>n. (\<integral>x. (u n x + v n x) / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal (\<lambda>n x. u n x + v n x)"
     by (rule subcocycle_int_tendsto_avg_ereal[OF subcocycle_add[OF assms]])
   ultimately show ?thesis using LIMSEQ_unique by blast
 qed
 
 lemma subcocycle_avg_ereal_cmult:
   assumes "subcocycle u" "c \<ge> (0::real)"
   shows "subcocycle_avg_ereal (\<lambda>n x. c * u n x) = c * subcocycle_avg_ereal u"
 proof (cases "c = 0")
   case True
   have *: "ereal (\<integral>x. (c * u n x) / n \<partial>M) = 0" if "n>0" for n
     by (subst True, auto)
   have "(\<lambda>n. ereal (\<integral>x. (c * u n x) / n \<partial>M)) \<longlonglongrightarrow> 0"
     by (subst lim_explicit, metis * less_le_trans zero_less_one)
   moreover have "(\<lambda>n. ereal (\<integral>x. (c * u n x) / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal (\<lambda>n x. c * u n x)"
     using subcocycle_int_tendsto_avg_ereal[OF subcocycle_cmult[OF assms]] by auto
   ultimately have "subcocycle_avg_ereal (\<lambda>n x. c * u n x) = 0"
     using LIMSEQ_unique by blast
   then show ?thesis using True by auto
 next
   case False
   have int: "\<And>n. integrable M (u n)" using assms unfolding subcocycle_def by auto
   have "ereal (\<integral>x. c * u n x / n \<partial>M) = c * ereal (\<integral>x. u n x / n \<partial>M)" for n by auto
   then have "(\<lambda>n. c * ereal (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal (\<lambda>n x. c * u n x)"
     using subcocycle_int_tendsto_avg_ereal[OF subcocycle_cmult[OF assms]] by auto
   moreover have "(\<lambda>n. c * ereal (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> c * subcocycle_avg_ereal u"
     apply (rule tendsto_mult_ereal) using False subcocycle_int_tendsto_avg_ereal[OF assms(1)] by auto
   ultimately show ?thesis using LIMSEQ_unique by blast
 qed
 
 lemma subcocycle_avg_ereal_max:
   assumes "subcocycle u" "subcocycle v"
   shows "subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x)) \<ge> max (subcocycle_avg_ereal u) (subcocycle_avg_ereal v)"
 proof (auto)
   have int: "integrable M (u n)" "integrable M (v n)" for n using assms unfolding subcocycle_def by auto
   have int2: "integrable M (\<lambda>x. max (u n x) (v n x))" for n using integrable_max int by auto
 
   have "(\<integral>x. u n x / n \<partial>M) \<le> (\<integral>x. max (u n x) (v n x) / n \<partial>M)" for n
     apply (rule integral_mono) using int int2 by (auto simp add: divide_simps)
   then show "subcocycle_avg_ereal u \<le> subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x))"
     using LIMSEQ_le[OF subcocycle_int_tendsto_avg_ereal[OF assms(1)]
           subcocycle_int_tendsto_avg_ereal[OF subcocycle_max[OF assms]]] by auto
 
   have "(\<integral>x. v n x / n \<partial>M) \<le> (\<integral>x. max (u n x) (v n x) / n \<partial>M)" for n
     apply (rule integral_mono) using int int2 by (auto simp add: divide_simps)
   then show "subcocycle_avg_ereal v \<le> subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x))"
     using LIMSEQ_le[OF subcocycle_int_tendsto_avg_ereal[OF assms(2)]
           subcocycle_int_tendsto_avg_ereal[OF subcocycle_max[OF assms]]] by auto
 qed
 
 text \<open>For a Birkhoff sum, the average at each time is the same, equal to the average of the
 function, so the asymptotic average is also equal to this common value.\<close>
 
 lemma subcocycle_avg_ereal_birkhoff:
   assumes "integrable M u"
   shows "subcocycle_avg_ereal (birkhoff_sum u) = (\<integral>x. u x \<partial>M)"
 proof -
   have *: "ereal (\<integral>x. (birkhoff_sum u n x) / n \<partial>M) = (\<integral>x. u x \<partial>M)" if "n>0" for n
     using birkhoff_sum_integral(2)[OF assms] that by auto
   have "(\<lambda>n. ereal (\<integral>x. (birkhoff_sum u n x) / n \<partial>M)) \<longlonglongrightarrow> (\<integral>x. u x \<partial>M)"
     by (subst lim_explicit, metis * less_le_trans zero_less_one)
   moreover have "(\<lambda>n. ereal (\<integral>x. (birkhoff_sum u n x) / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal (birkhoff_sum u)"
     using subcocycle_int_tendsto_avg_ereal[OF subcocycle_birkhoff[OF assms]] by auto
   ultimately show ?thesis using LIMSEQ_unique by blast
 qed
 
 text \<open>In nice situations, where one can avoid the use of ereal, the following
 definition is more convenient. The kind of statements we are after is as follows: if the
 ereal average is finite, then something holds, likely involving the real average.
 
 In particular, we show in this setting what we have proved above under this new assumption:
 convergence (in real numbers) of the average to the asymptotic average, as well as good behavior
 under sum, scalar multiplication by positive numbers, max, formula for Birkhoff sums.\<close>
 
 definition subcocycle_avg::"(nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> real" where
   "subcocycle_avg u = real_of_ereal(subcocycle_avg_ereal u)"
 
 lemma subcocycle_avg_real_ereal:
   assumes "subcocycle_avg_ereal u > - \<infinity>"
   shows "subcocycle_avg_ereal u = ereal(subcocycle_avg u)"
 unfolding subcocycle_avg_def using assms subcocycle_avg_finite[of u] ereal_real by auto
 
 lemma subcocycle_int_tendsto_avg:
   assumes "subcocycle u" "subcocycle_avg_ereal u > - \<infinity>"
   shows "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg u"
 using subcocycle_avg_real_ereal[OF assms(2)] subcocycle_int_tendsto_avg_ereal[OF assms(1)] by auto
 
 lemma subcocycle_avg_add:
   assumes "subcocycle u" "subcocycle v" "subcocycle_avg_ereal u > - \<infinity>" "subcocycle_avg_ereal v > - \<infinity>"
   shows "subcocycle_avg_ereal (\<lambda>n x. u n x + v n x) > -\<infinity>"
         "subcocycle_avg (\<lambda>n x. u n x + v n x) = subcocycle_avg u + subcocycle_avg v"
 using assms subcocycle_avg_finite real_of_ereal_add
 unfolding subcocycle_avg_def subcocycle_avg_ereal_add[OF assms(1) assms(2)] by auto
 
 lemma subcocycle_avg_cmult:
   assumes "subcocycle u" "c \<ge> (0::real)" "subcocycle_avg_ereal u > - \<infinity>"
   shows "subcocycle_avg_ereal (\<lambda>n x. c * u n x) > - \<infinity>"
         "subcocycle_avg (\<lambda>n x. c * u n x) = c * subcocycle_avg u"
 using assms subcocycle_avg_finite unfolding subcocycle_avg_def subcocycle_avg_ereal_cmult[OF assms(1) assms(2)] by auto
 
 lemma subcocycle_avg_max:
   assumes "subcocycle u" "subcocycle v" "subcocycle_avg_ereal u > - \<infinity>" "subcocycle_avg_ereal v > - \<infinity>"
   shows "subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x)) > -\<infinity>"
         "subcocycle_avg (\<lambda>n x. max (u n x) (v n x)) \<ge> max (subcocycle_avg u) (subcocycle_avg v)"
 proof -
   show *: "subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x)) > - \<infinity>"
     using assms(3) subcocycle_avg_ereal_max[OF assms(1) assms(2)] by auto
   have "ereal (subcocycle_avg (\<lambda>n x. max (u n x) (v n x))) \<ge> max (ereal(subcocycle_avg u)) (ereal(subcocycle_avg v))"
     using subcocycle_avg_real_ereal[OF assms(3)] subcocycle_avg_real_ereal[OF assms(4)]
       subcocycle_avg_real_ereal[OF *] subcocycle_avg_ereal_max[OF assms(1) assms(2)] by auto
   then show "subcocycle_avg (\<lambda>n x. max (u n x) (v n x)) \<ge> max (subcocycle_avg u) (subcocycle_avg v)"
     by auto
 qed
 
 lemma subcocycle_avg_birkhoff:
   assumes "integrable M u"
   shows "subcocycle_avg_ereal (birkhoff_sum u) > - \<infinity>"
         "subcocycle_avg (birkhoff_sum u) = (\<integral>x. u x \<partial>M)"
 unfolding subcocycle_avg_def subcocycle_avg_ereal_birkhoff[OF assms(1)] by auto
 
 end
 
 
 
 subsection \<open>Almost sure convergence of subcocycles\<close>
 
 text \<open>In this paragraph, we prove Kingman's theorem, i.e., the almost sure convergence of
 subcocycles. Their limit is almost surely invariant. There is no really easy proof. The one we use
 below is arguably the simplest known one, due to Steele (1989). The idea is to show that the limsup
 of the subcocycle is bounded by the liminf (which is almost surely constant along trajectories), by
 using subadditivity along time intervals where the liminf is almost reached, of length at most $N$.
 For some points, the liminf takes a large time $>N$ to be reached. We neglect those times,
 introducing an additional error that gets smaller with $N$, thanks to Birkhoff ergodic theorem
 applied to the set of bad points. The error is most easily managed if the subcocycle is assumed to
 be nonpositive, which one can assume in a first step. The general case is reduced to this one by
 replacing $u_n$ with $u_n - S_n u_1 \leq 0$, and using Birkhoff theorem to control $S_n u_1$.\<close>
 
 context fmpt begin
 
 text \<open>First, as explained above, we prove the theorem for nonpositive subcocycles.\<close>
 
 lemma kingman_theorem_AE_aux1:
   assumes "subcocycle u"
           "\<And>x. u 1 x \<le> 0"
   shows "\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and> (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
 proof -
   define l where "l = (\<lambda>x. liminf (\<lambda>n. u n x / n))"
   have u_meas [measurable]: "\<And>n. u n \<in> borel_measurable M" using assms(1) unfolding subcocycle_def by auto
   have l_meas [measurable]: "l \<in> borel_measurable M" unfolding l_def by auto
 
   {
     fix x assume *: "(\<lambda>n. birkhoff_sum (u 1) n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants (u 1) x"
     then have "(\<lambda>n. birkhoff_sum (u 1) n x / n) \<longlonglongrightarrow> ereal(real_cond_exp M Invariants (u 1) x)"
       by auto
     then have a: "liminf (\<lambda>n. birkhoff_sum (u 1) n x / n) = ereal(real_cond_exp M Invariants (u 1) x)"
       using lim_imp_Liminf by force
 
     have "ereal(u n x / n) \<le> ereal(birkhoff_sum (u 1) n x / n)" if "n>0" for n
       using subcocycle_bounded_by_birkhoff1[OF assms(1) that, of x] that by (simp add: divide_right_mono)
     with eventually_mono[OF eventually_gt_at_top[of 0] this]
     have "eventually (\<lambda>n. ereal(u n x / n) \<le> ereal(birkhoff_sum (u 1) n x / n)) sequentially" by auto
     then have "liminf (\<lambda>n. u n x / n) \<le> liminf (\<lambda>n. birkhoff_sum (u 1) n x / n)"
       by (simp add: Liminf_mono)
     then have "l x < \<infinity>" unfolding l_def using a by auto
   }
   then have "AE x in M. l x < \<infinity>"
     using birkhoff_theorem_AE_nonergodic[of "u 1"] subcocycle_def assms(1) by auto
 
   have l_dec: "l x \<le> l (T x)" for x
   proof -
     have "l x = liminf (\<lambda>n. ereal ((u (n+1) x)/(n+1)))"
       unfolding l_def by (rule liminf_shift[of "\<lambda>n. ereal (u n x / real n)", symmetric])
     also have "... \<le> liminf (\<lambda>n. ereal((u 1 x)/(n+1)) + ereal((u n (T x))/(n+1)))"
     proof (rule Liminf_mono[OF eventuallyI])
       fix n
       have "u (1+n) x \<le> u 1 x + u n ((T^^1) x)" using assms(1) unfolding subcocycle_def by blast
       then have "u (n+1) x \<le> u 1 x + u n (T x)" by auto
       then have "(u (n+1) x)/(n+1) \<le> (u 1 x)/(n+1) + (u n (T x))/(n+1)"
         by (metis add_divide_distrib divide_right_mono of_nat_0_le_iff)
       then show "ereal ((u (n+1) x)/(n+1)) \<le> ereal((u 1 x)/(n+1)) + ereal((u n (T x))/(n+1))" by auto
     qed
     also have "... = 0 + liminf(\<lambda>n. ereal((u n (T x))/(n+1)))"
     proof (rule ereal_liminf_lim_add[of "\<lambda>n. ereal((u 1 x)/real(n+1))" 0 "\<lambda>n. ereal((u n (T x))/(n+1))"])
       have "(\<lambda>n. ereal((u 1 x)*(1/real(n+1)))) \<longlonglongrightarrow> ereal((u 1 x) * 0)"
         by (intro tendsto_intros LIMSEQ_ignore_initial_segment)
       then show "(\<lambda>n. ereal((u 1 x)/real(n+1))) \<longlonglongrightarrow> 0" by (simp add: zero_ereal_def)
     qed (simp)
     also have "... = 1 * liminf(\<lambda>n. ereal((u n (T x))/(n+1)))" by simp
     also have "... = liminf(\<lambda>n. (n+1)/n * ereal((u n (T x))/(n+1)))"
     proof (rule ereal_liminf_lim_mult[symmetric])
       have "real (n+1) / real n = 1 + 1/real n" if "n>0" for n by (simp add: divide_simps mult.commute that)
       with eventually_mono[OF eventually_gt_at_top[of "0::nat"] this]
       have "eventually (\<lambda>n. real (n+1) / real n = 1 + 1/real n) sequentially" by simp
       moreover have "(\<lambda>n. 1 + 1/real n) \<longlonglongrightarrow> 1 + 0"
         by (intro tendsto_intros)
       ultimately have "(\<lambda>n. real (n+1) / real n) \<longlonglongrightarrow> 1" using Lim_transform_eventually by (simp add: filterlim_cong)
       then show "(\<lambda>n. ereal(real (n+1) / real n)) \<longlonglongrightarrow> 1" by (simp add: one_ereal_def)
     qed (auto)
     also have "... = l (T x)" unfolding l_def by auto
     finally show "l x \<le> l (T x)" by simp
   qed
   have "AE x in M. l (T x) = l x"
     apply (rule AE_increasing_then_invariant) using l_dec by auto
   then obtain g0 where g0: "g0 \<in> borel_measurable Invariants" "AE x in M. l x = g0 x"
     using Invariants_quasi_Invariants_functions[OF l_meas] by auto
   define g where "g = (\<lambda>x. if g0 x = \<infinity> then 0 else g0 x)"
   have g: "g \<in> borel_measurable Invariants" "AE x in M. g x = l x"
     unfolding g_def using g0(1) \<open>AE x in M. l x = g0 x\<close> \<open>AE x in M. l x < \<infinity>\<close> by auto
   have [measurable]: "g \<in> borel_measurable M" using g(1) Invariants_measurable_func by blast
   have "\<And>x. g x < \<infinity>" unfolding g_def by auto
 
   define A where "A = {x \<in> space M. l x < \<infinity> \<and> (\<forall>n. l ((T^^n) x) = g ((T^^n) x))}"
   have A_meas [measurable]: "A \<in> sets M" unfolding A_def by auto
   have "AE x in M. x \<in> A" unfolding A_def using T_AE_iterates[OF g(2)] \<open>AE x in M. l x < \<infinity>\<close> by auto
   then have "space M - A \<in> null_sets M" by (simp add: AE_iff_null set_diff_eq)
 
   have l_inv: "l((T^^n) x) = l x" if "x \<in> A" for x n
   proof -
     have "l((T^^n) x) = g((T^^n) x)" using \<open> x \<in> A \<close> unfolding A_def by blast
     also have "... = g x" using g(1) A_def Invariants_func_is_invariant_n that by blast
     also have "... = g((T^^0) x)" by auto
     also have "... = l((T^^0) x)" using \<open> x \<in> A \<close> unfolding A_def by (metis (mono_tags, lifting) mem_Collect_eq)
     finally show ?thesis by auto
   qed
 
   define F where "F = (\<lambda> K e x. real_of_ereal(max (l x) (-ereal K)) + e)"
   have F_meas [measurable]: "F K e \<in> borel_measurable M" for K e unfolding F_def by auto
   define B where "B = (\<lambda>N K e. {x \<in> A. \<exists>n\<in>{1..N}. u n x - n * F K e x < 0})"
   have B_meas [measurable]: "B N K e \<in> sets M" for N K e unfolding B_def by (measurable)
   define I where "I = (\<lambda>N K e x. (indicator (- B N K e) x)::real)"
   have I_meas [measurable]: "I N K e \<in> borel_measurable M" for N K e unfolding I_def by auto
   have I_int: "integrable M (I N K e)" for N K e
-    unfolding I_def apply (subst integrable_cong[where ?g = "indicator (space M - B N K e)::_ \<Rightarrow> real"], auto)
+    unfolding I_def apply (subst Bochner_Integration.integrable_cong[where ?g = "indicator (space M - B N K e)::_ \<Rightarrow> real"], auto)
     by (auto split: split_indicator simp: less_top[symmetric])
 
   have main: "AE x in M. limsup (\<lambda>n. u n x / n) \<le> F K e x + abs(F K e x) * ereal(real_cond_exp M Invariants (I N K e) x)"
     if "N>(1::nat)" "K>(0::real)" "e>(0::real)" for N K e
   proof -
     let ?B = "B N K e" and ?I = "I N K e" and ?F = "F K e"
 
     define t where "t = (\<lambda>x. if x \<in> ?B then Min {n\<in>{1..N}. u n x - n * ?F x < 0} else 1)"
     have [measurable]: "t \<in> measurable M (count_space UNIV)" unfolding t_def by measurable
     have t1: "t x \<in> {1..N}" for x
     proof (cases "x \<in> ?B")
       case False
       then have "t x = 1" by (simp add: t_def)
       then show ?thesis using \<open>N>1\<close>by auto
     next
       case True
       let ?A = "{n\<in>{1..N}. u n x - n * ?F x < 0}"
       have "t x = Min ?A" using True by (simp add: t_def)
       moreover have "Min ?A \<in> ?A" apply (rule Min_in, simp) using True B_def by blast
       ultimately show ?thesis by auto
     qed
 
     have bound1: "u (t x) x \<le> t x * ?F x + birkhoff_sum ?I (t x) x * abs(?F x)" for x
     proof (cases "x \<in> ?B")
       case True
       let ?A = "{n\<in>{1..N}. u n x - n * F K e x < 0}"
       have "t x = Min ?A" using True by (simp add: t_def)
       moreover have "Min ?A \<in> ?A" apply (rule Min_in, simp) using True B_def by blast
       ultimately have "u (t x) x \<le> (t x) * ?F x" by auto
       moreover have "0 \<le> birkhoff_sum ?I (t x) x * abs(?F x)" unfolding birkhoff_sum_def I_def by (simp add: sum_nonneg)
       ultimately show ?thesis by auto
     next
       case False
       then have "0 \<le> ?F x + ?I x * abs(?F x)" unfolding I_def by auto
       then have "u 1 x \<le> ?F x + ?I x * abs(?F x)" using assms(2)[of x] by auto
       moreover have "t x = 1" unfolding t_def using False by auto
       ultimately show ?thesis by auto
     qed
 
     define TB where "TB = (\<lambda>x. (T^^(t x)) x)"
     have [measurable]: "TB \<in> measurable M M" unfolding TB_def by auto
     define S where "S = (\<lambda>n x. (\<Sum>i<n. t((TB^^i) x)))"
     have [measurable]: "S n \<in> measurable M (count_space UNIV)" for n unfolding S_def by measurable
     have TB_pow: "(TB^^n) x = (T^^(S n x)) x" for n x
       unfolding S_def TB_def
       by (induction n, auto, metis (mono_tags, lifting) add.commute funpow_add o_apply)
 
     have uS: "u (S n x) x \<le> (S n x) * ?F x + birkhoff_sum ?I (S n x) x * abs(?F x)" if "x \<in> A" "n>0" for x n
     using \<open>n > 0\<close> proof (induction rule: ind_from_1)
       case 1
       show ?case unfolding S_def using bound1 by auto
     next
       case (Suc n)
       have *: "?F((TB^^n) x) = ?F x" apply (subst TB_pow) unfolding F_def using l_inv[OF \<open>x\<in>A\<close>] by auto
       have **: "S n x + t ((TB^^n) x) = S (Suc n) x" unfolding S_def by auto
       have "u (S (Suc n) x) x = u (S n x + t((TB^^n) x)) x" unfolding S_def by auto
       also have "... \<le> u (S n x) x + u (t((TB^^n) x)) ((T^^(S n x)) x)"
         using assms(1) unfolding subcocycle_def by auto
       also have "... \<le> u (S n x) x + u (t((TB^^n) x)) ((TB^^n) x)"
         using TB_pow by auto
       also have "... \<le> (S n x) * ?F x + birkhoff_sum ?I (S n x) x * abs(?F x) +
                   t ((TB^^n) x) * ?F ((TB^^n) x) + birkhoff_sum ?I (t ((TB^^n) x)) ((TB^^n) x) * abs(?F ((TB^^n) x))"
         using Suc bound1[of "((TB^^n) x)"] by auto
       also have "... = (S n x) * ?F x + birkhoff_sum ?I (S n x) x * abs(?F x) +
                   t ((TB^^n) x) * ?F x + birkhoff_sum ?I (t ((TB^^n) x)) ((T^^(S n x)) x) * abs(?F x)"
         using * TB_pow by auto
       also have "... = (real(S n x) + t ((TB^^n) x)) * ?F x +
                   (birkhoff_sum ?I (S n x) x + birkhoff_sum ?I (t ((TB^^n) x)) ((T^^(S n x)) x)) * abs(?F x)"
         by (simp add: mult.commute ring_class.ring_distribs(1))
       also have "... = (S n x + t ((TB^^n) x)) * ?F x +
                   (birkhoff_sum ?I (S n x) x + birkhoff_sum ?I (t ((TB^^n) x)) ((T^^(S n x)) x)) * abs(?F x)"
         by simp
       also have "... = (S (Suc n) x) * ?F x + birkhoff_sum ?I (S (Suc n) x) x * abs(?F x)"
         by (subst birkhoff_sum_cocycle[symmetric], subst **, subst **, simp)
       finally show ?case by simp
     qed
 
     have un: "u n x \<le> n * ?F x + N * abs(?F x) + birkhoff_sum ?I n x * abs(?F x)" if "x \<in> A" "n>N" for x n
     proof -
       let ?A = "{i. S i x > n}"
       let ?iA = "Inf ?A"
       have "n < (\<Sum>i<n + 1. 1)" by auto
       also have "... \<le> S (n+1) x" unfolding S_def apply (rule sum_mono) using t1 by auto
       finally have "?A \<noteq> {}" by blast
       then have "?iA \<in> ?A" by (meson Inf_nat_def1)
       moreover have "0 \<notin> ?A" unfolding S_def by auto
       ultimately have "?iA \<noteq> 0" by fastforce
       define j where "j = ?iA - 1"
       then have "j < ?iA" using \<open>?iA \<noteq> 0\<close> by auto
       then have "j \<notin> ?A" by (meson bdd_below_def cInf_lower le0 not_less)
       then have "S j x \<le> n" by auto
       define k where "k = n - S j x"
       have "n = S j x + k" unfolding k_def using \<open>S j x \<le> n\<close> by auto
       have "n < S (j+1) x" unfolding j_def using \<open>?iA \<noteq> 0\<close> \<open>?iA \<in> ?A\<close> by auto
       also have "... = S j x + t((TB^^j) x)" unfolding S_def by auto
       also have "... \<le> S j x + N" using t1 by auto
       finally have "k \<le> N" unfolding k_def using \<open>n > N\<close> by auto
       then have "S j x > 0" unfolding k_def using \<open>n > N\<close> by auto
       then have "j > 0" unfolding S_def using not_gr0 by fastforce
 
       have "birkhoff_sum ?I (S j x) x \<le> birkhoff_sum ?I n x"
         unfolding birkhoff_sum_def I_def using \<open>S j x \<le> n\<close>
         by (metis finite_Collect_less_nat indicator_pos_le lessThan_def lessThan_subset_iff sum_mono2)
 
       have "u n x \<le> u (S j x) x"
       proof (cases "k = 0")
         case True
         show ?thesis using True unfolding k_def using \<open>S j x \<le> n\<close> by auto
       next
         case False
         then have "k > 0" by simp
         have "u k ((T^^(S j x)) x) \<le> birkhoff_sum (u 1) k ((T ^^ S j x) x)"
           using subcocycle_bounded_by_birkhoff1[OF assms(1) \<open>k>0\<close>, of "(T^^(S j x)) x"] by simp
         also have "... \<le> 0" unfolding birkhoff_sum_def using sum_mono assms(2) by (simp add: sum_nonpos)
         also have "u n x \<le> u (S j x) x + u k ((T^^(S j x)) x)"
           apply (subst \<open>n = S j x + k\<close>) using assms(1) subcocycle_def by auto
         ultimately show ?thesis by auto
       qed
       also have "... \<le> (S j x) * ?F x + birkhoff_sum ?I (S j x) x * abs(?F x)"
         using uS[OF \<open>x \<in> A\<close> \<open>j>0\<close>] by simp
       also have "... \<le> (S j x) * ?F x + birkhoff_sum ?I n x * abs(?F x)"
         using \<open>birkhoff_sum ?I (S j x) x \<le> birkhoff_sum ?I n x\<close> by (simp add: mult_right_mono)
       also have "... = n * ?F x - k * ?F x + birkhoff_sum ?I n x * abs(?F x)"
         by (metis \<open>n = S j x + k\<close> add_diff_cancel_right' le_add2 left_diff_distrib' of_nat_diff)
       also have "... \<le> n * ?F x + k * abs(?F x) + birkhoff_sum ?I n x * abs(?F x)"
         by (auto, metis abs_ge_minus_self abs_mult abs_of_nat)
       also have "... \<le> n * ?F x + N * abs(?F x) + birkhoff_sum ?I n x * abs(?F x)"
         using \<open>k \<le> N\<close> by (simp add: mult_right_mono)
       finally show ?thesis by simp
     qed
 
     have "limsup (\<lambda>n. u n x / n) \<le> ?F x + limsup (\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n))" if "x \<in> A" for x
     proof -
       have "(\<lambda>n. ereal(?F x + N * abs(?F x) * (1 / n))) \<longlonglongrightarrow> ereal(?F x + N * abs (?F x) * 0)"
         by (intro tendsto_intros)
       then have *: "limsup (\<lambda>n. ?F x + N * abs(?F x)/n) = ?F x"
         using sequentially_bot tendsto_iff_Liminf_eq_Limsup by force
 
       {
         fix n assume "n > N"
         have "u n x / real n \<le> ?F x + N * abs(?F x) / n + abs(?F x) * birkhoff_sum ?I n x / n"
           using un[OF \<open>x \<in> A\<close> \<open>n > N\<close>] using \<open>n>N\<close> by (auto simp add: divide_simps mult.commute)
         then have "ereal(u n x/n) \<le> ereal(?F x + N * abs(?F x) / n) + abs(?F x) * ereal(birkhoff_sum ?I n x / n)"
           by auto
       }
       then have "eventually (\<lambda>n. ereal(u n x / n) \<le> ereal(?F x + N * abs(?F x) / n) + abs(?F x) * ereal(birkhoff_sum ?I n x / n)) sequentially"
         using eventually_mono[OF eventually_gt_at_top[of N]] by auto
       with Limsup_mono[OF this]
       have "limsup (\<lambda>n. u n x / n) \<le> limsup (\<lambda>n. ereal(?F x + N * abs(?F x) / n) + abs(?F x) * ereal(birkhoff_sum ?I n x / n))"
         by auto
       also have "... \<le> limsup (\<lambda>n. ?F x + N * abs(?F x) / n) + limsup (\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n))"
         by (rule ereal_limsup_add_mono)
       also have "... = ?F x + limsup (\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n))"
         using * by auto
       finally show ?thesis by auto
     qed
     then have *: "AE x in M. limsup (\<lambda>n. u n x / n) \<le> ?F x + limsup (\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n))"
       using \<open>AE x in M. x \<in> A\<close> by auto
 
     {
       fix x assume H: "(\<lambda>n. birkhoff_sum ?I n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants ?I x"
       have "(\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n)) \<longlonglongrightarrow> abs(?F x) * ereal(real_cond_exp M Invariants ?I x)"
         by (rule tendsto_mult_ereal, auto simp add: H)
       then have "limsup (\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n)) = abs(?F x) * ereal(real_cond_exp M Invariants ?I x)"
         using sequentially_bot tendsto_iff_Liminf_eq_Limsup by blast
     }
     moreover have "AE x in M. (\<lambda>n. birkhoff_sum ?I n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants ?I x"
       by (rule birkhoff_theorem_AE_nonergodic[OF I_int])
     ultimately have "AE x in M. limsup (\<lambda>n. abs(?F x) * ereal(birkhoff_sum ?I n x / n)) = abs(?F x) * ereal(real_cond_exp M Invariants ?I x)"
       by auto
     then show ?thesis using * by auto
   qed
 
   have bound2: "AE x in M. limsup (\<lambda>n. u n x / n) \<le> F K e x" if "K > 0" "e > 0" for K e
   proof -
     define C where "C = (\<lambda>N. A - B N K e)"
     have C_meas [measurable]: "\<And>N. C N \<in> sets M" unfolding C_def by auto
     {
       fix x assume "x \<in> A"
       have "F K e x > l x" using \<open>x \<in> A\<close> \<open>e > 0\<close> unfolding F_def A_def
         by (cases "l x", auto, metis add.commute ereal_max less_add_same_cancel2 max_less_iff_conj real_of_ereal.simps(1))
       then have "\<exists>n>0. ereal(u n x / n) < F K e x" unfolding l_def using liminf_upper_bound by fastforce
       then obtain n where "n>0" "ereal(u n x / n) < F K e x" by auto
       then have "u n x - n * F K e x < 0" by (simp add: divide_less_eq mult.commute)
       then have "x \<notin> C n" unfolding C_def B_def using \<open>x \<in> A\<close> \<open>n>0\<close> by auto
       then have "x \<notin> (\<Inter>n. C n)" by auto
     }
     then have "(\<Inter>n. C n) = {}" unfolding C_def by auto
     then have *: "0 = measure M (\<Inter>n. C n)" by auto
     have "(\<lambda>n. measure M (C n)) \<longlonglongrightarrow> 0"
       apply (subst *, rule finite_Lim_measure_decseq, auto) unfolding C_def B_def decseq_def by auto
     moreover have "measure M (C n) = (\<integral>x. norm(real_cond_exp M Invariants (I n K e) x) \<partial>M)" for n
     proof -
       have *: "AE x in M. 0 \<le> real_cond_exp M Invariants (I n K e) x"
         apply (rule real_cond_exp_pos, auto) unfolding I_def by auto
 
       have "measure M (C n) = (\<integral>x. indicator (C n) x \<partial>M)"
         by auto
       also have "... = (\<integral>x. I n K e x \<partial>M)"
         apply (rule integral_cong_AE, auto)
         unfolding C_def I_def indicator_def using \<open>AE x in M. x \<in> A\<close> by auto
       also have "... = (\<integral>x. real_cond_exp M Invariants (I n K e) x \<partial>M)"
         by (rule real_cond_exp_int(2)[symmetric, OF I_int])
       also have "... = (\<integral>x. norm(real_cond_exp M Invariants (I n K e) x) \<partial>M)"
         apply (rule integral_cong_AE, auto) using * by auto
       finally show ?thesis by auto
     qed
     ultimately have *: "(\<lambda>n. (\<integral>x. norm(real_cond_exp M Invariants (I n K e) x) \<partial>M)) \<longlonglongrightarrow> 0" by simp
 
     have "\<exists>r. strict_mono r \<and> (AE x in M. (\<lambda>n. real_cond_exp M Invariants (I (r n) K e) x) \<longlonglongrightarrow> 0)"
       apply (rule tendsto_L1_AE_subseq) using * real_cond_exp_int[OF I_int] by auto
     then obtain r where "strict_mono r" "AE x in M. (\<lambda>n. real_cond_exp M Invariants (I (r n) K e) x) \<longlonglongrightarrow> 0"
       by auto
     moreover have "AE x in M. \<forall>N \<in> {1<..}. limsup (\<lambda>n. u n x / n) \<le> F K e x + abs(F K e x) * ereal(real_cond_exp M Invariants (I N K e) x)"
       apply (rule AE_ball_countable') using main[OF _ \<open>K>0\<close> \<open>e>0\<close>] by auto
     moreover
     {
       fix x assume H: "(\<lambda>n. real_cond_exp M Invariants (I (r n) K e) x) \<longlonglongrightarrow> 0"
                       "\<And>N. N > 1 \<Longrightarrow> limsup (\<lambda>n. u n x / n) \<le> F K e x + abs(F K e x) * ereal(real_cond_exp M Invariants (I N K e) x)"
       have 1: "eventually (\<lambda>N. limsup (\<lambda>n. u n x / n) \<le> F K e x + abs(F K e x) * ereal(real_cond_exp M Invariants (I (r N) K e) x)) sequentially"
         apply (rule eventually_mono[OF eventually_gt_at_top[of 1] H(2)])
         using \<open>strict_mono r\<close> less_le_trans seq_suble by blast
       have 2: "(\<lambda>N. F K e x + (abs(F K e x) * ereal(real_cond_exp M Invariants (I (r N) K e) x))) \<longlonglongrightarrow> ereal(F K e x) + (abs(F K e x) * ereal 0)"
         by (intro tendsto_intros) (auto simp add: H(1))
       have "limsup (\<lambda>n. u n x / n) \<le> F K e x"
         apply (rule LIMSEQ_le_const) using 1 2 by (auto simp add: eventually_at_top_linorder)
     }
     ultimately show "AE x in M. limsup (\<lambda>n. u n x / n) \<le> F K e x" by auto
   qed
   have "AE x in M. limsup (\<lambda>n. u n x / n) \<le> real_of_ereal(max (l x) (-ereal K))" if "K>(0::nat)" for K
     apply (rule AE_upper_bound_inf_ereal) using bound2 \<open>K>0\<close> unfolding F_def by auto
   then have "AE x in M. \<forall>K\<in>{(0::nat)<..}. limsup (\<lambda>n. u n x / n) \<le> real_of_ereal(max (l x) (-ereal K))"
     by (rule AE_ball_countable', auto)
   moreover have "(\<lambda>n. u n x / n) \<longlonglongrightarrow> l x"
     if H: "\<forall>K\<in>{(0::nat)<..}. limsup (\<lambda>n. u n x / n) \<le> real_of_ereal(max (l x) (-ereal K))" for x
   proof -
     have "limsup (\<lambda>n. u n x / n) \<le> l x"
     proof (cases "l x = \<infinity>")
       case False
       then have "(\<lambda>K. real_of_ereal(max (l x) (-ereal K))) \<longlonglongrightarrow> l x"
         using ereal_truncation_real_bottom by auto
       moreover have "eventually (\<lambda>K. limsup (\<lambda>n. u n x / n) \<le> real_of_ereal(max (l x) (-ereal K))) sequentially"
         using H by (metis (no_types, lifting) eventually_at_top_linorder eventually_gt_at_top greaterThan_iff)
       ultimately show "limsup (\<lambda>n. u n x / n) \<le> l x" using Lim_bounded2 eventually_sequentially by auto
     qed (simp)
     then have "limsup (\<lambda>n. ereal (u n x / real n)) = l x"
       using Liminf_le_Limsup l_def eq_iff sequentially_bot by blast
     then show "(\<lambda>n. u n x / n) \<longlonglongrightarrow> l x"
       by (simp add: l_def tendsto_iff_Liminf_eq_Limsup)
   qed
   ultimately have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> l x" by auto
   then have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x" using g(2) by auto
   then show "\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and> (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
     using g(1) \<open>\<And>x. g x < \<infinity>\<close> by auto
 qed
 
 text \<open>We deduce it for general subcocycles, by reducing to nonpositive subcocycles by subtracting
 the Birkhoff sum of $u_1$ (for which the convergence follows from Birkhoff theorem).\<close>
 
 theorem kingman_theorem_AE_aux2:
   assumes "subcocycle u"
   shows "\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and> (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
 proof -
   define v where "v = (\<lambda>n x. u n x + birkhoff_sum (\<lambda>x. - u 1 x) n x)"
   have "subcocycle v" unfolding v_def
     apply (rule subcocycle_add[OF assms], rule subcocycle_birkhoff)
     using assms unfolding subcocycle_def by auto
   have "\<exists>(gv::'a\<Rightarrow>ereal). (gv\<in>borel_measurable Invariants \<and> (\<forall>x. gv x < \<infinity>) \<and> (AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> gv x))"
     apply (rule kingman_theorem_AE_aux1[OF \<open>subcocycle v\<close>]) unfolding v_def by auto
   then obtain gv where gv: "gv \<in> borel_measurable Invariants" "AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> (gv x::ereal)" "\<And>x. gv x < \<infinity>"
     by blast
   define g where "g = (\<lambda>x. gv x + ereal(real_cond_exp M Invariants (u 1) x))"
   have g_meas: "g \<in> borel_measurable Invariants" unfolding g_def using gv(1) by auto
   have g_fin: "\<And>x. g x < \<infinity>" unfolding g_def using gv(3) by auto
 
   have "AE x in M. (\<lambda>n. birkhoff_sum (u 1) n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants (u 1) x"
     apply (rule birkhoff_theorem_AE_nonergodic) using assms unfolding subcocycle_def by auto
   moreover
   {
     fix x assume H: "(\<lambda>n. v n x / n) \<longlonglongrightarrow> (gv x)"
                     "(\<lambda>n. birkhoff_sum (u 1) n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants (u 1) x"
     then have "(\<lambda>n. ereal(birkhoff_sum (u 1) n x / n)) \<longlonglongrightarrow> ereal(real_cond_exp M Invariants (u 1) x)"
       by auto
     {
       fix n
       have "u n x = v n x + birkhoff_sum (u 1) n x"
         unfolding v_def birkhoff_sum_def apply auto by (simp add: sum_negf)
       then have "u n x / n = v n x / n + birkhoff_sum (u 1) n x / n" by (simp add: add_divide_distrib)
       then have "ereal(u n x / n) = ereal(v n x / n) + ereal(birkhoff_sum (u 1) n x / n)"
         by auto
     } note * = this
     have "(\<lambda>n. ereal(u n x / n)) \<longlonglongrightarrow> g x" unfolding * g_def
       apply (intro tendsto_intros) using H by auto
   }
   ultimately have "AE x in M. (\<lambda>n. ereal(u n x / n)) \<longlonglongrightarrow> g x" using gv(2) by auto
   then show ?thesis using g_meas g_fin by blast
 qed
 
 text \<open>For applications, it is convenient to have a limit which is really measurable with respect
 to the invariant sigma algebra and does not come from a hard to use abstract existence statement.
 Hence we introduce the following definition for the would-be limit -- Kingman's theorem shows that
 it is indeed a limit.
 
 We introduce the definition for any function, not only subcocycles, but it will only be usable for
 subcocycles. We introduce an if clause in the definition so that the limit is always measurable,
 even when $u$ is not a subcocycle and there is no convergence.\<close>
 
 definition subcocycle_lim_ereal::"(nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> ('a \<Rightarrow> ereal)"
   where "subcocycle_lim_ereal u = (
     if (\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and>
       (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x)))
     then (SOME (g::'a\<Rightarrow>ereal). g\<in>borel_measurable Invariants \<and>
       (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))
     else (\<lambda>_. 0))"
 
 definition subcocycle_lim::"(nat \<Rightarrow> 'a \<Rightarrow> real) \<Rightarrow> ('a \<Rightarrow> real)"
   where "subcocycle_lim u = (\<lambda>x. real_of_ereal(subcocycle_lim_ereal u x))"
 
 lemma subcocycle_lim_meas_Inv [measurable]:
   "subcocycle_lim_ereal u \<in> borel_measurable Invariants"
   "subcocycle_lim u \<in> borel_measurable Invariants"
 proof -
   show "subcocycle_lim_ereal u \<in> borel_measurable Invariants"
   proof (cases "\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and> (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))")
     case True
     then have "subcocycle_lim_ereal u = (SOME (g::'a\<Rightarrow>ereal). g\<in>borel_measurable Invariants \<and>
           (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
       unfolding subcocycle_lim_ereal_def by auto
     then show ?thesis using someI_ex[OF True] by auto
   next
     case False
     then have "subcocycle_lim_ereal u = (\<lambda>_. 0)" unfolding subcocycle_lim_ereal_def by auto
     then show ?thesis by auto
   qed
   then show "subcocycle_lim u \<in> borel_measurable Invariants" unfolding subcocycle_lim_def by auto
 qed
 
 lemma subcocycle_lim_meas [measurable]:
   "subcocycle_lim_ereal u \<in> borel_measurable M"
   "subcocycle_lim u \<in> borel_measurable M"
 using subcocycle_lim_meas_Inv Invariants_measurable_func apply blast
 using subcocycle_lim_meas_Inv Invariants_measurable_func by blast
 
 lemma subcocycle_lim_ereal_not_PInf:
   "subcocycle_lim_ereal u x < \<infinity>"
 proof (cases "\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and> (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))")
   case True
   then have "subcocycle_lim_ereal u = (SOME (g::'a\<Rightarrow>ereal). g\<in>borel_measurable Invariants \<and>
         (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
     unfolding subcocycle_lim_ereal_def by auto
   then show ?thesis using someI_ex[OF True] by auto
 next
   case False
   then have "subcocycle_lim_ereal u = (\<lambda>_. 0)" unfolding subcocycle_lim_ereal_def by auto
   then show ?thesis by auto
 qed
 
 text \<open>We reformulate the subadditive ergodic theorem of Kingman with this definition.
 From this point on, the technical definition of \verb+subcocycle_lim_ereal+ will never be used, only
 the following property will be relevant.\<close>
 
 theorem kingman_theorem_AE_nonergodic_ereal:
   assumes "subcocycle u"
   shows "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
 proof -
   have *: "\<exists>(g::'a\<Rightarrow>ereal). (g\<in>borel_measurable Invariants \<and> (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
     using kingman_theorem_AE_aux2[OF assms] by auto
   then have "subcocycle_lim_ereal u = (SOME (g::'a\<Rightarrow>ereal). g\<in>borel_measurable Invariants \<and>
         (\<forall>x. g x < \<infinity>) \<and> (AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> g x))"
     unfolding subcocycle_lim_ereal_def by auto
   then show ?thesis using someI_ex[OF *] by auto
 qed
 
 text \<open>The subcocycle limit behaves well under addition, multiplication by a positive scalar,
 max, and is simply the conditional expectation with respect to invariants for Birkhoff sums,
 thanks to Birkhoff theorem.\<close>
 
 lemma subcocycle_lim_ereal_add:
   assumes "subcocycle u" "subcocycle v"
   shows "AE x in M. subcocycle_lim_ereal (\<lambda>n x. u n x + v n x) x = subcocycle_lim_ereal u x + subcocycle_lim_ereal v x"
 proof -
   have "AE x in M. (\<lambda>n. (u n x + v n x)/n) \<longlonglongrightarrow> subcocycle_lim_ereal (\<lambda>n x. u n x + v n x) x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF subcocycle_add[OF assms]])
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF assms(1)])
   moreover have "AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal v x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF assms(2)])
   moreover
   {
     fix x assume H: "(\<lambda>n. (u n x + v n x)/n) \<longlonglongrightarrow> subcocycle_lim_ereal (\<lambda>n x. u n x + v n x) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
                     "(\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal v x"
     have *: "(u n x + v n x)/n = ereal (u n x / n) + (v n x / n)" for n
       by (simp add: add_divide_distrib)
     have "(\<lambda>n. (u n x + v n x)/n) \<longlonglongrightarrow> subcocycle_lim_ereal u x + subcocycle_lim_ereal v x"
       unfolding * apply (intro tendsto_intros H(2) H(3)) using subcocycle_lim_ereal_not_PInf by auto
     then have "subcocycle_lim_ereal (\<lambda>n x. u n x + v n x) x = subcocycle_lim_ereal u x + subcocycle_lim_ereal v x"
       using H(1) by (simp add: LIMSEQ_unique)
   }
   ultimately show ?thesis by auto
 qed
 
 lemma subcocycle_lim_ereal_cmult:
   assumes "subcocycle u" "c\<ge>(0::real)"
   shows "AE x in M. subcocycle_lim_ereal (\<lambda>n x. c * u n x) x = c * subcocycle_lim_ereal u x"
 proof -
   have "AE x in M. (\<lambda>n. (c * u n x)/n) \<longlonglongrightarrow> subcocycle_lim_ereal (\<lambda>n x. c * u n x) x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF subcocycle_cmult[OF assms]])
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF assms(1)])
   moreover
   {
     fix x assume H: "(\<lambda>n. (c * u n x)/n) \<longlonglongrightarrow> subcocycle_lim_ereal (\<lambda>n x. c * u n x) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     have "(\<lambda>n. c * ereal (u n x / n)) \<longlonglongrightarrow> c * subcocycle_lim_ereal u x"
       by (rule tendsto_cmult_ereal[OF _ H(2)], auto)
     then have "subcocycle_lim_ereal (\<lambda>n x. c * u n x) x = c * subcocycle_lim_ereal u x"
       using H(1) by (simp add: LIMSEQ_unique)
   }
   ultimately show ?thesis by auto
 qed
 
 lemma subcocycle_lim_ereal_max:
   assumes "subcocycle u" "subcocycle v"
   shows "AE x in M. subcocycle_lim_ereal (\<lambda>n x. max (u n x) (v n x)) x
                     = max (subcocycle_lim_ereal u x) (subcocycle_lim_ereal v x)"
 proof -
   have "AE x in M. (\<lambda>n. max (u n x) (v n x) / n) \<longlonglongrightarrow> subcocycle_lim_ereal (\<lambda>n x. max (u n x) (v n x)) x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF subcocycle_max[OF assms]])
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF assms(1)])
   moreover have "AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal v x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF assms(2)])
   moreover
   {
     fix x assume H: "(\<lambda>n. max (u n x) (v n x) / n) \<longlonglongrightarrow> subcocycle_lim_ereal (\<lambda>n x. max (u n x) (v n x)) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
                     "(\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal v x"
     have "(\<lambda>n. max (ereal(u n x / n)) (ereal(v n x / n)))
             \<longlonglongrightarrow> max (subcocycle_lim_ereal u x) (subcocycle_lim_ereal v x)"
       apply (rule tendsto_max) using H by auto
     moreover have "max (ereal(u n x / n)) (ereal(v n x / n)) = max (u n x) (v n x) / n" for n
       by (simp del: ereal_max add:ereal_max[symmetric] max_divide_distrib_right)
     ultimately have "(\<lambda>n. max (u n x) (v n x) / n)
           \<longlonglongrightarrow> max (subcocycle_lim_ereal u x) (subcocycle_lim_ereal v x)"
       by auto
     then have "subcocycle_lim_ereal (\<lambda>n x. max (u n x) (v n x)) x
                 = max (subcocycle_lim_ereal u x) (subcocycle_lim_ereal v x)"
       using H(1) by (simp add: LIMSEQ_unique)
   }
   ultimately show ?thesis by auto
 qed
 
 lemma subcocycle_lim_ereal_birkhoff:
   assumes "integrable M u"
   shows "AE x in M. subcocycle_lim_ereal (birkhoff_sum u) x = ereal(real_cond_exp M Invariants u x)"
 proof -
   have "AE x in M. (\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants u x"
     by (rule birkhoff_theorem_AE_nonergodic[OF assms])
   moreover have "AE x in M. (\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal (birkhoff_sum u) x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF subcocycle_birkhoff[OF assms]])
   moreover
   {
     fix x assume H: "(\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants u x"
                     "(\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal (birkhoff_sum u) x"
     have "(\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> ereal(real_cond_exp M Invariants u x)"
       using H(1) by auto
     then have "subcocycle_lim_ereal (birkhoff_sum u) x = ereal(real_cond_exp M Invariants u x)"
       using H(2) by (simp add: LIMSEQ_unique)
   }
   ultimately show ?thesis by auto
 qed
 
 
 subsection \<open>$L^1$ and a.e.\ convergence of subcocycles with finite asymptotic average\<close>
 
 text \<open>In this subsection, we show that the almost sure convergence in Kingman theorem
 also takes place in $L^1$ if the limit is integrable, i.e., if the asymptotic average
 of the subcocycle is $> -\infty$. To deduce it from the almost sure convergence, we only need
 to show that there is no loss of mass, i.e., that the integral of the limit is not
 strictly larger than the limit of the integrals (thanks to Scheffe criterion). This follows
 from comparison to Birkhoff sums, for which we know that the average of the limit is
 the same as the average of the function.\<close>
 
 text \<open>First, we show that the subcocycle limit is bounded by the limit of the Birkhoff sums of
 $u_N$, i.e., its conditional expectation. This follows from the fact that $u_n$ is bounded by the
 Birkhoff sum of $u_N$ (up to negligible boundary terms).\<close>
 
 lemma subcocycle_lim_ereal_atmost_uN_invariants:
   assumes "subcocycle u" "N>(0::nat)"
   shows "AE x in M. subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
 proof -
   have "AE x in M. (\<lambda>n. u 1 ((T^^n) x) / n) \<longlonglongrightarrow> 0"
     apply (rule limit_foTn_over_n') using assms(1) unfolding subcocycle_def by auto
   moreover have "AE x in M. (\<lambda>n. birkhoff_sum (\<lambda>x. u N x/N) n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
     apply (rule birkhoff_theorem_AE_nonergodic) using assms(1) unfolding subcocycle_def by auto
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     by (rule kingman_theorem_AE_nonergodic_ereal[OF assms(1)])
   moreover
   {
     fix x assume H: "(\<lambda>n. u 1 ((T^^n) x) / n) \<longlonglongrightarrow> 0"
                     "(\<lambda>n. birkhoff_sum (\<lambda>x. u N x/N) n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
 
     let ?f = "\<lambda>n. birkhoff_sum (\<lambda>x. u N x / real N) (n - 2 * N) x / n
                   + (\<Sum>i<N. (1/n) * \<bar>u 1 ((T ^^ i) x)\<bar>)
                   + 2 * (\<Sum>i<2*N. \<bar>u 1 ((T ^^ (n - (2 * N - i))) x)\<bar> / n)"
     {
       fix n assume "n\<ge>2*N+1"
       then have "n > 2 * N" by simp
       have "u n x / n \<le> (birkhoff_sum (\<lambda>x. u N x / real N) (n - 2 * N) x
                   + (\<Sum>i<N. \<bar>u 1 ((T ^^ i) x)\<bar>)
                   + 2 * (\<Sum>i<2*N. \<bar>u 1 ((T ^^ (n - (2 * N - i))) x)\<bar>)) / n"
         using subcocycle_bounded_by_birkhoffN[OF assms(1) \<open>n>2*N\<close> \<open>N>0\<close>, of x] \<open>n>2*N\<close> by (simp add: divide_right_mono)
       also have "... = ?f n"
         apply (subst add_divide_distrib)+ by (auto simp add: sum_divide_distrib[symmetric])
       finally have "u n x / n \<le> ?f n" by simp
       then have "u n x / n \<le> ereal(?f n)" by simp
     }
 
     have "(\<lambda>n. ?f n) \<longlonglongrightarrow> real_cond_exp M Invariants (\<lambda>x. u N x / N) x + (\<Sum>i<N. 0 * \<bar>u 1 ((T ^^ i) x)\<bar>) + 2 * (\<Sum>i<2*N. 0)"
       apply (intro tendsto_intros) using H(2) tendsto_norm[OF H(1)] by auto
     then have "(\<lambda>n. ereal(?f n)) \<longlonglongrightarrow> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
       by auto
     with lim_mono[OF \<open>\<And>n. n \<ge> 2*N+1 \<Longrightarrow> u n x / n \<le> ereal(?f n)\<close> H(3) this]
     have "subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x" by simp
   }
   ultimately show ?thesis by auto
 qed
 
 text \<open>To apply Scheffe criterion, we need to deal with nonnegative functions, or equivalently
 with nonpositive functions after a change of sign. Hence, as in the proof of the almost
 sure version of Kingman theorem above, we first give the proof assuming that the
 subcocycle is nonpositive, and deduce the general statement by adding a suitable
 Birkhoff sum.\<close>
 
 lemma kingman_theorem_L1_aux:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>" "\<And>x. u 1 x \<le> 0"
   shows "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
         "integrable M (subcocycle_lim u)"
         "(\<lambda>n. (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)) \<longlonglongrightarrow> 0"
 proof -
   have int_u [measurable]: "\<And>n. integrable M (u n)" using assms(1) subcocycle_def by auto
   then have int_F [measurable]: "\<And>n. integrable M (\<lambda>x. - u n x/ n)" by auto
 
   have F_pos: "- u n x / n \<ge> 0" for x n
   proof (cases "n > 0")
     case True
     have "u n x \<le> (\<Sum>i<n. u 1 ((T ^^ i) x))"
       using subcocycle_bounded_by_birkhoff1[OF assms(1) \<open>n>0\<close>] unfolding birkhoff_sum_def by simp
     also have "... \<le> 0" using sum_mono[OF assms(3)] by auto
     finally have "u n x \<le> 0" by simp
     then have "-u n x \<ge> 0" by simp
     with divide_nonneg_nonneg[OF this] show "- u n x / n \<ge> 0" using \<open>n>0\<close> by auto
   qed (auto)
 
   {
     fix x assume *: "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     have H: "(\<lambda>n. - u n x / n) \<longlonglongrightarrow> - subcocycle_lim_ereal u x"
       using tendsto_cmult_ereal[OF _ *, of "-1"] by auto
     have "liminf (\<lambda>n. -u n x / n) = - subcocycle_lim_ereal u x"
          "(\<lambda>n. - u n x / n) \<longlonglongrightarrow> - subcocycle_lim_ereal u x"
          "- subcocycle_lim_ereal u x \<ge> 0"
       using H apply (simp add: tendsto_iff_Liminf_eq_Limsup, simp)
       apply (rule LIMSEQ_le_const[OF H]) using F_pos by auto
   }
   then have AE_1: "AE x in M. liminf (\<lambda>n. -u n x / n) = - subcocycle_lim_ereal u x"
                   "AE x in M. (\<lambda>n. - u n x / n) \<longlonglongrightarrow> - subcocycle_lim_ereal u x"
                   "AE x in M. - subcocycle_lim_ereal u x \<ge> 0"
     using kingman_theorem_AE_nonergodic_ereal[OF assms(1)] by auto
 
   have "(\<integral>\<^sup>+ x. -subcocycle_lim_ereal u x \<partial>M) = (\<integral>\<^sup>+ x. liminf (\<lambda>n. -u n x / n) \<partial>M)"
     apply (rule nn_integral_cong_AE) using AE_1(1) by auto
   also have "... \<le> liminf (\<lambda>n. \<integral>\<^sup>+ x. -u n x / n \<partial>M)"
     apply (subst e2ennreal_Liminf)
     apply (simp_all add: e2ennreal_ereal)
     using F_pos by (intro nn_integral_liminf) (simp add: int_F)
   also have "... = - subcocycle_avg_ereal u"
   proof -
     have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal u"
       by (rule subcocycle_int_tendsto_avg_ereal[OF assms(1)])
     with tendsto_cmult_ereal[OF _ this, of "-1"]
     have "(\<lambda>n. (\<integral>x. - u n x / n \<partial>M)) \<longlonglongrightarrow> - subcocycle_avg_ereal u" by simp
     then have "- subcocycle_avg_ereal u = liminf (\<lambda>n. (\<integral>x. - u n x / n \<partial>M))"
       by (simp add: tendsto_iff_Liminf_eq_Limsup)
     moreover have "(\<integral>\<^sup>+ x. ennreal (-u n x / n) \<partial>M) = ennreal(\<integral>x. - u n x / n \<partial>M)" for n
       apply (rule nn_integral_eq_integral[OF int_F]) using F_pos by auto
     ultimately show ?thesis
       by (auto simp: e2ennreal_Liminf e2ennreal_ereal)
   qed
   finally have "(\<integral>\<^sup>+ x. -subcocycle_lim_ereal u x \<partial>M) \<le> - subcocycle_avg_ereal u" by simp
   also have "\<dots> < \<infinity>" using assms(2)
     by (cases "subcocycle_avg_ereal u") (auto simp: e2ennreal_ereal e2ennreal_neg)
   finally have *: "(\<integral>\<^sup>+ x. -subcocycle_lim_ereal u x \<partial>M) < \<infinity>" .
   have "AE x in M. e2ennreal (- subcocycle_lim_ereal u x) \<noteq> \<infinity>"
     apply (rule nn_integral_PInf_AE) using * by auto
   then have **: "AE x in M. - subcocycle_lim_ereal u x \<noteq> \<infinity>"
     using AE_1(3) by eventually_elim simp
 
   {
     fix x assume H: "- subcocycle_lim_ereal u x \<noteq> \<infinity>"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
                     "- subcocycle_lim_ereal u x \<ge> 0"
     then have 1: "abs(subcocycle_lim_ereal u x) \<noteq> \<infinity>" by auto
     then have 2: "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x" using H(2) unfolding subcocycle_lim_def by auto
     then have 3: "(\<lambda>n. - (u n x / n)) \<longlonglongrightarrow> - subcocycle_lim u x" using tendsto_mult[OF _ 2, of "\<lambda>_. -1", of "-1"] by auto
     have 4: "-subcocycle_lim u x \<ge> 0" using H(3) unfolding subcocycle_lim_def by auto
 
     have "abs(subcocycle_lim_ereal u x) \<noteq> \<infinity>"
          "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
          "(\<lambda>n. - (u n x / n)) \<longlonglongrightarrow> - subcocycle_lim u x"
          "-subcocycle_lim u x \<ge> 0"
       using 1 2 3 4 by auto
   }
   then have AE_2: "AE x in M. abs(subcocycle_lim_ereal u x) \<noteq> \<infinity>"
                   "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
                   "AE x in M. (\<lambda>n. - (u n x / n)) \<longlonglongrightarrow> - subcocycle_lim u x"
                   "AE x in M. -subcocycle_lim u x \<ge> 0"
     using kingman_theorem_AE_nonergodic_ereal[OF assms(1)] ** AE_1(3) by auto
   then show "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x" by simp
 
   have "(\<integral>\<^sup>+x. abs(subcocycle_lim u x) \<partial>M) = (\<integral>\<^sup>+x. -subcocycle_lim_ereal u x \<partial>M)"
     apply (rule nn_integral_cong_AE)
     using AE_2 unfolding subcocycle_lim_def abs_real_of_ereal
     apply eventually_elim
     by (auto simp: e2ennreal_ereal)
   then have A: "(\<integral>\<^sup>+x. abs(subcocycle_lim u x) \<partial>M) < \<infinity>" using * by auto
   show int_Gr: "integrable M (subcocycle_lim u)"
     apply (rule integrableI_bounded) using A by auto
 
   have B: "(\<lambda>n. (\<integral>\<^sup>+ x. norm((- u n x /n) - (-subcocycle_lim u x)) \<partial>M)) \<longlonglongrightarrow> 0"
   proof (rule Scheffe_lemma1, auto simp add: int_Gr int_u AE_2(2) AE_2(3))
     {
       fix n assume "n>(0::nat)"
       have *: "AE x in M. subcocycle_lim u x \<le> real_cond_exp M Invariants (\<lambda>x. u n x / n) x"
         using subcocycle_lim_ereal_atmost_uN_invariants[OF assms(1) \<open>n>0\<close>] AE_2(1)
         unfolding subcocycle_lim_def by auto
       have "(\<integral>x. subcocycle_lim u x \<partial>M) \<le> (\<integral>x. real_cond_exp M Invariants (\<lambda>x. u n x / n) x \<partial>M)"
         apply (rule integral_mono_AE[OF int_Gr _ *], rule real_cond_exp_int(1)) using int_u by auto
       also have "... = (\<integral>x. u n x / n \<partial>M)" apply (rule real_cond_exp_int(2)) using int_u by auto
       finally have A: "(\<integral>x. subcocycle_lim u x \<partial>M) \<le> (\<integral>x. u n x / n \<partial>M)" by auto
 
       have "(\<integral>\<^sup>+x. abs(u n x) / n \<partial>M) = (\<integral>\<^sup>+x. - u n x / n \<partial>M)"
         apply (rule nn_integral_cong) using F_pos abs_of_nonneg by (intro arg_cong[where f = ennreal]) fastforce
       also have "... = (\<integral>x. - u n x / n \<partial>M)"
         apply (rule nn_integral_eq_integral) using F_pos int_F by auto
       also have "... \<le> (\<integral>x. - subcocycle_lim u x \<partial>M)" using A by (auto intro!: ennreal_leI)
       also have "... = (\<integral>\<^sup>+x. - subcocycle_lim u x \<partial>M)"
         apply (rule nn_integral_eq_integral[symmetric]) using int_Gr AE_2(4) by auto
       also have "... = (\<integral>\<^sup>+x. abs(subcocycle_lim u x) \<partial>M)"
         apply (rule nn_integral_cong_AE) using AE_2(4) by auto
       finally have "(\<integral>\<^sup>+x. abs(u n x) / n \<partial>M) \<le> (\<integral>\<^sup>+x. abs(subcocycle_lim u x) \<partial>M)" by simp
     }
     with eventually_mono[OF eventually_gt_at_top[of 0] this]
     have "eventually (\<lambda>n. (\<integral>\<^sup>+x. abs(u n x) / n \<partial>M) \<le> (\<integral>\<^sup>+x. abs(subcocycle_lim u x) \<partial>M)) sequentially"
       by fastforce
     then show "limsup (\<lambda>n. \<integral>\<^sup>+ x. abs(u n x) / n \<partial>M) \<le> \<integral>\<^sup>+ x. abs(subcocycle_lim u x) \<partial>M"
       using Limsup_bounded by fastforce
   qed
   moreover have "norm((- u n x /n) - (-subcocycle_lim u x)) = abs(u n x / n - subcocycle_lim u x)"
     for n x by auto
   ultimately show "(\<lambda>n. \<integral>\<^sup>+ x. ennreal \<bar>u n x / real n - subcocycle_lim u x\<bar> \<partial>M) \<longlonglongrightarrow> 0"
     by auto
 qed
 
 text \<open>We can then remove the nonpositivity assumption, by subtracting the Birkhoff sums of $u_1$
 to a general subcocycle $u$.\<close>
 
 theorem kingman_theorem_nonergodic:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>"
   shows "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
         "integrable M (subcocycle_lim u)"
         "(\<lambda>n. (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)) \<longlonglongrightarrow> 0"
 proof -
   have [measurable]: "u n \<in> borel_measurable M" for n using assms(1) unfolding subcocycle_def by auto
   have int_u [measurable]: "integrable M (u 1)" using assms(1) subcocycle_def by auto
   define v where "v = (\<lambda>n x. u n x + birkhoff_sum (\<lambda>x. - u 1 x) n x)"
   have [measurable]: "v n \<in> borel_measurable M" for n unfolding v_def by auto
   define w where "w = birkhoff_sum (u 1)"
   have [measurable]: "w n \<in> borel_measurable M" for n unfolding w_def by auto
   have "subcocycle v" unfolding v_def
     apply (rule subcocycle_add[OF assms(1)], rule subcocycle_birkhoff)
     using assms unfolding subcocycle_def by auto
   have "subcocycle w" unfolding w_def by (rule subcocycle_birkhoff[OF int_u])
   have uvw: "u n x = v n x + w n x" for n x
     unfolding v_def w_def birkhoff_sum_def by (auto simp add: sum_negf)
   then have "subcocycle_avg_ereal (\<lambda>n x. u n x) = subcocycle_avg_ereal v + subcocycle_avg_ereal w"
     using subcocycle_avg_ereal_add[OF \<open>subcocycle v\<close> \<open>subcocycle w\<close>] by auto
   then have "subcocycle_avg_ereal u = subcocycle_avg_ereal v + subcocycle_avg_ereal w"
     by auto
   then have "subcocycle_avg_ereal v > -\<infinity>"
     unfolding w_def using subcocycle_avg_ereal_birkhoff[OF int_u] assms(2) by auto
   have "subcocycle_avg_ereal w > - \<infinity>"
     unfolding w_def using subcocycle_avg_birkhoff[OF int_u] by auto
 
   have "\<And>x. v 1 x \<le> 0" unfolding v_def by auto
   have v: "AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim v x"
             "integrable M (subcocycle_lim v)"
             "(\<lambda>n. (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M)) \<longlonglongrightarrow> 0"
     using kingman_theorem_L1_aux[OF \<open>subcocycle v\<close> \<open>subcocycle_avg_ereal v > -\<infinity>\<close> \<open>\<And>x. v 1 x \<le> 0\<close>] by auto
   have w: "AE x in M. (\<lambda>n. w n x / n) \<longlonglongrightarrow> subcocycle_lim w x"
             "integrable M (subcocycle_lim w)"
             "(\<lambda>n. (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)) \<longlonglongrightarrow> 0"
   proof -
     show "AE x in M. (\<lambda>n. w n x / n) \<longlonglongrightarrow> subcocycle_lim w x"
       unfolding w_def subcocycle_lim_def using subcocycle_lim_ereal_birkhoff[OF int_u]
       birkhoff_theorem_AE_nonergodic[OF int_u] by auto
     show "integrable M (subcocycle_lim w)"
       apply (subst integrable_cong_AE[where ?g = "\<lambda>x. real_cond_exp M Invariants (u 1) x"])
       unfolding w_def subcocycle_lim_def
       using subcocycle_lim_ereal_birkhoff[OF int_u] real_cond_exp_int(1)[OF int_u] by auto
     have "(\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)
         = (\<integral>\<^sup>+x. abs(birkhoff_sum (u 1) n x / n - real_cond_exp M Invariants (u 1) x) \<partial>M)" for n
       apply (rule nn_integral_cong_AE)
       unfolding w_def subcocycle_lim_def using subcocycle_lim_ereal_birkhoff[OF int_u] by auto
     then show "(\<lambda>n. (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)) \<longlonglongrightarrow> 0"
       using birkhoff_theorem_L1_nonergodic[OF int_u] by auto
   qed
 
   {
     fix x assume H: "(\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim v x"
                     "(\<lambda>n. w n x / n) \<longlonglongrightarrow> subcocycle_lim w x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     then have "(\<lambda>n. v n x / n + w n x / n) \<longlonglongrightarrow> subcocycle_lim v x + subcocycle_lim w x"
       using tendsto_add[OF H(1) H(2)] by simp
     then have *: "(\<lambda>n. ereal(u n x / n)) \<longlonglongrightarrow> ereal(subcocycle_lim v x + subcocycle_lim w x)"
       unfolding uvw by (simp add: add_divide_distrib)
     then have "subcocycle_lim_ereal u x = ereal(subcocycle_lim v x + subcocycle_lim w x)"
       using H(3) LIMSEQ_unique by blast
     then have **: "subcocycle_lim u x = subcocycle_lim v x + subcocycle_lim w x"
       using subcocycle_lim_def by auto
     have "u n x / n - subcocycle_lim u x = v n x / n - subcocycle_lim v x + w n x / n - subcocycle_lim w x" for n
       apply (subst **, subst uvw) using add_divide_distrib add.commute by auto
     then have "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x
           \<and> subcocycle_lim u x = subcocycle_lim v x + subcocycle_lim w x
           \<and> (\<forall>n. u n x / n - subcocycle_lim u x = v n x / n - subcocycle_lim v x + w n x / n - subcocycle_lim w x)"
       using * ** by auto
   }
   then have AE: "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
                 "AE x in M. subcocycle_lim u x = subcocycle_lim v x + subcocycle_lim w x"
                 "AE x in M. \<forall>n. u n x / n - subcocycle_lim u x = v n x / n - subcocycle_lim v x + w n x / n - subcocycle_lim w x"
     using v(1) w(1) kingman_theorem_AE_nonergodic_ereal[OF assms(1)] by auto
   then show "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x" by simp
   show "integrable M (subcocycle_lim u)"
     apply (subst integrable_cong_AE[where ?g = "\<lambda>x. subcocycle_lim v x + subcocycle_lim w x"])
     by (auto simp add: AE(2) v(2) w(2))
 
   show "(\<lambda>n. (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)) \<longlonglongrightarrow> 0"
   proof (rule tendsto_sandwich[where ?f = "\<lambda>_. 0"
     and ?h = "\<lambda>n. (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M) + (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)"], auto)
     {
       fix n
       have "(\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)
         = (\<integral>\<^sup>+x. abs((v n x / n - subcocycle_lim v x) + (w n x / n - subcocycle_lim w x)) \<partial>M)"
         apply (rule nn_integral_cong_AE) using AE(3) by auto
       also have "... \<le> (\<integral>\<^sup>+x. ennreal(abs(v n x / n - subcocycle_lim v x)) + abs(w n x / n - subcocycle_lim w x) \<partial>M)"
         by (rule nn_integral_mono, auto simp add: ennreal_plus[symmetric] simp del: ennreal_plus)
       also have "... = (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M) + (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)"
         by (rule nn_integral_add, auto, measurable)
       finally have "(\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)
         \<le> (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M) + (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)"
         using tendsto_sandwich by simp
     }
     then show "eventually (\<lambda>n. (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)
         \<le> (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M) + (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M)) sequentially"
       by auto
 
     have "(\<lambda>n. (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M) + (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M))
               \<longlonglongrightarrow> 0 + 0"
       by (rule tendsto_add[OF v(3) w(3)])
     then show "(\<lambda>n. (\<integral>\<^sup>+x. abs(v n x / n - subcocycle_lim v x) \<partial>M) + (\<integral>\<^sup>+x. abs(w n x / n - subcocycle_lim w x) \<partial>M))
               \<longlonglongrightarrow> 0"
       by simp
   qed
 qed
 
 text \<open>From the almost sure convergence, we can prove the basic properties of the (real)
 subcocycle limit: relationship to the asymptotic average, behavior under sum, multiplication,
 max, behavior for Birkhoff sums.\<close>
 
 lemma subcocycle_lim_avg:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>"
   shows "(\<integral>x. subcocycle_lim u x \<partial>M) = subcocycle_avg u"
 proof -
   have H: "(\<lambda>n. (\<integral>\<^sup>+x. norm(u n x / n - subcocycle_lim u x) \<partial>M)) \<longlonglongrightarrow> 0"
           "integrable M (subcocycle_lim u)"
     using kingman_theorem_nonergodic[OF assms] by auto
   have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> (\<integral>x. subcocycle_lim u x \<partial>M)"
     apply (rule tendsto_L1_int[OF _ H(2) H(1)]) using subcocycle_integrable[OF assms(1)] by auto
   then have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> ereal (\<integral>x. subcocycle_lim u x \<partial>M)" by auto
   moreover have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> ereal (subcocycle_avg u)"
     using subcocycle_int_tendsto_avg[OF assms] by auto
   ultimately show ?thesis using LIMSEQ_unique by blast
 qed
 
 lemma subcocycle_lim_real_ereal:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>"
   shows "AE x in M. subcocycle_lim_ereal u x = ereal(subcocycle_lim u x)"
 proof -
   {
     fix x assume H: "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
     then have "(\<lambda>n. u n x / n) \<longlonglongrightarrow> ereal(subcocycle_lim u x)" by auto
     then have "subcocycle_lim_ereal u x = ereal(subcocycle_lim u x)"
       using H(1) LIMSEQ_unique by blast
   }
   then show ?thesis
     using kingman_theorem_AE_nonergodic_ereal[OF assms(1)] kingman_theorem_nonergodic(1)[OF assms] by auto
 qed
 
 lemma subcocycle_lim_add:
   assumes "subcocycle u" "subcocycle v" "subcocycle_avg_ereal u > -\<infinity>" "subcocycle_avg_ereal v > -\<infinity>"
   shows "subcocycle_avg_ereal (\<lambda>n x. u n x + v n x) > - \<infinity>"
         "AE x in M. subcocycle_lim (\<lambda>n x. u n x + v n x) x = subcocycle_lim u x + subcocycle_lim v x"
 proof -
   show *: "subcocycle_avg_ereal (\<lambda>n x. u n x + v n x) > - \<infinity>"
     using subcocycle_avg_add[OF assms(1) assms(2)] assms(3) assms(4) by auto
   have "AE x in M. (\<lambda>n. (u n x + v n x)/n) \<longlonglongrightarrow> subcocycle_lim (\<lambda>n x. u n x + v n x) x"
     by (rule kingman_theorem_nonergodic(1)[OF subcocycle_add[OF assms(1) assms(2)] *])
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
     by (rule kingman_theorem_nonergodic[OF assms(1) assms(3)])
   moreover have "AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim v x"
     by (rule kingman_theorem_nonergodic[OF assms(2) assms(4)])
   moreover
   {
     fix x assume H: "(\<lambda>n. (u n x + v n x)/n) \<longlonglongrightarrow> subcocycle_lim (\<lambda>n x. u n x + v n x) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
                     "(\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim v x"
     have *: "(u n x + v n x)/n = (u n x / n) + (v n x / n)" for n
       by (simp add: add_divide_distrib)
     have "(\<lambda>n. (u n x + v n x)/n) \<longlonglongrightarrow> subcocycle_lim u x + subcocycle_lim v x"
       unfolding * by (intro tendsto_intros H)
     then have "subcocycle_lim (\<lambda>n x. u n x + v n x) x = subcocycle_lim u x + subcocycle_lim v x"
       using H(1) by (simp add: LIMSEQ_unique)
   }
   ultimately show "AE x in M. subcocycle_lim (\<lambda>n x. u n x + v n x) x
                     = subcocycle_lim u x + subcocycle_lim v x"
     by auto
 qed
 
 lemma subcocycle_lim_cmult:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>" "c\<ge>(0::real)"
   shows "subcocycle_avg_ereal (\<lambda>n x. c * u n x) > - \<infinity>"
         "AE x in M. subcocycle_lim (\<lambda>n x. c * u n x) x = c * subcocycle_lim u x"
 proof -
   show *: "subcocycle_avg_ereal (\<lambda>n x. c * u n x) > - \<infinity>"
     using subcocycle_avg_cmult[OF assms(1) assms(3)] assms(2) assms(3) by auto
 
   have "AE x in M. (\<lambda>n. (c * u n x)/n) \<longlonglongrightarrow> subcocycle_lim (\<lambda>n x. c * u n x) x"
     by (rule kingman_theorem_nonergodic(1)[OF subcocycle_cmult[OF assms(1) assms(3)] *])
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
     by (rule kingman_theorem_nonergodic(1)[OF assms(1) assms(2)])
   moreover
   {
     fix x assume H: "(\<lambda>n. (c * u n x)/n) \<longlonglongrightarrow> subcocycle_lim (\<lambda>n x. c * u n x) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
     have "(\<lambda>n. c * (u n x / n)) \<longlonglongrightarrow> c * subcocycle_lim u x"
       by (rule tendsto_mult[OF _ H(2)], auto)
     then have "subcocycle_lim (\<lambda>n x. c * u n x) x = c * subcocycle_lim u x"
       using H(1) by (simp add: LIMSEQ_unique)
   }
   ultimately show "AE x in M. subcocycle_lim (\<lambda>n x. c * u n x) x = c * subcocycle_lim u x" by auto
 qed
 
 lemma subcocycle_lim_max:
   assumes "subcocycle u" "subcocycle v" "subcocycle_avg_ereal u > -\<infinity>" "subcocycle_avg_ereal v > -\<infinity>"
   shows "subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x)) > - \<infinity>"
         "AE x in M. subcocycle_lim (\<lambda>n x. max (u n x) (v n x)) x = max (subcocycle_lim u x) (subcocycle_lim v x)"
 proof -
   show *: "subcocycle_avg_ereal (\<lambda>n x. max (u n x) (v n x)) > - \<infinity>"
     using subcocycle_avg_max(1)[OF assms(1) assms(2)] assms(3) assms(4) by auto
   have "AE x in M. (\<lambda>n. max (u n x) (v n x) / n) \<longlonglongrightarrow> subcocycle_lim (\<lambda>n x. max (u n x) (v n x)) x"
     by (rule kingman_theorem_nonergodic[OF subcocycle_max[OF assms(1) assms(2)] *])
   moreover have "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
     by (rule kingman_theorem_nonergodic[OF assms(1) assms(3)])
   moreover have "AE x in M. (\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim v x"
     by (rule kingman_theorem_nonergodic[OF assms(2) assms(4)])
   moreover
   {
     fix x assume H: "(\<lambda>n. max (u n x) (v n x) / n) \<longlonglongrightarrow> subcocycle_lim (\<lambda>n x. max (u n x) (v n x)) x"
                     "(\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_lim u x"
                     "(\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim v x"
     have "(\<lambda>n. max (u n x / n) (v n x / n)) \<longlonglongrightarrow> max (subcocycle_lim u x) (subcocycle_lim v x)"
       apply (rule tendsto_max) using H by auto
     moreover have "max (u n x / n) (v n x / n) = max (u n x) (v n x) / n" for n
       by (simp add: max_divide_distrib_right)
     ultimately have "(\<lambda>n. max (u n x) (v n x) / n) \<longlonglongrightarrow> max (subcocycle_lim u x) (subcocycle_lim v x)"
       by auto
     then have "subcocycle_lim (\<lambda>n x. max (u n x) (v n x)) x = max (subcocycle_lim u x) (subcocycle_lim v x)"
       using H(1) by (simp add: LIMSEQ_unique)
   }
   ultimately show "AE x in M. subcocycle_lim (\<lambda>n x. max (u n x) (v n x)) x
                     = max (subcocycle_lim u x) (subcocycle_lim v x)" by auto
 qed
 
 lemma subcocycle_lim_birkhoff:
   assumes "integrable M u"
   shows "subcocycle_avg_ereal (birkhoff_sum u) > -\<infinity>"
         "AE x in M. subcocycle_lim (birkhoff_sum u) x = real_cond_exp M Invariants u x"
 proof -
   show *: "subcocycle_avg_ereal (birkhoff_sum u) > -\<infinity>"
     using subcocycle_avg_birkhoff[OF assms] by auto
   have "AE x in M. (\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants u x"
     by (rule birkhoff_theorem_AE_nonergodic[OF assms])
   moreover have "AE x in M. (\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> subcocycle_lim (birkhoff_sum u) x"
     by (rule kingman_theorem_nonergodic(1)[OF subcocycle_birkhoff[OF assms] *])
   moreover
   {
     fix x assume H: "(\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> real_cond_exp M Invariants u x"
                     "(\<lambda>n. birkhoff_sum u n x / n) \<longlonglongrightarrow> subcocycle_lim (birkhoff_sum u) x"
     then have "subcocycle_lim (birkhoff_sum u) x = real_cond_exp M Invariants u x"
       using H(2) by (simp add: LIMSEQ_unique)
   }
   ultimately show "AE x in M. subcocycle_lim (birkhoff_sum u) x = real_cond_exp M Invariants u x" by auto
 qed
 
 
 subsection \<open>Conditional expectations of subcocycles\<close>
 
 text \<open>In this subsection, we show that the conditional expectations of a subcocycle
 (with respect to the invariant subalgebra) also converge, with the same limit as the
 cocycle.
 
 Note that the conditional expectation of a subcocycle $u$ is still a subcocycle, with the
 same average at each step so with the same asymptotic average. Kingman theorem can be applied to
 it, and what we have to show is that the limit of this subcocycle is the same as the limit
 of the original subcocycle.
 
 When the asymptotic average is $>-\infty$, both limits have the same integral, and moreover
 the domination of the subcocycle by the Birkhoff sums of $u_n$ for fixed $n$
 (which converge to the conditional expectation of $u_n$) implies that one limit is smaller than
 the other. Hence, they coincide almost everywhere.
 
 The case when the asymptotic average is $-\infty$ is deduced from the previous one by truncation.
 \<close>
 
 text \<open>First, we prove the result when the asymptotic average with finite.\<close>
 
 theorem kingman_theorem_nonergodic_invariant:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>"
   shows "AE x in M. (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim u x"
         "(\<lambda>n. (\<integral>\<^sup>+x. abs(real_cond_exp M Invariants (u n) x / n - subcocycle_lim u x) \<partial>M)) \<longlonglongrightarrow> 0"
 proof -
   have int [simp]: "integrable M (u n)" for n using subcocycle_integrable[OF assms(1)] by auto
   then have int2: "integrable M (real_cond_exp M Invariants (u n))" for n using real_cond_exp_int by auto
   {
     fix n m
     have "u (n+m) x \<le> u n x + u m ((T^^n) x)" for x
       using subcocycle_ineq[OF assms(1)] by auto
     have "AE x in M. real_cond_exp M Invariants (u (n+m)) x \<le> real_cond_exp M Invariants (\<lambda>x. u n x + u m ((T^^n) x)) x"
       apply (rule real_cond_exp_mono)
       using subcocycle_ineq[OF assms(1)] apply auto
       by (rule Bochner_Integration.integrable_add, auto simp add: Tn_integral_preserving)
     moreover have "AE x in M. real_cond_exp M Invariants (\<lambda>x. u n x + u m ((T^^n) x)) x
               = real_cond_exp M Invariants (u n) x + real_cond_exp M Invariants (\<lambda>x. u m ((T^^n) x)) x"
       by (rule real_cond_exp_add, auto simp add: Tn_integral_preserving)
     moreover have "AE x in M. real_cond_exp M Invariants (u m \<circ> ((T^^n))) x = real_cond_exp M Invariants (u m) x"
       by (rule Invariants_of_foTn, simp)
     moreover have "AE x in M. real_cond_exp M Invariants (u m) x = real_cond_exp M Invariants (u m) ((T^^n) x)"
       using Invariants_func_is_invariant_n[symmetric, of "real_cond_exp M Invariants (u m)"] by auto
     ultimately have "AE x in M. real_cond_exp M Invariants (u (n+m)) x
         \<le> real_cond_exp M Invariants (u n) x + real_cond_exp M Invariants (u m) ((T^^n) x)"
       unfolding o_def by auto
   }
   with subcocycle_AE[OF this int2]
   obtain w where w: "subcocycle w" "AE x in M. \<forall>n. w n x = real_cond_exp M Invariants (u n) x"
     by blast
   have [measurable]: "integrable M (w n)" for n using subcocycle_integrable[OF w(1)] by simp
 
   {
     fix n::nat
     have "(\<integral>x. w n x / n \<partial>M) = (\<integral>x. real_cond_exp M Invariants (u n) x / n \<partial>M)"
       apply (rule integral_cong_AE) using w(2) by auto
     also have "... = (\<integral>x. real_cond_exp M Invariants (u n) x \<partial>M) / n"
       by (rule integral_divide_zero)
     also have "... = (\<integral>x. u n x \<partial>M) / n"
       by (simp add: divide_simps real_cond_exp_int(2)[OF int[of n]])
     also have "... = (\<integral>x. u n x / n \<partial>M)"
       by (rule integral_divide_zero[symmetric])
     finally have "ereal (\<integral>x. w n x / n \<partial>M) = ereal (\<integral>x. u n x / n \<partial>M)" by simp
   } note * = this
   have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal w"
     apply (rule Lim_transform_eventually[OF subcocycle_int_tendsto_avg_ereal[OF w(1)]])
     using * by auto
   then have "subcocycle_avg_ereal u = subcocycle_avg_ereal w"
     using subcocycle_int_tendsto_avg_ereal[OF assms(1)] LIMSEQ_unique by auto
   then have "subcocycle_avg_ereal w > -\<infinity>" using assms(2) by simp
   have "subcocycle_avg u = subcocycle_avg w"
     using \<open>subcocycle_avg_ereal u = subcocycle_avg_ereal w\<close> unfolding subcocycle_avg_def by simp
 
   have *: "AE x in M. N > 0 \<longrightarrow> subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x" for N
     by (cases "N = 0", auto simp add: subcocycle_lim_ereal_atmost_uN_invariants[OF assms(1)])
   have "AE x in M. \<forall>N. N > 0 \<longrightarrow> subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
     by (subst AE_all_countable, intro allI, simp add: *)
   moreover have "AE x in M. subcocycle_lim_ereal u x = ereal(subcocycle_lim u x)"
     by (rule subcocycle_lim_real_ereal[OF assms])
   moreover have "AE x in M. (\<lambda>N. u N x / N) \<longlonglongrightarrow> subcocycle_lim u x"
     using kingman_theorem_nonergodic[OF assms] by simp
   moreover have "AE x in M. (\<lambda>N. w N x / N) \<longlonglongrightarrow> subcocycle_lim w x"
     using kingman_theorem_nonergodic[OF w(1) \<open>subcocycle_avg_ereal w > -\<infinity>\<close> ] by simp
   moreover have "AE x in M. \<forall>n. w n x = real_cond_exp M Invariants (u n) x"
     using w(2) by simp
   moreover have "AE x in M. \<forall>n. real_cond_exp M Invariants (u n) x / n = real_cond_exp M Invariants (\<lambda>x. u n x / n) x"
     apply (subst AE_all_countable, intro allI) using AE_symmetric[OF real_cond_exp_cdiv[OF int]] by auto
   moreover
   {
     fix x assume x: "\<forall>N. N > 0 \<longrightarrow> subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
                     "subcocycle_lim_ereal u x = ereal(subcocycle_lim u x)"
                     "(\<lambda>N. u N x / N) \<longlonglongrightarrow> subcocycle_lim u x"
                     "(\<lambda>N. w N x / N) \<longlonglongrightarrow> subcocycle_lim w x"
                     "\<forall>n. w n x = real_cond_exp M Invariants (u n) x"
                     "\<forall>n. real_cond_exp M Invariants (u n) x / n = real_cond_exp M Invariants (\<lambda>x. u n x / n) x"
     {
       fix N::nat assume "N\<ge>1"
       have "subcocycle_lim u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
         using x(1) x(2) \<open>N\<ge>1\<close> by auto
       also have "... = real_cond_exp M Invariants (u N) x / N"
         using x(6) by simp
       also have "... = w N x / N"
         using x(5) by simp
       finally have "subcocycle_lim u x \<le> w N x / N"
         by simp
     } note * = this
     have "subcocycle_lim u x \<le> subcocycle_lim w x"
       apply (rule LIMSEQ_le_const[OF x(4)]) using * by auto
   }
   ultimately have *: "AE x in M. subcocycle_lim u x \<le> subcocycle_lim w x"
     by auto
   have **: "(\<integral>x. subcocycle_lim u x \<partial>M) = (\<integral>x. subcocycle_lim w x \<partial>M)"
     using subcocycle_lim_avg[OF assms] subcocycle_lim_avg[OF w(1) \<open>subcocycle_avg_ereal w > -\<infinity>\<close>]
             \<open>subcocycle_avg u = subcocycle_avg w\<close> by simp
   have AE_eq: "AE x in M. subcocycle_lim u x = subcocycle_lim w x"
     by (rule integral_ineq_eq_0_then_AE[OF * kingman_theorem_nonergodic(2)[OF assms]
         kingman_theorem_nonergodic(2)[OF w(1) \<open>subcocycle_avg_ereal w > -\<infinity>\<close>] **])
   moreover have "AE x in M. (\<lambda>n. w n x / n) \<longlonglongrightarrow> subcocycle_lim w x"
     by (rule kingman_theorem_nonergodic(1)[OF w(1) \<open>subcocycle_avg_ereal w > -\<infinity>\<close>])
   moreover have "AE x in M. \<forall>n. w n x = real_cond_exp M Invariants (u n) x"
     using w(2) by auto
   moreover
   {
     fix x assume H: "subcocycle_lim u x = subcocycle_lim w x"
                     "(\<lambda>n. w n x / n) \<longlonglongrightarrow> subcocycle_lim w x"
                     "\<forall>n. w n x = real_cond_exp M Invariants (u n) x"
     then have "(\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim u x"
       by auto
   }
   ultimately show "AE x in M. (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim u x"
     by auto
 
   {
     fix n::nat
     have "AE x in M. subcocycle_lim u x = subcocycle_lim w x"
       using AE_eq by simp
     moreover have "AE x in M. w n x = real_cond_exp M Invariants (u n) x"
       using w(2) by auto
     moreover
     {
       fix x assume H: "subcocycle_lim u x = subcocycle_lim w x"
                     "w n x = real_cond_exp M Invariants (u n) x"
       then have "ennreal \<bar>real_cond_exp M Invariants (u n) x / real n - subcocycle_lim u x\<bar>
                 = ennreal \<bar>w n x / real n - subcocycle_lim w x\<bar>"
       by auto
     }
     ultimately have "AE x in M. ennreal \<bar>real_cond_exp M Invariants (u n) x / real n - subcocycle_lim u x\<bar>
         = ennreal \<bar>w n x / real n - subcocycle_lim w x\<bar>"
       by auto
     then have "(\<integral>\<^sup>+ x. ennreal \<bar>real_cond_exp M Invariants (u n) x / real n - subcocycle_lim u x\<bar> \<partial>M)
               = (\<integral>\<^sup>+ x. ennreal \<bar>w n x / real n - subcocycle_lim w x\<bar> \<partial>M)"
       by (rule nn_integral_cong_AE)
   }
   moreover have "(\<lambda>n. (\<integral>\<^sup>+ x. \<bar>w n x / real n - subcocycle_lim w x\<bar> \<partial>M)) \<longlonglongrightarrow> 0"
     by (rule kingman_theorem_nonergodic(3)[OF w(1) \<open>subcocycle_avg_ereal w > -\<infinity>\<close>])
   ultimately show "(\<lambda>n. (\<integral>\<^sup>+ x. \<bar>real_cond_exp M Invariants (u n) x / real n - subcocycle_lim u x\<bar> \<partial>M)) \<longlonglongrightarrow> 0"
     by auto
 qed
 
 text \<open>Then, we extend it by truncation to the general case, i.e., to the asymptotic
 limit in extended reals.\<close>
 
 theorem kingman_theorem_AE_nonergodic_invariant_ereal:
   assumes "subcocycle u"
   shows "AE x in M. (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
 proof -
   have [simp]: "subcocycle u" using assms by simp
   have int [simp]: "integrable M (u n)" for n using subcocycle_integrable[OF assms(1)] by auto
 
   have limsup_ineq_K: "AE x in M.
     limsup (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<le> max (subcocycle_lim_ereal u x) (-real K)" for K::nat
   proof -
     define v where "v = (\<lambda> (n::nat) (x::'a). (-n * real K))"
     have [simp]: "subcocycle v"
       unfolding v_def subcocycle_def by (auto simp add: algebra_simps)
     have "ereal (\<integral>x. v n x / n \<partial>M) = ereal(- real K * measure M (space M))" if "n\<ge>1" for n
       unfolding v_def using that by simp
     then have "(\<lambda>n. ereal (\<integral>x. v n x / n \<partial>M)) \<longlonglongrightarrow> ereal(- real K * measure M (space M))"
       using lim_explicit by force
     moreover have "(\<lambda>n. ereal (\<integral>x. v n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal v"
       using subcocycle_int_tendsto_avg_ereal[OF \<open>subcocycle v\<close>] by auto
     ultimately have "subcocycle_avg_ereal v = - real K * measure M (space M)"
       using LIMSEQ_unique by blast
     then have "subcocycle_avg_ereal v > -\<infinity>"
       by auto
 
     {
       fix x assume H: "(\<lambda>n. v n x / n) \<longlonglongrightarrow> subcocycle_lim_ereal v x"
       have "ereal(v n x / n) = -real K" if "n\<ge>1" for n
         unfolding v_def using that by auto
       then have "(\<lambda>n. ereal(v n x / n)) \<longlonglongrightarrow> - real K"
         using lim_explicit by force
       then have "subcocycle_lim_ereal v x = -real K"
         using H LIMSEQ_unique by blast
     }
     then have "AE x in M. subcocycle_lim_ereal v x = -real K"
       using kingman_theorem_AE_nonergodic_ereal[OF \<open>subcocycle v\<close>] by auto
 
     define w where "w = (\<lambda>n x. max (u n x) (v n x))"
     have [simp]: "subcocycle w"
       unfolding w_def by (rule subcocycle_max, auto)
     have "subcocycle_avg_ereal w \<ge> subcocycle_avg_ereal v"
       unfolding w_def using subcocycle_avg_ereal_max by auto
     then have "subcocycle_avg_ereal w > -\<infinity>"
       using \<open>subcocycle_avg_ereal v > -\<infinity>\<close> by auto
 
     have *: "AE x in M. real_cond_exp M Invariants (u n) x \<le> real_cond_exp M Invariants (w n) x" for n
       apply (rule real_cond_exp_mono)
       using subcocycle_integrable[OF assms, of n] subcocycle_integrable[OF \<open>subcocycle w\<close>, of n] apply auto
       unfolding w_def by auto
     have "AE x in M. \<forall>n. real_cond_exp M Invariants (u n) x \<le> real_cond_exp M Invariants (w n) x"
       apply (subst AE_all_countable) using * by auto
     moreover have "AE x in M. (\<lambda>n. real_cond_exp M Invariants (w n) x / n) \<longlonglongrightarrow> subcocycle_lim w x"
       apply (rule kingman_theorem_nonergodic_invariant(1))
       using \<open>subcocycle_avg_ereal w > -\<infinity>\<close> by auto
     moreover have "AE x in M. subcocycle_lim_ereal w x = max (subcocycle_lim_ereal u x) (subcocycle_lim_ereal v x)"
       unfolding w_def using subcocycle_lim_ereal_max by auto
     moreover
     {
       fix x assume H: "(\<lambda>n. real_cond_exp M Invariants (w n) x / n) \<longlonglongrightarrow> subcocycle_lim w x"
                       "subcocycle_lim_ereal w x = max (subcocycle_lim_ereal u x) (subcocycle_lim_ereal v x)"
                       "subcocycle_lim_ereal v x = - real K"
                       "\<forall>n. real_cond_exp M Invariants (u n) x \<le> real_cond_exp M Invariants (w n) x"
       have "subcocycle_lim_ereal w x > -\<infinity>"
-        using H(2) H(3) 
+        using H(2) H(3)
         by auto (metis MInfty_neq_ereal(1) ereal_infty_less_eq2(2) max.cobounded2)
       then have "subcocycle_lim_ereal w x = ereal(subcocycle_lim w x)"
         unfolding subcocycle_lim_def using subcocycle_lim_ereal_not_PInf[of w x] ereal_real by force
       moreover have "(\<lambda>n. real_cond_exp M Invariants (w n) x / n) \<longlonglongrightarrow> ereal(subcocycle_lim w x)" using H(1) by auto
       ultimately have "(\<lambda>n. real_cond_exp M Invariants (w n) x / n) \<longlonglongrightarrow> subcocycle_lim_ereal w x" by auto
       then have *: "limsup (\<lambda>n. real_cond_exp M Invariants (w n) x / n) = subcocycle_lim_ereal w x"
         using tendsto_iff_Liminf_eq_Limsup trivial_limit_at_top_linorder by blast
 
       have "ereal(real_cond_exp M Invariants (u n) x / n) \<le> real_cond_exp M Invariants (w n) x / n" for n
         using H(4) by (auto simp add: divide_simps)
       then have "eventually (\<lambda>n. ereal(real_cond_exp M Invariants (u n) x / n) \<le> real_cond_exp M Invariants (w n) x / n) sequentially"
         by auto
       then have "limsup (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<le> limsup (\<lambda>n. real_cond_exp M Invariants (w n) x / n)"
         using Limsup_mono[of _ _ sequentially] by force
       then have "limsup (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<le> max (subcocycle_lim_ereal u x) (-real K)"
         using * H(2) H(3) by auto
     }
     ultimately show ?thesis using \<open>AE x in M. subcocycle_lim_ereal v x = -real K\<close> by auto
   qed
   have "AE x in M. \<forall>K::nat.
         limsup (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<le> max (subcocycle_lim_ereal u x) (-real K)"
     apply (subst AE_all_countable) using limsup_ineq_K by auto
 
   moreover have "AE x in M. liminf (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<ge> subcocycle_lim_ereal u x"
   proof -
     have *: "AE x in M. N > 0 \<longrightarrow> subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x" for N
       by (cases "N = 0", auto simp add: subcocycle_lim_ereal_atmost_uN_invariants[OF assms(1)])
     have "AE x in M. \<forall>N. N > 0 \<longrightarrow> subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
       by (subst AE_all_countable, intro allI, simp add: *)
     moreover have "AE x in M. \<forall>n. real_cond_exp M Invariants (\<lambda>x. u n x / n) x = real_cond_exp M Invariants (u n) x / n"
       apply (subst AE_all_countable, intro allI) using real_cond_exp_cdiv by auto
     moreover
     {
       fix x assume x: "\<forall>N. N > 0 \<longrightarrow> subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
                       "\<forall>n. real_cond_exp M Invariants (\<lambda>x. u n x / n) x = real_cond_exp M Invariants (u n) x / n"
       then have *: "subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (u n) x / n" if "n \<ge> 1" for n
         using that by auto
       have "subcocycle_lim_ereal u x \<le> liminf (\<lambda>n. real_cond_exp M Invariants (u n) x / n)"
         apply (subst liminf_bounded_iff) using * less_le_trans by blast
     }
     ultimately show ?thesis by auto
   qed
 
   moreover
   {
     fix x assume H: "\<forall>K::nat. limsup (\<lambda>n. real_cond_exp M Invariants (u n) x / n)
                               \<le> max (subcocycle_lim_ereal u x) (-real K)"
                     "liminf (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<ge> subcocycle_lim_ereal u x"
     have "(\<lambda>K::nat. max (subcocycle_lim_ereal u x) (-real K)) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
       by (rule ereal_truncation_bottom)
     with LIMSEQ_le_const[OF this]
     have *: "limsup (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<le> subcocycle_lim_ereal u x"
       using H(1) by auto
     have "(\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
       apply (subst tendsto_iff_Liminf_eq_Limsup[OF trivial_limit_at_top_linorder])
       using H(2) * Liminf_le_Limsup[OF trivial_limit_at_top_linorder, of "(\<lambda>n. real_cond_exp M Invariants (u n) x / n)"]
       by auto
   }
   ultimately show ?thesis by auto
 qed
 
 
 
 end
 
 subsection \<open>Subcocycles in the ergodic case\<close>
 
 text \<open>In this subsection, we describe how all the previous results simplify in the ergodic case.
 Indeed, subcocycle limits are almost surely constant, given by the asymptotic average.\<close>
 
 context ergodic_pmpt begin
 
 lemma subcocycle_ergodic_lim_avg:
   assumes "subcocycle u"
   shows "AE x in M. subcocycle_lim_ereal u x = subcocycle_avg_ereal u"
         "AE x in M. subcocycle_lim u x = subcocycle_avg u"
 proof -
   have I: "integrable M (u N)" for N using subcocycle_integrable[OF assms]by auto
   obtain c::ereal where c: "AE x in M. subcocycle_lim_ereal u x = c"
     using Invariant_func_is_AE_constant[OF subcocycle_lim_meas_Inv(1)] by blast
   have "c = subcocycle_avg_ereal u"
   proof (cases "subcocycle_avg_ereal u = - \<infinity>")
     case True
     {
       fix N assume "N > (0::nat)"
       have "AE x in M. real_cond_exp M Invariants (\<lambda>x. u N x / N) x = (\<integral> x. u N x / N \<partial>M)"
         apply (rule Invariants_cond_exp_is_integral) using I by auto
       moreover have "AE x in M. subcocycle_lim_ereal u x \<le> real_cond_exp M Invariants (\<lambda>x. u N x / N) x"
         using subcocycle_lim_ereal_atmost_uN_invariants[OF assms \<open>N>0\<close>] by simp
       ultimately have "AE x in M. c \<le> (\<integral>x. u N x / N \<partial>M)"
         using c by force
       then have "c \<le> (\<integral>x. u N x / N \<partial>M)" by auto
     }
     then have "\<forall>N\<ge>1. c \<le> (\<integral>x. u N x / N \<partial>M)" by auto
     with Lim_bounded2[OF subcocycle_int_tendsto_avg_ereal[OF assms] this]
     have "c \<le> subcocycle_avg_ereal u" by simp
     then show ?thesis using True by auto
   next
     case False
     then have fin: "subcocycle_avg_ereal u > - \<infinity>" by simp
     obtain cr::real where cr: "AE x in M. subcocycle_lim u x = cr"
       using Invariant_func_is_AE_constant[OF subcocycle_lim_meas_Inv(2)] by blast
     have "AE x in M. c = ereal cr" using c cr subcocycle_lim_real_ereal[OF assms fin] by force
     then have "c = ereal cr" by auto
     have "subcocycle_avg u = (\<integral>x. subcocycle_lim u x \<partial>M)"
       using subcocycle_lim_avg[OF assms fin] by auto
     also have "... = (\<integral>x. cr \<partial>M)"
       apply (rule integral_cong_AE) using cr by auto
     also have "... = cr"
       by (simp add: prob_space.prob_space prob_space_axioms)
     finally have "ereal(subcocycle_avg u) = ereal cr" by simp
     then show ?thesis using \<open> c = ereal cr \<close> subcocycle_avg_real_ereal[OF fin] by auto
   qed
   then show "AE x in M. subcocycle_lim_ereal u x = subcocycle_avg_ereal u" using c by auto
   then show "AE x in M. subcocycle_lim u x = subcocycle_avg u"
     unfolding subcocycle_lim_def subcocycle_avg_def by auto
 qed
 
 theorem kingman_theorem_AE_ereal:
   assumes "subcocycle u"
   shows "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_avg_ereal u"
 using kingman_theorem_AE_nonergodic_ereal[OF assms] subcocycle_ergodic_lim_avg(1)[OF assms] by auto
 
 theorem kingman_theorem:
   assumes "subcocycle u" "subcocycle_avg_ereal u > -\<infinity>"
   shows "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_avg u"
         "(\<lambda>n. (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_avg u) \<partial>M)) \<longlonglongrightarrow> 0"
 proof -
   have *: "AE x in M. subcocycle_lim u x = subcocycle_avg u"
     using subcocycle_ergodic_lim_avg(2)[OF assms(1)] by auto
   then show "AE x in M. (\<lambda>n. u n x / n) \<longlonglongrightarrow> subcocycle_avg u"
     using kingman_theorem_nonergodic(1)[OF assms] by auto
   have "(\<integral>\<^sup>+x. abs(u n x / n - subcocycle_avg u) \<partial>M) = (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_lim u x) \<partial>M)" for n
     apply (rule nn_integral_cong_AE) using * by auto
   then show "(\<lambda>n. (\<integral>\<^sup>+x. abs(u n x / n - subcocycle_avg u) \<partial>M)) \<longlonglongrightarrow> 0"
     using kingman_theorem_nonergodic(3)[OF assms] by auto
 qed
 
 end
 
 
 subsection \<open>Subocycles for invertible maps\<close>
 
 text \<open>If $T$ is invertible, then a subcocycle $u_n$ for $T$ gives rise to another subcocycle
 for $T^{-1}$. Intuitively, if $u$ is subadditive along the time interval $[0,n)$, then
 it should also be subadditive along the time interval $[-n,0)$. This is true, and
 formalized with the following statement.\<close>
 
 proposition (in mpt) subcocycle_u_Tinv:
   assumes "subcocycle u"
           "invertible_qmpt"
   shows "mpt.subcocycle M Tinv (\<lambda>n x. u n (((Tinv)^^n) x))"
 proof -
   have bij: "bij T" using \<open>invertible_qmpt\<close> unfolding invertible_qmpt_def by auto
   have int: "integrable M (u n)" for n
     using subcocycle_integrable[OF assms(1)] by simp
   interpret I: mpt M Tinv using Tinv_mpt[OF assms(2)] by simp
   show "I.subcocycle (\<lambda>n x. u n (((Tinv)^^n) x))" unfolding I.subcocycle_def
   proof(auto)
     show "integrable M (\<lambda>x. u n ((Tinv ^^ n) x))" for n
       using I.Tn_integral_preserving(1)[OF int[of n]] by simp
     fix n m::nat and x::'a
     define y where "y = (Tinv^^(m+n)) x"
     have "(T^^m) y = (T^^m) ((Tinv^^m) ((Tinv^^n) x))" unfolding y_def by (simp add: funpow_add)
     then have *: "(T^^m) y = (Tinv^^n) x"
       using fn_o_inv_fn_is_id[OF bij, of m] by (metis Tinv_def comp_def)
     have "u (n + m) ((Tinv ^^ (n + m)) x) = u (m+n) y"
       unfolding y_def by (simp add: add.commute[of n m])
     also have "... \<le> u m y + u n ((T^^m) y)"
       using subcocycle_ineq[OF \<open>subcocycle u\<close>, of m n y] by simp
     also have "... = u m ((Tinv^^(m+n)) x) + u n ((Tinv^^n) x)"
       using * y_def by auto
     finally show "u (n + m) ((Tinv ^^ (n + m)) x) \<le> u n ((Tinv ^^ n) x) + u m ((Tinv ^^ m) ((Tinv ^^ n) x))"
       by (simp add: funpow_add)
   qed
 qed
 
 text \<open>The subcocycle averages for $T$ and $T^{-1}$ coincide.\<close>
 
 proposition (in mpt) subcocycle_avg_ereal_Tinv:
   assumes "subcocycle u"
           "invertible_qmpt"
   shows "mpt.subcocycle_avg_ereal M (\<lambda>n x. u n (((Tinv)^^n) x)) = subcocycle_avg_ereal u"
 proof -
   have bij: "bij T" using \<open>invertible_qmpt\<close> unfolding invertible_qmpt_def by auto
   have int: "integrable M (u n)" for n
     using subcocycle_integrable[OF assms(1)] by simp
   interpret I: mpt M Tinv using Tinv_mpt[OF assms(2)] by simp
   have "(\<lambda>n. (\<integral>x. u n (((Tinv)^^n) x) / n \<partial>M)) \<longlonglongrightarrow> I.subcocycle_avg_ereal (\<lambda>n x. u n (((Tinv)^^n) x))"
     using I.subcocycle_int_tendsto_avg_ereal[OF subcocycle_u_Tinv[OF assms]] by simp
   moreover have "(\<integral>x. u n x / n \<partial>M) = ereal (\<integral>x. u n (((Tinv)^^n) x) / n \<partial>M)" for n
     apply (simp)
     apply (rule disjI2)
     apply (rule I.Tn_integral_preserving(2)[symmetric])
     apply (simp add: int)
     done
   ultimately have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> I.subcocycle_avg_ereal (\<lambda>n x. u n (((Tinv)^^n) x))"
     by presburger
   moreover have "(\<lambda>n. (\<integral>x. u n x / n \<partial>M)) \<longlonglongrightarrow> subcocycle_avg_ereal u"
     using subcocycle_int_tendsto_avg_ereal[OF \<open>subcocycle u\<close>] by simp
   ultimately show ?thesis
     using LIMSEQ_unique by simp
 qed
 
 text \<open>The asymptotic limit of the subcocycle is the same for $T$ and $T^{-1}$. This is clear in the
 ergodic case, and follows from the ergodic decomposition in the general case (on a standard
 probability space). We give a direct proof below (on a general probability space) using the fact
 that the asymptotic limit is the same for the subcocycle conditioned by the invariant sigma-algebra,
 which is clearly the same for $T$ and $T^{-1}$ as it is constant along orbits.\<close>
 
 proposition (in fmpt) subcocycle_lim_ereal_Tinv:
   assumes "subcocycle u"
           "invertible_qmpt"
   shows "AE x in M. fmpt.subcocycle_lim_ereal M Tinv (\<lambda>n x. u n (((Tinv)^^n) x)) x = subcocycle_lim_ereal u x"
 proof -
   have bij: "bij T" using \<open>invertible_qmpt\<close> unfolding invertible_qmpt_def by auto
   have int: "integrable M (u n)" for n
     using subcocycle_integrable[OF assms(1)] by simp
   interpret I: fmpt M Tinv using Tinv_fmpt[OF assms(2)] by simp
   have *: "AE x in M. real_cond_exp M I.Invariants (\<lambda> x. u n (((Tinv)^^n) x)) x
                   = real_cond_exp M I.Invariants (u n) x" for n
     using I.Invariants_of_foTn int unfolding o_def by simp
   have "AE x in M. \<forall>n. real_cond_exp M I.Invariants (\<lambda> x. u n (((Tinv)^^n) x)) x
                   = real_cond_exp M I.Invariants (u n) x"
     apply (subst AE_all_countable) using * by simp
   moreover have "AE x in M. (\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
     using kingman_theorem_AE_nonergodic_invariant_ereal[OF \<open>subcocycle u\<close>] by simp
   moreover have "AE x in M. (\<lambda>n. real_cond_exp M I.Invariants (\<lambda> x. u n (((Tinv)^^n) x)) x / n)
           \<longlonglongrightarrow> I.subcocycle_lim_ereal (\<lambda> n x. u n (((Tinv)^^n) x)) x"
     using I.kingman_theorem_AE_nonergodic_invariant_ereal[OF subcocycle_u_Tinv[OF assms]] by simp
   moreover
   {
     fix x assume H: "\<forall>n. real_cond_exp M I.Invariants (\<lambda> x. u n (((Tinv)^^n) x)) x
                       = real_cond_exp M I.Invariants (u n) x"
                     "(\<lambda>n. real_cond_exp M Invariants (u n) x / n) \<longlonglongrightarrow> subcocycle_lim_ereal u x"
                     "(\<lambda>n. real_cond_exp M I.Invariants (\<lambda> x. u n (((Tinv)^^n) x)) x / n)
                         \<longlonglongrightarrow> I.subcocycle_lim_ereal (\<lambda> n x. u n (((Tinv)^^n) x)) x"
     have "ereal(real_cond_exp M Invariants (u n) x / n)
           = ereal(real_cond_exp M I.Invariants (\<lambda> x. u n (((Tinv)^^n) x)) x / n)" for n
       using H(1) Invariants_Tinv[OF \<open>invertible_qmpt\<close>] by auto
     then have "(\<lambda>n. real_cond_exp M Invariants (u n) x / n)
                 \<longlonglongrightarrow> I.subcocycle_lim_ereal (\<lambda> n x. u n (((Tinv)^^n) x)) x"
       using H(3) by presburger
     then have "I.subcocycle_lim_ereal (\<lambda> n x. u n (((Tinv)^^n) x)) x = subcocycle_lim_ereal u x"
       using H(2) LIMSEQ_unique by auto
   }
   ultimately show ?thesis by auto
 qed
 
 proposition (in fmpt) subcocycle_lim_Tinv:
   assumes "subcocycle u"
           "invertible_qmpt"
   shows "AE x in M. fmpt.subcocycle_lim M Tinv (\<lambda>n x. u n (((Tinv)^^n) x)) x = subcocycle_lim u x"
 proof -
   interpret I: fmpt M Tinv using Tinv_fmpt[OF assms(2)] by simp
   show ?thesis
     unfolding subcocycle_lim_def I.subcocycle_lim_def
     using subcocycle_lim_ereal_Tinv[OF assms] by auto
 qed
 
 end (*of Kingman.thy*)
diff --git a/thys/MDP-Rewards/MDP_disc.thy b/thys/MDP-Rewards/MDP_disc.thy
--- a/thys/MDP-Rewards/MDP_disc.thy
+++ b/thys/MDP-Rewards/MDP_disc.thy
@@ -1,925 +1,925 @@
 (* Author: Maximilian Schäffeler *)
 
 theory MDP_disc
-  imports 
+  imports
     MDP_cont
     "HOL-Library.Omega_Words_Fun"
 begin
 
 section \<open>Markov Decision Processes with Discrete State Spaces\<close>
 
 (* counterpart to nn_integral_stream_space *)
 lemma (in prob_space) integral_stream_space:
   fixes f :: "'a stream \<Rightarrow> ('b :: {banach, second_countable_topology,real_normed_vector})"
   assumes int_f: "integrable (stream_space M) f"
   assumes [measurable]: "f \<in> borel_measurable (stream_space M)"
   shows "(\<integral>X. f X \<partial>stream_space M) = (\<integral>x. (\<integral>X. f (x ## X) \<partial>stream_space M) \<partial>M)"
 proof -
   interpret S: sequence_space M ..
   interpret P: pair_sigma_finite M "\<Pi>\<^sub>M i::nat\<in>UNIV. M" ..
 
   interpret P': pair_sigma_finite "\<Pi>\<^sub>M i::nat\<in>UNIV. M" M ..
 
   obtain i where "has_bochner_integral (stream_space M) f i"
     using int_f
     using integrable.cases by blast
   have "integrable S.S (\<lambda>X. f (to_stream X))"
     using int_f
     by (metis integrable_distr measurable_to_stream stream_space_eq_distr)
-  hence "integrable (distr (M \<Otimes>\<^sub>M Pi\<^sub>M UNIV (\<lambda>i. M)) (Pi\<^sub>M UNIV (\<lambda>i. M)) 
+  hence "integrable (distr (M \<Otimes>\<^sub>M Pi\<^sub>M UNIV (\<lambda>i. M)) (Pi\<^sub>M UNIV (\<lambda>i. M))
     (\<lambda>(x, y). case_nat x y)) (\<lambda>X. f (to_stream X))"
     by (auto simp: S.PiM_iter)
-  moreover have "integrable (distr (M \<Otimes>\<^sub>M Pi\<^sub>M UNIV (\<lambda>i. M)) (Pi\<^sub>M UNIV (\<lambda>i. M)) (\<lambda>(x, y). case_nat x y)) 
-    (\<lambda>X. f (to_stream X)) \<longleftrightarrow> 
+  moreover have "integrable (distr (M \<Otimes>\<^sub>M Pi\<^sub>M UNIV (\<lambda>i. M)) (Pi\<^sub>M UNIV (\<lambda>i. M)) (\<lambda>(x, y). case_nat x y))
+    (\<lambda>X. f (to_stream X)) \<longleftrightarrow>
     integrable (M \<Otimes>\<^sub>M S.S) (\<lambda>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) X)))"
     by (auto simp: integrable_distr_eq)
   ultimately have "integrable (M \<Otimes>\<^sub>M S.S) (\<lambda>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) X)))"
     by auto
-  hence "integrable (M \<Otimes>\<^sub>M (Pi\<^sub>M UNIV (\<lambda>i. M))) 
+  hence "integrable (M \<Otimes>\<^sub>M (Pi\<^sub>M UNIV (\<lambda>i. M)))
     (\<lambda>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) X)))"
     by auto
-  moreover have "integrable (M \<Otimes>\<^sub>M (Pi\<^sub>M UNIV (\<lambda>i. M))) 
-    (\<lambda>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) X))) = 
+  moreover have "integrable (M \<Otimes>\<^sub>M (Pi\<^sub>M UNIV (\<lambda>i. M)))
+    (\<lambda>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) X))) =
       integrable (M \<Otimes>\<^sub>M Pi\<^sub>M UNIV (\<lambda>i. M)) (\<lambda>(x, X). f (to_stream (case_nat x X)))"
-    by (fastforce intro!: integrable_cong)
+    by (fastforce intro!: Bochner_Integration.integrable_cong)
   ultimately have *: "integrable (M \<Otimes>\<^sub>M Pi\<^sub>M UNIV (\<lambda>i. M)) (\<lambda>(x, X). f (to_stream (case_nat x X)))"
     by auto
 
   have "(\<integral>X. f X \<partial>stream_space M) = (\<integral>X. f (to_stream X) \<partial>S.S)"
     by (subst stream_space_eq_distr) (simp add: integral_distr)
   also have "\<dots> = (\<integral>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) X)) \<partial>(M \<Otimes>\<^sub>M S.S))"
     by (subst S.PiM_iter[symmetric]) (simp add: integral_distr)
   also have "\<dots> = (\<integral>x. \<integral>X. f (to_stream ((\<lambda>(s, \<omega>). case_nat s \<omega>) (x, X)))\<partial>S.S  \<partial>M)"
     using *
     by (auto simp: pair_sigma_finite.integral_fst P.pair_sigma_finite_axioms case_prod_unfold)
   also have "\<dots> = (\<integral>x. \<integral>X. f (x ## to_stream X) \<partial>S.S \<partial>M)"
     by (auto intro!: integral_cong simp: to_stream_nat_case)
   also have "\<dots> = (\<integral>x. \<integral>X. f (x ## X) \<partial>distr (Pi\<^sub>M UNIV (\<lambda>i. M)) (stream_space M) to_stream \<partial>M)"
-    by (subst Bochner_Integration.integral_cong[OF refl]) (auto simp: integral_distr) 
+    by (subst Bochner_Integration.integral_cong[OF refl]) (auto simp: integral_distr)
   also have "\<dots> = (\<integral>x. \<integral>X. f (x ## X) \<partial>stream_space M \<partial>M)"
     using stream_space_eq_distr by metis
   finally show ?thesis .
 qed
 
-lemma prefix_cons: 
+lemma prefix_cons:
   "Omega_Words_Fun.prefix (Suc n) seq = seq 0#Omega_Words_Fun.prefix n (\<lambda>n. seq (Suc n))"
   by (metis map_upt_Suc subsequence_def)
 
 lemma restrict_Suc: "restrict y {0..<Suc i} (Suc n) = (restrict (\<lambda>n. y (Suc n)) {0..<i}) n"
   by auto
 
 lemma prefix_restrict: "Omega_Words_Fun.prefix i (restrict y {0..<i}) = Omega_Words_Fun.prefix i y"
 proof (induction i arbitrary: y)
   case (Suc i)
   then show ?case
-    unfolding restrict_Suc prefix_cons 
+    unfolding restrict_Suc prefix_cons
     by fastforce+
 qed simp
 
-lemma prefix_measurable[measurable]: 
-  "Omega_Words_Fun.prefix i \<in> Pi\<^sub>M {0..<i} 
+lemma prefix_measurable[measurable]:
+  "Omega_Words_Fun.prefix i \<in> Pi\<^sub>M {0..<i}
   (\<lambda>_. count_space (UNIV :: ('s ::countable \<times> 'a::countable) set)) \<rightarrow>\<^sub>M count_space UNIV"
 proof (induction i)
   case 0
   then show ?case by simp
 next
   case (Suc i)
-  have aux: "(\<lambda>w. (restrict w {0..<i}, w i)) \<in> Pi\<^sub>M {0..<Suc i} (\<lambda>_. count_space UNIV) \<rightarrow>\<^sub>M 
+  have aux: "(\<lambda>w. (restrict w {0..<i}, w i)) \<in> Pi\<^sub>M {0..<Suc i} (\<lambda>_. count_space UNIV) \<rightarrow>\<^sub>M
     Pi\<^sub>M {0..<i} (\<lambda>_. count_space UNIV) \<Otimes>\<^sub>M (count_space UNIV)"
     by auto
-  have aux': "(\<lambda>(w,wi). Omega_Words_Fun.prefix i (restrict w {0..<i})@[wi]) \<in> Pi\<^sub>M {0..<i} 
+  have aux': "(\<lambda>(w,wi). Omega_Words_Fun.prefix i (restrict w {0..<i})@[wi]) \<in> Pi\<^sub>M {0..<i}
     (\<lambda>_. count_space (UNIV :: ('s \<times> 'a) set)) \<Otimes>\<^sub>M (count_space UNIV) \<rightarrow>\<^sub>M count_space UNIV"
     using Suc.IH by auto
-  have f_eq: "\<And>w. Omega_Words_Fun.prefix i (restrict w {0..<i}) @ [w i] = 
+  have f_eq: "\<And>w. Omega_Words_Fun.prefix i (restrict w {0..<i}) @ [w i] =
     (\<lambda>(w,wi). Omega_Words_Fun.prefix i w @[wi]) ((restrict w {0..<i}), w i)"
     by auto
   have "(\<lambda>w:: nat \<Rightarrow> 's \<times> 'a. Omega_Words_Fun.prefix i (restrict w {0..<i}) @ [w i]) \<in> Pi\<^sub>M {0..<Suc i} (\<lambda>_. count_space UNIV) \<rightarrow>\<^sub>M count_space UNIV"
     using aux aux'[unfolded prefix_restrict]
     by (subst f_eq) auto
   thus ?case
     unfolding prefix_restrict[of _ "i"]
     by auto
 qed
 
 no_notation Omega_Words_Fun.build (infixr  \<open>##\<close> 65)
 
 locale discrete_MDP =
   fixes A :: "'s::countable \<Rightarrow> 'a::countable set" \<comment> \<open>enabled actions\<close>
     and K :: "'s \<times> 'a \<Rightarrow> 's pmf" \<comment> \<open>MDP kernel, transition probabilities\<close>
   assumes
     A_ne: "\<And>s. A s \<noteq> {}" \<comment> \<open>set of enabled actions is nonempty\<close>
 begin
 
 subsection \<open>Policies\<close>
 text \<open>Type synonym for decision rules.\<close>
 type_synonym ('c, 'd) dec = "'c \<Rightarrow> 'd pmf"
 
 definition is_dec :: "('s, 'a) dec \<Rightarrow> bool" where
   "is_dec d \<equiv> \<forall>s. d s \<subseteq> A s"
 
-lemma is_decI[intro]: 
+lemma is_decI[intro]:
   "(\<And>s. set_pmf (d s) \<subseteq> A s) \<Longrightarrow> is_dec d"
   unfolding is_dec_def
   by auto
 
 abbreviation "D\<^sub>R \<equiv> {d. is_dec d}"
 
 definition is_dec_det :: "('s \<Rightarrow> 'a) \<Rightarrow> bool" where
   "is_dec_det d \<equiv> \<forall>s. d s \<in> A s"
 
 abbreviation "D\<^sub>D \<equiv> {d. is_dec_det d}"
 
 definition "mk_dec_det d s = return_pmf (d s)"
 
 lemma is_dec_mk_dec_det_iff [simp]: "is_dec (mk_dec_det d) \<longleftrightarrow> is_dec_det d"
   by (simp add: is_dec_def is_dec_det_def mk_dec_det_def)
 
 lemma D_det_to_MR[intro]: "is_dec_det d \<Longrightarrow> is_dec (mk_dec_det d)"
   by simp
 
 text \<open>
 Due to the assumption @{thm A_ne}, a deterministic decision rule always exists.
 It immediately follows via @{thm is_dec_mk_dec_det_iff} that a randomized decision rule also exists.
 \<close>
 
 lemma SOME_is_dec_det: "is_dec_det (\<lambda>s. SOME a. a \<in> A s)"
   using A_ne by (simp add: is_dec_det_def some_in_eq)
 
 lemma ex_dec_det [simp]: "\<exists>d. is_dec_det d"
   using SOME_is_dec_det by blast
 
 lemma D_det_ne [simp]: "D\<^sub>D \<noteq> {}"
   by simp
 
 lemma D\<^sub>R_ne [simp]: "D\<^sub>R \<noteq> {}"
   using D_det_ne D_det_to_MR by blast
 
 lemma ex_dec[intro, simp]: "\<exists>d. is_dec d"
   using ex_dec_det by blast
 
 text \<open>Type synonym for policies.\<close>
 type_synonym ('c, 'd) pol = "('c \<times> 'd) list \<Rightarrow> ('c, 'd) dec"
 
 
 text \<open>A policy assigns a decision rule to each observed past.\<close>
 definition is_policy :: "('s, 'a) pol \<Rightarrow> bool" where
   "is_policy p \<equiv> \<forall>hs. is_dec (p hs)"
 
 abbreviation "\<Pi>\<^sub>H\<^sub>R \<equiv> {p. is_policy p}"
 
 text \<open>Deterministic policies\<close>
 definition "is_deterministic p \<equiv> is_policy p \<and> (\<forall>h s. \<exists>a. p h s = return_pmf a)"
 
 definition "mk_det p h s \<equiv> return_pmf (p h s)"
 
 abbreviation "\<Pi>\<^sub>H\<^sub>D \<equiv> {p. \<forall>h. p h \<in> D\<^sub>D}"
 
 text \<open>Markovian policies\<close>
 definition "is_markovian p \<equiv> is_policy p \<and> (\<forall>h h'. length h = length h' \<longrightarrow> p h = p h')"
 
 definition mk_markovian :: "(nat \<Rightarrow> ('s, 'a) dec) \<Rightarrow> ('s, 'a) pol" where
   "mk_markovian p \<equiv> (\<lambda>h. p (length h))"
 
 lemma is_markovian_mk_iff[simp]: "is_markovian (mk_markovian p) \<longleftrightarrow> (\<forall>n. is_dec (p n))"
   unfolding is_markovian_def mk_markovian_def is_policy_def
   by (metis (mono_tags, opaque_lifting) Ex_list_of_length)
 
 lemma is_markovian_mk[intro]: "\<forall>n. is_dec (p n) \<Longrightarrow> is_markovian (mk_markovian p)"
   unfolding is_markovian_def mk_markovian_def is_policy_def
   by auto
 
 lemma mk_markovian_nil [simp]: "mk_markovian p [] = p 0"
   unfolding mk_markovian_def by auto
 
 definition "mk_markovian_det p \<equiv> (\<lambda>h s. return_pmf (p (length h) s))"
 
 abbreviation "\<Pi>\<^sub>M\<^sub>D \<equiv> {p. \<forall>n. p n \<in> D\<^sub>D}"
 abbreviation "\<Pi>\<^sub>M\<^sub>R \<equiv> {p. \<forall>n. p n \<in> D\<^sub>R}"
 
 lemma \<Pi>\<^sub>M\<^sub>R_imp_policies[intro]: "p \<in> \<Pi>\<^sub>M\<^sub>R \<Longrightarrow> mk_markovian p \<in> \<Pi>\<^sub>H\<^sub>R"
   unfolding is_policy_def mk_markovian_def by auto
 
 lemma \<Pi>\<^sub>M\<^sub>D_MR_iff[simp]: "(\<lambda>n. mk_dec_det (p n)) \<in> \<Pi>\<^sub>M\<^sub>R \<longleftrightarrow> p \<in> \<Pi>\<^sub>M\<^sub>D"
   by auto
 
 lemma \<Pi>\<^sub>M\<^sub>D_to_MR[intro]: "p \<in> \<Pi>\<^sub>M\<^sub>D \<Longrightarrow> (\<lambda>n. mk_dec_det (p n)) \<in> \<Pi>\<^sub>M\<^sub>R"
   by simp
 
 lemma \<Pi>\<^sub>M\<^sub>D_ne[simp]: "\<Pi>\<^sub>M\<^sub>D \<noteq> {}"
   by (auto simp: someI_ex[OF ex_dec_det] intro: exI[of _ "\<lambda>n. (SOME d. is_dec_det d)"])
 
 lemma \<Pi>\<^sub>M\<^sub>R_ne[simp]: "\<Pi>\<^sub>M\<^sub>R \<noteq> {}"
   using \<Pi>\<^sub>M\<^sub>D_ne by fast
 
 lemma policies_ne[simp, intro]: "\<Pi>\<^sub>H\<^sub>R \<noteq> {}"
   using \<Pi>\<^sub>M\<^sub>R_ne is_policy_def by auto
 
 
 text \<open>Stationary policies\<close>
 definition "is_stationary p \<equiv> is_policy p \<and> (\<forall>h h'. p h = p h')"
 
 lemma is_stationary_const_iff[simp]: "is_stationary (\<lambda>_. d) = is_dec d"
   unfolding is_stationary_def is_policy_def by simp
 
 lemma is_stationary_const[intro]: "is_dec d \<Longrightarrow> is_stationary (\<lambda>_. d)"
   by simp
 
 abbreviation "mk_stationary p \<equiv> mk_markovian (\<lambda>_. p)"
 abbreviation "mk_stationary_det d \<equiv> mk_markovian (\<lambda>_. mk_dec_det d)"
 
 subsubsection \<open>Successor Policy\<close>
 text \<open>
-After taking the first step in the MDP, we will know which state and which action got selected 
-during the initial epoch. To obtain a policy that acts as if the current epoch was the initial one, 
-we prepend the observed state-action pair to the history. The result is again a policy, 
+After taking the first step in the MDP, we will know which state and which action got selected
+during the initial epoch. To obtain a policy that acts as if the current epoch was the initial one,
+we prepend the observed state-action pair to the history. The result is again a policy,
 i.e. it satisfies @{const is_policy}.
 \<close>
 definition "\<pi>_Suc p sa h = p (sa#h)"
 
 lemma is_policy_\<pi>_Suc [intro]: "is_policy p \<Longrightarrow> is_policy (\<pi>_Suc p sa)"
   unfolding is_policy_def \<pi>_Suc_def by force
 
 lemma Suc_mk_markovian[simp]: "\<pi>_Suc (mk_markovian p) x = mk_markovian (\<lambda>n. p (Suc n))"
   unfolding \<pi>_Suc_def mk_markovian_def by auto
 
 subsection \<open>Stream Space of the MDP\<close>
 subsubsection \<open>Initial State-Action Distribution\<close>
 text \<open>
-If we fix a decision rule @{term d} and an initial distribution of states @{term "S0"}, 
+If we fix a decision rule @{term d} and an initial distribution of states @{term "S0"},
 we obtain a distribution over state-action pairs in the following way:
-First, the initial state @{term "s"} is sampled from @{term S0}, 
+First, the initial state @{term "s"} is sampled from @{term S0},
 then an action @{term a} is selected from @{term "d s"}.
 \<close>
 
 definition "K0 d S0 = do {
-  s \<leftarrow> S0; 
+  s \<leftarrow> S0;
   a \<leftarrow> d s;
   return_pmf (s,a)
-}" 
+}"
 
 notation K0 ("K\<^sub>0")
 
 lemma K0_iff: "K0 d S0 = S0 \<bind> (\<lambda>s. map_pmf (\<lambda>a. (s,a)) (d s))"
   by (simp add: K0_def map_pmf_def)
 
 lemma vimage_pair[simp]: "Pair x -` {p} = (if x = fst p then {snd p} else {})"
   by auto
 
 lemma pmf_K0 [simp]: "pmf (K0 d S0) (s,a) = pmf S0 s * pmf (d s) a"
   unfolding K0_iff pmf_bind
   by (subst integral_measure_pmf[where A = "{s}"]) (auto simp: pmf_map pmf.rep_eq split: if_splits)
 
 lemma set_pmf_K0: "set_pmf (K0 p S0) = {(s,a). s \<in> S0 \<and> a \<in> p s}"
   by (auto simp add: K0_def)
 
 lemma fst_K0[simp]: "map_pmf fst (K0 p S0) = S0"
   unfolding K0_def
   by (simp add: map_bind_pmf map_pmf_comp bind_return_pmf')
 
 abbreviation "S \<equiv> stream_space (count_space UNIV)"
 
 text \<open>We inherit the trace space from MDPs with continuous state-action spaces\<close>
 interpretation MDP_cont: MDP_cont.discrete_MDP "count_space UNIV" "count_space UNIV" A K
 proof standard
-  show "(\<lambda>x. measure_pmf (K x)) \<in> 
+  show "(\<lambda>x. measure_pmf (K x)) \<in>
     count_space UNIV \<Otimes>\<^sub>M count_space UNIV \<rightarrow>\<^sub>M prob_algebra (count_space UNIV)"
     using measurable_prob_algebraI
     by (measurable, auto simp: prob_space_measure_pmf measurable_pair_measure_countable1)+
   show "\<exists>\<delta>\<in>count_space UNIV \<rightarrow>\<^sub>M count_space UNIV. \<forall>s. \<delta> s \<in> A s"
     by (auto simp: A_ne some_in_eq intro: bexI[of _ "\<lambda>s. SOME a. a \<in> A s"])
 qed (auto simp: A_ne)
 
 lemma count_space_M[simp]: "MDP_cont.M = count_space UNIV"
   by (auto simp: pair_measure_countable)
 
 lemma space_M[simp]: "space MDP_cont.M = UNIV"
   by (auto simp: MDP_cont.space_lim_stream)
 
 text \<open>We reuse the stream space provided by @{const MDP_cont.lim_stream}\<close>
 definition T :: "('s, 'a) pol \<Rightarrow> 's pmf \<Rightarrow> ('s \<times> 'a) stream measure"
   where "T p = MDP_cont.lim_stream (\<lambda>n (h,s). p (Omega_Words_Fun.prefix n h) s)"
 
-lemma sets_T[measurable_cong]: 
+lemma sets_T[measurable_cong]:
   "sets (T p x) = sets S"
   by (auto simp: T_def MDP_cont.sets_lim_stream)
 
 lemma space_stream_space_ne[simp]: "space S \<noteq> {}"
   by (auto simp: space_stream_space)
 
 lemma space_T[simp]: "space (T p S0) = space S"
   by (simp add: MDP_cont.space_lim_stream T_def space_stream_space)
 
-lemma is_policy_MDP_cont[intro]: 
+lemma is_policy_MDP_cont[intro]:
   fixes p :: "('s \<times> 'a) list \<Rightarrow> 's \<Rightarrow> 'a pmf"
   shows "MDP_cont.is_policy (\<lambda>n (h,s). p (Omega_Words_Fun.prefix n h) s)"
   unfolding MDP_cont.is_policy_def MDP_cont.is_dec_def
   using prefix_measurable measurable_pair_swap_iff
   by (auto simp: prob_space_measure_pmf
       intro: measurable_pair_measure_countable1 measurable_prob_algebraI)
 
 lemma prob_space_T[intro, simp]: "prob_space (T p x)"
   by (auto simp add: T_def prob_space_measure_pmf space_prob_algebra)
 
-lemma T_subprob[simp]: 
+lemma T_subprob[simp]:
   "T p S0 \<in> space (subprob_algebra S)"
   by (metis prob_space.M_in_subprob prob_space_T sets_T subprob_algebra_cong)
 
 lemma T_subprob_space [simp]: "subprob_space (T p S0)"
   by (auto intro: prob_space_imp_subprob_space)
 
-lemma K0_MDP_cont_eq: 
-  "MDP_cont.K0 (\<lambda>x (h,s). measure_pmf (p (Omega_Words_Fun.prefix x h) s)) (measure_pmf S0) = 
+lemma K0_MDP_cont_eq:
+  "MDP_cont.K0 (\<lambda>x (h,s). measure_pmf (p (Omega_Words_Fun.prefix x h) s)) (measure_pmf S0) =
     K0 (p []) S0"
   unfolding MDP_cont.K0_def K0_def MDP_cont.K'_def map_pmf_def
   by (simp add: measure_pmf_bind return_pmf.rep_eq)
 
 subsubsection \<open>Decomposition of the Stream Space\<close>
 text \<open>
 The distribution of traces/walks the MDP allows should intuitively satisfy the following rule:
 
 \<^enum> select the initial state @{term s} from @{term S0}
 \<^enum> pass it to the decision rule @{term "p []"} to determine a distribution over actions
 \<^enum> select the action @{term a}
-\<^item> finally pass the state-action pair @{term "(s,a)"} to the kernel @{term K} to get a new 
+\<^item> finally pass the state-action pair @{term "(s,a)"} to the kernel @{term K} to get a new
   distribution over states @{term s0'}
 
 Then the iteration repeats with the updated policy @{term "\<pi>_Suc p (s,a)"}.
 
 The result carries over from @{thm MDP_cont.lim_stream_eq}.
 \<close>
 
 lemma T_eq:
   shows "T p S0 = do {
     sa \<leftarrow> measure_pmf (K0 (p []) S0);
     \<omega> \<leftarrow> T (\<pi>_Suc p sa) (K sa);
     return S (sa ## \<omega>)
   }"
   unfolding T_def
 proof (subst MDP_cont.lim_stream_eq)
   show "MDP_cont.is_policy (\<lambda>x xa. measure_pmf (case xa of (h, xa) \<Rightarrow> p (Omega_Words_Fun.prefix x h) xa))"
     by auto
-qed (auto simp: space_prob_algebra prob_space_measure_pmf \<pi>_Suc_def MDP_cont.Suc_policy_def 
+qed (auto simp: space_prob_algebra prob_space_measure_pmf \<pi>_Suc_def MDP_cont.Suc_policy_def
     prefix_cons K0_MDP_cont_eq  prod.case_distrib)
 
 lemma T_eq_distr:
   shows "T p S0 = measure_pmf (K0 (p []) S0) \<bind> (\<lambda>sa. distr (T (\<pi>_Suc p sa) (K sa)) S ((##) sa))"
   by (simp add: T_eq[symmetric] bind_return_distr'[symmetric])
 
 text \<open>
-The iteration rule lets us nicely decompose integrals (expected values) over functions on traces of 
+The iteration rule lets us nicely decompose integrals (expected values) over functions on traces of
 the MDP.
 \<close>
 lemma integral_T:
   fixes f :: "('s \<times> 'a) stream \<Rightarrow> real"
   assumes f_bounded: "\<And>x. \<bar>f x\<bar> \<le> B"
   assumes f: "f \<in> borel_measurable S"
   shows "(\<integral>t. f t \<partial>T p x) = \<integral>sa. \<integral>t'. f (sa##t') \<partial>T (\<pi>_Suc p sa) (K sa) \<partial>K0 (p []) x"
 proof -
   note T_eq_distr
   have "(\<integral>t. f t \<partial>T p x) = (\<integral>t. f t \<partial>measure_pmf (K\<^sub>0 (p []) x) \<bind> (\<lambda>sa. distr (T (\<pi>_Suc p sa) (K sa)) (stream_space (count_space UNIV)) ((##) sa)))"
     using T_eq_distr by metis
   also have "\<dots> = measure_pmf.expectation (K\<^sub>0 (p []) x) (\<lambda>sa. LINT t'|T (\<pi>_Suc p sa) (K sa). f (sa ## t'))"
   proof (subst integral_bind[OF f f_bounded, where B' = 1], goal_cases)
     case 1
-    then show ?case 
-      by (auto intro!: prob_space_imp_subprob_space prob_space.prob_space_distr 
+    then show ?case
+      by (auto intro!: prob_space_imp_subprob_space prob_space.prob_space_distr
           simp: space_subprob_algebra)
   next
     case 3
     then show ?case
       by (auto intro!: prob_space.emeasure_le_1 prob_space.prob_space_distr)
   next
     case 4
     then show ?case
       by (auto simp: f integral_distr intro: Bochner_Integration.integral_cong)
   qed auto
   finally show ?thesis.
 qed
 
 
 lemma nn_integral_T:
   assumes f: "f \<in> borel_measurable S"
   shows "(\<integral>\<^sup>+t. f t \<partial>T p x) = (\<integral>\<^sup>+sa. \<integral>\<^sup>+ t'. f (sa##t') \<partial>T (\<pi>_Suc p sa) (K sa) \<partial>K0 (p []) x)"
   unfolding T_eq_distr[of p]
-  by (subst nn_integral_bind[OF f]) 
-    (auto intro!: prob_space_imp_subprob_space prob_space.prob_space_distr 
+  by (subst nn_integral_bind[OF f])
+    (auto intro!: prob_space_imp_subprob_space prob_space.prob_space_distr
       simp: f nn_integral_distr space_subprob_algebra)
 
 subsubsection \<open>A Denotational View on the Stochastic Process\<close>
 text \<open>
-Many definitions on MDPs do not rely on the individual traces but only on the distribution 
+Many definitions on MDPs do not rely on the individual traces but only on the distribution
 of states and actions at each epoch.
 
 We define this view on the trace space as the repeated iteration of @{const K0} and @{term K}.
 It conincides with the definition of @{const T}.
 \<close>
 
 primrec Pn :: "('s, 'a) pol \<Rightarrow> 's pmf \<Rightarrow> nat \<Rightarrow> ('s \<times> 'a) pmf" where
   "Pn p S0 0 = K0 (p []) S0"
 | "Pn p S0 (Suc n) = K0 (p []) S0 \<bind> (\<lambda>sa. Pn (\<pi>_Suc p sa) (K sa) n)"
 declare Pn.simps(2)[simp del]
 
 lemma Pn_eq_T:
   shows "measure_pmf (Pn p S0 n) = distr (T p S0) (count_space UNIV) (\<lambda>t. t !! n)"
 proof (induction n arbitrary: p S0)
   case (0 p S0)
   then show ?case
     unfolding T_eq[of p]
   proof (subst distr_bind[where K = S], goal_cases)
     case 1
-    then show ?case 
+    then show ?case
       by (auto intro!: prob_space_imp_subprob_space subprob_space.bind_in_space)
   next
     case 4
-    then show ?case 
+    then show ?case
       by (subst bind_cong[OF refl, where g = "return (count_space UNIV)"])
         (auto intro!: bind_const' simp: distr_bind[where K = S] distr_return bind_return'' space_stream_space subprob_space_return_ne)
   qed auto
 next
   case (Suc n)
   show ?case
     unfolding T_eq[of p]
   proof (subst distr_bind[where K = S], goal_cases)
     case 1
-    then show ?case 
+    then show ?case
       by (auto intro!: prob_space_imp_subprob_space subprob_space.bind_in_space)[1]
   next
     case 4
     then show ?case
       by (auto simp: Pn.simps(2) measure_pmf_bind Suc bind_return_distr' distr_distr comp_def intro!: bind_cong)
   qed auto
 qed
 
 text \<open>
 The definition of @{const Pn} also allows us to easily prove that only enabled actions can occur in
 the traces of the MDP.
 \<close>
 
 lemma Pn_in_A: "is_policy p \<Longrightarrow> (s, a) \<in> Pn p S0 n \<Longrightarrow> a \<in> A s"
 proof (induction n arbitrary: S0 p)
   case 0
-  then show ?case 
+  then show ?case
     using 0 unfolding is_policy_def is_dec_def
     by (auto simp: K0_def)
 next
   case (Suc n)
   then show ?case
     by (auto simp: Pn.simps(2) K0_def)
 qed
 
 lemma T_in_A:
   assumes "is_policy p"
   shows "AE t in T p S0. snd (t !! n) \<in> A (fst (t !! n))"
 proof -
   have aux: "AE t in distr (T p S0) (count_space UNIV) (\<lambda>t. t !! n). snd t \<in> A (fst t)"
     using assms Pn_eq_T[symmetric]
     by (auto simp: Pn_in_A intro!: AE_pmfI cong: AE_cong_simp)
   show ?thesis
     by (auto intro!: AE_distrD[OF _ aux])
 qed
 
 subsubsection \<open>State Process\<close>
 text \<open>Alongside @{const Pn}, we also define the state and action distributions as projections.\<close>
 
 definition "Xn p S0 n = map_pmf fst (Pn p S0 n)"
 
 lemma X0 [simp]: "Xn p S0 0 = S0"
   using fst_K0 Xn_def by auto
 
 lemma Xn_Suc: "Xn p S0 (Suc n) = Pn p S0 n \<bind> K"
 proof (induction n arbitrary: p S0)
   case 0
   then show ?case
     by (simp add: Pn.simps(2) Xn_def map_bind_pmf)
 next
   case (Suc n)
   then show ?case
     by (simp add: Pn.simps(2) Xn_def map_bind_pmf bind_assoc_pmf)
 qed
 
 lemma Pn_markovian_eq_Xn_bind: "Pn (mk_markovian p) S0 n = K0 (p n) (Xn (mk_markovian p) S0 n)"
 proof (induction n arbitrary: p S0)
   case 0
-  then show ?case 
+  then show ?case
     unfolding Xn_def by auto
 next
   case (Suc n)
   then show ?case
     unfolding Xn_def K0_def
     by (auto intro!: bind_pmf_cong simp: Pn.simps(2) map_bind_pmf Suc bind_assoc_pmf)
 qed
 
 lemma Xn_Suc': "Xn p S0 (Suc n) = K0 (p []) S0 \<bind> (\<lambda>sa. Xn (\<pi>_Suc p sa) (K sa) n)"
   unfolding Xn_def by (auto simp: Pn.simps(2) map_bind_pmf)
 
 lemma set_pmf_X0 [simp]: "set_pmf (Xn p S0 0) = S0"
   using X0 by auto
 
-lemma set_pmf_PSuc: "set_pmf (Pn (mk_markovian p) S0 n) = 
+lemma set_pmf_PSuc: "set_pmf (Pn (mk_markovian p) S0 n) =
   {(s, a). s \<in> set_pmf (Xn (mk_markovian p) S0 n) \<and> a \<in> p n s}"
   using set_pmf_K0 Pn_markovian_eq_Xn_bind
   by auto
 
 subsubsection \<open>The Conditional Distribution of Actions\<close>
 text \<open>
 Actions are selected wrt. the whole history of state-action pairs encountered so far.
 The following definition defines the expected action selection when only the current state is given.\<close>
 definition "Y_cond_X p S0 n x = map_pmf snd (cond_pmf (Pn p S0 n) {(s,a). s = x})"
 
 lemma prob_K0_X [simp]: "measure_pmf.prob (K0 p S0) {(s, a). s = x} = pmf S0 x"
   unfolding K0_iff
 proof (subst measure_pmf_bind, subst measure_pmf.measure_bind[of _ _ "count_space UNIV"], goal_cases)
   case 1
   then show ?case
     by (simp add: measure_pmf_in_subprob_algebra)
 next
   case 3
-  then show ?case 
+  then show ?case
     by (subst integral_measure_pmf_real[of "{x}"]) (auto split: if_splits)
-qed simp  
+qed simp
 
 lemma prob_Pn_X[simp]: "measure_pmf.prob (Pn p S0 n) {(s, a). s = x} = pmf (Xn p S0 n) x"
 proof (induction n arbitrary: p S0)
   case 0
   then show ?case
     by auto
 next
   case (Suc n)
   show ?case
-    unfolding Xn_Suc' Pn.simps(2) measure_pmf_bind 
+    unfolding Xn_Suc' Pn.simps(2) measure_pmf_bind
     using Suc
     by (simp add: measure_pmf.measure_bind[of _ _ "count_space UNIV"] K0_def
         measure_pmf_in_subprob_algebra pmf_bind)
 qed
 
 lemma pmf_Pn_pair:
   assumes "sa \<in> set_pmf (Pn p S0 n)"
   shows "pmf (Pn p S0 n) sa = pmf (Y_cond_X p S0 n (fst sa)) (snd sa) * pmf (Xn p S0 n) (fst sa)"
 proof -
   have aux: "set_pmf (Pn p S0 n) \<inter> {(s, a). s = fst sa} \<noteq> {}"
-    using Xn_def assms 
+    using Xn_def assms
     by auto
   have aux': "({(s, a). s = fst sa} \<inter> snd -` {snd sa}) = {sa}"
     by auto
   show ?thesis
     using assms
     unfolding Y_cond_X_def pmf_map cond_pmf.rep_eq[OF aux]
     by (auto simp: Xn_def pmf_eq_0_set_pmf measure_pmf.emeasure_eq_measure aux' measure_pmf_single)
 qed
 
 lemma pmf_Pn:
   assumes "x \<in> set_pmf (Xn p S0 n)"
   shows "pmf (Pn p S0 n) (x,a) = pmf (Y_cond_X p S0 n x) a * pmf (Xn p S0 n) x"
 proof -
   have aux: "set_pmf (Pn p S0 n) \<inter> {(s, a). s = x} \<noteq> {}"
     using Xn_def assms by auto
   have aux': "({(s, a). s = x} \<inter> snd -` {a}) = {(x, a)}"
     by auto
   show ?thesis
     using assms
     unfolding Y_cond_X_def cond_pmf.rep_eq[OF aux] pmf_map
     by (auto simp: pmf_eq_0_set_pmf measure_pmf.emeasure_eq_measure aux' measure_pmf_single)
 qed
 
 lemma pmf_Y_cond_X:
   assumes "x \<in> set_pmf (Xn p S0 n)"
   shows "pmf (Y_cond_X p S0 n x) a = pmf (Pn p S0 n) (x,a) / pmf (Xn p S0 n) x"
 proof -
   have aux: "set_pmf (Pn p S0 n) \<inter> {(s, a). s = x} \<noteq> {}"
     using Xn_def assms by auto
   have aux': "({(s, a). s = x} \<inter> snd -` {a}) = {(x, a)}"
     by auto
   show ?thesis
     using assms aux'
     unfolding Y_cond_X_def
-    by (auto simp: cond_pmf.rep_eq[OF aux] pmf_map pmf_eq_0_set_pmf measure_pmf.emeasure_eq_measure 
+    by (auto simp: cond_pmf.rep_eq[OF aux] pmf_map pmf_eq_0_set_pmf measure_pmf.emeasure_eq_measure
         measure_pmf_single)
 qed
 
 lemma Y_cond_X_0[simp]:
   assumes "x \<in> set_pmf S0"
   shows "Y_cond_X p S0 0 x = p [] x"
   by (auto intro: pmf_eqI simp: assms pmf_Y_cond_X pmf_eq_0_set_pmf)
 
 (* eqn 5.5.3 in Puterman *)
 lemma Y_cond_X_markovian[simp]:
   assumes h: "x \<in> Xn (mk_markovian p) S0 n"
   shows "Y_cond_X (mk_markovian p) S0 n x = p n x"
   by (auto intro!: pmf_eqI simp: pmf_Y_cond_X h Pn_markovian_eq_Xn_bind pmf_eq_0_set_pmf)
 
 lemma Pn_eq_Xn_Y_cond: "Pn p S0 n = Xn p S0 n \<bind> (\<lambda>x. map_pmf (\<lambda>a. (x, a)) (Y_cond_X p S0 n x))"
 proof (induction n)
   case 0
-  then show ?case 
+  then show ?case
     by (auto simp: K0_iff intro: bind_pmf_cong)
 next
   case (Suc n)
   show ?case
   proof (intro pmf_eqI; safe)
-    fix a :: 's 
+    fix a :: 's
     fix b :: 'a
-    have aux': "pmf (Xn p S0 (Suc n) \<bind> (\<lambda>x. map_pmf (Pair x) (Y_cond_X p S0 (Suc n) x))) (a,b) 
-      = measure_pmf.expectation (Pn p S0 (Suc n)) (\<lambda>x. 
+    have aux': "pmf (Xn p S0 (Suc n) \<bind> (\<lambda>x. map_pmf (Pair x) (Y_cond_X p S0 (Suc n) x))) (a,b)
+      = measure_pmf.expectation (Pn p S0 (Suc n)) (\<lambda>x.
           if fst x = a then pmf (Y_cond_X p S0 (Suc n) a) b else 0)"
-      by (auto intro!: Bochner_Integration.integral_cong[OF refl] 
+      by (auto intro!: Bochner_Integration.integral_cong[OF refl]
           simp: Xn_def bind_map_pmf pmf_map pmf_bind measure_pmf_single)
     also have "\<dots> = measure_pmf.expectation (Pn p S0 (Suc n))
      (\<lambda>x. indicator {(s',a'). s' = a} x * (pmf (Pn p S0 (Suc n)) (a, b) / pmf (Xn p S0 (Suc n)) a))"
     proof (intro Bochner_Integration.integral_cong_AE AE_pmfI)
       fix y
       assume h: "y \<in> set_pmf (Pn p S0 (Suc n))"
       hence h': "fst y \<in> set_pmf (Xn p S0 (Suc n))"
         by (metis mult_eq_0_iff pmf_Pn_pair pmf_eq_0_set_pmf)
-      show "(if fst y = a then pmf (Y_cond_X p S0 (Suc n) a) b else 0) = 
-        indicat_real {(s', a'). s' = a} y * 
+      show "(if fst y = a then pmf (Y_cond_X p S0 (Suc n) a) b else 0) =
+        indicat_real {(s', a'). s' = a} y *
         (pmf (Pn p S0 (Suc n)) (a, b) / pmf (Xn p S0 (Suc n)) a)"
         by (auto simp: case_prod_beta' pmf_Y_cond_X[of "fst y" p S0 "(Suc n)" b, OF h'])
     qed auto
-    also have "\<dots> = measure_pmf.prob (Pn p S0 (Suc n)) {(s',a'). s' = a} * 
+    also have "\<dots> = measure_pmf.prob (Pn p S0 (Suc n)) {(s',a'). s' = a} *
       pmf (Pn p S0 (Suc n)) (a, b) / pmf (Xn p S0 (Suc n)) a"
       by auto
     also have "\<dots> = pmf (Pn p S0 (Suc n)) (a,b)"
       using prob_Pn_X Xn_def pmf_Pn_pair pmf_eq_0_set_pmf by fastforce
-    finally show "pmf (Pn p S0 (Suc n)) (a, b) = pmf (Xn p S0 (Suc n) \<bind> 
+    finally show "pmf (Pn p S0 (Suc n)) (a, b) = pmf (Xn p S0 (Suc n) \<bind>
       (\<lambda>x. map_pmf (Pair x) (Y_cond_X p S0 (Suc n) x))) (a, b)"
       by auto
   qed
 qed
 
-lemma Pn_eq_Xn_Y_cond': 
+lemma Pn_eq_Xn_Y_cond':
   "Pn p S0 n = Xn p S0 n \<bind> (\<lambda>s. Y_cond_X p S0 n s \<bind> (\<lambda>a. return_pmf (s,a)))"
   by (metis K0_def K0_iff Pn_eq_Xn_Y_cond)
 
-lemma Pn_markovian_Suc: "Pn (mk_markovian p) S0 (Suc n) = 
+lemma Pn_markovian_Suc: "Pn (mk_markovian p) S0 (Suc n) =
   Pn (mk_markovian p) S0 n \<bind> (\<lambda>sa. K0 (p (Suc n)) (K sa))"
 proof (induction n arbitrary: S0 p)
   case 0
   then show ?case
     by (auto intro: bind_pmf_cong simp: Pn.simps(2) \<pi>_Suc_def)
 next
   case (Suc n)
   show ?case
     by (auto simp add: Suc bind_assoc_pmf Pn.simps(2)[of _ S0] intro: bind_pmf_cong)
 qed
 
 subsubsection \<open>Action Process\<close>
 text \<open>The distribution of actions.\<close>
 definition "Yn p S0 n = map_pmf snd (Pn p S0 n)"
 
 lemma Y0: "Yn p S0 0 = S0 \<bind> p []"
   by (simp add: Yn_def K0_iff map_bind_pmf map_pmf_comp)
 
 text \<open>
 For markovian policies, the decision rules at each epoch are independent of each other,
 hence we may express @{const Yn} solely in terms of @{const Xn} and the current decision rule.
 \<close>
 
 lemma Yn_markovian: "Yn (mk_markovian p) S0 n = Xn (mk_markovian p) S0 n \<bind> p n"
-proof (induction n arbitrary: p S0) 
+proof (induction n arbitrary: p S0)
   case 0
   then show ?case
     by (auto simp: Y0)
 next
   case (Suc n)
   then show ?case
     by (simp add: Xn_def Yn_def map_bind_pmf Suc Pn.simps(2) bind_assoc_pmf)
 qed
 
 subsection \<open>Restriction to Markovian Policies\<close>
-abbreviation "as_markovian p S0 n x \<equiv> 
+abbreviation "as_markovian p S0 n x \<equiv>
   if x \<in> (Xn p S0 n) then Y_cond_X p S0 n x else return_pmf (SOME a. a \<in> A x)"
 
 text \<open>
 For states which cannot occur we choose an arbitrary enabled action, as in this case we cannot make
 any statements about @{const Y_cond_X} (a distribution conditioned on an event with probability 0).
 \<close>
 
 lemma is_\<Pi>\<^sub>M\<^sub>R_as_markovian:
-  assumes p: "is_policy p" 
+  assumes p: "is_policy p"
   shows "as_markovian p S0 \<in> \<Pi>\<^sub>M\<^sub>R"
 proof -
   have aux: "\<And>hs s. s \<in> set_pmf (Xn p S0 hs) \<Longrightarrow> set_pmf ((Pn p S0 hs)) \<inter> {(s', a). s' = s} \<noteq> {}"
     by (simp add: measure_pmf_zero_iff[symmetric] pmf_eq_0_set_pmf)
   thus ?thesis
     using assms A_ne Pn_in_A
     unfolding is_dec_def Y_cond_X_def
     by (auto simp: some_in_eq)
 qed
 
 lemma is_policy_as_markovian: "is_policy p \<Longrightarrow> is_policy (mk_markovian (as_markovian p S0))"
   using is_\<Pi>\<^sub>M\<^sub>R_as_markovian \<Pi>\<^sub>M\<^sub>R_imp_policies by auto
 
 theorem Pn_as_markovian_eq: "Pn (mk_markovian (as_markovian p S0)) S0 = Pn p S0"
-proof 
+proof
   fix n show "Pn (mk_markovian (as_markovian p S0)) S0 n = Pn p S0 n"
   proof (induction n)
     case 0
     thus ?case
       by (auto intro!: map_pmf_cong bind_pmf_cong simp: K0_def)
   next
     case (Suc n)
-    have "\<And>x. x \<in> Xn p S0 (Suc n) \<Longrightarrow> 
+    have "\<And>x. x \<in> Xn p S0 (Suc n) \<Longrightarrow>
       Y_cond_X (mk_markovian (as_markovian p S0)) S0 (Suc n) x = Y_cond_X p S0 (Suc n) x"
       by (auto simp: Suc.IH Xn_Suc)
     moreover have "Xn (mk_markovian (as_markovian p S0)) S0 (Suc n) = Xn p S0 (Suc n)"
       by (simp add: Xn_Suc Suc.IH)
     ultimately show "Pn (mk_markovian (as_markovian p S0)) S0 (Suc n) = Pn p S0 (Suc n)"
       by (auto intro: bind_pmf_cong simp: Pn_eq_Xn_Y_cond)
   qed
 qed
 
 subsection \<open>MDPs without Initial Distribution\<close>
 text \<open>
 From now on, we assume a known, deterministic initial state.
 All results from the previous discussion carry over as we are now in the special case
 where we the initial state is of the form @{term "return_pmf s"}.
 \<close>
 definition "\<T> p s \<equiv> T p (return_pmf s)"
 
-lemma \<T>_eq_return_distr: "\<T> p s = 
+lemma \<T>_eq_return_distr: "\<T> p s =
   measure_pmf (p [] s) \<bind> (\<lambda>a. distr (T (\<pi>_Suc p (s,a)) (K (s,a))) S ((##) (s,a)))"
   unfolding \<T>_def
-  by (subst T_eq_distr) (fastforce intro!: bind_distr subprob_space.subprob_space_distr 
+  by (subst T_eq_distr) (fastforce intro!: bind_distr subprob_space.subprob_space_distr
       simp: K0_iff map_pmf_rep_eq space_subprob_algebra bind_return_pmf)+
 
 lemma \<T>_eq_return:
   shows "\<T> p s = do {
     y \<leftarrow> measure_pmf (p [] s);
-    \<omega> \<leftarrow> T (\<pi>_Suc p (s,y)) (K (s,y)); 
+    \<omega> \<leftarrow> T (\<pi>_Suc p (s,y)) (K (s,y));
     return S ((s,y) ## \<omega>)
   }"
   by (auto simp: \<T>_eq_return_distr bind_return_distr' prob_space.not_empty intro!: bind_cong)
 
 lemma \<T>_return:
   shows "T p S0 = measure_pmf S0 \<bind> \<T> p"
 proof -
-  have "T p S0 = measure_pmf S0 \<bind> (\<lambda>x. measure_pmf (map_pmf (Pair x) (p [] x))) \<bind> 
+  have "T p S0 = measure_pmf S0 \<bind> (\<lambda>x. measure_pmf (map_pmf (Pair x) (p [] x))) \<bind>
   (\<lambda>sa. distr (T (\<pi>_Suc p sa) (K sa)) (stream_space (count_space UNIV)) ((##) sa))"
     unfolding T_eq_distr[of p] K0_iff measure_pmf_bind
     by auto
   also have "\<dots> = measure_pmf S0 \<bind>
     (\<lambda>x. distr (measure_pmf (p [] x)) (count_space UNIV) (Pair x) \<bind>
           (\<lambda>sa. distr (T (\<pi>_Suc p sa) (K sa)) (stream_space (count_space UNIV)) ((##) sa)))"
-    using measurable_measure_pmf 
+    using measurable_measure_pmf
     by (subst bind_assoc[where N = "count_space UNIV", where R = S])
-      (fastforce intro!: prob_space_imp_subprob_space prob_space.prob_space_distr 
+      (fastforce intro!: prob_space_imp_subprob_space prob_space.prob_space_distr
         simp: space_subprob_algebra prob_space_measure_pmf map_pmf_rep_eq)+
   also have "\<dots> = measure_pmf S0 \<bind> \<T> p"
     by (subst bind_distr[where K  = S])
       (auto intro!: prob_space_imp_subprob_space prob_space.prob_space_distr bind_cong
         simp: space_subprob_algebra \<T>_eq_return_distr)
   finally show ?thesis.
 qed
 
 lemma \<T>_return_eq:
   shows
     "\<T> p s = do {
   a \<leftarrow> measure_pmf (p [] s);
   s' \<leftarrow> measure_pmf (K (s,a));
   w \<leftarrow> T (\<pi>_Suc p (s,a)) (return_pmf s');
   return S ((s,a)##w)
 }"
 proof -
   have "\<T> p s = do {
     a \<leftarrow> measure_pmf (p [] s);
     \<omega> \<leftarrow> T (\<pi>_Suc p (s, a)) (K (s, a));
    return S ((s, a) ## \<omega>)}"
-    using \<T>_eq_return 
+    using \<T>_eq_return
     by auto
   also have "\<dots> =  do {
     a \<leftarrow> measure_pmf (p [] s);
     s' \<leftarrow> measure_pmf (K (s, a));
     \<omega> \<leftarrow> T (\<pi>_Suc p (s, a)) (return_pmf s');
    return S ((s, a) ## \<omega>)}"
     unfolding \<T>_return
     by (subst bind_assoc[of _ _ S _ S]) (auto simp add: \<T>_def \<T>_return[symmetric])
   finally show ?thesis.
 qed
 
 lemma \<T>_eq:
   shows "\<T> p s = do {
   a \<leftarrow> measure_pmf (p [] s);
   s' \<leftarrow> measure_pmf (K (s,a));
   w \<leftarrow> \<T> (\<pi>_Suc p (s,a)) s';
   return S ((s,a)##w)
 }"
   by (subst \<T>_return_eq) (auto simp add: \<T>_def )
 
 lemma \<T>_prob_space[intro]: "prob_space (\<T> p s)"
   by (metis \<T>_def prob_space_T)
 
-lemma \<T>_sets[measurable_cong]: 
+lemma \<T>_sets[measurable_cong]:
   "sets (\<T> p s) = sets S"
   by (simp add: \<T>_def sets_T)
 
-lemma measurable_ident_Suc'[measurable]: 
+lemma measurable_ident_Suc'[measurable]:
   "(\<lambda>x. x) \<in> \<T> (\<pi>_Suc p sa) s' \<rightarrow>\<^sub>M S"
   by (simp add: \<T>_def)
 
-lemma nn_integral_\<T>: 
+lemma nn_integral_\<T>:
   fixes f :: "('s \<times> 'a) stream \<Rightarrow> real"
   assumes f[measurable]: "f \<in> borel_measurable S"
-  shows "(\<integral>\<^sup>+t. f t \<partial>\<T> p s) 
+  shows "(\<integral>\<^sup>+t. f t \<partial>\<T> p s)
     = \<integral>\<^sup>+a. \<integral>\<^sup>+s'. \<integral>\<^sup>+t'. f ((s,a)##t') \<partial>\<T> (\<pi>_Suc p (s,a)) s' \<partial>K (s,a) \<partial>p [] s"
 proof -
-  have "(\<integral>\<^sup>+t. f t \<partial>\<T> p s) = 
+  have "(\<integral>\<^sup>+t. f t \<partial>\<T> p s) =
   \<integral>\<^sup>+ x. \<integral>\<^sup>+ y. (f y) \<partial>measure_pmf (K (s, x)) \<bind> (\<lambda>s'. \<T> (\<pi>_Suc p (s, x)) s' \<bind> (\<lambda>w. return S ((s, x) ## w))) \<partial>(p [] s)"
     unfolding \<T>_eq[of p]
     by (subst nn_integral_bind[of _ S])
       (auto intro!: measure_pmf.bind_in_space subprob_space.bind_in_space simp: \<T>_prob_space prob_space_imp_subprob_space)
   also have "\<dots> = \<integral>\<^sup>+ x. \<integral>\<^sup>+ xa. \<integral>\<^sup>+ y. (f y) \<partial>\<T> (\<pi>_Suc p (s, x)) xa \<bind> (\<lambda>w. return S ((s, x) ## w))
               \<partial>measure_pmf (K (s, x)) \<partial>(p [] s)"
     by (subst nn_integral_bind[of _ S])
       (auto intro!: subprob_space.bind_in_space simp: \<T>_prob_space prob_space_imp_subprob_space)
   also have "\<dots> = \<integral>\<^sup>+ x. \<integral>\<^sup>+ xa. \<integral>\<^sup>+ y. (f y) \<partial>distr (\<T> (\<pi>_Suc p (s, x)) xa) S ((##) (s, x)) \<partial>measure_pmf (K (s, x)) \<partial>(p [] s)"
     by (auto simp add: bind_return_distr' \<T>_prob_space prob_space.not_empty)
   also have "\<dots> = \<integral>\<^sup>+ x. \<integral>\<^sup>+ xa. \<integral>\<^sup>+ xa. (f ((s, x) ## xa)) \<partial>\<T> (\<pi>_Suc p (s, x)) xa \<partial>measure_pmf (K (s, x)) \<partial>(p [] s)"
     by (auto simp: nn_integral_distr)
   finally show ?thesis.
 qed
 
-lemma integral_\<T>: 
+lemma integral_\<T>:
   fixes f :: "('s \<times> 'a) stream \<Rightarrow> real"
   assumes f_bounded: "\<And>x. \<bar>f x\<bar> \<le> B"
   assumes f[measurable]: "f \<in> borel_measurable S"
-  shows "(\<integral>t. f t \<partial>\<T> p s) 
+  shows "(\<integral>t. f t \<partial>\<T> p s)
     = \<integral>a. \<integral>s'. \<integral>t'. f ((s,a)##t') \<partial>\<T> (\<pi>_Suc p (s,a)) s' \<partial>K (s,a) \<partial>p [] s"
   unfolding \<T>_def integral_T[OF f_bounded f] K0_iff bind_return_pmf
   unfolding \<T>_return[of "\<pi>_Suc p _"] integral_map_pmf
   using \<T>_return[of "\<pi>_Suc p _", symmetric]
-  by (subst integral_bind[OF _ f_bounded, where B' = 1, where K = S]) 
+  by (subst integral_bind[OF _ f_bounded, where B' = 1, where K = S])
     (auto simp: \<T>_def intro: prob_space.emeasure_le_1)
 
 lemma integrable_\<T>_bounded[intro]:
   fixes f :: "('s \<times> 'a) stream \<Rightarrow> 'd :: {second_countable_topology,banach}"
   assumes f[measurable]: "f \<in> borel_measurable S"
   assumes b: "bounded (range f)"
   shows "integrable (\<T> p s) f"
   using b
-  by (auto simp: prob_space.finite_measure \<T>_prob_space bounded_iff 
+  by (auto simp: prob_space.finite_measure \<T>_prob_space bounded_iff
       intro!: finite_measure.integrable_const_bound)
 
 definition "Pn' p s = Pn p (return_pmf s)"
 definition "Xn' p s = Xn p (return_pmf s)"
 definition "Yn' p s = Yn p (return_pmf s)"
 definition "K0' d s \<equiv> map_pmf (\<lambda>a. (s, a)) (d s)"
 
 definition "K_st d s \<equiv> d s \<bind> (\<lambda>a. K (s,a))"
 
 lemma pmf_K_st: "pmf (K_st d s) t = \<integral>a. pmf (K(s, a)) t \<partial>d s"
   unfolding K_st_def
   by (subst pmf_bind) auto
 
 text \<open>
 @{const K_st} defines the distribution over the successor states for a given decision rule and state.
 It is mostly useful for markovian policies, as the information which action was selected is lost.\<close>
 
 lemma P0'[simp]: "Pn' p s 0 = K0' (p []) s"
   by (simp add: Pn'_def K0'_def K0_iff bind_return_pmf)
 
 lemma X0'[simp]: "Xn' p s 0 = return_pmf s"
   using X0 Xn'_def by auto
 
 lemma Pn_return_pmf: "S0 \<bind> (\<lambda>s'. Pn p (return_pmf s') n) = Pn p S0 n"
   by (induction n arbitrary: p S0)
     (auto intro: bind_pmf_cong simp add: Pn.simps(2) K0_def bind_assoc_pmf bind_return_pmf)
 
 lemma PSuc': "Pn' p s (Suc n) = K0' (p []) s \<bind> (\<lambda>sa. K sa \<bind> (\<lambda>s'. Pn' (\<pi>_Suc p sa) s' n))"
   unfolding Pn'_def
   by (auto intro!: bind_pmf_cong
       simp: Pn.simps(2) Pn_return_pmf K0_iff K0'_def bind_return_pmf map_bind_pmf bind_map_pmf)
 
-lemma PSuc'_markovian: 
+lemma PSuc'_markovian:
   "Pn' (mk_markovian p) s (Suc n) = K_st (p 0) s \<bind> (\<lambda>s'. Pn' (mk_markovian (p \<circ> Suc)) s' n)"
   unfolding PSuc'
   by (auto simp: bind_map_pmf bind_assoc_pmf comp_def K0'_def K_st_def intro!: bind_pmf_cong)
 
 lemma Xn'_Suc: "Xn' p s (Suc n) = Pn' p s n \<bind> K"
   by (auto simp: Xn_Suc Xn'_def Pn'_def)
 
 lemma Xn'_Pn': "Xn' p s n = map_pmf fst (Pn' p s n)"
   by (simp add: Xn_def Xn'_def Pn'_def)
 
 lemma Suc_Xn': "Xn' p s (Suc n) = p [] s \<bind> (\<lambda>a. K (s,a) \<bind> (\<lambda>s'. Xn' (\<pi>_Suc p (s,a)) s' n))"
   by (auto simp: Xn'_Pn' map_bind_pmf bind_map_pmf PSuc' K0'_def)
 
-lemma Suc_Xn'_markovian: 
+lemma Suc_Xn'_markovian:
   "Xn' (mk_markovian p) s (Suc n) = K_st (p 0) s \<bind> (\<lambda>s'. Xn' (mk_markovian (\<lambda>n. p (Suc n))) s' n)"
   by (auto simp: K_st_def bind_assoc_pmf Suc_Xn')
 
-lemma Xn'_split: "Xn' (mk_markovian p) s (n + m) = 
+lemma Xn'_split: "Xn' (mk_markovian p) s (n + m) =
   Xn' (mk_markovian p) s n \<bind> (\<lambda>s. Xn' (mk_markovian (\<lambda>i. p (i + n))) s m)"
   by (induction n arbitrary: p s) (auto intro!: bind_pmf_cong simp: bind_assoc_pmf bind_return_pmf Suc_Xn')
 
 lemma Yn'_markovian: "Yn' (mk_markovian p) s n = Xn' (mk_markovian p) s n \<bind> p n"
-  unfolding Yn'_def Xn'_def Yn_markovian 
+  unfolding Yn'_def Xn'_def Yn_markovian
   by simp
 
 lemma Pn'_markovian_eq_Xn'_bind: "Pn' (mk_markovian p) s n = Xn' (mk_markovian p) s n \<bind> K0' (p n)"
-  unfolding Xn'_def Pn'_def K0'_def K0_iff Pn_markovian_eq_Xn_bind 
+  unfolding Xn'_def Pn'_def K0'_def K0_iff Pn_markovian_eq_Xn_bind
   by simp
 
 lemma Pn'_eq_\<T>: "measure_pmf (Pn' p s n) = distr (\<T> p s) (count_space UNIV) (\<lambda>t. t !! n)"
   by (auto simp: \<T>_def Pn'_def Pn_eq_T)
 end
-end
\ No newline at end of file
+end
diff --git a/thys/Quasi_Borel_Spaces/Pair_QuasiBorel_Measure.thy b/thys/Quasi_Borel_Spaces/Pair_QuasiBorel_Measure.thy
--- a/thys/Quasi_Borel_Spaces/Pair_QuasiBorel_Measure.thy
+++ b/thys/Quasi_Borel_Spaces/Pair_QuasiBorel_Measure.thy
@@ -1,559 +1,559 @@
 (*  Title:   Pair_QuasiBorel_Measure.thy
     Author:  Michikazu Hirata, Tokyo Institute of Technology
 *)
 
 subsection \<open>Binary Product Measure\<close>
 
 theory Pair_QuasiBorel_Measure
   imports "Monad_QuasiBorel"
 begin
 
 subsubsection \<open> Binary Product Measure\<close>
 text \<open> Special case of \cite{Heunen_2017} Proposition 23 where $\Omega = \mathbb{R}\times \mathbb{R}$ and $X = X \times Y$.
       Let $[\alpha,\mu ] \in P(X)$ and $[\beta ,\nu] \in P(Y)$. $\alpha\times\beta$ is the $\alpha$ in Proposition 23. \<close>
 definition qbs_prob_pair_measure_t :: "['a qbs_prob_t, 'b qbs_prob_t] \<Rightarrow> ('a \<times> 'b) qbs_prob_t" where
 "qbs_prob_pair_measure_t p q  \<equiv> (let (X,\<alpha>,\<mu>) = p;
                                      (Y,\<beta>,\<nu>) = q in
                                  (X \<Otimes>\<^sub>Q Y, map_prod \<alpha> \<beta> \<circ> real_real.g, distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f))"
 
 lift_definition qbs_prob_pair_measure :: "['a qbs_prob_space, 'b qbs_prob_space] \<Rightarrow> ('a \<times> 'b) qbs_prob_space" (infix "\<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s" 80)
 is qbs_prob_pair_measure_t
   unfolding qbs_prob_pair_measure_t_def
 proof auto
   fix X X' :: "'a quasi_borel"
   fix Y Y' :: "'b quasi_borel"
   fix \<alpha> \<alpha>' \<mu> \<mu>' \<beta> \<beta>' \<nu> \<nu>'
   assume h:"qbs_prob_eq (X,\<alpha>,\<mu>) (X',\<alpha>',\<mu>')"
            "qbs_prob_eq (Y,\<beta>,\<nu>) (Y',\<beta>',\<nu>')"
   then have 1: "X = X'" "Y = Y'"
     by(auto simp: qbs_prob_eq_def)
   interpret pqp1: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: pair_qbs_probs_def qbs_prob_eq_dest(1)[OF h(1)] qbs_prob_eq_dest(1)[OF h(2)])
   interpret pqp2: pair_qbs_probs X' \<alpha>' \<mu>' Y' \<beta>' \<nu>'
     by(simp add: pair_qbs_probs_def qbs_prob_eq_dest(2)[OF h(1)] qbs_prob_eq_dest(2)[OF h(2)])
   interpret pqp: pair_qbs_prob "X \<Otimes>\<^sub>Q Y" "map_prod \<alpha> \<beta> \<circ> real_real.g" "distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f" "X' \<Otimes>\<^sub>Q Y'" "map_prod \<alpha>' \<beta>' \<circ> real_real.g" "distr (\<mu>' \<Otimes>\<^sub>M \<nu>') real_borel real_real.f"
     by(auto intro!: qbs_probI pqp1.P.prob_space_distr pqp2.P.prob_space_distr simp: pair_qbs_prob_def)
 
   show "qbs_prob_eq (X \<Otimes>\<^sub>Q Y, map_prod \<alpha> \<beta> \<circ> real_real.g, distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f) (X' \<Otimes>\<^sub>Q Y', map_prod \<alpha>' \<beta>' \<circ> real_real.g, distr (\<mu>' \<Otimes>\<^sub>M \<nu>') real_borel real_real.f)"
   proof(rule pqp.qbs_prob_space_eq_inverse(1))
     show "qbs_prob_space (X \<Otimes>\<^sub>Q Y, map_prod \<alpha> \<beta> \<circ> real_real.g, distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f)
            = qbs_prob_space (X' \<Otimes>\<^sub>Q Y', map_prod \<alpha>' \<beta>' \<circ> real_real.g, distr (\<mu>' \<Otimes>\<^sub>M \<nu>') real_borel real_real.f)"
          (is "?lhs = ?rhs")
     proof -
       have "?lhs = qbs_prob_space (X, \<alpha>, \<mu>) \<bind> (\<lambda>x. qbs_prob_space (Y, \<beta>, \<nu>) \<bind> (\<lambda>y. qbs_return (X \<Otimes>\<^sub>Q Y) (x, y)))"
         by(simp add: pqp1.qbs_bind_return_pq)
       also have "... = qbs_prob_space (X', \<alpha>', \<mu>') \<bind> (\<lambda>x. qbs_prob_space (Y', \<beta>', \<nu>') \<bind> (\<lambda>y. qbs_return (X' \<Otimes>\<^sub>Q Y') (x, y)))"
         using h by(simp add: qbs_prob_space_eq 1)
       also have "... = ?rhs"
         by(simp add: pqp2.qbs_bind_return_pq)
       finally show ?thesis .
     qed
   qed
 qed
 
 lemma(in pair_qbs_probs) qbs_prob_pair_measure_computation:
   "(qbs_prob_space (X,\<alpha>,\<mu>)) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s (qbs_prob_space (Y,\<beta>,\<nu>)) = qbs_prob_space (X \<Otimes>\<^sub>Q Y, map_prod \<alpha> \<beta> \<circ> real_real.g , distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f)"
   "qbs_prob (X \<Otimes>\<^sub>Q Y) (map_prod \<alpha> \<beta> \<circ> real_real.g) (distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f)"
   by(simp_all add: qbs_prob_pair_measure.abs_eq qbs_prob_pair_measure_t_def qbs_bind_return_pq)
 
 lemma qbs_prob_pair_measure_qbs:
   "qbs_prob_space_qbs (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) = qbs_prob_space_qbs p \<Otimes>\<^sub>Q qbs_prob_space_qbs q"
   by(transfer,simp add: qbs_prob_pair_measure_t_def Let_def prod.case_eq_if)
 
 lemma(in pair_qbs_probs) qbs_prob_pair_measure_measure:
     shows "qbs_prob_measure (qbs_prob_space (X,\<alpha>,\<mu>) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s qbs_prob_space (Y,\<beta>,\<nu>)) = distr (\<mu> \<Otimes>\<^sub>M \<nu>) (qbs_to_measure (X \<Otimes>\<^sub>Q Y)) (map_prod \<alpha> \<beta>)"
   by(simp add: qbs_prob_pair_measure_computation distr_distr comp_assoc)
 
 lemma qbs_prob_pair_measure_morphism:
  "case_prod qbs_prob_pair_measure \<in> monadP_qbs X \<Otimes>\<^sub>Q monadP_qbs Y \<rightarrow>\<^sub>Q monadP_qbs (X \<Otimes>\<^sub>Q Y)"
 proof(rule pair_qbs_morphismI)
   fix \<beta>x \<beta>y
   assume h: "\<beta>x \<in> qbs_Mx (monadP_qbs X)" " \<beta>y \<in> qbs_Mx (monadP_qbs Y)"
   then obtain \<alpha>x \<alpha>y gx gy where ha:
    "\<alpha>x \<in> qbs_Mx X" "gx \<in> real_borel \<rightarrow>\<^sub>M prob_algebra real_borel" "\<beta>x = (\<lambda>r. qbs_prob_space (X, \<alpha>x, gx r))"
    "\<alpha>y \<in> qbs_Mx Y" "gy \<in> real_borel \<rightarrow>\<^sub>M prob_algebra real_borel" "\<beta>y = (\<lambda>r. qbs_prob_space (Y, \<alpha>y, gy r))"
     using rep_monadP_qbs_MPx[of \<beta>x X] rep_monadP_qbs_MPx[of \<beta>y Y] by auto
   note [measurable] = ha(2,5)
   have "(\<lambda>(x, y). x \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s y) \<circ> (\<lambda>r. (\<beta>x r, \<beta>y r)) = (\<lambda>r. qbs_prob_space (X \<Otimes>\<^sub>Q Y, map_prod \<alpha>x \<alpha>y \<circ> real_real.g, distr (gx r \<Otimes>\<^sub>M gy r) real_borel real_real.f))"
     apply standard
     using qbs_prob_MPx[OF ha(1,2)] qbs_prob_MPx[OF ha(4,5)] pair_qbs_probs.qbs_prob_pair_measure_computation[of X \<alpha>x _ Y \<alpha>y]
     by (auto simp: ha pair_qbs_probs_def)
   also have "... \<in> qbs_Mx (monadP_qbs (X \<Otimes>\<^sub>Q Y))"
     using qbs_prob_MPx[OF ha(1,2)] qbs_prob_MPx[OF ha(4,5)] pair_qbs_probs.ab_g_in_Mx[of X \<alpha>x _ Y \<alpha>y]
     by(auto intro!: bexI[where x="map_prod \<alpha>x \<alpha>y \<circ> real_real.g"] bexI[where x="\<lambda>r. distr (gx r \<Otimes>\<^sub>M gy r) real_borel real_real.f"]
          simp: monadP_qbs_MPx_def in_MPx_def pair_qbs_probs_def)
   finally show "(\<lambda>(x, y). x \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s y) \<circ> (\<lambda>r. (\<beta>x r, \<beta>y r)) \<in> qbs_Mx (monadP_qbs (X \<Otimes>\<^sub>Q Y))" .
 qed
 
 lemma(in pair_qbs_probs) qbs_prob_pair_measure_nnintegral:
   assumes "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
   shows "(\<integral>\<^sup>+\<^sub>Q z. f z \<partial>(qbs_prob_space (X,\<alpha>,\<mu>) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s qbs_prob_space (Y,\<beta>,\<nu>))) = (\<integral>\<^sup>+ z. (f \<circ> map_prod \<alpha> \<beta>) z \<partial>(\<mu> \<Otimes>\<^sub>M \<nu>))"
         (is "?lhs = ?rhs")
 proof -
   have "?lhs = (\<integral>\<^sup>+ x. ((f \<circ> map_prod \<alpha> \<beta>) \<circ> real_real.g) x \<partial>distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f)"
     by(simp add: qbs_prob_ennintegral_def[OF assms] qbs_prob_pair_measure_computation)
   also have "... = (\<integral>\<^sup>+ x. ((f \<circ> map_prod \<alpha> \<beta>) \<circ> real_real.g) (real_real.f x) \<partial>(\<mu> \<Otimes>\<^sub>M \<nu>))"
     using assms by(intro nn_integral_distr) auto
   also have "... = ?rhs" by simp
   finally show ?thesis .
 qed
 
 lemma(in pair_qbs_probs) qbs_prob_pair_measure_integral:
   assumes "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     shows "(\<integral>\<^sub>Q z. f z \<partial>(qbs_prob_space (X,\<alpha>,\<mu>) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s qbs_prob_space (Y,\<beta>,\<nu>))) = (\<integral>z. (f \<circ> map_prod \<alpha> \<beta>) z \<partial>(\<mu> \<Otimes>\<^sub>M \<nu>))"
           (is "?lhs = ?rhs")
 proof -
   have "?lhs = (\<integral>x. ((f \<circ> map_prod \<alpha> \<beta>) \<circ> real_real.g) x \<partial>distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f)"
     by(simp add: qbs_prob_integral_def[OF assms] qbs_prob_pair_measure_computation)
   also have "... = (\<integral> x. ((f \<circ> map_prod \<alpha> \<beta>) \<circ> real_real.g) (real_real.f x) \<partial>(\<mu> \<Otimes>\<^sub>M \<nu>))"
     using assms by(intro integral_distr) auto
   also have "... = ?rhs" by simp
   finally show ?thesis .
 qed
 
 lemma qbs_prob_pair_measure_eq_bind:
   assumes "p \<in> monadP_qbs_Px X"
       and "q \<in> monadP_qbs_Px Y"
     shows "p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q = p \<bind> (\<lambda>x. q \<bind> (\<lambda>y. qbs_return (X \<Otimes>\<^sub>Q Y) (x,y)))"
 proof -
   obtain \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_monadP_qbs_Px[OF assms(1)] by auto
   obtain \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_monadP_qbs_Px[OF assms(2)] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: pair_qbs_probs_def hp hq)
   show ?thesis
     by(simp add: hp(1) hq(1) pqp.qbs_prob_pair_measure_computation(1) pqp.qbs_bind_return_pq(1))
 qed
 
 subsubsection \<open>Fubini Theorem\<close>
 lemma qbs_prob_ennintegral_Fubini_fst:
   assumes "p \<in> monadP_qbs_Px X"
           "q \<in> monadP_qbs_Px Y"
       and "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "(\<integral>\<^sup>+\<^sub>Q x. \<integral>\<^sup>+\<^sub>Q y. f (x,y) \<partial>q \<partial>p) = (\<integral>\<^sup>+\<^sub>Q z. f z \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
           (is "?lhs = ?rhs")
 proof -
   note [simp] = qbs_bind_morphism[OF qbs_morphism_const[of _ "monadP_qbs Y",simplified,OF assms(2)] curry_preserves_morphisms[OF qbs_return_morphism[of "X \<Otimes>\<^sub>Q Y"]],simplified curry_def,simplified]
                 qbs_morphism_Pair1'[OF _ qbs_return_morphism[of "X \<Otimes>\<^sub>Q Y"]]
                 assms(1)[simplified monadP_qbs_Px_def,simplified] assms(2)[simplified monadP_qbs_Px_def,simplified]
   have "?rhs = (\<integral>\<^sup>+\<^sub>Q z. f z \<partial>(p \<bind> (\<lambda>x. q \<bind> (\<lambda>y. qbs_return (X \<Otimes>\<^sub>Q Y) (x,y)))))"
     by(simp add: qbs_prob_pair_measure_eq_bind[OF assms(1,2)])
   also have "... = (\<integral>\<^sup>+\<^sub>Q x. qbs_prob_ennintegral (q \<bind> (\<lambda>y. qbs_return (X \<Otimes>\<^sub>Q Y) (x, y))) f \<partial>p)"
     by(auto intro!: qbs_prob_ennintegral_bind[OF assms(1) _ assms(3)])
   also have "... =  (\<integral>\<^sup>+\<^sub>Q x. \<integral>\<^sup>+\<^sub>Q y. qbs_prob_ennintegral (qbs_return (X \<Otimes>\<^sub>Q Y) (x, y)) f \<partial>q \<partial>p)"
     by(auto intro!: qbs_prob_ennintegral_cong qbs_prob_ennintegral_bind[OF assms(2) _ assms(3)])
   also have "... = ?lhs"
     using assms(3) by(auto intro!: qbs_prob_ennintegral_cong qbs_prob_ennintegral_return)
   finally show ?thesis by simp
 qed
 
 lemma qbs_prob_ennintegral_Fubini_snd:
   assumes "p \<in> monadP_qbs_Px X"
           "q \<in> monadP_qbs_Px Y"
       and "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "(\<integral>\<^sup>+\<^sub>Q y. \<integral>\<^sup>+\<^sub>Q x. f (x,y) \<partial>p \<partial>q) = (\<integral>\<^sup>+\<^sub>Q x. f x \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
           (is "?lhs = ?rhs")
 proof -
   note [simp] = qbs_bind_morphism[OF qbs_morphism_const[of _ "monadP_qbs X",simplified,OF assms(1)] curry_preserves_morphisms[OF qbs_morphism_pair_swap[OF qbs_return_morphism[of "X \<Otimes>\<^sub>Q Y"]],simplified curry_def,simplified]]
                 qbs_morphism_Pair2'[OF _ qbs_return_morphism[of "X \<Otimes>\<^sub>Q Y"]]
                 assms(1)[simplified monadP_qbs_Px_def,simplified] assms(2)[simplified monadP_qbs_Px_def,simplified]
   have "?rhs = (\<integral>\<^sup>+\<^sub>Q z. f z \<partial>(q \<bind> (\<lambda>y. p \<bind> (\<lambda>x. qbs_return (X \<Otimes>\<^sub>Q Y) (x,y)))))"
     by(simp add: qbs_prob_pair_measure_eq_bind[OF assms(1,2)] qbs_bind_return_rotate[OF assms(1,2)])
   also have "... = (\<integral>\<^sup>+\<^sub>Q y. qbs_prob_ennintegral (p \<bind> (\<lambda>x. qbs_return (X \<Otimes>\<^sub>Q Y) (x, y))) f \<partial>q)"
     by(auto intro!: qbs_prob_ennintegral_bind[OF assms(2) _ assms(3)])
   also have "... =  (\<integral>\<^sup>+\<^sub>Q y. \<integral>\<^sup>+\<^sub>Q x. qbs_prob_ennintegral (qbs_return (X \<Otimes>\<^sub>Q Y) (x, y)) f \<partial>p \<partial>q)"
     by(auto intro!: qbs_prob_ennintegral_cong qbs_prob_ennintegral_bind[OF assms(1) _ assms(3)])
   also have "... = ?lhs"
     using assms(3) by(auto intro!: qbs_prob_ennintegral_cong qbs_prob_ennintegral_return)
   finally show ?thesis by simp
 qed
 
 lemma qbs_prob_ennintegral_indep1:
   assumes "p \<in> monadP_qbs_Px X"
       and "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "(\<integral>\<^sup>+\<^sub>Q z. f (fst z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sup>+\<^sub>Q x. f x \<partial>p)"
           (is "?lhs = _")
 proof -
  obtain Y \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_qbs_prob_space[of q] by auto
   have "?lhs = (\<integral>\<^sup>+\<^sub>Q y. \<integral>\<^sup>+\<^sub>Q x. f x \<partial>p \<partial>q)"
     using qbs_prob_ennintegral_Fubini_snd[OF assms(1) qbs_prob.qbs_prob_space_in_Px[OF hq(2)] qbs_morphism_fst''[OF assms(2)]]
     by(simp add: hq(1))
   thus ?thesis
     by(simp add: qbs_prob_ennintegral_const)
 qed
 
 lemma qbs_prob_ennintegral_indep2:
   assumes "q \<in> monadP_qbs_Px Y"
       and "f \<in> Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "(\<integral>\<^sup>+\<^sub>Q z. f (snd z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sup>+\<^sub>Q y. f y \<partial>q)"
           (is "?lhs = _")
 proof -
   obtain X \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of p] by auto
   have "?lhs = (\<integral>\<^sup>+\<^sub>Q x. \<integral>\<^sup>+\<^sub>Q y. f y \<partial>q \<partial>p)"
     using qbs_prob_ennintegral_Fubini_fst[OF qbs_prob.qbs_prob_space_in_Px[OF hp(2)] assms(1) qbs_morphism_snd''[OF assms(2)]]
     by(simp add: hp(1))
   thus ?thesis
     by(simp add: qbs_prob_ennintegral_const)
 qed
 
 lemma qbs_ennintegral_indep_mult:
   assumes "p \<in> monadP_qbs_Px X"
           "q \<in> monadP_qbs_Px Y"
           "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
       and "g \<in> Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "(\<integral>\<^sup>+\<^sub>Q z. f (fst z) * g (snd z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sup>+\<^sub>Q x. f x \<partial>p) * (\<integral>\<^sup>+\<^sub>Q y. g y \<partial>q)"
           (is "?lhs = ?rhs")
 proof -
   have h:"(\<lambda>z. f (fst z) * g (snd z)) \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
-    using assms(4,3) 
+    using assms(4,3)
     by(auto intro!: borel_measurable_subalgebra[OF l_product_sets[of X Y]] simp: space_pair_measure lr_adjunction_correspondence)
 
   have "?lhs = (\<integral>\<^sup>+\<^sub>Q x. \<integral>\<^sup>+\<^sub>Q y .f x * g y \<partial>q \<partial>p)"
     using qbs_prob_ennintegral_Fubini_fst[OF assms(1,2) h] by simp
   also have "... = (\<integral>\<^sup>+\<^sub>Q x. f x * \<integral>\<^sup>+\<^sub>Q y . g y \<partial>q \<partial>p)"
     using qbs_prob_ennintegral_cmult[of q,OF _ assms(4)] assms(2)
     by(simp add: monadP_qbs_Px_def)
   also have "... = ?rhs"
     using qbs_prob_ennintegral_cmult[of p,OF _ assms(3)] assms(1)
     by(simp add: ab_semigroup_mult_class.mult.commute[where b="qbs_prob_ennintegral q g"] monadP_qbs_Px_def)
   finally show ?thesis .
 qed
 
 
 lemma(in pair_qbs_probs) qbs_prob_pair_measure_integrable:
   assumes "qbs_integrable (qbs_prob_space (X,\<alpha>,\<mu>) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s qbs_prob_space (Y,\<beta>,\<nu>)) f"
     shows "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
           "integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (f \<circ> (map_prod \<alpha> \<beta>))"
 proof -
   show "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     using qbs_integrable_morphism[OF qbs_prob_pair_measure_qbs assms]
     by simp
 next
   have 1:"integrable (distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f) (f \<circ> (map_prod \<alpha> \<beta> \<circ> real_real.g))"
     using assms[simplified qbs_prob_pair_measure_computation] qbs_integrable_def[of f]
     by simp
   have "integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (\<lambda>x. (f \<circ> (map_prod \<alpha> \<beta> \<circ> real_real.g)) (real_real.f x))"
     by(intro integrable_distr[OF _ 1]) simp
   thus "integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (f \<circ> map_prod \<alpha> \<beta>)"
     by(simp add: comp_def)
 qed
 
 lemma(in pair_qbs_probs) qbs_prob_pair_measure_integrable':
   assumes "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
       and "integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (f \<circ> (map_prod \<alpha> \<beta>))"
-    shows "qbs_integrable (qbs_prob_space (X,\<alpha>,\<mu>) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s qbs_prob_space (Y,\<beta>,\<nu>)) f" 
+    shows "qbs_integrable (qbs_prob_space (X,\<alpha>,\<mu>) \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s qbs_prob_space (Y,\<beta>,\<nu>)) f"
 proof -
   have "integrable (distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f) (f \<circ> (map_prod \<alpha> \<beta> \<circ> real_real.g)) = integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (\<lambda>x. (f \<circ> (map_prod \<alpha> \<beta> \<circ> real_real.g)) (real_real.f x))"
     by(intro integrable_distr_eq) (use assms(1) in auto)
   thus ?thesis
     using assms qbs_integrable_def
     by(simp add: comp_def qbs_prob_pair_measure_computation)
 qed
 
 lemma qbs_integrable_pair_swap:
   assumes "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
   shows "qbs_integrable (q \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s p) (\<lambda>(x,y). f (y,x))"
 proof -
   obtain X \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of p] by auto
   obtain Y \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_qbs_prob_space[of q] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: pair_qbs_probs_def hp hq)
   interpret pqp2: pair_qbs_probs Y \<beta> \<nu> X \<alpha> \<mu>
     by(simp add: pair_qbs_probs_def hp hq)
- 
+
   have "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
        "integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (f \<circ> map_prod \<alpha> \<beta>)"
     by(auto simp: pqp.qbs_prob_pair_measure_integrable[OF assms[simplified hp(1) hq(1)]])
   from qbs_morphism_pair_swap[OF this(1)] pqp.integrable_product_swap[OF this(2)]
   have "(\<lambda>(x,y). f (y,x)) \<in> Y \<Otimes>\<^sub>Q X \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
         "integrable (\<nu> \<Otimes>\<^sub>M \<mu>) ((\<lambda>(x,y). f (y,x)) \<circ> map_prod \<beta> \<alpha>)"
     by(simp_all add: map_prod_def comp_def split_beta')
   from pqp2.qbs_prob_pair_measure_integrable' [OF this]
   show ?thesis by(simp add: hp(1) hq(1))
 qed
 
 lemma qbs_integrable_pair1:
   assumes "p \<in> monadP_qbs_Px X"
           "q \<in> monadP_qbs_Px Y"
           "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
           "qbs_integrable p (\<lambda>x. \<integral>\<^sub>Q y. \<bar>f (x,y)\<bar> \<partial>q)"
       and "\<And>x. x \<in> qbs_space X \<Longrightarrow> qbs_integrable q (\<lambda>y. f (x,y))"
     shows "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
 proof -
   obtain \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_monadP_qbs_Px[OF assms(1)] by auto
   obtain \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_monadP_qbs_Px[OF assms(2)] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: pair_qbs_probs_def hp hq)
 
   have "integrable (\<mu> \<Otimes>\<^sub>M \<nu>) (f \<circ> map_prod \<alpha> \<beta>)"
   proof(rule pqp.Fubini_integrable)
     show "f \<circ> map_prod \<alpha> \<beta> \<in> borel_measurable (\<mu> \<Otimes>\<^sub>M \<nu>)"
       using assms(3) by auto
   next
     have "(\<lambda>x. LINT y|\<nu>. norm ((f \<circ> map_prod \<alpha> \<beta>) (x, y))) = (\<lambda>x. \<integral>\<^sub>Q y. \<bar>f (x,y)\<bar> \<partial>q) \<circ> \<alpha>"
       apply standard subgoal for x
         using qbs_morphism_Pair1'[OF qbs_Mx_to_X(2)[OF pqp.qp1.in_Mx,of x] assms(3)]
         by(auto intro!: pqp.qp2.qbs_prob_integral_def[symmetric] simp: hq(1))
       done
     moreover have "integrable \<mu> ..."
       using assms(4) pqp.qp1.qbs_integrable_def
       by (simp add: hp(1))
     ultimately show "integrable \<mu> (\<lambda>x. LINT y|\<nu>. norm ((f \<circ> map_prod \<alpha> \<beta>) (x, y)))"
       by simp
   next
     have "\<And>x. integrable \<nu> (\<lambda>y. (f \<circ> map_prod \<alpha> \<beta>) (x, y))"
     proof-
       fix x
       have "(\<lambda>y. (f \<circ> map_prod \<alpha> \<beta>) (x, y)) = (\<lambda>y. f (\<alpha> x,y)) \<circ> \<beta>"
         by auto
       moreover have "qbs_integrable (qbs_prob_space (Y, \<beta>, \<nu>)) (\<lambda>y. f (\<alpha> x, y))"
         by(auto intro!: assms(5)[simplified hq(1)] simp: qbs_Mx_to_X)
       ultimately show "integrable \<nu> (\<lambda>y. (f \<circ> map_prod \<alpha> \<beta>) (x, y))"
         by(simp add: pqp.qp2.qbs_integrable_def)
     qed
     thus "AE x in \<mu>. integrable \<nu> (\<lambda>y. (f \<circ> map_prod \<alpha> \<beta>) (x, y))"
       by simp
   qed
   thus ?thesis
     using pqp.qbs_prob_pair_measure_integrable'[OF assms(3)]
     by(simp add: hp(1) hq(1))
 qed
 
 lemma qbs_integrable_pair2:
   assumes "p \<in> monadP_qbs_Px X"
           "q \<in> monadP_qbs_Px Y"
           "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
           "qbs_integrable q (\<lambda>y. \<integral>\<^sub>Q x. \<bar>f (x,y)\<bar> \<partial>p)"
       and "\<And>y. y \<in> qbs_space Y \<Longrightarrow> qbs_integrable p (\<lambda>x. f (x,y))"
     shows "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
   using qbs_integrable_pair_swap[OF qbs_integrable_pair1[OF assms(2,1) qbs_morphism_pair_swap[OF assms(3)],simplified,OF assms(4,5)]]
   by simp
 
 lemma qbs_integrable_fst:
   assumes "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
   shows "qbs_integrable p (\<lambda>x. \<integral>\<^sub>Q y. f (x,y) \<partial>q)"
 proof -
   obtain X \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of p] by auto
   obtain Y \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_qbs_prob_space[of q] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: hp hq  pair_qbs_probs_def)
   have h0: "p \<in> monadP_qbs_Px X" "q \<in> monadP_qbs_Px Y" "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     using qbs_integrable_morphism[OF _ assms,simplified qbs_prob_pair_measure_qbs]
     by(simp_all add: monadP_qbs_Px_def hp(1) hq(1))
 
   show "qbs_integrable p (\<lambda>x. \<integral>\<^sub>Q y. f (x, y) \<partial>q)"
   proof(auto simp add: pqp.qp1.qbs_integrable_def hp(1))
     show "(\<lambda>x. \<integral>\<^sub>Q y. f (x, y) \<partial>q) \<in> borel_measurable (qbs_to_measure X)"
       using qbs_morphism_integral_fst[OF h0(2,3)] by auto
   next
     have "integrable \<mu> (\<lambda>x. LINT y|\<nu>. (f \<circ> map_prod \<alpha> \<beta>) (x, y))"
       by(intro pqp.integrable_fst') (rule pqp.qbs_prob_pair_measure_integrable(2)[OF assms[simplified hp(1) hq(1)]])
     moreover have "\<And>x. ((\<lambda>x. \<integral>\<^sub>Q y. f (x, y) \<partial>q) \<circ> \<alpha>) x = LINT y|\<nu>. (f \<circ> map_prod \<alpha> \<beta>) (x, y)"
      by(auto intro!: pqp.qp2.qbs_prob_integral_def qbs_morphism_Pair1'[OF qbs_Mx_to_X(2)[OF pqp.qp1.in_Mx] h0(3)] simp: hq)
     ultimately show "integrable \<mu> ((\<lambda>x. \<integral>\<^sub>Q y. f (x, y) \<partial>q) \<circ> \<alpha>)"
-      using integrable_cong[of \<mu> \<mu> "(\<lambda>x. \<integral>\<^sub>Q y. f (x, y) \<partial>q) \<circ> \<alpha>" " (\<lambda>x. LINT y|\<nu>. (f \<circ> map_prod \<alpha> \<beta>) (x, y))"]
+      using Bochner_Integration.integrable_cong[of \<mu> \<mu> "(\<lambda>x. \<integral>\<^sub>Q y. f (x, y) \<partial>q) \<circ> \<alpha>" " (\<lambda>x. LINT y|\<nu>. (f \<circ> map_prod \<alpha> \<beta>) (x, y))"]
       by simp
   qed
 qed
 
 lemma qbs_integrable_snd:
   assumes "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
   shows "qbs_integrable q (\<lambda>y. \<integral>\<^sub>Q x. f (x,y) \<partial>p)"
   using qbs_integrable_fst[OF qbs_integrable_pair_swap[OF assms]]
   by simp
 
 lemma qbs_integrable_indep_mult:
   assumes "qbs_integrable p f"
       and "qbs_integrable q g"
     shows "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>x. f (fst x) * g (snd x))"
 proof -
   obtain X \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of p] by auto
   obtain Y \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_qbs_prob_space[of q] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: hp hq  pair_qbs_probs_def)
   have h0: "p \<in> monadP_qbs_Px X" "q \<in> monadP_qbs_Px Y" "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q" "g \<in> Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     using qbs_integrable_morphism[OF _ assms(1)] qbs_integrable_morphism[OF _ assms(2)]
     by(simp_all add: monadP_qbs_Px_def hp(1) hq(1))
 
   show ?thesis
   proof(rule qbs_integrable_pair1[OF h0(1,2)],simp_all add: assms(2))
     show "(\<lambda>z. f (fst z) * g (snd z)) \<in>  X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
       using h0(3,4) by(auto intro!: borel_measurable_subalgebra[OF l_product_sets[of X Y]] simp: space_pair_measure lr_adjunction_correspondence)
   next
     show "qbs_integrable p (\<lambda>x. \<integral>\<^sub>Q y. \<bar>f x * g y\<bar> \<partial>q)"
       by(auto intro!: qbs_integrable_mult[OF qbs_integrable_abs[OF assms(1)]]
            simp only: idom_abs_sgn_class.abs_mult qbs_prob_integral_cmult ab_semigroup_mult_class.mult.commute[where b="\<integral>\<^sub>Q y. \<bar>g y\<bar> \<partial>q"])
   qed
 qed
 
 lemma qbs_integrable_indep1:
   assumes "qbs_integrable p f"
   shows "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>x. f (fst x))"
   using qbs_integrable_indep_mult[OF assms qbs_integrable_const[of q 1]]
   by simp
 
 lemma qbs_integrable_indep2:
   assumes "qbs_integrable q g"
   shows "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>x. g (snd x))"
   using qbs_integrable_pair_swap[OF qbs_integrable_indep1[OF assms],of p]
   by(simp add: split_beta')
 
 
 lemma qbs_prob_integral_Fubini_fst:
   assumes "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
     shows "(\<integral>\<^sub>Q x. \<integral>\<^sub>Q y. f (x,y) \<partial>q \<partial>p) = (\<integral>\<^sub>Q z. f z \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
           (is "?lhs = ?rhs")
 proof -
   obtain X \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of p] by auto
   obtain Y \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_qbs_prob_space[of q] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: hp hq  pair_qbs_probs_def)
   have h0: "p \<in> monadP_qbs_Px X" "q \<in> monadP_qbs_Px Y" "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     using qbs_integrable_morphism[OF _ assms,simplified qbs_prob_pair_measure_qbs]
     by(simp_all add: monadP_qbs_Px_def hp(1) hq(1))
 
   have "?lhs = (\<integral> x. \<integral>\<^sub>Q y. f (\<alpha> x, y) \<partial>q \<partial>\<mu>)"
     using qbs_morphism_integral_fst[OF h0(2) h0(3)]
     by(auto intro!: pqp.qp1.qbs_prob_integral_def simp: hp(1))
   also have "... = (\<integral>x. \<integral>y. f (\<alpha> x, \<beta> y) \<partial>\<nu> \<partial>\<mu>)"
     using qbs_morphism_Pair1'[OF qbs_Mx_to_X(2)[OF pqp.qp1.in_Mx] h0(3)]
     by(auto intro!: Bochner_Integration.integral_cong pqp.qp2.qbs_prob_integral_def
               simp: hq(1))
   also have "... = (\<integral>z. (f \<circ> map_prod \<alpha> \<beta>) z \<partial>(\<mu> \<Otimes>\<^sub>M \<nu>))"
     using pqp.integral_fst'[OF pqp.qbs_prob_pair_measure_integrable(2)[OF assms[simplified hp(1) hq(1)]]]
     by(simp add: map_prod_def comp_def)
   also have "... = ?rhs"
     by(simp add: pqp.qbs_prob_pair_measure_integral[OF h0(3)] hp(1) hq(1))
   finally show ?thesis .
 qed
 
 lemma qbs_prob_integral_Fubini_snd:
   assumes "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
     shows "(\<integral>\<^sub>Q y. \<integral>\<^sub>Q x. f (x,y) \<partial>p \<partial>q) = (\<integral>\<^sub>Q z. f z \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
           (is "?lhs = ?rhs")
 proof -
   obtain X \<alpha> \<mu> where hp:
     "p = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of p] by auto
   obtain Y \<beta> \<nu> where hq:
-   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>" 
+   "q = qbs_prob_space (Y, \<beta>, \<nu>)" "qbs_prob Y \<beta> \<nu>"
     using rep_qbs_prob_space[of q] by auto
   interpret pqp: pair_qbs_probs X \<alpha> \<mu> Y \<beta> \<nu>
     by(simp add: hp hq  pair_qbs_probs_def)
   have h0: "p \<in> monadP_qbs_Px X" "q \<in> monadP_qbs_Px Y" "f \<in> X \<Otimes>\<^sub>Q Y \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     using qbs_integrable_morphism[OF _ assms,simplified qbs_prob_pair_measure_qbs]
     by(simp_all add: monadP_qbs_Px_def hp(1) hq(1))
 
   have "?lhs = (\<integral> y. \<integral>\<^sub>Q x. f (x,\<beta> y) \<partial>p \<partial>\<nu>)"
     using qbs_morphism_integral_snd[OF h0(1) h0(3)]
     by(auto intro!: pqp.qp2.qbs_prob_integral_def simp: hq(1))
   also have "... = (\<integral>y. \<integral>x. f (\<alpha> x, \<beta> y) \<partial>\<mu> \<partial>\<nu>)"
     using qbs_morphism_Pair2'[OF qbs_Mx_to_X(2)[OF pqp.qp2.in_Mx] h0(3)]
     by(auto intro!: Bochner_Integration.integral_cong pqp.qp1.qbs_prob_integral_def
               simp: hp(1))
   also have "... = (\<integral>z. (f \<circ> map_prod \<alpha> \<beta>) z \<partial>(\<mu> \<Otimes>\<^sub>M \<nu>))"
     using pqp.integral_snd[of "curry (f \<circ> map_prod \<alpha> \<beta>)"] pqp.qbs_prob_pair_measure_integrable(2)[OF assms[simplified hp(1) hq(1)]]
     by(simp add: map_prod_def comp_def split_beta')
   also have "... = ?rhs"
     by(simp add: pqp.qbs_prob_pair_measure_integral[OF h0(3)] hp(1) hq(1))
   finally show ?thesis .
 qed
 
 lemma qbs_prob_integral_indep1:
   assumes "qbs_integrable p f"
   shows "(\<integral>\<^sub>Q z. f (fst z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sub>Q x. f x \<partial>p)"
   using qbs_prob_integral_Fubini_snd[OF qbs_integrable_indep1[OF assms],of q]
   by(simp add: qbs_prob_integral_const)
 
 lemma qbs_prob_integral_indep2:
   assumes "qbs_integrable q g"
   shows "(\<integral>\<^sub>Q z. g (snd z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sub>Q y. g y \<partial>q)"
   using qbs_prob_integral_Fubini_fst[OF qbs_integrable_indep2[OF assms],of p]
   by(simp add: qbs_prob_integral_const)
 
 lemma qbs_prob_integral_indep_mult:
   assumes "qbs_integrable p f"
       and "qbs_integrable q g"
     shows "(\<integral>\<^sub>Q z. f (fst z) * g (snd z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sub>Q x. f x \<partial>p) * (\<integral>\<^sub>Q y. g y \<partial>q)"
           (is "?lhs = ?rhs")
 proof -
   have "?lhs = (\<integral>\<^sub>Q x. \<integral>\<^sub>Q y. f x * g y \<partial>q \<partial>p)"
     using qbs_prob_integral_Fubini_fst[OF qbs_integrable_indep_mult[OF assms]]
     by simp
   also have "... = (\<integral>\<^sub>Q x. f x * (\<integral>\<^sub>Q y.  g y \<partial>q) \<partial>p)"
     by(simp add: qbs_prob_integral_cmult)
   also have "... = ?rhs"
     by(simp add: qbs_prob_integral_cmult ab_semigroup_mult_class.mult.commute[where b="\<integral>\<^sub>Q y.  g y \<partial>q"])
   finally show ?thesis .
 qed
 
 lemma qbs_prob_var_indep_plus:
   assumes "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"
           "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>z. (f z)\<^sup>2)"
           "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"
           "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>z. (g z)\<^sup>2)"
           "qbs_integrable (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>z. (f z) * (g z))"
       and "(\<integral>\<^sub>Q z. f z * g z \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sub>Q z. f z \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) * (\<integral>\<^sub>Q z. g z \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
     shows "qbs_prob_var (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>z. f z + g z) = qbs_prob_var (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f + qbs_prob_var (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"
   unfolding qbs_prob_var_def
 proof -
   show "(\<integral>\<^sub>Q z. (f z + g z - \<integral>\<^sub>Q w. f w + g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))\<^sup>2 \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) = (\<integral>\<^sub>Q z. (f z - qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f)\<^sup>2 \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) + (\<integral>\<^sub>Q z. (g z - qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g)\<^sup>2 \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
        (is "?lhs = ?rhs")
   proof -
     have "?lhs = (\<integral>\<^sub>Q z. ((f z - (\<integral>\<^sub>Q w. f w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))) + (g z - (\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))))\<^sup>2 \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
       by(simp add: qbs_prob_integral_add[OF assms(1,3)] add_diff_add)
     also have "... = (\<integral>\<^sub>Q z. (f z - (\<integral>\<^sub>Q w. f w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)))\<^sup>2 + (g z - (\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)))\<^sup>2 + (2 * f z * g z - 2 * (\<integral>\<^sub>Q w. f w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) * g z - (2 * f z * (\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) - 2 * (\<integral>\<^sub>Q w. f w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)) * (\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)))) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))"
       by(simp add: comm_semiring_1_class.power2_sum comm_semiring_1_cancel_class.left_diff_distrib' ring_class.right_diff_distrib)
     also have "... = ?rhs"
       using qbs_prob_integral_add[OF qbs_integrable_add[OF qbs_integrable_sq[OF assms(1,2)] qbs_integrable_sq[OF assms(3,4)]] qbs_integrable_diff[OF qbs_integrable_diff[OF qbs_integrable_mult[OF assms(5),of 2,simplified comm_semiring_1_class.semiring_normalization_rules(18)] qbs_integrable_mult[OF assms(3),of "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"]] qbs_integrable_diff[OF qbs_integrable_mult[OF assms(1),of "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g",simplified ab_semigroup_mult_class.mult_ac(1)[where b="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] ab_semigroup_mult_class.mult.commute[where a="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] comm_semiring_1_class.semiring_normalization_rules(18)[of _ _ "qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]] qbs_integrable_const[of _ "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]]]]
             qbs_prob_integral_add[OF qbs_integrable_sq[OF assms(1,2)] qbs_integrable_sq[OF assms(3,4)]]
             qbs_prob_integral_diff[OF qbs_integrable_diff[OF qbs_integrable_mult[OF assms(5),of 2,simplified comm_semiring_1_class.semiring_normalization_rules(18)] qbs_integrable_mult[OF assms(3),of "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"]] qbs_integrable_diff[OF qbs_integrable_mult[OF assms(1),of "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g",simplified ab_semigroup_mult_class.mult_ac(1)[where b="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] ab_semigroup_mult_class.mult.commute[where a="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] comm_semiring_1_class.semiring_normalization_rules(18)[of _ _ "qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]] qbs_integrable_const[of _ "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]]]
             qbs_prob_integral_diff[OF qbs_integrable_mult[OF assms(5),of 2,simplified comm_semiring_1_class.semiring_normalization_rules(18)] qbs_integrable_mult[OF assms(3),of "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f"]]
             qbs_prob_integral_diff[OF qbs_integrable_mult[OF assms(1),of "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g",simplified ab_semigroup_mult_class.mult_ac(1)[where b="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] ab_semigroup_mult_class.mult.commute[where a="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] comm_semiring_1_class.semiring_normalization_rules(18)[of _ _ "qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]] qbs_integrable_const[of _ "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]]
             qbs_prob_integral_cmult[of "p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q" 2 "\<lambda>z. f z * g z",simplified assms(6) comm_semiring_1_class.semiring_normalization_rules(18)]
             qbs_prob_integral_cmult[of "p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q" "2 * (\<integral>\<^sub>Q w. f w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))" g]
             qbs_prob_integral_cmult[of "p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q" "2 * (\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q))" f,simplified semigroup_mult_class.mult.assoc[of 2 "\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)"] ab_semigroup_mult_class.mult.commute[where a="qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"] comm_semiring_1_class.semiring_normalization_rules(18)[of 2 _ "\<integral>\<^sub>Q w. g w \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)"]]
             qbs_prob_integral_const[of "p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q" "2 * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) f * qbs_prob_integral (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) g"]
       by simp
     finally show ?thesis .
   qed
 qed
 
 lemma qbs_prob_var_indep_plus':
   assumes "qbs_integrable p f"
           "qbs_integrable p (\<lambda>x. (f x)\<^sup>2)"
           "qbs_integrable q g"
       and "qbs_integrable q (\<lambda>x. (g x)\<^sup>2)"
     shows "qbs_prob_var (p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q) (\<lambda>z. f (fst z) + g (snd z)) = qbs_prob_var p f + qbs_prob_var q g"
   using qbs_prob_var_indep_plus[OF qbs_integrable_indep1[OF assms(1)] qbs_integrable_indep1[OF assms(2)] qbs_integrable_indep2[OF assms(3)] qbs_integrable_indep2[OF assms(4)] qbs_integrable_indep_mult[OF assms(1) assms(3)] qbs_prob_integral_indep_mult[OF assms(1) assms(3),simplified  qbs_prob_integral_indep1[OF assms(1),of q,symmetric] qbs_prob_integral_indep2[OF assms(3),of p,symmetric]]]
         qbs_prob_integral_indep1[OF qbs_integrable_sq[OF assms(1,2)],of q "\<integral>\<^sub>Q z. f (fst z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)"] qbs_prob_integral_indep2[OF qbs_integrable_sq[OF assms(3,4)],of p "\<integral>\<^sub>Q z. g (snd z) \<partial>(p \<Otimes>\<^sub>Q\<^sub>m\<^sub>e\<^sub>s q)"]
   by(simp add: qbs_prob_var_def qbs_prob_integral_indep1[OF assms(1)] qbs_prob_integral_indep2[OF assms(3)])
 
-end
\ No newline at end of file
+end
diff --git a/thys/Quasi_Borel_Spaces/Probability_Space_QuasiBorel.thy b/thys/Quasi_Borel_Spaces/Probability_Space_QuasiBorel.thy
--- a/thys/Quasi_Borel_Spaces/Probability_Space_QuasiBorel.thy
+++ b/thys/Quasi_Borel_Spaces/Probability_Space_QuasiBorel.thy
@@ -1,1125 +1,1122 @@
 (*  Title:   Probability_Space_QuasiBorel.thy
     Author:  Michikazu Hirata, Yasuhiko Minamide, Tokyo Institute of Technology
 *)
 
 section \<open>Probability Spaces\<close>
 
 subsection \<open>Probability Measures \<close>
 
 theory Probability_Space_QuasiBorel
   imports Exponent_QuasiBorel
 begin
 
 subsubsection \<open> Probability Measures \<close>
 type_synonym 'a qbs_prob_t = "'a quasi_borel * (real \<Rightarrow> 'a) * real measure"
 
 locale in_Mx =
   fixes X :: "'a quasi_borel"
     and \<alpha> :: "real \<Rightarrow> 'a"
   assumes in_Mx[simp]:"\<alpha> \<in> qbs_Mx X"
 
-locale qbs_prob = in_Mx X \<alpha> + real_distribution \<mu> 
+locale qbs_prob = in_Mx X \<alpha> + real_distribution \<mu>
   for X :: "'a quasi_borel" and \<alpha> and \<mu>
 begin
 declare prob_space_axioms[simp]
 
 lemma m_in_space_prob_algebra[simp]:
  "\<mu> \<in> space (prob_algebra real_borel)"
   using space_prob_algebra[of real_borel] by simp
 end
 
 locale pair_qbs_probs = qp1:qbs_prob X \<alpha> \<mu> + qp2:qbs_prob Y \<beta> \<nu>
   for X :: "'a quasi_borel"and \<alpha> \<mu> and Y :: "'b quasi_borel" and \<beta> \<nu>
 begin
 
 sublocale pair_prob_space \<mu> \<nu>
   by standard
 
 lemma ab_measurable[measurable]:
  "map_prod \<alpha> \<beta> \<in> real_borel \<Otimes>\<^sub>M real_borel \<rightarrow>\<^sub>M qbs_to_measure (X \<Otimes>\<^sub>Q Y)"
   using qbs_morphism_map_prod[of \<alpha> "\<real>\<^sub>Q" X \<beta> "\<real>\<^sub>Q" Y] qp1.in_Mx qp2.in_Mx l_preserves_morphisms[of "\<real>\<^sub>Q \<Otimes>\<^sub>Q \<real>\<^sub>Q" "X \<Otimes>\<^sub>Q Y"]
   by(auto simp: qbs_Mx_is_morphisms)
 
 lemma ab_g_in_Mx[simp]:
  "map_prod \<alpha> \<beta> \<circ> real_real.g \<in> pair_qbs_Mx X Y"
   using qbs_closed1_dest[OF qp1.in_Mx] qbs_closed1_dest[OF qp2.in_Mx]
   by(auto simp add: pair_qbs_Mx_def comp_def)
 
 sublocale qbs_prob "X \<Otimes>\<^sub>Q Y" "map_prod \<alpha> \<beta> \<circ> real_real.g" "distr (\<mu> \<Otimes>\<^sub>M \<nu>) real_borel real_real.f"
   by(auto simp: qbs_prob_def in_Mx_def)
 
 end
 
 locale pair_qbs_prob = qp1:qbs_prob X \<alpha> \<mu> + qp2:qbs_prob Y \<beta> \<nu>
   for X :: "'a quasi_borel"and \<alpha> \<mu> and Y :: "'a quasi_borel" and \<beta> \<nu>
 begin
 
 sublocale pair_qbs_probs
   by standard
 
 lemma same_spaces[simp]:
   assumes "Y = X"
   shows "\<beta> \<in> qbs_Mx X"
   by(simp add: assms[symmetric])
 
 end
 
 lemma prob_algebra_real_prob_measure:
   "p \<in> space (prob_algebra (real_borel)) = real_distribution p"
 proof
   assume "p \<in> space (prob_algebra real_borel)"
   then show "real_distribution p"
     unfolding real_distribution_def real_distribution_axioms_def
     by(simp add: space_prob_algebra sets_eq_imp_space_eq)
 next
   assume "real_distribution p"
   then interpret rd: real_distribution p .
   show "p \<in> space (prob_algebra real_borel)"
     by (simp add: space_prob_algebra rd.prob_space_axioms)
 qed
 
 lemma qbs_probI:
   assumes "\<alpha> \<in> qbs_Mx X"
       and "sets \<mu> = sets borel"
       and "prob_space \<mu>"
     shows "qbs_prob X \<alpha> \<mu>"
   using assms
   by(auto intro!: qbs_prob.intro simp: in_Mx_def real_distribution_def real_distribution_axioms_def)
 
 lemma qbs_empty_not_qbs_prob :"\<not> qbs_prob (empty_quasi_borel) f M"
   by(simp add: qbs_prob_def in_Mx_def)
 
 definition qbs_prob_eq :: "['a qbs_prob_t, 'a qbs_prob_t] \<Rightarrow> bool" where
   "qbs_prob_eq p1 p2 \<equiv>
    (let (qbs1, a1, m1) = p1;
         (qbs2, a2, m2) = p2 in
     qbs_prob qbs1 a1 m1 \<and> qbs_prob qbs2 a2 m2 \<and> qbs1 = qbs2 \<and>
       distr m1 (qbs_to_measure qbs1) a1 = distr m2 (qbs_to_measure qbs2) a2)"
 
 definition qbs_prob_eq2 :: "['a qbs_prob_t, 'a qbs_prob_t] \<Rightarrow> bool" where
   "qbs_prob_eq2 p1 p2 \<equiv>
    (let (qbs1, a1, m1) = p1;
         (qbs2, a2, m2) = p2 in
     qbs_prob qbs1 a1 m1 \<and> qbs_prob qbs2 a2 m2 \<and> qbs1 = qbs2 \<and>
-      (\<forall>f \<in> qbs1 \<rightarrow>\<^sub>Q real_quasi_borel. 
+      (\<forall>f \<in> qbs1 \<rightarrow>\<^sub>Q real_quasi_borel.
            (\<integral>x. f (a1 x) \<partial> m1) = (\<integral>x. f (a2 x) \<partial> m2)))"
 
-definition qbs_prob_eq3 :: "['a qbs_prob_t, 'a qbs_prob_t] \<Rightarrow> bool" where 
-  "qbs_prob_eq3 p1 p2 \<equiv> 
+definition qbs_prob_eq3 :: "['a qbs_prob_t, 'a qbs_prob_t] \<Rightarrow> bool" where
+  "qbs_prob_eq3 p1 p2 \<equiv>
      (let (qbs1, a1, m1) = p1;
           (qbs2, a2, m2) = p2 in
      (qbs_prob qbs1 a1 m1 \<and> qbs_prob qbs2 a2 m2 \<and> qbs1 = qbs2 \<and>
       (\<forall>f \<in> qbs1 \<rightarrow>\<^sub>Q real_quasi_borel.
          (\<forall> k \<in> qbs_space qbs1. 0 \<le> f k) \<longrightarrow>
            (\<integral>x. f (a1 x) \<partial> m1) = (\<integral>x. f (a2 x) \<partial> m2))))"
 
 definition qbs_prob_eq4 :: "['a qbs_prob_t, 'a qbs_prob_t] \<Rightarrow> bool" where
   "qbs_prob_eq4 p1 p2 \<equiv>
      (let (qbs1, a1, m1) = p1;
           (qbs2, a2, m2) = p2 in
      (qbs_prob qbs1 a1 m1 \<and> qbs_prob qbs2 a2 m2 \<and> qbs1 = qbs2 \<and>
-      (\<forall>f \<in> qbs1 \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0. 
+      (\<forall>f \<in> qbs1 \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0.
            (\<integral>\<^sup>+x. f (a1 x) \<partial> m1) = (\<integral>\<^sup>+x. f (a2 x) \<partial> m2))))"
 
 lemma(in qbs_prob) qbs_prob_eq_refl[simp]:
  "qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
   by(simp add: qbs_prob_eq_def qbs_prob_axioms)
 
 lemma(in qbs_prob) qbs_prob_eq2_refl[simp]:
  "qbs_prob_eq2 (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
   by(simp add: qbs_prob_eq2_def qbs_prob_axioms)
 
 lemma(in qbs_prob) qbs_prob_eq3_refl[simp]:
  "qbs_prob_eq3 (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
   by(simp add: qbs_prob_eq3_def qbs_prob_axioms)
 
 lemma(in qbs_prob) qbs_prob_eq4_refl[simp]:
  "qbs_prob_eq4 (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
   by(simp add: qbs_prob_eq4_def qbs_prob_axioms)
 
 lemma(in pair_qbs_prob) qbs_prob_eq_intro:
   assumes "X = Y"
       and "distr \<mu> (qbs_to_measure X) \<alpha> = distr \<nu> (qbs_to_measure X) \<beta>"
     shows "qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
-  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms 
+  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms
   by(auto simp add: qbs_prob_eq_def)
 
 lemma(in pair_qbs_prob) qbs_prob_eq2_intro:
   assumes "X = Y"
       and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel
                  \<Longrightarrow> (\<integral>x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>x. f (\<beta> x) \<partial> \<nu>)"
     shows "qbs_prob_eq2 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
-  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms 
+  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms
   by(auto simp add: qbs_prob_eq2_def)
 
 lemma(in pair_qbs_prob) qbs_prob_eq3_intro:
   assumes "X = Y"
       and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel \<Longrightarrow> (\<forall> k \<in> qbs_space X. 0 \<le> f k)
                 \<Longrightarrow> (\<integral>x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>x. f (\<beta> x) \<partial> \<nu>)"
     shows "qbs_prob_eq3 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
-  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms 
+  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms
   by(auto simp add: qbs_prob_eq3_def)
 
 lemma(in pair_qbs_prob) qbs_prob_eq4_intro:
   assumes "X = Y"
       and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M ennreal_borel
                  \<Longrightarrow> (\<integral>\<^sup>+x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>\<^sup>+x. f (\<beta> x) \<partial> \<nu>)"
     shows "qbs_prob_eq4 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
-  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms 
+  using assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms
   by(auto simp add: qbs_prob_eq4_def)
 
 
 lemma qbs_prob_eq_dest:
   assumes "qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   shows "qbs_prob X \<alpha> \<mu>"
         "qbs_prob Y \<beta> \<nu>"
         "Y = X"
-    and "distr \<mu> (qbs_to_measure X) \<alpha> = distr \<nu> (qbs_to_measure X) \<beta>" 
+    and "distr \<mu> (qbs_to_measure X) \<alpha> = distr \<nu> (qbs_to_measure X) \<beta>"
   using assms by(auto simp: qbs_prob_eq_def)
 
 lemma qbs_prob_eq2_dest:
   assumes "qbs_prob_eq2 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   shows "qbs_prob X \<alpha> \<mu>"
         "qbs_prob Y \<beta> \<nu>"
         "Y = X"
     and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel
         \<Longrightarrow> (\<integral>x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>x. f (\<beta> x) \<partial> \<nu>)"
   using assms by(auto simp: qbs_prob_eq2_def)
 
 lemma qbs_prob_eq3_dest:
   assumes "qbs_prob_eq3 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   shows "qbs_prob X \<alpha> \<mu>"
         "qbs_prob Y \<beta> \<nu>"
         "Y = X"
     and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel \<Longrightarrow> (\<forall> k \<in> qbs_space X. 0 \<le> f k)
         \<Longrightarrow> (\<integral>x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>x. f (\<beta> x) \<partial> \<nu>)"
   using assms by(auto simp: qbs_prob_eq3_def)
 
 lemma qbs_prob_eq4_dest:
   assumes "qbs_prob_eq4 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   shows "qbs_prob X \<alpha> \<mu>"
         "qbs_prob Y \<beta> \<nu>"
         "Y = X"
     and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M ennreal_borel
         \<Longrightarrow> (\<integral>\<^sup>+x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>\<^sup>+x. f (\<beta> x) \<partial> \<nu>)"
   using assms by(auto simp: qbs_prob_eq4_def)
 
 definition qbs_prob_t_ennintegral :: "['a qbs_prob_t, 'a \<Rightarrow> ennreal] \<Rightarrow> ennreal" where
 "qbs_prob_t_ennintegral p f \<equiv>
-  (if f \<in> (fst p) \<rightarrow>\<^sub>Q ennreal_quasi_borel 
+  (if f \<in> (fst p) \<rightarrow>\<^sub>Q ennreal_quasi_borel
    then (\<integral>\<^sup>+x. f (fst (snd p) x) \<partial> (snd (snd p))) else 0)"
 
 definition qbs_prob_t_integral :: "['a qbs_prob_t, 'a \<Rightarrow> real] \<Rightarrow> real" where
-"qbs_prob_t_integral p f \<equiv> 
+"qbs_prob_t_integral p f \<equiv>
   (if f \<in> (fst p) \<rightarrow>\<^sub>Q \<real>\<^sub>Q
    then (\<integral>x. f (fst (snd p) x) \<partial> (snd (snd p)))
    else 0)"
 
 definition qbs_prob_t_integrable :: "['a qbs_prob_t, 'a \<Rightarrow> real] \<Rightarrow> bool" where
 "qbs_prob_t_integrable p f \<equiv> f \<in> fst p \<rightarrow>\<^sub>Q real_quasi_borel \<and> integrable (snd (snd p)) (f \<circ> (fst (snd p)))"
 
 definition qbs_prob_t_measure :: "'a qbs_prob_t \<Rightarrow> 'a measure" where
 "qbs_prob_t_measure p \<equiv> distr (snd (snd p)) (qbs_to_measure (fst p)) (fst (snd p))"
 
 lemma qbs_prob_eq_symp:
  "symp qbs_prob_eq"
   by(simp add: symp_def qbs_prob_eq_def)
 
 lemma qbs_prob_eq_transp:
  "transp qbs_prob_eq"
   by(simp add: transp_def qbs_prob_eq_def)
 
 quotient_type 'a qbs_prob_space = "'a qbs_prob_t" / partial: qbs_prob_eq
   morphisms rep_qbs_prob_space qbs_prob_space
 proof(rule part_equivpI)
   let ?U = "UNIV :: 'a set"
   let ?Uf = "UNIV :: (real \<Rightarrow> 'a) set"
   let ?f = "(\<lambda>_. undefined) :: real \<Rightarrow> 'a"
   have "qbs_prob (Abs_quasi_borel (?U,?Uf)) ?f (return borel 0)"
   proof(auto simp add: qbs_prob_def in_Mx_def)
     have "Rep_quasi_borel (Abs_quasi_borel (?U,?Uf)) = (?U, ?Uf)"
       using Abs_quasi_borel_inverse
       by (auto simp add: qbs_closed1_def qbs_closed2_def qbs_closed3_def is_quasi_borel_def)
     thus "(\<lambda>_. undefined) \<in> qbs_Mx (Abs_quasi_borel (?U, ?Uf))"
       by(simp add: qbs_Mx_def)
   next
     show "real_distribution (return borel 0)"
       by (simp add: prob_space_return real_distribution_axioms_def real_distribution_def)
   qed
   thus "\<exists>x :: 'a qbs_prob_t . qbs_prob_eq x x"
     unfolding qbs_prob_eq_def
     by(auto intro!: exI[where x="(Abs_quasi_borel (?U,?Uf), ?f, return borel 0)"])
 qed (simp_all add: qbs_prob_eq_symp qbs_prob_eq_transp)
 
 interpretation qbs_prob_space : quot_type "qbs_prob_eq" "Abs_qbs_prob_space" "Rep_qbs_prob_space"
   using Abs_qbs_prob_space_inverse Rep_qbs_prob_space
   by(simp add: quot_type_def equivp_implies_part_equivp qbs_prob_space_equivp Rep_qbs_prob_space_inverse Rep_qbs_prob_space_inject) blast
 
 lemma qbs_prob_space_induct:
   assumes "\<And>X \<alpha> \<mu>. qbs_prob X \<alpha> \<mu> \<Longrightarrow> P (qbs_prob_space (X,\<alpha>,\<mu>))"
   shows "P s"
   apply(rule qbs_prob_space.abs_induct)
   using assms by(auto simp: qbs_prob_eq_def)
 
 lemma qbs_prob_space_induct':
   assumes "\<And>X \<alpha> \<mu>. qbs_prob X \<alpha> \<mu> \<Longrightarrow> s = qbs_prob_space (X,\<alpha>,\<mu>)\<Longrightarrow> P (qbs_prob_space (X,\<alpha>,\<mu>))"
   shows "P s"
   by (metis (no_types, lifting) Rep_qbs_prob_space_inverse assms case_prodE qbs_prob_eq_def qbs_prob_space.abs_def qbs_prob_space.rep_prop qbs_prob_space_def)
 
 lemma rep_qbs_prob_space:
  "\<exists>X \<alpha> \<mu>. p = qbs_prob_space (X, \<alpha>, \<mu>) \<and> qbs_prob X \<alpha> \<mu>"
   by(rule qbs_prob_space.abs_induct,auto simp add: qbs_prob_eq_def)
 
 lemma(in qbs_prob) in_Rep:
   "(X, \<alpha>, \<mu>) \<in> Rep_qbs_prob_space (qbs_prob_space (X,\<alpha>,\<mu>))"
   by (metis mem_Collect_eq qbs_prob_eq_refl qbs_prob_space.abs_def qbs_prob_space.abs_inverse qbs_prob_space_def)
 
 lemma(in qbs_prob) if_in_Rep:
   assumes "(X',\<alpha>',\<mu>') \<in> Rep_qbs_prob_space (qbs_prob_space (X,\<alpha>,\<mu>))"
   shows "X' = X"
         "qbs_prob X' \<alpha>' \<mu>'"
         "qbs_prob_eq (X,\<alpha>,\<mu>) (X',\<alpha>',\<mu>')"
 proof -
   have h:"X' = X"
     by (metis assms mem_Collect_eq qbs_prob_eq_dest(3) qbs_prob_eq_refl qbs_prob_space.abs_def qbs_prob_space.abs_inverse qbs_prob_space_def)
   have [simp]:"qbs_prob X' \<alpha>' \<mu>'"
     by (metis assms mem_Collect_eq prod_cases3 qbs_prob_eq_dest(2) qbs_prob_space.rep_prop)
   have [simp]:"qbs_prob_eq (X,\<alpha>,\<mu>) (X',\<alpha>',\<mu>')"
     by (metis assms mem_Collect_eq qbs_prob_eq_refl qbs_prob_space.abs_def qbs_prob_space.abs_inverse qbs_prob_space_def)
   show "X' = X"
        "qbs_prob X' \<alpha>' \<mu>'"
        "qbs_prob_eq (X,\<alpha>,\<mu>) (X',\<alpha>',\<mu>')"
     by simp_all (simp add: h)
 qed
 
 lemma(in qbs_prob) in_Rep_induct:
   assumes "\<And>Y \<beta> \<nu>. (Y,\<beta>,\<nu>) \<in> Rep_qbs_prob_space (qbs_prob_space (X,\<alpha>,\<mu>)) \<Longrightarrow> P (Y,\<beta>,\<nu>)"
   shows "P (rep_qbs_prob_space (qbs_prob_space (X,\<alpha>,\<mu>)))"
   unfolding rep_qbs_prob_space_def qbs_prob_space.rep_def
   by(rule someI2[where a="(X,\<alpha>,\<mu>)"]) (use in_Rep assms in auto)
 
 (* qbs_prob_eq[1-4] are equivalent. *)
 lemma qbs_prob_eq_2_implies_3 :
   assumes "qbs_prob_eq2 p1 p2"
   shows "qbs_prob_eq3 p1 p2"
   using assms by(auto simp: qbs_prob_eq2_def qbs_prob_eq3_def)
 
 lemma qbs_prob_eq_3_implies_1 :
   assumes "qbs_prob_eq3 (p1 :: 'a qbs_prob_t) p2"
   shows "qbs_prob_eq p1 p2"
 proof(rule prod_cases3[where y=p1],rule prod_cases3[where y=p2],simp)
   fix X Y :: "'a quasi_borel"
   fix \<alpha> \<beta> \<mu> \<nu>
   assume "p1 = (X,\<alpha>,\<mu>)" "p2 = (Y,\<beta>,\<nu>)"
   then have h:"qbs_prob_eq3 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
     using assms by simp
   then interpret qp : pair_qbs_prob X \<alpha> \<mu> Y \<beta> \<nu>
     by(auto intro!: pair_qbs_prob.intro simp: qbs_prob_eq3_def)
   note [simp] = qbs_prob_eq3_dest(3)[OF h]
 
   show "qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   proof(rule qp.qbs_prob_eq_intro)
    show "distr \<mu> (qbs_to_measure X) \<alpha> = distr \<nu> (qbs_to_measure X) \<beta>"
     proof(rule measure_eqI)
       fix U
       assume hu:"U \<in> sets (distr \<mu> (qbs_to_measure X) \<alpha>)"
       have "measure (distr \<mu> (qbs_to_measure X) \<alpha>) U = measure (distr \<nu> (qbs_to_measure X) \<beta>) U"
             (is "?lhs = ?rhs")
       proof -
         have "?lhs = measure \<mu> (\<alpha> -` U \<inter> space \<mu>)"
           by(rule measure_distr) (use hu in simp_all)
         also have "... = integral\<^sup>L \<mu> (indicat_real (\<alpha> -` U))"
           by simp
         also have "... = (\<integral>x. indicat_real U (\<alpha> x) \<partial>\<mu>)"
           using indicator_vimage[of \<alpha> U] Bochner_Integration.integral_cong[of \<mu> _ "indicat_real (\<alpha> -` U)" "\<lambda>x. indicat_real U (\<alpha> x)"]
           by auto
         also have "... = (\<integral>x. indicat_real U (\<beta> x) \<partial>\<nu>)"
           using qbs_prob_eq3_dest(4)[OF h,of "indicat_real U"] hu
           by simp
         also have "... = integral\<^sup>L \<nu> (indicat_real (\<beta> -` U))"
           using indicator_vimage[of \<beta> U,symmetric] Bochner_Integration.integral_cong[of \<nu> _ "\<lambda>x. indicat_real U (\<beta> x)" "indicat_real (\<beta> -` U)"]
           by blast
         also have "... = measure \<nu> (\<beta> -` U \<inter> space \<nu>)"
           by simp
         also have "... = ?rhs"
           by(rule measure_distr[symmetric]) (use hu in simp_all)
         finally show ?thesis .
       qed
       thus "emeasure (distr \<mu> (qbs_to_measure X) \<alpha>) U = emeasure (distr \<nu> (qbs_to_measure X) \<beta>) U"
         using qp.qp2.finite_measure_distr[of \<beta>] qp.qp1.finite_measure_distr[of \<alpha>]
         by(simp add: finite_measure.emeasure_eq_measure)
     qed simp
   qed simp
 qed
 
 lemma qbs_prob_eq_1_implies_2 :
   assumes "qbs_prob_eq p1 (p2 :: 'a qbs_prob_t)"
   shows "qbs_prob_eq2 p1 p2"
 proof(rule prod_cases3[where y=p1],rule prod_cases3[where y=p2],simp)
   fix X Y :: "'a quasi_borel"
   fix \<alpha> \<beta> \<mu> \<nu>
   assume "p1 = (X,\<alpha>,\<mu>)" "p2 = (Y,\<beta>,\<nu>)"
   then have h:"qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
     using assms by simp
   then interpret qp : pair_qbs_prob X \<alpha> \<mu> Y \<beta> \<nu>
     by(auto intro!: pair_qbs_prob.intro simp: qbs_prob_eq_def)
   note [simp] = qbs_prob_eq_dest(3)[OF h]
 
   show "qbs_prob_eq2 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   proof(rule qp.qbs_prob_eq2_intro)
     fix f :: "'a \<Rightarrow> real"
     assume [measurable]:"f \<in> borel_measurable (qbs_to_measure X)"
     show "(\<integral>r. f (\<alpha> r) \<partial> \<mu>) = (\<integral>r. f (\<beta> r) \<partial> \<nu>)"
          (is "?lhs = ?rhs")
     proof -
       have "?lhs = (\<integral>x. f x \<partial>(distr \<mu> (qbs_to_measure X) \<alpha>))"
         by(simp add: Bochner_Integration.integral_distr[symmetric])
       also have "... = (\<integral>x. f x \<partial>(distr \<nu> (qbs_to_measure X) \<beta>))"
         by(simp add: qbs_prob_eq_dest(4)[OF h])
       also have "... = ?rhs"
         by(simp add: Bochner_Integration.integral_distr)
       finally show ?thesis .
     qed
   qed simp
 qed
- 
+
 lemma qbs_prob_eq_1_implies_4 :
   assumes "qbs_prob_eq p1 p2"
   shows "qbs_prob_eq4 p1 p2"
 proof(rule prod_cases3[where y=p1],rule prod_cases3[where y=p2],simp)
   fix X Y :: "'a quasi_borel"
   fix \<alpha> \<beta> \<mu> \<nu>
   assume "p1 = (X,\<alpha>,\<mu>)" "p2 = (Y,\<beta>,\<nu>)"
   then have h:"qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
     using assms by simp
   then interpret qp : pair_qbs_prob X \<alpha> \<mu> Y \<beta> \<nu>
     by(auto intro!: pair_qbs_prob.intro simp: qbs_prob_eq_def)
   note [simp] = qbs_prob_eq_dest(3)[OF h]
 
   show "qbs_prob_eq4 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   proof(rule qp.qbs_prob_eq4_intro)
     fix f ::"'a \<Rightarrow> ennreal"
     assume [measurable]:"f \<in> borel_measurable (qbs_to_measure X)"
     show "(\<integral>\<^sup>+ x. f (\<alpha> x) \<partial>\<mu>) = (\<integral>\<^sup>+ x. f (\<beta> x) \<partial>\<nu>)"
          (is "?lhs = ?rhs")
     proof -
       have "?lhs = integral\<^sup>N (distr \<mu> (qbs_to_measure X) \<alpha>) f"
         by(simp add: nn_integral_distr)
       also have "... = integral\<^sup>N (distr \<nu> (qbs_to_measure X) \<beta>) f"
         by(simp add: qbs_prob_eq_dest(4)[OF h])
       also have "... = ?rhs"
         by(simp add: nn_integral_distr)
       finally show ?thesis .
-    qed 
+    qed
   qed simp
 qed
 
 lemma qbs_prob_eq_4_implies_3 :
   assumes "qbs_prob_eq4 p1 p2"
   shows "qbs_prob_eq3 p1 p2"
 proof(rule prod_cases3[where y=p1],rule prod_cases3[where y=p2],simp)
   fix X Y :: "'a quasi_borel"
   fix \<alpha> \<beta> \<mu> \<nu>
   assume "p1 = (X,\<alpha>,\<mu>)" "p2 = (Y,\<beta>,\<nu>)"
   then have h:"qbs_prob_eq4 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
     using assms by simp
   then interpret qp : pair_qbs_prob X \<alpha> \<mu> Y \<beta> \<nu>
     by(auto intro!: pair_qbs_prob.intro simp: qbs_prob_eq4_def)
   note [simp] = qbs_prob_eq4_dest(3)[OF h]
 
   show "qbs_prob_eq3 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   proof(rule qp.qbs_prob_eq3_intro)
     fix f :: "'a \<Rightarrow> real"
     assume [measurable]:"f \<in> borel_measurable (qbs_to_measure X)"
        and h': "\<forall>k\<in>qbs_space X. 0 \<le> f k"
     show "(\<integral> x. f (\<alpha> x) \<partial>\<mu>) = (\<integral> x. f (\<beta> x) \<partial>\<nu>)"
          (is "?lhs = ?rhs")
     proof -
       have "?lhs = enn2real (\<integral>\<^sup>+ x. ennreal (f (\<alpha> x)) \<partial>\<mu>)"
         using h' by(auto simp: integral_eq_nn_integral[where f="(\<lambda>x. f (\<alpha> x))"] qbs_Mx_to_X(2))
       also have "... = enn2real (\<integral>\<^sup>+ x. (ennreal \<circ> f) (\<alpha> x) \<partial>\<mu>)"
         by simp
       also have "... = enn2real (\<integral>\<^sup>+ x. (ennreal \<circ> f) (\<beta> x) \<partial>\<nu>)"
         using qbs_prob_eq4_dest(4)[OF h,of "ennreal \<circ> f"] by simp
       also have "... = enn2real (\<integral>\<^sup>+ x. ennreal (f (\<beta> x)) \<partial>\<nu>)"
         by simp
       also have "... = ?rhs"
         using h' by(auto simp: integral_eq_nn_integral[where f="(\<lambda>x. f (\<beta> x))"] qbs_Mx_to_X(2))
       finally show ?thesis .
     qed
   qed simp
 qed
 
 lemma qbs_prob_eq_equiv12 :
  "qbs_prob_eq = qbs_prob_eq2"
   using qbs_prob_eq_1_implies_2 qbs_prob_eq_2_implies_3 qbs_prob_eq_3_implies_1
   by blast
 
 lemma qbs_prob_eq_equiv13 :
  "qbs_prob_eq = qbs_prob_eq3"
   using qbs_prob_eq_1_implies_2 qbs_prob_eq_2_implies_3 qbs_prob_eq_3_implies_1
   by blast
 
 lemma qbs_prob_eq_equiv14 :
  "qbs_prob_eq = qbs_prob_eq4"
   using qbs_prob_eq_2_implies_3 qbs_prob_eq_3_implies_1 qbs_prob_eq_1_implies_4 qbs_prob_eq_4_implies_3 qbs_prob_eq_1_implies_2
   by blast
 
 lemma qbs_prob_eq_equiv23 :
  "qbs_prob_eq2 = qbs_prob_eq3"
   using qbs_prob_eq_1_implies_2 qbs_prob_eq_2_implies_3 qbs_prob_eq_3_implies_1
   by blast
 
 lemma qbs_prob_eq_equiv24 :
  "qbs_prob_eq2 = qbs_prob_eq4"
   using qbs_prob_eq_2_implies_3 qbs_prob_eq_4_implies_3 qbs_prob_eq_3_implies_1 qbs_prob_eq_1_implies_4 qbs_prob_eq_1_implies_2
   by blast
 
 lemma qbs_prob_eq_equiv34:
  "qbs_prob_eq3 = qbs_prob_eq4"
   using qbs_prob_eq_3_implies_1 qbs_prob_eq_1_implies_4 qbs_prob_eq_4_implies_3
   by blast
 
 lemma qbs_prob_eq_equiv31 :
  "qbs_prob_eq = qbs_prob_eq3"
   using qbs_prob_eq_1_implies_2 qbs_prob_eq_2_implies_3 qbs_prob_eq_3_implies_1
   by blast
 
 lemma qbs_prob_space_eq:
   assumes "qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   shows "qbs_prob_space (X,\<alpha>,\<mu>) = qbs_prob_space (Y,\<beta>,\<nu>)"
   using Quotient3_rel[OF Quotient3_qbs_prob_space] assms
   by blast
 
 lemma(in pair_qbs_prob) qbs_prob_space_eq:
   assumes "Y = X"
       and "distr \<mu> (qbs_to_measure X) \<alpha> = distr \<nu> (qbs_to_measure X) \<beta>"
     shows "qbs_prob_space (X,\<alpha>,\<mu>) = qbs_prob_space (Y,\<beta>,\<nu>)"
   using assms qbs_prob_eq_intro qbs_prob_space_eq by auto
 
 lemma(in pair_qbs_prob) qbs_prob_space_eq2:
   assumes "Y = X"
       and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel
                  \<Longrightarrow> (\<integral>x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>x. f (\<beta> x) \<partial> \<nu>)"
     shows "qbs_prob_space (X,\<alpha>,\<mu>) = qbs_prob_space (Y,\<beta>,\<nu>)"
   using qbs_prob_space_eq assms qbs_prob_eq_2_implies_3[of "(X,\<alpha>,\<mu>)" "(Y,\<beta>,\<nu>)"] qbs_prob_eq_3_implies_1[of "(X,\<alpha>,\<mu>)" "(Y,\<beta>,\<nu>)"] qbs_prob_eq2_intro qbs_prob_eq_dest(4)
   by blast
 
 lemma(in pair_qbs_prob) qbs_prob_space_eq3:
   assumes "Y = X"
       and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel \<Longrightarrow> (\<forall>k\<in> qbs_space X. 0 \<le> f k)
                  \<Longrightarrow> (\<integral>x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>x. f (\<beta> x) \<partial> \<nu>)"
     shows "qbs_prob_space (X,\<alpha>,\<mu>) = qbs_prob_space (Y,\<beta>,\<nu>)"
   using assms qbs_prob_eq_3_implies_1[of "(X,\<alpha>,\<mu>)" "(Y,\<beta>,\<nu>)"] qbs_prob_eq3_intro qbs_prob_space_eq qbs_prob_eq_dest(4)
   by blast
 
 lemma(in pair_qbs_prob) qbs_prob_space_eq4:
   assumes "Y = X"
       and "\<And>f. f \<in> qbs_to_measure X \<rightarrow>\<^sub>M ennreal_borel
                  \<Longrightarrow> (\<integral>\<^sup>+x. f (\<alpha> x) \<partial> \<mu>) = (\<integral>\<^sup>+x. f (\<beta> x) \<partial> \<nu>)"
     shows "qbs_prob_space (X,\<alpha>,\<mu>) = qbs_prob_space (Y,\<beta>,\<nu>)"
   using assms qbs_prob_eq_4_implies_3[of "(X,\<alpha>,\<mu>)" "(Y,\<beta>,\<nu>)"] qbs_prob_space_eq3[OF assms(1)] qbs_prob_eq3_dest(4) qbs_prob_eq4_intro
-  by blast 
+  by blast
 
 lemma(in pair_qbs_prob) qbs_prob_space_eq_inverse:
   assumes "qbs_prob_space (X,\<alpha>,\<mu>) = qbs_prob_space (Y,\<beta>,\<nu>)"
     shows "qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
       and "qbs_prob_eq2 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
       and "qbs_prob_eq3 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
       and "qbs_prob_eq4 (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>)"
   using Quotient3_rel[OF Quotient3_qbs_prob_space,of "(X, \<alpha>, \<mu>)" "(Y,\<beta>,\<nu>)",simplified] assms qp1.qbs_prob_axioms qp2.qbs_prob_axioms
   by(simp_all add: qbs_prob_eq_equiv13[symmetric] qbs_prob_eq_equiv12[symmetric] qbs_prob_eq_equiv14[symmetric])
 
 
 lift_definition qbs_prob_space_qbs :: "'a qbs_prob_space \<Rightarrow> 'a quasi_borel"
 is fst by(auto simp add: qbs_prob_eq_def)
 
 lemma(in qbs_prob) qbs_prob_space_qbs_computation[simp]:
  "qbs_prob_space_qbs (qbs_prob_space (X,\<alpha>,\<mu>)) = X"
   by(simp add: qbs_prob_space_qbs.abs_eq)
 
 lemma rep_qbs_prob_space':
   assumes "qbs_prob_space_qbs s = X"
   shows "\<exists>\<alpha> \<mu>. s = qbs_prob_space (X,\<alpha>,\<mu>) \<and> qbs_prob X \<alpha> \<mu>"
 proof -
   obtain X' \<alpha> \<mu> where hs:
    "s = qbs_prob_space (X', \<alpha>, \<mu>)" "qbs_prob X' \<alpha> \<mu>"
     using rep_qbs_prob_space[of s] by auto
   then interpret qp:qbs_prob X' \<alpha> \<mu>
     by simp
   show ?thesis
     using assms hs(2) by(auto simp add: hs(1))
 qed
 
 lift_definition qbs_prob_ennintegral :: "['a qbs_prob_space, 'a \<Rightarrow> ennreal] \<Rightarrow> ennreal"
 is qbs_prob_t_ennintegral
   by(auto simp add: qbs_prob_t_ennintegral_def qbs_prob_eq_equiv14 qbs_prob_eq4_def)
 
 lift_definition qbs_prob_integral :: "['a qbs_prob_space, 'a \<Rightarrow> real] \<Rightarrow> real"
 is qbs_prob_t_integral
   by(auto simp add: qbs_prob_eq_equiv12 qbs_prob_t_integral_def qbs_prob_eq2_def)
 
 syntax
   "_qbs_prob_ennintegral" :: "pttrn \<Rightarrow> ennreal \<Rightarrow> 'a qbs_prob_space \<Rightarrow> ennreal" ("\<integral>\<^sup>+\<^sub>Q((2 _./ _)/ \<partial>_)" [60,61] 110)
 
 translations
  "\<integral>\<^sup>+\<^sub>Q x. f \<partial>p" \<rightleftharpoons> "CONST qbs_prob_ennintegral p (\<lambda>x. f)"
 
 syntax
   "_qbs_prob_integral" :: "pttrn \<Rightarrow> real \<Rightarrow> 'a qbs_prob_space \<Rightarrow> real" ("\<integral>\<^sub>Q((2 _./ _)/ \<partial>_)" [60,61] 110)
 
 translations
  "\<integral>\<^sub>Q x. f \<partial>p" \<rightleftharpoons> "CONST qbs_prob_integral p (\<lambda>x. f)"
 
 
 text \<open> We define the function \<open>l\<^sub>X \<in> L(P(X)) \<rightarrow>\<^sub>M G(X)\<close>. \<close>
 lift_definition qbs_prob_measure :: "'a qbs_prob_space \<Rightarrow> 'a measure"
 is qbs_prob_t_measure
   by(auto simp add: qbs_prob_eq_def qbs_prob_t_measure_def)
 
 declare [[coercion qbs_prob_measure]]
 
 lemma(in qbs_prob) qbs_prob_measure_computation[simp]:
   "qbs_prob_measure (qbs_prob_space (X,\<alpha>,\<mu>)) = distr \<mu> (qbs_to_measure X) \<alpha>"
   by (simp add: qbs_prob_measure.abs_eq qbs_prob_t_measure_def)
 
 
 definition qbs_emeasure ::"'a qbs_prob_space \<Rightarrow> 'a set \<Rightarrow> ennreal" where
 "qbs_emeasure s \<equiv> emeasure (qbs_prob_measure s)"
 
 lemma(in qbs_prob) qbs_emeasure_computation[simp]:
   assumes "U \<in> sets (qbs_to_measure X)"
   shows "qbs_emeasure (qbs_prob_space (X,\<alpha>,\<mu>)) U = emeasure \<mu> (\<alpha> -` U)"
   by(simp add: qbs_emeasure_def emeasure_distr[OF _ assms])
 
 
 definition qbs_measure ::"'a qbs_prob_space \<Rightarrow> 'a set \<Rightarrow> real" where
 "qbs_measure s \<equiv> measure (qbs_prob_measure s)"
 
 
 interpretation qbs_prob_measure_prob_space : prob_space "qbs_prob_measure (s::'a qbs_prob_space)" for s
 proof(transfer,auto)
   fix X :: "'a quasi_borel"
   fix \<alpha> \<mu>
   assume "qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
   then interpret qp: qbs_prob X \<alpha> \<mu>
     by(simp add: qbs_prob_eq_def)
   show "prob_space (qbs_prob_t_measure (X,\<alpha>,\<mu>))"
     by(simp add: qbs_prob_t_measure_def qp.prob_space_distr)
 qed
 
 lemma qbs_prob_measure_space:
   "qbs_space (qbs_prob_space_qbs s) = space (qbs_prob_measure s)"
   by(transfer,simp add: qbs_prob_t_measure_def)
 
 lemma qbs_prob_measure_sets[measurable_cong]:
   "sets (qbs_to_measure (qbs_prob_space_qbs s)) = sets (qbs_prob_measure s)"
   by(transfer,simp add: qbs_prob_t_measure_def)
 
 lemma(in qbs_prob) qbs_prob_ennintegral_def:
   assumes "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "qbs_prob_ennintegral (qbs_prob_space (X,\<alpha>,\<mu>)) f = (\<integral>\<^sup>+x. f (\<alpha> x) \<partial> \<mu>)"
   by (simp add: assms qbs_prob_ennintegral.abs_eq qbs_prob_t_ennintegral_def)
 
 lemma(in qbs_prob) qbs_prob_ennintegral_def2:
   assumes "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
   shows "qbs_prob_ennintegral (qbs_prob_space (X,\<alpha>,\<mu>)) f = integral\<^sup>N (distr \<mu> (qbs_to_measure X) \<alpha>) f"
   using assms by(auto simp add: qbs_prob_ennintegral.abs_eq qbs_prob_t_ennintegral_def qbs_prob_t_measure_def nn_integral_distr)
 
 lemma (in qbs_prob) qbs_prob_ennintegral_not_morphism:
   assumes  "f \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
   shows "qbs_prob_ennintegral (qbs_prob_space (X,\<alpha>,\<mu>)) f = 0"
   by(simp add: assms qbs_prob_ennintegral.abs_eq qbs_prob_t_ennintegral_def)
 
 lemma qbs_prob_ennintegral_def2:
   assumes "qbs_prob_space_qbs s = (X :: 'a quasi_borel)"
       and "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "qbs_prob_ennintegral s f = integral\<^sup>N (qbs_prob_measure s) f"
   using assms
 proof(transfer,auto)
   fix X :: "'a quasi_borel" and \<alpha> \<mu> f
   assume "qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
      and h:"f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
   then interpret qp : qbs_prob X \<alpha> \<mu>
     by(simp add: qbs_prob_eq_def)
   show "qbs_prob_t_ennintegral (X, \<alpha>, \<mu>) f = integral\<^sup>N (qbs_prob_t_measure (X, \<alpha>, \<mu>)) f"
     using qp.qbs_prob_ennintegral_def2[OF h]
     by(simp add: qbs_prob_ennintegral.abs_eq qbs_prob_t_measure_def)
 qed
 
 lemma(in qbs_prob) qbs_prob_integral_def:
   assumes "f \<in> X \<rightarrow>\<^sub>Q real_quasi_borel"
     shows "qbs_prob_integral (qbs_prob_space (X,\<alpha>,\<mu>)) f = (\<integral>x. f (\<alpha> x) \<partial> \<mu>)"
   by (simp add: assms qbs_prob_integral.abs_eq qbs_prob_t_integral_def)
 
 lemma(in qbs_prob) qbs_prob_integral_def2:
  "qbs_prob_integral (qbs_prob_space (X,\<alpha>,\<mu>)) f = integral\<^sup>L (distr \<mu> (qbs_to_measure X) \<alpha>) f"
 proof -
   consider "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q" | "f \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q" by auto
   thus ?thesis
   proof cases
     case h:2
     then have "\<not> integrable (qbs_prob_measure (qbs_prob_space (X,\<alpha>,\<mu>))) f"
       by auto
     thus ?thesis
       using h by(simp add: qbs_prob_integral.abs_eq qbs_prob_t_integral_def not_integrable_integral_eq)
   qed (auto simp add: qbs_prob_integral.abs_eq qbs_prob_t_integral_def integral_distr )
 qed
 
 lemma qbs_prob_integral_def2:
   "qbs_prob_integral (s::'a qbs_prob_space) f = integral\<^sup>L (qbs_prob_measure s) f"
 proof(transfer,auto)
   fix X :: "'a quasi_borel" and \<mu> \<alpha> f
   assume "qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
   then interpret qp : qbs_prob X \<alpha> \<mu>
     by(simp add: qbs_prob_eq_def)
   show "qbs_prob_t_integral (X,\<alpha>,\<mu>) f = integral\<^sup>L (qbs_prob_t_measure (X,\<alpha>,\<mu>)) f"
     using qp.qbs_prob_integral_def2
     by(simp add: qbs_prob_t_measure_def qbs_prob_integral.abs_eq)
 qed
 
 definition qbs_prob_var :: "'a qbs_prob_space \<Rightarrow> ('a \<Rightarrow> real) \<Rightarrow> real" where
 "qbs_prob_var s f \<equiv> qbs_prob_integral s (\<lambda>x. (f x - qbs_prob_integral s f)\<^sup>2)"
 
 lemma(in qbs_prob) qbs_prob_var_computation:
   assumes "f \<in> X \<rightarrow>\<^sub>Q real_quasi_borel"
   shows "qbs_prob_var (qbs_prob_space (X,\<alpha>,\<mu>)) f = (\<integral>x. (f (\<alpha> x) - (\<integral>x. f (\<alpha> x) \<partial> \<mu>))\<^sup>2 \<partial> \<mu>)"
 proof -
   have "(\<lambda>x. (f x - qbs_prob_integral (qbs_prob_space (X, \<alpha>, \<mu>)) f)\<^sup>2) \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
     using assms by auto
   thus ?thesis
     using assms qbs_prob_integral_def[of "\<lambda>x. (f x - qbs_prob_integral (qbs_prob_space (X,\<alpha>,\<mu>)) f)\<^sup>2"]
     by(simp add: qbs_prob_var_def qbs_prob_integral_def)
 qed
 
 lift_definition qbs_integrable :: "['a qbs_prob_space, 'a \<Rightarrow> real] \<Rightarrow> bool"
 is qbs_prob_t_integrable
 proof auto
   have H:"\<And> (X::'a quasi_borel) Y \<alpha> \<beta> \<mu> \<nu> f.
           qbs_prob_eq (X,\<alpha>,\<mu>) (Y,\<beta>,\<nu>) \<Longrightarrow> qbs_prob_t_integrable (X,\<alpha>,\<mu>) f \<Longrightarrow> qbs_prob_t_integrable (Y,\<beta>,\<nu>) f"
   proof -
     fix X Y :: "'a quasi_borel"
     fix \<alpha> \<beta> \<mu> \<nu> f
     assume H0:"qbs_prob_eq (X, \<alpha>, \<mu>) (Y, \<beta>, \<nu>)"
               "qbs_prob_t_integrable (X, \<alpha>, \<mu>) f"
     then interpret qp: pair_qbs_prob X \<alpha> \<mu> Y \<beta> \<nu>
       by(auto intro!: pair_qbs_prob.intro simp: qbs_prob_eq_def)
     have [measurable]: "f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel"
                 and h: "integrable \<mu> (f \<circ> \<alpha>)"
       using H0 by(auto simp: qbs_prob_t_integrable_def)
     note [simp] = qbs_prob_eq_dest(3)[OF H0(1)]
-   
+
     show "qbs_prob_t_integrable (Y, \<beta>, \<nu>) f"
       unfolding qbs_prob_t_integrable_def
     proof auto
       have "integrable (distr \<mu> (qbs_to_measure X) \<alpha>) f"
         using h by(simp add: comp_def integrable_distr_eq)
       hence "integrable (distr \<nu> (qbs_to_measure X) \<beta>) f"
         using qbs_prob_eq_dest(4)[OF H0(1)] by simp
       thus "integrable \<nu> (f \<circ> \<beta>)"
         by(simp add: comp_def integrable_distr_eq)
     qed
   qed
   fix X Y :: "'a quasi_borel"
   fix \<alpha> \<beta> \<mu> \<nu>
   assume H0:"qbs_prob_eq (X, \<alpha>, \<mu>) (Y, \<beta>, \<nu>)"
   then have H1:"qbs_prob_eq (Y, \<beta>, \<nu>) (X, \<alpha>, \<mu>)"
     by(auto simp add: qbs_prob_eq_def)
   show "qbs_prob_t_integrable (X, \<alpha>, \<mu>) = qbs_prob_t_integrable (Y, \<beta>, \<nu>)"
     using H[OF H0] H[OF H1] by auto
 qed
 
 lemma(in qbs_prob) qbs_integrable_def:
  "qbs_integrable (qbs_prob_space (X, \<alpha>, \<mu>)) f = (f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q \<and> integrable \<mu> (f \<circ> \<alpha>))"
   by (simp add: qbs_integrable.abs_eq qbs_prob_t_integrable_def)
 
 lemma qbs_integrable_morphism:
   assumes "qbs_prob_space_qbs s = X"
       and "qbs_integrable s f"
     shows "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q"
   using assms by(transfer,auto simp: qbs_prob_t_integrable_def)
 
 lemma(in qbs_prob) qbs_integrable_measurable[simp,measurable]:
   assumes "qbs_integrable (qbs_prob_space (X,\<alpha>,\<mu>)) f"
   shows "f \<in> qbs_to_measure X \<rightarrow>\<^sub>M real_borel"
   using assms by(auto simp add: qbs_integrable_def)
 
 lemma qbs_integrable_iff_integrable:
   "(qbs_integrable (s::'a qbs_prob_space) f) = (integrable (qbs_prob_measure s) f)"
   apply transfer
   subgoal for s f
   proof(rule prod_cases3[where y=s],simp)
     fix X :: "'a quasi_borel"
     fix \<alpha> \<mu>
     assume "qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
     then interpret qp: qbs_prob X \<alpha> \<mu>
       by(simp add: qbs_prob_eq_def)
 
     show "qbs_prob_t_integrable (X,\<alpha>,\<mu>) f = integrable (qbs_prob_t_measure (X,\<alpha>,\<mu>)) f"
          (is "?lhs = ?rhs")
       using integrable_distr_eq[of \<alpha> \<mu> "qbs_to_measure X" f]
       by(auto simp add: qbs_prob_t_integrable_def qbs_prob_t_measure_def comp_def)
   qed
   done
 
 lemma(in qbs_prob) qbs_integrable_iff_integrable_distr:
  "qbs_integrable (qbs_prob_space (X,\<alpha>,\<mu>)) f = integrable (distr \<mu> (qbs_to_measure X) \<alpha>) f"
   by(simp add: qbs_integrable_iff_integrable)
 
 lemma(in qbs_prob) qbs_integrable_iff_integrable:
   assumes "f \<in>  qbs_to_measure X \<rightarrow>\<^sub>M real_borel"
   shows "qbs_integrable (qbs_prob_space (X,\<alpha>,\<mu>)) f = integrable \<mu> (\<lambda>x. f (\<alpha> x))"
   by(auto intro!: integrable_distr_eq[of \<alpha> \<mu> "qbs_to_measure X" f] simp: assms qbs_integrable_iff_integrable_distr)
 
 lemma qbs_integrable_if_integrable:
   assumes "integrable (qbs_prob_measure s) f"
   shows "qbs_integrable (s::'a qbs_prob_space) f"
   using assms by(simp add: qbs_integrable_iff_integrable)
 
 lemma integrable_if_qbs_integrable:
   assumes "qbs_integrable (s::'a qbs_prob_space) f"
   shows "integrable (qbs_prob_measure s) f"
   using assms by(simp add: qbs_integrable_iff_integrable)
 
 lemma qbs_integrable_iff_bounded:
   assumes "qbs_prob_space_qbs s = X"
   shows "qbs_integrable s f \<longleftrightarrow> f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q \<and> qbs_prob_ennintegral s (\<lambda>x. ennreal \<bar>f x \<bar>) < \<infinity>"
         (is "?lhs = ?rhs")
 proof -
   obtain \<alpha> \<mu> where hs:
    "qbs_prob X \<alpha> \<mu>" "s = qbs_prob_space (X,\<alpha>,\<mu>)"
     using rep_qbs_prob_space'[OF assms] by auto
   then interpret qp:qbs_prob X \<alpha> \<mu> by simp
   have "?lhs = integrable (distr \<mu> (qbs_to_measure X) \<alpha>) f"
     by (simp add: hs(2) qbs_integrable_iff_integrable)
   also have "... = (f \<in> borel_measurable (distr \<mu> (qbs_to_measure X) \<alpha>) \<and> ((\<integral>\<^sup>+ x. ennreal (norm (f x)) \<partial>(distr \<mu> (qbs_to_measure X) \<alpha>)) < \<infinity>))"
     by(rule integrable_iff_bounded)
   also have "... = ?rhs"
   proof -
     have [simp]:"f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q \<Longrightarrow>(\<lambda>x. ennreal \<bar>f x\<bar>) \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
       by auto
     have "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q \<Longrightarrow> qbs_prob_ennintegral s (\<lambda>x. ennreal \<bar>f x\<bar>) = (\<integral>\<^sup>+ x. ennreal (norm (f x)) \<partial>qbs_prob_measure s)"
       using qp.qbs_prob_ennintegral_def2[of "\<lambda>x. ennreal \<bar>f x\<bar>"]
       by(auto simp: hs(2))
     thus ?thesis
       by(simp add: hs(2)) fastforce
   qed
   finally show ?thesis .
 qed
 
 lemma qbs_integrable_cong:
   assumes "qbs_prob_space_qbs s = X"
           "\<And>x. x \<in> qbs_space X \<Longrightarrow> f x = g x"
       and "qbs_integrable s f"
     shows "qbs_integrable s g"
-  apply(rule qbs_integrable_if_integrable)
-  using integrable_cong[OF refl, of "qbs_prob_measure s" f g,simplified qbs_prob_measure_space[symmetric] assms(1),OF assms(2)]
-        qbs_integrable_iff_integrable[of s f] assms(3)
-  by simp
+  by (metis Bochner_Integration.integrable_cong assms integrable_if_qbs_integrable qbs_integrable_if_integrable qbs_prob_measure_space)
 
 lemma qbs_integrable_const[simp]:
  "qbs_integrable s (\<lambda>x. c)"
   using qbs_integrable_iff_integrable[of s "\<lambda>x. c"] by simp
 
 lemma qbs_integrable_add[simp]:
   assumes "qbs_integrable s f"
       and "qbs_integrable s g"
     shows "qbs_integrable s (\<lambda>x. f x + g x)"
-  by(rule qbs_integrable_if_integrable[OF Bochner_Integration.integrable_add[OF integrable_if_qbs_integrable[OF assms(1)] integrable_if_qbs_integrable[OF assms(2)]]])
+  using assms qbs_integrable_iff_integrable by blast
 
 lemma qbs_integrable_diff[simp]:
   assumes "qbs_integrable s f"
       and "qbs_integrable s g"
     shows "qbs_integrable s (\<lambda>x. f x - g x)"
   by(rule qbs_integrable_if_integrable[OF Bochner_Integration.integrable_diff[OF integrable_if_qbs_integrable[OF assms(1)] integrable_if_qbs_integrable[OF assms(2)]]])
-  
+
 lemma qbs_integrable_mult_iff[simp]:
  "(qbs_integrable s (\<lambda>x. c * f x)) = (c = 0 \<or> qbs_integrable s f)"
-  using qbs_integrable_iff_integrable[of s "\<lambda>x. c * f x"] integrable_mult_left_iff[of "qbs_prob_measure s" c f] qbs_integrable_iff_integrable[of s f] 
+  using qbs_integrable_iff_integrable[of s "\<lambda>x. c * f x"] integrable_mult_left_iff[of "qbs_prob_measure s" c f] qbs_integrable_iff_integrable[of s f]
   by simp
 
 lemma qbs_integrable_mult[simp]:
   assumes "qbs_integrable s f"
   shows "qbs_integrable s (\<lambda>x. c * f x)"
   using assms qbs_integrable_mult_iff by auto
 
 lemma qbs_integrable_abs[simp]:
   assumes "qbs_integrable s f"
   shows "qbs_integrable s (\<lambda>x. \<bar>f x\<bar>)"
   by(rule qbs_integrable_if_integrable[OF integrable_abs[OF integrable_if_qbs_integrable[OF assms]]])
 
 lemma qbs_integrable_sq[simp]:
   assumes "qbs_integrable s f"
       and "qbs_integrable s (\<lambda>x. (f x)\<^sup>2)"
     shows "qbs_integrable s (\<lambda>x. (f x - c)\<^sup>2)"
   by(simp add: comm_ring_1_class.power2_diff,rule qbs_integrable_diff,rule qbs_integrable_add)
     (simp_all add: comm_semiring_1_class.semiring_normalization_rules(16)[of 2] assms)
 
 lemma qbs_ennintegral_eq_qbs_integral:
   assumes "qbs_prob_space_qbs s = X"
           "qbs_integrable s f"
       and "\<And>x. x \<in> qbs_space X \<Longrightarrow> 0 \<le> f x"
     shows "qbs_prob_ennintegral s (\<lambda>x. ennreal (f x)) = ennreal (qbs_prob_integral s f)"
   using nn_integral_eq_integral[OF integrable_if_qbs_integrable[OF assms(2)]] assms qbs_prob_ennintegral_def2[OF assms(1) qbs_morphism_comp[OF qbs_integrable_morphism[OF assms(1,2)],of ennreal "\<real>\<^sub>Q\<^sub>\<ge>\<^sub>0",simplified comp_def]] measurable_ennreal
   by (metis AE_I2 qbs_prob_integral_def2 qbs_prob_measure_space real.standard_borel_r_full_faithful)
 
 lemma qbs_prob_ennintegral_cong:
   assumes "qbs_prob_space_qbs s = X"
       and "\<And>x. x \<in> qbs_space X \<Longrightarrow> f x = g x"
     shows "qbs_prob_ennintegral s f = qbs_prob_ennintegral s g"
 proof -
   obtain \<alpha> \<mu> where hs:
   "s = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space'[OF assms(1)] by auto
   then interpret qp : qbs_prob  X \<alpha> \<mu>
     by simp
   have H1:"f \<circ> \<alpha> = g \<circ> \<alpha>"
     using assms(2)
     unfolding comp_def apply standard
     using assms(2)[of "\<alpha> _"] by (simp add: qbs_Mx_to_X(2))
   consider "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0" | "f \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0" by auto
   then have "qbs_prob_t_ennintegral (X,\<alpha>,\<mu>) f = qbs_prob_t_ennintegral (X,\<alpha>,\<mu>) g"
   proof cases
     case h:1
     then have "g \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
       using qbs_morphism_cong[of X f g "\<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"] assms by simp
     then show ?thesis
       using h H1 by(simp add: qbs_prob_t_ennintegral_def comp_def)
   next
     case h:2
     then have "g \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
       using assms qbs_morphism_cong[of X g f "\<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"] by auto
     then show ?thesis
       using h by(simp add: qbs_prob_t_ennintegral_def)
   qed
   thus ?thesis
     using hs(1) by (simp add: qbs_prob_ennintegral.abs_eq)
 qed
 
 
 lemma qbs_prob_ennintegral_const:
  "qbs_prob_ennintegral (s::'a qbs_prob_space) (\<lambda>x. c) = c"
   using qbs_prob_ennintegral_def2[OF _ qbs_morphism_const[of c "\<real>\<^sub>Q\<^sub>\<ge>\<^sub>0" "qbs_prob_space_qbs s",simplified]]
   by (simp add: qbs_prob_measure_prob_space.emeasure_space_1)
 
 lemma qbs_prob_ennintegral_add:
   assumes "qbs_prob_space_qbs s = X"
           "f \<in> (X::'a quasi_borel) \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
       and "g \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
     shows "qbs_prob_ennintegral s (\<lambda>x. f x + g x) = qbs_prob_ennintegral s f + qbs_prob_ennintegral s g"
   using qbs_prob_ennintegral_def2[of s X "\<lambda>x. f x + g x"] qbs_prob_ennintegral_def2[OF assms(1,2)] qbs_prob_ennintegral_def2[OF assms(1,3)] assms nn_integral_add[of f "qbs_prob_measure s" g]
   by fastforce
 
 lemma qbs_prob_ennintegral_cmult:
   assumes "qbs_prob_space_qbs s = X"
       and "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
   shows "qbs_prob_ennintegral s (\<lambda>x. c * f x) = c * qbs_prob_ennintegral s f"
   using qbs_prob_ennintegral_def2[OF assms(1),of "\<lambda>x. c * f x"] qbs_prob_ennintegral_def2[OF assms(1,2)] nn_integral_cmult[of f "qbs_prob_measure s"] assms
   by fastforce
 
 lemma qbs_prob_ennintegral_cmult_noninfty:
   assumes "c \<noteq> \<infinity>"
   shows "qbs_prob_ennintegral s (\<lambda>x. c * f x) = c * qbs_prob_ennintegral s f"
 proof -
   obtain X \<alpha> \<mu> where hs:
    "s = qbs_prob_space (X, \<alpha>, \<mu>)" "qbs_prob X \<alpha> \<mu>"
     using rep_qbs_prob_space[of s] by auto
   then interpret qp: qbs_prob X \<alpha> \<mu> by simp
   consider "f \<in> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0" | "f \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0" by auto
   then show ?thesis
   proof cases
     case 1
     then show ?thesis
       by(auto intro!: qbs_prob_ennintegral_cmult[where X=X] simp: hs(1))
   next
     case 2
     consider "c = 0" | "c \<noteq> 0 \<and> c \<noteq> \<infinity>"
       using assms by auto
     then show ?thesis
     proof cases
       case 1
       then show ?thesis
         by(simp add: hs qbs_prob_ennintegral.abs_eq qbs_prob_t_ennintegral_def)
     next
       case h:2
       have "(\<lambda>x. c * f x) \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
       proof(rule ccontr)
         assume "\<not> (\<lambda>x. c * f x) \<notin> X \<rightarrow>\<^sub>Q \<real>\<^sub>Q\<^sub>\<ge>\<^sub>0"
         hence 3:"(\<lambda>x. c * f x) \<in> qbs_to_measure X \<rightarrow>\<^sub>M ennreal_borel"
           by auto
         have "f = (\<lambda>x. (1/c) *  (c * f x))"
           using h by(simp add: divide_eq_1_ennreal ennreal_divide_times mult.assoc mult.commute[of c] mult_divide_eq_ennreal)
         also have "... \<in> qbs_to_measure X \<rightarrow>\<^sub>M ennreal_borel"
           using 3 by simp
         finally show False
           using 2 by auto
       qed
       thus ?thesis
         using qp.qbs_prob_ennintegral_not_morphism 2
         by(simp add: hs(1))
     qed
   qed
 qed
 
 lemma qbs_prob_integral_cong:
   assumes "qbs_prob_space_qbs s = X"
       and "\<And>x. x \<in> qbs_space X \<Longrightarrow> f x = g x"
     shows "qbs_prob_integral s f = qbs_prob_integral s g"
   by(simp add: qbs_prob_integral_def2) (metis Bochner_Integration.integral_cong assms(1) assms(2) qbs_prob_measure_space)
 
 lemma qbs_prob_integral_nonneg:
   assumes "qbs_prob_space_qbs s = X"
       and "\<And>x. x \<in> qbs_space X \<Longrightarrow> 0 \<le> f x"
   shows "0 \<le> qbs_prob_integral s f"
   using qbs_prob_measure_space[of s] assms
   by(simp add: qbs_prob_integral_def2)
 
 lemma qbs_prob_integral_mono:
   assumes "qbs_prob_space_qbs s = X"
           "qbs_integrable (s :: 'a qbs_prob_space) f"
           "qbs_integrable s g"
       and "\<And>x. x \<in> qbs_space X \<Longrightarrow> f x \<le> g x"
     shows "qbs_prob_integral s f \<le> qbs_prob_integral s g"
   using integral_mono[OF integrable_if_qbs_integrable[OF assms(2)] integrable_if_qbs_integrable[OF assms(3)] assms(4)[simplified qbs_prob_measure_space]]
   by(simp add: qbs_prob_integral_def2 assms(1) qbs_prob_measure_space[symmetric])
 
 lemma qbs_prob_integral_const:
   "qbs_prob_integral (s::'a qbs_prob_space) (\<lambda>x. c) = c"
   by(simp add: qbs_prob_integral_def2 qbs_prob_measure_prob_space.prob_space)
 
 lemma qbs_prob_integral_add:
   assumes "qbs_integrable (s::'a qbs_prob_space) f"
       and "qbs_integrable s g"
     shows "qbs_prob_integral s (\<lambda>x. f x + g x) = qbs_prob_integral s f + qbs_prob_integral s g"
   using Bochner_Integration.integral_add[OF integrable_if_qbs_integrable[OF assms(1)] integrable_if_qbs_integrable[OF assms(2)]]
   by(simp add: qbs_prob_integral_def2)
 
 lemma qbs_prob_integral_diff:
   assumes "qbs_integrable (s::'a qbs_prob_space) f"
       and "qbs_integrable s g"
     shows "qbs_prob_integral s (\<lambda>x. f x - g x) = qbs_prob_integral s f - qbs_prob_integral s g"
   using Bochner_Integration.integral_diff[OF integrable_if_qbs_integrable[OF assms(1)] integrable_if_qbs_integrable[OF assms(2)]]
   by(simp add: qbs_prob_integral_def2)
 
 lemma qbs_prob_integral_cmult:
   "qbs_prob_integral s (\<lambda>x. c * f x) = c * qbs_prob_integral s f"
   by(simp add: qbs_prob_integral_def2)
 
 lemma real_qbs_prob_integral_def:
   assumes "qbs_integrable (s::'a qbs_prob_space) f"
   shows "qbs_prob_integral s f = enn2real (qbs_prob_ennintegral s (\<lambda>x. ennreal (f x))) - enn2real (qbs_prob_ennintegral s (\<lambda>x. ennreal (- f x)))"
   using assms
 proof(transfer,auto)
   fix X :: "'a quasi_borel"
   fix \<alpha> \<mu> f
   assume H:"qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
            "qbs_prob_t_integrable (X,\<alpha>,\<mu>) f"
   then interpret qp: qbs_prob X \<alpha> \<mu>
     by(simp add: qbs_prob_eq_def)
   show "qbs_prob_t_integral (X,\<alpha>,\<mu>) f = enn2real (qbs_prob_t_ennintegral (X,\<alpha>,\<mu>) (\<lambda>x. ennreal (f x))) - enn2real (qbs_prob_t_ennintegral (X,\<alpha>,\<mu>) (\<lambda>x. ennreal (- f x)))"
     using H(2) real_lebesgue_integral_def[of \<mu> "f \<circ> \<alpha>"]
     by(auto simp add: comp_def qbs_prob_t_integrable_def qbs_prob_t_integral_def qbs_prob_t_ennintegral_def)
 qed
 
 lemma qbs_prob_var_eq:
   assumes "qbs_integrable (s::'a qbs_prob_space) f"
       and "qbs_integrable s (\<lambda>x. (f x)\<^sup>2)"
     shows "qbs_prob_var s f = qbs_prob_integral s (\<lambda>x. (f x)\<^sup>2) - (qbs_prob_integral s f)\<^sup>2"
   unfolding qbs_prob_var_def using assms
 proof(transfer,auto)
   fix X :: "'a quasi_borel"
   fix \<alpha> \<mu> f
   assume H:"qbs_prob_eq (X,\<alpha>,\<mu>) (X,\<alpha>,\<mu>)"
            "qbs_prob_t_integrable (X,\<alpha>,\<mu>) f"
            "qbs_prob_t_integrable (X,\<alpha>,\<mu>) (\<lambda>x. (f x)\<^sup>2)"
   then interpret qp: qbs_prob X \<alpha> \<mu>
     by(simp add: qbs_prob_eq_def)
   show "qbs_prob_t_integral (X,\<alpha>,\<mu>) (\<lambda>x. (f x - qbs_prob_t_integral (X,\<alpha>,\<mu>) f)\<^sup>2) = qbs_prob_t_integral (X,\<alpha>,\<mu>) (\<lambda>x. (f x)\<^sup>2) - (qbs_prob_t_integral (X,\<alpha>,\<mu>) f)\<^sup>2"
     using H(2,3) prob_space.variance_eq[of \<mu> "f \<circ> \<alpha>"]
     by(auto simp add: qbs_prob_t_integral_def qbs_prob_def qbs_prob_t_integrable_def comp_def qbs_prob_eq_def)
 qed
 
 lemma qbs_prob_var_affine:
   assumes "qbs_integrable s f"
   shows "qbs_prob_var s (\<lambda>x. a * f x + b) = a\<^sup>2 * qbs_prob_var s f"
         (is "?lhs = ?rhs")
 proof -
   have "?lhs = qbs_prob_integral s (\<lambda>x. (a * f x + b - (a * qbs_prob_integral s f + b))\<^sup>2)"
     using qbs_prob_integral_add[OF qbs_integrable_mult[OF assms,of a] qbs_integrable_const[of s b]]
     by (simp add: qbs_prob_integral_cmult qbs_prob_integral_const qbs_prob_var_def)
   also have "... = qbs_prob_integral s (\<lambda>x. (a * f x - a * qbs_prob_integral s f)\<^sup>2)"
     by simp
   also have "... = qbs_prob_integral s (\<lambda>x. a\<^sup>2 * (f x - qbs_prob_integral s f)\<^sup>2)"
     by (metis power_mult_distrib right_diff_distrib)
   also have "... = ?rhs"
     by(simp add: qbs_prob_var_def qbs_prob_integral_cmult[of s "a\<^sup>2"])
   finally show ?thesis .
 qed
 
 lemma qbs_prob_integral_Markov_inequality:
   assumes "qbs_prob_space_qbs s = X"
       and "qbs_integrable s f"
           "\<And>x. x \<in> qbs_space X \<Longrightarrow> 0 \<le> f x"
       and "0 < c"
     shows "qbs_emeasure s {x \<in> qbs_space X. c \<le> f x} \<le> ennreal (1/c * qbs_prob_integral s f)"
   using integral_Markov_inequality[OF integrable_if_qbs_integrable[OF assms(2)] _ assms(4)] assms(3)
   by(force simp add: qbs_prob_integral_def2 qbs_prob_measure_space qbs_emeasure_def assms(1) qbs_prob_measure_space[symmetric])
 
 lemma qbs_prob_integral_Markov_inequality':
   assumes "qbs_prob_space_qbs s = X"
           "qbs_integrable s f"
           "\<And>x. x \<in> qbs_space (qbs_prob_space_qbs s) \<Longrightarrow> 0 \<le> f x"
       and "0 < c"
     shows "qbs_measure s {x \<in> qbs_space (qbs_prob_space_qbs s). c \<le> f x} \<le> (1/c * qbs_prob_integral s f)"
   using qbs_prob_integral_Markov_inequality[OF assms] ennreal_le_iff[of "1/c * qbs_prob_integral s f" "qbs_measure s {x \<in> qbs_space (qbs_prob_space_qbs s). c \<le> f x}"] qbs_prob_integral_nonneg[of s X f,OF assms(1,3)] assms(4)
   by(simp add: qbs_measure_def qbs_emeasure_def qbs_prob_measure_prob_space.emeasure_eq_measure assms(1))
 
 lemma qbs_prob_integral_Markov_inequality_abs:
   assumes "qbs_prob_space_qbs s = X"
           "qbs_integrable s f"
       and "0 < c"
     shows "qbs_emeasure s {x \<in> qbs_space X. c \<le> \<bar>f x\<bar>} \<le> ennreal (1/c * qbs_prob_integral s (\<lambda>x. \<bar>f x\<bar>))"
   using qbs_prob_integral_Markov_inequality[OF assms(1) qbs_integrable_abs[OF assms(2)] _ assms(3)]
   by(simp add: assms(1))
 
 lemma qbs_prob_integral_Markov_inequality_abs':
   assumes "qbs_prob_space_qbs s = X"
           "qbs_integrable s f"
       and "0 < c"
     shows "qbs_measure s {x \<in> qbs_space X. c \<le> \<bar>f x\<bar>} \<le> (1/c * qbs_prob_integral s (\<lambda>x. \<bar>f x\<bar>))"
   using qbs_prob_integral_Markov_inequality'[OF assms(1) qbs_integrable_abs[OF assms(2)] _ assms(3)]
   by(simp add: assms(1))
 
 lemma qbs_prob_integral_real_Markov_inequality:
   assumes "qbs_prob_space_qbs s = \<real>\<^sub>Q"
           "qbs_integrable s f"
       and "0 < c"
     shows "qbs_emeasure s {r. c \<le> \<bar>f r\<bar>} \<le> ennreal (1/c * qbs_prob_integral s (\<lambda>x. \<bar>f x\<bar>))"
   using qbs_prob_integral_Markov_inequality_abs[OF assms]
   by simp
 
 lemma qbs_prob_integral_real_Markov_inequality':
   assumes "qbs_prob_space_qbs s = \<real>\<^sub>Q"
           "qbs_integrable s f"
       and "0 < c"
     shows "qbs_measure s {r. c \<le> \<bar>f r\<bar>} \<le> 1/c * qbs_prob_integral s (\<lambda>x. \<bar>f x\<bar>)"
   using qbs_prob_integral_Markov_inequality_abs'[OF assms]
   by simp
 
 lemma qbs_prob_integral_Chebyshev_inequality:
   assumes "qbs_prob_space_qbs s = X"
           "qbs_integrable s f"
           "qbs_integrable s (\<lambda>x. (f x)\<^sup>2)"
       and "0 < b"
     shows "qbs_measure s {x \<in> qbs_space X. b \<le> \<bar>f x - qbs_prob_integral s f\<bar>} \<le> 1 / b\<^sup>2 * qbs_prob_var s f"
 proof -
   have "qbs_integrable s (\<lambda>x. \<bar>f x - qbs_prob_integral s f\<bar>\<^sup>2)"
     by(simp, rule qbs_integrable_sq[OF assms(2,3)])
   moreover have "{x \<in> qbs_space X. b\<^sup>2 \<le> \<bar>f x - qbs_prob_integral s f\<bar>\<^sup>2} = {x \<in> qbs_space X. b \<le> \<bar>f x - qbs_prob_integral s f\<bar>}"
     by (metis (mono_tags, opaque_lifting) abs_le_square_iff abs_of_nonneg assms(4) less_imp_le power2_abs)
   ultimately show ?thesis
     using qbs_prob_integral_Markov_inequality'[OF assms(1),of "\<lambda>x. \<bar>f x - qbs_prob_integral s f\<bar>^2" "b^2"] assms(4)
     by(simp add: qbs_prob_var_def assms(1))
 qed
 
-end
\ No newline at end of file
+end
diff --git a/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy b/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy
--- a/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy
+++ b/thys/Zeta_3_Irrational/Zeta_3_Irrational.thy
@@ -1,2089 +1,2089 @@
 (*
   File:   Zeta_3_Irrational.thy
   Author: Manuel Eberl, TU München
 *)
 section \<open>The Irrationality of $\zeta(3)$\<close>
 theory Zeta_3_Irrational
 imports
   "E_Transcendental.E_Transcendental"
   "Prime_Number_Theorem.Prime_Number_Theorem"
   "Prime_Distribution_Elementary.PNT_Consequences"
 begin
 
 text \<open>
   Ap\'{e}ry's original proof of the irrationality of $\zeta(3)$ contained several
   tricky identities of sums involving binomial coefficients that are difficult to
   prove. I instead follow Beukers's proof, which consists of several fairly
   straightforward manipulations of integrals with absolutely no caveats.
 
   Both Ap\'{e}ry and Beukers make use of an asymptotic upper bound on
   $\text{lcm}\{1\ldots n\}$ -- namely $\text{lcm}\{1\ldots n\} \in o(c^n)$ for
   any $c > e$, which is a consequence of the Prime Number Theorem (which, fortunately,
   is available in the \emph{Archive of Formal Proofs}~\cite{afp_primes1,afp_primes2}).
 
   I follow the concise presentation of Beukers's proof in Filaseta's lecture
   notes~\cite{filaseta}, which turned out to be very amenable to formalisation.
 
   There is another earlier formalisation of the irrationality of $\zeta(3)$ by
   Mahboubi\ \emph{et al.}~\cite{mahboubi}, who followed Ap\'{e}ry's original proof,
   but were ultimately forced to find a more elementary way to prove the asymptotics
   of $\text{lcm}\{1\ldots n\}$ than the Prime Number Theorem.
 
   First, we will require some auxiliary material before we get started with the actual
   proof.
 \<close>
 
 (* TODO: A lot of this (if not all of it) should really be in the library *)
 subsection \<open>Auxiliary facts about polynomials\<close>
 
 lemma degree_higher_pderiv: "degree ((pderiv ^^ n) p) = degree p - n"
   for p :: "'a::{comm_semiring_1,semiring_no_zero_divisors,semiring_char_0} poly"
   by (induction n arbitrary: p) (auto simp: degree_pderiv)
 
 lemma pcompose_power_left: "pcompose (p ^ n) q = pcompose p q ^ n"
   by (induction n) (auto simp: pcompose_mult pcompose_1)
 
 lemma pderiv_sum: "pderiv (\<Sum>x\<in>A. f x) = (\<Sum>x\<in>A. pderiv (f x))"
   by (induction A rule: infinite_finite_induct) (auto simp: pderiv_add)
 
 lemma higher_pderiv_minus: "(pderiv ^^ n) (-p :: 'a :: idom poly) = -(pderiv ^^ n) p"
   by (induction n) (auto simp: pderiv_minus)
 
 lemma pderiv_power: "pderiv (p ^ n) = smult (of_nat n) (p ^ (n - 1)) * pderiv p"
   by (cases n) (simp_all add: pderiv_power_Suc del: power_Suc)
 
 lemma pderiv_monom: "pderiv (monom c n) = monom (of_nat n * c) (n - 1)"
   by (simp add: monom_altdef pderiv_smult pderiv_power pderiv_pCons mult_ac)
 
 lemma higher_pderiv_monom:
   "k \<le> n \<Longrightarrow> (pderiv ^^ k) (monom c n) = monom (of_nat (pochhammer (n - k + 1) k) * c) (n - k)"
   by (induction k) (auto simp: pderiv_monom pochhammer_rec Suc_diff_le Suc_diff_Suc mult_ac)
 
 lemma higher_pderiv_mult:
   "(pderiv ^^ n) (p * q) =
      (\<Sum>k\<le>n. Polynomial.smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (n - k)) q))"
 proof (induction n)
   case (Suc n)
   have eq: "(Suc n choose k) = (n choose k) + (n choose (k-1))" if "k > 0" for k
     using that by (cases k) auto
   have "(pderiv ^^ Suc n) (p * q) =
           (\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) +
           (\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ Suc k) p * (pderiv ^^ (n - k)) q))"
     by (simp add: Suc pderiv_sum pderiv_smult pderiv_mult sum.distrib smult_add_right algebra_simps Suc_diff_le)
   also have "(\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) =
              (\<Sum>k\<in>insert 0 {1..n}. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>k=1..n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) + p * (pderiv ^^ Suc n) q"
     by (subst sum.insert) (auto simp: add_ac)
   also have "(\<Sum>k\<le>n. smult (of_nat (n choose k)) ((pderiv ^^ Suc k) p * (pderiv ^^ (n - k)) q)) =
              (\<Sum>k=1..n+1. smult (of_nat (n choose (k-1))) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>k. k - 1" Suc]) auto
   also have "\<dots> = (\<Sum>k\<in>insert (n+1) {1..n}. smult (of_nat (n choose (k-1))) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>k=1..n. smult (of_nat (n choose (k-1))) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) + (pderiv ^^ Suc n) p * q"
     by (subst sum.insert) (auto simp: add_ac)
   also have "(\<Sum>k=1..n. smult (of_nat (n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) +
                  p * (pderiv ^^ Suc n) q + \<dots> =
              (\<Sum>k=1..n. smult (of_nat (Suc n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q)) +
                  p * (pderiv ^^ Suc n) q + (pderiv ^^ Suc n) p * q"
     by (simp add: sum.distrib algebra_simps smult_add_right eq smult_add_left)
   also have "\<dots> = (\<Sum>k\<in>{1..n}\<union>{0,Suc n}. smult (of_nat (Suc n choose k)) ((pderiv ^^ k) p * (pderiv ^^ (Suc n - k)) q))"
     by (subst sum.union_disjoint) (auto simp: algebra_simps)
   also have "{1..n}\<union>{0,Suc n} = {..Suc n}" by auto
   finally show ?case .
 qed auto
 
 subsection \<open>Auxiliary facts about integrals\<close>
 
 theorem (in pair_sigma_finite) Fubini_set_integrable:
   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
   assumes f[measurable]: "set_borel_measurable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
     and integ1: "set_integrable M1 A (\<lambda>x. \<integral>y\<in>B. norm (f (x, y)) \<partial>M2)"
     and integ2: "AE x\<in>A in M1. set_integrable M2 B (\<lambda>y. f (x, y))"
   shows "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
   unfolding set_integrable_def
 proof (rule Fubini_integrable)
   note integ1
   also have "set_integrable M1 A (\<lambda>x. \<integral>y\<in>B. norm (f (x, y)) \<partial>M2) \<longleftrightarrow>
         integrable M1 (\<lambda>x. LINT y|M2. norm (indicat_real (A \<times> B) (x, y) *\<^sub>R f (x, y)))"
     unfolding set_integrable_def
-    by (intro integrable_cong) (auto simp: indicator_def set_lebesgue_integral_def)
+    by (intro Bochner_Integration.integrable_cong) (auto simp: indicator_def set_lebesgue_integral_def)
   finally show \<dots> .
 next
   from integ2 show "AE x in M1. integrable M2 (\<lambda>y. indicat_real (A \<times> B) (x, y) *\<^sub>R f (x, y))"
   proof eventually_elim
     case (elim x)
     show "integrable M2 (\<lambda>y. indicat_real (A \<times> B) (x, y) *\<^sub>R f (x, y))"
     proof (cases "x \<in> A")
       case True
       with elim have "set_integrable M2 B (\<lambda>y. f (x, y))" by simp
       also have "?this \<longleftrightarrow> ?thesis"
         unfolding set_integrable_def using True
-        by (intro integrable_cong) (auto simp: indicator_def)
+        by (intro Bochner_Integration.integrable_cong) (auto simp: indicator_def)
       finally show ?thesis .
     qed auto
   qed
 qed (insert assms, auto simp: set_borel_measurable_def)
 
 lemma (in pair_sigma_finite) set_integral_fst':
   fixes f :: "_ \<Rightarrow> 'c :: {second_countable_topology, banach}"
   assumes "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
   shows   "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
              (\<integral>x\<in>A. (\<integral>y\<in>B. f (x, y) \<partial>M2) \<partial>M1)"
 proof -
   have "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
           (\<integral>z. indicator (A \<times> B) z *\<^sub>R f z \<partial>(M1 \<Otimes>\<^sub>M M2))"
     by (simp add: set_lebesgue_integral_def)
   also have "\<dots> = (\<integral>x. \<integral>y. indicator (A \<times> B) (x,y) *\<^sub>R f (x,y) \<partial>M2 \<partial>M1)"
     using assms by (subst integral_fst' [symmetric]) (auto simp: set_integrable_def)
   also have "\<dots> = (\<integral>x\<in>A. (\<integral>y\<in>B. f (x,y) \<partial>M2) \<partial>M1)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong refl) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 lemma (in pair_sigma_finite) set_integral_snd:
   fixes f :: "_ \<Rightarrow> 'c :: {second_countable_topology, banach}"
   assumes "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f"
   shows   "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
              (\<integral>y\<in>B. (\<integral>x\<in>A. f (x, y) \<partial>M1) \<partial>M2)"
 proof -
   have "set_lebesgue_integral (M1 \<Otimes>\<^sub>M M2) (A \<times> B) f =
           (\<integral>z. indicator (A \<times> B) z *\<^sub>R f z \<partial>(M1 \<Otimes>\<^sub>M M2))"
     by (simp add: set_lebesgue_integral_def)
   also have "\<dots> = (\<integral>y. \<integral>x. indicator (A \<times> B) (x,y) *\<^sub>R f (x,y) \<partial>M1 \<partial>M2)"
     using assms by (subst integral_snd) (auto simp: set_integrable_def case_prod_unfold)
   also have "\<dots> = (\<integral>y\<in>B. (\<integral>x\<in>A. f (x,y) \<partial>M1) \<partial>M2)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong refl) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 proposition (in pair_sigma_finite) Fubini_set_integral:
   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
   assumes f: "set_integrable (M1 \<Otimes>\<^sub>M M2) (A \<times> B) (case_prod f)"
   shows "(\<integral>y\<in>B. (\<integral>x\<in>A. f x y \<partial>M1) \<partial>M2) = (\<integral>x\<in>A. (\<integral>y\<in>B. f x y \<partial>M2) \<partial>M1)"
 proof -
   have "(\<integral>y\<in>B. (\<integral>x\<in>A. f x y \<partial>M1) \<partial>M2) = (\<integral>y. (\<integral>x. indicator (A \<times> B) (x, y) *\<^sub>R f x y \<partial>M1) \<partial>M2)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong) (auto simp: indicator_def)
   also have "\<dots> = (\<integral>x. (\<integral>y. indicator (A \<times> B) (x, y) *\<^sub>R f x y \<partial>M2) \<partial>M1)"
     using assms by (intro Fubini_integral) (auto simp: set_integrable_def case_prod_unfold)
   also have "\<dots> = (\<integral>x\<in>A. (\<integral>y\<in>B. f x y \<partial>M2) \<partial>M1)"
     unfolding set_lebesgue_integral_def
     by (intro Bochner_Integration.integral_cong) (auto simp: indicator_def)
   finally show ?thesis .
 qed
 
 lemma (in pair_sigma_finite) nn_integral_swap:
   assumes [measurable]: "f \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)"
   shows "(\<integral>\<^sup>+x. f x \<partial>(M1 \<Otimes>\<^sub>M M2)) = (\<integral>\<^sup>+(y,x). f (x,y) \<partial>(M2 \<Otimes>\<^sub>M M1))"
   by (subst distr_pair_swap, subst nn_integral_distr) (auto simp: case_prod_unfold)
 
 lemma set_integrable_bound:
   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
     and g :: "'a \<Rightarrow> 'c::{banach, second_countable_topology}"
   shows "set_integrable M A f \<Longrightarrow> set_borel_measurable M A g \<Longrightarrow>
            (AE x in M. x \<in> A \<longrightarrow> norm (g x) \<le> norm (f x)) \<Longrightarrow> set_integrable M A g"
   unfolding set_integrable_def
   apply (erule Bochner_Integration.integrable_bound)
    apply (simp add: set_borel_measurable_def)
   apply (erule eventually_mono)
   apply (auto simp: indicator_def)
   done
 
 lemma set_integrableI_nonneg:
   fixes f :: "'a \<Rightarrow> real"
   assumes "set_borel_measurable M A f"
   assumes "AE x in M. x \<in> A \<longrightarrow> 0 \<le> f x" "(\<integral>\<^sup>+x\<in>A. f x \<partial>M) < \<infinity>"
   shows "set_integrable M A f"
   unfolding set_integrable_def
 proof (rule integrableI_nonneg)
   from assms show "(\<lambda>x. indicator A x *\<^sub>R f x) \<in> borel_measurable M"
     by (simp add: set_borel_measurable_def)
   from assms(2) show "AE x in M. 0 \<le> indicat_real A x *\<^sub>R f x"
     by eventually_elim (auto simp: indicator_def)
   have "(\<integral>\<^sup>+x. ennreal (indicator A x *\<^sub>R f x) \<partial>M) = (\<integral>\<^sup>+x\<in>A. f x \<partial>M)"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> < \<infinity>" by fact
   finally show "(\<integral>\<^sup>+x. ennreal (indicator A x *\<^sub>R f x) \<partial>M) < \<infinity>" .
 qed
 
 lemma set_integral_eq_nn_integral:
   assumes "set_borel_measurable M A f"
   assumes "set_nn_integral M A f = ennreal x" "x \<ge> 0"
   assumes "AE x in M. x \<in> A \<longrightarrow> f x \<ge> 0"
   shows   "set_integrable M A f"
     and   "set_lebesgue_integral M A f = x"
 proof -
   have eq: "(\<lambda>x. (if x \<in> A then 1 else 0) * f x) = (\<lambda>x. if x \<in> A then f x else 0)"
            "(\<lambda>x. if x \<in> A then ennreal (f x) else 0) =
               (\<lambda>x. ennreal (f x) * (if x \<in> A then 1 else 0))"
            "(\<lambda>x. ennreal (f x * (if x \<in> A then 1 else 0))) =
               (\<lambda>x. ennreal (f x) * (if x \<in> A then 1 else 0))"
     by auto
   from assms show *: "set_integrable M A f"
     by (intro set_integrableI_nonneg) auto
 
   have "set_lebesgue_integral M A f = enn2real (set_nn_integral M A f)"
     unfolding set_lebesgue_integral_def using assms(1,4) * eq
     by (subst integral_eq_nn_integral)
        (auto intro!: nn_integral_cong simp: indicator_def of_bool_def set_integrable_def mult_ac)
   also have "\<dots> = x" using assms by simp
   finally show "set_lebesgue_integral M A f = x" .
 qed
 
 lemma set_integral_0 [simp, intro]: "set_integrable M A (\<lambda>y. 0)"
   by (simp add: set_integrable_def)
 
 lemma set_integrable_sum:
   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
   assumes "finite B"
   assumes "\<And>x. x \<in> B \<Longrightarrow> set_integrable M A (f x)"
   shows "set_integrable M A (\<lambda>y. \<Sum>x\<in>B. f x y)"
   using assms by (induction rule: finite_induct) (auto intro!: set_integral_add)
 
 lemma set_integral_sum:
   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
   assumes "finite B"
   assumes "\<And>x. x \<in> B \<Longrightarrow> set_integrable M A (f x)"
   shows "set_lebesgue_integral M A (\<lambda>y. \<Sum>x\<in>B. f x y) = (\<Sum>x\<in>B. set_lebesgue_integral M A (f x))"
   using assms
   apply (induction rule: finite_induct)
   apply simp
   apply simp
   apply (subst set_integral_add)
     apply (auto intro!: set_integrable_sum)
   done
 
 lemma set_nn_integral_cong:
   assumes "M = M'" "A = B" "\<And>x. x \<in> space M \<inter> A \<Longrightarrow> f x = g x"
   shows   "set_nn_integral M A f = set_nn_integral M' B g"
   using assms unfolding assms(1,2) by (intro nn_integral_cong) (auto simp: indicator_def)
 
 lemma set_nn_integral_mono:
   assumes "\<And>x. x \<in> space M \<inter> A \<Longrightarrow> f x \<le> g x"
   shows   "set_nn_integral M A f \<le> set_nn_integral M A g"
   using assms by (intro nn_integral_mono) (auto simp: indicator_def)
 
 lemma
   fixes f :: "real \<Rightarrow> real"
   assumes "a \<le> b"
   assumes deriv: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes cont: "continuous_on {a..b} f"
   shows has_bochner_integral_FTC_Icc_real:
       "has_bochner_integral lborel (\<lambda>x. f x * indicator {a .. b} x) (F b - F a)" (is ?has)
     and integral_FTC_Icc_real: "(\<integral>x. f x * indicator {a .. b} x \<partial>lborel) = F b - F a" (is ?eq)
 proof -
   have 1: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> (F has_vector_derivative f x) (at x within {a .. b})"
     unfolding has_real_derivative_iff_has_vector_derivative[symmetric]
     using deriv by auto
   show ?has ?eq
     using has_bochner_integral_FTC_Icc[OF \<open>a \<le> b\<close> 1 cont] integral_FTC_Icc[OF \<open>a \<le> b\<close> 1 cont]
     by (auto simp: mult.commute)
 qed
 
 lemma integral_by_parts_integrable:
   fixes f g F G::"real \<Rightarrow> real"
   assumes "a \<le> b"
   assumes cont_f[intro]: "continuous_on {a..b} f"
   assumes cont_g[intro]: "continuous_on {a..b} g"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (G has_field_derivative g x) (at x within {a..b})"
   shows  "integrable lborel (\<lambda>x.((F x) * (g x) + (f x) * (G x)) * indicator {a .. b} x)"
 proof -
   have "integrable lborel (\<lambda>x. indicator {a..b} x *\<^sub>R ((F x) * (g x) + (f x) * (G x)))"
     by (intro borel_integrable_compact continuous_intros assms)
        (auto intro!: DERIV_continuous_on assms)
   thus ?thesis by (simp add: mult_ac)
 qed
 
 lemma integral_by_parts:
   fixes f g F G::"real \<Rightarrow> real"
   assumes [arith]: "a \<le> b"
   assumes cont_f[intro]: "continuous_on {a..b} f"
   assumes cont_g[intro]: "continuous_on {a..b} g"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (G has_field_derivative g x) (at x within {a..b})"
   shows "(\<integral>x. (F x * g x) * indicator {a .. b} x \<partial>lborel)
             =  F b * G b - F a * G a - \<integral>x. (f x * G x) * indicator {a .. b} x \<partial>lborel"
 proof-
   have 0: "(\<integral>x. (F x * g x + f x * G x) * indicator {a .. b} x \<partial>lborel) = F b * G b - F a * G a"
     by (rule integral_FTC_Icc_real, auto intro!: derivative_eq_intros continuous_intros)
        (auto intro!: assms DERIV_continuous_on)
   have [continuous_intros]: "continuous_on {a..b} F"
     by (rule DERIV_continuous_on assms)+
   have [continuous_intros]: "continuous_on {a..b} G"
     by (rule DERIV_continuous_on assms)+
 
   have "(\<integral>x. indicator {a..b} x *\<^sub>R (F x * g x + f x * G x) \<partial>lborel) =
     (\<integral>x. indicator {a..b} x *\<^sub>R(F x * g x) \<partial>lborel) + \<integral>x. indicator {a..b} x *\<^sub>R (f x * G x) \<partial>lborel"
     apply (subst Bochner_Integration.integral_add[symmetric])
       apply (rule borel_integrable_compact; force intro!: continuous_intros assms)
      apply (rule borel_integrable_compact; force intro!: continuous_intros assms)
     apply (simp add: algebra_simps)
     done
 
   thus ?thesis using 0 by (simp add: algebra_simps)
 qed
 
 lemma interval_lebesgue_integral_by_parts:
   assumes "a \<le> b"
   assumes cont_f[intro]: "continuous_on {a..b} f"
   assumes cont_g[intro]: "continuous_on {a..b} g"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (F has_field_derivative f x) (at x within {a..b})"
   assumes [intro]: "\<And>x. x \<in> {a..b} \<Longrightarrow> (G has_field_derivative g x) (at x within {a..b})"
   shows "(LBINT x=a..b. F x * g x) = F b * G b - F a * G a - (LBINT x=a..b. f x * G x)"
   using integral_by_parts[of a b f g F G] assms
   by (simp add: interval_integral_Icc set_lebesgue_integral_def mult_ac)
 
 lemma interval_lebesgue_integral_by_parts_01:
   assumes cont_f[intro]: "continuous_on {0..1} f"
   assumes cont_g[intro]: "continuous_on {0..1} g"
   assumes [intro]: "\<And>x. x \<in> {0..1} \<Longrightarrow> (F has_field_derivative f x) (at x within {0..1})"
   assumes [intro]: "\<And>x. x \<in> {0..1} \<Longrightarrow> (G has_field_derivative g x) (at x within {0..1})"
   shows "(LBINT x=0..1. F x * g x) = F 1 * G 1 - F 0 * G 0 - (LBINT x=0..1. f x * G x)"
   using interval_lebesgue_integral_by_parts[of 0 1 f g F G] assms
   by (simp add: zero_ereal_def one_ereal_def)
 
 lemma continuous_on_imp_set_integrable_cbox:
   fixes h :: "'a :: euclidean_space \<Rightarrow> real"
   assumes "continuous_on (cbox a b) h"
   shows   "set_integrable lborel (cbox a b) h"
 proof -
   from assms have "h absolutely_integrable_on cbox a b"
     by (rule absolutely_integrable_continuous)
   moreover have "(\<lambda>x. indicat_real (cbox a b) x *\<^sub>R h x) \<in> borel_measurable borel"
     by (rule borel_measurable_continuous_on_indicator) (use assms in auto)
   ultimately show ?thesis
     unfolding set_integrable_def using assms by (subst (asm) integrable_completion) auto
 qed
 
 
 subsection \<open>Shifted Legendre polynomials\<close>
 
 text \<open>
   The first ingredient we need to show Apéry's theorem is the \<^emph>\<open>shifted
   Legendre polynomials\<close>
     \[P_n(X) = \frac{1}{n!} \frac{\partial^n}{\partial X^n} (X^n(1-X)^n)\]
   and the auxiliary polynomials
     \[Q_{n,k}(X) = \frac{\partial^k}{\partial X^k} (X^n(1-X)^n)\ .\]
   Note that $P_n$ is in fact an \emph{integer} polynomial.
 
   Only some very basic properties of these will be proven, since that is all we will need.
 \<close>
 
 context
   fixes n :: nat
 begin
 
 definition gen_shleg_poly :: "nat \<Rightarrow> int poly" where
   "gen_shleg_poly k = (pderiv ^^ k) ([:0, 1, -1:] ^ n)"
 
 definition shleg_poly where "shleg_poly = gen_shleg_poly n div [:fact n:]"
 
 text \<open>
   We can easily prove the following more explicit formula for $Q_{n,k}$:
   \[Q_{n,k}(X) = \sum_{i=0}^k (-1)^{k-1} {k \choose i}
       n^{\underline{i}}\, n^{\underline{k-i}}\, X^{n-i}\, (1-X)^{n-k+i}\]
 \<close>
 lemma gen_shleg_poly_altdef:
   assumes "k \<le> n"
   shows "gen_shleg_poly k =
             (\<Sum>i\<le>k. smult ((-1)^(k-i) * of_nat (k choose i) *
                     pochhammer (n-i+1) i * pochhammer (n-k+i+1) (k-i))
                     ([:0, 1:] ^ (n - i) * [:1, -1:] ^ (n-k+i)))"
 proof -
   have *: "(pderiv ^^ i) (x \<circ>\<^sub>p [:1, -1:]) =
           smult ((-1) ^ i) ((pderiv ^^ i) x \<circ>\<^sub>p [:1, -1:])" for i and x :: "int poly"
     by (induction i arbitrary: x)
        (auto simp: pderiv_smult pderiv_pcompose funpow_Suc_right pderiv_pCons
                    higher_pderiv_minus simp del: funpow.simps(2))
 
   have "gen_shleg_poly k = (pderiv ^^ k) ([:0, 1, -1:] ^ n)"
     by (simp add: gen_shleg_poly_def)
   also have "[:0, 1, -1::int:] = [:0, 1:] * [:1, -1:]"
     by simp
   also have "\<dots> ^ n = [:0, 1:] ^ n * [:1, -1:] ^ n"
     by (simp flip: power_mult_distrib)
   also have "(pderiv ^^ k) \<dots> =
                (\<Sum>i\<le>k. smult (of_nat (k choose i)) ((pderiv ^^ i)
                  ([:0, 1:] ^ n) * (pderiv ^^ (k - i)) ([:1, -1:] ^ n)))"
     by (simp add: higher_pderiv_mult)
   also have "\<dots> = (\<Sum>i\<le>k. smult (of_nat (k choose i))
                     ((pderiv ^^ i) (monom 1 n) * (pderiv ^^ (k - i)) (monom 1 n \<circ>\<^sub>p [:1, -1:])))"
     by (simp add: monom_altdef pcompose_pCons pcompose_power_left)
   also have "\<dots> = (\<Sum>i\<le>k. smult ((-1) ^ (k - i) * of_nat (k choose i))
                    ((pderiv ^^ i) (monom 1 n) * ((pderiv ^^ (k - i)) (monom 1 n) \<circ>\<^sub>p [:1, -1:])))"
     by (simp add: * mult_ac)
   also have "\<dots> = (\<Sum>i\<le>k. smult ((-1) ^ (k - i) * of_nat (k choose i))
                    (monom (pochhammer (n - i + 1) i) (n - i) *
                     monom (pochhammer (n - k + i + 1) (k - i)) (n - k + i) \<circ>\<^sub>p [:1, -1:]))"
     using assms by (simp add: higher_pderiv_monom)
   also have "\<dots> = (\<Sum>i\<le>k. smult ((-1) ^ (k - i) * of_nat (k choose i) * pochhammer (n - i + 1) i * pochhammer (n - k + i + 1) (k - i))
                    ([:0, 1:] ^ (n - i) * [:1, -1:] ^ (n - k + i)))"
     by (simp add: monom_altdef algebra_simps pcompose_smult pcompose_power_left pcompose_pCons)
   finally show ?thesis .
 qed
 
 lemma degree_gen_shleg_poly [simp]: "degree (gen_shleg_poly k) = 2 * n - k"
   by (simp add: gen_shleg_poly_def degree_higher_pderiv degree_power_eq)
 
 lemma gen_shleg_poly_n: "gen_shleg_poly n = smult (fact n) shleg_poly"
 proof -
   obtain r where r: "gen_shleg_poly n = [:fact n:] * r"
     unfolding gen_shleg_poly_def using fact_dvd_higher_pderiv[of n "[:0,1,-1:]^n"] by blast
   have "smult (fact n) shleg_poly = smult (fact n) (gen_shleg_poly n div [:fact n:])"
     by (simp add: shleg_poly_def)
   also note r
   also have "[:fact n:] * r div [:fact n:] = r"
     by (rule nonzero_mult_div_cancel_left) auto
   finally show ?thesis
     by (simp add: r)
 qed
 
 lemma degree_shleg_poly [simp]: "degree shleg_poly = n"
   using degree_gen_shleg_poly[of n] by (simp add: gen_shleg_poly_n)
 
 lemma pderiv_gen_shleg_poly [simp]: "pderiv (gen_shleg_poly k) = gen_shleg_poly (Suc k)"
   by (simp add: gen_shleg_poly_def)
 
 
 text \<open>
   The following functions are the interpretation of the shifted Legendre polynomials
   and the auxiliary polynomials as a function from reals to reals.
 \<close>
 definition Gen_Shleg :: "nat \<Rightarrow> real \<Rightarrow> real"
   where "Gen_Shleg k x = poly (of_int_poly (gen_shleg_poly k)) x"
 
 definition Shleg :: "real \<Rightarrow> real" where "Shleg = poly (of_int_poly shleg_poly)"
 
 lemma Gen_Shleg_altdef:
   assumes "k \<le> n"
   shows   "Gen_Shleg k x = (\<Sum>i\<le>k. (-1)^(k-i) * of_nat (k choose i) *
                             of_int (pochhammer (n-i+1) i * pochhammer (n-k+i+1) (k-i)) *
                             x ^ (n - i) * (1 - x) ^ (n-k+i))"
   using assms by (simp add: Gen_Shleg_def gen_shleg_poly_altdef poly_sum mult_ac)
 
 lemma Gen_Shleg_0 [simp]: "k < n \<Longrightarrow> Gen_Shleg k 0 = 0"
   by (simp add: Gen_Shleg_altdef zero_power)
 
 lemma Gen_Shleg_1 [simp]: "k < n \<Longrightarrow> Gen_Shleg k 1 = 0"
   by (simp add: Gen_Shleg_altdef zero_power)
 
 lemma Gen_Shleg_n_0 [simp]: "Gen_Shleg n 0 = fact n"
 proof -
   have "Gen_Shleg n 0 = (\<Sum>i\<le>n. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ (n - i))"
     by (simp add: Gen_Shleg_altdef)
   also have "\<dots> = (\<Sum>i\<in>{n}. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ (n - i))"
     by (intro sum.mono_neutral_right) auto
   also have "\<dots> = fact n"
     by (simp add: pochhammer_fact flip: pochhammer_of_nat)
   finally show ?thesis .
 qed
 
 lemma Gen_Shleg_n_1 [simp]: "Gen_Shleg n 1 = (-1) ^ n * fact n"
 proof -
   have "Gen_Shleg n 1 = (\<Sum>i\<le>n. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ i)"
     by (simp add: Gen_Shleg_altdef)
   also have "\<dots> = (\<Sum>i\<in>{0}. (-1) ^ (n-i) * real (n choose i) *
         (real (pochhammer (Suc (n-i)) i) *
          real (pochhammer (Suc i) (n-i))) * 0 ^ i)"
     by (intro sum.mono_neutral_right) auto
   also have "\<dots> = (-1) ^ n * fact n"
     by (simp add: pochhammer_fact flip: pochhammer_of_nat)
   finally show ?thesis .
 qed
 
 lemma Shleg_altdef: "Shleg x = Gen_Shleg n x / fact n"
   by (simp add: Shleg_def Gen_Shleg_def gen_shleg_poly_n)
 
 lemma Shleg_0 [simp]: "Shleg 0 = 1" and Shleg_1 [simp]: "Shleg 1 = (-1) ^ n"
   by (simp_all add: Shleg_altdef)
 
 lemma Gen_Shleg_0_left: "Gen_Shleg 0 x = x ^ n * (1 - x) ^ n"
   by (simp add: Gen_Shleg_def gen_shleg_poly_def power_mult_distrib)
 
 lemma has_field_derivative_Gen_Shleg:
   "(Gen_Shleg k has_field_derivative Gen_Shleg (Suc k) x) (at x)"
 proof -
   note [derivative_intros] = poly_DERIV
   show ?thesis unfolding Gen_Shleg_def
     by (rule derivative_eq_intros) auto
 qed
 
 lemma continuous_on_Gen_Shleg: "continuous_on A (Gen_Shleg k)"
   by (auto simp: Gen_Shleg_def intro!: continuous_intros)
 
 lemma continuous_on_Gen_Shleg' [continuous_intros]:
   "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. Gen_Shleg k (f x))"
   by (rule continuous_on_compose2[OF continuous_on_Gen_Shleg[of UNIV]]) auto
 
 lemma continuous_on_Shleg: "continuous_on A Shleg"
   by (auto simp: Shleg_def intro!: continuous_intros)
 
 lemma continuous_on_Shleg' [continuous_intros]:
   "continuous_on A f \<Longrightarrow> continuous_on A (\<lambda>x. Shleg (f x))"
   by (rule continuous_on_compose2[OF continuous_on_Shleg[of UNIV]]) auto
 
 lemma measurable_Gen_Shleg [measurable]: "Gen_Shleg n \<in> borel_measurable borel"
   by (intro borel_measurable_continuous_onI continuous_on_Gen_Shleg)
 
 lemma measurable_Shleg [measurable]: "Shleg \<in> borel_measurable borel"
   by (intro borel_measurable_continuous_onI continuous_on_Shleg)
 
 end
 
 
 subsection \<open>Auxiliary facts about the \<open>\<zeta>\<close> function\<close>
 
 lemma Re_zeta_ge_1:
   assumes "x > 1"
   shows   "Re (zeta (of_real x)) \<ge> 1"
 proof -
   have *: "(\<lambda>n. real (Suc n) powr -x) sums Re (zeta (complex_of_real x))"
     using sums_Re[OF sums_zeta[of "of_real x"]] assms by (simp add: powr_Reals_eq)
   show "Re (zeta (of_real x)) \<ge> 1"
   proof (rule sums_le[OF _ _ *])
     show "(\<lambda>n. if n = 0 then 1 else 0) sums 1"
       by (rule sums_single)
   qed auto
 qed
 
 lemma sums_zeta_of_nat_offset:
   fixes r :: nat
   assumes n: "n > 1"
   shows "(\<lambda>k. 1 / (r + k + 1) ^ n) sums (zeta (of_nat n) - (\<Sum>k=1..r. 1 / k ^ n))"
 proof -
   have "(\<lambda>k. 1 / (k + 1) ^ n) sums zeta (of_nat n)"
     using sums_zeta[of "of_nat n"] n
     by (simp add: powr_minus field_simps flip: of_nat_Suc)
   from sums_split_initial_segment[OF this, of r]
   have "(\<lambda>k. 1 / (r + k + 1) ^ n) sums (zeta (of_nat n) - (\<Sum>k<r. 1 / Suc k ^ n))"
     by (simp add: algebra_simps)
   also have "(\<Sum>k<r. 1 / Suc k ^ n) = (\<Sum>k=1..r. 1 / k ^ n)"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>k. k - 1" Suc]) auto
   finally show ?thesis .
 qed
 
 lemma sums_Re_zeta_of_nat_offset:
   fixes r :: nat
   assumes n: "n > 1"
   shows "(\<lambda>k. 1 / (r + k + 1) ^ n) sums (Re (zeta (of_nat n)) - (\<Sum>k=1..r. 1 / k ^ n))"
 proof -
   have "(\<lambda>k. Re (1 / (r + k + 1) ^ n)) sums (Re (zeta (of_nat n) - (\<Sum>k=1..r. 1 / k ^ n)))"
     by (intro sums_Re sums_zeta_of_nat_offset assms)
   thus ?thesis by simp
 qed
 
 
 subsection \<open>Divisor of a sum of rationals\<close>
 
 text \<open>
   A finite sum of rationals of the form $\frac{a_1}{b_1} + \ldots + \frac{a_n}{b_n}$
   can be brought into the form $\frac{c}{d}$, where $d$ is the LCM of the $b_i$ (or
   some integer multiple thereof).
 \<close>
 lemma sum_rationals_common_divisor:
   fixes f g :: "'a \<Rightarrow> int"
   assumes "finite A"
   assumes "\<And>x. x \<in> A \<Longrightarrow> g x \<noteq> 0"
   shows   "\<exists>c. (\<Sum>x\<in>A. f x / g x) = real_of_int c / (LCM x\<in>A. g x)"
   using assms
 proof (induction rule: finite_induct)
   case empty
   thus ?case by auto
 next
   case (insert x A)
   define d where "d = (LCM x\<in>A. g x)"
   from insert have [simp]: "d \<noteq> 0"
     by (auto simp: d_def Lcm_0_iff)
   from insert have [simp]: "g x \<noteq> 0" by auto
   from insert obtain c where c: "(\<Sum>x\<in>A. f x / g x) = real_of_int c / real_of_int d"
     by (auto simp: d_def)
   define e1 where "e1 = lcm d (g x) div d"
   define e2 where "e2 = lcm d (g x) div g x"
   have "(\<Sum>y\<in>insert x A. f y / g y) = c / d + f x / g x"
     using insert c by simp
   also have "c / d = (c * e1) / lcm d (g x)"
     by (simp add: e1_def real_of_int_div)
   also have "f x / g x = (f x * e2) / lcm d (g x)"
     by (simp add: e2_def real_of_int_div)
   also have "(c * e1) / lcm d (g x) + \<dots> = (c * e1 + f x * e2) / (LCM x\<in>insert x A. g x)"
     using insert by (simp add: add_divide_distrib lcm.commute d_def)
   finally show ?case ..
 qed
 
 lemma sum_rationals_common_divisor':
   fixes f g :: "'a \<Rightarrow> int"
   assumes "finite A"
   assumes "\<And>x. x \<in> A \<Longrightarrow> g x \<noteq> 0" and "(\<And>x. x \<in> A \<Longrightarrow> g x dvd d)" and "d \<noteq> 0"
   shows   "\<exists>c. (\<Sum>x\<in>A. f x / g x) = real_of_int c / real_of_int d"
 proof -
   define d' where "d' = (LCM x\<in>A. g x)"
   have "d' dvd d"
     unfolding d'_def using assms(3) by (auto simp: Lcm_dvd_iff)
   then obtain e where e: "d = d' * e" by blast
   have "\<exists>c. (\<Sum>x\<in>A. f x / g x) = real_of_int c / (LCM x\<in>A. g x)"
     by (rule sum_rationals_common_divisor) fact+
   then obtain c where c: "(\<Sum>x\<in>A. f x / g x) = real_of_int c / real_of_int d'"
     unfolding d'_def ..
   also have "\<dots> = real_of_int (c * e) / real_of_int d"
     using \<open>d \<noteq> 0\<close> by (simp add: e)
   finally show ?thesis ..
 qed
 
 
 subsection \<open>The first double integral\<close>
 
 text \<open>
   We shall now investigate the double integral
   \[I_1 := \int_0^1 \int_0^1 -\frac{\ln(xy)}{1-xy}\,x^r y^s\, \text{d}x\,\text{d}y\ .\]
   Since everything is non-negative for now, we can work over the extended non-negative
   real numbers and the issues of integrability or summability do not arise at all.
 \<close>
 
 definition beukers_nn_integral1 :: "nat \<Rightarrow> nat \<Rightarrow> ennreal" where
   "beukers_nn_integral1 r s =
      (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y) / (1 - x*y) * x^r * y^s) \<partial>lborel)"
 
 definition beukers_integral1 :: "nat \<Rightarrow> nat \<Rightarrow> real" where
   "beukers_integral1 r s = (\<integral>(x,y)\<in>{0<..<1}\<times>{0<..<1}. (-ln (x*y) / (1 - x*y) * x^r * y^s) \<partial>lborel)"
 
 lemma
   fixes x y z :: real
   assumes xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0..1}"
   shows beukers_denom_ineq: "(1 - x * y) * z < 1" and beukers_denom_neq: "(1 - x * y) * z \<noteq> 1"
 proof -
   from xyz have *: "x * y < 1 * 1"
     by (intro mult_strict_mono) auto
   from * have "(1 - x * y) * z \<le> (1 - x * y) * 1"
     using xyz by (intro mult_left_mono) auto
   also have "\<dots> < 1 * 1"
     using xyz by (intro mult_strict_right_mono) auto
   finally show "(1 - x * y) * z < 1" "(1 - x * y) * z \<noteq> 1" by simp_all
 qed
 
 text \<open>
   We first evaluate the improper integral
     \[\int_0^1 -\ln x \cdot x^e\,\text{d}x = \frac{1}{(e+1)^2}\ .\]
   for any $e>-1$.
 \<close>
 lemma integral_0_1_ln_times_powr:
   assumes "e > -1"
   shows   "(LBINT x=0..1. -ln x * x powr e) = 1 / (e + 1)\<^sup>2"
     and   "interval_lebesgue_integrable lborel 0 1 (\<lambda>x. -ln x * x powr e)"
 proof -
   define f where "f = (\<lambda>x. -ln x * x powr e)"
   define F where "F = (\<lambda>x. x powr (e + 1) * (1 - (e + 1) * ln x) / (e + 1) ^ 2)"
 
   have 0: "isCont f x" if "x \<in> {0<..<1}" for x
     using that by (auto intro!: continuous_intros simp: f_def)
   have 1: "(F has_real_derivative f x) (at x)" if "x \<in> {0<..<1}" for x
   proof -
     show "(F has_real_derivative f x) (at x)"
       unfolding F_def f_def using that assms
       apply (insert that assms)
       apply (rule derivative_eq_intros refl | simp)+
       apply (simp add: divide_simps)
       apply (simp add: power2_eq_square algebra_simps powr_add power_numeral_reduce)
       done
   qed
   have 2: "AE x in lborel. ereal 0 < ereal x \<longrightarrow> ereal x < ereal 1 \<longrightarrow> 0 \<le> f x"
     by (intro AE_I2) (auto simp: f_def mult_nonpos_nonneg)
   have 3: "((F \<circ> real_of_ereal) \<longlongrightarrow> 0) (at_right (ereal 0))"
     unfolding ereal_tendsto_simps F_def using assms by real_asymp
   have 4: "((F \<circ> real_of_ereal) \<longlongrightarrow> F 1) (at_left (ereal 1))"
     unfolding ereal_tendsto_simps F_def
     using assms by real_asymp (simp add: field_simps)
 
   have "(LBINT x=ereal 0..ereal 1. f x) = F 1 - 0"
     by (rule interval_integral_FTC_nonneg[where F = F])
        (use 0 1 2 3 4 in auto)
   thus "(LBINT x=0..1. -ln x * x powr e) = 1 / (e + 1)\<^sup>2"
     by (simp add: F_def zero_ereal_def one_ereal_def f_def)
   have "set_integrable lborel (einterval (ereal 0) (ereal 1)) f"
     by (rule interval_integral_FTC_nonneg)
        (use 0 1 2 3 4 in auto)
   thus "interval_lebesgue_integrable lborel 0 1 f"
     by (simp add: interval_lebesgue_integrable_def einterval_def)
 qed
 
 lemma interval_lebesgue_integral_lborel_01_cong:
   assumes "\<And>x. x \<in> {0<..<1} \<Longrightarrow> f x = g x"
   shows   "interval_lebesgue_integral lborel 0 1 f =
            interval_lebesgue_integral lborel 0 1 g"
   using assms
   by (subst (1 2) interval_integral_Ioo)
      (auto intro!: set_lebesgue_integral_cong assms)
 
 lemma nn_integral_0_1_ln_times_powr:
   assumes "e > -1"
   shows    "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y powr e) \<partial>lborel) = ennreal (1 / (e + 1)\<^sup>2)"
 proof -
   have *: "(LBINT x=0..1. - ln x * x powr e = 1 / (e + 1)\<^sup>2)"
           "interval_lebesgue_integrable lborel 0 1 (\<lambda>x. - ln x * x powr e)"
     using integral_0_1_ln_times_powr[OF assms] by simp_all
   have eq: "(\<lambda>y. (if 0 < y \<and> y < 1 then 1 else 0) * ln y * y powr e) =
             (\<lambda>y. if 0 < y \<and> y < 1 then ln y * y powr e else 0)"
     by auto
 
   have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y powr e) \<partial>lborel) =
            (\<integral>\<^sup>+y. ennreal (-ln y * y powr e * indicator {0<..<1} y) \<partial>lborel)"
     by (intro nn_integral_cong) (auto simp: indicator_def)
   also have "\<dots> = ennreal (1 / (e + 1)\<^sup>2)"
     using * eq
     by (subst nn_integral_eq_integral)
        (auto intro!: AE_I2 simp: indicator_def interval_lebesgue_integrable_def
                set_integrable_def one_ereal_def zero_ereal_def interval_integral_Ioo
                 mult_ac mult_nonpos_nonneg set_lebesgue_integral_def)
   finally show ?thesis .
 qed
 
 lemma nn_integral_0_1_ln_times_power:
   "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y ^ n) \<partial>lborel) = ennreal (1 / (n + 1)\<^sup>2)"
 proof -
   have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y ^ n) \<partial>lborel) =
           (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y powr real n) \<partial>lborel)"
     by (intro set_nn_integral_cong) (auto simp: powr_realpow)
   also have "\<dots> = ennreal (1 / (n + 1)^2)"
     by (subst nn_integral_0_1_ln_times_powr) auto
   finally show ?thesis by simp
 qed
 
 text \<open>
   Next, we also evaluate the more trivial integral
     \[\int_0^1 x^n\ \text{d}x\ .\]
 \<close>
 lemma nn_integral_0_1_power:
   "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y ^ n) \<partial>lborel) = ennreal (1 / (n + 1))"
 proof -
   have *: "((\<lambda>a. a ^ (n + 1) / real (n + 1)) has_real_derivative x ^ n) (at x)" for x
     by (rule derivative_eq_intros refl | simp)+
   have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y ^ n) \<partial>lborel) = (\<integral>\<^sup>+y\<in>{0..1}. ennreal (y ^ n) \<partial>lborel)"
     by (intro nn_integral_cong_AE AE_I[of _ _ "{0,1}"])
        (auto simp: indicator_def emeasure_lborel_countable)
   also have "\<dots> = ennreal (1 ^ (n + 1) / (n + 1) - 0 ^ (n + 1) / (n + 1))"
     using * by (intro nn_integral_FTC_Icc) auto
   also have "\<dots> = ennreal (1 / (n + 1))"
     by simp
   finally show ?thesis by simp
 qed
 
 text \<open>
   $I_1$ can alternatively be written as the triple integral
     \[\int_0^1\int_0^1\int_0^1
         \frac{x^r y^s}{1-(1-xy)w}\ \text{d}x\,\text{d}y\,\text{d}w\ .\]
 \<close>
 lemma beukers_nn_integral1_altdef:
   "beukers_nn_integral1 r s =
      (\<integral>\<^sup>+(w,x,y)\<in>{0<..<1}\<times>{0<..<1}\<times>{0<..<1}.
        ennreal (1 / (1-(1-x*y)*w) * x^r * y^s) \<partial>lborel)"
 proof -
   have "(\<integral>\<^sup>+(w,x,y)\<in>{0<..<1}\<times>{0<..<1}\<times>{0<..<1}.
            ennreal (1 / (1-(1-x*y)*w) * x^r * y^s) \<partial>lborel) =
         (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. (\<integral>\<^sup>+w\<in>{0<..<1}.
            ennreal (1 / (1-(1-x*y)*w) * x^r * y^s) \<partial>lborel) \<partial>lborel)"
     by (subst lborel_prod [symmetric], subst lborel_pair.nn_integral_snd [symmetric])
        (auto simp: case_prod_unfold indicator_def simp flip: lborel_prod intro!: nn_integral_cong)
   also have "\<dots> = (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y)/(1-x*y) * x^r * y^s) \<partial>lborel)"
   proof (intro nn_integral_cong, clarify)
     fix x y :: real
     have "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)*x^r*y^s) \<partial>lborel) =
              ennreal (-ln (x*y)*x^r*y^s/(1-x*y))"
       if xy: "(x, y) \<in> {0<..<1} \<times> {0<..<1}"
     proof -
       from xy have "x * y < 1"
         using mult_strict_mono[of x 1 y 1] by simp
       have deriv: "((\<lambda>w. -ln (1-(1-x*y)*w) / (1-x*y)) has_real_derivative
               1/(1-(1-x*y)*w)) (at w)" if w: "w \<in> {0..1}" for w
         by (insert xy w \<open>x*y<1\<close> beukers_denom_ineq[of x y w])
            (rule derivative_eq_intros refl | simp add: divide_simps)+
       have "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)*x^r*y^s) \<partial>lborel) =
               ennreal (x^r*y^s) * (\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel)"
         using xy by (subst nn_integral_cmult [symmetric])
                     (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
       also have "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel) =
                  (\<integral>\<^sup>+w\<in>{0..1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel)"
         by (intro nn_integral_cong_AE AE_I[of _ _ "{0,1}"])
            (auto simp: emeasure_lborel_countable indicator_def)
       also have "(\<integral>\<^sup>+w\<in>{0..1}. ennreal (1/(1-(1-x*y)*w)) \<partial>lborel) =
                    ennreal (-ln (1-(1-x*y)*1)/(1-x*y) - (-ln (1-(1-x*y)*0)/(1-x*y)))"
         using xy deriv less_imp_le[OF beukers_denom_ineq[of x y]]
         by (intro nn_integral_FTC_Icc) auto
       finally show ?thesis using xy
         by (simp flip: ennreal_mult' ennreal_mult'' add: mult_ac)
     qed
     thus "(\<integral>\<^sup>+w\<in>{0<..<1}. ennreal (1/(1-(1-x*y)*w)*x^r*y^s) \<partial>lborel) * indicator ({0<..<1}\<times>{0<..<1}) (x, y) =
            ennreal (-ln (x*y)/(1-x*y)*x^r*y^s) * indicator ({0<..<1}\<times>{0<..<1}) (x, y)"
       by (auto simp: indicator_def)
   qed
   also have "\<dots> = beukers_nn_integral1 r s"
     by (simp add: beukers_nn_integral1_def)
   finally show ?thesis ..
 qed
 
 context
   fixes r s :: nat and I1 I2' :: real and I2 :: ennreal and D :: "(real \<times> real \<times> real) set"
   assumes rs: "s \<le> r"
   defines "D \<equiv> {0<..<1}\<times>{0<..<1}\<times>{0<..<1}"
 begin
 
 text \<open>
   By unfolding the geometric series, pulling the summation out and evaluating the integrals,
   we find that
     \[I_1 = \sum_{k=0}^\infty \frac{1}{(k+r+1)^2(k+s+1)} + \frac{1}{(k+r+1)(k+s+1)^2}\ .\]
 \<close>
 lemma beukers_nn_integral1_series:
   "beukers_nn_integral1 r s = (\<Sum>k. ennreal (1/((k+r+1)^2*(k+s+1)) + 1/((k+r+1)*(k+s+1)^2)))"
 proof -
   have "beukers_nn_integral1 r s =
           (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. (\<Sum>k. ennreal (-ln (x*y) * x^(k+r) * y^(k+s))) \<partial>lborel)"
     unfolding beukers_nn_integral1_def
   proof (intro set_nn_integral_cong refl, clarify)
     fix x y :: real assume xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
     from xy have "x * y < 1" using mult_strict_mono[of x 1 y 1] by simp
     have "(\<Sum>k. ennreal (-ln (x*y) * x^(k+r) * y^(k+s))) =
              ennreal (-ln (x*y) * x^r * y^s) * (\<Sum>k. ennreal ((x*y)^k))"
       using xy by (subst ennreal_suminf_cmult [symmetric], subst ennreal_mult'' [symmetric])
                   (auto simp: power_add mult_ac power_mult_distrib)
     also have "(\<Sum>k. ennreal ((x*y)^k)) = ennreal (1 / (1 - x*y))"
       using geometric_sums[of "x*y"] \<open>x * y < 1\<close> xy by (intro suminf_ennreal_eq) auto
     also have "ennreal (-ln (x*y) * x^r * y^s) * \<dots> =
                  ennreal (-ln (x*y) / (1 - x*y) * x^r * y^s)"
       using \<open>x * y < 1\<close> by (subst ennreal_mult'' [symmetric]) auto
     finally show "ennreal (-ln (x*y) / (1 - x*y) * x^r * y^s) =
                     (\<Sum>k. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)))" ..
   qed
   also have "\<dots> = (\<Sum>k. (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. (ennreal (-ln (x*y) * x^(k+r) * y^(k+s))) \<partial>lborel))"
     unfolding case_prod_unfold by (subst nn_integral_suminf [symmetric]) (auto simp flip: borel_prod)
   also have "\<dots> = (\<Sum>k. ennreal (1 / ((k+r+1)^2*(k+s+1)) + 1 / ((k+r+1)*(k+s+1)^2)))"
   proof (rule suminf_cong)
     fix k :: nat
     define F where "F = (\<lambda>x y::real. x + y)"
     have "(\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) =
             (\<integral>\<^sup>+x\<in>{0<..<1}. (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) \<partial>lborel)"
       unfolding case_prod_unfold lborel_prod [symmetric]
       by (subst lborel.nn_integral_fst [symmetric]) (auto intro!: nn_integral_cong simp: indicator_def)
     also have "\<dots> = (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r) / (k+s+1) + x^(k+r)/(k+s+1)^2) \<partial>lborel)"
     proof (intro set_nn_integral_cong refl, clarify)
       fix x :: real assume x: "x \<in> {0<..<1}"
       have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) =
               (\<integral>\<^sup>+y\<in>{0<..<1}. (ennreal (-ln x * x^(k+r) * y^(k+s)) + ennreal (-ln y * x^(k+r) * y^(k+s))) \<partial>lborel)"
         by (intro set_nn_integral_cong)
            (use x in \<open>auto simp: ln_mult ring_distribs mult_nonpos_nonneg simp flip: ennreal_plus\<close>)
       also have "\<dots> = (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln x * x^(k+r) * y^(k+s)) \<partial>lborel) +
                       (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * x^(k+r) * y^(k+s)) \<partial>lborel)"
         by (subst nn_integral_add [symmetric]) (auto intro!: nn_integral_cong simp: indicator_def)
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln x * x^(k+r) * y^(k+s)) \<partial>lborel) =
                  ennreal (-ln x * x^(k+r)) * (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y^(k+s)) \<partial>lborel)"
         by (subst nn_integral_cmult [symmetric])
            (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult'')
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (y^(k+s)) \<partial>lborel) = ennreal (1/(k+s+1))"
         by (subst nn_integral_0_1_power) simp
       also have "ennreal (-ln x * x^(k+r)) * \<dots> = ennreal (-ln x * x^(k+r) / (k+s+1))"
         by (subst ennreal_mult'' [symmetric]) auto
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * x^(k+r) * y^(k+s)) \<partial>lborel) =
                    ennreal (x^(k+r)) * (\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y^(k+s)) \<partial>lborel)"
         by (subst nn_integral_cmult [symmetric])
            (use x in \<open>auto intro!: nn_integral_cong simp: indicator_def mult_ac simp flip: ennreal_mult'\<close>)
       also have "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln y * y^(k+s)) \<partial>lborel) = ennreal (1 / (k + s + 1)\<^sup>2)"
         by (subst nn_integral_0_1_ln_times_power) simp
       also have "ennreal (x ^ (k + r)) * \<dots> = ennreal (x ^ (k + r) / (k + s + 1) ^ 2)"
         by (subst ennreal_mult'' [symmetric]) auto
       also have "ennreal (- ln x * x ^ (k + r) / (k + s + 1)) + \<dots> =
                    ennreal (-ln x * x^(k+r) / (k+s+1) + x^(k+r)/(k+s+1)^2)"
         using x by (subst ennreal_plus) (auto simp: mult_nonpos_nonneg divide_nonpos_nonneg)
       finally show "(\<integral>\<^sup>+y\<in>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) =
                       ennreal (-ln x * x^(k+r) / (k+s+1) + x^(k+r)/(k+s+1)^2)" .
     qed
     also have "\<dots> = (\<integral>\<^sup>+x\<in>{0<..<1}. (ennreal (-ln x * x^(k+r) / (k+s+1)) +
                        ennreal (x^(k+r)/(k+s+1)^2)) \<partial>lborel)"
       by (intro set_nn_integral_cong refl, subst ennreal_plus)
          (auto simp: mult_nonpos_nonneg divide_nonpos_nonneg)
     also have "\<dots> = (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r) / (k+s+1)) \<partial>lborel) +
                     (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (x^(k+r)/(k+s+1)^2) \<partial>lborel)"
       by (subst nn_integral_add [symmetric]) (auto intro!: nn_integral_cong simp: indicator_def)
     also have "(\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r) / (k+s+1)) \<partial>lborel) =
                   ennreal (1 / (k+s+1)) * (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (-ln x * x^(k+r)) \<partial>lborel)"
       by (subst nn_integral_cmult [symmetric])
          (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
     also have "\<dots> = ennreal (1 / ((k+s+1) * (k+r+1)^2))"
       by (subst nn_integral_0_1_ln_times_power, subst ennreal_mult [symmetric]) (auto simp: algebra_simps)
     also have "(\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (x^(k+r)/(k+s+1)^2) \<partial>lborel) =
                   ennreal (1/(k+s+1)^2) * (\<integral>\<^sup>+x\<in>{0<..<1}. ennreal (x^(k+r)) \<partial>lborel)"
       by (subst nn_integral_cmult [symmetric])
          (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
     also have "\<dots> = ennreal (1/((k+r+1)*(k+s+1)^2))"
       by (subst nn_integral_0_1_power, subst ennreal_mult [symmetric]) (auto simp: algebra_simps)
     also have "ennreal (1 / ((k+s+1) * (k+r+1)^2)) + \<dots> =
                  ennreal (1/((k+r+1)^2*(k+s+1)) + 1/((k+r+1)*(k+s+1)^2))"
       by (subst ennreal_plus [symmetric]) (auto simp: algebra_simps)
     finally show "(\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (-ln (x*y) * x^(k+r) * y^(k+s)) \<partial>lborel) = \<dots>" .
   qed
   finally show ?thesis .
 qed
 
 text \<open>
   Remembering that $\zeta(3) = \sum k^{-3}$, it is easy to see that if $r = s$, this sum is simply
     \[2\left(\zeta(3) - \sum_{k=1}^r \frac{1}{k^3}\right)\ .\]
 \<close>
 lemma beukers_nn_integral1_same:
   assumes "r = s"
   shows   "beukers_nn_integral1 r s = ennreal (2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)))"
     and   "2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)) \<ge> 0"
 proof -
   from assms have [simp]: "s = r" by simp
   have *: "Suc 2 = 3" by simp
   have "beukers_nn_integral1 r s = (\<Sum>k. ennreal (2 / (r + k + 1) ^ 3))"
     unfolding beukers_nn_integral1_series
     by (simp only: assms power_Suc [symmetric] mult.commute[of "x ^ 2" for x] *
                    times_divide_eq_right mult_1_right add_ac flip: mult_2)
   also have **: "(\<lambda>k. 2 / (r + k + 1) ^ 3) sums
               (2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)))"
     using sums_mult[OF sums_Re_zeta_of_nat_offset[of 3], of 2] by simp
   hence "(\<Sum>k. ennreal (2 / (r + k + 1) ^ 3)) = ennreal \<dots>"
     by (intro suminf_ennreal_eq) auto
   finally show "beukers_nn_integral1 r s = ennreal (2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)))" .
   show "2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3)) \<ge> 0"
     by (rule sums_le[OF _ sums_zero **]) auto
 qed
 
 lemma beukers_integral1_same:
   assumes "r = s"
   shows   "beukers_integral1 r s = 2 * (Re (zeta 3) - (\<Sum>k=1..r. 1 / k ^ 3))"
 proof -
   have "ln (a * b) * a ^ r * b ^ s / (1 - a * b) \<le> 0" if "a \<in> {0<..<1}" "b \<in> {0<..<1}" for a b :: real
     using that mult_strict_mono[of a 1 b 1] by (intro mult_nonpos_nonneg divide_nonpos_nonneg) auto
   thus ?thesis
     using beukers_nn_integral1_same[OF assms]
     unfolding beukers_nn_integral1_def beukers_integral1_def
     by (intro set_integral_eq_nn_integral AE_I2)
        (auto simp flip: lborel_prod simp: case_prod_unfold set_borel_measurable_def
              intro: divide_nonpos_nonneg mult_nonpos_nonneg)
 qed
 
 text \<open>
   In contrast, for \<open>r > s\<close>, we find that
     \[I_1 = \frac{1}{r-s} \sum_{k=s+1}^r \frac{1}{k^2}\ .\]
 \<close>
 lemma beukers_nn_integral1_different:
   assumes "r > s"
   shows   "beukers_nn_integral1 r s = ennreal ((\<Sum>k\<in>{s<..r}. 1 / k ^ 2) / (r - s))"
 proof -
   have "(\<lambda>k. 1 / (r - s) * (1 / (s + k + 1) ^ 2 - 1 / (r + k + 1) ^ 2))
           sums (1 / (r - s) * ((Re (zeta (of_nat 2)) - (\<Sum>k=1..s. 1/k^2)) -
                                (Re (zeta (of_nat 2)) - (\<Sum>k=1..r. 1/k^2))))"
     (is "_ sums ?S") by (intro sums_mult sums_diff sums_Re_zeta_of_nat_offset) auto
   also have "?S = ((\<Sum>k=1..r. 1/k^2) - (\<Sum>k=1..s. 1/k^2)) / (r - s)"
     by (simp add: algebra_simps diff_divide_distrib)
   also have "(\<Sum>k=1..r. 1/k^2) - (\<Sum>k=1..s. 1/k^2) = (\<Sum>k\<in>{1..r}-{1..s}. 1/k^2)"
     using assms by (subst Groups_Big.sum_diff) auto
   also have "{1..r} - {1..s} = {s<..r}" by auto
 
   also have "(\<lambda>k. 1 / (r - s) * (1 / (s + k + 1) ^ 2 - 1 / (r + k + 1) ^ 2)) =
                (\<lambda>k. 1 / ((k+r+1) * (k+s+1)^2) + 1 / ((k+r+1)^2 * (k+s+1)))"
   proof (intro ext, goal_cases)
     case (1 k)
     define x where "x = real (k + r + 1)"
     define y where "y = real (k + s + 1)"
     have [simp]: "x \<noteq> 0" "y \<noteq> 0" by (auto simp: x_def y_def)
     have "(x\<^sup>2 * y + x * y\<^sup>2) * (real r - real s) = x * y * (x\<^sup>2 - y\<^sup>2)"
       by (simp add: algebra_simps power2_eq_square x_def y_def)
     hence "1 / (x*y^2) + 1 / (x^2*y) = 1 / (r - s) * (1 / y^2 - 1 / x^2)"
       using assms by (simp add: divide_simps of_nat_diff)
     thus ?case by (simp add: x_def y_def algebra_simps)
   qed
   finally show ?thesis
     unfolding beukers_nn_integral1_series by (intro suminf_ennreal_eq) (auto simp: add_ac)
 qed
 
 lemma beukers_integral1_different:
   assumes "r > s"
   shows   "beukers_integral1 r s = (\<Sum>k\<in>{s<..r}. 1 / k ^ 2) / (r - s)"
 proof -
   have "ln (a * b) * a ^ r * b ^ s / (1 - a * b) \<le> 0" if "a \<in> {0<..<1}" "b \<in> {0<..<1}" for a b :: real
     using that mult_strict_mono[of a 1 b 1] by (intro mult_nonpos_nonneg divide_nonpos_nonneg) auto
     thus ?thesis
     using beukers_nn_integral1_different[OF assms]
     unfolding beukers_nn_integral1_def beukers_integral1_def
     by (intro set_integral_eq_nn_integral AE_I2)
        (auto simp flip: lborel_prod simp: case_prod_unfold set_borel_measurable_def
              intro: divide_nonpos_nonneg mult_nonpos_nonneg intro!: sum_nonneg divide_nonneg_nonneg)
 qed
 
 end
 
 text \<open>
   It is also easy to see that if we exchange \<open>r\<close> and \<open>s\<close>, nothing changes.
 \<close>
 lemma beukers_nn_integral1_swap:
   "beukers_nn_integral1 r s = beukers_nn_integral1 s r"
   unfolding beukers_nn_integral1_def lborel_prod [symmetric]
   by (subst lborel_pair.nn_integral_swap, simp)
      (intro nn_integral_cong, auto simp: indicator_def algebra_simps split: if_splits)
 
 lemma beukers_nn_integral1_finite: "beukers_nn_integral1 r s < \<infinity>"
   using beukers_nn_integral1_different[of r s] beukers_nn_integral1_different[of s r]
   by (cases r s rule: linorder_cases)
      (simp_all add: beukers_nn_integral1_same beukers_nn_integral1_swap)
 
 lemma beukers_integral1_integrable:
   "set_integrable lborel ({0<..<1}\<times>{0<..<1})
      (\<lambda>(x,y). (-ln (x*y) / (1 - x*y) * x^r * y^s :: real))"
 proof (intro set_integrableI_nonneg AE_I2; clarify?)
   fix x y :: real assume xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
   have "0 \<ge> ln (x * y) / (1 - x * y) * x ^ r * y ^ s"
     using mult_strict_mono[of x 1 y 1]
     by (intro mult_nonpos_nonneg divide_nonpos_nonneg) (use xy in auto)
   thus "0 \<le> - ln (x * y) / (1 - x * y) * x ^ r * y ^ s" by simp
 next
   show "\<integral>\<^sup>+x\<in>{0<..<1}\<times>{0<..<1}. ennreal (case x of (x, y) \<Rightarrow>
            - ln (x * y) / (1 - x * y) * x ^ r * y ^ s) \<partial>lborel < \<infinity>"
     using beukers_nn_integral1_finite by (simp add: beukers_nn_integral1_def case_prod_unfold)
 qed (simp_all flip: lborel_prod add: set_borel_measurable_def)
 
 lemma beukers_integral1_integrable':
   "set_integrable lborel ({0<..<1}\<times>{0<..<1}\<times>{0<..<1})
      (\<lambda>(z,x,y). (x^r * y^s / (1 - (1 - x*y) * z) :: real))"
 proof (intro set_integrableI_nonneg AE_I2; clarify?)
   fix x y z :: real assume xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0<..<1}"
   show "0 \<le> x^r * y^s / (1 - (1 - x*y) * z)"
     using mult_strict_mono[of x 1 y 1] xyz beukers_denom_ineq[of x y z]
     by (intro mult_nonneg_nonneg divide_nonneg_nonneg) auto
 next
   show "\<integral>\<^sup>+x\<in>{0<..<1}\<times>{0<..<1}\<times>{0<..<1}. ennreal (case x of (z,x,y) \<Rightarrow>
            x ^ r * y ^ s / (1-(1-x*y)*z)) \<partial>lborel < \<infinity>"
     using beukers_nn_integral1_finite
     by (simp add: beukers_nn_integral1_altdef case_prod_unfold)
 qed (simp_all flip: lborel_prod add: set_borel_measurable_def)
 
 lemma beukers_integral1_conv_nn_integral:
   "beukers_integral1 r s = enn2real (beukers_nn_integral1 r s)"
 proof -
   have "ln (a * b) * a ^ r * b ^ s / (1 - a * b) \<le> 0" if "a \<in> {0<..<1}" "b \<in> {0<..<1}"
     for a b :: real
     using mult_strict_mono[of a 1 b 1] that by (intro divide_nonpos_nonneg mult_nonpos_nonneg) auto
   thus ?thesis unfolding beukers_integral1_def using beukers_nn_integral1_finite[of r s]
     by (intro set_integral_eq_nn_integral)
        (auto simp: case_prod_unfold beukers_nn_integral1_def
                    set_borel_measurable_def simp flip: borel_prod
              intro!: AE_I2 intro: divide_nonpos_nonneg mult_nonpos_nonneg)
 qed
 
 lemma beukers_integral1_swap: "beukers_integral1 r s = beukers_integral1 s r"
   by (simp add: beukers_integral1_conv_nn_integral beukers_nn_integral1_swap)
 
 
 subsection \<open>The second double integral\<close>
 
 context
   fixes n :: nat
   fixes D :: "(real \<times> real) set" and D' :: "(real \<times> real \<times> real) set"
   fixes P :: "real \<Rightarrow> real" and Q :: "nat \<Rightarrow> real \<Rightarrow> real"
   defines "D \<equiv> {0<..<1} \<times> {0<..<1}" and "D' \<equiv> {0<..<1} \<times> {0<..<1} \<times> {0<..<1}"
   defines "Q \<equiv> Gen_Shleg n" and "P \<equiv> Shleg n"
 begin
 
 text \<open>
   The next integral to consider is the following variant of $I_1$:
   \[I_2 :=
       \int_0^1 \int_0^1 -\frac{\ln(xy)}{1-xy} P_n(x) P_n(y)\,\text{d}x\,\text{d}y\ .\]
 \<close>
 
 definition beukers_integral2 :: real where
   "beukers_integral2 = (\<integral>(x,y)\<in>D. (-ln (x*y) / (1-x*y) * P x * P y) \<partial>lborel)"
 
 text \<open>
   $I_2$ is simply a sum of integrals of type $I_1$, so using our results for
   $I_1$, we can write $I_2$ in the form $A \zeta(3) + \frac{B}{\text{lcm}\{1\ldots n\}^3}$
   where $A$ and $B$ are integers and $A > 0$:
 \<close>
 lemma beukers_integral2_conv_int_combination:
   obtains A B :: int where "A > 0" and
     "beukers_integral2 = of_int A * Re (zeta 3) + of_int B / of_nat (Lcm {1..n} ^ 3)"
 proof -
   let ?I1 = "(\<lambda>i. (i, i)) ` {..n}"
   let ?I2 = "Set.filter (\<lambda>(i,j). i \<noteq> j) ({..n}\<times>{..n})"
   let ?I3 = "Set.filter (\<lambda>(i,j). i < j) ({..n}\<times>{..n})"
   let ?I4 = "Set.filter (\<lambda>(i,j). i > j) ({..n}\<times>{..n})"
   define p where "p = shleg_poly n"
   define I where "I = (SIGMA i:{..n}. {1..i})"
   define J where "J = (SIGMA (i,j):?I4. {j<..i})"
   define h where "h = beukers_integral1"
   define A :: int where "A = (\<Sum>i\<le>n. 2 * poly.coeff p i ^ 2)"
   define B1 where "B1 = (\<Sum>(i,k)\<in>I. real_of_int (-2 * coeff p i ^ 2) / real_of_int (k ^ 3))"
   define B2 where "B2 = (\<Sum>((i,j),k)\<in>J. real_of_int (2 * coeff p i * coeff p j) / real_of_int (k^2*(i-j)))"
   define d where "d = Lcm {1..n} ^ 3"
 
   have [simp]: "h i j = h j i" for i j
     by (simp add: h_def beukers_integral1_swap)
 
   have "beukers_integral2 =
         (\<integral>(x,y)\<in>D. (\<Sum>(i,j)\<in>{..n}\<times>{..n}. coeff p i * coeff p j *
            -ln (x*y) / (1-x*y) * x ^ i * y ^ j) \<partial>lborel)"
     unfolding beukers_integral2_def
     by (subst sum.cartesian_product [symmetric])
        (simp add: poly_altdef P_def Shleg_def mult_ac case_prod_unfold p_def
                   sum_distrib_left sum_distrib_right sum_negf sum_divide_distrib)
   also have "\<dots> = (\<Sum>(i,j)\<in>{..n}\<times>{..n}. coeff p i * coeff p j * h i j)"
     unfolding case_prod_unfold
   proof (subst set_integral_sum)
     fix ij :: "nat \<times> nat"
     have "set_integrable lborel D
           (\<lambda>(x,y). real_of_int (coeff p (fst ij) * coeff p (snd ij)) *
                  (-ln (x*y) / (1-x*y) * x ^ fst ij * y ^ snd ij))"
       unfolding case_prod_unfold using beukers_integral1_integrable[of "fst ij" "snd ij"]
       by (intro set_integrable_mult_right) (auto simp: D_def case_prod_unfold)
     thus "set_integrable lborel D
           (\<lambda>pa. real_of_int (coeff p (fst ij) * coeff p (snd ij)) *
                  -ln (fst pa * snd pa) / (1 - fst pa * snd pa) * fst pa ^ fst ij * snd pa ^ snd ij)"
       by (simp add: mult_ac case_prod_unfold)
   qed (auto simp: beukers_integral1_def h_def case_prod_unfold mult.assoc D_def
             simp flip: set_integral_mult_right)
   also have "\<dots> = (\<Sum>(i,j)\<in>?I1\<union>?I2. coeff p i * coeff p j * h i j)"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>(i,j)\<in>?I1. coeff p i * coeff p j * h i j) +
                   (\<Sum>(i,j)\<in>?I2. coeff p i * coeff p j * h i j)"
     by (intro sum.union_disjoint) auto
   also have "(\<Sum>(i,j)\<in>?I1. coeff p i * coeff p j * h i j) =
                (\<Sum>i\<le>n. coeff p i ^ 2 * h i i)"
     by (subst sum.reindex) (auto intro: inj_onI simp: case_prod_unfold power2_eq_square)
   also have "\<dots> = (\<Sum>i\<le>n. coeff p i ^ 2 * 2 * (Re (zeta 3) - (\<Sum>k=1..i. 1 / k ^ 3)))"
     unfolding h_def D_def
     by (intro sum.cong refl, subst beukers_integral1_same) auto
   also have "\<dots> = of_int A * Re (zeta 3) -
                     (\<Sum>i\<le>n. 2 * coeff p i ^ 2 * (\<Sum>k=1..i. 1 / k ^ 3))"
     by (simp add: sum_subtractf sum_distrib_left sum_distrib_right algebra_simps A_def)
   also have "\<dots> = of_int A * Re (zeta 3) + B1"
     unfolding I_def B1_def by (subst sum.Sigma [symmetric]) (auto simp: sum_distrib_left sum_negf)
   also have "(\<Sum>(i,j)\<in>?I2. coeff p i * coeff p j * h i j) =
                (\<Sum>(i,j)\<in>?I3\<union>?I4. coeff p i * coeff p j * h i j)"
     by (intro sum.cong) auto
   also have "\<dots> = (\<Sum>(i,j)\<in>?I3. coeff p i * coeff p j * h i j) +
                   (\<Sum>(i,j)\<in>?I4. coeff p i * coeff p j * h i j)"
     by (intro sum.union_disjoint) auto
   also have "(\<Sum>(i,j)\<in>?I3. coeff p i * coeff p j * h i j) =
                (\<Sum>(i,j)\<in>?I4. coeff p i * coeff p j * h i j)"
     by (intro sum.reindex_bij_witness[of _ "\<lambda>(i,j). (j,i)" "\<lambda>(i,j). (j,i)"]) auto
   also have "\<dots> + \<dots> = 2 * \<dots>" by simp
   also have "\<dots> = (\<Sum>(i,j)\<in>?I4. \<Sum>k\<in>{j<..i}. 2 * coeff p i * coeff p j / k ^ 2 / (i - j))"
     unfolding sum_distrib_left
     by (intro sum.cong refl)
        (auto simp: h_def beukers_integral1_different sum_divide_distrib sum_distrib_left mult_ac)
   also have "\<dots> = B2"
     unfolding J_def B2_def by (subst sum.Sigma [symmetric]) (auto simp: case_prod_unfold)
 
   also have "\<exists>B1'. B1 = real_of_int B1' / real_of_int d"
     unfolding B1_def case_prod_unfold
     by (rule sum_rationals_common_divisor') (auto simp: d_def I_def)
   then obtain B1' where "B1 = real_of_int B1' / real_of_int d" ..
 
   also have "\<exists>B2'. B2 = real_of_int B2' / real_of_int d"
     unfolding B2_def case_prod_unfold J_def
   proof (rule sum_rationals_common_divisor'; clarsimp?)
     fix i j k :: nat assume ijk: "i \<le> n" "j < k" "k \<le> i"
     have "int (k ^ 2 * (i - j)) dvd int (Lcm {1..n} ^ 2 * Lcm {1..n})"
       unfolding int_dvd_int_iff using ijk
       by (intro mult_dvd_mono dvd_power_same dvd_Lcm) auto
     also have "\<dots> = d"
       by (simp add: d_def power_numeral_reduce)
     finally show "int k ^ 2 * int (i - j) dvd int d" by simp
   qed(auto simp: d_def J_def intro!: Nat.gr0I)
   then obtain B2' where "B2 = real_of_int B2' / real_of_int d" ..
 
   finally have "beukers_integral2 =
                   of_int A * Re (zeta 3) + of_int (B1' + B2') / of_nat (Lcm {1..n} ^ 3)"
     by (simp add: add_divide_distrib d_def)
 
   moreover have "coeff p 0 = P 0"
     unfolding P_def p_def Shleg_def by (simp add: poly_0_coeff_0)
   hence "coeff p 0 = 1"
     by (simp add: P_def)
   hence "A > 0"
     unfolding A_def by (intro sum_pos2[of _ 0]) auto
 
   ultimately show ?thesis
     by (intro that[of A "B1' + B2'"]) auto
 qed
 
 lemma beukers_integral2_integrable:
   "set_integrable lborel D (\<lambda>(x,y). -ln (x*y) / (1 - x*y) * P x * P y)"
 proof -
   have "bounded (P ` {0..1})"
     unfolding P_def Shleg_def
     by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   have [measurable]: "P \<in> borel_measurable borel" by (simp add: P_def)
   from C[of 0] have "C \<ge> 0" by simp
   show ?thesis
   proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
     show "set_integrable lborel D (\<lambda>(x,y). C ^ 2 * (-ln (x*y) / (1 - x*y)))"
       using beukers_integral1_integrable[of 0 0] unfolding case_prod_unfold
       by (intro set_integrable_mult_right) (auto simp: D_def)
   next
     fix x y :: real
     assume xy: "(x, y) \<in> D"
     from xy have "x * y < 1"
       using mult_strict_mono[of x 1 y 1] by (simp add: D_def)
     have "norm (-ln (x*y) / (1 - x*y) * P x * P y) = (-ln (x*y)) / (1 - x*y) * norm (P x) * norm (P y)"
       using xy \<open>x * y < 1\<close> by (simp add: abs_mult abs_divide D_def)
     also have "\<dots> \<le> (-ln (x*y)) / (1-x*y) * C * C"
       using xy C[of x] C[of y] \<open>x * y < 1\<close> \<open>C \<ge> 0\<close>
       by (intro mult_mono divide_left_mono)
          (auto simp: D_def divide_nonpos_nonneg mult_nonpos_nonneg)
     also have "\<dots> = norm ((-ln (x*y)) / (1-x*y) * C * C)"
       using xy \<open>x * y < 1\<close> \<open>C \<ge> 0\<close> by (simp add: abs_divide abs_mult D_def)
     finally show "norm (-ln (x*y) / (1 - x*y) * P x * P y)
            \<le> norm (case (x, y) of (x, y) \<Rightarrow> C\<^sup>2 * (- ln (x * y) / (1 - x * y)))"
       by (auto simp: algebra_simps power2_eq_square abs_mult abs_divide)
   qed (auto simp: D_def set_borel_measurable_def case_prod_unfold simp flip: lborel_prod)
 qed
 
 
 subsection \<open>The triple integral\<close>
 
 text \<open>
   Lastly, we turn to the triple integral
   \[I_3 := \int_0^1 \int_0^1 \int_0^1
       \frac{(x(1-x)y(1-y)w(1-w))^n}{(1-(1-xy)w)^{n+1}}\ \text{d}x\,\text{d}y\,\text{d}w\ .\]
 \<close>
 
 definition beukers_nn_integral3 :: ennreal where
   "beukers_nn_integral3 =
      (\<integral>\<^sup>+(w,x,y)\<in>D'. ((x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1)) \<partial>lborel)"
 
 definition beukers_integral3 :: real where
   "beukers_integral3 =
      (\<integral>(w,x,y)\<in>D'. ((x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1)) \<partial>lborel)"
 
 text \<open>
   We first prove the following bound
   (which is a consequence of the arithmetic--geometric mean inequality)
   that will help us to bound the triple integral.
 \<close>
 lemma beukers_integral3_integrand_bound:
   fixes x y z :: real
   assumes xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0<..<1}"
   shows   "(x*(1-x)*y*(1-y)*z*(1-z)) / (1-(1-x*y)*z) \<le> 1 / 27" (is "?lhs \<le> _")
 proof -
   have ineq1: "x * (1 - x) \<le> 1 / 4" if x: "x \<in> {0..1}" for x :: real
   proof -
     have "x * (1 - x) - 1 / 4 = -((x - 1 / 2) ^ 2)"
       by (simp add: algebra_simps power2_eq_square)
     also have "\<dots> \<le> 0"
       by simp
     finally show ?thesis by simp
   qed
 
   have ineq2: "x * (1 - x) ^ 2 \<le> 4 / 27" if x: "x \<in> {0..1}" for x :: real
   proof -
     have "x * (1 - x) ^ 2 - 4 / 27 = (x - 4 / 3) * (x - 1 / 3) ^ 2"
       by (simp add: algebra_simps power2_eq_square)
     also have "\<dots> \<le> 0"
       by (rule mult_nonpos_nonneg) (use x in auto)
     finally show ?thesis by simp
   qed
 
   have "1 - (1-x*y)*z = (1 - z) + x * y * z"
     by (simp add: algebra_simps)
   also have "\<dots> \<ge> 2 * sqrt (1 - z) * sqrt x * sqrt y * sqrt z"
     using arith_geo_mean_sqrt[of "1 - z" "x * y * z"] xyz
     by (auto simp: real_sqrt_mult)
 
   finally have *: "?lhs \<le> (x*(1-x)*y*(1-y)*z*(1-z)) / (2 * sqrt (1 - z) * sqrt x * sqrt y * sqrt z)"
     using xyz beukers_denom_ineq[of x y z]
     by (intro divide_left_mono mult_nonneg_nonneg mult_pos_pos) auto
 
   have "(x*(1-x)*y*(1-y)*z*(1-z)) = (sqrt x * sqrt x * (1-x) * sqrt y * sqrt y *
                (1-y) * sqrt z * sqrt z * sqrt (1-z) * sqrt (1-z))"
     using xyz by simp
   also have "\<dots> / (2 * sqrt (1 - z) * sqrt x * sqrt y * sqrt z) =
                sqrt (x * (1 - x) ^ 2) * sqrt (y * (1 - y) ^ 2) * sqrt (z * (1 - z)) / 2"
     using xyz by (simp add: divide_simps real_sqrt_mult del: real_sqrt_mult_self)
   also have "\<dots> \<le> sqrt (4 / 27) * sqrt (4 / 27) * sqrt (1 / 4) / 2"
     using xyz by (intro divide_right_mono mult_mono real_sqrt_le_mono ineq1 ineq2) auto
   also have "\<dots> = 1 / 27"
     by (simp add: real_sqrt_divide)
   finally show ?thesis using * by argo
 qed
 
 text \<open>
   Connecting the above bound with our results of $I_1$, it is easy to see that
   $I_3 \leq 2 \cdot 27^{-n} \cdot \zeta(3)$:
 \<close>
 lemma beukers_nn_integral3_le:
   "beukers_nn_integral3 \<le> ennreal (2 * (1 / 27) ^ n * Re (zeta 3))"
 proof -
   have D' [measurable]: "D' \<in> sets (borel \<Otimes>\<^sub>M borel \<Otimes>\<^sub>M borel)"
     unfolding D'_def by (simp flip: borel_prod)
   have "beukers_nn_integral3 =
           (\<integral>\<^sup>+(w,x,y)\<in>D'. ((x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1)) \<partial>lborel)"
     by (simp add: beukers_nn_integral3_def)
   also have "\<dots> \<le> (\<integral>\<^sup>+(w,x,y)\<in>D'. ((1 / 27) ^ n / (1-(1-x*y)*w)) \<partial>lborel)"
   proof (intro set_nn_integral_mono ennreal_leI, clarify, goal_cases)
     case (1 w x y)
     have "(x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1) =
             ((x*(1-x)*y*(1-y)*w*(1-w)) / (1-(1-x*y)*w)) ^ n / (1-(1-x*y)*w)"
       by (simp add: divide_simps)
     also have "\<dots> \<le> (1 / 27) ^ n / (1 - (1 - x * y) * w)"
       using beukers_denom_ineq[of x y w] 1
       by (intro divide_right_mono power_mono beukers_integral3_integrand_bound)
          (auto simp: D'_def)
     finally show ?case .
   qed
   also have "\<dots> = ennreal ((1 / 27) ^ n) * (\<integral>\<^sup>+(w,x,y)\<in>D'. (1 / (1-(1-x*y)*w)) \<partial>lborel)"
     unfolding lborel_prod [symmetric] case_prod_unfold
     by (subst nn_integral_cmult [symmetric])
        (auto intro!: nn_integral_cong simp: indicator_def simp flip: ennreal_mult')
   also have "(\<integral>\<^sup>+(w,x,y)\<in>D'. (1 / (1-(1-x*y)*w)) \<partial>lborel) =
                (\<integral>\<^sup>+(x,y)\<in>{0<..<1}\<times>{0<..<1}. ennreal (- (ln (x * y) / (1 - x * y))) \<partial>lborel)"
     using beukers_nn_integral1_altdef[of 0 0]
     by (simp add: beukers_nn_integral1_def D'_def case_prod_unfold)
   also have "\<dots> = ennreal (2 * Re (zeta 3))"
     using beukers_nn_integral1_same[of 0 0] by (simp add: D_def beukers_nn_integral1_def)
   also have "ennreal ((1 / 27) ^ n) * \<dots> = ennreal (2 * (1 / 27) ^ n * Re (zeta 3))"
     by (subst ennreal_mult' [symmetric]) (simp_all add: mult_ac)
   finally show ?thesis .
 qed
 
 lemma beukers_nn_integral3_finite: "beukers_nn_integral3 < \<infinity>"
   by (rule le_less_trans, rule beukers_nn_integral3_le) simp_all
 
 lemma beukers_integral3_integrable:
   "set_integrable lborel D' (\<lambda>(w,x,y). (x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1))"
   unfolding case_prod_unfold using less_imp_le[OF beukers_denom_ineq] beukers_nn_integral3_finite
   by (intro set_integrableI_nonneg AE_I2 impI)
      (auto simp: D'_def set_borel_measurable_def beukers_nn_integral3_def case_prod_unfold
            simp flip: lborel_prod intro!: divide_nonneg_nonneg mult_nonneg_nonneg)
 
 lemma beukers_integral3_conv_nn_integral:
   "beukers_integral3 = enn2real beukers_nn_integral3"
   unfolding beukers_integral3_def using beukers_nn_integral3_finite less_imp_le[OF beukers_denom_ineq]
   by (intro set_integral_eq_nn_integral AE_I2 impI)
      (auto simp: D'_def set_borel_measurable_def beukers_nn_integral3_def case_prod_unfold
            simp flip: lborel_prod)
 
 lemma beukers_integral3_le: "beukers_integral3 \<le> 2 * (1 / 27) ^ n * Re (zeta 3)"
 proof -
   have "beukers_integral3 = enn2real beukers_nn_integral3"
     by (rule beukers_integral3_conv_nn_integral)
   also have "\<dots> \<le> enn2real (ennreal (2 * (1 / 27) ^ n * Re (zeta 3)))"
     by (intro enn2real_mono beukers_nn_integral3_le) auto
   also have "\<dots> = 2 * (1 / 27) ^ n * Re (zeta 3)"
     using Re_zeta_ge_1[of 3] by (intro enn2real_ennreal mult_nonneg_nonneg) auto
   finally show ?thesis .
 qed
 
 text \<open>
   It is also easy to see that $I_3 > 0$.
 \<close>
 lemma beukers_nn_integral3_pos: "beukers_nn_integral3 > 0"
 proof -
   have D' [measurable]: "D' \<in> sets (borel \<Otimes>\<^sub>M borel \<Otimes>\<^sub>M borel)"
     unfolding D'_def by (simp flip: borel_prod)
 
   have *: "\<not>(AE (w,x,y) in lborel. ennreal ((x*(1-x)*y*(1-y)*w*(1-w))^n /
              (1-(1-x*y)*w)^(n+1)) * indicator D' (w,x,y) \<le> 0)"
             (is "\<not>(AE z in lborel. ?P z)")
   proof -
     {
       fix w x y :: real assume xyw: "(w,x,y) \<in> D'"
       hence "(x*(1-x)*y*(1-y)*w*(1-w))^n / (1-(1-x*y)*w)^(n+1) > 0"
         using beukers_denom_ineq[of x y w]
         by (intro divide_pos_pos mult_pos_pos zero_less_power) (auto simp: D'_def)
       with xyw have "\<not>?P (w,x,y)"
         by (auto simp: indicator_def D'_def)
     }
     hence *: "\<not>?P z" if "z \<in> D'" for z using that by blast
     hence "{z\<in>space lborel. \<not>?P z} = D'" by auto
     moreover have "emeasure lborel D' = 1"
     proof -
       have "D' = box (0,0,0) (1,1,1)"
         by (auto simp: D'_def box_def Basis_prod_def)
       also have "emeasure lborel \<dots> = 1"
         by (subst emeasure_lborel_box) (auto simp: Basis_prod_def)
       finally show ?thesis by simp
     qed
     ultimately show ?thesis
       by (subst AE_iff_measurable[of D']) (simp_all flip: borel_prod)
   qed
 
   hence "nn_integral lborel (\<lambda>_::real\<times>real\<times>real. 0) < beukers_nn_integral3"
     unfolding beukers_nn_integral3_def
     by (intro nn_integral_less) (simp_all add: case_prod_unfold flip: lborel_prod)
   thus ?thesis by simp
 qed
 
 lemma beukers_integral3_pos: "beukers_integral3 > 0"
 proof -
   have "0 < enn2real beukers_nn_integral3"
     using beukers_nn_integral3_pos beukers_nn_integral3_finite
     by (subst enn2real_positive_iff) auto
   also have "\<dots> = beukers_integral3"
     by (rule beukers_integral3_conv_nn_integral [symmetric])
   finally show ?thesis .
 qed
 
 
 subsection \<open>Connecting the double and triple integral\<close>
 
 text \<open>
   In this section, we will prove the most technically involved part,
   namely that $I_2 = I_3$. I will not go into detail about how this works --
   the reader is advised to simply look at Filaseta's presentation of the proof.
 
   The basic idea is to integrate by parts \<open>n\<close> times with respect to \<open>y\<close> to eliminate
   the factor $P(y)$, then change variables $z = \frac{1-w}{1-(1-xy)w}$, and then
   apply the same integration by parts \<open>n\<close> times to \<open>x\<close> to eliminate $P(x)$.
 \<close>
 
 text \<open>
   The first expand \[-\frac{\ln (xy)}{1-xy} = \int_0^1 \frac{1}{1-(1-xy)z}\,\text{d}z\ .\]
 \<close>
 lemma beukers_aux_ln_conv_integral:
   fixes x y :: real
   assumes xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
   shows "-ln (x*y) / (1-x*y) = (LBINT z=0..1. 1 / (1-(1-x*y)*z))"
 proof -
   have "x * y < 1"
     using mult_strict_mono[of x 1 y 1] xy by simp
   have less: "(1 - x * y) * u < 1" if u: "u \<in> {0..1}" for u
   proof -
     from u \<open>x * y < 1\<close> have "(1 - x * y) * u \<le> (1 - x * y) * 1"
       by (intro mult_left_mono) auto
     also have "\<dots> < 1 * 1"
       using xy by (intro mult_strict_right_mono) auto
     finally show "(1 - x * y) * u < 1" by simp
   qed
   have neq: "(1 - x * y) * u \<noteq> 1" if "u \<in> {0..1}" for u
     using less[of u] that by simp
 
   let ?F = "\<lambda>z. ln (1-(1-x*y)*z)/(x*y-1)"
   have "(LBINT z=ereal 0..ereal 1. 1 / (1-(1-x*y)*z)) = ?F 1 - ?F 0"
   proof (rule interval_integral_FTC_finite, goal_cases cont deriv)
     case cont
     show ?case
       using neq by (intro continuous_intros) auto
   next
     case (deriv z)
     show ?case
       unfolding has_real_derivative_iff_has_vector_derivative [symmetric]
       by (insert less[of z] xy \<open>x * y < 1\<close> deriv)
          (rule derivative_eq_intros refl | simp)+
   qed
   also have "\<dots> = -ln (x*y) / (1-x*y)"
     using \<open>x * y < 1\<close> by (simp add: field_simps)
   finally show ?thesis
     by (simp add: zero_ereal_def one_ereal_def)
 qed
 
 text \<open>
   The first part we shall show is the integration by parts.
 \<close>
 lemma beukers_aux_by_parts_aux:
   assumes xz: "x \<in> {0<..<1}" "z \<in> {0<..<1}" and "k \<le> n"
   shows "(LBINT y=0..1. Q n y * (1/(1-(1-x*y)*z))) =
          (LBINT y=0..1. Q (n-k) y * (fact k * (x*z)^k / (1-(1-x*y)*z) ^ (k+1)))"
   using assms(3)
 proof (induction k)
   case (Suc k)
   note [derivative_intros] = DERIV_chain2[OF has_field_derivative_Gen_Shleg]
   define G where "G = (\<lambda>y. -fact k * (x*z)^k / (1-(1-x*y)*z) ^ (k+1))"
   define g where "g = (\<lambda>y. fact (Suc k) * (x*z)^Suc k / (1-(1-x*y)*z) ^ (k+2))"
 
   have less: "(1 - x * y) * z < 1" and neq: "(1 - x * y) * z \<noteq> 1"
     if y: "y \<in> {0..1}" for y
   proof -
     from y xz have "x * y \<le> x * 1"
       by (intro mult_left_mono) auto
     also have "\<dots> < 1"
       using xz by simp
     finally have "(1 - x * y) * z \<le> 1 * z"
       using xz y by (intro mult_right_mono) auto
     also have "\<dots> < 1"
       using xz by simp
     finally show "(1 - x * y) * z < 1" by simp
     thus "(1 - x * y) * z \<noteq> 1" by simp
   qed
 
   have cont: "continuous_on {0..1} g"
     using neq by (auto simp: g_def intro!: continuous_intros)
   have deriv: "(G has_real_derivative g y) (at y within {0..1})" if y: "y \<in> {0..1}" for y
     unfolding G_def
     by (insert neq xz y, (rule derivative_eq_intros refl power_not_zero)+)
        (auto simp: divide_simps g_def)
   have deriv2: "(Q (n - Suc k) has_real_derivative Q (n - k) y) (at y within {0..1})" for y
     using Suc.prems by (auto intro!: derivative_eq_intros simp: Suc_diff_Suc Q_def)
 
   have "(LBINT y=0..1. Q (n-Suc k) y * (fact (Suc k) * (x*z)^Suc k / (1-(1-x*y)*z) ^ (k+2))) =
         (LBINT y=0..1. Q (n-Suc k) y * g y)"
     by (simp add: g_def)
   also have "(LBINT y=0..1. Q (n-Suc k) y * g y) = -(LBINT y=0..1. Q (n-k) y * G y)"
     using Suc.prems deriv deriv2 cont
     by (subst interval_lebesgue_integral_by_parts_01[where f = "Q (n-k)" and G = G])
        (auto intro!: continuous_intros simp: Q_def)
   also have "\<dots> = (LBINT y=0..1. Q (n-k) y * (fact k * (x*z)^k / (1-(1-x*y)*z) ^ (k+1)))"
     by (simp add: G_def flip: interval_lebesgue_integral_uminus)
   finally show ?case using Suc by simp
 qed auto
 
 lemma beukers_aux_by_parts:
   assumes xz: "x \<in> {0<..<1}" "z \<in> {0<..<1}"
   shows "(LBINT y=0..1. P y / (1-(1-x*y)*z)) =
          (LBINT y=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z) ^ (n+1))"
 proof -
   have "(LBINT y=0..1. P y * (1/(1-(1-x*y)*z))) =
            1 / fact n * (LBINT y=0..1. Q n y * (1/(1-(1-x*y)*z)))"
     unfolding interval_lebesgue_integral_mult_right [symmetric]
     by (simp add: P_def Q_def Shleg_altdef)
   also have "\<dots> = (LBINT y=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z) ^ (n+1))"
     by (subst beukers_aux_by_parts_aux[OF assms, of n], simp,
         subst interval_lebesgue_integral_mult_right [symmetric])
        (simp add: Q_def mult_ac Gen_Shleg_0_left power_mult_distrib)
   finally show ?thesis by simp
 qed
 
 text \<open>
   We then get the following by applying the integration by parts to \<open>y\<close>:
 \<close>
 lemma beukers_aux_integral_transform1:
   fixes z :: real
   assumes z: "z \<in> {0<..<1}"
   shows   "(LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)) =
            (LBINT (x,y):D. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
 proof -
   have cbox: "cbox (0, 0) (1, 1) = ({0..1} \<times> {0..1} :: (real \<times> real) set)"
     by (auto simp: cbox_def Basis_prod_def inner_prod_def)
   have box: "box (0, 0) (1, 1) = ({0<..<1} \<times> {0<..<1} :: (real \<times> real) set)"
     by (auto simp: box_def Basis_prod_def inner_prod_def)
   have "set_integrable lborel (cbox (0,0) (1,1))
           (\<lambda>(x, y). P x * P y / (1 - (1 - x * y) * z))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0, 0) (1, 1)"
     have "(1 - fst p * snd p) * z \<le> 1 * z"
       using mult_mono[of "fst p" 1 "snd p" 1] p z cbox by (intro mult_right_mono) auto
     also have "\<dots> < 1" using z by simp
     finally show "1 - (1 - fst p * snd p) * z \<noteq> 0" by simp
   qed
   hence integrable: "set_integrable lborel (box (0,0) (1,1))
           (\<lambda>(x, y). P x * P y / (1 - (1 - x * y) * z))"
     by (rule set_integrable_subset) (auto simp:  box simp flip: borel_prod)
 
   have "set_integrable lborel (cbox (0,0) (1,1))
           (\<lambda>(x, y). P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0, 0) (1, 1)"
     have "(1 - fst p * snd p) * z \<le> 1 * z"
       using mult_mono[of "fst p" 1 "snd p" 1] p z cbox by (intro mult_right_mono) auto
     also have "\<dots> < 1" using z by simp
     finally show "(1 - (1 - fst p * snd p) * z) ^ (n + 1) \<noteq> 0" by simp
   qed
   hence integrable': "set_integrable lborel D
           (\<lambda>(x, y). P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     by (rule set_integrable_subset) (auto simp: box D_def simp flip: borel_prod)
 
   have "(LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)) =
           (LBINT x=0..1. (LBINT y=0..1. P x * P y / (1-(1-x*y)*z)))"
     unfolding D_def lborel_prod [symmetric] using box integrable
     by (subst lborel_pair.set_integral_fst') (simp_all add: interval_integral_Ioo lborel_prod)
   also have "\<dots> = (LBINT x=0..1. P x * (LBINT y=0..1. P y / (1-(1-x*y)*z)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (simp add: mult_ac)
   also have "\<dots> = (LBINT x=0..1. P x * (LBINT y=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     using z by (intro interval_lebesgue_integral_lborel_01_cong, subst beukers_aux_by_parts) auto
   also have "\<dots> = (LBINT x=0..1. (LBINT y=0..1. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (simp add: mult_ac)
   also have "\<dots> = (LBINT (x,y):D. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     unfolding D_def lborel_prod [symmetric] using box integrable'
     by (subst lborel_pair.set_integral_fst')
        (simp_all add: D_def interval_integral_Ioo lborel_prod)
   finally show "(LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)) = \<dots>" .
 qed
 
 text \<open>
   We then change variables for \<open>z\<close>:
 \<close>
 lemma beukers_aux_integral_transform2:
   assumes xy: "x \<in> {0<..<1}" "y \<in> {0<..<1}"
   shows "(LBINT z=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
          (LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
 proof -
   define g where "g = (\<lambda>z. (1 - z) / (1-(1-x*y)*z))"
   define g' where "g' = (\<lambda>z. -x*y / (1-(1-x*y)*z)^2)"
   have "x * y < 1"
     using mult_strict_mono[of x 1 y 1] xy by simp
   have less: "(1 - (x * y)) * w < 1" and neq: "(1 - (x * y)) * w \<noteq> 1"
     if w: "w \<in> {0..1}" for w
   proof -
     have "(1 - (x * y)) * w \<le> (1 - (x * y)) * 1"
       using w \<open>x * y < 1\<close> by (intro mult_left_mono) auto
     also have "\<dots> < 1"
       using xy by simp
     finally show "(1 - (x * y)) * w < 1" .
     thus "(1 - (x * y)) * w \<noteq> 1" by simp
   qed
 
   have deriv: "(g has_real_derivative g' w) (at w within {0..1})" if "w \<in> {0..1}" for w
     unfolding g_def g'_def
     apply (insert that xy neq)
     apply (rule derivative_eq_intros refl)+
      apply (simp_all add: divide_simps power2_eq_square)
      apply (auto simp: algebra_simps)
     done
   have "continuous_on {0..1} (\<lambda>xa. (1 - xa) ^ n / (1 - (1 - x * y) * xa))"
     using neq by (auto intro!: continuous_intros)
   moreover have "g ` {0..1} \<subseteq> {0..1}"
   proof clarify
     fix w :: real assume w: "w \<in> {0..1}"
     have "(1 - x * y) * w \<le> 1 * w"
       using \<open>x * y < 1\<close> xy w by (intro mult_right_mono) auto
     thus "g w \<in> {0..1}"
       unfolding g_def using less[of w] w by (auto simp: divide_simps)
   qed
   ultimately have cont: "continuous_on (g ` {0..1}) (\<lambda>xa. (1 - xa) ^ n / (1 - (1 - x * y) * xa))"
     by (rule continuous_on_subset)
   have cont': "continuous_on {0..1} g'"
     using neq by (auto simp: g'_def intro!: continuous_intros)
 
   have "(LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w)) =
           (1-y)^n * (LBINT w=0..1. (1 - w)^n / (1-(1-x*y)*w))"
     unfolding interval_lebesgue_integral_mult_right [symmetric]
     by (simp add: algebra_simps power_mult_distrib)
   also have "(LBINT w=0..1. (1 - w)^n / (1-(1-x*y)*w)) =
         -(LBINT w=g 0..g 1. (1 - w)^n / (1-(1-x*y)*w))"
     by (subst interval_integral_endpoints_reverse)(simp add: g_def zero_ereal_def one_ereal_def)
   also have "(LBINT w=g 0..g 1. (1 - w)^n / (1-(1-x*y)*w)) =
              (LBINT w=0..1. g' w * ((1 - g w) ^ n / (1 - (1-x*y) * g w)))"
     using deriv cont cont'
     by (subst interval_integral_substitution_finite [symmetric, where g = g and g' = g'])
        (simp_all add: zero_ereal_def one_ereal_def)
   also have "-\<dots> = (LBINT z=0..1. ((x*y)^n * z^n / (1-(1-x*y)*z)^(n+1)))"
     unfolding interval_lebesgue_integral_uminus [symmetric] using xy
     apply (intro interval_lebesgue_integral_lborel_01_cong)
     apply (simp add: divide_simps g_def g'_def)
     apply (auto simp: algebra_simps power_mult_distrib power2_eq_square)
     done
   also have "(1-y)^n * \<dots> = (LBINT z=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
     unfolding interval_lebesgue_integral_mult_right [symmetric]
     by (simp add: algebra_simps power_mult_distrib)
   finally show "\<dots> = (LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w))" ..
 qed
 
 text \<open>
   Lastly, we apply the same integration by parts to \<open>x\<close>:
 \<close>
 lemma beukers_aux_integral_transform3:
   assumes w: "w \<in> {0<..<1}"
   shows   "(LBINT (x,y):D. P x * (1-y)^n / (1-(1-x*y)*w)) =
            (LBINT (x,y):D. (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
 proof -
   have cbox: "cbox (0, 0) (1, 1) = ({0..1} \<times> {0..1} :: (real \<times> real) set)"
     by (auto simp: cbox_def Basis_prod_def inner_prod_def)
   have box: "box (0, 0) (1, 1) = ({0<..<1} \<times> {0<..<1} :: (real \<times> real) set)"
     by (auto simp: box_def Basis_prod_def inner_prod_def)
 
   have "set_integrable lborel
           (cbox (0,0) (1,1)) (\<lambda>(x,y). P x * (1-y)^n/(1-(1-x*y)*w))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0,0) (1,1)"
     have "(1 - fst p * snd p) * w \<le> 1 * w"
       using p cbox w by (intro mult_right_mono) auto
     also have "\<dots> < 1" using w by simp
     finally have "(1 - fst p * snd p) * w < 1" by simp
     thus "1 - (1 - fst p * snd p) * w \<noteq> 0" by simp
   qed
   hence integrable: "set_integrable lborel D (\<lambda>(x,y). P x * (1-y)^n/(1-(1-x*y)*w))"
     by (rule set_integrable_subset) (auto simp: D_def simp flip: borel_prod)
 
   have "set_integrable lborel (cbox (0,0) (1,1))
           (\<lambda>(x,y). (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
     unfolding lborel_prod case_prod_unfold P_def
   proof (intro continuous_on_imp_set_integrable_cbox continuous_intros ballI)
     fix p :: "real \<times> real" assume p: "p \<in> cbox (0,0) (1,1)"
     have "(1 - fst p * snd p) * w \<le> 1 * w"
       using p cbox w by (intro mult_right_mono) auto
     also have "\<dots> < 1" using w by simp
     finally have "(1 - fst p * snd p) * w < 1" by simp
     thus "(1 - (1 - fst p * snd p) * w) ^ (n + 1) \<noteq> 0" by simp
   qed
   hence integrable': "set_integrable lborel D
                         (\<lambda>(x,y). (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
     by (rule set_integrable_subset) (auto simp: D_def simp flip: borel_prod)
 
   have "(LBINT (x,y):D. P x * (1-y)^n / (1-(1-x*y)*w)) =
           (LBINT y=0..1. (LBINT x=0..1. P x * (1-y)^n / (1-(1-x*y)*w)))"
     using integrable unfolding case_prod_unfold D_def lborel_prod [symmetric]
     by (subst lborel_pair.set_integral_snd) (auto simp: interval_integral_Ioo)
   also have "\<dots> = (LBINT y=0..1. (1-y)^n * (LBINT x=0..1. P x / (1-(1-y*x)*w)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (auto simp: mult_ac)
   also have "\<dots> = (LBINT y=0..1. (1-y)^n * (LBINT x=0..1. (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1)))"
     using w by (intro interval_lebesgue_integral_lborel_01_cong, subst beukers_aux_by_parts) (auto simp: mult_ac)
   also have "\<dots> = (LBINT y=0..1. (LBINT x=0..1.
                      (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1)))"
     by (subst interval_lebesgue_integral_mult_right [symmetric]) (auto simp: mult_ac)
   also have "\<dots> = (LBINT (x,y):D. (1-y)^n * (x*y*w)^n * (1-x)^n / (1-(1-x*y)*w)^(n+1))"
     using integrable' unfolding case_prod_unfold D_def lborel_prod [symmetric]
     by (subst lborel_pair.set_integral_snd) (auto simp: interval_integral_Ioo)
   finally show ?thesis .
 qed
 
 text \<open>
   We need to show the existence of some of these triple integrals.
 \<close>
 lemma beukers_aux_integrable1:
   "set_integrable lborel (({0<..<1} \<times> {0<..<1}) \<times> {0<..<1})
      (\<lambda>((x,y),z). P x * P y / (1-(1-x*y)*z))"
 proof -
   have D [measurable]: "D \<in> sets (borel \<Otimes>\<^sub>M borel)"
     unfolding D_def by (simp flip: borel_prod)
   have "bounded (P ` {0..1})"
     unfolding P_def by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   show ?thesis unfolding D'_def case_prod_unfold
   proof (subst lborel_prod [symmetric],
          intro lborel_pair.Fubini_set_integrable AE_I2 impI; clarsimp?)
     fix x y :: real
     assume xy: "x > 0" "x < 1" "y > 0" "y < 1"
     have "x * y < 1" using xy mult_strict_mono[of x 1 y 1] by simp
     show "set_integrable lborel {0<..<1} (\<lambda>z. P x * P y / (1-(1-x*y)*z))"
       by (rule set_integrable_subset[of _ "{0..1}"], rule borel_integrable_atLeastAtMost')
          (use \<open>x*y<1\<close> beukers_denom_neq[of x y] xy in \<open>auto intro!: continuous_intros simp: P_def\<close>)
   next
     have "set_integrable lborel D
              (\<lambda>(x,y). (\<integral>z\<in>{0<..<1}. norm (P x * P y / (1-(1-x*y)*z)) \<partial>lborel))"
     proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
       show "set_integrable lborel D (\<lambda>(x,y). C\<^sup>2 * (-ln (x*y) / (1 - x*y)))"
         using beukers_integral1_integrable[of 0 0]
         unfolding case_prod_unfold by (intro set_integrable_mult_right) (auto simp: D_def)
     next
       fix x y assume xy: "(x, y) \<in> D"
       have "norm (LBINT z:{0<..<1}. norm (P x * P y / (1-(1-x*y)*z))) =
               norm (LBINT z:{0<..<1}. \<bar>P x\<bar> * \<bar>P y\<bar> * (1 / (1-(1-x*y)*z)))"
       proof (intro arg_cong[where f = norm] set_lebesgue_integral_cong allI impI, goal_cases)
         case (2 z)
         with beukers_denom_ineq[of x y z] xy show ?case
           by (auto simp: abs_mult D_def)
       qed (auto simp: abs_mult D_def)
       also have "\<dots> = norm (\<bar>P x\<bar> * \<bar>P y\<bar> * (LBINT z=0..1. (1 / (1-(1-x*y)*z))))"
         by (subst set_integral_mult_right) (auto simp: interval_integral_Ioo)
       also have "\<dots> = norm (norm (P x) * norm (P y) * (- ln (x * y) / (1 - x * y)))"
         using beukers_aux_ln_conv_integral[of x y] xy by (simp add: D_def)
       also have "\<dots> = norm (P x) * norm (P y) * (- ln (x * y) / (1 - x * y))"
         using xy mult_strict_mono[of x 1 y 1]
         by (auto simp: D_def divide_nonpos_nonneg abs_mult)
       also have "norm (P x) * norm (P y) * (- ln (x * y) / (1 - x * y)) \<le>
                    norm (C * C * (- ln (x * y) / (1 - x * y)))"
         using xy C[of x] C[of y] mult_strict_mono[of x 1 y 1] unfolding norm_mult norm_divide
         by (intro mult_mono C) (auto simp: D_def divide_nonpos_nonneg)
       finally show "norm (LBINT z:{0<..<1}. norm (P x * P y / (1-(1-x*y)*z)))
            \<le> norm (case (x, y) of (x, y) \<Rightarrow> C\<^sup>2 * (- ln (x * y) / (1 - x * y)))"
         by (simp add: power2_eq_square mult_ac)
     next
       show "set_borel_measurable lborel D (\<lambda>(x, y).
               LBINT z:{0<..<1}. norm (P x * P y / (1 - (1 - x * y) * z)))"
         unfolding lborel_prod [symmetric] set_borel_measurable_def
                   case_prod_unfold set_lebesgue_integral_def P_def
         by measurable
     qed
     thus "set_integrable lborel ({0<..<1} \<times> {0<..<1})
             (\<lambda>x. LBINT y:{0<..<1}. \<bar>P (fst x) * P (snd x)\<bar> / \<bar>1 - (1 - fst x * snd x) * y\<bar>)"
       by (simp add: case_prod_unfold D_def)
   qed (auto simp: case_prod_unfold lborel_prod [symmetric] set_borel_measurable_def P_def)
 qed
 
 lemma beukers_aux_integrable2:
   "set_integrable lborel D' (\<lambda>(z,x,y). P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z) ^ (n+1))"
 proof -
   have [measurable]: "P \<in> borel_measurable borel" unfolding P_def
     by (intro borel_measurable_continuous_onI continuous_intros)
   have "bounded (P ` {0..1})"
     unfolding P_def by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   show ?thesis unfolding D'_def
   proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
     show "set_integrable lborel ({0<..<1} \<times> {0<..<1} \<times> {0<..<1})
             (\<lambda>(z,x,y). C * (1 / (1-(1-x*y)*z)))"
       unfolding case_prod_unfold
       using beukers_integral1_integrable'[of 0 0]
       by (intro set_integrable_mult_right) (auto simp: lborel_prod case_prod_unfold)
   next
     fix x y z :: real assume xyz: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "z \<in> {0<..<1}"
     have "norm (P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
             norm (P x) * (1-y)^n * ((x*y*z) / (1-(1-x*y)*z))^n / (1-(1-x*y)*z)"
       using xyz beukers_denom_ineq[of x y z] by (simp add: abs_mult power_divide mult_ac)
     also have "(x*y*z) / (1-(1-x*y)*z) = 1/((1-z)/(z*x*y)+1)"
       using xyz by (simp add: field_simps)
     also have "norm (P x) * (1-y)^n * \<dots>^n / (1-(1-x*y)*z) \<le>
                C * 1^n * 1^n / (1-(1-x*y)*z)"
       using xyz C[of x] beukers_denom_ineq[of x y z]
       by (intro mult_mono divide_right_mono power_mono zero_le_power mult_nonneg_nonneg divide_nonneg_nonneg)
          (auto simp: field_simps)
     also have "\<dots> \<le> \<bar>C * 1^n * 1^n / (1-(1-x*y)*z)\<bar>"
       by linarith
     finally show "norm (P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) \<le>
                     norm (case (z,x,y) of (z,x,y) \<Rightarrow> C * (1 / (1-(1-x*y)*z)))"
       by (simp add: case_prod_unfold)
   qed (simp_all add: case_prod_unfold set_borel_measurable_def flip: borel_prod)
 qed
 
 lemma beukers_aux_integrable3:
   "set_integrable lborel D' (\<lambda>(w,x,y). P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
 proof -
   have [measurable]: "P \<in> borel_measurable borel" unfolding P_def
     by (intro borel_measurable_continuous_onI continuous_intros)
   have "bounded (P ` {0..1})"
     unfolding P_def by (intro compact_imp_bounded compact_continuous_image continuous_intros) auto
   then obtain C where C: "\<And>x. x \<in> {0..1} \<Longrightarrow> norm (P x) \<le> C"
     unfolding bounded_iff by fast
   show ?thesis unfolding D'_def
   proof (rule set_integrable_bound[OF _ _ AE_I2]; clarify?)
     show "set_integrable lborel ({0<..<1} \<times> {0<..<1} \<times> {0<..<1})
             (\<lambda>(z,x,y). C * (1 / (1-(1-x*y)*z)))"
       unfolding case_prod_unfold
       using beukers_integral1_integrable'[of 0 0]
       by (intro set_integrable_mult_right) (auto simp: lborel_prod case_prod_unfold)
   next
     fix x y w :: real assume xyw: "x \<in> {0<..<1}" "y \<in> {0<..<1}" "w \<in> {0<..<1}"
     have "norm (P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)) =
             norm (P x) * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)"
       using xyw beukers_denom_ineq[of x y w] by (simp add: abs_mult power_divide mult_ac)
     also have "\<dots> \<le> C * 1^n * 1^n / (1-(1-x*y)*w)"
       using xyw C[of x] beukers_denom_ineq[of x y w]
       by (intro mult_mono divide_right_mono power_mono zero_le_power mult_nonneg_nonneg divide_nonneg_nonneg)
          (auto simp: field_simps)
     also have "\<dots> \<le> \<bar>C * 1^n * 1^n / (1-(1-x*y)*w)\<bar>"
       by linarith
     finally show "norm (P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)) \<le>
                     norm (case (w,x,y) of (z,x,y) \<Rightarrow> C * (1 / (1-(1-x*y)*z)))"
       by (simp add: case_prod_unfold)
   qed (simp_all add: case_prod_unfold set_borel_measurable_def flip: borel_prod)
 qed
 
 text \<open>
   Now we only need to put all of these results together:
 \<close>
 lemma beukers_integral2_conv_3: "beukers_integral2 = beukers_integral3"
 proof -
   have cont_P: "continuous_on {0..1} P"
     by (auto simp: P_def intro: continuous_intros)
   have D [measurable]: "D \<in> sets borel" "D \<in> sets (borel \<Otimes>\<^sub>M borel)"
     unfolding D_def by (simp_all flip: borel_prod)
   have [measurable]: "P \<in> borel_measurable borel" unfolding P_def
     by (intro borel_measurable_continuous_onI continuous_intros)
 
   have "beukers_integral2 = (LBINT (x,y):D. P x * P y * (LBINT z=0..1. 1 / (1-(1-x*y)*z)))"
     unfolding beukers_integral2_def case_prod_unfold
     by (intro set_lebesgue_integral_cong allI impI, measurable)
        (subst beukers_aux_ln_conv_integral, auto simp: D_def)
   also have "\<dots> = (LBINT (x,y):D. (LBINT z=0..1. P x * P y / (1-(1-x*y)*z)))"
       by (subst interval_lebesgue_integral_mult_right [symmetric]) auto
   also have "\<dots> = (LBINT (x,y):D. (LBINT z:{0<..<1}. P x * P y / (1-(1-x*y)*z)))"
     by (simp add: interval_integral_Ioo)
   also have "\<dots> = (LBINT z:{0<..<1}. (LBINT (x,y):D. P x * P y / (1-(1-x*y)*z)))"
   proof (subst lborel_pair.Fubini_set_integral [symmetric])
     have "set_integrable lborel (({0<..<1} \<times> {0<..<1}) \<times> {0<..<1})
             (\<lambda>((x, y), z). P x * P y / (1 - (1 - x * y) * z))"
       using beukers_aux_integrable1 by simp
     also have "?this \<longleftrightarrow> set_integrable (lborel \<Otimes>\<^sub>M lborel) ({0<..<1} \<times> D)
                            (\<lambda>(z,x,y). P x * P y / (1 - (1 - x * y) * z))"
       unfolding set_integrable_def
-      by (subst lborel_pair.integrable_product_swap_iff [symmetric], intro integrable_cong)
+      by (subst lborel_pair.integrable_product_swap_iff [symmetric], intro Bochner_Integration.integrable_cong)
          (auto simp: indicator_def case_prod_unfold lborel_prod D_def)
     finally show \<dots> .
   qed (auto simp: case_prod_unfold)
   also have "\<dots> = (LBINT z:{0<..<1}. (LBINT (x,y):D. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     by (rule set_lebesgue_integral_cong) (use beukers_aux_integral_transform1 in simp_all)
   also have "\<dots> = (LBINT (x,y):D. (LBINT z:{0<..<1}. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)))"
     using beukers_aux_integrable2
     by (subst lborel_pair.Fubini_set_integral [symmetric])
        (auto simp: case_prod_unfold lborel_prod D_def D'_def)
   also have "\<dots> = (LBINT (x,y):D. (LBINT w:{0<..<1}. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)))"
   proof (intro set_lebesgue_integral_cong allI impI; clarify?)
     fix x y :: real
     assume xy: "(x, y) \<in> D"
     have "(LBINT z:{0<..<1}. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
             P x * (LBINT z=0..1. (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1))"
       by (subst interval_lebesgue_integral_mult_right [symmetric])
          (simp add: mult_ac interval_integral_Ioo)
     also have "\<dots> = P x * (LBINT w=0..1. (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
       using xy by (subst beukers_aux_integral_transform2) (auto simp: D_def)
     also have "\<dots> = (LBINT w:{0<..<1}. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w))"
       by (subst interval_lebesgue_integral_mult_right [symmetric])
          (simp add: mult_ac interval_integral_Ioo)
     finally show "(LBINT z:{0<..<1}. P x * (x*y*z)^n * (1-y)^n / (1-(1-x*y)*z)^(n+1)) =
                     (LBINT w:{0<..<1}. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w))" .
   qed (auto simp: D_def simp flip: borel_prod)
   also have "\<dots> = (LBINT w:{0<..<1}. (LBINT (x,y):D. P x * (1-w)^n * (1-y)^n / (1-(1-x*y)*w)))"
     using beukers_aux_integrable3
     by (subst lborel_pair.Fubini_set_integral [symmetric])
        (auto simp: case_prod_unfold lborel_prod D_def D'_def)
   also have "\<dots> = (LBINT w=0..1. (1-w)^n * (LBINT (x,y):D. P x * (1-y)^n / (1-(1-x*y)*w)))"
     unfolding case_prod_unfold
     by (subst set_integral_mult_right [symmetric]) (simp add: mult_ac interval_integral_Ioo)
   also have "\<dots> = (LBINT w=0..1. (1-w)^n * (LBINT (x,y):D. (x*y*w*(1-x)*(1-y))^n / (1-(1-x*y)*w)^(n+1)))"
     by (intro interval_lebesgue_integral_lborel_01_cong, subst beukers_aux_integral_transform3)
        (auto simp: mult_ac power_mult_distrib)
   also have "\<dots> = (LBINT w=0..1. (LBINT (x,y):D. (x*y*w*(1-x)*(1-y)*(1-w))^n / (1-(1-x*y)*w)^(n+1)))"
     by (subst set_integral_mult_right [symmetric])
        (auto simp: case_prod_unfold mult_ac power_mult_distrib)
   also have "\<dots> = beukers_integral3"
     using beukers_integral3_integrable unfolding D'_def D_def beukers_integral3_def
     by (subst (2) lborel_prod [symmetric], subst lborel_pair.set_integral_fst')
        (auto simp: case_prod_unfold interval_integral_Ioo lborel_prod algebra_simps)
   finally show ?thesis .
 qed
 
 
 subsection \<open>The main result\<close>
 
 text \<open>
   Combining all of the results so far, we can derive the key inequalities
   \[0 < A\zeta(3) + B < 2 \zeta(3) \cdot 27^{-n} \cdot \text{lcm}\{1\ldots n\}^3\]
   for integers $A$, $B$ with $A > 0$.
 \<close>
 lemma zeta_3_linear_combination_bounds:
   obtains A B :: int
   where "A > 0"
         "A * Re (zeta 3) + B \<in> {0 <.. 2 * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n}"
 proof -
   define I where "I = beukers_integral2"
   define d where "d = Lcm {1..n} ^ 3"
   have "d > 0" by (auto simp: d_def intro!: Nat.gr0I)
   from beukers_integral2_conv_int_combination obtain A' B :: int
     where *: "A' > 0" "I = A' * Re (zeta 3) + B / d" unfolding I_def d_def .
   define A where "A = A' * d"
   from * have A: "A > 0" "I = (A * Re (zeta 3) + B) / d"
     using \<open>d > 0\<close> by (simp_all add: A_def field_simps)
 
   have "0 < I"
     using beukers_integral3_pos by (simp add: I_def beukers_integral2_conv_3)
   with \<open>d > 0\<close> have "A * Re (zeta 3) + B > 0"
     by (simp add: field_simps A)
 
   moreover have "I \<le> 2 * (1 / 27) ^ n * Re (zeta 3)"
     using beukers_integral2_conv_3 beukers_integral3_le by (simp add: I_def)
   hence "A * Re (zeta 3) + B \<le> 2 * Re (zeta 3) * d / 27 ^ n"
     using \<open>d > 0\<close> by (simp add: A field_simps)
 
   ultimately show ?thesis
     using A by (intro that[of A B]) (auto simp: d_def)
 qed
 
 text \<open>
   If $\zeta(3) = \frac{a}{b}$ for some integers $a$ and $b$, we can thus derive
   the inequality $2b\zeta(3) \cdot 27^{-n} \cdot \text{lcm}\{1\ldots n\}^3\geq 1$ for any
   natural number $n$.
 \<close>
 lemma beukers_key_inequality:
   fixes a :: int and b :: nat
   assumes "b > 0" and ab: "Re (zeta 3) = a / b"
   shows   "2 * b * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n \<ge> 1"
 proof -
   from zeta_3_linear_combination_bounds obtain A B :: int
     where AB: "A > 0"
               "A * Re (zeta 3) + B \<in> {0 <.. 2 * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n}" .
   from AB have "0 < (A * Re (zeta 3) + B) * b"
     using \<open>b > 0\<close> by (intro mult_pos_pos) auto
   also have "\<dots> = A * (Re (zeta 3) * b) + B * b"
     using \<open>b > 0\<close> by (simp add: algebra_simps)
   also have "Re (zeta 3) * b = a"
     using \<open>b > 0\<close> by (simp add: ab)
   also have "of_int A * of_int a + of_int (B * b) = of_int (A * a + B * b)"
     by simp
   finally have "1 \<le> A * a + B * b"
     by linarith
   hence "1 \<le> real_of_int (A * a + B * b)"
     by linarith
   also have "\<dots> = (A * (a / b) + B) * b"
     using \<open>b > 0\<close> by (simp add: ring_distribs)
   also have "a / b = Re (zeta 3)"
     by (simp add: ab)
   also have "A * Re (zeta 3) + B \<le> 2 * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n"
     using AB by simp
   finally show "2 * b * Re (zeta 3) * Lcm {1..n} ^ 3 / 27 ^ n \<ge> 1"
     using \<open>b > 0\<close> by (simp add: mult_ac)
 qed
 
 end
 
 (* TODO: Move *)
 lemma smallo_power: "n > 0 \<Longrightarrow> f \<in> o[F](g) \<Longrightarrow> (\<lambda>x. f x ^ n) \<in> o[F](\<lambda>x. g x ^ n)"
   by (induction n rule: nat_induct_non_zero) (auto intro: landau_o.small.mult)
 
 text \<open>
   This is now a contradiction, since $\text{lcm}\{1\ldots n\} \in o(3^n)$ by the
   Prime Number Theorem -- hence the main result.
 \<close>
 theorem zeta_3_irrational: "zeta 3 \<notin> \<rat>"
 proof
   assume "zeta 3 \<in> \<rat>"
   obtain a :: int and b :: nat where "b > 0" and ab': "zeta 3 = a / b"
   proof -
     from \<open>zeta 3 \<in> \<rat>\<close> obtain r where r: "zeta 3 = of_rat r"
       by (elim Rats_cases)
     also have "r = rat_of_int (fst (quotient_of r)) / rat_of_int (snd (quotient_of r))"
       by (intro quotient_of_div) auto
     also have "of_rat \<dots> = (of_int (fst (quotient_of r)) / of_int (snd (quotient_of r)) :: complex)"
       by (simp add: of_rat_divide)
     also have "of_int (snd (quotient_of r)) = of_nat (nat (snd (quotient_of r)))"
       using quotient_of_denom_pos'[of r] by auto
     finally have "zeta 3 = of_int (fst (quotient_of r)) / of_nat (nat (snd (quotient_of r)))" .
     thus ?thesis
       using quotient_of_denom_pos'[of r]
       by (intro that[of "nat (snd (quotient_of r))" "fst (quotient_of r)"]) auto
   qed
   hence ab: "Re (zeta 3) = a / b" by simp
 
   interpret prime_number_theorem
     by standard (rule prime_number_theorem)
 
   have Lcm_upto_smallo: "(\<lambda>n. real (Lcm {1..n})) \<in> o(\<lambda>n. c ^ n)" if c: "c > exp 1" for c
   proof -
     have "0 < exp (1::real)" by simp
     also note c
     finally have "c > 0" .
     have "(\<lambda>n. real (Lcm {1..n})) = (\<lambda>n. real (Lcm {1..nat \<lfloor>real n\<rfloor>}))"
       by simp
     also have "\<dots> \<in> o(\<lambda>n. c powr real n)"
       using Lcm_upto.smallo'
       by (rule landau_o.small.compose) (simp_all add: c filterlim_real_sequentially)
     also have "(\<lambda>n. c powr real n) = (\<lambda>n. c ^ n)"
       using c \<open>c > 0\<close> by (subst powr_realpow) auto
     finally show ?thesis .
   qed
 
   have "(\<lambda>n. 2 * b * Re (zeta 3) * real (Lcm {1..n}) ^ 3 / 27 ^ n) \<in>
           O(\<lambda>n. real (Lcm {1..n}) ^ 3 / 27 ^ n)"
     using \<open>b > 0\<close> Re_zeta_ge_1[of 3] by simp
   also have "exp 1 < (3 :: real)"
     using e_approx_32 by (simp add: abs_if split: if_splits)
   hence "(\<lambda>n. real (Lcm {1..n}) ^ 3 / 27 ^ n) \<in> o(\<lambda>n. (3 ^ n) ^ 3 / 27 ^ n)"
     unfolding of_nat_power
     by (intro landau_o.small.divide_right smallo_power Lcm_upto_smallo) auto
   also have "(\<lambda>n. (3 ^ n) ^ 3 / 27 ^ n :: real) = (\<lambda>_. 1)"
     by (simp add: power_mult [of 3, symmetric] mult.commute[of _ 3] power_mult[of _ 3])
   finally have *: "(\<lambda>n. 2 * b * Re (zeta 3) * real (Lcm {1..n}) ^ 3 / 27 ^ n) \<in> o(\<lambda>_. 1)" .
   have lim: "(\<lambda>n. 2 * b * Re (zeta 3) * real (Lcm {1..n}) ^ 3 / 27 ^ n) \<longlonglongrightarrow> 0"
     using smalloD_tendsto[OF *] by simp
 
   moreover have "1 \<le> real (2 * b) * Re (zeta 3) * real (Lcm {1..n} ^ 3) / 27 ^ n" for n
     using beukers_key_inequality[of b a] ab \<open>b > 0\<close> by simp
 
   ultimately have "1 \<le> (0 :: real)"
     by (intro tendsto_lowerbound[OF lim] always_eventually allI) auto
   thus False by simp
 qed
 
 end
\ No newline at end of file