diff --git a/src/HOL/Conditionally_Complete_Lattices.thy b/src/HOL/Conditionally_Complete_Lattices.thy
--- a/src/HOL/Conditionally_Complete_Lattices.thy
+++ b/src/HOL/Conditionally_Complete_Lattices.thy
@@ -1,738 +1,739 @@
 (*  Title:      HOL/Conditionally_Complete_Lattices.thy
     Author:     Amine Chaieb and L C Paulson, University of Cambridge
     Author:     Johannes Hölzl, TU München
     Author:     Luke S. Serafin, Carnegie Mellon University
 *)
 
 section \<open>Conditionally-complete Lattices\<close>
 
 theory Conditionally_Complete_Lattices
 imports Finite_Set Lattices_Big Set_Interval
 begin
 
 context preorder
 begin
 
 definition "bdd_above A \<longleftrightarrow> (\<exists>M. \<forall>x \<in> A. x \<le> M)"
 definition "bdd_below A \<longleftrightarrow> (\<exists>m. \<forall>x \<in> A. m \<le> x)"
 
 lemma bdd_aboveI[intro]: "(\<And>x. x \<in> A \<Longrightarrow> x \<le> M) \<Longrightarrow> bdd_above A"
   by (auto simp: bdd_above_def)
 
 lemma bdd_belowI[intro]: "(\<And>x. x \<in> A \<Longrightarrow> m \<le> x) \<Longrightarrow> bdd_below A"
   by (auto simp: bdd_below_def)
 
 lemma bdd_aboveI2: "(\<And>x. x \<in> A \<Longrightarrow> f x \<le> M) \<Longrightarrow> bdd_above (f`A)"
   by force
 
 lemma bdd_belowI2: "(\<And>x. x \<in> A \<Longrightarrow> m \<le> f x) \<Longrightarrow> bdd_below (f`A)"
   by force
 
 lemma bdd_above_empty [simp, intro]: "bdd_above {}"
   unfolding bdd_above_def by auto
 
 lemma bdd_below_empty [simp, intro]: "bdd_below {}"
   unfolding bdd_below_def by auto
 
 lemma bdd_above_mono: "bdd_above B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> bdd_above A"
   by (metis (full_types) bdd_above_def order_class.le_neq_trans psubsetD)
 
 lemma bdd_below_mono: "bdd_below B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> bdd_below A"
   by (metis bdd_below_def order_class.le_neq_trans psubsetD)
 
 lemma bdd_above_Int1 [simp]: "bdd_above A \<Longrightarrow> bdd_above (A \<inter> B)"
   using bdd_above_mono by auto
 
 lemma bdd_above_Int2 [simp]: "bdd_above B \<Longrightarrow> bdd_above (A \<inter> B)"
   using bdd_above_mono by auto
 
 lemma bdd_below_Int1 [simp]: "bdd_below A \<Longrightarrow> bdd_below (A \<inter> B)"
   using bdd_below_mono by auto
 
 lemma bdd_below_Int2 [simp]: "bdd_below B \<Longrightarrow> bdd_below (A \<inter> B)"
   using bdd_below_mono by auto
 
 lemma bdd_above_Ioo [simp, intro]: "bdd_above {a <..< b}"
   by (auto simp add: bdd_above_def intro!: exI[of _ b] less_imp_le)
 
 lemma bdd_above_Ico [simp, intro]: "bdd_above {a ..< b}"
   by (auto simp add: bdd_above_def intro!: exI[of _ b] less_imp_le)
 
 lemma bdd_above_Iio [simp, intro]: "bdd_above {..< b}"
   by (auto simp add: bdd_above_def intro: exI[of _ b] less_imp_le)
 
 lemma bdd_above_Ioc [simp, intro]: "bdd_above {a <.. b}"
   by (auto simp add: bdd_above_def intro: exI[of _ b] less_imp_le)
 
 lemma bdd_above_Icc [simp, intro]: "bdd_above {a .. b}"
   by (auto simp add: bdd_above_def intro: exI[of _ b] less_imp_le)
 
 lemma bdd_above_Iic [simp, intro]: "bdd_above {.. b}"
   by (auto simp add: bdd_above_def intro: exI[of _ b] less_imp_le)
 
 lemma bdd_below_Ioo [simp, intro]: "bdd_below {a <..< b}"
   by (auto simp add: bdd_below_def intro!: exI[of _ a] less_imp_le)
 
 lemma bdd_below_Ioc [simp, intro]: "bdd_below {a <.. b}"
   by (auto simp add: bdd_below_def intro!: exI[of _ a] less_imp_le)
 
 lemma bdd_below_Ioi [simp, intro]: "bdd_below {a <..}"
   by (auto simp add: bdd_below_def intro: exI[of _ a] less_imp_le)
 
 lemma bdd_below_Ico [simp, intro]: "bdd_below {a ..< b}"
   by (auto simp add: bdd_below_def intro: exI[of _ a] less_imp_le)
 
 lemma bdd_below_Icc [simp, intro]: "bdd_below {a .. b}"
   by (auto simp add: bdd_below_def intro: exI[of _ a] less_imp_le)
 
 lemma bdd_below_Ici [simp, intro]: "bdd_below {a ..}"
   by (auto simp add: bdd_below_def intro: exI[of _ a] less_imp_le)
 
 end
 
 lemma (in order_top) bdd_above_top[simp, intro!]: "bdd_above A"
   by (rule bdd_aboveI[of _ top]) simp
 
 lemma (in order_bot) bdd_above_bot[simp, intro!]: "bdd_below A"
   by (rule bdd_belowI[of _ bot]) simp
 
 lemma bdd_above_image_mono: "mono f \<Longrightarrow> bdd_above A \<Longrightarrow> bdd_above (f`A)"
   by (auto simp: bdd_above_def mono_def)
 
 lemma bdd_below_image_mono: "mono f \<Longrightarrow> bdd_below A \<Longrightarrow> bdd_below (f`A)"
   by (auto simp: bdd_below_def mono_def)
 
 lemma bdd_above_image_antimono: "antimono f \<Longrightarrow> bdd_below A \<Longrightarrow> bdd_above (f`A)"
   by (auto simp: bdd_above_def bdd_below_def antimono_def)
 
 lemma bdd_below_image_antimono: "antimono f \<Longrightarrow> bdd_above A \<Longrightarrow> bdd_below (f`A)"
   by (auto simp: bdd_above_def bdd_below_def antimono_def)
 
 lemma
   fixes X :: "'a::ordered_ab_group_add set"
   shows bdd_above_uminus[simp]: "bdd_above (uminus ` X) \<longleftrightarrow> bdd_below X"
     and bdd_below_uminus[simp]: "bdd_below (uminus ` X) \<longleftrightarrow> bdd_above X"
   using bdd_above_image_antimono[of uminus X] bdd_below_image_antimono[of uminus "uminus`X"]
   using bdd_below_image_antimono[of uminus X] bdd_above_image_antimono[of uminus "uminus`X"]
   by (auto simp: antimono_def image_image)
 
 context lattice
 begin
 
 lemma bdd_above_insert [simp]: "bdd_above (insert a A) = bdd_above A"
   by (auto simp: bdd_above_def intro: le_supI2 sup_ge1)
 
 lemma bdd_below_insert [simp]: "bdd_below (insert a A) = bdd_below A"
   by (auto simp: bdd_below_def intro: le_infI2 inf_le1)
 
 lemma bdd_finite [simp]:
   assumes "finite A" shows bdd_above_finite: "bdd_above A" and bdd_below_finite: "bdd_below A"
   using assms by (induct rule: finite_induct, auto)
 
 lemma bdd_above_Un [simp]: "bdd_above (A \<union> B) = (bdd_above A \<and> bdd_above B)"
 proof
   assume "bdd_above (A \<union> B)"
   thus "bdd_above A \<and> bdd_above B" unfolding bdd_above_def by auto
 next
   assume "bdd_above A \<and> bdd_above B"
   then obtain a b where "\<forall>x\<in>A. x \<le> a" "\<forall>x\<in>B. x \<le> b" unfolding bdd_above_def by auto
   hence "\<forall>x \<in> A \<union> B. x \<le> sup a b" by (auto intro: Un_iff le_supI1 le_supI2)
   thus "bdd_above (A \<union> B)" unfolding bdd_above_def ..
 qed
 
 lemma bdd_below_Un [simp]: "bdd_below (A \<union> B) = (bdd_below A \<and> bdd_below B)"
 proof
   assume "bdd_below (A \<union> B)"
   thus "bdd_below A \<and> bdd_below B" unfolding bdd_below_def by auto
 next
   assume "bdd_below A \<and> bdd_below B"
   then obtain a b where "\<forall>x\<in>A. a \<le> x" "\<forall>x\<in>B. b \<le> x" unfolding bdd_below_def by auto
   hence "\<forall>x \<in> A \<union> B. inf a b \<le> x" by (auto intro: Un_iff le_infI1 le_infI2)
   thus "bdd_below (A \<union> B)" unfolding bdd_below_def ..
 qed
 
 lemma bdd_above_image_sup[simp]:
   "bdd_above ((\<lambda>x. sup (f x) (g x)) ` A) \<longleftrightarrow> bdd_above (f`A) \<and> bdd_above (g`A)"
 by (auto simp: bdd_above_def intro: le_supI1 le_supI2)
 
 lemma bdd_below_image_inf[simp]:
   "bdd_below ((\<lambda>x. inf (f x) (g x)) ` A) \<longleftrightarrow> bdd_below (f`A) \<and> bdd_below (g`A)"
 by (auto simp: bdd_below_def intro: le_infI1 le_infI2)
 
 lemma bdd_below_UN[simp]: "finite I \<Longrightarrow> bdd_below (\<Union>i\<in>I. A i) = (\<forall>i \<in> I. bdd_below (A i))"
 by (induction I rule: finite.induct) auto
 
 lemma bdd_above_UN[simp]: "finite I \<Longrightarrow> bdd_above (\<Union>i\<in>I. A i) = (\<forall>i \<in> I. bdd_above (A i))"
 by (induction I rule: finite.induct) auto
 
 end
 
 
 text \<open>
 
 To avoid name classes with the \<^class>\<open>complete_lattice\<close>-class we prefix \<^const>\<open>Sup\<close> and
 \<^const>\<open>Inf\<close> in theorem names with c.
 
 \<close>
 
 class conditionally_complete_lattice = lattice + Sup + Inf +
   assumes cInf_lower: "x \<in> X \<Longrightarrow> bdd_below X \<Longrightarrow> Inf X \<le> x"
     and cInf_greatest: "X \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> z \<le> x) \<Longrightarrow> z \<le> Inf X"
   assumes cSup_upper: "x \<in> X \<Longrightarrow> bdd_above X \<Longrightarrow> x \<le> Sup X"
     and cSup_least: "X \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> x \<le> z) \<Longrightarrow> Sup X \<le> z"
 begin
 
 lemma cSup_upper2: "x \<in> X \<Longrightarrow> y \<le> x \<Longrightarrow> bdd_above X \<Longrightarrow> y \<le> Sup X"
   by (metis cSup_upper order_trans)
 
 lemma cInf_lower2: "x \<in> X \<Longrightarrow> x \<le> y \<Longrightarrow> bdd_below X \<Longrightarrow> Inf X \<le> y"
   by (metis cInf_lower order_trans)
 
 lemma cSup_mono: "B \<noteq> {} \<Longrightarrow> bdd_above A \<Longrightarrow> (\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. b \<le> a) \<Longrightarrow> Sup B \<le> Sup A"
   by (metis cSup_least cSup_upper2)
 
 lemma cInf_mono: "B \<noteq> {} \<Longrightarrow> bdd_below A \<Longrightarrow> (\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<le> b) \<Longrightarrow> Inf A \<le> Inf B"
   by (metis cInf_greatest cInf_lower2)
 
 lemma cSup_subset_mono: "A \<noteq> {} \<Longrightarrow> bdd_above B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> Sup A \<le> Sup B"
   by (metis cSup_least cSup_upper subsetD)
 
 lemma cInf_superset_mono: "A \<noteq> {} \<Longrightarrow> bdd_below B \<Longrightarrow> A \<subseteq> B \<Longrightarrow> Inf B \<le> Inf A"
   by (metis cInf_greatest cInf_lower subsetD)
 
 lemma cSup_eq_maximum: "z \<in> X \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> x \<le> z) \<Longrightarrow> Sup X = z"
   by (intro antisym cSup_upper[of z X] cSup_least[of X z]) auto
 
 lemma cInf_eq_minimum: "z \<in> X \<Longrightarrow> (\<And>x. x \<in> X \<Longrightarrow> z \<le> x) \<Longrightarrow> Inf X = z"
   by (intro antisym cInf_lower[of z X] cInf_greatest[of X z]) auto
 
 lemma cSup_le_iff: "S \<noteq> {} \<Longrightarrow> bdd_above S \<Longrightarrow> Sup S \<le> a \<longleftrightarrow> (\<forall>x\<in>S. x \<le> a)"
   by (metis order_trans cSup_upper cSup_least)
 
 lemma le_cInf_iff: "S \<noteq> {} \<Longrightarrow> bdd_below S \<Longrightarrow> a \<le> Inf S \<longleftrightarrow> (\<forall>x\<in>S. a \<le> x)"
   by (metis order_trans cInf_lower cInf_greatest)
 
 lemma cSup_eq_non_empty:
   assumes 1: "X \<noteq> {}"
   assumes 2: "\<And>x. x \<in> X \<Longrightarrow> x \<le> a"
   assumes 3: "\<And>y. (\<And>x. x \<in> X \<Longrightarrow> x \<le> y) \<Longrightarrow> a \<le> y"
   shows "Sup X = a"
   by (intro 3 1 antisym cSup_least) (auto intro: 2 1 cSup_upper)
 
 lemma cInf_eq_non_empty:
   assumes 1: "X \<noteq> {}"
   assumes 2: "\<And>x. x \<in> X \<Longrightarrow> a \<le> x"
   assumes 3: "\<And>y. (\<And>x. x \<in> X \<Longrightarrow> y \<le> x) \<Longrightarrow> y \<le> a"
   shows "Inf X = a"
   by (intro 3 1 antisym cInf_greatest) (auto intro: 2 1 cInf_lower)
 
 lemma cInf_cSup: "S \<noteq> {} \<Longrightarrow> bdd_below S \<Longrightarrow> Inf S = Sup {x. \<forall>s\<in>S. x \<le> s}"
   by (rule cInf_eq_non_empty) (auto intro!: cSup_upper cSup_least simp: bdd_below_def)
 
 lemma cSup_cInf: "S \<noteq> {} \<Longrightarrow> bdd_above S \<Longrightarrow> Sup S = Inf {x. \<forall>s\<in>S. s \<le> x}"
   by (rule cSup_eq_non_empty) (auto intro!: cInf_lower cInf_greatest simp: bdd_above_def)
 
 lemma cSup_insert: "X \<noteq> {} \<Longrightarrow> bdd_above X \<Longrightarrow> Sup (insert a X) = sup a (Sup X)"
   by (intro cSup_eq_non_empty) (auto intro: le_supI2 cSup_upper cSup_least)
 
 lemma cInf_insert: "X \<noteq> {} \<Longrightarrow> bdd_below X \<Longrightarrow> Inf (insert a X) = inf a (Inf X)"
   by (intro cInf_eq_non_empty) (auto intro: le_infI2 cInf_lower cInf_greatest)
 
 lemma cSup_singleton [simp]: "Sup {x} = x"
   by (intro cSup_eq_maximum) auto
 
 lemma cInf_singleton [simp]: "Inf {x} = x"
   by (intro cInf_eq_minimum) auto
 
 lemma cSup_insert_If:  "bdd_above X \<Longrightarrow> Sup (insert a X) = (if X = {} then a else sup a (Sup X))"
   using cSup_insert[of X] by simp
 
 lemma cInf_insert_If: "bdd_below X \<Longrightarrow> Inf (insert a X) = (if X = {} then a else inf a (Inf X))"
   using cInf_insert[of X] by simp
 
 lemma le_cSup_finite: "finite X \<Longrightarrow> x \<in> X \<Longrightarrow> x \<le> Sup X"
 proof (induct X arbitrary: x rule: finite_induct)
   case (insert x X y) then show ?case
     by (cases "X = {}") (auto simp: cSup_insert intro: le_supI2)
 qed simp
 
 lemma cInf_le_finite: "finite X \<Longrightarrow> x \<in> X \<Longrightarrow> Inf X \<le> x"
 proof (induct X arbitrary: x rule: finite_induct)
   case (insert x X y) then show ?case
     by (cases "X = {}") (auto simp: cInf_insert intro: le_infI2)
 qed simp
 
 lemma cSup_eq_Sup_fin: "finite X \<Longrightarrow> X \<noteq> {} \<Longrightarrow> Sup X = Sup_fin X"
   by (induct X rule: finite_ne_induct) (simp_all add: cSup_insert)
 
 lemma cInf_eq_Inf_fin: "finite X \<Longrightarrow> X \<noteq> {} \<Longrightarrow> Inf X = Inf_fin X"
   by (induct X rule: finite_ne_induct) (simp_all add: cInf_insert)
 
 lemma cSup_atMost[simp]: "Sup {..x} = x"
   by (auto intro!: cSup_eq_maximum)
 
 lemma cSup_greaterThanAtMost[simp]: "y < x \<Longrightarrow> Sup {y<..x} = x"
   by (auto intro!: cSup_eq_maximum)
 
 lemma cSup_atLeastAtMost[simp]: "y \<le> x \<Longrightarrow> Sup {y..x} = x"
   by (auto intro!: cSup_eq_maximum)
 
 lemma cInf_atLeast[simp]: "Inf {x..} = x"
   by (auto intro!: cInf_eq_minimum)
 
 lemma cInf_atLeastLessThan[simp]: "y < x \<Longrightarrow> Inf {y..<x} = y"
   by (auto intro!: cInf_eq_minimum)
 
 lemma cInf_atLeastAtMost[simp]: "y \<le> x \<Longrightarrow> Inf {y..x} = y"
   by (auto intro!: cInf_eq_minimum)
 
 lemma cINF_lower: "bdd_below (f ` A) \<Longrightarrow> x \<in> A \<Longrightarrow> \<Sqinter>(f ` A) \<le> f x"
   using cInf_lower [of _ "f ` A"] by simp
 
 lemma cINF_greatest: "A \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> m \<le> f x) \<Longrightarrow> m \<le> \<Sqinter>(f ` A)"
   using cInf_greatest [of "f ` A"] by auto
 
 lemma cSUP_upper: "x \<in> A \<Longrightarrow> bdd_above (f ` A) \<Longrightarrow> f x \<le> \<Squnion>(f ` A)"
   using cSup_upper [of _ "f ` A"] by simp
 
 lemma cSUP_least: "A \<noteq> {} \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> f x \<le> M) \<Longrightarrow> \<Squnion>(f ` A) \<le> M"
   using cSup_least [of "f ` A"] by auto
 
 lemma cINF_lower2: "bdd_below (f ` A) \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<le> u \<Longrightarrow> \<Sqinter>(f ` A) \<le> u"
   by (auto intro: cINF_lower order_trans)
 
 lemma cSUP_upper2: "bdd_above (f ` A) \<Longrightarrow> x \<in> A \<Longrightarrow> u \<le> f x \<Longrightarrow> u \<le> \<Squnion>(f ` A)"
   by (auto intro: cSUP_upper order_trans)
 
 lemma cSUP_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Squnion>x\<in>A. c) = c"
   by (intro antisym cSUP_least) (auto intro: cSUP_upper)
 
 lemma cINF_const [simp]: "A \<noteq> {} \<Longrightarrow> (\<Sqinter>x\<in>A. c) = c"
   by (intro antisym cINF_greatest) (auto intro: cINF_lower)
 
 lemma le_cINF_iff: "A \<noteq> {} \<Longrightarrow> bdd_below (f ` A) \<Longrightarrow> u \<le> \<Sqinter>(f ` A) \<longleftrightarrow> (\<forall>x\<in>A. u \<le> f x)"
   by (metis cINF_greatest cINF_lower order_trans)
 
 lemma cSUP_le_iff: "A \<noteq> {} \<Longrightarrow> bdd_above (f ` A) \<Longrightarrow> \<Squnion>(f ` A) \<le> u \<longleftrightarrow> (\<forall>x\<in>A. f x \<le> u)"
   by (metis cSUP_least cSUP_upper order_trans)
 
 lemma less_cINF_D: "bdd_below (f`A) \<Longrightarrow> y < (\<Sqinter>i\<in>A. f i) \<Longrightarrow> i \<in> A \<Longrightarrow> y < f i"
   by (metis cINF_lower less_le_trans)
 
 lemma cSUP_lessD: "bdd_above (f`A) \<Longrightarrow> (\<Squnion>i\<in>A. f i) < y \<Longrightarrow> i \<in> A \<Longrightarrow> f i < y"
   by (metis cSUP_upper le_less_trans)
 
 lemma cINF_insert: "A \<noteq> {} \<Longrightarrow> bdd_below (f ` A) \<Longrightarrow> \<Sqinter>(f ` insert a A) = inf (f a) (\<Sqinter>(f ` A))"
   by (simp add: cInf_insert cong del: INF_cong)
 
 lemma cSUP_insert: "A \<noteq> {} \<Longrightarrow> bdd_above (f ` A) \<Longrightarrow> \<Squnion>(f ` insert a A) = sup (f a) (\<Squnion>(f ` A))"
   by (simp add: cSup_insert cong del: SUP_cong)
 
 lemma cINF_mono: "B \<noteq> {} \<Longrightarrow> bdd_below (f ` A) \<Longrightarrow> (\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<le> g m) \<Longrightarrow> \<Sqinter>(f ` A) \<le> \<Sqinter>(g ` B)"
   using cInf_mono [of "g ` B" "f ` A"] by auto
 
 lemma cSUP_mono: "A \<noteq> {} \<Longrightarrow> bdd_above (g ` B) \<Longrightarrow> (\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<le> g m) \<Longrightarrow> \<Squnion>(f ` A) \<le> \<Squnion>(g ` B)"
   using cSup_mono [of "f ` A" "g ` B"] by auto
 
 lemma cINF_superset_mono: "A \<noteq> {} \<Longrightarrow> bdd_below (g ` B) \<Longrightarrow> A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> g x \<le> f x) \<Longrightarrow> \<Sqinter>(g ` B) \<le> \<Sqinter>(f ` A)"
   by (rule cINF_mono) auto
 
