diff --git a/thys/Poincare_Disc/Poincare_Between.thy b/thys/Poincare_Disc/Poincare_Between.thy
--- a/thys/Poincare_Disc/Poincare_Between.thy
+++ b/thys/Poincare_Disc/Poincare_Between.thy
@@ -1,1257 +1,1257 @@
 theory Poincare_Between
   imports Poincare_Distance
 begin
 
 (* ------------------------------------------------------------------ *)
 section\<open>H-betweenness in the Poincar\'e model\<close>
 (* ------------------------------------------------------------------ *)
 
 subsection \<open>H-betwenness expressed by a cross-ratio\<close>
 
 text\<open>The point $v$ is h-between $u$ and $w$ if the cross-ratio between the pairs $u$ and $w$ and $v$
 and inverse of $v$ is real and negative.\<close>
 definition poincare_between :: "complex_homo \<Rightarrow> complex_homo \<Rightarrow> complex_homo \<Rightarrow> bool" where
   "poincare_between u v w \<longleftrightarrow>
          u = v \<or> v = w \<or>
          (let cr = cross_ratio u v w (inversion v)
            in is_real (to_complex cr) \<and> Re (to_complex cr) < 0)"
 
 subsubsection \<open>H-betwenness is preserved by h-isometries\<close>
 
 text \<open>Since they preserve cross-ratio and inversion, h-isometries (unit disc preserving Möbius
 transformations and conjugation) preserve h-betweeness.\<close>
 
 lemma unit_disc_fix_moebius_preserve_poincare_between [simp]:
   assumes "unit_disc_fix M" and "u \<in> unit_disc" and "v \<in> unit_disc" and "w \<in> unit_disc"
   shows "poincare_between (moebius_pt M u) (moebius_pt M v) (moebius_pt M w) \<longleftrightarrow>
          poincare_between u v w"
 proof (cases "u = v \<or> v = w")
   case True
   thus ?thesis
     using assms
     unfolding poincare_between_def
     by auto
 next
   case False
   moreover
   hence "moebius_pt M u \<noteq> moebius_pt M v \<and> moebius_pt M v \<noteq> moebius_pt M w"
     by auto
   moreover
   have "v \<noteq> inversion v" "w \<noteq> inversion v"
     using inversion_noteq_unit_disc[of v w]
     using inversion_noteq_unit_disc[of v v]
     using \<open>v \<in> unit_disc\<close> \<open>w \<in> unit_disc\<close>
     by auto
   ultimately
   show ?thesis
     using assms
     using unit_circle_fix_moebius_pt_inversion[of M v, symmetric]
     unfolding poincare_between_def
     by (simp del: unit_circle_fix_moebius_pt_inversion)
 qed
 
 lemma conjugate_preserve_poincare_between [simp]:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "w \<in> unit_disc"
   shows "poincare_between (conjugate u) (conjugate v) (conjugate w) \<longleftrightarrow>
          poincare_between u v w"
 proof (cases "u = v \<or> v = w")
   case True
   thus ?thesis
     using assms
     unfolding poincare_between_def
     by auto
 next
   case False
   moreover
   hence "conjugate u \<noteq> conjugate v \<and> conjugate v \<noteq> conjugate w"
     using conjugate_inj by blast
   moreover
   have "v \<noteq> inversion v" "w \<noteq> inversion v"
     using inversion_noteq_unit_disc[of v w]
     using inversion_noteq_unit_disc[of v v]
     using \<open>v \<in> unit_disc\<close> \<open>w \<in> unit_disc\<close>
     by auto
   ultimately
   show ?thesis
     using assms
     using conjugate_cross_ratio[of v w "inversion v" u]
     unfolding poincare_between_def
     by (metis conjugate_id_iff conjugate_involution inversion_def inversion_sym o_apply)
 qed
 
 
 subsubsection \<open>Some elementary properties of h-betwenness\<close>
 
 lemma poincare_between_nonstrict [simp]:
   shows "poincare_between u u v" and "poincare_between u v v"
   by (simp_all add: poincare_between_def)                       
 
 lemma poincare_between_sandwich:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc"
   assumes "poincare_between u v u"
   shows "u = v"
 proof (rule ccontr)
   assume "\<not> ?thesis"
   thus False
     using assms
     using inversion_noteq_unit_disc[of v u]
     using cross_ratio_1[of v u "inversion v"]
     unfolding poincare_between_def Let_def
     by auto
 qed
 
 lemma poincare_between_rev:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "w \<in> unit_disc"
   shows "poincare_between u v w \<longleftrightarrow> poincare_between w v u"       
   using assms 
   using inversion_noteq_unit_disc[of v w]
   using inversion_noteq_unit_disc[of v u]
   using cross_ratio_commute_13[of u v w "inversion v"]
   using cross_ratio_not_inf[of w "inversion v" v u]
   using cross_ratio_not_zero[of w v u "inversion v"]
   using inf_or_of_complex[of "cross_ratio w v u (inversion v)"]
   unfolding poincare_between_def
   by (auto simp add: Let_def Im_complex_div_eq_0 Re_divide divide_less_0_iff)
 
 subsubsection \<open>H-betwenness and h-collinearity\<close>
 
 text\<open>Three points can be in an h-between relation only when they are h-collinear.\<close>
 lemma poincare_between_poincare_collinear [simp]:       
   assumes in_disc: "u \<in> unit_disc"  "v \<in> unit_disc"  "w \<in> unit_disc"
   assumes betw: "poincare_between u v w"
   shows "poincare_collinear {u, v, w}"
 proof (cases "u = v \<or> v = w")
   case True
   thus ?thesis
     using assms
     by auto
 next
   case False
   hence distinct: "distinct [u, v, w, inversion v]"
     using in_disc inversion_noteq_unit_disc[of v v] inversion_noteq_unit_disc[of v u] inversion_noteq_unit_disc[of v w]
     using betw poincare_between_sandwich[of w v]
     by (auto simp add: poincare_between_def Let_def)
 
   then obtain H where *: "{u, v, w, inversion v} \<subseteq> circline_set H"
     using assms
     unfolding poincare_between_def
     using four_points_on_circline_iff_cross_ratio_real[of u v w "inversion v"]
     by auto
   hence "H = poincare_line u v"
     using assms distinct
     using unique_circline_set[of u v "inversion v"]
     using poincare_line[of u v] poincare_line_inversion[of u v]
     unfolding circline_set_def
     by auto
   thus ?thesis
     using * assms False
     unfolding poincare_collinear_def
     by (rule_tac x="poincare_line u v" in exI) simp
 qed
 
 lemma poincare_between_poincare_line_uvz:
   assumes "u \<noteq> v" and "u \<in> unit_disc" and "v \<in> unit_disc" and
           "z \<in> unit_disc" and "poincare_between u v z"
   shows "z \<in> circline_set (poincare_line u v)"
   using assms
   using poincare_between_poincare_collinear[of u v z]
   using unique_poincare_line[OF assms(1-3)]
   unfolding poincare_collinear_def
   by auto
 
 lemma poincare_between_poincare_line_uzv:
   assumes "u \<noteq> v" and "u \<in> unit_disc" and "v \<in> unit_disc" and
           "z \<in> unit_disc" "poincare_between u z v"
   shows "z \<in> circline_set (poincare_line u v)"
   using assms
   using poincare_between_poincare_collinear[of u z v]
   using unique_poincare_line[OF assms(1-3)]
   unfolding poincare_collinear_def
   by auto
 
 subsubsection \<open>H-betweeness on Euclidean segments\<close> 
 
 text\<open>If the three points lie on an h-line that is a Euclidean line (e.g., if it contains zero),
 h-betweenness can be characterized much simpler than in the definition.\<close>
 
 lemma poincare_between_x_axis_u0v:
   assumes "is_real u'" and "u' \<noteq> 0" and "v' \<noteq> 0"
   shows "poincare_between (of_complex u') 0\<^sub>h (of_complex v') \<longleftrightarrow> is_real v' \<and> Re u' * Re v' < 0"
 proof-
   have "Re u' \<noteq> 0"
     using \<open>is_real u'\<close> \<open>u' \<noteq> 0\<close>
     using complex_eq_if_Re_eq
     by auto
   have nz: "of_complex u' \<noteq> 0\<^sub>h" "of_complex v' \<noteq> 0\<^sub>h"
     by (simp_all add: \<open>u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close>)
   hence "0\<^sub>h \<noteq> of_complex v'"
     by metis
 
   let ?cr = "cross_ratio (of_complex u') 0\<^sub>h (of_complex v') \<infinity>\<^sub>h"
   have "is_real (to_complex ?cr) \<and> Re (to_complex ?cr) < 0 \<longleftrightarrow> is_real v' \<and> Re u' * Re v' < 0"
     using cross_ratio_0inf[of v' u'] \<open>v' \<noteq> 0\<close> \<open>u' \<noteq> 0\<close> \<open>is_real u'\<close>
     by (metis Re_complex_div_lt_0 Re_mult_real complex_cnj_divide divide_cancel_left eq_cnj_iff_real to_complex_of_complex)
   thus ?thesis
     unfolding poincare_between_def inversion_zero
     using \<open>of_complex u' \<noteq> 0\<^sub>h\<close> \<open>0\<^sub>h \<noteq> of_complex v'\<close>
     by simp
 qed
 
 lemma poincare_between_u0v:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "u \<noteq> 0\<^sub>h" and "v \<noteq> 0\<^sub>h"
   shows "poincare_between u 0\<^sub>h v \<longleftrightarrow> (\<exists> k < 0. to_complex u = cor k * to_complex v)" (is "?P u v")
 proof (cases "u = v")
   case True
   thus ?thesis
     using assms
     using inf_or_of_complex[of v]
     using poincare_between_sandwich[of u "0\<^sub>h"]      
     by auto
 next                                                 
   case False
   have "\<forall> u. u \<in> unit_disc \<and> u \<noteq> 0\<^sub>h \<longrightarrow> ?P u v" (is "?P' v")
   proof (rule wlog_rotation_to_positive_x_axis)
     fix \<phi> v
     let ?M = "moebius_pt (moebius_rotation \<phi>)"
     assume 1: "v \<in> unit_disc" "v \<noteq> 0\<^sub>h"
     assume 2: "?P' (?M v)"
     show "?P' v"
     proof (rule allI, rule impI, (erule conjE)+)
       fix u
       assume 3: "u \<in> unit_disc" "u \<noteq> 0\<^sub>h"  
       have "poincare_between (?M u) 0\<^sub>h (?M v) \<longleftrightarrow> poincare_between u 0\<^sub>h v"
         using \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close>
         using unit_disc_fix_moebius_preserve_poincare_between unit_disc_fix_rotation zero_in_unit_disc 
         by fastforce
       thus "?P u v"
         using 1 2[rule_format, of "?M u"] 3
         using inf_or_of_complex[of u] inf_or_of_complex[of v]
         by auto
     qed
   next
     fix x
     assume 1: "is_real x" "0 < Re x" "Re x < 1"
     hence "x \<noteq> 0"
       by auto
     show "?P' (of_complex x)"    
     proof (rule allI, rule impI, (erule conjE)+)
       fix u
       assume 2: "u \<in> unit_disc" "u \<noteq> 0\<^sub>h"
       then obtain u' where "u = of_complex u'"
         using inf_or_of_complex[of u]
         by auto
       show "?P u (of_complex x)"
         using 1 2 \<open>x \<noteq> 0\<close> \<open>u = of_complex u'\<close>
         using poincare_between_rev[of u "0\<^sub>h" "of_complex x"]
         using poincare_between_x_axis_u0v[of x u'] \<open>is_real x\<close>
         apply (auto simp add: cmod_eq_Re)
         apply (rule_tac x="Re u' / Re x" in exI, simp add: divide_neg_pos algebra_split_simps)
         using mult_neg_pos mult_pos_neg
         by blast
     qed
   qed fact+
   thus ?thesis
     using assms
     by auto
 qed
 
 lemma poincare_between_u0v_polar_form:
   assumes "x \<in> unit_disc" and "y \<in> unit_disc" and "x \<noteq> 0\<^sub>h" and "y \<noteq> 0\<^sub>h" and 
           "to_complex x = cor rx * cis \<phi>" "to_complex y = cor ry * cis \<phi>"
   shows "poincare_between x 0\<^sub>h y \<longleftrightarrow> rx * ry < 0" (is "?P x y rx ry")
 proof-
   from assms have "rx \<noteq> 0" "ry \<noteq> 0"
     using inf_or_of_complex[of x] inf_or_of_complex[of y]
     by auto
 
   have "(\<exists>k<0. cor rx = cor k * cor ry ) = (rx * ry < 0)"
   proof
     assume "\<exists>k<0. cor rx = cor k * cor ry"
     then obtain k where "k < 0" "cor rx = cor k * cor ry"
       by auto
     hence "rx = k * ry"
       using of_real_eq_iff
       by fastforce
     thus "rx * ry < 0" 
       using \<open>k < 0\<close> \<open>rx \<noteq> 0\<close> \<open>ry \<noteq> 0\<close>
       by (smt divisors_zero mult_nonneg_nonpos mult_nonpos_nonpos zero_less_mult_pos2)
   next
     assume "rx * ry < 0"
     hence "rx = (rx/ry)*ry" "rx / ry < 0"
       using \<open>rx \<noteq> 0\<close> \<open>ry \<noteq> 0\<close>
       by (auto simp add: divide_less_0_iff algebra_split_simps)
     thus "\<exists>k<0. cor rx = cor k * cor ry"
       using \<open>rx \<noteq> 0\<close> \<open>ry \<noteq> 0\<close>
       by (rule_tac x="rx / ry" in exI, simp)
   qed
   thus ?thesis
     using assms                                 
     using poincare_between_u0v[OF assms(1-4)]
     by auto
 qed
 
 lemma poincare_between_x_axis_0uv:
   fixes x y :: real
   assumes "-1 < x" and "x < 1" and "x \<noteq> 0"
   assumes "-1 < y" and "y < 1" and "y \<noteq> 0"
   shows "poincare_between 0\<^sub>h (of_complex x) (of_complex y) \<longleftrightarrow>
         (x < 0 \<and> y < 0 \<and> y \<le> x) \<or> (x > 0 \<and> y > 0 \<and> x \<le> y)" (is "?lhs \<longleftrightarrow> ?rhs")
 proof (cases "x = y")
   case True
   thus ?thesis
     using assms
     unfolding poincare_between_def
     by auto
 next
   case False
   let ?x = "of_complex x" and ?y = "of_complex y"
 
   have "?x \<in> unit_disc" "?y \<in> unit_disc"
     using assms
     by auto
 
   have distinct: "distinct [0\<^sub>h, ?x, ?y, inversion ?x]"
     using \<open>x \<noteq> 0\<close> \<open>y \<noteq> 0\<close> \<open>x \<noteq> y\<close> \<open>?x \<in> unit_disc\<close> \<open>?y \<in> unit_disc\<close>
     using inversion_noteq_unit_disc[of ?x ?y]
     using inversion_noteq_unit_disc[of ?x ?x]
     using inversion_noteq_unit_disc[of ?x "0\<^sub>h"]
     using of_complex_inj[of x y]
     by (metis distinct_length_2_or_more distinct_singleton of_complex_zero_iff of_real_eq_0_iff of_real_eq_iff zero_in_unit_disc)
 
   let ?cr = "cross_ratio 0\<^sub>h ?x ?y (inversion ?x)"
   have "Re (to_complex ?cr) = x\<^sup>2 * (x*y - 1) / (x * (y - x))"
     using \<open>x \<noteq> 0\<close> \<open>x \<noteq> y\<close>
     unfolding inversion_def
     by simp (transfer, transfer, auto simp add: vec_cnj_def power2_eq_square field_simps split: if_split_asm)
   moreover
   { 
     fix a b :: real
     assume "b \<noteq> 0"
     hence "a < 0 \<longleftrightarrow> b\<^sup>2 * a < (0::real)"
       by (metis mult.commute mult_eq_0_iff mult_neg_pos mult_pos_pos not_less_iff_gr_or_eq not_real_square_gt_zero power2_eq_square)
   }
   hence "x\<^sup>2 * (x*y - 1) < 0"
     using assms
     by (smt minus_mult_minus mult_le_cancel_left1)
   moreover
   have "x * (y - x) > 0 \<longleftrightarrow> ?rhs"
     using \<open>x \<noteq> 0\<close> \<open>y \<noteq> 0\<close> \<open>x \<noteq> y\<close>
     by (smt mult_le_0_iff)
   ultimately
   have *: "Re (to_complex ?cr) < 0 \<longleftrightarrow> ?rhs"
     by (simp add: divide_less_0_iff)
 
   show ?thesis
   proof
     assume ?lhs
     have "is_real (to_complex ?cr)" "Re (to_complex ?cr) < 0"
       using \<open>?lhs\<close> distinct
       unfolding poincare_between_def Let_def
       by auto
     thus ?rhs
       using *
       by simp
   next
     assume ?rhs
     hence "Re (to_complex ?cr) < 0"
       using *
       by simp
     moreover
     have "{0\<^sub>h, of_complex (cor x), of_complex (cor y), inversion (of_complex (cor x))} \<subseteq> circline_set x_axis"
       using \<open>x \<noteq> 0\<close> is_real_inversion[of "cor x"]
       using inf_or_of_complex[of "inversion ?x"]
       by (auto simp del: inversion_of_complex)
     hence "is_real (to_complex ?cr)"
       using four_points_on_circline_iff_cross_ratio_real[OF distinct]
       by auto
     ultimately
     show ?lhs
       using distinct
       unfolding poincare_between_def Let_def
       by auto
   qed
 qed
 
 lemma poincare_between_0uv:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "u \<noteq> 0\<^sub>h" and "v \<noteq> 0\<^sub>h"
   shows "poincare_between 0\<^sub>h u v \<longleftrightarrow>
-         (let u' = to_complex u; v' = to_complex v in arg u' = arg v' \<and> cmod u' \<le> cmod v')" (is "?P u v")
+         (let u' = to_complex u; v' = to_complex v in Arg u' = Arg v' \<and> cmod u' \<le> cmod v')" (is "?P u v")
 proof (cases "u = v")
   case True
   thus ?thesis
     by simp
 next
   case False
-  have "\<forall> v. v \<in> unit_disc \<and> v \<noteq> 0\<^sub>h \<and> v \<noteq> u \<longrightarrow> (poincare_between 0\<^sub>h u v \<longleftrightarrow> (let u' = to_complex u; v' = to_complex v in arg u' = arg v' \<and> cmod u' \<le> cmod v'))" (is "?P' u")
+  have "\<forall> v. v \<in> unit_disc \<and> v \<noteq> 0\<^sub>h \<and> v \<noteq> u \<longrightarrow> (poincare_between 0\<^sub>h u v \<longleftrightarrow> (let u' = to_complex u; v' = to_complex v in Arg u' = Arg v' \<and> cmod u' \<le> cmod v'))" (is "?P' u")
   proof (rule wlog_rotation_to_positive_x_axis)
     show "u \<in> unit_disc" "u \<noteq> 0\<^sub>h"
       by fact+
   next
     fix x
     assume *: "is_real x" "0 < Re x" "Re x < 1"
     hence "of_complex x \<in> unit_disc" "of_complex x \<noteq> 0\<^sub>h" "of_complex x \<in> circline_set x_axis"
       unfolding circline_set_x_axis
       by (auto simp add: cmod_eq_Re)
     show "?P' (of_complex x)"
     proof safe
       fix v
       assume "v \<in> unit_disc" "v \<noteq> 0\<^sub>h" "v \<noteq> of_complex x" "poincare_between 0\<^sub>h (of_complex x) v"
       hence "v \<in> circline_set x_axis"
         using poincare_between_poincare_line_uvz[of "0\<^sub>h" "of_complex x" v]
         using poincare_line_0_real_is_x_axis[of "of_complex x"]
         using \<open>of_complex x \<noteq> 0\<^sub>h\<close> \<open>v \<noteq> 0\<^sub>h\<close> \<open>v \<noteq> of_complex x\<close> \<open>of_complex x \<in> unit_disc\<close> \<open>of_complex x \<in> circline_set x_axis\<close>
         by auto
       obtain v' where "v = of_complex v'"
         using \<open>v \<in> unit_disc\<close>
         using inf_or_of_complex[of v]
         by auto
       hence **: "v = of_complex v'" "-1 < Re v'" "Re v' < 1" "Re v' \<noteq> 0" "is_real v'"
         using \<open>v \<in> unit_disc\<close> \<open>v \<noteq> 0\<^sub>h\<close> \<open>v \<in> circline_set x_axis\<close> of_complex_inj[of v']
         unfolding circline_set_x_axis
         by (auto simp add: cmod_eq_Re real_imag_0)
-      show "let u' = to_complex (of_complex x); v' = to_complex v in arg u' = arg v' \<and> cmod u' \<le> cmod v'"
+      show "let u' = to_complex (of_complex x); v' = to_complex v in Arg u' = Arg v' \<and> cmod u' \<le> cmod v'"
         using poincare_between_x_axis_0uv[of "Re x" "Re v'"] * **
         using \<open>poincare_between 0\<^sub>h (of_complex x) v\<close>
         using arg_complex_of_real_positive[of "Re x"] arg_complex_of_real_negative[of "Re x"]
         using arg_complex_of_real_positive[of "Re v'"] arg_complex_of_real_negative[of "Re v'"]
         by (auto simp add: cmod_eq_Re)
     next
       fix v
       assume "v \<in> unit_disc" "v \<noteq> 0\<^sub>h" "v \<noteq> of_complex x"
       then obtain v' where **: "v = of_complex v'" "v' \<noteq> 0" "v' \<noteq> x"
         using inf_or_of_complex[of v]
         by auto blast
-      assume "let u' = to_complex (of_complex x); v' = to_complex v in arg u' = arg v' \<and> cmod u' \<le> cmod v'"
+      assume "let u' = to_complex (of_complex x); v' = to_complex v in Arg u' = Arg v' \<and> cmod u' \<le> cmod v'"
       hence ***: "Re x < 0 \<and> Re v' < 0 \<and> Re v' \<le> Re x \<or> 0 < Re x \<and> 0 < Re v' \<and> Re x \<le> Re v'" "is_real v'"
         using arg_pi_iff[of x] arg_pi_iff[of v']
         using arg_0_iff[of x] arg_0_iff[of v']
         using * **
         by (smt cmod_Re_le_iff to_complex_of_complex)+
       have "-1 < Re v'" "Re v' < 1" "Re v' \<noteq> 0" "is_real v'"
         using \<open>v \<in> unit_disc\<close> ** \<open>is_real v'\<close>
         by (auto simp add: cmod_eq_Re complex_eq_if_Re_eq)
       thus "poincare_between 0\<^sub>h (of_complex x) v"
         using poincare_between_x_axis_0uv[of "Re x" "Re v'"] * ** ***
         by simp
     qed
   next
     fix \<phi> u
     assume "u \<in> unit_disc" "u \<noteq> 0\<^sub>h"
     let ?M = "moebius_rotation \<phi>"
     assume *: "?P' (moebius_pt ?M u)"
     show "?P' u"
     proof (rule allI, rule impI, (erule conjE)+)
       fix v
       assume "v \<in> unit_disc" "v \<noteq> 0\<^sub>h" "v \<noteq> u"
       have "moebius_pt ?M v \<noteq> moebius_pt ?M u"
         using \<open>v \<noteq> u\<close>
         by auto
       obtain u' v' where "v = of_complex v'" "u = of_complex u'" "v' \<noteq> 0" "u' \<noteq> 0"
         using inf_or_of_complex[of u] inf_or_of_complex[of v]
         using \<open>v \<in> unit_disc\<close> \<open>u \<in> unit_disc\<close> \<open>v \<noteq> 0\<^sub>h\<close> \<open>u \<noteq> 0\<^sub>h\<close>
         by auto
       thus "?P u v"
         using *[rule_format, of "moebius_pt ?M v"]
         using \<open>moebius_pt ?M v \<noteq> moebius_pt ?M u\<close>
         using unit_disc_fix_moebius_preserve_poincare_between[of ?M "0\<^sub>h" u v]
         using \<open>v \<in> unit_disc\<close> \<open>u \<in> unit_disc\<close> \<open>v \<noteq> 0\<^sub>h\<close> \<open>u \<noteq> 0\<^sub>h\<close>
         using arg_mult_eq[of "cis \<phi>" u' v']
         by simp (auto simp add: arg_mult norm_mult)
     qed
   qed
   thus ?thesis
     using assms False
     by auto
 qed
 
 lemma poincare_between_y_axis_0uv:
   fixes x y :: real
   assumes "-1 < x" and "x < 1" and "x \<noteq> 0"
   assumes "-1 < y" and "y < 1" and "y \<noteq> 0"
   shows "poincare_between 0\<^sub>h (of_complex (\<i> * x)) (of_complex (\<i> * y)) \<longleftrightarrow>
         (x < 0 \<and> y < 0 \<and> y \<le> x) \<or> (x > 0 \<and> y > 0 \<and> x \<le> y)" (is "?lhs \<longleftrightarrow> ?rhs")
   using assms
   using poincare_between_0uv[of "of_complex (\<i> * x)" "of_complex (\<i> * y)"]
   using arg_pi2_iff[of "\<i> * cor x"] arg_pi2_iff[of "\<i> * cor y"]
   using arg_minus_pi2_iff[of "\<i> * cor x"] arg_minus_pi2_iff[of "\<i> * cor y"]
   apply (simp add: norm_mult)
   apply (smt (verit, best))
   done
 
 lemma poincare_between_x_axis_uvw:
   fixes x y z :: real
   assumes "-1 < x" and "x < 1" 
   assumes "-1 < y" and "y < 1" and "y \<noteq> x"
   assumes "-1 < z" and "z < 1" and "z \<noteq> x"
   shows "poincare_between (of_complex x) (of_complex y) (of_complex z) \<longleftrightarrow>
         (y < x \<and> z < x \<and> z \<le> y) \<or> (y > x \<and> z > x \<and> y \<le> z)"  (is "?lhs \<longleftrightarrow> ?rhs")
 proof (cases "x = 0 \<or> y = 0 \<or> z = 0")
   case True
   thus ?thesis
   proof (cases "x = 0")
     case True
     thus ?thesis
       using poincare_between_x_axis_0uv assms
       by simp
   next
     case False
     show ?thesis
     proof (cases "z = 0")
       case True
       thus ?thesis
         using poincare_between_x_axis_0uv assms poincare_between_rev
         by (smt norm_of_real of_complex_zero of_real_0 poincare_between_nonstrict(2) unit_disc_iff_cmod_lt_1)
     next
       case False
       have "y = 0"
         using \<open>x \<noteq> 0\<close> \<open>z \<noteq> 0\<close> \<open>x = 0 \<or> y = 0 \<or> z = 0\<close>
         by simp
 
       have "poincare_between (of_complex x) 0\<^sub>h (of_complex z) = (is_real z \<and> x * z < 0)"
         using \<open>x \<noteq> 0\<close> \<open>z \<noteq> 0\<close> poincare_between_x_axis_u0v 
         by auto
       moreover
       have "x * z < 0 \<longleftrightarrow> ?rhs"
         using True \<open>x \<noteq> 0\<close> \<open>z \<noteq> 0\<close>
         by (smt zero_le_mult_iff)
       ultimately
       show ?thesis
         using \<open>y = 0\<close>
         by auto
     qed
   qed
 next
   case False
   thus ?thesis
   proof (cases "z = y")
     case True
     thus ?thesis
       using assms
       unfolding poincare_between_def
       by auto
   next
     case False
     let ?x = "of_complex x" and ?y = "of_complex y" and ?z = "of_complex z"
   
     have "?x \<in> unit_disc" "?y \<in> unit_disc" "?z \<in> unit_disc"
       using assms
       by auto
   
     have distinct: "distinct [?x, ?y, ?z, inversion ?y]"
       using \<open>y \<noteq> x\<close> \<open>z \<noteq> x\<close> False \<open>?x \<in> unit_disc\<close> \<open>?y \<in> unit_disc\<close> \<open>?z \<in> unit_disc\<close>
       using inversion_noteq_unit_disc[of ?y ?y]
       using inversion_noteq_unit_disc[of ?y ?x]
       using inversion_noteq_unit_disc[of ?y ?z]
       using of_complex_inj[of x y]  of_complex_inj[of y z]  of_complex_inj[of x z]
       by auto
 
     have "cor y * cor x \<noteq> 1"
       using assms
       by (smt minus_mult_minus mult_less_cancel_left2 mult_less_cancel_right2 of_real_1 of_real_eq_iff of_real_mult)
   
     let ?cr = "cross_ratio ?x ?y ?z (inversion ?y)"
     have "Re (to_complex ?cr) = (x - y) * (z*y - 1)/ ((x*y - 1)*(z - y))"
     proof-
       have " \<And>y x z. \<lbrakk>y \<noteq> x; z \<noteq> x; z \<noteq> y; cor y * cor x \<noteq> 1; x \<noteq> 0; y \<noteq> 0; z \<noteq> 0\<rbrakk> \<Longrightarrow> 
            (y * y + y * (y * (x * z)) - (y * x + y * (y * (y * z)))) /
            (y * y + y * (y * (x * z)) - (y * z + y * (y * (y * x)))) =
            (y + y * (x * z) - (x + y * (y * z))) / (y + y * (x * z) - (z + y * (y * x)))"
         by (metis (no_types, hide_lams) ab_group_add_class.ab_diff_conv_add_uminus distrib_left mult_divide_mult_cancel_left_if mult_minus_right)
       thus ?thesis
         using \<open>y \<noteq> x\<close> \<open>z \<noteq> x\<close> False \<open>\<not> (x = 0 \<or> y = 0 \<or> z = 0)\<close>
         using \<open>cor y * cor x \<noteq> 1\<close>
         unfolding inversion_def
         by (transfer, transfer, auto simp add: vec_cnj_def power2_eq_square field_simps split: if_split_asm)
     qed
       
     moreover
     have "(x*y - 1) < 0"
       using assms
       by (smt minus_mult_minus mult_less_cancel_right2 zero_less_mult_iff)
     moreover
     have "(z*y - 1) < 0"
       using assms
       by (smt minus_mult_minus mult_less_cancel_right2 zero_less_mult_iff)
     moreover
     have "(x - y) / (z - y) < 0 \<longleftrightarrow> ?rhs"
       using \<open>y \<noteq> x\<close> \<open>z \<noteq> x\<close> False \<open>\<not> (x = 0 \<or> y = 0 \<or> z = 0)\<close>
       by (smt divide_less_cancel divide_nonneg_nonpos divide_nonneg_pos divide_nonpos_nonneg divide_nonpos_nonpos)
     ultimately
     have *: "Re (to_complex ?cr) < 0 \<longleftrightarrow> ?rhs"
       by (smt algebra_split_simps(24) minus_divide_left zero_less_divide_iff zero_less_mult_iff)
     show ?thesis
     proof
       assume ?lhs
       have "is_real (to_complex ?cr)" "Re (to_complex ?cr) < 0"
         using \<open>?lhs\<close> distinct
         unfolding poincare_between_def Let_def
         by auto
       thus ?rhs
         using *
         by simp
     next
       assume ?rhs
       hence "Re (to_complex ?cr) < 0"
         using *
         by simp
       moreover
       have "{of_complex (cor x), of_complex (cor y), of_complex (cor z), inversion (of_complex (cor y))} \<subseteq> circline_set x_axis"
         using \<open>\<not> (x = 0 \<or> y = 0 \<or> z = 0)\<close> is_real_inversion[of "cor y"]
         using inf_or_of_complex[of "inversion ?y"]
         by (auto simp del: inversion_of_complex)
       hence "is_real (to_complex ?cr)"
         using four_points_on_circline_iff_cross_ratio_real[OF distinct]
         by auto
       ultimately
       show ?lhs
         using distinct
         unfolding poincare_between_def Let_def
         by auto
     qed
   qed
 qed
 
 subsubsection \<open>H-betweenness and h-collinearity\<close>
 
 text\<open>For three h-collinear points at least one of the three possible h-betweeness relations must
 hold.\<close>
 lemma poincare_collinear3_between:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "w \<in> unit_disc"
   assumes "poincare_collinear {u, v, w}"
   shows "poincare_between u v w \<or> poincare_between u w v \<or> poincare_between v u w" (is "?P' u v w")
 proof (cases "u=v")
   case True
   thus ?thesis
     using assms
     by auto
 next
   case False
   have "\<forall> w. w \<in> unit_disc \<and> poincare_collinear {u, v, w} \<longrightarrow> ?P' u v w" (is "?P u v")
   proof (rule wlog_positive_x_axis[where P="?P"])
     fix x
     assume x: "is_real x" "0 < Re x" "Re x < 1"
     hence "x \<noteq> 0"
       using complex.expand[of x 0]
       by auto
     hence *: "poincare_line 0\<^sub>h (of_complex x) = x_axis"
       using x poincare_line_0_real_is_x_axis[of "of_complex x"]
       unfolding circline_set_x_axis
       by auto
     have "of_complex x \<in> unit_disc"
       using x
       by (auto simp add: cmod_eq_Re)
     have "of_complex x \<noteq> 0\<^sub>h"
       using \<open>x \<noteq> 0\<close>
       by auto
     show "?P 0\<^sub>h (of_complex x)"
     proof safe
       fix w
       assume "w \<in> unit_disc"
       assume "poincare_collinear {0\<^sub>h, of_complex x, w}"
       hence "w \<in> circline_set x_axis"
         using * unique_poincare_line[of "0\<^sub>h" "of_complex x"] \<open>of_complex x \<in> unit_disc\<close> \<open>x \<noteq> 0\<close> \<open>of_complex x \<noteq> 0\<^sub>h\<close>
         unfolding poincare_collinear_def
         by auto
       then obtain w' where w': "w = of_complex w'" "is_real w'"
         using \<open>w \<in> unit_disc\<close>
         using inf_or_of_complex[of w]
         unfolding circline_set_x_axis
         by auto
       hence "-1 < Re w'" "Re w' < 1"
         using \<open>w \<in> unit_disc\<close>
         by (auto simp add: cmod_eq_Re)
       assume 1: "\<not> poincare_between (of_complex x) 0\<^sub>h w"
       hence "w \<noteq> 0\<^sub>h" "w' \<noteq> 0"
         using w'
         unfolding poincare_between_def
         by auto
       hence "Re w' \<noteq> 0"
         using w' complex.expand[of w' 0]
         by auto
 
       have "Re w' \<ge> 0"
         using 1 poincare_between_x_axis_u0v[of x w'] \<open>Re x > 0\<close> \<open>is_real x\<close> \<open>x \<noteq> 0\<close> \<open>w' \<noteq> 0\<close> w'
         using mult_pos_neg
         by force
 
       moreover
 
       assume "\<not> poincare_between 0\<^sub>h (of_complex x) w"
       hence "Re w' < Re x"
         using poincare_between_x_axis_0uv[of "Re x" "Re w'"]
         using w' x \<open>-1 < Re w'\<close> \<open>Re w' < 1\<close> \<open>Re w' \<noteq> 0\<close>
         by auto
 
       ultimately
       show "poincare_between 0\<^sub>h w (of_complex x)"
         using poincare_between_x_axis_0uv[of "Re w'" "Re x"]
         using w' x \<open>-1 < Re w'\<close> \<open>Re w' < 1\<close> \<open>Re w' \<noteq> 0\<close>
         by auto
     qed
   next
     show "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
       by fact+
   next
     fix M u v
     assume 1: "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
     let ?Mu = "moebius_pt M u" and ?Mv = "moebius_pt M v"
     assume 2: "?P ?Mu ?Mv"
     show "?P u v"
     proof safe
       fix w
       assume "w \<in> unit_disc" "poincare_collinear {u, v, w}" "\<not> poincare_between u v w" "\<not> poincare_between v u w"
       thus "poincare_between u w v"
         using 1 2[rule_format, of "moebius_pt M w"]
         by simp
     qed
   qed
   thus ?thesis
     using assms
     by simp
 qed
 
 lemma poincare_collinear3_iff:
   assumes "u \<in> unit_disc" "v \<in> unit_disc"  "w \<in> unit_disc"
   shows "poincare_collinear {u, v, w} \<longleftrightarrow> poincare_between u v w \<or> poincare_between v u w \<or> poincare_between v w u"
   using assms 
   by (metis poincare_collinear3_between insert_commute poincare_between_poincare_collinear poincare_between_rev)
 
 subsection \<open>Some properties of betweenness\<close>
 
 lemma poincare_between_transitivity:
   assumes "a \<in> unit_disc" and "x \<in> unit_disc" and "b \<in> unit_disc" and "y \<in> unit_disc" and
           "poincare_between a x b" and "poincare_between a b y"
   shows "poincare_between x b y"
 proof(cases "a = b")
   case True
   thus ?thesis
     using assms
     using poincare_between_sandwich by blast
 next
   case False
   have "\<forall> x. \<forall> y. poincare_between a x b \<and> poincare_between a b y \<and> x \<in> unit_disc
                   \<and> y \<in> unit_disc \<longrightarrow> poincare_between x b y" (is "?P a b")
   proof (rule wlog_positive_x_axis[where P="?P"])
     show "a \<in> unit_disc"
       using assms by simp
   next
     show "b \<in> unit_disc"
       using assms by simp
   next
     show "a \<noteq> b"
       using False by simp
   next
     fix M u v
     assume *: "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v" 
               "\<forall>x y. poincare_between (moebius_pt M u) x (moebius_pt M v) \<and> 
                   poincare_between (moebius_pt M u) (moebius_pt M v) y \<and>
                   x \<in> unit_disc \<and> y \<in> unit_disc \<longrightarrow>
                   poincare_between x (moebius_pt M v) y"
     show "\<forall>x y. poincare_between u x v \<and> poincare_between u v y \<and> x \<in> unit_disc \<and> y \<in> unit_disc 
                 \<longrightarrow> poincare_between x v y"
     proof safe
       fix x y
       assume "poincare_between u x v" "poincare_between u v y" " x \<in> unit_disc" "y \<in> unit_disc"
 
       have "poincare_between (moebius_pt M u) (moebius_pt M x) (moebius_pt M v)" 
         using \<open>poincare_between u x v\<close> \<open>unit_disc_fix M\<close> \<open>x \<in> unit_disc\<close> \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close>
         by simp
       moreover
       have "poincare_between (moebius_pt M u) (moebius_pt M v) (moebius_pt M y)"
         using \<open>poincare_between u v y\<close> \<open>unit_disc_fix M\<close> \<open>y \<in> unit_disc\<close> \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close>
         by simp
       moreover
       have "(moebius_pt M x) \<in> unit_disc"
         using \<open>unit_disc_fix M\<close> \<open>x \<in> unit_disc\<close> by simp
       moreover
       have "(moebius_pt M y) \<in> unit_disc"
         using \<open>unit_disc_fix M\<close> \<open>y \<in> unit_disc\<close> by simp
       ultimately
       have "poincare_between (moebius_pt M x) (moebius_pt M v) (moebius_pt M y)"
         using * by blast
       thus "poincare_between x v y"
         using \<open>y \<in> unit_disc\<close> * \<open>x \<in> unit_disc\<close> by simp
     qed
   next
     fix x
     assume xx: "is_real x" "0 < Re x" "Re x < 1"
     hence "of_complex x \<in> unit_disc"
       using cmod_eq_Re by auto
     hence "of_complex x \<noteq> \<infinity>\<^sub>h"
       by simp
     have " of_complex x \<noteq> 0\<^sub>h"
       using xx by auto
     have "of_complex x \<in> circline_set x_axis"
       using xx by simp
     show "\<forall>m n. poincare_between 0\<^sub>h m (of_complex x) \<and> poincare_between 0\<^sub>h (of_complex x) n \<and>
             m \<in> unit_disc \<and> n \<in> unit_disc \<longrightarrow> poincare_between m (of_complex x) n"
     proof safe
       fix m n
       assume **: "poincare_between 0\<^sub>h m (of_complex x)" "poincare_between 0\<^sub>h (of_complex x) n"
                  "m \<in> unit_disc" " n \<in> unit_disc"
       show "poincare_between m (of_complex x) n"
       proof(cases "m = 0\<^sub>h")
         case True
         thus ?thesis
           using ** by auto
       next
         case False
         hence "m \<in> circline_set x_axis"
           using poincare_between_poincare_line_uzv[of "0\<^sub>h" "of_complex x" m]
           using poincare_line_0_real_is_x_axis[of "of_complex x"] 
           using \<open>of_complex x \<in> unit_disc\<close> \<open>of_complex x \<noteq> \<infinity>\<^sub>h\<close> \<open>of_complex x \<noteq> 0\<^sub>h\<close>
           using \<open>of_complex x \<in> circline_set x_axis\<close> \<open>m \<in> unit_disc\<close> **(1)
           by simp
         then obtain m' where "m = of_complex m'" "is_real m'"
           using inf_or_of_complex[of m] \<open>m \<in> unit_disc\<close>
           unfolding circline_set_x_axis
           by auto
         hence "Re m' \<le> Re x"
           using \<open>poincare_between 0\<^sub>h m (of_complex x)\<close> xx \<open>of_complex x \<noteq> 0\<^sub>h\<close>
           using False ** \<open>of_complex x \<in> unit_disc\<close>
           using cmod_Re_le_iff poincare_between_0uv by auto
  
         have "n \<noteq> 0\<^sub>h"
           using **(2, 4) \<open>of_complex x \<noteq> 0\<^sub>h\<close> \<open>of_complex x \<in> unit_disc\<close>
           using poincare_between_sandwich by fastforce
         have "n \<in> circline_set x_axis"
           using poincare_between_poincare_line_uvz[of "0\<^sub>h" "of_complex x" n]
           using poincare_line_0_real_is_x_axis[of "of_complex x"] 
           using \<open>of_complex x \<in> unit_disc\<close> \<open>of_complex x \<noteq> \<infinity>\<^sub>h\<close> \<open>of_complex x \<noteq> 0\<^sub>h\<close>
           using \<open>of_complex x \<in> circline_set x_axis\<close> \<open>n \<in> unit_disc\<close> **(2)
           by simp
         then obtain n' where "n = of_complex n'" "is_real n'"
           using inf_or_of_complex[of n] \<open>n \<in> unit_disc\<close>
           unfolding circline_set_x_axis
           by auto
         hence "Re x \<le> Re n'"
           using \<open>poincare_between 0\<^sub>h (of_complex x) n\<close> xx \<open>of_complex x \<noteq> 0\<^sub>h\<close>
           using False ** \<open>of_complex x \<in> unit_disc\<close> \<open>n \<noteq> 0\<^sub>h\<close>
           using cmod_Re_le_iff poincare_between_0uv
           by (metis Re_complex_of_real arg_0_iff rcis_cmod_Arg rcis_zero_arg to_complex_of_complex)
         
         have "poincare_between (of_complex m') (of_complex x) (of_complex n')" 
           using \<open>Re x \<le> Re n'\<close> \<open>Re m' \<le> Re x\<close>
           using poincare_between_x_axis_uvw[of "Re m'" "Re x" "Re n'"]
           using \<open>is_real n'\<close> \<open>is_real m'\<close> \<open>n \<in> unit_disc\<close> \<open>n = of_complex n'\<close>
           using xx \<open>m = of_complex m'\<close> \<open>m \<in> unit_disc\<close>
           by (smt complex_of_real_Re norm_of_real poincare_between_def unit_disc_iff_cmod_lt_1)
 
         thus ?thesis
           using \<open>n = of_complex n'\<close> \<open>m = of_complex m'\<close>
           by auto
       qed
     qed
   qed 
   thus ?thesis
     using assms
     by blast
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Poincare between - sum distances\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Another possible definition of the h-betweenness relation is given in terms of h-distances
 between pairs of points. We prove it as a characterization equivalent to our cross-ratio based
 definition.\<close>
 
 lemma poincare_between_sum_distances_x_axis_u0v:
   assumes "of_complex u' \<in> unit_disc" "of_complex v' \<in> unit_disc"
   assumes "is_real u'" "u' \<noteq> 0" "v' \<noteq> 0"
   shows  "poincare_distance (of_complex u') 0\<^sub>h + poincare_distance 0\<^sub>h (of_complex v') = poincare_distance (of_complex u') (of_complex v') \<longleftrightarrow>
           is_real v' \<and> Re u' * Re v' < 0" (is "?P u' v' \<longleftrightarrow> ?Q u' v'")
 proof-
   have "Re u' \<noteq> 0"
     using \<open>is_real u'\<close> \<open>u' \<noteq> 0\<close>
     using complex_eq_if_Re_eq
     by simp
 
   let ?u = "cmod u'" and ?v = "cmod v'" and ?uv = "cmod (u' - v')"
   have disc: "?u\<^sup>2 < 1" "?v\<^sup>2 < 1"
     using unit_disc_cmod_square_lt_1[OF assms(1)]
     using unit_disc_cmod_square_lt_1[OF assms(2)]
     by auto
   have "poincare_distance (of_complex u') 0\<^sub>h + poincare_distance 0\<^sub>h (of_complex v') =
               arcosh (((1 + ?u\<^sup>2) * (1 + ?v\<^sup>2) + 4 * ?u * ?v) / ((1 - ?u\<^sup>2) * (1 - ?v\<^sup>2)))" (is "_ = arcosh ?r1")
           using poincare_distance_formula_zero_sum[OF assms(1-2)]
           by (simp add: Let_def)
   moreover
   have "poincare_distance (of_complex u') (of_complex v') =
               arcosh (((1 - ?u\<^sup>2) * (1 - ?v\<^sup>2) + 2 * ?uv\<^sup>2) / ((1 - ?u\<^sup>2) * (1 - ?v\<^sup>2)))" (is "_ = arcosh ?r2")
     using disc
     using poincare_distance_formula[OF assms(1-2)]
     by (subst add_divide_distrib) simp
   moreover
   have "arcosh ?r1 = arcosh ?r2 \<longleftrightarrow> ?Q u' v'"
   proof
     assume "arcosh ?r1 = arcosh ?r2"
     hence "?r1 = ?r2"
     proof (subst (asm) arcosh_eq_iff)
       show "?r1 \<ge> 1"
       proof-
         have "(1 - ?u\<^sup>2) * (1 - ?v\<^sup>2) \<le> (1 + ?u\<^sup>2) * (1 + ?v\<^sup>2) + 4 * ?u * ?v"
           by (simp add: field_simps)
         thus ?thesis
           using disc
           by simp
       qed
     next
       show "?r2 \<ge> 1"
         using disc
         by simp
     qed
     hence "(1 + ?u\<^sup>2) * (1 + ?v\<^sup>2) + 4 * ?u * ?v = (1 - ?u\<^sup>2) * (1 - ?v\<^sup>2) + 2 * ?uv\<^sup>2"
       using disc
       by auto              
     hence "(cmod (u' - v'))\<^sup>2 = (cmod u' + cmod v')\<^sup>2"
       by (simp add: field_simps power2_eq_square)
     hence *: "Re u' * Re v' + \<bar>Re u'\<bar> * sqrt ((Im v')\<^sup>2 + (Re v')\<^sup>2) = 0"
       using \<open>is_real u'\<close>
       unfolding cmod_power2 cmod_def
       by (simp add: field_simps) (simp add: power2_eq_square field_simps)
     hence "sqrt ((Im v')\<^sup>2 + (Re v')\<^sup>2) = \<bar>Re v'\<bar>"
       using \<open>Re u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close>
       by (smt complex_neq_0 mult.commute mult_cancel_right mult_minus_left real_sqrt_gt_0_iff)
     hence "Im v' = 0"
       by (smt Im_eq_0 norm_complex_def)
     moreover
     hence "Re u' * Re v' = - \<bar>Re u'\<bar> * \<bar>Re v'\<bar>"
       using *
       by simp
     hence "Re u' * Re v' < 0"
       using \<open>Re u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close>
       by (simp add: \<open>is_real v'\<close> complex_eq_if_Re_eq)
     ultimately
     show "?Q u' v'"
       by simp
   next
     assume "?Q u' v'"
     hence "is_real v'" "Re u' * Re v' < 0"
       by auto
     have "?r1 = ?r2"
     proof (cases "Re u' > 0")
       case True
       hence "Re v' < 0"
         using \<open>Re u' * Re v' < 0\<close>
         by (smt zero_le_mult_iff)
       show ?thesis
         using disc \<open>is_real u'\<close> \<open>is_real v'\<close>
         using \<open>Re u' > 0\<close> \<open>Re v' < 0\<close>
         unfolding cmod_power2 cmod_def
         by simp (simp add: power2_eq_square field_simps)
     next
       case False
       hence "Re u' < 0"
         using \<open>Re u' \<noteq> 0\<close>
         by simp
       hence "Re v' > 0"
         using \<open>Re u' * Re v' < 0\<close>
         by (smt zero_le_mult_iff)
       show ?thesis
         using disc \<open>is_real u'\<close> \<open>is_real v'\<close>
         using \<open>Re u' < 0\<close> \<open>Re v' > 0\<close>
         unfolding cmod_power2 cmod_def
         by simp (simp add: power2_eq_square field_simps)
     qed
     thus "arcosh ?r1 = arcosh ?r2"
       by metis
   qed
   ultimately
   show ?thesis
     by simp
 qed
 
 text\<open>
   Different proof of the previous theorem relying on the cross-ratio definition, and not the distance formula.
   We suppose that this could be also used to prove the triangle inequality.
 \<close>
 lemma poincare_between_sum_distances_x_axis_u0v_different_proof:
   assumes "of_complex u' \<in> unit_disc" "of_complex v' \<in> unit_disc"
   assumes "is_real u'" "u' \<noteq> 0" "v' \<noteq> 0" (* additional condition *) "is_real v'"
   shows  "poincare_distance (of_complex u') 0\<^sub>h + poincare_distance 0\<^sub>h (of_complex v') = poincare_distance (of_complex u') (of_complex v') \<longleftrightarrow>
           Re u' * Re v' < 0" (is "?P u' v' \<longleftrightarrow> ?Q u' v'")
 proof-
   have "-1 < Re u'" "Re u' < 1" "Re u' \<noteq> 0"
     using assms
     by (auto simp add: cmod_eq_Re complex_eq_if_Re_eq)
   have "-1 < Re v'" "Re v' < 1" "Re v' \<noteq> 0"
     using assms
     by (auto simp add: cmod_eq_Re complex_eq_if_Re_eq)
 
   have "\<bar>ln (Re ((1 - u') / (1 + u')))\<bar> + \<bar>ln (Re ((1 - v') / (1 + v')))\<bar> =
         \<bar>ln (Re ((1 + u') * (1 - v') / ((1 - u') * (1 + v'))))\<bar> \<longleftrightarrow> Re u' * Re v' < 0" (is "\<bar>ln ?a1\<bar>  + \<bar>ln ?a2\<bar> = \<bar>ln ?a3\<bar> \<longleftrightarrow> _")
   proof-
     have 1: "0 < ?a1" "ln ?a1 > 0 \<longleftrightarrow> Re u' < 0"
       using \<open>Re u' < 1\<close> \<open>Re u' > -1\<close> \<open>is_real u'\<close>
       using complex_is_Real_iff
       by auto
     have 2: "0 < ?a2" "ln ?a2 > 0 \<longleftrightarrow> Re v' < 0"
       using \<open>Re v' < 1\<close> \<open>Re v' > -1\<close> \<open>is_real v'\<close>
       using complex_is_Real_iff
       by auto
     have 3: "0 < ?a3" "ln ?a3 > 0 \<longleftrightarrow> Re v' < Re u'"
       using \<open>Re u' < 1\<close> \<open>Re u' > -1\<close> \<open>is_real u'\<close>
       using \<open>Re v' < 1\<close> \<open>Re v' > -1\<close> \<open>is_real v'\<close>
       using complex_is_Real_iff
        by auto (simp add: field_simps)+
     show ?thesis
     proof
       assume *: "Re u' * Re v' < 0"
       show "\<bar>ln ?a1\<bar> + \<bar>ln ?a2\<bar> = \<bar>ln ?a3\<bar>"
       proof (cases "Re u' > 0")
         case True
         hence "Re v' < 0"
           using *
           by (smt mult_nonneg_nonneg)
         show ?thesis
           using 1 2 3 \<open>Re u' > 0\<close> \<open>Re v' < 0\<close>
           using \<open>Re u' < 1\<close> \<open>Re u' > -1\<close> \<open>is_real u'\<close>
           using \<open>Re v' < 1\<close> \<open>Re v' > -1\<close> \<open>is_real v'\<close>
           using complex_is_Real_iff
           using ln_div ln_mult
           by simp
       next
         case False
         hence "Re v' > 0" "Re u' < 0"
           using *
           by (smt zero_le_mult_iff)+
         show ?thesis
           using 1 2 3 \<open>Re u' < 0\<close> \<open>Re v' > 0\<close>
           using \<open>Re u' < 1\<close> \<open>Re u' > -1\<close> \<open>is_real u'\<close>
           using \<open>Re v' < 1\<close> \<open>Re v' > -1\<close> \<open>is_real v'\<close>
           using complex_is_Real_iff
           using ln_div ln_mult
           by simp
       qed
     next
       assume *: "\<bar>ln ?a1\<bar> + \<bar>ln ?a2\<bar> = \<bar>ln ?a3\<bar>"
       {
         assume "Re u' > 0" "Re v' > 0"
         hence False
           using * 1 2 3
           using \<open>Re u' < 1\<close> \<open>Re u' > -1\<close> \<open>is_real u'\<close>
           using \<open>Re v' < 1\<close> \<open>Re v' > -1\<close> \<open>is_real v'\<close>
           using complex_is_Real_iff
           using ln_mult ln_div
           by (cases "Re v' < Re u'") auto
       }
       moreover
       {
         assume "Re u' < 0" "Re v' < 0"
         hence False
           using * 1 2 3
           using \<open>Re u' < 1\<close> \<open>Re u' > -1\<close> \<open>is_real u'\<close>
           using \<open>Re v' < 1\<close> \<open>Re v' > -1\<close> \<open>is_real v'\<close>
           using complex_is_Real_iff
           using ln_mult ln_div
           by (cases "Re v' < Re u'") auto
       }
       ultimately
       show "Re u' * Re v' < 0"
         using \<open>Re u' \<noteq> 0\<close> \<open>Re v' \<noteq> 0\<close>
         by (smt divisors_zero mult_le_0_iff)
     qed
   qed
   thus ?thesis
     using assms
     apply (subst poincare_distance_sym, simp, simp)
     apply (subst poincare_distance_zero_x_axis, simp, simp add: circline_set_x_axis)
     apply (subst poincare_distance_zero_x_axis, simp, simp add: circline_set_x_axis)
     apply (subst poincare_distance_x_axis_x_axis, simp, simp, simp add: circline_set_x_axis, simp add: circline_set_x_axis)
     apply simp
     done
 qed
 
 lemma poincare_between_sum_distances:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "w \<in> unit_disc"
   shows "poincare_between u v w \<longleftrightarrow> 
          poincare_distance u v + poincare_distance v w = poincare_distance u w" (is "?P' u v w")
 proof (cases "u = v")
   case True
   thus ?thesis
     using assms
     by simp
 next
   case False
   have "\<forall> w. w \<in> unit_disc \<longrightarrow> (poincare_between u v w \<longleftrightarrow> poincare_distance u v + poincare_distance v w = poincare_distance u w)" (is "?P u v")
   proof (rule wlog_positive_x_axis)
     fix x
     assume "is_real x" "0 < Re x" "Re x < 1"
     have "of_complex x \<in> circline_set x_axis"
       using \<open>is_real x\<close>
       by (auto simp add: circline_set_x_axis)
 
     have "of_complex x \<in> unit_disc"
       using \<open>is_real x\<close> \<open>0 < Re x\<close> \<open>Re x < 1\<close>
       by (simp add: cmod_eq_Re)
 
     have "x \<noteq> 0"
       using \<open>is_real x\<close> \<open>Re x > 0\<close>
       by auto
 
     show "?P (of_complex x) 0\<^sub>h"
     proof (rule allI, rule impI)
       fix w
       assume "w \<in> unit_disc"
       then obtain w' where "w = of_complex w'"
         using inf_or_of_complex[of w]
         by auto
 
       show "?P' (of_complex x) 0\<^sub>h w"
       proof (cases "w = 0\<^sub>h")
         case True
         thus ?thesis
           by simp
       next
         case False
         hence "w' \<noteq> 0"
           using \<open>w = of_complex w'\<close>
           by auto
 
         show ?thesis
           using \<open>is_real x\<close> \<open>x \<noteq> 0\<close> \<open>w = of_complex w'\<close> \<open>w' \<noteq> 0\<close>
           using \<open>of_complex x \<in> unit_disc\<close> \<open>w \<in> unit_disc\<close>
           apply simp
           apply (subst poincare_between_x_axis_u0v, simp_all)
           apply (subst poincare_between_sum_distances_x_axis_u0v, simp_all)
           done
       qed
     qed
   next
     show "v \<in> unit_disc" "u \<in> unit_disc"
       using assms
       by auto
   next
     show "v \<noteq> u"
       using \<open>u \<noteq> v\<close>
       by simp
   next
     fix M u v
     assume *: "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v" and
           **: "?P (moebius_pt M v) (moebius_pt M u)"
     show "?P v u"
     proof (rule allI, rule impI)
       fix w
       assume "w \<in> unit_disc"
       hence "moebius_pt M w \<in> unit_disc"
         using \<open>unit_disc_fix M\<close>
         by auto
       thus "?P' v u w"
         using \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close> \<open>w \<in> unit_disc\<close> \<open>unit_disc_fix M\<close>
         using **[rule_format, of "moebius_pt M w"]
         by auto
     qed
   qed
   thus ?thesis
     using assms
     by simp
 qed
 
 subsection \<open>Some more properties of h-betweenness.\<close>
 
 text \<open>Some lemmas proved earlier are proved almost directly using the sum of distances characterization.\<close>
 
 lemma unit_disc_fix_moebius_preserve_poincare_between':
   assumes "unit_disc_fix M" and "u \<in> unit_disc" and "v \<in> unit_disc" and "w \<in> unit_disc"
   shows "poincare_between (moebius_pt M u) (moebius_pt M v) (moebius_pt M w) \<longleftrightarrow>
          poincare_between u v w"
   using assms
   using poincare_between_sum_distances
   by simp
 
 lemma conjugate_preserve_poincare_between':
   assumes "u \<in> unit_disc" "v \<in> unit_disc" "w \<in> unit_disc"
   shows "poincare_between (conjugate u) (conjugate v) (conjugate w) \<longleftrightarrow> poincare_between u v w"
   using assms
   using poincare_between_sum_distances
   by simp
 
 text \<open>There is a unique point on a ray on the given distance from the given starting point\<close>
 lemma unique_poincare_distance_on_ray:
   assumes "d \<ge> 0" "u \<noteq> v" "u \<in> unit_disc" "v \<in> unit_disc"
   assumes "y \<in> unit_disc" "poincare_distance u y = d" "poincare_between u v y"
   assumes "z \<in> unit_disc" "poincare_distance u z = d" "poincare_between u v z"
   shows "y = z"
 proof-
   have "\<forall> d y z. d \<ge> 0 \<and>
         y \<in> unit_disc \<and> poincare_distance u y = d \<and> poincare_between u v y \<and>
         z \<in> unit_disc \<and> poincare_distance u z = d \<and> poincare_between u v z \<longrightarrow> y = z" (is "?P u v")
   proof (rule wlog_positive_x_axis[where P="?P"])
     fix x
     assume x: "is_real x" "0 < Re x" "Re x < 1"
     hence "x \<noteq> 0"
       using complex.expand[of x 0]
       by auto
     hence *: "poincare_line 0\<^sub>h (of_complex x) = x_axis"
       using x poincare_line_0_real_is_x_axis[of "of_complex x"]
       unfolding circline_set_x_axis
       by auto
     have "of_complex x \<in> unit_disc"
       using x
       by (auto simp add: cmod_eq_Re)
-    have "arg x = 0"
+    have "Arg x = 0"
       using x
       using arg_0_iff by blast
     show "?P 0\<^sub>h (of_complex x)"
     proof safe
       fix y z
       assume "y \<in> unit_disc" "z \<in> unit_disc"
       then obtain y' z' where yz: "y = of_complex y'" "z = of_complex z'"
         using inf_or_of_complex[of y] inf_or_of_complex[of z]
         by auto
       assume betw: "poincare_between 0\<^sub>h (of_complex x) y"  "poincare_between 0\<^sub>h (of_complex x) z"
       hence "y \<noteq> 0\<^sub>h" "z \<noteq> 0\<^sub>h"
         using \<open>x \<noteq> 0\<close> \<open>of_complex x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close>
         using poincare_between_sandwich[of "0\<^sub>h" "of_complex x"]
         using of_complex_zero_iff[of x]
         by force+
 
-      hence "arg y' = 0" "cmod y' \<ge> cmod x" "arg z' = 0" "cmod z' \<ge> cmod x"
+      hence "Arg y' = 0" "cmod y' \<ge> cmod x" "Arg z' = 0" "cmod z' \<ge> cmod x"
         using poincare_between_0uv[of "of_complex x" y] poincare_between_0uv[of "of_complex x" z]
-        using \<open>of_complex x \<in> unit_disc\<close> \<open>x \<noteq> 0\<close> \<open>arg x = 0\<close> \<open>y \<in> unit_disc\<close> \<open>z \<in> unit_disc\<close> betw yz
+        using \<open>of_complex x \<in> unit_disc\<close> \<open>x \<noteq> 0\<close> \<open>Arg x = 0\<close> \<open>y \<in> unit_disc\<close> \<open>z \<in> unit_disc\<close> betw yz
         by (simp_all add: Let_def)
       hence *: "is_real y'" "is_real z'" "Re y' > 0" "Re z' > 0"
         using arg_0_iff[of y'] arg_0_iff[of z'] x \<open>y \<noteq> 0\<^sub>h\<close> \<open>z \<noteq> 0\<^sub>h\<close> yz
         by auto
       assume "poincare_distance 0\<^sub>h z = poincare_distance 0\<^sub>h y" "0 \<le> poincare_distance 0\<^sub>h y"
       thus "y = z"
         using * yz \<open>y \<in> unit_disc\<close> \<open>z \<in> unit_disc\<close>
         using unique_x_axis_poincare_distance_positive[of "poincare_distance 0\<^sub>h y"]
         by (auto simp add: cmod_eq_Re unit_disc_to_complex_inj)
     qed
   next
     show "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
       by fact+
   next
     fix M u v
     assume *: "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
     assume **: "?P (moebius_pt M u) (moebius_pt M v)"
     show "?P u v"
     proof safe
       fix d y z
       assume ***: "0 \<le> poincare_distance u y"
              "y \<in> unit_disc" "poincare_between u v y"
              "z \<in> unit_disc" "poincare_between u v z"
              "poincare_distance u z = poincare_distance u y"
       let ?Mu = "moebius_pt M u" and ?Mv = "moebius_pt M v" and ?My = "moebius_pt M y" and ?Mz = "moebius_pt M z"
       have "?Mu \<in> unit_disc" "?Mv \<in> unit_disc" "?My \<in> unit_disc" "?Mz \<in> unit_disc"
         using \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>z \<in> unit_disc\<close>
         using \<open>unit_disc_fix M\<close>
         by auto
       hence "?My = ?Mz"
         using * ***
         using **[rule_format, of "poincare_distance ?Mu ?My" ?My ?Mz]
         by simp
       thus "y = z"
         using bij_moebius_pt[of M]
         unfolding bij_def inj_on_def
         by blast
     qed
   qed
   thus ?thesis
     using assms
     by auto
 qed
 
 end
\ No newline at end of file
diff --git a/thys/Poincare_Disc/Poincare_Lines.thy b/thys/Poincare_Disc/Poincare_Lines.thy
--- a/thys/Poincare_Disc/Poincare_Lines.thy
+++ b/thys/Poincare_Disc/Poincare_Lines.thy
@@ -1,1878 +1,1878 @@
 (* ------------------------------------------------------------------ *)
 section \<open>H-lines in the Poincar\'e model\<close>
 (* ------------------------------------------------------------------ *)
 
 theory Poincare_Lines
   imports Complex_Geometry.Unit_Circle_Preserving_Moebius Complex_Geometry.Circlines_Angle
 begin
 
 
 (* ------------------------------------------------------------------ *)
 subsection \<open>Definition and basic properties of h-lines\<close>
 (* ------------------------------------------------------------------ *)
 
 text \<open>H-lines in the Poincar\'e model are either line segments passing trough the origin or
 segments (within the unit disc) of circles that are perpendicular to the unit circle. Algebraically
 these are circlines that are represented by Hermitean matrices of
 the form
 $$H = \left(
  \begin{array}{cc}
  A & B\\
  \overline{B} & A
  \end{array}
 \right),$$
 for $A \in \mathbb{R}$, and $B \in \mathbb{C}$, and $|B|^2 > A^2$,
 where the circline equation is the usual one: $z^*Hz = 0$, for homogenous coordinates $z$.\<close>
 
 definition is_poincare_line_cmat :: "complex_mat \<Rightarrow> bool" where
   [simp]: "is_poincare_line_cmat H \<longleftrightarrow>
              (let (A, B, C, D) = H
                in hermitean (A, B, C, D) \<and> A = D \<and> (cmod B)\<^sup>2 > (cmod A)\<^sup>2)"
 
 lift_definition is_poincare_line_clmat :: "circline_mat \<Rightarrow> bool" is is_poincare_line_cmat
   done
 
 text \<open>We introduce the predicate that checks if a given complex matrix is a matrix of a h-line in
 the Poincar\'e model, and then by means of the lifting package lift it to the type of non-zero
 Hermitean matrices, and then to circlines (that are equivalence classes of such matrices).\<close>
 
 lift_definition is_poincare_line :: "circline \<Rightarrow> bool" is is_poincare_line_clmat
 proof (transfer, transfer)
   fix H1 H2 :: complex_mat
   assume hh: "hermitean H1 \<and> H1 \<noteq> mat_zero" "hermitean H2 \<and> H2 \<noteq> mat_zero"
   assume "circline_eq_cmat H1 H2"
   thus "is_poincare_line_cmat H1 \<longleftrightarrow> is_poincare_line_cmat H2"
     using hh
     by (cases H1, cases H2) (auto simp: norm_mult power_mult_distrib)
 qed
 
 lemma is_poincare_line_mk_circline:
   assumes "(A, B, C, D) \<in> hermitean_nonzero"
   shows "is_poincare_line (mk_circline A B C D) \<longleftrightarrow> (cmod B)\<^sup>2 > (cmod A)\<^sup>2 \<and> A = D"
   using assms
   by (transfer, transfer, auto simp add: Let_def)
 
 
 text\<open>Abstract characterisation of @{term is_poincare_line} predicate: H-lines in the Poincar\'e
 model are real circlines (circlines with the negative determinant) perpendicular to the unit
 circle.\<close>
 
 lemma is_poincare_line_iff:
   shows "is_poincare_line H \<longleftrightarrow> circline_type H = -1 \<and> perpendicular H unit_circle"
   unfolding perpendicular_def
 proof (simp, transfer, transfer)
   fix H
   assume hh: "hermitean H \<and> H \<noteq> mat_zero"
   obtain A B C D where *: "H = (A, B, C, D)"
     by (cases H, auto)
   have **: "is_real A" "is_real D" "C = cnj B"
     using hh * hermitean_elems
     by auto
   hence "(Re A = Re D \<and> cmod A * cmod A < cmod B * cmod B) =
          (Re A * Re D < Re B * Re B + Im B * Im B \<and> (Re D = Re A \<or> Re A * Re D = Re B * Re B + Im B * Im B))"
     using *
     by (smt cmod_power2 power2_eq_square zero_power2)+
   thus "is_poincare_line_cmat H \<longleftrightarrow>
          circline_type_cmat H = - 1 \<and> cos_angle_cmat (of_circline_cmat H) unit_circle_cmat = 0"
     using * **
     by (auto simp add: sgn_1_neg complex_eq_if_Re_eq cmod_square power2_eq_square simp del: pos_oriented_cmat_def)
 qed
 
 text\<open>The @{term x_axis} is an h-line.\<close>
 lemma is_poincare_line_x_axis [simp]:
   shows "is_poincare_line x_axis"
   by (transfer, transfer) (auto simp add: hermitean_def mat_adj_def mat_cnj_def)
 
 text\<open>The @{term unit_circle} is not an h-line.\<close>
 lemma not_is_poincare_line_unit_circle [simp]:
   shows "\<not> is_poincare_line unit_circle"
   by (transfer, transfer, simp)
 
 (* ------------------------------------------------------------------ *)
 subsubsection \<open>Collinear points\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Points are collinear if they all belong to an h-line. \<close>
 definition poincare_collinear :: "complex_homo set \<Rightarrow> bool" where
   "poincare_collinear S \<longleftrightarrow> (\<exists> p. is_poincare_line p \<and> S \<subseteq> circline_set p)"
 
 (* ------------------------------------------------------------------ *)
 subsubsection \<open>H-lines and inversion\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Every h-line in the Poincar\'e model contains the inverse (wrt.~the unit circle) of each of its
 points (note that at most one of them belongs to the unit disc).\<close>
 lemma is_poincare_line_inverse_point:
   assumes "is_poincare_line H" "u \<in> circline_set H"
   shows "inversion u \<in> circline_set H"
   using assms
   unfolding is_poincare_line_iff circline_set_def perpendicular_def inversion_def
   apply simp
 proof (transfer, transfer)
   fix u H
   assume hh: "hermitean H \<and> H \<noteq> mat_zero" "u \<noteq> vec_zero" and
          aa: "circline_type_cmat H = - 1 \<and> cos_angle_cmat (of_circline_cmat H) unit_circle_cmat = 0" "on_circline_cmat_cvec H u"
   obtain A B C D u1 u2 where *: "H = (A, B, C, D)" "u = (u1, u2)"
     by (cases H, cases u, auto)
   have "is_real A" "is_real D" "C = cnj B"
     using * hh hermitean_elems
     by auto
   moreover
   have "A = D"
     using aa(1) * \<open>is_real A\<close> \<open>is_real D\<close>
     by (auto simp del: pos_oriented_cmat_def simp add: complex.expand split: if_split_asm)
   thus "on_circline_cmat_cvec H (conjugate_cvec (reciprocal_cvec u))"
     using aa(2) *
     by (simp add: vec_cnj_def field_simps)
 qed
 
 text\<open>Every h-line in the Poincar\'e model and is invariant under unit circle inversion.\<close>
 
 lemma circline_inversion_poincare_line:
   assumes "is_poincare_line H"
   shows "circline_inversion H = H"
 proof-
   obtain u v w where *: "u \<noteq> v" "v \<noteq> w" "u \<noteq> w" "{u, v, w} \<subseteq> circline_set H"
     using assms is_poincare_line_iff[of H]
     using circline_type_neg_card_gt3[of H]
     by auto
   hence "{inversion u, inversion v, inversion w} \<subseteq> circline_set (circline_inversion H)"
         "{inversion u, inversion v, inversion w} \<subseteq> circline_set H"
     using is_poincare_line_inverse_point[OF assms]
     by auto
   thus ?thesis
     using * unique_circline_set[of "inversion u" "inversion v" "inversion w"]
     by (metis insert_subset inversion_involution)
 qed
 
 (* ------------------------------------------------------------------ *)
 subsubsection \<open>Classification of h-lines into Euclidean segments and circles\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>If an h-line contains zero, than it also contains infinity (the inverse point of zero) and is by
 definition an Euclidean line.\<close>
 lemma is_poincare_line_trough_zero_trough_infty [simp]:
   assumes "is_poincare_line l" and "0\<^sub>h \<in> circline_set l"
   shows "\<infinity>\<^sub>h \<in> circline_set l"
   using is_poincare_line_inverse_point[OF assms]
   by simp
 
 lemma is_poincare_line_trough_zero_is_line:
   assumes "is_poincare_line l" and "0\<^sub>h \<in> circline_set l"
   shows "is_line l"
   using assms
   using inf_in_circline_set is_poincare_line_trough_zero_trough_infty
   by blast
 
 text\<open>If an h-line does not contain zero, than it also does not contain infinity (the inverse point of
 zero) and is by definition an Euclidean circle.\<close>
 lemma is_poincare_line_not_trough_zero_not_trough_infty [simp]:
   assumes "is_poincare_line l"
   assumes "0\<^sub>h \<notin> circline_set l"
   shows "\<infinity>\<^sub>h \<notin> circline_set l"
   using assms
   using is_poincare_line_inverse_point[OF assms(1), of "\<infinity>\<^sub>h"]
   by auto
 
 lemma is_poincare_line_not_trough_zero_is_circle:
   assumes "is_poincare_line l" "0\<^sub>h \<notin> circline_set l"
   shows "is_circle l"
   using assms
   using inf_in_circline_set is_poincare_line_not_trough_zero_not_trough_infty
   by auto
 
 (* ------------------------------------------------------------------ *)
 subsubsection\<open>Points on h-line\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Each h-line in the Poincar\'e model contains at least two different points within the unit
 disc.\<close>
 
 text\<open>First we prove an auxiliary lemma.\<close>
 lemma ex_is_poincare_line_points':
   assumes i12: "i1 \<in> circline_set H \<inter> unit_circle_set"
                "i2 \<in> circline_set H \<inter> unit_circle_set"
                "i1 \<noteq> i2"
   assumes a: "a \<in> circline_set H" "a \<notin> unit_circle_set"
   shows "\<exists> b. b \<noteq> i1 \<and> b \<noteq> i2 \<and> b \<noteq> a \<and> b \<noteq> inversion a \<and> b \<in> circline_set H"
 proof-
   have "inversion a \<notin> unit_circle_set"
     using \<open>a \<notin> unit_circle_set\<close> 
     unfolding unit_circle_set_def circline_set_def
     by (metis inversion_id_iff_on_unit_circle inversion_involution mem_Collect_eq)
 
   have "a \<noteq> inversion a"
     using \<open>a \<notin> unit_circle_set\<close> inversion_id_iff_on_unit_circle[of a]
     unfolding unit_circle_set_def circline_set_def
     by auto
 
   have "a \<noteq> i1" "a \<noteq> i2" "inversion a \<noteq> i1" "inversion a \<noteq> i2"
     using assms \<open>inversion a \<notin> unit_circle_set\<close>
     by auto
 
   then obtain b where cr2: "cross_ratio b i1 a i2 = of_complex 2"
     using \<open>i1 \<noteq> i2\<close>
     using ex_cross_ratio[of i1 a i2]
     by blast
 
   have distinct_b: "b \<noteq> i1" "b \<noteq> i2" "b \<noteq> a"
     using \<open>i1 \<noteq> i2\<close> \<open>a \<noteq> i1\<close> \<open>a \<noteq> i2\<close>
     using ex1_cross_ratio[of i1 a i2]
     using cross_ratio_0[of i1 a i2] cross_ratio_1[of i1 a i2] cross_ratio_inf[of i1 i2 a]
     using cr2
     by auto
 
   hence "b \<in> circline_set H" 
     using assms four_points_on_circline_iff_cross_ratio_real[of b i1 a i2] cr2
     using unique_circline_set[of i1 i2 a]
     by auto
 
   moreover
 
   have "b \<noteq> inversion a"
   proof (rule ccontr)
     assume *: "\<not> ?thesis"
     have "inversion i1 = i1" "inversion i2 = i2"
       using i12
       unfolding unit_circle_set_def
       by auto
     hence "cross_ratio (inversion a) i1 a i2 = cross_ratio a i1 (inversion a) i2"
       using * cross_ratio_inversion[of i1 a i2 b] \<open>a \<noteq> i1\<close> \<open>a \<noteq> i2\<close> \<open>i1 \<noteq> i2\<close> \<open>b \<noteq> i1\<close>
       using four_points_on_circline_iff_cross_ratio_real[of b i1 a i2]
       using i12 distinct_b conjugate_id_iff[of "cross_ratio b i1 a i2"]
       using i12 a \<open>b \<in> circline_set H\<close>            
       by auto
     hence "cross_ratio (inversion a) i1 a i2 \<noteq> of_complex 2"
       using cross_ratio_commute_13[of "inversion a" i1 a i2]
       using reciprocal_id_iff
       using of_complex_inj
       by force
     thus False
       using * cr2
       by simp
   qed
 
   ultimately
   show ?thesis
     using assms \<open>b \<noteq> i1\<close> \<open>b \<noteq> i2\<close> \<open>b \<noteq> a\<close>
     by auto
 qed
 
 text\<open>Now we can prove the statement.\<close>
 lemma ex_is_poincare_line_points:
   assumes "is_poincare_line H"
   shows "\<exists> u v. u \<in> unit_disc \<and> v \<in> unit_disc \<and> u \<noteq> v \<and> {u, v} \<subseteq> circline_set H"
 proof-
   obtain u v w where *: "u \<noteq> v" "v \<noteq> w" "u \<noteq> w" "{u, v, w} \<subseteq> circline_set H"
     using assms is_poincare_line_iff[of H]
     using circline_type_neg_card_gt3[of H]
     by auto
 
   have "\<not> {u, v, w} \<subseteq> unit_circle_set"
     using unique_circline_set[of u v w] *
     by (metis assms insert_subset not_is_poincare_line_unit_circle unit_circle_set_def)
 
   hence "H \<noteq> unit_circle"
     unfolding unit_circle_set_def
     using *
     by auto
 
   show ?thesis
   proof (cases "(u \<in> unit_disc \<and> v \<in> unit_disc) \<or>
                 (u \<in> unit_disc \<and> w \<in> unit_disc) \<or>
                 (v \<in> unit_disc \<and> w \<in> unit_disc)")
     case True
     thus ?thesis
       using *
       by auto
   next
     case False
 
     have "\<exists> a b. a \<noteq> b \<and> a \<noteq> inversion b \<and> a \<in> circline_set H \<and> b \<in> circline_set H \<and> a \<notin> unit_circle_set \<and> b \<notin> unit_circle_set"
     proof (cases "(u \<in> unit_circle_set \<and> v \<in> unit_circle_set) \<or>
                   (u \<in> unit_circle_set \<and> w \<in> unit_circle_set) \<or>
                   (v \<in> unit_circle_set \<and> w \<in> unit_circle_set)")
       case True
       then obtain i1 i2 a where *:
         "i1 \<in> unit_circle_set \<inter> circline_set H" "i2 \<in> unit_circle_set \<inter> circline_set H" 
         "a \<in> circline_set H" "a \<notin> unit_circle_set"
         "i1 \<noteq> i2" "i1 \<noteq> a" "i2 \<noteq> a"
         using * \<open>\<not> {u, v, w} \<subseteq> unit_circle_set\<close>
         by auto
       then obtain b where "b \<in> circline_set H" "b \<noteq> i1" "b \<noteq> i2" "b \<noteq> a" "b \<noteq> inversion a"
         using ex_is_poincare_line_points'[of i1 H i2 a]
         by blast
 
       hence "b \<notin> unit_circle_set"
         using * \<open>H \<noteq> unit_circle\<close> unique_circline_set[of i1 i2 b]
         unfolding unit_circle_set_def
         by auto
         
       thus ?thesis
         using * \<open>b \<in> circline_set H\<close> \<open>b \<noteq> a\<close> \<open>b \<noteq> inversion a\<close>
         by auto
     next
       case False  
       then obtain f g h where
         *: "f \<noteq> g" "f \<in> circline_set H" "f \<notin> unit_circle_set"  
                     "g \<in> circline_set H" "g \<notin> unit_circle_set"
                     "h \<in> circline_set H" "h \<noteq> f" "h \<noteq> g"
         using *
         by auto
       show ?thesis
       proof (cases "f = inversion g")   
         case False
         thus ?thesis
           using *
           by auto
       next
         case True
         show ?thesis
         proof (cases "h \<in> unit_circle_set")
           case False
           thus ?thesis
             using * \<open>f = inversion g\<close>
             by auto
         next
           case True
           obtain m where cr2: "cross_ratio m h f g = of_complex 2"
             using ex_cross_ratio[of h f g] * \<open>f \<noteq> g\<close> \<open>h \<noteq> f\<close> \<open>h \<noteq> g\<close>
             by auto
           hence "m \<noteq> h" "m \<noteq> f" "m \<noteq> g"
             using \<open>h \<noteq> f\<close> \<open>h \<noteq> g\<close> \<open>f \<noteq> g\<close>
             using ex1_cross_ratio[of h f g]
             using cross_ratio_0[of h f g] cross_ratio_1[of h f g] cross_ratio_inf[of h g f]
             using cr2
             by auto
           hence "m \<in> circline_set H" 
             using four_points_on_circline_iff_cross_ratio_real[of m h f g] cr2
             using \<open>h \<noteq> f\<close> \<open>h \<noteq> g\<close> \<open>f \<noteq> g\<close> *
             using unique_circline_set[of h f g]
             by auto
 
           show ?thesis
           proof (cases "m \<in> unit_circle_set")
             case False
             thus ?thesis
               using \<open>m \<noteq> f\<close> \<open>m \<noteq> g\<close> \<open>f = inversion g\<close> * \<open>m \<in> circline_set H\<close>
               by auto
           next
             case True
             then obtain n where "n \<noteq> h" "n \<noteq> m" "n \<noteq> f" "n \<noteq> inversion f" "n \<in> circline_set H"
               using ex_is_poincare_line_points'[of h H m f] * \<open>m \<in> circline_set H\<close> \<open>h \<in> unit_circle_set\<close> \<open>m \<noteq> h\<close>
               by auto
             hence "n \<notin> unit_circle_set"
               using * \<open>H \<noteq> unit_circle\<close> unique_circline_set[of m n h] 
               using \<open>m \<noteq> h\<close> \<open>m \<in> unit_circle_set\<close> \<open>h \<in> unit_circle_set\<close> \<open>m \<in> circline_set H\<close>
               unfolding unit_circle_set_def
               by auto
         
             thus ?thesis
               using * \<open>n \<in> circline_set H\<close> \<open>n \<noteq> f\<close> \<open>n \<noteq> inversion f\<close>
               by auto
           qed
         qed
       qed
     qed
     then obtain a b where ab: "a \<noteq> b" "a \<noteq> inversion b" "a \<in> circline_set H" "b \<in> circline_set H" "a \<notin> unit_circle_set" "b \<notin> unit_circle_set"
       by blast
     have "\<forall> x. x \<in> circline_set H \<and> x \<notin> unit_circle_set \<longrightarrow> (\<exists> x'. x' \<in> circline_set H \<inter> unit_disc \<and> (x' = x \<or> x' = inversion x))"
     proof safe
       fix x
       assume x: "x \<in> circline_set H" "x \<notin> unit_circle_set" 
       show "\<exists> x'. x' \<in> circline_set H \<inter> unit_disc \<and> (x' = x \<or> x' = inversion x)"
       proof (cases "x \<in> unit_disc")
         case True
         thus ?thesis
           using x
           by auto
       next
         case False
         hence "x \<in> unit_disc_compl"
           using x  in_on_out_univ[of "ounit_circle"]
           unfolding unit_circle_set_def unit_disc_def unit_disc_compl_def
           by auto
         hence "inversion x \<in> unit_disc"
           using inversion_unit_disc_compl
           by blast
         thus ?thesis
           using is_poincare_line_inverse_point[OF assms, of x] x
           by auto
       qed
     qed
     then obtain a' b' where 
       *: "a' \<in> circline_set H" "a' \<in> unit_disc" "b' \<in> circline_set H" "b' \<in> unit_disc" and
       **: "a' = a \<or> a' = inversion a" "b' = b \<or> b' = inversion b" 
       using ab
       by blast
     have "a' \<noteq> b'"
       using \<open>a \<noteq> b\<close> \<open>a \<noteq> inversion b\<close> ** *
       by (metis inversion_involution)
     thus ?thesis
       using *
       by auto
   qed
 qed
 
 (* ------------------------------------------------------------------ *)
 subsubsection \<open>H-line uniqueness\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>There is no more than one h-line that contains two different h-points (in the disc).\<close>
 lemma unique_is_poincare_line:
   assumes in_disc: "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
   assumes pl: "is_poincare_line l1" "is_poincare_line l2"
   assumes on_l: "{u, v} \<subseteq> circline_set l1 \<inter> circline_set l2"
   shows "l1 = l2"
 proof-
   have "u \<noteq> inversion u" "v \<noteq> inversion u"
     using in_disc
     using inversion_noteq_unit_disc[of u v]
     using inversion_noteq_unit_disc[of u u]
     by auto
   thus ?thesis
     using on_l
     using unique_circline_set[of u "inversion u" "v"] \<open>u \<noteq> v\<close>
     using is_poincare_line_inverse_point[of l1 u]
     using is_poincare_line_inverse_point[of l2 u]
     using pl
     by auto                                                                            
 qed
 
 text\<open>For the rest of our formalization it is often useful to consider points on h-lines that are not
 within the unit disc. Many lemmas in the rest of this section will have such generalizations.\<close>
 
 text\<open>There is no more than one h-line that contains two different and not mutually inverse points
 (not necessary in the unit disc).\<close>
 lemma unique_is_poincare_line_general:
   assumes different: "u \<noteq> v" "u \<noteq> inversion v"
   assumes pl: "is_poincare_line l1" "is_poincare_line l2"
   assumes on_l: "{u, v} \<subseteq> circline_set l1 \<inter> circline_set l2"
   shows  "l1 = l2"
 proof (cases "u \<noteq> inversion u")
   case True
   thus ?thesis
     using unique_circline_set[of u "inversion u" "v"]
     using assms
     using is_poincare_line_inverse_point by force
 next
   case False
   show ?thesis
   proof (cases "v \<noteq> inversion v")
     case True
     thus ?thesis
       using unique_circline_set[of u "inversion v" "v"]
       using assms
       using is_poincare_line_inverse_point by force
   next
     case False
 
     have "on_circline unit_circle u" "on_circline unit_circle v"
       using \<open>\<not> u \<noteq> inversion u\<close> \<open>\<not> v \<noteq> inversion v\<close>
       using inversion_id_iff_on_unit_circle
       by fastforce+
     thus ?thesis
       using pl on_l \<open>u \<noteq> v\<close>
       unfolding circline_set_def
       apply simp
     proof (transfer, transfer, safe)
       fix u1 u2 v1 v2 A1 B1 C1 D1 A2 B2 C2 D2 :: complex
       let ?u = "(u1, u2)" and ?v = "(v1, v2)" and  ?H1 = "(A1, B1, C1, D1)" and ?H2 = "(A2, B2, C2, D2)"
       assume *: "?u \<noteq> vec_zero" "?v \<noteq> vec_zero"
         "on_circline_cmat_cvec unit_circle_cmat ?u" "on_circline_cmat_cvec unit_circle_cmat ?v" 
         "is_poincare_line_cmat ?H1" "is_poincare_line_cmat ?H2"
         "hermitean ?H1" "?H1 \<noteq> mat_zero" "hermitean ?H2" "?H2 \<noteq> mat_zero"
         "on_circline_cmat_cvec ?H1 ?u" "on_circline_cmat_cvec ?H1 ?v"
         "on_circline_cmat_cvec ?H2 ?u" "on_circline_cmat_cvec ?H2 ?v"
         "\<not> (u1, u2) \<approx>\<^sub>v (v1, v2)"
       have **: "A1 = D1" "A2 = D2" "C1 = cnj B1" "C2 = cnj B2" "is_real A1" "is_real A2"
         using \<open>is_poincare_line_cmat ?H1\<close> \<open>is_poincare_line_cmat ?H2\<close>
         using \<open>hermitean ?H1\<close> \<open>?H1 \<noteq> mat_zero\<close> \<open>hermitean ?H2\<close> \<open>?H2 \<noteq> mat_zero\<close>
         using hermitean_elems
         by auto
 
       have uv: "u1 \<noteq> 0" "u2 \<noteq> 0" "v1 \<noteq> 0" "v2 \<noteq> 0"
         using *(1-4)
         by (auto simp add: vec_cnj_def)
 
       have u: "cor ((Re (u1/u2))\<^sup>2) + cor ((Im (u1/u2))\<^sup>2) = 1"
         using \<open>on_circline_cmat_cvec unit_circle_cmat ?u\<close> uv
         apply (subst of_real_add[symmetric])
         apply (subst complex_mult_cnj[symmetric])
         apply (simp add: vec_cnj_def mult.commute)
         done
 
       have v: "cor ((Re (v1/v2))\<^sup>2) + cor ((Im (v1/v2))\<^sup>2) = 1"
         using \<open>on_circline_cmat_cvec unit_circle_cmat ?v\<close> uv
         apply (subst of_real_add[symmetric])
         apply (subst complex_mult_cnj[symmetric])
         apply (simp add: vec_cnj_def mult.commute)
         done
 
       have 
         "A1 * (cor ((Re (u1/u2))\<^sup>2) + cor ((Im (u1/u2))\<^sup>2) + 1) + cor (Re B1) * cor(2 * Re (u1/u2)) + cor (Im B1) * cor(2 * Im (u1/u2)) = 0"
         "A2 * (cor ((Re (u1/u2))\<^sup>2) + cor ((Im (u1/u2))\<^sup>2) + 1) + cor (Re B2) * cor(2 * Re (u1/u2)) + cor (Im B2) * cor(2 * Im (u1/u2)) = 0"
         "A1 * (cor ((Re (v1/v2))\<^sup>2) + cor ((Im (v1/v2))\<^sup>2) + 1) + cor (Re B1) * cor(2 * Re (v1/v2)) + cor (Im B1) * cor(2 * Im (v1/v2)) = 0"
         "A2 * (cor ((Re (v1/v2))\<^sup>2) + cor ((Im (v1/v2))\<^sup>2) + 1) + cor (Re B2) * cor(2 * Re (v1/v2)) + cor (Im B2) * cor(2 * Im (v1/v2)) = 0"
         using circline_equation_quadratic_equation[of A1 "u1/u2" B1 D1 "Re (u1/u2)" "Im (u1 / u2)" "Re B1" "Im B1"]
         using circline_equation_quadratic_equation[of A2 "u1/u2" B2 D2 "Re (u1/u2)" "Im (u1 / u2)" "Re B2" "Im B2"]
         using circline_equation_quadratic_equation[of A1 "v1/v2" B1 D1 "Re (v1/v2)" "Im (v1 / v2)" "Re B1" "Im B1"]
         using circline_equation_quadratic_equation[of A2 "v1/v2" B2 D2 "Re (v1/v2)" "Im (v1 / v2)" "Re B2" "Im B2"]
         using \<open>on_circline_cmat_cvec ?H1 ?u\<close> \<open>on_circline_cmat_cvec ?H2 ?u\<close> 
         using \<open>on_circline_cmat_cvec ?H1 ?v\<close> \<open>on_circline_cmat_cvec ?H2 ?v\<close> 
         using ** uv
         by (simp_all add: vec_cnj_def field_simps)
 
       hence
         "A1 + cor (Re B1) * cor(Re (u1/u2)) + cor (Im B1) * cor(Im (u1/u2)) = 0"
         "A1 + cor (Re B1) * cor(Re (v1/v2)) + cor (Im B1) * cor(Im (v1/v2)) = 0"
         "A2 + cor (Re B2) * cor(Re (u1/u2)) + cor (Im B2) * cor(Im (u1/u2)) = 0"
         "A2 + cor (Re B2) * cor(Re (v1/v2)) + cor (Im B2) * cor(Im (v1/v2)) = 0"
         using u v
         by simp_all algebra+
 
       hence 
         "cor (Re A1 + Re B1 * Re (u1/u2) + Im B1 * Im (u1/u2)) = 0"
         "cor (Re A2 + Re B2 * Re (u1/u2) + Im B2 * Im (u1/u2)) = 0"
         "cor (Re A1 + Re B1 * Re (v1/v2) + Im B1 * Im (v1/v2)) = 0"
         "cor (Re A2 + Re B2 * Re (v1/v2) + Im B2 * Im (v1/v2)) = 0"
         using \<open>is_real A1\<close> \<open>is_real A2\<close>
         by simp_all
 
       hence 
         "Re A1 + Re B1 * Re (u1/u2) + Im B1 * Im (u1/u2) = 0"
         "Re A1 + Re B1 * Re (v1/v2) + Im B1 * Im (v1/v2) = 0"
         "Re A2 + Re B2 * Re (u1/u2) + Im B2 * Im (u1/u2) = 0"
         "Re A2 + Re B2 * Re (v1/v2) + Im B2 * Im (v1/v2) = 0"
         using of_real_eq_0_iff 
         by blast+
 
       moreover
 
       have "Re(u1/u2) \<noteq> Re(v1/v2) \<or> Im(u1/u2) \<noteq> Im(v1/v2)"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         hence "u1/u2 = v1/v2"
           using complex_eqI by blast
         thus False
           using uv \<open>\<not> (u1, u2) \<approx>\<^sub>v (v1, v2)\<close>
           using "*"(1) "*"(2) complex_cvec_eq_mix[OF *(1) *(2)]
           by (auto simp add: field_simps)
       qed
 
       moreover
 
       have "Re A1 \<noteq> 0 \<or> Re B1 \<noteq> 0 \<or> Im B1 \<noteq> 0"
         using \<open>?H1 \<noteq> mat_zero\<close> **
         by (metis complex_cnj_zero complex_of_real_Re mat_zero_def of_real_0)
 
       ultimately
 
       obtain k where
         k: "Re A2 = k * Re A1" "Re B2 = k * Re B1" "Im B2 = k * Im B1"
         using linear_system_homogenous_3_2[of "\<lambda>x y z. 1 * x + Re (u1 / u2) * y + Im (u1 / u2) * z" 1 "Re (u1/u2)" "Im (u1/u2)" 
                                               "\<lambda>x y z. 1 * x + Re (v1 / v2) * y + Im (v1 / v2) * z" 1 "Re (v1/v2)" "Im (v1/v2)"
                                               "Re A2" "Re B2" "Im B2" "Re A1" "Re B1" "Im B1"]
         by (auto simp add: field_simps)
 
       have "Re A2 \<noteq> 0 \<or> Re B2 \<noteq> 0 \<or> Im B2 \<noteq> 0"
         using \<open>?H2 \<noteq> mat_zero\<close> **
         by (metis complex_cnj_zero complex_of_real_Re mat_zero_def of_real_0)
       hence "k \<noteq> 0"
         using k
         by auto
 
       show "circline_eq_cmat ?H1 ?H2"
         using ** k \<open>k \<noteq> 0\<close>
         by (auto simp add: vec_cnj_def) (rule_tac x="k" in exI, auto simp add: complex.expand)
     qed
   qed
 qed
 
 text \<open>The only h-line that goes trough zero and a non-zero point on the x-axis is the x-axis.\<close>
 lemma is_poincare_line_0_real_is_x_axis:
   assumes "is_poincare_line l" "0\<^sub>h \<in> circline_set l"
     "x \<in> circline_set l \<inter> circline_set x_axis" "x \<noteq> 0\<^sub>h" "x \<noteq> \<infinity>\<^sub>h"
   shows "l = x_axis"
   using assms
   using is_poincare_line_trough_zero_trough_infty[OF assms(1-2)]
   using unique_circline_set[of x "0\<^sub>h" "\<infinity>\<^sub>h"]
   by auto
 
 text \<open>The only h-line that goes trough zero and a non-zero point on the y-axis is the y-axis.\<close>
 lemma is_poincare_line_0_imag_is_y_axis:
   assumes "is_poincare_line l" "0\<^sub>h \<in> circline_set l"
     "y \<in> circline_set l \<inter> circline_set y_axis" "y \<noteq> 0\<^sub>h" "y \<noteq> \<infinity>\<^sub>h"
   shows "l = y_axis"
   using assms
   using is_poincare_line_trough_zero_trough_infty[OF assms(1-2)]
   using unique_circline_set[of y "0\<^sub>h" "\<infinity>\<^sub>h"]
   by auto
 
 (* ------------------------------------------------------------------ *)
 subsubsection\<open>H-isometries preserve h-lines\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>\emph{H-isometries} are defined as homographies (actions of Möbius transformations) and
 antihomographies (compositions of actions of Möbius transformations with conjugation) that fix the
 unit disc (map it onto itself). They also map h-lines onto h-lines\<close>
 
 text\<open>We prove a bit more general lemma that states that all Möbius transformations that fix the
 unit circle (not necessary the unit disc) map h-lines onto h-lines\<close>
 lemma unit_circle_fix_preserve_is_poincare_line [simp]:
   assumes "unit_circle_fix M" "is_poincare_line H"
   shows "is_poincare_line (moebius_circline M H)"
   using assms
   unfolding is_poincare_line_iff
 proof (safe)
   let ?H' = "moebius_ocircline M (of_circline H)"
   let ?U' = "moebius_ocircline M ounit_circle"
   assume ++: "unit_circle_fix M" "perpendicular H unit_circle"
   have ounit: "ounit_circle = moebius_ocircline M ounit_circle \<or>
                ounit_circle = moebius_ocircline M (opposite_ocircline ounit_circle)"
     using ++(1) unit_circle_fix_iff[of M]
     by (simp add: inj_of_ocircline moebius_circline_ocircline)
 
   show "perpendicular (moebius_circline M H) unit_circle"
   proof (cases "pos_oriented ?H'")
     case True
     hence *: "of_circline (of_ocircline ?H') = ?H'"
       using of_circline_of_ocircline_pos_oriented
       by blast
     from ounit show ?thesis
     proof
       assume **: "ounit_circle = moebius_ocircline M ounit_circle"
       show ?thesis
         using ++ 
         unfolding perpendicular_def
         by (simp, subst moebius_circline_ocircline, subst *, subst **) simp
     next
       assume **: "ounit_circle = moebius_ocircline M (opposite_ocircline ounit_circle)"
       show ?thesis
         using ++
         unfolding perpendicular_def
         by (simp, subst moebius_circline_ocircline, subst *, subst **) simp
     qed
   next
     case False
     hence *: "of_circline (of_ocircline ?H') = opposite_ocircline ?H'"
       by (metis of_circline_of_ocircline pos_oriented_of_circline)
     from ounit show ?thesis
     proof
       assume **: "ounit_circle = moebius_ocircline M ounit_circle"
       show ?thesis
         using ++
         unfolding perpendicular_def
         by (simp, subst moebius_circline_ocircline, subst *, subst **) simp
     next
       assume **: "ounit_circle = moebius_ocircline M (opposite_ocircline ounit_circle)"
       show ?thesis
         using ++
         unfolding perpendicular_def
         by (simp, subst moebius_circline_ocircline, subst *, subst **) simp
     qed
   qed
 qed simp
 
 lemma unit_circle_fix_preserve_is_poincare_line_iff [simp]:
   assumes "unit_circle_fix M"
   shows "is_poincare_line (moebius_circline M H) \<longleftrightarrow> is_poincare_line H"
   using assms
   using unit_circle_fix_preserve_is_poincare_line[of M H]
   using unit_circle_fix_preserve_is_poincare_line[of "moebius_inv M" "moebius_circline M H"]
   by (auto simp del: unit_circle_fix_preserve_is_poincare_line)
 
 text\<open>Since h-lines are preserved by transformations that fix the unit circle, so is collinearity.\<close>
 lemma unit_disc_fix_preserve_poincare_collinear [simp]:
   assumes "unit_circle_fix M" "poincare_collinear A"
   shows "poincare_collinear (moebius_pt M ` A)"
   using assms
   unfolding poincare_collinear_def                                                    
   by (auto, rule_tac x="moebius_circline M p" in exI, auto)
 
 lemma unit_disc_fix_preserve_poincare_collinear_iff [simp]:
   assumes "unit_circle_fix M"
   shows "poincare_collinear (moebius_pt M ` A) \<longleftrightarrow> poincare_collinear A"
   using assms
   using unit_disc_fix_preserve_poincare_collinear[of M A]
   using unit_disc_fix_preserve_poincare_collinear[of "moebius_inv M" "moebius_pt M ` A"]
   by (auto simp del: unit_disc_fix_preserve_poincare_collinear)
 
 lemma unit_disc_fix_preserve_poincare_collinear3 [simp]:
   assumes "unit_disc_fix M"
   shows "poincare_collinear {moebius_pt M u, moebius_pt M v, moebius_pt M w} \<longleftrightarrow>
          poincare_collinear {u, v, w}"
   using assms unit_disc_fix_preserve_poincare_collinear_iff[of M "{u, v, w}"]
   by simp
 
 text\<open>Conjugation is also an h-isometry and it preserves h-lines.\<close>
 lemma is_poincare_line_conjugate_circline [simp]:
   assumes "is_poincare_line H"
   shows "is_poincare_line (conjugate_circline H)"
   using assms
   by (transfer, transfer, auto simp add: mat_cnj_def hermitean_def mat_adj_def)
 
 lemma is_poincare_line_conjugate_circline_iff [simp]:
   shows "is_poincare_line (conjugate_circline H) \<longleftrightarrow> is_poincare_line H"
   using is_poincare_line_conjugate_circline[of "conjugate_circline H"]
   by auto
 
 text\<open>Since h-lines are preserved by conjugation, so is collinearity.\<close>
 lemma conjugate_preserve_poincare_collinear [simp]:
   assumes "poincare_collinear A"
   shows "poincare_collinear (conjugate ` A)"
   using assms
   unfolding poincare_collinear_def
   by auto (rule_tac x="conjugate_circline p" in exI, auto)
 
 lemma conjugate_conjugate [simp]: "conjugate ` conjugate ` A = A"
   by (auto simp add: image_iff)
 
 lemma conjugate_preserve_poincare_collinear_iff [simp]:
   shows "poincare_collinear (conjugate ` A) \<longleftrightarrow> poincare_collinear A"
   using conjugate_preserve_poincare_collinear[of "A"]
   using conjugate_preserve_poincare_collinear[of "conjugate ` A"]
   by (auto simp del: conjugate_preserve_poincare_collinear)
 
 (* ------------------------------------------------------------------ *)
 subsubsection\<open>Mapping h-lines to x-axis\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Each h-line in the Poincar\'e model can be mapped onto the x-axis (by a unit-disc preserving
 Möbius transformation).\<close>
 lemma ex_unit_disc_fix_is_poincare_line_to_x_axis:
   assumes "is_poincare_line l"
   shows  "\<exists> M. unit_disc_fix M \<and> moebius_circline M l = x_axis"
 proof-
   from assms obtain u v where "u \<noteq> v" "u \<in> unit_disc" "v \<in> unit_disc" and "{u, v} \<subseteq> circline_set l"
     using ex_is_poincare_line_points
     by blast
   then obtain M where *: "unit_disc_fix M" "moebius_pt M u = 0\<^sub>h" "moebius_pt M v \<in> positive_x_axis"
     using ex_unit_disc_fix_to_zero_positive_x_axis[of u v]
     by auto
   moreover
   hence "{0\<^sub>h, moebius_pt M v} \<subseteq> circline_set x_axis"
     unfolding positive_x_axis_def
     by auto
   moreover
   have "moebius_pt M v \<noteq> 0\<^sub>h"
     using \<open>u \<noteq> v\<close> *
     by (metis moebius_pt_neq_I)
   moreover
   have "moebius_pt M v \<noteq> \<infinity>\<^sub>h"
     using \<open>unit_disc_fix M\<close> \<open>v \<in> unit_disc\<close>
     using unit_disc_fix_discI
     by fastforce
   ultimately
   show ?thesis
     using \<open>is_poincare_line l\<close> \<open>{u, v} \<subseteq> circline_set l\<close> \<open>unit_disc_fix M\<close>
     using is_poincare_line_0_real_is_x_axis[of "moebius_circline M l" "moebius_pt M v"]
     by (rule_tac x="M" in exI, force) 
 qed
 
 text \<open>When proving facts about h-lines, without loss of generality it can be assumed that h-line is
 the x-axis (if the property being proved is invariant under Möbius transformations that fix the
 unit disc).\<close>
 
 lemma wlog_line_x_axis:
   assumes is_line: "is_poincare_line H"
   assumes x_axis: "P x_axis"
   assumes preserves: "\<And> M. \<lbrakk>unit_disc_fix M; P (moebius_circline M H)\<rbrakk> \<Longrightarrow> P H"
   shows "P H"
   using assms
   using ex_unit_disc_fix_is_poincare_line_to_x_axis[of H]
   by auto
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Construction of the h-line between the two given points\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Next we show how to construct the (unique) h-line between the two given points in the Poincar\'e model\<close>
 
 text\<open>
 Geometrically, h-line can be constructed by finding the inverse point of one of the two points and 
 by constructing the circle (or line) trough it and the two given points.
 
 Algebraically, for two given points $u$ and $v$ in $\mathbb{C}$, the h-line matrix coefficients can
 be $A = i\cdot(u\overline{v}-v\overline{u})$ and $B = i\cdot(v(|u|^2+1) - u(|v|^2+1))$.
 
 We need to extend this to homogenous coordinates. There are several degenerate cases.
 
  - If $\{z, w\} = \{0_h, \infty_h\}$ then there is no unique h-line (any line trough zero is an h-line).
 
  - If z and w are mutually inverse, then the construction fails (both geometric and algebraic).
 
  - If z and w are different points on the unit circle, then the standard construction fails (only geometric).
 
  - None of this problematic cases occur when z and w are inside the unit disc.
 
 We express the construction algebraically, and construct the Hermitean circline matrix for the two
 points given in homogenous coordinates. It works correctly in all cases except when the two points
 are the same or are mutually inverse.
 \<close>
 
 
 definition mk_poincare_line_cmat :: "real \<Rightarrow> complex \<Rightarrow> complex_mat" where
   [simp]: "mk_poincare_line_cmat A B = (cor A, B, cnj B, cor A)"
 
 lemma mk_poincare_line_cmat_zero_iff:
   "mk_poincare_line_cmat A B = mat_zero \<longleftrightarrow> A = 0 \<and> B = 0"
   by auto
 
 lemma mk_poincare_line_cmat_hermitean
   [simp]:  "hermitean (mk_poincare_line_cmat A B)"
   by simp
 
 lemma mk_poincare_line_cmat_scale:
   "cor k *\<^sub>s\<^sub>m mk_poincare_line_cmat A B = mk_poincare_line_cmat (k * A) (k * B)"
   by simp
 
 definition poincare_line_cvec_cmat :: "complex_vec \<Rightarrow> complex_vec \<Rightarrow> complex_mat" where
   [simp]: "poincare_line_cvec_cmat z w =
             (let (z1, z2) = z;
                  (w1, w2) = w;
                  nom = w1*cnj w2*(z1*cnj z1 + z2*cnj z2) - z1*cnj z2*(w1*cnj w1 + w2*cnj w2);
                  den = z1*cnj z2*cnj w1*w2 - w1*cnj w2*cnj z1*z2
               in if den \<noteq> 0 then
                     mk_poincare_line_cmat (Re(\<i>*den)) (\<i>*nom)
                  else if z1*cnj z2 \<noteq> 0 then
                     mk_poincare_line_cmat 0 (\<i>*z1*cnj z2)
                  else if w1*cnj w2 \<noteq> 0 then
                     mk_poincare_line_cmat 0 (\<i>*w1*cnj w2)
                  else
                     mk_poincare_line_cmat 0 \<i>)"
 
 lemma poincare_line_cvec_cmat_AeqD:
   assumes "poincare_line_cvec_cmat z w = (A, B, C, D)"
   shows "A = D"
   using assms
   by (cases z, cases w) (auto split: if_split_asm)
 
 lemma poincare_line_cvec_cmat_hermitean [simp]: 
   shows "hermitean (poincare_line_cvec_cmat z w)"
   by (cases z, cases w) (auto split: if_split_asm simp del: mk_poincare_line_cmat_def)
 
 lemma poincare_line_cvec_cmat_nonzero [simp]:
   assumes "z \<noteq> vec_zero" "w \<noteq> vec_zero"
   shows  "poincare_line_cvec_cmat z w \<noteq> mat_zero"
 proof-
 
   obtain z1 z2 w1 w2 where *: "z = (z1, z2)" "w = (w1, w2)"
     by (cases z, cases w, auto)
 
   let ?den = "z1*cnj z2*cnj w1*w2 - w1*cnj w2*cnj z1*z2"
   show ?thesis
   proof (cases "?den \<noteq> 0")
     case True
     have "is_real (\<i> * ?den)"
       using eq_cnj_iff_real[of "\<i> *?den"]
       by (simp add: field_simps)
     hence "Re (\<i> * ?den) \<noteq> 0"
       using \<open>?den \<noteq> 0\<close>
       by (metis complex_i_not_zero complex_surj mult_eq_0_iff zero_complex.code)
     thus ?thesis
       using * \<open>?den \<noteq> 0\<close>
       by (simp del: mk_poincare_line_cmat_def mat_zero_def add: mk_poincare_line_cmat_zero_iff)
   next
     case False
     thus ?thesis
       using *
       by (simp del: mk_poincare_line_cmat_def mat_zero_def add: mk_poincare_line_cmat_zero_iff)
   qed
 qed
 
 lift_definition poincare_line_hcoords_clmat :: "complex_homo_coords \<Rightarrow> complex_homo_coords \<Rightarrow> circline_mat" is poincare_line_cvec_cmat
   using poincare_line_cvec_cmat_hermitean poincare_line_cvec_cmat_nonzero
   by simp
 
 lift_definition poincare_line :: "complex_homo \<Rightarrow> complex_homo \<Rightarrow> circline" is poincare_line_hcoords_clmat
 proof transfer
   fix za zb wa wb
   assume "za \<noteq> vec_zero" "zb \<noteq> vec_zero" "wa \<noteq> vec_zero" "wb \<noteq> vec_zero"
   assume "za \<approx>\<^sub>v zb" "wa \<approx>\<^sub>v wb"
   obtain za1 za2 zb1 zb2 wa1 wa2 wb1 wb2 where
   *: "(za1, za2) = za" "(zb1, zb2) = zb"
      "(wa1, wa2) = wa" "(wb1, wb2) = wb"
     by (cases za, cases zb, cases wa, cases wb, auto)
   obtain kz kw where
     **: "kz \<noteq> 0" "kw \<noteq> 0" "zb1 = kz * za1" "zb2 = kz * za2" "wb1 = kw * wa1" "wb2 = kw * wa2"
     using \<open>za \<approx>\<^sub>v zb\<close> \<open>wa \<approx>\<^sub>v wb\<close> *[symmetric]
     by auto
 
   let ?nom = "\<lambda> z1 z2 w1 w2. w1*cnj w2*(z1*cnj z1 + z2*cnj z2) - z1*cnj z2*(w1*cnj w1 + w2*cnj w2)"
   let ?den = "\<lambda> z1 z2 w1 w2. z1*cnj z2*cnj w1*w2 - w1*cnj w2*cnj z1*z2"
 
   show "circline_eq_cmat (poincare_line_cvec_cmat za wa)
                          (poincare_line_cvec_cmat zb wb)"
   proof-
     have "\<exists>k. k \<noteq> 0 \<and>
             poincare_line_cvec_cmat (zb1, zb2) (wb1, wb2) = cor k *\<^sub>s\<^sub>m poincare_line_cvec_cmat (za1, za2) (wa1, wa2)"
     proof (cases "?den za1 za2 wa1 wa2 \<noteq> 0")
       case True
       hence "?den zb1 zb2 wb1 wb2 \<noteq> 0"
         using **
         by (simp add: field_simps)
 
       let ?k = "kz * cnj kz * kw * cnj kw"
 
       have "?k \<noteq> 0"
         using **
         by simp
 
       have "is_real ?k"
         using eq_cnj_iff_real[of ?k]
         by auto
 
       have "cor (Re ?k) = ?k"
         using \<open>is_real ?k\<close>
         using complex_of_real_Re
         by blast
 
       have "Re ?k \<noteq> 0"
         using \<open>?k \<noteq> 0\<close> \<open>cor (Re ?k) = ?k\<close>
         by (metis of_real_0)
 
       have arg1: "Re (\<i> * ?den zb1 zb2 wb1 wb2) = Re ?k * Re (\<i> * ?den za1 za2 wa1 wa2)"
         apply (subst **)+
         apply (subst Re_mult_real[symmetric, OF \<open>is_real ?k\<close>])
         apply (rule arg_cong[where f=Re])
         apply (simp add: field_simps)
         done
       have arg2: "\<i> * ?nom zb1 zb2 wb1 wb2 = ?k * \<i> * ?nom za1 za2 wa1 wa2"
         using **
         by (simp add: field_simps)
       have "mk_poincare_line_cmat (Re (\<i>*?den zb1 zb2 wb1 wb2)) (\<i>*?nom zb1 zb2 wb1 wb2) =
             cor (Re ?k) *\<^sub>s\<^sub>m mk_poincare_line_cmat (Re (\<i>*?den za1 za2 wa1 wa2)) (\<i>*?nom za1 za2 wa1 wa2)"
         using \<open>cor (Re ?k) = ?k\<close> \<open>is_real ?k\<close>
         apply (subst mk_poincare_line_cmat_scale)
         apply (subst arg1, subst arg2)
         apply (subst \<open>cor (Re ?k) = ?k\<close>)+
         apply simp
         done
        thus ?thesis
         using \<open>?den za1 za2 wa1 wa2 \<noteq> 0\<close> \<open>?den zb1 zb2 wb1 wb2 \<noteq> 0\<close>
         using \<open>Re ?k \<noteq> 0\<close> \<open>cor (Re ?k) = ?k\<close>
         by (rule_tac x="Re ?k" in exI, simp)
     next
       case False
       hence "?den zb1 zb2 wb1 wb2 = 0"
         using **
         by (simp add: field_simps)
       show ?thesis
       proof (cases "za1*cnj za2 \<noteq> 0")
         case True
         hence "zb1*cnj zb2 \<noteq> 0"
           using **
           by (simp add: field_simps)
 
         let ?k = "kz * cnj kz"
 
         have "?k \<noteq> 0" "is_real ?k"
           using **
           using eq_cnj_iff_real[of ?k]
           by auto
         thus ?thesis
           using \<open>za1 * cnj za2 \<noteq> 0\<close> \<open>zb1 * cnj zb2 \<noteq> 0\<close>
           using \<open>\<not> (?den za1 za2 wa1 wa2 \<noteq> 0)\<close> \<open>?den zb1 zb2 wb1 wb2 = 0\<close> **
           by (rule_tac x="Re (kz * cnj kz)" in exI, auto simp add: complex.expand)
       next
         case False
         hence "zb1 * cnj zb2 = 0"
           using **
           by (simp add: field_simps)
         show ?thesis
         proof (cases "wa1 * cnj wa2 \<noteq> 0")
           case True
           hence "wb1*cnj wb2 \<noteq> 0"
             using **
             by (simp add: field_simps)
 
           let ?k = "kw * cnj kw"
 
           have "?k \<noteq> 0" "is_real ?k"
             using **
             using eq_cnj_iff_real[of ?k]
             by auto
 
           thus ?thesis
             using \<open>\<not> (za1 * cnj za2 \<noteq> 0)\<close> 
             using \<open>wa1 * cnj wa2 \<noteq> 0\<close> \<open>wb1 * cnj wb2 \<noteq> 0\<close>
             using \<open>\<not> (?den za1 za2 wa1 wa2 \<noteq> 0)\<close> \<open>?den zb1 zb2 wb1 wb2 = 0\<close> **
             by (rule_tac x="Re (kw * cnj kw)" in exI) 
                (auto simp add: complex.expand)
         next
           case False
           hence "wb1 * cnj wb2 = 0"
             using **
             by (simp add: field_simps)
           thus ?thesis
             using \<open>\<not> (za1 * cnj za2 \<noteq> 0)\<close> \<open>zb1 * cnj zb2 = 0\<close>
             using \<open>\<not> (wa1 * cnj wa2 \<noteq> 0)\<close> \<open>wb1 * cnj wb2 = 0\<close>
             using \<open>\<not> (?den za1 za2 wa1 wa2 \<noteq> 0)\<close> \<open>?den zb1 zb2 wb1 wb2 = 0\<close> **
             by simp
         qed
       qed
     qed
     thus ?thesis
       using *[symmetric]
       by simp
   qed
 qed
 
 subsubsection \<open>Correctness of the construction\<close>
 
 text\<open>For finite points, our definition matches the classic algebraic definition for points in
 $\mathbb{C}$ (given in ordinary, not homogenous coordinates).\<close>
 lemma poincare_line_non_homogenous:
   assumes "u \<noteq> \<infinity>\<^sub>h" "v \<noteq> \<infinity>\<^sub>h" "u \<noteq> v" "u \<noteq> inversion v"
   shows "let u' = to_complex u;  v' = to_complex v;
              A = \<i> * (u' * cnj v' - v' * cnj u');
              B = \<i> * (v' * ((cmod u')\<^sup>2 + 1) - u' * ((cmod v')\<^sup>2 + 1))
           in poincare_line u v = mk_circline A B (cnj B) A"
   using assms
   unfolding unit_disc_def disc_def inversion_def
   apply (simp add: Let_def)
 proof (transfer, transfer, safe)
   fix u1 u2 v1 v2
   assume uv: "(u1, u2) \<noteq> vec_zero" "(v1, v2) \<noteq> vec_zero" 
              "\<not> (u1, u2) \<approx>\<^sub>v \<infinity>\<^sub>v" "\<not> (v1, v2) \<approx>\<^sub>v \<infinity>\<^sub>v"            
              "\<not> (u1, u2) \<approx>\<^sub>v (v1, v2)" "\<not> (u1, u2) \<approx>\<^sub>v conjugate_cvec (reciprocal_cvec (v1, v2))"
   let ?u = "to_complex_cvec (u1, u2)" and ?v = "to_complex_cvec (v1, v2)"
   let ?A = "\<i> * (?u * cnj ?v - ?v * cnj ?u)"
   let ?B = "\<i> * (?v * ((cor (cmod ?u))\<^sup>2 + 1) - ?u * ((cor (cmod ?v))\<^sup>2 + 1))"
   let ?C = "- (\<i> * (cnj ?v * ((cor (cmod ?u))\<^sup>2 + 1) - cnj ?u * ((cor (cmod ?v))\<^sup>2 + 1)))"
   let ?D = ?A
   let ?H = "(?A, ?B, ?C, ?D)"
 
 
   let ?den = "u1 * cnj u2 * cnj v1 * v2 - v1 * cnj v2 * cnj u1 * u2"
 
   have "u2 \<noteq> 0" "v2 \<noteq> 0"
     using uv                                                    
     using inf_cvec_z2_zero_iff 
     by blast+
 
   have "\<not> (u1, u2) \<approx>\<^sub>v (cnj v2, cnj v1)"
     using uv(6)
     by (simp add: vec_cnj_def)
   moreover
   have "(cnj v2, cnj v1) \<noteq> vec_zero"
     using uv(2)
     by auto
   ultimately
   have *: "u1 * cnj v1 \<noteq> u2 * cnj v2" "u1 * v2 \<noteq> u2 * v1" 
     using uv(5) uv(1) uv(2) \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close>
     using complex_cvec_eq_mix 
     by blast+
 
   show "circline_eq_cmat (poincare_line_cvec_cmat (u1, u2) (v1, v2))
                          (mk_circline_cmat ?A ?B ?C ?D)"
   proof (cases "?den \<noteq> 0")
     case True
 
     let ?nom = "v1 * cnj v2 * (u1 * cnj u1 + u2 * cnj u2) - u1 * cnj u2 * (v1 * cnj v1 + v2 * cnj v2)"
     let ?H' = "mk_poincare_line_cmat (Re (\<i> * ?den)) (\<i> * ?nom)"
 
     have "circline_eq_cmat ?H ?H'"
     proof-
       let ?k = "(u2 * cnj v2) * (v2 * cnj u2)"
       have "is_real ?k"
         using eq_cnj_iff_real 
         by fastforce
       hence "cor (Re ?k) = ?k"
         using complex_of_real_Re 
         by blast
 
       have "Re (\<i> * ?den) = Re ?k * ?A"
       proof-
         have "?A = cnj ?A"
           by (simp add: field_simps)
         hence "is_real ?A"
           using eq_cnj_iff_real 
           by fastforce
         moreover
         have "\<i> * ?den =  cnj (\<i> * ?den)"
           by (simp add: field_simps)
         hence "is_real (\<i> * ?den)"
           using eq_cnj_iff_real 
           by fastforce
         hence "cor (Re (\<i> * ?den)) = \<i> * ?den"
           using complex_of_real_Re
           by blast
         ultimately
         show ?thesis
           using \<open>cor (Re ?k) = ?k\<close>
           by (simp add: field_simps)
       qed
       
       moreover
       have "\<i> * ?nom = Re ?k  * ?B"
         using \<open>cor (Re ?k) = ?k\<close> \<open>u2 \<noteq>  0\<close> \<open>v2 \<noteq> 0\<close> complex_mult_cnj_cmod[symmetric]
         by (auto simp add: field_simps)
       
       moreover
       have "?k \<noteq> 0"
         using \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close>
         by simp
       hence "Re ?k \<noteq> 0"
         using \<open>is_real ?k\<close>
         by (metis \<open>cor (Re ?k) = ?k\<close> of_real_0)
 
       ultimately
       show ?thesis
         by simp (rule_tac x="Re ?k" in exI, simp add: mult.commute)
     qed
 
     moreover
 
     have "poincare_line_cvec_cmat (u1, u2) (v1, v2) = ?H'"
       using \<open>?den \<noteq> 0\<close>
       unfolding poincare_line_cvec_cmat_def
       by (simp add: Let_def)
 
     moreover
 
     hence "hermitean ?H' \<and> ?H' \<noteq> mat_zero"
       by (metis mk_poincare_line_cmat_hermitean poincare_line_cvec_cmat_nonzero uv(1) uv(2))
 
     hence "hermitean ?H \<and> ?H \<noteq> mat_zero"
       using \<open>circline_eq_cmat ?H ?H'\<close>
       using circline_eq_cmat_hermitean_nonzero[of ?H' ?H] symp_circline_eq_cmat
       unfolding symp_def
       by metis
 
     hence "mk_circline_cmat ?A ?B ?C ?D = ?H"
       by simp
 
     ultimately
 
     have "circline_eq_cmat (mk_circline_cmat ?A ?B ?C ?D)
                            (poincare_line_cvec_cmat (u1, u2) (v1, v2))"
       by simp
     thus ?thesis
       using symp_circline_eq_cmat
       unfolding symp_def
       by blast
   next
     case False
 
     let ?d = "v1 * (u1 * cnj u1 / (u2 * cnj u2) + 1) / v2 - u1 * (v1 * cnj v1 / (v2 * cnj v2) + 1) / u2"
     let ?cd = "cnj v1 * (u1 * cnj u1 / (u2 * cnj u2) + 1) / cnj v2 - cnj u1 * (v1 * cnj v1 / (v2 * cnj v2) + 1) / cnj u2"
 
     have "cnj ?d = ?cd"
       by (simp add: mult.commute)
 
     let ?d1 = "(v1 / v2) * (cnj u1 / cnj u2) - 1"
     let ?d2 = "u1 / u2 - v1 / v2"
 
     have **: "?d = ?d1 * ?d2"
       using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> 
       by(simp add: field_simps)
 
     hence "?d \<noteq> 0"
       using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> *
       by auto (simp add: field_simps)+
 
     have "is_real ?d1"
     proof-
       have "cnj ?d1 = ?d1"
         using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> *
         by (simp add: field_simps)
       thus ?thesis
         using eq_cnj_iff_real
         by blast
     qed
 
     show ?thesis
     proof (cases "u1 * cnj u2 \<noteq> 0")
       case True
       let ?nom = "u1 * cnj u2"
       let ?H' = "mk_poincare_line_cmat 0 (\<i> * ?nom)"
 
       have "circline_eq_cmat ?H ?H'"
       proof-
 
         let ?k = "(u1 * cnj u2) / ?d"
 
         have "is_real ?k"
         proof-
           have "is_real ((u1 * cnj u2) / ?d2)"
           proof-
             let ?rhs = "(u2 * cnj u2) / (1 - (v1*u2)/(u1*v2))"
 
             have 1: "(u1 * cnj u2) / ?d2 = ?rhs"
               using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> * \<open>u1 * cnj u2 \<noteq> 0\<close>
               by (simp add: field_simps)
             moreover
             have "cnj ?rhs = ?rhs"
             proof-
               have "cnj (1 - v1 * u2 / (u1 * v2)) = 1 - v1 * u2 / (u1 * v2)"
                 using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> * \<open>u1 * cnj u2 \<noteq> 0\<close>
                 by (simp add: field_simps)
               moreover
               have "cnj (u2 * cnj u2) = u2 * cnj u2"
                 by simp
               ultimately
               show ?thesis
                 by simp
             qed
 
             ultimately 
 
             show ?thesis
               using eq_cnj_iff_real
               by fastforce
           qed
 
           thus ?thesis
             using ** \<open>is_real ?d1\<close>
             by (metis complex_cnj_divide divide_divide_eq_left' eq_cnj_iff_real)
         qed
 
         have "?k \<noteq> 0"
           using \<open>?d \<noteq> 0\<close> \<open>u1 * cnj u2 \<noteq> 0\<close>
           by simp
 
         have "cnj ?k = ?k"
           using \<open>is_real ?k\<close>
           using eq_cnj_iff_real by blast
 
         have "Re ?k \<noteq> 0"
           using \<open>?k \<noteq> 0\<close> \<open>is_real ?k\<close> 
           by (metis complex.expand zero_complex.simps(1) zero_complex.simps(2))
 
         have "u1 * cnj u2 = ?k * ?d"
           using \<open>?d \<noteq> 0\<close>
           by simp
 
         moreover
 
         hence "cnj u1 * u2 = cnj ?k * cnj ?d"
           by (metis complex_cnj_cnj complex_cnj_mult)
         hence "cnj u1 * u2 = ?k * ?cd"
           using \<open>cnj ?k = ?k\<close> \<open>cnj ?d = ?cd\<close>
           by metis
 
         ultimately
 
         show ?thesis
           using \<open>~ ?den \<noteq> 0\<close> \<open>u1 * cnj u2 \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> \<open>Re ?k \<noteq> 0\<close> \<open>is_real ?k\<close> \<open>?d \<noteq> 0\<close>
           using complex_mult_cnj_cmod[symmetric, of u1]
           using complex_mult_cnj_cmod[symmetric, of v1]
           using complex_mult_cnj_cmod[symmetric, of u2]
           using complex_mult_cnj_cmod[symmetric, of v2]
           apply (simp add: power_divide norm_mult norm_divide)
           apply (rule_tac x="Re ?k" in exI)
           apply simp
           apply (simp add: field_simps)
           done
       qed
 
       moreover
 
       have "poincare_line_cvec_cmat (u1, u2) (v1, v2) = ?H'"
         using \<open>\<not> ?den \<noteq> 0\<close> \<open>u1 * cnj u2 \<noteq> 0\<close>
         unfolding poincare_line_cvec_cmat_def
         by (simp add: Let_def)
 
       moreover
 
       hence "hermitean ?H' \<and> ?H' \<noteq> mat_zero"
         by (metis mk_poincare_line_cmat_hermitean poincare_line_cvec_cmat_nonzero uv(1) uv(2))
 
       hence "hermitean ?H \<and> ?H \<noteq> mat_zero"
         using \<open>circline_eq_cmat ?H ?H'\<close>
         using circline_eq_cmat_hermitean_nonzero[of ?H' ?H] symp_circline_eq_cmat
         unfolding symp_def
         by metis
 
       hence "mk_circline_cmat ?A ?B ?C ?D = ?H"
         by simp
 
       ultimately
 
       have "circline_eq_cmat (mk_circline_cmat ?A ?B ?C ?D)
                              (poincare_line_cvec_cmat (u1, u2) (v1, v2))"
         by simp
       thus ?thesis
         using symp_circline_eq_cmat
         unfolding symp_def
         by blast
     next
       case  False
       show ?thesis
       proof (cases "v1 * cnj v2 \<noteq> 0")
         case True
         let ?nom = "v1 * cnj v2"
         let ?H' = "mk_poincare_line_cmat 0 (\<i> * ?nom)"
 
         have "circline_eq_cmat ?H ?H'"
         proof-
           let ?k = "(v1 * cnj v2) / ?d"
 
           have "is_real ?k"
           proof-
           have "is_real ((v1 * cnj v2) / ?d2)"
           proof-
             let ?rhs = "(v2 * cnj v2) / ((u1*v2)/(u2*v1) - 1)"
 
             have 1: "(v1 * cnj v2) / ?d2 = ?rhs"
               using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> * \<open>v1 * cnj v2 \<noteq> 0\<close>
               by (simp add: field_simps)
             moreover
             have "cnj ?rhs = ?rhs"
             proof-
               have "cnj (u1 * v2 / (u2 * v1) - 1) = u1 * v2 / (u2 * v1) - 1"
                 using \<open>\<not> ?den \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> * \<open>v1 * cnj v2 \<noteq> 0\<close>
                 by (simp add: field_simps)
               moreover                            
               have "cnj (v2 * cnj v2) = v2 * cnj v2"
                 by simp
               ultimately
               show ?thesis
                 by simp
             qed
 
             ultimately 
 
             show ?thesis
               using eq_cnj_iff_real
               by fastforce
           qed
 
           thus ?thesis
             using ** \<open>is_real ?d1\<close>
             by (metis complex_cnj_divide divide_divide_eq_left' eq_cnj_iff_real)
         qed
 
         have "?k \<noteq> 0"
           using \<open>?d \<noteq> 0\<close> \<open>v1 * cnj v2 \<noteq> 0\<close>
           by simp
 
         have "cnj ?k = ?k"
           using \<open>is_real ?k\<close>
           using eq_cnj_iff_real by blast
 
         have "Re ?k \<noteq> 0"
           using \<open>?k \<noteq> 0\<close> \<open>is_real ?k\<close> 
           by (metis complex.expand zero_complex.simps(1) zero_complex.simps(2))
 
         have "v1 * cnj v2 = ?k * ?d"
           using \<open>?d \<noteq> 0\<close>
           by simp
 
         moreover
 
         hence "cnj v1 * v2 = cnj ?k * cnj ?d"
           by (metis complex_cnj_cnj complex_cnj_mult)
         hence "cnj v1 * v2 = ?k * ?cd"
           using \<open>cnj ?k = ?k\<close> \<open>cnj ?d = ?cd\<close>
           by metis
 
         ultimately
 
         show ?thesis
           using \<open>~ ?den \<noteq> 0\<close> \<open>v1 * cnj v2 \<noteq> 0\<close> \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close> \<open>Re ?k \<noteq> 0\<close> \<open>is_real ?k\<close> \<open>?d \<noteq> 0\<close>
           using complex_mult_cnj_cmod[symmetric, of u1]
           using complex_mult_cnj_cmod[symmetric, of v1]
           using complex_mult_cnj_cmod[symmetric, of u2]
           using complex_mult_cnj_cmod[symmetric, of v2]
           apply (simp add: power_divide norm_mult norm_divide)
           apply (rule_tac x="Re ?k" in exI)
           apply simp
           apply (simp add: field_simps)
           done
         qed
 
         moreover
 
         have "poincare_line_cvec_cmat (u1, u2) (v1, v2) = ?H'"
           using \<open>\<not> ?den \<noteq> 0\<close> \<open>\<not> u1 * cnj u2 \<noteq> 0\<close> \<open>v1 * cnj v2 \<noteq> 0\<close>
           unfolding poincare_line_cvec_cmat_def
           by (simp add: Let_def)
 
         moreover
 
         hence "hermitean ?H' \<and> ?H' \<noteq> mat_zero"
           by (metis mk_poincare_line_cmat_hermitean poincare_line_cvec_cmat_nonzero uv(1) uv(2))
 
         hence "hermitean ?H \<and> ?H \<noteq> mat_zero"
           using \<open>circline_eq_cmat ?H ?H'\<close>
           using circline_eq_cmat_hermitean_nonzero[of ?H' ?H] symp_circline_eq_cmat
           unfolding symp_def
           by metis
 
         hence "mk_circline_cmat ?A ?B ?C ?D = ?H"
           by simp
 
         ultimately
 
         have "circline_eq_cmat (mk_circline_cmat ?A ?B ?C ?D)
                                (poincare_line_cvec_cmat (u1, u2) (v1, v2))"
           by simp
         thus ?thesis
           using symp_circline_eq_cmat
           unfolding symp_def
           by blast
       next
         case False
         hence False
           using \<open>\<not> ?den \<noteq> 0\<close> \<open>\<not> u1 * cnj u2 \<noteq> 0\<close> uv
           by (simp add: \<open>u2 \<noteq> 0\<close> \<open>v2 \<noteq> 0\<close>)
         thus ?thesis
           by simp
       qed
     qed
   qed                    
 qed
 
 text\<open>Our construction (in homogenous coordinates) always yields an h-line that contain two starting
 points (this also holds for all degenerate cases except when points are the same).\<close>
 lemma poincare_line [simp]:
   assumes "z \<noteq> w"
   shows "on_circline (poincare_line z w) z"
         "on_circline (poincare_line z w) w"
 proof-
   have "on_circline (poincare_line z w) z \<and> on_circline (poincare_line z w) w"
     using assms
   proof (transfer, transfer)
     fix z w
     assume vz: "z \<noteq> vec_zero" "w \<noteq> vec_zero"
     obtain z1 z2 w1 w2 where
     zw: "(z1, z2) = z" "(w1, w2) = w"
       by (cases z, cases w, auto)
 
     let ?den = "z1*cnj z2*cnj w1*w2 - w1*cnj w2*cnj z1*z2"
     have *: "cor (Re (\<i> * ?den)) = \<i> * ?den"
     proof-
       have "cnj ?den = -?den"
         by auto
       hence "is_imag ?den"
         using eq_minus_cnj_iff_imag[of ?den]
         by simp
       thus ?thesis
         using complex_of_real_Re[of "\<i> * ?den"]
         by simp
     qed
     show "on_circline_cmat_cvec (poincare_line_cvec_cmat z w) z \<and>
           on_circline_cmat_cvec (poincare_line_cvec_cmat z w) w"
       unfolding poincare_line_cvec_cmat_def mk_poincare_line_cmat_def
       apply (subst zw[symmetric])+
       unfolding Let_def prod.case
       apply (subst *)+
       by (auto simp add: vec_cnj_def field_simps)
   qed
   thus "on_circline (poincare_line z w) z" "on_circline (poincare_line z w) w"
     by auto
 qed
 
 lemma poincare_line_circline_set [simp]:
   assumes "z \<noteq> w"
   shows "z \<in> circline_set (poincare_line z w)"
         "w \<in> circline_set (poincare_line z w)"
   using assms
   by (auto simp add: circline_set_def)
 
 text\<open>When the points are different, the constructed line matrix always has a negative determinant\<close>
 lemma poincare_line_type:
   assumes "z \<noteq> w"
   shows "circline_type (poincare_line z w) = -1"
 proof-
   have "\<exists> a b. a \<noteq> b \<and> {a, b} \<subseteq> circline_set (poincare_line z w)"
     using poincare_line[of z w] assms
     unfolding circline_set_def
     by (rule_tac x=z in exI, rule_tac x=w in exI, simp)
   thus ?thesis
     using circline_type[of "poincare_line z w"]
     using circline_type_pos_card_eq0[of "poincare_line z w"]
     using circline_type_zero_card_eq1[of "poincare_line z w"]
     by auto
 qed
 
 text\<open>The constructed line is an h-line in the Poincar\'e model (in all cases when the two points are
 different)\<close>
 lemma is_poincare_line_poincare_line [simp]:
   assumes "z \<noteq> w"
   shows "is_poincare_line (poincare_line z w)"
   using poincare_line_type[of z w, OF assms]
 proof (transfer, transfer)
   fix z w
   assume vz: "z \<noteq> vec_zero" "w \<noteq> vec_zero"
   obtain A B C D where *: "poincare_line_cvec_cmat z w = (A, B, C, D)"
     by (cases "poincare_line_cvec_cmat z w") auto
   assume "circline_type_cmat (poincare_line_cvec_cmat z w) = - 1"
   thus "is_poincare_line_cmat (poincare_line_cvec_cmat z w)"
     using vz *
     using poincare_line_cvec_cmat_hermitean[of z w]
     using poincare_line_cvec_cmat_nonzero[of z w]
     using poincare_line_cvec_cmat_AeqD[of z w A B C D]
     using hermitean_elems[of A B C D]
     using cmod_power2[of D] cmod_power2[of C]
     unfolding is_poincare_line_cmat_def
     by (simp del: poincare_line_cvec_cmat_def add: sgn_1_neg power2_eq_square)
 qed
 
 text \<open>When the points are different, the constructed h-line between two points also contains their inverses\<close>
 lemma poincare_line_inversion:
   assumes "z \<noteq> w"
   shows "on_circline (poincare_line z w) (inversion z)"
         "on_circline (poincare_line z w) (inversion w)"
   using assms
   using is_poincare_line_poincare_line[OF \<open>z \<noteq> w\<close>]
   using is_poincare_line_inverse_point
   unfolding circline_set_def
   by auto
 
 text \<open>When the points are different, the onstructed h-line between two points contains the inverse of its every point\<close>
 lemma poincare_line_inversion_full:
   assumes "u \<noteq> v"
   assumes "on_circline (poincare_line u v) x"
   shows "on_circline (poincare_line u v) (inversion x)"
   using is_poincare_line_inverse_point[of "poincare_line u v" x]
   using is_poincare_line_poincare_line[OF \<open>u \<noteq> v\<close>] assms
   unfolding circline_set_def
   by simp
 
 subsubsection \<open>Existence of h-lines\<close>
 
 text\<open>There is an h-line trough every point in the Poincar\'e model\<close>
 lemma ex_poincare_line_one_point:
   shows "\<exists> l. is_poincare_line l \<and> z \<in> circline_set l"
 proof (cases "z = 0\<^sub>h")
   case True
   thus ?thesis
     by (rule_tac x="x_axis" in exI) simp
 next
   case False
   thus ?thesis
     by (rule_tac x="poincare_line 0\<^sub>h z" in exI) auto
 qed
 
 lemma poincare_collinear_singleton [simp]:
   assumes "u \<in> unit_disc"
   shows "poincare_collinear {u}"
   using assms
   using ex_poincare_line_one_point[of u]
   by (auto simp add: poincare_collinear_def)
 
 text\<open>There is an h-line trough every two points in the Poincar\'e model\<close>
 lemma ex_poincare_line_two_points:
   assumes "z \<noteq> w"
   shows "\<exists> l. is_poincare_line l \<and> z \<in> circline_set l \<and> w \<in> circline_set l"
   using assms
   by (rule_tac x="poincare_line z w" in exI, simp)
 
 lemma poincare_collinear_doubleton [simp]:
   assumes "u \<in> unit_disc" "v \<in> unit_disc"
   shows "poincare_collinear {u, v}"
   using assms
   using ex_poincare_line_one_point[of u]
   using ex_poincare_line_two_points[of u v]
   by (cases "u = v") (simp_all add: poincare_collinear_def)
 
 
 subsubsection \<open>Uniqueness of h-lines\<close>
 
 text \<open>The only h-line between two points is the one obtained by the line-construction.\<close> 
 text \<open>First we show this only for two different points inside the disc.\<close>
 lemma unique_poincare_line:
   assumes in_disc: "u \<noteq> v" "u \<in> unit_disc" "v \<in> unit_disc"
   assumes on_l: "u \<in> circline_set l" "v \<in> circline_set l" "is_poincare_line l"
   shows "l = poincare_line u v"
   using assms
   using unique_is_poincare_line[of u v l "poincare_line u v"]
   unfolding circline_set_def
   by auto
 
 text\<open>The assumption that the points are inside the disc can be relaxed.\<close>
 lemma unique_poincare_line_general:
   assumes in_disc: "u \<noteq> v" "u \<noteq> inversion v"
   assumes on_l: "u \<in> circline_set l" "v \<in> circline_set l" "is_poincare_line l"
   shows "l = poincare_line u v"
   using assms
   using unique_is_poincare_line_general[of u v l "poincare_line u v"]
   unfolding circline_set_def
   by auto
 
 text\<open>The explicit line construction enables us to prove that there exists a unique h-line through any
 given two h-points (uniqueness part was already shown earlier).\<close>
 text \<open>First we show this only for two different points inside the disc.\<close>
 lemma ex1_poincare_line:
   assumes "u \<noteq> v" "u \<in> unit_disc" "v \<in> unit_disc"
   shows "\<exists>! l. is_poincare_line l \<and> u \<in> circline_set l \<and> v \<in> circline_set l"
 proof (rule ex1I)
   let ?l = "poincare_line u v"
   show "is_poincare_line ?l \<and> u \<in> circline_set ?l \<and> v \<in> circline_set ?l"
     using assms
     unfolding circline_set_def
     by auto
 next
   fix l
   assume "is_poincare_line l \<and> u \<in> circline_set l \<and> v \<in> circline_set l"
   thus "l = poincare_line u v"
     using unique_poincare_line assms
     by auto
 qed
 
 text \<open>The assumption that the points are in the disc can be relaxed.\<close>
 lemma ex1_poincare_line_general:
   assumes "u \<noteq> v" "u \<noteq> inversion v"
   shows "\<exists>! l. is_poincare_line l \<and> u \<in> circline_set l \<and> v \<in> circline_set l"
 proof (rule ex1I)
   let ?l = "poincare_line u v"
   show "is_poincare_line ?l \<and> u \<in> circline_set ?l \<and> v \<in> circline_set ?l"
     using assms
     unfolding circline_set_def
     by auto
 next
   fix l
   assume "is_poincare_line l \<and> u \<in> circline_set l \<and> v \<in> circline_set l"
   thus "l = poincare_line u v"
     using unique_poincare_line_general assms
     by auto
 qed
 
 subsubsection \<open>Some consequences of line uniqueness\<close>
 
 text\<open>H-line $uv$ is the same as the h-line $vu$.\<close>
 lemma poincare_line_sym:
   assumes "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
   shows "poincare_line u v = poincare_line v u"
   using assms
   using unique_poincare_line[of u v "poincare_line v u"]
   by simp
 
 lemma poincare_line_sym_general:
   assumes "u \<noteq> v" "u \<noteq> inversion v"
   shows "poincare_line u v = poincare_line v u"
   using assms
   using unique_poincare_line_general[of u v "poincare_line v u"]
   by simp
 
 text\<open>Each h-line is the h-line constructed out of its two arbitrary different points.\<close>
 lemma ex_poincare_line_points:
   assumes "is_poincare_line H"
   shows "\<exists> u v. u \<in> unit_disc \<and> v \<in> unit_disc \<and> u \<noteq> v \<and> H = poincare_line u v"
   using assms
   using ex_is_poincare_line_points
   using unique_poincare_line[where l=H]
   by fastforce
 
 text\<open>If an h-line contains two different points on x-axis/y-axis then it is the x-axis/y-axis.\<close>
 lemma poincare_line_0_real_is_x_axis:
   assumes "x \<in> circline_set x_axis" "x \<noteq> 0\<^sub>h" "x \<noteq> \<infinity>\<^sub>h"
   shows "poincare_line 0\<^sub>h x = x_axis"
   using assms
   using is_poincare_line_0_real_is_x_axis[of "poincare_line 0\<^sub>h x" x]
   by auto
 
 lemma poincare_line_0_imag_is_y_axis:
   assumes "y \<in> circline_set y_axis" "y \<noteq> 0\<^sub>h" "y \<noteq> \<infinity>\<^sub>h"
   shows "poincare_line 0\<^sub>h y = y_axis"
   using assms
   using is_poincare_line_0_imag_is_y_axis[of "poincare_line 0\<^sub>h y" y]
   by auto
 
 lemma poincare_line_x_axis:
   assumes "x \<in> unit_disc" "y \<in> unit_disc" "x \<in> circline_set x_axis" "y \<in> circline_set x_axis" "x \<noteq> y"
   shows "poincare_line x y = x_axis"
   using assms
   using unique_poincare_line
   by auto
 
 lemma poincare_line_minus_one_one [simp]: 
   shows "poincare_line (of_complex (-1)) (of_complex 1) = x_axis"
 proof-
   have "0\<^sub>h \<in> circline_set (poincare_line (of_complex (-1)) (of_complex 1))"
     unfolding circline_set_def
     by simp (transfer, transfer,  simp add: vec_cnj_def)
   hence "poincare_line 0\<^sub>h (of_complex 1) = poincare_line (of_complex (-1)) (of_complex 1)"
     by (metis is_poincare_line_poincare_line is_poincare_line_trough_zero_trough_infty not_zero_on_unit_circle of_complex_inj of_complex_one one_neq_neg_one one_on_unit_circle poincare_line_0_real_is_x_axis poincare_line_circline_set(2) reciprocal_involution reciprocal_one reciprocal_zero unique_circline_01inf')
   thus ?thesis
     using poincare_line_0_real_is_x_axis[of "of_complex 1"]
     by auto
 qed
 
 subsubsection \<open>Transformations of constructed lines\<close>
 
 text\<open>Unit dics preserving Möbius transformations preserve the h-line construction\<close>
 lemma unit_disc_fix_preserve_poincare_line [simp]:
   assumes "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
   shows "poincare_line (moebius_pt M u) (moebius_pt M v) = moebius_circline M (poincare_line u v)"
 proof (rule unique_poincare_line[symmetric])
   show "moebius_pt M u \<noteq> moebius_pt M v"
     using \<open>u \<noteq> v\<close> 
     by auto
 next
   show "moebius_pt M u \<in> circline_set (moebius_circline M (poincare_line u v))"
        "moebius_pt M v \<in> circline_set (moebius_circline M (poincare_line u v))"
     unfolding circline_set_def
     using moebius_circline[of M "poincare_line u v"] \<open>u \<noteq> v\<close>
     by auto
 next
   from assms(1) have "unit_circle_fix M"
     by simp
   thus "is_poincare_line (moebius_circline M (poincare_line u v))"
     using unit_circle_fix_preserve_is_poincare_line assms
     by auto
 next
   show "moebius_pt M u \<in> unit_disc" "moebius_pt M v \<in> unit_disc"
     using assms(2-3) unit_disc_fix_iff[OF assms(1)]
     by auto
 qed
 
 text\<open>Conjugate preserve the h-line construction\<close>
 lemma conjugate_preserve_poincare_line [simp]:
   assumes "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
   shows "poincare_line (conjugate u) (conjugate v) = conjugate_circline (poincare_line u v)"
 proof-
   have "conjugate u \<noteq> conjugate v"
     using \<open>u \<noteq> v\<close>
     by (auto simp add: conjugate_inj)
   moreover
   have "conjugate u \<in> unit_disc" "conjugate v \<in> unit_disc"
     using assms
     by auto
   moreover
   have "conjugate u \<in> circline_set (conjugate_circline (poincare_line u v))"
        "conjugate v \<in> circline_set (conjugate_circline (poincare_line u v))"
     using \<open>u \<noteq> v\<close>
     by simp_all
   moreover
   have "is_poincare_line (conjugate_circline (poincare_line u v))"
     using is_poincare_line_poincare_line[OF \<open>u \<noteq> v\<close>]
     by simp
   ultimately
   show ?thesis
     using unique_poincare_line[of "conjugate u" "conjugate v" "conjugate_circline (poincare_line u v)"]
     by simp
 qed
 
 subsubsection \<open>Collinear points and h-lines\<close>
 
 lemma poincare_collinear3_poincare_line_general:
   assumes "poincare_collinear {a, a1, a2}" "a1 \<noteq> a2" "a1 \<noteq> inversion a2"
   shows "a \<in> circline_set (poincare_line a1 a2)"
   using assms
   using poincare_collinear_def unique_poincare_line_general
   by auto
 
 lemma poincare_line_poincare_collinear3_general:
   assumes "a \<in> circline_set (poincare_line a1 a2)" "a1 \<noteq> a2"
   shows "poincare_collinear {a, a1, a2}"
   using assms
   unfolding poincare_collinear_def
   by (rule_tac x="poincare_line a1 a2" in exI, simp)
   
 
 lemma poincare_collinear3_poincare_lines_equal_general:
   assumes "poincare_collinear {a, a1, a2}" "a \<noteq> a1" "a \<noteq> a2" "a \<noteq> inversion a1" "a \<noteq> inversion a2"
   shows "poincare_line a a1 = poincare_line a a2"
   using assms
   using unique_poincare_line_general[of a a2 "poincare_line a a1"]
   by (simp add: insert_commute poincare_collinear3_poincare_line_general)
 
 subsubsection \<open>Points collinear with @{term "0\<^sub>h"}\<close>
 
 lemma poincare_collinear_zero_iff:
   assumes "of_complex y' \<in> unit_disc" and "of_complex z' \<in> unit_disc" and
           "y' \<noteq> z'" and "y' \<noteq> 0" and "z' \<noteq> 0"
   shows "poincare_collinear {0\<^sub>h, of_complex y', of_complex z'} \<longleftrightarrow>
          y'*cnj z' = cnj y'*z'" (is "?lhs \<longleftrightarrow> ?rhs")
 proof-
   have "of_complex y' \<noteq> of_complex z'"
     using assms
     using of_complex_inj
     by blast
   show ?thesis
   proof
     assume ?lhs
     hence "0\<^sub>h \<in> circline_set (poincare_line (of_complex y') (of_complex z'))"
       using unique_poincare_line[of "of_complex y'" "of_complex z'"]
       using assms \<open>of_complex y' \<noteq> of_complex z'\<close>
       unfolding poincare_collinear_def
       by auto
     moreover
     let ?mix = "y' * cnj z' - cnj y' * z'"
     have "is_real (\<i> * ?mix)"
       using eq_cnj_iff_real[of ?mix]
       by auto
     hence "y' * cnj z' = cnj y' * z' \<longleftrightarrow> Re (\<i> * ?mix) = 0"
       using complex.expand[of "\<i> * ?mix" 0]
       by (metis complex_i_not_zero eq_iff_diff_eq_0 mult_eq_0_iff zero_complex.simps(1) zero_complex.simps(2))
     ultimately
     show ?rhs
       using \<open>y' \<noteq> z'\<close> \<open>y' \<noteq> 0\<close> \<open>z' \<noteq> 0\<close>
       unfolding circline_set_def
       by simp (transfer, transfer, auto simp add: vec_cnj_def split: if_split_asm, metis Re_complex_of_real Re_mult_real Im_complex_of_real)
   next
     assume ?rhs
     thus ?lhs
       using assms \<open>of_complex y' \<noteq> of_complex z'\<close>
       unfolding poincare_collinear_def
       unfolding circline_set_def
       apply (rule_tac x="poincare_line (of_complex y') (of_complex z')" in exI)
       apply auto
       apply (transfer, transfer, simp add: vec_cnj_def)
       done
   qed
 qed
 
 lemma poincare_collinear_zero_polar_form:
   assumes "poincare_collinear {0\<^sub>h, of_complex x, of_complex y}" and
           "x \<noteq> 0" and "y \<noteq> 0" and "of_complex x \<in> unit_disc" and "of_complex y \<in> unit_disc"
   shows "\<exists> \<phi> rx ry. x = cor rx * cis \<phi> \<and> y = cor ry * cis \<phi> \<and> rx \<noteq> 0 \<and> ry \<noteq> 0"
 proof-
   from \<open>x \<noteq> 0\<close> \<open>y \<noteq> 0\<close> obtain \<phi> \<phi>' rx ry where
-    polar: "x = cor rx * cis \<phi>" "y = cor ry * cis \<phi>'" and  "\<phi> = arg x" "\<phi>' = arg y"
+    polar: "x = cor rx * cis \<phi>" "y = cor ry * cis \<phi>'" and  "\<phi> = Arg x" "\<phi>' = Arg y"
     by (metis cmod_cis)
   hence "rx \<noteq> 0" "ry \<noteq> 0"
     using \<open>x \<noteq> 0\<close> \<open>y \<noteq> 0\<close>
     by auto
   have "of_complex y \<in> circline_set (poincare_line 0\<^sub>h (of_complex x))"
     using assms
     using unique_poincare_line[of "0\<^sub>h" "of_complex x"]
     unfolding poincare_collinear_def
     unfolding circline_set_def
     using of_complex_zero_iff
     by fastforce
   hence "cnj x * y = x * cnj y"
     using \<open>x \<noteq> 0\<close> \<open>y \<noteq> 0\<close>
     unfolding circline_set_def
     by simp (transfer, transfer, simp add: vec_cnj_def field_simps)
   hence "cis(\<phi>' - \<phi>) = cis(\<phi> - \<phi>')"
     using polar \<open>rx \<noteq> 0\<close> \<open>ry \<noteq> 0\<close>
     by (simp add: cis_mult)
   hence "sin (\<phi>' - \<phi>) = 0"
     using cis_diff_cis_opposite[of "\<phi>' - \<phi>"]
     by simp
   then obtain k :: int where "\<phi>' - \<phi> = k * pi"
     using sin_zero_iff_int2[of "\<phi>' - \<phi>"]
     by auto
   hence *: "\<phi>' = \<phi> + k * pi"
     by simp
   show ?thesis
   proof (cases "even k")
     case True
     then obtain k' where "k = 2*k'"
       using evenE by blast
     hence "cis \<phi> = cis \<phi>'"
       using * cos_periodic_int sin_periodic_int
       by (simp add: cis.ctr field_simps)
     thus ?thesis
       using polar \<open>rx \<noteq> 0\<close> \<open>ry \<noteq> 0\<close>
       by (rule_tac x=\<phi> in exI, rule_tac x=rx in exI, rule_tac x=ry in exI) simp
   next
     case False
     then obtain k' where "k = 2*k' + 1"
       using oddE by blast
     hence "cis \<phi> = - cis \<phi>'"
       using * cos_periodic_int sin_periodic_int
       by (simp add: cis.ctr complex_minus field_simps)
     thus ?thesis
       using polar \<open>rx \<noteq> 0\<close> \<open>ry \<noteq> 0\<close>
       by (rule_tac x=\<phi> in exI, rule_tac x=rx in exI, rule_tac x="-ry" in exI) simp
   qed
 qed
 
 end
diff --git a/thys/Poincare_Disc/Poincare_Lines_Axis_Intersections.thy b/thys/Poincare_Disc/Poincare_Lines_Axis_Intersections.thy
--- a/thys/Poincare_Disc/Poincare_Lines_Axis_Intersections.thy
+++ b/thys/Poincare_Disc/Poincare_Lines_Axis_Intersections.thy
@@ -1,1234 +1,1234 @@
 theory Poincare_Lines_Axis_Intersections
   imports Poincare_Between
 begin
 
 (* ------------------------------------------------------------------ *)
 section\<open>Intersection of h-lines with the x-axis in the Poincar\'e model\<close>
 (* ------------------------------------------------------------------ *)
 
 (* ---------------------------------------------------------------- *)
 subsection\<open>Betweeness of x-axis intersection\<close>
 (* ---------------------------------------------------------------- *)
 
 text\<open>The intersection point of the h-line determined by points $u$ and $v$ and the x-axis is between
 $u$ and $v$, then $u$ and $v$ are in the opposite half-planes (one must be in the upper, and the
 other one in the lower half-plane).\<close>
 
 lemma poincare_between_x_axis_intersection:
   assumes "u \<in> unit_disc" and "v \<in> unit_disc" and "z \<in> unit_disc" and "u \<noteq> v"
   assumes "u \<notin> circline_set x_axis" and "v \<notin> circline_set x_axis"
   assumes "z \<in> circline_set (poincare_line u v) \<inter> circline_set x_axis"
-  shows "poincare_between u z v \<longleftrightarrow> arg (to_complex u) * arg (to_complex v) < 0"
+  shows "poincare_between u z v \<longleftrightarrow> Arg (to_complex u) * Arg (to_complex v) < 0"
 proof-
   have "\<forall> u v. u \<in> unit_disc \<and> v \<in> unit_disc \<and> u \<noteq> v \<and>
        u \<notin> circline_set x_axis \<and> v \<notin> circline_set x_axis \<and> 
        z \<in> circline_set (poincare_line u v) \<inter> circline_set x_axis \<longrightarrow> 
-       (poincare_between u z v \<longleftrightarrow> arg (to_complex u) * arg (to_complex v) < 0)" (is "?P z")
+       (poincare_between u z v \<longleftrightarrow> Arg (to_complex u) * Arg (to_complex v) < 0)" (is "?P z")
   proof (rule wlog_real_zero)
     show "?P 0\<^sub>h"
     proof ((rule allI)+, rule impI, (erule conjE)+)
       fix u v
       assume *: "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
                 "u \<notin> circline_set x_axis" "v \<notin> circline_set x_axis"
                 "0\<^sub>h \<in> circline_set (poincare_line u v) \<inter> circline_set x_axis"
       obtain u' v' where uv: "u = of_complex u'" "v = of_complex v'"
         using * inf_or_of_complex[of u] inf_or_of_complex[of v]
         by auto
 
        
       hence "u \<noteq> 0\<^sub>h" "v \<noteq> 0\<^sub>h" "u' \<noteq> 0" "v' \<noteq> 0"
         using *
         by auto
 
-      hence "arg u' \<noteq> 0" "arg v' \<noteq> 0"
+      hence "Arg u' \<noteq> 0" "Arg v' \<noteq> 0"
         using * arg_0_iff[of u'] arg_0_iff[of v']
         unfolding circline_set_x_axis uv
         by auto
 
       have "poincare_collinear {0\<^sub>h, u, v}"
         using *
         unfolding poincare_collinear_def
         by (rule_tac x="poincare_line u v" in exI, simp)
-      have "(\<exists>k<0. u' = cor k * v') \<longleftrightarrow> (arg u' * arg v' < 0)" (is "?lhs \<longleftrightarrow> ?rhs")
+      have "(\<exists>k<0. u' = cor k * v') \<longleftrightarrow> (Arg u' * Arg v' < 0)" (is "?lhs \<longleftrightarrow> ?rhs")
       proof
         assume "?lhs"
         then obtain k where "k < 0" "u' = cor k * v'"
           by auto
         thus ?rhs
           using arg_mult_real_negative[of k v'] arg_uminus_opposite_sign[of v']
-          using \<open>u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close> \<open>arg u' \<noteq> 0\<close> \<open>arg v' \<noteq> 0\<close>
+          using \<open>u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close> \<open>Arg u' \<noteq> 0\<close> \<open>Arg v' \<noteq> 0\<close>
           by (auto simp add: mult_neg_pos mult_pos_neg)
       next
         assume ?rhs
         obtain ru rv \<phi> where polar: "u' = cor ru * cis \<phi>" "v' = cor rv * cis \<phi>"
           using \<open>poincare_collinear {0\<^sub>h, u, v}\<close> poincare_collinear_zero_polar_form[of u' v'] uv * \<open>u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close>
           by auto
         have "ru * rv < 0"
           using polar \<open>?rhs\<close> \<open>u' \<noteq> 0\<close> \<open>v' \<noteq> 0\<close>
           using arg_mult_real_negative[of "ru" "cis \<phi>"] arg_mult_real_positive[of "ru" "cis \<phi>"]
           using arg_mult_real_negative[of "rv" "cis \<phi>"] arg_mult_real_positive[of "rv" "cis \<phi>"]
           apply (cases "ru > 0")
           apply (cases "rv > 0", simp, simp add: mult_pos_neg)
           apply (cases "rv > 0", simp add: mult_neg_pos, simp)
           done
         thus "?lhs"
           using polar     
           by (rule_tac x="ru / rv" in exI, auto simp add: divide_less_0_iff mult_less_0_iff)
       qed
-      thus "poincare_between u 0\<^sub>h v = (arg (to_complex u) * arg (to_complex v) < 0)"
+      thus "poincare_between u 0\<^sub>h v = (Arg (to_complex u) * Arg (to_complex v) < 0)"
         using poincare_between_u0v[of u v] * \<open>u \<noteq> 0\<^sub>h\<close> \<open>v \<noteq> 0\<^sub>h\<close> uv
         by simp
     qed
   next
     fix a z 
     assume 1: "is_real a" "cmod a < 1" "z \<in> unit_disc"
     assume 2: "?P (moebius_pt (blaschke a) z)"
     show "?P z"
     proof ((rule allI)+, rule impI, (erule conjE)+)
       fix u v
       let ?M = "moebius_pt (blaschke a)"
       let ?Mu = "?M u"
       let ?Mv = "?M v"
       assume *: "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v" "u \<notin> circline_set x_axis" "v \<notin> circline_set x_axis"
       hence "u \<noteq> \<infinity>\<^sub>h" "v \<noteq> \<infinity>\<^sub>h"
         by auto
 
       have **: "\<And> x y :: real. x * y < 0 \<longleftrightarrow> sgn (x * y) < 0"
         by simp
 
       assume "z \<in> circline_set (poincare_line u v) \<inter> circline_set x_axis"
-      thus "poincare_between u z v = (arg (to_complex u) * arg (to_complex v) < 0)"
+      thus "poincare_between u z v = (Arg (to_complex u) * Arg (to_complex v) < 0)"
         using * 1 2[rule_format, of ?Mu ?Mv] \<open>cmod a < 1\<close> \<open>is_real a\<close> blaschke_unit_disc_fix[of a]
         using inversion_noteq_unit_disc[of "of_complex a" u] \<open>u \<noteq> \<infinity>\<^sub>h\<close>
         using inversion_noteq_unit_disc[of "of_complex a" v] \<open>v \<noteq> \<infinity>\<^sub>h\<close>
         apply auto
         apply (subst (asm) **, subst **, subst (asm) sgn_mult, subst sgn_mult, simp)
         apply (subst (asm) **, subst (asm) **, subst (asm) sgn_mult, subst (asm) sgn_mult, simp)
         done
     qed
   next
     show "z \<in> unit_disc" by fact
   next
     show "is_real (to_complex z)"
       using assms inf_or_of_complex[of z]
       by (auto simp add: circline_set_x_axis)
   qed
   thus ?thesis
     using assms
     by simp
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Check if an h-line intersects the x-axis\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma x_axis_intersection_equation:
   assumes
    "H = mk_circline A B C D" and
    "(A, B, C, D) \<in> hermitean_nonzero"
  shows "of_complex z \<in> circline_set x_axis \<inter> circline_set H \<longleftrightarrow>
         A*z\<^sup>2 + 2*Re B*z + D = 0 \<and> is_real z" (is "?lhs \<longleftrightarrow> ?rhs")
 proof-
   have "?lhs \<longleftrightarrow> A*z\<^sup>2 + (B + cnj B)*z + D = 0 \<and> z = cnj z"
     using assms
     using circline_equation_x_axis[of z]
     using circline_equation[of H A B C D z]
     using hermitean_elems
     by (auto simp add: power2_eq_square field_simps)
   thus ?thesis
     using eq_cnj_iff_real[of z]
     using hermitean_elems[of A B C D]
     by (simp add: complex_add_cnj complex_eq_if_Re_eq)
 qed
 
 text \<open>Check if an h-line intersects x-axis within the unit disc - this could be generalized to
 checking if an arbitrary circline intersects the x-axis, but we do not need that.\<close>
 
 definition intersects_x_axis_cmat :: "complex_mat \<Rightarrow> bool" where
   [simp]: "intersects_x_axis_cmat H = (let (A, B, C, D) = H in A = 0 \<or> (Re B)\<^sup>2 > (Re A)\<^sup>2)"
 
 lift_definition intersects_x_axis_clmat :: "circline_mat \<Rightarrow> bool" is intersects_x_axis_cmat
   done
 
 lift_definition intersects_x_axis :: "circline \<Rightarrow> bool" is intersects_x_axis_clmat
 proof (transfer)
   fix H1 H2
   assume hh: "hermitean H1 \<and> H1 \<noteq> mat_zero" and "hermitean H2 \<and> H2 \<noteq> mat_zero"
   obtain A1 B1 C1 D1 A2 B2 C2 D2 where *: "H1 = (A1, B1, C1, D1)" "H2 = (A2, B2, C2, D2)"
     by (cases H1, cases H2, auto)
   assume "circline_eq_cmat H1 H2"
   then obtain k where k: "k \<noteq> 0 \<and> H2 = cor k *\<^sub>s\<^sub>m H1"
     by auto
   show "intersects_x_axis_cmat H1 = intersects_x_axis_cmat H2"
   proof-
     have "k \<noteq> 0 \<Longrightarrow> (Re A1)\<^sup>2 < (Re B1)\<^sup>2 \<longleftrightarrow> (k * Re A1)\<^sup>2 < (k * Re B1)\<^sup>2"
       by (smt mult_strict_left_mono power2_eq_square semiring_normalization_rules(13) zero_less_power2)
     thus ?thesis
       using * k
       by auto
   qed
 qed
 
 lemma intersects_x_axis_mk_circline:
   assumes "is_real A" and "A \<noteq> 0 \<or> B \<noteq> 0"
   shows "intersects_x_axis (mk_circline A B (cnj B) A) \<longleftrightarrow> A = 0 \<or> (Re B)\<^sup>2 > (Re A)\<^sup>2"
 proof-
   let ?H = "(A, B, (cnj B),  A)"
   have "hermitean ?H"                
     using \<open>is_real A\<close> 
     unfolding hermitean_def mat_adj_def mat_cnj_def
     using eq_cnj_iff_real 
     by auto
   moreover
   have "?H \<noteq> mat_zero"
     using assms
     by auto
   ultimately
   show ?thesis
     by (transfer, transfer, auto simp add: Let_def)
 qed
 
 lemma intersects_x_axis_iff:
   assumes "is_poincare_line H"
   shows "(\<exists> x \<in> unit_disc. x \<in> circline_set H \<inter> circline_set x_axis) \<longleftrightarrow> intersects_x_axis H"
 proof-
   obtain Ac B C Dc where  *: "H = mk_circline Ac B C Dc" "hermitean (Ac, B, C, Dc)" "(Ac, B, C, Dc) \<noteq> mat_zero"
     using ex_mk_circline[of H]
     by auto
   hence "(cmod B)\<^sup>2 > (cmod Ac)\<^sup>2" "Ac = Dc"
     using assms
     using is_poincare_line_mk_circline
     by auto
 
   hence "H = mk_circline (Re Ac) B (cnj B) (Re Ac)" "hermitean (cor (Re Ac),  B, (cnj B), cor (Re Ac))" "(cor (Re Ac),  B, (cnj B), cor (Re Ac)) \<noteq> mat_zero"
     using hermitean_elems[of Ac B C Dc] *
     by auto
   then obtain A where
     *: "H = mk_circline (cor A) B (cnj B) (cor A)" "(cor A,  B, (cnj B), cor A) \<in> hermitean_nonzero"
     by auto
 
   show ?thesis
   proof (cases "A = 0")
     case True
     thus ?thesis
       using *
       using x_axis_intersection_equation[OF *(1-2), of 0]
       using intersects_x_axis_mk_circline[of "cor A" B]
       by auto
   next
     case False
     show ?thesis
     proof
       assume "\<exists> x \<in> unit_disc. x \<in> circline_set H \<inter> circline_set x_axis"
       then obtain x where **: "of_complex x \<in> unit_disc" "of_complex x \<in> circline_set H \<inter> circline_set x_axis"
         by (metis inf_or_of_complex inf_notin_unit_disc)
       hence "is_real x"
         unfolding circline_set_x_axis
         using of_complex_inj
         by auto
       hence eq: "A * (Re x)\<^sup>2 + 2 * Re B * Re x + A = 0"
         using **
         using x_axis_intersection_equation[OF *(1-2), of "Re x"]
         by simp
       hence "(2 * Re B)\<^sup>2 - 4 * A * A \<ge> 0"
         using discriminant_iff[of A _ "2 * Re B" A]
         using discrim_def[of A "2 * Re B" A] False
         by auto
       hence "(Re B)\<^sup>2 \<ge> (Re A)\<^sup>2"
         by (simp add: power2_eq_square)
       moreover
       have "(Re B)\<^sup>2 \<noteq> (Re A)\<^sup>2"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         hence "Re B = Re A \<or> Re B = - Re A"
           using power2_eq_iff by blast
         hence "A * (Re x)\<^sup>2 +  A * 2* Re x + A = 0 \<or> A * (Re x)\<^sup>2 - A * 2 * Re x + A = 0"
           using eq
           by auto
         hence "A * ((Re x)\<^sup>2 +  2* Re x + 1) = 0 \<or> A * ((Re x)\<^sup>2 - 2 * Re x + 1) = 0"
           by (simp add: field_simps)
         hence "(Re x)\<^sup>2 + 2 * Re x + 1 = 0 \<or> (Re x)\<^sup>2 - 2 * Re x + 1 = 0"
           using \<open>A \<noteq> 0\<close>
           by simp
         hence "(Re x + 1)\<^sup>2 = 0 \<or> (Re x - 1)\<^sup>2 = 0"
           by (simp add: power2_sum power2_diff field_simps)
         hence "Re x = -1 \<or> Re x = 1"
           by auto
         thus False
           using \<open>is_real x\<close> \<open>of_complex x \<in> unit_disc\<close>
           by (auto simp add: cmod_eq_Re)
       qed
       ultimately
       show "intersects_x_axis H"
         using intersects_x_axis_mk_circline
         using *
         by auto
     next
       assume "intersects_x_axis H"
       hence "(Re B)\<^sup>2 > (Re A)\<^sup>2"
         using * False
         using intersects_x_axis_mk_circline
         by simp
       hence discr: "(2 * Re B)\<^sup>2 - 4 * A * A > 0"
         by (simp add: power2_eq_square)
       then obtain x1 x2 where
         eqs: "A * x1\<^sup>2 + 2 * Re B * x1 + A = 0" "A * x2\<^sup>2 + 2 * Re B * x2 + A = 0" "x1 \<noteq> x2"
         using discriminant_pos_ex[OF \<open>A \<noteq> 0\<close>, of "2 * Re B" A]
         using discrim_def[of A "2 * Re B" A]
         by auto
       hence "x1 * x2 = 1"
         using viette2[OF \<open>A \<noteq> 0\<close>, of "2 * Re B" A x1 x2] discr \<open>A \<noteq> 0\<close>
         by auto
       have "abs x1 \<noteq> 1" "abs x2 \<noteq> 1"
         using eqs discr \<open>x1 * x2 = 1\<close>
         by (auto simp add: abs_if power2_eq_square)
       hence "abs x1 < 1 \<or> abs x2 < 1"
         using \<open>x1 * x2 = 1\<close>
         by (smt mult_le_cancel_left1 mult_minus_right)
       thus "\<exists>x \<in> unit_disc. x \<in> circline_set H \<inter> circline_set x_axis"
         using x_axis_intersection_equation[OF *(1-2), of x1]
         using x_axis_intersection_equation[OF *(1-2), of x2]
         using eqs
         by auto
     qed
   qed
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Check if a Poincar\'e line intersects the y-axis\<close>
 (* ------------------------------------------------------------------ *)
 
 definition intersects_y_axis_cmat :: "complex_mat \<Rightarrow> bool" where
   [simp]: "intersects_y_axis_cmat H = (let (A, B, C, D) = H in A = 0 \<or> (Im B)\<^sup>2 > (Re A)\<^sup>2)"
 
 lift_definition intersects_y_axis_clmat :: "circline_mat \<Rightarrow> bool" is intersects_y_axis_cmat
   done
 
 lift_definition intersects_y_axis :: "circline \<Rightarrow> bool" is intersects_y_axis_clmat
 proof (transfer)
   fix H1 H2
   assume hh: "hermitean H1 \<and> H1 \<noteq> mat_zero" and "hermitean H2 \<and> H2 \<noteq> mat_zero"
   obtain A1 B1 C1 D1 A2 B2 C2 D2 where *: "H1 = (A1, B1, C1, D1)" "H2 = (A2, B2, C2, D2)"
     by (cases H1, cases H2, auto)
   assume "circline_eq_cmat H1 H2"
   then obtain k where k: "k \<noteq> 0 \<and> H2 = cor k *\<^sub>s\<^sub>m H1"
     by auto
   show "intersects_y_axis_cmat H1 = intersects_y_axis_cmat H2"
   proof-
     have "k \<noteq> 0 \<Longrightarrow> (Re A1)\<^sup>2 < (Im B1)\<^sup>2 \<longleftrightarrow> (k * Re A1)\<^sup>2 < (k * Im B1)\<^sup>2"
       by (smt mult_strict_left_mono power2_eq_square semiring_normalization_rules(13) zero_less_power2)
     thus ?thesis
       using * k
       by auto
   qed
 qed
 
 lemma intersects_x_axis_intersects_y_axis [simp]:
   shows "intersects_x_axis (moebius_circline (moebius_rotation (pi/2)) H) \<longleftrightarrow> intersects_y_axis H"
   unfolding moebius_rotation_def moebius_similarity_def
   by simp (transfer, transfer, auto simp add: mat_adj_def mat_cnj_def)
 
 lemma intersects_y_axis_iff:
   assumes "is_poincare_line H"
   shows "(\<exists> y \<in> unit_disc. y \<in> circline_set H \<inter> circline_set y_axis) \<longleftrightarrow> intersects_y_axis H" (is "?lhs \<longleftrightarrow> ?rhs")
 proof-
   let ?R = "moebius_rotation (pi / 2)"
   let ?H' = "moebius_circline ?R H"
   have 1: "is_poincare_line ?H'"
     using assms
     using unit_circle_fix_preserve_is_poincare_line[OF _ assms, of ?R]
     by simp
 
   show ?thesis
   proof
     assume "?lhs"
     then obtain y where "y \<in> unit_disc" "y \<in> circline_set H \<inter> circline_set y_axis"
       by auto
     hence "moebius_pt ?R y \<in> unit_disc \<and> moebius_pt ?R y \<in> circline_set ?H' \<inter> circline_set x_axis"
       using rotation_pi_2_y_axis
       by (metis Int_iff circline_set_moebius_circline_E moebius_circline_comp_inv_left moebius_pt_comp_inv_left unit_disc_fix_discI unit_disc_fix_rotation)
     thus ?rhs
       using intersects_x_axis_iff[OF 1]
       using intersects_x_axis_intersects_y_axis[of H]
       by auto
   next
     assume "intersects_y_axis H"
     hence "intersects_x_axis ?H'"
       using intersects_x_axis_intersects_y_axis[of H]
       by simp
     then obtain x where *: "x \<in> unit_disc" "x \<in> circline_set ?H' \<inter> circline_set x_axis"
       using intersects_x_axis_iff[OF 1]
       by auto
     let ?y = "moebius_pt (-?R) x"
     have "?y \<in> unit_disc \<and> ?y \<in> circline_set H \<inter> circline_set y_axis"
       using * rotation_pi_2_y_axis[symmetric]
       by (metis Int_iff circline_set_moebius_circline_E moebius_pt_comp_inv_left moebius_rotation_uminus uminus_moebius_def unit_disc_fix_discI unit_disc_fix_rotation)
     thus ?lhs
       by auto
   qed
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Intersection point of a Poincar\'e line with the x-axis in the unit disc\<close>
 (* ------------------------------------------------------------------ *)
 
 definition calc_x_axis_intersection_cvec :: "complex \<Rightarrow> complex \<Rightarrow> complex_vec" where
  [simp]:  "calc_x_axis_intersection_cvec A B =
     (let discr = (Re B)\<^sup>2 - (Re A)\<^sup>2 in
          (-Re(B) + sgn (Re B) * sqrt(discr), A))"
 
 (* intersection with the x-axis for poincare lines that are euclidean circles *)
 definition calc_x_axis_intersection_cmat_cvec :: "complex_mat \<Rightarrow> complex_vec" where [simp]:
   "calc_x_axis_intersection_cmat_cvec H =
     (let (A, B, C, D) = H in 
        if A \<noteq> 0 then
           calc_x_axis_intersection_cvec A B
        else
           (0, 1)
     )"
 
 lift_definition calc_x_axis_intersection_clmat_hcoords :: "circline_mat \<Rightarrow> complex_homo_coords" is calc_x_axis_intersection_cmat_cvec
   by (auto split: if_split_asm)
 
 lift_definition calc_x_axis_intersection :: "circline \<Rightarrow> complex_homo" is calc_x_axis_intersection_clmat_hcoords
 proof transfer
   fix H1 H2
   assume *: "hermitean H1 \<and> H1 \<noteq> mat_zero" "hermitean H2 \<and> H2 \<noteq> mat_zero"
   obtain A1 B1 C1 D1 A2 B2 C2 D2 where hh: "H1 = (A1, B1, C1, D1)" "H2 = (A2, B2, C2, D2)"
     by (cases H1, cases H2, auto)
   assume "circline_eq_cmat H1 H2"
   then obtain k where k: "k \<noteq> 0" "H2 = cor k *\<^sub>s\<^sub>m H1"
     by auto
 
   have "calc_x_axis_intersection_cvec A1 B1 \<approx>\<^sub>v calc_x_axis_intersection_cvec A2 B2"
     using hh k
     apply simp
     apply (rule_tac x="cor k" in exI)
     apply auto
     apply (simp add: sgn_mult power_mult_distrib)
     apply (subst right_diff_distrib[symmetric])
     apply (subst real_sqrt_mult)
     by (simp add: real_sgn_eq right_diff_distrib)
 
   thus "calc_x_axis_intersection_cmat_cvec H1 \<approx>\<^sub>v
         calc_x_axis_intersection_cmat_cvec H2"
     using hh k
     by (auto simp del: calc_x_axis_intersection_cvec_def)
 qed
 
 
 lemma calc_x_axis_intersection_in_unit_disc:
   assumes "is_poincare_line H" "intersects_x_axis H"
   shows "calc_x_axis_intersection H \<in> unit_disc"
 proof (cases "is_line H")
   case True
   thus ?thesis
     using assms
     unfolding unit_disc_def disc_def
     by simp (transfer, transfer, auto simp add: vec_cnj_def)
 next
   case False
   thus ?thesis
     using assms
     unfolding unit_disc_def disc_def
   proof (simp, transfer, transfer)
     fix H
     assume hh: "hermitean H \<and> H \<noteq> mat_zero"
     then obtain A B D where *: "H = (A, B, cnj B, D)" "is_real A" "is_real D"
       using hermitean_elems
       by (cases H) blast
     assume "is_poincare_line_cmat H"
     hence *: "H = (A, B, cnj B, A)" "is_real A"
       using *
       by auto
 
     assume "\<not> circline_A0_cmat H"
     hence "A \<noteq> 0"
       using *
       by simp
 
     assume "intersects_x_axis_cmat H"
     hence "(Re B)\<^sup>2 > (Re A)\<^sup>2"
       using * \<open>A \<noteq> 0\<close>
       by (auto simp add: power2_eq_square complex.expand)
 
     hence "Re B \<noteq> 0"
       by auto
 
     have "Re A \<noteq> 0"
       using \<open>is_real A\<close> \<open>A \<noteq> 0\<close>
       by (auto simp add: complex.expand)
 
     have "sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2) < sqrt((Re B)\<^sup>2)"
       using \<open>Re A \<noteq> 0\<close>
       by (subst real_sqrt_less_iff) auto
     also have "... =  sgn (Re B) * (Re B)"
       by (smt mult_minus_right nonzero_eq_divide_eq real_sgn_eq real_sqrt_abs)
     finally
     have 1: "sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2) < sgn (Re B) * (Re B)"
       .
 
     have 2: "(Re B)\<^sup>2 - (Re A)\<^sup>2 < sgn (Re B) * (Re B) * sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)"
       using \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close>
       using mult_strict_right_mono[OF 1, of "sqrt ((Re B)\<^sup>2 - (Re A)\<^sup>2)"]
       by simp
 
     have 3: "(Re B)\<^sup>2 - 2*sgn (Re B)*Re B*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2) + (Re B)\<^sup>2 - (Re A)\<^sup>2 < (Re A)\<^sup>2"
       using mult_strict_left_mono[OF 2, of 2]
       by (simp add: field_simps)
 
     have "(sgn (Re B))\<^sup>2 = 1"
       using \<open>Re B \<noteq> 0\<close>
       by (simp add: sgn_if)
 
     hence "(-Re B + sgn (Re B) * sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 < (Re A)\<^sup>2"
       using \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close> 3
       by (simp add: power2_diff field_simps)
 
     thus "in_ocircline_cmat_cvec unit_circle_cmat (calc_x_axis_intersection_cmat_cvec H)"
       using * \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close>
       by (auto simp add: vec_cnj_def power2_eq_square split: if_split_asm)
   qed
 qed
 
 
 lemma calc_x_axis_intersection:
   assumes "is_poincare_line H" and "intersects_x_axis H"
   shows "calc_x_axis_intersection H \<in> circline_set H \<inter> circline_set x_axis"
 proof (cases "is_line H")
   case True
   thus ?thesis
     using assms
     unfolding circline_set_def
     by simp (transfer, transfer, auto simp add: vec_cnj_def)
 next
   case False
   thus ?thesis
     using assms
     unfolding circline_set_def
   proof (simp, transfer, transfer)
     fix H
     assume hh: "hermitean H \<and> H \<noteq> mat_zero"
     then obtain A B D where *: "H = (A, B, cnj B, D)" "is_real A" "is_real D"
       using hermitean_elems
       by (cases H) blast
     assume "is_poincare_line_cmat H"
     hence *: "H = (A, B, cnj B, A)" "is_real A"
       using *
       by auto
     assume "\<not> circline_A0_cmat H"
     hence "A \<noteq> 0"
       using *
       by auto
 
     assume "intersects_x_axis_cmat H"
     hence "(Re B)\<^sup>2 > (Re A)\<^sup>2"
       using * \<open>A \<noteq> 0\<close>
       by (auto simp add: power2_eq_square complex.expand)
 
     hence "Re B \<noteq> 0"
       by auto
 
     show "on_circline_cmat_cvec H (calc_x_axis_intersection_cmat_cvec H) \<and>
         on_circline_cmat_cvec x_axis_cmat (calc_x_axis_intersection_cmat_cvec H)" (is "?P1 \<and> ?P2")
     proof
       show "on_circline_cmat_cvec H (calc_x_axis_intersection_cmat_cvec H)"
       proof (cases "circline_A0_cmat H")
         case True
         thus ?thesis
           using * \<open>is_poincare_line_cmat H\<close> \<open>intersects_x_axis_cmat H\<close>
           by (simp add: vec_cnj_def)
       next
         case False
         let ?x = "calc_x_axis_intersection_cvec A B"
         let ?nom = "fst ?x" and ?den = "snd ?x"
         have x: "?x = (?nom, ?den)"
           by simp
 
         hence "on_circline_cmat_cvec H (calc_x_axis_intersection_cvec A B)"
         proof (subst *, subst x, subst on_circline_cmat_cvec_circline_equation)
           have "(sgn(Re B))\<^sup>2 = 1"
             using \<open>Re B \<noteq> 0\<close> sgn_pos zero_less_power2 by fastforce
           have "(sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 = (Re B)\<^sup>2 - (Re A)\<^sup>2"
             using \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close>
             by simp
 
           have "(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 = 
                 (-(Re B))\<^sup>2 + (sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)"
             by (simp add: power2_diff)
           also have "... = (Re B)*(Re B) + (sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)"
             by (simp add: power2_eq_square)
           also have "... = (Re B)*(Re B) + (sgn(Re B))\<^sup>2*(sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)"
             by (simp add: power_mult_distrib)
           also have "... = (Re B)*(Re B) + (Re B)\<^sup>2 - (Re A)\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)"
             using \<open>(sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 = (Re B)\<^sup>2 - (Re A)\<^sup>2\<close> \<open>(sgn(Re B))\<^sup>2 = 1\<close>
             by simp
           finally have "(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 =
                         (Re B)*(Re B) + (Re B)\<^sup>2 - (Re A)\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)"
             by simp           
 
           have "is_real ?nom" "is_real ?den"
             using \<open>is_real A\<close>
             by simp+
           hence "cnj (?nom) = ?nom" "cnj (?den) = ?den"
             by (simp add:eq_cnj_iff_real)+      
           hence "A*?nom*(cnj (?nom)) + B*?den*(cnj (?nom)) + (cnj B)*(cnj (?den))*?nom + A*?den*(cnj (?den))
                 = A*?nom*?nom + B*?den*?nom + (cnj B)*?den*?nom + A*?den*?den"
             by auto
           also have "... = A*?nom*?nom + (B + (cnj B))*?den*?nom + A*?den*?den"
             by (simp add:field_simps)
           also have "... = A*?nom*?nom + 2*(Re B)*?den*?nom + A*?den*?den"
             by (simp add:complex_add_cnj)
           also have "... = A*?nom\<^sup>2 + 2*(Re B)*?den*?nom + A*?den*?den"
             by (simp add:power2_eq_square)
           also have "... = A*(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2
                            + 2*(Re B)*A*(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)) + A*A*A"
             unfolding calc_x_axis_intersection_cvec_def
             by auto
           also have "... = A*((Re B)*(Re B) + (Re B)\<^sup>2 - (Re A)\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)) 
                      + 2*(Re B)*A*(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)) + A*A*A"
             using \<open>(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2))\<^sup>2 =
                         (Re B)*(Re B) + (Re B)\<^sup>2 - (Re A)\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)\<close>
             by simp
           also have "... = A*((Re B)*(Re B) + (Re B)\<^sup>2 - A\<^sup>2 - 2*(Re B)*sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)) 
                      + 2*(Re B)*A*(-(Re B) + sgn(Re B)*sqrt((Re B)\<^sup>2 - (Re A)\<^sup>2)) + A*A*A"
             using \<open>is_real A\<close>
             by simp
           also have "... = 0"
             apply (simp add:field_simps)
             by (simp add: power2_eq_square)
           finally have "A*?nom*(cnj (?nom)) + B*?den*(cnj (?nom)) + (cnj B)*(cnj (?den))*?nom + A*?den*(cnj (?den)) = 0"
             by simp       
           thus "circline_equation A B (cnj B) A ?nom ?den"
             by simp
         qed
         thus ?thesis
           using * \<open>is_poincare_line_cmat H\<close> \<open>intersects_x_axis_cmat H\<close>
           by (simp add: vec_cnj_def)
       qed
     next
       show  "on_circline_cmat_cvec x_axis_cmat (calc_x_axis_intersection_cmat_cvec H)"
         using * \<open>is_poincare_line_cmat H\<close> \<open>intersects_x_axis_cmat H\<close> \<open>is_real A\<close>
         using eq_cnj_iff_real[of A]
         by (simp add: vec_cnj_def)
     qed
   qed
 qed
 
 lemma unique_calc_x_axis_intersection:
   assumes "is_poincare_line H" and "H \<noteq> x_axis"
   assumes "x \<in> unit_disc" and "x \<in> circline_set H \<inter> circline_set x_axis"
   shows  "x = calc_x_axis_intersection H"
 proof-
   have *: "intersects_x_axis H"
     using assms
     using intersects_x_axis_iff[OF assms(1)]
     by auto
   show "x = calc_x_axis_intersection H"
     using calc_x_axis_intersection[OF assms(1) *]
     using calc_x_axis_intersection_in_unit_disc[OF assms(1) *]
     using assms
     using unique_is_poincare_line[of x "calc_x_axis_intersection H" H x_axis]
     by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Check if an h-line intersects the positive part of the x-axis\<close>
 (* ------------------------------------------------------------------ *)
 
 definition intersects_x_axis_positive_cmat :: "complex_mat \<Rightarrow> bool" where
   [simp]: "intersects_x_axis_positive_cmat H = (let (A, B, C, D) = H in Re A \<noteq> 0 \<and> Re B / Re A < -1)"
 
 lift_definition intersects_x_axis_positive_clmat :: "circline_mat \<Rightarrow> bool" is intersects_x_axis_positive_cmat
   done
 
 lift_definition intersects_x_axis_positive :: "circline \<Rightarrow> bool" is intersects_x_axis_positive_clmat
 proof (transfer)
   fix H1 H2
   assume hh: "hermitean H1 \<and> H1 \<noteq> mat_zero" and "hermitean H2 \<and> H2 \<noteq> mat_zero"
   obtain A1 B1 C1 D1 A2 B2 C2 D2 where *: "H1 = (A1, B1, C1, D1)" "H2 = (A2, B2, C2, D2)"
     by (cases H1, cases H2, auto)
   assume "circline_eq_cmat H1 H2"
   then obtain k where "k \<noteq> 0 \<and> H2 = cor k *\<^sub>s\<^sub>m H1"
     by auto
   thus "intersects_x_axis_positive_cmat H1 = intersects_x_axis_positive_cmat H2"
     using *
     by simp
 qed
 
 lemma intersects_x_axis_positive_mk_circline:
   assumes "is_real A" and "A \<noteq> 0 \<or> B \<noteq> 0"
   shows "intersects_x_axis_positive (mk_circline A B (cnj B) A) \<longleftrightarrow> Re B / Re A < -1"
 proof-
   let ?H = "(A, B, (cnj B),  A)"
   have "hermitean ?H" 
     using \<open>is_real A\<close> 
     unfolding hermitean_def mat_adj_def mat_cnj_def
     using eq_cnj_iff_real 
     by auto
   moreover
   have "?H \<noteq> mat_zero"
     using assms
     by auto
   ultimately
   show ?thesis
     by (transfer, transfer, auto simp add: Let_def)
 qed
 
 
 lemma intersects_x_axis_positive_intersects_x_axis [simp]:
   assumes "intersects_x_axis_positive H"
   shows "intersects_x_axis H"
 proof-
   have "\<And> a aa. \<lbrakk> Re a \<noteq> 0; Re aa / Re a < - 1; \<not> (Re a)\<^sup>2 < (Re aa)\<^sup>2 \<rbrakk> \<Longrightarrow> aa = 0 \<and> a = 0"
     by (smt less_divide_eq_1_pos one_less_power pos2 power2_minus power_divide zero_less_power2)
   thus ?thesis
     using assms
     apply transfer
     apply transfer
     apply (auto simp add: hermitean_def mat_adj_def mat_cnj_def)
     done
 qed
 
 lemma add_less_abs_positive_iff:
   fixes a b :: real
   assumes "abs b < abs a"
   shows "a + b > 0 \<longleftrightarrow> a > 0"
   using assms
   by auto
 
 lemma calc_x_axis_intersection_positive_abs':
   fixes A B :: real
   assumes "B\<^sup>2 > A\<^sup>2" and "A \<noteq> 0"
   shows "abs (sgn(B) * sqrt(B\<^sup>2 - A\<^sup>2) / A) < abs(-B/A)"
 proof-
   from assms have "B \<noteq> 0"
     by auto
 
   have "B\<^sup>2 - A\<^sup>2 < B\<^sup>2"
     using \<open>A \<noteq> 0\<close>
     by auto
   hence "sqrt (B\<^sup>2 - A\<^sup>2) < abs B"
     using real_sqrt_less_iff[of "B\<^sup>2 - A\<^sup>2" "B\<^sup>2"]
     by simp
   thus ?thesis
     using assms \<open>B \<noteq> 0\<close>
     by (simp add: abs_mult divide_strict_right_mono)
 qed
 
 lemma calc_intersect_x_axis_positive_lemma:
   assumes "B\<^sup>2 > A\<^sup>2" and "A \<noteq> 0"
   shows "(-B + sgn B * sqrt(B\<^sup>2 - A\<^sup>2)) / A > 0 \<longleftrightarrow> -B/A > 1"
 proof-
   have "(-B + sgn B * sqrt(B\<^sup>2 - A\<^sup>2)) / A = -B / A + (sgn B * sqrt(B\<^sup>2 - A\<^sup>2)) / A"
     using assms
     by (simp add: field_simps)
   moreover
   have "-B / A + (sgn B * sqrt(B\<^sup>2 - A\<^sup>2)) / A > 0 \<longleftrightarrow> - B / A > 0"
     using add_less_abs_positive_iff[OF calc_x_axis_intersection_positive_abs'[OF assms]]
     by simp
   moreover
   hence "(B/A)\<^sup>2 > 1"
     using assms
     by (simp add: power_divide)
   hence "B/A > 1 \<or> B/A < -1"
     by (smt one_power2 pos2 power2_minus power_0 power_strict_decreasing zero_power2)
   hence "-B / A > 0 \<longleftrightarrow> -B / A > 1"
     by auto
   ultimately
   show ?thesis
     using assms
     by auto
 qed
 
 lemma intersects_x_axis_positive_iff':
   assumes "is_poincare_line H"
   shows "intersects_x_axis_positive H \<longleftrightarrow> 
          calc_x_axis_intersection H \<in> unit_disc \<and> calc_x_axis_intersection H \<in> circline_set H \<inter> positive_x_axis" (is "?lhs \<longleftrightarrow> ?rhs")
 proof
   let ?x = "calc_x_axis_intersection H"
   assume ?lhs
   hence "?x \<in> circline_set x_axis" "?x \<in> circline_set H" "?x \<in> unit_disc"
     using calc_x_axis_intersection_in_unit_disc[OF assms] calc_x_axis_intersection[OF assms]
     by auto
   moreover
   have "Re (to_complex ?x) > 0"
     using \<open>?lhs\<close> assms
   proof (transfer, transfer)
     fix H
     assume hh: "hermitean H \<and> H \<noteq> mat_zero"
     obtain A B C D where *: "H = (A, B, C, D)"
       by (cases H, auto)
     assume "intersects_x_axis_positive_cmat H"
     hence **: "Re B / Re A < - 1" "Re A \<noteq> 0"
       using *
       by auto
     have "(Re B)\<^sup>2 > (Re A)\<^sup>2"
       using **
       by (smt divide_less_eq_1_neg divide_minus_left less_divide_eq_1_pos real_sqrt_abs real_sqrt_less_iff right_inverse_eq)
     have "is_real A" "A \<noteq> 0"
       using hh hermitean_elems * \<open>Re A \<noteq> 0\<close> complex.expand[of A 0]
       by auto
     have "(cmod B)\<^sup>2 > (cmod A)\<^sup>2"
       using \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close> \<open>is_real A\<close>
       by (smt cmod_power2 power2_less_0 zero_power2)
     have ***: "0 < (- Re B + sgn (Re B) * sqrt ((Re B)\<^sup>2 - (Re A)\<^sup>2)) / Re A"
       using calc_intersect_x_axis_positive_lemma[of "Re A" "Re B"] ** \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close>
       by auto
 
     assume "is_poincare_line_cmat H"
     hence "A = D"
       using * hh
       by simp
 
     have "Re ((cor (sgn (Re B)) * cor (sqrt ((Re B)\<^sup>2 - (Re A)\<^sup>2)) - cor (Re B)) / A) = (sgn (Re B) * sqrt ((Re B)\<^sup>2 - (Re A)\<^sup>2) - Re B) / Re D"
       using \<open>is_real A\<close> \<open>A = D\<close>
       by (metis (no_types, lifting) Re_complex_of_real complex_of_real_Re of_real_diff of_real_divide of_real_mult)
     thus "0 < Re (to_complex_cvec (calc_x_axis_intersection_cmat_cvec H))"
       using * hh ** *** \<open>(cmod B)\<^sup>2 > (cmod A)\<^sup>2\<close> \<open>(Re B)\<^sup>2 > (Re A)\<^sup>2\<close> \<open>A \<noteq> 0\<close> \<open>A = D\<close>
       by simp
   qed
   ultimately
   show ?rhs
     unfolding positive_x_axis_def
     by auto
 next
   let ?x = "calc_x_axis_intersection H"
   assume ?rhs
   hence "Re (to_complex ?x) > 0"  "?x \<noteq> \<infinity>\<^sub>h" "?x \<in> circline_set x_axis" "?x \<in> unit_disc" "?x \<in> circline_set H"
     unfolding positive_x_axis_def
     by auto
   hence "intersects_x_axis H"
     using intersects_x_axis_iff[OF assms]
     by auto
   thus ?lhs
     using \<open>Re (to_complex ?x) > 0\<close> assms
   proof (transfer, transfer)
     fix H
     assume hh: "hermitean H \<and> H \<noteq> mat_zero"
     obtain A B C D where *: "H = (A, B, C, D)"
       by (cases H, auto)
     assume "0 < Re (to_complex_cvec (calc_x_axis_intersection_cmat_cvec H))" "intersects_x_axis_cmat H" "is_poincare_line_cmat H"
     hence **: "A \<noteq> 0" "0 < Re ((cor (sgn (Re B)) * cor (sqrt ((Re B)\<^sup>2 - (Re A)\<^sup>2)) - cor (Re B)) / A)"  "A = D" "is_real A" "(Re B)\<^sup>2 > (Re A)\<^sup>2"
       using * hh hermitean_elems
       by (auto split: if_split_asm)
 
     have "Re A \<noteq> 0"
       using complex.expand[of A 0] \<open>A \<noteq> 0\<close> \<open>is_real A\<close>
       by auto
 
     have "Re ((cor (sgn (Re B)) * cor (sqrt ((Re B)\<^sup>2 - (Re D)\<^sup>2)) - cor (Re B)) / D) = (sgn (Re B) * sqrt ((Re B)\<^sup>2 - (Re D)\<^sup>2) - Re B) / Re D"
       using \<open>is_real A\<close> \<open>A = D\<close>
       by (metis (no_types, lifting) Re_complex_of_real complex_of_real_Re of_real_diff of_real_divide of_real_mult)
 
     thus "intersects_x_axis_positive_cmat H"
       using * ** \<open>Re A \<noteq> 0\<close>
       using calc_intersect_x_axis_positive_lemma[of "Re A" "Re B"]
       by simp
   qed
 qed
 
 lemma intersects_x_axis_positive_iff:
   assumes "is_poincare_line H" and "H \<noteq> x_axis"
   shows "intersects_x_axis_positive H \<longleftrightarrow> 
          (\<exists> x. x \<in> unit_disc \<and> x \<in> circline_set H \<inter> positive_x_axis)" (is "?lhs \<longleftrightarrow> ?rhs")
 proof
   assume ?lhs
   thus ?rhs
     using intersects_x_axis_positive_iff'[OF assms(1)]
     by auto
 next
   assume ?rhs
   then obtain x where "x \<in> unit_disc" "x \<in> circline_set H \<inter> positive_x_axis"
     by auto
   thus ?lhs
     using unique_calc_x_axis_intersection[OF assms, of x]
     using intersects_x_axis_positive_iff'[OF assms(1)]
     unfolding positive_x_axis_def
     by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Check if an h-line intersects the positive part of the y-axis\<close>
 (* ------------------------------------------------------------------ *)
 
 definition intersects_y_axis_positive_cmat :: "complex_mat \<Rightarrow> bool" where
   [simp]: "intersects_y_axis_positive_cmat H = (let (A, B, C, D) = H in Re A \<noteq> 0 \<and> Im B / Re A < -1)"
 
 lift_definition intersects_y_axis_positive_clmat :: "circline_mat \<Rightarrow> bool" is intersects_y_axis_positive_cmat
   done
 
 lift_definition intersects_y_axis_positive :: "circline \<Rightarrow> bool" is intersects_y_axis_positive_clmat
 proof (transfer)
   fix H1 H2
   assume hh: "hermitean H1 \<and> H1 \<noteq> mat_zero" and "hermitean H2 \<and> H2 \<noteq> mat_zero"
   obtain A1 B1 C1 D1 A2 B2 C2 D2 where *: "H1 = (A1, B1, C1, D1)" "H2 = (A2, B2, C2, D2)"
     by (cases H1, cases H2, auto)
   assume "circline_eq_cmat H1 H2"
   then obtain k where "k \<noteq> 0 \<and> H2 = cor k *\<^sub>s\<^sub>m H1"
     by auto
   thus "intersects_y_axis_positive_cmat H1 = intersects_y_axis_positive_cmat H2"
     using *
     by simp
 qed
 
 lemma intersects_x_axis_positive_intersects_y_axis_positive [simp]:
   shows "intersects_x_axis_positive (moebius_circline (moebius_rotation (-pi/2)) H) \<longleftrightarrow> intersects_y_axis_positive H"
   using hermitean_elems
   unfolding moebius_rotation_def moebius_similarity_def
   by simp (transfer, transfer, auto simp add: mat_adj_def mat_cnj_def)
 
 lemma intersects_y_axis_positive_iff:
   assumes "is_poincare_line H" "H \<noteq> y_axis"
   shows "(\<exists> y \<in> unit_disc. y \<in> circline_set H \<inter> positive_y_axis) \<longleftrightarrow> intersects_y_axis_positive H" (is "?lhs \<longleftrightarrow> ?rhs")
 proof-
   let ?R = "moebius_rotation (-pi / 2)"
   let ?H' = "moebius_circline ?R H"
   have 1: "is_poincare_line ?H'"
     using assms
     using unit_circle_fix_preserve_is_poincare_line[OF _ assms(1), of ?R]
     by simp
 
   have 2: "moebius_circline ?R H \<noteq> x_axis"
   proof (rule ccontr)
     assume "\<not> ?thesis"
     hence "H = moebius_circline (moebius_rotation (pi/2)) x_axis"
       using moebius_circline_comp_inv_left[of ?R H]
       by auto
     thus False
       using \<open>H \<noteq> y_axis\<close>
       by auto
   qed
 
   show ?thesis
   proof
     assume "?lhs"
     then obtain y where "y \<in> unit_disc" "y \<in> circline_set H \<inter> positive_y_axis"
       by auto
     hence "moebius_pt ?R y \<in> unit_disc" "moebius_pt ?R y \<in> circline_set ?H' \<inter> positive_x_axis"
       using rotation_minus_pi_2_positive_y_axis
       by auto
     thus ?rhs
       using intersects_x_axis_positive_iff[OF 1 2]
       using intersects_x_axis_positive_intersects_y_axis_positive[of H]
       by auto
   next
     assume "intersects_y_axis_positive H"
     hence "intersects_x_axis_positive ?H'"
       using intersects_x_axis_positive_intersects_y_axis_positive[of H]
       by simp
     then obtain x where *: "x \<in> unit_disc" "x \<in> circline_set ?H' \<inter> positive_x_axis"
       using intersects_x_axis_positive_iff[OF 1 2]
       by auto
     let ?y = "moebius_pt (-?R) x"
     have "?y \<in> unit_disc \<and> ?y \<in> circline_set H \<inter> positive_y_axis"
       using * rotation_minus_pi_2_positive_y_axis[symmetric]
       by (metis Int_iff circline_set_moebius_circline_E image_eqI moebius_pt_comp_inv_image_left moebius_rotation_uminus uminus_moebius_def unit_disc_fix_discI unit_disc_fix_rotation)
     thus ?lhs
       by auto
   qed
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Position of the intersection point in the unit disc\<close>
 (* ------------------------------------------------------------------ *)
 
 text\<open>Check if the intersection point of one h-line with the x-axis is located more outward the edge
 of the disc than the intersection point of another h-line.\<close>
 
 definition outward_cmat :: "complex_mat \<Rightarrow> complex_mat \<Rightarrow> bool" where
  [simp]: "outward_cmat H1 H2 = (let (A1, B1, C1, D1) = H1; (A2, B2, C2, D2) = H2
                                  in -Re B1/Re A1 \<le> -Re B2/Re A2)"
 lift_definition outward_clmat :: "circline_mat \<Rightarrow> circline_mat \<Rightarrow> bool" is outward_cmat
   done
 lift_definition outward :: "circline \<Rightarrow> circline \<Rightarrow> bool" is outward_clmat
   apply transfer
   apply simp
   apply (case_tac circline_mat1, case_tac circline_mat2, case_tac circline_mat3, case_tac circline_mat4)
   apply simp
   apply (erule_tac exE)+
   apply (erule_tac conjE)+
   apply simp
   done
 
 lemma outward_mk_circline:
   assumes "is_real A1" and "is_real A2" and "A1 \<noteq> 0 \<or> B1 \<noteq> 0" and "A2 \<noteq> 0 \<or> B2 \<noteq> 0" 
   shows "outward (mk_circline A1 B1 (cnj B1) A1) (mk_circline A2 B2 (cnj B2) A2) \<longleftrightarrow> - Re B1 / Re A1 \<le> - Re B2 / Re A2"
 proof-
   let ?H1 = "(A1, B1, (cnj B1),  A1)"
   let ?H2 = "(A2, B2, (cnj B2),  A2)"
   have "hermitean ?H1" "hermitean ?H2"
     using \<open>is_real A1\<close> \<open>is_real A2\<close>
     unfolding hermitean_def mat_adj_def mat_cnj_def
     using eq_cnj_iff_real 
     by auto
   moreover
   have "?H1 \<noteq> mat_zero" "?H2 \<noteq> mat_zero"
     using assms
     by auto
   ultimately
   show ?thesis
     by (transfer, transfer, auto simp add: Let_def)
 qed
 
 lemma calc_x_axis_intersection_fun_mono:
   fixes x1 x2 :: real
   assumes "x1 > 1" and "x2 > x1"
   shows "x1 - sqrt(x1\<^sup>2 - 1) > x2 - sqrt(x2\<^sup>2 - 1)"
   using assms
 proof-
   have *: "sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1) > 0"
     using assms
     by (smt one_less_power pos2 real_sqrt_gt_zero)
 
   have "sqrt(x1\<^sup>2 - 1) < x1"
     using real_sqrt_less_iff[of "x1\<^sup>2 - 1" "x1\<^sup>2"] \<open>x1 > 1\<close>
     by auto
   moreover
   have "sqrt(x2\<^sup>2 - 1) < x2"
     using real_sqrt_less_iff[of "x2\<^sup>2 - 1" "x2\<^sup>2"] \<open>x1 > 1\<close> \<open>x2 > x1\<close>
     by auto
   ultimately
   have "sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1) < x1 + x2"
     by simp
   hence "(x1 + x2) / (sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1)) > 1"
     using *
     using less_divide_eq_1_pos[of "sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1)" "x1 + x2"]
     by simp
   hence "(x2\<^sup>2 - x1\<^sup>2) / (sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1)) > x2 - x1"
     using \<open>x2 > x1\<close>
     using mult_less_cancel_left_pos[of "x2 - x1" 1 "(x2 + x1) / (sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1))"]
     by (simp add: power2_eq_square field_simps)
   moreover
   have "(x2\<^sup>2 - x1\<^sup>2) = (sqrt(x1\<^sup>2 - 1) + sqrt(x2\<^sup>2 - 1)) * ((sqrt(x2\<^sup>2 - 1) - sqrt(x1\<^sup>2 - 1)))"
     using \<open>x1 > 1\<close> \<open>x2 > x1\<close>
     by (simp add: field_simps)
   ultimately
   have "sqrt(x2\<^sup>2 - 1) - sqrt(x1\<^sup>2 - 1) > x2 - x1"
     using *
     by simp
   thus ?thesis
     by simp
 qed
 
 lemma calc_x_axis_intersection_mono:
   fixes a1 b1 a2 b2 :: real
   assumes "-b1/a1 > 1" and "a1 \<noteq> 0" and "-b2/a2 \<ge> -b1/a1" and "a2 \<noteq> 0"
   shows "(-b1 + sgn b1 * sqrt(b1\<^sup>2 - a1\<^sup>2)) / a1 \<ge> (-b2 + sgn b2 * sqrt(b2\<^sup>2 - a2\<^sup>2)) / a2" (is "?lhs \<ge> ?rhs")
 proof-
   have "?lhs = -b1/a1 - sqrt((-b1/a1)\<^sup>2 - 1)"
   proof (cases "b1 > 0")
     case True
     hence "a1 < 0"
       using assms
       by (smt divide_neg_pos)
     thus ?thesis
       using \<open>b1 > 0\<close> \<open>a1 < 0\<close>
       by (simp add: real_sqrt_divide field_simps)
   next
     case False
     hence "b1 < 0"
       using assms
       by (cases "b1 = 0") auto
     hence "a1 > 0"
       using assms
       by (smt divide_pos_neg)
     thus ?thesis
       using \<open>b1 < 0\<close> \<open>a1 > 0\<close>
       by (simp add: real_sqrt_divide field_simps)
   qed
 
   moreover
 
   have "?rhs = -b2/a2 - sqrt((-b2/a2)\<^sup>2 - 1)"
   proof (cases "b2 > 0")
     case True
     hence "a2 < 0"
       using assms
       by (smt divide_neg_pos)
     thus ?thesis
       using \<open>b2 > 0\<close> \<open>a2 < 0\<close>
       by (simp add: real_sqrt_divide field_simps)
   next
     case False
     hence "b2 < 0"
       using assms
       by (cases "b2 = 0") auto
     hence "a2 > 0"
       using assms
       by (smt divide_pos_neg)
     thus ?thesis
       using \<open>b2 < 0\<close> \<open>a2 > 0\<close>
       by (simp add: real_sqrt_divide field_simps)
   qed
 
   ultimately
 
   show ?thesis
     using calc_x_axis_intersection_fun_mono[of "-b1/a1" "-b2/a2"]
     using assms
     by (cases "-b1/a1=-b2/a2", auto)
 qed
 
 lemma outward:
   assumes "is_poincare_line H1" and "is_poincare_line H2"
   assumes "intersects_x_axis_positive H1" and "intersects_x_axis_positive H2"
   assumes "outward H1 H2"
   shows "Re (to_complex (calc_x_axis_intersection H1)) \<ge> Re (to_complex (calc_x_axis_intersection H2))"
 proof-
   have "intersects_x_axis H1" "intersects_x_axis H2"
     using assms
     by auto
   thus ?thesis
     using assms
   proof (transfer, transfer)
     fix H1 H2
     assume hh: "hermitean H1 \<and> H1 \<noteq> mat_zero"  "hermitean H2 \<and> H2 \<noteq> mat_zero"
     obtain A1 B1 C1 D1 A2 B2 C2 D2 where *: "H1 = (A1, B1, C1, D1)" "H2 = (A2, B2, C2, D2)"
       by (cases H1, cases H2, auto)
     have "is_real A1" "is_real A2"
       using hermitean_elems * hh
       by auto
     assume 1: "intersects_x_axis_positive_cmat H1" "intersects_x_axis_positive_cmat H2"
     assume 2: "intersects_x_axis_cmat H1" "intersects_x_axis_cmat H2"
     assume 3: "is_poincare_line_cmat H1" "is_poincare_line_cmat H2"
     assume 4: "outward_cmat H1 H2"
     have "A1 \<noteq> 0" "A2 \<noteq> 0"
       using * \<open>is_real A1\<close> \<open>is_real A2\<close> 1 complex.expand[of A1 0] complex.expand[of A2 0]
       by auto
     hence "(sgn (Re B2) * sqrt ((Re B2)\<^sup>2 - (Re A2)\<^sup>2) - Re B2) / Re A2
          \<le> (sgn (Re B1) * sqrt ((Re B1)\<^sup>2 - (Re A1)\<^sup>2) - Re B1) / Re A1"
       using calc_x_axis_intersection_mono[of "Re B1" "Re A1" "Re B2" "Re A2"]
       using 1 4 *
       by simp
     moreover
     have "(sgn (Re B2) * sqrt ((Re B2)\<^sup>2 - (Re A2)\<^sup>2) - Re B2) / Re A2 = 
           Re ((cor (sgn (Re B2)) * cor (sqrt ((Re B2)\<^sup>2 - (Re A2)\<^sup>2)) - cor (Re B2)) / A2)"
       using \<open>is_real A2\<close> \<open>A2 \<noteq> 0\<close>
       by (simp add: Re_divide_real)
     moreover
     have "(sgn (Re B1) * sqrt ((Re B1)\<^sup>2 - (Re A1)\<^sup>2) - Re B1) / Re A1 =
            Re ((cor (sgn (Re B1)) * cor (sqrt ((Re B1)\<^sup>2 - (Re A1)\<^sup>2)) - cor (Re B1)) / A1)"
       using \<open>is_real A1\<close> \<open>A1 \<noteq> 0\<close>
       by (simp add: Re_divide_real)
     ultimately
     show "Re (to_complex_cvec (calc_x_axis_intersection_cmat_cvec H2))
           \<le> Re (to_complex_cvec (calc_x_axis_intersection_cmat_cvec H1))"
       using 2 3 \<open>A1 \<noteq> 0\<close> \<open>A2 \<noteq> 0\<close> * \<open>is_real A1\<close> \<open>is_real A2\<close>
       by (simp del: is_poincare_line_cmat_def intersects_x_axis_cmat_def)
   qed    
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Ideal points and x-axis intersection\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma ideal_points_intersects_x_axis:               
   assumes "is_poincare_line H" and "ideal_points H = {i1, i2}" and "H \<noteq> x_axis"
   shows  "intersects_x_axis H \<longleftrightarrow> Im (to_complex i1) * Im (to_complex i2) < 0"
   using assms
 proof-
   have "i1 \<noteq> i2"
     using assms(1) assms(2) ex_poincare_line_points ideal_points_different(1)
     by blast
 
   have "calc_ideal_points H = {i1, i2}"
     using assms
     using ideal_points_unique
     by auto
 
   have "\<forall> i1 \<in> calc_ideal_points H. 
         \<forall> i2 \<in> calc_ideal_points H. 
              is_poincare_line H \<and> H \<noteq> x_axis \<and> i1 \<noteq> i2 \<longrightarrow> (Im (to_complex i1) * Im (to_complex i2) < 0 \<longleftrightarrow> intersects_x_axis H)"
   proof (transfer, transfer, (rule ballI)+, rule impI, (erule conjE)+, case_tac H, case_tac i1, case_tac i2)
     fix i11 i12 i21 i22 A B C D H i1 i2
     assume H: "H = (A, B, C, D)" "hermitean H" "H \<noteq> mat_zero"
     assume line: "is_poincare_line_cmat H"
     assume i1: "i1 = (i11, i12)" "i1 \<in> calc_ideal_points_cmat_cvec H"
     assume i2: "i2 = (i21, i22)" "i2 \<in> calc_ideal_points_cmat_cvec H"
     assume different: "\<not> i1 \<approx>\<^sub>v i2"
     assume not_x_axis:  "\<not> circline_eq_cmat H x_axis_cmat"
 
     have "is_real A" "is_real D" "C = cnj B"
       using H hermitean_elems
       by auto
     have "(cmod A)\<^sup>2 < (cmod B)\<^sup>2" "A = D"
       using line H
       by auto
 
     let ?discr =  "sqrt ((cmod B)\<^sup>2 - (Re D)\<^sup>2)"
     let ?den = "(cmod B)\<^sup>2"
     let ?i1 = "B * (- D - \<i> * ?discr)"
     let ?i2 = "B * (- D + \<i> * ?discr)"
 
     have "i11 = ?i1 \<or> i11 = ?i2" "i12 = ?den"
          "i21 = ?i1 \<or> i21 = ?i2" "i22 = ?den"  
       using i1 i2 H line
       by (auto split: if_split_asm)
     hence i: "i11 = ?i1 \<and> i21 = ?i2 \<or> i11 = ?i2 \<and> i21 = ?i1"
       using \<open>\<not> i1 \<approx>\<^sub>v i2\<close> i1 i2
       by auto
 
     have "Im (i11 / i12) * Im (i21 / i22) = Im (?i1 / ?den) * Im (?i2 / ?den)"
       using i \<open>i12 = ?den\<close> \<open>i22 = ?den\<close>
       by auto
     also have "... = Im (?i1) * Im (?i2) / ?den\<^sup>2"
       by simp
     also have "... = (Im B * (Im B * (Re D * Re D)) - Re B * (Re B * ((cmod B)\<^sup>2 - (Re D)\<^sup>2))) / cmod B ^ 4"
       using \<open>(cmod B)\<^sup>2 > (cmod A)\<^sup>2\<close> \<open>A = D\<close>
       using \<open>is_real D\<close> cmod_eq_Re[of A]
       by (auto simp add: field_simps)
     also have "... = ((Im B)\<^sup>2 * (Re D)\<^sup>2 - (Re B)\<^sup>2 * ((Re B)\<^sup>2 + (Im B)\<^sup>2 - (Re D)\<^sup>2)) / cmod B ^ 4"
     proof-
       have "cmod B * cmod B = Re B * Re B + Im B * Im B"
         by (metis cmod_power2 power2_eq_square)
       thus ?thesis
         by (simp add: power2_eq_square)
     qed
     also have "... = (((Re D)\<^sup>2 - (Re B)\<^sup>2) * ((Re B)\<^sup>2 + (Im B)\<^sup>2)) / cmod B ^ 4"
       by (simp add: power2_eq_square field_simps)
     finally have Im_product: "Im (i11 / i12) * Im (i21 / i22) = ((Re D)\<^sup>2 - (Re B)\<^sup>2) * ((Re B)\<^sup>2 + (Im B)\<^sup>2) / cmod B ^ 4"
       .
 
     show "Im (to_complex_cvec i1) * Im (to_complex_cvec i2) < 0 \<longleftrightarrow> intersects_x_axis_cmat H"
     proof safe
       assume opposite: "Im (to_complex_cvec i1) * Im (to_complex_cvec i2) < 0"
       show "intersects_x_axis_cmat H"
       proof-
         have "((Re D)\<^sup>2 - (Re B)\<^sup>2) * ((Re B)\<^sup>2 + (Im B)\<^sup>2) / cmod B ^ 4 < 0"
           using Im_product opposite i1 i2
           by simp
         hence "((Re D)\<^sup>2 - (Re B)\<^sup>2) * ((Re B)\<^sup>2 + (Im B)\<^sup>2) < 0"
           by (simp add: divide_less_0_iff)
         hence "(Re D)\<^sup>2 < (Re B)\<^sup>2"
           by (simp add: mult_less_0_iff not_sum_power2_lt_zero)
         thus ?thesis
           using H \<open>A = D\<close>  \<open>is_real D\<close>
           by auto
       qed
     next
       have *: "(\<forall>k. k * Im B = 1 \<longrightarrow> k = 0) \<longrightarrow> Im B = 0"
         apply (safe, erule_tac x="1 / Im B" in allE)
         using divide_cancel_left by fastforce
       assume "intersects_x_axis_cmat H"
       hence "Re D = 0 \<or> (Re D)\<^sup>2 < (Re B)\<^sup>2"
         using H \<open>A = D\<close>
         by auto
       hence "(Re D)\<^sup>2 < (Re B)\<^sup>2" 
         using \<open>is_real D\<close> line  H \<open>C = cnj B\<close>
         using not_x_axis *
         by (auto simp add: complex_eq_iff)
       hence "((Re D)\<^sup>2 - (Re B)\<^sup>2) * ((Re B)\<^sup>2 + (Im B)\<^sup>2) < 0"
         by (metis add_cancel_left_left diff_less_eq mult_eq_0_iff mult_less_0_iff power2_eq_square power2_less_0 sum_squares_gt_zero_iff)
       thus "Im (to_complex_cvec i1) * Im (to_complex_cvec i2) < 0" 
         using Im_product i1 i2
         using divide_eq_0_iff divide_less_0_iff prod.simps(2) to_complex_cvec_def zero_complex.simps(1) zero_less_norm_iff 
         by fastforce
     qed
   qed
   thus ?thesis
     using assms \<open>calc_ideal_points H = {i1, i2}\<close> \<open>i1 \<noteq> i2\<close>
     by auto
 qed
 
 end
diff --git a/thys/Poincare_Disc/Poincare_Tarski.thy b/thys/Poincare_Disc/Poincare_Tarski.thy
--- a/thys/Poincare_Disc/Poincare_Tarski.thy
+++ b/thys/Poincare_Disc/Poincare_Tarski.thy
@@ -1,3044 +1,3044 @@
 section \<open>Poincar\'e model satisfies Tarski axioms\<close>
 
 theory Poincare_Tarski
   imports Poincare Poincare_Lines_Axis_Intersections Tarski
 begin
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Pasch axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma Pasch_fun_mono:
   fixes r1 r2 :: real
   assumes "0 < r1" and "r1 \<le> r2" and "r2 < 1"
   shows "r1 + 1/r1 \<ge> r2 + 1/r2"
 proof (cases "r1 = r2")
   case True
   thus ?thesis
     by simp
 next
   case False
   hence "r2 - r1 > 0"
     using assms
     by simp
 
   have "r1 * r2 < 1"
     using assms
     by (smt mult_le_cancel_left1)
   hence "1 / (r1 * r2) > 1"
     using assms
     by simp
   hence "(r2 - r1) / (r1 * r2) > (r2 - r1)"
     using \<open>r2 - r1 > 0\<close>
     using mult_less_cancel_left_pos[of "r2 - r1" 1 "1 / (r1 * r2)"]
     by simp
   hence "1 / r1 - 1 / r2 > r2 - r1"
     using assms
     by (simp add: field_simps)
   thus ?thesis
     by simp
 qed
 
 text\<open>Pasch axiom, non-degenerative case.\<close>
 lemma Pasch_nondeg:
   assumes "x \<in> unit_disc" and "y \<in> unit_disc" and "z \<in> unit_disc" and "u \<in> unit_disc" and "v \<in> unit_disc"
   assumes "distinct [x, y, z, u, v]" 
   assumes "\<not> poincare_collinear {x, y, z}" 
   assumes "poincare_between x u z" and "poincare_between y v z"
   shows "\<exists> a. a \<in> unit_disc \<and> poincare_between u a y \<and> poincare_between x a v"
 proof-
   have "\<forall> y z u. distinct [x, y, z, u, v] \<and> \<not> poincare_collinear {x, y, z} \<and> y \<in> unit_disc \<and> z \<in> unit_disc \<and> u \<in> unit_disc \<and>
                  poincare_between x u z \<and> poincare_between y v z \<longrightarrow> (\<exists> a. a \<in> unit_disc \<and> poincare_between u a y \<and> poincare_between x a v)" (is "?P x v")
   proof (rule wlog_positive_x_axis[where P="?P"])
     fix v
     assume v: "is_real v" "0 < Re v" "Re v < 1"
     hence "of_complex v \<in> unit_disc"
       by (auto simp add: cmod_eq_Re)
     show "?P 0\<^sub>h (of_complex v)"
     proof safe
       fix y z u
       assume distinct: "distinct [0\<^sub>h, y, z, u, of_complex v]"
       assume in_disc: "y \<in> unit_disc" "z \<in> unit_disc" "u \<in> unit_disc"
       then obtain y' z' u'
         where *: "y = of_complex y'" "z = of_complex z'" "u = of_complex u'"
         using inf_or_of_complex inf_notin_unit_disc
         by metis
 
       have "y' \<noteq> 0" "z' \<noteq> 0" "u' \<noteq> 0" "v \<noteq> 0" "y' \<noteq> z'" "y' \<noteq> u'" "z' \<noteq> u'" "y \<noteq> z" "y \<noteq> u" "z \<noteq> u"
         using of_complex_inj distinct *
         by auto
 
       note distinct = distinct this
 
       assume "\<not> poincare_collinear {0\<^sub>h, y, z}"
 
       hence nondeg_yz: "y'*cnj z' \<noteq> cnj y' * z'"
         using * poincare_collinear_zero_iff[of y' z'] in_disc distinct
         by auto
 
       assume "poincare_between 0\<^sub>h u z"
 
-      hence "arg u' = arg z'" "cmod u' \<le> cmod z'"
+      hence "Arg u' = Arg z'" "cmod u' \<le> cmod z'"
         using * poincare_between_0uv[of u z] distinct in_disc
         by auto
 
       then obtain \<phi> ru rz where
         uz_polar: "u' = cor ru * cis \<phi>" "z' = cor rz * cis \<phi>" "0 < ru" "ru \<le> rz" "0 < rz" and
-                  "\<phi> = arg u'" "\<phi> = arg z'"
+                  "\<phi> = Arg u'" "\<phi> = Arg z'"
         using * \<open>u' \<noteq> 0\<close> \<open>z' \<noteq> 0\<close>
         by (smt cmod_cis norm_le_zero_iff)
 
       obtain \<theta> ry where
-        y_polar: "y' = cor ry * cis \<theta>" "ry > 0" and "\<theta> = arg y'"
+        y_polar: "y' = cor ry * cis \<theta>" "ry > 0" and "\<theta> = Arg y'"
         using \<open>y' \<noteq> 0\<close>
         by (smt cmod_cis norm_le_zero_iff)
 
       from in_disc * \<open>u' = cor ru * cis \<phi>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>y' = cor ry * cis \<theta>\<close>
       have "ru < 1" "rz < 1" "ry < 1"
         by (auto simp: norm_mult)
 
       note polar = this y_polar uz_polar
 
       have nondeg: "cis \<theta> * cis (- \<phi>) \<noteq> cis (- \<theta>) * cis \<phi>"
         using nondeg_yz polar
         by simp
 
       let ?yz = "poincare_line y z"
       let ?v = "calc_x_axis_intersection ?yz"
 
       assume "poincare_between y (of_complex v) z"
 
       hence "of_complex v \<in> circline_set ?yz"
         using in_disc \<open>of_complex v \<in> unit_disc\<close>
         using distinct poincare_between_poincare_collinear[of y "of_complex v" z]
         using unique_poincare_line[of y z]
         by (auto simp add: poincare_collinear_def)
       moreover
       have "of_complex v \<in> circline_set x_axis"
         using \<open>is_real v\<close>
         unfolding circline_set_x_axis
         by auto
       moreover
       have "?yz \<noteq> x_axis"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         hence "{0\<^sub>h, y, z} \<subseteq> circline_set (poincare_line y z)"
           unfolding circline_set_def
           using distinct poincare_line[of y z]
           by auto
         hence "poincare_collinear {0\<^sub>h, y, z}"
           unfolding poincare_collinear_def
           using distinct
           by force
         thus False
           using \<open>\<not> poincare_collinear {0\<^sub>h, y, z}\<close>
           by simp
       qed
       ultimately
       have "?v = of_complex v" "intersects_x_axis ?yz"
         using unique_calc_x_axis_intersection[of "poincare_line y z" "of_complex v"]
         using intersects_x_axis_iff[of ?yz]
         using distinct \<open>of_complex v \<in> unit_disc\<close>
         by (metis IntI is_poincare_line_poincare_line)+
 
       have "intersects_x_axis_positive ?yz"
         using \<open>Re v > 0\<close> \<open>of_complex v \<in> unit_disc\<close>
         using \<open>of_complex v \<in> circline_set ?yz\<close> \<open>of_complex v \<in> circline_set x_axis\<close>
         using intersects_x_axis_positive_iff[of ?yz] \<open>y \<noteq> z\<close> \<open>?yz \<noteq> x_axis\<close>
         unfolding positive_x_axis_def
         by force
 
       have "y \<notin> circline_set x_axis"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         moreover
         hence "poincare_line y (of_complex v) = x_axis"
           using distinct \<open>of_complex v \<in> circline_set x_axis\<close>
           using in_disc \<open>of_complex v \<in> unit_disc\<close>
           using unique_poincare_line[of y "of_complex v" x_axis]
           by simp
         moreover
         have "z \<in> circline_set (poincare_line y (of_complex v))"
           using \<open>of_complex v \<in> circline_set ?yz\<close>
           using unique_poincare_line[of y "of_complex v" "poincare_line y z"]
           using in_disc \<open>of_complex v \<in> unit_disc\<close> distinct
           using poincare_line[of y z]
           unfolding circline_set_def
           by (metis distinct_length_2_or_more is_poincare_line_poincare_line mem_Collect_eq)
         ultimately
         have "y \<in> circline_set x_axis" "z \<in> circline_set x_axis"
           by auto
         hence "poincare_collinear {0\<^sub>h, y, z}"
           unfolding poincare_collinear_def
           by force
         thus False
           using \<open>\<not> poincare_collinear {0\<^sub>h, y, z}\<close>
           by simp
       qed
 
       moreover
 
       have "z \<notin> circline_set x_axis"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         moreover
         hence "poincare_line z (of_complex v) = x_axis"
           using distinct \<open>of_complex v \<in> circline_set x_axis\<close>
           using in_disc \<open>of_complex v \<in> unit_disc\<close>
           using unique_poincare_line[of z "of_complex v" x_axis]
           by simp
         moreover
         have "y \<in> circline_set (poincare_line z (of_complex v))"
           using \<open>of_complex v \<in> circline_set ?yz\<close>
           using unique_poincare_line[of z "of_complex v" "poincare_line y z"]
           using in_disc \<open>of_complex v \<in> unit_disc\<close> distinct
           using poincare_line[of y z]
           unfolding circline_set_def
           by (metis distinct_length_2_or_more is_poincare_line_poincare_line mem_Collect_eq)
         ultimately
         have "y \<in> circline_set x_axis" "z \<in> circline_set x_axis"
           by auto
         hence "poincare_collinear {0\<^sub>h, y, z}"
           unfolding poincare_collinear_def
           by force
         thus False
           using \<open>\<not> poincare_collinear {0\<^sub>h, y, z}\<close>
           by simp
       qed
 
       ultimately
 
       have "\<phi> * \<theta> < 0"
         using \<open>poincare_between y (of_complex v) z\<close>
         using poincare_between_x_axis_intersection[of y z "of_complex v"]
         using in_disc \<open>of_complex v \<in> unit_disc\<close> distinct
         using \<open>of_complex v \<in> circline_set ?yz\<close> \<open>of_complex v \<in> circline_set x_axis\<close>
-        using \<open>\<phi> = arg z'\<close> \<open>\<theta> = arg y'\<close> *
+        using \<open>\<phi> = Arg z'\<close> \<open>\<theta> = Arg y'\<close> *
         by (simp add: field_simps)
 
       have "\<phi> \<noteq> pi" "\<phi> \<noteq> 0"
         using \<open>z \<notin> circline_set x_axis\<close> * polar cis_pi
         unfolding circline_set_x_axis
         by auto
 
       have "\<theta> \<noteq> pi" "\<theta> \<noteq> 0"
         using \<open>y \<notin> circline_set x_axis\<close> * polar cis_pi
         unfolding circline_set_x_axis
         by auto
 
       have phi_sin: "\<phi> > 0 \<longleftrightarrow> sin \<phi> > 0" "\<phi> < 0 \<longleftrightarrow> sin \<phi> < 0"
-        using \<open>\<phi> = arg z'\<close> \<open>\<phi> \<noteq> 0\<close> \<open>\<phi> \<noteq> pi\<close>
+        using \<open>\<phi> = Arg z'\<close> \<open>\<phi> \<noteq> 0\<close> \<open>\<phi> \<noteq> pi\<close>
         using Arg_bounded[of z']
         by (smt sin_gt_zero sin_le_zero sin_pi_minus sin_0_iff_canon sin_ge_zero)+
 
       have theta_sin: "\<theta> > 0 \<longleftrightarrow> sin \<theta> > 0" "\<theta> < 0 \<longleftrightarrow> sin \<theta> < 0"
-        using \<open>\<theta> = arg y'\<close> \<open>\<theta> \<noteq> 0\<close> \<open>\<theta> \<noteq> pi\<close>
+        using \<open>\<theta> = Arg y'\<close> \<open>\<theta> \<noteq> 0\<close> \<open>\<theta> \<noteq> pi\<close>
         using Arg_bounded[of y']
         by (smt sin_gt_zero sin_le_zero sin_pi_minus sin_0_iff_canon sin_ge_zero)+
 
       have "sin \<phi> * sin \<theta> < 0"
         using \<open>\<phi> * \<theta> < 0\<close> phi_sin theta_sin
         by (simp add: mult_less_0_iff)
 
       have "sin (\<phi> - \<theta>) \<noteq> 0"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         hence "sin (\<phi> - \<theta>) = 0"
           by simp
         have "- 2 * pi < \<phi> - \<theta>" "\<phi> - \<theta> < 2 * pi"
-          using \<open>\<phi> = arg z'\<close> \<open>\<theta> = arg y'\<close> Arg_bounded[of z'] Arg_bounded[of y'] \<open>\<phi> \<noteq> pi\<close> \<open>\<theta> \<noteq> pi\<close>
+          using \<open>\<phi> = Arg z'\<close> \<open>\<theta> = Arg y'\<close> Arg_bounded[of z'] Arg_bounded[of y'] \<open>\<phi> \<noteq> pi\<close> \<open>\<theta> \<noteq> pi\<close>
           by auto
         hence "\<phi> - \<theta> = -pi \<or> \<phi> - \<theta> = 0 \<or> \<phi> - \<theta> = pi"
           using \<open>sin (\<phi> - \<theta>) = 0\<close>
           by (smt sin_0_iff_canon sin_periodic_pi2)
         moreover
         {
           assume "\<phi> - \<theta> = - pi"
           hence "\<phi> = \<theta> - pi"
             by simp
           hence False
             using nondeg_yz
             using \<open>y' = cor ry * cis \<theta>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>rz > 0\<close> \<open>ry > 0\<close>
             by auto
         }
         moreover
         {
           assume "\<phi> - \<theta> = 0"
           hence "\<phi> = \<theta>"
             by simp
           hence False
             using \<open>y' = cor ry * cis \<theta>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>rz > 0\<close> \<open>ry > 0\<close>
             using nondeg_yz
             by auto
         }
         moreover
         {
           assume "\<phi> - \<theta> = pi"
           hence "\<phi> = \<theta> + pi"
             by simp
           hence False
             using \<open>y' = cor ry * cis \<theta>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>rz > 0\<close> \<open>ry > 0\<close>
             using nondeg_yz
             by auto
         }
         ultimately
         show False
           by auto
       qed
 
       have "u \<notin> circline_set x_axis"
       proof-
         have "\<not> is_real u'"
           using * polar in_disc
-          using \<open>\<phi> \<noteq> 0\<close> \<open>\<phi> = arg u'\<close> \<open>\<phi> \<noteq> pi\<close>  phi_sin(1) phi_sin(2)
+          using \<open>\<phi> \<noteq> 0\<close> \<open>\<phi> = Arg u'\<close> \<open>\<phi> \<noteq> pi\<close>  phi_sin(1) phi_sin(2)
           by (metis is_real_arg2)
         moreover
         have "u \<noteq> \<infinity>\<^sub>h"
           using in_disc
           by auto
         ultimately
         show ?thesis
           using * of_complex_inj[of u']
           unfolding circline_set_x_axis
           by auto
       qed
 
       let ?yu = "poincare_line y u"
       have nondeg_yu: "y' * cnj u' \<noteq> cnj u' * u'"
         using nondeg_yz polar \<open>ru > 0\<close> \<open>rz > 0\<close> distinct
         by auto
 
       {
         (* derive results simultaneously for both u and z *)
         fix r :: real
         assume "r > 0"
 
         have den: "cor ry * cis \<theta> * cnj 1 * cnj (cor r * cis \<phi>) * 1 - cor r * cis \<phi> * cnj 1 * cnj (cor ry * cis \<theta>) * 1 \<noteq> 0"
           using \<open>0 < r\<close> \<open>0 < ry\<close> nondeg
           by auto
 
         let ?A = "2 * r * ry * sin(\<phi> - \<theta>)"
         let ?B = "\<i> * (r * cis \<phi> * (1 + ry\<^sup>2) - ry * cis \<theta> * (1 + r\<^sup>2))"
         let ?ReB = "ry * (1 + r\<^sup>2) * sin \<theta> - r * (1 + ry\<^sup>2) * sin \<phi>"
 
         have "Re (\<i> * (r * cis (-\<phi>) * ry * cis (\<theta>) - ry * cis (-\<theta>) * r * cis (\<phi>))) = ?A"
           by (simp add: sin_diff field_simps)
         moreover
         have "cor ry * cis (- \<theta>) * (cor ry * cis \<theta>) = ry\<^sup>2"  "cor r * cis (- \<phi>) * (cor r * cis \<phi>) = r\<^sup>2"
           by (metis cis_inverse cis_neq_zero divide_complex_def cor_squared nonzero_mult_div_cancel_right power2_eq_square semiring_normalization_rules(15))+
         ultimately
         have 1: "poincare_line_cvec_cmat (of_complex_cvec (cor ry * cis \<theta>)) (of_complex_cvec (cor r * cis \<phi>)) = (?A, ?B, cnj ?B, ?A)"
           using den
           unfolding poincare_line_cvec_cmat_def of_complex_cvec_def Let_def prod.case
           by (simp add: field_simps)
 
         have 2: "is_real ?A"
           by simp
         let ?mix = "cis \<theta> * cis (- \<phi>) - cis (- \<theta>) * cis \<phi>"
         have "is_imag ?mix"
           using eq_minus_cnj_iff_imag[of ?mix]
           by simp
         hence "Im ?mix \<noteq> 0"
           using nondeg
           using complex.expand[of ?mix 0]
           by auto
         hence 3: "Re ?A \<noteq> 0"
           using \<open>r > 0\<close> \<open>ry > 0\<close>
           by (simp add: sin_diff field_simps)
 
         have "?A \<noteq> 0"
           using 2 3
           by auto
         hence 4: "cor ?A \<noteq> 0"
           using 2 3
           by (metis zero_complex.simps(1))
 
         have 5: "?ReB / ?A = (sin \<theta>) / (2 * sin(\<phi> - \<theta>)) * (1/r + r) - (sin \<phi>) / (2 * sin (\<phi> - \<theta>)) * (1/ry + ry)" 
           using \<open>ry > 0\<close> \<open>r > 0\<close>
           apply (subst diff_divide_distrib)             
           apply (subst add_frac_num, simp)
           apply (subst add_frac_num, simp)
           apply (simp add: power2_eq_square mult.commute)
           apply (simp add: field_simps)
           done
 
         have "poincare_line_cvec_cmat (of_complex_cvec (cor ry * cis \<theta>)) (of_complex_cvec (cor r * cis \<phi>)) = (?A, ?B, cnj ?B, ?A) \<and>
                 is_real ?A \<and> Re ?A \<noteq> 0 \<and> ?A \<noteq> 0 \<and> cor ?A \<noteq> 0 \<and>
                 Re ?B = ?ReB \<and>
                 ?ReB / ?A = (sin \<theta>) / (2 * sin(\<phi> - \<theta>)) * (1/r + r) - (sin \<phi>) / (2 * sin (\<phi> - \<theta>)) * (1/ry + ry)"
           using 1 2 3 4 5
           by auto
       }
       note ** = this
 
       let ?Ayz = "2 * rz * ry * sin (\<phi> - \<theta>)"
       let ?Byz = "\<i> * (rz * cis \<phi> * (1 + ry\<^sup>2) - ry * cis \<theta> * (1 + rz\<^sup>2))"
       let ?ReByz = "ry * (1 + rz\<^sup>2) * sin \<theta> - rz * (1 + ry\<^sup>2) * sin \<phi>"
       let ?Kz = "(sin \<theta>) / (2 * sin(\<phi> - \<theta>)) * (1/rz + rz) - (sin \<phi>) / (2 * sin (\<phi> - \<theta>)) * (1/ry + ry)"
       have yz: "poincare_line_cvec_cmat (of_complex_cvec (cor ry * cis \<theta>)) (of_complex_cvec (cor rz * cis \<phi>)) = (?Ayz, ?Byz, cnj ?Byz, ?Ayz)"
         "is_real ?Ayz" "Re ?Ayz \<noteq> 0" "?Ayz \<noteq> 0" "cor ?Ayz \<noteq> 0" "Re ?Byz = ?ReByz" and Kz: "?ReByz / ?Ayz = ?Kz"
         using **[OF \<open>0 < rz\<close>]
         by auto
 
       let ?Ayu = "2 * ru * ry * sin (\<phi> - \<theta>)"
       let ?Byu = "\<i> * (ru * cis \<phi> * (1 + ry\<^sup>2) - ry * cis \<theta> * (1 + ru\<^sup>2))"
       let ?ReByu = "ry * (1 + ru\<^sup>2) * sin \<theta> - ru * (1 + ry\<^sup>2) * sin \<phi>"
       let ?Ku = "(sin \<theta>) / (2 * sin(\<phi> - \<theta>)) * (1/ru + ru) - (sin \<phi>) / (2 * sin (\<phi> - \<theta>)) * (1/ry + ry)"
       have yu: "poincare_line_cvec_cmat (of_complex_cvec (cor ry * cis \<theta>)) (of_complex_cvec (cor ru * cis \<phi>)) = (?Ayu, ?Byu, cnj ?Byu, ?Ayu)"
         "is_real ?Ayu" "Re ?Ayu \<noteq> 0" "?Ayu \<noteq> 0" "cor ?Ayu \<noteq> 0" "Re ?Byu = ?ReByu" and Ku: "?ReByu / ?Ayu = ?Ku"
         using **[OF \<open>0 < ru\<close>]
         by auto
 
       have "?Ayz \<noteq> 0"
         using \<open>sin (\<phi> - \<theta>) \<noteq> 0\<close> \<open>ry > 0\<close> \<open>rz > 0\<close>
         by auto
 
       have "Re ?Byz / ?Ayz < -1"
         using \<open>intersects_x_axis_positive ?yz\<close>
           * \<open>y' = cor ry * cis \<theta>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>u' = cor ru * cis \<phi>\<close>
         apply simp
         apply (transfer fixing: ry rz ru \<theta> \<phi>)
         apply (transfer fixing: ry rz ru \<theta> \<phi>)
       proof-
         assume "intersects_x_axis_positive_cmat (poincare_line_cvec_cmat (of_complex_cvec (cor ry * cis \<theta>)) (of_complex_cvec (cor rz * cis \<phi>)))"
         thus "(ry * sin \<theta> * (1 + rz\<^sup>2) - rz * sin \<phi> * (1 + ry\<^sup>2)) / (2 * rz * ry * sin (\<phi> - \<theta>)) < - 1"
           using yz
           by simp
       qed
 
       have "?ReByz / ?Ayz \<ge> ?ReByu / ?Ayu"
       proof (cases "sin \<phi> > 0")
         case True
         hence "sin \<theta> < 0"
           using \<open>sin \<phi> * sin \<theta> < 0\<close>
           by (smt mult_nonneg_nonneg)
 
         have "?ReByz < 0"
         proof-
           have "ry * (1 + rz\<^sup>2) * sin \<theta> < 0"
             using \<open>ry > 0\<close> \<open>rz > 0\<close>
             using \<open>sin \<theta> < 0\<close>
             by (smt mult_pos_neg mult_pos_pos zero_less_power)
           moreover
           have "rz * (1 + ry\<^sup>2) * sin \<phi> > 0"
             using \<open>ry > 0\<close> \<open>rz > 0\<close>
             using \<open>sin \<phi> > 0\<close>
             by (smt mult_pos_neg mult_pos_pos zero_less_power)
           ultimately
           show ?thesis
             by simp
         qed
         have "?Ayz > 0"
           using \<open>Re ?Byz / ?Ayz < -1\<close> \<open>Re ?Byz = ?ReByz\<close> \<open>?ReByz < 0\<close>
           by (smt divide_less_0_iff)
         hence "sin (\<phi> - \<theta>) > 0"
           using \<open>ry > 0\<close> \<open>rz > 0\<close>
           by (smt mult_pos_pos zero_less_mult_pos)
 
         have "1 / ru + ru \<ge> 1 / rz + rz"
           using Pasch_fun_mono[of ru rz] \<open>0 < ru\<close> \<open>ru \<le> rz\<close> \<open>rz < 1\<close>
           by simp
         hence "sin \<theta> * (1 / ru + ru) \<le> sin \<theta> * (1 / rz + rz)"
           using \<open>sin \<theta> < 0\<close>
           by auto
         thus ?thesis
           using \<open>ru > 0\<close> \<open>rz > 0\<close> \<open>ru \<le> rz\<close> \<open>rz < 1\<close> \<open>?Ayz > 0\<close> \<open>sin (\<phi> - \<theta>) > 0\<close>
           using divide_right_mono[of "sin \<theta> * (1 / ru + ru)" "sin \<theta> * (1 / rz + rz)" "2 * sin (\<phi> - \<theta>)"]
           by (subst Kz, subst Ku) simp
       next
         assume "\<not> sin \<phi> > 0"
         hence "sin \<phi> < 0"
           using \<open>sin \<phi> * sin \<theta> < 0\<close>
           by (cases "sin \<phi> = 0", simp_all)
         hence "sin \<theta> > 0"
           using \<open>sin \<phi> * sin \<theta> < 0\<close>
           by (smt mult_nonpos_nonpos)
         have "?ReByz > 0"
         proof-
           have "ry * (1 + rz\<^sup>2) * sin \<theta> > 0"
             using \<open>ry > 0\<close> \<open>rz > 0\<close>
             using \<open>sin \<theta> > 0\<close>
             by (smt mult_pos_neg mult_pos_pos zero_less_power)
           moreover
           have "rz * (1 + ry\<^sup>2) * sin \<phi> < 0"
             using \<open>ry > 0\<close> \<open>rz > 0\<close>
             using \<open>sin \<phi> < 0\<close>
             by (smt mult_pos_neg mult_pos_pos zero_less_power)
           ultimately
           show ?thesis
             by simp
         qed
         have "?Ayz < 0"
           using \<open>Re ?Byz / ?Ayz < -1\<close> \<open>?Ayz \<noteq> 0\<close> \<open>Re ?Byz = ?ReByz\<close> \<open>?ReByz > 0\<close>
           by (smt divide_less_0_iff)
         hence "sin (\<phi> - \<theta>) < 0"
           using \<open>ry > 0\<close> \<open>rz > 0\<close>
           by (smt mult_nonneg_nonneg)
 
         have "1 / ru + ru \<ge> 1 / rz + rz"
           using Pasch_fun_mono[of ru rz] \<open>0 < ru\<close> \<open>ru \<le> rz\<close> \<open>rz < 1\<close>
           by simp
         hence "sin \<theta> * (1 / ru + ru) \<ge> sin \<theta> * (1 / rz + rz)"
           using \<open>sin \<theta> > 0\<close>
           by auto
         thus ?thesis
           using \<open>ru > 0\<close> \<open>rz > 0\<close> \<open>ru \<le> rz\<close> \<open>rz < 1\<close> \<open>?Ayz < 0\<close> \<open>sin (\<phi> - \<theta>) < 0\<close>
           using divide_right_mono_neg[of  "sin \<theta> * (1 / rz + rz)" "sin \<theta> * (1 / ru + ru)" "2 * sin (\<phi> - \<theta>)"]
           by (subst Kz, subst Ku) simp
       qed
 
       have "intersects_x_axis_positive ?yu"
         using * \<open>y' = cor ry * cis \<theta>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>u' = cor ru * cis \<phi>\<close>
         apply simp
         apply (transfer fixing: ry rz ru \<theta> \<phi>)
         apply (transfer fixing: ry rz ru \<theta> \<phi>)
       proof-
         have "Re ?Byu / ?Ayu < -1"
           using \<open>Re ?Byz / ?Ayz < -1\<close> \<open>?ReByz / ?Ayz \<ge> ?ReByu / ?Ayu\<close>
           by (subst (asm) \<open>Re ?Byz = ?ReByz\<close>, subst \<open>Re ?Byu = ?ReByu\<close>) simp
         thus "intersects_x_axis_positive_cmat (poincare_line_cvec_cmat (of_complex_cvec (cor ry * cis \<theta>)) (of_complex_cvec (cor ru * cis \<phi>)))"
           using yu
           by simp
       qed
 
       let ?a = "calc_x_axis_intersection ?yu"
       have "?a \<in> positive_x_axis" "?a \<in> circline_set ?yu" "?a \<in> unit_disc"
         using \<open>intersects_x_axis_positive ?yu\<close>
         using intersects_x_axis_positive_iff'[of ?yu] \<open>y \<noteq> u\<close>
         by auto
 
       then obtain a' where a': "?a = of_complex a'" "is_real a'" "Re a' > 0" "Re a' < 1"
         unfolding positive_x_axis_def circline_set_x_axis
         by (auto simp add: cmod_eq_Re)
 
       have "intersects_x_axis ?yz" "intersects_x_axis ?yu"
         using \<open>intersects_x_axis_positive ?yz\<close> \<open>intersects_x_axis_positive ?yu\<close>
         by auto
 
       show "\<exists>a. a \<in> unit_disc \<and> poincare_between u a y \<and> poincare_between 0\<^sub>h a (of_complex v)"
       proof (rule_tac x="?a" in exI, safe)
         show "poincare_between u ?a y"
           using poincare_between_x_axis_intersection[of y u ?a]
           using calc_x_axis_intersection[OF is_poincare_line_poincare_line[OF \<open>y \<noteq> u\<close>] \<open>intersects_x_axis ?yu\<close>]
           using calc_x_axis_intersection_in_unit_disc[OF is_poincare_line_poincare_line[OF \<open>y \<noteq> u\<close>] \<open>intersects_x_axis ?yu\<close>]
           using in_disc \<open>y \<noteq> u\<close> \<open>y \<notin> circline_set x_axis\<close> \<open>u \<notin> circline_set x_axis\<close>
-          using * \<open>\<phi> = arg u'\<close> \<open>\<theta> = arg y'\<close> \<open>\<phi> * \<theta> < 0\<close>
+          using * \<open>\<phi> = Arg u'\<close> \<open>\<theta> = Arg y'\<close> \<open>\<phi> * \<theta> < 0\<close>
           by (subst poincare_between_rev, auto simp add: mult.commute)
       next
         show "poincare_between 0\<^sub>h ?a (of_complex v)"
         proof-
           have "-?ReByz / ?Ayz \<le> -?ReByu / ?Ayu"
             using \<open>?ReByz / ?Ayz \<ge> ?ReByu / ?Ayu\<close>
             by linarith
           have "outward ?yz ?yu"
             using * \<open>y' = cor ry * cis \<theta>\<close> \<open>z' = cor rz * cis \<phi>\<close> \<open>u' = cor ru * cis \<phi>\<close>
             apply simp
             apply (transfer fixing: ry rz ru \<theta> \<phi>)
             apply (transfer fixing: ry rz ru \<theta> \<phi>)
             apply (subst yz yu)+
             unfolding outward_cmat_def
             apply (simp only: Let_def prod.case)
             apply (subst yz yu)+
             using \<open>-?ReByz / ?Ayz \<le> -?ReByu / ?Ayu\<close>
             by simp
           hence "Re a' \<le> Re v"
             using \<open>?v = of_complex v\<close>
             using \<open>?a = of_complex a'\<close>
             using \<open>intersects_x_axis_positive ?yz\<close> \<open>intersects_x_axis_positive ?yu\<close>
             using outward[OF is_poincare_line_poincare_line[OF \<open>y \<noteq> z\<close>] is_poincare_line_poincare_line[OF \<open>y \<noteq> u\<close>]]
             by simp
           thus ?thesis
             using \<open>?v = of_complex v\<close>
             using poincare_between_x_axis_0uv[of "Re a'" "Re v"] a' v
             by simp
         qed
       next
         show "?a \<in> unit_disc"
           by fact
       qed
     qed
   next
     show "x \<in> unit_disc" "v \<in> unit_disc" "x \<noteq> v"
       using assms
       by auto
   next
     fix M x v
     let ?Mx = "moebius_pt M x" and ?Mv = "moebius_pt M v"
     assume 1: "unit_disc_fix M" "x \<in> unit_disc" "v \<in> unit_disc" "x \<noteq> v"
     assume 2: "?P ?Mx ?Mv"
     show "?P x v"
     proof safe
       fix y z u
       let ?My = "moebius_pt M y" and ?Mz = "moebius_pt M z" and ?Mu = "moebius_pt M u"
       assume "distinct [x, y, z, u, v]" "\<not> poincare_collinear {x, y, z}" "y \<in> unit_disc" "z \<in> unit_disc" "u \<in> unit_disc"
              "poincare_between x u z" "poincare_between y v z"
       hence "\<exists> Ma. Ma \<in> unit_disc \<and> poincare_between ?Mu Ma ?My \<and> poincare_between ?Mx Ma ?Mv"
         using 1 2[rule_format, of ?My ?Mz ?Mu]
         by simp
       then obtain Ma where Ma: "Ma \<in> unit_disc" "poincare_between ?Mu Ma ?My \<and> poincare_between ?Mx Ma ?Mv"
         by blast
       let ?a = "moebius_pt (-M) Ma"
       let ?Ma = "moebius_pt M ?a"
       have "?Ma = Ma"
         by (metis moebius_pt_invert uminus_moebius_def)
       hence "?Ma \<in> unit_disc" "poincare_between ?Mu ?Ma ?My \<and> poincare_between ?Mx ?Ma ?Mv"
         using Ma
         by auto
       thus "\<exists>a. a \<in> unit_disc \<and> poincare_between u a y \<and> poincare_between x a v"
         using unit_disc_fix_moebius_inv[OF \<open>unit_disc_fix M\<close>] \<open>unit_disc_fix M\<close> \<open>Ma \<in> unit_disc\<close>
         using \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close> \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close>
         by (rule_tac x="?a" in exI, simp del: moebius_pt_comp_inv_right)
     qed
   qed
   thus ?thesis
     using assms
     by auto
 qed
 
 text\<open>Pasch axiom, only degenerative cases.\<close>
 lemma Pasch_deg:
   assumes "x \<in> unit_disc" and "y \<in> unit_disc" and "z \<in> unit_disc" and "u \<in> unit_disc" and "v \<in> unit_disc"
   assumes "\<not> distinct [x, y, z, u, v] \<or> poincare_collinear {x, y, z}"
   assumes "poincare_between x u z" and "poincare_between y v z"
   shows "\<exists> a. a \<in> unit_disc \<and> poincare_between u a y \<and> poincare_between x a v"
 proof(cases "poincare_collinear {x, y, z}")
   case True
   hence "poincare_between x y z \<or> poincare_between y x z \<or> poincare_between y z x"
     using assms(1, 2, 3) poincare_collinear3_between poincare_between_rev by blast
   show ?thesis
   proof(cases "poincare_between x y z")
     case True
     have "poincare_between x y v"
       using True assms poincare_between_transitivity
       by (meson poincare_between_rev)
     thus ?thesis
       using assms(2)
       by (rule_tac x="y" in exI, simp)
   next
     case False
     hence "poincare_between y x z \<or> poincare_between y z x"
       using \<open>poincare_between x y z \<or> poincare_between y x z \<or> poincare_between y z x\<close>
       by simp
     show ?thesis
     proof(cases "poincare_between y x z")
       case True
       hence "poincare_between u x y"
         using assms
         by (meson poincare_between_rev poincare_between_transitivity)
       thus ?thesis
         using assms
         by (rule_tac x="x" in exI, simp)
     next
       case False
       hence "poincare_between y z x"
         using \<open>poincare_between y x z \<or> poincare_between y z x\<close>
         by auto
       hence "poincare_between x z v"
         using assms
         by (meson poincare_between_rev poincare_between_transitivity)
       hence "poincare_between x u v"
         using assms poincare_between_transitivity poincare_between_rev
         by (smt poincare_between_sum_distances)
       thus ?thesis
         using assms
         by (rule_tac x="u" in exI, simp)
     qed
   qed
 next
   case False
   hence "\<not> distinct [x, y, z, u, v]"
     using assms(6) by auto
   show ?thesis
   proof(cases "u=z")
     case True
     thus ?thesis
       using assms
       apply(rule_tac x="v" in exI)
       by(simp add:poincare_between_rev)
   next
     case False (* "u \<noteq> z" *)
     hence "x \<noteq> z"
       using assms poincare_between_sandwich by blast
     show ?thesis
     proof(cases "v=z")
       case True
       thus ?thesis
         using assms
         by (rule_tac x="u" in exI, simp)
     next
       case False (* v \<noteq> z *)
       hence "y \<noteq> z"
         using assms poincare_between_sandwich by blast
       show ?thesis
       proof(cases "u = x")
         case True
         thus ?thesis
           using assms
           by (rule_tac x="x" in exI, simp)
       next
         case False (*u \<noteq> x*)
         have "x \<noteq> y"
           using assms \<open>\<not> poincare_collinear {x, y, z}\<close>
           by fastforce
         have "x \<noteq> v"
           using assms \<open>\<not> poincare_collinear {x, y, z}\<close>
           by (metis insert_commute poincare_between_poincare_collinear)
         have "u \<noteq> y"
           using assms \<open>\<not> poincare_collinear {x, y, z}\<close>
           using poincare_between_poincare_collinear by blast
         have "u \<noteq> v"
         proof(rule ccontr)
           assume "\<not> u \<noteq> v"
           hence "poincare_between x v z"
             using assms by auto
           hence "x \<in> circline_set (poincare_line z v)"
             using poincare_between_rev[of x v z]
             using poincare_between_poincare_line_uvz[of z v x]
             using assms \<open>v \<noteq> z\<close>
             by auto
           have "y \<in> circline_set (poincare_line z v)"
             using assms \<open>\<not> u \<noteq> v\<close> 
             using poincare_between_rev[of y v z]
             using poincare_between_poincare_line_uvz[of z v y]
             using assms \<open>v \<noteq> z\<close>
             by auto
           have "z \<in> circline_set (poincare_line z v)"
             using ex_poincare_line_two_points[of z v] \<open>v \<noteq> z\<close>
             by auto
           have "is_poincare_line (poincare_line z v)"
             using \<open>v \<noteq> z\<close>
             by auto
           hence "poincare_collinear {x, y, z}"
             using \<open>x \<in> circline_set (poincare_line z v)\<close>
             using \<open>y \<in> circline_set (poincare_line z v)\<close>
             using \<open>z \<in> circline_set (poincare_line z v)\<close>
             unfolding poincare_collinear_def
             by (rule_tac x="poincare_line z v" in exI, simp)            
           thus False
             using \<open>\<not> poincare_collinear {x, y, z}\<close> by simp
         qed
         have "v = y"
           using \<open>u \<noteq> v\<close> \<open>u \<noteq> y\<close> \<open>x \<noteq> v\<close> \<open>x \<noteq> y\<close> \<open>u \<noteq> x\<close> \<open>y \<noteq> z\<close> \<open>v \<noteq> z\<close> \<open>x \<noteq> z\<close> \<open>u \<noteq> z\<close>
           using \<open>\<not> distinct [x, y, z, u, v]\<close>
           by auto
         thus ?thesis
           using assms
           by (rule_tac x="y" in exI, simp)
       qed
     qed
   qed
 qed
 
 text \<open>Axiom of Pasch\<close>
 lemma Pasch:
   assumes "x \<in> unit_disc" and "y \<in> unit_disc" and "z \<in> unit_disc" and "u \<in> unit_disc" and "v \<in> unit_disc"
   assumes "poincare_between x u z" and "poincare_between y v z"
   shows "\<exists> a. a \<in> unit_disc \<and> poincare_between u a y \<and> poincare_between x a v"
 proof(cases "distinct [x, y, z, u, v] \<and> \<not> poincare_collinear {x, y, z}")
   case True
   thus ?thesis
     using assms Pasch_nondeg by auto
 next
   case False
   thus ?thesis
     using assms Pasch_deg by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Segment construction axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma segment_construction:
   assumes "x \<in> unit_disc" and "y \<in> unit_disc"
   assumes "a \<in> unit_disc" and "b \<in> unit_disc"
   shows "\<exists> z. z \<in> unit_disc \<and> poincare_between x y z \<and> poincare_distance y z = poincare_distance a b"
 proof-
   obtain d where d: "d = poincare_distance a b"
     by auto
   have "d \<ge> 0"
     using assms
     by (simp add: d poincare_distance_ge0)
 
   have "\<exists> z. z \<in> unit_disc \<and> poincare_between x y z \<and> poincare_distance y z = d" (is "?P x y")
   proof (cases "x = y")
     case True
     have "\<exists> z. z \<in> unit_disc \<and> poincare_distance x z = d"
     proof (rule wlog_zero)
       show "\<exists> z. z \<in> unit_disc \<and> poincare_distance 0\<^sub>h z = d"
         using ex_x_axis_poincare_distance_negative[of d] \<open>d \<ge> 0\<close>
         by blast
     next
       show "x \<in> unit_disc"
         by fact
     next
       fix a u
       assume "u \<in> unit_disc" "cmod a < 1"
       assume "\<exists>z. z \<in> unit_disc \<and> poincare_distance (moebius_pt (blaschke a) u) z = d"
       then obtain z where *: "z \<in> unit_disc" "poincare_distance (moebius_pt (blaschke a) u) z = d"
         by auto
       obtain z' where z': "z = moebius_pt (blaschke a) z'" "z' \<in> unit_disc"
         using \<open>z \<in> unit_disc\<close>
         using unit_disc_fix_iff[of "blaschke a"] \<open>cmod a < 1\<close>
         using blaschke_unit_disc_fix[of a]
         by blast
 
       show "\<exists>z. z \<in> unit_disc \<and> poincare_distance u z = d"
         using * z' \<open>u : unit_disc\<close>
         using blaschke_unit_disc_fix[of a] \<open>cmod a < 1\<close>
         by (rule_tac x=z' in exI, simp)
     qed
     thus ?thesis
       using \<open>x = y\<close>
       unfolding poincare_between_def
       by auto
   next
     case False
     show ?thesis
     proof (rule wlog_positive_x_axis[where P="\<lambda> y x. ?P x y"])
       fix x
       assume "is_real x" "0 < Re x" "Re x < 1"
 
       then obtain z where z: "is_real z" "Re z \<le> 0" "- 1 < Re z" "of_complex z \<in> unit_disc"
         "of_complex z \<in> unit_disc" "of_complex z \<in> circline_set x_axis" "poincare_distance 0\<^sub>h (of_complex z) = d"
         using ex_x_axis_poincare_distance_negative[of d] \<open>d \<ge> 0\<close>
         by auto
 
       have "poincare_between (of_complex x) 0\<^sub>h (of_complex z)"
       proof (cases "z = 0")
         case True
         thus ?thesis
           unfolding poincare_between_def
           by auto
       next
         case False
         have "x \<noteq> 0"
           using \<open>is_real x\<close> \<open>Re x > 0\<close>
           by auto
         thus ?thesis
           using poincare_between_x_axis_u0v[of x z]
           using z \<open>is_real x\<close> \<open>x \<noteq> 0\<close> \<open>Re x > 0\<close> False
           using complex_eq_if_Re_eq mult_pos_neg
           by fastforce
     qed
     thus "?P (of_complex x) 0\<^sub>h"
       using \<open>poincare_distance 0\<^sub>h (of_complex z) = d\<close> \<open>of_complex z \<in> unit_disc\<close>
       by blast
   next
     show "x \<in> unit_disc" "y \<in> unit_disc"
       by fact+
   next
     show "y \<noteq> x" using \<open>x \<noteq> y\<close> by simp
   next
     fix M u v
     assume "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
     assume "?P (moebius_pt M v) (moebius_pt M u)"
     then obtain z where *: "z \<in> unit_disc" "poincare_between (moebius_pt M v) (moebius_pt M u) z" "poincare_distance (moebius_pt M u) z = d"
       by auto
     obtain z' where z': "z = moebius_pt M z'" "z' \<in> unit_disc"
         using \<open>z \<in> unit_disc\<close>
         using unit_disc_fix_iff[of M] \<open>unit_disc_fix M\<close>
         by blast
       thus "?P v u"
         using * \<open>u \<in> unit_disc\<close> \<open>v \<in> unit_disc\<close> \<open>unit_disc_fix M\<close>
         by auto
     qed
   qed
   thus ?thesis
     using assms d
     by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Five segment axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma five_segment_axiom:
   assumes
      in_disc: "x \<in> unit_disc"  "y \<in> unit_disc" "z \<in> unit_disc" "u \<in> unit_disc" and
      in_disc': "x' \<in> unit_disc" "y' \<in> unit_disc" "z' \<in> unit_disc" "u' \<in> unit_disc" and
       "x \<noteq> y" and
       betw: "poincare_between x y z" "poincare_between x' y' z'" and
       xy: "poincare_distance x y = poincare_distance x' y'" and
       xu: "poincare_distance x u = poincare_distance x' u'" and
       yu: "poincare_distance y u = poincare_distance y' u'" and
       yz: "poincare_distance y z = poincare_distance y' z'"
     shows
      "poincare_distance z u = poincare_distance z' u'"
 proof-
   from assms obtain M where
   M: "unit_disc_fix_f M" "M x = x'" "M u = u'" "M y = y'"
     using unit_disc_fix_f_congruent_triangles[of x y u]
     by blast
   have "M z = z'"
   proof (rule unique_poincare_distance_on_ray[where u=x' and v=y' and y="M z" and z=z' and d="poincare_distance x z"])
     show "0 \<le> poincare_distance x z"
       using poincare_distance_ge0 in_disc
       by simp
   next
     show "x' \<noteq> y'"
       using M \<open>x \<noteq> y\<close>
       using in_disc in_disc' poincare_distance_eq_0_iff xy
       by auto
   next
     show "poincare_distance x' (M z) = poincare_distance x z"
       using M in_disc
       unfolding unit_disc_fix_f_def
       by auto
   next
     show "M z \<in> unit_disc"
       using M in_disc
       unfolding unit_disc_fix_f_def
       by auto
   next
     show "poincare_distance x' z' = poincare_distance x z"
       using xy yz betw
       using poincare_between_sum_distances[of x y z]
       using poincare_between_sum_distances[of x' y' z']
       using in_disc in_disc'
       by auto
   next
     show "poincare_between x' y' (M z)"
       using M
       using in_disc betw
       unfolding unit_disc_fix_f_def
       by auto
   qed fact+
   thus ?thesis
     using \<open>unit_disc_fix_f M\<close>
     using in_disc in_disc'
     \<open>M u = u'\<close>
     unfolding unit_disc_fix_f_def
     by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Upper dimension axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma upper_dimension_axiom:
   assumes in_disc: "x \<in> unit_disc" "y \<in> unit_disc" "z \<in> unit_disc" "u \<in> unit_disc" "v \<in> unit_disc"
   assumes "poincare_distance x u = poincare_distance x v"
           "poincare_distance y u = poincare_distance y v"
           "poincare_distance z u = poincare_distance z v"
           "u \<noteq> v"
   shows "poincare_between x y z \<or> poincare_between y z x \<or> poincare_between z x y"
 proof (cases "x = y \<or> y = z \<or> x = z")
   case True
   thus ?thesis
     using in_disc
     by auto
 next
   case False
   hence "x \<noteq> y" "x \<noteq> z" "y \<noteq> z"
     by auto
   let ?cong = "\<lambda> a b a' b'. poincare_distance a b = poincare_distance a' b'"
   have "\<forall> z u v. z \<in> unit_disc \<and> u \<in> unit_disc \<and> v \<in> unit_disc \<and>
                  ?cong x u x v \<and> ?cong y u y v \<and> ?cong z u z v  \<and> u \<noteq> v \<longrightarrow>
                  poincare_collinear {x, y, z}" (is "?P x y")
   proof (rule wlog_positive_x_axis[where P="?P"])
     fix x
     assume x: "is_real x" "0 < Re x" "Re x < 1"
     hence "x \<noteq> 0"
       by auto
     have "0\<^sub>h \<in> circline_set x_axis"
       by simp
     show "?P 0\<^sub>h (of_complex x)"
     proof safe
       fix z u v
       assume in_disc: "z \<in> unit_disc" "u \<in> unit_disc" "v \<in> unit_disc"
       then obtain z' u' v' where zuv: "z = of_complex z'" "u = of_complex u'" "v = of_complex v'"
         using inf_or_of_complex[of z] inf_or_of_complex[of u] inf_or_of_complex[of v]
         by auto
 
       assume cong: "?cong 0\<^sub>h u 0\<^sub>h v" "?cong (of_complex x) u (of_complex x) v" "?cong z u z v" "u \<noteq> v"
 
       let ?r0 = "poincare_distance 0\<^sub>h u" and
           ?rx = "poincare_distance (of_complex x) u"
 
       have "?r0 > 0" "?rx > 0"
         using in_disc  cong
         using poincare_distance_eq_0_iff[of "0\<^sub>h" u] poincare_distance_ge0[of "0\<^sub>h" u]
         using poincare_distance_eq_0_iff[of "0\<^sub>h" v] poincare_distance_ge0[of "0\<^sub>h" v]
         using poincare_distance_eq_0_iff[of "of_complex x" u] poincare_distance_ge0[of "of_complex x" u]
         using poincare_distance_eq_0_iff[of "of_complex x" v] poincare_distance_ge0[of "of_complex x" v]
         using x
         by (auto simp add: cmod_eq_Re)
 
       let ?pc0 = "poincare_circle 0\<^sub>h ?r0" and
           ?pcx = "poincare_circle (of_complex x) ?rx"
       have "u \<in> ?pc0 \<inter> ?pcx" "v \<in> ?pc0 \<inter> ?pcx"
         using in_disc cong
         by (auto simp add: poincare_circle_def)
       hence "u = conjugate v"
         using intersect_poincare_circles_x_axis[of 0 x ?r0 ?rx u v]
         using x \<open>x \<noteq> 0\<close> \<open>u \<noteq> v\<close> \<open>?r0 > 0\<close> \<open>?rx > 0\<close>
         by simp
 
       let ?ru = "poincare_distance u z"
       have "?ru > 0"
         using poincare_distance_ge0[of u z] in_disc
         using cong
         using poincare_distance_eq_0_iff[of z u] poincare_distance_eq_0_iff[of z v]
         using poincare_distance_eq_0_iff
         by force
 
       have "z \<in> poincare_circle u ?ru \<inter> poincare_circle v ?ru"
         using cong in_disc
         unfolding poincare_circle_def
         by (simp add: poincare_distance_sym)
 
       hence "is_real z'"
         using intersect_poincare_circles_conjugate_centers[of u v ?ru z] \<open>u = conjugate v\<close> zuv
         using in_disc \<open>u \<noteq> v\<close> \<open>?ru > 0\<close>
         by simp
 
       thus "poincare_collinear {0\<^sub>h, of_complex x, z}"
         using poincare_line_0_real_is_x_axis[of "of_complex x"] x \<open>x \<noteq> 0\<close> zuv \<open>0\<^sub>h \<in> circline_set x_axis\<close>
         unfolding poincare_collinear_def
         by (rule_tac x=x_axis in exI, auto simp add: circline_set_x_axis)
     qed
   next
     fix M x y
     assume 1: "unit_disc_fix M" "x \<in> unit_disc" "y \<in> unit_disc" "x \<noteq> y"
     assume 2: "?P (moebius_pt M x) (moebius_pt M y)"
     show "?P x y"
     proof safe
       fix z u v
       assume "z \<in> unit_disc" "u \<in> unit_disc" "v \<in> unit_disc"
              "?cong x u x v" "?cong y u y v" "?cong z u z v" "u \<noteq> v"
       hence "poincare_collinear {moebius_pt M x, moebius_pt M y, moebius_pt M z}"
         using 1 2[rule_format, of "moebius_pt M z" "moebius_pt M u" "moebius_pt M v"]
         by simp
       then obtain p where "is_poincare_line p" "{moebius_pt M x, moebius_pt M y, moebius_pt M z} \<subseteq> circline_set p"
         unfolding poincare_collinear_def
         by auto
       thus "poincare_collinear {x, y, z}"
         using \<open>unit_disc_fix M\<close>
         unfolding poincare_collinear_def
         by (rule_tac x="moebius_circline (-M) p" in exI, auto)
     qed
   qed fact+
 
   thus ?thesis
     using assms
     using poincare_collinear3_between[of x y z]
     using poincare_between_rev
     by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Lower dimension axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma lower_dimension_axiom:
   shows "\<exists> a \<in> unit_disc. \<exists> b \<in> unit_disc. \<exists> c \<in> unit_disc.
             \<not> poincare_between a b c \<and> \<not> poincare_between b c a \<and> \<not> poincare_between c a b"
 proof-
   let ?u = "of_complex (1/2)" and ?v = "of_complex (\<i>/2)"
   have 1: "0\<^sub>h \<in> unit_disc" and 2: "?u \<in> unit_disc" and 3: "?v \<in> unit_disc"
     by simp_all
   have *: "\<not> poincare_collinear {0\<^sub>h, ?u, ?v}"
   proof (rule ccontr)
     assume "\<not> ?thesis"
     then obtain p where "is_poincare_line p" "{0\<^sub>h, ?u, ?v} \<subseteq> circline_set p"
       unfolding poincare_collinear_def
       by auto
     moreover
     have "of_complex (1 / 2) \<noteq> of_complex (\<i> / 2)"
       using of_complex_inj
       by fastforce
     ultimately
     have "0\<^sub>h \<in> circline_set (poincare_line ?u ?v)"
       using unique_poincare_line[of ?u ?v p]
       by auto
     thus False
       unfolding circline_set_def
       by simp (transfer, transfer, simp add: vec_cnj_def)
   qed
   show ?thesis
     apply (rule_tac x="0\<^sub>h" in bexI, rule_tac x="?u" in bexI, rule_tac x="?v" in bexI)
     apply (rule ccontr, auto)
     using *
     using poincare_between_poincare_collinear[OF 1 2 3]
     using poincare_between_poincare_collinear[OF 2 3 1]
     using poincare_between_poincare_collinear[OF 3 1 2]
     by (metis insert_commute)+
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Negated Euclidean axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 lemma negated_euclidean_axiom_aux:
   assumes "on_circline H (of_complex (1/2 + \<i>/2))" and "is_poincare_line H"
   assumes "intersects_x_axis_positive H"
   shows "\<not> intersects_y_axis_positive H"
   using assms
 proof (transfer, transfer)
   fix H
   assume hh: "hermitean H \<and> H \<noteq> mat_zero" "is_poincare_line_cmat H"
   obtain A B C D where "H = (A, B, C, D)"
     by (cases H, auto)
   hence *: "is_real A" "H = (A, B, cnj B, A)" "(cmod B)\<^sup>2 > (cmod A)\<^sup>2"
     using hermitean_elems[of A B C D] hh
     by auto
 
   assume "intersects_x_axis_positive_cmat H"
   hence "Re A \<noteq> 0" "Re B / Re A < - 1"
     using *
     by auto
 
   assume "on_circline_cmat_cvec H (of_complex_cvec (1 / 2 + \<i> / 2))"
   hence "6*A + 4*Re B + 4*Im B = 0"
     using *
     unfolding of_real_mult
     apply (subst Re_express_cnj[of B])
     apply (subst Im_express_cnj[of B])
     apply (simp add: vec_cnj_def)
     apply (simp add: field_simps)
     done
   hence "Re (6*A + 4*Re B + 4*Im B) = 0"
     by simp
   hence "3*Re A + 2*Re B + 2*Im B = 0"
     using \<open>is_real A\<close>
     by simp
 
   hence "3/2 + Re B/Re A + Im B/Re A = 0"
     using \<open>Re A \<noteq> 0\<close>
     by (simp add: field_simps)
 
   hence "-Im B/Re A - 3/2 < -1"
     using \<open>Re B / Re A < -1\<close>
     by simp
   hence "Im B/Re A > -1/2"
     by (simp add: field_simps)
   thus "\<not> intersects_y_axis_positive_cmat H"
     using *
     by simp
 qed
 
 lemma negated_euclidean_axiom:
   shows "\<exists> a b c d t.
            a \<in> unit_disc \<and> b \<in> unit_disc \<and> c \<in> unit_disc \<and> d \<in> unit_disc \<and> t \<in> unit_disc \<and>
            poincare_between a d t \<and> poincare_between b d c \<and> a \<noteq> d \<and>
                 (\<forall> x y. x \<in> unit_disc \<and> y \<in> unit_disc \<and>
                         poincare_between a b x \<and> poincare_between x t y \<longrightarrow> \<not> poincare_between a c y)"
 proof-
   let ?a = "0\<^sub>h"
   let ?b = "of_complex (1/2)"
   let ?c = "of_complex (\<i>/2)"
   let ?dl = "(5 - sqrt 17) / 4"
   let ?d = "of_complex (?dl + \<i>*?dl)"
   let ?t = "of_complex (1/2 + \<i>/2)"
 
   have "?dl \<noteq> 0"
   proof-
     have "(sqrt 17)\<^sup>2 \<noteq> 5\<^sup>2"
       by simp
     hence "sqrt 17 \<noteq> 5"
       by force
     thus ?thesis
       by simp
   qed
 
   have "?d \<noteq> ?a"
   proof (rule ccontr)
     assume "\<not> ?thesis"
     hence "?dl + \<i>*?dl = 0"
       by simp
     hence "Re (?dl + \<i>*?dl) = 0"
       by simp
     thus False
       using \<open>?dl \<noteq> 0\<close>
       by simp
   qed
 
   have "?dl > 0"
   proof-
     have "(sqrt 17)\<^sup>2 < 5\<^sup>2"
       by (simp add: power2_eq_square)
     hence "sqrt 17 < 5"
       by (rule power2_less_imp_less, simp)
     thus ?thesis
       by simp
   qed
 
   have "?a \<noteq> ?b"
     by (metis divide_eq_0_iff of_complex_zero_iff zero_neq_numeral zero_neq_one)
 
   have "?a \<noteq> ?c"
     by (metis complex_i_not_zero divide_eq_0_iff of_complex_zero_iff zero_neq_numeral)
 
   show ?thesis
   proof (rule_tac x="?a" in exI, rule_tac x="?b" in exI, rule_tac x="?c" in exI, rule_tac x="?d" in exI, rule_tac x="?t" in exI, safe)
 
 
     show "?a \<in> unit_disc" "?b \<in> unit_disc" "?c \<in> unit_disc" "?t \<in> unit_disc"
       by (auto simp add: cmod_def power2_eq_square)
 
     have cmod_d: "cmod (?dl + \<i>*?dl) = ?dl * sqrt 2"
       using \<open>?dl > 0\<close>
       unfolding cmod_def
       by (simp add: real_sqrt_mult)
 
     show "?d \<in> unit_disc"
     proof-
       have "?dl < 1 / sqrt 2"
       proof-
         have "17\<^sup>2 < (5 * sqrt 17)\<^sup>2"
           by (simp add: field_simps)
         hence "17 < 5 * sqrt 17"
           by (rule power2_less_imp_less, simp)
         hence "?dl\<^sup>2 < (1 / sqrt 2)\<^sup>2"
           by (simp add: power2_eq_square field_simps)
         thus "?dl < 1 / sqrt 2"
           by (rule power2_less_imp_less, simp)
       qed
       thus ?thesis
         using cmod_d
         by (simp add: field_simps)
     qed
 
     have cmod_d: "1 - (cmod (to_complex ?d))\<^sup>2 = (-17 + 5*sqrt 17) / 4" (is "_ = ?cmod_d")
       apply (simp only: to_complex_of_complex)
       apply (subst cmod_d)
       apply (simp add: power_mult_distrib)
       apply (simp add: power2_eq_square field_simps)
       done
 
     have cmod_d_c: "(cmod (to_complex ?d - to_complex ?c))\<^sup>2 = (17 - 4*sqrt 17) / 4" (is "_ = ?cmod_dc")
       unfolding cmod_square
       by (simp add: field_simps)
 
     have cmod_c: "1 - (cmod (to_complex ?c))\<^sup>2 = 3/4" (is "_ = ?cmod_c")
       by (simp add: power2_eq_square)
 
     have xx: "\<And> x::real. x + x = 2*x"
       by simp
 
     have "cmod ((to_complex ?b) - (to_complex ?d)) = cmod ((to_complex ?d) - (to_complex ?c))"
       by (simp add: cmod_def power2_eq_square field_simps)
     moreover
     have "cmod (to_complex ?b) = cmod (to_complex ?c)"
       by simp
     ultimately
     have *: "poincare_distance_formula' (to_complex ?b) (to_complex ?d) =
              poincare_distance_formula' (to_complex ?d) (to_complex ?c)"
       unfolding poincare_distance_formula'_def
       by simp
 
     have **: "poincare_distance_formula' (to_complex ?d) (to_complex ?c) = (sqrt 17) / 3"
       unfolding poincare_distance_formula'_def
     proof (subst cmod_d, subst cmod_c, subst cmod_d_c)
       have "(sqrt 17 * 15)\<^sup>2 \<noteq> 51\<^sup>2"
         by simp
       hence "sqrt 17 * 15 \<noteq> 51"
         by force
       hence "sqrt 17 * 15 - 51 \<noteq> 0"
         by simp
 
       have "(5 * sqrt 17)\<^sup>2 \<noteq> 17\<^sup>2"
         by simp
       hence "5 * sqrt 17 \<noteq> 17"
         by force
       hence "?cmod_d * ?cmod_c \<noteq> 0"
         by simp
       hence "1 + 2 * (?cmod_dc / (?cmod_d * ?cmod_c)) =  (?cmod_d * ?cmod_c + 2 * ?cmod_dc) / (?cmod_d * ?cmod_c)"
         using add_frac_num[of "?cmod_d * ?cmod_c" "2 * ?cmod_dc" 1]
         by (simp add: field_simps)
       also have "... = (64 * (85 - sqrt 17 * 17)) / (64 * (sqrt 17 * 15 - 51))"
         by (simp add: field_simps)
       also have "... = (85 - sqrt 17 * 17) / (sqrt 17 * 15 - 51)"
         by (rule mult_divide_mult_cancel_left, simp)
       also have "... = sqrt 17 / 3"
         by (subst frac_eq_eq, fact, simp, simp add: field_simps)
       finally
       show "1 + 2 * (?cmod_dc / (?cmod_d * ?cmod_c)) = sqrt 17 / 3"
         .
     qed
 
     have "sqrt 17 \<ge> 3"
     proof-
       have "(sqrt 17)\<^sup>2 \<ge> 3\<^sup>2"
         by simp
       thus ?thesis
         by (rule power2_le_imp_le, simp)
     qed
     thus "poincare_between ?b ?d ?c"
       unfolding poincare_between_sum_distances[OF \<open>?b \<in> unit_disc\<close> \<open>?d \<in> unit_disc\<close> \<open>?c \<in> unit_disc\<close>]
       unfolding poincare_distance_formula[OF \<open>?b \<in> unit_disc\<close> \<open>?d \<in> unit_disc\<close>]
       unfolding poincare_distance_formula[OF \<open>?d \<in> unit_disc\<close> \<open>?c \<in> unit_disc\<close>]
       unfolding poincare_distance_formula[OF \<open>?b \<in> unit_disc\<close> \<open>?c \<in> unit_disc\<close>]
       unfolding poincare_distance_formula_def
       apply (subst *, subst xx, subst **, subst arcosh_double)
       apply (simp_all add: cmod_def power2_eq_square)
       done
 
     show "poincare_between ?a ?d ?t"
     proof (subst poincare_between_0uv[OF \<open>?d \<in> unit_disc\<close> \<open>?t \<in> unit_disc\<close> \<open>?d \<noteq> ?a\<close>])
       show "?t \<noteq> 0\<^sub>h"
       proof (rule ccontr)
         assume "\<not> ?thesis"
         hence "1/2 + \<i>/2 = 0"
           by simp
         hence "Re (1/2 + \<i>/2) = 0"
           by simp
         thus False
           by simp
       qed
     next
       have "19\<^sup>2 \<le> (5 * sqrt 17)\<^sup>2"
         by simp
       hence "19 \<le> 5 * sqrt 17"
         by (rule power2_le_imp_le, simp)
       hence "cmod (to_complex ?d) \<le> cmod (to_complex ?t)"
         by (simp add: Let_def cmod_def power2_eq_square field_simps)
       moreover
-      have "arg (to_complex ?d) = arg (to_complex ?t)"
+      have "Arg (to_complex ?d) = Arg (to_complex ?t)"
       proof-
         have 1: "to_complex ?d = ((5 - sqrt 17) / 4) * (1 + \<i>)"
           by (simp add: field_simps)
 
         have 2: "to_complex ?t = (cor (1/2)) * (1 + \<i>)"
           by (simp add: field_simps)
 
         have "(sqrt 17)\<^sup>2 < 5\<^sup>2"
           by simp
         hence "sqrt 17 < 5"
           by (rule power2_less_imp_less, simp)
         hence 3: "(5 - sqrt 17) / 4 > 0"
           by simp
 
         have 4: "(1::real) / 2 > 0"
           by simp
 
         show ?thesis
           apply (subst 1, subst 2)
           apply (subst arg_mult_real_positive[OF 3])
           apply (subst arg_mult_real_positive[OF 4])
           by simp
       qed
       ultimately
-      show "let d' = to_complex ?d; t' = to_complex ?t in arg d' = arg t' \<and> cmod d' \<le> cmod t'"
+      show "let d' = to_complex ?d; t' = to_complex ?t in Arg d' = Arg t' \<and> cmod d' \<le> cmod t'"
         by simp
     qed
 
     show "?a = ?d \<Longrightarrow> False"
       using \<open>?d \<noteq> ?a\<close>
       by simp
 
     fix x y
     assume "x \<in> unit_disc" "y \<in> unit_disc"
 
     assume abx: "poincare_between ?a ?b x"
     hence "x \<in> circline_set x_axis"
       using poincare_between_poincare_line_uvz[of ?a ?b x] \<open>x \<in> unit_disc\<close> \<open>?a \<noteq> ?b\<close>
       using poincare_line_0_real_is_x_axis[of ?b]
       by (auto simp add: circline_set_x_axis)
 
     have "x \<noteq> 0\<^sub>h"
       using abx poincare_between_sandwich[of ?a ?b] \<open>?a \<noteq> ?b\<close>
       by auto
 
     have "x \<in> positive_x_axis"
       using \<open>x \<in> circline_set x_axis\<close> \<open>x \<noteq> 0\<^sub>h\<close> \<open>x \<in> unit_disc\<close>
       using abx poincare_between_x_axis_0uv[of "1/2" "Re (to_complex x)"]
       unfolding circline_set_x_axis positive_x_axis_def
       by (auto simp add: cmod_eq_Re abs_less_iff complex_eq_if_Re_eq)
 
     assume acy: "poincare_between ?a ?c y"
     hence "y \<in> circline_set y_axis"
       using poincare_between_poincare_line_uvz[of ?a ?c y] \<open>y \<in> unit_disc\<close> \<open>?a \<noteq> ?c\<close>
       using poincare_line_0_imag_is_y_axis[of ?c]
       by (auto simp add: circline_set_y_axis)
 
     have "y \<noteq> 0\<^sub>h"
       using acy poincare_between_sandwich[of ?a ?c] \<open>?a \<noteq> ?c\<close>
       by auto
 
     have "y \<in> positive_y_axis"
     proof-
       have " \<And>x. \<lbrakk>x \<noteq> 0; poincare_between 0\<^sub>h (of_complex (\<i> / 2)) (of_complex x); is_imag x; - 1 < Im x\<rbrakk> \<Longrightarrow> 0 < Im x"
         by (smt add.left_neutral complex.expand divide_complex_def complex_eq divide_less_0_1_iff divide_less_eq_1_pos imaginary_unit.simps(1) mult.left_neutral of_real_1 of_real_add of_real_divide of_real_eq_0_iff one_add_one poincare_between_y_axis_0uv zero_complex.simps(1) zero_complex.simps(2) zero_less_divide_1_iff)
       thus ?thesis
         using \<open>y \<in> circline_set y_axis\<close> \<open>y \<noteq> 0\<^sub>h\<close> \<open>y \<in> unit_disc\<close>
         using acy
         unfolding circline_set_y_axis positive_y_axis_def
         by (auto simp add: cmod_eq_Im abs_less_iff)
     qed
 
     have "x \<noteq> y"
       using \<open>x \<in> positive_x_axis\<close> \<open>y \<in> positive_y_axis\<close>
       unfolding positive_x_axis_def positive_y_axis_def circline_set_x_axis circline_set_y_axis
       by auto
 
     assume xty: "poincare_between x ?t y"
 
     let ?xy = "poincare_line x y"
 
     have "?t \<in> circline_set ?xy"
       using xty poincare_between_poincare_line_uzv[OF \<open>x \<noteq> y\<close> \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>?t \<in> unit_disc\<close>]
       by simp
 
     moreover
 
     have "?xy \<noteq> x_axis"
       using poincare_line_circline_set[OF \<open>x \<noteq> y\<close>] \<open>y \<in> positive_y_axis\<close>
       by (auto simp add: circline_set_x_axis positive_y_axis_def)
     hence "intersects_x_axis_positive ?xy"
       using intersects_x_axis_positive_iff[of "?xy"] \<open>x \<noteq> y\<close> \<open>x \<in> unit_disc\<close> \<open>x \<in> positive_x_axis\<close>
       by auto
 
     moreover
 
     have "?xy \<noteq> y_axis"
       using poincare_line_circline_set[OF \<open>x \<noteq> y\<close>] \<open>x \<in> positive_x_axis\<close>
       by (auto simp add: circline_set_y_axis positive_x_axis_def)
     hence "intersects_y_axis_positive ?xy"
       using intersects_y_axis_positive_iff[of "?xy"] \<open>x \<noteq> y\<close> \<open>y \<in> unit_disc\<close> \<open>y \<in> positive_y_axis\<close>
       by auto
 
     ultimately
 
     show False
       using negated_euclidean_axiom_aux[of ?xy] \<open>x \<noteq> y\<close>
       unfolding circline_set_def
       by auto
   qed
 qed
 
 text \<open>Alternate form of the Euclidean axiom -- this one is much easier to prove\<close>
 lemma negated_euclidean_axiom':
   shows "\<exists> a b c.
            a \<in> unit_disc \<and> b \<in> unit_disc \<and> c \<in> unit_disc \<and> \<not>(poincare_collinear {a, b, c})  \<and>
                 \<not>(\<exists> x. x \<in> unit_disc \<and> 
                   poincare_distance a x = poincare_distance b x \<and>
                   poincare_distance a x = poincare_distance c x)"
 proof-
   let ?a = "of_complex (\<i>/2)"
   let ?b = "of_complex (-\<i>/2)"
   let ?c = "of_complex (1/5)"
 
   have "(\<i>/2) \<noteq> (-\<i>/2)"
     by simp
   hence "?a \<noteq> ?b"
     by (metis to_complex_of_complex)
   have "(\<i>/2) \<noteq> (1/5)"
     by simp
   hence "?a \<noteq> ?c"
     by (metis to_complex_of_complex)
   have "(-\<i>/2) \<noteq> (1/5)"
     by (simp add: minus_equation_iff)
   hence "?b \<noteq> ?c"
     by (metis to_complex_of_complex)
 
   have "?a \<in> unit_disc" "?b \<in> unit_disc" "?c \<in> unit_disc"
     by auto
 
   moreover
   have "\<not>(poincare_collinear {?a, ?b, ?c})"
     unfolding poincare_collinear_def
   proof(rule ccontr)
     assume " \<not> (\<nexists>p. is_poincare_line p \<and> {?a, ?b, ?c} \<subseteq> circline_set p)"
     then obtain p where "is_poincare_line p \<and> {?a, ?b, ?c} \<subseteq> circline_set p"
       by auto
     let ?ab = "poincare_line ?a ?b"
     have "p = ?ab"
       using \<open>is_poincare_line p \<and> {?a, ?b, ?c} \<subseteq> circline_set p\<close>
       using unique_poincare_line[of ?a ?b] \<open>?a \<noteq> ?b\<close> \<open>?a \<in> unit_disc\<close> \<open>?b \<in> unit_disc\<close>
       by auto
     have "?c \<notin> circline_set ?ab"
     proof(rule ccontr)
       assume "\<not> ?c \<notin> circline_set ?ab"
       have "poincare_between ?a 0\<^sub>h ?b"
         unfolding poincare_between_def
         using cross_ratio_0inf by auto
       hence "0\<^sub>h \<in> circline_set ?ab"
         using \<open>?a \<noteq> ?b\<close> \<open>?a \<in> unit_disc\<close> \<open>?b \<in> unit_disc\<close>
         using poincare_between_poincare_line_uzv zero_in_unit_disc 
         by blast
       hence "?ab = poincare_line 0\<^sub>h ?a"
         using unique_poincare_line[of ?a ?b] \<open>?a \<noteq> ?b\<close> \<open>?a \<in> unit_disc\<close> \<open>?b \<in> unit_disc\<close>
         using \<open>is_poincare_line p \<and> {?a, ?b, ?c} \<subseteq> circline_set p\<close> 
         using \<open>p = ?ab\<close> poincare_line_circline_set(1) unique_poincare_line
         by (metis add.inverse_neutral divide_minus_left of_complex_zero_iff  zero_in_unit_disc)
       hence "(\<i>/2) * cnj(1/5) = cnj(\<i>/2) * (1/5)"
         using poincare_collinear_zero_iff[of "(\<i>/2)" "(1/5)"]
         using \<open>?a \<noteq> ?c\<close> \<open>\<not> ?c \<notin> circline_set ?ab\<close> \<open>?a \<in> unit_disc\<close> \<open>?c \<in> unit_disc\<close> \<open>p = ?ab\<close>
         using \<open>0\<^sub>h \<in> circline_set ?ab\<close> \<open>is_poincare_line p \<and> {?a, ?b, ?c} \<subseteq> circline_set p\<close> 
         using poincare_collinear_def by auto
       thus False
         by simp
     qed 
     thus False
       using \<open>p = ?ab\<close> \<open>is_poincare_line p \<and> {?a, ?b, ?c} \<subseteq> circline_set p\<close> 
       by auto
   qed
 
   moreover
 
   have "\<not>(\<exists> x. x \<in> unit_disc \<and> 
                   poincare_distance ?a x = poincare_distance ?b x \<and>
                   poincare_distance ?a x = poincare_distance ?c x)"
   proof(rule ccontr)
     assume "\<not> ?thesis"
     then obtain x where "x \<in> unit_disc" "poincare_distance ?a x = poincare_distance ?b x"
                         "poincare_distance ?a x = poincare_distance ?c x"
       by blast
     let ?x = "to_complex x"
     have "poincare_distance_formula' (\<i>/2) ?x = poincare_distance_formula' (-\<i>/2) ?x"
       using \<open>poincare_distance ?a x = poincare_distance ?b x\<close>
       using \<open>x \<in> unit_disc\<close> \<open>?a \<in> unit_disc\<close> \<open>?b \<in> unit_disc\<close>
       by (metis cosh_dist to_complex_of_complex)
     hence "(cmod (\<i> / 2 - ?x))\<^sup>2 = (cmod (- \<i> / 2 - ?x))\<^sup>2"
       unfolding poincare_distance_formula'_def
       apply (simp add:field_simps)
       using \<open>x \<in> unit_disc\<close> unit_disc_cmod_square_lt_1 by fastforce
     hence "Im ?x = 0"
       unfolding cmod_def
       by (simp add: power2_eq_iff)
 
     have "1 - (Re ?x)\<^sup>2 \<noteq> 0"
       using \<open>x \<in> unit_disc\<close> unit_disc_cmod_square_lt_1
       using cmod_power2 by force
     hence "24 - 24 * (Re ?x)\<^sup>2 \<noteq> 0"
       by simp
     have "poincare_distance_formula' (\<i>/2) ?x = poincare_distance_formula' (1/5) ?x"
       using \<open>poincare_distance ?a x = poincare_distance ?c x\<close>
       using \<open>x \<in> unit_disc\<close> \<open>?a \<in> unit_disc\<close> \<open>?c \<in> unit_disc\<close>
       by (metis cosh_dist to_complex_of_complex)
     hence "(2 + 8 * (Re ?x)\<^sup>2) /(3 - 3 * (Re ?x)\<^sup>2) = 2 * (1 - Re ?x * 5)\<^sup>2 / (24 - 24 * (Re ?x)\<^sup>2)" (is "?lhs = ?rhs")
       unfolding poincare_distance_formula'_def
       apply (simp add:field_simps)
       unfolding cmod_def 
       using \<open>Im ?x = 0\<close> 
       by (simp add:field_simps)
     hence *: "?lhs * (24 - 24 * (Re ?x)\<^sup>2)  = ?rhs * (24 - 24 * (Re ?x)\<^sup>2) "
       using \<open>(24 - 24 * (Re ?x)\<^sup>2) \<noteq> 0\<close> 
       by simp
     have "?lhs * (24 - 24 * (Re ?x)\<^sup>2) = (2 + 8 * (Re ?x)\<^sup>2) * 8"
       using \<open>(24 - 24 * (Re ?x)\<^sup>2) \<noteq> 0\<close> \<open>1 - (Re ?x)\<^sup>2 \<noteq> 0\<close>
       by (simp add:field_simps)
     have "?rhs * (24 - 24 * (Re ?x)\<^sup>2) = 2 * (1 - Re ?x * 5)\<^sup>2"
       using \<open>(24 - 24 * (Re ?x)\<^sup>2) \<noteq> 0\<close> \<open>1 - (Re ?x)\<^sup>2 \<noteq> 0\<close>
       by (simp add:field_simps)
     hence "(2 + 8 * (Re ?x)\<^sup>2) * 8 = 2 * (1 - Re ?x * 5)\<^sup>2"
       using * \<open>?lhs * (24 - 24 * (Re ?x)\<^sup>2) = (2 + 8 * (Re ?x)\<^sup>2) * 8\<close>
       by simp      
     hence "7 * (Re ?x)\<^sup>2 + 10 * (Re ?x) + 7 = 0"
       by (simp add:field_simps comm_ring_1_class.power2_diff)
     thus False
       using discriminant_iff[of 7 "Re (to_complex x)" 10 7] discrim_def[of 7 10 7]
       by auto
   qed
 
   ultimately show ?thesis
     apply (rule_tac x="?a" in exI)
     apply (rule_tac x="?b" in exI)
     apply (rule_tac x="?c" in exI)
     by auto
 qed
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Continuity axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 text \<open>The set $\phi$ is on the left of the set $\psi$\<close>
 abbreviation set_order where
  "set_order A \<phi> \<psi> \<equiv> \<forall>x\<in> unit_disc. \<forall>y\<in> unit_disc.  \<phi> x \<and> \<psi> y \<longrightarrow> poincare_between A x y"
 text \<open>The point $B$ is between the sets $\phi$ and $\psi$\<close>
 abbreviation point_between_sets where
  "point_between_sets \<phi> B \<psi> \<equiv> \<forall>x\<in> unit_disc. \<forall>y\<in> unit_disc.  \<phi> x \<and> \<psi> y \<longrightarrow> poincare_between x B y"
 
 lemma  continuity:
   assumes "\<exists> A \<in> unit_disc. set_order A \<phi> \<psi>"
   shows   "\<exists> B \<in> unit_disc. point_between_sets \<phi> B \<psi>"
 proof (cases "(\<exists> x0 \<in> unit_disc. \<phi> x0) \<and> (\<exists> y0 \<in> unit_disc. \<psi> y0)")
   case False
   thus ?thesis
     using assms by blast
 next
   case True
   then obtain Y0 where "\<psi> Y0" "Y0 \<in> unit_disc"
     by auto
   obtain A where *: "A \<in> unit_disc" "set_order A \<phi> \<psi>"
     using assms
     by auto
   show ?thesis
   proof(cases "\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> x = A")
     case True
     thus ?thesis
       using \<open>A \<in> unit_disc\<close>
       using poincare_between_nonstrict(1) by blast
   next
     case False
     then obtain X0 where "\<phi> X0" "X0 \<noteq> A" "X0 \<in> unit_disc"
       by auto
     have "Y0 \<noteq> A"
     proof(rule ccontr)
       assume "\<not> Y0 \<noteq> A"
       hence "\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> poincare_between A x A"
         using * \<open>\<psi> Y0\<close>
         by (cases A) force
       hence "\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> x = A"
         using * poincare_between_sandwich by blast
       thus False
         using False by auto
     qed
 
     show ?thesis
     proof (cases "\<exists> B \<in> unit_disc. \<phi> B \<and> \<psi> B")
       case True
       then obtain B where "B \<in> unit_disc" "\<phi> B" "\<psi> B"
         by auto
       hence "\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> poincare_between A x B"
         using * by auto
       have "\<forall> y \<in> unit_disc. \<psi> y \<longrightarrow> poincare_between A B y"
         using * \<open>B \<in> unit_disc\<close> \<open>\<phi> B\<close>
         by auto
 
       show ?thesis
       proof(rule+)
         show "B \<in> unit_disc"
           by fact
       next
         fix x y
         assume "x \<in> unit_disc" "y \<in> unit_disc" "\<phi> x \<and> \<psi> y"
         hence "poincare_between A x B" "poincare_between A B y"
           using \<open>\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> poincare_between A x B\<close>
           using \<open>\<forall> y \<in> unit_disc. \<psi> y \<longrightarrow> poincare_between A B y\<close>
           by simp+
         thus "poincare_between x B y"
           using \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>B \<in> unit_disc\<close> \<open>A \<in> unit_disc\<close>
           using poincare_between_transitivity[of A x B y]
           by simp
       qed
     next
       case False
       have "poincare_between A X0 Y0"
         using \<open>\<phi> X0\<close> \<open>\<psi> Y0\<close> * \<open>Y0 \<in> unit_disc\<close> \<open>X0 \<in> unit_disc\<close>
         by auto
       have "\<forall> \<phi>. \<forall> \<psi>. set_order A \<phi> \<psi> \<and> \<not> (\<exists> B \<in> unit_disc. \<phi> B \<and> \<psi> B) \<and> \<phi> X0 \<and> 
                       (\<exists> y \<in> unit_disc. \<psi> y) \<and> (\<exists> x \<in> unit_disc. \<phi> x)
                    \<longrightarrow> (\<exists> B \<in> unit_disc. point_between_sets \<phi> B \<psi>)"
             (is "?P A X0")
       proof (rule wlog_positive_x_axis[where P="?P"])
         show "A \<in> unit_disc"
           by fact
       next
         show "X0 \<in> unit_disc"
           by fact
       next
         show "A \<noteq> X0"
           using \<open>X0 \<noteq> A\<close> by simp
       next
         fix M u v
         let ?M = "\<lambda> x. moebius_pt M x"
         let ?Mu = "?M u" and ?Mv = "?M v"
         assume hip: "unit_disc_fix M" "u \<in> unit_disc" "v \<in> unit_disc" "u \<noteq> v"
                "?P ?Mu ?Mv"
         show "?P u v"
         proof safe
           fix \<phi> \<psi> x y
           assume "set_order u \<phi> \<psi>" "\<not> (\<exists>B\<in>unit_disc. \<phi> B \<and> \<psi> B)" "\<phi> v"
                   "y \<in> unit_disc" "\<psi> y" "x \<in> unit_disc" "\<phi> x"
 
           let ?M\<phi> = "\<lambda> X'. \<exists> X. \<phi> X \<and> ?M X = X'" 
           let ?M\<psi> = "\<lambda> X'. \<exists> X. \<psi> X \<and> ?M X = X'"
 
           obtain M\<phi> where "M\<phi> = ?M\<phi>" by simp
           obtain M\<psi> where "M\<psi> = ?M\<psi>" by simp
 
           have "M\<phi> ?Mv"
             using \<open>\<phi> v\<close> using \<open>M\<phi> = ?M\<phi>\<close> 
             by blast
           moreover
           have "\<not> (\<exists> B \<in>unit_disc. M\<phi> B \<and> M\<psi> B)"
             using \<open>\<not> (\<exists>B\<in>unit_disc. \<phi> B \<and> \<psi> B)\<close>
             using \<open>M\<phi> = ?M\<phi>\<close> \<open>M\<psi> = ?M\<psi>\<close>
             by (metis hip(1) moebius_pt_invert unit_disc_fix_discI unit_disc_fix_moebius_inv)
           moreover
           have "\<exists> y \<in> unit_disc. M\<psi> y"
             using \<open>y \<in> unit_disc\<close> \<open>\<psi> y\<close>  \<open>M\<psi> = ?M\<psi>\<close> \<open>unit_disc_fix M\<close>
             by auto
           moreover
           have "set_order ?Mu ?M\<phi> ?M\<psi>"
           proof ((rule ballI)+, rule impI)                                       
             fix Mx My
             assume "Mx \<in> unit_disc" "My \<in> unit_disc" "?M\<phi> Mx \<and> ?M\<psi> My"
             then obtain x y where "\<phi> x \<and> ?M x = Mx" "\<psi> y \<and> ?M y = My"
               by blast
 
             hence "x \<in> unit_disc" "y \<in> unit_disc"
               using \<open>Mx \<in> unit_disc\<close> \<open>My \<in> unit_disc\<close> \<open>unit_disc_fix M\<close>
               by (metis moebius_pt_comp_inv_left unit_disc_fix_discI unit_disc_fix_moebius_inv)+
 
             hence "poincare_between u x y"
               using \<open>set_order u \<phi> \<psi>\<close>
               using \<open>Mx \<in> unit_disc\<close> \<open>My \<in> unit_disc\<close> \<open>\<phi> x \<and> ?M x = Mx\<close> \<open>\<psi> y \<and> ?M y = My\<close>
               by blast
             then show "poincare_between ?Mu Mx My"
               using \<open>\<phi> x \<and> ?M x = Mx\<close> \<open>\<psi> y \<and> ?M y = My\<close>
               using \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>u \<in> unit_disc\<close> \<open>unit_disc_fix M\<close> 
               using unit_disc_fix_moebius_preserve_poincare_between by blast
           qed
 
           hence  "set_order ?Mu M\<phi> M\<psi>"
             using \<open>M\<phi> = ?M\<phi>\<close> \<open>M\<psi> = ?M\<psi>\<close>
             by simp
           ultimately
           have "\<exists> Mb \<in> unit_disc. point_between_sets M\<phi> Mb M\<psi>"
             using hip(5)
             by blast
           then obtain Mb where bbb: 
             "Mb \<in> unit_disc" "point_between_sets ?M\<phi> Mb ?M\<psi>"
             using \<open>M\<phi> = ?M\<phi>\<close> \<open>M\<psi> = ?M\<psi>\<close>
             by auto
 
           let ?b = "moebius_pt (moebius_inv M) Mb"
           show "\<exists> b \<in> unit_disc. point_between_sets \<phi> b \<psi>"
           proof (rule_tac x="?b" in bexI, (rule ballI)+, rule impI)
             fix x y
             assume "x \<in> unit_disc" "y \<in> unit_disc" "\<phi> x \<and> \<psi> y"
             hence "poincare_between u x y"
               using \<open>set_order u \<phi> \<psi>\<close>
               by blast
             
             let ?Mx = "?M x" and ?My = "?M y"
 
             have "?M\<phi> ?Mx" "?M\<psi> ?My"
               using \<open>\<phi> x \<and> \<psi> y\<close>
               by blast+
             have "?Mx \<in> unit_disc" "?My \<in> unit_disc"
               using \<open>x \<in> unit_disc\<close> \<open>unit_disc_fix M\<close> \<open>y \<in> unit_disc\<close>
               by auto
 
             hence "poincare_between ?Mx Mb ?My"
               using \<open>?M\<phi> ?Mx\<close> \<open>?M\<psi> ?My\<close> \<open>?Mx \<in> unit_disc\<close> \<open>?My \<in> unit_disc\<close> bbb
               by auto
 
             then show "poincare_between x ?b y"
               using \<open>unit_disc_fix M\<close> 
               using \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>Mb \<in> unit_disc\<close> \<open>?Mx \<in> unit_disc\<close> \<open>?My \<in> unit_disc\<close>
               using unit_disc_fix_moebius_preserve_poincare_between[of M x ?b y]
               by auto
           next
             show "?b \<in> unit_disc"
               using bbb \<open>unit_disc_fix M\<close>
               by auto
           qed
         qed
       next
         fix X
         assume xx: "is_real X" "0 < Re X" "Re X < 1"
         let ?X = "of_complex X"
         show "?P 0\<^sub>h ?X"
         proof ((rule allI)+, rule impI, (erule conjE)+)
           fix \<phi> \<psi>
           assume "set_order 0\<^sub>h \<phi> \<psi>" "\<not> (\<exists>B\<in>unit_disc. \<phi> B \<and> \<psi> B)" "\<phi> ?X" 
                  "\<exists>y\<in>unit_disc. \<psi> y" "\<exists>x\<in>unit_disc. \<phi> x"
           have "?X \<in> unit_disc"
             using xx
             by (simp add: cmod_eq_Re)
 
           have \<psi>pos: "\<forall> y \<in> unit_disc. \<psi> y \<longrightarrow> (is_real (to_complex y) \<and> Re (to_complex y) > 0)"
           proof(rule ballI, rule impI)
             fix y
             let ?y = "to_complex y"
             assume "y \<in> unit_disc" "\<psi> y"
 
             hence "poincare_between 0\<^sub>h ?X y"
               using \<open>set_order 0\<^sub>h \<phi> \<psi>\<close>
               using \<open>?X \<in> unit_disc\<close> \<open>\<phi> ?X\<close>
               by auto
 
             thus "is_real ?y \<and> 0 < Re ?y"
               using xx \<open>?X \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close>
               by (metis (mono_tags, hide_lams) arg_0_iff of_complex_zero_iff poincare_between_0uv poincare_between_sandwich to_complex_of_complex unit_disc_to_complex_inj zero_in_unit_disc)
           qed
 
           have \<phi>noneg: "\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> (is_real (to_complex x) \<and> Re (to_complex x) \<ge> 0)"
           proof(rule ballI, rule impI)
             fix x
             assume "x \<in> unit_disc" "\<phi> x"
 
             obtain y where "y \<in> unit_disc" "\<psi> y"
               using \<open>\<exists> y \<in> unit_disc. \<psi> y\<close> by blast
 
             let ?x = "to_complex x" and ?y = "to_complex y"
 
             have "is_real ?y" "Re ?y > 0"
               using \<psi>pos \<open>\<psi> y\<close> \<open>y \<in> unit_disc\<close>
               by auto
 
             have "poincare_between 0\<^sub>h x y"
               using \<open>set_order 0\<^sub>h \<phi> \<psi>\<close>
               using \<open>x \<in> unit_disc\<close> \<open>\<phi> x\<close> \<open>y\<in>unit_disc\<close> \<open>\<psi> y\<close>
               by auto
 
             thus "is_real ?x \<and> 0 \<le> Re ?x"
               using \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>is_real (to_complex y)\<close> \<open>\<psi> y\<close>
               using \<open>set_order 0\<^sub>h \<phi> \<psi>\<close>
               using \<open>\<phi> ?X\<close> \<open>?X \<in> unit_disc\<close> \<open>Re ?y > 0\<close>
               by (metis arg_0_iff le_less of_complex_zero poincare_between_0uv to_complex_of_complex zero_complex.simps(1) zero_complex.simps(2))
           qed
 
           have \<phi>less\<psi>: "\<forall>x\<in>unit_disc. \<forall>y\<in>unit_disc. \<phi> x \<and> \<psi> y \<longrightarrow> Re (to_complex x) < Re (to_complex y)"
           proof((rule ballI)+, rule impI)
             fix x y
             let ?x = "to_complex x" and ?y = "to_complex y"
             assume "x \<in> unit_disc" "y \<in> unit_disc" "\<phi> x \<and> \<psi> y"
 
             hence "poincare_between 0\<^sub>h x y"
               using \<open>set_order 0\<^sub>h \<phi> \<psi>\<close>
               by auto
             moreover
             have "is_real ?x" "Re ?x \<ge> 0"
               using \<phi>noneg
               using \<open>x \<in> unit_disc\<close> \<open>\<phi> x \<and> \<psi> y\<close> by auto
             moreover
             have "is_real ?y" "Re ?y > 0"
               using \<psi>pos
               using \<open>y \<in> unit_disc\<close> \<open>\<phi> x \<and> \<psi> y\<close> by auto
             ultimately
             have "Re ?x \<le> Re ?y"
               using \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close>
               by (metis Re_complex_of_real arg_0_iff le_less of_complex_zero poincare_between_0uv rcis_cmod_Arg rcis_zero_arg to_complex_of_complex)
 
             have "Re ?x \<noteq> Re ?y"
               using \<open>\<phi> x \<and> \<psi> y\<close> \<open>is_real ?x\<close> \<open>is_real ?y\<close>
               using \<open>\<not> (\<exists>B\<in>unit_disc. \<phi> B \<and> \<psi> B)\<close> \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close>
               by (metis complex.expand unit_disc_to_complex_inj)
 
             thus "Re ?x < Re ?y"
               using \<open>Re ?x \<le> Re ?y\<close> by auto
           qed
 
           have "\<exists> b \<in> unit_disc. \<forall> x \<in> unit_disc. \<forall> y \<in> unit_disc. 
                     is_real (to_complex b) \<and> 
                     (\<phi> x \<and> \<psi> y \<longrightarrow> (Re (to_complex x) \<le> Re (to_complex b) \<and> Re (to_complex b) \<le> Re (to_complex y)))"
           proof-
             let ?Phi = "{x. (of_complex (cor x)) \<in> unit_disc \<and> \<phi> (of_complex (cor x))}"
 
             have "\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> Re (to_complex x) \<le> Sup ?Phi"
             proof(safe)
               fix x
               let ?x = "to_complex x"
               assume "x \<in> unit_disc" "\<phi> x"
               hence "is_real ?x" "Re ?x \<ge> 0"
                 using \<phi>noneg
                 by auto
               hence "cor (Re ?x) = ?x"
                  using complex_of_real_Re by blast
               hence "of_complex (cor (Re ?x)) \<in> unit_disc"
                 using \<open>x \<in> unit_disc\<close> 
                 by (metis inf_notin_unit_disc of_complex_to_complex)
               moreover
               have "\<phi> (of_complex (cor (Re ?x)))"
                 using \<open>cor (Re ?x) = ?x\<close> \<open>\<phi> x\<close> \<open>x \<in> unit_disc\<close>
                 by (metis inf_notin_unit_disc of_complex_to_complex)
               ultimately
               have "Re ?x \<in> ?Phi"
                 by auto
 
               have "\<exists>M. \<forall>x \<in> ?Phi. x \<le> M"
                 using \<phi>less\<psi>
                 using \<open>\<exists> y \<in> unit_disc. \<psi> y\<close>
                 by (metis (mono_tags, lifting) Re_complex_of_real le_less mem_Collect_eq to_complex_of_complex)
 
               thus "Re ?x \<le> Sup ?Phi"
                 using cSup_upper[of "Re ?x" ?Phi]
                 unfolding bdd_above_def
                 using \<open>Re ?x \<in> ?Phi\<close>
                 by auto                
             qed
 
             have "\<forall> y \<in> unit_disc. \<psi> y \<longrightarrow> Sup ?Phi \<le> Re (to_complex y)"
             proof (safe)
               fix y
               let ?y = "to_complex y"
               assume "\<psi> y" "y \<in> unit_disc"
               show "Sup ?Phi \<le> Re ?y"
               proof (rule ccontr)
                 assume "\<not> ?thesis"
                 hence "Re ?y < Sup ?Phi"
                   by auto
 
                 have "\<exists> x. \<phi> (of_complex (cor x)) \<and> (of_complex (cor x)) \<in> unit_disc"
                 proof -
                   obtain x' where "x' \<in> unit_disc" "\<phi> x'"
                     using \<open>\<exists> x \<in> unit_disc. \<phi> x\<close> by blast
                   let ?x' = "to_complex x'"
                   have "is_real ?x'"
                     using \<open>x' \<in> unit_disc\<close> \<open>\<phi> x'\<close>
                     using \<phi>noneg
                     by auto
                   hence "cor (Re ?x') = ?x'"
                     using complex_of_real_Re by blast
                   hence "x' = of_complex (cor (Re ?x'))"
                     using \<open>x' \<in> unit_disc\<close>
                     by (metis inf_notin_unit_disc of_complex_to_complex)
                   show ?thesis
                     apply (rule_tac x="Re ?x'" in exI)
                     using \<open>x' \<in> unit_disc\<close> 
                     apply (subst (asm) \<open>x' = of_complex (cor (Re ?x'))\<close>, simp)
                     using \<open>\<phi> x'\<close>
                     by (subst (asm) (2) \<open>x' = of_complex (cor (Re ?x'))\<close>, simp)               
                 qed
 
                 hence "?Phi \<noteq> {}"
                   by auto
 
                 then obtain x where "\<phi> (of_complex (cor x))" "Re ?y < x"
                                     "(of_complex (cor x)) \<in> unit_disc"
                   using \<open>Re ?y < Sup ?Phi\<close>
                   using less_cSupE[of "Re ?y" ?Phi]
                   by auto
                 moreover
                 have "Re ?y < Re (to_complex (of_complex (cor x)))"
                   using \<open>Re ?y < x\<close> 
                   by simp
                 ultimately
                 show False
                   using \<phi>less\<psi>
                   using \<open>\<psi> y\<close> \<open>y \<in> unit_disc\<close>
                   by (metis less_not_sym)
               qed
             qed
 
             thus ?thesis
               using \<open>\<forall> x \<in> unit_disc. \<phi> x \<longrightarrow> Re (to_complex x) \<le> Sup ?Phi\<close>
               apply (rule_tac x="(of_complex (cor (Sup ?Phi)))" in bexI, simp)
               using \<open>\<exists>y\<in>unit_disc. \<psi> y\<close> \<open>\<phi> ?X\<close> \<open>?X \<in> unit_disc\<close>
               using \<open>\<forall>y\<in>unit_disc. \<psi> y \<longrightarrow> is_real (to_complex y) \<and> 0 < Re (to_complex y)\<close>
               by (smt complex_of_real_Re inf_notin_unit_disc norm_of_real of_complex_to_complex to_complex_of_complex unit_disc_iff_cmod_lt_1 xx(2))
           qed
 
           then obtain B where "B \<in> unit_disc" "is_real (to_complex B)"
             "\<forall>x\<in>unit_disc. \<forall>y\<in>unit_disc. \<phi> x \<and> \<psi> y \<longrightarrow> Re (to_complex x) \<le> Re (to_complex B) \<and>
              Re (to_complex B) \<le> Re (to_complex y)"
             by blast
 
           show "\<exists> b \<in> unit_disc. point_between_sets \<phi> b \<psi>"
           proof (rule_tac x="B" in bexI)
             show "B \<in> unit_disc"
               by fact
           next
             show "point_between_sets \<phi> B \<psi>"
             proof ((rule ballI)+, rule impI)
               fix x y 
               let ?x = "to_complex x" and ?y = "to_complex y" and ?B = "to_complex B"
               assume "x \<in> unit_disc" "y \<in> unit_disc" "\<phi> x \<and> \<psi> y"
 
               hence "Re ?x \<le> Re ?B \<and> Re ?B \<le> Re ?y"
                 using \<open>\<forall>x\<in>unit_disc. \<forall>y\<in>unit_disc. \<phi> x \<and> \<psi> y \<longrightarrow> Re (to_complex x) \<le> Re ?B \<and>
                        Re (to_complex B) \<le> Re (to_complex y)\<close>
                 by auto
               moreover
               have "is_real ?x" "Re ?x \<ge> 0"
                 using \<phi>noneg
                 using \<open>x \<in> unit_disc\<close> \<open>\<phi> x \<and> \<psi> y\<close>
                 by auto
               moreover
               have "is_real ?y" "Re ?y > 0"
                 using \<psi>pos
                 using \<open>y \<in> unit_disc\<close> \<open>\<phi> x \<and> \<psi> y\<close>
                 by auto
               moreover
               have "cor (Re ?x) = ?x"
                 using complex_of_real_Re \<open>is_real ?x\<close> by blast
               hence "x = of_complex (cor (Re ?x))"
                 using \<open>x \<in> unit_disc\<close>
                 by (metis inf_notin_unit_disc of_complex_to_complex)
               moreover
               have "cor (Re ?y) = ?y"
                 using complex_of_real_Re \<open>is_real ?y\<close> by blast
               hence "y = of_complex (cor (Re ?y))"
                 using \<open>y \<in> unit_disc\<close>
                 by (metis inf_notin_unit_disc of_complex_to_complex)
               moreover
               have "cor (Re ?B) = ?B"
                 using complex_of_real_Re \<open>is_real (to_complex  B)\<close> by blast
               hence "B = of_complex (cor (Re ?B))"
                 using \<open>B \<in> unit_disc\<close>
                 by (metis inf_notin_unit_disc of_complex_to_complex)
               ultimately
               show "poincare_between x B y"
                 using \<open>is_real (to_complex B)\<close> \<open>x \<in> unit_disc\<close> \<open>y \<in> unit_disc\<close> \<open>B \<in> unit_disc\<close>
                 using poincare_between_x_axis_uvw[of "Re (to_complex x)" "Re (to_complex B)" "Re (to_complex y)"]
                 by (smt Re_complex_of_real arg_0_iff poincare_between_nonstrict(1) rcis_cmod_Arg rcis_zero_arg unit_disc_iff_cmod_lt_1)
             qed
           qed            
         qed
       qed 
       thus ?thesis
         using False \<open>\<phi> X0\<close> \<open>\<psi> Y0\<close> * \<open>Y0 \<in> unit_disc\<close> \<open>X0 \<in> unit_disc\<close>
         by auto
     qed      
   qed
 qed
 
 
 (* ------------------------------------------------------------------ *)
 subsection\<open>Limiting parallels axiom\<close>
 (* ------------------------------------------------------------------ *)
 
 text \<open>Auxiliary definitions\<close>
 
 definition poincare_on_line where
   "poincare_on_line p a b \<longleftrightarrow> poincare_collinear {p, a, b}"
 
 definition poincare_on_ray where 
   "poincare_on_ray p a b \<longleftrightarrow> poincare_between a p b \<or> poincare_between a b p"
 
 definition poincare_in_angle where
   "poincare_in_angle p a b c \<longleftrightarrow>
       b \<noteq> a \<and> b \<noteq> c \<and> p \<noteq> b \<and> (\<exists> x \<in> unit_disc. poincare_between a x c \<and> x \<noteq> a \<and> x \<noteq> c \<and> poincare_on_ray p b x)"
 
 definition poincare_ray_meets_line where
   "poincare_ray_meets_line a b c d \<longleftrightarrow> (\<exists> x \<in> unit_disc. poincare_on_ray x a b \<and> poincare_on_line x c d)"
 
 text \<open>All points on ray are collinear\<close>
 lemma poincare_on_ray_poincare_collinear:
   assumes "p \<in> unit_disc" and "a \<in> unit_disc" and "b \<in> unit_disc" and "poincare_on_ray p a b"
   shows "poincare_collinear {p, a, b}"
   using assms poincare_between_poincare_collinear
   unfolding poincare_on_ray_def
   by (metis insert_commute)
 
 text \<open>H-isometries preserve all defined auxiliary relations\<close>
 
 lemma unit_disc_fix_preserves_poincare_on_line [simp]:
   assumes "unit_disc_fix M" and "p \<in> unit_disc" "a \<in> unit_disc" "b \<in> unit_disc"
   shows "poincare_on_line (moebius_pt M p) (moebius_pt M a) (moebius_pt M b) \<longleftrightarrow> poincare_on_line p a b"
   using assms
   unfolding poincare_on_line_def
   by auto
 
 lemma unit_disc_fix_preserves_poincare_on_ray [simp]:
   assumes "unit_disc_fix M" "p \<in> unit_disc" "a \<in> unit_disc" "b \<in> unit_disc"
   shows "poincare_on_ray (moebius_pt M p) (moebius_pt M a) (moebius_pt M b) \<longleftrightarrow> poincare_on_ray p a b"
   using assms
   unfolding poincare_on_ray_def
   by auto
 
 lemma unit_disc_fix_preserves_poincare_in_angle [simp]:
   assumes "unit_disc_fix M" "p \<in> unit_disc" "a \<in> unit_disc" "b \<in> unit_disc" "c \<in> unit_disc"
   shows "poincare_in_angle (moebius_pt M p) (moebius_pt M a) (moebius_pt M b) (moebius_pt M c) \<longleftrightarrow> poincare_in_angle p a b c" (is "?lhs \<longleftrightarrow> ?rhs")
 proof
   assume "?lhs"
   then obtain Mx where *: "Mx \<in> unit_disc"
       "poincare_between (moebius_pt M a) Mx (moebius_pt M c)"
       "Mx \<noteq> moebius_pt M a" "Mx \<noteq> moebius_pt M c"  "poincare_on_ray (moebius_pt M p) (moebius_pt M b) Mx"
       "moebius_pt M b \<noteq> moebius_pt M a" "moebius_pt M b \<noteq> moebius_pt M c" "moebius_pt M p \<noteq> moebius_pt M b"
     unfolding poincare_in_angle_def
     by auto
   obtain x where "Mx = moebius_pt M x" "x \<in> unit_disc"
     by (metis "*"(1) assms(1) image_iff unit_disc_fix_iff)
   thus ?rhs
     using * assms
     unfolding poincare_in_angle_def
     by auto
 next
   assume ?rhs
   then obtain x where *: "x \<in> unit_disc"
       "poincare_between a x c"
       "x \<noteq> a" "x \<noteq> c"  "poincare_on_ray p b x"
       "b \<noteq> a" "b \<noteq> c" "p \<noteq> b"
     unfolding poincare_in_angle_def
     by auto
   thus ?lhs
     using assms
     unfolding poincare_in_angle_def
     by auto (rule_tac x="moebius_pt M x" in bexI, auto)
 qed
 
 lemma unit_disc_fix_preserves_poincare_ray_meets_line [simp]:
   assumes "unit_disc_fix M" "a \<in> unit_disc" "b \<in> unit_disc" "c \<in> unit_disc" "d \<in> unit_disc"
   shows "poincare_ray_meets_line (moebius_pt M a) (moebius_pt M b) (moebius_pt M c) (moebius_pt M d) \<longleftrightarrow> poincare_ray_meets_line a b c d" (is "?lhs \<longleftrightarrow> ?rhs")
 proof
   assume ?lhs
   then obtain Mx where *: "Mx \<in> unit_disc" "poincare_on_ray Mx (moebius_pt M a) (moebius_pt M b)" 
     "poincare_on_line Mx (moebius_pt M c) (moebius_pt M d)"
     unfolding poincare_ray_meets_line_def
     by auto
   obtain x where "Mx = moebius_pt M x" "x \<in> unit_disc"
     by (metis "*"(1) assms(1) image_iff unit_disc_fix_iff)
   thus ?rhs
     using assms *
     unfolding poincare_ray_meets_line_def poincare_on_line_def
     by auto
 next
   assume ?rhs
   then obtain x where *: "x \<in> unit_disc" "poincare_on_ray x a b" 
     "poincare_on_line x c d"
     unfolding poincare_ray_meets_line_def
     by auto
   thus ?lhs
     using assms *
     unfolding poincare_ray_meets_line_def poincare_on_line_def
     by auto (rule_tac x="moebius_pt M x" in bexI, auto)
 qed
 
 text \<open>H-lines that intersect on the absolute do not meet (they do not share a common h-point)\<close>
 lemma tangent_not_meet:
   assumes "x1 \<in> unit_disc" and "x2 \<in> unit_disc" and "x1 \<noteq> x2" and "\<not> poincare_collinear {0\<^sub>h, x1, x2}"
   assumes "i \<in> ideal_points (poincare_line x1 x2)" "a \<in> unit_disc" "a \<noteq> 0\<^sub>h" "poincare_collinear {0\<^sub>h, a, i}"
   shows "\<not> poincare_ray_meets_line 0\<^sub>h a x1 x2"
 proof (rule ccontr)
   assume "\<not> ?thesis"
   then obtain x where "x \<in> unit_disc" "poincare_on_ray x 0\<^sub>h a" "poincare_collinear {x, x1, x2}"
     unfolding poincare_ray_meets_line_def poincare_on_line_def
     by auto
 
   have "poincare_collinear {0\<^sub>h, a, x}"
     using \<open>poincare_on_ray x 0\<^sub>h a\<close> \<open>x \<in> unit_disc\<close> \<open>a \<in> unit_disc\<close>
     by (meson poincare_between_poincare_collinear poincare_between_rev poincare_on_ray_def poincare_on_ray_poincare_collinear zero_in_unit_disc)
 
   have "x \<noteq> 0\<^sub>h"
     using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close> \<open>poincare_collinear {x, x1, x2}\<close>
     unfolding poincare_collinear_def
     by (auto simp add: assms(2) assms(3) poincare_between_rev)
 
   let ?l1 = "poincare_line 0\<^sub>h a"
   let ?l2 = "poincare_line x1 x2"
 
   have "i \<in> circline_set unit_circle"
     using \<open>i \<in> ideal_points (poincare_line x1 x2)\<close>
     using assms(3) ideal_points_on_unit_circle is_poincare_line_poincare_line by blast
 
   have "i \<in> circline_set ?l1"
     using \<open>poincare_collinear {0\<^sub>h, a, i}\<close>
     unfolding poincare_collinear_def
     using \<open>a \<in> unit_disc\<close> \<open>a \<noteq> 0\<^sub>h\<close>
     by (metis insert_subset unique_poincare_line zero_in_unit_disc)
 
   moreover
 
   have "x \<in> circline_set ?l1"
     using \<open>a \<in> unit_disc\<close> \<open>a \<noteq> 0\<^sub>h\<close> \<open>poincare_collinear {0\<^sub>h, a, x}\<close> \<open>x \<in> unit_disc\<close>
     by (metis poincare_collinear3_between poincare_between_poincare_line_uvz poincare_between_poincare_line_uzv poincare_line_sym zero_in_unit_disc)
 
   moreover
 
   have "inversion x \<in> circline_set ?l1"
     using \<open>poincare_collinear {0\<^sub>h, a, x}\<close>
     using poincare_line_inversion_full[of "0\<^sub>h" a x] \<open>a \<in> unit_disc\<close> \<open>a \<noteq> 0\<^sub>h\<close> \<open>x \<in> unit_disc\<close>
     by (metis poincare_collinear3_between is_poincare_line_inverse_point is_poincare_line_poincare_line poincare_between_poincare_line_uvz poincare_between_poincare_line_uzv poincare_line_sym zero_in_unit_disc)
 
   moreover
 
   have "x \<in> circline_set ?l2"
     using \<open>poincare_collinear {x, x1, x2}\<close> \<open>x1 \<noteq> x2\<close> \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> \<open>x \<in> unit_disc\<close>
     by (metis insert_commute inversion_noteq_unit_disc poincare_between_poincare_line_uvz poincare_between_poincare_line_uzv poincare_collinear3_iff poincare_line_sym_general)
 
   moreover
 
   hence "inversion x \<in> circline_set ?l2"
     using  \<open>x1 \<noteq> x2\<close> \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> \<open>x \<in> unit_disc\<close>
     using poincare_line_inversion_full[of x1 x2 x]
     unfolding circline_set_def
     by auto
 
   moreover
 
   have "i \<in> circline_set ?l2"
     using \<open>x1 \<noteq> x2\<close> \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close>
     using \<open>i \<in> ideal_points ?l2\<close>
     by (simp add: ideal_points_on_circline)
 
   moreover
 
   have "x \<noteq> inversion x"
     using \<open>x \<in> unit_disc\<close>
     using inversion_noteq_unit_disc by fastforce
 
   moreover
 
   have "x \<noteq> i"
     using \<open>x \<in> unit_disc\<close>
     using \<open>i \<in> circline_set unit_circle\<close> circline_set_def inversion_noteq_unit_disc 
     by fastforce+
 
   moreover
 
   have "inversion x \<noteq> i"
     using \<open>i \<in> circline_set unit_circle\<close> \<open>x \<noteq> i\<close> circline_set_def inversion_unit_circle 
     by fastforce
 
   ultimately
           
   have "?l1 = ?l2"
     using unique_circline_set[of x "inversion x" i]
     by blast
 
   hence "0\<^sub>h \<in> circline_set ?l2"
     by (metis \<open>a \<noteq> 0\<^sub>h\<close> poincare_line_circline_set(1))
 
   thus False
     using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close>
     unfolding poincare_collinear_def
     using \<open>poincare_collinear {x, x1, x2}\<close> \<open>x1 \<noteq> x2\<close> \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> poincare_collinear_def unique_poincare_line
     by auto
 qed 
 
 lemma limiting_parallels:
   assumes "a \<in> unit_disc" and "x1 \<in> unit_disc" and "x2 \<in> unit_disc" and "\<not> poincare_on_line a x1 x2"
   shows "\<exists>a1\<in>unit_disc. \<exists>a2\<in>unit_disc.
           \<not> poincare_on_line a a1 a2 \<and>
           \<not> poincare_ray_meets_line a a1 x1 x2 \<and> \<not> poincare_ray_meets_line a a2 x1 x2 \<and>
           (\<forall>a'\<in>unit_disc. poincare_in_angle a' a1 a a2 \<longrightarrow> poincare_ray_meets_line a a' x1 x2)" (is "?P a x1 x2")
 proof-
   have "\<not> poincare_collinear {a, x1, x2}"
     using \<open>\<not> poincare_on_line a x1 x2\<close>
     unfolding poincare_on_line_def
     by simp
 
   have "\<forall> x1 x2. x1 \<in> unit_disc \<and> x2 \<in> unit_disc \<and> \<not> poincare_collinear {a, x1, x2} \<longrightarrow> ?P a x1 x2" (is "?Q a")
   proof (rule wlog_zero[OF \<open>a \<in> unit_disc\<close>])
     fix a u
     assume *: "u \<in> unit_disc" "cmod a < 1"
     hence uf: "unit_disc_fix (blaschke a)"
       by simp
     assume **: "?Q (moebius_pt (blaschke a) u)"
     show "?Q u"
     proof safe
       fix x1 x2
       let ?M = "moebius_pt (blaschke a)"
       assume xx: "x1 \<in> unit_disc" "x2 \<in> unit_disc" "\<not> poincare_collinear {u, x1, x2}"
       hence MM: "?M x1 \<in> unit_disc \<and> ?M x2\<in> unit_disc \<and> \<not> poincare_collinear {?M u, ?M x1, ?M x2}"   
         using *
         by auto
       show "?P u x1 x2" (is "\<exists>a1\<in>unit_disc. \<exists>a2\<in>unit_disc. ?P' a1 a2 u x1 x2")
       proof-
         obtain Ma1 Ma2 where MM: "Ma1 \<in> unit_disc" "Ma2 \<in> unit_disc" "?P' Ma1 Ma2 (?M u) (?M x1) (?M x2)"   
           using **[rule_format, OF MM]
           by blast
         hence MM': "\<forall>a'\<in>unit_disc. poincare_in_angle a' Ma1 (?M u) Ma2 \<longrightarrow> poincare_ray_meets_line (?M u) a' (?M x1) (?M x2)"
           by auto
         obtain a1 a2 where a: "a1 \<in> unit_disc" "a2 \<in> unit_disc" "?M a1 = Ma1" "?M a2 = Ma2"
           using uf
           by (metis \<open>Ma1 \<in> unit_disc\<close> \<open>Ma2 \<in> unit_disc\<close> image_iff unit_disc_fix_iff)
 
         have "\<forall>a'\<in>unit_disc. poincare_in_angle a' a1 u a2 \<longrightarrow> poincare_ray_meets_line u a' x1 x2"
         proof safe
           fix a'
           assume "a' \<in> unit_disc" "poincare_in_angle a' a1 u a2"
           thus "poincare_ray_meets_line u a' x1 x2"
             using MM(1-2) MM'[rule_format, of "?M a'"] * uf a xx
             by (meson unit_disc_fix_discI unit_disc_fix_preserves_poincare_in_angle unit_disc_fix_preserves_poincare_ray_meets_line)
         qed
 
         hence "?P' a1 a2 u x1 x2"
           using MM * uf xx a
           by auto
           
         thus ?thesis
           using \<open>a1 \<in> unit_disc\<close> \<open>a2 \<in> unit_disc\<close>
           by blast
       qed
     qed
   next
     show "?Q 0\<^sub>h"
     proof safe
       fix x1 x2
       assume "x1 \<in> unit_disc" "x2 \<in> unit_disc"
       assume "\<not> poincare_collinear {0\<^sub>h, x1, x2}"
       show "?P 0\<^sub>h x1 x2"
       proof-
         let ?lx = "poincare_line x1 x2"
 
         have "x1 \<noteq> x2"
           using \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close>\<open>\<not> poincare_collinear  {0\<^sub>h, x1, x2}\<close>
           using poincare_collinear3_between                  
           by auto
 
         have lx: "is_poincare_line ?lx"
           using is_poincare_line_poincare_line[OF \<open>x1 \<noteq> x2\<close>]
           by simp
 
         obtain i1 i2 where "ideal_points ?lx = {i1, i2}"
           by (meson \<open>x1 \<noteq> x2\<close> is_poincare_line_poincare_line obtain_ideal_points)
       
         let ?li = "poincare_line i1 i2"
         let ?i1 = "to_complex i1"
         let ?i2 = "to_complex i2"
 
         have "i1 \<in> unit_circle_set" "i2 \<in> unit_circle_set"
           using lx \<open>ideal_points ?lx = {i1, i2}\<close>
           unfolding unit_circle_set_def
           by (metis ideal_points_on_unit_circle insertI1, metis ideal_points_on_unit_circle insertI1 insertI2)
                                                                
         have "i1 \<noteq> i2"
           using \<open>ideal_points ?lx = {i1, i2}\<close> \<open>x1 \<in> unit_disc\<close> \<open>x1 \<noteq> x2\<close> \<open>x2 \<in> unit_disc\<close> ideal_points_different(1) 
           by blast
 
         let ?a1 = "of_complex (?i1 / 2)"
         let ?a2 = "of_complex (?i2 / 2)"
         let ?la = "poincare_line ?a1 ?a2"
 
         have "?a1 \<in> unit_disc" "?a2 \<in> unit_disc"
           using \<open>i1 \<in> unit_circle_set\<close> \<open>i2 \<in> unit_circle_set\<close>
           unfolding unit_circle_set_def unit_disc_def disc_def circline_set_def
           by auto (transfer, transfer, case_tac i1, case_tac i2, simp add: vec_cnj_def)+
 
         have "?a1 \<noteq> 0\<^sub>h" "?a2 \<noteq> 0\<^sub>h" 
           using \<open>i1 \<in> unit_circle_set\<close> \<open>i2 \<in> unit_circle_set\<close>
           unfolding unit_circle_set_def
           by auto
 
         have "?a1 \<noteq> ?a2"
           using \<open>i1 \<noteq> i2\<close>
           by (metis \<open>i1 \<in> unit_circle_set\<close> \<open>i2 \<in> unit_circle_set\<close> circline_set_def divide_cancel_right inversion_infty inversion_unit_circle mem_Collect_eq of_complex_to_complex of_complex_zero to_complex_of_complex unit_circle_set_def zero_neq_numeral)
 
         have "poincare_collinear {0\<^sub>h, ?a1, i1}"
           unfolding poincare_collinear_def
           using \<open>?a1 \<noteq> 0\<^sub>h\<close>[symmetric] is_poincare_line_poincare_line[of "0\<^sub>h" ?a1]
           unfolding circline_set_def
           apply (rule_tac x="poincare_line 0\<^sub>h ?a1" in exI, auto)
           apply (transfer, transfer, auto simp add: vec_cnj_def)
           done                                                               
 
         have "poincare_collinear {0\<^sub>h, ?a2, i2}"
           unfolding poincare_collinear_def
           using \<open>?a2 \<noteq> 0\<^sub>h\<close>[symmetric] is_poincare_line_poincare_line[of "0\<^sub>h" ?a2]
           unfolding circline_set_def
           apply (rule_tac x="poincare_line 0\<^sub>h ?a2" in exI, auto)
           apply (transfer, transfer, auto simp add: vec_cnj_def)
           done                                                               
 
         have "\<not> poincare_ray_meets_line 0\<^sub>h ?a1 x1 x2"
           using tangent_not_meet[of x1 x2 i1 ?a1]
           using \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> \<open>?a1 \<in> unit_disc\<close> \<open>x1 \<noteq> x2\<close> \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close>
           using \<open>ideal_points ?lx = {i1, i2}\<close> \<open>?a1 \<noteq> 0\<^sub>h\<close> \<open>poincare_collinear {0\<^sub>h, ?a1, i1}\<close>
           by simp
 
         moreover
 
         have "\<not> poincare_ray_meets_line 0\<^sub>h ?a2 x1 x2"
           using tangent_not_meet[of x1 x2 i2 ?a2]
           using \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close> \<open>x1 \<noteq> x2\<close> \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close>
           using \<open>ideal_points ?lx = {i1, i2}\<close> \<open>?a2 \<noteq> 0\<^sub>h\<close> \<open>poincare_collinear {0\<^sub>h, ?a2, i2}\<close>
           by simp
 
         moreover
 
         have "\<forall>a' \<in> unit_disc. poincare_in_angle a' ?a1 0\<^sub>h ?a2 \<longrightarrow> poincare_ray_meets_line 0\<^sub>h a' x1 x2"
           unfolding poincare_in_angle_def
         proof safe
           fix a' a
           assume *: "a' \<in> unit_disc" "a \<in> unit_disc" "poincare_on_ray a' 0\<^sub>h a" "a' \<noteq> 0\<^sub>h"
                     "poincare_between ?a1 a ?a2" "a \<noteq> ?a1" "a \<noteq> ?a2"
           show "poincare_ray_meets_line 0\<^sub>h a' x1 x2"
           proof-
             have "\<forall> a' a1 a2 x1 x2 i1 i2.
                   a' \<in> unit_disc \<and> x1 \<in> unit_disc \<and> x2 \<in> unit_disc \<and> x1 \<noteq> x2 \<and>
                   \<not> poincare_collinear {0\<^sub>h, x1, x2} \<and> ideal_points (poincare_line x1 x2) = {i1, i2} \<and>
                   a1 = of_complex (to_complex i1 / 2) \<and> a2 = of_complex (to_complex i2 / 2) \<and>
                   i1 \<noteq> i2 \<and> a1 \<noteq> a2 \<and> poincare_collinear {0\<^sub>h, a1, i1} \<and> poincare_collinear {0\<^sub>h, a2, i2} \<and>
                   a1 \<in> unit_disc \<and> a2 \<in> unit_disc \<and> i1 \<in> unit_circle_set \<and> i2 \<in> unit_circle_set \<and>
                   poincare_on_ray a' 0\<^sub>h a \<and> a' \<noteq> 0\<^sub>h \<and> poincare_between a1 a a2 \<and> a \<noteq> a1 \<and> a \<noteq> a2 \<longrightarrow>
                   poincare_ray_meets_line 0\<^sub>h a' x1 x2" (is "\<forall> a' a1 a2 x1 x2 i1 i2. ?R 0\<^sub>h a' a1 a2 x1 x2 i1 i2 a")
             proof (rule wlog_rotation_to_positive_x_axis[OF \<open>a \<in> unit_disc\<close>])
               let ?R' = "\<lambda> a zero. \<forall> a' a1 a2 x1 x2 i1 i2. ?R zero a' a1 a2 x1 x2 i1 i2 a"
               fix xa
               assume xa: "is_real xa" "0 < Re xa" "Re xa < 1"
               let ?a = "of_complex xa"
               show "?R' ?a 0\<^sub>h"
               proof safe
                 fix a' a1 a2 x1 x2 i1 i2
                 let ?i1 = "to_complex i1" and ?i2 = "to_complex i2"
                 let ?a1 = "of_complex (?i1 / 2)" and ?a2 = "of_complex (?i2 / 2)"
                 let ?la = "poincare_line ?a1 ?a2" and ?lx = "poincare_line x1 x2" and ?li = "poincare_line i1 i2"
                 assume "a' \<in> unit_disc" "x1 \<in> unit_disc" "x2 \<in> unit_disc" "x1 \<noteq> x2"
                 assume "\<not> poincare_collinear {0\<^sub>h, x1, x2}" "ideal_points ?lx = {i1, i2}"
                 assume "poincare_on_ray a' 0\<^sub>h ?a" "a' \<noteq> 0\<^sub>h"
                 assume "poincare_between ?a1 ?a ?a2"  "?a \<noteq> ?a1" "?a \<noteq> ?a2"
                 assume "i1 \<noteq> i2" "?a1 \<noteq> ?a2" "poincare_collinear {0\<^sub>h, ?a1, i1}"  "poincare_collinear {0\<^sub>h, ?a2, i2}"
                 assume "?a1 \<in> unit_disc"  "?a2 \<in> unit_disc"
                 assume "i1 \<in> unit_circle_set" "i2 \<in> unit_circle_set"
                 show "poincare_ray_meets_line 0\<^sub>h a' x1 x2"
                 proof-   
                   have "?lx = ?li"
                     using \<open>ideal_points ?lx = {i1, i2}\<close> \<open>x1 \<noteq> x2\<close> ideal_points_line_unique
                     by auto
 
                   have lx: "is_poincare_line ?lx"
                     using is_poincare_line_poincare_line[OF \<open>x1 \<noteq> x2\<close>]
                     by simp
 
                   have "x1 \<in> circline_set ?lx" "x2 \<in> circline_set ?lx"
                     using lx \<open>x1 \<noteq> x2\<close>
                     by auto
 
                   have "?lx \<noteq> x_axis"
                     using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close> \<open>x1 \<in> circline_set ?lx\<close> \<open>x2 \<in> circline_set ?lx\<close> lx
                     unfolding poincare_collinear_def 
                     by auto
 
                   have "0\<^sub>h \<notin> circline_set ?lx"
                     using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close> lx \<open>x1 \<in> circline_set ?lx\<close> \<open>x2 \<in> circline_set ?lx\<close>
                     unfolding poincare_collinear_def
                     by auto
 
                   have "xa \<noteq> 0" "?a \<noteq> 0\<^sub>h" 
                     using xa
                     by auto
                   hence "0\<^sub>h \<noteq> ?a"
                     by metis
 
                   have "?a \<in> positive_x_axis"
                     using xa
                     unfolding positive_x_axis_def 
                     by simp
 
                   have "?a \<in> unit_disc"
                     using xa
                     by (auto simp add: cmod_eq_Re)
 
                   have "?a \<in> circline_set ?la"
                     using \<open>poincare_between ?a1 ?a ?a2\<close>
                     using \<open>?a1 \<noteq> ?a2\<close> \<open>?a \<in> unit_disc\<close> \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close> poincare_between_poincare_line_uzv 
                     by blast
                                                 
                   have "?a1 \<in> circline_set ?la" "?a2 \<in> circline_set ?la"
                     by (auto simp add: \<open>?a1 \<noteq> ?a2\<close>)
 
                   have la: "is_poincare_line ?la"
                     using is_poincare_line_poincare_line[OF \<open>?a1 \<noteq> ?a2\<close>]
                     by  simp
 
                   have inv: "inversion i1 = i1" "inversion i2 = i2"
                     using \<open>i1 \<in> unit_circle_set\<close> \<open>i2 \<in> unit_circle_set\<close>
                     by (auto simp add: circline_set_def unit_circle_set_def)
 
                   have  "i1 \<noteq> \<infinity>\<^sub>h" "i2 \<noteq> \<infinity>\<^sub>h"
                     using inv
                     by auto
 
                   have "?a1 \<notin> circline_set x_axis \<and> ?a2 \<notin> circline_set x_axis"
                   proof (rule ccontr)
                     assume "\<not> ?thesis"
                     hence "?a1 \<in> circline_set x_axis \<or> ?a2 \<in> circline_set x_axis"
                       by auto
                     hence "?la = x_axis"
                     proof
                       assume "?a1 \<in> circline_set x_axis"
                       hence "{?a, ?a1} \<subseteq> circline_set ?la \<inter> circline_set x_axis"
                         using \<open>?a \<in> circline_set ?la\<close> \<open>?a1 \<in> circline_set ?la\<close>\<open>?a \<in> positive_x_axis\<close>
                         using circline_set_x_axis_I xa(1) 
                         by blast
                       thus "?la = x_axis"
                         using unique_is_poincare_line[of ?a ?a1 ?la x_axis]
                         using \<open>?a1 \<in> unit_disc\<close> \<open>?a \<in> unit_disc\<close> la \<open>?a \<noteq> ?a1\<close>
                         by auto
                     next
                       assume "?a2 \<in> circline_set x_axis"
                       hence "{?a, ?a2} \<subseteq> circline_set ?la \<inter> circline_set x_axis"
                         using \<open>?a \<in> circline_set ?la\<close> \<open>?a2 \<in> circline_set ?la\<close> \<open>?a \<in> positive_x_axis\<close>
                         using circline_set_x_axis_I xa(1) 
                         by blast
                       thus "?la = x_axis"
                         using unique_is_poincare_line[of ?a ?a2 ?la x_axis]
                         using \<open>?a2 \<in> unit_disc\<close> \<open>?a \<in> unit_disc\<close> la \<open>?a \<noteq> ?a2\<close>
                         by auto
                     qed
 
                     hence "i1 \<in> circline_set x_axis \<and> i2 \<in> circline_set x_axis"
                       using \<open>?a1 \<in> circline_set ?la\<close> \<open>?a2 \<in> circline_set ?la\<close>
                       by (metis \<open>i1 \<noteq> \<infinity>\<^sub>h\<close> \<open>i2 \<noteq> \<infinity>\<^sub>h\<close> \<open>of_complex (to_complex i1 / 2) \<in> unit_disc\<close> \<open>of_complex (to_complex i2 / 2) \<in> unit_disc\<close> \<open>poincare_collinear {0\<^sub>h, of_complex (to_complex i1 / 2), i1}\<close> \<open>poincare_collinear {0\<^sub>h, of_complex (to_complex i2 / 2), i2}\<close> divide_eq_0_iff inf_not_of_complex inv(1) inv(2) inversion_noteq_unit_disc of_complex_to_complex of_complex_zero_iff poincare_collinear3_poincare_lines_equal_general poincare_line_0_real_is_x_axis poincare_line_circline_set(2) zero_in_unit_disc zero_neq_numeral)
 
                     thus False
                       using \<open>?lx \<noteq> x_axis\<close> unique_is_poincare_line_general[of i1 i2 ?li x_axis] \<open>i1 \<noteq> i2\<close> inv \<open>?lx = ?li\<close>
                       by auto
                   qed
 
                   hence "?la \<noteq> x_axis"
                     using \<open>?a1 \<noteq> ?a2\<close> poincare_line_circline_set(1)      
                     by fastforce
 
                   have "intersects_x_axis_positive ?la"
                     using intersects_x_axis_positive_iff[of ?la] \<open>?la \<noteq> x_axis\<close> \<open>?a \<in> circline_set ?la\<close> la
                     using \<open>?a \<in> unit_disc\<close> \<open>?a \<in> positive_x_axis\<close>
                     by auto
 
                   have "intersects_x_axis ?lx"
                   proof-
-                    have "arg (to_complex ?a1) * arg (to_complex ?a2) < 0"
+                    have "Arg (to_complex ?a1) * Arg (to_complex ?a2) < 0"
                       using \<open>poincare_between ?a1 ?a ?a2\<close> \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close>
                       using poincare_between_x_axis_intersection[of ?a1 ?a2 "of_complex xa"]
                       using \<open>?a1 \<noteq> ?a2\<close> \<open>?a \<in> unit_disc\<close> \<open>?a1 \<notin> circline_set x_axis \<and> ?a2 \<notin> circline_set x_axis\<close> \<open>?a \<in> positive_x_axis\<close>
                       using \<open>?a \<in> circline_set ?la\<close>                                                                                         
                       unfolding positive_x_axis_def
                       by simp
 
                     moreover
 
                     have "\<And> x y x' y' :: real. \<lbrakk>sgn x' = sgn x; sgn y' = sgn y\<rbrakk> \<Longrightarrow> x*y < 0 \<longleftrightarrow> x'*y' < 0"
                       by (metis sgn_less sgn_mult)
 
                     ultimately
 
                     have "Im (to_complex ?a1) * Im (to_complex ?a2) < 0"
                       using arg_Im_sgn[of "to_complex ?a1"] arg_Im_sgn[of "to_complex ?a2"]
                       using \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close> \<open>?a1 \<notin> circline_set x_axis \<and> ?a2 \<notin> circline_set x_axis\<close> 
                       using inf_or_of_complex[of ?a1] inf_or_of_complex[of ?a2] circline_set_x_axis
                       by (metis circline_set_x_axis_I to_complex_of_complex)
 
                     thus ?thesis
                       using ideal_points_intersects_x_axis[of ?lx i1 i2]
                       using \<open>ideal_points ?lx = {i1, i2}\<close> lx \<open>?lx \<noteq> x_axis\<close>
                       by simp
                   qed
 
                   have "intersects_x_axis_positive ?lx"
                   proof-
                     have "cmod ?i1 = 1" "cmod ?i2 = 1"                
                       using \<open>i1 \<in> unit_circle_set\<close> \<open>i2 \<in> unit_circle_set\<close> 
                       unfolding unit_circle_set_def 
                       by auto
 
                     let ?a1' = "?i1 / 2" and ?a2' = "?i2 / 2"
                     let ?Aa1 = "\<i> * (?a1' * cnj ?a2' - ?a2' * cnj ?a1')" and 
                         ?Ba1 = "\<i> * (?a2' * cor ((cmod ?a1')\<^sup>2 + 1) - ?a1' * cor ((cmod ?a2')\<^sup>2 + 1))"
 
                     have "?Aa1 \<noteq> 0 \<or> ?Ba1 \<noteq> 0"
                       using \<open>cmod (to_complex i1) = 1\<close>  \<open>cmod (to_complex i2) = 1\<close> \<open>?a1 \<noteq> ?a2\<close>              
                       by (auto simp add: power_divide complex_mult_cnj_cmod)
 
                     have "is_real ?Aa1"
                       by simp
 
                     have "?a1 \<noteq> inversion ?a2"
                       using \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close> inversion_noteq_unit_disc by fastforce
 
                     hence "Re ?Ba1 / Re ?Aa1 < -1"
                       using \<open>intersects_x_axis_positive ?la\<close> \<open>?a1 \<noteq> ?a2\<close>
                       using intersects_x_axis_positive_mk_circline[of ?Aa1 ?Ba1] \<open>?Aa1 \<noteq> 0 \<or> ?Ba1 \<noteq> 0\<close> \<open>is_real ?Aa1\<close>
                       using poincare_line_non_homogenous[of ?a1 ?a2]
                       by (simp add: Let_def)
 
                     moreover
 
                     let ?i1' = "to_complex i1" and ?i2' = "to_complex i2"
                     let ?Ai1 = "\<i> * (?i1' * cnj ?i2' - ?i2' * cnj ?i1')" and 
                         ?Bi1 = "\<i> * (?i2' * cor ((cmod ?i1')\<^sup>2 + 1) - ?i1' * cor ((cmod ?i2')\<^sup>2 + 1))"
 
                     have "?Ai1 \<noteq> 0 \<or> ?Bi1 \<noteq> 0"
                       using \<open>cmod (to_complex i1) = 1\<close>  \<open>cmod (to_complex i2) = 1\<close> \<open>?a1 \<noteq> ?a2\<close>              
                       by (auto simp add: power_divide complex_mult_cnj_cmod)
 
                     have "is_real ?Ai1"
                       by simp
 
                     have "sgn (Re ?Bi1 / Re ?Ai1) = sgn (Re ?Ba1 / Re ?Aa1)"  
                     proof-
                       have "Re ?Bi1 / Re ?Ai1 = (Im ?i1 * 2 - Im ?i2 * 2) /
                                                 (Im ?i2 * (Re ?i1 * 2) - Im ?i1 * (Re ?i2 * 2))"
                         using \<open>cmod ?i1 = 1\<close>  \<open>cmod ?i2 = 1\<close>
                         by (auto simp add: complex_mult_cnj_cmod field_simps)
                       also have "... =  (Im ?i1 - Im ?i2) /
                                         (Im ?i2 * (Re ?i1) - Im ?i1 * (Re ?i2))" (is "... = ?expr")
                         apply (subst left_diff_distrib[symmetric])
                         apply (subst semiring_normalization_rules(18))+
                         apply (subst left_diff_distrib[symmetric])
                         by (metis mult.commute mult_divide_mult_cancel_left_if zero_neq_numeral)
                       finally have 1: "Re ?Bi1 / Re ?Ai1 = (Im ?i1 - Im ?i2) / (Im ?i2 * (Re ?i1) - Im ?i1 * (Re ?i2))"
                         .
 
                 
                       have "Re ?Ba1 / Re ?Aa1 = (Im ?i1 * 20 - Im ?i2 * 20) /
                                                 (Im ?i2 * (Re ?i1 * 16) - Im ?i1 * (Re ?i2 * 16))"
                         using \<open>cmod (to_complex i1) = 1\<close>  \<open>cmod (to_complex i2) = 1\<close>
                         by (auto simp add: complex_mult_cnj_cmod field_simps)
                       also have "... = (20 / 16) * ((Im ?i1 - Im ?i2) /
                                        (Im ?i2 * (Re ?i1) - Im ?i1 * (Re ?i2)))"
                         apply (subst left_diff_distrib[symmetric])+
                         apply (subst semiring_normalization_rules(18))+
                         apply (subst left_diff_distrib[symmetric])+
                         by (metis (no_types, hide_lams)  field_class.field_divide_inverse mult.commute times_divide_times_eq)
                       finally have 2: "Re ?Ba1 / Re ?Aa1 = (5 / 4) * ((Im ?i1 - Im ?i2) / (Im ?i2 * (Re ?i1) - Im ?i1 * (Re ?i2)))"
                         by simp
 
                       have "?expr \<noteq> 0"
                         using \<open>Re ?Ba1 / Re ?Aa1 < -1\<close>
                         apply  (subst (asm) 2)
                         by linarith
                       thus ?thesis
                         apply (subst 1, subst 2)
                         apply (simp only: sgn_mult)
                         by simp
                     qed
                       
 
                     moreover
 
                     have "i1 \<noteq> inversion i2"
                       by (simp add: \<open>i1 \<noteq> i2\<close> inv(2))
 
                     have "(Re ?Bi1 / Re ?Ai1)\<^sup>2 > 1"
                     proof-
                       have "?Ai1 = 0 \<or> (Re ?Bi1)\<^sup>2 > (Re ?Ai1)\<^sup>2"
                         using \<open>intersects_x_axis ?lx\<close>
                         using \<open>i1 \<noteq> i2\<close> \<open>i1 \<noteq> \<infinity>\<^sub>h\<close> \<open>i2 \<noteq> \<infinity>\<^sub>h\<close> \<open>i1 \<noteq> inversion i2\<close>
                         using intersects_x_axis_mk_circline[of ?Ai1 ?Bi1] \<open>?Ai1 \<noteq> 0 \<or> ?Bi1 \<noteq> 0\<close> \<open>is_real ?Ai1\<close>
                         using poincare_line_non_homogenous[of i1 i2] \<open>?lx = ?li\<close>
                         by metis
                                                   
                       moreover
                       have "?Ai1 \<noteq> 0"
                       proof (rule ccontr)
                         assume "\<not> ?thesis"
                         hence "0\<^sub>h \<in> circline_set ?li"
                           unfolding circline_set_def
                           apply simp
                           apply (transfer, transfer, case_tac i1, case_tac i2)
                           by (auto simp add: vec_cnj_def field_simps)
                         thus False
                           using \<open>0\<^sub>h \<notin> circline_set ?lx\<close> \<open>?lx = ?li\<close>
                           by simp
                       qed
 
                       ultimately
 
                       have "(Re ?Bi1)\<^sup>2 > (Re ?Ai1)\<^sup>2"    
                         by auto
 
                       moreover
 
                       have "Re ?Ai1 \<noteq> 0"
                         using \<open>is_real ?Ai1\<close> \<open>?Ai1 \<noteq> 0\<close>
                         by (simp add: complex_eq_iff)
 
                       ultimately
 
                       show ?thesis
                         by (simp add: power_divide)
                     qed
 
                     moreover
 
                     {
                       fix x1 x2 :: real
                       assume "sgn x1 = sgn x2" "x1 < -1" "x2\<^sup>2 > 1"
                       hence "x2 < -1"
                         by (smt one_power2 real_sqrt_abs real_sqrt_less_iff sgn_neg sgn_pos)
                     }
 
                     ultimately
 
                     have "Re ?Bi1 / Re ?Ai1 < -1"
                       by metis
 
                     thus ?thesis
                       using \<open>i1 \<noteq> i2\<close> \<open>i1 \<noteq> \<infinity>\<^sub>h\<close> \<open>i2 \<noteq> \<infinity>\<^sub>h\<close> \<open>i1 \<noteq> inversion i2\<close>
                       using intersects_x_axis_positive_mk_circline[of ?Ai1 ?Bi1] \<open>?Ai1 \<noteq> 0 \<or> ?Bi1 \<noteq> 0\<close> \<open>is_real ?Ai1\<close>
                       using poincare_line_non_homogenous[of i1 i2] \<open>?lx = ?li\<close>
                       by (simp add: Let_def)
                   qed
 
                   then obtain x where x: "x \<in> unit_disc" "x \<in> circline_set ?lx \<inter> positive_x_axis"
                     using intersects_x_axis_positive_iff[OF lx \<open>?lx \<noteq> x_axis\<close>]
                     by auto
 
                   have "poincare_on_ray x 0\<^sub>h a' \<and> poincare_collinear {x1, x2, x}"
                   proof
                     show "poincare_collinear {x1, x2, x}"
                       using x lx \<open>x1 \<in> circline_set ?lx\<close> \<open>x2 \<in> circline_set ?lx\<close>
                       unfolding poincare_collinear_def
                       by auto
                   next
                     show "poincare_on_ray x 0\<^sub>h a'"
                       unfolding poincare_on_ray_def
                     proof-
                       have  "a' \<in> circline_set x_axis"
                         using \<open>poincare_on_ray a' 0\<^sub>h ?a\<close> xa \<open>0\<^sub>h \<noteq> ?a\<close> \<open>xa \<noteq> 0\<close> \<open>a' \<in> unit_disc\<close>
                         unfolding poincare_on_ray_def 
                         using poincare_line_0_real_is_x_axis[of "of_complex xa"]
                         using poincare_between_poincare_line_uvz[of "0\<^sub>h" "of_complex xa" a']
                         using poincare_between_poincare_line_uzv[of "0\<^sub>h" "of_complex xa" a']
                         by (auto simp  add: cmod_eq_Re)
 
                       then obtain xa' where xa': "a' = of_complex xa'" "is_real xa'"
                         using \<open>a' \<in> unit_disc\<close>
                         using circline_set_def on_circline_x_axis 
                         by auto
 
                       hence "-1 < Re xa'" "Re xa' < 1" "xa' \<noteq> 0"
                         using \<open>a' \<in> unit_disc\<close> \<open>a' \<noteq> 0\<^sub>h\<close>
                         by (auto simp add: cmod_eq_Re)
 
                       hence "Re xa' > 0" "Re xa' < 1" "is_real xa'"
                         using \<open>poincare_on_ray a' 0\<^sub>h (of_complex xa)\<close>
                         using poincare_between_x_axis_0uv[of "Re xa'" "Re xa"]
                         using poincare_between_x_axis_0uv[of "Re xa" "Re xa'"]
                         using circline_set_positive_x_axis_I[of "Re xa'"]
                         using xa xa' complex_of_real_Re
                         unfolding poincare_on_ray_def
                         by (smt of_real_0, linarith, blast)
 
                       moreover
 
                       obtain xx where "is_real xx" "Re xx > 0" "Re xx < 1" "x = of_complex xx"
                         using x
                         unfolding positive_x_axis_def
                         using circline_set_def cmod_eq_Re on_circline_x_axis
                         by auto
 
                       ultimately
 
                       show "poincare_between 0\<^sub>h x a' \<or> poincare_between 0\<^sub>h a' x"
                         using \<open>a' = of_complex xa'\<close>
                         by (smt \<open>a' \<in> unit_disc\<close> arg_0_iff poincare_between_0uv poincare_between_def to_complex_of_complex x(1))
                     qed
 
                   qed
 
                   thus ?thesis               
                     using \<open>x \<in> unit_disc\<close>
                     unfolding poincare_ray_meets_line_def poincare_on_line_def
                     by (metis insert_commute)
                 qed
               qed
             next
               show "a \<noteq> 0\<^sub>h"
               proof (rule ccontr)
                 assume "\<not> ?thesis"
                 then obtain k where "k<0" "to_complex ?a1 = cor k * to_complex ?a2"
                   using poincare_between_u0v[OF \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close> \<open>?a1 \<noteq> 0\<^sub>h\<close> \<open>?a2 \<noteq> 0\<^sub>h\<close>]
                   using \<open>poincare_between ?a1 a ?a2\<close>
                   by auto
                 hence "to_complex i1 = cor k * to_complex i2" "k < 0"
                   by auto
                 hence "0\<^sub>h \<in> circline_set (poincare_line x1 x2)"
                   using ideal_points_proportional[of "poincare_line x1 x2" i1 i2 k] \<open>ideal_points (poincare_line x1 x2) = {i1, i2}\<close>
                   using is_poincare_line_poincare_line[OF \<open>x1 \<noteq> x2\<close>]
                   by simp
                 thus False
                   using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close>
                   using is_poincare_line_poincare_line[OF \<open>x1 \<noteq> x2\<close>]
                   unfolding poincare_collinear_def
                   by (meson \<open>x1 \<noteq> x2\<close> empty_subsetI insert_subset poincare_line_circline_set(1) poincare_line_circline_set(2))
               qed
             next
               fix \<phi> u
               let ?R' = "\<lambda> a zero. \<forall> a' a1 a2 x1 x2 i1 i2. ?R zero a' a1 a2 x1 x2 i1 i2 a"
               let ?M = "moebius_pt (moebius_rotation \<phi>)"
               assume *: "u \<in> unit_disc" "u \<noteq> 0\<^sub>h" and **: "?R' (?M u) 0\<^sub>h"
               have uf: "unit_disc_fix (moebius_rotation \<phi>)"
                 by simp
               have "?M 0\<^sub>h = 0\<^sub>h"
                 by auto
               hence **: "?R' (?M u) (?M 0\<^sub>h)"
                 using **
                 by simp
               show "?R' u 0\<^sub>h"
               proof (rule allI)+
                 fix a' a1 a2 x1 x2 i1 i2
                 have i1: "i1 \<in> unit_circle_set \<longrightarrow> moebius_pt (moebius_rotation \<phi>) (of_complex (to_complex i1 / 2)) = of_complex (to_complex (moebius_pt (moebius_rotation \<phi>) i1) / 2)"
                   using unit_circle_set_def by force
                 
                 have i2: "i2 \<in> unit_circle_set \<longrightarrow> moebius_pt (moebius_rotation \<phi>) (of_complex (to_complex i2 / 2)) = of_complex (to_complex (moebius_pt (moebius_rotation \<phi>) i2) / 2)"
                   using unit_circle_set_def by force
                 
                 show "?R 0\<^sub>h a' a1 a2 x1 x2 i1 i2 u"
                   using **[rule_format, of "?M a'" "?M x1" "?M x2" "?M i1" "?M i2" "?M a1" "?M a2"] uf * 
                   apply (auto simp del:  moebius_pt_moebius_rotation_zero moebius_pt_moebius_rotation)
                   using i1 i2
                   by simp
               qed
             qed
             thus ?thesis                                                                  
               using \<open>a' \<in> unit_disc\<close> \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> \<open>x1 \<noteq> x2\<close> 
               using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close> \<open>ideal_points ?lx = {i1, i2}\<close> \<open>i1 \<noteq> i2\<close>
               using \<open>?a1 \<noteq> ?a2\<close> \<open>poincare_collinear {0\<^sub>h, ?a1, i1}\<close> \<open>poincare_collinear {0\<^sub>h, ?a2, i2}\<close>
               using \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close> \<open>i1 \<in> unit_circle_set\<close> \<open>i2 \<in> unit_circle_set\<close>
               using \<open>poincare_on_ray a' 0\<^sub>h a\<close> \<open>a' \<noteq> 0\<^sub>h\<close> \<open>poincare_between ?a1 a ?a2\<close> \<open>a \<noteq> ?a1\<close> \<open>a \<noteq> ?a2\<close>
               by blast
           qed
         qed
 
         moreover
 
         have "\<not> poincare_on_line 0\<^sub>h ?a1 ?a2"
         proof
           assume *: "poincare_on_line 0\<^sub>h ?a1 ?a2"
           hence "poincare_collinear {0\<^sub>h, ?a1, ?a2}"
             unfolding poincare_on_line_def
             by simp
           hence "poincare_line 0\<^sub>h ?a1 = poincare_line 0\<^sub>h ?a2"
             using poincare_collinear3_poincare_lines_equal_general[of "0\<^sub>h" ?a1 ?a2]
             using \<open>?a1 \<in> unit_disc\<close> \<open>?a1 \<noteq> 0\<^sub>h\<close> \<open>?a2 \<in> unit_disc\<close> \<open>?a2 \<noteq> 0\<^sub>h\<close> 
             by (metis inversion_noteq_unit_disc zero_in_unit_disc)
 
           have "i1 \<in> circline_set (poincare_line 0\<^sub>h ?a1)"
             using \<open>poincare_collinear {0\<^sub>h, ?a1, i1}\<close>
             using poincare_collinear3_poincare_line_general[of i1 "0\<^sub>h" ?a1]
             using \<open>?a1 \<in> unit_disc\<close> \<open>?a1 \<noteq> 0\<^sub>h\<close>
             by (metis insert_commute inversion_noteq_unit_disc zero_in_unit_disc)
           moreover
           have "i2 \<in> circline_set (poincare_line 0\<^sub>h ?a1)"
             using \<open>poincare_collinear {0\<^sub>h, ?a2, i2}\<close>
             using poincare_collinear3_poincare_line_general[of i2 "0\<^sub>h" ?a2]
             using \<open>?a2 \<in> unit_disc\<close> \<open>?a2 \<noteq> 0\<^sub>h\<close> \<open>poincare_line 0\<^sub>h ?a1 = poincare_line 0\<^sub>h ?a2\<close>
             by (metis insert_commute inversion_noteq_unit_disc zero_in_unit_disc)
 
           ultimately
 
           have "poincare_collinear {0\<^sub>h, i1, i2}"
             using \<open>?a1 \<in> unit_disc\<close> \<open>?a1 \<noteq> 0\<^sub>h\<close> \<open>poincare_collinear {0\<^sub>h, ?a1, i1}\<close>
             by (smt insert_subset poincare_collinear_def unique_poincare_line zero_in_unit_disc)
           hence "0\<^sub>h \<in> circline_set (poincare_line i1 i2)"
             using poincare_collinear3_poincare_line_general[of "0\<^sub>h" i1 i2]
             using \<open>i1 \<noteq> i2\<close> \<open>i2 \<in> unit_circle_set\<close> unit_circle_set_def
             by force
 
           moreover
 
           have "?lx = ?li"
             using \<open>ideal_points ?lx = {i1, i2}\<close> \<open>x1 \<noteq> x2\<close> ideal_points_line_unique
             by auto
 
           ultimately
 
           show False
             using \<open>\<not> poincare_collinear {0\<^sub>h, x1, x2}\<close>
             using \<open>x1 \<noteq> x2\<close> poincare_line_poincare_collinear3_general
             by auto
         qed          
 
         ultimately
 
         show ?thesis
           using \<open>?a1 \<in> unit_disc\<close> \<open>?a2 \<in> unit_disc\<close>
           by blast
       qed
     qed
   qed
   thus ?thesis
     using \<open>x1 \<in> unit_disc\<close> \<open>x2 \<in> unit_disc\<close> \<open>\<not> poincare_collinear {a, x1, x2}\<close>
     by blast
 qed                                                                        
 
 subsection\<open>Interpretation of locales\<close>
 
 global_interpretation PoincareTarskiAbsolute: TarskiAbsolute where cong  = p_congruent and betw = p_between
   defines p_on_line = PoincareTarskiAbsolute.on_line and
           p_on_ray = PoincareTarskiAbsolute.on_ray and
           p_in_angle = PoincareTarskiAbsolute.in_angle and
           p_ray_meets_line = PoincareTarskiAbsolute.ray_meets_line
 proof-
   show "TarskiAbsolute p_congruent p_between"
   proof
     text\<open> 1. Reflexivity of congruence \<close>
     fix x y
     show "p_congruent x y y x"
       unfolding p_congruent_def
       by transfer (simp add: poincare_distance_sym)
   next
     text\<open> 2. Transitivity of congruence \<close>
     fix x y z u v w
     show "p_congruent x y z u \<and> p_congruent x y v w \<longrightarrow> p_congruent z u v w"
       by (transfer, simp)
   next
     text\<open> 3. Identity of congruence \<close>
     fix x y z
     show "p_congruent x y z z \<longrightarrow> x = y"
       unfolding p_congruent_def
       by transfer (simp add: poincare_distance_eq_0_iff)
   next
     text\<open> 4. Segment construction \<close>
     fix x y a b
     show "\<exists> z. p_between x y z \<and> p_congruent y z a b"
       using segment_construction
       unfolding p_congruent_def
       by transfer (simp, blast)
   next
     text\<open> 5. Five segment \<close>
     fix x y z x' y' z' u u'
     show "x \<noteq> y \<and> p_between x y z \<and> p_between x' y' z' \<and>
       p_congruent x y x' y' \<and> p_congruent y z y' z' \<and>
       p_congruent x u x' u' \<and> p_congruent y u y' u' \<longrightarrow>
       p_congruent z u z' u'"
       unfolding p_congruent_def
       apply transfer
       using five_segment_axiom                                             
       by meson
   next
     text\<open> 6. Identity of betweeness \<close>
     fix x y
     show "p_between x y x \<longrightarrow> x = y"
       by transfer (simp add: poincare_between_sum_distances poincare_distance_eq_0_iff poincare_distance_sym)
   next
     text\<open> 7. Pasch \<close>
     fix x y z u v
     show "p_between x u z \<and> p_between y v z \<longrightarrow> (\<exists> a. p_between u a y \<and> p_between x a v)"
       apply transfer
       using Pasch
       by blast
   next
     text\<open> 8. Lower dimension \<close>
     show "\<exists> a. \<exists> b. \<exists> c. \<not> p_between a b c \<and> \<not> p_between b c a \<and> \<not> p_between c a b"
       apply (transfer)
       using lower_dimension_axiom
       by simp
   next
     text\<open> 9. Upper dimension \<close>
     fix x y z u v
     show "p_congruent x u x v \<and> p_congruent y u y v \<and> p_congruent z u z v \<and> u \<noteq> v \<longrightarrow>
           p_between x y z \<or> p_between y z x \<or> p_between z x y"
       unfolding p_congruent_def
       by (transfer, simp add: upper_dimension_axiom)
   qed
 qed 
 
 
 interpretation PoincareTarskiHyperbolic: TarskiHyperbolic
   where cong = p_congruent and betw = p_between
 proof
   text\<open> 10. Euclid negation \<close>
   show "\<exists> a b c d t. p_between a d t \<and> p_between b d c \<and> a \<noteq> d \<and>
                    (\<forall> x y. p_between a b x \<and> p_between a c y \<longrightarrow> \<not> p_between x t y)"
     using negated_euclidean_axiom
     by transfer (auto, blast)
 next
   fix a x1  x2
   assume "\<not> TarskiAbsolute.on_line p_between a x1 x2"
   hence "\<not> p_on_line a x1 x2"
     using TarskiAbsolute.on_line_def[OF PoincareTarskiAbsolute.TarskiAbsolute_axioms]
     using PoincareTarskiAbsolute.on_line_def
     by simp
   text\<open> 11. Limiting parallels  \<close>
   thus "\<exists>a1 a2.
           \<not> TarskiAbsolute.on_line p_between a a1 a2 \<and>
           \<not> TarskiAbsolute.ray_meets_line p_between a a1 x1 x2 \<and>
           \<not> TarskiAbsolute.ray_meets_line p_between a a2 x1 x2 \<and>
           (\<forall>a'. TarskiAbsolute.in_angle p_between a' a1 a a2 \<longrightarrow> TarskiAbsolute.ray_meets_line p_between a a' x1 x2)"
     unfolding TarskiAbsolute.in_angle_def[OF PoincareTarskiAbsolute.TarskiAbsolute_axioms]
     unfolding TarskiAbsolute.on_ray_def[OF PoincareTarskiAbsolute.TarskiAbsolute_axioms]
     unfolding TarskiAbsolute.ray_meets_line_def[OF PoincareTarskiAbsolute.TarskiAbsolute_axioms]
     unfolding TarskiAbsolute.on_ray_def[OF PoincareTarskiAbsolute.TarskiAbsolute_axioms]
     unfolding TarskiAbsolute.on_line_def[OF PoincareTarskiAbsolute.TarskiAbsolute_axioms]
     unfolding PoincareTarskiAbsolute.on_line_def
     apply transfer
   proof- 
     fix a x1 x2
     assume *: "a \<in> unit_disc" "x1 \<in> unit_disc" "x2 \<in> unit_disc"
               "\<not> (poincare_between a x1 x2 \<or> poincare_between x1 a x2 \<or> poincare_between x1 x2 a)"
     hence "\<not> poincare_on_line a x1 x2"
       using poincare_collinear3_iff[of a x1 x2]
       using poincare_between_rev poincare_on_line_def by blast
     hence "\<exists>a1\<in>unit_disc.
             \<exists>a2\<in>unit_disc.
             \<not> poincare_on_line a a1 a2 \<and>
             \<not> poincare_ray_meets_line a a1 x1 x2 \<and>
             \<not> poincare_ray_meets_line a a2 x1 x2 \<and>
             (\<forall>a'\<in>unit_disc.
                 poincare_in_angle a' a1 a a2 \<longrightarrow>
                 poincare_ray_meets_line a a' x1 x2)"
       using limiting_parallels[of a x1 x2] *
       by blast
     then obtain a1 a2 where **: "a1\<in>unit_disc" "a2\<in>unit_disc" "\<not> poincare_on_line a a1 a2"
                             "\<not> poincare_ray_meets_line a a2 x1 x2"
                             "\<not> poincare_ray_meets_line a a1 x1 x2"
                             "\<forall>a'\<in>unit_disc.
                                   poincare_in_angle a' a1 a a2 \<longrightarrow>
                                   poincare_ray_meets_line a a' x1 x2"
       by blast
     have "\<not> (\<exists>x\<in>{z. z \<in> unit_disc}.
                     (poincare_between a x a1 \<or>
                      poincare_between a a1 x) \<and>
                     (poincare_between x x1 x2 \<or>
                      poincare_between x1 x x2 \<or>
                      poincare_between x1 x2 x))"
       using \<open>\<not> poincare_ray_meets_line a a1 x1 x2\<close>
       unfolding poincare_on_line_def poincare_ray_meets_line_def poincare_on_ray_def
       using poincare_collinear3_iff[of _ x1 x2] poincare_between_rev *(2, 3)
       by auto
     moreover
     have "\<not> (\<exists>x\<in>{z. z \<in> unit_disc}.
                     (poincare_between a x a2 \<or>
                      poincare_between a a2 x) \<and>
                     (poincare_between x x1 x2 \<or>
                      poincare_between x1 x x2 \<or>
                      poincare_between x1 x2 x))"
       using \<open>\<not> poincare_ray_meets_line a a2 x1 x2\<close>
       unfolding poincare_on_line_def poincare_ray_meets_line_def poincare_on_ray_def
       using poincare_collinear3_iff[of _ x1 x2] poincare_between_rev *(2, 3)
       by auto
     moreover
     have "\<not> (poincare_between a a1 a2 \<or> poincare_between a1 a a2 \<or> poincare_between a1 a2 a)"
       using \<open>\<not> poincare_on_line a a1 a2\<close> poincare_collinear3_iff[of a a1 a2]
       using *(1) **(1-2)
       unfolding poincare_on_line_def
       by simp
     moreover 
     have "(\<forall>a'\<in>{z. z \<in> unit_disc}.
                  a \<noteq> a1 \<and>
                  a \<noteq> a2 \<and>
                  a' \<noteq> a \<and>
                  (\<exists>x\<in>{z. z \<in> unit_disc}.
                      poincare_between a1 x a2 \<and>
                      x \<noteq> a1 \<and>
                      x \<noteq> a2 \<and>
                      (poincare_between a a' x \<or>
                       poincare_between a x a')) \<longrightarrow>
                  (\<exists>x\<in>{z. z \<in> unit_disc}.
                      (poincare_between a x a' \<or>
                       poincare_between a a' x) \<and>
                      (poincare_between x x1 x2 \<or>
                       poincare_between x1 x x2 \<or>
                       poincare_between x1 x2 x)))"
       using **(6)
       unfolding poincare_on_line_def poincare_in_angle_def poincare_ray_meets_line_def poincare_on_ray_def
       using poincare_collinear3_iff[of _ x1 x2] poincare_between_rev *(2, 3)
       by auto
     ultimately
     show "\<exists>a1\<in>{z. z \<in> unit_disc}.
            \<exists>a2\<in>{z. z \<in> unit_disc}.
              \<not> (poincare_between a a1 a2 \<or> poincare_between a1 a a2 \<or> poincare_between a1 a2 a) \<and>
              \<not> (\<exists>x\<in>{z. z \<in> unit_disc}.
                     (poincare_between a x a1 \<or>
                      poincare_between a a1 x) \<and>
                     (poincare_between x x1 x2 \<or>
                      poincare_between x1 x x2 \<or>
                      poincare_between x1 x2 x)) \<and>
              \<not> (\<exists>x\<in>{z. z \<in> unit_disc}.
                     (poincare_between a x a2 \<or>
                      poincare_between a a2 x) \<and>
                     (poincare_between x x1 x2 \<or>
                      poincare_between x1 x x2 \<or>
                      poincare_between x1 x2 x)) \<and>
              (\<forall>a'\<in>{z. z \<in> unit_disc}.
                  a \<noteq> a1 \<and>
                  a \<noteq> a2 \<and>
                  a' \<noteq> a \<and>
                  (\<exists>x\<in>{z. z \<in> unit_disc}.
                      poincare_between a1 x a2 \<and>
                      x \<noteq> a1 \<and>
                      x \<noteq> a2 \<and>
                      (poincare_between a a' x \<or>
                       poincare_between a x a')) \<longrightarrow>
                  (\<exists>x\<in>{z. z \<in> unit_disc}.
                      (poincare_between a x a' \<or>
                       poincare_between a a' x) \<and>
                      (poincare_between x x1 x2 \<or>
                       poincare_between x1 x x2 \<or>
                       poincare_between x1 x2 x)))" 
       using **(1, 2)
       by auto
    qed
 qed
 
 interpretation PoincareElementaryTarskiHyperbolic: ElementaryTarskiHyperbolic p_congruent p_between
 proof
   text\<open> 12.  Continuity \<close>
   fix \<phi> \<psi>
   assume "\<exists> a. \<forall> x. \<forall> y. \<phi> x \<and> \<psi> y \<longrightarrow> p_between a x y"
   thus "\<exists> b. \<forall> x. \<forall> y. \<phi> x \<and> \<psi> y \<longrightarrow> p_between x b y"
     apply transfer
     using continuity
     by auto
 qed
 
 end