diff --git a/thys/Martingales/Bochner_Integration_Supplement.thy b/thys/Martingales/Bochner_Integration_Supplement.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Bochner_Integration_Supplement.thy
@@ -0,0 +1,722 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Bochner_Integration_Supplement
+  imports "HOL-Analysis.Bochner_Integration" "HOL-Analysis.Set_Integral" Elementary_Metric_Spaces_Supplement
+begin
+
+section \<open>Supplementary Lemmas for Bochner Integration\<close>
+
+subsection \<open>Integrable Simple Functions\<close>
+
+text \<open>We restate some basic results concerning Bochner-integrable functions.\<close>
+  
+lemma integrable_implies_simple_function_sequence:
+  fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
+  assumes "integrable M f"
+  obtains s where "\<And>i. simple_function M (s i)"
+      and "\<And>i. emeasure M {y \<in> space M. s i y \<noteq> 0} \<noteq> \<infinity>"
+      and "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> f x"
+      and "\<And>x i. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)"
+proof-
+  have f: "f \<in> borel_measurable M" "(\<integral>\<^sup>+x. norm (f x) \<partial>M) < \<infinity>" using assms unfolding integrable_iff_bounded by auto
+  obtain s where s: "\<And>i. simple_function M (s i)" "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> f x" "\<And>i x. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)" using borel_measurable_implies_sequence_metric[OF f(1)] unfolding norm_conv_dist by metis
+  {
+    fix i
+    have "(\<integral>\<^sup>+x. norm (s i x) \<partial>M) \<le> (\<integral>\<^sup>+x. ennreal (2 * norm (f x)) \<partial>M)" using s by (intro nn_integral_mono, auto)
+    also have "\<dots> < \<infinity>" using f by (simp add: nn_integral_cmult ennreal_mult_less_top ennreal_mult)
+    finally have sbi: "Bochner_Integration.simple_bochner_integrable M (s i)" using s by (intro simple_bochner_integrableI_bounded) auto
+    hence "emeasure M {y \<in> space M. s i y \<noteq> 0} \<noteq> \<infinity>" by (auto intro: integrableI_simple_bochner_integrable simple_bochner_integrable.cases)
+  }
+  thus ?thesis using that s by blast
+qed
+
+text \<open>Simple functions can be represented by sums of indicator functions.\<close>
+
+lemma simple_function_indicator_representation:
+  fixes f ::"'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes "simple_function M f" "x \<in> space M"
+  shows "f x = (\<Sum>y \<in> f ` space M. indicator (f -` {y} \<inter> space M) x *\<^sub>R y)"
+  (is "?l = ?r")
+proof -
+  have "?r = (\<Sum>y \<in> f ` space M.
+    (if y = f x then indicator (f -` {y} \<inter> space M) x *\<^sub>R y else 0))" by (auto intro!: sum.cong)
+  also have "... =  indicator (f -` {f x} \<inter> space M) x *\<^sub>R f x" using assms by (auto dest: simple_functionD)
+  also have "... = f x" using assms by (auto simp: indicator_def)
+  finally show ?thesis by auto
+qed
+
+lemma simple_function_indicator_representation_AE:
+  fixes f ::"'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes "simple_function M f"
+  shows "AE x in M. f x = (\<Sum>y \<in> f ` space M. indicator (f -` {y} \<inter> space M) x *\<^sub>R y)"  
+  by (metis (mono_tags, lifting) AE_I2 simple_function_indicator_representation assms)
+
+lemmas simple_function_scaleR[intro] = simple_function_compose2[where h="(*\<^sub>R)"]
+lemmas integrable_simple_function = simple_bochner_integrable.intros[THEN has_bochner_integral_simple_bochner_integrable, THEN integrable.intros] 
+
+text \<open>Induction rule for simple integrable functions.\<close>
+
+lemma\<^marker>\<open>tag important\<close> integrable_simple_function_induct[consumes 2, case_names cong indicator add, induct set: simple_function]:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes f: "simple_function M f" "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>"
+  assumes cong: "\<And>f g. simple_function M f \<Longrightarrow> emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity> 
+                    \<Longrightarrow> simple_function M g \<Longrightarrow> emeasure M {y \<in> space M. g y \<noteq> 0} \<noteq> \<infinity> 
+                    \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> P f \<Longrightarrow> P g"
+  assumes indicator: "\<And>A y. A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow> P (\<lambda>x. indicator A x *\<^sub>R y)"
+  assumes add: "\<And>f g. simple_function M f \<Longrightarrow> emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow> 
+                      simple_function M g \<Longrightarrow> emeasure M {y \<in> space M. g y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow> 
+                      (\<And>z. z \<in> space M \<Longrightarrow> norm (f z + g z) = norm (f z) + norm (g z)) \<Longrightarrow>
+                      P f \<Longrightarrow> P g \<Longrightarrow> P (\<lambda>x. f x + g x)"
+  shows "P f"
+proof-
+  let ?f = "\<lambda>x. (\<Sum>y\<in>f ` space M. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+  have f_ae_eq: "f x = ?f x" if "x \<in> space M" for x using simple_function_indicator_representation[OF f(1) that] .
+  moreover have "emeasure M {y \<in> space M. ?f y \<noteq> 0} \<noteq> \<infinity>" by (metis (no_types, lifting) Collect_cong calculation f(2))
+  moreover have "P (\<lambda>x. \<Sum>y\<in>S. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+                "simple_function M (\<lambda>x. \<Sum>y\<in>S. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+                "emeasure M {y \<in> space M. (\<Sum>x\<in>S. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<noteq> \<infinity>"
+                if "S \<subseteq> f ` space M" for S using simple_functionD(1)[OF assms(1), THEN rev_finite_subset, OF that] that 
+  proof (induction rule: finite_induct)
+    case empty
+    {
+      case 1
+      then show ?case using indicator[of "{}"] by force
+    next
+      case 2
+      then show ?case by force 
+    next
+      case 3
+      then show ?case by force 
+    }
+  next
+    case (insert x F)
+    have "(f -` {x} \<inter> space M) \<subseteq> {y \<in> space M. f y \<noteq> 0}" if "x \<noteq> 0" using that by blast
+    moreover have "{y \<in> space M. f y \<noteq> 0} = space M - (f -` {0} \<inter> space M)" by blast
+    moreover have "space M - (f -` {0} \<inter> space M) \<in> sets M" using simple_functionD(2)[OF f(1)] by blast
+    ultimately have fin_0: "emeasure M (f -` {x} \<inter> space M) < \<infinity>" if "x \<noteq> 0" using that by (metis emeasure_mono f(2) infinity_ennreal_def top.not_eq_extremum top_unique)
+    hence fin_1: "emeasure M {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0} \<noteq> \<infinity>" if "x \<noteq> 0" by (metis (mono_tags, lifting) emeasure_mono f(1) indicator_simps(2) linorder_not_less mem_Collect_eq scaleR_eq_0_iff simple_functionD(2) subsetI that)
+
+    have *: "(\<Sum>y\<in>insert x F. indicat_real (f -` {y} \<inter> space M) xa *\<^sub>R y) = (\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) xa *\<^sub>R y) + indicat_real (f -` {x} \<inter> space M) xa *\<^sub>R x" for xa by (metis (no_types, lifting) Diff_empty Diff_insert0 add.commute insert.hyps(1) insert.hyps(2) sum.insert_remove)
+    have **: "{y \<in> space M. (\<Sum>x\<in>insert x F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<subseteq> {y \<in> space M. (\<Sum>x\<in>F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<union> {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0}" unfolding * by fastforce    
+    {
+      case 1
+      hence x: "x \<in> f ` space M" and F: "F \<subseteq> f ` space M" by auto
+      show ?case 
+      proof (cases "x = 0")
+        case True
+        then show ?thesis unfolding * using insert(3)[OF F] by simp
+      next
+        case False
+        have norm_argument: "norm ((\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y) + indicat_real (f -` {x} \<inter> space M) z *\<^sub>R x) = norm (\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y) + norm (indicat_real (f -` {x} \<inter> space M) z *\<^sub>R x)" if z: "z \<in> space M" for z
+        proof (cases "f z = x")
+          case True
+          have "indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y = 0" if "y \<in> F" for y using True insert(2) z that 1 unfolding indicator_def by force
+          hence "(\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y) = 0" by (meson sum.neutral)
+          then show ?thesis by force
+        next
+          case False
+          then show ?thesis by force
+        qed
+        show ?thesis using False simple_functionD(2)[OF f(1)] insert(3,5)[OF F] simple_function_scaleR fin_0 fin_1 by (subst *, subst add, subst simple_function_sum) (blast intro: norm_argument indicator)+
+      qed 
+    next
+      case 2
+      hence x: "x \<in> f ` space M" and F: "F \<subseteq> f ` space M" by auto
+      show ?case 
+      proof (cases "x = 0")
+        case True
+        then show ?thesis unfolding * using insert(4)[OF F] by simp
+      next
+        case False
+        then show ?thesis unfolding * using insert(4)[OF F] simple_functionD(2)[OF f(1)] by fast
+      qed
+    next
+      case 3
+      hence x: "x \<in> f ` space M" and F: "F \<subseteq> f ` space M" by auto
+      show ?case 
+      proof (cases "x = 0")
+        case True
+        then show ?thesis unfolding * using insert(5)[OF F] by simp
+      next
+        case False
+        have "emeasure M {y \<in> space M. (\<Sum>x\<in>insert x F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<le> emeasure M ({y \<in> space M. (\<Sum>x\<in>F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<union> {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0})"
+          using ** simple_functionD(2)[OF insert(4)[OF F]] simple_functionD(2)[OF f(1)] by (intro emeasure_mono, force+)
+        also have "... \<le> emeasure M {y \<in> space M. (\<Sum>x\<in>F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} + emeasure M {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0}"
+          using simple_functionD(2)[OF insert(4)[OF F]] simple_functionD(2)[OF f(1)] by (intro emeasure_subadditive, force+)
+        also have "... < \<infinity>" using insert(5)[OF F] fin_1[OF False] by (simp add: less_top)
+        finally show ?thesis by simp
+      qed
+    }
+  qed
+  moreover have "simple_function M (\<lambda>x. \<Sum>y\<in>f ` space M. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)" using calculation by blast
+  moreover have "P (\<lambda>x. \<Sum>y\<in>f ` space M. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)" using calculation by blast
+  ultimately show ?thesis by (intro cong[OF _ _ f(1,2)], blast, presburger+) 
+qed
+
+text \<open>Induction rule for non-negative simple integrable functions\<close>
+lemma\<^marker>\<open>tag important\<close> integrable_simple_function_induct_nn[consumes 3, case_names cong indicator add, induct set: simple_function]:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes f: "simple_function M f" "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>" "\<And>x. x \<in> space M \<longrightarrow> f x \<ge> 0"
+  assumes cong: "\<And>f g. simple_function M f \<Longrightarrow> emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x \<ge> 0) \<Longrightarrow> simple_function M g \<Longrightarrow> emeasure M {y \<in> space M. g y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> g x \<ge> 0) \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> P f \<Longrightarrow> P g"
+  assumes indicator: "\<And>A y. y \<ge> 0 \<Longrightarrow> A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow> P (\<lambda>x. indicator A x *\<^sub>R y)"
+  assumes add: "\<And>f g. (\<And>x. x \<in> space M \<Longrightarrow> f x \<ge> 0) \<Longrightarrow> simple_function M f \<Longrightarrow> emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow> 
+                      (\<And>x. x \<in> space M \<Longrightarrow> g x \<ge> 0) \<Longrightarrow> simple_function M g \<Longrightarrow> emeasure M {y \<in> space M. g y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow> 
+                      (\<And>z. z \<in> space M \<Longrightarrow> norm (f z + g z) = norm (f z) + norm (g z)) \<Longrightarrow>
+                      P f \<Longrightarrow> P g \<Longrightarrow> P (\<lambda>x. f x + g x)"
+  shows "P f"
+proof-
+  let ?f = "\<lambda>x. (\<Sum>y\<in>f ` space M. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+  have f_ae_eq: "f x = ?f x" if "x \<in> space M" for x using simple_function_indicator_representation[OF f(1) that] .
+  moreover have "emeasure M {y \<in> space M. ?f y \<noteq> 0} \<noteq> \<infinity>" by (metis (no_types, lifting) Collect_cong calculation f(2))
+  moreover have "P (\<lambda>x. \<Sum>y\<in>S. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+                "simple_function M (\<lambda>x. \<Sum>y\<in>S. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+                "emeasure M {y \<in> space M. (\<Sum>x\<in>S. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<noteq> \<infinity>"
+                "\<And>x. x \<in> space M \<Longrightarrow> 0 \<le> (\<Sum>y\<in>S. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)"
+                if "S \<subseteq> f ` space M" for S using simple_functionD(1)[OF assms(1), THEN rev_finite_subset, OF that] that 
+  proof (induction rule: finite_subset_induct')
+    case empty
+    {
+      case 1
+      then show ?case using indicator[of 0 "{}"] by force
+    next
+      case 2
+      then show ?case by force 
+    next
+      case 3
+      then show ?case by force 
+    next
+      case 4
+      then show ?case by force 
+    }
+  next
+    case (insert x F)
+    have "(f -` {x} \<inter> space M) \<subseteq> {y \<in> space M. f y \<noteq> 0}" if "x \<noteq> 0" using that by blast
+    moreover have "{y \<in> space M. f y \<noteq> 0} = space M - (f -` {0} \<inter> space M)" by blast
+    moreover have "space M - (f -` {0} \<inter> space M) \<in> sets M" using simple_functionD(2)[OF f(1)] by blast
+    ultimately have fin_0: "emeasure M (f -` {x} \<inter> space M) < \<infinity>" if "x \<noteq> 0" using that by (metis emeasure_mono f(2) infinity_ennreal_def top.not_eq_extremum top_unique)
+    hence fin_1: "emeasure M {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0} \<noteq> \<infinity>" if "x \<noteq> 0" by (metis (mono_tags, lifting) emeasure_mono f(1) indicator_simps(2) linorder_not_less mem_Collect_eq scaleR_eq_0_iff simple_functionD(2) subsetI that)
+
+    have nonneg_x: "x \<ge> 0" using insert f by blast
+    have *: "(\<Sum>y\<in>insert x F. indicat_real (f -` {y} \<inter> space M) xa *\<^sub>R y) = (\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) xa *\<^sub>R y) + indicat_real (f -` {x} \<inter> space M) xa *\<^sub>R x" for xa by (metis (no_types, lifting) add.commute insert.hyps(1) insert.hyps(4) sum.insert)
+    have **: "{y \<in> space M. (\<Sum>x\<in>insert x F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<subseteq> {y \<in> space M. (\<Sum>x\<in>F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<union> {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0}" unfolding * by fastforce    
+    {
+      case 1
+      show ?case 
+      proof (cases "x = 0")
+        case True
+        then show ?thesis unfolding * using insert by simp
+      next
+        case False
+        have norm_argument: "norm ((\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y) + indicat_real (f -` {x} \<inter> space M) z *\<^sub>R x) = norm (\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y) + norm (indicat_real (f -` {x} \<inter> space M) z *\<^sub>R x)" if z: "z \<in> space M" for z
+        proof (cases "f z = x")
+          case True
+          have "indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y = 0" if "y \<in> F" for y using True insert z that 1 unfolding indicator_def by force
+          hence "(\<Sum>y\<in>F. indicat_real (f -` {y} \<inter> space M) z *\<^sub>R y) = 0" by (meson sum.neutral)
+          thus ?thesis by force
+        qed (force)
+        show ?thesis using False fin_0 fin_1 f norm_argument by (subst *, subst add, presburger add: insert, intro insert, intro insert, fastforce simp add: indicator_def intro!: insert(2) f(3), auto intro!: indicator insert nonneg_x)
+      qed 
+    next
+      case 2
+      show ?case 
+      proof (cases "x = 0")
+        case True
+        then show ?thesis unfolding * using insert by simp
+      next
+        case False
+        then show ?thesis unfolding * using insert simple_functionD(2)[OF f(1)] by fast
+      qed
+    next
+      case 3
+      show ?case 
+      proof (cases "x = 0")
+        case True
+        then show ?thesis unfolding * using insert by simp
+      next
+        case False
+        have "emeasure M {y \<in> space M. (\<Sum>x\<in>insert x F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<le> emeasure M ({y \<in> space M. (\<Sum>x\<in>F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} \<union> {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0})"
+          using ** simple_functionD(2)[OF insert(6)] simple_functionD(2)[OF f(1)] insert.IH(2) by (intro emeasure_mono, blast, simp) 
+        also have "... \<le> emeasure M {y \<in> space M. (\<Sum>x\<in>F. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x) \<noteq> 0} + emeasure M {y \<in> space M. indicat_real (f -` {x} \<inter> space M) y *\<^sub>R x \<noteq> 0}"
+          using simple_functionD(2)[OF insert(6)] simple_functionD(2)[OF f(1)] by (intro emeasure_subadditive, force+)
+        also have "... < \<infinity>" using insert(7) fin_1[OF False] by (simp add: less_top)
+        finally show ?thesis by simp
+      qed
+    next
+      case (4 \<xi>)
+      thus ?case using insert nonneg_x f(3) by (auto simp add: scaleR_nonneg_nonneg intro: sum_nonneg)
+    }
+  qed
+  moreover have "simple_function M (\<lambda>x. \<Sum>y\<in>f ` space M. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)" using calculation by blast
+  moreover have "P (\<lambda>x. \<Sum>y\<in>f ` space M. indicat_real (f -` {y} \<inter> space M) x *\<^sub>R y)" using calculation by blast
+  moreover have "\<And>x. x \<in> space M \<Longrightarrow> 0 \<le> f x" using f(3) by simp
+  ultimately show ?thesis by (intro cong[OF _ _ _ f(1,2)], blast, blast, fast) presburger+
+qed
+
+lemma finite_nn_integral_imp_ae_finite:
+  fixes f :: "'a \<Rightarrow> ennreal"
+  assumes "f \<in> borel_measurable M" "(\<integral>\<^sup>+x. f x \<partial>M) < \<infinity>"
+  shows "AE x in M. f x < \<infinity>"
+proof (rule ccontr, goal_cases)
+  case 1
+  let ?A = "space M \<inter> {x. f x = \<infinity>}"
+  have *: "emeasure M ?A > 0" using 1 assms(1) by (metis (mono_tags, lifting) assms(2) eventually_mono infinity_ennreal_def nn_integral_noteq_infinite top.not_eq_extremum)
+  have "(\<integral>\<^sup>+x. f x * indicator ?A x \<partial>M) = (\<integral>\<^sup>+x. \<infinity> * indicator ?A x \<partial>M)" by (metis (mono_tags, lifting) indicator_inter_arith indicator_simps(2) mem_Collect_eq mult_eq_0_iff)
+  also have "... = \<infinity> * emeasure M ?A" using assms(1) by (intro nn_integral_cmult_indicator, simp)
+  also have "... = \<infinity>" using * by fastforce
+  finally have "(\<integral>\<^sup>+x. f x * indicator ?A x \<partial>M) = \<infinity>" .
+  moreover have "(\<integral>\<^sup>+x. f x * indicator ?A x \<partial>M) \<le> (\<integral>\<^sup>+x. f x \<partial>M)" by (intro nn_integral_mono, simp add: indicator_def)
+  ultimately show ?case using assms(2) by simp
+qed
+
+text \<open>Convergence in L1-Norm implies existence of a subsequence which convergences almost everywhere. 
+      This lemma is easier to use than the existing one in \<^theory>\<open>HOL-Analysis.Bochner_Integration\<close>\<close>
+
+lemma cauchy_L1_AE_cauchy_subseq:
+  fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b::{banach, second_countable_topology}"
+  assumes [measurable]: "\<And>n. integrable M (s n)"
+      and "\<And>e. e > 0 \<Longrightarrow> \<exists>N. \<forall>i\<ge>N. \<forall>j\<ge>N. LINT x|M. norm (s i x - s j x) < e"
+  obtains r where "strict_mono r" "AE x in M. Cauchy (\<lambda>i. s (r i) x)"
+proof-
+  have "\<exists>r. \<forall>n. (\<forall>i\<ge>r n. \<forall>j\<ge> r n. LINT x|M. norm (s i x - s j x) < (1 / 2) ^ n) \<and> (r (Suc n) > r n)"
+  proof (intro dependent_nat_choice, goal_cases)
+    case 1
+    then show ?case using assms(2) by presburger
+  next
+    case (2 x n)
+    obtain N where *: "LINT x|M. norm (s i x - s j x) < (1 / 2) ^ Suc n" if "i \<ge> N" "j \<ge> N" for i j using assms(2)[of "(1 / 2) ^ Suc n"] by auto
+    {
+      fix i j assume "i \<ge> max N (Suc x)" "j \<ge> max N (Suc x)"
+      hence "integral\<^sup>L M (\<lambda>x. norm (s i x - s j x)) < (1 / 2) ^ Suc n" using * by fastforce
+    }
+    then show ?case by fastforce
+  qed
+  then obtain r where strict_mono: "strict_mono r" and "\<forall>i\<ge>r n. \<forall>j\<ge> r n. LINT x|M. norm (s i x - s j x) < (1 / 2) ^ n" for n using strict_mono_Suc_iff by blast
+  hence r_is: "LINT x|M. norm (s (r (Suc n)) x - s (r n) x) < (1 / 2) ^ n" for n by (simp add: strict_mono_leD)
+
+  define g where "g = (\<lambda>n x. (\<Sum>i\<le>n. ennreal (norm (s (r (Suc i)) x - s (r i) x))))"
+  define g' where "g' = (\<lambda>x. \<Sum>i. ennreal (norm (s (r (Suc i)) x - s (r i) x)))"
+
+  have integrable_g: "(\<integral>\<^sup>+ x. g n x \<partial>M) < 2" for n
+  proof -
+    have "(\<integral>\<^sup>+ x. g n x \<partial>M) = (\<integral>\<^sup>+ x. (\<Sum>i\<le>n. ennreal (norm (s (r (Suc i)) x - s (r i) x))) \<partial>M)" using g_def by simp
+    also have "... = (\<Sum>i\<le>n. (\<integral>\<^sup>+ x. ennreal (norm (s (r (Suc i)) x - s (r i) x)) \<partial>M))" by (intro nn_integral_sum, simp)
+    also have "... = (\<Sum>i\<le>n. LINT x|M. norm (s (r (Suc i)) x - s (r i) x))" unfolding dist_norm using assms(1) by (subst nn_integral_eq_integral[OF integrable_norm], auto)
+    also have "... < ennreal (\<Sum>i\<le>n. (1 / 2) ^ i)" by (intro ennreal_lessI[OF sum_pos sum_strict_mono[OF finite_atMost _ r_is]], auto)
+    also have "... \<le> ennreal 2" unfolding sum_gp0[of "1 / 2" n] by (intro ennreal_leI, auto)
+    finally show "(\<integral>\<^sup>+ x. g n x \<partial>M) < 2" by simp
+  qed
+
+  have integrable_g': "(\<integral>\<^sup>+ x. g' x \<partial>M) \<le> 2"
+  proof -
+    have "incseq (\<lambda>n. g n x)" for x by (intro incseq_SucI, auto simp add: g_def ennreal_leI)
+    hence "convergent (\<lambda>n. g n x)" for x unfolding convergent_def using LIMSEQ_incseq_SUP by fast
+    hence "(\<lambda>n. g n x) \<longlonglongrightarrow> g' x" for x unfolding g_def g'_def by (intro summable_iff_convergent'[THEN iffD2, THEN summable_LIMSEQ'], blast)
+    hence "(\<integral>\<^sup>+ x. g' x \<partial>M) = (\<integral>\<^sup>+ x. liminf (\<lambda>n. g n x) \<partial>M)" by (metis lim_imp_Liminf trivial_limit_sequentially)
+    also have "... \<le> liminf (\<lambda>n. \<integral>\<^sup>+ x. g n x \<partial>M)" by (intro nn_integral_liminf, simp add: g_def)
+    also have "... \<le> liminf (\<lambda>n. 2)" using integrable_g by (intro Liminf_mono) (simp add: order_le_less)
+    also have "... = 2" using sequentially_bot tendsto_iff_Liminf_eq_Limsup by blast
+    finally show ?thesis .
+  qed
+  hence "AE x in M. g' x < \<infinity>" by (intro finite_nn_integral_imp_ae_finite) (auto simp add: order_le_less_trans g'_def)
+  moreover have "summable (\<lambda>i. norm (s (r (Suc i)) x - s (r i) x))" if "g' x \<noteq> \<infinity>" for x using that unfolding g'_def by (intro summable_suminf_not_top) fastforce+ 
+  ultimately have ae_summable: "AE x in M. summable (\<lambda>i. s (r (Suc i)) x - s (r i) x)" using summable_norm_cancel unfolding dist_norm by force
+
+  {
+    fix x assume "summable (\<lambda>i. s (r (Suc i)) x - s (r i) x)"
+    hence "(\<lambda>n. \<Sum>i<n. s (r (Suc i)) x - s (r i) x) \<longlonglongrightarrow> (\<Sum>i. s (r (Suc i)) x - s (r i) x)" using summable_LIMSEQ by blast
+    moreover have "(\<lambda>n. (\<Sum>i<n. s (r (Suc i)) x - s (r i) x)) = (\<lambda>n. s (r n) x - s (r 0) x)" using sum_lessThan_telescope by fastforce
+    ultimately have "(\<lambda>n. s (r n) x - s (r 0) x) \<longlonglongrightarrow> (\<Sum>i. s (r (Suc i)) x - s (r i) x)" by argo
+    hence "(\<lambda>n. s (r n) x - s (r 0) x + s (r 0) x) \<longlonglongrightarrow> (\<Sum>i. s (r (Suc i)) x - s (r i) x) + s (r 0) x" by (intro isCont_tendsto_compose[of _ "\<lambda>z. z + s (r 0) x"], auto)
+    hence "Cauchy (\<lambda>n. s (r n) x)" by (simp add: LIMSEQ_imp_Cauchy)
+  }
+  hence "AE x in M. Cauchy (\<lambda>i. s (r i) x)" using ae_summable by fast
+  thus ?thesis by (rule that[OF strict_mono(1)])
+qed
+
+subsection \<open>Totally Ordered Banach Spaces\<close>
+
+lemma integrable_max[simp, intro]:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology}"
+  assumes fg[measurable]: "integrable M f" "integrable M g"
+  shows "integrable M (\<lambda>x. max (f x) (g x))"
+proof (rule Bochner_Integration.integrable_bound)
+  {
+    fix x y :: 'b                                             
+    have "norm (max x y) \<le> max (norm x) (norm y)" by linarith
+    also have "... \<le> norm x + norm y" by simp
+    finally have "norm (max x y) \<le> norm (norm x + norm y)" by simp
+  }
+  thus "AE x in M. norm (max (f x) (g x)) \<le> norm (norm (f x) + norm (g x))" by simp
+qed (auto intro: Bochner_Integration.integrable_add[OF integrable_norm[OF fg(1)] integrable_norm[OF fg(2)]])
+
+lemma integrable_min[simp, intro]:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology}"
+  assumes [measurable]: "integrable M f" "integrable M g"
+  shows "integrable M (\<lambda>x. min (f x) (g x))"
+proof -
+  have "norm (min (f x) (g x)) \<le> norm (f x) \<or> norm (min (f x) (g x)) \<le> norm (g x)" for x by linarith
+  thus ?thesis by (intro integrable_bound[OF integrable_max[OF integrable_norm(1,1), OF assms]], auto)
+qed
+
+text \<open>Restatement of \<open>integral_nonneg_AE\<close> for functions taking values in a Banach space.\<close>
+lemma integral_nonneg_AE_banach:                        
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes [measurable]: "f \<in> borel_measurable M" and nonneg: "AE x in M. 0 \<le> f x"
+  shows "0 \<le> integral\<^sup>L M f"
+proof cases
+  assume integrable: "integrable M f"
+  hence max: "(\<lambda>x. max 0 (f x)) \<in> borel_measurable M" "\<And>x. 0 \<le> max 0 (f x)" "integrable M (\<lambda>x. max 0 (f x))" by auto
+  hence "0 \<le> integral\<^sup>L M (\<lambda>x. max 0 (f x))"
+  proof -
+  obtain s where *: "\<And>i. simple_function M (s i)" 
+                    "\<And>i. emeasure M {y \<in> space M. s i y \<noteq> 0} \<noteq> \<infinity>" 
+                    "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> f x" 
+                    "\<And>x i. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)" using integrable_implies_simple_function_sequence[OF integrable] by blast
+    have simple: "\<And>i. simple_function M (\<lambda>x. max 0 (s i x))" using * by fast
+    have "\<And>i. {y \<in> space M. max 0 (s i y) \<noteq> 0} \<subseteq> {y \<in> space M. s i y \<noteq> 0}" unfolding max_def by force
+    moreover have "\<And>i. {y \<in> space M. s i y \<noteq> 0} \<in> sets M" using * by measurable
+    ultimately have "\<And>i. emeasure M {y \<in> space M. max 0 (s i y) \<noteq> 0} \<le> emeasure M {y \<in> space M. s i y \<noteq> 0}" by (rule emeasure_mono) 
+    hence **:"\<And>i. emeasure M {y \<in> space M. max 0 (s i y) \<noteq> 0} \<noteq> \<infinity>" using *(2) by (auto intro: order.strict_trans1 simp add:  top.not_eq_extremum)
+    have "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. max 0 (s i x)) \<longlonglongrightarrow> max 0 (f x)" using *(3) tendsto_max by blast
+    moreover have "\<And>x i. x \<in> space M \<Longrightarrow> norm (max 0 (s i x)) \<le> norm (2 *\<^sub>R f x)" using *(4) unfolding max_def by auto
+    ultimately have tendsto: "(\<lambda>i. integral\<^sup>L M (\<lambda>x. max 0 (s i x))) \<longlonglongrightarrow> integral\<^sup>L M (\<lambda>x. max 0 (f x))" 
+      using borel_measurable_simple_function simple integrable by (intro integral_dominated_convergence[OF max(1) _ integrable_norm[OF integrable_scaleR_right], of _ 2 f], blast+)
+    {
+      fix h :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}" 
+      assume "simple_function M h" "emeasure M {y \<in> space M. h y \<noteq> 0} \<noteq> \<infinity>" "\<And>x. x \<in> space M \<longrightarrow> h x \<ge> 0"
+      hence *: "integral\<^sup>L M h \<ge> 0"
+      proof (induct rule: integrable_simple_function_induct_nn)
+        case (cong f g)                   
+        then show ?case using Bochner_Integration.integral_cong by force
+      next
+        case (indicator A y)
+        hence "A \<noteq> {} \<Longrightarrow> y \<ge> 0" using sets.sets_into_space by fastforce
+        then show ?case using indicator by (cases "A = {}", auto simp add: scaleR_nonneg_nonneg)
+      next
+        case (add f g)
+        then show ?case by (simp add: integrable_simple_function)
+      qed
+    }
+    thus ?thesis using LIMSEQ_le_const[OF tendsto, of 0] ** simple by fastforce
+  qed
+  also have "\<dots> = integral\<^sup>L M f" using nonneg by (auto intro: integral_cong_AE)
+  finally show ?thesis .
+qed (simp add: not_integrable_integral_eq)
+
+lemma integral_mono_AE_banach:
+  fixes f g :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g" "AE x in M. f x \<le> g x"
+  shows "integral\<^sup>L M f \<le> integral\<^sup>L M g"
+  using integral_nonneg_AE_banach[of "\<lambda>x. g x - f x"] assms Bochner_Integration.integral_diff[OF assms(1,2)] by force
+
+lemma integral_mono_banach:
+  fixes f g :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g" "\<And>x. x \<in> space M \<Longrightarrow> f x \<le> g x"
+  shows "integral\<^sup>L M f \<le> integral\<^sup>L M g"
+  using integral_mono_AE_banach assms by blast
+
+subsection \<open>Integrability and Measurability of the Diameter\<close>
+
+context
+  fixes s :: "nat \<Rightarrow> 'a \<Rightarrow> 'b :: {second_countable_topology, banach}" and M
+  assumes bounded: "\<And>x. x \<in> space M \<Longrightarrow> bounded (range (\<lambda>i. s i x))"
+begin
+
+lemma borel_measurable_diameter: 
+  assumes [measurable]: "\<And>i. (s i) \<in> borel_measurable M"
+  shows "(\<lambda>x. diameter {s i x |i. n \<le> i}) \<in> borel_measurable M"
+proof -
+  have "{s i x |i. N \<le> i} \<noteq> {}" for x N by blast
+  hence diameter_SUP: "diameter {s i x |i. N \<le> i} = (SUP (i, j) \<in> {N..} \<times> {N..}. dist (s i x) (s j x))" for x N unfolding diameter_def by (auto intro!: arg_cong[of _ _ Sup])
+  
+  have "case_prod dist ` ({s i x |i. n \<le> i} \<times> {s i x |i. n \<le> i}) = ((\<lambda>(i, j). dist (s i x) (s j x)) ` ({n..} \<times> {n..}))" for x by fast
+  hence *: "(\<lambda>x. diameter {s i x |i. n \<le> i}) =  (\<lambda>x. Sup ((\<lambda>(i, j). dist (s i x) (s j x)) ` ({n..} \<times> {n..})))" using diameter_SUP by (simp add: case_prod_beta')
+  
+  have "bounded ((\<lambda>(i, j). dist (s i x) (s j x)) ` ({n..} \<times> {n..}))" if "x \<in> space M" for x by (rule bounded_imp_dist_bounded[OF bounded, OF that])
+  hence bdd: "bdd_above ((\<lambda>(i, j). dist (s i x) (s j x)) ` ({n..} \<times> {n..}))" if "x \<in> space M" for x using that bounded_imp_bdd_above by presburger
+  have "fst p \<in> borel_measurable M" "snd p \<in> borel_measurable M" if "p \<in> s ` {n..} \<times> s ` {n..}" for p using that by fastforce+
+  hence "(\<lambda>x. fst p x - snd p x) \<in> borel_measurable M" if "p \<in> s ` {n..} \<times> s ` {n..}" for p using that borel_measurable_diff by simp
+  hence "(\<lambda>x. case p of (f, g) \<Rightarrow> dist (f x) (g x)) \<in> borel_measurable M" if "p \<in> s ` {n..} \<times> s ` {n..}" for p unfolding dist_norm using that by measurable
+  moreover have "countable (s ` {n..} \<times> s ` {n..})" by (intro countable_SIGMA countable_image, auto)
+  ultimately show ?thesis unfolding * by (auto intro!: borel_measurable_cSUP bdd)
+qed
+
+lemma integrable_bound_diameter:
+  fixes f :: "'a \<Rightarrow> real"
+  assumes "integrable M f" 
+      and [measurable]: "\<And>i. (s i) \<in> borel_measurable M"
+      and "\<And>x i. x \<in> space M \<Longrightarrow> norm (s i x) \<le> f x"
+    shows "integrable M (\<lambda>x. diameter {s i x |i. n \<le> i})"
+proof -
+  have "{s i x |i. N \<le> i} \<noteq> {}" for x N by blast
+  hence diameter_SUP: "diameter {s i x |i. N \<le> i} = (SUP (i, j) \<in> {N..} \<times> {N..}. dist (s i x) (s j x))" for x N unfolding diameter_def by (auto intro!: arg_cong[of _ _ Sup])
+  {
+    fix x assume x: "x \<in> space M"
+    let ?S = "(\<lambda>(i, j). dist (s i x) (s j x)) ` ({n..} \<times> {n..})"
+    have "case_prod dist ` ({s i x |i. n \<le> i} \<times> {s i x |i. n \<le> i}) = (\<lambda>(i, j). dist (s i x) (s j x)) ` ({n..} \<times> {n..})" by fast
+    hence *: "diameter {s i x |i. n \<le> i} =  Sup ?S" using diameter_SUP by (simp add: case_prod_beta')
+    
+    have "bounded ?S" by (rule bounded_imp_dist_bounded[OF bounded[OF x]])
+    hence Sup_S_nonneg:"0 \<le> Sup ?S" by (auto intro!: cSup_upper2 x bounded_imp_bdd_above)
+
+    have "dist (s i x) (s j x) \<le>  2 * f x" for i j by (intro dist_triangle2[THEN order_trans, of _ 0]) (metis norm_conv_dist assms(3) x add_mono mult_2)
+    hence "\<forall>c \<in> ?S. c \<le> 2 * f x" by force
+    hence "Sup ?S \<le> 2 * f x" by (intro cSup_least, auto)
+    hence "norm (Sup ?S) \<le> 2 * norm (f x)" using Sup_S_nonneg by auto
+    also have "... = norm (2 *\<^sub>R f x)" by simp
+    finally have "norm (diameter {s i x |i. n \<le> i}) \<le> norm (2 *\<^sub>R f x)" unfolding * .
+  }
+  hence "AE x in M. norm (diameter {s i x |i. n \<le> i}) \<le> norm (2 *\<^sub>R f x)" by blast
+  thus  "integrable M (\<lambda>x. diameter {s i x |i. n \<le> i})" using borel_measurable_diameter by (intro Bochner_Integration.integrable_bound[OF assms(1)[THEN integrable_scaleR_right[of 2]]], measurable)
+qed
+end    
+
+subsection \<open>Auxiliary Lemmas for Set Integrals\<close>
+
+lemma set_integral_scaleR_left: 
+  assumes "A \<in> sets M" "c \<noteq> 0 \<Longrightarrow> integrable M f"
+  shows "LINT t:A|M. f t *\<^sub>R c = (LINT t:A|M. f t) *\<^sub>R c"
+  unfolding set_lebesgue_integral_def 
+  using integrable_mult_indicator[OF assms]
+  by (subst integral_scaleR_left[symmetric], auto)
+
+lemma nn_set_integral_eq_set_integral:
+  assumes [measurable]:"integrable M f"
+      and "AE x \<in> A in M. 0 \<le> f x" "A \<in> sets M"
+    shows "(\<integral>\<^sup>+x\<in>A. f x \<partial>M) = (\<integral> x \<in> A. f x \<partial>M)"
+proof-
+  have "(\<integral>\<^sup>+x. indicator A x *\<^sub>R f x \<partial>M) = (\<integral> x \<in> A. f x \<partial>M)"
+  unfolding set_lebesgue_integral_def using assms(2) by (intro nn_integral_eq_integral[of _ "\<lambda>x. indicat_real A x *\<^sub>R f x"], blast intro: assms integrable_mult_indicator, fastforce)
+  moreover have "(\<integral>\<^sup>+x. indicator A x *\<^sub>R f x \<partial>M) = (\<integral>\<^sup>+x\<in>A. f x \<partial>M)"  by (metis ennreal_0 indicator_simps(1) indicator_simps(2) mult.commute mult_1 mult_zero_left real_scaleR_def)
+  ultimately show ?thesis by argo
+qed
+
+lemma set_integral_restrict_space:
+  fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
+  assumes "\<Omega> \<inter> space M \<in> sets M"
+  shows "set_lebesgue_integral (restrict_space M \<Omega>) A f = set_lebesgue_integral M A (\<lambda>x. indicator \<Omega> x *\<^sub>R f x)"
+  unfolding set_lebesgue_integral_def 
+  by (subst integral_restrict_space, auto intro!: integrable_mult_indicator assms simp: mult.commute)
+
+lemma set_integral_const:
+  fixes c :: "'b::{banach, second_countable_topology}"
+  assumes "A \<in> sets M" "emeasure M A \<noteq> \<infinity>"
+  shows "set_lebesgue_integral M A (\<lambda>_. c) = measure M A *\<^sub>R c"
+  unfolding set_lebesgue_integral_def 
+  using assms by (metis has_bochner_integral_indicator has_bochner_integral_integral_eq infinity_ennreal_def less_top)
+
+lemma set_integral_mono_banach:
+  fixes f g :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "set_integrable M A f" "set_integrable M A g"
+    "\<And>x. x \<in> A \<Longrightarrow> f x \<le> g x"
+  shows "(LINT x:A|M. f x) \<le> (LINT x:A|M. g x)"
+  using assms unfolding set_integrable_def set_lebesgue_integral_def
+  by (auto intro: integral_mono_banach split: split_indicator)
+
+lemma set_integral_mono_AE_banach:
+  fixes f g :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "set_integrable M A f" "set_integrable M A g" "AE x\<in>A in M. f x \<le> g x"
+  shows "set_lebesgue_integral M A f \<le> set_lebesgue_integral M A g" using assms unfolding set_lebesgue_integral_def by (auto simp add: set_integrable_def intro!: integral_mono_AE_banach[of M "\<lambda>x. indicator A x *\<^sub>R f x" "\<lambda>x. indicator A x *\<^sub>R g x"], simp add: indicator_def)
+
+subsection \<open>Averaging Theorem\<close>
+
+text \<open>We aim to lift results from the real case to arbitrary Banach spaces. 
+      Our fundamental tool in this regard will be the averaging theorem. The proof of this theorem is due to Serge Lang (Real and Functional Analysis) \cite{Lang_1993}. 
+      The theorem allows us to make statements about a function’s value almost everywhere, depending on the value its integral takes on various sets of the measure space.\<close>
+
+text \<open>Before we introduce and prove the averaging theorem, we will first show the following lemma which is crucial for our proof. 
+      While not stated exactly in this manner, our proof makes use of the characterization of second-countable topological spaces given in the book General Topology by Ryszard Engelking (Theorem 4.1.15) \cite{engelking_1989}.\<close>
+(* Engelking's book General Topology *)
+lemma balls_countable_basis:
+  obtains D :: "'a :: {metric_space, second_countable_topology} set" 
+  where "topological_basis (case_prod ball ` (D \<times> (\<rat> \<inter> {0<..})))"
+    and "countable D"
+    and "D \<noteq> {}"    
+proof -
+  obtain D :: "'a set" where dense_subset: "countable D" "D \<noteq> {}" "\<lbrakk>open U; U \<noteq> {}\<rbrakk> \<Longrightarrow> \<exists>y \<in> D. y \<in> U" for U using countable_dense_exists by blast
+  have "topological_basis (case_prod ball ` (D \<times> (\<rat> \<inter> {0<..})))"
+  proof (intro topological_basis_iff[THEN iffD2], fast, clarify)
+    fix U and x :: 'a assume asm: "open U" "x \<in> U"
+    obtain e where e: "e > 0" "ball x e \<subseteq> U" using asm openE by blast
+    obtain y where y: "y \<in> D" "y \<in> ball x (e / 3)" using dense_subset(3)[OF open_ball, of x "e / 3"] centre_in_ball[THEN iffD2, OF divide_pos_pos[OF e(1), of 3]] by force
+    obtain r where r: "r \<in> \<rat> \<inter> {e/3<..<e/2}" unfolding Rats_def using of_rat_dense[OF divide_strict_left_mono[OF _ e(1)], of 2 3] by auto
+
+    have *: "x \<in> ball y r" using r y by (simp add: dist_commute)
+    hence "ball y r \<subseteq> U" using r by (intro order_trans[OF _ e(2)], simp, metric)
+    moreover have "ball y r \<in> (case_prod ball ` (D \<times> (\<rat> \<inter> {0<..})))" using y(1) r by force
+    ultimately show "\<exists>B'\<in>(case_prod ball ` (D \<times> (\<rat> \<inter> {0<..}))). x \<in> B' \<and> B' \<subseteq> U" using * by meson
+  qed
+  thus ?thesis using that dense_subset by blast
+qed
+
+context sigma_finite_measure
+begin         
+
+text \<open>To show statements concerning \<open>\<sigma>\<close>-finite measure spaces, one usually shows the statement for finite measure spaces and uses a limiting argument to show it for the \<open>\<sigma>\<close>-finite case.
+      The following induction scheme formalizes this.\<close>
+lemma sigma_finite_measure_induct[case_names finite_measure, consumes 0]:
+  assumes "\<And>(N :: 'a measure) \<Omega>. finite_measure N 
+                              \<Longrightarrow> N = restrict_space M \<Omega>
+                              \<Longrightarrow> \<Omega> \<in> sets M 
+                              \<Longrightarrow> emeasure N \<Omega> \<noteq> \<infinity> 
+                              \<Longrightarrow> emeasure N \<Omega> \<noteq> 0 
+                              \<Longrightarrow> almost_everywhere N Q"
+      and [measurable]: "Measurable.pred M Q"
+  shows "almost_everywhere M Q"
+proof -
+  have *: "almost_everywhere N Q" if "finite_measure N" "N = restrict_space M \<Omega>" "\<Omega> \<in> sets M" "emeasure N \<Omega> \<noteq> \<infinity>" for N \<Omega> using that by (cases "emeasure N \<Omega> = 0", auto intro: emeasure_0_AE assms(1))
+
+  obtain A :: "nat \<Rightarrow> 'a set" where A: "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" and emeasure_finite: "emeasure M (A i) \<noteq> \<infinity>" for i using sigma_finite by metis
+  note A(1)[measurable]
+  have space_restr: "space (restrict_space M (A i)) = A i" for i unfolding space_restrict_space by simp
+  {
+    fix i    
+    have *: "{x \<in> A i \<inter> space M. Q x} = {x \<in> space M. Q x} \<inter> (A i)" by fast
+    have "Measurable.pred (restrict_space M (A i)) Q" using A by (intro measurableI, auto simp add: space_restr intro!: sets_restrict_space_iff[THEN iffD2], measurable, auto)
+  }
+  note this[measurable]
+  {
+    fix i
+    have "finite_measure (restrict_space M (A i))" using emeasure_finite by (intro finite_measureI, subst space_restr, subst emeasure_restrict_space, auto)
+    hence "emeasure (restrict_space M (A i)) {x \<in> A i. \<not>Q x} = 0" using emeasure_finite by (intro AE_iff_measurable[THEN iffD1, OF _ _ *], measurable, subst space_restr[symmetric], intro sets.top, auto simp add: emeasure_restrict_space)
+    hence "emeasure M {x \<in> A i. \<not> Q x} = 0" by (subst emeasure_restrict_space[symmetric], auto)
+  }
+  hence "emeasure M (\<Union>i. {x \<in> A i. \<not> Q x}) = 0" by (intro emeasure_UN_eq_0, auto)
+  moreover have "(\<Union>i. {x \<in> A i. \<not> Q x}) = {x \<in> space M. \<not> Q x}" using A by auto
+  ultimately show ?thesis by (intro AE_iff_measurable[THEN iffD2], auto)
+qed
+
+(* Real Functional Analysis - Lang*)
+text \<open>The Averaging Theorem allows us to make statements concerning how a function behaves almost everywhere, depending on its behaviour on average.\<close>
+lemma averaging_theorem:
+  fixes f::"_ \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes [measurable]:"integrable M f" 
+      and closed: "closed S"
+      and "\<And>A. A \<in> sets M \<Longrightarrow> measure M A > 0 \<Longrightarrow> (1 / measure M A) *\<^sub>R set_lebesgue_integral M A f \<in> S"
+    shows "AE x in M. f x \<in> S"
+proof (induct rule: sigma_finite_measure_induct)
+  case (finite_measure N \<Omega>)
+
+  interpret finite_measure N by (rule finite_measure)
+  
+  have integrable[measurable]: "integrable N f" using assms finite_measure by (auto simp: integrable_restrict_space integrable_mult_indicator)
+  have average: "(1 / Sigma_Algebra.measure N A) *\<^sub>R set_lebesgue_integral N A f \<in> S" if "A \<in> sets N" "measure N A > 0" for A
+  proof -
+    have *: "A \<in> sets M" using that by (simp add: sets_restrict_space_iff finite_measure)
+    have "A = A \<inter> \<Omega>" by (metis finite_measure(2,3) inf.orderE sets.sets_into_space space_restrict_space that(1))
+    hence "set_lebesgue_integral N A f = set_lebesgue_integral M A f" unfolding finite_measure by (subst set_integral_restrict_space, auto simp add: finite_measure set_lebesgue_integral_def indicator_inter_arith[symmetric])
+    moreover have "measure N A = measure M A" using that by (auto intro!: measure_restrict_space simp add: finite_measure sets_restrict_space_iff)
+    ultimately show ?thesis using that * assms(3) by presburger
+  qed
+
+  obtain D :: "'b set" where balls_basis: "topological_basis (case_prod ball ` (D \<times> (\<rat> \<inter> {0<..})))" and countable_D: "countable D" using balls_countable_basis by blast
+  have countable_balls: "countable (case_prod ball ` (D \<times> (\<rat> \<inter> {0<..})))" using countable_rat countable_D by blast
+
+  obtain B where B_balls: "B \<subseteq> case_prod ball ` (D \<times> (\<rat> \<inter> {0<..}))" "\<Union>B = -S" using topological_basis[THEN iffD1, OF balls_basis] open_Compl[OF assms(2)] by meson
+  hence countable_B: "countable B" using countable_balls countable_subset by fast
+
+  define b where "b = from_nat_into (B \<union> {{}})"
+  have "B \<union> {{}} \<noteq> {}" by simp
+  have range_b: "range b = B \<union> {{}}" using countable_B by (auto simp add: b_def intro!: range_from_nat_into)
+  have open_b: "open (b i)" for i unfolding b_def using B_balls open_ball from_nat_into[of "B \<union> {{}}" i] by force
+  have Union_range_b: "\<Union>(range b) = -S" using B_balls range_b by simp
+
+  {
+    fix v r assume ball_in_Compl: "ball v r \<subseteq> -S"
+    define A where "A = f -` ball v r \<inter> space N"
+    have dist_less: "dist (f x) v < r" if "x \<in> A" for x using that unfolding A_def vimage_def by (simp add: dist_commute)
+    hence AE_less: "AE x \<in> A in N. norm (f x - v) < r" by (auto simp add: dist_norm)
+    have *: "A \<in> sets N" unfolding A_def by simp
+    have "emeasure N A = 0" 
+    proof -
+      {
+        assume asm: "emeasure N A > 0"
+        hence measure_pos: "measure N A > 0" unfolding emeasure_eq_measure by simp
+        hence "(1 / measure N A) *\<^sub>R set_lebesgue_integral N A f - v = (1 / measure N A) *\<^sub>R set_lebesgue_integral N A (\<lambda>x. f x - v)" using integrable integrable_const * by (subst set_integral_diff(2), auto simp add: set_integrable_def set_integral_const[OF *] algebra_simps intro!: integrable_mult_indicator)
+        moreover have "norm (\<integral>x\<in>A. (f x - v)\<partial>N) \<le> (\<integral>x\<in>A. norm (f x - v)\<partial>N)" using * by (auto intro!: integral_norm_bound[of N "\<lambda>x. indicator A x *\<^sub>R (f x - v)", THEN order_trans] integrable_mult_indicator integrable simp add: set_lebesgue_integral_def)
+        ultimately have "norm ((1 / measure N A) *\<^sub>R set_lebesgue_integral N A f - v) \<le>  set_lebesgue_integral N A (\<lambda>x. norm (f x - v)) / measure N A" using asm by (auto intro: divide_right_mono)
+        also have "... < set_lebesgue_integral N A (\<lambda>x. r) / measure N A" 
+          unfolding set_lebesgue_integral_def 
+          using asm * integrable integrable_const AE_less measure_pos
+          by (intro divide_strict_right_mono integral_less_AE[of _ _ A] integrable_mult_indicator)
+            (fastforce simp add: dist_less dist_norm indicator_def)+
+        also have "... = r" using * measure_pos by (simp add: set_integral_const)
+        finally have "dist ((1 / measure N A) *\<^sub>R set_lebesgue_integral N A f) v < r" by (subst dist_norm)
+        hence "False" using average[OF * measure_pos] by (metis ComplD dist_commute in_mono mem_ball ball_in_Compl)
+      }
+      thus ?thesis by fastforce
+    qed
+  }
+  note * = this
+  {
+    fix b' assume "b' \<in> B"
+    hence ball_subset_Compl: "b' \<subseteq> -S" and ball_radius_pos: "\<exists>v \<in> D. \<exists>r>0. b' = ball v r" using B_balls by (blast, fast)
+  }
+  note ** = this
+  hence "emeasure N (f -` b i \<inter> space N) = 0" for i by (cases "b i = {}", simp) (metis UnE singletonD  * range_b[THEN eq_refl, THEN range_subsetD])
+  hence "emeasure N (\<Union>i. f -` b i \<inter> space N) = 0" using open_b by (intro emeasure_UN_eq_0) fastforce+
+  moreover have "(\<Union>i. f -` b i \<inter> space N) = f -` (\<Union>(range b)) \<inter> space N" by blast
+  ultimately have "emeasure N (f -` (-S) \<inter> space N) = 0" using Union_range_b by argo
+  hence "AE x in N. f x \<notin> -S" using open_Compl[OF assms(2)] by (intro AE_iff_measurable[THEN iffD2], auto)
+  thus ?case by force
+qed (simp add: pred_sets2[OF borel_closed] assms(2))
+  
+lemma density_zero:
+  fixes f::"'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "integrable M f"
+      and density_0: "\<And>A. A \<in> sets M \<Longrightarrow> set_lebesgue_integral M A f = 0"
+  shows "AE x in M. f x = 0"
+  using averaging_theorem[OF assms(1), of "{0}"] assms(2)
+  by (simp add: scaleR_nonneg_nonneg)
+
+text \<open>The following lemma shows that densities are unique in Banach spaces.\<close>
+lemma density_unique_banach:
+  fixes f f'::"'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "integrable M f" "integrable M f'"
+      and density_eq: "\<And>A. A \<in> sets M \<Longrightarrow> set_lebesgue_integral M A f = set_lebesgue_integral M A f'"
+  shows "AE x in M. f x = f' x"
+proof-
+  { 
+    fix A assume asm: "A \<in> sets M"
+    hence "LINT x|M. indicat_real A x *\<^sub>R (f x - f' x) = 0" using density_eq assms(1,2) by (simp add: set_lebesgue_integral_def algebra_simps Bochner_Integration.integral_diff[OF integrable_mult_indicator(1,1)])
+  }
+  thus ?thesis using density_zero[OF Bochner_Integration.integrable_diff[OF assms(1,2)]] by (simp add: set_lebesgue_integral_def)
+qed
+
+lemma density_nonneg:
+  fixes f::"_ \<Rightarrow> 'b::{second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" 
+      and "\<And>A. A \<in> sets M \<Longrightarrow> set_lebesgue_integral M A f \<ge> 0"
+    shows "AE x in M. f x \<ge> 0"
+  using averaging_theorem[OF assms(1), of "{0..}", OF closed_atLeast] assms(2)
+  by (simp add: scaleR_nonneg_nonneg)
+
+corollary integral_nonneg_eq_0_iff_AE_banach:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes f[measurable]: "integrable M f" and nonneg: "AE x in M. 0 \<le> f x"
+  shows "integral\<^sup>L M f = 0 \<longleftrightarrow> (AE x in M. f x = 0)"
+proof 
+  assume *: "integral\<^sup>L M f = 0"
+  {
+    fix A assume asm: "A \<in> sets M"
+    have "0 \<le> integral\<^sup>L M (\<lambda>x. indicator A x *\<^sub>R f x)" using nonneg by (subst integral_zero[of M, symmetric], intro integral_mono_AE_banach integrable_mult_indicator asm f integrable_zero, auto simp add: indicator_def)
+    moreover have "... \<le> integral\<^sup>L M f" using nonneg by (intro integral_mono_AE_banach integrable_mult_indicator asm f, auto simp add: indicator_def)
+    ultimately have "set_lebesgue_integral M A f = 0" unfolding set_lebesgue_integral_def using * by force
+  }
+  thus "AE x in M. f x = 0" by (intro density_zero f, blast)
+qed (auto simp add: integral_eq_zero_AE)
+
+corollary integral_eq_mono_AE_eq_AE:
+  fixes f g :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g" "integral\<^sup>L M f = integral\<^sup>L M g" "AE x in M. f x \<le> g x" 
+  shows "AE x in M. f x = g x"
+proof -
+  define h where "h = (\<lambda>x. g x - f x)"
+  have "AE x in M. h x = 0" unfolding h_def using assms by (subst integral_nonneg_eq_0_iff_AE_banach[symmetric]) auto
+  then show ?thesis unfolding h_def by auto
+qed
+
+end
+
+end
\ No newline at end of file
diff --git a/thys/Martingales/Conditional_Expectation_Banach.thy b/thys/Martingales/Conditional_Expectation_Banach.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Conditional_Expectation_Banach.thy
@@ -0,0 +1,1048 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Conditional_Expectation_Banach
+  imports "HOL-Probability.Conditional_Expectation" "HOL-Probability.Independent_Family" Bochner_Integration_Supplement
+begin
+
+section \<open>Conditional Expectation in Banach Spaces\<close>
+
+text \<open>While constructing the conditional expectation operator, we have come up with the following approach, which is based on the construction in \cite{Hytoenen_2016}. 
+      Both our approach, and the one in \cite{Hytoenen_2016} are based on showing that the conditional expectation is a contraction on some dense subspace of the space of functions \<open>L\<^sup>1(E)\<close>.
+      In our approach, we start by constructing the conditional expectation explicitly for simple functions. 
+      Then we show that the conditional expectation is a contraction on simple functions, i.e. \<open>\<parallel>E(s|F)(x)\<parallel> \<le> E(\<parallel>s(x)\<parallel>|F)\<close> for \<open>\<mu>\<close>-almost all \<open>x \<in> \<Omega>\<close> with \<open>s : \<Omega> \<rightarrow> E\<close> simple and integrable. 
+      Using this, we can show that the conditional expectation of a convergent sequence of simple functions is again convergent. 
+      Finally, we show that this limit exhibits the properties of a conditional expectation. 
+      This approach has the benefit of being straightforward and easy to implement, since we could make use of the existing formalization for real-valued functions.
+      To use the construction in \cite{Hytoenen_2016} we need more tools from functional analysis, which Isabelle/HOL currently does not have.\<close>
+
+text \<open>Before we can talk about 'the' conditional expectation, we must define what it means for a function to have a conditional expectation.\<close>
+
+definition has_cond_exp :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b::{real_normed_vector, second_countable_topology}) \<Rightarrow> bool" where 
+  "has_cond_exp M F f g = ((\<forall>A \<in> sets F. (\<integral> x \<in> A. f x \<partial>M) = (\<integral> x \<in> A. g x \<partial>M))
+                        \<and> integrable M f 
+                        \<and> integrable M g 
+                        \<and> g \<in> borel_measurable F)"
+
+text \<open>This predicate precisely characterizes what it means for a function \<^term>\<open>f\<close> to have a conditional expectation \<^term>\<open>g\<close>,
+      with respect to the measure \<^term>\<open>M\<close> and the sub-\<open>\<sigma>\<close>-algebra \<^term>\<open>F\<close>.\<close>
+
+lemma has_cond_expI':
+  assumes "\<And>A. A \<in> sets F \<Longrightarrow> (\<integral> x \<in> A. f x \<partial>M) = (\<integral> x \<in> A. g x \<partial>M)"
+          "integrable M f"
+          "integrable M g"
+          "g \<in> borel_measurable F"
+  shows "has_cond_exp M F f g"
+  using assms unfolding has_cond_exp_def by simp
+
+lemma has_cond_expD:
+  assumes "has_cond_exp M F f g"
+  shows "\<And>A. A \<in> sets F \<Longrightarrow> (\<integral> x \<in> A. f x \<partial>M) = (\<integral> x \<in> A. g x \<partial>M)"
+        "integrable M f"
+        "integrable M g"
+        "g \<in> borel_measurable F"
+  using assms unfolding has_cond_exp_def by simp+
+
+text \<open>Now we can use Hilbert’s \<open>\<some>\<close>-operator to define the conditional expectation, if it exists.\<close>
+
+definition cond_exp :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b::{banach, second_countable_topology})" where
+  "cond_exp M F f = (if \<exists>g. has_cond_exp M F f g then (SOME g. has_cond_exp M F f g) else (\<lambda>_. 0))"
+
+lemma borel_measurable_cond_exp[measurable]: "cond_exp M F f \<in> borel_measurable F" 
+  by (metis cond_exp_def someI has_cond_exp_def borel_measurable_const)
+
+lemma integrable_cond_exp[intro]: "integrable M (cond_exp M F f)" 
+  by (metis cond_exp_def has_cond_expD(3) integrable_zero someI)
+
+lemma set_integrable_cond_exp[intro]:
+  assumes "A \<in> sets M"
+  shows "set_integrable M A (cond_exp M F f)" using integrable_mult_indicator[OF assms integrable_cond_exp, of F f] by (auto simp add: set_integrable_def intro!: integrable_mult_indicator[OF assms integrable_cond_exp])
+
+lemma has_cond_exp_self: 
+  assumes "integrable M f"
+  shows "has_cond_exp M (vimage_algebra (space M) f borel) f f"
+  using assms by (auto intro!: has_cond_expI' measurable_vimage_algebra1)
+
+lemma has_cond_exp_sets_cong:
+  assumes "sets F = sets G"
+  shows "has_cond_exp M F = has_cond_exp M G"
+  using assms unfolding has_cond_exp_def by force
+
+lemma cond_exp_sets_cong:
+  assumes "sets F = sets G"
+  shows "AE x in M. cond_exp M F f x = cond_exp M G f x"
+  by (intro AE_I2, simp add: cond_exp_def has_cond_exp_sets_cong[OF assms, of M])
+
+context sigma_finite_subalgebra
+begin
+
+lemma borel_measurable_cond_exp'[measurable]: "cond_exp M F f \<in> borel_measurable M"
+  by (metis cond_exp_def someI has_cond_exp_def borel_measurable_const subalg measurable_from_subalg)
+
+lemma cond_exp_null: 
+  assumes "\<nexists>g. has_cond_exp M F f g" 
+  shows "cond_exp M F f = (\<lambda>_. 0)"
+  unfolding cond_exp_def using assms by argo
+
+text \<open>We state the tower property of the conditional expectation in terms of the predicate \<^term>\<open>has_cond_exp\<close>.\<close>
+
+lemma has_cond_exp_nested_subalg:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "subalgebra G F" "has_cond_exp M F f h" "has_cond_exp M G f h'"
+  shows "has_cond_exp M F h' h"
+  by (intro has_cond_expI') (metis assms has_cond_expD in_mono subalgebra_def)+
+
+text \<open>The following lemma shows that the conditional expectation is unique as an element of L1, given that it exists.\<close>
+
+lemma has_cond_exp_charact:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "has_cond_exp M F f g"
+  shows "has_cond_exp M F f (cond_exp M F f)"
+        "AE x in M. cond_exp M F f x = g x"
+proof -
+  show cond_exp: "has_cond_exp M F f (cond_exp M F f)" using assms someI cond_exp_def by metis
+  let ?MF = "restr_to_subalg M F"
+  interpret sigma_finite_measure ?MF by (rule sigma_fin_subalg)
+  {
+    fix A assume "A \<in> sets ?MF"
+    then have [measurable]: "A \<in> sets F" using sets_restr_to_subalg[OF subalg] by simp
+    have "(\<integral>x \<in> A. g x \<partial>?MF) = (\<integral>x \<in> A. g x \<partial>M)" using assms subalg by (auto simp add: integral_subalgebra2 set_lebesgue_integral_def dest!: has_cond_expD)
+    also have "... = (\<integral>x \<in> A. cond_exp M F f x \<partial>M)" using assms cond_exp by (simp add: has_cond_exp_def)
+    also have "... = (\<integral>x \<in> A. cond_exp M F f x \<partial>?MF)" using subalg by (auto simp add: integral_subalgebra2 set_lebesgue_integral_def)
+    finally have "(\<integral>x \<in> A. g x \<partial>?MF) = (\<integral>x \<in> A. cond_exp M F f x \<partial>?MF)" by simp
+  }
+  hence "AE x in ?MF. cond_exp M F f x = g x" using cond_exp assms subalg by (intro density_unique_banach, auto dest: has_cond_expD intro!: integrable_in_subalg)
+  then show "AE x in M. cond_exp M F f x = g x" using AE_restr_to_subalg[OF subalg] by simp
+qed
+
+corollary cond_exp_charact:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "\<And>A. A \<in> sets F \<Longrightarrow> (\<integral> x \<in> A. f x \<partial>M) = (\<integral> x \<in> A. g x \<partial>M)"
+          "integrable M f"
+          "integrable M g"
+          "g \<in> borel_measurable F"
+    shows "AE x in M. cond_exp M F f x = g x"
+  by (intro has_cond_exp_charact has_cond_expI' assms) auto
+
+text \<open>Identity on F-measurable functions:\<close>
+
+text \<open>If an integrable function \<^term>\<open>f\<close> is already \<^term>\<open>F\<close>-measurable, then \<^term>\<open>cond_exp M F f = f\<close> \<open>\<mu>\<close>-a.e.
+      This is a corollary of the lemma on the characterization of \<^term>\<open>cond_exp\<close>.\<close>
+corollary cond_exp_F_meas[intro, simp]:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "integrable M f"
+          "f \<in> borel_measurable F"
+    shows "AE x in M. cond_exp M F f x = f x"
+  by (rule cond_exp_charact, auto intro: assms)
+
+text \<open>Congruence\<close>
+
+lemma has_cond_exp_cong:
+  assumes "integrable M f" "\<And>x. x \<in> space M \<Longrightarrow> f x = g x" "has_cond_exp M F g h"
+  shows "has_cond_exp M F f h"
+proof (intro has_cond_expI'[OF _ assms(1)])
+  fix A assume asm: "A \<in> sets F"
+  hence "set_lebesgue_integral M A f = set_lebesgue_integral M A g" by (intro set_lebesgue_integral_cong) (meson assms(2) subalg in_mono subalgebra_def sets.sets_into_space subalgebra_def subsetD)+
+  thus "set_lebesgue_integral M A f = set_lebesgue_integral M A h" using asm assms(3) by (simp add: has_cond_exp_def)
+qed (auto simp add: has_cond_expD[OF assms(3)])
+
+lemma cond_exp_cong:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f" "integrable M g" "\<And>x. x \<in> space M \<Longrightarrow> f x = g x"
+  shows "AE x in M. cond_exp M F f x = cond_exp M F g x"
+proof (cases "\<exists>h. has_cond_exp M F f h")
+  case True
+  then obtain h where h: "has_cond_exp M F f h" "has_cond_exp M F g h" using has_cond_exp_cong assms by metis 
+  show ?thesis using h[THEN has_cond_exp_charact(2)] by fastforce
+next
+  case False
+  moreover have "\<nexists>h. has_cond_exp M F g h" using False has_cond_exp_cong assms by auto
+  ultimately show ?thesis unfolding cond_exp_def by auto
+qed
+
+lemma has_cond_exp_cong_AE:
+  assumes "integrable M f" "AE x in M. f x = g x" "has_cond_exp M F g h"
+  shows "has_cond_exp M F f h"
+  using assms(1,2) subalg subalgebra_def subset_iff 
+  by (intro has_cond_expI', subst set_lebesgue_integral_cong_AE[OF _ assms(1)[THEN borel_measurable_integrable] borel_measurable_integrable(1)[OF has_cond_expD(2)[OF assms(3)]]]) 
+     (fast intro: has_cond_expD[OF assms(3)] integrable_cong_AE_imp[OF _ _ AE_symmetric])+
+
+lemma has_cond_exp_cong_AE':
+  assumes "h \<in> borel_measurable F" "AE x in M. h x = h' x" "has_cond_exp M F f h'"
+  shows "has_cond_exp M F f h"
+  using assms(1, 2) subalg subalgebra_def subset_iff
+  using AE_restr_to_subalg2[OF subalg assms(2)] measurable_from_subalg
+  by (intro has_cond_expI' , subst set_lebesgue_integral_cong_AE[OF _ measurable_from_subalg(1,1)[OF subalg], OF _ assms(1) has_cond_expD(4)[OF assms(3)]])
+     (fast intro: has_cond_expD[OF assms(3)] integrable_cong_AE_imp[OF _ _ AE_symmetric])+
+
+lemma cond_exp_cong_AE:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f" "integrable M g" "AE x in M. f x = g x"
+  shows "AE x in M. cond_exp M F f x = cond_exp M F g x"
+proof (cases "\<exists>h. has_cond_exp M F f h")
+  case True
+  then obtain h where h: "has_cond_exp M F f h" "has_cond_exp M F g h" using has_cond_exp_cong_AE assms by (metis (mono_tags, lifting) eventually_mono)
+  show ?thesis using h[THEN has_cond_exp_charact(2)] by fastforce
+next
+  case False
+  moreover have "\<nexists>h. has_cond_exp M F g h" using False has_cond_exp_cong_AE assms by auto
+  ultimately show ?thesis unfolding cond_exp_def by auto
+qed
+
+text \<open>The conditional expectation operator on the reals, \<^term>\<open>real_cond_exp\<close>, satisfies the conditions of the conditional expectation as we have defined it.\<close>
+lemma has_cond_exp_real:
+  fixes f :: "'a \<Rightarrow> real"
+  assumes "integrable M f"
+  shows "has_cond_exp M F f (real_cond_exp M F f)"
+  by (intro has_cond_expI', auto intro!: real_cond_exp_intA assms)
+
+lemma cond_exp_real[intro]:
+  fixes f :: "'a \<Rightarrow> real"
+  assumes "integrable M f"
+  shows "AE x in M. cond_exp M F f x = real_cond_exp M F f x" 
+  using has_cond_exp_charact has_cond_exp_real assms by blast
+
+lemma cond_exp_cmult:
+  fixes f :: "'a \<Rightarrow> real"
+  assumes "integrable M f"
+  shows "AE x in M. cond_exp M F (\<lambda>x. c * f x) x = c * cond_exp M F f x"
+  using real_cond_exp_cmult[OF assms(1), of c] assms(1)[THEN cond_exp_real] assms(1)[THEN integrable_mult_right, THEN cond_exp_real, of c] by fastforce
+
+subsection \<open>Existence\<close>
+
+text \<open>Showing the existence is a bit involved. Specifically, what we aim to show is that \<^term>\<open>has_cond_exp M F f (cond_exp M F f)\<close> holds for any Bochner-integrable \<^term>\<open>f\<close>.
+      We will employ the standard machinery of measure theory. First, we will prove existence for indicator functions. 
+      Then we will extend our proof by linearity to simple functions. 
+      Finally we use a limiting argument to show that the conditional expectation exists for all Bochner-integrable functions.\<close>
+
+text \<open>Indicator functions\<close>
+
+lemma has_cond_exp_indicator:
+  assumes "A \<in> sets M" "emeasure M A < \<infinity>"
+  shows "has_cond_exp M F (\<lambda>x. indicat_real A x *\<^sub>R y) (\<lambda>x. real_cond_exp M F (indicator A) x *\<^sub>R y)"
+proof (intro has_cond_expI', goal_cases)
+  case (1 B)
+  have "\<integral>x\<in>B. (indicat_real A x *\<^sub>R y) \<partial>M  = (\<integral>x\<in>B. indicat_real A x \<partial>M) *\<^sub>R y" using assms by (intro set_integral_scaleR_left, meson 1 in_mono subalg subalgebra_def, blast)
+  also have "... = (\<integral>x\<in>B. real_cond_exp M F (indicator A) x \<partial>M) *\<^sub>R y" using 1 assms by (subst real_cond_exp_intA, auto)
+  also have "... = \<integral>x\<in>B. (real_cond_exp M F (indicator A) x *\<^sub>R y) \<partial>M" using assms by (intro set_integral_scaleR_left[symmetric], meson 1 in_mono subalg subalgebra_def, blast)
+  finally show ?case .
+next
+  case 2
+  show ?case using integrable_scaleR_left integrable_real_indicator assms by blast
+next
+  case 3
+  show ?case using assms by (intro integrable_scaleR_left, intro real_cond_exp_int, blast+)
+next
+  case 4
+  show ?case by (intro borel_measurable_scaleR, intro Conditional_Expectation.borel_measurable_cond_exp, simp)
+qed
+
+lemma cond_exp_indicator[intro]:
+  fixes y :: "'b::{second_countable_topology,banach}"
+  assumes [measurable]: "A \<in> sets M" "emeasure M A < \<infinity>"
+  shows "AE x in M. cond_exp M F (\<lambda>x. indicat_real A x *\<^sub>R y) x = cond_exp M F (indicator A) x *\<^sub>R y"
+proof -
+  have "AE x in M. cond_exp M F (\<lambda>x. indicat_real A x *\<^sub>R y) x = real_cond_exp M F (indicator A) x *\<^sub>R y" using has_cond_exp_indicator[OF assms] has_cond_exp_charact by blast
+  thus ?thesis using cond_exp_real[OF integrable_real_indicator, OF assms] by fastforce
+qed
+
+text \<open>Addition\<close>
+
+lemma has_cond_exp_add:
+  fixes f g :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "has_cond_exp M F f f'" "has_cond_exp M F g g'"
+  shows "has_cond_exp M F (\<lambda>x. f x + g x) (\<lambda>x. f' x + g' x)"
+proof (intro has_cond_expI', goal_cases)
+  case (1 A)
+  have "\<integral>x\<in>A. (f x + g x)\<partial>M = (\<integral>x\<in>A. f x \<partial>M) + (\<integral>x\<in>A. g x \<partial>M)" using assms[THEN has_cond_expD(2)] subalg 1 by (intro set_integral_add(2), auto simp add: subalgebra_def set_integrable_def intro: integrable_mult_indicator)
+  also have "... = (\<integral>x\<in>A. f' x \<partial>M) + (\<integral>x\<in>A. g' x \<partial>M)" using assms[THEN has_cond_expD(1)[OF _ 1]] by argo
+  also have "... = \<integral>x\<in>A. (f' x + g' x)\<partial>M" using assms[THEN has_cond_expD(3)] subalg 1 by (intro set_integral_add(2)[symmetric], auto simp add: subalgebra_def set_integrable_def intro: integrable_mult_indicator)
+  finally show ?case .
+next
+  case 2
+  show ?case by (metis Bochner_Integration.integrable_add assms has_cond_expD(2))
+next
+  case 3
+  show ?case by (metis Bochner_Integration.integrable_add assms has_cond_expD(3))
+next
+  case 4
+  show ?case using assms borel_measurable_add has_cond_expD(4) by blast
+qed
+
+lemma has_cond_exp_scaleR_right:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "has_cond_exp M F f f'"
+  shows "has_cond_exp M F (\<lambda>x. c *\<^sub>R f x) (\<lambda>x. c *\<^sub>R f' x)"
+  using has_cond_expD[OF assms] by (intro has_cond_expI', auto)
+
+lemma cond_exp_scaleR_right:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f"
+  shows "AE x in M. cond_exp M F (\<lambda>x. c *\<^sub>R f x) x = c *\<^sub>R cond_exp M F f x"
+proof (cases "\<exists>f'. has_cond_exp M F f f'")
+  case True
+  then show ?thesis using assms has_cond_exp_charact has_cond_exp_scaleR_right by metis
+next
+  case False
+  show ?thesis
+  proof (cases "c = 0")
+    case True
+    then show ?thesis by simp
+  next
+    case c_nonzero: False
+    have "\<nexists>f'. has_cond_exp M F (\<lambda>x. c *\<^sub>R f x) f'"
+    proof (standard, goal_cases)
+      case 1
+      then obtain f' where f': "has_cond_exp M F (\<lambda>x. c *\<^sub>R f x) f'" by blast
+      have "has_cond_exp M F f (\<lambda>x. inverse c *\<^sub>R f' x)" using has_cond_expD[OF f'] divideR_right[OF c_nonzero] assms by (intro has_cond_expI', auto)
+      then show ?case using False by blast
+    qed
+    then show ?thesis using cond_exp_null[OF False] cond_exp_null by force
+  qed 
+qed
+
+lemma cond_exp_uminus:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f"
+  shows "AE x in M. cond_exp M F (\<lambda>x. - f x) x = - cond_exp M F f x"
+  using cond_exp_scaleR_right[OF assms, of "-1"] by force
+
+text \<open>Together with the induction scheme \<open>integrable_simple_function_induct\<close>, we can show that the conditional expectation of an integrable simple function exists.\<close>
+
+corollary has_cond_exp_simple:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "simple_function M f" "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>"
+  shows "has_cond_exp M F f (cond_exp M F f)"
+  using assms
+proof (induction rule: integrable_simple_function_induct)
+  case (cong f g)
+  then show ?case using has_cond_exp_cong by (metis (no_types, opaque_lifting) Bochner_Integration.integrable_cong has_cond_expD(2) has_cond_exp_charact(1))
+next
+  case (indicator A y)
+  then show ?case using has_cond_exp_charact[OF has_cond_exp_indicator] by fast
+next
+  case (add u v)
+  then show ?case using has_cond_exp_add has_cond_exp_charact(1) by blast
+qed
+
+text \<open>Now comes the most difficult part. Given a convergent sequence of integrable simple functions \<^term>\<open>\<lambda>n. s n\<close>, 
+      we must show that the sequence \<^term>\<open>\<lambda>n. cond_exp M F (s n)\<close> is also convergent. Furthermore, we must show that this limit satisfies the properties of a conditional expectation. 
+      Unfortunately, we will only be able to show that this sequence convergences in the L1-norm. 
+      Luckily, this is enough to show that the operator \<^term>\<open>cond_exp M F\<close> preserves limits as a function from L1 to L1.\<close>
+
+text \<open>In anticipation of this result, we show that the conditional expectation operator is a contraction for simple functions.
+      We first reformulate the lemma \<open>real_cond_exp_abs\<close>, which shows the statement for real-valued functions, using our definitions. 
+      Then we show the statement for simple functions via induction.\<close>
+
+lemma cond_exp_contraction_real:
+  fixes f :: "'a \<Rightarrow> real"
+  assumes integrable[measurable]: "integrable M f"
+  shows "AE x in M. norm (cond_exp M F f x) \<le> cond_exp M F (\<lambda>x. norm (f x)) x"
+proof-
+  have int: "integrable M (\<lambda>x. norm (f x))" using assms by blast
+  have *: "AE x in M. 0 \<le> cond_exp M F (\<lambda>x. norm (f x)) x" using cond_exp_real[THEN AE_symmetric, OF integrable_norm[OF integrable]] real_cond_exp_ge_c[OF integrable_norm[OF integrable], of 0] norm_ge_zero by fastforce
+  have **: "A \<in> sets F \<Longrightarrow> \<integral>x\<in>A. \<bar>f x\<bar> \<partial>M = \<integral>x\<in>A. real_cond_exp M F (\<lambda>x. norm (f x)) x \<partial>M" for A unfolding real_norm_def using assms integrable_abs real_cond_exp_intA by blast
+  
+  have norm_int: "A \<in> sets F \<Longrightarrow> (\<integral>x\<in>A. \<bar>f x\<bar> \<partial>M) = (\<integral>\<^sup>+x\<in>A. \<bar>f x\<bar> \<partial>M)" for A using assms by (intro nn_set_integral_eq_set_integral[symmetric], blast, fastforce) (meson subalg subalgebra_def subsetD)
+  
+  have "AE x in M. real_cond_exp M F (\<lambda>x. norm (f x)) x \<ge> 0" using int real_cond_exp_ge_c by force
+  hence cond_exp_norm_int: "A \<in> sets F \<Longrightarrow> (\<integral>x\<in>A. real_cond_exp M F (\<lambda>x. norm (f x)) x \<partial>M) = (\<integral>\<^sup>+x\<in>A. real_cond_exp M F (\<lambda>x. norm (f x)) x \<partial>M)" for A using assms by (intro nn_set_integral_eq_set_integral[symmetric], blast, fastforce) (meson subalg subalgebra_def subsetD)
+  
+  have "A \<in> sets F \<Longrightarrow> \<integral>\<^sup>+x\<in>A. \<bar>f x\<bar>\<partial>M = \<integral>\<^sup>+x\<in>A. real_cond_exp M F (\<lambda>x. norm (f x)) x \<partial>M" for A using ** norm_int cond_exp_norm_int by (auto simp add: nn_integral_set_ennreal)
+  moreover have "(\<lambda>x. ennreal \<bar>f x\<bar>) \<in> borel_measurable M" by measurable
+  moreover have "(\<lambda>x. ennreal (real_cond_exp M F (\<lambda>x. norm (f x)) x)) \<in> borel_measurable F" by measurable
+  ultimately have "AE x in M. nn_cond_exp M F (\<lambda>x. ennreal \<bar>f x\<bar>) x = real_cond_exp M F (\<lambda>x. norm (f x)) x" by (intro nn_cond_exp_charact[THEN AE_symmetric], auto)
+  hence "AE x in M. nn_cond_exp M F (\<lambda>x. ennreal \<bar>f x\<bar>) x \<le> cond_exp M F (\<lambda>x. norm (f x)) x" using cond_exp_real[OF int] by force
+  moreover have "AE x in M. \<bar>real_cond_exp M F f x\<bar> = norm (cond_exp M F f x)" unfolding real_norm_def using cond_exp_real[OF assms] * by force
+  ultimately have "AE x in M. ennreal (norm (cond_exp M F f x)) \<le> cond_exp M F (\<lambda>x. norm (f x)) x" using real_cond_exp_abs[OF assms[THEN borel_measurable_integrable]] by fastforce
+  hence "AE x in M. enn2real (ennreal (norm (cond_exp M F f x))) \<le> enn2real (cond_exp M F (\<lambda>x. norm (f x)) x)" using ennreal_le_iff2 by force
+  thus ?thesis using * by fastforce
+qed
+
+lemma cond_exp_contraction_simple:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "simple_function M f" "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>"
+  shows "AE x in M. norm (cond_exp M F f x) \<le> cond_exp M F (\<lambda>x. norm (f x)) x"
+  using assms
+proof (induction rule: integrable_simple_function_induct)
+  case (cong f g)
+  hence ae: "AE x in M. f x = g x" by blast
+  hence "AE x in M. cond_exp M F f x = cond_exp M F g x" using cong has_cond_exp_simple by (subst cond_exp_cong_AE) (auto intro!: has_cond_expD(2))
+  hence "AE x in M. norm (cond_exp M F f x) = norm (cond_exp M F g x)" by force
+  moreover have "AE x in M. cond_exp M F (\<lambda>x. norm (f x)) x = cond_exp M F (\<lambda>x. norm (g x)) x"  using ae cong has_cond_exp_simple by (subst cond_exp_cong_AE) (auto dest: has_cond_expD)
+  ultimately show ?case using cong(6) by fastforce
+next
+  case (indicator A y)
+  hence "AE x in M. cond_exp M F (\<lambda>a. indicator A a *\<^sub>R y) x = cond_exp M F (indicator A) x *\<^sub>R y" by blast
+  hence *: "AE x in M. norm (cond_exp M F (\<lambda>a. indicat_real A a *\<^sub>R y) x) \<le> norm y * cond_exp M F (\<lambda>x. norm (indicat_real A x)) x" using cond_exp_contraction_real[OF integrable_real_indicator, OF indicator] by fastforce
+
+  have "AE x in M. norm y * cond_exp M F (\<lambda>x. norm (indicat_real A x)) x = norm y * real_cond_exp M F (\<lambda>x. norm (indicat_real A x)) x" using cond_exp_real[OF integrable_real_indicator, OF indicator] by fastforce
+  moreover have "AE x in M. cond_exp M F (\<lambda>x. norm y * norm (indicat_real A x)) x = real_cond_exp M F (\<lambda>x. norm y * norm (indicat_real A x)) x" using indicator by (intro cond_exp_real, auto)
+  ultimately have "AE x in M. norm y * cond_exp M F (\<lambda>x. norm (indicat_real A x)) x = cond_exp M F (\<lambda>x. norm y * norm (indicat_real A x)) x" using real_cond_exp_cmult[of "\<lambda>x. norm (indicat_real A x)" "norm y"] indicator by fastforce
+  moreover have "(\<lambda>x. norm y * norm (indicat_real A x)) = (\<lambda>x. norm (indicat_real A x *\<^sub>R y))" by force
+  ultimately show ?case using * by force
+next
+  case (add u v)
+  have "AE x in M. norm (cond_exp M F (\<lambda>a. u a + v a) x) = norm (cond_exp M F u x + cond_exp M F v x)" using has_cond_exp_charact(2)[OF has_cond_exp_add, OF has_cond_exp_simple(1,1), OF add(1,2,3,4)] by fastforce
+  moreover have "AE x in M. norm (cond_exp M F u x + cond_exp M F v x) \<le> norm (cond_exp M F u x) + norm (cond_exp M F v x)" using norm_triangle_ineq by blast
+  moreover have "AE x in M. norm (cond_exp M F u x) + norm (cond_exp M F v x) \<le> cond_exp M F (\<lambda>x. norm (u x)) x + cond_exp M F (\<lambda>x. norm (v x)) x" using add(6,7) by fastforce
+  moreover have "AE x in M. cond_exp M F (\<lambda>x. norm (u x)) x + cond_exp M F (\<lambda>x. norm (v x)) x = cond_exp M F (\<lambda>x. norm (u x) + norm (v x)) x" using integrable_simple_function[OF add(1,2)] integrable_simple_function[OF add(3,4)] by (intro has_cond_exp_charact(2)[OF has_cond_exp_add[OF has_cond_exp_charact(1,1)], THEN AE_symmetric], auto intro: has_cond_exp_real)
+  moreover have "AE x in M. cond_exp M F (\<lambda>x. norm (u x) + norm (v x)) x = cond_exp M F (\<lambda>x. norm (u x + v x)) x" using add(5) integrable_simple_function[OF add(1,2)] integrable_simple_function[OF add(3,4)] by (intro cond_exp_cong, auto)
+  ultimately show ?case by force
+qed
+
+lemma has_cond_exp_simple_lim:
+    fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes integrable[measurable]: "integrable M f"
+      and "\<And>i. simple_function M (s i)"
+      and "\<And>i. emeasure M {y \<in> space M. s i y \<noteq> 0} \<noteq> \<infinity>"
+      and "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> f x"
+      and "\<And>x i. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)"
+  obtains r 
+  where "strict_mono r" "has_cond_exp M F f (\<lambda>x. lim (\<lambda>i. cond_exp M F (s (r i)) x))" 
+        "AE x in M. convergent (\<lambda>i. cond_exp M F (s (r i)) x)"
+proof -
+  have [measurable]: "(s i) \<in> borel_measurable M" for i using assms(2) by (simp add: borel_measurable_simple_function)
+  have integrable_s: "integrable M (\<lambda>x. s i x)" for i using assms integrable_simple_function by blast
+  have integrable_4f: "integrable M (\<lambda>x. 4 * norm (f x))" using assms(1) by simp
+  have integrable_2f: "integrable M (\<lambda>x. 2 * norm (f x))" using assms(1) by simp
+  have integrable_2_cond_exp_norm_f: "integrable M (\<lambda>x. 2 * cond_exp M F (\<lambda>x. norm (f x)) x)" by fast
+
+  have "emeasure M {y \<in> space M. s i y - s j y \<noteq> 0} \<le>  emeasure M {y \<in> space M. s i y \<noteq> 0} + emeasure M {y \<in> space M. s j y \<noteq> 0}" for i j using simple_functionD(2)[OF assms(2)] by (intro order_trans[OF emeasure_mono emeasure_subadditive], auto)
+  hence fin_sup: "emeasure M {y \<in> space M. s i y - s j y \<noteq> 0} \<noteq> \<infinity>" for i j using assms(3) by (metis (mono_tags) ennreal_add_eq_top linorder_not_less top.not_eq_extremum infinity_ennreal_def)
+
+  have "emeasure M {y \<in> space M. norm (s i y - s j y) \<noteq> 0} \<le>  emeasure M {y \<in> space M. s i y \<noteq> 0} + emeasure M {y \<in> space M. s j y \<noteq> 0}" for i j using simple_functionD(2)[OF assms(2)] by (intro order_trans[OF emeasure_mono emeasure_subadditive], auto)
+  hence fin_sup_norm: "emeasure M {y \<in> space M. norm (s i y - s j y) \<noteq> 0} \<noteq> \<infinity>" for i j using assms(3) by (metis (mono_tags) ennreal_add_eq_top linorder_not_less top.not_eq_extremum infinity_ennreal_def)
+
+  have Cauchy: "Cauchy (\<lambda>n. s n x)" if "x \<in> space M" for x using assms(4) LIMSEQ_imp_Cauchy that by blast
+  hence bounded_range_s: "bounded (range (\<lambda>n. s n x))" if "x \<in> space M" for x using that cauchy_imp_bounded by fast
+
+  text \<open>Since the sequence \<^term>\<open>(\<lambda>n. s n x)\<close> is Cauchy for almost all \<^term>\<open>x\<close>, we know that the diameter tends to zero almost everywhere.\<close>
+  text \<open>Dominated convergence tells us that the integral of the diameter also converges to zero.\<close>
+  have "AE x in M. (\<lambda>n. diameter {s i x | i. n \<le> i}) \<longlonglongrightarrow> 0" using Cauchy cauchy_iff_diameter_tends_to_zero_and_bounded by fast
+  moreover have "(\<lambda>x. diameter {s i x |i. n \<le> i}) \<in> borel_measurable M" for n using bounded_range_s borel_measurable_diameter by measurable
+  moreover have "AE x in M. norm (diameter {s i x |i. n \<le> i}) \<le> 4 * norm (f x)" for n
+  proof - 
+    {
+      fix x assume x: "x \<in> space M"
+      have "diameter {s i x |i. n \<le> i} \<le> 2 * norm (f x) + 2 * norm (f x)" by (intro diameter_le, blast, subst dist_norm[symmetric], intro dist_triangle3[THEN order_trans, of 0], intro add_mono) (auto intro: assms(5)[OF x])
+      hence "norm (diameter {s i x |i. n \<le> i}) \<le> 4 * norm (f x)" using diameter_ge_0[OF bounded_subset[OF bounded_range_s], OF x, of "{s i x |i. n \<le> i}"] by force
+    }
+    thus ?thesis by fast
+  qed
+  ultimately have diameter_tendsto_zero: "(\<lambda>n. LINT x|M. diameter {s i x | i. n \<le> i}) \<longlonglongrightarrow> 0" by (intro integral_dominated_convergence[OF borel_measurable_const[of 0] _ integrable_4f, simplified]) (fast+)
+  
+  have diameter_integrable: "integrable M (\<lambda>x. diameter {s i x | i. n \<le> i})" for n using assms(1,5) 
+    by (intro integrable_bound_diameter[OF bounded_range_s integrable_2f], auto)
+
+  have dist_integrable: "integrable M (\<lambda>x. dist (s i x) (s j x))" for i j  using assms(5) dist_triangle3[of "s i _" _ 0, THEN order_trans, OF add_mono, of _ "2 * norm (f _)"]
+    by (intro Bochner_Integration.integrable_bound[OF integrable_4f]) fastforce+
+
+  text \<open>Since \<^term>\<open>cond_exp M F\<close> is a contraction for simple functions, the following sequence of integral values is also Cauchy.\<close>
+  text \<open>This follows, since the distance between the terms of this sequence are always less than or equal to the diameter, which itself converges to zero.\<close>
+  text \<open>Hence, we obtain a subsequence which is Cauchy almost everywhere.\<close>
+  have "\<exists>N. \<forall>i\<ge>N. \<forall>j\<ge>N. LINT x|M. norm (cond_exp M F (s i) x - cond_exp M F (s j) x) < e" if e_pos: "e > 0" for e
+  proof -
+    obtain N where *: "LINT x|M. diameter {s i x | i. n \<le> i} < e" if "n \<ge> N" for n using that order_tendsto_iff[THEN iffD1, OF diameter_tendsto_zero, unfolded eventually_sequentially] e_pos by presburger
+    {
+      fix i j x assume asm: "i \<ge> N" "j \<ge> N" "x \<in> space M"
+      have "case_prod dist ` ({s i x |i. N \<le> i} \<times> {s i x |i. N \<le> i}) = case_prod (\<lambda>i j. dist (s i x) (s j x)) ` ({N..} \<times> {N..})" by fast
+      hence "diameter {s i x | i. N \<le> i} = (SUP (i, j) \<in> {N..} \<times> {N..}. dist (s i x) (s j x))" unfolding diameter_def by auto
+      moreover have "(SUP (i, j) \<in> {N..} \<times> {N..}. dist (s i x) (s j x)) \<ge> dist (s i x) (s j x)" using asm bounded_imp_bdd_above[OF bounded_imp_dist_bounded, OF bounded_range_s] by (intro cSup_upper, auto)
+      ultimately have "diameter {s i x | i. N \<le> i} \<ge> dist (s i x) (s j x)" by presburger
+    }
+    hence "LINT x|M. dist (s i x) (s j x) < e" if "i \<ge> N" "j \<ge> N" for i j using that * by (intro integral_mono[OF dist_integrable diameter_integrable, THEN order.strict_trans1], blast+)
+    moreover have "LINT x|M. norm (cond_exp M F (s i) x - cond_exp M F (s j) x) \<le> LINT x|M. dist (s i x) (s j x)" for i j
+    proof -
+      have "LINT x|M. norm (cond_exp M F (s i) x - cond_exp M F (s j) x) = LINT x|M. norm (cond_exp M F (s i) x + - 1 *\<^sub>R cond_exp M F (s j) x)" unfolding dist_norm by simp
+      also have "... = LINT x|M. norm (cond_exp M F (\<lambda>x. s i x - s j x) x)" using has_cond_exp_charact(2)[OF has_cond_exp_add[OF _ has_cond_exp_scaleR_right, OF has_cond_exp_charact(1,1), OF has_cond_exp_simple(1,1)[OF assms(2,3)]], THEN AE_symmetric, of i "-1" j] by (intro integral_cong_AE) force+      
+      also have "... \<le> LINT x|M. cond_exp M F (\<lambda>x. norm (s i x - s j x)) x" using cond_exp_contraction_simple[OF _ fin_sup, of i j] integrable_cond_exp assms(2) by (intro integral_mono_AE, fast+)
+      also have "... = LINT x|M. norm (s i x - s j x)" unfolding set_integral_space(1)[OF integrable_cond_exp, symmetric] set_integral_space[OF dist_integrable[unfolded dist_norm], symmetric] by (intro has_cond_expD(1)[OF has_cond_exp_simple[OF _ fin_sup_norm], symmetric]) (metis assms(2) simple_function_compose1 simple_function_diff, metis sets.top subalg subalgebra_def)
+      finally show ?thesis unfolding dist_norm .  
+    qed
+    ultimately show ?thesis using order.strict_trans1 by meson
+  qed
+  then obtain r where strict_mono_r: "strict_mono r" and AE_Cauchy: "AE x in M. Cauchy (\<lambda>i. cond_exp M F (s (r i)) x)"
+    by (rule cauchy_L1_AE_cauchy_subseq[OF integrable_cond_exp], auto)
+  hence ae_lim_cond_exp: "AE x in M. (\<lambda>n. cond_exp M F (s (r n)) x) \<longlonglongrightarrow> lim (\<lambda>n. cond_exp M F (s (r n)) x)" using Cauchy_convergent_iff convergent_LIMSEQ_iff by fastforce
+
+  text \<open>Now that we have a candidate for the conditional expectation, we must show that it actually has the required properties.\<close>
+
+  text \<open>Dominated convergence shows that this limit is indeed integrable.\<close>
+  text \<open>Here, we again use the fact that conditional expectation is a contraction on simple functions.\<close>
+  have cond_exp_bounded: "AE x in M. norm (cond_exp M F (s (r n)) x) \<le> cond_exp M F (\<lambda>x. 2 * norm (f x)) x" for n
+  proof -
+    have "AE x in M. norm (cond_exp M F (s (r n)) x) \<le> cond_exp M F (\<lambda>x. norm (s (r n) x)) x" by (rule cond_exp_contraction_simple[OF assms(2,3)])
+    moreover have "AE x in M. real_cond_exp M F (\<lambda>x. norm (s (r n) x)) x \<le> real_cond_exp M F (\<lambda>x. 2 * norm (f x)) x" using integrable_s integrable_2f assms(5) by (intro real_cond_exp_mono, auto) 
+    ultimately show ?thesis using cond_exp_real[OF integrable_norm, OF integrable_s, of "r n"] cond_exp_real[OF integrable_2f] by force
+  qed
+  have lim_integrable: "integrable M (\<lambda>x. lim (\<lambda>i. cond_exp M F (s (r i)) x))" by (intro integrable_dominated_convergence[OF _ borel_measurable_cond_exp' integrable_cond_exp ae_lim_cond_exp cond_exp_bounded], simp)
+
+  text \<open>Moreover, we can use the DCT twice to show that the conditional expectation property holds, i.e. the value of the integral of the candidate, agrees with \<^term>\<open>f\<close> on sets \<^term>\<open>A \<in> F\<close>.\<close>
+  {
+    fix A assume A_in_sets_F: "A \<in> sets F"
+    have "AE x in M. norm (indicator A x *\<^sub>R cond_exp M F (s (r n)) x) \<le> cond_exp M F (\<lambda>x. 2 * norm (f x)) x" for n
+    proof -
+      have "AE x in M. norm (indicator A x *\<^sub>R cond_exp M F (s (r n)) x) \<le> norm (cond_exp M F (s (r n)) x)" unfolding indicator_def by simp
+      thus ?thesis using cond_exp_bounded[of n] by force
+    qed
+    hence lim_cond_exp_int: "(\<lambda>n. LINT x:A|M. cond_exp M F (s (r n)) x) \<longlonglongrightarrow> LINT x:A|M. lim (\<lambda>n. cond_exp M F (s (r n)) x)" 
+      using ae_lim_cond_exp measurable_from_subalg[OF subalg borel_measurable_indicator, OF A_in_sets_F] cond_exp_bounded
+      unfolding set_lebesgue_integral_def
+      by (intro integral_dominated_convergence[OF borel_measurable_scaleR borel_measurable_scaleR integrable_cond_exp]) (fastforce simp add: tendsto_scaleR)+
+
+    have "AE x in M. norm (indicator A x *\<^sub>R s (r n) x) \<le> 2 * norm (f x)" for n
+    proof -
+      have "AE x in M. norm (indicator A x *\<^sub>R s (r n) x) \<le> norm (s (r n) x)" unfolding indicator_def by simp
+      thus ?thesis using assms(5)[of _ "r n"] by fastforce
+    qed
+    hence lim_s_int: "(\<lambda>n. LINT x:A|M. s (r n) x) \<longlonglongrightarrow> LINT x:A|M. f x"
+      using measurable_from_subalg[OF subalg borel_measurable_indicator, OF A_in_sets_F] LIMSEQ_subseq_LIMSEQ[OF assms(4) strict_mono_r] assms(5)
+      unfolding set_lebesgue_integral_def comp_def
+      by (intro integral_dominated_convergence[OF borel_measurable_scaleR borel_measurable_scaleR integrable_2f]) (fastforce simp add: tendsto_scaleR)+
+
+    have "LINT x:A|M. lim (\<lambda>n. cond_exp M F (s (r n)) x) = lim (\<lambda>n. LINT x:A|M. cond_exp M F (s (r n)) x)" using limI[OF lim_cond_exp_int] by argo
+    also have "... = lim (\<lambda>n. LINT x:A|M. s (r n) x)" using has_cond_expD(1)[OF has_cond_exp_simple[OF assms(2,3)] A_in_sets_F, symmetric] by presburger
+    also have "... = LINT x:A|M. f x" using limI[OF lim_s_int] by argo
+    finally have "LINT x:A|M. lim (\<lambda>n. cond_exp M F (s (r n)) x) = LINT x:A|M. f x" .
+  }
+  text \<open>Putting it all together, we have the statement we are looking for.\<close>
+  hence "has_cond_exp M F f (\<lambda>x. lim (\<lambda>i. cond_exp M F (s (r i)) x))" using assms(1) lim_integrable by (intro has_cond_expI', auto) 
+  thus thesis using AE_Cauchy Cauchy_convergent strict_mono_r by (auto intro!: that)
+qed
+
+text \<open>Now, we can show that the conditional expectation is well-defined for all integrable functions.\<close>
+corollary has_cond_expI:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f"
+  shows "has_cond_exp M F f (cond_exp M F f)"
+proof -
+  obtain s where s_is: "\<And>i. simple_function M (s i)" "\<And>i. emeasure M {y \<in> space M. s i y \<noteq> 0} \<noteq> \<infinity>" "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> f x" "\<And>x i. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)" using integrable_implies_simple_function_sequence[OF assms] by blast
+  show ?thesis using has_cond_exp_simple_lim[OF assms s_is] has_cond_exp_charact(1) by metis
+qed
+
+subsection \<open>Properties\<close>
+
+text \<open>The defining property of the conditional expectation now always holds, given that the function \<^term>\<open>f\<close> is integrable.\<close>
+
+lemma cond_exp_set_integral:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f" "A \<in> sets F"
+  shows "(\<integral> x \<in> A. f x \<partial>M) = (\<integral> x \<in> A. cond_exp M F f x \<partial>M)"
+  using has_cond_expD(1)[OF has_cond_expI, OF assms] by argo
+
+(* Tower Property *)
+
+text \<open>The following property of the conditional expectation is called the "Tower Property".\<close>
+
+lemma cond_exp_nested_subalg:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f" "subalgebra M G" "subalgebra G F"
+  shows "AE \<xi> in M. cond_exp M F f \<xi> = cond_exp M F (cond_exp M G f) \<xi>"
+  using has_cond_expI assms sigma_finite_subalgebra_def by (auto intro!: has_cond_exp_nested_subalg[THEN has_cond_exp_charact(2), THEN AE_symmetric] sigma_finite_subalgebra.has_cond_expI[OF sigma_finite_subalgebra.intro[OF assms(2)]] nested_subalg_is_sigma_finite)
+
+(* Linearity *)
+
+text \<open>The conditional expectation is linear.\<close>
+
+lemma cond_exp_add:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology,banach}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE x in M. cond_exp M F (\<lambda>x. f x + g x) x = cond_exp M F f x + cond_exp M F g x"
+  using has_cond_exp_add[OF has_cond_expI(1,1), OF assms, THEN has_cond_exp_charact(2)] .
+
+lemma cond_exp_diff:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE x in M. cond_exp M F (\<lambda>x. f x - g x) x = cond_exp M F f x - cond_exp M F g x"
+  using has_cond_exp_add[OF _ has_cond_exp_scaleR_right, OF has_cond_expI(1,1), OF assms, THEN has_cond_exp_charact(2), of "-1"] by simp
+
+lemma cond_exp_diff':
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE x in M. cond_exp M F (f - g) x = cond_exp M F f x - cond_exp M F g x"
+  unfolding fun_diff_def using assms by (rule cond_exp_diff)
+
+lemma cond_exp_scaleR_left:
+  fixes f :: "'a \<Rightarrow> real"
+  assumes "integrable M f"
+  shows "AE x in M. cond_exp M F (\<lambda>x. f x *\<^sub>R c) x = cond_exp M F f x *\<^sub>R c" 
+  using cond_exp_set_integral[OF assms] subalg assms unfolding subalgebra_def
+  by (intro cond_exp_charact,
+      subst set_integral_scaleR_left, blast, intro assms, 
+      subst set_integral_scaleR_left, blast, intro integrable_cond_exp)
+      auto
+
+text \<open>The conditional expectation operator is a contraction, i.e. a bounded linear operator with operator norm less than or equal to 1.\<close>
+text \<open>To show this we first obtain a subsequence \<^term>\<open>\<lambda>x. (\<lambda>i. s (r i) x)\<close>, such that \<^term>\<open>(\<lambda>i. cond_exp M F (s (r i)) x)\<close> converges to \<^term>\<open>cond_exp M F f x\<close> a.e. 
+      Afterwards, we obtain a sub-subsequence \<^term>\<open>\<lambda>x. (\<lambda>i. s (r (r' i)) x)\<close>, such that  \<^term>\<open>(\<lambda>i. cond_exp M F (\<lambda>x. norm (s (r i))) x)\<close> converges to \<^term>\<open>cond_exp M F (\<lambda>x. norm (f x)) x\<close> a.e.
+      Finally, we show that the inequality holds by showing that the terms of the subsequences obey the inequality and the fact that a subsequence of a convergent sequence converges to the same limit.\<close>
+
+lemma cond_exp_contraction:
+  fixes f :: "'a \<Rightarrow> 'b::{second_countable_topology, banach}"
+  assumes "integrable M f"
+  shows "AE x in M. norm (cond_exp M F f x) \<le> cond_exp M F (\<lambda>x. norm (f x)) x" 
+proof -
+  obtain s where s: "\<And>i. simple_function M (s i)" "\<And>i. emeasure M {y \<in> space M. s i y \<noteq> 0} \<noteq> \<infinity>" "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> f x" "\<And>i x. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)" 
+    by (blast intro: integrable_implies_simple_function_sequence[OF assms])
+
+  obtain r where r: "strict_mono r" and "has_cond_exp M F f (\<lambda>x. lim (\<lambda>i. cond_exp M F (s (r i)) x))" "AE x in M. (\<lambda>i. cond_exp M F (s (r i)) x) \<longlonglongrightarrow> lim (\<lambda>i. cond_exp M F (s (r i)) x)"
+    using has_cond_exp_simple_lim[OF assms s] unfolding convergent_LIMSEQ_iff by blast
+  hence r_tendsto: "AE x in M. (\<lambda>i. cond_exp M F (s (r i)) x) \<longlonglongrightarrow> cond_exp M F f x" using has_cond_exp_charact(2) by force
+
+  have norm_s_r: "\<And>i. simple_function M (\<lambda>x. norm (s (r i) x))" "\<And>i. emeasure M {y \<in> space M. norm (s (r i) y) \<noteq> 0} \<noteq> \<infinity>" "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. norm (s (r i) x)) \<longlonglongrightarrow> norm (f x)" "\<And>i x. x \<in> space M \<Longrightarrow> norm (norm (s (r i) x)) \<le> 2 * norm (norm (f x))" 
+    using s by (auto intro: LIMSEQ_subseq_LIMSEQ[OF tendsto_norm r, unfolded comp_def] simple_function_compose1) 
+  
+  obtain r' where r': "strict_mono r'" and "has_cond_exp M F (\<lambda>x. norm (f x)) (\<lambda>x. lim (\<lambda>i. cond_exp M F (\<lambda>x. norm (s (r (r' i)) x)) x))" "AE x in M. (\<lambda>i. cond_exp M F (\<lambda>x. norm (s (r (r' i)) x)) x) \<longlonglongrightarrow> lim (\<lambda>i. cond_exp M F (\<lambda>x. norm (s (r (r' i)) x)) x)" using has_cond_exp_simple_lim[OF integrable_norm norm_s_r, OF assms] unfolding convergent_LIMSEQ_iff by blast
+  hence r'_tendsto: "AE x in M. (\<lambda>i. cond_exp M F (\<lambda>x. norm (s (r (r' i)) x)) x) \<longlonglongrightarrow> cond_exp M F (\<lambda>x. norm (f x)) x" using has_cond_exp_charact(2) by force
+
+  have "AE x in M. \<forall>i. norm (cond_exp M F (s (r (r' i))) x) \<le> cond_exp M F (\<lambda>x. norm (s (r (r' i)) x)) x" using s by (auto intro: cond_exp_contraction_simple simp add: AE_all_countable)
+  moreover have "AE x in M. (\<lambda>i. norm (cond_exp M F (s (r (r' i))) x)) \<longlonglongrightarrow> norm (cond_exp M F f x)" using r_tendsto LIMSEQ_subseq_LIMSEQ[OF tendsto_norm r', unfolded comp_def] by fast
+  ultimately show ?thesis using LIMSEQ_le r'_tendsto by fast
+qed
+
+text \<open>The following lemmas are called "pulling out whats known". We first show the statement for real-valued functions using the lemma \<open>real_cond_exp_intg\<close>, which is already present.
+      We then show it for arbitrary \<^term>\<open>g\<close> using the lecture notes of Gordan Zitkovic for the course "Theory of Probability I" \cite{Zitkovic_2015}.\<close>
+
+lemma cond_exp_measurable_mult:
+  fixes f g :: "'a \<Rightarrow> real"
+  assumes [measurable]: "integrable M (\<lambda>x. f x * g x)" "integrable M g" "f \<in> borel_measurable F" 
+  shows "integrable M (\<lambda>x. f x * cond_exp M F g x)"
+        "AE x in M. cond_exp M F (\<lambda>x. f x * g x) x = f x * cond_exp M F g x"
+proof-
+  show integrable: "integrable M (\<lambda>x. f x * cond_exp M F g x)" using cond_exp_real[OF assms(2)] by (intro integrable_cong_AE_imp[OF real_cond_exp_intg(1), OF assms(1,3) assms(2)[THEN borel_measurable_integrable]] measurable_from_subalg[OF subalg]) auto
+  interpret sigma_finite_measure "restr_to_subalg M F" by (rule sigma_fin_subalg)
+  {
+    fix A assume asm: "A \<in> sets F"
+    hence asm': "A \<in> sets M" using subalg by (fastforce simp add: subalgebra_def)
+    have "set_lebesgue_integral M A (cond_exp M F (\<lambda>x. f x * g x)) = set_lebesgue_integral M A (\<lambda>x. f x * g x)" by (simp add: cond_exp_set_integral[OF assms(1) asm])
+    also have "... = set_lebesgue_integral M A (\<lambda>x. f x * real_cond_exp M F g x)" using borel_measurable_times[OF borel_measurable_indicator[OF asm] assms(3)] borel_measurable_integrable[OF assms(2)] integrable_mult_indicator[OF asm' assms(1)] by (fastforce simp add: set_lebesgue_integral_def mult.assoc[symmetric] intro: real_cond_exp_intg(2)[symmetric])
+    also have "... = set_lebesgue_integral M A (\<lambda>x. f x * cond_exp M F g x)" using cond_exp_real[OF assms(2)] asm' borel_measurable_cond_exp' borel_measurable_cond_exp2 measurable_from_subalg[OF subalg assms(3)] by (auto simp add: set_lebesgue_integral_def intro: integral_cong_AE)
+    finally have "set_lebesgue_integral M A (cond_exp M F (\<lambda>x. f x * g x)) = \<integral>x\<in>A. (f x * cond_exp M F g x)\<partial>M" .
+  }
+  hence "AE x in restr_to_subalg M F. cond_exp M F (\<lambda>x. f x * g x) x = f x * cond_exp M F g x" by (intro density_unique_banach integrable_cond_exp integrable integrable_in_subalg subalg, measurable, simp add: set_lebesgue_integral_def integral_subalgebra2[OF subalg] sets_restr_to_subalg[OF subalg])
+  thus "AE x in M. cond_exp M F (\<lambda>x. f x * g x) x = f x * cond_exp M F g x" by (rule AE_restr_to_subalg[OF subalg])
+qed
+
+lemma cond_exp_measurable_scaleR:
+  fixes f :: "'a \<Rightarrow> real" and g :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes [measurable]: "integrable M (\<lambda>x. f x *\<^sub>R g x)" "integrable M g" "f \<in> borel_measurable F"
+  shows "integrable M (\<lambda>x. f x *\<^sub>R cond_exp M F g x)"
+        "AE x in M. cond_exp M F (\<lambda>x. f x *\<^sub>R g x) x = f x *\<^sub>R cond_exp M F g x"
+proof -
+  let ?F = "restr_to_subalg M F"
+  have subalg': "subalgebra M (restr_to_subalg M F)" by (metis sets_eq_imp_space_eq sets_restr_to_subalg subalg subalgebra_def)
+  {
+    fix z assume asm[measurable]: "integrable M (\<lambda>x. z x *\<^sub>R g x)" "z \<in> borel_measurable ?F"
+    hence asm'[measurable]: "z \<in> borel_measurable F" using measurable_in_subalg' subalg by blast
+    have "integrable M (\<lambda>x. z x *\<^sub>R cond_exp M F g x)" "LINT x|M. z x *\<^sub>R g x = LINT x|M. z x *\<^sub>R cond_exp M F g x"
+    proof -
+      obtain s where s_is: "\<And>i. simple_function ?F (s i)" "\<And>x. x \<in> space ?F \<Longrightarrow> (\<lambda>i. s i x) \<longlonglongrightarrow> z x" "\<And>i x. x \<in> space ?F \<Longrightarrow> norm (s i x) \<le> 2 * norm (z x)" using borel_measurable_implies_sequence_metric[OF asm(2), of 0] by force
+
+      text \<open>We need to apply the dominated convergence theorem twice, therefore we need to show the following prerequisites.\<close>
+
+      have s_scaleR_g_tendsto: "AE x in M. (\<lambda>i. s i x *\<^sub>R g x) \<longlonglongrightarrow> z x *\<^sub>R g x" using s_is(2) by (simp add: space_restr_to_subalg tendsto_scaleR)
+      have s_scaleR_cond_exp_g_tendsto: "AE x in ?F. (\<lambda>i. s i x *\<^sub>R cond_exp M F g x) \<longlonglongrightarrow> z x *\<^sub>R cond_exp M F g x" using s_is(2) by (simp add: tendsto_scaleR)
+
+      have s_scaleR_g_meas: "(\<lambda>x. s i x *\<^sub>R g x) \<in> borel_measurable M" for i using s_is(1)[THEN borel_measurable_simple_function, THEN subalg'[THEN measurable_from_subalg]] by simp
+      have s_scaleR_cond_exp_g_meas: "(\<lambda>x. s i x *\<^sub>R cond_exp M F g x) \<in> borel_measurable ?F" for i using s_is(1)[THEN borel_measurable_simple_function] measurable_in_subalg[OF subalg borel_measurable_cond_exp] by (fastforce intro: borel_measurable_scaleR)
+
+      have s_scaleR_g_AE_bdd: "AE x in M. norm (s i x *\<^sub>R g x) \<le> 2 * norm (z x *\<^sub>R g x)" for i using s_is(3) by (fastforce simp add: space_restr_to_subalg mult.assoc[symmetric] mult_right_mono)
+      {
+        fix i
+        have asm: "integrable M (\<lambda>x. norm (z x) * norm (g x))" using asm(1)[THEN integrable_norm] by simp
+        have "AE x in ?F. norm (s i x *\<^sub>R cond_exp M F g x) \<le> 2 * norm (z x) * norm (cond_exp M F g x)" using s_is(3) by (fastforce simp add: mult_mono)
+        moreover have "AE x in ?F. norm (z x) * cond_exp M F (\<lambda>x. norm (g x)) x = cond_exp M F (\<lambda>x. norm (z x) * norm (g x)) x" by (rule cond_exp_measurable_mult(2)[THEN AE_symmetric, OF asm integrable_norm, OF assms(2), THEN AE_restr_to_subalg2[OF subalg]], auto)
+        ultimately have "AE x in ?F. norm (s i x *\<^sub>R cond_exp M F g x) \<le> 2 * cond_exp M F (\<lambda>x. norm (z x *\<^sub>R g x)) x" using cond_exp_contraction[OF assms(2), THEN AE_restr_to_subalg2[OF subalg]] order_trans[OF _ mult_mono] by fastforce
+      }
+      note s_scaleR_cond_exp_g_AE_bdd = this
+
+      text \<open>In the following section we need to pay attention to which measures we are using for integration. The rhs is F-measurable while the lhs is only M-measurable.\<close>
+
+      {
+        fix i
+        have s_meas_M[measurable]: "s i \<in> borel_measurable M" by (meson borel_measurable_simple_function measurable_from_subalg s_is(1) subalg')
+        have s_meas_F[measurable]: "s i \<in> borel_measurable F" by (meson borel_measurable_simple_function measurable_in_subalg' s_is(1) subalg)
+
+        have s_scaleR_eq: "s i x *\<^sub>R h x = (\<Sum>y\<in>s i ` space M. (indicator (s i -` {y} \<inter> space M) x *\<^sub>R y) *\<^sub>R h x)" if "x \<in> space M" for x and h :: "'a \<Rightarrow> 'b" using simple_function_indicator_representation[OF s_is(1), of x i] that unfolding space_restr_to_subalg scaleR_left.sum[of _ _ "h x", symmetric] by presburger
+        
+        have "LINT x|M. s i x *\<^sub>R g x = LINT x|M. (\<Sum>y\<in>s i ` space M. indicator (s i -` {y} \<inter> space M) x *\<^sub>R y *\<^sub>R g x)" using s_scaleR_eq by (intro Bochner_Integration.integral_cong) auto
+        also have "... = (\<Sum>y\<in>s i ` space M. LINT x|M. indicator (s i -` {y} \<inter> space M) x *\<^sub>R y *\<^sub>R g x)" by (intro Bochner_Integration.integral_sum integrable_mult_indicator[OF _ integrable_scaleR_right] assms(2)) simp
+        also have "... = (\<Sum>y\<in>s i ` space M.  y *\<^sub>R set_lebesgue_integral M (s i -` {y} \<inter> space M) g)" by (simp only: set_lebesgue_integral_def[symmetric]) simp
+        also have "... = (\<Sum>y\<in>s i ` space M.  y *\<^sub>R set_lebesgue_integral M (s i -` {y} \<inter> space M) (cond_exp M F g))" using assms(2) subalg borel_measurable_vimage[OF s_meas_F] by (subst cond_exp_set_integral, auto simp add: subalgebra_def) 
+        also have "... = (\<Sum>y\<in>s i ` space M. LINT x|M. indicator (s i -` {y} \<inter> space M) x *\<^sub>R y *\<^sub>R cond_exp M F g x)" by (simp only: set_lebesgue_integral_def[symmetric]) simp
+        also have "... = LINT x|M. (\<Sum>y\<in>s i ` space M. indicator (s i -` {y} \<inter> space M) x *\<^sub>R y *\<^sub>R cond_exp M F g x)" by (intro Bochner_Integration.integral_sum[symmetric] integrable_mult_indicator[OF _ integrable_scaleR_right]) auto
+        also have "... = LINT x|M. s i x *\<^sub>R cond_exp M F g x" using s_scaleR_eq by (intro Bochner_Integration.integral_cong) auto
+        finally have "LINT x|M. s i x *\<^sub>R g x = LINT x|?F. s i x *\<^sub>R cond_exp M F g x" by (simp add: integral_subalgebra2[OF subalg])
+      }
+      note integral_s_eq = this
+
+      text \<open>Now we just plug in the results we obtained into DCT, and use the fact that limits are unique.\<close>
+
+      show "integrable M (\<lambda>x. z x *\<^sub>R cond_exp M F g x)" using s_scaleR_cond_exp_g_meas asm(2) borel_measurable_cond_exp' by (intro integrable_from_subalg[OF subalg] integrable_cond_exp integrable_dominated_convergence[OF _ _ _ s_scaleR_cond_exp_g_tendsto s_scaleR_cond_exp_g_AE_bdd]) (auto intro: measurable_from_subalg[OF subalg] integrable_in_subalg measurable_in_subalg subalg)
+         
+      have "(\<lambda>i. LINT x|M. s i x *\<^sub>R g x) \<longlonglongrightarrow> LINT x|M. z x *\<^sub>R g x" using s_scaleR_g_meas asm(1)[THEN integrable_norm] asm' borel_measurable_cond_exp' by (intro integral_dominated_convergence[OF _ _ _ s_scaleR_g_tendsto s_scaleR_g_AE_bdd]) (auto intro: measurable_from_subalg[OF subalg])
+      moreover have "(\<lambda>i. LINT x|?F. s i x *\<^sub>R cond_exp M F g x) \<longlonglongrightarrow> LINT x|?F. z x *\<^sub>R cond_exp M F g x" using s_scaleR_cond_exp_g_meas asm(2) borel_measurable_cond_exp' by (intro integral_dominated_convergence[OF _ _ _ s_scaleR_cond_exp_g_tendsto s_scaleR_cond_exp_g_AE_bdd]) (auto intro: measurable_from_subalg[OF subalg] integrable_in_subalg measurable_in_subalg subalg)
+      ultimately show "LINT x|M. z x *\<^sub>R g x = LINT x|M. z x *\<^sub>R cond_exp M F g x" using integral_s_eq using subalg by (simp add: LIMSEQ_unique integral_subalgebra2)
+    qed
+  }
+  note * = this
+
+  text \<open>The main statement now follows with \<^term>\<open>z = (\<lambda>x. indicator A x * f x)\<close>.\<close>
+  show "integrable M (\<lambda>x. f x *\<^sub>R cond_exp M F g x)" using * assms measurable_in_subalg[OF subalg] by blast
+
+  {
+    fix A assume asm: "A \<in> F"
+    hence "integrable M (\<lambda>x. indicat_real A x *\<^sub>R f x *\<^sub>R g x)" using subalg by (fastforce simp add: subalgebra_def intro!: integrable_mult_indicator assms(1))
+    hence "set_lebesgue_integral M A (\<lambda>x. f x *\<^sub>R g x) = set_lebesgue_integral M A (\<lambda>x. f x *\<^sub>R cond_exp M F g x)" unfolding set_lebesgue_integral_def using asm by (auto intro!: * measurable_in_subalg[OF subalg])
+  }
+  thus "AE x in M. cond_exp M F (\<lambda>x. f x *\<^sub>R g x) x = f x *\<^sub>R cond_exp M F g x" using borel_measurable_cond_exp by (intro cond_exp_charact, auto intro!: * assms measurable_in_subalg[OF subalg])
+qed
+
+lemma cond_exp_sum [intro, simp]:
+  fixes f :: "'t \<Rightarrow> 'a \<Rightarrow> 'b :: {second_countable_topology,banach}"
+  assumes [measurable]: "\<And>i. integrable M (f i)"
+  shows "AE x in M. cond_exp M F (\<lambda>x. \<Sum>i\<in>I. f i x) x = (\<Sum>i\<in>I. cond_exp M F (f i) x)"
+proof (rule has_cond_exp_charact, intro has_cond_expI')
+  fix A assume [measurable]: "A \<in> sets F"
+  then have A_meas [measurable]: "A \<in> sets M" by (meson subsetD subalg subalgebra_def)
+
+  have "(\<integral>x\<in>A. (\<Sum>i\<in>I. f i x)\<partial>M) = (\<integral>x. (\<Sum>i\<in>I. indicator A x *\<^sub>R f i x)\<partial>M)" unfolding set_lebesgue_integral_def by (simp add: scaleR_sum_right)
+  also have "... = (\<Sum>i\<in>I. (\<integral>x. indicator A x *\<^sub>R f i x \<partial>M))" using assms by (auto intro!: Bochner_Integration.integral_sum integrable_mult_indicator)
+  also have "... = (\<Sum>i\<in>I. (\<integral>x. indicator A x *\<^sub>R cond_exp M F (f i) x \<partial>M))" using cond_exp_set_integral[OF assms] by (simp add: set_lebesgue_integral_def)
+  also have "... = (\<integral>x. (\<Sum>i\<in>I. indicator A x *\<^sub>R cond_exp M F (f i) x)\<partial>M)" using assms by (auto intro!: Bochner_Integration.integral_sum[symmetric] integrable_mult_indicator)
+  also have "... = (\<integral>x\<in>A. (\<Sum>i\<in>I. cond_exp M F (f i) x)\<partial>M)" unfolding set_lebesgue_integral_def by (simp add: scaleR_sum_right)
+  finally show "(\<integral>x\<in>A. (\<Sum>i\<in>I. f i x)\<partial>M) = (\<integral>x\<in>A. (\<Sum>i\<in>I. cond_exp M F (f i) x)\<partial>M)" by auto
+qed (auto simp add: assms integrable_cond_exp)
+
+subsection \<open>Linearly Ordered Banach Spaces\<close>
+
+text \<open>In this subsection we show monotonicity results concerning the conditional expectation operator.\<close>
+
+lemma cond_exp_gr_c:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f"  "AE x in M. f x > c"
+  shows "AE x in M. cond_exp M F f x > c"
+proof -
+  define X where "X = {x \<in> space M. cond_exp M F f x \<le> c}"
+  have [measurable]: "X \<in> sets F" unfolding X_def by measurable (metis sets.top subalg subalgebra_def)
+  hence X_in_M: "X \<in> sets M" using sets_restr_to_subalg subalg subalgebra_def by blast
+  have "emeasure M X = 0"
+  proof (rule ccontr)
+    assume "emeasure M X \<noteq> 0"
+    have "emeasure (restr_to_subalg M F) X = emeasure M X" by (simp add: emeasure_restr_to_subalg subalg)
+    hence "emeasure (restr_to_subalg M F) X > 0" using \<open>\<not>(emeasure M X) = 0\<close> gr_zeroI by auto
+    then obtain A where A: "A \<in> sets (restr_to_subalg M F)" "A \<subseteq> X" "emeasure (restr_to_subalg M F) A > 0" "emeasure (restr_to_subalg M F) A < \<infinity>"
+      using sigma_fin_subalg by (metis emeasure_notin_sets ennreal_0 infinity_ennreal_def le_less_linear neq_top_trans not_gr_zero order_refl sigma_finite_measure.approx_PInf_emeasure_with_finite)
+    hence [simp]: "A \<in> sets F" using subalg sets_restr_to_subalg by blast
+    hence A_in_sets_M[simp]: "A \<in> sets M" using sets_restr_to_subalg subalg subalgebra_def by blast
+    have [simp]: "set_integrable M A (\<lambda>x. c)" using A subalg by (auto simp add: set_integrable_def emeasure_restr_to_subalg) 
+    have [simp]: "set_integrable M A f" unfolding set_integrable_def by (rule integrable_mult_indicator, auto simp add: assms(1))
+    have "AE x in M. indicator A x *\<^sub>R c = indicator A x *\<^sub>R f x"
+    proof (rule integral_eq_mono_AE_eq_AE)
+      have "(\<integral>x\<in>A. c \<partial>M) \<le> (\<integral>x\<in>A. f x \<partial>M)" using assms(2) by (intro set_integral_mono_AE_banach) auto
+      moreover
+      {
+        have "(\<integral>x\<in>A. f x \<partial>M) = (\<integral>x\<in>A. cond_exp M F f x \<partial>M)" by (rule cond_exp_set_integral, auto simp add: assms)
+        also have "... \<le> (\<integral>x\<in>A. c \<partial>M)" using A by (auto intro!: set_integral_mono_banach simp add: X_def)
+        finally have "(\<integral>x\<in>A. f x \<partial>M) \<le> (\<integral>x\<in>A. c \<partial>M)" by simp
+      }
+      ultimately show "LINT x|M. indicator A x *\<^sub>R c = LINT x|M. indicator A x *\<^sub>R f x" unfolding set_lebesgue_integral_def by simp
+      show "AE x in M. indicator A x *\<^sub>R c \<le> indicator A x *\<^sub>R f x" using assms by (auto simp add: X_def indicator_def)
+    qed (auto simp add: set_integrable_def[symmetric])
+    hence "AE x\<in>A in M. c = f x" by auto
+    hence "AE x\<in>A in M. False" using assms(2) by auto
+    hence "A \<in> null_sets M" using AE_iff_null_sets A_in_sets_M by metis
+    thus False using A(3) by (simp add: emeasure_restr_to_subalg null_setsD1 subalg)
+  qed
+  thus ?thesis using AE_iff_null_sets[OF X_in_M] unfolding X_def by auto
+qed
+
+corollary cond_exp_less_c:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "AE x in M. f x < c"
+  shows "AE x in M. cond_exp M F f x < c"
+proof -
+  have "AE x in M. cond_exp M F f x = - cond_exp M F (\<lambda>x. - f x) x" using cond_exp_uminus[OF assms(1)] by auto
+  moreover have "AE x in M. cond_exp M F (\<lambda>x. - f x) x > - c"  using assms by (intro cond_exp_gr_c) auto
+  ultimately show ?thesis by (force simp add: minus_less_iff)
+qed
+
+lemma cond_exp_mono_strict:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g" "AE x in M. f x < g x"
+  shows "AE x in M. cond_exp M F f x < cond_exp M F g x"
+  using cond_exp_less_c[OF Bochner_Integration.integrable_diff, OF assms(1,2), of 0] 
+        cond_exp_diff[OF assms(1,2)] assms(3) by auto
+
+lemma cond_exp_ge_c:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes [measurable]: "integrable M f"                                                               
+      and "AE x in M. f x \<ge> c"
+  shows "AE x in M. cond_exp M F f x \<ge> c"
+proof -
+  let ?F = "restr_to_subalg M F"
+  interpret sigma_finite_measure "restr_to_subalg M F" using sigma_fin_subalg by auto
+  { 
+    fix A assume asm: "A \<in> sets ?F" "0 < measure ?F A"
+    have [simp]: "sets ?F = sets F" "measure ?F A = measure M A" using asm by (auto simp add: measure_def sets_restr_to_subalg[OF subalg] emeasure_restr_to_subalg[OF subalg])
+    have M_A: "emeasure M A < \<infinity>" using measure_zero_top asm by (force simp add: top.not_eq_extremum)
+    hence F_A: "emeasure ?F A < \<infinity>" using asm(1) emeasure_restr_to_subalg subalg by fastforce
+    have "set_lebesgue_integral M A (\<lambda>_. c) \<le> set_lebesgue_integral M A f" using assms asm M_A subalg by (intro set_integral_mono_AE_banach, auto simp add: set_integrable_def integrable_mult_indicator subalgebra_def sets_restr_to_subalg)
+    also have "... = set_lebesgue_integral M A (cond_exp M F f)" using cond_exp_set_integral[OF assms(1)] asm by auto
+    also have "... = set_lebesgue_integral ?F A (cond_exp M F f)" unfolding set_lebesgue_integral_def using asm borel_measurable_cond_exp by (intro integral_subalgebra2[OF subalg, symmetric], simp)
+    finally have "(1 / measure ?F A) *\<^sub>R set_lebesgue_integral ?F A (cond_exp M F f) \<in> {c..}" using asm subalg M_A by (auto simp add: set_integral_const subalgebra_def intro!: pos_divideR_le_eq[THEN iffD1]) 
+  }
+  thus ?thesis using AE_restr_to_subalg[OF subalg] averaging_theorem[OF integrable_in_subalg closed_atLeast, OF subalg borel_measurable_cond_exp integrable_cond_exp] by auto
+qed
+
+corollary cond_exp_le_c:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f"
+      and "AE x in M. f x \<le> c"
+  shows "AE x in M. cond_exp M F f x \<le> c"
+proof -
+  have "AE x in M. cond_exp M F f x = - cond_exp M F (\<lambda>x. - f x) x" using cond_exp_uminus[OF assms(1)] by force
+  moreover have "AE x in M. cond_exp M F (\<lambda>x. - f x) x \<ge> - c" using assms by (intro cond_exp_ge_c) auto
+  ultimately show ?thesis by (force simp add: minus_le_iff)
+qed
+
+corollary cond_exp_mono:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g" "AE x in M. f x \<le> g x"
+  shows "AE x in M. cond_exp M F f x \<le> cond_exp M F g x"
+  using cond_exp_le_c[OF Bochner_Integration.integrable_diff, OF assms(1,2), of 0] 
+        cond_exp_diff[OF assms(1,2)] assms(3) by auto
+                                      
+corollary cond_exp_min:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE \<xi> in M. cond_exp M F (\<lambda>x. min (f x) (g x)) \<xi> \<le> min (cond_exp M F f \<xi>) (cond_exp M F g \<xi>)"
+proof -
+  have "AE \<xi> in M. cond_exp M F (\<lambda>x. min (f x) (g x)) \<xi> \<le> cond_exp M F f \<xi>" by (intro cond_exp_mono integrable_min assms, simp)
+  moreover have "AE \<xi> in M. cond_exp M F (\<lambda>x. min (f x) (g x)) \<xi> \<le> cond_exp M F g \<xi>" by (intro cond_exp_mono integrable_min assms, simp)
+  ultimately show "AE \<xi> in M. cond_exp M F (\<lambda>x. min (f x) (g x)) \<xi> \<le> min (cond_exp M F f \<xi>) (cond_exp M F g \<xi>)" by fastforce
+qed
+
+corollary cond_exp_max:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE \<xi> in M. cond_exp M F (\<lambda>x. max (f x) (g x)) \<xi> \<ge> max (cond_exp M F f \<xi>) (cond_exp M F g \<xi>)"
+proof -
+  have "AE \<xi> in M. cond_exp M F (\<lambda>x. max (f x) (g x)) \<xi> \<ge> cond_exp M F f \<xi>" by (intro cond_exp_mono integrable_max assms, simp)
+  moreover have "AE \<xi> in M. cond_exp M F (\<lambda>x. max (f x) (g x)) \<xi> \<ge> cond_exp M F g \<xi>" by (intro cond_exp_mono integrable_max assms, simp)
+  ultimately show "AE \<xi> in M. cond_exp M F (\<lambda>x. max (f x) (g x)) \<xi> \<ge> max (cond_exp M F f \<xi>) (cond_exp M F g \<xi>)" by fastforce
+qed
+
+corollary cond_exp_inf:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector, lattice}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE \<xi> in M. cond_exp M F (\<lambda>x. inf (f x) (g x)) \<xi> \<le> inf (cond_exp M F f \<xi>) (cond_exp M F g \<xi>)"
+  unfolding inf_min using assms by (rule cond_exp_min)
+
+corollary cond_exp_sup:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, linorder_topology, ordered_real_vector, lattice}"
+  assumes "integrable M f" "integrable M g"
+  shows "AE \<xi> in M. cond_exp M F (\<lambda>x. sup (f x) (g x)) \<xi> \<ge> sup (cond_exp M F f \<xi>) (cond_exp M F g \<xi>)"
+  unfolding sup_max using assms by (rule cond_exp_max)
+
+end
+
+subsection \<open>Probability Spaces\<close>
+
+lemma (in prob_space) sigma_finite_subalgebra_restr_to_subalg:
+  assumes "subalgebra M F"
+  shows "sigma_finite_subalgebra M F"
+proof (intro sigma_finite_subalgebra.intro)
+  interpret F: prob_space "restr_to_subalg M F" using assms prob_space_restr_to_subalg prob_space_axioms by blast
+  show "sigma_finite_measure (restr_to_subalg M F)" by (rule F.sigma_finite_measure_axioms)
+qed (rule assms)
+
+lemma (in prob_space) cond_exp_trivial:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach}"
+  assumes "integrable M f"
+  shows "AE x in M. cond_exp M (sigma (space M) {}) f x = expectation f"
+proof -
+  interpret sigma_finite_subalgebra M "sigma (space M) {}" by (auto intro: sigma_finite_subalgebra_restr_to_subalg simp add: subalgebra_def sigma_sets_empty_eq)
+  show ?thesis using assms by (intro cond_exp_charact) (auto simp add: sigma_sets_empty_eq set_lebesgue_integral_def prob_space cong: Bochner_Integration.integral_cong)
+qed
+
+text \<open>The following lemma shows that independent \<open>\<sigma>\<close>-algebras don't matter for the conditional expectation. The proof is adapted from \cite{Zitkovic_2015}.\<close>
+
+lemma (in prob_space) cond_exp_indep_subalgebra:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, real_normed_field}"
+  assumes subalgebra: "subalgebra M F" "subalgebra M G"
+      and independent: "indep_set G (sigma (space M) (F \<union> vimage_algebra (space M) f borel))"
+  assumes [measurable]: "integrable M f"
+  shows "AE x in M. cond_exp M (sigma (space M) (F \<union> G)) f x = cond_exp M F f x"
+proof -
+  interpret Un_sigma: sigma_finite_subalgebra M "sigma (space M) (F \<union> G)" using assms(1,2) by (auto intro!: sigma_finite_subalgebra_restr_to_subalg sets.sigma_sets_subset simp add: subalgebra_def space_measure_of_conv sets_measure_of_conv)
+  interpret sigma_finite_subalgebra M F using assms by (auto intro: sigma_finite_subalgebra_restr_to_subalg)
+  {
+    fix A
+    assume asm: "A \<in> sigma (space M) {a \<inter> b | a b. a \<in> F \<and> b \<in> G}"
+    have in_events: "sigma_sets (space M) {a \<inter> b |a b. a \<in> sets F \<and> b \<in> sets G} \<subseteq> events" using subalgebra by (intro sets.sigma_sets_subset, auto simp add: subalgebra_def)
+    have "Int_stable {a \<inter> b | a b. a \<in> F \<and> b \<in> G}"
+    proof -
+      {
+        fix af bf ag bg
+        assume F: "af \<in> F" "bf \<in> F" and G: "ag \<in> G" "bg \<in> G"
+        have "af \<inter> bf \<in> F" by (intro sets.Int F)
+        moreover have "ag \<inter> bg \<in> G" by (intro sets.Int G)
+        ultimately have "\<exists>a b. af \<inter> ag \<inter> (bf \<inter> bg) = a \<inter> b \<and> a \<in> sets F \<and> b \<in> sets G" by (metis inf_assoc inf_left_commute)
+      }
+      thus ?thesis by (force intro!: Int_stableI)
+    qed
+    moreover have "{a \<inter> b | a b. a \<in> F \<and> b \<in> G} \<subseteq> Pow (space M)" using subalgebra by (force simp add: subalgebra_def dest: sets.sets_into_space)
+    moreover have "A \<in> sigma_sets (space M) {a \<inter> b | a b. a \<in> F \<and> b \<in> G}" using calculation asm by force
+    ultimately have "set_lebesgue_integral M A f = set_lebesgue_integral M A (cond_exp M F f)"
+    proof (induction rule: sigma_sets_induct_disjoint)
+      case (basic A)
+      then obtain a b where A: "A = a \<inter> b" "a \<in> F" "b \<in> G" by blast
+
+      hence events[measurable]: "a \<in> events" "b \<in> events" using subalgebra by (auto simp add: subalgebra_def)
+
+      have [simp]: "sigma_sets (space M) {indicator b -` A \<inter> space M |A. A \<in> borel} \<subseteq> G"
+        using borel_measurable_indicator[OF A(3), THEN measurable_sets] sets.top subalgebra
+        by (intro sets.sigma_sets_subset') (fastforce simp add: subalgebra_def)+
+
+      have Un_in_sigma: "F \<union> vimage_algebra (space M) f borel \<subseteq> sigma (space M) (F \<union> vimage_algebra (space M) f borel)" by (metis equalityE le_supI sets.space_closed sigma_le_sets space_vimage_algebra subalg subalgebra_def)
+
+      have [intro]: "indep_var borel (indicator b) borel (\<lambda>\<omega>. indicator a \<omega> *\<^sub>R f \<omega>)"
+      proof -
+        have [simp]: "sigma_sets (space M) {(\<lambda>\<omega>. indicator a \<omega> *\<^sub>R f \<omega>) -` A \<inter> space M |A. A \<in> borel} \<subseteq> sigma (space M) (F \<union> vimage_algebra (space M) f borel)"
+        proof -
+          have *: "(\<lambda>\<omega>. indicator a \<omega> *\<^sub>R f \<omega>) \<in> borel_measurable (sigma (space M) (F \<union> vimage_algebra (space M) f borel))"
+            using borel_measurable_indicator[OF A(2), THEN measurable_sets, OF borel_open] subalgebra
+            by (intro borel_measurable_scaleR borel_measurableI Un_in_sigma[THEN subsetD])
+               (auto simp add: space_measure_of_conv subalgebra_def sets_vimage_algebra2)
+          thus ?thesis using measurable_sets[OF *] by (intro sets.sigma_sets_subset', auto simp add: space_measure_of_conv)
+        qed
+        have "indep_set (sigma_sets (space M) {indicator b -` A \<inter> space M |A. A \<in> borel}) (sigma_sets (space M) {(\<lambda>\<omega>. indicator a \<omega> *\<^sub>R f \<omega>) -` A \<inter> space M |A. A \<in> borel})" 
+          using independent unfolding indep_set_def by (rule indep_sets_mono_sets, auto split: bool.split)
+        thus ?thesis by (subst indep_var_eq, auto intro!: borel_measurable_scaleR)
+      qed
+
+      have [intro]: "indep_var borel (indicator b) borel (\<lambda>\<omega>. indicat_real a \<omega> *\<^sub>R cond_exp M F f \<omega>)"
+      proof -
+        have [simp]:"sigma_sets (space M) {(\<lambda>\<omega>. indicator a \<omega> *\<^sub>R cond_exp M F f \<omega>) -` A \<inter> space M |A. A \<in> borel} \<subseteq> sigma (space M) (F \<union> vimage_algebra (space M) f borel)"
+        proof -
+          have *: "(\<lambda>\<omega>. indicator a \<omega> *\<^sub>R cond_exp M F f \<omega>) \<in> borel_measurable (sigma (space M) (F \<union> vimage_algebra (space M) f borel))"
+            using borel_measurable_indicator[OF A(2), THEN measurable_sets, OF borel_open] subalgebra 
+                  borel_measurable_cond_exp[THEN measurable_sets, OF borel_open, of _ M F f]
+            by (intro borel_measurable_scaleR borel_measurableI Un_in_sigma[THEN subsetD])
+               (auto simp add: space_measure_of_conv subalgebra_def)
+          thus ?thesis using measurable_sets[OF *] by (intro sets.sigma_sets_subset', auto simp add: space_measure_of_conv)
+        qed
+        have "indep_set (sigma_sets (space M) {indicator b -` A \<inter> space M |A. A \<in> borel}) (sigma_sets (space M) {(\<lambda>\<omega>. indicator a \<omega> *\<^sub>R cond_exp M F f \<omega>) -` A \<inter> space M |A. A \<in> borel})" 
+          using independent unfolding indep_set_def by (rule indep_sets_mono_sets, auto split: bool.split)
+        thus ?thesis by (subst indep_var_eq, auto intro!: borel_measurable_scaleR)
+      qed
+  
+      have "set_lebesgue_integral M A f = (LINT x|M. indicator b x * (indicator a x *\<^sub>R f x))"
+        unfolding set_lebesgue_integral_def A indicator_inter_arith 
+        by (intro Bochner_Integration.integral_cong, auto simp add: scaleR_scaleR[symmetric] indicator_times_eq_if(1))
+      also have "... = (LINT x|M. indicator b x) * (LINT x|M. indicator a x *\<^sub>R f x)" 
+        by (intro indep_var_lebesgue_integral
+                  Bochner_Integration.integrable_bound[OF integrable_const[of "1 :: 'b"] borel_measurable_indicator]
+                  integrable_mult_indicator[OF _ assms(4)], blast) (auto simp add: indicator_def)
+        also have "... = (LINT x|M. indicator b x) * (LINT x|M. indicator a x *\<^sub>R cond_exp M F f x)" 
+          using cond_exp_set_integral[OF assms(4) A(2)] unfolding set_lebesgue_integral_def by argo
+        also have "... = (LINT x|M. indicator b x * (indicator a x *\<^sub>R cond_exp M F f x))"
+        by (intro indep_var_lebesgue_integral[symmetric]
+                  Bochner_Integration.integrable_bound[OF integrable_const[of "1 :: 'b"] borel_measurable_indicator]
+                  integrable_mult_indicator[OF _ integrable_cond_exp], blast) (auto simp add: indicator_def)
+      also have "... = set_lebesgue_integral M A (cond_exp M F f)" 
+        unfolding set_lebesgue_integral_def A indicator_inter_arith 
+        by (intro Bochner_Integration.integral_cong, auto simp add: scaleR_scaleR[symmetric] indicator_times_eq_if(1))
+      finally show ?case .
+    next
+      case empty
+      then show ?case unfolding set_lebesgue_integral_def by simp
+    next
+      case (compl A)
+      have A_in_space: "A \<subseteq> space M" using compl using in_events sets.sets_into_space by blast
+      have "set_lebesgue_integral M (space M - A) f = set_lebesgue_integral M (space M - A \<union> A) f - set_lebesgue_integral M A f"
+        using compl(1) in_events
+        by (subst set_integral_Un[of "space M - A" A], blast)
+           (simp | intro integrable_mult_indicator[folded set_integrable_def, OF _ assms(4)], fast)+
+      also have "... = set_lebesgue_integral M (space M - A \<union> A) (cond_exp M F f) - set_lebesgue_integral M A (cond_exp M F f)" 
+        using cond_exp_set_integral[OF assms(4) sets.top] compl subalgebra by (simp add: subalgebra_def Un_absorb2[OF A_in_space])
+      also have "... = set_lebesgue_integral M (space M - A) (cond_exp M F f)"
+        using compl(1) in_events
+        by (subst set_integral_Un[of "space M - A" A], blast)
+           (simp | intro integrable_mult_indicator[folded set_integrable_def, OF _ integrable_cond_exp], fast)+
+      finally show ?case .
+    next
+      case (union A)
+      have "set_lebesgue_integral M (\<Union> (range A)) f = (\<Sum>i. set_lebesgue_integral M (A i) f)" 
+        using union in_events
+        by (intro lebesgue_integral_countable_add) (auto simp add: disjoint_family_onD intro!: integrable_mult_indicator[folded set_integrable_def, OF _ assms(4)]) 
+      also have "... = (\<Sum>i. set_lebesgue_integral M (A i) (cond_exp M F f))" using union by presburger
+      also have "... = set_lebesgue_integral M (\<Union> (range A)) (cond_exp M F f)"
+        using union in_events
+        by (intro lebesgue_integral_countable_add[symmetric]) (auto simp add: disjoint_family_onD intro!: integrable_mult_indicator[folded set_integrable_def, OF _ integrable_cond_exp]) 
+      finally show ?case .
+    qed
+  }
+  moreover have "sigma (space M) {a \<inter> b | a b. a \<in> F \<and> b \<in> G} = sigma (space M) (F \<union> G)"
+  proof -
+    have "sigma_sets (space M) {a \<inter> b |a b. a \<in> sets F \<and> b \<in> sets G} = sigma_sets (space M) (sets F \<union> sets G)"
+    proof -
+      {
+        fix a b assume asm: "a \<in> F" "b \<in> G"
+        hence "a \<inter> b \<in> sigma_sets (space M) (F \<union> G)" using subalgebra unfolding Int_range_binary by (intro sigma_sets_Inter[OF _ binary_in_sigma_sets]) (force simp add: subalgebra_def dest: sets.sets_into_space)+
+      }
+      moreover
+      {
+        fix a
+        assume "a \<in> sets F"
+        hence "a \<in> sigma_sets (space M) {a \<inter> b |a b. a \<in> sets F \<and> b \<in> sets G}"
+          using subalgebra sets.top[of G] sets.sets_into_space[of _ F] 
+          by (intro sigma_sets.Basic, auto simp add: subalgebra_def)
+      }
+      moreover
+      {
+        fix a assume "a \<in> sets F \<or> a \<in> sets G" "a \<notin> sets F"
+        hence "a \<in> sets G" by blast
+        hence "a \<in> sigma_sets (space M) {a \<inter> b |a b. a \<in> sets F \<and> b \<in> sets G}" 
+          using subalgebra sets.top[of F] sets.sets_into_space[of _ G] 
+          by (intro sigma_sets.Basic, auto simp add: subalgebra_def)
+      }
+      ultimately show ?thesis by (intro sigma_sets_eqI) auto
+    qed
+    thus ?thesis using subalgebra by (intro sigma_eqI) (force simp add: subalgebra_def dest: sets.sets_into_space)+
+  qed
+  moreover have "(cond_exp M F f) \<in> borel_measurable (sigma (space M) (sets F \<union> sets G))"
+  proof -
+    have "F \<subseteq> sigma (space M) (F \<union> G)" by (metis Un_least Un_upper1 measure_of_of_measure sets.space_closed sets_measure_of sigma_sets_subseteq subalg subalgebra(2) subalgebra_def)
+    thus ?thesis using borel_measurable_cond_exp[THEN measurable_sets, OF borel_open, of _ M F f] subalgebra by (intro borel_measurableI, force simp only: space_measure_of_conv subalgebra_def)
+  qed
+  ultimately show ?thesis using assms(4) integrable_cond_exp by (intro Un_sigma.cond_exp_charact) presburger+
+qed
+
+text \<open>If a random variable is independent of a \<open>\<sigma>\<close>-algebra \<^term>\<open>F\<close>, its conditional expectation \<^term>\<open>cond_exp M F f\<close> is just its expectation.\<close>
+
+lemma (in prob_space) cond_exp_indep:
+  fixes f :: "'a \<Rightarrow> 'b :: {second_countable_topology, banach, real_normed_field}"
+  assumes subalgebra: "subalgebra M F"
+      and independent: "indep_set F (vimage_algebra (space M) f borel)"
+      and integrable: "integrable M f"
+  shows "AE x in M. cond_exp M F f x = expectation f"
+proof -
+  have "indep_set F (sigma (space M) (sigma (space M) {} \<union> (vimage_algebra (space M) f borel)))"
+    using independent unfolding indep_set_def 
+    by (rule indep_sets_mono_sets, simp add: bool.split) 
+       (metis bot.extremum dual_order.refl sets.sets_measure_of_eq sets.sigma_sets_subset' sets_vimage_algebra_space space_vimage_algebra sup.absorb_iff2)
+  hence cond_exp_indep: "AE x in M. cond_exp M (sigma (space M) (sigma (space M) {} \<union> F)) f x = expectation f"
+    using cond_exp_indep_subalgebra[OF _ subalgebra _ integrable, of "sigma (space M) {}"] cond_exp_trivial[OF integrable]
+    by (auto simp add: subalgebra_def sigma_sets_empty_eq)
+  have "sets (sigma (space M) (sigma (space M) {} \<union> F)) = F"
+    using subalgebra sets.top[of F] unfolding subalgebra_def 
+    by (simp add: sigma_sets_empty_eq, subst insert_absorb[of "space M" F], blast) 
+       (metis insert_absorb[OF sets.empty_sets] sets.sets_measure_of_eq)
+  hence "AE x in M. cond_exp M (sigma (space M) (sigma (space M) {} \<union> F)) f x = cond_exp M F f x" by (rule cond_exp_sets_cong)
+  thus ?thesis using cond_exp_indep by force
+qed
+
+end
\ No newline at end of file
diff --git a/thys/Martingales/Elementary_Metric_Spaces_Supplement.thy b/thys/Martingales/Elementary_Metric_Spaces_Supplement.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Elementary_Metric_Spaces_Supplement.thy
@@ -0,0 +1,71 @@
+theory Elementary_Metric_Spaces_Supplement
+  imports "HOL-Analysis.Elementary_Metric_Spaces"
+begin
+
+section \<open>Supplementary Lemmas for Elementary Metric Spaces\<close>
+
+subsection \<open>Diameter Lemma\<close>
+
+lemma diameter_comp_strict_mono:
+  fixes s :: "nat \<Rightarrow> 'a :: metric_space"
+  assumes "strict_mono r" "bounded {s i |i. r n \<le> i}"
+  shows "diameter {s (r i) | i. n \<le> i} \<le> diameter {s i | i. r n \<le> i}"
+proof (rule diameter_subset)
+  show "{s (r i) | i. n \<le> i} \<subseteq> {s i | i. r n \<le> i}" using assms(1) monotoneD strict_mono_mono by fastforce
+qed (intro assms(2))
+
+lemma diameter_bounded_bound':
+  fixes S :: "'a :: metric_space set"
+  assumes S: "bdd_above (case_prod dist ` (S\<times>S))" "x \<in> S" "y \<in> S"
+  shows "dist x y \<le> diameter S"
+proof -
+  have "(x,y) \<in> S\<times>S" using S by auto
+  then have "dist x y \<le> (SUP (x,y)\<in>S\<times>S. dist x y)" by (rule cSUP_upper2[OF assms(1)]) simp
+  with \<open>x \<in> S\<close> show ?thesis by (auto simp: diameter_def)
+qed
+
+lemma bounded_imp_dist_bounded:
+  assumes "bounded (range s)"
+  shows "bounded ((\<lambda>(i, j). dist (s i) (s j)) ` ({n..} \<times> {n..}))"
+  using bounded_dist_comp[OF bounded_fst bounded_snd, OF bounded_Times(1,1)[OF assms(1,1)]] by (rule bounded_subset, force) 
+
+text \<open>A sequence is Cauchy, if and only if it is bounded and it's diameter tends to zero. The diameter is well-defined only if the sequence is bounded.\<close>
+lemma cauchy_iff_diameter_tends_to_zero_and_bounded:
+  fixes s :: "nat \<Rightarrow> 'a :: metric_space"
+  shows "Cauchy s \<longleftrightarrow> ((\<lambda>n. diameter {s i | i. i \<ge> n}) \<longlonglongrightarrow> 0 \<and> bounded (range s))"
+proof -
+  have "{s i |i. N \<le> i} \<noteq> {}" for N by blast
+  hence diameter_SUP: "diameter {s i |i. N \<le> i} = (SUP (i, j) \<in> {N..} \<times> {N..}. dist (s i) (s j))" for N unfolding diameter_def by (auto intro!: arg_cong[of _ _ Sup])
+  show ?thesis 
+  proof (intro iffI)
+    assume asm: "Cauchy s"
+    have "\<exists>N. \<forall>n\<ge>N. norm (diameter {s i |i. n \<le> i}) < e" if e_pos: "e > 0" for e
+    proof -
+      obtain N where dist_less: "dist (s n) (s m) < (1/2) * e" if "n \<ge> N" "m \<ge> N" for n m using asm e_pos by (metis Cauchy_def mult_pos_pos zero_less_divide_iff zero_less_numeral zero_less_one)
+      {
+        fix r assume "r \<ge> N"
+        hence "dist (s n) (s m) < (1/2) * e" if "n \<ge> r" "m \<ge> r" for n m using dist_less that by simp
+        hence "(SUP (i, j) \<in> {r..} \<times> {r..}. dist (s i) (s j)) \<le> (1/2) * e" by (intro cSup_least) fastforce+
+        also have "... < e" using e_pos by simp
+        finally have "diameter {s i |i. r \<le> i} < e" using diameter_SUP by presburger
+      }
+      moreover have "diameter {s i |i. r \<le> i} \<ge> 0" for r unfolding diameter_SUP using bounded_imp_dist_bounded[OF cauchy_imp_bounded, THEN bounded_imp_bdd_above, OF asm] by (intro cSup_upper2, auto)
+      ultimately show ?thesis by auto
+    qed                 
+    thus "(\<lambda>n. diameter {s i |i. n \<le> i}) \<longlonglongrightarrow> 0 \<and> bounded (range s)" using cauchy_imp_bounded[OF asm] by (simp add: LIMSEQ_iff)
+  next
+    assume asm: "(\<lambda>n. diameter {s i |i. n \<le> i}) \<longlonglongrightarrow> 0 \<and> bounded (range s)"
+    have "\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. dist (s n) (s m) < e" if e_pos: "e > 0" for e
+    proof -
+      obtain N where diam_less: "diameter {s i |i. r \<le> i} < e" if "r \<ge> N" for r using LIMSEQ_D asm(1) e_pos by fastforce
+      {
+        fix n m assume "n \<ge> N" "m \<ge> N"
+        hence "dist (s n) (s m) < e" using cSUP_lessD[OF bounded_imp_dist_bounded[THEN bounded_imp_bdd_above], OF _ diam_less[unfolded diameter_SUP]] asm by auto
+      }
+      thus ?thesis by blast
+    qed
+    then show "Cauchy s" by (simp add: Cauchy_def)
+  qed            
+qed
+  
+end
\ No newline at end of file
diff --git a/thys/Martingales/Example_Coin_Toss.thy b/thys/Martingales/Example_Coin_Toss.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Example_Coin_Toss.thy
@@ -0,0 +1,246 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Example_Coin_Toss
+  imports Martingale "HOL-Probability.Stream_Space" "HOL-Probability.Probability_Mass_Function"
+begin
+
+section \<open>Example: Coin Toss\<close>
+
+text \<open>Consider a coin-tossing game, where the coin lands on heads with probability \<open>p \<in> [0, 1]\<close>. Assume that the gambler wins a fixed amount \<open>c > 0\<close> on a heads outcome 
+      and loses the same amount \<open>c\<close> on a tails outcome. Let \<open>(X\<^sub>n)\<^sub>n\<^sub>\<in>\<^sub>\<nat>\<close> be a stochastic process, where \<open>X\<^sub>n\<close> denotes the gambler’s fortune after the \<open>n\<close>-th coin toss. 
+      Then, we have the following three cases.\<close>
+
+text \<open>1. If \<open>p = 1/2\<close>, it means the coin is fair and has an equal chance of landing heads or tails. 
+      In this case, the gambler, on average, neither wins nor loses money over time. The expected value of the gambler’s fortune stays the same over time. 
+      Therefore, \<open>(X\<^sub>n)\<^sub>n\<^sub>\<in>\<^sub>\<nat>\<close> is a martingale.\<close>
+text \<open>2. If \<open>p \<ge> 1/2\<close> , it means the coin is biased in favor of heads. In this case, the gambler is more likely to win money on each bet. 
+      Over time, the gambler’s fortune tends to increase on average. 
+      Therefore, \<open>(X\<^sub>n)\<^sub>n\<^sub>\<in>\<^sub>\<nat>\<close> is a submartingale.\<close>
+
+text \<open>3. If \<open>p \<le> 1/2\<close> , it means the coin is biased in favor of tails. In this scenario, the gambler is more likely to lose money on each bet. 
+      Over time, the gambler’s fortune decreases on average. 
+      Therefore, \<open>(X\<^sub>n)\<^sub>n\<^sub>\<in>\<^sub>\<nat>\<close> is a supermartingale.\<close>
+
+text \<open>To formalize this example, we first consider a probability space consisting of infinite sequences of coin tosses.\<close>
+
+definition bernoulli_stream :: "real \<Rightarrow> (bool stream) measure" where
+  "bernoulli_stream p = stream_space (measure_pmf (bernoulli_pmf p))"
+                                  
+lemma space_bernoulli_stream[simp]: "space (bernoulli_stream p) = UNIV" by (simp add: bernoulli_stream_def space_stream_space)
+
+text \<open>We define the fortune of the player at time \<^term>\<open>n\<close> to be the number of heads minus number of tails.\<close>
+
+definition fortune :: "nat \<Rightarrow> bool stream \<Rightarrow> real" where
+  "fortune n = (\<lambda>s. \<Sum>b \<leftarrow> stake (Suc n) s. if b then 1 else -1)"
+
+definition toss :: "nat \<Rightarrow> bool stream \<Rightarrow> real" where
+  "toss n = (\<lambda>s. if snth s n then 1 else -1)"
+
+lemma toss_indicator_def: "toss n = indicator {s. s !! n} - indicator {s. \<not> s !! n}"
+  unfolding toss_def indicator_def by force
+
+lemma range_toss: "range (toss n) = {-1, 1}"
+proof -
+  have "sconst True !! n" by simp
+  moreover have "\<not>sconst False !! n" by simp
+  ultimately have "\<exists>x. x !! n" "\<exists>x. \<not>x !! n" by blast+
+  thus ?thesis unfolding toss_def image_def by auto
+qed
+
+lemma vimage_toss: "toss n -` A = (if 1 \<in> A then {s. s !! n} else {}) \<union> (if -1 \<in> A then {s. \<not>s !! n} else {})"
+  unfolding vimage_def toss_def by auto
+
+lemma fortune_Suc: "fortune (Suc n) s = fortune n s + toss (Suc n) s"
+  by (induction n arbitrary: s) (simp add: fortune_def toss_def)+
+
+lemma fortune_toss_sum: "fortune n s = (\<Sum>i \<in> {..n}. toss i s)"
+  by (induction n arbitrary: s) (simp add: fortune_def toss_def, simp add: fortune_Suc)
+
+lemma fortune_bound: "norm (fortune n s) \<le> Suc n" by (induction n) (force simp add: fortune_toss_sum toss_def)+
+
+text \<open>Our definition of \<^term>\<open>bernoulli_stream\<close> constitutes a probability space.\<close>
+
+interpretation prob_space "bernoulli_stream p" unfolding bernoulli_stream_def by (simp add: measure_pmf.prob_space_axioms prob_space.prob_space_stream_space)
+
+abbreviation "toss_filtration p \<equiv> nat_natural_filtration (bernoulli_stream p) toss"
+
+text \<open>The stochastic process \<^term>\<open>toss\<close> is adapted to the filtration it generates.\<close> 
+
+interpretation toss: nat_adapted_process "bernoulli_stream p" "nat_natural_filtration (bernoulli_stream p) toss" toss 
+  by (intro nat_adapted_process.intro stochastic_process.adapted_process_natural_filtration)
+     (unfold_locales, auto simp add: toss_def bernoulli_stream_def)
+
+text \<open>Similarly, the stochastic process \<^term>\<open>fortune\<close> is adapted to the filtration generated by the tosses.\<close>
+
+interpretation fortune: nat_finite_adapted_process_linorder "bernoulli_stream p" "nat_natural_filtration (bernoulli_stream p) toss" fortune 
+proof -
+  show "nat_finite_adapted_process_linorder (bernoulli_stream p) (toss_filtration p) fortune"
+  unfolding fortune_toss_sum   
+  by (intro nat_finite_adapted_process_linorder.intro 
+            finite_adapted_process_linorder.intro 
+            finite_adapted_process_order.intro 
+            finite_adapted_process.intro
+            toss.partial_sum_adapted[folded atMost_atLeast0]) intro_locales
+qed
+
+lemma integrable_toss: "integrable (bernoulli_stream p) (toss n)" 
+  using toss.random_variable
+  by (intro Bochner_Integration.integrable_bound[OF integrable_const[of _ "1 :: real"]]) (auto simp add: toss_def)
+
+lemma integrable_fortune: "integrable (bernoulli_stream p) (fortune n)" using fortune_bound 
+  by (intro Bochner_Integration.integrable_bound[OF integrable_const[of _ "Suc n"] fortune.random_variable]) auto
+
+text \<open>We provide the following lemma to explicitly calculate the probability of events in this probability space.\<close>
+
+lemma measure_bernoulli_stream_snth_pred:
+  assumes "0 \<le> p" and "p \<le> 1" and "finite J" 
+  shows "prob p {w \<in> space (bernoulli_stream p). \<forall>j\<in>J. P j = w !! j} = p ^ card (J \<inter> Collect P) * (1 - p) ^ (card (J - Collect P))"
+proof -
+  let ?PiE = "(\<Pi>\<^sub>E i\<in>J. if P i then {True} else {False})"
+  have "product_prob_space (\<lambda>_. measure_pmf (bernoulli_pmf p))" by unfold_locales
+
+  hence *: "to_stream -` {s. \<forall>i\<in>J. P i = s !! i} = {s. \<forall>i\<in>J. P i = s i}" using assms by (simp add: to_stream_def)
+  also have "... = prod_emb UNIV (\<lambda>_. measure_pmf (bernoulli_pmf p)) J ?PiE"
+  proof -
+    {
+      fix s assume "(\<forall>i\<in>J. P i = s i)"
+      hence "(\<forall>i\<in>J. P i = s i) = (s \<in> prod_emb UNIV (\<lambda>_. measure_pmf (bernoulli_pmf p)) J ?PiE)" 
+        by (subst prod_emb_iff[of s]) (smt (verit, best) not_def assms(3) id_def PiE_eq_singleton UNIV_I extensional_UNIV insert_iff singletonD space_measure_pmf)
+    }
+    moreover
+    {
+      fix s assume "\<not>(\<forall>i\<in>J. P i = s i)"
+      then obtain i where "i \<in> J" "P i \<noteq> s i" by blast
+      hence "(\<forall>i\<in>J. P i = s i) = (s \<in> prod_emb UNIV (\<lambda>_. measure_pmf (bernoulli_pmf p)) J ?PiE)"
+        by (simp add: restrict_def prod_emb_iff[of s]) (smt (verit, ccfv_SIG) PiE_mem assms(3) id_def insert_iff singleton_iff)
+    }
+    ultimately show ?thesis by auto
+  qed
+  finally have inteq: "(to_stream -` {s. \<forall>i\<in>J. P i = s !! i}) = prod_emb UNIV (\<lambda>_. measure_pmf (bernoulli_pmf p)) J ?PiE" .
+  let ?M = "(Pi\<^sub>M UNIV (\<lambda>_. measure_pmf (bernoulli_pmf p)))"
+  have "emeasure (bernoulli_stream p) {s \<in> space (bernoulli_stream p). \<forall>i\<in>J. P i = s !! i} = emeasure ?M (to_stream -` {s. \<forall>i\<in>J. P i  = s !! i})"
+    using assms emeasure_distr[of "to_stream" ?M "(vimage_algebra (streams (space (measure_pmf (bernoulli_pmf p)))) (!!) ?M)" "{s. \<forall>i\<in>J. P i = s !! i}", symmetric] measurable_to_stream[of "(measure_pmf (bernoulli_pmf p))"]
+    by (simp only: bernoulli_stream_def stream_space_def *, simp add: space_PiM ) (smt (verit, best) emeasure_notin_sets in_vimage_algebra inf_top.right_neutral sets_distr vimage_Collect)
+  also have "... = emeasure ?M (prod_emb UNIV (\<lambda>_. measure_pmf (bernoulli_pmf p)) J ?PiE)" using inteq by (simp add: space_PiM)
+  also have "... = (\<Prod>i\<in>J. emeasure (measure_pmf (bernoulli_pmf p)) (if P i then {True} else {False}))" 
+    by (subst emeasure_PiM_emb) (auto simp add: prob_space_measure_pmf assms(3))
+  also have "... = (\<Prod>i\<in>J \<inter> Collect P. ennreal p) * (\<Prod>i\<in>J - Collect P. ennreal (1 - p))"
+    unfolding emeasure_pmf_single[of "bernoulli_pmf p" True, unfolded pmf_bernoulli_True[OF assms(1,2)], symmetric]
+              emeasure_pmf_single[of "bernoulli_pmf p" False, unfolded pmf_bernoulli_False[OF assms(1,2)], symmetric]
+    by (simp add: prod.Int_Diff[OF assms(3), of _ "Collect P"])
+  also have "... = p ^ card (J \<inter> Collect P) * (1 - p) ^ card (J - Collect P)" using assms by (simp add: prod_ennreal ennreal_mult' ennreal_power)
+  finally show ?thesis using assms by (intro measure_eq_emeasure_eq_ennreal) auto
+qed
+
+lemma 
+  assumes "0 \<le> p" and "p \<le> 1"
+  shows measure_bernoulli_stream_snth: "prob p {w \<in> space (bernoulli_stream p). w !! i} = p"
+    and measure_bernoulli_stream_neg_snth: "prob p {w \<in> space (bernoulli_stream p). \<not>w !! i} = 1 - p"
+  using measure_bernoulli_stream_snth_pred[OF assms, of "{i}" "\<lambda>x. True"]
+        measure_bernoulli_stream_snth_pred[OF assms, of "{i}" "\<lambda>x. False"] by auto
+
+text \<open>Now we can express the expected value of a single coin toss.\<close>
+
+lemma integral_toss:
+  assumes "0 \<le> p" "p \<le> 1"
+  shows "expectation p (toss n) = 2 * p - 1"
+proof -
+  have [simp]:"{s. s !! n} \<in> events p" using measurable_snth[THEN measurable_sets, of "{True}" "measure_pmf (bernoulli_pmf p)" n, folded bernoulli_stream_def]
+    by (simp add: vimage_def)
+  have "expectation p (toss n) = Bochner_Integration.simple_bochner_integral (bernoulli_stream p) (toss n)"
+    using toss.random_variable[of n, THEN measurable_sets]
+    by (intro simple_bochner_integrable_eq_integral[symmetric] simple_bochner_integrable.intros) (auto simp add: toss_def simple_function_def image_def)
+  also have "... = p - prob p {s. \<not> s !! n}" unfolding simple_bochner_integral_def using measure_bernoulli_stream_snth[OF assms]
+    by (simp add: range_toss, simp add: toss_def)
+  also have "... = p - (1 - prob p {s. s !! n})" by (subst prob_compl[symmetric], auto simp add: Collect_neg_eq Compl_eq_Diff_UNIV)
+  finally show ?thesis using measure_bernoulli_stream_snth[OF assms] by simp
+qed
+
+text \<open>Now, we show that the tosses are independent from one another.\<close>
+
+lemma indep_vars_toss:
+  assumes "0 \<le> p" "p \<le> 1"
+  shows "indep_vars p (\<lambda>_. borel) toss {0..}"
+proof (subst indep_vars_def, intro conjI indep_sets_sigma)
+  {
+    fix A J assume asm: "J \<noteq> {}" "finite J" "\<forall>j\<in>J. A j \<in> {toss j -` A \<inter> space (bernoulli_stream p) |A. A \<in> borel}"
+    hence "\<forall>j\<in>J. \<exists>B \<in> borel. A j = toss j -` B \<inter> space (bernoulli_stream p)" by auto
+    then obtain B where B_is: "A j = toss j -` B j \<inter> space (bernoulli_stream p)" "B j \<in> borel" if "j \<in> J" for j by metis
+
+    have "prob p (\<Inter> (A ` J)) = (\<Prod>j\<in>J. prob p (A j))"
+    proof cases
+      text \<open>We consider the case where there is a zero probability event.\<close>
+      assume "\<exists>j \<in> J. 1 \<notin> B j \<and> -1 \<notin> B j"
+      then obtain j where j_is: "j \<in> J" "1 \<notin> B j" "-1 \<notin> B j" by blast
+      hence A_j_empty: "A j = {}" using B_is by (force simp add: toss_def vimage_def)
+      hence "\<Inter> (A ` J) = {}" using j_is by blast
+      moreover have "prob p (A j) = 0" using A_j_empty by simp
+      ultimately show ?thesis using j_is asm(2) by auto
+    next
+      text \<open>We now assume all events have positive probability.\<close>
+      assume "\<not>(\<exists>j \<in> J. 1 \<notin> B j \<and> -1 \<notin> B j)"
+      hence *: "1 \<in> B j \<or> -1 \<in> B j" if "j \<in> J" for j using that by blast
+
+
+      define J' where [simp]: "J' = {j \<in> J. (1 \<in> B j) \<longleftrightarrow> (-1 \<notin> B j)}"
+      hence "toss j w \<in> B j \<longleftrightarrow> (1 \<in> B j) = w !! j" if "j \<in> J'" for w j using that unfolding toss_def by simp
+      hence "(\<Inter> (A ` J')) = {w \<in> space (bernoulli_stream p). \<forall>j\<in>J'. (1 \<in> B j) = w !! j}" using B_is by force
+      hence prob_J': "prob p (\<Inter> (A ` J')) = p ^ card (J' \<inter> {j. 1 \<in> B j}) * (1 - p) ^ card (J' - {j. 1 \<in> B j})" 
+        using measure_bernoulli_stream_snth_pred[OF assms finite_subset[OF _ asm(2)], of J' "\<lambda>j. 1 \<in> B j"] by auto
+      
+      text \<open>The index set \<^term>\<open>J'\<close> consists of the indices of all non-trivial events.\<close>
+      
+      have A_j_True: "A j = {w \<in> space (bernoulli_stream p). w !! j}" if "j \<in> J' \<inter> {j. 1 \<in> B j}" for j
+        using that by (auto simp add: toss_def B_is(1) split: if_splits) 
+
+      have A_j_False: "A j = {w \<in> space (bernoulli_stream p). \<not>w !! j}" if "j \<in> J' - {j. 1 \<in> B j}" for j 
+        using that B_is by (auto simp add: toss_def) 
+      
+      have A_j_top: "A j = space (bernoulli_stream p)" if "j \<in> J - J'" for j using that * by (auto simp add: B_is toss_def)
+      hence "\<Inter> (A ` J) = \<Inter> (A ` J')" by auto
+      hence "prob p (\<Inter> (A ` J)) = prob p (\<Inter> (A ` J'))" by presburger
+      also have "... = (\<Prod>j\<in>J' \<inter> {j. 1 \<in> B j}. prob p (A j)) * (\<Prod>j\<in>J' - {j. 1 \<in> B j}. prob p (A j))" 
+        by (simp only: prob_J' A_j_True A_j_False measure_bernoulli_stream_snth[OF assms] measure_bernoulli_stream_neg_snth[OF assms] cong: prod.cong) simp
+      also have "... = (\<Prod>j\<in>J'. prob p (A j))" using asm(2) by (intro prod.Int_Diff[symmetric]) auto
+      also have "... = (\<Prod>j\<in>J'. prob p (A j)) * (\<Prod>j\<in>J - J'. prob p (A j))" using A_j_top prob_space by simp
+      also have "... = (\<Prod>j\<in>J. prob p (A j))" using asm(2) by (metis (no_types, lifting) J'_def mem_Collect_eq mult.commute prod.subset_diff subsetI)
+      finally show ?thesis .
+    qed
+  }
+  thus "indep_sets p (\<lambda>i. {toss i -` A \<inter> space (bernoulli_stream p) |A. A \<in> sets borel}) {0..}" using measurable_sets[OF toss.random_variable]
+  by (intro indep_setsI subsetI) fastforce
+qed (simp, intro Int_stableI, simp, metis sets.Int vimage_Int)
+
+text \<open>The fortune of a player is a martingale (resp. sub- or supermartingale) with respect to the filtration generated by the coin tosses.\<close>
+
+theorem fortune_martingale:
+  assumes "p = 1/2"
+  shows "nat_martingale (bernoulli_stream p) (toss_filtration p) fortune"
+  using cond_exp_indep[OF fortune.subalg indep_set_natural_filtration integrable_toss, OF zero_order(1) lessI indep_vars_toss, of p] 
+        integral_toss assms
+    by (intro fortune.martingale_of_cond_exp_diff_Suc_eq_zero integrable_fortune) (force simp add: fortune_toss_sum)
+
+theorem fortune_submartingale:
+  assumes "1/2 \<le> p" "p \<le> 1"
+  shows "nat_submartingale (bernoulli_stream p) (toss_filtration p) fortune"
+proof (intro fortune.submartingale_of_cond_exp_diff_Suc_nonneg integrable_fortune)
+  fix n
+  show "AE \<xi> in bernoulli_stream p. 0 \<le> cond_exp (bernoulli_stream p) (toss_filtration p n) (\<lambda>\<xi>. fortune (Suc n) \<xi> - fortune n \<xi>) \<xi>"
+    using cond_exp_indep[OF fortune.subalg indep_set_natural_filtration integrable_toss, OF zero_order(1) lessI indep_vars_toss, of p n] 
+          integral_toss[of p "Suc n"] assms
+    by (force simp add: fortune_toss_sum)
+qed
+
+theorem fortune_supermartingale:
+  assumes "0 \<le> p" "p \<le> 1/2" 
+  shows "nat_supermartingale (bernoulli_stream p) (toss_filtration p) fortune"
+proof (intro fortune.supermartingale_of_cond_exp_diff_Suc_le_zero integrable_fortune)
+  fix n
+  show "AE \<xi> in bernoulli_stream p. 0 \<ge> cond_exp (bernoulli_stream p) (toss_filtration p n) (\<lambda>\<xi>. fortune (Suc n) \<xi> - fortune n \<xi>) \<xi>"
+    using cond_exp_indep[OF fortune.subalg indep_set_natural_filtration integrable_toss, OF zero_order(1) lessI indep_vars_toss, of p n] 
+          integral_toss[of p "Suc n"] assms
+    by (force simp add: fortune_toss_sum)
+qed
+
+end
diff --git a/thys/Martingales/Filtered_Measure.thy b/thys/Martingales/Filtered_Measure.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Filtered_Measure.thy
@@ -0,0 +1,86 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Filtered_Measure
+  imports "HOL-Probability.Conditional_Expectation"
+begin
+
+section \<open>Filtered Measure Spaces\<close>
+
+subsection \<open>Filtered Measure\<close>
+
+locale filtered_measure = 
+  fixes M F and t\<^sub>0 :: "'b :: {second_countable_topology, order_topology, t2_space}"
+  assumes subalgebras: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> subalgebra M (F i)"
+      and sets_F_mono: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> sets (F i) \<le> sets (F j)"
+begin
+
+lemma space_F[simp]: 
+  assumes "t\<^sub>0 \<le> i"
+  shows "space (F i) = space M"
+  using subalgebras assms by (simp add: subalgebra_def)
+
+lemma subalgebra_F[intro]: 
+  assumes "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "subalgebra (F j) (F i)"
+  unfolding subalgebra_def using assms by (simp add: sets_F_mono)
+
+lemma borel_measurable_mono:
+  assumes "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "borel_measurable (F i) \<subseteq> borel_measurable (F j)"
+  unfolding subset_iff by (metis assms subalgebra_F measurable_from_subalg)
+
+end
+
+locale linearly_filtered_measure = filtered_measure M F t\<^sub>0 for M and F :: "_ :: {linorder_topology} \<Rightarrow> _" and t\<^sub>0
+
+locale nat_filtered_measure = linearly_filtered_measure M F 0 for M and F :: "nat \<Rightarrow> _"
+locale real_filtered_measure = linearly_filtered_measure M F 0 for M and F :: "real \<Rightarrow> _"
+
+subsection \<open>\<open>\<sigma>\<close>-Finite Filtered Measure\<close>
+
+text \<open>The locale presented here is a generalization of the \<^locale>\<open>sigma_finite_subalgebra\<close> for a particular filtration.\<close>
+
+locale sigma_finite_filtered_measure = filtered_measure +
+  assumes sigma_finite_initial: "sigma_finite_subalgebra M (F t\<^sub>0)"
+
+lemma (in sigma_finite_filtered_measure) sigma_finite_subalgebra_F[intro]:
+  assumes "t\<^sub>0 \<le> i"
+  shows "sigma_finite_subalgebra M (F i)"
+  using assms by (metis dual_order.refl sets_F_mono sigma_finite_initial sigma_finite_subalgebra.nested_subalg_is_sigma_finite subalgebras subalgebra_def)
+
+locale nat_sigma_finite_filtered_measure = sigma_finite_filtered_measure M F "0 :: nat" for M F
+locale real_sigma_finite_filtered_measure = sigma_finite_filtered_measure M F "0 :: real" for M F
+
+sublocale nat_sigma_finite_filtered_measure \<subseteq> sigma_finite_subalgebra M "F i" by blast
+sublocale real_sigma_finite_filtered_measure \<subseteq> sigma_finite_subalgebra M "F \<bar>i\<bar>" by fastforce 
+
+subsection \<open>Finite Filtered Measure\<close>
+
+locale finite_filtered_measure = filtered_measure + finite_measure
+
+sublocale finite_filtered_measure \<subseteq> sigma_finite_filtered_measure 
+  using subalgebras by (unfold_locales, blast, meson dual_order.refl finite_measure_axioms finite_measure_def finite_measure_restr_to_subalg sigma_finite_measure.sigma_finite_countable)
+
+locale nat_finite_filtered_measure = finite_filtered_measure M F "0 :: nat" for M F
+locale real_finite_filtered_measure = finite_filtered_measure M F "0 :: real" for M F
+
+sublocale nat_finite_filtered_measure \<subseteq> nat_sigma_finite_filtered_measure ..
+sublocale real_finite_filtered_measure \<subseteq> real_sigma_finite_filtered_measure ..
+
+subsection \<open>Constant Filtration\<close>
+
+lemma filtered_measure_constant_filtration:
+  assumes "subalgebra M F"
+  shows "filtered_measure M (\<lambda>_. F) t\<^sub>0"
+  using assms by (unfold_locales) blast+
+
+sublocale sigma_finite_subalgebra \<subseteq> constant_filtration: sigma_finite_filtered_measure M "\<lambda>_ :: 't :: {second_countable_topology, linorder_topology}. F" t\<^sub>0
+  using subalg by (unfold_locales) blast+
+
+lemma (in finite_measure) filtered_measure_constant_filtration:
+  assumes "subalgebra M F"
+  shows "finite_filtered_measure M (\<lambda>_. F) t\<^sub>0"
+  using assms by (unfold_locales) blast+
+
+end
\ No newline at end of file
diff --git a/thys/Martingales/Martingale.thy b/thys/Martingales/Martingale.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Martingale.thy
@@ -0,0 +1,714 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Martingale
+  imports Stochastic_Process Conditional_Expectation_Banach
+begin                
+
+section \<open>Martingales\<close>
+
+text \<open>The following locales are necessary for defining martingales.\<close>
+
+subsection \<open>Additional Locale Definitions\<close>
+
+locale sigma_finite_adapted_process = sigma_finite_filtered_measure M F t\<^sub>0 + adapted_process M F t\<^sub>0 X for M F t\<^sub>0 X
+
+locale nat_sigma_finite_adapted_process = sigma_finite_adapted_process M F "0 :: nat" X for M F X
+locale real_sigma_finite_adapted_process = sigma_finite_adapted_process M F "0 :: real" X for M F X
+
+sublocale nat_sigma_finite_adapted_process \<subseteq> nat_sigma_finite_filtered_measure ..
+sublocale real_sigma_finite_adapted_process \<subseteq> real_sigma_finite_filtered_measure ..
+
+locale finite_adapted_process = finite_filtered_measure M F t\<^sub>0 + adapted_process M F t\<^sub>0 X for M F t\<^sub>0 X
+
+sublocale finite_adapted_process \<subseteq> sigma_finite_adapted_process ..
+
+locale nat_finite_adapted_process = finite_adapted_process M F "0 :: nat" X for M F X
+locale real_finite_adapted_process = finite_adapted_process M F "0 :: real" X for M F X
+
+sublocale nat_finite_adapted_process \<subseteq> nat_sigma_finite_adapted_process ..
+sublocale real_finite_adapted_process \<subseteq> real_sigma_finite_adapted_process ..
+
+(* with ordering *)
+
+locale sigma_finite_adapted_process_order = sigma_finite_adapted_process M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_  \<Rightarrow> _ \<Rightarrow> _ :: {order_topology, ordered_real_vector}" 
+
+locale nat_sigma_finite_adapted_process_order = sigma_finite_adapted_process_order M F "0 :: nat" X for M F X
+locale real_sigma_finite_adapted_process_order = sigma_finite_adapted_process_order M F "0 :: real" X for M F X
+
+sublocale nat_sigma_finite_adapted_process_order \<subseteq> nat_sigma_finite_adapted_process ..
+sublocale real_sigma_finite_adapted_process_order \<subseteq> real_sigma_finite_adapted_process ..
+                                                
+locale finite_adapted_process_order = finite_adapted_process M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_  \<Rightarrow> _ \<Rightarrow> _ :: {order_topology, ordered_real_vector}" 
+
+locale nat_finite_adapted_process_order = finite_adapted_process_order M F "0 :: nat" X for M F X
+locale real_finite_adapted_process_order = finite_adapted_process_order M F "0 :: real" X for M F X
+
+sublocale nat_finite_adapted_process_order \<subseteq> nat_sigma_finite_adapted_process_order ..
+sublocale real_finite_adapted_process_order \<subseteq> real_sigma_finite_adapted_process_order ..
+
+(* with linear ordering *)
+
+locale sigma_finite_adapted_process_linorder = sigma_finite_adapted_process_order M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_  \<Rightarrow> _ \<Rightarrow> _ :: {linorder_topology}"
+
+locale nat_sigma_finite_adapted_process_linorder = sigma_finite_adapted_process_linorder M F "0 :: nat" X for M F X
+locale real_sigma_finite_adapted_process_linorder = sigma_finite_adapted_process_linorder M F "0 :: real" X for M F X
+
+sublocale nat_sigma_finite_adapted_process_linorder \<subseteq> nat_sigma_finite_adapted_process_order ..
+sublocale real_sigma_finite_adapted_process_linorder \<subseteq> real_sigma_finite_adapted_process_order ..
+
+locale finite_adapted_process_linorder = finite_adapted_process_order M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_  \<Rightarrow> _ \<Rightarrow> _ :: {linorder_topology}"
+
+locale nat_finite_adapted_process_linorder = finite_adapted_process_linorder M F "0 :: nat" X for M F X
+locale real_finite_adapted_process_linorder = finite_adapted_process_linorder M F "0 :: real" X for M F X
+
+sublocale nat_finite_adapted_process_linorder \<subseteq> nat_sigma_finite_adapted_process_linorder ..
+sublocale real_finite_adapted_process_linorder \<subseteq> real_sigma_finite_adapted_process_linorder ..
+
+subsection \<open>Martingale\<close>
+
+text \<open>A martingale is an adapted process where the expected value of the next observation, given all past observations, is equal to the current value.\<close>
+
+locale martingale = sigma_finite_adapted_process +
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)"
+      and martingale_property: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> AE \<xi> in M. X i \<xi> = cond_exp M (F i) (X j) \<xi>"
+
+locale martingale_order = martingale M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {order_topology, ordered_real_vector}"
+locale martingale_linorder = martingale M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {linorder_topology, ordered_real_vector}"
+sublocale martingale_linorder \<subseteq> martingale_order ..
+
+lemma (in sigma_finite_filtered_measure) martingale_const_fun[intro]:  
+  assumes "integrable M f" "f \<in> borel_measurable (F t\<^sub>0)"
+  shows "martingale M F t\<^sub>0 (\<lambda>_. f)"
+  using assms sigma_finite_subalgebra.cond_exp_F_meas[OF _ assms(1), THEN AE_symmetric] borel_measurable_mono
+  by (unfold_locales) blast+
+
+lemma (in sigma_finite_filtered_measure) martingale_cond_exp[intro]:  
+  assumes "integrable M f"
+  shows "martingale M F t\<^sub>0 (\<lambda>i. cond_exp M (F i) f)"
+  using sigma_finite_subalgebra.borel_measurable_cond_exp' borel_measurable_cond_exp 
+  by (unfold_locales) (auto intro: sigma_finite_subalgebra.cond_exp_nested_subalg[OF _ assms] simp add: subalgebra_F subalgebras)
+
+corollary (in sigma_finite_filtered_measure) martingale_zero[intro]: "martingale M F t\<^sub>0 (\<lambda>_ _. 0)" by fastforce
+
+corollary (in finite_filtered_measure) martingale_const[intro]: "martingale M F t\<^sub>0 (\<lambda>_ _. c)" by fastforce
+
+subsection \<open>Submartingale\<close>
+
+text \<open>A submartingale is an adapted process where the expected value of the next observation, given all past observations, is greater than or equal to the current value.\<close>
+
+locale submartingale = sigma_finite_adapted_process_order +
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)"
+      and submartingale_property: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> AE \<xi> in M. X i \<xi> \<le> cond_exp M (F i) (X j) \<xi>"
+
+locale submartingale_linorder = submartingale M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {linorder_topology}"
+
+sublocale martingale_order \<subseteq> submartingale using martingale_property by (unfold_locales) (force simp add: integrable)+
+sublocale martingale_linorder \<subseteq> submartingale_linorder ..
+
+subsection \<open>Supermartingale\<close>
+
+text \<open>A supermartingale is an adapted process where the expected value of the next observation, given all past observations, is less than or equal to the current value.\<close>
+
+locale supermartingale = sigma_finite_adapted_process_order +
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)"
+      and supermartingale_property: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> AE \<xi> in M. X i \<xi> \<ge> cond_exp M (F i) (X j) \<xi>"
+
+locale supermartingale_linorder = supermartingale M F t\<^sub>0 X for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {linorder_topology}"
+
+sublocale martingale_order \<subseteq> supermartingale using martingale_property by (unfold_locales) (force simp add: integrable)+
+sublocale martingale_linorder \<subseteq> supermartingale_linorder ..
+
+text \<open>A stochastic process is a martingale, if and only if it is both a submartingale and a supermartingale.\<close>
+
+lemma martingale_iff: 
+  shows "martingale M F t\<^sub>0 X \<longleftrightarrow> submartingale M F t\<^sub>0 X \<and> supermartingale M F t\<^sub>0 X"
+proof (rule iffI)
+  assume asm: "martingale M F t\<^sub>0 X"
+  interpret martingale_order M F t\<^sub>0 X by (intro martingale_order.intro asm)
+  show "submartingale M F t\<^sub>0 X \<and> supermartingale M F t\<^sub>0 X" using submartingale_axioms supermartingale_axioms by blast
+next
+  assume asm: "submartingale M F t\<^sub>0 X \<and> supermartingale M F t\<^sub>0 X"
+  interpret submartingale M F t\<^sub>0 X by (simp add: asm)
+  interpret supermartingale M F t\<^sub>0 X by (simp add: asm)
+  show "martingale M F t\<^sub>0 X" using submartingale_property supermartingale_property by (unfold_locales) (intro integrable, blast, force)
+qed
+
+subsection \<open>Martingale Lemmas\<close>
+
+text \<open>In the following segment, we cover basic properties of martingales.\<close>
+
+context martingale
+begin
+
+lemma cond_exp_diff_eq_zero:
+  assumes "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "AE \<xi> in M. cond_exp M (F i) (\<lambda>\<xi>. X j \<xi> - X i \<xi>) \<xi> = 0"
+  using martingale_property[OF assms] assms
+        sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, of i]
+        sigma_finite_subalgebra.cond_exp_diff[OF _ integrable(1,1), of "F i" j i] by fastforce
+
+lemma set_integral_eq:
+  assumes "A \<in> F i" "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "set_lebesgue_integral M A (X i) = set_lebesgue_integral M A (X j)"
+proof -
+  interpret sigma_finite_subalgebra M "F i" using assms(2) by blast
+  have "\<integral>x \<in> A. X i x \<partial>M = \<integral>x \<in> A. cond_exp M (F i) (X j) x \<partial>M" using martingale_property[OF assms(2,3)] borel_measurable_cond_exp' assms subalgebras subalgebra_def by (intro set_lebesgue_integral_cong_AE[OF _ random_variable]) fastforce+
+  also have "... = \<integral>x \<in> A. X j x \<partial>M" using assms by (auto simp: integrable intro: cond_exp_set_integral[symmetric])
+  finally show ?thesis .
+qed
+
+lemma scaleR_const[intro]:
+  shows "martingale M F t\<^sub>0 (\<lambda>i x. c *\<^sub>R X i x)"
+proof -
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    interpret sigma_finite_subalgebra M "F i" using asm by blast
+    have "AE x in M. c *\<^sub>R X i x = cond_exp M (F i) (\<lambda>x. c *\<^sub>R X j x) x" using asm cond_exp_scaleR_right[OF integrable, of j, THEN AE_symmetric] martingale_property[OF asm] by force
+  }
+  thus ?thesis by (unfold_locales) (auto simp add: integrable martingale.integrable)
+qed
+
+lemma uminus[intro]:
+  shows "martingale M F t\<^sub>0 (- X)" 
+  using scaleR_const[of "-1"] by (force intro: back_subst[of "martingale M F t\<^sub>0"])
+
+lemma add[intro]:
+  assumes "martingale M F t\<^sub>0 Y"
+  shows "martingale M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+proof -
+  interpret Y: martingale M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    hence "AE \<xi> in M. X i \<xi> + Y i \<xi> = cond_exp M (F i) (\<lambda>x. X j x + Y j x) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_add[OF _ integrable martingale.integrable[OF assms], of "F i" j j, THEN AE_symmetric]
+            martingale_property[OF asm] martingale.martingale_property[OF assms asm] by force
+  }
+  thus ?thesis using assms
+  by (unfold_locales) (auto simp add: integrable martingale.integrable)
+qed
+
+lemma diff[intro]:
+  assumes "martingale M F t\<^sub>0 Y"
+  shows "martingale M F t\<^sub>0 (\<lambda>i x. X i x - Y i x)"
+proof -
+  interpret Y: martingale M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    hence "AE \<xi> in M. X i \<xi> - Y i \<xi> = cond_exp M (F i) (\<lambda>x. X j x - Y j x) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_diff[OF _ integrable martingale.integrable[OF assms], of "F i" j j, THEN AE_symmetric] 
+            martingale_property[OF asm] martingale.martingale_property[OF assms asm] by fastforce
+  }
+  thus ?thesis using assms by (unfold_locales) (auto simp add: integrable martingale.integrable)  
+qed
+
+end
+
+text \<open>Using properties of the conditional expectation, we present the following alternative characterizations of martingales.\<close>
+
+lemma (in sigma_finite_adapted_process) martingale_of_cond_exp_diff_eq_zero: 
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)" 
+      and diff_zero: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> AE x in M. cond_exp M (F i) (\<lambda>\<xi>. X j \<xi> - X i \<xi>) x = 0"
+    shows "martingale M F t\<^sub>0 X"
+proof 
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. X i \<xi> = cond_exp M (F i) (X j) \<xi>" 
+      using diff_zero[OF asm] sigma_finite_subalgebra.cond_exp_diff[OF _ integrable(1,1), of "F i" j i] 
+            sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, of i] by fastforce
+  }
+qed (intro integrable)
+
+lemma (in sigma_finite_adapted_process) martingale_of_set_integral_eq:
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)"
+      and "\<And>A i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> A \<in> F i \<Longrightarrow> set_lebesgue_integral M A (X i) = set_lebesgue_integral M A (X j)" 
+    shows "martingale M F t\<^sub>0 X"
+proof (unfold_locales)
+  fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+  interpret sigma_finite_subalgebra M "F i" using asm by blast
+  interpret r: sigma_finite_measure "restr_to_subalg M (F i)" by (simp add: sigma_fin_subalg)
+  {
+    fix A assume "A \<in> restr_to_subalg M (F i)"
+    hence *: "A \<in> F i" using sets_restr_to_subalg subalgebras asm by blast 
+    have "set_lebesgue_integral (restr_to_subalg M (F i)) A (X i) = set_lebesgue_integral M A (X i)" using * subalg asm by (auto simp: set_lebesgue_integral_def intro: integral_subalgebra2 borel_measurable_scaleR adapted borel_measurable_indicator) 
+    also have "... = set_lebesgue_integral M A (cond_exp M (F i) (X j))" using * assms(2)[OF asm] cond_exp_set_integral[OF integrable] asm by auto
+    finally have "set_lebesgue_integral (restr_to_subalg M (F i)) A (X i) = set_lebesgue_integral (restr_to_subalg M (F i)) A (cond_exp M (F i) (X j))" using * subalg by (auto simp: set_lebesgue_integral_def intro!: integral_subalgebra2[symmetric] borel_measurable_scaleR borel_measurable_cond_exp borel_measurable_indicator)
+  }
+  hence "AE \<xi> in restr_to_subalg M (F i). X i \<xi> = cond_exp M (F i) (X j) \<xi>" using asm by (intro r.density_unique_banach, auto intro: integrable_in_subalg subalg borel_measurable_cond_exp integrable)
+  thus "AE \<xi> in M. X i \<xi> = cond_exp M (F i) (X j) \<xi>" using AE_restr_to_subalg[OF subalg] by blast
+qed (simp add: integrable)
+
+subsection \<open>Submartingale Lemmas\<close>
+
+context submartingale
+begin
+
+lemma cond_exp_diff_nonneg:
+  assumes "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "AE x in M. cond_exp M (F i) (\<lambda>\<xi>. X j \<xi> - X i \<xi>) x \<ge> 0"
+  using submartingale_property[OF assms] assms sigma_finite_subalgebra.cond_exp_diff[OF _ integrable(1,1), of _ j i] sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, of i] by fastforce
+
+lemma add[intro]:
+  assumes "submartingale M F t\<^sub>0 Y"
+  shows "submartingale M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+proof -
+  interpret Y: submartingale M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    hence "AE \<xi> in M. X i \<xi> + Y i \<xi> \<le> cond_exp M (F i) (\<lambda>x. X j x + Y j x) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_add[OF _ integrable submartingale.integrable[OF assms], of "F i" j j] 
+            submartingale_property[OF asm] submartingale.submartingale_property[OF assms asm] add_mono[of "X i _" _ "Y i _"] by force
+  }
+  thus ?thesis using assms by (unfold_locales) (auto simp add: borel_measurable_add random_variable adapted integrable Y.random_variable Y.adapted submartingale.integrable)  
+qed
+
+lemma diff[intro]:
+  assumes "supermartingale M F t\<^sub>0 Y"
+  shows "submartingale M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> - Y i \<xi>)"
+proof -
+  interpret Y: supermartingale M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    hence "AE \<xi> in M. X i \<xi> - Y i \<xi> \<le> cond_exp M (F i) (\<lambda>x. X j x - Y j x) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_diff[OF _ integrable supermartingale.integrable[OF assms], of "F i" j j] 
+            submartingale_property[OF asm] supermartingale.supermartingale_property[OF assms asm] diff_mono[of "X i _" _ _ "Y i _"] by force
+  }
+  thus ?thesis using assms by (unfold_locales) (auto simp add: borel_measurable_diff random_variable adapted integrable Y.random_variable Y.adapted supermartingale.integrable)  
+qed
+
+lemma scaleR_nonneg: 
+  assumes "c \<ge> 0"
+  shows "submartingale M F t\<^sub>0 (\<lambda>i \<xi>. c *\<^sub>R X i \<xi>)"
+proof
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. c *\<^sub>R X i \<xi> \<le> cond_exp M (F i) (\<lambda>\<xi>. c *\<^sub>R X j \<xi>) \<xi>"  
+      using sigma_finite_subalgebra.cond_exp_scaleR_right[OF _ integrable, of "F i" j c] submartingale_property[OF asm] by (fastforce intro!: scaleR_left_mono[OF _ assms])
+  }
+qed (auto simp add: borel_measurable_integrable borel_measurable_scaleR integrable random_variable adapted borel_measurable_const_scaleR)
+
+lemma scaleR_le_zero: 
+  assumes "c \<le> 0"
+  shows "supermartingale M F t\<^sub>0 (\<lambda>i \<xi>. c *\<^sub>R X i \<xi>)"
+proof
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. c *\<^sub>R X i \<xi> \<ge> cond_exp M (F i) (\<lambda>\<xi>. c *\<^sub>R X j \<xi>) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_scaleR_right[OF _ integrable, of "F i" j c] submartingale_property[OF asm] 
+            by (fastforce intro!: scaleR_left_mono_neg[OF _ assms])
+  }
+qed (auto simp add: borel_measurable_integrable borel_measurable_scaleR integrable random_variable adapted borel_measurable_const_scaleR)
+
+lemma uminus[intro]:
+  shows "supermartingale M F t\<^sub>0 (- X)"
+  unfolding fun_Compl_def using scaleR_le_zero[of "-1"] by simp
+
+end
+
+context submartingale_linorder
+begin
+
+lemma set_integral_le:
+  assumes "A \<in> F i" "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "set_lebesgue_integral M A (X i) \<le> set_lebesgue_integral M A (X j)"  
+  using submartingale_property[OF assms(2), of j] assms subalgebras
+  by (subst sigma_finite_subalgebra.cond_exp_set_integral[OF _ integrable assms(1), of j])
+     (auto intro!: scaleR_left_mono integral_mono_AE_banach integrable_mult_indicator integrable simp add: subalgebra_def set_lebesgue_integral_def)
+
+lemma max:
+  assumes "submartingale_linorder M F t\<^sub>0 Y"
+  shows "submartingale_linorder M F t\<^sub>0 (\<lambda>i \<xi>. max (X i \<xi>) (Y i \<xi>))"
+proof (unfold_locales)
+  interpret Y: submartingale_linorder M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    have "AE \<xi> in M. max (X i \<xi>) (Y i \<xi>) \<le> max (cond_exp M (F i) (X j) \<xi>) (cond_exp M (F i) (Y j) \<xi>)" using submartingale_property Y.submartingale_property asm unfolding max_def by fastforce
+    thus "AE \<xi> in M. max (X i \<xi>) (Y i \<xi>) \<le> cond_exp M (F i) (\<lambda>\<xi>. max (X j \<xi>) (Y j \<xi>)) \<xi>" using sigma_finite_subalgebra.cond_exp_max[OF _ integrable Y.integrable, of "F i" j j] asm by (fast intro: order.trans)
+  }
+  show "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> (\<lambda>\<xi>. max (X i \<xi>) (Y i \<xi>)) \<in> borel_measurable (F i)" "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (\<lambda>\<xi>. max (X i \<xi>) (Y i \<xi>))" by (force intro: Y.integrable integrable assms)+
+qed
+
+lemma max_0:
+  shows "submartingale_linorder M F t\<^sub>0 (\<lambda>i \<xi>. max 0 (X i \<xi>))"
+proof -
+  interpret zero: martingale_linorder M F t\<^sub>0 "\<lambda>_ _. 0" by (force intro: martingale_linorder.intro martingale_order.intro)
+  show ?thesis by (intro zero.max submartingale_linorder.intro submartingale_axioms)
+qed
+
+end
+
+lemma (in sigma_finite_adapted_process_order) submartingale_of_cond_exp_diff_nonneg:
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow>  integrable M (X i)" 
+      and diff_nonneg: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> AE x in M. cond_exp M (F i) (\<lambda>\<xi>. X j \<xi> - X i \<xi>) x \<ge> 0"
+    shows "submartingale M F t\<^sub>0 X"
+proof (unfold_locales)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. X i \<xi> \<le> cond_exp M (F i) (X j) \<xi>" 
+      using diff_nonneg[OF asm] sigma_finite_subalgebra.cond_exp_diff[OF _ integrable(1,1), of "F i" j i]
+            sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, of i] by fastforce
+  }
+qed (intro integrable)
+
+lemma (in sigma_finite_adapted_process_linorder) submartingale_of_set_integral_le:
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)"
+      and "\<And>A i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> A \<in> F i \<Longrightarrow> set_lebesgue_integral M A (X i) \<le> set_lebesgue_integral M A (X j)"
+    shows "submartingale M F t\<^sub>0 X"
+proof (unfold_locales)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    interpret r: sigma_finite_measure "restr_to_subalg M (F i)" using asm sigma_finite_subalgebra.sigma_fin_subalg by blast
+    {
+      fix A assume "A \<in> restr_to_subalg M (F i)"
+      hence *: "A \<in> F i" using asm sets_restr_to_subalg subalgebras by blast
+      have "set_lebesgue_integral (restr_to_subalg M (F i)) A (X i) = set_lebesgue_integral M A (X i)" using * asm subalgebras by (auto simp: set_lebesgue_integral_def intro: integral_subalgebra2 borel_measurable_scaleR adapted borel_measurable_indicator) 
+      also have "... \<le> set_lebesgue_integral M A (cond_exp M (F i) (X j))" using * assms(2)[OF asm] asm sigma_finite_subalgebra.cond_exp_set_integral[OF _ integrable] by fastforce
+      also have "... = set_lebesgue_integral (restr_to_subalg M (F i)) A (cond_exp M (F i) (X j))" using * asm subalgebras by (auto simp: set_lebesgue_integral_def intro!: integral_subalgebra2[symmetric] borel_measurable_scaleR borel_measurable_cond_exp borel_measurable_indicator)
+      finally have "0 \<le> set_lebesgue_integral (restr_to_subalg M (F i)) A (\<lambda>\<xi>. cond_exp M (F i) (X j) \<xi> - X i \<xi>)" using * asm subalgebras by (subst set_integral_diff, auto simp add: set_integrable_def sets_restr_to_subalg intro!: integrable adapted integrable_in_subalg borel_measurable_scaleR borel_measurable_indicator borel_measurable_cond_exp integrable_mult_indicator)
+    }
+    hence "AE \<xi> in restr_to_subalg M (F i). 0 \<le> cond_exp M (F i) (X j) \<xi> - X i \<xi>" 
+      by (intro r.density_nonneg integrable_in_subalg asm subalgebras borel_measurable_diff borel_measurable_cond_exp adapted Bochner_Integration.integrable_diff integrable_cond_exp integrable)
+    thus "AE \<xi> in M. X i \<xi> \<le> cond_exp M (F i) (X j) \<xi>" using AE_restr_to_subalg[OF subalgebras] asm by simp
+  }
+qed (intro integrable)
+
+subsection \<open>Supermartingale Lemmas\<close>
+
+text \<open>The following lemmas are exact duals of the ones for submartingales.\<close>
+
+context supermartingale
+begin
+
+lemma cond_exp_diff_nonneg:
+  assumes "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "AE x in M. cond_exp M (F i) (\<lambda>\<xi>. X i \<xi> - X j \<xi>) x \<ge> 0"
+  using assms supermartingale_property[OF assms] sigma_finite_subalgebra.cond_exp_diff[OF _ integrable(1,1), of "F i" i j] 
+        sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, of i] by fastforce
+
+lemma add[intro]:
+  assumes "supermartingale M F t\<^sub>0 Y"
+  shows "supermartingale M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+proof -
+  interpret Y: supermartingale M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    hence "AE \<xi> in M. X i \<xi> + Y i \<xi> \<ge> cond_exp M (F i) (\<lambda>x. X j x + Y j x) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_add[OF _ integrable supermartingale.integrable[OF assms], of "F i" j j] 
+            supermartingale_property[OF asm] supermartingale.supermartingale_property[OF assms asm] add_mono[of _ "X i _" _ "Y i _"] by force
+  }
+  thus ?thesis using assms by (unfold_locales) (auto simp add: borel_measurable_add random_variable adapted integrable Y.random_variable Y.adapted supermartingale.integrable)  
+qed
+
+lemma diff[intro]:
+  assumes "submartingale M F t\<^sub>0 Y"
+  shows "supermartingale M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> - Y i \<xi>)"
+proof -
+  interpret Y: submartingale M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    hence "AE \<xi> in M. X i \<xi> - Y i \<xi> \<ge> cond_exp M (F i) (\<lambda>x. X j x - Y j x) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_diff[OF _ integrable submartingale.integrable[OF assms], of "F i" j j, unfolded fun_diff_def] 
+            supermartingale_property[OF asm] submartingale.submartingale_property[OF assms asm] diff_mono[of _ "X i _" "Y i _"] by force
+  }
+  thus ?thesis using assms by (unfold_locales) (auto simp add: borel_measurable_diff random_variable adapted integrable Y.random_variable Y.adapted submartingale.integrable)  
+qed
+
+lemma scaleR_nonneg: 
+  assumes "c \<ge> 0"
+  shows "supermartingale M F t\<^sub>0 (\<lambda>i \<xi>. c *\<^sub>R X i \<xi>)"
+proof
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. c *\<^sub>R X i \<xi> \<ge> cond_exp M (F i) (\<lambda>\<xi>. c *\<^sub>R X j \<xi>) \<xi>"
+      using sigma_finite_subalgebra.cond_exp_scaleR_right[OF _ integrable, of "F i" j c] supermartingale_property[OF asm] by (fastforce intro!: scaleR_left_mono[OF _ assms])
+  }
+qed (auto simp add: borel_measurable_integrable borel_measurable_scaleR integrable random_variable adapted borel_measurable_const_scaleR)
+
+lemma scaleR_le_zero: 
+  assumes "c \<le> 0"
+  shows "submartingale M F t\<^sub>0 (\<lambda>i \<xi>. c *\<^sub>R X i \<xi>)"
+proof
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. c *\<^sub>R X i \<xi> \<le> cond_exp M (F i) (\<lambda>\<xi>. c *\<^sub>R X j \<xi>) \<xi>" 
+      using sigma_finite_subalgebra.cond_exp_scaleR_right[OF _ integrable, of "F i" j c] supermartingale_property[OF asm] by (fastforce intro!: scaleR_left_mono_neg[OF _ assms])
+  }
+qed (auto simp add: borel_measurable_integrable borel_measurable_scaleR integrable random_variable adapted borel_measurable_const_scaleR)
+
+lemma uminus[intro]:
+  shows "submartingale M F t\<^sub>0 (- X)"
+  unfolding fun_Compl_def using scaleR_le_zero[of "-1"] by simp
+
+end
+
+context supermartingale_linorder
+begin
+
+lemma set_integral_ge:
+  assumes "A \<in> F i" "t\<^sub>0 \<le> i" "i \<le> j"
+  shows "set_lebesgue_integral M A (X i) \<ge> set_lebesgue_integral M A (X j)"
+  using supermartingale_property[OF assms(2), of j] assms subalgebras
+  by (subst sigma_finite_subalgebra.cond_exp_set_integral[OF _ integrable assms(1), of j])
+     (auto intro!: scaleR_left_mono integral_mono_AE_banach integrable_mult_indicator integrable simp add: subalgebra_def set_lebesgue_integral_def)
+
+lemma min:
+  assumes "supermartingale_linorder M F t\<^sub>0 Y"
+  shows "supermartingale_linorder M F t\<^sub>0 (\<lambda>i \<xi>. min (X i \<xi>) (Y i \<xi>))"
+proof (unfold_locales)
+  interpret Y: supermartingale_linorder M F t\<^sub>0 Y by (rule assms)
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    have "AE \<xi> in M. min (X i \<xi>) (Y i \<xi>) \<ge> min (cond_exp M (F i) (X j) \<xi>) (cond_exp M (F i) (Y j) \<xi>)" using supermartingale_property Y.supermartingale_property asm unfolding min_def by fastforce
+    thus "AE \<xi> in M. min (X i \<xi>) (Y i \<xi>) \<ge> cond_exp M (F i) (\<lambda>\<xi>. min (X j \<xi>) (Y j \<xi>)) \<xi>" using sigma_finite_subalgebra.cond_exp_min[OF _ integrable Y.integrable, of "F i" j j] asm by (fast intro: order.trans)
+  }
+  show "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> (\<lambda>\<xi>. min (X i \<xi>) (Y i \<xi>)) \<in> borel_measurable (F i)" "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (\<lambda>\<xi>. min (X i \<xi>) (Y i \<xi>))" by (force intro: Y.integrable integrable assms)+
+qed
+
+lemma min_0:
+  shows "supermartingale_linorder M F t\<^sub>0 (\<lambda>i \<xi>. min 0 (X i \<xi>))"
+proof -
+  interpret zero: martingale_linorder M F t\<^sub>0 "\<lambda>_ _. 0" by (force intro: martingale_linorder.intro)
+  show ?thesis by (intro zero.min supermartingale_linorder.intro supermartingale_axioms)
+qed
+
+end
+
+lemma (in sigma_finite_adapted_process_order) supermartingale_of_cond_exp_diff_le_zero:
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)" 
+      and diff_le_zero: "\<And>i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> AE x in M. cond_exp M (F i) (\<lambda>\<xi>. X j \<xi> - X i \<xi>) x \<le> 0"
+    shows "supermartingale M F t\<^sub>0 X"
+proof 
+  {
+    fix i j :: 'b assume asm: "t\<^sub>0 \<le> i" "i \<le> j"
+    thus "AE \<xi> in M. X i \<xi> \<ge> cond_exp M (F i) (X j) \<xi>" 
+      using diff_le_zero[OF asm] sigma_finite_subalgebra.cond_exp_diff[OF _ integrable(1,1), of "F i" j i] 
+            sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, of i] by fastforce
+  }
+qed (intro integrable)
+
+lemma (in sigma_finite_adapted_process_linorder) supermartingale_of_set_integral_ge:
+  assumes integrable: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> integrable M (X i)" 
+      and "\<And>A i j. t\<^sub>0 \<le> i \<Longrightarrow> i \<le> j \<Longrightarrow> A \<in> F i \<Longrightarrow> set_lebesgue_integral M A (X j) \<le> set_lebesgue_integral M A (X i)" 
+    shows "supermartingale M F t\<^sub>0 X"
+proof -
+  interpret _: adapted_process M F t\<^sub>0 "-X" by (rule uminus_adapted)
+  interpret uminus_X: sigma_finite_adapted_process_linorder M F t\<^sub>0 "-X" ..
+  note * = set_integral_uminus[unfolded set_integrable_def, OF integrable_mult_indicator[OF _ integrable]]
+  have "supermartingale M F t\<^sub>0 (-(- X))"
+    using ord_eq_le_trans[OF * ord_le_eq_trans[OF le_imp_neg_le[OF assms(2)] *[symmetric]]] subalgebras
+    by (intro submartingale.uminus uminus_X.submartingale_of_set_integral_le) 
+       (clarsimp simp add: fun_Compl_def subalgebra_def integrable | fastforce)+
+  thus ?thesis unfolding fun_Compl_def by simp
+qed
+
+text \<open>Many of the statements we have made concerning martingales can be simplified when the indexing set is the natural numbers. 
+      Given a point in time \<^term>\<open>i \<in> \<nat>\<close>, it suffices to consider the successor \<^term>\<open>i + 1\<close>, instead of all future times \<^term>\<open>j \<ge> i\<close>.\<close>
+
+subsection \<open>Discrete Time Martingales\<close>
+
+locale nat_martingale = martingale M F "0 :: nat" X for M F X
+locale nat_submartingale = submartingale M F "0 :: nat" X for M F X
+locale nat_supermartingale = supermartingale M F "0 :: nat" X for M F X
+
+locale nat_submartingale_linorder = submartingale_linorder M F "0 :: nat" X for M F X
+locale nat_supermartingale_linorder = supermartingale_linorder M F "0 :: nat" X for M F X
+
+sublocale nat_submartingale_linorder \<subseteq> nat_submartingale ..
+sublocale nat_supermartingale_linorder \<subseteq> nat_supermartingale ..
+
+text \<open>A predictable martingale is necessarily constant.\<close>
+lemma (in nat_martingale) predictable_const:
+  assumes "nat_predictable_process M F X"
+  shows "AE \<xi> in M. X i \<xi> = X j \<xi>"
+proof -
+  have *: "AE \<xi> in M. X i \<xi> = X 0 \<xi>" for i
+  proof (induction i)
+    case 0
+    then show ?case by (simp add: bot_nat_def)
+  next
+    case (Suc i)
+    interpret S: nat_adapted_process M F "\<lambda>i. X (Suc i)" by (intro nat_predictable_process.adapted_Suc assms)
+    show ?case using Suc S.adapted[of i] martingale_property[OF _ le_SucI, of i] sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable, of "F i" "Suc i"] by fastforce
+  qed
+  show ?thesis using *[of i] *[of j] by force
+qed
+
+lemma (in nat_sigma_finite_adapted_process) martingale_of_set_integral_eq_Suc:
+  assumes integrable: "\<And>i. integrable M (X i)"
+      and "\<And>A i. A \<in> F i \<Longrightarrow> set_lebesgue_integral M A (X i) = set_lebesgue_integral M A (X (Suc i))" 
+    shows "nat_martingale M F X"
+proof (intro nat_martingale.intro martingale_of_set_integral_eq)
+  fix i j A assume asm: "i \<le> j" "A \<in> sets (F i)"
+  show "set_lebesgue_integral M A (X i) = set_lebesgue_integral M A (X j)" using asm
+  proof (induction "j - i" arbitrary: i j)
+    case 0
+    then show ?case using asm by simp
+  next
+    case (Suc n)
+    hence *: "n = j - Suc i" by linarith
+    have "Suc i \<le> j" using Suc(2,3) by linarith
+    thus ?case using sets_F_mono[OF _ le_SucI] Suc(4) Suc(1)[OF *] by (auto intro: assms(2)[THEN trans])
+  qed
+qed (simp add: integrable)
+
+lemma (in nat_sigma_finite_adapted_process) martingale_nat:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>i. AE \<xi> in M. X i \<xi> = cond_exp M (F i) (X (Suc i)) \<xi>" 
+    shows "nat_martingale M F X"
+proof (unfold_locales)
+  fix i j :: nat assume asm: "i \<le> j"
+  show "AE \<xi> in M. X i \<xi> = cond_exp M (F i) (X j) \<xi>" using asm
+  proof (induction "j - i" arbitrary: i j)
+    case 0
+    hence "j = i" by simp
+    thus ?case using sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable adapted, THEN AE_symmetric] by blast
+  next
+    case (Suc n)
+    have j: "j = Suc (n + i)" using Suc by linarith
+    have n: "n = n + i - i" using Suc by linarith
+    have *: "AE \<xi> in M. cond_exp M (F (n + i)) (X j) \<xi> = X (n + i) \<xi>" unfolding j using assms(2)[THEN AE_symmetric] by blast
+    have "AE \<xi> in M. cond_exp M (F i) (X j) \<xi> = cond_exp M (F i) (cond_exp M (F (n + i)) (X j)) \<xi>" by (intro cond_exp_nested_subalg integrable subalg, simp add: subalgebra_def sets_F_mono)
+    hence "AE \<xi> in M. cond_exp M (F i) (X j) \<xi> = cond_exp M (F i) (X (n + i)) \<xi>" using cond_exp_cong_AE[OF integrable_cond_exp integrable *] by force
+    thus ?case using Suc(1)[OF n] by fastforce
+  qed
+qed (simp add: integrable)
+
+lemma (in nat_sigma_finite_adapted_process) martingale_of_cond_exp_diff_Suc_eq_zero:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>i. AE \<xi> in M. cond_exp M (F i) (\<lambda>\<xi>. X (Suc i) \<xi> - X i \<xi>) \<xi> = 0" 
+    shows "nat_martingale M F X"
+proof (intro martingale_nat integrable) 
+  fix i 
+  show "AE \<xi> in M. X i \<xi> = cond_exp M (F i) (X (Suc i)) \<xi>" using cond_exp_diff[OF integrable(1,1), of i "Suc i" i] cond_exp_F_meas[OF integrable adapted, of i] assms(2)[of i] by fastforce
+qed
+
+subsection \<open>Discrete Time Submartingales\<close>
+
+lemma (in nat_submartingale) predictable_mono:
+  assumes "nat_predictable_process M F X" "i \<le> j"
+  shows "AE \<xi> in M. X i \<xi> \<le> X j \<xi>"
+  using assms(2)
+proof (induction "j - i" arbitrary: i j)
+  case 0
+  then show ?case by simp 
+next
+  case (Suc n)
+  hence *: "n = j - Suc i" by linarith
+  interpret S: nat_adapted_process M F "\<lambda>i. X (Suc i)" by (intro nat_predictable_process.adapted_Suc assms)
+  have "Suc i \<le> j" using Suc(2,3) by linarith
+  thus ?case using Suc(1)[OF *] S.adapted[of i] submartingale_property[OF _ le_SucI, of i] sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable, of "F i" "Suc i"] by fastforce
+qed
+
+lemma (in nat_sigma_finite_adapted_process_linorder) submartingale_of_set_integral_le_Suc:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>A i. A \<in> F i \<Longrightarrow> set_lebesgue_integral M A (X i) \<le> set_lebesgue_integral M A (X (Suc i))" 
+    shows "nat_submartingale M F X"
+proof (intro nat_submartingale.intro submartingale_of_set_integral_le)
+  fix i j A assume asm: "i \<le> j" "A \<in> sets (F i)"
+  show "set_lebesgue_integral M A (X i) \<le> set_lebesgue_integral M A (X j)" using asm
+  proof (induction "j - i" arbitrary: i j)
+    case 0
+    then show ?case using asm by simp
+  next
+    case (Suc n)
+    hence *: "n = j - Suc i" by linarith
+    have "Suc i \<le> j" using Suc(2,3) by linarith
+    thus ?case using sets_F_mono[OF _ le_SucI] Suc(4) Suc(1)[OF *] by (auto intro: assms(2)[THEN order_trans])
+  qed
+qed (simp add: integrable)
+
+lemma (in nat_sigma_finite_adapted_process_linorder) submartingale_nat:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>i. AE \<xi> in M. X i \<xi> \<le> cond_exp M (F i) (X (Suc i)) \<xi>" 
+    shows "nat_submartingale M F X"
+  using subalg integrable assms(2)
+  by (intro submartingale_of_set_integral_le_Suc ord_le_eq_trans[OF set_integral_mono_AE_banach cond_exp_set_integral[symmetric]], simp)
+     (meson in_mono integrable_mult_indicator set_integrable_def subalgebra_def, meson integrable_cond_exp in_mono integrable_mult_indicator set_integrable_def subalgebra_def, fast+)
+
+lemma (in nat_sigma_finite_adapted_process_linorder) submartingale_of_cond_exp_diff_Suc_nonneg:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>i. AE \<xi> in M. cond_exp M (F i) (\<lambda>\<xi>. X (Suc i) \<xi> - X i \<xi>) \<xi> \<ge> 0" 
+    shows "nat_submartingale M F X"
+proof (intro submartingale_nat integrable) 
+  fix i 
+  show "AE \<xi> in M. X i \<xi> \<le> cond_exp M (F i) (X (Suc i)) \<xi>" using cond_exp_diff[OF integrable(1,1), of i "Suc i" i] cond_exp_F_meas[OF integrable adapted, of i] assms(2)[of i] by fastforce
+qed
+
+lemma (in nat_submartingale_linorder) partial_sum_scaleR:
+  assumes "nat_adapted_process M F C" "\<And>i. AE \<xi> in M. 0 \<le> C i \<xi>" "\<And>i. AE \<xi> in M. C i \<xi> \<le> R"
+  shows "nat_submartingale M F (\<lambda>n \<xi>. \<Sum>i<n. C i \<xi> *\<^sub>R (X (Suc i) \<xi> - X i \<xi>))"
+proof-
+  interpret C: nat_adapted_process M F C by (rule assms)
+  interpret C': nat_adapted_process M F "\<lambda>i \<xi>. C (i - 1) \<xi> *\<^sub>R (X i \<xi> - X (i - 1) \<xi>)" by (intro nat_adapted_process.intro adapted_process.scaleR_right_adapted adapted_process.diff_adapted, unfold_locales) (auto intro: adaptedD C.adaptedD)+
+  interpret C'': nat_adapted_process M F "\<lambda>n \<xi>. \<Sum>i<n. C i \<xi> *\<^sub>R (X (Suc i) \<xi> - X i \<xi>)" by (rule C'.partial_sum_Suc_adapted[unfolded diff_Suc_1])
+  interpret S: nat_sigma_finite_adapted_process_linorder M F "(\<lambda>n \<xi>. \<Sum>i<n. C i \<xi> *\<^sub>R (X (Suc i) \<xi> - X i \<xi>))" ..
+  have "integrable M (\<lambda>x. C i x *\<^sub>R (X (Suc i) x - X i x))" for i using assms(2,3)[of i] by (intro Bochner_Integration.integrable_bound[OF integrable_scaleR_right, OF Bochner_Integration.integrable_diff, OF integrable(1,1), of R "Suc i" i]) (auto simp add: mult_mono)
+  moreover have "AE \<xi> in M. 0 \<le> cond_exp M (F i) (\<lambda>\<xi>. (\<Sum>i<Suc i. C i \<xi> *\<^sub>R (X (Suc i) \<xi> - X i \<xi>)) - (\<Sum>i<i. C i \<xi> *\<^sub>R (X (Suc i) \<xi> - X i \<xi>))) \<xi>" for i 
+    using sigma_finite_subalgebra.cond_exp_measurable_scaleR[OF _ calculation _ C.adapted, of i] 
+          cond_exp_diff_nonneg[OF _ le_SucI, OF _ order.refl, of i] assms(2,3)[of i] by (fastforce simp add: scaleR_nonneg_nonneg integrable)
+  ultimately show ?thesis by (intro S.submartingale_of_cond_exp_diff_Suc_nonneg Bochner_Integration.integrable_sum, blast+)
+qed
+
+lemma (in nat_submartingale_linorder) partial_sum_scaleR':
+  assumes "nat_predictable_process M F C" "\<And>i. AE \<xi> in M. 0 \<le> C i \<xi>" "\<And>i. AE \<xi> in M. C i \<xi> \<le> R"
+  shows "nat_submartingale M F (\<lambda>n \<xi>. \<Sum>i<n. C (Suc i) \<xi> *\<^sub>R (X (Suc i) \<xi> - X i \<xi>))"
+proof -
+  interpret C: nat_predictable_process M F C by (rule assms)
+  interpret Suc_C: nat_adapted_process M F "\<lambda>i. C (Suc i)" using C.adapted_Suc .
+  show ?thesis by (intro partial_sum_scaleR[of _ R] assms) (intro_locales)
+qed
+
+subsection \<open>Discrete Time Supermartingales\<close>
+
+lemma (in nat_supermartingale) predictable_mono:
+  assumes "nat_predictable_process M F X" "i \<le> j"
+  shows "AE \<xi> in M. X i \<xi> \<ge> X j \<xi>"
+  using assms(2)
+proof (induction "j - i" arbitrary: i j)
+  case 0
+  then show ?case by simp 
+next
+  case (Suc n)
+  hence *: "n = j - Suc i" by linarith
+  interpret S: nat_adapted_process M F "\<lambda>i. X (Suc i)" by (intro nat_predictable_process.adapted_Suc assms)
+  have "Suc i \<le> j" using Suc(2,3) by linarith
+  thus ?case using Suc(1)[OF *] S.adapted[of i] supermartingale_property[OF _ le_SucI, of i] sigma_finite_subalgebra.cond_exp_F_meas[OF _ integrable, of "F i" "Suc i"] by fastforce
+qed
+  
+lemma (in nat_sigma_finite_adapted_process_linorder) supermartingale_of_set_integral_ge_Suc:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>A i. A \<in> F i \<Longrightarrow> set_lebesgue_integral M A (X i) \<ge> set_lebesgue_integral M A (X (Suc i))" 
+    shows "nat_supermartingale M F X"
+proof -
+  interpret _: adapted_process M F 0 "-X" by (rule uminus_adapted)
+  interpret uminus_X: nat_sigma_finite_adapted_process_linorder M F "-X" ..
+  note * = set_integral_uminus[unfolded set_integrable_def, OF integrable_mult_indicator[OF _ integrable]]
+  have "nat_supermartingale M F (-(- X))" 
+    using ord_eq_le_trans[OF * ord_le_eq_trans[OF le_imp_neg_le[OF assms(2)] *[symmetric]]] subalgebras
+    by (intro nat_supermartingale.intro submartingale.uminus nat_submartingale.axioms uminus_X.submartingale_of_set_integral_le_Suc) 
+       (clarsimp simp add: fun_Compl_def subalgebra_def integrable | fastforce)+
+  thus ?thesis unfolding fun_Compl_def by simp
+qed
+
+lemma (in nat_sigma_finite_adapted_process_linorder) supermartingale_nat:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>i. AE \<xi> in M. X i \<xi> \<ge> cond_exp M (F i) (X (Suc i)) \<xi>" 
+    shows "nat_supermartingale M F X"
+proof -
+  interpret _: adapted_process M F 0 "-X" by (rule uminus_adapted)
+  interpret uminus_X: nat_sigma_finite_adapted_process_linorder M F "-X" ..
+  have "AE \<xi> in M. - X i \<xi> \<le> cond_exp M (F i) (\<lambda>x. - X (Suc i) x) \<xi>" for i using assms(2) cond_exp_uminus[OF integrable, of i "Suc i"] by force
+  hence "nat_supermartingale M F (-(- X))" by (intro nat_supermartingale.intro submartingale.uminus nat_submartingale.axioms uminus_X.submartingale_nat) (auto simp add: fun_Compl_def integrable)
+  thus ?thesis unfolding fun_Compl_def by simp
+qed
+
+lemma (in nat_sigma_finite_adapted_process_linorder) supermartingale_of_cond_exp_diff_Suc_le_zero:
+  assumes integrable: "\<And>i. integrable M (X i)" 
+      and "\<And>i. AE \<xi> in M. cond_exp M (F i) (\<lambda>\<xi>. X (Suc i) \<xi> - X i \<xi>) \<xi> \<le> 0" 
+    shows "nat_supermartingale M F X"
+proof (intro supermartingale_nat integrable) 
+  fix i
+  show "AE \<xi> in M. X i \<xi> \<ge> cond_exp M (F i) (X (Suc i)) \<xi>" using cond_exp_diff[OF integrable(1,1), of i "Suc i" i] cond_exp_F_meas[OF integrable adapted, of i] assms(2)[of i] by fastforce
+qed
+
+end
\ No newline at end of file
diff --git a/thys/Martingales/Measure_Space_Supplement.thy b/thys/Martingales/Measure_Space_Supplement.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Measure_Space_Supplement.thy
@@ -0,0 +1,61 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Measure_Space_Supplement
+  imports "HOL-Analysis.Measure_Space"
+begin
+
+section \<open>Supplementary Lemmas for Measure Spaces\<close>
+
+subsection \<open>\<open>\<sigma>\<close>-Algebra Generated by a Family of Functions\<close>
+
+definition family_vimage_algebra :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set \<Rightarrow> 'b measure \<Rightarrow> 'a measure" where
+  "family_vimage_algebra \<Omega> S M \<equiv> sigma \<Omega> (\<Union>f \<in> S. {f -` A \<inter> \<Omega> | A. A \<in> M})"
+
+text \<open>For singleton \<^term>\<open>S\<close>, i.e. \<^term>\<open>S = {f}\<close> for some \<^term>\<open>f\<close>, the definition simplifies to that of \<^term>\<open>vimage_algebra\<close>.\<close>
+
+lemma family_vimage_algebra_singleton: "family_vimage_algebra \<Omega> {f} M = vimage_algebra \<Omega> f M" unfolding family_vimage_algebra_def vimage_algebra_def by simp
+
+lemma
+  shows sets_family_vimage_algebra: "sets (family_vimage_algebra \<Omega> S M) = sigma_sets \<Omega> (\<Union>f \<in> S. {f -` A \<inter> \<Omega> | A. A \<in> M})" 
+    and space_family_vimage_algebra[simp]: "space (family_vimage_algebra \<Omega> S M) = \<Omega>"
+  by (auto simp add: family_vimage_algebra_def sets_measure_of_conv space_measure_of_conv)
+
+lemma measurable_family_vimage_algebra:
+  assumes "f \<in> S" "f \<in> \<Omega> \<rightarrow> space M"
+  shows "f \<in> family_vimage_algebra \<Omega> S M \<rightarrow>\<^sub>M M"
+  using assms by (intro measurableI, auto simp add: sets_family_vimage_algebra)
+
+lemma measurable_family_vimage_algebra_singleton:
+  assumes "f \<in> \<Omega> \<rightarrow> space M"
+  shows "f \<in> family_vimage_algebra \<Omega> {f} M \<rightarrow>\<^sub>M M"
+  using assms measurable_family_vimage_algebra by blast
+
+text \<open>A collection of functions are measurable with respect to some \<open>\<sigma>\<close>-algebra \<^term>\<open>N\<close>, if and only if the \<open>\<sigma>\<close>-algebra they generate is contained in \<^term>\<open>N\<close>.\<close>
+lemma measurable_family_iff_sets:
+  shows "(S \<subseteq> N \<rightarrow>\<^sub>M M) \<longleftrightarrow> S \<subseteq> space N \<rightarrow> space M \<and> family_vimage_algebra (space N) S M \<subseteq> N"
+proof (standard, goal_cases)
+  case 1
+  hence subset: "S \<subseteq> space N \<rightarrow> space M" using measurable_space by fast
+  have "{f -` A \<inter> space N |A. A \<in> M} \<subseteq> N" if "f \<in> S" for f using measurable_iff_sets[unfolded family_vimage_algebra_singleton[symmetric], of f] 1 subset that by (fastforce simp add: sets_family_vimage_algebra)
+  then show ?case unfolding sets_family_vimage_algebra using sets.sigma_algebra_axioms by (simp add: subset, intro sigma_algebra.sigma_sets_subset, blast+)
+next
+  case 2
+  hence subset: "S \<subseteq> space N \<rightarrow> space M" by simp
+  show ?case
+  proof (standard, goal_cases)
+    case (1 x)
+    have "family_vimage_algebra (space N) {x} M \<subseteq> N" by (metis (no_types, lifting) 1 2 sets_family_vimage_algebra SUP_le_iff sigma_sets_le_sets_iff singletonD)
+    thus ?case using measurable_iff_sets[unfolded family_vimage_algebra_singleton[symmetric]] subset[THEN subsetD, OF 1] by fast 
+  qed
+qed
+
+lemma family_vimage_algebra_diff:
+  shows "family_vimage_algebra \<Omega> S M = sigma \<Omega> (sets (family_vimage_algebra \<Omega> (S - I) M) \<union> family_vimage_algebra \<Omega> (S \<inter> I) M)"
+  using sets.space_closed space_measure_of_conv 
+  unfolding family_vimage_algebra_def sets_family_vimage_algebra
+  by (intro sigma_eqI, blast, fastforce)
+     (intro sigma_sets_eqI, blast, simp add: sets_measure_of_conv split: if_splits, 
+      meson Diff_subset Sup_subset_mono in_mono inf_sup_ord(1) sigma_sets_subseteq subset_image_iff, fastforce+)
+
+end
\ No newline at end of file
diff --git a/thys/Martingales/ROOT b/thys/Martingales/ROOT
new file mode 100755
--- /dev/null
+++ b/thys/Martingales/ROOT
@@ -0,0 +1,16 @@
+chapter AFP
+
+session "Martingales" (AFP) = "HOL-Probability" +
+  options [timeout = 1200]
+  theories
+    Measure_Space_Supplement
+    Elementary_Metric_Spaces_Supplement
+    Bochner_Integration_Supplement
+    Conditional_Expectation_Banach
+    Filtered_Measure
+    Stochastic_Process
+    Martingale
+    Example_Coin_Toss
+  document_files
+    "root.tex"
+    "root.bib"
diff --git a/thys/Martingales/Stochastic_Process.thy b/thys/Martingales/Stochastic_Process.thy
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/Stochastic_Process.thy
@@ -0,0 +1,773 @@
+(*  Author:     Ata Keskin, TU München 
+*)
+
+theory Stochastic_Process
+imports Filtered_Measure Measure_Space_Supplement "HOL-Probability.Independent_Family"
+begin      
+
+section \<open>Stochastic Processes\<close>
+
+subsection \<open>Stochastic Process\<close>
+
+text \<open>A stochastic process is a collection of random variables, indexed by a type \<^typ>\<open>'b\<close>.\<close>
+
+locale stochastic_process =
+  fixes M t\<^sub>0 and X :: "'b :: {second_countable_topology, order_topology, t2_space} \<Rightarrow> 'a \<Rightarrow> 'c :: {second_countable_topology, banach}"
+  assumes random_variable[measurable]: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> X i \<in> borel_measurable M"
+begin
+
+definition left_continuous where "left_continuous = (AE \<xi> in M. \<forall>t. continuous (at_left t) (\<lambda>i. X i \<xi>))"
+definition right_continuous where "right_continuous = (AE \<xi> in M. \<forall>t. continuous (at_right t) (\<lambda>i. X i \<xi>))"
+
+end
+
+text \<open>We specify the following locales to formalize discrete time and continuous time processes.\<close>
+
+locale nat_stochastic_process = stochastic_process M "0 :: nat" X for M X
+locale real_stochastic_process = stochastic_process M "0 :: real" X for M X
+
+lemma stochastic_process_const_fun:
+  assumes "f \<in> borel_measurable M"
+  shows "stochastic_process M t\<^sub>0 (\<lambda>_. f)" using assms by (unfold_locales)
+
+lemma stochastic_process_const:
+  shows "stochastic_process M t\<^sub>0 (\<lambda>i _. c i)" by (unfold_locales) simp
+
+text \<open>In the following segment, we cover basic operations on stochastic processes.\<close>
+
+context stochastic_process
+begin
+
+lemma compose_stochastic:
+  assumes "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> f i \<in> borel_measurable borel"
+  shows "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. (f i) (X i \<xi>))"
+  by (unfold_locales) (intro measurable_compose[OF random_variable assms]) 
+
+lemma norm_stochastic: "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. norm (X i \<xi>))" by (fastforce intro: compose_stochastic)
+
+lemma scaleR_right_stochastic:
+  assumes "stochastic_process M t\<^sub>0 Y"
+  shows "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. (Y i \<xi>) *\<^sub>R (X i \<xi>))"
+  using stochastic_process.random_variable[OF assms] random_variable by (unfold_locales) simp
+
+lemma scaleR_right_const_fun_stochastic: 
+  assumes "f \<in> borel_measurable M" 
+  shows "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. f \<xi> *\<^sub>R (X i \<xi>))" 
+  by (unfold_locales) (intro borel_measurable_scaleR assms random_variable)
+
+lemma scaleR_right_const_stochastic: "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. c i *\<^sub>R (X i \<xi>))"
+  by (unfold_locales) simp
+
+lemma add_stochastic:
+  assumes "stochastic_process M t\<^sub>0 Y"
+  shows "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+  using stochastic_process.random_variable[OF assms] random_variable by (unfold_locales) simp
+
+lemma diff_stochastic:
+  assumes "stochastic_process M t\<^sub>0 Y"
+  shows "stochastic_process M t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> - Y i \<xi>)"
+  using stochastic_process.random_variable[OF assms] random_variable by (unfold_locales) simp
+
+lemma uminus_stochastic: "stochastic_process M t\<^sub>0 (-X)" using scaleR_right_const_stochastic[of "\<lambda>_. -1"] by (simp add: fun_Compl_def)
+
+lemma partial_sum_stochastic: "stochastic_process M t\<^sub>0 (\<lambda>n \<xi>. \<Sum>i\<in>{t\<^sub>0..n}. X i \<xi>)" by (unfold_locales) simp
+
+lemma partial_sum'_stochastic: "stochastic_process M t\<^sub>0 (\<lambda>n \<xi>. \<Sum>i\<in>{t\<^sub>0..<n}. X i \<xi>)" by (unfold_locales) simp
+
+end
+
+lemma stochastic_process_sum:
+  assumes "\<And>i. i \<in> I \<Longrightarrow> stochastic_process M t\<^sub>0 (X i)"
+  shows "stochastic_process M t\<^sub>0 (\<lambda>k \<xi>. \<Sum>i \<in> I. X i k \<xi>)" using assms[THEN stochastic_process.random_variable] by (unfold_locales, auto)
+
+subsubsection \<open>Natural Filtration\<close>
+
+text \<open>The natural filtration induced by a stochastic process \<^term>\<open>X\<close> is the filtration generated by all events involving the process up to the time index \<^term>\<open>t\<close>, i.e. \<open>F t = \<sigma>({X s | s. s \<le> t})\<close>.\<close>
+
+definition natural_filtration :: "'a measure \<Rightarrow> 'b \<Rightarrow> ('b \<Rightarrow> 'a \<Rightarrow> 'c :: topological_space) \<Rightarrow> 'b :: {second_countable_topology, order_topology} \<Rightarrow> 'a measure" where
+  "natural_filtration M t\<^sub>0 Y = (\<lambda>t. family_vimage_algebra (space M) {Y i | i. i \<in> {t\<^sub>0..t}} borel)"
+
+abbreviation "nat_natural_filtration \<equiv> \<lambda>M. natural_filtration M (0 :: nat)"
+abbreviation "real_natural_filtration \<equiv> \<lambda>M. natural_filtration M (0 :: real)"
+
+lemma space_natural_filtration[simp]: "space (natural_filtration M t\<^sub>0 X t) = space M" unfolding natural_filtration_def space_family_vimage_algebra ..
+
+lemma sets_natural_filtration: "sets (natural_filtration M t\<^sub>0 X t) = sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M | A. A \<in> borel})"
+  unfolding natural_filtration_def sets_family_vimage_algebra by (intro sigma_sets_eqI) blast+
+
+lemma sets_natural_filtration': 
+  assumes "borel = sigma UNIV S"
+  shows "sets (natural_filtration M t\<^sub>0 X t) = sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M | A. A \<in> S})"
+proof (subst sets_natural_filtration, intro sigma_sets_eqI, clarify)
+  fix i and A :: "'a set" assume asm: "i \<in> {t\<^sub>0..t}" "A \<in> sets borel"
+  hence "A \<in> sigma_sets UNIV S" unfolding assms by simp
+  thus "X i -` A \<inter> space M \<in> sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M |A. A \<in> S})"
+  proof (induction)
+    case (Compl a)
+    have "X i -` (UNIV - a) \<inter> space M = space M - (X i -` a \<inter> space M)" by blast
+    then show ?case using Compl(2)[THEN sigma_sets.Compl] by presburger
+  next
+    case (Union a)
+    have "X i -` \<Union> (range a) \<inter> space M = \<Union> (range (\<lambda>j. X i -` a j \<inter> space M))" by blast
+    then show ?case using Union(2)[THEN sigma_sets.Union] by presburger
+  qed (auto intro: asm sigma_sets.Empty)
+qed (intro sigma_sets.Basic, force simp add: assms)
+
+lemma sets_natural_filtration_open: 
+  "sets (natural_filtration M t\<^sub>0 X t) = sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M | A. open A})"
+  using sets_natural_filtration' by (force simp only: borel_def mem_Collect_eq)
+
+lemma sets_natural_filtration_oi: 
+  "sets (natural_filtration M t\<^sub>0 X t) = sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M | A :: _ :: {linorder_topology, second_countable_topology} set. A \<in> range greaterThan})" 
+  by (rule sets_natural_filtration'[OF borel_Ioi])
+
+lemma sets_natural_filtration_io:
+  "sets (natural_filtration M t\<^sub>0 X t) = sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M | A :: _ :: {linorder_topology, second_countable_topology} set. A \<in> range lessThan})" 
+  by (rule sets_natural_filtration'[OF borel_Iio])
+
+lemma sets_natural_filtration_ci:
+  "sets (natural_filtration M t\<^sub>0 X t) = sigma_sets (space M) (\<Union>i\<in>{t\<^sub>0..t}. {X i -` A \<inter> space M | A :: real set. A \<in> range atLeast})" 
+  by (rule sets_natural_filtration'[OF borel_Ici])
+
+context stochastic_process
+begin
+
+lemma subalgebra_natural_filtration: 
+  shows "subalgebra M (natural_filtration M t\<^sub>0 X i)" 
+  unfolding subalgebra_def using measurable_family_iff_sets by (force simp add: natural_filtration_def)
+
+lemma filtered_measure_natural_filtration: 
+  shows "filtered_measure M (natural_filtration M t\<^sub>0 X) t\<^sub>0"
+    by (unfold_locales) (intro subalgebra_natural_filtration, simp only: sets_natural_filtration, intro sigma_sets_subseteq, force) 
+
+text \<open>In order to show that the natural filtration constitutes a filtered \<open>\<sigma>\<close>-finite measure, we need to provide a countable exhausting set in the preimage of \<^term>\<open>X t\<^sub>0\<close>.\<close>
+
+lemma sigma_finite_filtered_measure_natural_filtration:
+  assumes exhausting_set: "countable A" "(\<Union>A) = space M" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>" "\<And>a. a \<in> A \<Longrightarrow> \<exists>b \<in> borel. a = X t\<^sub>0 -` b \<inter> space M"
+    shows "sigma_finite_filtered_measure M (natural_filtration M t\<^sub>0 X) t\<^sub>0"
+proof (unfold_locales)
+  have "A \<subseteq> sets (restr_to_subalg M (natural_filtration M t\<^sub>0 X t\<^sub>0))" using exhausting_set by (simp add: sets_restr_to_subalg[OF subalgebra_natural_filtration] sets_natural_filtration) fast
+  moreover have "\<Union> A = space (restr_to_subalg M (natural_filtration M t\<^sub>0 X t\<^sub>0))" unfolding space_restr_to_subalg using exhausting_set by simp
+  moreover have "\<forall>a\<in>A. emeasure (restr_to_subalg M (natural_filtration M t\<^sub>0 X t\<^sub>0)) a \<noteq> \<infinity>" using calculation(1) exhausting_set(3) 
+    by (auto simp add: sets_restr_to_subalg[OF subalgebra_natural_filtration] emeasure_restr_to_subalg[OF subalgebra_natural_filtration])
+  ultimately show "\<exists>A. countable A \<and> A \<subseteq> sets (restr_to_subalg M (natural_filtration M t\<^sub>0 X t\<^sub>0)) \<and> \<Union> A = space (restr_to_subalg M (natural_filtration M t\<^sub>0 X t\<^sub>0)) \<and> (\<forall>a\<in>A. emeasure (restr_to_subalg M (natural_filtration M t\<^sub>0 X t\<^sub>0)) a \<noteq> \<infinity>)" using exhausting_set by blast
+  show "\<And>i j. \<lbrakk>t\<^sub>0 \<le> i; i \<le> j\<rbrakk> \<Longrightarrow> sets (natural_filtration M t\<^sub>0 X i) \<subseteq> sets (natural_filtration M t\<^sub>0 X j)" using filtered_measure.subalgebra_F[OF filtered_measure_natural_filtration] by (simp add: subalgebra_def)
+qed (auto intro: subalgebra_natural_filtration)
+
+lemma finite_filtered_measure_natural_filtration:
+  assumes "finite_measure M"
+  shows "finite_filtered_measure M (natural_filtration M t\<^sub>0 X) t\<^sub>0" 
+  using finite_measure.axioms[OF assms] filtered_measure_natural_filtration by intro_locales
+
+end
+
+text \<open>Filtration generated by independent variables.\<close>
+
+lemma (in prob_space) indep_set_natural_filtration:
+  assumes "t\<^sub>0 \<le> s" "s < t" "indep_vars (\<lambda>_. borel) X {t\<^sub>0..}"
+  shows "indep_set (natural_filtration M t\<^sub>0 X s) (vimage_algebra (space M) (X t) borel)"
+proof -
+  have "indep_sets (\<lambda>i. {X i -` A \<inter> space M |A. A \<in> sets borel}) (\<Union>(range (case_bool {t\<^sub>0..s} {t})))" 
+    using assms 
+    by (intro assms(3)[unfolded indep_vars_def, THEN conjunct2, THEN indep_sets_mono]) (auto simp add: case_bool_if)
+  thus ?thesis unfolding indep_set_def using assms
+    by (intro indep_sets_cong[THEN iffD1, OF refl _ indep_sets_collect_sigma[of "\<lambda>i. {X i -` A \<inter> space M | A. A \<in> borel}" "case_bool {t\<^sub>0..s} {t}"]])
+       (simp add: sets_natural_filtration sets_vimage_algebra split: bool.split, simp, intro Int_stableI, clarsimp, metis sets.Int vimage_Int Int_commute Int_left_absorb Int_left_commute, force simp add: disjoint_family_on_def split: bool.split)
+qed
+
+subsection \<open>Adapted Process\<close>
+
+text \<open>We call a collection a stochastic process \<^term>\<open>X\<close> adapted if \<^term>\<open>X i\<close> is \<^term>\<open>F i\<close>-borel-measurable for all indices \<^term>\<open>i :: 't\<close>.\<close>
+                                
+locale adapted_process = filtered_measure M F t\<^sub>0 for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {second_countable_topology, banach}" +
+  assumes adapted[measurable]: "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> X i \<in> borel_measurable (F i)"
+begin
+
+lemma adaptedE[elim]:
+  assumes "\<lbrakk>\<And>j i. t\<^sub>0 \<le> j \<Longrightarrow> j \<le> i \<Longrightarrow> X j \<in> borel_measurable (F i)\<rbrakk> \<Longrightarrow> P"
+  shows P
+  using assms using adapted by (metis dual_order.trans borel_measurable_subalgebra sets_F_mono space_F)
+
+lemma adaptedD:
+  assumes "t\<^sub>0 \<le> j" "j \<le> i" 
+  shows "X j \<in> borel_measurable (F i)" using assms adaptedE by meson
+
+end
+
+locale nat_adapted_process = adapted_process M F "0 :: nat" X for M F X
+locale real_adapted_process = adapted_process M F "0 :: real" X for M F X
+
+sublocale nat_adapted_process \<subseteq> nat_filtered_measure ..
+sublocale real_adapted_process \<subseteq> real_filtered_measure ..
+
+lemma (in filtered_measure) adapted_process_const_fun:
+  assumes "f \<in> borel_measurable (F t\<^sub>0)"
+  shows "adapted_process M F t\<^sub>0 (\<lambda>_. f)"
+  using measurable_from_subalg subalgebra_F assms by (unfold_locales) blast
+
+lemma (in filtered_measure) adapted_process_const:
+  shows "adapted_process M F t\<^sub>0 (\<lambda>i _. c i)" by (unfold_locales) simp
+
+
+text \<open>Again, we cover basic operations.\<close>
+
+context adapted_process
+begin
+
+lemma compose_adapted:
+  assumes "\<And>i. t\<^sub>0 \<le> i \<Longrightarrow> f i \<in> borel_measurable borel"
+  shows "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. (f i) (X i \<xi>))"
+  by (unfold_locales) (intro measurable_compose[OF adapted assms])
+
+lemma norm_adapted: "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. norm (X i \<xi>))" by (fastforce intro: compose_adapted)
+
+lemma scaleR_right_adapted:
+  assumes "adapted_process M F t\<^sub>0 R"
+  shows "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. (R i \<xi>) *\<^sub>R (X i \<xi>))"
+  using adapted_process.adapted[OF assms] adapted by (unfold_locales) simp
+  
+lemma scaleR_right_const_fun_adapted:
+  assumes "f \<in> borel_measurable (F t\<^sub>0)" 
+  shows "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. f \<xi> *\<^sub>R (X i \<xi>))"
+  using assms by (fast intro: scaleR_right_adapted adapted_process_const_fun)
+
+lemma scaleR_right_const_adapted: "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. c i *\<^sub>R (X i \<xi>))" by (unfold_locales) simp
+
+lemma add_adapted:
+  assumes "adapted_process M F t\<^sub>0 Y"
+  shows "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+  using adapted_process.adapted[OF assms] adapted by (unfold_locales) simp
+
+lemma diff_adapted:
+  assumes "adapted_process M F t\<^sub>0 Y"
+  shows "adapted_process M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> - Y i \<xi>)"
+  using adapted_process.adapted[OF assms] adapted by (unfold_locales) simp
+
+lemma uminus_adapted: "adapted_process M F t\<^sub>0 (-X)" using scaleR_right_const_adapted[of "\<lambda>_. -1"] by (simp add: fun_Compl_def)
+
+lemma partial_sum_adapted: "adapted_process M F t\<^sub>0 (\<lambda>n \<xi>. \<Sum>i\<in>{t\<^sub>0..n}. X i \<xi>)" 
+proof (unfold_locales)
+  fix i :: 'b
+  have "X j \<in> borel_measurable (F i)" if "t\<^sub>0 \<le> j" "j \<le> i" for j using that adaptedE by meson
+  thus "(\<lambda>\<xi>. \<Sum>i\<in>{t\<^sub>0..i}. X i \<xi>) \<in> borel_measurable (F i)" by simp
+qed
+
+lemma partial_sum'_adapted: "adapted_process M F t\<^sub>0 (\<lambda>n \<xi>. \<Sum>i\<in>{t\<^sub>0..<n}. X i \<xi>)" 
+proof (unfold_locales)
+  fix i :: 'b
+  have "X j \<in> borel_measurable (F i)" if "t\<^sub>0 \<le> j" "j < i" for j using that adaptedE by fastforce
+  thus "(\<lambda>\<xi>. \<Sum>i\<in>{t\<^sub>0..<i}. X i \<xi>) \<in> borel_measurable (F i)" by simp
+qed
+
+end
+
+text \<open>In the dicrete time case, we have the following lemma which will be useful later on.\<close>
+
+lemma (in nat_adapted_process) partial_sum_Suc_adapted: "nat_adapted_process M F (\<lambda>n \<xi>. \<Sum>i<n. X (Suc i) \<xi>)" 
+proof (unfold_locales)
+  fix i
+  have "X j \<in> borel_measurable (F i)" if "j \<le> i" for j using that adaptedD by blast
+  thus "(\<lambda>\<xi>. \<Sum>i<i. X (Suc i) \<xi>) \<in> borel_measurable (F i)" by auto
+qed
+
+lemma (in filtered_measure) adapted_process_sum:
+  assumes "\<And>i. i \<in> I \<Longrightarrow> adapted_process M F t\<^sub>0 (X i)"
+  shows "adapted_process M F t\<^sub>0 (\<lambda>k \<xi>. \<Sum>i \<in> I. X i k \<xi>)" 
+proof -
+  {
+    fix i k assume "i \<in> I" and asm: "t\<^sub>0 \<le> k"
+    then interpret adapted_process M F t\<^sub>0 "X i" using assms by simp
+    have "X i k \<in> borel_measurable M" "X i k \<in> borel_measurable (F k)" using measurable_from_subalg subalgebras adapted asm by (blast, simp)
+  }
+  thus ?thesis by (unfold_locales) simp
+qed
+
+text \<open>An adapted process is necessarily a stochastic process.\<close>
+
+sublocale adapted_process \<subseteq> stochastic_process using measurable_from_subalg subalgebras adapted by (unfold_locales) blast
+
+sublocale nat_adapted_process \<subseteq> nat_stochastic_process ..
+sublocale real_adapted_process \<subseteq> real_stochastic_process ..
+
+text \<open>A stochastic process is always adapted to the natural filtration it generates.\<close>
+
+lemma (in stochastic_process) adapted_process_natural_filtration: "adapted_process M (natural_filtration M t\<^sub>0 X) t\<^sub>0 X"
+  using filtered_measure_natural_filtration
+  by (intro_locales) (auto simp add: natural_filtration_def intro!: adapted_process_axioms.intro measurable_family_vimage_algebra) 
+
+subsection \<open>Progressively Measurable Process\<close>
+
+locale progressive_process = filtered_measure M F t\<^sub>0 for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {second_countable_topology, banach}" +
+  assumes progressive[measurable]: "\<And>t. t\<^sub>0 \<le> t \<Longrightarrow> (\<lambda>(i, x). X i x) \<in> borel_measurable (restrict_space borel {t\<^sub>0..t} \<Otimes>\<^sub>M F t)"
+begin
+
+lemma progressiveD:
+  assumes "S \<in> borel"
+  shows "(\<lambda>(j, \<xi>). X j \<xi>) -` S \<inter> ({t\<^sub>0..i} \<times> space M) \<in> (restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i)" 
+  using measurable_sets[OF progressive, OF _ assms, of i]
+  by (cases "t\<^sub>0 \<le> i") (auto simp add: space_restrict_space sets_pair_measure space_pair_measure)
+
+end
+
+locale nat_progressive_process = progressive_process M F "0 :: nat" X for M F X
+locale real_progressive_process = progressive_process M F "0 :: real" X for M F X
+
+lemma (in filtered_measure) progressive_process_const_fun:
+  assumes "f \<in> borel_measurable (F t\<^sub>0)"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>_. f)"
+proof (unfold_locales)
+  fix i assume asm: "t\<^sub>0 \<le> i"
+  have "f \<in> borel_measurable (F i)" using borel_measurable_mono[OF order.refl asm] assms by blast
+  thus "case_prod (\<lambda>_. f) \<in> borel_measurable (restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i)" using measurable_compose[OF measurable_snd] by simp
+qed
+
+lemma (in filtered_measure) progressive_process_const:
+  assumes "c \<in> borel_measurable borel"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i _. c i)"
+  using assms by (unfold_locales) (auto simp add: measurable_split_conv intro!: measurable_compose[OF measurable_fst] measurable_restrict_space1)
+
+context progressive_process
+begin
+
+lemma compose_progressive:
+  assumes "case_prod f \<in> borel_measurable borel"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. (f i) (X i \<xi>))"
+proof
+  fix i assume asm: "t\<^sub>0 \<le> i"
+  have "(\<lambda>(j, \<xi>). (j, X j \<xi>)) \<in> (restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i) \<rightarrow>\<^sub>M borel \<Otimes>\<^sub>M borel" 
+    using progressive[OF asm] measurable_fst''[OF measurable_restrict_space1, OF measurable_id] 
+    by (auto simp add: measurable_pair_iff measurable_split_conv)
+  moreover have "(\<lambda>(j, \<xi>). f j (X j \<xi>)) = case_prod f o ((\<lambda>(j, y). (j, y)) o (\<lambda>(j, \<xi>). (j, X j \<xi>)))" by fastforce
+  ultimately show "(\<lambda>(j, \<xi>). (f j) (X j \<xi>)) \<in> borel_measurable (restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i)" using assms by (simp add: borel_prod)
+qed
+
+lemma norm_progressive: "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. norm (X i \<xi>))" using measurable_compose[OF progressive borel_measurable_norm] by (unfold_locales) simp
+
+lemma scaleR_right_progressive:
+  assumes "progressive_process M F t\<^sub>0 R"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. (R i \<xi>) *\<^sub>R (X i \<xi>))"
+  using progressive_process.progressive[OF assms] by (unfold_locales) (simp add: progressive assms)
+  
+lemma scaleR_right_const_fun_progressive: 
+  assumes "f \<in> borel_measurable (F t\<^sub>0)" 
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. f \<xi> *\<^sub>R (X i \<xi>))"
+  using assms by (fast intro: scaleR_right_progressive progressive_process_const_fun)
+
+lemma scaleR_right_const_progressive: 
+  assumes "c \<in> borel_measurable borel"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. c i *\<^sub>R (X i \<xi>))" 
+  using assms by (fastforce intro: scaleR_right_progressive progressive_process_const)
+
+lemma add_progressive:
+  assumes "progressive_process M F t\<^sub>0 Y"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+  using progressive_process.progressive[OF assms] by (unfold_locales) (simp add: progressive assms)
+
+lemma diff_progressive:
+  assumes "progressive_process M F t\<^sub>0 Y"
+  shows "progressive_process M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> - Y i \<xi>)"
+  using progressive_process.progressive[OF assms] by (unfold_locales) (simp add: progressive assms)
+
+lemma uminus_progressive: "progressive_process M F t\<^sub>0 (-X)" using scaleR_right_const_progressive[of "\<lambda>_. -1"] by (simp add: fun_Compl_def)
+
+end
+
+text \<open>A progressively measurable process is also adapted.\<close>
+
+sublocale progressive_process \<subseteq> adapted_process using measurable_compose_rev[OF progressive measurable_Pair1'] 
+  unfolding prod.case space_restrict_space
+  by unfold_locales simp
+
+sublocale nat_progressive_process \<subseteq> nat_adapted_process ..
+sublocale real_progressive_process \<subseteq> real_adapted_process ..
+
+text \<open>In the discrete setting, adaptedness is equivalent to progressive measurability.\<close>
+
+theorem nat_progressive_iff_adapted: "nat_progressive_process M F X \<longleftrightarrow> nat_adapted_process M F X"
+proof (intro iffI)
+  assume asm: "nat_progressive_process M F X"
+  interpret nat_progressive_process M F X by (rule asm)
+  show "nat_adapted_process M F X" ..
+next
+  assume asm: "nat_adapted_process M F X"
+  interpret nat_adapted_process M F X by (rule asm) 
+  show "nat_progressive_process M F X"
+  proof (unfold_locales, intro borel_measurableI)
+    fix S :: "'b set" and i :: nat assume open_S: "open S"
+    {
+      fix j assume asm: "j \<le> i"
+      hence "X j -` S \<inter> space M \<in> F i" using adaptedD[of j, THEN measurable_sets] space_F open_S by fastforce
+      moreover have "case_prod X -` S \<inter> {j} \<times> space M = {j} \<times> (X j -` S \<inter> space M)" for j by fast
+      moreover have "{j :: nat} \<in> restrict_space borel {0..i}" using asm by (simp add: sets_restrict_space_iff)
+      ultimately have "case_prod X -` S \<inter> {j} \<times> space M \<in> restrict_space borel {0..i} \<Otimes>\<^sub>M F i" by simp
+    }
+    hence "(\<lambda>j. (\<lambda>(x, y). X x y) -` S \<inter> {j} \<times> space M) ` {..i} \<subseteq> restrict_space borel {0..i} \<Otimes>\<^sub>M F i" by blast
+    moreover have "case_prod X -` S \<inter> space (restrict_space borel {0..i} \<Otimes>\<^sub>M F i) = (\<Union>j\<le>i. case_prod X -` S \<inter> {j} \<times> space M)" unfolding space_pair_measure space_restrict_space space_F by force  
+    ultimately show "case_prod X -` S \<inter> space (restrict_space borel {0..i} \<Otimes>\<^sub>M F i) \<in> restrict_space borel {0..i} \<Otimes>\<^sub>M F i" by (metis sets.countable_UN)
+  qed
+qed
+
+subsection \<open>Predictable Process\<close>
+
+text \<open>We introduce the constant \<^term>\<open>\<Sigma>\<^sub>P\<close> to denote the predictable \<open>\<sigma>\<close>-algebra.\<close>
+
+context linearly_filtered_measure
+begin
+
+definition \<Sigma>\<^sub>P :: "('b \<times> 'a) measure" where predictable_sigma: "\<Sigma>\<^sub>P \<equiv> sigma ({t\<^sub>0..} \<times> space M) ({{s<..t} \<times> A | A s t. A \<in> F s \<and> t\<^sub>0 \<le> s \<and> s < t} \<union> {{t\<^sub>0} \<times> A | A. A \<in> F t\<^sub>0})"
+
+lemma space_predictable_sigma[simp]: "space \<Sigma>\<^sub>P = ({t\<^sub>0..} \<times> space M)" unfolding predictable_sigma space_measure_of_conv by blast
+
+lemma sets_predictable_sigma: "sets \<Sigma>\<^sub>P = sigma_sets ({t\<^sub>0..} \<times> space M) ({{s<..t} \<times> A | A s t. A \<in> F s \<and> t\<^sub>0 \<le> s \<and> s < t} \<union> {{t\<^sub>0} \<times> A | A. A \<in> F t\<^sub>0})" 
+  unfolding predictable_sigma using space_F sets.sets_into_space by (subst sets_measure_of) fastforce+
+
+lemma measurable_predictable_sigma_snd:
+  assumes "countable \<I>" "\<I> \<subseteq> {{s<..t} | s t. t\<^sub>0 \<le> s \<and> s < t}" "{t\<^sub>0<..} \<subseteq> (\<Union>\<I>)"
+  shows "snd \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M F t\<^sub>0"
+proof (intro measurableI)
+  fix S :: "'a set" assume asm: "S \<in> F t\<^sub>0"
+  have countable: "countable ((\<lambda>I. I \<times> S) ` \<I>)" using assms(1) by blast
+  have "(\<lambda>I. I \<times> S) ` \<I> \<subseteq> {{s<..t} \<times> A | A s t. A \<in> F s \<and> t\<^sub>0 \<le> s \<and>  s < t}" using sets_F_mono[OF order_refl, THEN subsetD, OF _ asm] assms(2) by blast
+  hence "(\<Union>I\<in>\<I>. I \<times> S) \<union> {t\<^sub>0} \<times> S \<in> \<Sigma>\<^sub>P" unfolding sets_predictable_sigma using asm by (intro sigma_sets_Un[OF sigma_sets_UNION[OF countable] sigma_sets.Basic] sigma_sets.Basic) blast+
+  moreover have "snd -` S \<inter> space \<Sigma>\<^sub>P = {t\<^sub>0..} \<times> S" using sets.sets_into_space[OF asm] by fastforce
+  moreover have "{t\<^sub>0} \<union> {t\<^sub>0<..} = {t\<^sub>0..}" by auto
+  moreover have "(\<Union>I\<in>\<I>. I \<times> S) \<union> {t\<^sub>0} \<times> S = {t\<^sub>0..} \<times> S" using assms(2,3) calculation(3) by fastforce
+  ultimately show "snd -` S \<inter> space \<Sigma>\<^sub>P \<in> \<Sigma>\<^sub>P" by argo
+qed (auto)
+
+lemma measurable_predictable_sigma_fst:
+  assumes "countable \<I>" "\<I> \<subseteq> {{s<..t} | s t. t\<^sub>0 \<le> s \<and> s < t}" "{t\<^sub>0<..} \<subseteq> (\<Union>\<I>)"
+  shows "fst \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M borel"
+proof -
+  have "A \<times> space M \<in> sets \<Sigma>\<^sub>P" if "A \<in> sigma_sets {t\<^sub>0..} {{s<..t} | s t. t\<^sub>0 \<le> s \<and> s < t}" for A unfolding sets_predictable_sigma using that 
+  proof (induction rule: sigma_sets.induct)
+    case (Basic a)
+    thus ?case using space_F sets.top by blast
+  next
+    case (Compl a)
+    have "({t\<^sub>0..} - a) \<times> space M = {t\<^sub>0..} \<times> space M - a \<times> space M" by blast
+    then show ?case using Compl(2)[THEN sigma_sets.Compl] by presburger
+  next
+    case (Union a)
+    have "\<Union> (range a) \<times> space M = \<Union> (range (\<lambda>i. a i \<times> space M))" by blast
+    then show ?case using Union(2)[THEN sigma_sets.Union] by presburger
+  qed (auto)
+  moreover have "restrict_space borel {t\<^sub>0..} = sigma {t\<^sub>0..} {{s<..t} | s t. t\<^sub>0 \<le> s \<and> s < t}"
+  proof -
+    have "sigma_sets {t\<^sub>0..} ((\<inter>) {t\<^sub>0..} ` sigma_sets UNIV (range greaterThan)) = sigma_sets {t\<^sub>0..} {{s<..t} |s t. t\<^sub>0 \<le> s \<and> s < t}"
+    proof (intro sigma_sets_eqI ; clarify)
+      fix A :: "'b set" assume asm: "A \<in> sigma_sets UNIV (range greaterThan)"
+      thus "{t\<^sub>0..} \<inter> A \<in> sigma_sets {t\<^sub>0..} {{s<..t} |s t. t\<^sub>0 \<le> s \<and> s < t}"
+      proof (induction rule: sigma_sets.induct)
+        case (Basic a)
+        then obtain s where s: "a = {s<..}" by blast
+        show ?case
+        proof (cases "t\<^sub>0 \<le> s")
+          case True
+          hence *: "{t\<^sub>0..} \<inter> a = (\<Union>i \<in> \<I>. {s<..} \<inter> i)" using s assms(3) by force
+          have "((\<inter>) {s<..} ` \<I>) \<subseteq> sigma_sets {t\<^sub>0..} {{s<..t} | s t. t\<^sub>0 \<le> s \<and> s < t}"
+          proof (clarify)
+            fix A assume "A \<in> \<I>"
+            then obtain s' t' where A: "A = {s'<..t'}" "t\<^sub>0 \<le> s'" "s' < t'" using assms(2) by blast
+            hence "{s<..} \<inter> A = {max s s'<..t'}" by fastforce
+            moreover have "t\<^sub>0 \<le> max s s'" using A True by linarith
+            moreover have "max s s' < t'" if "s < t'" using A that by linarith
+            moreover have "{s<..} \<inter> A = {}" if "\<not> s < t'" using A that by force
+            ultimately show "{s<..} \<inter> A \<in> sigma_sets {t\<^sub>0..} {{s<..t} |s t. t\<^sub>0 \<le> s \<and> s < t}" by (cases "s < t'") (blast, simp add: sigma_sets.Empty)
+          qed
+          thus ?thesis unfolding * using assms(1) by (intro sigma_sets_UNION) auto
+        next
+          case False
+          hence "{t\<^sub>0..} \<inter> a = {t\<^sub>0..}" using s by force
+          thus ?thesis using sigma_sets_top by auto
+        qed
+      next
+        case (Compl a)
+        have "{t\<^sub>0..} \<inter> (UNIV - a) = {t\<^sub>0..} - ({t\<^sub>0..} \<inter> a)" by blast
+        then show ?case using Compl(2)[THEN sigma_sets.Compl] by presburger
+      next
+        case (Union a)
+        have "{t\<^sub>0..} \<inter> \<Union> (range a) = \<Union> (range (\<lambda>i. {t\<^sub>0..} \<inter> a i))" by blast
+        then show ?case using Union(2)[THEN sigma_sets.Union] by presburger
+      qed (simp add: sigma_sets.Empty)
+    next 
+      fix s t assume asm: "t\<^sub>0 \<le> s" "s < t"
+      hence *: "{s<..t} = {s<..} \<inter> ({t\<^sub>0..} - {t<..})" by force
+      have "{s<..} \<in> sigma_sets {t\<^sub>0..} ((\<inter>) {t\<^sub>0..} ` sigma_sets UNIV (range greaterThan))" using asm by (intro sigma_sets.Basic) auto
+      moreover have "{t\<^sub>0..} - {t<..} \<in> sigma_sets {t\<^sub>0..} ((\<inter>) {t\<^sub>0..} ` sigma_sets UNIV (range greaterThan))" using asm by (intro sigma_sets.Compl sigma_sets.Basic) auto
+      ultimately show "{s<..t} \<in> sigma_sets {t\<^sub>0..} ((\<inter>) {t\<^sub>0..} ` sigma_sets UNIV (range greaterThan))" unfolding * Int_range_binary[of "{s<..}"] by (intro sigma_sets_Inter[OF _ binary_in_sigma_sets]) auto        
+    qed
+    thus ?thesis unfolding borel_Ioi restrict_space_def emeasure_sigma by (force intro: sigma_eqI)
+  qed
+  ultimately have "restrict_space borel {t\<^sub>0..} \<Otimes>\<^sub>M sigma (space M) {} \<subseteq> sets \<Sigma>\<^sub>P" 
+    unfolding sets_pair_measure space_restrict_space space_measure_of_conv
+    using space_predictable_sigma sets.sigma_algebra_axioms[of \<Sigma>\<^sub>P] 
+    by (intro sigma_algebra.sigma_sets_subset) (auto simp add: sigma_sets_empty_eq sets_measure_of_conv)
+  moreover have "space (restrict_space borel {t\<^sub>0..} \<Otimes>\<^sub>M sigma (space M) {}) = space \<Sigma>\<^sub>P" by (simp add: space_pair_measure)
+  moreover have "fst \<in> restrict_space borel {t\<^sub>0..} \<Otimes>\<^sub>M sigma (space M) {} \<rightarrow>\<^sub>M borel" by (fastforce intro: measurable_fst''[OF measurable_restrict_space1, of "\<lambda>x. x"]) 
+  ultimately show ?thesis by (meson borel_measurable_subalgebra)
+qed
+
+end
+
+locale predictable_process = linearly_filtered_measure M F t\<^sub>0 for M F t\<^sub>0 and X :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {second_countable_topology, banach}" +
+  assumes predictable: "(\<lambda>(t, x). X t x) \<in> borel_measurable \<Sigma>\<^sub>P"
+begin
+
+lemmas predictableD = measurable_sets[OF predictable, unfolded space_predictable_sigma]
+
+end
+
+(* * *)
+
+locale nat_predictable_process = predictable_process M F "0 :: nat" X for M F X
+locale real_predictable_process = predictable_process M F "0 :: real" X for M F X
+
+lemma (in nat_filtered_measure) measurable_predictable_sigma_snd':
+  shows "snd \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M F 0"
+  by (intro measurable_predictable_sigma_snd[of "range (\<lambda>x. {Suc x})"]) (force | simp add: greaterThan_0)+
+
+lemma (in nat_filtered_measure) measurable_predictable_sigma_fst':
+  shows "fst \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M borel"
+  by (intro measurable_predictable_sigma_fst[of "range (\<lambda>x. {Suc x})"]) (force | simp add: greaterThan_0)+
+
+lemma (in real_filtered_measure) measurable_predictable_sigma_snd':
+  shows "snd \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M F 0"
+  using real_arch_simple by (intro measurable_predictable_sigma_snd[of "range (\<lambda>x::nat. {0<..real (Suc x)})"]) (fastforce intro: add_increasing)+
+
+lemma (in real_filtered_measure) measurable_predictable_sigma_fst':
+  shows "fst \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M borel"
+  using real_arch_simple by (intro measurable_predictable_sigma_fst[of "range (\<lambda>x::nat. {0<..real (Suc x)})"]) (fastforce intro: add_increasing)+
+
+text \<open>We show sufficient conditions for functions constant in one argument to constitute a predictable process. In contrast to the cases before, this is not a triviality.\<close>
+
+lemma (in linearly_filtered_measure) predictable_process_const_fun:
+  assumes "snd \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M F t\<^sub>0" "f \<in> borel_measurable (F t\<^sub>0)"
+    shows "predictable_process M F t\<^sub>0 (\<lambda>_. f)"
+  using measurable_compose_rev[OF assms(2)] assms(1) by (unfold_locales) (auto simp add: measurable_split_conv)
+
+lemma (in nat_filtered_measure) predictable_process_const_fun'[intro]:
+  assumes "f \<in> borel_measurable (F 0)"
+  shows "nat_predictable_process M F (\<lambda>_. f)"
+  using assms by (intro predictable_process_const_fun[OF measurable_predictable_sigma_snd', THEN nat_predictable_process.intro])
+
+lemma (in real_filtered_measure) predictable_process_const_fun'[intro]:
+  assumes "f \<in> borel_measurable (F 0)"
+  shows "real_predictable_process M F (\<lambda>_. f)"
+  using assms by (intro predictable_process_const_fun[OF measurable_predictable_sigma_snd', THEN real_predictable_process.intro])
+
+lemma (in linearly_filtered_measure) predictable_process_const:
+  assumes "fst \<in> borel_measurable \<Sigma>\<^sub>P" "c \<in> borel_measurable borel"
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i _. c i)"
+  using assms by (unfold_locales) (simp add: measurable_split_conv)
+
+lemma (in linearly_filtered_measure) predictable_process_const_const[intro]:
+  shows "predictable_process M F t\<^sub>0 (\<lambda>_ _. c)"
+  by (unfold_locales) simp
+
+lemma (in nat_filtered_measure) predictable_process_const'[intro]:
+  assumes "c \<in> borel_measurable borel"
+  shows "nat_predictable_process M F (\<lambda>i _. c i)"
+  using assms by (intro predictable_process_const[OF measurable_predictable_sigma_fst', THEN nat_predictable_process.intro])
+
+lemma (in real_filtered_measure) predictable_process_const'[intro]:
+  assumes "c \<in> borel_measurable borel"
+  shows "real_predictable_process M F (\<lambda>i _. c i)"
+  using assms by (intro predictable_process_const[OF measurable_predictable_sigma_fst', THEN real_predictable_process.intro])
+
+context predictable_process
+begin
+
+lemma compose_predictable:
+  assumes "fst \<in> borel_measurable \<Sigma>\<^sub>P" "case_prod f \<in> borel_measurable borel"
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. (f i) (X i \<xi>))"
+proof
+  have "(\<lambda>(i, \<xi>). (i, X i \<xi>)) \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M borel \<Otimes>\<^sub>M borel" using predictable assms(1) by (auto simp add: measurable_pair_iff measurable_split_conv)
+  moreover have "(\<lambda>(i, \<xi>). f i (X i \<xi>)) = case_prod f o (\<lambda>(i, \<xi>). (i, X i \<xi>))" by fastforce
+  ultimately show "(\<lambda>(i, \<xi>). f i (X i \<xi>)) \<in> borel_measurable \<Sigma>\<^sub>P" unfolding borel_prod using assms by simp
+qed
+
+lemma norm_predictable: "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. norm (X i \<xi>))" using measurable_compose[OF predictable borel_measurable_norm] 
+  by (unfold_locales) (simp add: prod.case_distrib)
+
+lemma scaleR_right_predictable:
+  assumes "predictable_process M F t\<^sub>0 R"
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. (R i \<xi>) *\<^sub>R (X i \<xi>))"
+  using predictable predictable_process.predictable[OF assms] by (unfold_locales) (auto simp add: measurable_split_conv)
+
+lemma scaleR_right_const_fun_predictable: 
+  assumes "snd \<in> \<Sigma>\<^sub>P \<rightarrow>\<^sub>M F t\<^sub>0" "f \<in> borel_measurable (F t\<^sub>0)" 
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. f \<xi> *\<^sub>R (X i \<xi>))"
+  using assms by (fast intro: scaleR_right_predictable predictable_process_const_fun)
+
+lemma scaleR_right_const_predictable: 
+  assumes "fst \<in> borel_measurable \<Sigma>\<^sub>P" "c \<in> borel_measurable borel"
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. c i *\<^sub>R (X i \<xi>))" 
+  using assms by (fastforce intro: scaleR_right_predictable predictable_process_const)
+
+lemma scaleR_right_const'_predictable: "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. c *\<^sub>R (X i \<xi>))" 
+  by (fastforce intro: scaleR_right_predictable)
+
+lemma add_predictable:
+  assumes "predictable_process M F t\<^sub>0 Y"
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> + Y i \<xi>)"
+  using predictable predictable_process.predictable[OF assms] by (unfold_locales) (auto simp add: measurable_split_conv)
+
+lemma diff_predictable:
+  assumes "predictable_process M F t\<^sub>0 Y"
+  shows "predictable_process M F t\<^sub>0 (\<lambda>i \<xi>. X i \<xi> - Y i \<xi>)"
+  using predictable predictable_process.predictable[OF assms] by (unfold_locales) (auto simp add: measurable_split_conv)
+
+lemma uminus_predictable: "predictable_process M F t\<^sub>0 (-X)" using scaleR_right_const'_predictable[of "-1"] by (simp add: fun_Compl_def)
+
+end
+
+text \<open>Every predictable process is also progressively measurable.\<close>
+
+sublocale predictable_process \<subseteq> progressive_process
+proof (unfold_locales)
+  fix i :: 'b assume asm: "t\<^sub>0 \<le> i"
+  {
+    fix S :: "('b \<times> 'a) set" assume "S \<in> {{s<..t} \<times> A | A s t. A \<in> F s \<and> t\<^sub>0 \<le> s \<and> s < t} \<union> {{t\<^sub>0} \<times> A | A. A \<in> F t\<^sub>0}"
+    hence "(\<lambda>x. x) -` S \<inter> ({t\<^sub>0..i} \<times> space M) \<in> restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i"
+    proof
+      assume "S \<in> {{s<..t} \<times> A | A s t. A \<in> F s \<and> t\<^sub>0 \<le> s \<and> s < t}"
+      then obtain s t A where S_is: "S = {s<..t} \<times> A" "t\<^sub>0 \<le> s" "s < t" "A \<in> F s" by blast
+      hence "(\<lambda>x. x) -` S \<inter> ({t\<^sub>0..i} \<times> space M) = {s<..min i t} \<times> A" using sets.sets_into_space[OF S_is(4)] by auto
+      then show ?thesis using S_is sets_F_mono[of s i] by (cases "s \<le> i") (fastforce simp add: sets_restrict_space_iff)+
+    next
+      assume "S \<in> {{t\<^sub>0} \<times> A | A. A \<in> F t\<^sub>0}"
+      then obtain A where S_is: "S = {t\<^sub>0} \<times> A" "A \<in> F t\<^sub>0" by blast
+      hence "(\<lambda>x. x) -` S \<inter> ({t\<^sub>0..i} \<times> space M) = {t\<^sub>0} \<times> A" using asm sets.sets_into_space[OF S_is(2)] by auto
+      thus ?thesis using S_is(2) sets_F_mono[OF order_refl asm] asm by (fastforce simp add: sets_restrict_space_iff)
+    qed
+    hence "(\<lambda>x. x) -` S \<inter> space (restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i) \<in> restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i" by (simp add: space_pair_measure space_F[OF asm])
+  }
+  moreover have "{{s<..t} \<times> A |A s t. A \<in> sets (F s) \<and> t\<^sub>0 \<le> s \<and> s < t} \<union> {{t\<^sub>0} \<times> A |A. A \<in> sets (F t\<^sub>0)} \<subseteq> Pow ({t\<^sub>0..} \<times> space M)" using sets.sets_into_space by force
+  ultimately have "(\<lambda>x. x) \<in> restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i \<rightarrow>\<^sub>M \<Sigma>\<^sub>P" using space_F[OF asm] by (intro measurable_sigma_sets[OF sets_predictable_sigma]) (fast, force simp add: space_pair_measure)
+  thus "case_prod X \<in> borel_measurable (restrict_space borel {t\<^sub>0..i} \<Otimes>\<^sub>M F i)" using predictable by simp
+qed
+
+sublocale nat_predictable_process \<subseteq> nat_progressive_process ..
+sublocale real_predictable_process \<subseteq> real_progressive_process ..
+
+text \<open>The following lemma characterizes predictability in a discrete-time setting.\<close>
+
+lemma (in nat_filtered_measure) sets_in_filtration:
+  assumes "(\<Union>i. {i} \<times> A i) \<in> \<Sigma>\<^sub>P"
+  shows "A (Suc i) \<in> F i" "A 0 \<in> F 0"
+  using assms unfolding sets_predictable_sigma
+proof (induction "(\<Union>i. {i} \<times> A i)" arbitrary: A)
+  case Basic
+  {
+    assume "\<exists>S. (\<Union>i. {i} \<times> A i) = {0} \<times> S"
+    then obtain S where S: "(\<Union>i. {i} \<times> A i) = {bot} \<times> S" unfolding bot_nat_def by blast
+    hence "S \<in> F bot" using Basic by (fastforce simp add: times_eq_iff bot_nat_def)
+    moreover have "A i = {}" if "i \<noteq> bot" for i using that S by blast
+    moreover have "A bot = S" using S by blast
+    ultimately have "A (Suc i) \<in> F i" "A 0 \<in> F 0" for i unfolding bot_nat_def by (auto simp add: bot_nat_def)
+  }
+  note * = this
+  {
+    assume "\<nexists>S. (\<Union>i. {i} \<times> A i) = {0} \<times> S"
+    then obtain s t B where B: "(\<Union>i. {i} \<times> A i) = {s<..t} \<times> B" "B \<in> sets (F s)" "s < t" using Basic by auto
+    hence "A i = B" if "i \<in> {s<..t}" for i using that by fast
+    moreover have "A i = {}" if "i \<notin> {s<..t}" for i using B that by fastforce
+    ultimately have "A (Suc i) \<in> F i" "A 0 \<in> F 0" for i unfolding bot_nat_def using B sets_F_mono by (auto simp add: bot_nat_def) (metis less_Suc_eq_le sets.empty_sets subset_eq)
+  }
+  note ** = this
+  show "A (Suc i) \<in> sets (F i)" "A 0 \<in> sets (F 0)" using *(1)[of i] *(2) **(1)[of i] **(2) by blast+
+next
+  case Empty
+  {
+    case 1
+    then show ?case using Empty by simp
+  next
+    case 2
+    then show ?case using Empty by simp
+  }
+next
+  case (Compl a)
+  have a_in: "a \<subseteq> {0..} \<times> space M" using Compl(1) sets.sets_into_space sets_predictable_sigma space_predictable_sigma by metis
+  hence A_in: "A i \<subseteq> space M" for i using Compl(4) by blast
+  have a: "a = {0..} \<times> space M - (\<Union>i. {i} \<times> A i)" using a_in Compl(4) by blast
+  also have "... = - (\<Inter>j. - ({j} \<times> (space M - A j)))" by blast
+  also have "... = (\<Union>j. {j} \<times> (space M - A j))" by blast
+  finally have *: "(space M - A (Suc i)) \<in> F i" "(space M - A 0) \<in> F 0" using Compl(2,3) by auto
+  {
+    case 1
+    then show ?case using * A_in by (metis bot_nat_0.extremum double_diff sets.Diff sets.top sets_F_mono sets_le_imp_space_le space_F)
+ next
+    case 2
+    then show ?case using * A_in by (metis bot_nat_0.extremum double_diff sets.Diff sets.top sets_F_mono sets_le_imp_space_le space_F)
+  }
+next
+  case (Union a)
+  have a_in: "a i \<subseteq> {0..} \<times> space M" for i using Union(1) sets.sets_into_space sets_predictable_sigma space_predictable_sigma by metis
+  hence A_in: "A i \<subseteq> space M" for i using Union(4) by blast
+  have "snd x \<in> snd ` (a i \<inter> ({fst x} \<times> space M))" if "x \<in> a i" for i x using that a_in by fastforce
+  hence a_i: "a i = (\<Union>j. {j} \<times> (snd ` (a i \<inter> ({j} \<times> space M))))" for i by force
+  have A_i: "A i = snd ` (\<Union> (range a) \<inter> ({i} \<times> space M))" for i unfolding Union(4) using A_in by force 
+  have *: "snd ` (a j \<inter> ({Suc i} \<times> space M)) \<in> F i" "snd ` (a j \<inter> ({0} \<times> space M)) \<in> F 0" for j using Union(2,3)[OF a_i] by auto
+  {
+    case 1
+    have "(\<Union>j. snd ` (a j \<inter> ({Suc i} \<times> space M))) \<in> F i" using * by fast
+    moreover have "(\<Union>j. snd ` (a j \<inter> ({Suc i} \<times> space M))) = snd ` (\<Union> (range a) \<inter> ({Suc i} \<times> space M))" by fast
+    ultimately show ?case using A_i by metis
+  next
+    case 2
+    have "(\<Union>j. snd ` (a j \<inter> ({0} \<times> space M))) \<in> F 0" using * by fast
+    moreover have "(\<Union>j. snd ` (a j \<inter> ({0} \<times> space M))) = snd ` (\<Union> (range a) \<inter> ({0} \<times> space M))" by fast
+    ultimately show ?case using A_i by metis
+  }
+qed
+
+text \<open>This leads to the following useful fact.\<close>
+
+lemma (in nat_predictable_process) adapted_Suc: "nat_adapted_process M F (\<lambda>i. X (Suc i))"
+proof (unfold_locales, intro borel_measurableI)
+  fix S :: "'b set" and i assume open_S: "open S"
+  have "{Suc i} = {i<..Suc i}" by fastforce
+  hence "{Suc i} \<times> space M \<in> \<Sigma>\<^sub>P" using space_F[symmetric, of i] unfolding sets_predictable_sigma by (intro sigma_sets.Basic) blast
+  moreover have "case_prod X -` S \<inter> (UNIV \<times> space M) \<in> \<Sigma>\<^sub>P" unfolding atLeast_0[symmetric] using open_S by (intro predictableD, simp add: borel_open)
+  ultimately have "case_prod X -` S \<inter> ({Suc i} \<times> space M) \<in> \<Sigma>\<^sub>P" unfolding sets_predictable_sigma using space_F sets.sets_into_space
+    by (subst Times_Int_distrib1[of "{Suc i}" UNIV "space M", simplified], subst inf.commute, subst Int_assoc[symmetric], subst Int_range_binary) 
+       (intro sigma_sets_Inter binary_in_sigma_sets, fast)+
+  moreover have "case_prod X -` S \<inter> ({Suc i} \<times> space M) = {Suc i} \<times> (X (Suc i) -` S \<inter> space M)" by (auto simp add: le_Suc_eq)
+  moreover have "... = (\<Union>j. {j} \<times> (if j = Suc i then (X (Suc i) -` S \<inter> space M) else {}))" by (force split: if_splits)
+  ultimately have "(\<Union>j. {j} \<times> (if j = Suc i then (X (Suc i) -` S \<inter> space M) else {})) \<in> \<Sigma>\<^sub>P" by argo
+  thus "X (Suc i) -` S \<inter> space (F i) \<in> sets (F i)" using sets_in_filtration[of "\<lambda>j. if j = Suc i then (X (Suc i) -` S \<inter> space M) else {}"] space_F[OF zero_le] by presburger
+qed
+
+text \<open>The following lemma characterizes predictability in the discrete setting.\<close>
+
+theorem nat_predictable_process_iff: "nat_predictable_process M F X \<longleftrightarrow> nat_adapted_process M F (\<lambda>i. X (Suc i)) \<and> X 0 \<in> borel_measurable (F 0)"
+proof (intro iffI)
+  assume asm: "nat_adapted_process M F (\<lambda>i. X (Suc i)) \<and> X 0 \<in> borel_measurable (F 0)"
+  interpret nat_adapted_process M F "\<lambda>i. X (Suc i)" using asm by blast
+  have "(\<lambda>(x, y). X x y) \<in> borel_measurable \<Sigma>\<^sub>P"
+  proof (intro borel_measurableI)
+    fix S :: "'b set" assume open_S: "open S"
+    have "{i} \<times> (X i -` S \<inter> space M) \<in> sets \<Sigma>\<^sub>P" for i 
+    proof (cases i)
+      case 0
+      then show ?thesis unfolding sets_predictable_sigma 
+        using measurable_sets[OF _ borel_open[OF open_S], of "X 0" "F 0"] asm by auto
+    next
+      case (Suc i)
+      have "{Suc i} = {i<..Suc i}" by fastforce
+      then show ?thesis unfolding sets_predictable_sigma 
+        using measurable_sets[OF adapted borel_open[OF open_S], of i] 
+        by (intro sigma_sets.Basic, auto simp add: Suc)
+    qed
+    moreover have "(\<lambda>(x, y). X x y) -` S \<inter> space \<Sigma>\<^sub>P = (\<Union>i. {i} \<times> (X i -` S \<inter> space M))" by fastforce
+    ultimately show "(\<lambda>(x, y). X x y) -` S \<inter> space \<Sigma>\<^sub>P \<in> sets \<Sigma>\<^sub>P" by simp
+  qed
+  thus "nat_predictable_process M F X" by (unfold_locales)
+next
+  assume asm: "nat_predictable_process M F X"
+  interpret nat_predictable_process M F X by (rule asm)
+  show "nat_adapted_process M F (\<lambda>i. X (Suc i)) \<and> X 0 \<in> borel_measurable (F 0)" using adapted_Suc by simp
+qed
+                                                                            
+end
\ No newline at end of file
diff --git a/thys/Martingales/document/root.bib b/thys/Martingales/document/root.bib
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/document/root.bib
@@ -0,0 +1,46 @@
+@book{Hytoenen_2016, 
+	place={Cham, Switzerland}, 
+	title={Analysis in Banach Spaces Volume I: Martingales and Littlewood-Paley theory}, 
+	publisher={Springer International Publishing}, 
+	author={Hytönen, Tuomas and Neerven, Jan van and Veraar, Mark and Weis, Lutz}, 
+	year={2016},
+	ISBN={978-3-319-48519-5}
+} 
+
+@book{Lang_1993, 
+	place={New York}, 
+	title={Real and Functional Analysis}, 
+	publisher={Springer}, 
+	author={Lang, Serge}, 
+	year={1993},
+	isbn={978-1-4612-0897-6}
+} 
+
+@article{keskin2023formalization,
+      title={A Formalization of Martingales in {Isabelle/HOL}}, 
+      author={Ata Keskin},
+      year={2023},
+      eprint={2311.06188},
+      archivePrefix={arXiv},
+      primaryClass={cs.LO}
+}
+
+@book{engelking_1989,
+	title={General Topology},
+	author={Engelking, R.},
+	isbn={978-3-8853-8006-1},
+	series={Sigma series in pure mathematics},
+	url={https://books.google.com.tr/books?id=K3spAQAAMAAJ},
+	year={1989},
+	publisher={Heldermann}
+}
+
+@misc{Zitkovic_2015, 
+	place={Austin, Texas}, 
+	title={Lecture Notes on Conditional Expectation, Theory of Probability {I}, {UT Austin}},
+	note={\url{https://web.ma.utexas.edu/users/gordanz/notes/conditional_expectation.pdf}}, 
+	journal={Theory of Probability I}, publisher={The University of Texas at Austin}, 
+	author={Zitkovic, Gordan}, 
+	year={2015}, 
+	month={Jan}
+} 
\ No newline at end of file
diff --git a/thys/Martingales/document/root.tex b/thys/Martingales/document/root.tex
new file mode 100644
--- /dev/null
+++ b/thys/Martingales/document/root.tex
@@ -0,0 +1,79 @@
+\documentclass[11pt,a4paper]{article}
+\usepackage[T1]{fontenc}
+\usepackage{amsmath}
+\usepackage{amssymb}
+\usepackage{isabelle,isabellesym}
+
+% further packages required for unusual symbols (see also
+% isabellesym.sty), use only when needed
+
+%\usepackage{amssymb}
+  %for \<leadsto>, \<box>, \<diamond>, \<sqsupset>, \<mho>, \<Join>,
+  %\<lhd>, \<lesssim>, \<greatersim>, \<lessapprox>, \<greaterapprox>,
+  %\<triangleq>, \<yen>, \<lozenge>
+
+%\usepackage{eurosym}
+  %for \<euro>
+
+%\usepackage[only,bigsqcap,bigparallel,fatsemi,interleave,sslash]{stmaryrd}
+  %for \<Sqinter>, \<Parallel>, \<Zsemi>, \<Parallel>, \<sslash>
+
+%\usepackage{eufrak}
+  %for \<AA> ... \<ZZ>, \<aa> ... \<zz> (also included in amssymb)
+
+%\usepackage{textcomp}
+  %for \<onequarter>, \<onehalf>, \<threequarters>, \<degree>, \<cent>,
+  %\<currency>
+
+% this should be the last package used
+\usepackage{pdfsetup}
+
+% urls in roman style, theory text in math-similar italics
+\urlstyle{rm}
+\isabellestyle{it}
+
+% for uniform font size
+%\renewcommand{\isastyle}{\isastyleminor}
+
+\begin{document}
+
+\title{On the Formalization of Martingales}
+\author{Ata Keskin}
+\maketitle
+\begin{abstract}
+In the scope of this project, we present a formalization of martingales in arbitrary Banach spaces using Isabelle/HOL.
+
+The current formalization of conditional expectation in the Isabelle library is limited to real-valued functions. To overcome this limitation, we extend the construction of conditional expectation to general Banach spaces, employing an approach similar to the one described in \cite{Hytoenen_2016}. We use measure theoretic arguments to construct the conditional expectation using suitable limits of simple functions.
+
+Subsequently, we define stochastic processes and introduce the concepts of adapted, progressively measurable and predictable processes using suitable locale definitions\footnote{\texttt{Martingale.Stochastic\_Process}}. We show the relation
+\[
+	\text{adapted} \supseteq \text{progressive} \supseteq \text{predictable}
+\]
+Furthermore, we show that progressive measurability and adaptedness are equivalent when the indexing set is discrete.
+We pay special attention to predictable processes in discrete-time, showing that $(X_n)_{n \in \mathbb{N}}$ is predictable if and only if $(X_{n + 1})_{n \in \mathbb{N}}$ is adapted.
+
+Moving forward, we rigorously define martingales, submartingales, and supermartingales, presenting their first consequences and corollaries\footnote{\texttt{Martingale.Martingale}}. Discrete-time martingales are given special attention in the formalization. In every step of our formalization, we make extensive use of the powerful locale system of Isabelle.
+
+The formalization further contributes by generalizing concepts in Bochner integration by extending their application from the real numbers to arbitrary Banach spaces equipped with a second-countable topology. Induction schemes for integrable simple functions on Banach spaces are introduced, accommodating various scenarios with or without a real vector ordering\footnote{\texttt{Martingale.Bochner\_Integration\_Addendum}}. Specifically, we formalize a powerful result called the ``Averaging Theorem''\cite{Lang_1993} which allows us to show that densities are unique in Banach spaces.
+
+In-depth information on the formalization and the proofs of the individual theorems can be found in \cite{keskin2023formalization}.
+\end{abstract}
+\tableofcontents
+\pagebreak
+
+% sane default for proof documents
+\parindent 0pt\parskip 0.5ex
+
+% generated text of all theories
+\input{session}
+
+% optional bibliography
+\bibliographystyle{abbrv}
+\bibliography{root}
+
+\end{document}
+
+%%% Local Variables:
+%%% mode: latex
+%%% TeX-master: t
+%%% End:
diff --git a/thys/ROOTS b/thys/ROOTS
--- a/thys/ROOTS
+++ b/thys/ROOTS
@@ -1,789 +1,790 @@
 ABY3_Protocols
 ADS_Functor
 AI_Planning_Languages_Semantics
 AODV
 AOT
 AVL-Trees
 AWN
 Abortable_Linearizable_Modules
 Abs_Int_ITP2012
 Abstract-Hoare-Logics
 Abstract-Rewriting
 Abstract_Completeness
 Abstract_Soundness
 Ackermanns_not_PR
 Actuarial_Mathematics
 Adaptive_State_Counting
 Affine_Arithmetic
 Aggregation_Algebras
 Akra_Bazzi
 Algebraic_Numbers
 Algebraic_VCs
 Allen_Calculus
 Amicable_Numbers
 Amortized_Complexity
 AnselmGod
 Applicative_Lifting
 Approximation_Algorithms
 Architectural_Design_Patterns
 Aristotles_Assertoric_Syllogistic
 Arith_Prog_Rel_Primes
 ArrowImpossibilityGS
 Attack_Trees
 Auto2_HOL
 Auto2_Imperative_HOL
 AutoFocus-Stream
 Automated_Stateful_Protocol_Verification
 Automatic_Refinement
 AxiomaticCategoryTheory
 BDD
 BD_Security_Compositional
 BNF_CC
 BNF_Operations
 BTree
 Balog_Szemeredi_Gowers
 Banach_Steinhaus
 Belief_Revision
 Bell_Numbers_Spivey
 BenOr_Kozen_Reif
 Berlekamp_Zassenhaus
 Bernoulli
 Bertrands_Postulate
 Bicategory
 BinarySearchTree
 Binary_Code_Imprimitive
 Binding_Syntax_Theory
 Binomial-Heaps
 Binomial-Queues
 BirdKMP
 Birkhoff_Finite_Distributive_Lattices
 Blue_Eyes
 Bondy
 Boolean_Expression_Checkers
 Boolos_Curious_Inference
 Boolos_Curious_Inference_Automated
 Bounded_Deducibility_Security
 Buchi_Complementation
 Budan_Fourier
 Buffons_Needle
 Buildings
 BytecodeLogicJmlTypes
 C2KA_DistributedSystems
 CAVA_Automata
 CAVA_LTL_Modelchecker
 CCS
 CHERI-C_Memory_Model
 CISC-Kernel
 Concentration_Inequalities
 CRDT
 CRYSTALS-Kyber
 CSP_RefTK
 CVP_Hardness
 CYK
 CZH_Elementary_Categories
 CZH_Foundations
 CZH_Universal_Constructions
 CakeML
 CakeML_Codegen
 Call_Arity
 Card_Equiv_Relations
 Card_Multisets
 Card_Number_Partitions
 Card_Partitions
 Cardinality_Continuum
 Cartan_FP
 Case_Labeling
 Catalan_Numbers
 Category
 Category2
 Category3
 Catoids
 Cauchy
 Cayley_Hamilton
 Certification_Monads
 Ceva
 Chandy_Lamport
 Chebyshev_Polynomials
 Chord_Segments
 Circus
 Clean
 Clique_and_Monotone_Circuits
 ClockSynchInst
 Closest_Pair_Points
 CoCon
 CoSMeDis
 CoSMed
 CofGroups
 Coinductive
 Coinductive_Languages
 Collections
 Combinable_Wands
 Combinatorial_Enumeration_Algorithms
 Combinatorics_Words
 Combinatorics_Words_Graph_Lemma
 Combinatorics_Words_Lyndon
 CommCSL
 Commuting_Hermitian
 Comparison_Sort_Lower_Bound
 Compiling-Exceptions-Correctly
 Complete_Non_Orders
 Completeness
 Complex_Bounded_Operators
 Complex_Geometry
 Complx
 ComponentDependencies
 ConcurrentGC
 ConcurrentIMP
 Concurrent_Ref_Alg
 Concurrent_Revisions
 Conditional_Simplification
 Conditional_Transfer_Rule
 Consensus_Refined
 Constructive_Cryptography
 Constructive_Cryptography_CM
 Constructor_Funs
 Containers
 Cook_Levin
 CoreC++
 Core_DOM
 Core_SC_DOM
 Correctness_Algebras
 Cotangent_PFD_Formula
 Count_Complex_Roots
 Coupledsim_Contrasim
 CryptHOL
 CryptoBasedCompositionalProperties
 Crypto_Standards
 Cubic_Quartic_Equations
 DCR-ExecutionEquivalence
 DFS_Framework
 DOM_Components
 DPRM_Theorem
 DPT-SAT-Solver
 DataRefinementIBP
 Datatype_Order_Generator
 Decl_Sem_Fun_PL
 Decreasing-Diagrams
 Decreasing-Diagrams-II
 Dedekind_Real
 Deep_Learning
 Delta_System_Lemma
 Density_Compiler
 Dependent_SIFUM_Refinement
 Dependent_SIFUM_Type_Systems
 Depth-First-Search
 Derangements
 Deriving
 Descartes_Sign_Rule
 Design_Theory
 Dict_Construction
 Differential_Dynamic_Logic
 Differential_Game_Logic
 DigitsInBase
 Digit_Expansions
 Dijkstra_Shortest_Path
 Diophantine_Eqns_Lin_Hom
 Directed_Sets
 Dirichlet_L
 Dirichlet_Series
 DiscretePricing
 Discrete_Summation
 Disintegration
 DiskPaxos
 Distributed_Distinct_Elements
 Dominance_CHK
 DynamicArchitectures
 Dynamic_Tables
 E_Transcendental
 Earley_Parser
 Echelon_Form
 EdmondsKarp_Maxflow
 Edwards_Elliptic_Curves_Group
 Efficient-Mergesort
 Efficient_Weighted_Path_Order
 Elimination_Of_Repeated_Factors
 Elliptic_Curves_Group_Law
 Encodability_Process_Calculi
 Epistemic_Logic
 Equivalence_Relation_Enumeration
 Ergodic_Theory
 Error_Function
 Euler_MacLaurin
 Euler_Partition
 Euler_Polyhedron_Formula
 Eudoxus_Reals
 Eval_FO
 Example-Submission
 Executable_Randomized_Algorithms
 Expander_Graphs
 Extended_Finite_State_Machine_Inference
 Extended_Finite_State_Machines
 FFT
 FLP
 FOL-Fitting
 FOL_Axiomatic
 FOL_Harrison
 FOL_Seq_Calc1
 FOL_Seq_Calc2
 FOL_Seq_Calc3
 FO_Theory_Rewriting
 FSM_Tests
 Factor_Algebraic_Polynomial
 Factored_Transition_System_Bounding
 Falling_Factorial_Sum
 Farkas
 FeatherweightJava
 Featherweight_OCL
 Fermat3_4
 FileRefinement
 FinFun
 Finger-Trees
 Finite-Map-Extras
 Finite_Automata_HF
 Finite_Fields
 Finitely_Generated_Abelian_Groups
 First_Order_Terms
 First_Welfare_Theorem
 Fishburn_Impossibility
 Fisher_Yates
 Fishers_Inequality
 Fixed_Length_Vector
 Flow_Networks
 Floyd_Warshall
 Flyspeck-Tame
 FocusStreamsCaseStudies
 Forcing
 Formal_Puiseux_Series
 Formal_SSA
 Formula_Derivatives
 Foundation_of_geometry
 Fourier
 Free-Boolean-Algebra
 Free-Groups
 Frequency_Moments
 Fresh_Identifiers
 FunWithFunctions
 FunWithTilings
 Functional-Automata
 Functional_Ordered_Resolution_Prover
 Furstenberg_Topology
 GPU_Kernel_PL
 Gabow_SCC
 GaleStewart_Games
 Gale_Shapley
 Game_Based_Crypto
 Gauss-Jordan-Elim-Fun
 Gauss_Jordan
 Gauss_Sums
 Gaussian_Integers
 GenClock
 General-Triangle
 Generalized_Counting_Sort
 Generic_Deriving
 Generic_Join
 GewirthPGCProof
 Girth_Chromatic
 Given_Clause_Loops
 GoedelGod
 Goedel_HFSet_Semantic
 Goedel_HFSet_Semanticless
 Goedel_Incompleteness
 Goodstein_Lambda
 GraphMarkingIBP
 Graph_Saturation
 Graph_Theory
 Gray_Codes
 Green
 Groebner_Bases
 Groebner_Macaulay
 Gromov_Hyperbolicity
 Grothendieck_Schemes
 Group-Ring-Module
 HOL-CSP
 HOLCF-Prelude
 HRB-Slicing
 Hahn_Jordan_Decomposition
 Hales_Jewett
 Heard_Of
 Hello_World
 HereditarilyFinite
 Hermite
 Hermite_Lindemann
 Hidden_Markov_Models
 Higher_Order_Terms
 HoareForDivergence
 Hoare_Time
 Hood_Melville_Queue
 HotelKeyCards
 Huffman
 Hybrid_Logic
 Hybrid_Multi_Lane_Spatial_Logic
 Hybrid_Systems_VCs
 HyperCTL
 HyperHoareLogic
 Hyperdual
 Hypergraph_Basics
 Hypergraph_Colourings
 IEEE_Floating_Point
 IFC_Tracking
 IMAP-CRDT
 IMO2019
 IMP2
 IMP2_Binary_Heap
 IMP_Compiler
 IMP_Compiler_Reuse
 IO_Language_Conformance
 IP_Addresses
 Imperative_Insertion_Sort
 Implicational_Logic
 Impossible_Geometry
 Incompleteness
 Incredible_Proof_Machine
 Independence_CH
 Inductive_Confidentiality
 Inductive_Inference
 InfPathElimination
 InformationFlowSlicing
 InformationFlowSlicing_Inter
 Integration
 Interpolation_Polynomials_HOL_Algebra
 Interpreter_Optimizations
 Interval_Arithmetic_Word32
 Intro_Dest_Elim
 Involutions2Squares
 Iptables_Semantics
 Irrational_Series_Erdos_Straus
 Irrationality_J_Hancl
 Irrationals_From_THEBOOK
 IsaGeoCoq
 IsaNet
 Isabelle_C
 Isabelle_Marries_Dirac
 Isabelle_Meta_Model
 Jacobson_Basic_Algebra
 Jinja
 JinjaDCI
 JinjaThreads
 JiveDataStoreModel
 Jordan_Hoelder
 Jordan_Normal_Form
 KAD
 KAT_and_DRA
 KBPs
 KD_Tree
 Key_Agreement_Strong_Adversaries
 Khovanskii_Theorem
 Kleene_Algebra
 Kneser_Cauchy_Davenport
 Knights_Tour
 Knot_Theory
 Knuth_Bendix_Order
 Knuth_Morris_Pratt
 Koenigsberg_Friendship
 Kruskal
 Kuratowski_Closure_Complement
 LLL_Basis_Reduction
 LLL_Factorization
 LOFT
 LP_Duality
 LTL
 LTL_Master_Theorem
 LTL_Normal_Form
 LTL_to_DRA
 LTL_to_GBA
 Lam-ml-Normalization
 LambdaAuth
 LambdaMu
 Lambda_Free_EPO
 Lambda_Free_KBOs
 Lambda_Free_RPOs
 Lambert_Series
 Lambert_W
 Landau_Symbols
 Laplace_Transform
 Latin_Square
 LatticeProperties
 Launchbury
 Laws_of_Large_Numbers
 Lazy-Lists-II
 Lazy_Case
 Lehmer
 Lifting_Definition_Option
 Lifting_the_Exponent
 LightweightJava
 LinearQuantifierElim
 Linear_Inequalities
 Linear_Programming
 Linear_Recurrences
 Liouville_Numbers
 List-Index
 List-Infinite
 List_Interleaving
 List_Inversions
 List_Update
 LocalLexing
 Localization_Ring
 Locally-Nameless-Sigma
 Logging_Independent_Anonymity
 Lovasz_Local
 Lowe_Ontological_Argument
 Lower_Semicontinuous
 Lp
 Lucas_Theorem
 MDP-Algorithms
 MDP-Rewards
 MFMC_Countable
 MFODL_Monitor_Optimized
 MFOTL_Monitor
 MSO_Regex_Equivalence
 Markov_Models
 Marriage
+Martingales
 Mason_Stothers
 Matrices_for_ODEs
 Matrix
 Matrix_Tensor
 Matroids
 Max-Card-Matching
 Maximum_Segment_Sum
 Median_Method
 Median_Of_Medians_Selection
 Menger
 Mereology
 Mersenne_Primes
 Metalogic_ProofChecker
 MHComputation
 MiniML
 MiniSail
 Minimal_SSA
 Minkowskis_Theorem
 Minsky_Machines
 MLSS_Decision_Proc
 ML_Unification
 Modal_Logics_for_NTS
 Modular_Assembly_Kit_Security
 Modular_arithmetic_LLL_and_HNF_algorithms
 Monad_Memo_DP
 Monad_Normalisation
 MonoBoolTranAlgebra
 MonoidalCategory
 Monomorphic_Monad
 MuchAdoAboutTwo
 Multi_Party_Computation
 Multirelations
 Multirelations_Heterogeneous
 Multiset_Ordering_NPC
 Multitape_To_Singletape_TM
 Myhill-Nerode
 Name_Carrying_Type_Inference
 Nano_JSON
 Nash_Williams
 Nat-Interval-Logic
 Native_Word
 Nested_Multisets_Ordinals
 Network_Security_Policy_Verification
 Neumann_Morgenstern_Utility
 No_FTL_observers
 No_FTL_observers_Gen_Rel
 Nominal2
 Nominal_Myhill_Nerode
 Noninterference_CSP
 Noninterference_Concurrent_Composition
 Noninterference_Generic_Unwinding
 Noninterference_Inductive_Unwinding
 Noninterference_Ipurge_Unwinding
 Noninterference_Sequential_Composition
 NormByEval
 Nullstellensatz
 Number_Theoretic_Transform
 Octonions
 OpSets
 Open_Induction
 Optics
 Optimal_BST
 Orbit_Stabiliser
 Order_Lattice_Props
 Ordered_Resolution_Prover
 Ordinal
 Ordinal_Partitions
 Ordinals_and_Cardinals
 Ordinary_Differential_Equations
 PAC_Checker
 PAL
 PAPP_Impossibility
 PCF
 PLM
 POPLmark-deBruijn
 PSemigroupsConvolution
 Package_logic
 Padic_Field
 Padic_Ints
 Pairing_Heap
 Paraconsistency
 Parity_Game
 Partial_Function_MR
 Partial_Order_Reduction
 Password_Authentication_Protocol
 Pell
 Perfect_Fields
 Perfect-Number-Thm
 Perron_Frobenius
 Physical_Quantities
 Pi_Calculus
 Pi_Transcendental
 Planarity_Certificates
 Pluennecke_Ruzsa_Inequality
 Poincare_Bendixson
 Poincare_Disc
 Polygonal_Number_Theorem
 Polylog
 Polynomial_Crit_Geometry
 Polynomial_Factorization
 Polynomial_Interpolation
 Polynomials
 Pop_Refinement
 Posix-Lexing
 Possibilistic_Noninterference
 Power_Sum_Polynomials
 Pratt_Certificate
 Prefix_Free_Code_Combinators
 Presburger-Automata
 Prim_Dijkstra_Simple
 Prime_Distribution_Elementary
 Prime_Harmonic_Series
 Prime_Number_Theorem
 Priority_Queue_Braun
 Priority_Search_Trees
 Probabilistic_Noninterference
 Probabilistic_Prime_Tests
 Probabilistic_System_Zoo
 Probabilistic_Timed_Automata
 Probabilistic_While
 Probability_Inequality_Completeness
 Program-Conflict-Analysis
 Progress_Tracking
 Projective_Geometry
 Projective_Measurements
 Promela
 Proof_Strategy_Language
 PropResPI
 Propositional_Logic_Class
 Propositional_Proof_Systems
 Prpu_Maxflow
 PseudoHoops
 Psi_Calculi
 Ptolemys_Theorem
 Public_Announcement_Logic
 Q0_Metatheory
 Q0_Soundness
 QHLProver
 QR_Decomposition
 Quantales
 Quantales_Converse
 Quantifier_Elimination_Hybrid
 Quasi_Borel_Spaces
 Quaternions
 Query_Optimization
 Quick_Sort_Cost
 RIPEMD-160-SPARK
 ROBDD
 RSAPSS
 Ramsey-Infinite
 Random_BSTs
 Random_Graph_Subgraph_Threshold
 Randomised_BSTs
 Randomised_Social_Choice
 Rank_Nullity_Theorem
 Real_Impl
 Real_Power
 Real_Time_Deque
 Recursion-Addition
 Recursion-Theory-I
 Refine_Imperative_HOL
 Refine_Monadic
 RefinementReactive
 Regex_Equivalence
 Registers
 Regression_Test_Selection
 Regular-Sets
 Regular_Algebras
 Regular_Tree_Relations
 Relation_Algebra
 Relational-Incorrectness-Logic
 Relational_Cardinality
 Relational_Disjoint_Set_Forests
 Relational_Forests
 Relational_Method
 Relational_Minimum_Spanning_Trees
 Relational_Paths
 Rensets
 Rep_Fin_Groups
 ResiduatedTransitionSystem
 Residuated_Lattices
 Resolution_FOL
 Rewrite_Properties_Reduction
 Rewriting_Z
 Ribbon_Proofs
 Risk_Free_Lending
 Robbins-Conjecture
 Robinson_Arithmetic
 Root_Balanced_Tree
 Roth_Arithmetic_Progressions
 Routing
 Roy_Floyd_Warshall
 SATSolverVerification
 SCC_Bloemen_Sequential
 SC_DOM_Components
 SDS_Impossibility
 SIFPL
 SIFUM_Type_Systems
 SPARCv8
 S_Finite_Measure_Monad
 Safe_Distance
 Safe_OCL
 Safe_Range_RC
 Saturation_Framework
 Saturation_Framework_Extensions
 Sauer_Shelah_Lemma
 Schutz_Spacetime
 Schwartz_Zippel
 Secondary_Sylow
 Security_Protocol_Refinement
 Selection_Heap_Sort
 SenSocialChoice
 Separata
 Separation_Algebra
 Separation_Logic_Imperative_HOL
 Separation_Logic_Unbounded
 SequentInvertibility
 Shadow_DOM
 Shadow_SC_DOM
 Shivers-CFA
 ShortestPath
 Show
 Sigma_Commit_Crypto
 Signature_Groebner
 Simpl
 Simple_Clause_Learning
 Simple_Firewall
 Simplex
 Simplicial_complexes_and_boolean_functions
 SimplifiedOntologicalArgument
 Skew_Heap
 Skip_Lists
 Slicing
 Sliding_Window_Algorithm
 Smith_Normal_Form
 Smooth_Manifolds
 Solidity
 Sophomores_Dream
 Sort_Encodings
 Source_Coding_Theorem
 SpecCheck
 Special_Function_Bounds
 Splay_Tree
 Sqrt_Babylonian
 Stable_Matching
 Stalnaker_Logic
 Standard_Borel_Spaces
 Statecharts
 Stateful_Protocol_Composition_and_Typing
 Stellar_Quorums
 Stern_Brocot
 Stewart_Apollonius
 Stirling_Formula
 Stochastic_Matrices
 Stone_Algebras
 Stone_Kleene_Relation_Algebras
 Stone_Relation_Algebras
 Store_Buffer_Reduction
 Stream-Fusion
 Stream_Fusion_Code
 StrictOmegaCategories
 Strong_Security
 Sturm_Sequences
 Sturm_Tarski
 Stuttering_Equivalence
 Subresultants
 Subset_Boolean_Algebras
 SumSquares
 Sunflowers
 SuperCalc
 Suppes_Theorem
 Surprise_Paradox
 Symmetric_Polynomials
 Syntax_Independent_Logic
 Synthetic_Completeness
 Szemeredi_Regularity
 Szpilrajn
 TESL_Language
 TLA
 Tail_Recursive_Functions
 Tarskis_Geometry
 Taylor_Models
 Three_Circles
 Three_Squares
 Timed_Automata
 Topological_Semantics
 Topology
 TortoiseHare
 TsirelsonBound
 Transcendence_Series_Hancl_Rucki
 Transformer_Semantics
 Transition_Systems_and_Automata
 Transitive-Closure
 Transitive-Closure-II
 Transitive_Models
 Transport
 Treaps
 Tree-Automata
 Tree_Decomposition
 Tree_Enumeration
 Triangle
 Trie
 Turans_Graph_Theorem
 Twelvefold_Way
 Two_Generated_Word_Monoids_Intersection
 Tycon
 Types_Tableaus_and_Goedels_God
 Types_To_Sets_Extension
 UPF
 UPF_Firewall
 UTP
 Undirected_Graph_Theory
 Universal_Hash_Families
 Universal_Turing_Machine
 UpDown_Scheme
 VYDRA_MDL
 Valuation
 Van_Emde_Boas_Trees
 Van_der_Waerden
 VectorSpace
 VeriComp
 Verified-Prover
 Verified_SAT_Based_AI_Planning
 VerifyThis2018
 VerifyThis2019
 Vickrey_Clarke_Groves
 Virtual_Substitution
 VolpanoSmith
 WHATandWHERE_Security
 WOOT_Strong_Eventual_Consistency
 WebAssembly
 Weight_Balanced_Trees
 Weighted_Arithmetic_Geometric_Mean
 Weighted_Path_Order
 Well_Quasi_Orders
 Wetzels_Problem
 Winding_Number_Eval
 Word_Lib
 WorkerWrapper
 X86_Semantics
 XML
 Youngs_Inequality
 ZFC_in_HOL
 Zeckendorf
 Zeta_3_Irrational
 Zeta_Function
 pGCL
 Labeled_Transition_Systems
 Pushdown_Systems