-lemma cSUP_subset_mono: "A \<noteq> {} \<Longrightarrow> bdd_above (g ` B) \<Longrightarrow> A \<subseteq> B \<Longrightarrow> (\<And>x. x \<in> B \<Longrightarrow> f x \<le> g x) \<Longrightarrow> \<Squnion>(f ` A) \<le> \<Squnion>(g ` B)"
+lemma cSUP_subset_mono: 
+  "\<lbrakk>A \<noteq> {}; bdd_above (g ` B); A \<subseteq> B; \<And>x. x \<in> A \<Longrightarrow> f x \<le> g x\<rbrakk> \<Longrightarrow> \<Squnion> (f ` A) \<le> \<Squnion> (g ` B)"
   by (rule cSUP_mono) auto
 
 lemma less_eq_cInf_inter: "bdd_below A \<Longrightarrow> bdd_below B \<Longrightarrow> A \<inter> B \<noteq> {} \<Longrightarrow> inf (Inf A) (Inf B) \<le> Inf (A \<inter> B)"
   by (metis cInf_superset_mono lattice_class.inf_sup_ord(1) le_infI1)
 
 lemma cSup_inter_less_eq: "bdd_above A \<Longrightarrow> bdd_above B \<Longrightarrow> A \<inter> B \<noteq> {} \<Longrightarrow> Sup (A \<inter> B) \<le> sup (Sup A) (Sup B) "
   by (metis cSup_subset_mono lattice_class.inf_sup_ord(1) le_supI1)
 
 lemma cInf_union_distrib: "A \<noteq> {} \<Longrightarrow> bdd_below A \<Longrightarrow> B \<noteq> {} \<Longrightarrow> bdd_below B \<Longrightarrow> Inf (A \<union> B) = inf (Inf A) (Inf B)"
   by (intro antisym le_infI cInf_greatest cInf_lower) (auto intro: le_infI1 le_infI2 cInf_lower)
 
 lemma cINF_union: "A \<noteq> {} \<Longrightarrow> bdd_below (f ` A) \<Longrightarrow> B \<noteq> {} \<Longrightarrow> bdd_below (f ` B) \<Longrightarrow> \<Sqinter> (f ` (A \<union> B)) = \<Sqinter> (f ` A) \<sqinter> \<Sqinter> (f ` B)"
   using cInf_union_distrib [of "f ` A" "f ` B"] by (simp add: image_Un cong del: INF_cong)
 
 lemma cSup_union_distrib: "A \<noteq> {} \<Longrightarrow> bdd_above A \<Longrightarrow> B \<noteq> {} \<Longrightarrow> bdd_above B \<Longrightarrow> Sup (A \<union> B) = sup (Sup A) (Sup B)"
   by (intro antisym le_supI cSup_least cSup_upper) (auto intro: le_supI1 le_supI2 cSup_upper)
 
 lemma cSUP_union: "A \<noteq> {} \<Longrightarrow> bdd_above (f ` A) \<Longrightarrow> B \<noteq> {} \<Longrightarrow> bdd_above (f ` B) \<Longrightarrow> \<Squnion> (f ` (A \<union> B)) = \<Squnion> (f ` A) \<squnion> \<Squnion> (f ` B)"
   using cSup_union_distrib [of "f ` A" "f ` B"] by (simp add: image_Un cong del: SUP_cong)
 
 lemma cINF_inf_distrib: "A \<noteq> {} \<Longrightarrow> bdd_below (f`A) \<Longrightarrow> bdd_below (g`A) \<Longrightarrow> \<Sqinter> (f ` A) \<sqinter> \<Sqinter> (g ` A) = (\<Sqinter>a\<in>A. inf (f a) (g a))"
   by (intro antisym le_infI cINF_greatest cINF_lower2)
      (auto intro: le_infI1 le_infI2 cINF_greatest cINF_lower le_infI)
 
 lemma SUP_sup_distrib: "A \<noteq> {} \<Longrightarrow> bdd_above (f`A) \<Longrightarrow> bdd_above (g`A) \<Longrightarrow> \<Squnion> (f ` A) \<squnion> \<Squnion> (g ` A) = (\<Squnion>a\<in>A. sup (f a) (g a))"
   by (intro antisym le_supI cSUP_least cSUP_upper2)
      (auto intro: le_supI1 le_supI2 cSUP_least cSUP_upper le_supI)
 
 lemma cInf_le_cSup:
   "A \<noteq> {} \<Longrightarrow> bdd_above A \<Longrightarrow> bdd_below A \<Longrightarrow> Inf A \<le> Sup A"
   by (auto intro!: cSup_upper2[of "SOME a. a \<in> A"] intro: someI cInf_lower)
 
 end
 
 instance complete_lattice \<subseteq> conditionally_complete_lattice
   by standard (auto intro: Sup_upper Sup_least Inf_lower Inf_greatest)
 
 lemma cSup_eq:
   fixes a :: "'a :: {conditionally_complete_lattice, no_bot}"
   assumes upper: "\<And>x. x \<in> X \<Longrightarrow> x \<le> a"
   assumes least: "\<And>y. (\<And>x. x \<in> X \<Longrightarrow> x \<le> y) \<Longrightarrow> a \<le> y"
   shows "Sup X = a"
 proof cases
   assume "X = {}" with lt_ex[of a] least show ?thesis by (auto simp: less_le_not_le)
 qed (intro cSup_eq_non_empty assms)
 
 lemma cInf_eq:
   fixes a :: "'a :: {conditionally_complete_lattice, no_top}"
   assumes upper: "\<And>x. x \<in> X \<Longrightarrow> a \<le> x"
   assumes least: "\<And>y. (\<And>x. x \<in> X \<Longrightarrow> y \<le> x) \<Longrightarrow> y \<le> a"
   shows "Inf X = a"
 proof cases
   assume "X = {}" with gt_ex[of a] least show ?thesis by (auto simp: less_le_not_le)
 qed (intro cInf_eq_non_empty assms)
 
 class conditionally_complete_linorder = conditionally_complete_lattice + linorder
 begin
 
 lemma less_cSup_iff:
   "X \<noteq> {} \<Longrightarrow> bdd_above X \<Longrightarrow> y < Sup X \<longleftrightarrow> (\<exists>x\<in>X. y < x)"
   by (rule iffI) (metis cSup_least not_less, metis cSup_upper less_le_trans)
 
 lemma cInf_less_iff: "X \<noteq> {} \<Longrightarrow> bdd_below X \<Longrightarrow> Inf X < y \<longleftrightarrow> (\<exists>x\<in>X. x < y)"
   by (rule iffI) (metis cInf_greatest not_less, metis cInf_lower le_less_trans)
 
 lemma cINF_less_iff: "A \<noteq> {} \<Longrightarrow> bdd_below (f`A) \<Longrightarrow> (\<Sqinter>i\<in>A. f i) < a \<longleftrightarrow> (\<exists>x\<in>A. f x < a)"
   using cInf_less_iff[of "f`A"] by auto
 
 lemma less_cSUP_iff: "A \<noteq> {} \<Longrightarrow> bdd_above (f`A) \<Longrightarrow> a < (\<Squnion>i\<in>A. f i) \<longleftrightarrow> (\<exists>x\<in>A. a < f x)"
   using less_cSup_iff[of "f`A"] by auto
 
 lemma less_cSupE:
   assumes "y < Sup X" "X \<noteq> {}" obtains x where "x \<in> X" "y < x"
   by (metis cSup_least assms not_le that)
 
 lemma less_cSupD:
   "X \<noteq> {} \<Longrightarrow> z < Sup X \<Longrightarrow> \<exists>x\<in>X. z < x"
   by (metis less_cSup_iff not_le_imp_less bdd_above_def)
 
 lemma cInf_lessD:
   "X \<noteq> {} \<Longrightarrow> Inf X < z \<Longrightarrow> \<exists>x\<in>X. x < z"
   by (metis cInf_less_iff not_le_imp_less bdd_below_def)
 
 lemma complete_interval:
   assumes "a < b" and "P a" and "\<not> P b"
   shows "\<exists>c. a \<le> c \<and> c \<le> b \<and> (\<forall>x. a \<le> x \<and> x < c \<longrightarrow> P x) \<and>
              (\<forall>d. (\<forall>x. a \<le> x \<and> x < d \<longrightarrow> P x) \<longrightarrow> d \<le> c)"
 proof (rule exI [where x = "Sup {d. \<forall>x. a \<le> x \<and> x < d \<longrightarrow> P x}"], auto)
   show "a \<le> Sup {d. \<forall>c. a \<le> c \<and> c < d \<longrightarrow> P c}"
     by (rule cSup_upper, auto simp: bdd_above_def)
        (metis \<open>a < b\<close> \<open>\<not> P b\<close> linear less_le)
 next
   show "Sup {d. \<forall>c. a \<le> c \<and> c < d \<longrightarrow> P c} \<le> b"
     apply (rule cSup_least)
     apply auto
     apply (metis less_le_not_le)
     apply (metis \<open>a<b\<close> \<open>\<not> P b\<close> linear less_le)
     done
 next
   fix x
   assume x: "a \<le> x" and lt: "x < Sup {d. \<forall>c. a \<le> c \<and> c < d \<longrightarrow> P c}"
   show "P x"
     apply (rule less_cSupE [OF lt], auto)
     apply (metis less_le_not_le)
     apply (metis x)
     done
 next
   fix d
     assume 0: "\<forall>x. a \<le> x \<and> x < d \<longrightarrow> P x"
     thus "d \<le> Sup {d. \<forall>c. a \<le> c \<and> c < d \<longrightarrow> P c}"
       by (rule_tac cSup_upper, auto simp: bdd_above_def)
          (metis \<open>a<b\<close> \<open>\<not> P b\<close> linear less_le)
 qed
 
 end
 
 instance complete_linorder < conditionally_complete_linorder
   ..
 
 lemma cSup_eq_Max: "finite (X::'a::conditionally_complete_linorder set) \<Longrightarrow> X \<noteq> {} \<Longrightarrow> Sup X = Max X"
   using cSup_eq_Sup_fin[of X] by (simp add: Sup_fin_Max)
 
 lemma cInf_eq_Min: "finite (X::'a::conditionally_complete_linorder set) \<Longrightarrow> X \<noteq> {} \<Longrightarrow> Inf X = Min X"
   using cInf_eq_Inf_fin[of X] by (simp add: Inf_fin_Min)
 
 lemma cSup_lessThan[simp]: "Sup {..<x::'a::{conditionally_complete_linorder, no_bot, dense_linorder}} = x"
   by (auto intro!: cSup_eq_non_empty intro: dense_le)
 
 lemma cSup_greaterThanLessThan[simp]: "y < x \<Longrightarrow> Sup {y<..<x::'a::{conditionally_complete_linorder, dense_linorder}} = x"
   by (auto intro!: cSup_eq_non_empty intro: dense_le_bounded)
 
 lemma cSup_atLeastLessThan[simp]: "y < x \<Longrightarrow> Sup {y..<x::'a::{conditionally_complete_linorder, dense_linorder}} = x"
   by (auto intro!: cSup_eq_non_empty intro: dense_le_bounded)
 
 lemma cInf_greaterThan[simp]: "Inf {x::'a::{conditionally_complete_linorder, no_top, dense_linorder} <..} = x"
   by (auto intro!: cInf_eq_non_empty intro: dense_ge)
 
 lemma cInf_greaterThanAtMost[simp]: "y < x \<Longrightarrow> Inf {y<..x::'a::{conditionally_complete_linorder, dense_linorder}} = y"
   by (auto intro!: cInf_eq_non_empty intro: dense_ge_bounded)
 
 lemma cInf_greaterThanLessThan[simp]: "y < x \<Longrightarrow> Inf {y<..<x::'a::{conditionally_complete_linorder, dense_linorder}} = y"
   by (auto intro!: cInf_eq_non_empty intro: dense_ge_bounded)
 
 lemma Inf_insert_finite:
   fixes S :: "'a::conditionally_complete_linorder set"
   shows "finite S \<Longrightarrow> Inf (insert x S) = (if S = {} then x else min x (Inf S))"
   by (simp add: cInf_eq_Min)
 
 lemma Sup_insert_finite:
   fixes S :: "'a::conditionally_complete_linorder set"
   shows "finite S \<Longrightarrow> Sup (insert x S) = (if S = {} then x else max x (Sup S))"
   by (simp add: cSup_insert sup_max)
 
 lemma finite_imp_less_Inf:
   fixes a :: "'a::conditionally_complete_linorder"
   shows "\<lbrakk>finite X; x \<in> X; \<And>x. x\<in>X \<Longrightarrow> a < x\<rbrakk> \<Longrightarrow> a < Inf X"
   by (induction X rule: finite_induct) (simp_all add: cInf_eq_Min Inf_insert_finite)
 
 lemma finite_less_Inf_iff:
   fixes a :: "'a :: conditionally_complete_linorder"
   shows "\<lbrakk>finite X; X \<noteq> {}\<rbrakk> \<Longrightarrow> a < Inf X \<longleftrightarrow> (\<forall>x \<in> X. a < x)"
   by (auto simp: cInf_eq_Min)
 
 lemma finite_imp_Sup_less:
   fixes a :: "'a::conditionally_complete_linorder"
   shows "\<lbrakk>finite X; x \<in> X; \<And>x. x\<in>X \<Longrightarrow> a > x\<rbrakk> \<Longrightarrow> a > Sup X"
   by (induction X rule: finite_induct) (simp_all add: cSup_eq_Max Sup_insert_finite)
 
 lemma finite_Sup_less_iff:
   fixes a :: "'a :: conditionally_complete_linorder"
   shows "\<lbrakk>finite X; X \<noteq> {}\<rbrakk> \<Longrightarrow> a > Sup X \<longleftrightarrow> (\<forall>x \<in> X. a > x)"
   by (auto simp: cSup_eq_Max)
 
 class linear_continuum = conditionally_complete_linorder + dense_linorder +
   assumes UNIV_not_singleton: "\<exists>a b::'a. a \<noteq> b"
 begin
 
 lemma ex_gt_or_lt: "\<exists>b. a < b \<or> b < a"
   by (metis UNIV_not_singleton neq_iff)
 
 end
 
 instantiation nat :: conditionally_complete_linorder
 begin
 
 definition "Sup (X::nat set) = Max X"
 definition "Inf (X::nat set) = (LEAST n. n \<in> X)"
 
 lemma bdd_above_nat: "bdd_above X \<longleftrightarrow> finite (X::nat set)"
 proof
   assume "bdd_above X"
   then obtain z where "X \<subseteq> {.. z}"
     by (auto simp: bdd_above_def)
   then show "finite X"
     by (rule finite_subset) simp
 qed simp
 
 instance
 proof
   fix x :: nat
   fix X :: "nat set"
   show "Inf X \<le> x" if "x \<in> X" "bdd_below X"
     using that by (simp add: Inf_nat_def Least_le)
   show "x \<le> Inf X" if "X \<noteq> {}" "\<And>y. y \<in> X \<Longrightarrow> x \<le> y"
     using that unfolding Inf_nat_def ex_in_conv[symmetric] by (rule LeastI2_ex)
   show "x \<le> Sup X" if "x \<in> X" "bdd_above X"
     using that by (simp add: Sup_nat_def bdd_above_nat)
   show "Sup X \<le> x" if "X \<noteq> {}" "\<And>y. y \<in> X \<Longrightarrow> y \<le> x"
   proof -
     from that have "bdd_above X"
       by (auto simp: bdd_above_def)
     with that show ?thesis 
       by (simp add: Sup_nat_def bdd_above_nat)
   qed
 qed
 
 end
 
 lemma Inf_nat_def1:
   fixes K::"nat set"
   assumes "K \<noteq> {}"
   shows "Inf K \<in> K"
 by (auto simp add: Min_def Inf_nat_def) (meson LeastI assms bot.extremum_unique subsetI)
 
 
 instantiation int :: conditionally_complete_linorder
 begin
 
 definition "Sup (X::int set) = (THE x. x \<in> X \<and> (\<forall>y\<in>X. y \<le> x))"
 definition "Inf (X::int set) = - (Sup (uminus ` X))"
 
 instance
 proof
   { fix x :: int and X :: "int set" assume "X \<noteq> {}" "bdd_above X"
     then obtain x y where "X \<subseteq> {..y}" "x \<in> X"
       by (auto simp: bdd_above_def)
     then have *: "finite (X \<inter> {x..y})" "X \<inter> {x..y} \<noteq> {}" and "x \<le> y"
       by (auto simp: subset_eq)
     have "\<exists>!x\<in>X. (\<forall>y\<in>X. y \<le> x)"
     proof
       { fix z assume "z \<in> X"
         have "z \<le> Max (X \<inter> {x..y})"
         proof cases
           assume "x \<le> z" with \<open>z \<in> X\<close> \<open>X \<subseteq> {..y}\<close> *(1) show ?thesis
             by (auto intro!: Max_ge)
         next
           assume "\<not> x \<le> z"
           then have "z < x" by simp
           also have "x \<le> Max (X \<inter> {x..y})"
             using \<open>x \<in> X\<close> *(1) \<open>x \<le> y\<close> by (intro Max_ge) auto
           finally show ?thesis by simp
         qed }
       note le = this
       with Max_in[OF *] show ex: "Max (X \<inter> {x..y}) \<in> X \<and> (\<forall>z\<in>X. z \<le> Max (X \<inter> {x..y}))" by auto
 
       fix z assume *: "z \<in> X \<and> (\<forall>y\<in>X. y \<le> z)"
       with le have "z \<le> Max (X \<inter> {x..y})"
         by auto
       moreover have "Max (X \<inter> {x..y}) \<le> z"
         using * ex by auto
       ultimately show "z = Max (X \<inter> {x..y})"
         by auto
     qed
     then have "Sup X \<in> X \<and> (\<forall>y\<in>X. y \<le> Sup X)"
       unfolding Sup_int_def by (rule theI') }
   note Sup_int = this
 
   { fix x :: int and X :: "int set" assume "x \<in> X" "bdd_above X" then show "x \<le> Sup X"
       using Sup_int[of X] by auto }
   note le_Sup = this
   { fix x :: int and X :: "int set" assume "X \<noteq> {}" "\<And>y. y \<in> X \<Longrightarrow> y \<le> x" then show "Sup X \<le> x"
       using Sup_int[of X] by (auto simp: bdd_above_def) }
   note Sup_le = this
 
   { fix x :: int and X :: "int set" assume "x \<in> X" "bdd_below X" then show "Inf X \<le> x"
       using le_Sup[of "-x" "uminus ` X"] by (auto simp: Inf_int_def) }
   { fix x :: int and X :: "int set" assume "X \<noteq> {}" "\<And>y. y \<in> X \<Longrightarrow> x \<le> y" then show "x \<le> Inf X"
       using Sup_le[of "uminus ` X" "-x"] by (force simp: Inf_int_def) }
 qed
 end
 
 lemma interval_cases:
   fixes S :: "'a :: conditionally_complete_linorder set"
   assumes ivl: "\<And>a b x. a \<in> S \<Longrightarrow> b \<in> S \<Longrightarrow> a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> x \<in> S"
   shows "\<exists>a b. S = {} \<or>
     S = UNIV \<or>
     S = {..<b} \<or>
     S = {..b} \<or>
     S = {a<..} \<or>
     S = {a..} \<or>
     S = {a<..<b} \<or>
     S = {a<..b} \<or>
     S = {a..<b} \<or>
     S = {a..b}"
 proof -
   define lower upper where "lower = {x. \<exists>s\<in>S. s \<le> x}" and "upper = {x. \<exists>s\<in>S. x \<le> s}"
   with ivl have "S = lower \<inter> upper"
     by auto
   moreover
   have "\<exists>a. upper = UNIV \<or> upper = {} \<or> upper = {.. a} \<or> upper = {..< a}"
   proof cases
     assume *: "bdd_above S \<and> S \<noteq> {}"
     from * have "upper \<subseteq> {.. Sup S}"
       by (auto simp: upper_def intro: cSup_upper2)
     moreover from * have "{..< Sup S} \<subseteq> upper"
       by (force simp add: less_cSup_iff upper_def subset_eq Ball_def)
     ultimately have "upper = {.. Sup S} \<or> upper = {..< Sup S}"
       unfolding ivl_disj_un(2)[symmetric] by auto
     then show ?thesis by auto
   next
     assume "\<not> (bdd_above S \<and> S \<noteq> {})"
     then have "upper = UNIV \<or> upper = {}"
       by (auto simp: upper_def bdd_above_def not_le dest: less_imp_le)
     then show ?thesis
       by auto
   qed
   moreover
   have "\<exists>b. lower = UNIV \<or> lower = {} \<or> lower = {b ..} \<or> lower = {b <..}"
   proof cases
     assume *: "bdd_below S \<and> S \<noteq> {}"
     from * have "lower \<subseteq> {Inf S ..}"
       by (auto simp: lower_def intro: cInf_lower2)
     moreover from * have "{Inf S <..} \<subseteq> lower"
       by (force simp add: cInf_less_iff lower_def subset_eq Ball_def)
     ultimately have "lower = {Inf S ..} \<or> lower = {Inf S <..}"
       unfolding ivl_disj_un(1)[symmetric] by auto
     then show ?thesis by auto
   next
     assume "\<not> (bdd_below S \<and> S \<noteq> {})"
     then have "lower = UNIV \<or> lower = {}"
       by (auto simp: lower_def bdd_below_def not_le dest: less_imp_le)
     then show ?thesis
       by auto
   qed
   ultimately show ?thesis
     unfolding greaterThanAtMost_def greaterThanLessThan_def atLeastAtMost_def atLeastLessThan_def
     by (metis inf_bot_left inf_bot_right inf_top.left_neutral inf_top.right_neutral)
 qed
 
 lemma cSUP_eq_cINF_D:
   fixes f :: "_ \<Rightarrow> 'b::conditionally_complete_lattice"
   assumes eq: "(\<Squnion>x\<in>A. f x) = (\<Sqinter>x\<in>A. f x)"
      and bdd: "bdd_above (f ` A)" "bdd_below (f ` A)"
      and a: "a \<in> A"
   shows "f a = (\<Sqinter>x\<in>A. f x)"
 apply (rule antisym)
 using a bdd
 apply (auto simp: cINF_lower)
 apply (metis eq cSUP_upper)
 done
 
 lemma cSUP_UNION:
   fixes f :: "_ \<Rightarrow> 'b::conditionally_complete_lattice"
   assumes ne: "A \<noteq> {}" "\<And>x. x \<in> A \<Longrightarrow> B(x) \<noteq> {}"
       and bdd_UN: "bdd_above (\<Union>x\<in>A. f ` B x)"
   shows "(\<Squnion>z \<in> \<Union>x\<in>A. B x. f z) = (\<Squnion>x\<in>A. \<Squnion>z\<in>B x. f z)"
 proof -
   have bdd: "\<And>x. x \<in> A \<Longrightarrow> bdd_above (f ` B x)"
     using bdd_UN by (meson UN_upper bdd_above_mono)
   obtain M where "\<And>x y. x \<in> A \<Longrightarrow> y \<in> B(x) \<Longrightarrow> f y \<le> M"
     using bdd_UN by (auto simp: bdd_above_def)
   then have bdd2: "bdd_above ((\<lambda>x. \<Squnion>z\<in>B x. f z) ` A)"
     unfolding bdd_above_def by (force simp: bdd cSUP_le_iff ne(2))
   have "(\<Squnion>z \<in> \<Union>x\<in>A. B x. f z) \<le> (\<Squnion>x\<in>A. \<Squnion>z\<in>B x. f z)"
     using assms by (fastforce simp add: intro!: cSUP_least intro: cSUP_upper2 simp: bdd2 bdd)
   moreover have "(\<Squnion>x\<in>A. \<Squnion>z\<in>B x. f z) \<le> (\<Squnion> z \<in> \<Union>x\<in>A. B x. f z)"
     using assms by (fastforce simp add: intro!: cSUP_least intro: cSUP_upper simp: image_UN bdd_UN)
   ultimately show ?thesis
     by (rule order_antisym)
 qed
 
 lemma cINF_UNION:
   fixes f :: "_ \<Rightarrow> 'b::conditionally_complete_lattice"
   assumes ne: "A \<noteq> {}" "\<And>x. x \<in> A \<Longrightarrow> B(x) \<noteq> {}"
       and bdd_UN: "bdd_below (\<Union>x\<in>A. f ` B x)"
   shows "(\<Sqinter>z \<in> \<Union>x\<in>A. B x. f z) = (\<Sqinter>x\<in>A. \<Sqinter>z\<in>B x. f z)"
 proof -
   have bdd: "\<And>x. x \<in> A \<Longrightarrow> bdd_below (f ` B x)"
     using bdd_UN by (meson UN_upper bdd_below_mono)
   obtain M where "\<And>x y. x \<in> A \<Longrightarrow> y \<in> B(x) \<Longrightarrow> f y \<ge> M"
     using bdd_UN by (auto simp: bdd_below_def)
   then have bdd2: "bdd_below ((\<lambda>x. \<Sqinter>z\<in>B x. f z) ` A)"
     unfolding bdd_below_def by (force simp: bdd le_cINF_iff ne(2))
   have "(\<Sqinter>z \<in> \<Union>x\<in>A. B x. f z) \<le> (\<Sqinter>x\<in>A. \<Sqinter>z\<in>B x. f z)"
     using assms by (fastforce simp add: intro!: cINF_greatest intro: cINF_lower simp: bdd2 bdd)
   moreover have "(\<Sqinter>x\<in>A. \<Sqinter>z\<in>B x. f z) \<le> (\<Sqinter>z \<in> \<Union>x\<in>A. B x. f z)"
     using assms  by (fastforce simp add: intro!: cINF_greatest intro: cINF_lower2  simp: bdd bdd_UN bdd2)
   ultimately show ?thesis
     by (rule order_antisym)
 qed
 
 lemma cSup_abs_le:
   fixes S :: "('a::{linordered_idom,conditionally_complete_linorder}) set"
   shows "S \<noteq> {} \<Longrightarrow> (\<And>x. x\<in>S \<Longrightarrow> \<bar>x\<bar> \<le> a) \<Longrightarrow> \<bar>Sup S\<bar> \<le> a"
   apply (auto simp add: abs_le_iff intro: cSup_least)
   by (metis bdd_aboveI cSup_upper neg_le_iff_le order_trans)
 
 end
diff --git a/src/HOL/Library/Equipollence.thy b/src/HOL/Library/Equipollence.thy
--- a/src/HOL/Library/Equipollence.thy
+++ b/src/HOL/Library/Equipollence.thy
@@ -1,358 +1,696 @@
 section \<open>Equipollence and Other Relations Connected with Cardinality\<close>
 
 theory "Equipollence"
-  imports FuncSet
+  imports FuncSet 
 begin
 
 subsection\<open>Eqpoll\<close>
 
 definition eqpoll :: "'a set \<Rightarrow> 'b set \<Rightarrow> bool" (infixl "\<approx>" 50)
   where "eqpoll A B \<equiv> \<exists>f. bij_betw f A B"
 
 definition lepoll :: "'a set \<Rightarrow> 'b set \<Rightarrow> bool" (infixl "\<lesssim>" 50)
   where "lepoll A B \<equiv> \<exists>f. inj_on f A \<and> f ` A \<subseteq> B"
 
 definition lesspoll :: "'a set \<Rightarrow> 'b set \<Rightarrow> bool" (infixl \<open>\<prec>\<close> 50)
   where "A \<prec> B == A \<lesssim> B \<and> ~(A \<approx> B)"
 
 lemma lepoll_empty_iff_empty [simp]: "A \<lesssim> {} \<longleftrightarrow> A = {}"
   by (auto simp: lepoll_def)
 
 lemma eqpoll_iff_card_of_ordIso: "A \<approx> B \<longleftrightarrow> ordIso2 (card_of A) (card_of B)"
   by (simp add: card_of_ordIso eqpoll_def)
 
+lemma eqpoll_refl [iff]: "A \<approx> A"
+  by (simp add: card_of_refl eqpoll_iff_card_of_ordIso)
+
 lemma eqpoll_finite_iff: "A \<approx> B \<Longrightarrow> finite A \<longleftrightarrow> finite B"
   by (meson bij_betw_finite eqpoll_def)
 
 lemma eqpoll_iff_card:
   assumes "finite A" "finite B"
   shows  "A \<approx> B \<longleftrightarrow> card A = card B"
   using assms by (auto simp: bij_betw_iff_card eqpoll_def)
 
 lemma lepoll_antisym:
   assumes "A \<lesssim> B" "B \<lesssim> A" shows "A \<approx> B"
   using assms unfolding eqpoll_def lepoll_def by (metis Schroeder_Bernstein)
 
 lemma lepoll_trans [trans]: "\<lbrakk>A \<lesssim> B; B \<lesssim> C\<rbrakk> \<Longrightarrow> A \<lesssim> C"
   apply (clarsimp simp: lepoll_def)
   apply (rename_tac f g)
   apply (rule_tac x="g \<circ> f" in exI)
   apply (auto simp: image_subset_iff inj_on_def)
   done
 
 lemma lepoll_trans1 [trans]: "\<lbrakk>A \<approx> B; B \<lesssim> C\<rbrakk> \<Longrightarrow> A \<lesssim> C"
   by (meson card_of_ordLeq eqpoll_iff_card_of_ordIso lepoll_def lepoll_trans ordIso_iff_ordLeq)
 
 lemma lepoll_trans2 [trans]: "\<lbrakk>A \<lesssim> B; B \<approx> C\<rbrakk> \<Longrightarrow> A \<lesssim> C"
   apply (clarsimp simp: eqpoll_def lepoll_def bij_betw_def)
   apply (rename_tac f g)
   apply (rule_tac x="g \<circ> f" in exI)
   apply (auto simp: image_subset_iff inj_on_def)
   done
 
 lemma eqpoll_sym: "A \<approx> B \<Longrightarrow> B \<approx> A"
   unfolding eqpoll_def
   using bij_betw_the_inv_into by auto
 
 lemma eqpoll_trans [trans]: "\<lbrakk>A \<approx> B; B \<approx> C\<rbrakk> \<Longrightarrow> A \<approx> C"
   unfolding eqpoll_def using bij_betw_trans by blast
 
 lemma eqpoll_imp_lepoll: "A \<approx> B \<Longrightarrow> A \<lesssim> B"
   unfolding eqpoll_def lepoll_def by (metis bij_betw_def order_refl)
 
 lemma subset_imp_lepoll: "A \<subseteq> B \<Longrightarrow> A \<lesssim> B"
   by (force simp: lepoll_def)
 
+lemma lepoll_refl [iff]: "A \<lesssim> A"
+  by (simp add: subset_imp_lepoll)
+
 lemma lepoll_iff: "A \<lesssim> B \<longleftrightarrow> (\<exists>g. A \<subseteq> g ` B)"
   unfolding lepoll_def
 proof safe
   fix g assume "A \<subseteq> g ` B"
   then show "\<exists>f. inj_on f A \<and> f ` A \<subseteq> B"
     by (rule_tac x="inv_into B g" in exI) (auto simp: inv_into_into inj_on_inv_into)
 qed (metis image_mono the_inv_into_onto)
 
+lemma empty_lepoll [iff]: "{} \<lesssim> A"
+  by (simp add: lepoll_iff)
+
 lemma subset_image_lepoll: "B \<subseteq> f ` A \<Longrightarrow> B \<lesssim> A"
   by (auto simp: lepoll_iff)
 
 lemma image_lepoll: "f ` A \<lesssim> A"
   by (auto simp: lepoll_iff)
 
 lemma infinite_le_lepoll: "infinite A \<longleftrightarrow> (UNIV::nat set) \<lesssim> A"
 apply (auto simp: lepoll_def)
   apply (simp add: infinite_countable_subset)
   using infinite_iff_countable_subset by blast
 
+lemma lepoll_Pow_self: "A \<lesssim> Pow A"
+  unfolding lepoll_def inj_def
+  proof (intro exI conjI)
+    show "inj_on (\<lambda>x. {x}) A"
+      by (auto simp: inj_on_def)
+qed auto
+
 lemma bij_betw_iff_bijections:
   "bij_betw f A B \<longleftrightarrow> (\<exists>g. (\<forall>x \<in> A. f x \<in> B \<and> g(f x) = x) \<and> (\<forall>y \<in> B. g y \<in> A \<and> f(g y) = y))"
   (is "?lhs = ?rhs")
 proof
   assume L: ?lhs
   then show ?rhs
     apply (rule_tac x="the_inv_into A f" in exI)
     apply (auto simp: bij_betw_def f_the_inv_into_f the_inv_into_f_f the_inv_into_into)
     done
 next
   assume ?rhs
   then show ?lhs
     by (auto simp: bij_betw_def inj_on_def image_def; metis)
 qed
 
 lemma eqpoll_iff_bijections:
    "A \<approx> B \<longleftrightarrow> (\<exists>f g. (\<forall>x \<in> A. f x \<in> B \<and> g(f x) = x) \<and> (\<forall>y \<in> B. g y \<in> A \<and> f(g y) = y))"
     by (auto simp: eqpoll_def bij_betw_iff_bijections)
 
 lemma lepoll_restricted_funspace:
    "{f. f ` A \<subseteq> B \<and> {x. f x \<noteq> k x} \<subseteq> A \<and> finite {x. f x \<noteq> k x}} \<lesssim> Fpow (A \<times> B)"
 proof -
   have *: "\<exists>U \<in> Fpow (A \<times> B). f = (\<lambda>x. if \<exists>y. (x, y) \<in> U then SOME y. (x,y) \<in> U else k x)"
     if "f ` A \<subseteq> B" "{x. f x \<noteq> k x} \<subseteq> A" "finite {x. f x \<noteq> k x}" for f
     apply (rule_tac x="(\<lambda>x. (x, f x)) ` {x. f x \<noteq> k x}" in bexI)
     using that by (auto simp: image_def Fpow_def)
   show ?thesis
     apply (rule subset_image_lepoll [where f = "\<lambda>U x. if \<exists>y. (x,y) \<in> U then @y. (x,y) \<in> U else k x"])
     using * by (auto simp: image_def)
 qed
 
 lemma singleton_lepoll: "{x} \<lesssim> insert y A"
   by (force simp: lepoll_def)
 
 lemma singleton_eqpoll: "{x} \<approx> {y}"
   by (blast intro: lepoll_antisym singleton_lepoll)
 
 lemma subset_singleton_iff_lepoll: "(\<exists>x. S \<subseteq> {x}) \<longleftrightarrow> S \<lesssim> {()}"
 proof safe
   show "S \<lesssim> {()}" if "S \<subseteq> {x}" for x
     using subset_imp_lepoll [OF that] by (simp add: singleton_eqpoll lepoll_trans2)
   show "\<exists>x. S \<subseteq> {x}" if "S \<lesssim> {()}"
   by (metis (no_types, hide_lams) image_empty image_insert lepoll_iff that)
 qed
 
+lemma infinite_insert_lepoll:
+  assumes "infinite A" shows "insert a A \<lesssim> A"
+proof -
+  obtain f :: "nat \<Rightarrow> 'a" where "inj f" and f: "range f \<subseteq> A"
+    using assms infinite_countable_subset by blast
+  let ?g = "(\<lambda>z. if z=a then f 0 else if z \<in> range f then f (Suc (inv f z)) else z)"
+  show ?thesis
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    show "inj_on ?g (insert a A)"
+      using inj_on_eq_iff [OF \<open>inj f\<close>]
+      by (auto simp: inj_on_def)
+    show "?g ` insert a A \<subseteq> A"
+      using f by auto
+  qed
+qed
+
+lemma infinite_insert_eqpoll: "infinite A \<Longrightarrow> insert a A \<approx> A"
+  by (simp add: lepoll_antisym infinite_insert_lepoll subset_imp_lepoll subset_insertI)
+
+lemma finite_lepoll_infinite:
+  assumes "infinite A" "finite B" shows "B \<lesssim> A"
+proof -
+  have "B \<lesssim> (UNIV::nat set)"
+    unfolding lepoll_def
+    using finite_imp_inj_to_nat_seg [OF \<open>finite B\<close>] by blast
+  then show ?thesis
+    using \<open>infinite A\<close> infinite_le_lepoll lepoll_trans by auto
+qed
 
 subsection\<open>The strict relation\<close>
 
 lemma lesspoll_not_refl [iff]: "~ (i \<prec> i)"
   by (simp add: lepoll_antisym lesspoll_def)
 
 lemma lesspoll_imp_lepoll: "A \<prec> B ==> A \<lesssim> B"
 by (unfold lesspoll_def, blast)
 
 lemma lepoll_iff_leqpoll: "A \<lesssim> B \<longleftrightarrow> A \<prec> B | A \<approx> B"
   using eqpoll_imp_lepoll lesspoll_def by blast
 
 lemma lesspoll_trans [trans]: "\<lbrakk>X \<prec> Y; Y \<prec> Z\<rbrakk> \<Longrightarrow> X \<prec> Z"
   by (meson eqpoll_sym lepoll_antisym lepoll_trans lepoll_trans1 lesspoll_def)
 
 lemma lesspoll_trans1 [trans]: "\<lbrakk>X \<lesssim> Y; Y \<prec> Z\<rbrakk> \<Longrightarrow> X \<prec> Z"
   by (meson eqpoll_sym lepoll_antisym lepoll_trans lepoll_trans1 lesspoll_def)
 
 lemma lesspoll_trans2 [trans]: "\<lbrakk>X \<prec> Y; Y \<lesssim> Z\<rbrakk> \<Longrightarrow> X \<prec> Z"
   by (meson eqpoll_imp_lepoll eqpoll_sym lepoll_antisym lepoll_trans lesspoll_def)
 
 lemma eq_lesspoll_trans [trans]: "\<lbrakk>X \<approx> Y; Y \<prec> Z\<rbrakk> \<Longrightarrow> X \<prec> Z"
   using eqpoll_imp_lepoll lesspoll_trans1 by blast
 
 lemma lesspoll_eq_trans [trans]: "\<lbrakk>X \<prec> Y; Y \<approx> Z\<rbrakk> \<Longrightarrow> X \<prec> Z"
   using eqpoll_imp_lepoll lesspoll_trans2 by blast
 
-subsection\<open>Cartesian products\<close>
+lemma lesspoll_Pow_self: "A \<prec> Pow A"
+  unfolding lesspoll_def bij_betw_def eqpoll_def
+  by (meson lepoll_Pow_self Cantors_paradox)
+
+lemma finite_lesspoll_infinite:
+  assumes "infinite A" "finite B" shows "B \<prec> A"
+  by (meson assms eqpoll_finite_iff finite_lepoll_infinite lesspoll_def)
+
+subsection\<open>Mapping by an injection\<close>
+
+lemma inj_on_image_eqpoll_self: "inj_on f A \<Longrightarrow> f ` A \<approx> A"
+  by (meson bij_betw_def eqpoll_def eqpoll_sym)
+
+lemma inj_on_image_lepoll_1 [simp]:
+  assumes "inj_on f A" shows "f ` A \<lesssim> B \<longleftrightarrow> A \<lesssim> B"
+  by (meson assms image_lepoll lepoll_def lepoll_trans order_refl)
+
+lemma inj_on_image_lepoll_2 [simp]:
+  assumes "inj_on f B" shows "A \<lesssim> f ` B \<longleftrightarrow> A \<lesssim> B"
+  by (meson assms eq_iff image_lepoll lepoll_def lepoll_trans)
+
+lemma inj_on_image_lesspoll_1 [simp]:
+  assumes "inj_on f A" shows "f ` A \<prec> B \<longleftrightarrow> A \<prec> B"
+  by (meson assms image_lepoll le_less lepoll_def lesspoll_trans1)
+
+lemma inj_on_image_lesspoll_2 [simp]:
+  assumes "inj_on f B" shows "A \<prec> f ` B \<longleftrightarrow> A \<prec> B"
+  by (meson assms eqpoll_sym inj_on_image_eqpoll_self lesspoll_eq_trans)
+
+lemma inj_on_image_eqpoll_1 [simp]:
+  assumes "inj_on f A" shows "f ` A \<approx> B \<longleftrightarrow> A \<approx> B"
+  by (metis assms eqpoll_trans inj_on_image_eqpoll_self eqpoll_sym)
+
+lemma inj_on_image_eqpoll_2 [simp]:
+  assumes "inj_on f B" shows "A \<approx> f ` B \<longleftrightarrow> A \<approx> B"
+  by (metis assms inj_on_image_eqpoll_1 eqpoll_sym)
+
+subsection \<open>Inserting elements into sets\<close>
+
+lemma insert_lepoll_insertD:
+  assumes "insert u A \<lesssim> insert v B" "u \<notin> A" "v \<notin> B" shows "A \<lesssim> B"
+proof -
+  obtain f where inj: "inj_on f (insert u A)" and fim: "f ` (insert u A) \<subseteq> insert v B"
+    by (meson assms lepoll_def)
+  show ?thesis
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    let ?g = "\<lambda>x\<in>A. if f x = v then f u else f x"
+    show "inj_on ?g A"
+      using inj \<open>u \<notin> A\<close> by (auto simp: inj_on_def)
+    show "?g ` A \<subseteq> B"
+      using fim \<open>u \<notin> A\<close> image_subset_iff inj inj_on_image_mem_iff by fastforce
+  qed
+qed
+
+lemma insert_eqpoll_insertD: "\<lbrakk>insert u A \<approx> insert v B; u \<notin> A; v \<notin> B\<rbrakk> \<Longrightarrow> A \<approx> B"
+  by (meson insert_lepoll_insertD eqpoll_imp_lepoll eqpoll_sym lepoll_antisym)
+
+lemma insert_lepoll_cong:
+  assumes "A \<lesssim> B" "b \<notin> B" shows "insert a A \<lesssim> insert b B"
+proof -
+  obtain f where f: "inj_on f A" "f ` A \<subseteq> B"
+    by (meson assms lepoll_def)
+  let ?f = "\<lambda>u \<in> insert a A. if u=a then b else f u"
+  show ?thesis
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    show "inj_on ?f (insert a A)"
+      using f \<open>b \<notin> B\<close> by (auto simp: inj_on_def)
+    show "?f ` insert a A \<subseteq> insert b B"
+      using f \<open>b \<notin> B\<close> by auto
+  qed
+qed
+
+lemma insert_eqpoll_cong:
+     "\<lbrakk>A \<approx> B; a \<notin> A; b \<notin> B\<rbrakk> \<Longrightarrow> insert a A \<approx> insert b B"
+  apply (rule lepoll_antisym)
+  apply (simp add: eqpoll_imp_lepoll insert_lepoll_cong)+
+  by (meson eqpoll_imp_lepoll eqpoll_sym insert_lepoll_cong)
+
+lemma insert_eqpoll_insert_iff:
+     "\<lbrakk>a \<notin> A; b \<notin> B\<rbrakk> \<Longrightarrow> insert a A \<approx> insert b B  \<longleftrightarrow>  A \<approx> B"
+  by (meson insert_eqpoll_insertD insert_eqpoll_cong)
+
+lemma insert_lepoll_insert_iff:
+     " \<lbrakk>a \<notin> A; b \<notin> B\<rbrakk> \<Longrightarrow> (insert a A \<lesssim> insert b B) \<longleftrightarrow> (A \<lesssim> B)"
+  by (meson insert_lepoll_insertD insert_lepoll_cong)
+
+lemma less_imp_insert_lepoll:
+  assumes "A \<prec> B" shows "insert a A \<lesssim> B"
+proof -
+  obtain f where "inj_on f A" "f ` A \<subset> B"
+    using assms by (metis bij_betw_def eqpoll_def lepoll_def lesspoll_def psubset_eq)
+  then obtain b where b: "b \<in> B" "b \<notin> f ` A"
+    by auto
+  show ?thesis
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    show "inj_on (f(a:=b)) (insert a A)"
+      using b \<open>inj_on f A\<close> by (auto simp: inj_on_def)
+    show "(f(a:=b)) ` insert a A \<subseteq> B"
+      using \<open>f ` A \<subset> B\<close>  by (auto simp: b)
+  qed
+qed
+
+lemma finite_insert_lepoll: "finite A \<Longrightarrow> (insert a A \<lesssim> A) \<longleftrightarrow> (a \<in> A)"
+proof (induction A rule: finite_induct)
+  case (insert x A)
+  then show ?case
+    apply (auto simp: insert_absorb)
+    by (metis insert_commute insert_iff insert_lepoll_insertD)
+qed auto
+
+
+subsection\<open>Binary sums and unions\<close>
+
+lemma Un_lepoll_mono:
+  assumes "A \<lesssim> C" "B \<lesssim> D" "disjnt C D" shows "A \<union> B \<lesssim> C \<union> D"
+proof -
+  obtain f g where inj: "inj_on f A" "inj_on g B" and fg: "f ` A \<subseteq> C" "g ` B \<subseteq> D"
+    by (meson assms lepoll_def)
+  have "inj_on (\<lambda>x. if x \<in> A then f x else g x) (A \<union> B)"
+    using inj \<open>disjnt C D\<close> fg unfolding disjnt_iff
+    by (fastforce intro: inj_onI dest: inj_on_contraD split: if_split_asm)
+  with fg show ?thesis
+    unfolding lepoll_def
+    by (rule_tac x="\<lambda>x. if x \<in> A then f x else g x" in exI) auto
+qed
+
+lemma Un_eqpoll_cong: "\<lbrakk>A \<approx> C; B \<approx> D; disjnt A B; disjnt C D\<rbrakk> \<Longrightarrow> A \<union> B \<approx> C \<union> D"
+  by (meson Un_lepoll_mono eqpoll_imp_lepoll eqpoll_sym lepoll_antisym)
+
+lemma sum_lepoll_mono:
+  assumes "A \<lesssim> C" "B \<lesssim> D" shows "A <+> B \<lesssim> C <+> D"
+proof -
+  obtain f g where "inj_on f A" "f ` A \<subseteq> C" "inj_on g B" "g ` B \<subseteq> D"
+    by (meson assms lepoll_def)
+  then show ?thesis
+    unfolding lepoll_def
+    by (rule_tac x="case_sum (Inl \<circ> f) (Inr \<circ> g)" in exI) (force simp: inj_on_def)
+qed
+
+lemma sum_eqpoll_cong: "\<lbrakk>A \<approx> C; B \<approx> D\<rbrakk> \<Longrightarrow> A <+> B \<approx> C <+> D"
+  by (meson eqpoll_imp_lepoll eqpoll_sym lepoll_antisym sum_lepoll_mono)
+
+subsection\<open>Binary Cartesian products\<close>
+
+lemma times_square_lepoll: "A \<lesssim> A \<times> A"
+  unfolding lepoll_def inj_def
+proof (intro exI conjI)
+  show "inj_on (\<lambda>x. (x,x)) A"
+    by (auto simp: inj_on_def)
+qed auto
+
+lemma times_commute_eqpoll: "A \<times> B \<approx> B \<times> A"
+  unfolding eqpoll_def
+  by (force intro: bij_betw_byWitness [where f = "\<lambda>(x,y). (y,x)" and f' = "\<lambda>(x,y). (y,x)"])
+
+lemma times_assoc_eqpoll: "(A \<times> B) \<times> C \<approx> A \<times> (B \<times> C)"
+  unfolding eqpoll_def
+  by (force intro: bij_betw_byWitness [where f = "\<lambda>((x,y),z). (x,(y,z))" and f' = "\<lambda>(x,(y,z)). ((x,y),z)"])
+
+lemma times_singleton_eqpoll: "{a} \<times> A \<approx> A"
+proof -
+  have "{a} \<times> A = (\<lambda>x. (a,x)) ` A"
+    by auto
+  also have "\<dots>  \<approx> A"
+    proof (rule inj_on_image_eqpoll_self)
+      show "inj_on (Pair a) A"
+        by (auto simp: inj_on_def)
+    qed
+    finally show ?thesis .
+qed
+
+lemma times_lepoll_mono:
+  assumes "A \<lesssim> C" "B \<lesssim> D" shows "A \<times> B \<lesssim> C \<times> D"
+proof -
+  obtain f g where "inj_on f A" "f ` A \<subseteq> C" "inj_on g B" "g ` B \<subseteq> D"
+    by (meson assms lepoll_def)
+  then show ?thesis
+    unfolding lepoll_def
+    by (rule_tac x="\<lambda>(x,y). (f x, g y)" in exI) (auto simp: inj_on_def)
+qed
+
+lemma times_eqpoll_cong: "\<lbrakk>A \<approx> C; B \<approx> D\<rbrakk> \<Longrightarrow> A \<times> B \<approx> C \<times> D"
+  by (metis eqpoll_imp_lepoll eqpoll_sym lepoll_antisym times_lepoll_mono)
+
+lemma
+  assumes "B \<noteq> {}" shows lepoll_times1: "A \<lesssim> A \<times> B" and lepoll_times2:  "A \<lesssim> B \<times> A"
+  using assms lepoll_iff by fastforce+
+
+lemma times_0_eqpoll: "{} \<times> A \<approx> {}"
+  by (simp add: eqpoll_iff_bijections)
+
+lemma Sigma_lepoll_mono:
+  assumes "A \<subseteq> C" "\<And>x. x \<in> A \<Longrightarrow> B x \<lesssim> D x" shows "Sigma A B \<lesssim> Sigma C D"
+proof -
+  have "\<And>x. x \<in> A \<Longrightarrow> \<exists>f. inj_on f (B x) \<and> f ` (B x) \<subseteq> D x"
+    by (meson assms lepoll_def)
+  then obtain f where  "\<And>x. x \<in> A \<Longrightarrow> inj_on (f x) (B x) \<and> f x ` B x \<subseteq> D x"
+    by metis
+  with \<open>A \<subseteq> C\<close> show ?thesis
+    unfolding lepoll_def inj_on_def
+    by (rule_tac x="\<lambda>(x,y). (x, f x y)" in exI) force
+qed
+
+lemma sum_times_distrib_eqpoll: "(A <+> B) \<times> C \<approx> (A \<times> C) <+> (B \<times> C)"
+  unfolding eqpoll_def
+proof
+  show "bij_betw (\<lambda>(x,z). case_sum(\<lambda>y. Inl(y,z)) (\<lambda>y. Inr(y,z)) x) ((A <+> B) \<times> C) (A \<times> C <+> B \<times> C)"
+    by (rule bij_betw_byWitness [where f' = "case_sum (\<lambda>(x,z). (Inl x, z)) (\<lambda>(y,z). (Inr y, z))"]) auto
+qed
+
+lemma prod_insert_eqpoll:
+  assumes "a \<notin> A" shows "insert a A \<times> B \<approx> B <+> A \<times> B"
+  unfolding eqpoll_def
+  proof
+  show "bij_betw (\<lambda>(x,y). if x=a then Inl y else Inr (x,y)) (insert a A \<times> B) (B <+> A \<times> B)"
+    by (rule bij_betw_byWitness [where f' = "case_sum (\<lambda>y. (a,y)) id"]) (auto simp: assms)
+qed
+
+subsection\<open>General Unions\<close>
+
+lemma Union_eqpoll_Times:
+  assumes B: "\<And>x. x \<in> A \<Longrightarrow> F x \<approx> B" and disj: "pairwise (\<lambda>x y. disjnt (F x) (F y)) A"
+  shows "(\<Union>x\<in>A. F x) \<approx> A \<times> B"
+proof (rule lepoll_antisym)
+  obtain b where b: "\<And>x. x \<in> A \<Longrightarrow> bij_betw (b x) (F x) B"
+    using B unfolding eqpoll_def by metis
+  show "\<Union>(F ` A) \<lesssim> A \<times> B"
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    define \<chi> where "\<chi> \<equiv> \<lambda>z. THE x. x \<in> A \<and> z \<in> F x"
+    have \<chi>: "\<chi> z = x" if "x \<in> A" "z \<in> F x" for x z
+      unfolding \<chi>_def
+      apply (rule the_equality)
+      apply (simp add: that)
+      by (metis disj disjnt_iff pairwiseD that)
+    let ?f = "\<lambda>z. (\<chi> z, b (\<chi> z) z)"
+    show "inj_on ?f (\<Union>(F ` A))"
+      unfolding inj_on_def
+      by clarify (metis \<chi> b bij_betw_inv_into_left)
+    show "?f ` \<Union>(F ` A) \<subseteq> A \<times> B"
+      using \<chi> b bij_betwE by blast
+  qed
+  show "A \<times> B \<lesssim> \<Union>(F ` A)"
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    let ?f = "\<lambda>(x,y). inv_into (F x) (b x) y"
+    have *: "inv_into (F x) (b x) y \<in> F x" if "x \<in> A" "y \<in> B" for x y
+      by (metis b bij_betw_imp_surj_on inv_into_into that)
+    then show "inj_on ?f (A \<times> B)"
+      unfolding inj_on_def
+      by clarsimp (metis (mono_tags, lifting) b bij_betw_inv_into_right disj disjnt_iff pairwiseD)
+    show "?f ` (A \<times> B) \<subseteq> \<Union> (F ` A)"
+      by clarsimp (metis b bij_betw_imp_surj_on inv_into_into)
+  qed
+qed
+
+lemma UN_lepoll_UN:
+  assumes A: "\<And>x. x \<in> A \<Longrightarrow> B x \<lesssim> C x"
+    and disj: "pairwise (\<lambda>x y. disjnt (C x) (C y)) A"
+  shows "\<Union> (B`A) \<lesssim> \<Union> (C`A)"
+proof -
+  obtain f where f: "\<And>x. x \<in> A \<Longrightarrow> inj_on (f x) (B x) \<and> f x ` (B x) \<subseteq> (C x)"
+    using A unfolding lepoll_def by metis
+  show ?thesis
+    unfolding lepoll_def
+  proof (intro exI conjI)
+    define \<chi> where "\<chi> \<equiv> \<lambda>z. @x. x \<in> A \<and> z \<in> B x"
+    have \<chi>: "\<chi> z \<in> A \<and> z \<in> B (\<chi> z)" if "x \<in> A" "z \<in> B x" for x z
+      unfolding \<chi>_def by (metis (mono_tags, lifting) someI_ex that)
+    let ?f = "\<lambda>z. (f (\<chi> z) z)"
+    show "inj_on ?f (\<Union>(B ` A))"
+      using disj f unfolding inj_on_def disjnt_iff pairwise_def image_subset_iff
+      by (metis UN_iff \<chi>)
+    show "?f ` \<Union> (B ` A) \<subseteq> \<Union> (C ` A)"
+      using \<chi> f unfolding image_subset_iff by blast
+  qed
+qed
+
+lemma UN_eqpoll_UN:
+  assumes A: "\<And>x. x \<in> A \<Longrightarrow> B x \<approx> C x"
+    and B: "pairwise (\<lambda>x y. disjnt (B x) (B y)) A"
+    and C: "pairwise (\<lambda>x y. disjnt (C x) (C y)) A"
+  shows "(\<Union>x\<in>A. B x) \<approx> (\<Union>x\<in>A. C x)"
+proof (rule lepoll_antisym)
+  show "\<Union> (B ` A) \<lesssim> \<Union> (C ` A)"
+    by (meson A C UN_lepoll_UN eqpoll_imp_lepoll)
+  show "\<Union> (C ` A) \<lesssim> \<Union> (B ` A)"
+    by (simp add: A B UN_lepoll_UN eqpoll_imp_lepoll eqpoll_sym)
+qed
+
+subsection\<open>General Cartesian products (Pi)\<close>
 
 lemma PiE_sing_eqpoll_self: "({a} \<rightarrow>\<^sub>E B) \<approx> B"
 proof -
   have 1: "x = y"
     if "x \<in> {a} \<rightarrow>\<^sub>E B" "y \<in> {a} \<rightarrow>\<^sub>E B" "x a = y a" for x y
     by (metis IntD2 PiE_def extensionalityI singletonD that)
   have 2: "x \<in> (\<lambda>h. h a) ` ({a} \<rightarrow>\<^sub>E B)" if "x \<in> B" for x
     using that by (rule_tac x="\<lambda>z\<in>{a}. x" in image_eqI) auto
   show ?thesis
   unfolding eqpoll_def bij_betw_def inj_on_def
   by (force intro: 1 2)
 qed
 
 lemma lepoll_funcset_right:
    "B \<lesssim> B' \<Longrightarrow> A \<rightarrow>\<^sub>E B \<lesssim> A \<rightarrow>\<^sub>E B'"
   apply (auto simp: lepoll_def inj_on_def)
   apply (rule_tac x = "\<lambda>g. \<lambda>z \<in> A. f(g z)" in exI)
   apply (auto simp: fun_eq_iff)
   apply (metis PiE_E)
   by blast
 
 lemma lepoll_funcset_left:
   assumes "B \<noteq> {}" "A \<lesssim> A'"
   shows "A \<rightarrow>\<^sub>E B \<lesssim> A' \<rightarrow>\<^sub>E B"
 proof -
   obtain b where "b \<in> B"
     using assms by blast
   obtain f where "inj_on f A" and fim: "f ` A \<subseteq> A'"
     using assms by (auto simp: lepoll_def)
   then obtain h where h: "\<And>x. x \<in> A \<Longrightarrow> h (f x) = x"
     using the_inv_into_f_f by fastforce
   let ?F = "\<lambda>g. \<lambda>u \<in> A'. if h u \<in> A then g(h u) else b"
   show ?thesis
     unfolding lepoll_def inj_on_def
   proof (intro exI conjI ballI impI ext)
     fix k l x
     assume k: "k \<in> A \<rightarrow>\<^sub>E B" and l: "l \<in> A \<rightarrow>\<^sub>E B" and "?F k = ?F l"
     then have "?F k (f x) = ?F l (f x)"
       by simp
     then show "k x = l x"
       apply (auto simp: h split: if_split_asm)
       apply (metis PiE_arb h k l)
       apply (metis (full_types) PiE_E h k l)
       using fim k l by fastforce
   next
     show "?F ` (A \<rightarrow>\<^sub>E B) \<subseteq> A' \<rightarrow>\<^sub>E B"
       using \<open>b \<in> B\<close> by force
   qed
 qed
 
 lemma lepoll_funcset:
    "\<lbrakk>B \<noteq> {}; A \<lesssim> A'; B \<lesssim> B'\<rbrakk> \<Longrightarrow> A \<rightarrow>\<^sub>E B \<lesssim> A' \<rightarrow>\<^sub>E B'"
   by (rule lepoll_trans [OF lepoll_funcset_right lepoll_funcset_left]) auto
 
 lemma lepoll_PiE:
   assumes "\<And>i. i \<in> A \<Longrightarrow> B i \<lesssim> C i"
   shows "PiE A B \<lesssim> PiE A C"
 proof -
   obtain f where f: "\<And>i. i \<in> A \<Longrightarrow> inj_on (f i) (B i) \<and> (f i) ` B i \<subseteq> C i"
     using assms unfolding lepoll_def by metis
   then show ?thesis
     unfolding lepoll_def
     apply (rule_tac x = "\<lambda>g. \<lambda>i \<in> A. f i (g i)" in exI)
     apply (auto simp: inj_on_def)
      apply (rule PiE_ext, auto)
      apply (metis (full_types) PiE_mem restrict_apply')
     by blast
 qed
 
 
 lemma card_le_PiE_subindex:
   assumes "A \<subseteq> A'" "Pi\<^sub>E A' B \<noteq> {}"
   shows "PiE A B \<lesssim> PiE A' B"
 proof -
   have "\<And>x. x \<in> A' \<Longrightarrow> \<exists>y. y \<in> B x"
     using assms by blast
   then obtain g where g: "\<And>x. x \<in> A' \<Longrightarrow> g x \<in> B x"
     by metis
   let ?F = "\<lambda>f x. if x \<in> A then f x else if x \<in> A' then g x else undefined"
   have "Pi\<^sub>E A B \<subseteq> (\<lambda>f. restrict f A) ` Pi\<^sub>E A' B"
   proof
     show "f \<in> Pi\<^sub>E A B \<Longrightarrow> f \<in> (\<lambda>f. restrict f A) ` Pi\<^sub>E A' B" for f
       using \<open>A \<subseteq> A'\<close>
       by (rule_tac x="?F f" in image_eqI) (auto simp: g fun_eq_iff)
   qed
   then have "Pi\<^sub>E A B \<lesssim> (\<lambda>f. \<lambda>i \<in> A. f i) ` Pi\<^sub>E A' B"
     by (simp add: subset_imp_lepoll)
   also have "\<dots> \<lesssim> PiE A' B"
     by (rule image_lepoll)
   finally show ?thesis .
 qed
 
 
 lemma finite_restricted_funspace:
   assumes "finite A" "finite B"
   shows "finite {f. f ` A \<subseteq> B \<and> {x. f x \<noteq> k x} \<subseteq> A}" (is "finite ?F")
 proof (rule finite_subset)
   show "finite ((\<lambda>U x. if \<exists>y. (x,y) \<in> U then @y. (x,y) \<in> U else k x) ` Pow(A \<times> B))" (is "finite ?G")
     using assms by auto
   show "?F \<subseteq> ?G"
   proof
     fix f
     assume "f \<in> ?F"
     then show "f \<in> ?G"
       by (rule_tac x="(\<lambda>x. (x,f x)) ` {x. f x \<noteq> k x}" in image_eqI) (auto simp: fun_eq_iff image_def)
   qed
 qed
 
 
 proposition finite_PiE_iff:
    "finite(PiE I S) \<longleftrightarrow> PiE I S = {} \<or> finite {i \<in> I. ~(\<exists>a. S i \<subseteq> {a})} \<and> (\<forall>i \<in> I. finite(S i))"
  (is "?lhs = ?rhs")
 proof (cases "PiE I S = {}")
   case False
   define J where "J \<equiv> {i \<in> I. \<nexists>a. S i \<subseteq> {a}}"
   show ?thesis
   proof
     assume L: ?lhs
     have "infinite (Pi\<^sub>E I S)" if "infinite J"
     proof -
       have "(UNIV::nat set) \<lesssim> (UNIV::(nat\<Rightarrow>bool) set)"
       proof -
         have "\<forall>N::nat set. inj_on (=) N"
           by (simp add: inj_on_def)
         then show ?thesis
           by (meson infinite_iff_countable_subset infinite_le_lepoll top.extremum)
       qed
       also have "\<dots> = (UNIV::nat set) \<rightarrow>\<^sub>E (UNIV::bool set)"
         by auto
       also have "\<dots> \<lesssim> J \<rightarrow>\<^sub>E (UNIV::bool set)"
         apply (rule lepoll_funcset_left)
         using infinite_le_lepoll that by auto
       also have "\<dots> \<lesssim> Pi\<^sub>E J S"
       proof -
         have *: "(UNIV::bool set) \<lesssim> S i" if "i \<in> I" and "\<forall>a. \<not> S i \<subseteq> {a}" for i
         proof -
           obtain a b where "{a,b} \<subseteq> S i" "a \<noteq> b"
             by (metis \<open>\<forall>a. \<not> S i \<subseteq> {a}\<close> all_not_in_conv empty_subsetI insertCI insert_subset set_eq_subset subsetI)
           then show ?thesis
             apply (clarsimp simp: lepoll_def inj_on_def)
             apply (rule_tac x="\<lambda>x. if x then a else b" in exI, auto)
             done
         qed
         show ?thesis
           by (auto simp: * J_def intro: lepoll_PiE)
       qed
       also have "\<dots> \<lesssim> Pi\<^sub>E I S"
         using False by (auto simp: J_def intro: card_le_PiE_subindex)
       finally have "(UNIV::nat set) \<lesssim> Pi\<^sub>E I S" .
       then show ?thesis
         by (simp add: infinite_le_lepoll)
     qed
     moreover have "finite (S i)" if "i \<in> I" for i
     proof (rule finite_subset)
       obtain f where f: "f \<in> PiE I S"
         using False by blast
       show "S i \<subseteq> (\<lambda>f. f i) ` Pi\<^sub>E I S"
       proof
         show "s \<in> (\<lambda>f. f i) ` Pi\<^sub>E I S" if "s \<in> S i" for s
           using that f \<open>i \<in> I\<close>
           by (rule_tac x="\<lambda>j. if j = i then s else f j" in image_eqI) auto
       qed
     next
       show "finite ((\<lambda>x. x i) ` Pi\<^sub>E I S)"
         using L by blast
     qed
     ultimately show ?rhs
       using L
       by (auto simp: J_def False)
   next
     assume R: ?rhs
     have "\<forall>i \<in> I - J. \<exists>a. S i = {a}"
       using False J_def by blast
     then obtain a where a: "\<forall>i \<in> I - J. S i = {a i}"
       by metis
     let ?F = "{f. f ` J \<subseteq> (\<Union>i \<in> J. S i) \<and> {i. f i \<noteq> (if i \<in> I then a i else undefined)} \<subseteq> J}"
     have *: "finite (Pi\<^sub>E I S)"
       if "finite J" and "\<forall>i\<in>I. finite (S i)"
     proof (rule finite_subset)
       show "Pi\<^sub>E I S \<subseteq> ?F"
         apply safe
         using J_def apply blast
         by (metis DiffI PiE_E a singletonD)
       show "finite ?F"
       proof (rule finite_restricted_funspace [OF \<open>finite J\<close>])
         show "finite (\<Union> (S ` J))"
           using that J_def by blast
       qed
   qed
   show ?lhs
       using R by (auto simp: * J_def)
   qed
 qed auto
 
 
 corollary finite_funcset_iff:
   "finite(I \<rightarrow>\<^sub>E S) \<longleftrightarrow> (\<exists>a. S \<subseteq> {a}) \<or> I = {} \<or> finite I \<and> finite S"
   apply (auto simp: finite_PiE_iff PiE_eq_empty_iff dest: not_finite_existsD)
   using finite.simps by auto
 
 end